cmake/OpenCVCompilerOptions.cmake

   1 if("${CMAKE_CXX_COMPILER};${CMAKE_C_COMPILER};${CMAKE_CXX_COMPILER_LAUNCHER}" MATCHES "ccache")
   2   set(CMAKE_COMPILER_IS_CCACHE 1)  # TODO: FIXIT Avoid setting of CMAKE_ variables
   3   set(OPENCV_COMPILER_IS_CCACHE 1)
   4 endif()
   5 function(access_CMAKE_COMPILER_IS_CCACHE)
   6   if(NOT OPENCV_SUPPRESS_DEPRECATIONS)
   7     message(WARNING "DEPRECATED: CMAKE_COMPILER_IS_CCACHE is replaced to OPENCV_COMPILER_IS_CCACHE.")
   8   endif()
   9 endfunction()
  10 variable_watch(CMAKE_COMPILER_IS_CCACHE access_CMAKE_COMPILER_IS_CCACHE)
  11 if(ENABLE_CCACHE AND NOT OPENCV_COMPILER_IS_CCACHE)
  12   # This works fine with Unix Makefiles and Ninja generators
  13   find_host_program(CCACHE_PROGRAM ccache)
  14   if(CCACHE_PROGRAM)
  15     message(STATUS "Looking for ccache - found (${CCACHE_PROGRAM})")
  16     get_property(__OLD_RULE_LAUNCH_COMPILE GLOBAL PROPERTY RULE_LAUNCH_COMPILE)
  17     if(CMAKE_GENERATOR MATCHES "Xcode")
  18       configure_file("${CMAKE_CURRENT_LIST_DIR}/templates/xcode-launch-c.in" "${CMAKE_BINARY_DIR}/xcode-launch-c")
  19       configure_file("${CMAKE_CURRENT_LIST_DIR}/templates/xcode-launch-cxx.in" "${CMAKE_BINARY_DIR}/xcode-launch-cxx")
  20       execute_process(COMMAND chmod a+rx
  21           "${CMAKE_BINARY_DIR}/xcode-launch-c"
  22           "${CMAKE_BINARY_DIR}/xcode-launch-cxx"
  23       )
  24       # Xcode project attributes
  25       set(CMAKE_XCODE_ATTRIBUTE_CC         "${CMAKE_BINARY_DIR}/xcode-launch-c")
  26       set(CMAKE_XCODE_ATTRIBUTE_CXX        "${CMAKE_BINARY_DIR}/xcode-launch-cxx")
  27       set(CMAKE_XCODE_ATTRIBUTE_LD         "${CMAKE_BINARY_DIR}/xcode-launch-c")
  28       set(CMAKE_XCODE_ATTRIBUTE_LDPLUSPLUS "${CMAKE_BINARY_DIR}/xcode-launch-cxx")
  29       set(OPENCV_COMPILER_IS_CCACHE 1)
  30       message(STATUS "ccache: enable support through Xcode project properties")
  31     elseif(__OLD_RULE_LAUNCH_COMPILE)
  32       message(STATUS "Can't replace CMake compiler launcher")
  33     else()
  34       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
  35       # NOTE: Actually this check doesn't work as expected.
  36       # "RULE_LAUNCH_COMPILE" is ignored by CMake during try_compile() step.
  37       # ocv_check_compiler_flag(CXX "" IS_CCACHE_WORKS)
  38       set(IS_CCACHE_WORKS 1)
  39       if(IS_CCACHE_WORKS)
  40         set(OPENCV_COMPILER_IS_CCACHE 1)
  41       else()
  42         message(STATUS "Unable to compile program with enabled ccache, reverting...")
  43         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${__OLD_RULE_LAUNCH_COMPILE}")
  44       endif()
  45     endif()
  46   else()
  47     message(STATUS "Looking for ccache - not found")
  48   endif()
  49 endif()
  50
  51 if((CV_CLANG AND NOT CMAKE_GENERATOR MATCHES "Xcode")  # PCH has no support for Clang
  52     OR OPENCV_COMPILER_IS_CCACHE
  53 )
  54   set(ENABLE_PRECOMPILED_HEADERS OFF CACHE BOOL "" FORCE)
  55 endif()
  56
  57 macro(add_extra_compiler_option option)
  58   ocv_check_flag_support(CXX "${option}" _varname "${OPENCV_EXTRA_CXX_FLAGS} ${ARGN}")
  59   if(${_varname})
  60     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} ${option}")
  61   endif()
  62
  63   ocv_check_flag_support(C "${option}" _varname "${OPENCV_EXTRA_C_FLAGS} ${ARGN}")
  64   if(${_varname})
  65     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} ${option}")
  66   endif()
  67 endmacro()
  68
  69 macro(add_extra_compiler_option_force option)
  70   set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} ${option}")
  71   set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} ${option}")
  72 endmacro()
  73
  74
  75 # Gets environment variable and puts its value to the corresponding preprocessor definition
  76 # Useful for WINRT that has no access to environment variables
  77 macro(add_env_definitions option)
  78   set(value $ENV{${option}})
  79   if("${value}" STREQUAL "")
  80     message(WARNING "${option} environment variable is empty. Please set it to appropriate location to get correct results")
  81   else()
  82     string(REPLACE "\\" "\\\\" value ${value})
  83   endif()
  84   add_definitions("-D${option}=\"${value}\"")
  85 endmacro()
  86
  87 if(NOT MSVC)
  88   # OpenCV fails some tests when 'char' is 'unsigned' by default
  89   add_extra_compiler_option(-fsigned-char)
  90 endif()
  91
  92 if(MSVC)
  93   if(NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " /fp:")
  94     if(ENABLE_FAST_MATH)
  95       add_extra_compiler_option("/fp:fast")
  96     else()
  97       add_extra_compiler_option("/fp:precise")
  98     endif()
  99   endif()
 100 elseif(CV_ICC)
 101   if(NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " /fp:"
 102       AND NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " -fp-model"
 103   )
 104     if(NOT ENABLE_FAST_MATH)
 105       add_extra_compiler_option("-fp-model precise")
 106     endif()
 107   endif()
 108 elseif(CV_GCC OR CV_CLANG)
 109   if(ENABLE_FAST_MATH)
 110     add_extra_compiler_option(-ffast-math)
 111   endif()
 112 endif()
 113
 114 if(CV_GCC OR CV_CLANG)
 115   # High level of warnings.
 116   add_extra_compiler_option(-W)
 117   if (NOT MSVC)
 118     # clang-cl interprets -Wall as MSVC would: -Weverything, which is more than
 119     # we want.
 120     add_extra_compiler_option(-Wall)
 121   endif()
 122   add_extra_compiler_option(-Wreturn-type)
 123   add_extra_compiler_option(-Wnon-virtual-dtor)
 124   add_extra_compiler_option(-Waddress)
 125   add_extra_compiler_option(-Wsequence-point)
 126   add_extra_compiler_option(-Wformat)
 127   add_extra_compiler_option(-Wformat-security -Wformat)
 128   add_extra_compiler_option(-Wmissing-declarations)
 129   add_extra_compiler_option(-Wmissing-prototypes)
 130   add_extra_compiler_option(-Wstrict-prototypes)
 131   add_extra_compiler_option(-Wundef)
 132   add_extra_compiler_option(-Winit-self)
 133   add_extra_compiler_option(-Wpointer-arith)
 134   if(NOT (CV_GCC AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS "5.0"))
 135     add_extra_compiler_option(-Wshadow)  # old GCC emits warnings for variables + methods combination
 136   endif()
 137   add_extra_compiler_option(-Wsign-promo)
 138   add_extra_compiler_option(-Wuninitialized)
 139   if(CV_GCC AND (CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 6.0) AND (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 7.0))
 140     add_extra_compiler_option(-Wno-psabi)
 141   endif()
 142   if(HAVE_CXX11)
 143     if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND NOT ENABLE_PRECOMPILED_HEADERS)
 144       add_extra_compiler_option(-Wsuggest-override)
 145     elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 146       add_extra_compiler_option(-Winconsistent-missing-override)
 147     endif()
 148   endif()
 149
 150   if(ENABLE_NOISY_WARNINGS)
 151     add_extra_compiler_option(-Wcast-align)
 152     add_extra_compiler_option(-Wstrict-aliasing=2)
 153   else()
 154     add_extra_compiler_option(-Wno-delete-non-virtual-dtor)
 155     add_extra_compiler_option(-Wno-unnamed-type-template-args)
 156     add_extra_compiler_option(-Wno-comment)
 157     if(NOT OPENCV_SKIP_IMPLICIT_FALLTHROUGH
 158         AND NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES "implicit-fallthrough"
 159         AND (CV_GCC AND NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS 7.0.0)
 160     )
 161       add_extra_compiler_option(-Wimplicit-fallthrough=3)
 162     endif()
 163     if(CV_GCC AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 7.0)
 164       add_extra_compiler_option(-Wno-strict-overflow) # Issue appears when compiling surf.cpp from opencv_contrib/modules/xfeatures2d
 165     endif()
 166     if(CV_GCC AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 5.0)
 167       add_extra_compiler_option(-Wno-missing-field-initializers)  # GCC 4.x emits warnings about {}, fixed in GCC 5+
 168     endif()
 169     if(CV_CLANG AND NOT CMAKE_CXX_COMPILER_ID STREQUAL "AppleClang" AND NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS 10.0)
 170       add_extra_compiler_option(-Wno-deprecated-enum-enum-conversion)
 171       add_extra_compiler_option(-Wno-deprecated-anon-enum-enum-conversion)
 172     endif()
 173   endif()
 174   add_extra_compiler_option(-fdiagnostics-show-option)
 175
 176   # The -Wno-long-long is required in 64bit systems when including system headers.
 177   if(X86_64)
 178     add_extra_compiler_option(-Wno-long-long)
 179   endif()
 180
 181   # We need pthread's, unless we have explicitly disabled multi-thread execution.
 182   if(NOT OPENCV_DISABLE_THREAD_SUPPORT
 183       AND (
 184         (UNIX
 185           AND NOT ANDROID
 186           AND NOT (APPLE AND CV_CLANG)
 187           AND NOT EMSCRIPTEN
 188         )
 189         OR (EMSCRIPTEN AND WITH_PTHREADS_PF)  # https://github.com/opencv/opencv/issues/20285
 190       )
 191   ) # TODO
 192     add_extra_compiler_option(-pthread)
 193   endif()
 194
 195   if(CV_CLANG)
 196     add_extra_compiler_option(-Qunused-arguments)
 197   endif()
 198
 199   if(OPENCV_WARNINGS_ARE_ERRORS)
 200     add_extra_compiler_option(-Werror)
 201   endif()
 202
 203   if(APPLE)
 204     add_extra_compiler_option(-Wno-semicolon-before-method-body)
 205   endif()
 206
 207   # Other optimizations
 208   if(ENABLE_OMIT_FRAME_POINTER)
 209     add_extra_compiler_option(-fomit-frame-pointer)
 210   elseif(DEFINED ENABLE_OMIT_FRAME_POINTER)
 211     add_extra_compiler_option(-fno-omit-frame-pointer)
 212   endif()
 213
 214   # Profiling?
 215   if(ENABLE_PROFILING)
 216     # turn off incompatible options
 217     foreach(flags CMAKE_CXX_FLAGS CMAKE_C_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG CMAKE_C_FLAGS_DEBUG
 218                   OPENCV_EXTRA_FLAGS_RELEASE OPENCV_EXTRA_FLAGS_DEBUG OPENCV_EXTRA_C_FLAGS OPENCV_EXTRA_CXX_FLAGS)
 219       string(REPLACE "-fomit-frame-pointer" "" ${flags} "${${flags}}")
 220       string(REPLACE "-ffunction-sections" "" ${flags} "${${flags}}")
 221       string(REPLACE "-fdata-sections" "" ${flags} "${${flags}}")
 222     endforeach()
 223     # -pg should be placed both in the linker and in the compiler settings
 224     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg")
 225     add_extra_compiler_option("-pg -g")
 226   else()
 227     if(MSVC)
 228       # TODO: Clang/C2 is not supported
 229     elseif(((IOS OR ANDROID) AND NOT BUILD_SHARED_LIBS) AND NOT OPENCV_FORCE_FUNCTIONS_SECTIONS)
 230       # don't create separate sections for functions/data, reduce package size
 231     else()
 232       # Remove unreferenced functions: function level linking
 233       add_extra_compiler_option(-ffunction-sections)
 234       add_extra_compiler_option(-fdata-sections)
 235       if(NOT OPENCV_SKIP_GC_SECTIONS)
 236         if(APPLE)
 237           set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS} -Wl,-dead_strip")
 238           set(OPENCV_EXTRA_SHARED_LINKER_FLAGS "${OPENCV_EXTRA_SHARED_LINKER_FLAGS} -Wl,-dead_strip")
 239           set(OPENCV_EXTRA_MODULE_LINKER_FLAGS "${OPENCV_EXTRA_MODULE_LINKER_FLAGS} -Wl,-dead_strip")
 240         else()
 241           set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS} -Wl,--gc-sections")
 242           set(OPENCV_EXTRA_SHARED_LINKER_FLAGS "${OPENCV_EXTRA_SHARED_LINKER_FLAGS} -Wl,--gc-sections")
 243           set(OPENCV_EXTRA_MODULE_LINKER_FLAGS "${OPENCV_EXTRA_MODULE_LINKER_FLAGS} -Wl,--gc-sections")
 244         endif()
 245       endif()
 246     endif()
 247   endif()
 248
 249   if(ENABLE_COVERAGE)
 250     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} --coverage")
 251     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} --coverage")
 252     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} --coverage")
 253   endif()
 254
 255   if(ENABLE_INSTRUMENTATION)
 256     if(NOT HAVE_CXX11)
 257       message(WARNING "ENABLE_INSTRUMENTATION requires C++11 support")
 258     endif()
 259     set(WITH_VTK OFF) # There are issues with VTK 6.0
 260   endif()
 261
 262   if(ENABLE_LTO)
 263     add_extra_compiler_option(-flto)
 264   endif()
 265   if(ENABLE_THIN_LTO)
 266     add_extra_compiler_option(-flto=thin)
 267   endif()
 268
 269   set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} -DNDEBUG")
 270   if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG} " MATCHES "-O")
 271     set(OPENCV_EXTRA_FLAGS_DEBUG "${OPENCV_EXTRA_FLAGS_DEBUG} -O0")
 272   endif()
 273   set(OPENCV_EXTRA_FLAGS_DEBUG "${OPENCV_EXTRA_FLAGS_DEBUG} -DDEBUG -D_DEBUG")
 274
 275   if(BUILD_WITH_DEBUG_INFO)
 276     # https://gcc.gnu.org/onlinedocs/gcc/Debugging-Options.html
 277     # '-g' is equal to '-g2', '-g1' produces minimal information, enough for making backtraces
 278     ocv_update(OPENCV_DEBUG_OPTION "-g1")
 279     if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS_RELEASE}" MATCHES " -g")
 280       set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} ${OPENCV_DEBUG_OPTION}")
 281     endif()
 282   endif()
 283 endif()
 284
 285 if(MSVC)
 286   #TODO Code refactoring is required to resolve security warnings
 287   #if(NOT ENABLE_BUILD_HARDENING)
 288     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /D _CRT_SECURE_NO_DEPRECATE /D _CRT_NONSTDC_NO_DEPRECATE /D _SCL_SECURE_NO_WARNINGS")
 289   #endif()
 290
 291   if(BUILD_WITH_DEBUG_INFO)
 292     set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} /Zi")
 293     set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE} /debug")
 294     set(OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE} /debug")
 295     set(OPENCV_EXTRA_MODULE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_MODULE_LINKER_FLAGS_RELEASE} /debug")
 296   endif()
 297
 298   # Remove unreferenced functions: function level linking
 299   set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /Gy")
 300   if(NOT MSVC_VERSION LESS 1400)
 301     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /bigobj")
 302   endif()
 303
 304   if(OPENCV_WARNINGS_ARE_ERRORS)
 305     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /WX")
 306   endif()
 307
 308   if(ENABLE_LTO)
 309     set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} /GL")
 310     set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE} /LTCG")
 311   endif()
 312
 313   if(NOT MSVC_VERSION LESS 1800 AND NOT CMAKE_GENERATOR MATCHES "Visual Studio")
 314     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} /FS")
 315     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} /FS")
 316   endif()
 317 endif()
 318
 319 if(PROJECT_NAME STREQUAL "OpenCV")
 320   include("${OpenCV_SOURCE_DIR}/cmake/OpenCVCompilerOptimizations.cmake")
 321 endif()
 322 if(COMMAND ocv_compiler_optimization_options)
 323   ocv_compiler_optimization_options()
 324 endif()
 325 if(COMMAND ocv_compiler_optimization_options_finalize)
 326   ocv_compiler_optimization_options_finalize()
 327 endif()
 328
 329 # set default visibility to hidden
 330 if((CV_GCC OR CV_CLANG)
 331     AND NOT MSVC
 332     AND NOT OPENCV_SKIP_VISIBILITY_HIDDEN
 333     AND NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " -fvisibility")
 334   add_extra_compiler_option(-fvisibility=hidden)
 335   add_extra_compiler_option(-fvisibility-inlines-hidden)
 336 endif()
 337
 338 # workaround gcc bug for aligned ld/st
 339 # https://github.com/opencv/opencv/issues/13211
 340 if((PPC64LE AND NOT CMAKE_CROSSCOMPILING) OR OPENCV_FORCE_COMPILER_CHECK_VSX_ALIGNED)
 341   ocv_check_runtime_flag("${CPU_BASELINE_FLAGS}" OPENCV_CHECK_VSX_ALIGNED "${OpenCV_SOURCE_DIR}/cmake/checks/runtime/cpu_vsx_aligned.cpp")
 342   if(NOT OPENCV_CHECK_VSX_ALIGNED)
 343     add_extra_compiler_option_force(-DCV_COMPILER_VSX_BROKEN_ALIGNED)
 344   endif()
 345 endif()
 346 # validate inline asm with fixes register number and constraints wa, wd, wf
 347 if(PPC64LE)
 348   ocv_check_compiler_flag(CXX "${CPU_BASELINE_FLAGS}" OPENCV_CHECK_VSX_ASM "${OpenCV_SOURCE_DIR}/cmake/checks/cpu_vsx_asm.cpp")
 349   if(NOT OPENCV_CHECK_VSX_ASM)
 350     add_extra_compiler_option_force(-DCV_COMPILER_VSX_BROKEN_ASM)
 351   endif()
 352 endif()
 353
 354 # Apply "-Wl,--as-needed" linker flags: https://github.com/opencv/opencv/issues/7001
 355 if(NOT OPENCV_SKIP_LINK_AS_NEEDED)
 356   if(UNIX AND (NOT APPLE OR NOT CMAKE_VERSION VERSION_LESS "3.2"))
 357     set(_option "-Wl,--as-needed")
 358     set(_saved_CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 359     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${_option}")  # requires CMake 3.2+ and CMP0056
 360     ocv_check_compiler_flag(CXX "" HAVE_LINK_AS_NEEDED)
 361     set(CMAKE_EXE_LINKER_FLAGS "${_saved_CMAKE_EXE_LINKER_FLAGS}")
 362     if(HAVE_LINK_AS_NEEDED)
 363       set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS} ${_option}")
 364       set(OPENCV_EXTRA_SHARED_LINKER_FLAGS "${OPENCV_EXTRA_SHARED_LINKER_FLAGS} ${_option}")
 365       set(OPENCV_EXTRA_MODULE_LINKER_FLAGS "${OPENCV_EXTRA_MODULE_LINKER_FLAGS} ${_option}")
 366     endif()
 367   endif()
 368 endif()
 369
 370 # Apply "-Wl,--no-undefined" linker flags: https://github.com/opencv/opencv/pull/21347
 371 if(NOT OPENCV_SKIP_LINK_NO_UNDEFINED)
 372   if(UNIX AND (NOT APPLE OR NOT CMAKE_VERSION VERSION_LESS "3.2"))
 373     set(_option "-Wl,--no-undefined")
 374     set(_saved_CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 375     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${_option}")  # requires CMake 3.2+ and CMP0056
 376     ocv_check_compiler_flag(CXX "" HAVE_LINK_NO_UNDEFINED)
 377     set(CMAKE_EXE_LINKER_FLAGS "${_saved_CMAKE_EXE_LINKER_FLAGS}")
 378     if(HAVE_LINK_NO_UNDEFINED)
 379       set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS} ${_option}")
 380       set(OPENCV_EXTRA_SHARED_LINKER_FLAGS "${OPENCV_EXTRA_SHARED_LINKER_FLAGS} ${_option}")
 381       set(OPENCV_EXTRA_MODULE_LINKER_FLAGS "${OPENCV_EXTRA_MODULE_LINKER_FLAGS} ${_option}")
 382     endif()
 383   endif()
 384 endif()
 385
 386 # combine all "extra" options
 387 if(NOT OPENCV_SKIP_EXTRA_COMPILER_FLAGS)
 388   set(CMAKE_C_FLAGS           "${CMAKE_C_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_C_FLAGS}")
 389   set(CMAKE_CXX_FLAGS         "${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}")
 390   set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_FLAGS_RELEASE}")
 391   set(CMAKE_C_FLAGS_RELEASE   "${CMAKE_C_FLAGS_RELEASE} ${OPENCV_EXTRA_FLAGS_RELEASE}")
 392   set(CMAKE_CXX_FLAGS_DEBUG   "${CMAKE_CXX_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG}")
 393   set(CMAKE_C_FLAGS_DEBUG     "${CMAKE_C_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG}")
 394   set(CMAKE_EXE_LINKER_FLAGS         "${CMAKE_EXE_LINKER_FLAGS} ${OPENCV_EXTRA_EXE_LINKER_FLAGS}")
 395   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE}")
 396   set(CMAKE_EXE_LINKER_FLAGS_DEBUG   "${CMAKE_EXE_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_DEBUG}")
 397   set(CMAKE_SHARED_LINKER_FLAGS         "${CMAKE_SHARED_LINKER_FLAGS} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS}")
 398   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE}")
 399   set(CMAKE_SHARED_LINKER_FLAGS_DEBUG   "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS_DEBUG}")
 400   set(CMAKE_MODULE_LINKER_FLAGS         "${CMAKE_MODULE_LINKER_FLAGS} ${OPENCV_EXTRA_MODULE_LINKER_FLAGS}")
 401   set(CMAKE_MODULE_LINKER_FLAGS_RELEASE "${CMAKE_MODULE_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_MODULE_LINKER_FLAGS_RELEASE}")
 402   set(CMAKE_MODULE_LINKER_FLAGS_DEBUG   "${CMAKE_MODULE_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_MODULE_LINKER_FLAGS_DEBUG}")
 403 endif()
 404
 405 if(MSVC)
 406   if(NOT ENABLE_NOISY_WARNINGS)
 407     if(MSVC_VERSION EQUAL 1400)
 408       ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4510 /wd4610 /wd4312 /wd4201 /wd4244 /wd4328 /wd4267)
 409     endif()
 410   endif()
 411
 412   foreach(flags CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 413     string(REPLACE "/Zm1000" "" ${flags} "${${flags}}")
 414   endforeach()
 415
 416   # Enable 'extern "C"' and asynchronous (division by zero, access violation) exceptions
 417   if(NOT OPENCV_SKIP_MSVC_EXCEPTIONS_FLAG)
 418     foreach(flags CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 419       string(REGEX REPLACE " /EH[^ ]* " " " ${flags} " ${${flags}}")
 420     endforeach()
 421     if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${CMAKE_CXX_FLAGS_DEBUG}" MATCHES " /EH")
 422       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /EHa")
 423     endif()
 424   endif()
 425
 426   # Enable [[attribute]] syntax checking to prevent silent failure: "attribute is ignored in this syntactic position"
 427   add_extra_compiler_option("/w15240")
 428
 429   if(NOT ENABLE_NOISY_WARNINGS)
 430     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4127) # conditional expression is constant
 431     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4251) # class 'std::XXX' needs to have dll-interface to be used by clients of YYY
 432     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4324) # 'struct_name' : structure was padded due to __declspec(align())
 433     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4275) # non dll-interface class 'std::exception' used as base for dll-interface class 'cv::Exception'
 434     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4512) # Assignment operator could not be generated
 435     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4589) # Constructor of abstract class 'cv::ORB' ignores initializer for virtual base class 'cv::Algorithm'
 436   endif()
 437
 438   if(CV_ICC AND NOT ENABLE_NOISY_WARNINGS)
 439     foreach(flags CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_DEBUG)
 440       string(REGEX REPLACE "( |^)/W[0-9]+( |$)" "\\1\\2" ${flags} "${${flags}}")
 441     endforeach()
 442     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /Qwd673") # PCH warning
 443   endif()
 444 endif()
 445
 446 if(APPLE AND NOT CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{LDFLAGS} AND EXISTS "/usr/local/lib")
 447   link_directories("/usr/local/lib")
 448 endif()
 449
 450 if(ENABLE_BUILD_HARDENING)
 451   include("${CMAKE_CURRENT_LIST_DIR}/OpenCVCompilerDefenses.cmake")
 452 endif()
 453
 454 if(MSVC)
 455   include("${CMAKE_CURRENT_LIST_DIR}/OpenCVCRTLinkage.cmake")
 456   add_definitions(-D_VARIADIC_MAX=10)
 457 endif()
 458
 459 if(CMAKE_SYSTEM_NAME STREQUAL "Windows")
 460   get_directory_property(__DIRECTORY_COMPILE_DEFINITIONS COMPILE_DEFINITIONS)
 461   if((NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS_RELEASE} ${__DIRECTORY_COMPILE_DEFINITIONS}" MATCHES "_WIN32_WINNT"
 462       AND NOT OPENCV_CMAKE_SKIP_MACRO_WIN32_WINNT)
 463       OR OPENCV_CMAKE_FORCE_MACRO_WIN32_WINNT
 464   )
 465     # https://docs.microsoft.com/en-us/cpp/porting/modifying-winver-and-win32-winnt
 466     # Target Windows 7 API
 467     set(OPENCV_CMAKE_MACRO_WIN32_WINNT "0x0601" CACHE STRING "Value of _WIN32_WINNT macro")
 468     add_definitions(-D_WIN32_WINNT=${OPENCV_CMAKE_MACRO_WIN32_WINNT})
 469   endif()
 470 endif()
 471
 472 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 473 macro(ocv_add_modules_compiler_options)
 474   if(MSVC AND NOT OPENCV_SKIP_MSVC_W4_OPTION)
 475     foreach(flags CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 476       string(REPLACE "/W3" "/W4" ${flags} "${${flags}}")
 477     endforeach()
 478   endif()
 479   if(OPENCV_ENABLE_MEMORY_SANITIZER)
 480     add_definitions(-DOPENCV_ENABLE_MEMORY_SANITIZER=1)
 481   endif()
 482 endmacro()
 483
 484 # adjust -Wl,-rpath-link
 485 if(CMAKE_SKIP_RPATH)
 486   if((NOT CMAKE_CROSSCOMPILING OR OPENCV_ENABLE_LINKER_RPATH_LINK_ORIGIN) AND NOT OPENCV_SKIP_LINKER_RPATH_LINK_ORIGIN)
 487     if(DEFINED CMAKE_SHARED_LIBRARY_RPATH_ORIGIN_TOKEN)
 488       list(APPEND CMAKE_PLATFORM_RUNTIME_PATH "${CMAKE_SHARED_LIBRARY_RPATH_ORIGIN_TOKEN}")
 489     else()
 490       list(APPEND CMAKE_PLATFORM_RUNTIME_PATH "\$ORIGIN")
 491     endif()
 492   elseif(NOT OPENCV_SKIP_LINKER_RPATH_LINK_BINARY_LIB)
 493     list(APPEND CMAKE_PLATFORM_RUNTIME_PATH "${LIBRARY_OUTPUT_PATH}")
 494   endif()
 495 endif()
 496 if(OPENCV_EXTRA_RPATH_LINK_PATH)
 497   string(REPLACE ":" ";" OPENCV_EXTRA_RPATH_LINK_PATH_ "${OPENCV_EXTRA_RPATH_LINK_PATH}")
 498   list(APPEND CMAKE_PLATFORM_RUNTIME_PATH ${OPENCV_EXTRA_RPATH_LINK_PATH_})
 499   if(NOT CMAKE_EXECUTABLE_RPATH_LINK_CXX_FLAG)
 500     message(WARNING "OPENCV_EXTRA_RPATH_LINK_PATH may not work properly because CMAKE_EXECUTABLE_RPATH_LINK_CXX_FLAG is not defined (not supported)")
 501   endif()
 502 endif()
 503
 504 # Control MSVC /MP flag
 505 # Input variables: OPENCV_MSVC_PARALLEL (ON,1,2,3,...) + OPENCV_SKIP_MSVC_PARALLEL
 506 # Details:
 507 # - https://docs.microsoft.com/en-us/cpp/build/reference/mp-build-with-multiple-processes
 508 # - https://docs.microsoft.com/en-us/cpp/build/reference/cl-environment-variables
 509 # - https://gitlab.kitware.com/cmake/cmake/merge_requests/1718/diffs
 510 if(CMAKE_GENERATOR MATCHES "Visual Studio" AND CMAKE_CXX_COMPILER_ID MATCHES "MSVC|Intel")
 511   ocv_check_environment_variables(OPENCV_SKIP_MSVC_PARALLEL)
 512   if(OPENCV_SKIP_MSVC_PARALLEL)
 513     # nothing
 514   elseif(" ${CMAKE_CXX_FLAGS}" MATCHES "/MP")
 515     # nothing, already defined in compiler flags
 516   elseif(DEFINED ENV{CL} AND " $ENV{CL}" MATCHES "/MP")
 517     # nothing, compiler will use CL environment variable
 518   elseif(DEFINED ENV{_CL_} AND " $ENV{_CL_}" MATCHES "/MP")
 519     # nothing, compiler will use _CL_ environment variable
 520   else()
 521     ocv_check_environment_variables(OPENCV_MSVC_PARALLEL)
 522     set(_mp_value "ON")
 523     if(DEFINED OPENCV_MSVC_PARALLEL)
 524       set(_mp_value "${OPENCV_MSVC_PARALLEL}")
 525     endif()
 526     set(OPENCV_MSVC_PARALLEL "${_mp_value}" CACHE STRING "Control MSVC /MP flag")
 527     if(_mp_value)
 528       if(_mp_value GREATER 0)
 529         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /MP${_mp_value}")
 530         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MP${_mp_value}")
 531       else()
 532         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /MP")
 533         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MP")
 534       endif()
 535     endif()
 536   endif()
 537 endif()