cmake/OpenCVCompilerOptions.cmake

   1 if("${CMAKE_CXX_COMPILER};${CMAKE_C_COMPILER};${CMAKE_CXX_COMPILER_LAUNCHER}" MATCHES "ccache")
   2   set(CMAKE_COMPILER_IS_CCACHE 1)  # TODO: FIXIT Avoid setting of CMAKE_ variables
   3   set(OPENCV_COMPILER_IS_CCACHE 1)
   4 endif()
   5 function(access_CMAKE_COMPILER_IS_CCACHE)
   6   if(NOT OPENCV_SUPPRESS_DEPRECATIONS)
   7     message(WARNING "DEPRECATED: CMAKE_COMPILER_IS_CCACHE is replaced to OPENCV_COMPILER_IS_CCACHE.")
   8   endif()
   9 endfunction()
  10 variable_watch(CMAKE_COMPILER_IS_CCACHE access_CMAKE_COMPILER_IS_CCACHE)
  11 if(ENABLE_CCACHE AND NOT OPENCV_COMPILER_IS_CCACHE)
  12   # This works fine with Unix Makefiles and Ninja generators
  13   find_host_program(CCACHE_PROGRAM ccache)
  14   if(CCACHE_PROGRAM)
  15     message(STATUS "Looking for ccache - found (${CCACHE_PROGRAM})")
  16     get_property(__OLD_RULE_LAUNCH_COMPILE GLOBAL PROPERTY RULE_LAUNCH_COMPILE)
  17     if(CMAKE_GENERATOR MATCHES "Xcode")
  18       configure_file("${CMAKE_CURRENT_LIST_DIR}/templates/xcode-launch-c.in" "${CMAKE_BINARY_DIR}/xcode-launch-c")
  19       configure_file("${CMAKE_CURRENT_LIST_DIR}/templates/xcode-launch-cxx.in" "${CMAKE_BINARY_DIR}/xcode-launch-cxx")
  20       execute_process(COMMAND chmod a+rx
  21           "${CMAKE_BINARY_DIR}/xcode-launch-c"
  22           "${CMAKE_BINARY_DIR}/xcode-launch-cxx"
  23       )
  24       # Xcode project attributes
  25       set(CMAKE_XCODE_ATTRIBUTE_CC         "${CMAKE_BINARY_DIR}/xcode-launch-c")
  26       set(CMAKE_XCODE_ATTRIBUTE_CXX        "${CMAKE_BINARY_DIR}/xcode-launch-cxx")
  27       set(CMAKE_XCODE_ATTRIBUTE_LD         "${CMAKE_BINARY_DIR}/xcode-launch-c")
  28       set(CMAKE_XCODE_ATTRIBUTE_LDPLUSPLUS "${CMAKE_BINARY_DIR}/xcode-launch-cxx")
  29       set(OPENCV_COMPILER_IS_CCACHE 1)
  30       message(STATUS "ccache: enable support through Xcode project properties")
  31     elseif(__OLD_RULE_LAUNCH_COMPILE)
  32       message(STATUS "Can't replace CMake compiler launcher")
  33     else()
  34       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
  35       # NOTE: Actually this check doesn't work as expected.
  36       # "RULE_LAUNCH_COMPILE" is ignored by CMake during try_compile() step.
  37       # ocv_check_compiler_flag(CXX "" IS_CCACHE_WORKS)
  38       set(IS_CCACHE_WORKS 1)
  39       if(IS_CCACHE_WORKS)
  40         set(OPENCV_COMPILER_IS_CCACHE 1)
  41       else()
  42         message(STATUS "Unable to compile program with enabled ccache, reverting...")
  43         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${__OLD_RULE_LAUNCH_COMPILE}")
  44       endif()
  45     endif()
  46   else()
  47     message(STATUS "Looking for ccache - not found")
  48   endif()
  49 endif()
  50
  51 if((CV_CLANG AND NOT CMAKE_GENERATOR MATCHES "Xcode")  # PCH has no support for Clang
  52     OR OPENCV_COMPILER_IS_CCACHE
  53 )
  54   set(ENABLE_PRECOMPILED_HEADERS OFF CACHE BOOL "" FORCE)
  55 endif()
  56
  57 macro(add_extra_compiler_option option)
  58   ocv_check_flag_support(CXX "${option}" _varname "${OPENCV_EXTRA_CXX_FLAGS} ${ARGN}")
  59   if(${_varname})
  60     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} ${option}")
  61   endif()
  62
  63   ocv_check_flag_support(C "${option}" _varname "${OPENCV_EXTRA_C_FLAGS} ${ARGN}")
  64   if(${_varname})
  65     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} ${option}")
  66   endif()
  67 endmacro()
  68
  69 macro(add_extra_compiler_option_force option)
  70   set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} ${option}")
  71   set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} ${option}")
  72 endmacro()
  73
  74
  75 # Gets environment variable and puts its value to the corresponding preprocessor definition
  76 # Useful for WINRT that has no access to environment variables
  77 macro(add_env_definitions option)
  78   set(value $ENV{${option}})
  79   if("${value}" STREQUAL "")
  80     message(WARNING "${option} environment variable is empty. Please set it to appropriate location to get correct results")
  81   else()
  82     string(REPLACE "\\" "\\\\" value ${value})
  83   endif()
  84   add_definitions("-D${option}=\"${value}\"")
  85 endmacro()
  86
  87 if(NOT MSVC)
  88   # OpenCV fails some tests when 'char' is 'unsigned' by default
  89   add_extra_compiler_option(-fsigned-char)
  90 endif()
  91
  92 if(MSVC)
  93   if(NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " /fp:")
  94     if(ENABLE_FAST_MATH)
  95       add_extra_compiler_option("/fp:fast")
  96     else()
  97       add_extra_compiler_option("/fp:precise")
  98     endif()
  99   endif()
 100 elseif(CV_ICC)
 101   if(NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " /fp:"
 102       AND NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " -fp-model"
 103   )
 104     if(NOT ENABLE_FAST_MATH)
 105       add_extra_compiler_option("-fp-model precise")
 106     endif()
 107   endif()
 108 elseif(CV_GCC OR CV_CLANG)
 109   if(ENABLE_FAST_MATH)
 110     add_extra_compiler_option(-ffast-math)
 111   endif()
 112 endif()
 113
 114 if(CV_GCC OR CV_CLANG)
 115   # High level of warnings.
 116   add_extra_compiler_option(-W)
 117   if (NOT MSVC)
 118     # clang-cl interprets -Wall as MSVC would: -Weverything, which is more than
 119     # we want.
 120     add_extra_compiler_option(-Wall)
 121   endif()
 122   add_extra_compiler_option(-Werror=return-type)
 123   add_extra_compiler_option(-Werror=non-virtual-dtor)
 124   add_extra_compiler_option(-Werror=address)
 125   add_extra_compiler_option(-Werror=sequence-point)
 126   add_extra_compiler_option(-Wformat)
 127   add_extra_compiler_option(-Werror=format-security -Wformat)
 128   add_extra_compiler_option(-Wmissing-declarations)
 129   add_extra_compiler_option(-Wmissing-prototypes)
 130   add_extra_compiler_option(-Wstrict-prototypes)
 131   add_extra_compiler_option(-Wundef)
 132   add_extra_compiler_option(-Winit-self)
 133   add_extra_compiler_option(-Wpointer-arith)
 134   add_extra_compiler_option(-Wshadow)
 135   add_extra_compiler_option(-Wsign-promo)
 136   add_extra_compiler_option(-Wuninitialized)
 137   if(CV_GCC AND (CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 6.0) AND (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 7.0))
 138     add_extra_compiler_option(-Wno-psabi)
 139   endif()
 140   if(HAVE_CXX11)
 141     if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND NOT ENABLE_PRECOMPILED_HEADERS)
 142       add_extra_compiler_option(-Wsuggest-override)
 143     elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 144       add_extra_compiler_option(-Winconsistent-missing-override)
 145     endif()
 146   endif()
 147
 148   if(ENABLE_NOISY_WARNINGS)
 149     add_extra_compiler_option(-Wcast-align)
 150     add_extra_compiler_option(-Wstrict-aliasing=2)
 151   else()
 152     add_extra_compiler_option(-Wno-delete-non-virtual-dtor)
 153     add_extra_compiler_option(-Wno-unnamed-type-template-args)
 154     add_extra_compiler_option(-Wno-comment)
 155     if(NOT OPENCV_SKIP_IMPLICIT_FALLTHROUGH
 156         AND NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES "implicit-fallthrough"
 157         AND (CV_GCC AND NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS 7.0.0)
 158     )
 159       add_extra_compiler_option(-Wimplicit-fallthrough=3)
 160     endif()
 161     if(CV_GCC AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 7.0)
 162       add_extra_compiler_option(-Wno-strict-overflow) # Issue appears when compiling surf.cpp from opencv_contrib/modules/xfeatures2d
 163     endif()
 164     if(CV_GCC AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 5.0)
 165       add_extra_compiler_option(-Wno-missing-field-initializers)  # GCC 4.x emits warnings about {}, fixed in GCC 5+
 166     endif()
 167     if(CV_CLANG AND NOT CMAKE_CXX_COMPILER_ID STREQUAL "AppleClang" AND NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS 10.0)
 168       add_extra_compiler_option(-Wno-deprecated-enum-enum-conversion)
 169       add_extra_compiler_option(-Wno-deprecated-anon-enum-enum-conversion)
 170     endif()
 171   endif()
 172   add_extra_compiler_option(-fdiagnostics-show-option)
 173
 174   # The -Wno-long-long is required in 64bit systems when including system headers.
 175   if(X86_64)
 176     add_extra_compiler_option(-Wno-long-long)
 177   endif()
 178
 179   # We need pthread's
 180   if((UNIX
 181           AND NOT ANDROID
 182           AND NOT (APPLE AND CV_CLANG)
 183           AND NOT EMSCRIPTEN
 184       )
 185       OR (EMSCRIPTEN AND WITH_PTHREADS_PF)  # https://github.com/opencv/opencv/issues/20285
 186   )
 187     add_extra_compiler_option(-pthread)
 188   endif()
 189
 190   if(CV_CLANG)
 191     add_extra_compiler_option(-Qunused-arguments)
 192   endif()
 193
 194   if(OPENCV_WARNINGS_ARE_ERRORS)
 195     add_extra_compiler_option(-Werror)
 196   endif()
 197
 198   if(APPLE)
 199     add_extra_compiler_option(-Wno-semicolon-before-method-body)
 200   endif()
 201
 202   # Other optimizations
 203   if(ENABLE_OMIT_FRAME_POINTER)
 204     add_extra_compiler_option(-fomit-frame-pointer)
 205   elseif(DEFINED ENABLE_OMIT_FRAME_POINTER)
 206     add_extra_compiler_option(-fno-omit-frame-pointer)
 207   endif()
 208
 209   # Profiling?
 210   if(ENABLE_PROFILING)
 211     # turn off incompatible options
 212     foreach(flags CMAKE_CXX_FLAGS CMAKE_C_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG CMAKE_C_FLAGS_DEBUG
 213                   OPENCV_EXTRA_FLAGS_RELEASE OPENCV_EXTRA_FLAGS_DEBUG OPENCV_EXTRA_C_FLAGS OPENCV_EXTRA_CXX_FLAGS)
 214       string(REPLACE "-fomit-frame-pointer" "" ${flags} "${${flags}}")
 215       string(REPLACE "-ffunction-sections" "" ${flags} "${${flags}}")
 216       string(REPLACE "-fdata-sections" "" ${flags} "${${flags}}")
 217     endforeach()
 218     # -pg should be placed both in the linker and in the compiler settings
 219     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg")
 220     add_extra_compiler_option("-pg -g")
 221   else()
 222     if(MSVC)
 223       # TODO: Clang/C2 is not supported
 224     elseif(((IOS OR ANDROID) AND NOT BUILD_SHARED_LIBS) AND NOT OPENCV_FORCE_FUNCTIONS_SECTIONS)
 225       # don't create separate sections for functions/data, reduce package size
 226     else()
 227       # Remove unreferenced functions: function level linking
 228       add_extra_compiler_option(-ffunction-sections)
 229       add_extra_compiler_option(-fdata-sections)
 230       if(NOT OPENCV_SKIP_GC_SECTIONS)
 231         if(APPLE)
 232           set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS} -Wl,-dead_strip")
 233           set(OPENCV_EXTRA_SHARED_LINKER_FLAGS "${OPENCV_EXTRA_SHARED_LINKER_FLAGS} -Wl,-dead_strip")
 234           set(OPENCV_EXTRA_MODULE_LINKER_FLAGS "${OPENCV_EXTRA_MODULE_LINKER_FLAGS} -Wl,-dead_strip")
 235         else()
 236           set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS} -Wl,--gc-sections")
 237           set(OPENCV_EXTRA_SHARED_LINKER_FLAGS "${OPENCV_EXTRA_SHARED_LINKER_FLAGS} -Wl,--gc-sections")
 238           set(OPENCV_EXTRA_MODULE_LINKER_FLAGS "${OPENCV_EXTRA_MODULE_LINKER_FLAGS} -Wl,--gc-sections")
 239         endif()
 240       endif()
 241     endif()
 242   endif()
 243
 244   if(ENABLE_COVERAGE)
 245     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} --coverage")
 246     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} --coverage")
 247     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} --coverage")
 248   endif()
 249
 250   if(ENABLE_INSTRUMENTATION)
 251     if(NOT HAVE_CXX11)
 252       message(WARNING "ENABLE_INSTRUMENTATION requires C++11 support")
 253     endif()
 254     set(WITH_VTK OFF) # There are issues with VTK 6.0
 255   endif()
 256
 257   if(ENABLE_LTO)
 258     add_extra_compiler_option(-flto)
 259   endif()
 260   if(ENABLE_THIN_LTO)
 261     add_extra_compiler_option(-flto=thin)
 262   endif()
 263
 264   set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} -DNDEBUG")
 265   if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG} " MATCHES "-O")
 266     set(OPENCV_EXTRA_FLAGS_DEBUG "${OPENCV_EXTRA_FLAGS_DEBUG} -O0")
 267   endif()
 268   set(OPENCV_EXTRA_FLAGS_DEBUG "${OPENCV_EXTRA_FLAGS_DEBUG} -DDEBUG -D_DEBUG")
 269
 270   if(BUILD_WITH_DEBUG_INFO)
 271     # https://gcc.gnu.org/onlinedocs/gcc/Debugging-Options.html
 272     # '-g' is equal to '-g2', '-g1' produces minimal information, enough for making backtraces
 273     ocv_update(OPENCV_DEBUG_OPTION "-g1")
 274     if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS_RELEASE}" MATCHES " -g")
 275       set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} ${OPENCV_DEBUG_OPTION}")
 276     endif()
 277   endif()
 278 endif()
 279
 280 if(MSVC)
 281   #TODO Code refactoring is required to resolve security warnings
 282   #if(NOT ENABLE_BUILD_HARDENING)
 283     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /D _CRT_SECURE_NO_DEPRECATE /D _CRT_NONSTDC_NO_DEPRECATE /D _SCL_SECURE_NO_WARNINGS")
 284   #endif()
 285
 286   if(BUILD_WITH_DEBUG_INFO)
 287     set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} /Zi")
 288     set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE} /debug")
 289     set(OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE} /debug")
 290     set(OPENCV_EXTRA_MODULE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_MODULE_LINKER_FLAGS_RELEASE} /debug")
 291   endif()
 292
 293   # Remove unreferenced functions: function level linking
 294   set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /Gy")
 295   if(NOT MSVC_VERSION LESS 1400)
 296     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /bigobj")
 297   endif()
 298
 299   if(OPENCV_WARNINGS_ARE_ERRORS)
 300     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /WX")
 301   endif()
 302
 303   if(ENABLE_LTO)
 304     set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} /GL")
 305     set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE} /LTCG")
 306   endif()
 307
 308   if(NOT MSVC_VERSION LESS 1800 AND NOT CMAKE_GENERATOR MATCHES "Visual Studio")
 309     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} /FS")
 310     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} /FS")
 311   endif()
 312 endif()
 313
 314 include(cmake/OpenCVCompilerOptimizations.cmake)
 315 if(COMMAND ocv_compiler_optimization_options)
 316   ocv_compiler_optimization_options()
 317 endif()
 318 if(COMMAND ocv_compiler_optimization_options_finalize)
 319   ocv_compiler_optimization_options_finalize()
 320 endif()
 321
 322 # set default visibility to hidden
 323 if((CV_GCC OR CV_CLANG)
 324     AND NOT MSVC
 325     AND NOT OPENCV_SKIP_VISIBILITY_HIDDEN
 326     AND NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " -fvisibility")
 327   add_extra_compiler_option(-fvisibility=hidden)
 328   add_extra_compiler_option(-fvisibility-inlines-hidden)
 329 endif()
 330
 331 # workaround gcc bug for aligned ld/st
 332 # https://github.com/opencv/opencv/issues/13211
 333 if((PPC64LE AND NOT CMAKE_CROSSCOMPILING) OR OPENCV_FORCE_COMPILER_CHECK_VSX_ALIGNED)
 334   ocv_check_runtime_flag("${CPU_BASELINE_FLAGS}" OPENCV_CHECK_VSX_ALIGNED "${OpenCV_SOURCE_DIR}/cmake/checks/runtime/cpu_vsx_aligned.cpp")
 335   if(NOT OPENCV_CHECK_VSX_ALIGNED)
 336     add_extra_compiler_option_force(-DCV_COMPILER_VSX_BROKEN_ALIGNED)
 337   endif()
 338 endif()
 339 # validate inline asm with fixes register number and constraints wa, wd, wf
 340 if(PPC64LE)
 341   ocv_check_compiler_flag(CXX "${CPU_BASELINE_FLAGS}" OPENCV_CHECK_VSX_ASM "${OpenCV_SOURCE_DIR}/cmake/checks/cpu_vsx_asm.cpp")
 342   if(NOT OPENCV_CHECK_VSX_ASM)
 343     add_extra_compiler_option_force(-DCV_COMPILER_VSX_BROKEN_ASM)
 344   endif()
 345 endif()
 346
 347 # Apply "-Wl,--as-needed" linker flags: https://github.com/opencv/opencv/issues/7001
 348 if(NOT OPENCV_SKIP_LINK_AS_NEEDED)
 349   if(UNIX AND (NOT APPLE OR NOT CMAKE_VERSION VERSION_LESS "3.2"))
 350     set(_option "-Wl,--as-needed")
 351     set(_saved_CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 352     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${_option}")  # requires CMake 3.2+ and CMP0056
 353     ocv_check_compiler_flag(CXX "" HAVE_LINK_AS_NEEDED)
 354     set(CMAKE_EXE_LINKER_FLAGS "${_saved_CMAKE_EXE_LINKER_FLAGS}")
 355     if(HAVE_LINK_AS_NEEDED)
 356       set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS} ${_option}")
 357       set(OPENCV_EXTRA_SHARED_LINKER_FLAGS "${OPENCV_EXTRA_SHARED_LINKER_FLAGS} ${_option}")
 358       set(OPENCV_EXTRA_MODULE_LINKER_FLAGS "${OPENCV_EXTRA_MODULE_LINKER_FLAGS} ${_option}")
 359     endif()
 360   endif()
 361 endif()
 362
 363 # Apply "-Wl,--no-undefined" linker flags: https://github.com/opencv/opencv/pull/21347
 364 if(NOT OPENCV_SKIP_LINK_NO_UNDEFINED)
 365   if(UNIX AND (NOT APPLE OR NOT CMAKE_VERSION VERSION_LESS "3.2"))
 366     set(_option "-Wl,--no-undefined")
 367     set(_saved_CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 368     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${_option}")  # requires CMake 3.2+ and CMP0056
 369     ocv_check_compiler_flag(CXX "" HAVE_LINK_NO_UNDEFINED)
 370     set(CMAKE_EXE_LINKER_FLAGS "${_saved_CMAKE_EXE_LINKER_FLAGS}")
 371     if(HAVE_LINK_NO_UNDEFINED)
 372       set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS} ${_option}")
 373       set(OPENCV_EXTRA_SHARED_LINKER_FLAGS "${OPENCV_EXTRA_SHARED_LINKER_FLAGS} ${_option}")
 374       set(OPENCV_EXTRA_MODULE_LINKER_FLAGS "${OPENCV_EXTRA_MODULE_LINKER_FLAGS} ${_option}")
 375     endif()
 376   endif()
 377 endif()
 378
 379 # combine all "extra" options
 380 if(NOT OPENCV_SKIP_EXTRA_COMPILER_FLAGS)
 381   set(CMAKE_C_FLAGS           "${CMAKE_C_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_C_FLAGS}")
 382   set(CMAKE_CXX_FLAGS         "${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}")
 383   set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_FLAGS_RELEASE}")
 384   set(CMAKE_C_FLAGS_RELEASE   "${CMAKE_C_FLAGS_RELEASE} ${OPENCV_EXTRA_FLAGS_RELEASE}")
 385   set(CMAKE_CXX_FLAGS_DEBUG   "${CMAKE_CXX_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG}")
 386   set(CMAKE_C_FLAGS_DEBUG     "${CMAKE_C_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG}")
 387   set(CMAKE_EXE_LINKER_FLAGS         "${CMAKE_EXE_LINKER_FLAGS} ${OPENCV_EXTRA_EXE_LINKER_FLAGS}")
 388   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE}")
 389   set(CMAKE_EXE_LINKER_FLAGS_DEBUG   "${CMAKE_EXE_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_DEBUG}")
 390   set(CMAKE_SHARED_LINKER_FLAGS         "${CMAKE_SHARED_LINKER_FLAGS} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS}")
 391   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE}")
 392   set(CMAKE_SHARED_LINKER_FLAGS_DEBUG   "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS_DEBUG}")
 393   set(CMAKE_MODULE_LINKER_FLAGS         "${CMAKE_MODULE_LINKER_FLAGS} ${OPENCV_EXTRA_MODULE_LINKER_FLAGS}")
 394   set(CMAKE_MODULE_LINKER_FLAGS_RELEASE "${CMAKE_MODULE_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_MODULE_LINKER_FLAGS_RELEASE}")
 395   set(CMAKE_MODULE_LINKER_FLAGS_DEBUG   "${CMAKE_MODULE_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_MODULE_LINKER_FLAGS_DEBUG}")
 396 endif()
 397
 398 if(MSVC)
 399   if(NOT ENABLE_NOISY_WARNINGS)
 400     if(MSVC_VERSION EQUAL 1400)
 401       ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4510 /wd4610 /wd4312 /wd4201 /wd4244 /wd4328 /wd4267)
 402     endif()
 403   endif()
 404
 405   foreach(flags CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 406     string(REPLACE "/Zm1000" "" ${flags} "${${flags}}")
 407   endforeach()
 408
 409   # Enable 'extern "C"' and asynchronous (division by zero, access violation) exceptions
 410   if(NOT OPENCV_SKIP_MSVC_EXCEPTIONS_FLAG)
 411     foreach(flags CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 412       string(REGEX REPLACE " /EH[^ ]* " " " ${flags} " ${${flags}}")
 413     endforeach()
 414     if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${CMAKE_CXX_FLAGS_DEBUG}" MATCHES " /EH")
 415       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /EHa")
 416     endif()
 417   endif()
 418
 419   # Enable [[attribute]] syntax checking to prevent silent failure: "attribute is ignored in this syntactic position"
 420   add_extra_compiler_option("/w15240")
 421
 422   if(NOT ENABLE_NOISY_WARNINGS)
 423     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4127) # conditional expression is constant
 424     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4251) # class 'std::XXX' needs to have dll-interface to be used by clients of YYY
 425     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4324) # 'struct_name' : structure was padded due to __declspec(align())
 426     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4275) # non dll-interface class 'std::exception' used as base for dll-interface class 'cv::Exception'
 427     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4512) # Assignment operator could not be generated
 428     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4589) # Constructor of abstract class 'cv::ORB' ignores initializer for virtual base class 'cv::Algorithm'
 429   endif()
 430
 431   if(CV_ICC AND NOT ENABLE_NOISY_WARNINGS)
 432     foreach(flags CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_DEBUG)
 433       string(REGEX REPLACE "( |^)/W[0-9]+( |$)" "\\1\\2" ${flags} "${${flags}}")
 434     endforeach()
 435     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /Qwd673") # PCH warning
 436   endif()
 437 endif()
 438
 439 if(APPLE AND NOT CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{LDFLAGS} AND EXISTS "/usr/local/lib")
 440   link_directories("/usr/local/lib")
 441 endif()
 442
 443 if(ENABLE_BUILD_HARDENING)
 444   include(${CMAKE_CURRENT_LIST_DIR}/OpenCVCompilerDefenses.cmake)
 445 endif()
 446
 447 if(MSVC)
 448   include(cmake/OpenCVCRTLinkage.cmake)
 449   add_definitions(-D_VARIADIC_MAX=10)
 450 endif()
 451
 452 if(CMAKE_SYSTEM_NAME STREQUAL "Windows")
 453   get_directory_property(__DIRECTORY_COMPILE_DEFINITIONS COMPILE_DEFINITIONS)
 454   if((NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS_RELEASE} ${__DIRECTORY_COMPILE_DEFINITIONS}" MATCHES "_WIN32_WINNT"
 455       AND NOT OPENCV_CMAKE_SKIP_MACRO_WIN32_WINNT)
 456       OR OPENCV_CMAKE_FORCE_MACRO_WIN32_WINNT
 457   )
 458     # https://docs.microsoft.com/en-us/cpp/porting/modifying-winver-and-win32-winnt
 459     # Target Windows 7 API
 460     set(OPENCV_CMAKE_MACRO_WIN32_WINNT "0x0601" CACHE STRING "Value of _WIN32_WINNT macro")
 461     add_definitions(-D_WIN32_WINNT=${OPENCV_CMAKE_MACRO_WIN32_WINNT})
 462   endif()
 463 endif()
 464
 465 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 466 macro(ocv_add_modules_compiler_options)
 467   if(MSVC AND NOT OPENCV_SKIP_MSVC_W4_OPTION)
 468     foreach(flags CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 469       string(REPLACE "/W3" "/W4" ${flags} "${${flags}}")
 470     endforeach()
 471   endif()
 472   if(OPENCV_ENABLE_MEMORY_SANITIZER)
 473     add_definitions(-DOPENCV_ENABLE_MEMORY_SANITIZER=1)
 474   endif()
 475 endmacro()
 476
 477 # adjust -Wl,-rpath-link
 478 if(CMAKE_SKIP_RPATH)
 479   if((NOT CMAKE_CROSSCOMPILING OR OPENCV_ENABLE_LINKER_RPATH_LINK_ORIGIN) AND NOT OPENCV_SKIP_LINKER_RPATH_LINK_ORIGIN)
 480     if(DEFINED CMAKE_SHARED_LIBRARY_RPATH_ORIGIN_TOKEN)
 481       list(APPEND CMAKE_PLATFORM_RUNTIME_PATH "${CMAKE_SHARED_LIBRARY_RPATH_ORIGIN_TOKEN}")
 482     else()
 483       list(APPEND CMAKE_PLATFORM_RUNTIME_PATH "\$ORIGIN")
 484     endif()
 485   elseif(NOT OPENCV_SKIP_LINKER_RPATH_LINK_BINARY_LIB)
 486     list(APPEND CMAKE_PLATFORM_RUNTIME_PATH "${LIBRARY_OUTPUT_PATH}")
 487   endif()
 488 endif()
 489 if(OPENCV_EXTRA_RPATH_LINK_PATH)
 490   string(REPLACE ":" ";" OPENCV_EXTRA_RPATH_LINK_PATH_ "${OPENCV_EXTRA_RPATH_LINK_PATH}")
 491   list(APPEND CMAKE_PLATFORM_RUNTIME_PATH ${OPENCV_EXTRA_RPATH_LINK_PATH_})
 492   if(NOT CMAKE_EXECUTABLE_RPATH_LINK_CXX_FLAG)
 493     message(WARNING "OPENCV_EXTRA_RPATH_LINK_PATH may not work properly because CMAKE_EXECUTABLE_RPATH_LINK_CXX_FLAG is not defined (not supported)")
 494   endif()
 495 endif()
 496
 497 # Control MSVC /MP flag
 498 # Input variables: OPENCV_MSVC_PARALLEL (ON,1,2,3,...) + OPENCV_SKIP_MSVC_PARALLEL
 499 # Details:
 500 # - https://docs.microsoft.com/en-us/cpp/build/reference/mp-build-with-multiple-processes
 501 # - https://docs.microsoft.com/en-us/cpp/build/reference/cl-environment-variables
 502 # - https://gitlab.kitware.com/cmake/cmake/merge_requests/1718/diffs
 503 if(CMAKE_GENERATOR MATCHES "Visual Studio" AND CMAKE_CXX_COMPILER_ID MATCHES "MSVC|Intel")
 504   ocv_check_environment_variables(OPENCV_SKIP_MSVC_PARALLEL)
 505   if(OPENCV_SKIP_MSVC_PARALLEL)
 506     # nothing
 507   elseif(" ${CMAKE_CXX_FLAGS}" MATCHES "/MP")
 508     # nothing, already defined in compiler flags
 509   elseif(DEFINED ENV{CL} AND " $ENV{CL}" MATCHES "/MP")
 510     # nothing, compiler will use CL environment variable
 511   elseif(DEFINED ENV{_CL_} AND " $ENV{_CL_}" MATCHES "/MP")
 512     # nothing, compiler will use _CL_ environment variable
 513   else()
 514     ocv_check_environment_variables(OPENCV_MSVC_PARALLEL)
 515     set(_mp_value "ON")
 516     if(DEFINED OPENCV_MSVC_PARALLEL)
 517       set(_mp_value "${OPENCV_MSVC_PARALLEL}")
 518     endif()
 519     set(OPENCV_MSVC_PARALLEL "${_mp_value}" CACHE STRING "Control MSVC /MP flag")
 520     if(_mp_value)
 521       if(_mp_value GREATER 0)
 522         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /MP${_mp_value}")
 523         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MP${_mp_value}")
 524       else()
 525         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /MP")
 526         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MP")
 527       endif()
 528     endif()
 529   endif()
 530 endif()