cmake/OpenCVCompilerOptions.cmake

   1 if(MINGW OR (X86 AND UNIX AND NOT APPLE))
   2   # mingw compiler is known to produce unstable SSE code with -O3 hence we are trying to use -O2 instead
   3   if(CMAKE_COMPILER_IS_GNUCXX)
   4     foreach(flags CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
   5       string(REPLACE "-O3" "-O2" ${flags} "${${flags}}")
   6     endforeach()
   7   endif()
   8
   9   if(CMAKE_COMPILER_IS_GNUCC)
  10     foreach(flags CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_DEBUG)
  11       string(REPLACE "-O3" "-O2" ${flags} "${${flags}}")
  12     endforeach()
  13   endif()
  14 endif()
  15
  16 if(MSVC)
  17   string(REGEX REPLACE "^  *| * $" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
  18   string(REGEX REPLACE "^  *| * $" "" CMAKE_CXX_FLAGS_INIT "${CMAKE_CXX_FLAGS_INIT}")
  19   if(CMAKE_CXX_FLAGS STREQUAL CMAKE_CXX_FLAGS_INIT)
  20     # override cmake default exception handling option
  21     string(REPLACE "/EHsc" "/EHa" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
  22     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}"  CACHE STRING "Flags used by the compiler during all build types." FORCE)
  23   endif()
  24 endif()
  25
  26 set(OPENCV_EXTRA_FLAGS "")
  27 set(OPENCV_EXTRA_C_FLAGS "")
  28 set(OPENCV_EXTRA_CXX_FLAGS "")
  29 set(OPENCV_EXTRA_FLAGS_RELEASE "")
  30 set(OPENCV_EXTRA_FLAGS_DEBUG "")
  31 set(OPENCV_EXTRA_EXE_LINKER_FLAGS "")
  32 set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "")
  33 set(OPENCV_EXTRA_EXE_LINKER_FLAGS_DEBUG "")
  34
  35 macro(add_extra_compiler_option option)
  36   if(CMAKE_BUILD_TYPE)
  37     set(CMAKE_TRY_COMPILE_CONFIGURATION ${CMAKE_BUILD_TYPE})
  38   endif()
  39   ocv_check_flag_support(CXX "${option}" _varname "${OPENCV_EXTRA_CXX_FLAGS} ${ARGN}")
  40   if(${_varname})
  41     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} ${option}")
  42   endif()
  43
  44   ocv_check_flag_support(C "${option}" _varname "${OPENCV_EXTRA_C_FLAGS} ${ARGN}")
  45   if(${_varname})
  46     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} ${option}")
  47   endif()
  48 endmacro()
  49
  50 # OpenCV fails some tests when 'char' is 'unsigned' by default
  51 add_extra_compiler_option(-fsigned-char)
  52
  53 if(MINGW)
  54   # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=40838
  55   # here we are trying to workaround the problem
  56   add_extra_compiler_option(-mstackrealign)
  57   if(NOT HAVE_CXX_MSTACKREALIGN)
  58     add_extra_compiler_option(-mpreferred-stack-boundary=2)
  59   endif()
  60 endif()
  61
  62 if(CMAKE_COMPILER_IS_GNUCXX)
  63   # High level of warnings.
  64   add_extra_compiler_option(-W)
  65   add_extra_compiler_option(-Wall)
  66   add_extra_compiler_option(-Werror=return-type)
  67   add_extra_compiler_option(-Werror=non-virtual-dtor)
  68   add_extra_compiler_option(-Werror=address)
  69   add_extra_compiler_option(-Werror=sequence-point)
  70   add_extra_compiler_option(-Wformat)
  71   add_extra_compiler_option(-Werror=format-security -Wformat)
  72   add_extra_compiler_option(-Wmissing-declarations)
  73   add_extra_compiler_option(-Wmissing-prototypes)
  74   add_extra_compiler_option(-Wstrict-prototypes)
  75   add_extra_compiler_option(-Wundef)
  76   add_extra_compiler_option(-Winit-self)
  77   add_extra_compiler_option(-Wpointer-arith)
  78   add_extra_compiler_option(-Wshadow)
  79   add_extra_compiler_option(-Wsign-promo)
  80
  81   if(ENABLE_NOISY_WARNINGS)
  82     add_extra_compiler_option(-Wcast-align)
  83     add_extra_compiler_option(-Wstrict-aliasing=2)
  84   else()
  85     add_extra_compiler_option(-Wno-narrowing)
  86     add_extra_compiler_option(-Wno-delete-non-virtual-dtor)
  87     add_extra_compiler_option(-Wno-unnamed-type-template-args)
  88   endif()
  89   add_extra_compiler_option(-fdiagnostics-show-option)
  90
  91   # The -Wno-long-long is required in 64bit systems when including sytem headers.
  92   if(X86_64)
  93     add_extra_compiler_option(-Wno-long-long)
  94   endif()
  95
  96   # We need pthread's
  97   if(UNIX AND NOT ANDROID AND NOT (APPLE AND CMAKE_COMPILER_IS_CLANGCXX))
  98     add_extra_compiler_option(-pthread)
  99   endif()
 100
 101   if(OPENCV_WARNINGS_ARE_ERRORS)
 102     add_extra_compiler_option(-Werror)
 103   endif()
 104
 105   if(X86 AND NOT MINGW64 AND NOT X86_64 AND NOT APPLE)
 106     add_extra_compiler_option(-march=i686)
 107   endif()
 108
 109   # Other optimizations
 110   if(ENABLE_OMIT_FRAME_POINTER)
 111     add_extra_compiler_option(-fomit-frame-pointer)
 112   else()
 113     add_extra_compiler_option(-fno-omit-frame-pointer)
 114   endif()
 115   if(ENABLE_FAST_MATH)
 116     add_extra_compiler_option(-ffast-math)
 117   endif()
 118   if(ENABLE_POWERPC)
 119     add_extra_compiler_option("-mcpu=G3 -mtune=G5")
 120   endif()
 121   if(ENABLE_SSE)
 122     add_extra_compiler_option(-msse)
 123   endif()
 124   if(ENABLE_SSE2)
 125     add_extra_compiler_option(-msse2)
 126   endif()
 127   if (ENABLE_NEON)
 128     add_extra_compiler_option("-mfpu=neon")
 129   endif()
 130   if (ENABLE_VFPV3 AND NOT ENABLE_NEON)
 131     add_extra_compiler_option("-mfpu=vfpv3")
 132   endif()
 133
 134   # SSE3 and further should be disabled under MingW because it generates compiler errors
 135   if(NOT MINGW)
 136     if(ENABLE_AVX)
 137       add_extra_compiler_option(-mavx)
 138     endif()
 139
 140     # GCC depresses SSEx instructions when -mavx is used. Instead, it generates new AVX instructions or AVX equivalence for all SSEx instructions when needed.
 141     if(NOT OPENCV_EXTRA_CXX_FLAGS MATCHES "-mavx")
 142       if(ENABLE_SSE3)
 143         add_extra_compiler_option(-msse3)
 144       endif()
 145
 146       if(ENABLE_SSSE3)
 147         add_extra_compiler_option(-mssse3)
 148       endif()
 149
 150       if(ENABLE_SSE41)
 151         add_extra_compiler_option(-msse4.1)
 152       endif()
 153
 154       if(ENABLE_SSE42)
 155         add_extra_compiler_option(-msse4.2)
 156       endif()
 157     endif()
 158   endif(NOT MINGW)
 159
 160   if(X86 OR X86_64)
 161     if(NOT APPLE AND CMAKE_SIZEOF_VOID_P EQUAL 4)
 162       if(OPENCV_EXTRA_CXX_FLAGS MATCHES "-m(sse2|avx)")
 163         add_extra_compiler_option(-mfpmath=sse)# !! important - be on the same wave with x64 compilers
 164       else()
 165         add_extra_compiler_option(-mfpmath=387)
 166       endif()
 167     endif()
 168   endif()
 169
 170   if(ENABLE_NEON)
 171     add_extra_compiler_option(-mfpu=neon)
 172   endif()
 173
 174   # Profiling?
 175   if(ENABLE_PROFILING)
 176     add_extra_compiler_option("-pg -g")
 177     # turn off incompatible options
 178     foreach(flags CMAKE_CXX_FLAGS CMAKE_C_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG CMAKE_C_FLAGS_DEBUG
 179                   OPENCV_EXTRA_FLAGS_RELEASE OPENCV_EXTRA_FLAGS_DEBUG OPENCV_EXTRA_C_FLAGS OPENCV_EXTRA_CXX_FLAGS)
 180       string(REPLACE "-fomit-frame-pointer" "" ${flags} "${${flags}}")
 181       string(REPLACE "-ffunction-sections" "" ${flags} "${${flags}}")
 182     endforeach()
 183   elseif(NOT APPLE AND NOT ANDROID)
 184     # Remove unreferenced functions: function level linking
 185     add_extra_compiler_option(-ffunction-sections)
 186   endif()
 187
 188   set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} -DNDEBUG")
 189   set(OPENCV_EXTRA_FLAGS_DEBUG "${OPENCV_EXTRA_FLAGS_DEBUG} -O0 -DDEBUG -D_DEBUG")
 190 endif()
 191
 192 if(MSVC)
 193   set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /D _CRT_SECURE_NO_DEPRECATE /D _CRT_NONSTDC_NO_DEPRECATE /D _SCL_SECURE_NO_WARNINGS")
 194   # 64-bit portability warnings, in MSVC80
 195   if(MSVC80)
 196     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /Wp64")
 197   endif()
 198
 199   if(BUILD_WITH_DEBUG_INFO)
 200     set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE} /debug")
 201   endif()
 202
 203   # Remove unreferenced functions: function level linking
 204   set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /Gy")
 205   if(NOT MSVC_VERSION LESS 1400)
 206     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /bigobj")
 207   endif()
 208   if(BUILD_WITH_DEBUG_INFO)
 209     set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} /Zi")
 210   endif()
 211
 212   if(ENABLE_AVX AND NOT MSVC_VERSION LESS 1600)
 213     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /arch:AVX")
 214   endif()
 215
 216   if(ENABLE_SSE4_1 AND CV_ICC AND NOT OPENCV_EXTRA_FLAGS MATCHES "/arch:")
 217     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /arch:SSE4.1")
 218   endif()
 219
 220   if(ENABLE_SSE3 AND CV_ICC AND NOT OPENCV_EXTRA_FLAGS MATCHES "/arch:")
 221     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /arch:SSE3")
 222   endif()
 223
 224   if(NOT MSVC64)
 225     # 64-bit MSVC compiler uses SSE/SSE2 by default
 226     if(ENABLE_SSE2 AND NOT OPENCV_EXTRA_FLAGS MATCHES "/arch:")
 227       set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /arch:SSE2")
 228     endif()
 229     if(ENABLE_SSE AND NOT OPENCV_EXTRA_FLAGS MATCHES "/arch:")
 230       set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /arch:SSE")
 231     endif()
 232   endif()
 233
 234   if(ENABLE_SSE OR ENABLE_SSE2 OR ENABLE_SSE3 OR ENABLE_SSE4_1 OR ENABLE_AVX)
 235     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /Oi")
 236   endif()
 237
 238   if(X86 OR X86_64)
 239     if(CMAKE_SIZEOF_VOID_P EQUAL 4 AND ENABLE_SSE2)
 240       set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /fp:fast") # !! important - be on the same wave with x64 compilers
 241     endif()
 242   endif()
 243
 244   if(OPENCV_WARNINGS_ARE_ERRORS)
 245     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /WX")
 246   endif()
 247 endif()
 248
 249 # Extra link libs if the user selects building static libs:
 250 if(NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX AND NOT ANDROID)
 251   # Android does not need these settings because they are already set by toolchain file
 252   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} stdc++)
 253   set(OPENCV_EXTRA_FLAGS "-fPIC ${OPENCV_EXTRA_FLAGS}")
 254 endif()
 255
 256 # Add user supplied extra options (optimization, etc...)
 257 # ==========================================================
 258 set(OPENCV_EXTRA_FLAGS         "${OPENCV_EXTRA_FLAGS}"         CACHE INTERNAL "Extra compiler options")
 259 set(OPENCV_EXTRA_C_FLAGS       "${OPENCV_EXTRA_C_FLAGS}"       CACHE INTERNAL "Extra compiler options for C sources")
 260 set(OPENCV_EXTRA_CXX_FLAGS     "${OPENCV_EXTRA_CXX_FLAGS}"     CACHE INTERNAL "Extra compiler options for C++ sources")
 261 set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE}" CACHE INTERNAL "Extra compiler options for Release build")
 262 set(OPENCV_EXTRA_FLAGS_DEBUG   "${OPENCV_EXTRA_FLAGS_DEBUG}"   CACHE INTERNAL "Extra compiler options for Debug build")
 263 set(OPENCV_EXTRA_EXE_LINKER_FLAGS         "${OPENCV_EXTRA_EXE_LINKER_FLAGS}"         CACHE INTERNAL "Extra linker flags")
 264 set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE}" CACHE INTERNAL "Extra linker flags for Release build")
 265 set(OPENCV_EXTRA_EXE_LINKER_FLAGS_DEBUG   "${OPENCV_EXTRA_EXE_LINKER_FLAGS_DEBUG}"   CACHE INTERNAL "Extra linker flags for Debug build")
 266
 267 # set default visibility to hidden
 268 if(CMAKE_COMPILER_IS_GNUCXX AND CMAKE_OPENCV_GCC_VERSION_NUM GREATER 399)
 269   add_extra_compiler_option(-fvisibility=hidden)
 270   add_extra_compiler_option(-fvisibility-inlines-hidden)
 271 endif()
 272
 273 #combine all "extra" options
 274 set(CMAKE_C_FLAGS           "${CMAKE_C_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_C_FLAGS}")
 275 set(CMAKE_CXX_FLAGS         "${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}")
 276 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_FLAGS_RELEASE}")
 277 set(CMAKE_C_FLAGS_RELEASE   "${CMAKE_C_FLAGS_RELEASE} ${OPENCV_EXTRA_FLAGS_RELEASE}")
 278 set(CMAKE_CXX_FLAGS_DEBUG   "${CMAKE_CXX_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG}")
 279 set(CMAKE_C_FLAGS_DEBUG     "${CMAKE_C_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG}")
 280 set(CMAKE_EXE_LINKER_FLAGS         "${CMAKE_EXE_LINKER_FLAGS} ${OPENCV_EXTRA_EXE_LINKER_FLAGS}")
 281 set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE}")
 282 set(CMAKE_EXE_LINKER_FLAGS_DEBUG   "${CMAKE_EXE_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_DEBUG}")
 283
 284 if(MSVC)
 285   # avoid warnings from MSVC about overriding the /W* option
 286   # we replace /W3 with /W4 only for C++ files,
 287   # since all the 3rd-party libraries OpenCV uses are in C,
 288   # and we do not care about their warnings.
 289   string(REPLACE "/W3" "/W4" CMAKE_CXX_FLAGS         "${CMAKE_CXX_FLAGS}")
 290   string(REPLACE "/W3" "/W4" CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE}")
 291   string(REPLACE "/W3" "/W4" CMAKE_CXX_FLAGS_DEBUG   "${CMAKE_CXX_FLAGS_DEBUG}")
 292
 293   if(NOT ENABLE_NOISY_WARNINGS AND MSVC_VERSION EQUAL 1400)
 294     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4510 /wd4610 /wd4312 /wd4201 /wd4244 /wd4328 /wd4267)
 295   endif()
 296
 297   # allow extern "C" functions throw exceptions
 298   foreach(flags CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 299     string(REPLACE "/EHsc-" "/EHs" ${flags} "${${flags}}")
 300     string(REPLACE "/EHsc"  "/EHs" ${flags} "${${flags}}")
 301
 302     string(REPLACE "/Zm1000" "" ${flags} "${${flags}}")
 303   endforeach()
 304
 305   if(NOT ENABLE_NOISY_WARNINGS)
 306     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4251") #class 'std::XXX' needs to have dll-interface to be used by clients of YYY
 307   endif()
 308 endif()