cmake/OpenCVConfig.cmake

   1 # ===================================================================================
   2 #  The OpenCV CMake configuration file
   3 #
   4 #             ** File generated automatically, do not modify **
   5 #
   6 #  Usage from an external project:
   7 #    In your CMakeLists.txt, add these lines:
   8 #
   9 #    FIND_PACKAGE(OpenCV REQUIRED)
  10 #    TARGET_LINK_LIBRARIES(MY_TARGET_NAME ${OpenCV_LIBS})
  11 #
  12 #    Or you can search for specific OpenCV modules:
  13 #
  14 #    FIND_PACKAGE(OpenCV REQUIRED core highgui)
  15 #
  16 #    If the module is found then OPENCV_<MODULE>_FOUND is set to TRUE.
  17 #
  18 #    This file will define the following variables:
  19 #      - OpenCV_LIBS                     : The list of libraries to links against.
  20 #      - OpenCV_LIB_DIR                  : The directory(es) where lib files are. Calling LINK_DIRECTORIES
  21 #                                          with this path is NOT needed.
  22 #      - OpenCV_INCLUDE_DIRS             : The OpenCV include directories.
  23 #      - OpenCV_COMPUTE_CAPABILITIES     : The version of compute capability
  24 #      - OpenCV_ANDROID_NATIVE_API_LEVEL : Minimum required level of Android API
  25 #      - OpenCV_VERSION                  : The version of this OpenCV build. Example: "2.4.0"
  26 #      - OpenCV_VERSION_MAJOR            : Major version part of OpenCV_VERSION. Example: "2"
  27 #      - OpenCV_VERSION_MINOR            : Minor version part of OpenCV_VERSION. Example: "4"
  28 #      - OpenCV_VERSION_PATCH            : Patch version part of OpenCV_VERSION. Example: "0"
  29 #
  30 #    Advanced variables:
  31 #      - OpenCV_SHARED
  32 #      - OpenCV_CONFIG_PATH
  33 #      - OpenCV_LIB_COMPONENTS
  34 #
  35 # ===================================================================================
  36 #
  37 #    Windows pack specific options:
  38 #      - OpenCV_STATIC
  39 #      - OpenCV_CUDA
  40
  41 if(CMAKE_VERSION VERSION_GREATER 2.6)
  42   get_property(OpenCV_LANGUAGES GLOBAL PROPERTY ENABLED_LANGUAGES)
  43   if(NOT ";${OpenCV_LANGUAGES};" MATCHES ";CXX;")
  44     enable_language(CXX)
  45   endif()
  46 endif()
  47
  48 if(NOT DEFINED OpenCV_STATIC)
  49   # look for global setting
  50   if(NOT DEFINED BUILD_SHARED_LIBS OR BUILD_SHARED_LIBS)
  51     set(OpenCV_STATIC OFF)
  52   else()
  53     set(OpenCV_STATIC ON)
  54   endif()
  55 endif()
  56
  57 if(NOT DEFINED OpenCV_CUDA)
  58   # if user' app uses CUDA, then it probably wants CUDA-enabled OpenCV binaries
  59   if(CUDA_FOUND)
  60     set(OpenCV_CUDA ON)
  61   endif()
  62 endif()
  63
  64 if(MSVC)
  65   if(CMAKE_CL_64)
  66     set(OpenCV_ARCH x64)
  67     set(OpenCV_TBB_ARCH intel64)
  68   else()
  69     set(OpenCV_ARCH x86)
  70     set(OpenCV_TBB_ARCH ia32)
  71   endif()
  72   if(MSVC_VERSION EQUAL 1400)
  73     set(OpenCV_RUNTIME vc8)
  74   elseif(MSVC_VERSION EQUAL 1500)
  75     set(OpenCV_RUNTIME vc9)
  76   elseif(MSVC_VERSION EQUAL 1600)
  77     set(OpenCV_RUNTIME vc10)
  78   elseif(MSVC_VERSION EQUAL 1700)
  79     set(OpenCV_RUNTIME vc11)
  80   endif()
  81 elseif(MINGW)
  82   set(OpenCV_RUNTIME mingw)
  83
  84   execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpmachine
  85                   OUTPUT_VARIABLE OPENCV_GCC_TARGET_MACHINE
  86                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  87   if(CMAKE_OPENCV_GCC_TARGET_MACHINE MATCHES "64")
  88     set(MINGW64 1)
  89     set(OpenCV_ARCH x64)
  90   else()
  91     set(OpenCV_ARCH x86)
  92   endif()
  93 endif()
  94
  95 if(CMAKE_VERSION VERSION_GREATER 2.6.2)
  96   unset(OpenCV_CONFIG_PATH CACHE)
  97 endif()
  98
  99 get_filename_component(OpenCV_CONFIG_PATH "${CMAKE_CURRENT_LIST_FILE}" PATH CACHE)
 100 if(OpenCV_RUNTIME AND OpenCV_ARCH)
 101   if(OpenCV_STATIC AND EXISTS "${OpenCV_CONFIG_PATH}/${OpenCV_ARCH}/${OpenCV_RUNTIME}/staticlib/OpenCVConfig.cmake")
 102     if(OpenCV_CUDA AND EXISTS "${OpenCV_CONFIG_PATH}/gpu/${OpenCV_ARCH}/${OpenCV_RUNTIME}/staticlib/OpenCVConfig.cmake")
 103       set(OpenCV_LIB_PATH "${OpenCV_CONFIG_PATH}/gpu/${OpenCV_ARCH}/${OpenCV_RUNTIME}/staticlib")
 104     else()
 105       set(OpenCV_LIB_PATH "${OpenCV_CONFIG_PATH}/${OpenCV_ARCH}/${OpenCV_RUNTIME}/staticlib")
 106     endif()
 107   elseif(EXISTS "${OpenCV_CONFIG_PATH}/${OpenCV_ARCH}/${OpenCV_RUNTIME}/lib/OpenCVConfig.cmake")
 108     if(OpenCV_CUDA AND EXISTS "${OpenCV_CONFIG_PATH}/gpu/${OpenCV_ARCH}/${OpenCV_RUNTIME}/lib/OpenCVConfig.cmake")
 109       set(OpenCV_LIB_PATH "${OpenCV_CONFIG_PATH}/gpu/${OpenCV_ARCH}/${OpenCV_RUNTIME}/lib")
 110     else()
 111       set(OpenCV_LIB_PATH "${OpenCV_CONFIG_PATH}/${OpenCV_ARCH}/${OpenCV_RUNTIME}/lib")
 112     endif()
 113   endif()
 114 endif()
 115
 116 if(OpenCV_LIB_PATH AND EXISTS "${OpenCV_LIB_PATH}/OpenCVConfig.cmake")
 117   set(OpenCV_LIB_DIR_OPT "${OpenCV_LIB_PATH}" CACHE PATH "Path where release OpenCV libraries are located" FORCE)
 118   set(OpenCV_LIB_DIR_DBG "${OpenCV_LIB_PATH}" CACHE PATH "Path where debug OpenCV libraries are located" FORCE)
 119   set(OpenCV_3RDPARTY_LIB_DIR_OPT "${OpenCV_LIB_PATH}" CACHE PATH "Path where release 3rdpaty OpenCV dependencies are located" FORCE)
 120   set(OpenCV_3RDPARTY_LIB_DIR_DBG "${OpenCV_LIB_PATH}" CACHE PATH "Path where debug 3rdpaty OpenCV dependencies are located" FORCE)
 121
 122   include("${OpenCV_LIB_PATH}/OpenCVConfig.cmake")
 123
 124   if(OpenCV_CUDA)
 125     set(_OpenCV_LIBS "")
 126     foreach(_lib ${OpenCV_LIBS})
 127       string(REPLACE "${OpenCV_CONFIG_PATH}/gpu/${OpenCV_ARCH}/${OpenCV_RUNTIME}" "${OpenCV_CONFIG_PATH}/${OpenCV_ARCH}/${OpenCV_RUNTIME}" _lib2 "${_lib}")
 128       if(NOT EXISTS "${_lib}" AND EXISTS "${_lib2}")
 129         list(APPEND _OpenCV_LIBS "${_lib2}")
 130       else()
 131         list(APPEND _OpenCV_LIBS "${_lib}")
 132       endif()
 133     endforeach()
 134     set(OpenCV_LIBS ${_OpenCV_LIBS})
 135   endif()
 136   set(OpenCV_FOUND TRUE CACHE BOOL "" FORCE)
 137   set(OPENCV_FOUND TRUE CACHE BOOL "" FORCE)
 138
 139   if(NOT OpenCV_FIND_QUIETLY)
 140     message(STATUS "Found OpenCV ${OpenCV_VERSION} in ${OpenCV_LIB_PATH}")
 141     if(NOT OpenCV_LIB_PATH MATCHES "/staticlib")
 142       get_filename_component(_OpenCV_LIB_PATH "${OpenCV_LIB_PATH}/../bin" ABSOLUTE)
 143       file(TO_NATIVE_PATH "${_OpenCV_LIB_PATH}" _OpenCV_LIB_PATH)
 144       message(STATUS "You might need to add ${_OpenCV_LIB_PATH} to your PATH to be able to run your applications.")
 145       if(OpenCV_LIB_PATH MATCHES "/gpu/")
 146         string(REPLACE "\\gpu" "" _OpenCV_LIB_PATH2 "${_OpenCV_LIB_PATH}")
 147         message(STATUS "GPU support is enabled so you might also need ${_OpenCV_LIB_PATH2} in your PATH (it must go after the ${_OpenCV_LIB_PATH}).")
 148       endif()
 149     endif()
 150   endif()
 151 else()
 152   if(NOT OpenCV_FIND_QUIETLY)
 153     message(WARNING "Found OpenCV 2.4.3 Windows Super Pack but it has not binaries compatible with your configuration.
 154     You should manually point CMake variable OpenCV_DIR to your build of OpenCV library.")
 155   endif()
 156   set(OpenCV_FOUND FALSE CACHE BOOL "" FORCE)
 157   set(OPENCV_FOUND FALSE CACHE BOOL "" FORCE)
 158 endif()