cmake/OpenCVCompilerOptions.cmake

   1 if("${CMAKE_CXX_COMPILER};${CMAKE_C_COMPILER};${CMAKE_CXX_COMPILER_LAUNCHER}" MATCHES "ccache")
   2   set(CMAKE_COMPILER_IS_CCACHE 1)  # TODO: FIXIT Avoid setting of CMAKE_ variables
   3   set(OPENCV_COMPILER_IS_CCACHE 1)
   4 endif()
   5 function(access_CMAKE_COMPILER_IS_CCACHE)
   6   if(NOT OPENCV_SUPPRESS_DEPRECATIONS)
   7     message(WARNING "DEPRECATED: CMAKE_COMPILER_IS_CCACHE is replaced to OPENCV_COMPILER_IS_CCACHE.")
   8   endif()
   9 endfunction()
  10 variable_watch(CMAKE_COMPILER_IS_CCACHE access_CMAKE_COMPILER_IS_CCACHE)
  11 if(ENABLE_CCACHE AND NOT OPENCV_COMPILER_IS_CCACHE AND NOT CMAKE_GENERATOR MATCHES "Xcode")
  12   # This works fine with Unix Makefiles and Ninja generators
  13   find_host_program(CCACHE_PROGRAM ccache)
  14   if(CCACHE_PROGRAM)
  15     message(STATUS "Looking for ccache - found (${CCACHE_PROGRAM})")
  16     get_property(__OLD_RULE_LAUNCH_COMPILE GLOBAL PROPERTY RULE_LAUNCH_COMPILE)
  17     if(__OLD_RULE_LAUNCH_COMPILE)
  18       message(STATUS "Can't replace CMake compiler launcher")
  19     else()
  20       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
  21       # NOTE: Actually this check doesn't work as expected.
  22       # "RULE_LAUNCH_COMPILE" is ignored by CMake during try_compile() step.
  23       # ocv_check_compiler_flag(CXX "" IS_CCACHE_WORKS)
  24       set(IS_CCACHE_WORKS 1)
  25       if(IS_CCACHE_WORKS)
  26         set(OPENCV_COMPILER_IS_CCACHE 1)
  27       else()
  28         message(STATUS "Unable to compile program with enabled ccache, reverting...")
  29         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${__OLD_RULE_LAUNCH_COMPILE}")
  30       endif()
  31     endif()
  32   else()
  33     message(STATUS "Looking for ccache - not found")
  34   endif()
  35 endif()
  36
  37 if((CV_CLANG AND NOT CMAKE_GENERATOR MATCHES "Xcode")  # PCH has no support for Clang
  38     OR OPENCV_COMPILER_IS_CCACHE
  39 )
  40   set(ENABLE_PRECOMPILED_HEADERS OFF CACHE BOOL "" FORCE)
  41 endif()
  42
  43 macro(add_extra_compiler_option option)
  44   ocv_check_flag_support(CXX "${option}" _varname "${OPENCV_EXTRA_CXX_FLAGS} ${ARGN}")
  45   if(${_varname})
  46     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} ${option}")
  47   endif()
  48
  49   ocv_check_flag_support(C "${option}" _varname "${OPENCV_EXTRA_C_FLAGS} ${ARGN}")
  50   if(${_varname})
  51     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} ${option}")
  52   endif()
  53 endmacro()
  54
  55 macro(add_extra_compiler_option_force option)
  56   set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} ${option}")
  57   set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} ${option}")
  58 endmacro()
  59
  60
  61 # Gets environment variable and puts its value to the corresponding preprocessor definition
  62 # Useful for WINRT that has no access to environment variables
  63 macro(add_env_definitions option)
  64   set(value $ENV{${option}})
  65   if("${value}" STREQUAL "")
  66     message(WARNING "${option} environment variable is empty. Please set it to appropriate location to get correct results")
  67   else()
  68     string(REPLACE "\\" "\\\\" value ${value})
  69   endif()
  70   add_definitions("-D${option}=\"${value}\"")
  71 endmacro()
  72
  73 if(NOT MSVC)
  74   # OpenCV fails some tests when 'char' is 'unsigned' by default
  75   add_extra_compiler_option(-fsigned-char)
  76 endif()
  77
  78 if(CV_ICC AND NOT ENABLE_FAST_MATH)
  79   if(MSVC)
  80     add_extra_compiler_option("/fp:precise")
  81   else()
  82     add_extra_compiler_option("-fp-model precise")
  83   endif()
  84 endif()
  85
  86 if(CV_GCC OR CV_CLANG)
  87   # High level of warnings.
  88   add_extra_compiler_option(-W)
  89   add_extra_compiler_option(-Wall)
  90   add_extra_compiler_option(-Werror=return-type)
  91   add_extra_compiler_option(-Werror=non-virtual-dtor)
  92   add_extra_compiler_option(-Werror=address)
  93   add_extra_compiler_option(-Werror=sequence-point)
  94   add_extra_compiler_option(-Wformat)
  95   add_extra_compiler_option(-Werror=format-security -Wformat)
  96   add_extra_compiler_option(-Wmissing-declarations)
  97   add_extra_compiler_option(-Wmissing-prototypes)
  98   add_extra_compiler_option(-Wstrict-prototypes)
  99   add_extra_compiler_option(-Wundef)
 100   add_extra_compiler_option(-Winit-self)
 101   add_extra_compiler_option(-Wpointer-arith)
 102   add_extra_compiler_option(-Wshadow)
 103   add_extra_compiler_option(-Wsign-promo)
 104   add_extra_compiler_option(-Wuninitialized)
 105   add_extra_compiler_option(-Winit-self)
 106   if(HAVE_CXX11)
 107     if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND NOT ENABLE_PRECOMPILED_HEADERS)
 108       add_extra_compiler_option(-Wsuggest-override)
 109     elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 110       add_extra_compiler_option(-Winconsistent-missing-override)
 111     endif()
 112   endif()
 113
 114   if(ENABLE_NOISY_WARNINGS)
 115     add_extra_compiler_option(-Wcast-align)
 116     add_extra_compiler_option(-Wstrict-aliasing=2)
 117   else()
 118     add_extra_compiler_option(-Wno-narrowing)
 119     add_extra_compiler_option(-Wno-delete-non-virtual-dtor)
 120     add_extra_compiler_option(-Wno-unnamed-type-template-args)
 121     add_extra_compiler_option(-Wno-comment)
 122     if(NOT OPENCV_SKIP_IMPLICIT_FALLTHROUGH
 123         AND NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES "implicit-fallthrough"
 124         AND (CV_GCC AND NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS 7.0.0)
 125     )
 126       add_extra_compiler_option(-Wimplicit-fallthrough=3)
 127     endif()
 128     if(CV_GCC AND CMAKE_CXX_COMPILER_VERSION VERSION_EQUAL 7.2.0)
 129       add_extra_compiler_option(-Wno-strict-overflow) # Issue is fixed in GCC 7.2.1
 130     endif()
 131   endif()
 132   add_extra_compiler_option(-fdiagnostics-show-option)
 133
 134   # The -Wno-long-long is required in 64bit systems when including system headers.
 135   if(X86_64)
 136     add_extra_compiler_option(-Wno-long-long)
 137   endif()
 138
 139   # We need pthread's
 140   if(UNIX AND NOT ANDROID AND NOT (APPLE AND CV_CLANG)) # TODO
 141     add_extra_compiler_option(-pthread)
 142   endif()
 143
 144   if(CV_CLANG)
 145     add_extra_compiler_option(-Qunused-arguments)
 146   endif()
 147
 148   if(OPENCV_WARNINGS_ARE_ERRORS)
 149     add_extra_compiler_option(-Werror)
 150   endif()
 151
 152   if(APPLE)
 153     add_extra_compiler_option(-Wno-semicolon-before-method-body)
 154   endif()
 155
 156   # Other optimizations
 157   if(ENABLE_OMIT_FRAME_POINTER)
 158     add_extra_compiler_option(-fomit-frame-pointer)
 159   elseif(DEFINED ENABLE_OMIT_FRAME_POINTER)
 160     add_extra_compiler_option(-fno-omit-frame-pointer)
 161   endif()
 162   if(ENABLE_FAST_MATH)
 163     add_extra_compiler_option(-ffast-math)
 164   endif()
 165
 166   # Profiling?
 167   if(ENABLE_PROFILING)
 168     add_extra_compiler_option("-pg -g")
 169     # turn off incompatible options
 170     foreach(flags CMAKE_CXX_FLAGS CMAKE_C_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG CMAKE_C_FLAGS_DEBUG
 171                   OPENCV_EXTRA_FLAGS_RELEASE OPENCV_EXTRA_FLAGS_DEBUG OPENCV_EXTRA_C_FLAGS OPENCV_EXTRA_CXX_FLAGS)
 172       string(REPLACE "-fomit-frame-pointer" "" ${flags} "${${flags}}")
 173       string(REPLACE "-ffunction-sections" "" ${flags} "${${flags}}")
 174       string(REPLACE "-fdata-sections" "" ${flags} "${${flags}}")
 175     endforeach()
 176   elseif(NOT ((IOS OR ANDROID) AND NOT BUILD_SHARED_LIBS))
 177     # Remove unreferenced functions: function level linking
 178     add_extra_compiler_option(-ffunction-sections)
 179     add_extra_compiler_option(-fdata-sections)
 180     if(NOT APPLE AND NOT OPENCV_SKIP_GC_SECTIONS)
 181       set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS} -Wl,--gc-sections")
 182     endif()
 183   endif()
 184
 185   if(ENABLE_COVERAGE)
 186     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} --coverage")
 187     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} --coverage")
 188     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} --coverage")
 189   endif()
 190
 191   if(ENABLE_INSTRUMENTATION)
 192     if(NOT HAVE_CXX11)
 193       message(WARNING "ENABLE_INSTRUMENTATION requires C++11 support")
 194     endif()
 195     set(WITH_VTK OFF) # There are issues with VTK 6.0
 196   endif()
 197
 198   if(ENABLE_LTO)
 199     add_extra_compiler_option(-flto)
 200   endif()
 201   if(ENABLE_THIN_LTO)
 202     add_extra_compiler_option(-flto=thin)
 203   endif()
 204
 205   set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} -DNDEBUG")
 206   if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG} " MATCHES "-O")
 207     set(OPENCV_EXTRA_FLAGS_DEBUG "${OPENCV_EXTRA_FLAGS_DEBUG} -O0")
 208   endif()
 209   set(OPENCV_EXTRA_FLAGS_DEBUG "${OPENCV_EXTRA_FLAGS_DEBUG} -DDEBUG -D_DEBUG")
 210
 211   if(BUILD_WITH_DEBUG_INFO)
 212     # https://gcc.gnu.org/onlinedocs/gcc/Debugging-Options.html
 213     # '-g' is equal to '-g2', '-g1' produces minimal information, enough for making backtraces
 214     ocv_update(OPENCV_DEBUG_OPTION "-g1")
 215     if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS_RELEASE}" MATCHES " -g")
 216       set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} ${OPENCV_DEBUG_OPTION}")
 217     endif()
 218   endif()
 219 endif()
 220
 221 if(MSVC)
 222   #TODO Code refactoring is required to resolve security warnings
 223   #if(NOT ENABLE_BUILD_HARDENING)
 224     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /D _CRT_SECURE_NO_DEPRECATE /D _CRT_NONSTDC_NO_DEPRECATE /D _SCL_SECURE_NO_WARNINGS")
 225   #endif()
 226
 227   if(BUILD_WITH_DEBUG_INFO)
 228     set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} /Zi")
 229     set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE} /debug")
 230     set(OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE} /debug")
 231   endif()
 232
 233   # Remove unreferenced functions: function level linking
 234   set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /Gy")
 235   if(NOT MSVC_VERSION LESS 1400)
 236     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /bigobj")
 237   endif()
 238
 239   if(OPENCV_WARNINGS_ARE_ERRORS)
 240     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /WX")
 241   endif()
 242
 243   if(ENABLE_LTO)
 244     set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} /GL")
 245     set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE} /LTCG")
 246   endif()
 247
 248   if(NOT MSVC_VERSION LESS 1800 AND NOT CMAKE_GENERATOR MATCHES "Visual Studio")
 249     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} /FS")
 250     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} /FS")
 251   endif()
 252 endif()
 253
 254 # Adding additional using directory for WindowsPhone 8.0 to get Windows.winmd properly
 255 if(WINRT_PHONE AND WINRT_8_0)
 256   set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} /AI\$(WindowsSDK_MetadataPath)")
 257 endif()
 258
 259 include(cmake/OpenCVCompilerOptimizations.cmake)
 260 if(COMMAND ocv_compiler_optimization_options)
 261   ocv_compiler_optimization_options()
 262 endif()
 263 if(COMMAND ocv_compiler_optimization_options_finalize)
 264   ocv_compiler_optimization_options_finalize()
 265 endif()
 266
 267 # set default visibility to hidden
 268 if((CV_GCC OR CV_CLANG)
 269     AND NOT OPENCV_SKIP_VISIBILITY_HIDDEN
 270     AND NOT " ${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}" MATCHES " -fvisibility")
 271   add_extra_compiler_option(-fvisibility=hidden)
 272   add_extra_compiler_option(-fvisibility-inlines-hidden)
 273 endif()
 274
 275 # combine all "extra" options
 276 if(NOT OPENCV_SKIP_EXTRA_COMPILER_FLAGS)
 277   set(CMAKE_C_FLAGS           "${CMAKE_C_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_C_FLAGS}")
 278   set(CMAKE_CXX_FLAGS         "${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}")
 279   set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_FLAGS_RELEASE}")
 280   set(CMAKE_C_FLAGS_RELEASE   "${CMAKE_C_FLAGS_RELEASE} ${OPENCV_EXTRA_FLAGS_RELEASE}")
 281   set(CMAKE_CXX_FLAGS_DEBUG   "${CMAKE_CXX_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG}")
 282   set(CMAKE_C_FLAGS_DEBUG     "${CMAKE_C_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG}")
 283   set(CMAKE_EXE_LINKER_FLAGS         "${CMAKE_EXE_LINKER_FLAGS} ${OPENCV_EXTRA_EXE_LINKER_FLAGS}")
 284   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE}")
 285   set(CMAKE_EXE_LINKER_FLAGS_DEBUG   "${CMAKE_EXE_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_DEBUG}")
 286   set(CMAKE_SHARED_LINKER_FLAGS         "${CMAKE_SHARED_LINKER_FLAGS} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS}")
 287   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS_RELEASE}")
 288   set(CMAKE_SHARED_LINKER_FLAGS_DEBUG   "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_SHARED_LINKER_FLAGS_DEBUG}")
 289 endif()
 290
 291 if(MSVC)
 292   if(NOT ENABLE_NOISY_WARNINGS)
 293     if(MSVC_VERSION EQUAL 1400)
 294       ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4510 /wd4610 /wd4312 /wd4201 /wd4244 /wd4328 /wd4267)
 295     endif()
 296   endif()
 297
 298   foreach(flags CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 299     string(REPLACE "/Zm1000" "" ${flags} "${${flags}}")
 300   endforeach()
 301
 302   # Enable 'extern "C"' and asynchronous (division by zero, access violation) exceptions
 303   if(NOT OPENCV_SKIP_MSVC_EXCEPTIONS_FLAG)
 304     foreach(flags CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 305       string(REGEX REPLACE " /EH[^ ]* " " " ${flags} " ${${flags}}")
 306     endforeach()
 307     if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${CMAKE_CXX_FLAGS_DEBUG}" MATCHES " /EH")
 308       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /EHa")
 309     endif()
 310   endif()
 311
 312   if(NOT ENABLE_NOISY_WARNINGS)
 313     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4127) # conditional expression is constant
 314     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4251) # class 'std::XXX' needs to have dll-interface to be used by clients of YYY
 315     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4324) # 'struct_name' : structure was padded due to __declspec(align())
 316     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4275) # non dll-interface class 'std::exception' used as base for dll-interface class 'cv::Exception'
 317     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4512) # Assignment operator could not be generated
 318     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4589) # Constructor of abstract class 'cv::ORB' ignores initializer for virtual base class 'cv::Algorithm'
 319   endif()
 320
 321   if(CV_ICC AND NOT ENABLE_NOISY_WARNINGS)
 322     foreach(flags CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_DEBUG)
 323       string(REGEX REPLACE "( |^)/W[0-9]+( |$)" "\\1\\2" ${flags} "${${flags}}")
 324     endforeach()
 325     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /Qwd673") # PCH warning
 326   endif()
 327 endif()
 328
 329 if(APPLE AND NOT CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{LDFLAGS} AND EXISTS "/usr/local/lib")
 330   link_directories("/usr/local/lib")
 331 endif()
 332
 333 if(ENABLE_BUILD_HARDENING)
 334   include(${CMAKE_CURRENT_LIST_DIR}/OpenCVCompilerDefenses.cmake)
 335 endif()
 336
 337 if(MSVC)
 338   include(cmake/OpenCVCRTLinkage.cmake)
 339   add_definitions(-D_VARIADIC_MAX=10)
 340 endif()
 341
 342 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 343 macro(ocv_add_modules_compiler_options)
 344   if(MSVC AND NOT OPENCV_SKIP_MSVC_W4_OPTION)
 345     foreach(flags CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 346       string(REPLACE "/W3" "/W4" ${flags} "${${flags}}")
 347     endforeach()
 348   endif()
 349 endmacro()