cmake/OpenCVConfig.cmake

   1 # ===================================================================================
   2 #  The OpenCV CMake configuration file
   3 #
   4 #             ** File generated automatically, do not modify **
   5 #
   6 #  Usage from an external project:
   7 #    In your CMakeLists.txt, add these lines:
   8 #
   9 #    FIND_PACKAGE(OpenCV REQUIRED)
  10 #    TARGET_LINK_LIBRARIES(MY_TARGET_NAME ${OpenCV_LIBS})
  11 #
  12 #    Or you can search for specific OpenCV modules:
  13 #
  14 #    FIND_PACKAGE(OpenCV REQUIRED core highgui)
  15 #
  16 #    If the module is found then OPENCV_<MODULE>_FOUND is set to TRUE.
  17 #
  18 #    This file will define the following variables:
  19 #      - OpenCV_LIBS                     : The list of libraries to links against.
  20 #      - OpenCV_LIB_DIR                  : The directory(es) where lib files are. Calling LINK_DIRECTORIES
  21 #                                          with this path is NOT needed.
  22 #      - OpenCV_INCLUDE_DIRS             : The OpenCV include directories.
  23 #      - OpenCV_COMPUTE_CAPABILITIES     : The version of compute capability
  24 #      - OpenCV_ANDROID_NATIVE_API_LEVEL : Minimum required level of Android API
  25 #      - OpenCV_VERSION                  : The version of this OpenCV build. Example: "2.4.0"
  26 #      - OpenCV_VERSION_MAJOR            : Major version part of OpenCV_VERSION. Example: "2"
  27 #      - OpenCV_VERSION_MINOR            : Minor version part of OpenCV_VERSION. Example: "4"
  28 #      - OpenCV_VERSION_PATCH            : Patch version part of OpenCV_VERSION. Example: "0"
  29 #
  30 #    Advanced variables:
  31 #      - OpenCV_SHARED
  32 #      - OpenCV_CONFIG_PATH
  33 #      - OpenCV_LIB_COMPONENTS
  34 #
  35 # ===================================================================================
  36 #
  37 #    Windows pack specific options:
  38 #      - OpenCV_STATIC
  39 #      - OpenCV_CUDA
  40
  41 get_property(OpenCV_LANGUAGES GLOBAL PROPERTY ENABLED_LANGUAGES)
  42 if(NOT ";${OpenCV_LANGUAGES};" MATCHES ";CXX;")
  43   enable_language(CXX)
  44 endif()
  45
  46 if(NOT DEFINED OpenCV_STATIC)
  47   # look for global setting
  48   if(NOT DEFINED BUILD_SHARED_LIBS OR BUILD_SHARED_LIBS)
  49     set(OpenCV_STATIC OFF)
  50   else()
  51     set(OpenCV_STATIC ON)
  52   endif()
  53 endif()
  54
  55 if(NOT DEFINED OpenCV_CUDA)
  56   # if user' app uses CUDA, then it probably wants CUDA-enabled OpenCV binaries
  57   if(CUDA_FOUND)
  58     set(OpenCV_CUDA ON)
  59   endif()
  60 endif()
  61
  62 if(MSVC)
  63   if(CMAKE_CL_64)
  64     set(OpenCV_ARCH x64)
  65     set(OpenCV_TBB_ARCH intel64)
  66   else()
  67     set(OpenCV_ARCH x86)
  68     set(OpenCV_TBB_ARCH ia32)
  69   endif()
  70   if(MSVC_VERSION EQUAL 1400)
  71     set(OpenCV_RUNTIME vc8)
  72   elseif(MSVC_VERSION EQUAL 1500)
  73     set(OpenCV_RUNTIME vc9)
  74   elseif(MSVC_VERSION EQUAL 1600)
  75     set(OpenCV_RUNTIME vc10)
  76   elseif(MSVC_VERSION EQUAL 1700)
  77     set(OpenCV_RUNTIME vc11)
  78   endif()
  79 elseif(MINGW)
  80   set(OpenCV_RUNTIME mingw)
  81
  82   execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpmachine
  83                   OUTPUT_VARIABLE OPENCV_GCC_TARGET_MACHINE
  84                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  85   if(CMAKE_OPENCV_GCC_TARGET_MACHINE MATCHES "64")
  86     set(MINGW64 1)
  87     set(OpenCV_ARCH x64)
  88   else()
  89     set(OpenCV_ARCH x86)
  90   endif()
  91 endif()
  92
  93 unset(OpenCV_CONFIG_PATH CACHE)
  94
  95 get_filename_component(OpenCV_CONFIG_PATH "${CMAKE_CURRENT_LIST_FILE}" PATH CACHE)
  96 if(OpenCV_RUNTIME AND OpenCV_ARCH)
  97   if(OpenCV_STATIC AND EXISTS "${OpenCV_CONFIG_PATH}/${OpenCV_ARCH}/${OpenCV_RUNTIME}/staticlib/OpenCVConfig.cmake")
  98     if(OpenCV_CUDA AND EXISTS "${OpenCV_CONFIG_PATH}/gpu/${OpenCV_ARCH}/${OpenCV_RUNTIME}/staticlib/OpenCVConfig.cmake")
  99       set(OpenCV_LIB_PATH "${OpenCV_CONFIG_PATH}/gpu/${OpenCV_ARCH}/${OpenCV_RUNTIME}/staticlib")
 100     else()
 101       set(OpenCV_LIB_PATH "${OpenCV_CONFIG_PATH}/${OpenCV_ARCH}/${OpenCV_RUNTIME}/staticlib")
 102     endif()
 103   elseif(EXISTS "${OpenCV_CONFIG_PATH}/${OpenCV_ARCH}/${OpenCV_RUNTIME}/lib/OpenCVConfig.cmake")
 104     if(OpenCV_CUDA AND EXISTS "${OpenCV_CONFIG_PATH}/gpu/${OpenCV_ARCH}/${OpenCV_RUNTIME}/lib/OpenCVConfig.cmake")
 105       set(OpenCV_LIB_PATH "${OpenCV_CONFIG_PATH}/gpu/${OpenCV_ARCH}/${OpenCV_RUNTIME}/lib")
 106     else()
 107       set(OpenCV_LIB_PATH "${OpenCV_CONFIG_PATH}/${OpenCV_ARCH}/${OpenCV_RUNTIME}/lib")
 108     endif()
 109   endif()
 110 endif()
 111
 112 if(OpenCV_LIB_PATH AND EXISTS "${OpenCV_LIB_PATH}/OpenCVConfig.cmake")
 113   set(OpenCV_LIB_DIR_OPT "${OpenCV_LIB_PATH}" CACHE PATH "Path where release OpenCV libraries are located" FORCE)
 114   set(OpenCV_LIB_DIR_DBG "${OpenCV_LIB_PATH}" CACHE PATH "Path where debug OpenCV libraries are located" FORCE)
 115   set(OpenCV_3RDPARTY_LIB_DIR_OPT "${OpenCV_LIB_PATH}" CACHE PATH "Path where release 3rdpaty OpenCV dependencies are located" FORCE)
 116   set(OpenCV_3RDPARTY_LIB_DIR_DBG "${OpenCV_LIB_PATH}" CACHE PATH "Path where debug 3rdpaty OpenCV dependencies are located" FORCE)
 117
 118   include("${OpenCV_LIB_PATH}/OpenCVConfig.cmake")
 119
 120   if(OpenCV_CUDA)
 121     set(_OpenCV_LIBS "")
 122     foreach(_lib ${OpenCV_LIBS})
 123       string(REPLACE "${OpenCV_CONFIG_PATH}/gpu/${OpenCV_ARCH}/${OpenCV_RUNTIME}" "${OpenCV_CONFIG_PATH}/${OpenCV_ARCH}/${OpenCV_RUNTIME}" _lib2 "${_lib}")
 124       if(NOT EXISTS "${_lib}" AND EXISTS "${_lib2}")
 125         list(APPEND _OpenCV_LIBS "${_lib2}")
 126       else()
 127         list(APPEND _OpenCV_LIBS "${_lib}")
 128       endif()
 129     endforeach()
 130     set(OpenCV_LIBS ${_OpenCV_LIBS})
 131   endif()
 132   set(OpenCV_FOUND TRUE CACHE BOOL "" FORCE)
 133   set(OPENCV_FOUND TRUE CACHE BOOL "" FORCE)
 134
 135   if(NOT OpenCV_FIND_QUIETLY)
 136     message(STATUS "Found OpenCV ${OpenCV_VERSION} in ${OpenCV_LIB_PATH}")
 137     if(NOT OpenCV_LIB_PATH MATCHES "/staticlib")
 138       get_filename_component(_OpenCV_LIB_PATH "${OpenCV_LIB_PATH}/../bin" ABSOLUTE)
 139       file(TO_NATIVE_PATH "${_OpenCV_LIB_PATH}" _OpenCV_LIB_PATH)
 140       message(STATUS "You might need to add ${_OpenCV_LIB_PATH} to your PATH to be able to run your applications.")
 141       if(OpenCV_LIB_PATH MATCHES "/gpu/")
 142         string(REPLACE "\\gpu" "" _OpenCV_LIB_PATH2 "${_OpenCV_LIB_PATH}")
 143         message(STATUS "GPU support is enabled so you might also need ${_OpenCV_LIB_PATH2} in your PATH (it must go after the ${_OpenCV_LIB_PATH}).")
 144       endif()
 145     endif()
 146   endif()
 147 else()
 148   if(NOT OpenCV_FIND_QUIETLY)
 149     message(WARNING "Found OpenCV 2.4.3 Windows Super Pack but it has not binaries compatible with your configuration.
 150     You should manually point CMake variable OpenCV_DIR to your build of OpenCV library.")
 151   endif()
 152   set(OpenCV_FOUND FALSE CACHE BOOL "" FORCE)
 153   set(OPENCV_FOUND FALSE CACHE BOOL "" FORCE)
 154 endif()