cmake/OpenCVCompilerOptions.cmake

   1 if("${CMAKE_CXX_COMPILER};${CMAKE_C_COMPILER};${CMAKE_CXX_COMPILER_LAUNCHER}" MATCHES "ccache")
   2   set(CMAKE_COMPILER_IS_CCACHE 1)  # TODO: FIXIT Avoid setting of CMAKE_ variables
   3   set(OPENCV_COMPILER_IS_CCACHE 1)
   4 endif()
   5 function(access_CMAKE_COMPILER_IS_CCACHE)
   6   if(NOT OPENCV_SUPPRESS_DEPRECATIONS)
   7     message(WARNING "DEPRECATED: CMAKE_COMPILER_IS_CCACHE is replaced to OPENCV_COMPILER_IS_CCACHE.")
   8   endif()
   9 endfunction()
  10 variable_watch(CMAKE_COMPILER_IS_CCACHE access_CMAKE_COMPILER_IS_CCACHE)
  11 if(ENABLE_CCACHE AND NOT OPENCV_COMPILER_IS_CCACHE AND NOT CMAKE_GENERATOR MATCHES "Xcode")
  12   # This works fine with Unix Makefiles and Ninja generators
  13   find_host_program(CCACHE_PROGRAM ccache)
  14   if(CCACHE_PROGRAM)
  15     message(STATUS "Looking for ccache - found (${CCACHE_PROGRAM})")
  16     get_property(__OLD_RULE_LAUNCH_COMPILE GLOBAL PROPERTY RULE_LAUNCH_COMPILE)
  17     if(__OLD_RULE_LAUNCH_COMPILE)
  18       message(STATUS "Can't replace CMake compiler launcher")
  19     else()
  20       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
  21       # NOTE: Actually this check doesn't work as expected.
  22       # "RULE_LAUNCH_COMPILE" is ignored by CMake during try_compile() step.
  23       # ocv_check_compiler_flag(CXX "" IS_CCACHE_WORKS)
  24       set(IS_CCACHE_WORKS 1)
  25       if(IS_CCACHE_WORKS)
  26         set(OPENCV_COMPILER_IS_CCACHE 1)
  27       else()
  28         message(STATUS "Unable to compile program with enabled ccache, reverting...")
  29         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${__OLD_RULE_LAUNCH_COMPILE}")
  30       endif()
  31     endif()
  32   else()
  33     message(STATUS "Looking for ccache - not found")
  34   endif()
  35 endif()
  36
  37 if((CV_CLANG AND NOT CMAKE_GENERATOR MATCHES "Xcode")  # PCH has no support for Clang
  38     OR OPENCV_COMPILER_IS_CCACHE
  39 )
  40   set(ENABLE_PRECOMPILED_HEADERS OFF CACHE BOOL "" FORCE)
  41 endif()
  42
  43 macro(add_extra_compiler_option option)
  44   ocv_check_flag_support(CXX "${option}" _varname "${OPENCV_EXTRA_CXX_FLAGS} ${ARGN}")
  45   if(${_varname})
  46     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} ${option}")
  47   endif()
  48
  49   ocv_check_flag_support(C "${option}" _varname "${OPENCV_EXTRA_C_FLAGS} ${ARGN}")
  50   if(${_varname})
  51     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} ${option}")
  52   endif()
  53 endmacro()
  54
  55 macro(add_extra_compiler_option_force option)
  56   set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} ${option}")
  57   set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} ${option}")
  58 endmacro()
  59
  60
  61 # Gets environment variable and puts its value to the corresponding preprocessor definition
  62 # Useful for WINRT that has no access to environment variables
  63 macro(add_env_definitions option)
  64   set(value $ENV{${option}})
  65   if("${value}" STREQUAL "")
  66     message(WARNING "${option} environment variable is empty. Please set it to appropriate location to get correct results")
  67   else()
  68     string(REPLACE "\\" "\\\\" value ${value})
  69   endif()
  70   add_definitions("-D${option}=\"${value}\"")
  71 endmacro()
  72
  73 if(NOT MSVC)
  74   # OpenCV fails some tests when 'char' is 'unsigned' by default
  75   add_extra_compiler_option(-fsigned-char)
  76 endif()
  77
  78 if(CV_ICC AND NOT ENABLE_FAST_MATH)
  79   if(MSVC)
  80     add_extra_compiler_option("/fp:precise")
  81   else()
  82     add_extra_compiler_option("-fp-model precise")
  83   endif()
  84 endif()
  85
  86 if(CV_GCC OR CV_CLANG)
  87   # High level of warnings.
  88   add_extra_compiler_option(-W)
  89   if (NOT MSVC)
  90     # clang-cl interprets -Wall as MSVC would: -Weverything, which is more than
  91     # we want.
  92     add_extra_compiler_option(-Wall)
  93   endif()
  94   add_extra_compiler_option(-Werror=return-type)
  95   add_extra_compiler_option(-Werror=non-virtual-dtor)
  96   add_extra_compiler_option(-Werror=address)
  97   add_extra_compiler_option(-Werror=sequence-point)
  98   add_extra_compiler_option(-Wformat)
  99   add_extra_compiler_option(-Werror=format-security -Wformat)
 100   add_extra_compiler_option(-Wmissing-declarations)
 101   add_extra_compiler_option(-Wmissing-prototypes)
 102   add_extra_compiler_option(-Wstrict-prototypes)
 103   add_extra_compiler_option(-Wundef)
 104   add_extra_compiler_option(-Winit-self)
 105   add_extra_compiler_option(-Wpointer-arith)
 106   add_extra_compiler_option(-Wshadow)
 107   add_extra_compiler_option(-Wsign-promo)
 108   add_extra_compiler_option(-Wuninitialized)
 109   add_extra_compiler_option(-Winit-self)
 110   if(HAVE_CXX11)
 111     if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND NOT ENABLE_PRECOMPILED_HEADERS)
 112       add_extra_compiler_option(-Wsuggest-override)
 113     elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 114       add_extra_compiler_option(-Winconsistent-missing-override)
 115     endif()
 116   endif()
 117
 118   if(ENABLE_NOISY_WARNINGS)
 119     add_extra_compiler_option(-Wcast-align)
 120     add_extra_compiler_option(-Wstrict-aliasing=2)
 121   else()
 122     add_extra_compiler_option(-Wno-delete-non-virtual-dtor)
 123     add_extra_compiler_option(-Wno-unnamed-type-template-args)
 124     add_extra_compiler_option(-Wno-comment)
 125     if(NOT OPENCV_SKIP_IMPLICIT_FALLTHROUGH
 126         AND NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES "implicit-fallthrough"
 127         AND (CV_GCC AND NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS 7.0.0)
 128     )
 129       add_extra_compiler_option(-Wimplicit-fallthrough=3)
 130     endif()
 131     if(CV_GCC AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 7.0)
 132       add_extra_compiler_option(-Wno-strict-overflow) # Issue appears when compiling surf.cpp from opencv_contrib/modules/xfeatures2d
 133     endif()
 134     if(CV_GCC AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 5.0)
 135       add_extra_compiler_option(-Wno-missing-field-initializers)  # GCC 4.x emits warnings about {}, fixed in GCC 5+
 136     endif()
 137   endif()
 138   add_extra_compiler_option(-fdiagnostics-show-option)
 139
 140   # The -Wno-long-long is required in 64bit systems when including system headers.
 141   if(X86_64)
 142     add_extra_compiler_option(-Wno-long-long)
 143   endif()
 144
 145   # We need pthread's
 146   if(UNIX AND NOT ANDROID AND NOT (APPLE AND CV_CLANG)) # TODO
 147     add_extra_compiler_option(-pthread)
 148   endif()
 149
 150   if(CV_CLANG)
 151     add_extra_compiler_option(-Qunused-arguments)
 152   endif()
 153
 154   if(OPENCV_WARNINGS_ARE_ERRORS)
 155     add_extra_compiler_option(-Werror)
 156   endif()
 157
 158   if(APPLE)
 159     add_extra_compiler_option(-Wno-semicolon-before-method-body)
 160   endif()
 161
 162   # Other optimizations
 163   if(ENABLE_OMIT_FRAME_POINTER)
 164     add_extra_compiler_option(-fomit-frame-pointer)
 165   elseif(DEFINED ENABLE_OMIT_FRAME_POINTER)
 166     add_extra_compiler_option(-fno-omit-frame-pointer)
 167   endif()
 168   if(ENABLE_FAST_MATH)
 169     add_extra_compiler_option(-ffast-math)
 170   endif()
 171
 172   # Profiling?
 173   if(ENABLE_PROFILING)
 174     add_extra_compiler_option("-pg -g")
 175     # turn off incompatible options
 176     foreach(flags CMAKE_CXX_FLAGS CMAKE_C_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG CMAKE_C_FLAGS_DEBUG
 177                   OPENCV_EXTRA_FLAGS_RELEASE OPENCV_EXTRA_FLAGS_DEBUG OPENCV_EXTRA_C_FLAGS OPENCV_EXTRA_CXX_FLAGS)
 178       string(REPLACE "-fomit-frame-pointer" "" ${flags} "${${flags}}")
 179       string(REPLACE "-ffunction-sections" "" ${flags} "${${flags}}")
 180       string(REPLACE "-fdata-sections" "" ${flags} "${${flags}}")
 181     endforeach()
 182   else()
 183     if(MSVC)
 184       # TODO: Clang/C2 is not supported
 185     elseif(((IOS OR ANDROID) AND NOT BUILD_SHARED_LIBS) AND NOT OPENCV_FORCE_FUNCTIONS_SECTIONS)
 186       # don't create separate sections for functions/data, reduce package size
 187     else()
 188       # Remove unreferenced functions: function level linking
 189       add_extra_compiler_option(-ffunction-sections)
 190       add_extra_compiler_option(-fdata-sections)
 191       if(NOT OPENCV_SKIP_GC_SECTIONS)
 192         if(APPLE)
 193           set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS} -Wl,-dead_strip")
 194           set(OPENCV_EXTRA_SHARED_LINKER_FLAGS "${OPENCV_EXTRA_SHARED_LINKER_FLAGS} -Wl,-dead_strip")
 195         else()
 196           set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS} -Wl,--gc-sections")
 197           set(OPENCV_EXTRA_SHARED_LINKER_FLAGS "${OPENCV_EXTRA_SHARED_LINKER_FLAGS} -Wl,--gc-sections")
 198         endif()
 199       endif()
 200     endif()
 201   endif()
 202
 203   if(ENABLE_COVERAGE)
 204     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} --coverage")
 205     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} --coverage")
 206     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} --coverage")
 207   endif()
 208
 209   if(ENABLE_INSTRUMENTATION)
 210     if(NOT HAVE_CXX11)
 211       message(WARNING "ENABLE_INSTRUMENTATION requires C++11 support")
 212     endif()
 213     set(WITH_VTK OFF) # There are issues with VTK 6.0
 214   endif()
 215
 216   if(ENABLE_LTO)
 217     add_extra_compiler_option(-flto)
 218   endif()
 219   if(ENABLE_THIN_LTO)
 220     add_extra_compiler_option(-flto=thin)
 221   endif()
 222
 223   set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} -DNDEBUG")
 224   if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG} " MATCHES "-O")
 225     set(OPENCV_EXTRA_FLAGS_DEBUG "${OPENCV_EXTRA_FLAGS_DEBUG} -O0")
 226   endif()
 227   set(OPENCV_EXTRA_FLAGS_DEBUG "${OPENCV_EXTRA_FLAGS_DEBUG} -DDEBUG -D_DEBUG")
 228
 229   if(BUILD_WITH_DEBUG_INFO)
 230     # https://gcc.gnu.org/onlinedocs/gcc/Debugging-Options.html
 231     # '-g' is equal to '-g2', '-g1' produces minimal information, enough for making backtraces
 232     ocv_update(OPENCV_DEBUG_OPTION "-g1")
 233     if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS_RELEASE}" MATCHES " -g")
 234       set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} ${OPENCV_DEBUG_OPTION}")
 235     endif()
 236   endif()
 237 endif()
 238
 239 if(MSVC)
 240   #TODO Code refactoring is required to resolve security warnings
 241   #if(NOT ENABLE_BUILD_HARDENING)
 242     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /D _CRT_SECURE_NO_DEPRECATE /D _CRT_NONSTDC_NO_DEPRECATE /D _SCL_SECURE_NO_WARNINGS")
 243   #endif()
 244
 245   if(BUILD_WITH_DEBUG_INFO)
 246     set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} /Zi")
 247     set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE} /debug")
 248     set(OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE} /debug")
 249   endif()
 250
 251   # Remove unreferenced functions: function level linking
 252   set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /Gy")
 253   if(NOT MSVC_VERSION LESS 1400)
 254     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /bigobj")
 255   endif()
 256
 257   if(OPENCV_WARNINGS_ARE_ERRORS)
 258     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /WX")
 259   endif()
 260
 261   if(ENABLE_LTO)
 262     set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} /GL")
 263     set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE} /LTCG")
 264   endif()
 265
 266   if(NOT MSVC_VERSION LESS 1800 AND NOT CMAKE_GENERATOR MATCHES "Visual Studio")
 267     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} /FS")
 268     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} /FS")
 269   endif()
 270 endif()
 271
 272 # Adding additional using directory for WindowsPhone 8.0 to get Windows.winmd properly
 273 if(WINRT_PHONE AND WINRT_8_0)
 274   set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} /AI\$(WindowsSDK_MetadataPath)")
 275 endif()
 276
 277 include(cmake/OpenCVCompilerOptimizations.cmake)
 278 if(COMMAND ocv_compiler_optimization_options)
 279   ocv_compiler_optimization_options()
 280 endif()
 281 if(COMMAND ocv_compiler_optimization_options_finalize)
 282   ocv_compiler_optimization_options_finalize()
 283 endif()
 284
 285 # set default visibility to hidden
 286 if((CV_GCC OR CV_CLANG)
 287     AND NOT MSVC
 288     AND NOT OPENCV_SKIP_VISIBILITY_HIDDEN
 289     AND NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " -fvisibility")
 290   add_extra_compiler_option(-fvisibility=hidden)
 291   add_extra_compiler_option(-fvisibility-inlines-hidden)
 292 endif()
 293
 294 # workaround gcc bug for aligned ld/st
 295 # https://github.com/opencv/opencv/issues/13211
 296 if((PPC64LE AND NOT CMAKE_CROSSCOMPILING) OR OPENCV_FORCE_COMPILER_CHECK_VSX_ALIGNED)
 297   ocv_check_runtime_flag("${CPU_BASELINE_FLAGS}" OPENCV_CHECK_VSX_ALIGNED "${OpenCV_SOURCE_DIR}/cmake/checks/runtime/cpu_vsx_aligned.cpp")
 298   if(NOT OPENCV_CHECK_VSX_ALIGNED)
 299     add_extra_compiler_option_force(-DCV_COMPILER_VSX_BROKEN_ALIGNED)
 300   endif()
 301 endif()
 302 # validate inline asm with fixes register number and constraints wa, wd, wf
 303 if(PPC64LE)
 304   ocv_check_compiler_flag(CXX "${CPU_BASELINE_FLAGS}" OPENCV_CHECK_VSX_ASM "${OpenCV_SOURCE_DIR}/cmake/checks/cpu_vsx_asm.cpp")
 305   if(NOT OPENCV_CHECK_VSX_ASM)
 306     add_extra_compiler_option_force(-DCV_COMPILER_VSX_BROKEN_ASM)
 307   endif()
 308 endif()
 309
 310 # combine all "extra" options
 311 if(NOT OPENCV_SKIP_EXTRA_COMPILER_FLAGS)
 312   set(CMAKE_C_FLAGS           "${CMAKE_C_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_C_FLAGS}")
 313   set(CMAKE_CXX_FLAGS         "${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}")
 314   set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_FLAGS_RELEASE}")
 315   set(CMAKE_C_FLAGS_RELEASE   "${CMAKE_C_FLAGS_RELEASE} ${OPENCV_EXTRA_FLAGS_RELEASE}")
 316   set(CMAKE_CXX_FLAGS_DEBUG   "${CMAKE_CXX_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG}")
 317   set(CMAKE_C_FLAGS_DEBUG     "${CMAKE_C_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG}")
 318   set(CMAKE_EXE_LINKER_FLAGS         "${CMAKE_EXE_LINKER_FLAGS} ${OPENCV_EXTRA_EXE_LINKER_FLAGS}")
 319   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE}")
 320   set(CMAKE_EXE_LINKER_FLAGS_DEBUG   "${CMAKE_EXE_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_DEBUG}")
 321   set(CMAKE_SHARED_LINKER_FLAGS         "${CMAKE_SHARED_LINKER_FLAGS} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS}")
 322   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE}")
 323   set(CMAKE_SHARED_LINKER_FLAGS_DEBUG   "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS_DEBUG}")
 324 endif()
 325
 326 if(MSVC)
 327   if(NOT ENABLE_NOISY_WARNINGS)
 328     if(MSVC_VERSION EQUAL 1400)
 329       ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4510 /wd4610 /wd4312 /wd4201 /wd4244 /wd4328 /wd4267)
 330     endif()
 331   endif()
 332
 333   foreach(flags CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 334     string(REPLACE "/Zm1000" "" ${flags} "${${flags}}")
 335   endforeach()
 336
 337   # Enable 'extern "C"' and asynchronous (division by zero, access violation) exceptions
 338   if(NOT OPENCV_SKIP_MSVC_EXCEPTIONS_FLAG)
 339     foreach(flags CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 340       string(REGEX REPLACE " /EH[^ ]* " " " ${flags} " ${${flags}}")
 341     endforeach()
 342     if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${CMAKE_CXX_FLAGS_DEBUG}" MATCHES " /EH")
 343       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /EHa")
 344     endif()
 345   endif()
 346
 347   if(NOT ENABLE_NOISY_WARNINGS)
 348     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4127) # conditional expression is constant
 349     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4251) # class 'std::XXX' needs to have dll-interface to be used by clients of YYY
 350     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4324) # 'struct_name' : structure was padded due to __declspec(align())
 351     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4275) # non dll-interface class 'std::exception' used as base for dll-interface class 'cv::Exception'
 352     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4512) # Assignment operator could not be generated
 353     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4589) # Constructor of abstract class 'cv::ORB' ignores initializer for virtual base class 'cv::Algorithm'
 354   endif()
 355
 356   if(CV_ICC AND NOT ENABLE_NOISY_WARNINGS)
 357     foreach(flags CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_DEBUG)
 358       string(REGEX REPLACE "( |^)/W[0-9]+( |$)" "\\1\\2" ${flags} "${${flags}}")
 359     endforeach()
 360     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /Qwd673") # PCH warning
 361   endif()
 362 endif()
 363
 364 if(APPLE AND NOT CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{LDFLAGS} AND EXISTS "/usr/local/lib")
 365   link_directories("/usr/local/lib")
 366 endif()
 367
 368 if(ENABLE_BUILD_HARDENING)
 369   include(${CMAKE_CURRENT_LIST_DIR}/OpenCVCompilerDefenses.cmake)
 370 endif()
 371
 372 if(MSVC)
 373   include(cmake/OpenCVCRTLinkage.cmake)
 374   add_definitions(-D_VARIADIC_MAX=10)
 375 endif()
 376
 377 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 378 macro(ocv_add_modules_compiler_options)
 379   if(MSVC AND NOT OPENCV_SKIP_MSVC_W4_OPTION)
 380     foreach(flags CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 381       string(REPLACE "/W3" "/W4" ${flags} "${${flags}}")
 382     endforeach()
 383   endif()
 384 endmacro()