cmake/OpenCVCompilerDefenses.cmake

   1 # Enable build defense flags.
   2 # Performance may be affected.
   3 # More information:
   4 # - https://www.owasp.org/index.php/C-Based_Toolchain_Hardening
   5 # - https://wiki.debian.org/Hardening
   6 # - https://wiki.gentoo.org/wiki/Hardened/Toolchain
   7 # - https://docs.microsoft.com/en-us/cpp/build/reference/sdl-enable-additional-security-checks
   8
   9
  10 set(OPENCV_LINKER_DEFENSES_FLAGS_COMMON "")
  11
  12 macro(ocv_add_defense_compiler_flag option)
  13   ocv_check_flag_support(CXX "${option}" _varname "${ARGN}")
  14   if(${_varname})
  15     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${option}")
  16   endif()
  17
  18   ocv_check_flag_support(C "${option}" _varname "${ARGN}")
  19   if(${_varname})
  20     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${option}")
  21   endif()
  22 endmacro()
  23
  24 macro(ocv_add_defense_compiler_flag_release option)
  25   ocv_check_flag_support(CXX "${option}" _varname "${ARGN}")
  26   if(${_varname})
  27     set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} ${option}")
  28   endif()
  29
  30   ocv_check_flag_support(C "${option}" _varname "${ARGN}")
  31   if(${_varname})
  32     set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${option}")
  33   endif()
  34 endmacro()
  35
  36 # Define flags
  37
  38 if(MSVC)
  39   ocv_add_defense_compiler_flag("/GS")
  40   ocv_add_defense_compiler_flag("/sdl")
  41   ocv_add_defense_compiler_flag("/guard:cf")
  42   ocv_add_defense_compiler_flag("/w34018 /w34146 /w34244 /w34267 /w34302 /w34308 /w34509 /w34532 /w34533 /w34700 /w34789 /w34995 /w34996")
  43   set(OPENCV_LINKER_DEFENSES_FLAGS_COMMON "${OPENCV_LINKER_DEFENSES_FLAGS_COMMON} /guard:cf /dynamicbase" )
  44   if(NOT X86_64)
  45     set(OPENCV_LINKER_DEFENSES_FLAGS_COMMON "${OPENCV_LINKER_DEFENSES_FLAGS_COMMON} /safeseh")
  46   endif()
  47 elseif(CV_GCC)
  48   if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.9")
  49     ocv_add_defense_compiler_flag("-fstack-protector")
  50   else()
  51     ocv_add_defense_compiler_flag("-fstack-protector-strong")
  52   endif()
  53
  54   # These flags is added by general options: -Wformat -Wformat-security
  55   if(NOT CMAKE_CXX_FLAGS MATCHES "-Wformat" OR NOT CMAKE_CXX_FLAGS MATCHES "format-security")
  56     message(FATAL_ERROR "Defense flags: uncompatible options")
  57   endif()
  58
  59   if(ANDROID)
  60     ocv_add_defense_compiler_flag_release("-D_FORTIFY_SOURCE=2")
  61     if(NOT CMAKE_CXX_FLAGS_RELEASE MATCHES "-D_FORTIFY_SOURCE=2") # TODO Check this
  62       ocv_add_defense_compiler_flag_release("-D_FORTIFY_SOURCE=1")
  63     endif()
  64   else()
  65     ocv_add_defense_compiler_flag_release("-D_FORTIFY_SOURCE=2")
  66   endif()
  67
  68   set(OPENCV_LINKER_DEFENSES_FLAGS_COMMON "${OPENCV_LINKER_DEFENSES_FLAGS_COMMON} -z noexecstack -z relro -z now" )
  69 else()
  70   # not supported
  71 endif()
  72
  73 set(CMAKE_POSITION_INDEPENDENT_CODE TRUE)
  74 if(CV_GCC OR CV_CLANG)
  75     if(NOT CMAKE_CXX_FLAGS MATCHES "-fPIC")
  76       ocv_add_defense_compiler_flag("-fPIC")
  77     endif()
  78   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fPIE -pie")
  79 endif()
  80
  81 set( CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${OPENCV_LINKER_DEFENSES_FLAGS_COMMON}" )
  82 set( CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} ${OPENCV_LINKER_DEFENSES_FLAGS_COMMON}" )
  83 set( CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${OPENCV_LINKER_DEFENSES_FLAGS_COMMON}" )
  84
  85 if(CV_GCC OR CV_CLANG)
  86   foreach(flags
  87           CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG
  88           CMAKE_C_FLAGS CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_DEBUG)
  89     string(REPLACE "-O3" "-O2" ${flags} "${${flags}}")
  90   endforeach()
  91 endif()