cmake/OpenCVCompilerOptions.cmake

   1 if(MINGW)
   2   # mingw compiler is known to produce unstable SSE code with -O3 hence we are trying to use -O2 instead
   3   if(CMAKE_COMPILER_IS_GNUCXX)
   4     foreach(flags CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
   5       string(REPLACE "-O3" "-O2" ${flags} "${${flags}}")
   6     endforeach()
   7   endif()
   8
   9   if(CMAKE_COMPILER_IS_GNUCC)
  10     foreach(flags CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_DEBUG)
  11       string(REPLACE "-O3" "-O2" ${flags} "${${flags}}")
  12     endforeach()
  13   endif()
  14 endif()
  15
  16 if(MSVC)
  17   string(REGEX REPLACE "^  *| * $" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
  18   string(REGEX REPLACE "^  *| * $" "" CMAKE_CXX_FLAGS_INIT "${CMAKE_CXX_FLAGS_INIT}")
  19   if(CMAKE_CXX_FLAGS STREQUAL CMAKE_CXX_FLAGS_INIT)
  20     # override cmake default exception handling option
  21     string(REPLACE "/EHsc" "/EHa" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
  22     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}"  CACHE STRING "Flags used by the compiler during all build types." FORCE)
  23   endif()
  24 endif()
  25
  26 set(OPENCV_EXTRA_FLAGS "")
  27 set(OPENCV_EXTRA_C_FLAGS "")
  28 set(OPENCV_EXTRA_CXX_FLAGS "")
  29 set(OPENCV_EXTRA_FLAGS_RELEASE "")
  30 set(OPENCV_EXTRA_FLAGS_DEBUG "")
  31 set(OPENCV_EXTRA_EXE_LINKER_FLAGS "")
  32 set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "")
  33 set(OPENCV_EXTRA_EXE_LINKER_FLAGS_DEBUG "")
  34
  35 macro(add_extra_compiler_option option)
  36   if(CMAKE_BUILD_TYPE)
  37     set(CMAKE_TRY_COMPILE_CONFIGURATION ${CMAKE_BUILD_TYPE})
  38   endif()
  39   ocv_check_flag_support(CXX "${option}" _varname "${OPENCV_EXTRA_CXX_FLAGS} ${ARGN}")
  40   if(${_varname})
  41     set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS} ${option}")
  42   endif()
  43
  44   ocv_check_flag_support(C "${option}" _varname "${OPENCV_EXTRA_C_FLAGS} ${ARGN}")
  45   if(${_varname})
  46     set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} ${option}")
  47   endif()
  48 endmacro()
  49
  50 if(MINGW)
  51   # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=40838
  52   # here we are trying to workaround the problem
  53   add_extra_compiler_option(-mstackrealign)
  54   if(NOT HAVE_CXX_MSTACKREALIGN)
  55     add_extra_compiler_option(-mpreferred-stack-boundary=2)
  56   endif()
  57 endif()
  58
  59 if(CMAKE_COMPILER_IS_GNUCXX)
  60   # High level of warnings.
  61   add_extra_compiler_option(-W)
  62   add_extra_compiler_option(-Wall)
  63   add_extra_compiler_option(-Werror=return-type)
  64   add_extra_compiler_option(-Werror=non-virtual-dtor)
  65   add_extra_compiler_option(-Werror=address)
  66   add_extra_compiler_option(-Werror=sequence-point)
  67   add_extra_compiler_option(-Wformat)
  68   add_extra_compiler_option(-Werror=format-security -Wformat)
  69   add_extra_compiler_option(-Wmissing-declarations)
  70   add_extra_compiler_option(-Wmissing-prototypes)
  71   add_extra_compiler_option(-Wstrict-prototypes)
  72   add_extra_compiler_option(-Wundef)
  73   add_extra_compiler_option(-Winit-self)
  74   add_extra_compiler_option(-Wpointer-arith)
  75   add_extra_compiler_option(-Wshadow)
  76   add_extra_compiler_option(-Wsign-promo)
  77
  78   if(ENABLE_NOISY_WARNINGS)
  79     add_extra_compiler_option(-Wcast-align)
  80     add_extra_compiler_option(-Wstrict-aliasing=2)
  81   else()
  82     add_extra_compiler_option(-Wno-narrowing)
  83     add_extra_compiler_option(-Wno-delete-non-virtual-dtor)
  84     add_extra_compiler_option(-Wno-unnamed-type-template-args)
  85   endif()
  86   add_extra_compiler_option(-fdiagnostics-show-option)
  87
  88   # The -Wno-long-long is required in 64bit systems when including sytem headers.
  89   if(X86_64)
  90     add_extra_compiler_option(-Wno-long-long)
  91   endif()
  92
  93   # We need pthread's
  94   if(UNIX AND NOT ANDROID)
  95     add_extra_compiler_option(-pthread)
  96   endif()
  97
  98   if(OPENCV_WARNINGS_ARE_ERRORS)
  99     add_extra_compiler_option(-Werror)
 100   endif()
 101
 102   if(X86 AND NOT MINGW64 AND NOT X86_64 AND NOT APPLE)
 103     add_extra_compiler_option(-march=i686)
 104   endif()
 105
 106   # Other optimizations
 107   if(ENABLE_OMIT_FRAME_POINTER)
 108     add_extra_compiler_option(-fomit-frame-pointer)
 109   else()
 110     add_extra_compiler_option(-fno-omit-frame-pointer)
 111   endif()
 112   if(ENABLE_FAST_MATH)
 113     add_extra_compiler_option(-ffast-math)
 114   endif()
 115   if(ENABLE_POWERPC)
 116     add_extra_compiler_option("-mcpu=G3 -mtune=G5")
 117   endif()
 118   if(ENABLE_SSE)
 119     add_extra_compiler_option(-msse)
 120   endif()
 121   if(ENABLE_SSE2)
 122     add_extra_compiler_option(-msse2)
 123   endif()
 124
 125   # SSE3 and further should be disabled under MingW because it generates compiler errors
 126   if(NOT MINGW)
 127     if(ENABLE_SSE3)
 128       add_extra_compiler_option(-msse3)
 129     endif()
 130
 131     if(${CMAKE_OPENCV_GCC_VERSION_NUM} GREATER 402)
 132       set(HAVE_GCC43_OR_NEWER 1)
 133     endif()
 134     if(${CMAKE_OPENCV_GCC_VERSION_NUM} GREATER 401)
 135       set(HAVE_GCC42_OR_NEWER 1)
 136     endif()
 137
 138     if(HAVE_GCC42_OR_NEWER OR APPLE)
 139       if(ENABLE_SSSE3)
 140         add_extra_compiler_option(-mssse3)
 141       endif()
 142       if(HAVE_GCC43_OR_NEWER OR APPLE)
 143         if(ENABLE_SSE41)
 144            add_extra_compiler_option(-msse4.1)
 145         endif()
 146         if(ENABLE_SSE42)
 147            add_extra_compiler_option(-msse4.2)
 148         endif()
 149       endif()
 150     endif()
 151   endif(NOT MINGW)
 152
 153   if(X86 OR X86_64)
 154     if(NOT APPLE AND CMAKE_SIZEOF_VOID_P EQUAL 4)
 155       if(ENABLE_SSE2)
 156         add_extra_compiler_option(-mfpmath=sse)# !! important - be on the same wave with x64 compilers
 157       else()
 158         add_extra_compiler_option(-mfpmath=387)
 159       endif()
 160     endif()
 161   endif()
 162
 163   # Profiling?
 164   if(ENABLE_PROFILING)
 165     add_extra_compiler_option("-pg -g")
 166     # turn off incompatible options
 167     foreach(flags CMAKE_CXX_FLAGS CMAKE_C_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG CMAKE_C_FLAGS_DEBUG
 168                   OPENCV_EXTRA_FLAGS_RELEASE OPENCV_EXTRA_FLAGS_DEBUG OPENCV_EXTRA_C_FLAGS OPENCV_EXTRA_CXX_FLAGS)
 169       string(REPLACE "-fomit-frame-pointer" "" ${flags} "${${flags}}")
 170       string(REPLACE "-ffunction-sections" "" ${flags} "${${flags}}")
 171     endforeach()
 172   elseif(NOT APPLE AND NOT ANDROID)
 173     # Remove unreferenced functions: function level linking
 174     add_extra_compiler_option(-ffunction-sections)
 175   endif()
 176
 177   set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} -DNDEBUG")
 178   set(OPENCV_EXTRA_FLAGS_DEBUG "${OPENCV_EXTRA_FLAGS_DEBUG} -O0 -DDEBUG -D_DEBUG")
 179   if(BUILD_WITH_DEBUG_INFO)
 180     set(OPENCV_EXTRA_FLAGS_DEBUG "${OPENCV_EXTRA_FLAGS_DEBUG} -ggdb3")
 181   endif()
 182 endif()
 183
 184 if(MSVC)
 185   set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /D _CRT_SECURE_NO_DEPRECATE /D _CRT_NONSTDC_NO_DEPRECATE /D _SCL_SECURE_NO_WARNINGS")
 186   # 64-bit portability warnings, in MSVC80
 187   if(MSVC80)
 188     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /Wp64")
 189   endif()
 190
 191   if(BUILD_WITH_DEBUG_INFO)
 192     set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE} /debug")
 193   endif()
 194
 195   # Remove unreferenced functions: function level linking
 196   set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /Gy")
 197   if(NOT MSVC_VERSION LESS 1400)
 198     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /bigobj")
 199   endif()
 200   if(BUILD_WITH_DEBUG_INFO)
 201     set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE} /Zi")
 202   endif()
 203
 204   if(NOT MSVC64)
 205     # 64-bit MSVC compiler uses SSE/SSE2 by default
 206     if(ENABLE_SSE)
 207       set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /arch:SSE")
 208     endif()
 209     if(ENABLE_SSE2)
 210       set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /arch:SSE2")
 211     endif()
 212   endif()
 213
 214   if(ENABLE_SSE3)
 215     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /arch:SSE3")
 216   endif()
 217   if(ENABLE_SSE4_1)
 218     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /arch:SSE4.1")
 219   endif()
 220
 221   if(ENABLE_SSE OR ENABLE_SSE2 OR ENABLE_SSE3 OR ENABLE_SSE4_1)
 222     set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /Oi")
 223   endif()
 224
 225   if(X86 OR X86_64)
 226     if(CMAKE_SIZEOF_VOID_P EQUAL 4 AND ENABLE_SSE2)
 227       set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS} /fp:fast")# !! important - be on the same wave with x64 compilers
 228     endif()
 229   endif()
 230 endif()
 231
 232 # Extra link libs if the user selects building static libs:
 233 if(NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX AND NOT ANDROID)
 234   # Android does not need these settings because they are already set by toolchain file
 235   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} stdc++)
 236   set(OPENCV_EXTRA_FLAGS "-fPIC ${OPENCV_EXTRA_FLAGS}")
 237 endif()
 238
 239 # Add user supplied extra options (optimization, etc...)
 240 # ==========================================================
 241 set(OPENCV_EXTRA_FLAGS "${OPENCV_EXTRA_FLAGS}" CACHE INTERNAL "Extra compiler options")
 242 set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS}" CACHE INTERNAL "Extra compiler options for C sources")
 243 set(OPENCV_EXTRA_CXX_FLAGS "${OPENCV_EXTRA_CXX_FLAGS}" CACHE INTERNAL "Extra compiler options for C++ sources")
 244 set(OPENCV_EXTRA_FLAGS_RELEASE "${OPENCV_EXTRA_FLAGS_RELEASE}" CACHE INTERNAL "Extra compiler options for Release build")
 245 set(OPENCV_EXTRA_FLAGS_DEBUG "${OPENCV_EXTRA_FLAGS_DEBUG}" CACHE INTERNAL "Extra compiler options for Debug build")
 246 set(OPENCV_EXTRA_EXE_LINKER_FLAGS "${OPENCV_EXTRA_EXE_LINKER_FLAGS}" CACHE INTERNAL "Extra linker flags")
 247 set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE "${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE}" CACHE INTERNAL "Extra linker flags for Release build")
 248 set(OPENCV_EXTRA_EXE_LINKER_FLAGS_DEBUG "${OPENCV_EXTRA_EXE_LINKER_FLAGS_DEBUG}" CACHE INTERNAL "Extra linker flags for Debug build")
 249
 250 #combine all "extra" options
 251 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_C_FLAGS}")
 252 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_FLAGS} ${OPENCV_EXTRA_CXX_FLAGS}")
 253 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_FLAGS_RELEASE}")
 254 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${OPENCV_EXTRA_FLAGS_RELEASE}")
 255 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG}")
 256 set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} ${OPENCV_EXTRA_FLAGS_DEBUG}")
 257 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${OPENCV_EXTRA_EXE_LINKER_FLAGS}")
 258 set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE}")
 259 set(CMAKE_EXE_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_DEBUG}")
 260
 261 if(MSVC)
 262   # avoid warnings from MSVC about overriding the /W* option
 263   # we replace /W3 with /W4 only for C++ files,
 264   # since all the 3rd-party libraries OpenCV uses are in C,
 265   # and we do not care about their warnings.
 266   string(REPLACE "/W3" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 267   string(REPLACE "/W3" "/W4" CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE}")
 268   string(REPLACE "/W3" "/W4" CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG}")
 269
 270   if(NOT ENABLE_NOISY_WARNINGS AND MSVC_VERSION EQUAL 1400)
 271     ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4510 /wd4610 /wd4312 /wd4201 /wd4244 /wd4328 /wd4267)
 272   endif()
 273
 274   # allow extern "C" functions throw exceptions
 275   foreach(flags CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 276     string(REPLACE "/EHsc-" "/EHs" ${flags} "${${flags}}")
 277     string(REPLACE "/EHsc" "/EHs" ${flags} "${${flags}}")
 278
 279     string(REPLACE "/Zm1000" "" ${flags} "${${flags}}")
 280   endforeach()
 281
 282   if(NOT ENABLE_NOISY_WARNINGS)
 283     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4251") #class 'std::XXX' needs to have dll-interface to be used by clients of YYY
 284   endif()
 285 endif()