cmake/OpenCVCompilerOptions.cmake

   1 if("${CMAKE_CXX_COMPILER};${CMAKE_C_COMPILER};${CMAKE_CXX_COMPILER_LAUNCHER}" MATCHES "ccache")
   2   set(CMAKE_COMPILER_IS_CCACHE 1)  # TODO: FIXIT Avoid setting of CMAKE_ variables
   3   set(OPENCV_COMPILER_IS_CCACHE 1)
   4 endif()
   5 function(access_CMAKE_COMPILER_IS_CCACHE)
   6   if(NOT OPENCV_SUPPRESS_DEPRECATIONS)
   7     message(WARNING "DEPRECATED: CMAKE_COMPILER_IS_CCACHE is replaced to OPENCV_COMPILER_IS_CCACHE.")
   8   endif()
   9 endfunction()
  10 variable_watch(CMAKE_COMPILER_IS_CCACHE access_CMAKE_COMPILER_IS_CCACHE)
  11 if(ENABLE_CCACHE AND NOT OPENCV_COMPILER_IS_CCACHE AND NOT CMAKE_GENERATOR MATCHES "Xcode")
  12   # This works fine with Unix Makefiles and Ninja generators
  13   find_host_program(CCACHE_PROGRAM ccache)
  14   if(CCACHE_PROGRAM)
  15     message(STATUS "Looking for ccache - found (${CCACHE_PROGRAM})")
  16     get_property(__OLD_RULE_LAUNCH_COMPILE GLOBAL PROPERTY RULE_LAUNCH_COMPILE)
  17     if(__OLD_RULE_LAUNCH_COMPILE)
  18       message(STATUS "Can't replace CMake compiler launcher")
  19     else()
  20       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
  21       # NOTE: Actually this check doesn't work as expected.
  22       # "RULE_LAUNCH_COMPILE" is ignored by CMake during try_compile() step.
  23       # ocv_check_compiler_flag(CXX "" IS_CCACHE_WORKS)
  24       set(IS_CCACHE_WORKS 1)
  25       if(IS_CCACHE_WORKS)
  26         set(OPENCV_COMPILER_IS_CCACHE 1)
  27       else()
  28         message(STATUS "Unable to compile program with enabled ccache, reverting...")
  29         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${__OLD_RULE_LAUNCH_COMPILE}")
  30       endif()
  31     endif()
  32   else()
  33     message(STATUS "Looking for ccache - not found")
  34   endif()
  35 endif()
  36
  37 if((CV_CLANG AND NOT CMAKE_GENERATOR MATCHES "Xcode")  # PCH has no support for Clang
  38     OR OPENCV_COMPILER_IS_CCACHE
  39 )
  40   set(ENABLE_PRECOMPILED_HEADERS OFF CACHE BOOL "" FORCE)
  41 endif()
  42
  43 macro(add_extra_compiler_option option)
  44   ocv_check_flag_support(CXX "${option}" _varname "${OPENCV_EXTRA_CXX_FLAGS} ${ARGN}")
  45   if(${_varname})
  46     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} ${option}")
  47   endif()
  48
  49   ocv_check_flag_support(C "${option}" _varname "${OPENCV_EXTRA_C_FLAGS} ${ARGN}")
  50   if(${_varname})
  51     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} ${option}")
  52   endif()
  53 endmacro()
  54
  55 macro(add_extra_compiler_option_force option)
  56   set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} ${option}")
  57   set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} ${option}")
  58 endmacro()
  59
  60
  61 # Gets environment variable and puts its value to the corresponding preprocessor definition
  62 # Useful for WINRT that has no access to environment variables
  63 macro(add_env_definitions option)
  64   set(value $ENV{${option}})
  65   if("${value}" STREQUAL "")
  66     message(WARNING "${option} environment variable is empty. Please set it to appropriate location to get correct results")
  67   else()
  68     string(REPLACE "\\" "\\\\" value ${value})
  69   endif()
  70   add_definitions("-D${option}=\"${value}\"")
  71 endmacro()
  72
  73 if(NOT MSVC)
  74   # OpenCV fails some tests when 'char' is 'unsigned' by default
  75   add_extra_compiler_option(-fsigned-char)
  76 endif()
  77
  78 if(MSVC)
  79   if(NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " /fp:")
  80     if(ENABLE_FAST_MATH)
  81       add_extra_compiler_option("/fp:fast")
  82     else()
  83       add_extra_compiler_option("/fp:precise")
  84     endif()
  85   endif()
  86 elseif(CV_ICC)
  87   if(NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " /fp:"
  88       AND NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " -fp-model"
  89   )
  90     if(NOT ENABLE_FAST_MATH)
  91       add_extra_compiler_option("-fp-model precise")
  92     endif()
  93   endif()
  94 elseif(CV_GCC OR CV_CLANG)
  95   if(ENABLE_FAST_MATH)
  96     add_extra_compiler_option(-ffast-math)
  97   endif()
  98 endif()
  99
 100 if(CV_GCC OR CV_CLANG)
 101   # High level of warnings.
 102   add_extra_compiler_option(-W)
 103   if (NOT MSVC)
 104     # clang-cl interprets -Wall as MSVC would: -Weverything, which is more than
 105     # we want.
 106     add_extra_compiler_option(-Wall)
 107   endif()
 108   add_extra_compiler_option(-Werror=return-type)
 109   add_extra_compiler_option(-Werror=non-virtual-dtor)
 110   add_extra_compiler_option(-Werror=address)
 111   add_extra_compiler_option(-Werror=sequence-point)
 112   add_extra_compiler_option(-Wformat)
 113   add_extra_compiler_option(-Werror=format-security -Wformat)
 114   add_extra_compiler_option(-Wmissing-declarations)
 115   add_extra_compiler_option(-Wmissing-prototypes)
 116   add_extra_compiler_option(-Wstrict-prototypes)
 117   add_extra_compiler_option(-Wundef)
 118   add_extra_compiler_option(-Winit-self)
 119   add_extra_compiler_option(-Wpointer-arith)
 120   add_extra_compiler_option(-Wshadow)
 121   add_extra_compiler_option(-Wsign-promo)
 122   add_extra_compiler_option(-Wuninitialized)
 123   add_extra_compiler_option(-Winit-self)
 124   if(CV_GCC AND (CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 6.0) AND (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 7.0))
 125     add_extra_compiler_option(-Wno-psabi)
 126   endif()
 127   if(HAVE_CXX11)
 128     if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND NOT ENABLE_PRECOMPILED_HEADERS)
 129       add_extra_compiler_option(-Wsuggest-override)
 130     elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 131       add_extra_compiler_option(-Winconsistent-missing-override)
 132     endif()
 133   endif()
 134
 135   if(ENABLE_NOISY_WARNINGS)
 136     add_extra_compiler_option(-Wcast-align)
 137     add_extra_compiler_option(-Wstrict-aliasing=2)
 138   else()
 139     add_extra_compiler_option(-Wno-delete-non-virtual-dtor)
 140     add_extra_compiler_option(-Wno-unnamed-type-template-args)
 141     add_extra_compiler_option(-Wno-comment)
 142     if(NOT OPENCV_SKIP_IMPLICIT_FALLTHROUGH
 143         AND NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES "implicit-fallthrough"
 144         AND (CV_GCC AND NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS 7.0.0)
 145     )
 146       add_extra_compiler_option(-Wimplicit-fallthrough=3)
 147     endif()
 148     if(CV_GCC AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 7.0)
 149       add_extra_compiler_option(-Wno-strict-overflow) # Issue appears when compiling surf.cpp from opencv_contrib/modules/xfeatures2d
 150     endif()
 151     if(CV_GCC AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 5.0)
 152       add_extra_compiler_option(-Wno-missing-field-initializers)  # GCC 4.x emits warnings about {}, fixed in GCC 5+
 153     endif()
 154     if(CV_CLANG AND NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS 10.0)
 155       add_extra_compiler_option(-Wno-deprecated-enum-enum-conversion)
 156       add_extra_compiler_option(-Wno-deprecated-anon-enum-enum-conversion)
 157     endif()
 158   endif()
 159   add_extra_compiler_option(-fdiagnostics-show-option)
 160
 161   # The -Wno-long-long is required in 64bit systems when including system headers.
 162   if(X86_64)
 163     add_extra_compiler_option(-Wno-long-long)
 164   endif()
 165
 166   # We need pthread's
 167   if(UNIX AND NOT ANDROID AND NOT (APPLE AND CV_CLANG)) # TODO
 168     add_extra_compiler_option(-pthread)
 169   endif()
 170
 171   if(CV_CLANG)
 172     add_extra_compiler_option(-Qunused-arguments)
 173   endif()
 174
 175   if(OPENCV_WARNINGS_ARE_ERRORS)
 176     add_extra_compiler_option(-Werror)
 177   endif()
 178
 179   if(APPLE)
 180     add_extra_compiler_option(-Wno-semicolon-before-method-body)
 181   endif()
 182
 183   # Other optimizations
 184   if(ENABLE_OMIT_FRAME_POINTER)
 185     add_extra_compiler_option(-fomit-frame-pointer)
 186   elseif(DEFINED ENABLE_OMIT_FRAME_POINTER)
 187     add_extra_compiler_option(-fno-omit-frame-pointer)
 188   endif()
 189
 190   # Profiling?
 191   if(ENABLE_PROFILING)
 192     # turn off incompatible options
 193     foreach(flags CMAKE_CXX_FLAGS CMAKE_C_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG CMAKE_C_FLAGS_DEBUG
 194                   OPENCV_EXTRA_FLAGS_RELEASE OPENCV_EXTRA_FLAGS_DEBUG OPENCV_EXTRA_C_FLAGS OPENCV_EXTRA_CXX_FLAGS)
 195       string(REPLACE "-fomit-frame-pointer" "" ${flags} "${${flags}}")
 196       string(REPLACE "-ffunction-sections" "" ${flags} "${${flags}}")
 197       string(REPLACE "-fdata-sections" "" ${flags} "${${flags}}")
 198     endforeach()
 199     # -pg should be placed both in the linker and in the compiler settings
 200     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg")
 201     add_extra_compiler_option("-pg -g")
 202   else()
 203     if(MSVC)
 204       # TODO: Clang/C2 is not supported
 205     elseif(((IOS OR ANDROID) AND NOT BUILD_SHARED_LIBS) AND NOT OPENCV_FORCE_FUNCTIONS_SECTIONS)
 206       # don't create separate sections for functions/data, reduce package size
 207     else()
 208       # Remove unreferenced functions: function level linking
 209       add_extra_compiler_option(-ffunction-sections)
 210       add_extra_compiler_option(-fdata-sections)
 211       if(NOT OPENCV_SKIP_GC_SECTIONS)
 212         if(APPLE)
 213           set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS} -Wl,-dead_strip")
 214           set(OPENCV_EXTRA_SHARED_LINKER_FLAGS "${OPENCV_EXTRA_SHARED_LINKER_FLAGS} -Wl,-dead_strip")
 215         else()
 216           set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS} -Wl,--gc-sections")
 217           set(OPENCV_EXTRA_SHARED_LINKER_FLAGS "${OPENCV_EXTRA_SHARED_LINKER_FLAGS} -Wl,--gc-sections")
 218         endif()
 219       endif()
 220     endif()
 221   endif()
 222
 223   if(ENABLE_COVERAGE)
 224     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} --coverage")
 225     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} --coverage")
 226     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} --coverage")
 227   endif()
 228
 229   if(ENABLE_INSTRUMENTATION)
 230     if(NOT HAVE_CXX11)
 231       message(WARNING "ENABLE_INSTRUMENTATION requires C++11 support")
 232     endif()
 233     set(WITH_VTK OFF) # There are issues with VTK 6.0
 234   endif()
 235
 236   if(ENABLE_LTO)
 237     add_extra_compiler_option(-flto)
 238   endif()
 239   if(ENABLE_THIN_LTO)
 240     add_extra_compiler_option(-flto=thin)
 241   endif()
 242
 243   set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} -DNDEBUG")
 244   if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG} " MATCHES "-O")
 245     set(OPENCV_EXTRA_FLAGS_DEBUG "${OPENCV_EXTRA_FLAGS_DEBUG} -O0")
 246   endif()
 247   set(OPENCV_EXTRA_FLAGS_DEBUG "${OPENCV_EXTRA_FLAGS_DEBUG} -DDEBUG -D_DEBUG")
 248
 249   if(BUILD_WITH_DEBUG_INFO)
 250     # https://gcc.gnu.org/onlinedocs/gcc/Debugging-Options.html
 251     # '-g' is equal to '-g2', '-g1' produces minimal information, enough for making backtraces
 252     ocv_update(OPENCV_DEBUG_OPTION "-g1")
 253     if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS_RELEASE}" MATCHES " -g")
 254       set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} ${OPENCV_DEBUG_OPTION}")
 255     endif()
 256   endif()
 257 endif()
 258
 259 if(MSVC)
 260   #TODO Code refactoring is required to resolve security warnings
 261   #if(NOT ENABLE_BUILD_HARDENING)
 262     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /D _CRT_SECURE_NO_DEPRECATE /D _CRT_NONSTDC_NO_DEPRECATE /D _SCL_SECURE_NO_WARNINGS")
 263   #endif()
 264
 265   if(BUILD_WITH_DEBUG_INFO)
 266     set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} /Zi")
 267     set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE} /debug")
 268     set(OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE} /debug")
 269   endif()
 270
 271   # Remove unreferenced functions: function level linking
 272   set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /Gy")
 273   if(NOT MSVC_VERSION LESS 1400)
 274     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /bigobj")
 275   endif()
 276
 277   if(OPENCV_WARNINGS_ARE_ERRORS)
 278     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /WX")
 279   endif()
 280
 281   if(ENABLE_LTO)
 282     set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} /GL")
 283     set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE} /LTCG")
 284   endif()
 285
 286   if(NOT MSVC_VERSION LESS 1800 AND NOT CMAKE_GENERATOR MATCHES "Visual Studio")
 287     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} /FS")
 288     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} /FS")
 289   endif()
 290 endif()
 291
 292 include(cmake/OpenCVCompilerOptimizations.cmake)
 293 if(COMMAND ocv_compiler_optimization_options)
 294   ocv_compiler_optimization_options()
 295 endif()
 296 if(COMMAND ocv_compiler_optimization_options_finalize)
 297   ocv_compiler_optimization_options_finalize()
 298 endif()
 299
 300 # set default visibility to hidden
 301 if((CV_GCC OR CV_CLANG)
 302     AND NOT MSVC
 303     AND NOT OPENCV_SKIP_VISIBILITY_HIDDEN
 304     AND NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " -fvisibility")
 305   add_extra_compiler_option(-fvisibility=hidden)
 306   add_extra_compiler_option(-fvisibility-inlines-hidden)
 307 endif()
 308
 309 # workaround gcc bug for aligned ld/st
 310 # https://github.com/opencv/opencv/issues/13211
 311 if((PPC64LE AND NOT CMAKE_CROSSCOMPILING) OR OPENCV_FORCE_COMPILER_CHECK_VSX_ALIGNED)
 312   ocv_check_runtime_flag("${CPU_BASELINE_FLAGS}" OPENCV_CHECK_VSX_ALIGNED "${OpenCV_SOURCE_DIR}/cmake/checks/runtime/cpu_vsx_aligned.cpp")
 313   if(NOT OPENCV_CHECK_VSX_ALIGNED)
 314     add_extra_compiler_option_force(-DCV_COMPILER_VSX_BROKEN_ALIGNED)
 315   endif()
 316 endif()
 317 # validate inline asm with fixes register number and constraints wa, wd, wf
 318 if(PPC64LE)
 319   ocv_check_compiler_flag(CXX "${CPU_BASELINE_FLAGS}" OPENCV_CHECK_VSX_ASM "${OpenCV_SOURCE_DIR}/cmake/checks/cpu_vsx_asm.cpp")
 320   if(NOT OPENCV_CHECK_VSX_ASM)
 321     add_extra_compiler_option_force(-DCV_COMPILER_VSX_BROKEN_ASM)
 322   endif()
 323 endif()
 324
 325 # Apply "-Wl,--as-needed" linker flags: https://github.com/opencv/opencv/issues/7001
 326 if(NOT OPENCV_SKIP_LINK_AS_NEEDED)
 327   if(UNIX AND (NOT APPLE OR NOT CMAKE_VERSION VERSION_LESS "3.2"))
 328     set(_option "-Wl,--as-needed")
 329     set(_saved_CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 330     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${_option}")  # requires CMake 3.2+ and CMP0056
 331     ocv_check_compiler_flag(CXX "" HAVE_LINK_AS_NEEDED)
 332     set(CMAKE_EXE_LINKER_FLAGS "${_saved_CMAKE_EXE_LINKER_FLAGS}")
 333     if(HAVE_LINK_AS_NEEDED)
 334       set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS} ${_option}")
 335       set(OPENCV_EXTRA_SHARED_LINKER_FLAGS "${OPENCV_EXTRA_SHARED_LINKER_FLAGS} ${_option}")
 336     endif()
 337   endif()
 338 endif()
 339
 340 # combine all "extra" options
 341 if(NOT OPENCV_SKIP_EXTRA_COMPILER_FLAGS)
 342   set(CMAKE_C_FLAGS           "${CMAKE_C_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_C_FLAGS}")
 343   set(CMAKE_CXX_FLAGS         "${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}")
 344   set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_FLAGS_RELEASE}")
 345   set(CMAKE_C_FLAGS_RELEASE   "${CMAKE_C_FLAGS_RELEASE} ${OPENCV_EXTRA_FLAGS_RELEASE}")
 346   set(CMAKE_CXX_FLAGS_DEBUG   "${CMAKE_CXX_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG}")
 347   set(CMAKE_C_FLAGS_DEBUG     "${CMAKE_C_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG}")
 348   set(CMAKE_EXE_LINKER_FLAGS         "${CMAKE_EXE_LINKER_FLAGS} ${OPENCV_EXTRA_EXE_LINKER_FLAGS}")
 349   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE}")
 350   set(CMAKE_EXE_LINKER_FLAGS_DEBUG   "${CMAKE_EXE_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_DEBUG}")
 351   set(CMAKE_SHARED_LINKER_FLAGS         "${CMAKE_SHARED_LINKER_FLAGS} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS}")
 352   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE}")
 353   set(CMAKE_SHARED_LINKER_FLAGS_DEBUG   "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS_DEBUG}")
 354 endif()
 355
 356 if(MSVC)
 357   if(NOT ENABLE_NOISY_WARNINGS)
 358     if(MSVC_VERSION EQUAL 1400)
 359       ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4510 /wd4610 /wd4312 /wd4201 /wd4244 /wd4328 /wd4267)
 360     endif()
 361   endif()
 362
 363   foreach(flags CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 364     string(REPLACE "/Zm1000" "" ${flags} "${${flags}}")
 365   endforeach()
 366
 367   # Enable 'extern "C"' and asynchronous (division by zero, access violation) exceptions
 368   if(NOT OPENCV_SKIP_MSVC_EXCEPTIONS_FLAG)
 369     foreach(flags CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 370       string(REGEX REPLACE " /EH[^ ]* " " " ${flags} " ${${flags}}")
 371     endforeach()
 372     if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${CMAKE_CXX_FLAGS_DEBUG}" MATCHES " /EH")
 373       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /EHa")
 374     endif()
 375   endif()
 376
 377   if(NOT ENABLE_NOISY_WARNINGS)
 378     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4127) # conditional expression is constant
 379     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4251) # class 'std::XXX' needs to have dll-interface to be used by clients of YYY
 380     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4324) # 'struct_name' : structure was padded due to __declspec(align())
 381     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4275) # non dll-interface class 'std::exception' used as base for dll-interface class 'cv::Exception'
 382     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4512) # Assignment operator could not be generated
 383     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4589) # Constructor of abstract class 'cv::ORB' ignores initializer for virtual base class 'cv::Algorithm'
 384   endif()
 385
 386   if(CV_ICC AND NOT ENABLE_NOISY_WARNINGS)
 387     foreach(flags CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_DEBUG)
 388       string(REGEX REPLACE "( |^)/W[0-9]+( |$)" "\\1\\2" ${flags} "${${flags}}")
 389     endforeach()
 390     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /Qwd673") # PCH warning
 391   endif()
 392 endif()
 393
 394 if(APPLE AND NOT CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{LDFLAGS} AND EXISTS "/usr/local/lib")
 395   link_directories("/usr/local/lib")
 396 endif()
 397
 398 if(ENABLE_BUILD_HARDENING)
 399   include(${CMAKE_CURRENT_LIST_DIR}/OpenCVCompilerDefenses.cmake)
 400 endif()
 401
 402 if(MSVC)
 403   include(cmake/OpenCVCRTLinkage.cmake)
 404   add_definitions(-D_VARIADIC_MAX=10)
 405 endif()
 406
 407 if(CMAKE_SYSTEM_NAME STREQUAL "Windows")
 408   get_directory_property(__DIRECTORY_COMPILE_DEFINITIONS COMPILE_DEFINITIONS)
 409   if((NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS_RELEASE} ${__DIRECTORY_COMPILE_DEFINITIONS}" MATCHES "_WIN32_WINNT"
 410       AND NOT OPENCV_CMAKE_SKIP_MACRO_WIN32_WINNT)
 411       OR OPENCV_CMAKE_FORCE_MACRO_WIN32_WINNT
 412   )
 413     # https://docs.microsoft.com/en-us/cpp/porting/modifying-winver-and-win32-winnt
 414     # Target Windows 7 API
 415     set(OPENCV_CMAKE_MACRO_WIN32_WINNT "0x0601" CACHE STRING "Value of _WIN32_WINNT macro")
 416     add_definitions(-D_WIN32_WINNT=${OPENCV_CMAKE_MACRO_WIN32_WINNT})
 417   endif()
 418 endif()
 419
 420 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 421 macro(ocv_add_modules_compiler_options)
 422   if(MSVC AND NOT OPENCV_SKIP_MSVC_W4_OPTION)
 423     foreach(flags CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 424       string(REPLACE "/W3" "/W4" ${flags} "${${flags}}")
 425     endforeach()
 426   endif()
 427   if(OPENCV_ENABLE_MEMORY_SANITIZER)
 428     add_definitions(-DOPENCV_ENABLE_MEMORY_SANITIZER=1)
 429   endif()
 430 endmacro()
 431
 432 # adjust -Wl,-rpath-link
 433 if(CMAKE_SKIP_RPATH)
 434   if((NOT CMAKE_CROSSCOMPILING OR OPENCV_ENABLE_LINKER_RPATH_LINK_ORIGIN) AND NOT OPENCV_SKIP_LINKER_RPATH_LINK_ORIGIN)
 435     if(DEFINED CMAKE_SHARED_LIBRARY_RPATH_ORIGIN_TOKEN)
 436       list(APPEND CMAKE_PLATFORM_RUNTIME_PATH "${CMAKE_SHARED_LIBRARY_RPATH_ORIGIN_TOKEN}")
 437     else()
 438       list(APPEND CMAKE_PLATFORM_RUNTIME_PATH "\$ORIGIN")
 439     endif()
 440   elseif(NOT OPENCV_SKIP_LINKER_RPATH_LINK_BINARY_LIB)
 441     list(APPEND CMAKE_PLATFORM_RUNTIME_PATH "${LIBRARY_OUTPUT_PATH}")
 442   endif()
 443 endif()
 444 if(OPENCV_EXTRA_RPATH_LINK_PATH)
 445   string(REPLACE ":" ";" OPENCV_EXTRA_RPATH_LINK_PATH_ "${OPENCV_EXTRA_RPATH_LINK_PATH}")
 446   list(APPEND CMAKE_PLATFORM_RUNTIME_PATH ${OPENCV_EXTRA_RPATH_LINK_PATH_})
 447   if(NOT CMAKE_EXECUTABLE_RPATH_LINK_CXX_FLAG)
 448     message(WARNING "OPENCV_EXTRA_RPATH_LINK_PATH may not work properly because CMAKE_EXECUTABLE_RPATH_LINK_CXX_FLAG is not defined (not supported)")
 449   endif()
 450 endif()
 451
 452 # Control MSVC /MP flag
 453 # Input variables: OPENCV_MSVC_PARALLEL (ON,1,2,3,...) + OPENCV_SKIP_MSVC_PARALLEL
 454 # Details:
 455 # - https://docs.microsoft.com/en-us/cpp/build/reference/mp-build-with-multiple-processes
 456 # - https://docs.microsoft.com/en-us/cpp/build/reference/cl-environment-variables
 457 # - https://gitlab.kitware.com/cmake/cmake/merge_requests/1718/diffs
 458 if(CMAKE_GENERATOR MATCHES "Visual Studio" AND CMAKE_CXX_COMPILER_ID MATCHES "MSVC|Intel")
 459   ocv_check_environment_variables(OPENCV_SKIP_MSVC_PARALLEL)
 460   if(OPENCV_SKIP_MSVC_PARALLEL)
 461     # nothing
 462   elseif(" ${CMAKE_CXX_FLAGS}" MATCHES "/MP")
 463     # nothing, already defined in compiler flags
 464   elseif(DEFINED ENV{CL} AND " $ENV{CL}" MATCHES "/MP")
 465     # nothing, compiler will use CL environment variable
 466   elseif(DEFINED ENV{_CL_} AND " $ENV{_CL_}" MATCHES "/MP")
 467     # nothing, compiler will use _CL_ environment variable
 468   else()
 469     ocv_check_environment_variables(OPENCV_MSVC_PARALLEL)
 470     set(_mp_value "ON")
 471     if(DEFINED OPENCV_MSVC_PARALLEL)
 472       set(_mp_value "${OPENCV_MSVC_PARALLEL}")
 473     endif()
 474     set(OPENCV_MSVC_PARALLEL "${_mp_value}" CACHE STRING "Control MSVC /MP flag")
 475     if(_mp_value)
 476       if(_mp_value GREATER 0)
 477         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /MP${_mp_value}")
 478         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MP${_mp_value}")
 479       else()
 480         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /MP")
 481         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MP")
 482       endif()
 483     endif()
 484   endif()
 485 endif()