cmake/OpenCVCompilerOptions.cmake

   1 if("${CMAKE_CXX_COMPILER};${CMAKE_C_COMPILER};${CMAKE_CXX_COMPILER_LAUNCHER}" MATCHES "ccache")
   2   set(CMAKE_COMPILER_IS_CCACHE 1)  # TODO: FIXIT Avoid setting of CMAKE_ variables
   3   set(OPENCV_COMPILER_IS_CCACHE 1)
   4 endif()
   5 function(access_CMAKE_COMPILER_IS_CCACHE)
   6   if(NOT OPENCV_SUPPRESS_DEPRECATIONS)
   7     message(WARNING "DEPRECATED: CMAKE_COMPILER_IS_CCACHE is replaced to OPENCV_COMPILER_IS_CCACHE.")
   8   endif()
   9 endfunction()
  10 variable_watch(CMAKE_COMPILER_IS_CCACHE access_CMAKE_COMPILER_IS_CCACHE)
  11 if(ENABLE_CCACHE AND NOT OPENCV_COMPILER_IS_CCACHE)
  12   # This works fine with Unix Makefiles and Ninja generators
  13   find_host_program(CCACHE_PROGRAM ccache)
  14   if(CCACHE_PROGRAM)
  15     message(STATUS "Looking for ccache - found (${CCACHE_PROGRAM})")
  16     get_property(__OLD_RULE_LAUNCH_COMPILE GLOBAL PROPERTY RULE_LAUNCH_COMPILE)
  17     if(CMAKE_GENERATOR MATCHES "Xcode")
  18       configure_file("${CMAKE_CURRENT_LIST_DIR}/templates/xcode-launch-c.in" "${CMAKE_BINARY_DIR}/xcode-launch-c")
  19       configure_file("${CMAKE_CURRENT_LIST_DIR}/templates/xcode-launch-cxx.in" "${CMAKE_BINARY_DIR}/xcode-launch-cxx")
  20       execute_process(COMMAND chmod a+rx
  21           "${CMAKE_BINARY_DIR}/xcode-launch-c"
  22           "${CMAKE_BINARY_DIR}/xcode-launch-cxx"
  23       )
  24       # Xcode project attributes
  25       set(CMAKE_XCODE_ATTRIBUTE_CC         "${CMAKE_BINARY_DIR}/xcode-launch-c")
  26       set(CMAKE_XCODE_ATTRIBUTE_CXX        "${CMAKE_BINARY_DIR}/xcode-launch-cxx")
  27       set(CMAKE_XCODE_ATTRIBUTE_LD         "${CMAKE_BINARY_DIR}/xcode-launch-c")
  28       set(CMAKE_XCODE_ATTRIBUTE_LDPLUSPLUS "${CMAKE_BINARY_DIR}/xcode-launch-cxx")
  29       set(OPENCV_COMPILER_IS_CCACHE 1)
  30       message(STATUS "ccache: enable support through Xcode project properties")
  31     elseif(__OLD_RULE_LAUNCH_COMPILE)
  32       message(STATUS "Can't replace CMake compiler launcher")
  33     else()
  34       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
  35       # NOTE: Actually this check doesn't work as expected.
  36       # "RULE_LAUNCH_COMPILE" is ignored by CMake during try_compile() step.
  37       # ocv_check_compiler_flag(CXX "" IS_CCACHE_WORKS)
  38       set(IS_CCACHE_WORKS 1)
  39       if(IS_CCACHE_WORKS)
  40         set(OPENCV_COMPILER_IS_CCACHE 1)
  41       else()
  42         message(STATUS "Unable to compile program with enabled ccache, reverting...")
  43         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${__OLD_RULE_LAUNCH_COMPILE}")
  44       endif()
  45     endif()
  46   else()
  47     message(STATUS "Looking for ccache - not found")
  48   endif()
  49 endif()
  50
  51 if((CV_CLANG AND NOT CMAKE_GENERATOR MATCHES "Xcode")  # PCH has no support for Clang
  52     OR OPENCV_COMPILER_IS_CCACHE
  53 )
  54   set(ENABLE_PRECOMPILED_HEADERS OFF CACHE BOOL "" FORCE)
  55 endif()
  56
  57 macro(add_extra_compiler_option option)
  58   ocv_check_flag_support(CXX "${option}" _varname "${OPENCV_EXTRA_CXX_FLAGS} ${ARGN}")
  59   if(${_varname})
  60     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} ${option}")
  61   endif()
  62
  63   ocv_check_flag_support(C "${option}" _varname "${OPENCV_EXTRA_C_FLAGS} ${ARGN}")
  64   if(${_varname})
  65     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} ${option}")
  66   endif()
  67 endmacro()
  68
  69 macro(add_extra_compiler_option_force option)
  70   set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} ${option}")
  71   set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} ${option}")
  72 endmacro()
  73
  74
  75 # Gets environment variable and puts its value to the corresponding preprocessor definition
  76 # Useful for WINRT that has no access to environment variables
  77 macro(add_env_definitions option)
  78   set(value $ENV{${option}})
  79   if("${value}" STREQUAL "")
  80     message(WARNING "${option} environment variable is empty. Please set it to appropriate location to get correct results")
  81   else()
  82     string(REPLACE "\\" "\\\\" value ${value})
  83   endif()
  84   add_definitions("-D${option}=\"${value}\"")
  85 endmacro()
  86
  87 if(NOT MSVC)
  88   # OpenCV fails some tests when 'char' is 'unsigned' by default
  89   add_extra_compiler_option(-fsigned-char)
  90 endif()
  91
  92 if(MSVC)
  93   if(NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " /fp:")
  94     if(ENABLE_FAST_MATH)
  95       add_extra_compiler_option("/fp:fast")
  96     else()
  97       add_extra_compiler_option("/fp:precise")
  98     endif()
  99   endif()
 100 elseif(CV_ICC)
 101   if(NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " /fp:"
 102       AND NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " -fp-model"
 103   )
 104     if(NOT ENABLE_FAST_MATH)
 105       add_extra_compiler_option("-fp-model precise")
 106     endif()
 107   endif()
 108 elseif(CV_GCC OR CV_CLANG)
 109   if(ENABLE_FAST_MATH)
 110     add_extra_compiler_option(-ffast-math)
 111   endif()
 112 endif()
 113
 114 if(CV_GCC OR CV_CLANG)
 115   # High level of warnings.
 116   add_extra_compiler_option(-W)
 117   if (NOT MSVC)
 118     # clang-cl interprets -Wall as MSVC would: -Weverything, which is more than
 119     # we want.
 120     add_extra_compiler_option(-Wall)
 121   endif()
 122   add_extra_compiler_option(-Werror=return-type)
 123   add_extra_compiler_option(-Werror=non-virtual-dtor)
 124   add_extra_compiler_option(-Werror=address)
 125   add_extra_compiler_option(-Werror=sequence-point)
 126   add_extra_compiler_option(-Wformat)
 127   add_extra_compiler_option(-Werror=format-security -Wformat)
 128   add_extra_compiler_option(-Wmissing-declarations)
 129   add_extra_compiler_option(-Wmissing-prototypes)
 130   add_extra_compiler_option(-Wstrict-prototypes)
 131   add_extra_compiler_option(-Wundef)
 132   add_extra_compiler_option(-Winit-self)
 133   add_extra_compiler_option(-Wpointer-arith)
 134   add_extra_compiler_option(-Wshadow)
 135   add_extra_compiler_option(-Wsign-promo)
 136   add_extra_compiler_option(-Wuninitialized)
 137   if(CV_GCC AND (CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 6.0) AND (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 7.0))
 138     add_extra_compiler_option(-Wno-psabi)
 139   endif()
 140   if(HAVE_CXX11)
 141     if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND NOT ENABLE_PRECOMPILED_HEADERS)
 142       add_extra_compiler_option(-Wsuggest-override)
 143     elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 144       add_extra_compiler_option(-Winconsistent-missing-override)
 145     endif()
 146   endif()
 147
 148   if(ENABLE_NOISY_WARNINGS)
 149     add_extra_compiler_option(-Wcast-align)
 150     add_extra_compiler_option(-Wstrict-aliasing=2)
 151   else()
 152     add_extra_compiler_option(-Wno-delete-non-virtual-dtor)
 153     add_extra_compiler_option(-Wno-unnamed-type-template-args)
 154     add_extra_compiler_option(-Wno-comment)
 155     if(NOT OPENCV_SKIP_IMPLICIT_FALLTHROUGH
 156         AND NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES "implicit-fallthrough"
 157         AND (CV_GCC AND NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS 7.0.0)
 158     )
 159       add_extra_compiler_option(-Wimplicit-fallthrough=3)
 160     endif()
 161     if(CV_GCC AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 7.0)
 162       add_extra_compiler_option(-Wno-strict-overflow) # Issue appears when compiling surf.cpp from opencv_contrib/modules/xfeatures2d
 163     endif()
 164     if(CV_GCC AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 5.0)
 165       add_extra_compiler_option(-Wno-missing-field-initializers)  # GCC 4.x emits warnings about {}, fixed in GCC 5+
 166     endif()
 167     if(CV_CLANG AND NOT CMAKE_CXX_COMPILER_ID STREQUAL "AppleClang" AND NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS 10.0)
 168       add_extra_compiler_option(-Wno-deprecated-enum-enum-conversion)
 169       add_extra_compiler_option(-Wno-deprecated-anon-enum-enum-conversion)
 170     endif()
 171   endif()
 172   add_extra_compiler_option(-fdiagnostics-show-option)
 173
 174   # The -Wno-long-long is required in 64bit systems when including system headers.
 175   if(X86_64)
 176     add_extra_compiler_option(-Wno-long-long)
 177   endif()
 178
 179   # We need pthread's
 180   if(UNIX AND NOT ANDROID AND NOT (APPLE AND CV_CLANG)) # TODO
 181     add_extra_compiler_option(-pthread)
 182   endif()
 183
 184   if(CV_CLANG)
 185     add_extra_compiler_option(-Qunused-arguments)
 186   endif()
 187
 188   if(OPENCV_WARNINGS_ARE_ERRORS)
 189     add_extra_compiler_option(-Werror)
 190   endif()
 191
 192   if(APPLE)
 193     add_extra_compiler_option(-Wno-semicolon-before-method-body)
 194   endif()
 195
 196   # Other optimizations
 197   if(ENABLE_OMIT_FRAME_POINTER)
 198     add_extra_compiler_option(-fomit-frame-pointer)
 199   elseif(DEFINED ENABLE_OMIT_FRAME_POINTER)
 200     add_extra_compiler_option(-fno-omit-frame-pointer)
 201   endif()
 202
 203   # Profiling?
 204   if(ENABLE_PROFILING)
 205     # turn off incompatible options
 206     foreach(flags CMAKE_CXX_FLAGS CMAKE_C_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG CMAKE_C_FLAGS_DEBUG
 207                   OPENCV_EXTRA_FLAGS_RELEASE OPENCV_EXTRA_FLAGS_DEBUG OPENCV_EXTRA_C_FLAGS OPENCV_EXTRA_CXX_FLAGS)
 208       string(REPLACE "-fomit-frame-pointer" "" ${flags} "${${flags}}")
 209       string(REPLACE "-ffunction-sections" "" ${flags} "${${flags}}")
 210       string(REPLACE "-fdata-sections" "" ${flags} "${${flags}}")
 211     endforeach()
 212     # -pg should be placed both in the linker and in the compiler settings
 213     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg")
 214     add_extra_compiler_option("-pg -g")
 215   else()
 216     if(MSVC)
 217       # TODO: Clang/C2 is not supported
 218     elseif(((IOS OR ANDROID) AND NOT BUILD_SHARED_LIBS) AND NOT OPENCV_FORCE_FUNCTIONS_SECTIONS)
 219       # don't create separate sections for functions/data, reduce package size
 220     else()
 221       # Remove unreferenced functions: function level linking
 222       add_extra_compiler_option(-ffunction-sections)
 223       add_extra_compiler_option(-fdata-sections)
 224       if(NOT OPENCV_SKIP_GC_SECTIONS)
 225         if(APPLE)
 226           set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS} -Wl,-dead_strip")
 227           set(OPENCV_EXTRA_SHARED_LINKER_FLAGS "${OPENCV_EXTRA_SHARED_LINKER_FLAGS} -Wl,-dead_strip")
 228         else()
 229           set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS} -Wl,--gc-sections")
 230           set(OPENCV_EXTRA_SHARED_LINKER_FLAGS "${OPENCV_EXTRA_SHARED_LINKER_FLAGS} -Wl,--gc-sections")
 231         endif()
 232       endif()
 233     endif()
 234   endif()
 235
 236   if(ENABLE_COVERAGE)
 237     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} --coverage")
 238     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} --coverage")
 239     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} --coverage")
 240   endif()
 241
 242   if(ENABLE_INSTRUMENTATION)
 243     if(NOT HAVE_CXX11)
 244       message(WARNING "ENABLE_INSTRUMENTATION requires C++11 support")
 245     endif()
 246     set(WITH_VTK OFF) # There are issues with VTK 6.0
 247   endif()
 248
 249   if(ENABLE_LTO)
 250     add_extra_compiler_option(-flto)
 251   endif()
 252   if(ENABLE_THIN_LTO)
 253     add_extra_compiler_option(-flto=thin)
 254   endif()
 255
 256   set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} -DNDEBUG")
 257   if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG} " MATCHES "-O")
 258     set(OPENCV_EXTRA_FLAGS_DEBUG "${OPENCV_EXTRA_FLAGS_DEBUG} -O0")
 259   endif()
 260   set(OPENCV_EXTRA_FLAGS_DEBUG "${OPENCV_EXTRA_FLAGS_DEBUG} -DDEBUG -D_DEBUG")
 261
 262   if(BUILD_WITH_DEBUG_INFO)
 263     # https://gcc.gnu.org/onlinedocs/gcc/Debugging-Options.html
 264     # '-g' is equal to '-g2', '-g1' produces minimal information, enough for making backtraces
 265     ocv_update(OPENCV_DEBUG_OPTION "-g1")
 266     if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS_RELEASE}" MATCHES " -g")
 267       set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} ${OPENCV_DEBUG_OPTION}")
 268     endif()
 269   endif()
 270 endif()
 271
 272 if(MSVC)
 273   #TODO Code refactoring is required to resolve security warnings
 274   #if(NOT ENABLE_BUILD_HARDENING)
 275     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /D _CRT_SECURE_NO_DEPRECATE /D _CRT_NONSTDC_NO_DEPRECATE /D _SCL_SECURE_NO_WARNINGS")
 276   #endif()
 277
 278   if(BUILD_WITH_DEBUG_INFO)
 279     set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} /Zi")
 280     set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE} /debug")
 281     set(OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE} /debug")
 282   endif()
 283
 284   # Remove unreferenced functions: function level linking
 285   set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /Gy")
 286   if(NOT MSVC_VERSION LESS 1400)
 287     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /bigobj")
 288   endif()
 289
 290   if(OPENCV_WARNINGS_ARE_ERRORS)
 291     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /WX")
 292   endif()
 293
 294   if(ENABLE_LTO)
 295     set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} /GL")
 296     set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE} /LTCG")
 297   endif()
 298
 299   if(NOT MSVC_VERSION LESS 1800 AND NOT CMAKE_GENERATOR MATCHES "Visual Studio")
 300     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} /FS")
 301     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} /FS")
 302   endif()
 303 endif()
 304
 305 include(cmake/OpenCVCompilerOptimizations.cmake)
 306 if(COMMAND ocv_compiler_optimization_options)
 307   ocv_compiler_optimization_options()
 308 endif()
 309 if(COMMAND ocv_compiler_optimization_options_finalize)
 310   ocv_compiler_optimization_options_finalize()
 311 endif()
 312
 313 # set default visibility to hidden
 314 if((CV_GCC OR CV_CLANG)
 315     AND NOT MSVC
 316     AND NOT OPENCV_SKIP_VISIBILITY_HIDDEN
 317     AND NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " -fvisibility")
 318   add_extra_compiler_option(-fvisibility=hidden)
 319   add_extra_compiler_option(-fvisibility-inlines-hidden)
 320 endif()
 321
 322 # workaround gcc bug for aligned ld/st
 323 # https://github.com/opencv/opencv/issues/13211
 324 if((PPC64LE AND NOT CMAKE_CROSSCOMPILING) OR OPENCV_FORCE_COMPILER_CHECK_VSX_ALIGNED)
 325   ocv_check_runtime_flag("${CPU_BASELINE_FLAGS}" OPENCV_CHECK_VSX_ALIGNED "${OpenCV_SOURCE_DIR}/cmake/checks/runtime/cpu_vsx_aligned.cpp")
 326   if(NOT OPENCV_CHECK_VSX_ALIGNED)
 327     add_extra_compiler_option_force(-DCV_COMPILER_VSX_BROKEN_ALIGNED)
 328   endif()
 329 endif()
 330 # validate inline asm with fixes register number and constraints wa, wd, wf
 331 if(PPC64LE)
 332   ocv_check_compiler_flag(CXX "${CPU_BASELINE_FLAGS}" OPENCV_CHECK_VSX_ASM "${OpenCV_SOURCE_DIR}/cmake/checks/cpu_vsx_asm.cpp")
 333   if(NOT OPENCV_CHECK_VSX_ASM)
 334     add_extra_compiler_option_force(-DCV_COMPILER_VSX_BROKEN_ASM)
 335   endif()
 336 endif()
 337
 338 # Apply "-Wl,--as-needed" linker flags: https://github.com/opencv/opencv/issues/7001
 339 if(NOT OPENCV_SKIP_LINK_AS_NEEDED)
 340   if(UNIX AND (NOT APPLE OR NOT CMAKE_VERSION VERSION_LESS "3.2"))
 341     set(_option "-Wl,--as-needed")
 342     set(_saved_CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 343     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${_option}")  # requires CMake 3.2+ and CMP0056
 344     ocv_check_compiler_flag(CXX "" HAVE_LINK_AS_NEEDED)
 345     set(CMAKE_EXE_LINKER_FLAGS "${_saved_CMAKE_EXE_LINKER_FLAGS}")
 346     if(HAVE_LINK_AS_NEEDED)
 347       set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS} ${_option}")
 348       set(OPENCV_EXTRA_SHARED_LINKER_FLAGS "${OPENCV_EXTRA_SHARED_LINKER_FLAGS} ${_option}")
 349     endif()
 350   endif()
 351 endif()
 352
 353 # combine all "extra" options
 354 if(NOT OPENCV_SKIP_EXTRA_COMPILER_FLAGS)
 355   set(CMAKE_C_FLAGS           "${CMAKE_C_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_C_FLAGS}")
 356   set(CMAKE_CXX_FLAGS         "${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}")
 357   set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_FLAGS_RELEASE}")
 358   set(CMAKE_C_FLAGS_RELEASE   "${CMAKE_C_FLAGS_RELEASE} ${OPENCV_EXTRA_FLAGS_RELEASE}")
 359   set(CMAKE_CXX_FLAGS_DEBUG   "${CMAKE_CXX_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG}")
 360   set(CMAKE_C_FLAGS_DEBUG     "${CMAKE_C_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG}")
 361   set(CMAKE_EXE_LINKER_FLAGS         "${CMAKE_EXE_LINKER_FLAGS} ${OPENCV_EXTRA_EXE_LINKER_FLAGS}")
 362   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE}")
 363   set(CMAKE_EXE_LINKER_FLAGS_DEBUG   "${CMAKE_EXE_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_DEBUG}")
 364   set(CMAKE_SHARED_LINKER_FLAGS         "${CMAKE_SHARED_LINKER_FLAGS} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS}")
 365   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE}")
 366   set(CMAKE_SHARED_LINKER_FLAGS_DEBUG   "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS_DEBUG}")
 367 endif()
 368
 369 if(MSVC)
 370   if(NOT ENABLE_NOISY_WARNINGS)
 371     if(MSVC_VERSION EQUAL 1400)
 372       ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4510 /wd4610 /wd4312 /wd4201 /wd4244 /wd4328 /wd4267)
 373     endif()
 374   endif()
 375
 376   foreach(flags CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 377     string(REPLACE "/Zm1000" "" ${flags} "${${flags}}")
 378   endforeach()
 379
 380   # Enable 'extern "C"' and asynchronous (division by zero, access violation) exceptions
 381   if(NOT OPENCV_SKIP_MSVC_EXCEPTIONS_FLAG)
 382     foreach(flags CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 383       string(REGEX REPLACE " /EH[^ ]* " " " ${flags} " ${${flags}}")
 384     endforeach()
 385     if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${CMAKE_CXX_FLAGS_DEBUG}" MATCHES " /EH")
 386       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /EHa")
 387     endif()
 388   endif()
 389
 390   if(NOT ENABLE_NOISY_WARNINGS)
 391     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4127) # conditional expression is constant
 392     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4251) # class 'std::XXX' needs to have dll-interface to be used by clients of YYY
 393     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4324) # 'struct_name' : structure was padded due to __declspec(align())
 394     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4275) # non dll-interface class 'std::exception' used as base for dll-interface class 'cv::Exception'
 395     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4512) # Assignment operator could not be generated
 396     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4589) # Constructor of abstract class 'cv::ORB' ignores initializer for virtual base class 'cv::Algorithm'
 397   endif()
 398
 399   if(CV_ICC AND NOT ENABLE_NOISY_WARNINGS)
 400     foreach(flags CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_DEBUG)
 401       string(REGEX REPLACE "( |^)/W[0-9]+( |$)" "\\1\\2" ${flags} "${${flags}}")
 402     endforeach()
 403     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /Qwd673") # PCH warning
 404   endif()
 405 endif()
 406
 407 if(APPLE AND NOT CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{LDFLAGS} AND EXISTS "/usr/local/lib")
 408   link_directories("/usr/local/lib")
 409 endif()
 410
 411 if(ENABLE_BUILD_HARDENING)
 412   include(${CMAKE_CURRENT_LIST_DIR}/OpenCVCompilerDefenses.cmake)
 413 endif()
 414
 415 if(MSVC)
 416   include(cmake/OpenCVCRTLinkage.cmake)
 417   add_definitions(-D_VARIADIC_MAX=10)
 418 endif()
 419
 420 if(CMAKE_SYSTEM_NAME STREQUAL "Windows")
 421   get_directory_property(__DIRECTORY_COMPILE_DEFINITIONS COMPILE_DEFINITIONS)
 422   if((NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS_RELEASE} ${__DIRECTORY_COMPILE_DEFINITIONS}" MATCHES "_WIN32_WINNT"
 423       AND NOT OPENCV_CMAKE_SKIP_MACRO_WIN32_WINNT)
 424       OR OPENCV_CMAKE_FORCE_MACRO_WIN32_WINNT
 425   )
 426     # https://docs.microsoft.com/en-us/cpp/porting/modifying-winver-and-win32-winnt
 427     # Target Windows 7 API
 428     set(OPENCV_CMAKE_MACRO_WIN32_WINNT "0x0601" CACHE STRING "Value of _WIN32_WINNT macro")
 429     add_definitions(-D_WIN32_WINNT=${OPENCV_CMAKE_MACRO_WIN32_WINNT})
 430   endif()
 431 endif()
 432
 433 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 434 macro(ocv_add_modules_compiler_options)
 435   if(MSVC AND NOT OPENCV_SKIP_MSVC_W4_OPTION)
 436     foreach(flags CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 437       string(REPLACE "/W3" "/W4" ${flags} "${${flags}}")
 438     endforeach()
 439   endif()
 440   if(OPENCV_ENABLE_MEMORY_SANITIZER)
 441     add_definitions(-DOPENCV_ENABLE_MEMORY_SANITIZER=1)
 442   endif()
 443 endmacro()
 444
 445 # adjust -Wl,-rpath-link
 446 if(CMAKE_SKIP_RPATH)
 447   if((NOT CMAKE_CROSSCOMPILING OR OPENCV_ENABLE_LINKER_RPATH_LINK_ORIGIN) AND NOT OPENCV_SKIP_LINKER_RPATH_LINK_ORIGIN)
 448     if(DEFINED CMAKE_SHARED_LIBRARY_RPATH_ORIGIN_TOKEN)
 449       list(APPEND CMAKE_PLATFORM_RUNTIME_PATH "${CMAKE_SHARED_LIBRARY_RPATH_ORIGIN_TOKEN}")
 450     else()
 451       list(APPEND CMAKE_PLATFORM_RUNTIME_PATH "\$ORIGIN")
 452     endif()
 453   elseif(NOT OPENCV_SKIP_LINKER_RPATH_LINK_BINARY_LIB)
 454     list(APPEND CMAKE_PLATFORM_RUNTIME_PATH "${LIBRARY_OUTPUT_PATH}")
 455   endif()
 456 endif()
 457 if(OPENCV_EXTRA_RPATH_LINK_PATH)
 458   string(REPLACE ":" ";" OPENCV_EXTRA_RPATH_LINK_PATH_ "${OPENCV_EXTRA_RPATH_LINK_PATH}")
 459   list(APPEND CMAKE_PLATFORM_RUNTIME_PATH ${OPENCV_EXTRA_RPATH_LINK_PATH_})
 460   if(NOT CMAKE_EXECUTABLE_RPATH_LINK_CXX_FLAG)
 461     message(WARNING "OPENCV_EXTRA_RPATH_LINK_PATH may not work properly because CMAKE_EXECUTABLE_RPATH_LINK_CXX_FLAG is not defined (not supported)")
 462   endif()
 463 endif()
 464
 465 # Control MSVC /MP flag
 466 # Input variables: OPENCV_MSVC_PARALLEL (ON,1,2,3,...) + OPENCV_SKIP_MSVC_PARALLEL
 467 # Details:
 468 # - https://docs.microsoft.com/en-us/cpp/build/reference/mp-build-with-multiple-processes
 469 # - https://docs.microsoft.com/en-us/cpp/build/reference/cl-environment-variables
 470 # - https://gitlab.kitware.com/cmake/cmake/merge_requests/1718/diffs
 471 if(CMAKE_GENERATOR MATCHES "Visual Studio" AND CMAKE_CXX_COMPILER_ID MATCHES "MSVC|Intel")
 472   ocv_check_environment_variables(OPENCV_SKIP_MSVC_PARALLEL)
 473   if(OPENCV_SKIP_MSVC_PARALLEL)
 474     # nothing
 475   elseif(" ${CMAKE_CXX_FLAGS}" MATCHES "/MP")
 476     # nothing, already defined in compiler flags
 477   elseif(DEFINED ENV{CL} AND " $ENV{CL}" MATCHES "/MP")
 478     # nothing, compiler will use CL environment variable
 479   elseif(DEFINED ENV{_CL_} AND " $ENV{_CL_}" MATCHES "/MP")
 480     # nothing, compiler will use _CL_ environment variable
 481   else()
 482     ocv_check_environment_variables(OPENCV_MSVC_PARALLEL)
 483     set(_mp_value "ON")
 484     if(DEFINED OPENCV_MSVC_PARALLEL)
 485       set(_mp_value "${OPENCV_MSVC_PARALLEL}")
 486     endif()
 487     set(OPENCV_MSVC_PARALLEL "${_mp_value}" CACHE STRING "Control MSVC /MP flag")
 488     if(_mp_value)
 489       if(_mp_value GREATER 0)
 490         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /MP${_mp_value}")
 491         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MP${_mp_value}")
 492       else()
 493         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /MP")
 494         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MP")
 495       endif()
 496     endif()
 497   endif()
 498 endif()