cmake/OpenCVCompilerOptions.cmake

   1 if("${CMAKE_CXX_COMPILER};${CMAKE_C_COMPILER};${CMAKE_CXX_COMPILER_LAUNCHER}" MATCHES "ccache")
   2   set(CMAKE_COMPILER_IS_CCACHE 1)  # TODO: FIXIT Avoid setting of CMAKE_ variables
   3   set(OPENCV_COMPILER_IS_CCACHE 1)
   4 endif()
   5 function(access_CMAKE_COMPILER_IS_CCACHE)
   6   if(NOT OPENCV_SUPPRESS_DEPRECATIONS)
   7     message(WARNING "DEPRECATED: CMAKE_COMPILER_IS_CCACHE is replaced to OPENCV_COMPILER_IS_CCACHE.")
   8   endif()
   9 endfunction()
  10 variable_watch(CMAKE_COMPILER_IS_CCACHE access_CMAKE_COMPILER_IS_CCACHE)
  11 if(ENABLE_CCACHE AND NOT OPENCV_COMPILER_IS_CCACHE AND NOT CMAKE_GENERATOR MATCHES "Xcode")
  12   # This works fine with Unix Makefiles and Ninja generators
  13   find_host_program(CCACHE_PROGRAM ccache)
  14   if(CCACHE_PROGRAM)
  15     message(STATUS "Looking for ccache - found (${CCACHE_PROGRAM})")
  16     get_property(__OLD_RULE_LAUNCH_COMPILE GLOBAL PROPERTY RULE_LAUNCH_COMPILE)
  17     if(__OLD_RULE_LAUNCH_COMPILE)
  18       message(STATUS "Can't replace CMake compiler launcher")
  19     else()
  20       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
  21       # NOTE: Actually this check doesn't work as expected.
  22       # "RULE_LAUNCH_COMPILE" is ignored by CMake during try_compile() step.
  23       # ocv_check_compiler_flag(CXX "" IS_CCACHE_WORKS)
  24       set(IS_CCACHE_WORKS 1)
  25       if(IS_CCACHE_WORKS)
  26         set(OPENCV_COMPILER_IS_CCACHE 1)
  27       else()
  28         message(STATUS "Unable to compile program with enabled ccache, reverting...")
  29         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${__OLD_RULE_LAUNCH_COMPILE}")
  30       endif()
  31     endif()
  32   else()
  33     message(STATUS "Looking for ccache - not found")
  34   endif()
  35 endif()
  36
  37 if((CV_CLANG AND NOT CMAKE_GENERATOR MATCHES "Xcode")  # PCH has no support for Clang
  38     OR OPENCV_COMPILER_IS_CCACHE
  39 )
  40   set(ENABLE_PRECOMPILED_HEADERS OFF CACHE BOOL "" FORCE)
  41 endif()
  42
  43 macro(add_extra_compiler_option option)
  44   ocv_check_flag_support(CXX "${option}" _varname "${OPENCV_EXTRA_CXX_FLAGS} ${ARGN}")
  45   if(${_varname})
  46     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} ${option}")
  47   endif()
  48
  49   ocv_check_flag_support(C "${option}" _varname "${OPENCV_EXTRA_C_FLAGS} ${ARGN}")
  50   if(${_varname})
  51     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} ${option}")
  52   endif()
  53 endmacro()
  54
  55 macro(add_extra_compiler_option_force option)
  56   set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} ${option}")
  57   set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} ${option}")
  58 endmacro()
  59
  60
  61 # Gets environment variable and puts its value to the corresponding preprocessor definition
  62 # Useful for WINRT that has no access to environment variables
  63 macro(add_env_definitions option)
  64   set(value $ENV{${option}})
  65   if("${value}" STREQUAL "")
  66     message(WARNING "${option} environment variable is empty. Please set it to appropriate location to get correct results")
  67   else()
  68     string(REPLACE "\\" "\\\\" value ${value})
  69   endif()
  70   add_definitions("-D${option}=\"${value}\"")
  71 endmacro()
  72
  73 if(NOT MSVC)
  74   # OpenCV fails some tests when 'char' is 'unsigned' by default
  75   add_extra_compiler_option(-fsigned-char)
  76 endif()
  77
  78 if(MSVC)
  79   if(NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " /fp:")
  80     if(ENABLE_FAST_MATH)
  81       add_extra_compiler_option("/fp:fast")
  82     else()
  83       add_extra_compiler_option("/fp:precise")
  84     endif()
  85   endif()
  86 elseif(CV_ICC)
  87   if(NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " /fp:"
  88       AND NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " -fp-model"
  89   )
  90     if(NOT ENABLE_FAST_MATH)
  91       add_extra_compiler_option("-fp-model precise")
  92     endif()
  93   endif()
  94 elseif(CV_GCC OR CV_CLANG)
  95   if(ENABLE_FAST_MATH)
  96     add_extra_compiler_option(-ffast-math)
  97   endif()
  98 endif()
  99
 100 if(CV_GCC OR CV_CLANG)
 101   # High level of warnings.
 102   add_extra_compiler_option(-W)
 103   if (NOT MSVC)
 104     # clang-cl interprets -Wall as MSVC would: -Weverything, which is more than
 105     # we want.
 106     add_extra_compiler_option(-Wall)
 107   endif()
 108   add_extra_compiler_option(-Werror=return-type)
 109   add_extra_compiler_option(-Werror=non-virtual-dtor)
 110   add_extra_compiler_option(-Werror=address)
 111   add_extra_compiler_option(-Werror=sequence-point)
 112   add_extra_compiler_option(-Wformat)
 113   add_extra_compiler_option(-Werror=format-security -Wformat)
 114   add_extra_compiler_option(-Wmissing-declarations)
 115   add_extra_compiler_option(-Wmissing-prototypes)
 116   add_extra_compiler_option(-Wstrict-prototypes)
 117   add_extra_compiler_option(-Wundef)
 118   add_extra_compiler_option(-Winit-self)
 119   add_extra_compiler_option(-Wpointer-arith)
 120   add_extra_compiler_option(-Wshadow)
 121   add_extra_compiler_option(-Wsign-promo)
 122   add_extra_compiler_option(-Wuninitialized)
 123   add_extra_compiler_option(-Winit-self)
 124   if(CV_GCC AND (CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 6.0) AND (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 7.0))
 125     add_extra_compiler_option(-Wno-psabi)
 126   endif()
 127   if(HAVE_CXX11)
 128     if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND NOT ENABLE_PRECOMPILED_HEADERS)
 129       add_extra_compiler_option(-Wsuggest-override)
 130     elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 131       add_extra_compiler_option(-Winconsistent-missing-override)
 132     endif()
 133   endif()
 134
 135   if(ENABLE_NOISY_WARNINGS)
 136     add_extra_compiler_option(-Wcast-align)
 137     add_extra_compiler_option(-Wstrict-aliasing=2)
 138   else()
 139     add_extra_compiler_option(-Wno-delete-non-virtual-dtor)
 140     add_extra_compiler_option(-Wno-unnamed-type-template-args)
 141     add_extra_compiler_option(-Wno-comment)
 142     if(NOT OPENCV_SKIP_IMPLICIT_FALLTHROUGH
 143         AND NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES "implicit-fallthrough"
 144         AND (CV_GCC AND NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS 7.0.0)
 145     )
 146       add_extra_compiler_option(-Wimplicit-fallthrough=3)
 147     endif()
 148     if(CV_GCC AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 7.0)
 149       add_extra_compiler_option(-Wno-strict-overflow) # Issue appears when compiling surf.cpp from opencv_contrib/modules/xfeatures2d
 150     endif()
 151     if(CV_GCC AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 5.0)
 152       add_extra_compiler_option(-Wno-missing-field-initializers)  # GCC 4.x emits warnings about {}, fixed in GCC 5+
 153     endif()
 154   endif()
 155   add_extra_compiler_option(-fdiagnostics-show-option)
 156
 157   # The -Wno-long-long is required in 64bit systems when including system headers.
 158   if(X86_64)
 159     add_extra_compiler_option(-Wno-long-long)
 160   endif()
 161
 162   # We need pthread's
 163   if(UNIX AND NOT ANDROID AND NOT (APPLE AND CV_CLANG)) # TODO
 164     add_extra_compiler_option(-pthread)
 165   endif()
 166
 167   if(CV_CLANG)
 168     add_extra_compiler_option(-Qunused-arguments)
 169   endif()
 170
 171   if(OPENCV_WARNINGS_ARE_ERRORS)
 172     add_extra_compiler_option(-Werror)
 173   endif()
 174
 175   if(APPLE)
 176     add_extra_compiler_option(-Wno-semicolon-before-method-body)
 177   endif()
 178
 179   # Other optimizations
 180   if(ENABLE_OMIT_FRAME_POINTER)
 181     add_extra_compiler_option(-fomit-frame-pointer)
 182   elseif(DEFINED ENABLE_OMIT_FRAME_POINTER)
 183     add_extra_compiler_option(-fno-omit-frame-pointer)
 184   endif()
 185
 186   # Profiling?
 187   if(ENABLE_PROFILING)
 188     add_extra_compiler_option("-pg -g")
 189     # turn off incompatible options
 190     foreach(flags CMAKE_CXX_FLAGS CMAKE_C_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG CMAKE_C_FLAGS_DEBUG
 191                   OPENCV_EXTRA_FLAGS_RELEASE OPENCV_EXTRA_FLAGS_DEBUG OPENCV_EXTRA_C_FLAGS OPENCV_EXTRA_CXX_FLAGS)
 192       string(REPLACE "-fomit-frame-pointer" "" ${flags} "${${flags}}")
 193       string(REPLACE "-ffunction-sections" "" ${flags} "${${flags}}")
 194       string(REPLACE "-fdata-sections" "" ${flags} "${${flags}}")
 195     endforeach()
 196   else()
 197     if(MSVC)
 198       # TODO: Clang/C2 is not supported
 199     elseif(((IOS OR ANDROID) AND NOT BUILD_SHARED_LIBS) AND NOT OPENCV_FORCE_FUNCTIONS_SECTIONS)
 200       # don't create separate sections for functions/data, reduce package size
 201     else()
 202       # Remove unreferenced functions: function level linking
 203       add_extra_compiler_option(-ffunction-sections)
 204       add_extra_compiler_option(-fdata-sections)
 205       if(NOT OPENCV_SKIP_GC_SECTIONS)
 206         if(APPLE)
 207           set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS} -Wl,-dead_strip")
 208           set(OPENCV_EXTRA_SHARED_LINKER_FLAGS "${OPENCV_EXTRA_SHARED_LINKER_FLAGS} -Wl,-dead_strip")
 209         else()
 210           set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS} -Wl,--gc-sections")
 211           set(OPENCV_EXTRA_SHARED_LINKER_FLAGS "${OPENCV_EXTRA_SHARED_LINKER_FLAGS} -Wl,--gc-sections")
 212         endif()
 213       endif()
 214     endif()
 215   endif()
 216
 217   if(ENABLE_COVERAGE)
 218     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} --coverage")
 219     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} --coverage")
 220     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} --coverage")
 221   endif()
 222
 223   if(ENABLE_INSTRUMENTATION)
 224     if(NOT HAVE_CXX11)
 225       message(WARNING "ENABLE_INSTRUMENTATION requires C++11 support")
 226     endif()
 227     set(WITH_VTK OFF) # There are issues with VTK 6.0
 228   endif()
 229
 230   if(ENABLE_LTO)
 231     add_extra_compiler_option(-flto)
 232   endif()
 233   if(ENABLE_THIN_LTO)
 234     add_extra_compiler_option(-flto=thin)
 235   endif()
 236
 237   set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} -DNDEBUG")
 238   if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG} " MATCHES "-O")
 239     set(OPENCV_EXTRA_FLAGS_DEBUG "${OPENCV_EXTRA_FLAGS_DEBUG} -O0")
 240   endif()
 241   set(OPENCV_EXTRA_FLAGS_DEBUG "${OPENCV_EXTRA_FLAGS_DEBUG} -DDEBUG -D_DEBUG")
 242
 243   if(BUILD_WITH_DEBUG_INFO)
 244     # https://gcc.gnu.org/onlinedocs/gcc/Debugging-Options.html
 245     # '-g' is equal to '-g2', '-g1' produces minimal information, enough for making backtraces
 246     ocv_update(OPENCV_DEBUG_OPTION "-g1")
 247     if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS_RELEASE}" MATCHES " -g")
 248       set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} ${OPENCV_DEBUG_OPTION}")
 249     endif()
 250   endif()
 251 endif()
 252
 253 if(MSVC)
 254   #TODO Code refactoring is required to resolve security warnings
 255   #if(NOT ENABLE_BUILD_HARDENING)
 256     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /D _CRT_SECURE_NO_DEPRECATE /D _CRT_NONSTDC_NO_DEPRECATE /D _SCL_SECURE_NO_WARNINGS")
 257   #endif()
 258
 259   if(BUILD_WITH_DEBUG_INFO)
 260     set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} /Zi")
 261     set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE} /debug")
 262     set(OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE} /debug")
 263   endif()
 264
 265   # Remove unreferenced functions: function level linking
 266   set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /Gy")
 267   if(NOT MSVC_VERSION LESS 1400)
 268     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /bigobj")
 269   endif()
 270
 271   if(OPENCV_WARNINGS_ARE_ERRORS)
 272     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /WX")
 273   endif()
 274
 275   if(ENABLE_LTO)
 276     set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} /GL")
 277     set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE} /LTCG")
 278   endif()
 279
 280   if(NOT MSVC_VERSION LESS 1800 AND NOT CMAKE_GENERATOR MATCHES "Visual Studio")
 281     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} /FS")
 282     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} /FS")
 283   endif()
 284 endif()
 285
 286 # Adding additional using directory for WindowsPhone 8.0 to get Windows.winmd properly
 287 if(WINRT_PHONE AND WINRT_8_0)
 288   set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} /AI\$(WindowsSDK_MetadataPath)")
 289 endif()
 290
 291 include(cmake/OpenCVCompilerOptimizations.cmake)
 292 if(COMMAND ocv_compiler_optimization_options)
 293   ocv_compiler_optimization_options()
 294 endif()
 295 if(COMMAND ocv_compiler_optimization_options_finalize)
 296   ocv_compiler_optimization_options_finalize()
 297 endif()
 298
 299 # set default visibility to hidden
 300 if((CV_GCC OR CV_CLANG)
 301     AND NOT MSVC
 302     AND NOT OPENCV_SKIP_VISIBILITY_HIDDEN
 303     AND NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " -fvisibility")
 304   add_extra_compiler_option(-fvisibility=hidden)
 305   add_extra_compiler_option(-fvisibility-inlines-hidden)
 306 endif()
 307
 308 # workaround gcc bug for aligned ld/st
 309 # https://github.com/opencv/opencv/issues/13211
 310 if((PPC64LE AND NOT CMAKE_CROSSCOMPILING) OR OPENCV_FORCE_COMPILER_CHECK_VSX_ALIGNED)
 311   ocv_check_runtime_flag("${CPU_BASELINE_FLAGS}" OPENCV_CHECK_VSX_ALIGNED "${OpenCV_SOURCE_DIR}/cmake/checks/runtime/cpu_vsx_aligned.cpp")
 312   if(NOT OPENCV_CHECK_VSX_ALIGNED)
 313     add_extra_compiler_option_force(-DCV_COMPILER_VSX_BROKEN_ALIGNED)
 314   endif()
 315 endif()
 316 # validate inline asm with fixes register number and constraints wa, wd, wf
 317 if(PPC64LE)
 318   ocv_check_compiler_flag(CXX "${CPU_BASELINE_FLAGS}" OPENCV_CHECK_VSX_ASM "${OpenCV_SOURCE_DIR}/cmake/checks/cpu_vsx_asm.cpp")
 319   if(NOT OPENCV_CHECK_VSX_ASM)
 320     add_extra_compiler_option_force(-DCV_COMPILER_VSX_BROKEN_ASM)
 321   endif()
 322 endif()
 323
 324 # combine all "extra" options
 325 if(NOT OPENCV_SKIP_EXTRA_COMPILER_FLAGS)
 326   set(CMAKE_C_FLAGS           "${CMAKE_C_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_C_FLAGS}")
 327   set(CMAKE_CXX_FLAGS         "${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}")
 328   set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_FLAGS_RELEASE}")
 329   set(CMAKE_C_FLAGS_RELEASE   "${CMAKE_C_FLAGS_RELEASE} ${OPENCV_EXTRA_FLAGS_RELEASE}")
 330   set(CMAKE_CXX_FLAGS_DEBUG   "${CMAKE_CXX_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG}")
 331   set(CMAKE_C_FLAGS_DEBUG     "${CMAKE_C_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG}")
 332   set(CMAKE_EXE_LINKER_FLAGS         "${CMAKE_EXE_LINKER_FLAGS} ${OPENCV_EXTRA_EXE_LINKER_FLAGS}")
 333   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE}")
 334   set(CMAKE_EXE_LINKER_FLAGS_DEBUG   "${CMAKE_EXE_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_DEBUG}")
 335   set(CMAKE_SHARED_LINKER_FLAGS         "${CMAKE_SHARED_LINKER_FLAGS} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS}")
 336   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE}")
 337   set(CMAKE_SHARED_LINKER_FLAGS_DEBUG   "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS_DEBUG}")
 338 endif()
 339
 340 if(MSVC)
 341   if(NOT ENABLE_NOISY_WARNINGS)
 342     if(MSVC_VERSION EQUAL 1400)
 343       ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4510 /wd4610 /wd4312 /wd4201 /wd4244 /wd4328 /wd4267)
 344     endif()
 345   endif()
 346
 347   foreach(flags CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 348     string(REPLACE "/Zm1000" "" ${flags} "${${flags}}")
 349   endforeach()
 350
 351   # Enable 'extern "C"' and asynchronous (division by zero, access violation) exceptions
 352   if(NOT OPENCV_SKIP_MSVC_EXCEPTIONS_FLAG)
 353     foreach(flags CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 354       string(REGEX REPLACE " /EH[^ ]* " " " ${flags} " ${${flags}}")
 355     endforeach()
 356     if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${CMAKE_CXX_FLAGS_DEBUG}" MATCHES " /EH")
 357       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /EHa")
 358     endif()
 359   endif()
 360
 361   if(NOT ENABLE_NOISY_WARNINGS)
 362     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4127) # conditional expression is constant
 363     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4251) # class 'std::XXX' needs to have dll-interface to be used by clients of YYY
 364     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4324) # 'struct_name' : structure was padded due to __declspec(align())
 365     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4275) # non dll-interface class 'std::exception' used as base for dll-interface class 'cv::Exception'
 366     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4512) # Assignment operator could not be generated
 367     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4589) # Constructor of abstract class 'cv::ORB' ignores initializer for virtual base class 'cv::Algorithm'
 368   endif()
 369
 370   if(CV_ICC AND NOT ENABLE_NOISY_WARNINGS)
 371     foreach(flags CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_DEBUG)
 372       string(REGEX REPLACE "( |^)/W[0-9]+( |$)" "\\1\\2" ${flags} "${${flags}}")
 373     endforeach()
 374     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /Qwd673") # PCH warning
 375   endif()
 376 endif()
 377
 378 if(APPLE AND NOT CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{LDFLAGS} AND EXISTS "/usr/local/lib")
 379   link_directories("/usr/local/lib")
 380 endif()
 381
 382 if(ENABLE_BUILD_HARDENING)
 383   include(${CMAKE_CURRENT_LIST_DIR}/OpenCVCompilerDefenses.cmake)
 384 endif()
 385
 386 if(MSVC)
 387   include(cmake/OpenCVCRTLinkage.cmake)
 388   add_definitions(-D_VARIADIC_MAX=10)
 389 endif()
 390
 391 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 392 macro(ocv_add_modules_compiler_options)
 393   if(MSVC AND NOT OPENCV_SKIP_MSVC_W4_OPTION)
 394     foreach(flags CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 395       string(REPLACE "/W3" "/W4" ${flags} "${${flags}}")
 396     endforeach()
 397   endif()
 398   if(OPENCV_ENABLE_MEMORY_SANITIZER)
 399     add_definitions(-DOPENCV_ENABLE_MEMORY_SANITIZER=1)
 400   endif()
 401 endmacro()
 402
 403 # adjust -Wl,-rpath-link
 404 if(CMAKE_SKIP_RPATH)
 405   if((NOT CMAKE_CROSSCOMPILING OR OPENCV_ENABLE_LINKER_RPATH_LINK_ORIGIN) AND NOT OPENCV_SKIP_LINKER_RPATH_LINK_ORIGIN)
 406     if(DEFINED CMAKE_SHARED_LIBRARY_RPATH_ORIGIN_TOKEN)
 407       list(APPEND CMAKE_PLATFORM_RUNTIME_PATH "${CMAKE_SHARED_LIBRARY_RPATH_ORIGIN_TOKEN}")
 408     else()
 409       list(APPEND CMAKE_PLATFORM_RUNTIME_PATH "\$ORIGIN")
 410     endif()
 411   elseif(NOT OPENCV_SKIP_LINKER_RPATH_LINK_BINARY_LIB)
 412     list(APPEND CMAKE_PLATFORM_RUNTIME_PATH "${LIBRARY_OUTPUT_PATH}")
 413   endif()
 414 endif()
 415 if(OPENCV_EXTRA_RPATH_LINK_PATH)
 416   string(REPLACE ":" ";" OPENCV_EXTRA_RPATH_LINK_PATH_ "${OPENCV_EXTRA_RPATH_LINK_PATH}")
 417   list(APPEND CMAKE_PLATFORM_RUNTIME_PATH ${OPENCV_EXTRA_RPATH_LINK_PATH_})
 418   if(NOT CMAKE_EXECUTABLE_RPATH_LINK_CXX_FLAG)
 419     message(WARNING "OPENCV_EXTRA_RPATH_LINK_PATH may not work properly because CMAKE_EXECUTABLE_RPATH_LINK_CXX_FLAG is not defined (not supported)")
 420   endif()
 421 endif()