cmake/FindLibngtcp2_crypto_openssl.cmake

   1 # - Try to find libngtcp2_crypto_openssl
   2 # Once done this will define
   3 #  LIBNGTCP2_CRYPTO_OPENSSL_FOUND        - System has libngtcp2_crypto_openssl
   4 #  LIBNGTCP2_CRYPTO_OPENSSL_INCLUDE_DIRS - The libngtcp2_crypto_openssl include directories
   5 #  LIBNGTCP2_CRYPTO_OPENSSL_LIBRARIES    - The libraries needed to use libngtcp2_crypto_openssl
   6
   7 find_package(PkgConfig QUIET)
   8 pkg_check_modules(PC_LIBNGTCP2_CRYPTO_OPENSSL QUIET libngtcp2_crypto_openssl)
   9
  10 find_path(LIBNGTCP2_CRYPTO_OPENSSL_INCLUDE_DIR
  11   NAMES ngtcp2/ngtcp2_crypto_openssl.h
  12   HINTS ${PC_LIBNGTCP2_CRYPTO_OPENSSL_INCLUDE_DIRS}
  13 )
  14 find_library(LIBNGTCP2_CRYPTO_OPENSSL_LIBRARY
  15   NAMES ngtcp2_crypto_openssl
  16   HINTS ${PC_LIBNGTCP2_CRYPTO_OPENSSL_LIBRARY_DIRS}
  17 )
  18
  19 if(LIBNGTCP2_CRYPTO_OPENSSL_INCLUDE_DIR)
  20   set(_version_regex "^#define[ \t]+NGTCP2_VERSION[ \t]+\"([^\"]+)\".*")
  21   file(STRINGS "${LIBNGTCP2_CRYPTO_OPENSSL_INCLUDE_DIR}/ngtcp2/version.h"
  22     LIBNGTCP2_CRYPTO_OPENSSL_VERSION REGEX "${_version_regex}")
  23   string(REGEX REPLACE "${_version_regex}" "\\1"
  24     LIBNGTCP2_CRYPTO_OPENSSL_VERSION "${LIBNGTCP2_CRYPTO_OPENSSL_VERSION}")
  25   unset(_version_regex)
  26 endif()
  27
  28 include(FindPackageHandleStandardArgs)
  29 # handle the QUIETLY and REQUIRED arguments and set
  30 # LIBNGTCP2_CRYPTO_OPENSSL_FOUND to TRUE if all listed variables are
  31 # TRUE and the requested version matches.
  32 find_package_handle_standard_args(Libngtcp2_crypto_openssl REQUIRED_VARS
  33                                   LIBNGTCP2_CRYPTO_OPENSSL_LIBRARY
  34                                   LIBNGTCP2_CRYPTO_OPENSSL_INCLUDE_DIR
  35                                   VERSION_VAR LIBNGTCP2_CRYPTO_OPENSSL_VERSION)
  36
  37 if(LIBNGTCP2_CRYPTO_OPENSSL_FOUND)
  38   set(LIBNGTCP2_CRYPTO_OPENSSL_LIBRARIES ${LIBNGTCP2_CRYPTO_OPENSSL_LIBRARY})
  39   set(LIBNGTCP2_CRYPTO_OPENSSL_INCLUDE_DIRS ${LIBNGTCP2_CRYPTO_OPENSSL_INCLUDE_DIR})
  40 endif()
  41
  42 mark_as_advanced(LIBNGTCP2_CRYPTO_OPENSSL_INCLUDE_DIR
  43                  LIBNGTCP2_CRYPTO_OPENSSL_LIBRARY)