cmake/FindIPP.cmake

   1 # This cmake script is taken from the OpenCV project (BSD license)
   2
   3 #
   4 # The script to detect Intel(R) Integrated Performance Primitives (IPP)
   5 # installation/package
   6 #
   7 # This will try to find Intel IPP libraries, and include path by automatic
   8 # search through typical install locations and if failed it will
   9 # examine IPPROOT environment variable.
  10 # Note, IPPROOT is not set by IPP installer, it should be set manually.
  11 #
  12 # On return this will define:
  13 #
  14 # IPP_FOUND        - True if Intel IPP found
  15 # IPP_ROOT_DIR     - root of IPP installation
  16 # IPP_INCLUDE_DIRS - IPP include folder
  17 # IPP_LIBRARY_DIRS - IPP libraries folder
  18 # IPP_LIBRARIES    - IPP libraries names that are used by OpenCV
  19 # IPP_LATEST_VERSION_STR   - string with the newest detected IPP version
  20 # IPP_LATEST_VERSION_MAJOR - numbers of IPP version (MAJOR.MINOR.BUILD)
  21 # IPP_LATEST_VERSION_MINOR
  22 # IPP_LATEST_VERSION_BUILD
  23 #
  24 # Created: 30 Dec 2010 by Vladimir Dudnik (vladimir.dudnik@intel.com)
  25 #
  26
  27 set(IPP_FOUND)
  28 set(IPP_VERSION_STR "5.3.0.0") # will not detect earlier versions
  29 set(IPP_VERSION_MAJOR 0)
  30 set(IPP_VERSION_MINOR 0)
  31 set(IPP_VERSION_BUILD 0)
  32 set(IPP_ROOT_DIR)
  33 set(IPP_INCLUDE_DIRS)
  34 set(IPP_LIBRARY_DIRS)
  35 set(IPP_LIBRARIES)
  36 set(IPP_LIB_PREFIX ${CMAKE_STATIC_LIBRARY_PREFIX})
  37 set(IPP_LIB_SUFFIX  ${CMAKE_STATIC_LIBRARY_SUFFIX})
  38 set(IPP_PREFIX "ipp")
  39 set(IPP_SUFFIX "_l")
  40 set(IPPCORE    "core") # core functionality
  41 set(IPPS       "s")    # signal processing
  42 set(IPPI       "i")    # image processing
  43 set(IPPCC      "cc")   # color conversion
  44 set(IPPCV      "cv")   # computer vision
  45 set(IPPVM      "vm")   # vector math
  46
  47
  48 set(IPP_X64 0)
  49 if (CMAKE_SIZEOF_VOID_P EQUAL 8)
  50     set(IPP_X64 1)
  51 endif()
  52 if (CMAKE_CL_64)
  53     set(IPP_X64 1)
  54 endif()
  55
  56 # ------------------------------------------------------------------------
  57 # This function detect IPP version by analyzing ippversion.h file
  58 # Note, ippversion.h file was inroduced since IPP 5.3
  59 # ------------------------------------------------------------------------
  60 function(get_ipp_version _ROOT_DIR)
  61     set(_VERSION_STR)
  62     set(_MAJOR)
  63     set(_MINOR)
  64     set(_BUILD)
  65
  66     # read IPP version info from file
  67     file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR1 REGEX "IPP_VERSION_MAJOR")
  68     file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR2 REGEX "IPP_VERSION_MINOR")
  69     file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR3 REGEX "IPP_VERSION_BUILD")
  70
  71     if(NOT STR3)
  72         file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR3 REGEX "IPP_VERSION_UPDATE")
  73     endif()
  74
  75     file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR4 REGEX "IPP_VERSION_STR")
  76
  77     # extract info and assign to variables
  78     string(REGEX MATCHALL "[0-9]+" _MAJOR ${STR1})
  79     string(REGEX MATCHALL "[0-9]+" _MINOR ${STR2})
  80     string(REGEX MATCHALL "[0-9]+" _BUILD ${STR3})
  81     string(REGEX MATCHALL "[0-9]+[.]+[0-9]+[^\"]+|[0-9]+[.]+[0-9]+" _VERSION_STR ${STR4})
  82
  83     # export info to parent scope
  84     set(IPP_VERSION_STR   ${_VERSION_STR} PARENT_SCOPE)
  85     set(IPP_VERSION_MAJOR ${_MAJOR}       PARENT_SCOPE)
  86     set(IPP_VERSION_MINOR ${_MINOR}       PARENT_SCOPE)
  87     set(IPP_VERSION_BUILD ${_BUILD}       PARENT_SCOPE)
  88
  89     message(STATUS "found IPP: ${_MAJOR}.${_MINOR}.${_BUILD} [${_VERSION_STR}]")
  90     message(STATUS "at: ${_ROOT_DIR}")
  91
  92     return()
  93
  94 endfunction()
  95
  96
  97 # ------------------------------------------------------------------------
  98 # This is auxiliary function called from set_ipp_variables()
  99 # to set IPP_LIBRARIES variable in IPP 6.x style (IPP 5.3 should also work)
 100 # ------------------------------------------------------------------------
 101 function(set_ipp_old_libraries)
 102     set(IPP_PREFIX "ipp")
 103     set(IPP_SUFFIX)            # old style static core libs suffix
 104     set(IPP_ARCH)              # architecture suffix
 105     set(IPP_DISP   "emerged")  # old style dipatcher and cpu-specific
 106     set(IPP_MRGD   "merged")   #   static libraries
 107     set(IPPCORE    "core")     # core functionality
 108     set(IPPSP      "s")        # signal processing
 109     set(IPPIP      "i")        # image processing
 110     set(IPPCC      "cc")       # color conversion
 111     set(IPPCV      "cv")       # computer vision
 112     set(IPPVM      "vm")       # vector math
 113
 114     if (IPP_X64)
 115         set(IPP_ARCH "em64t")
 116     endif()
 117
 118     if(WIN32)
 119         set(IPP_SUFFIX "l")
 120     endif()
 121
 122     set(IPP_LIBRARIES
 123         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPVM}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 124         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPVM}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 125         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCC}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 126         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCC}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 127         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCV}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 128         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCV}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 129         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPIP}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 130         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPIP}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 131         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPSP}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 132         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPSP}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 133         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCORE}${IPP_ARCH}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 134         PARENT_SCOPE)
 135
 136     return()
 137
 138 endfunction()
 139
 140
 141 # ------------------------------------------------------------------------
 142 # This is auxiliary function called from set_ipp_variables()
 143 # to set IPP_LIBRARIES variable in IPP 7.x style
 144 # ------------------------------------------------------------------------
 145 function(set_ipp_new_libraries)
 146     set(IPP_PREFIX "ipp")
 147     set(IPP_SUFFIX "_l")       # static not threaded libs suffix
 148     set(IPP_THRD   "_t")       # static threaded libs suffix
 149     set(IPPCORE    "core")     # core functionality
 150     set(IPPSP      "s")        # signal processing
 151     set(IPPIP      "i")        # image processing
 152     set(IPPCC      "cc")       # color conversion
 153     set(IPPCV      "cv")       # computer vision
 154     set(IPPVM      "vm")       # vector math
 155
 156     set(IPP_LIBRARIES
 157         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPVM}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 158         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCC}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 159         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCV}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 160         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPI}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 161         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPS}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 162         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCORE}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 163         PARENT_SCOPE)
 164
 165     return()
 166
 167 endfunction()
 168
 169
 170 # ------------------------------------------------------------------------
 171 # This function will set
 172 # IPP_INCLUDE_DIRS, IPP_LIBRARY_DIRS and IPP_LIBRARIES variables depending
 173 # on IPP version parameter.
 174 # Since IPP 7.0 version library names and install folder structure
 175 # was changed
 176 # ------------------------------------------------------------------------
 177 function(set_ipp_variables _LATEST_VERSION)
 178     if(${_LATEST_VERSION} VERSION_LESS "7.0")
 179 #        message(STATUS "old")
 180
 181         # set INCLUDE and LIB folders
 182         set(IPP_INCLUDE_DIRS ${IPP_ROOT_DIR}/include PARENT_SCOPE)
 183         set(IPP_LIBRARY_DIRS ${IPP_ROOT_DIR}/lib     PARENT_SCOPE)
 184
 185         if (IPP_X64)
 186             if(NOT EXISTS ${IPP_ROOT_DIR}/../em64t)
 187                 message(SEND_ERROR "IPP EM64T libraries not found")
 188             endif()
 189         else()
 190             if(NOT EXISTS ${IPP_ROOT_DIR}/../ia32)
 191                 message(SEND_ERROR "IPP IA32 libraries not found")
 192             endif()
 193         endif()
 194
 195         # set IPP_LIBRARIES variable (6.x lib names)
 196         set_ipp_old_libraries()
 197         set(IPP_LIBRARIES ${IPP_LIBRARIES} PARENT_SCOPE)
 198         message(STATUS "IPP libs: ${IPP_LIBRARIES}")
 199
 200     else()
 201 #        message(STATUS "new")
 202
 203         # set INCLUDE and LIB folders
 204         set(IPP_INCLUDE_DIRS ${IPP_ROOT_DIR}/include PARENT_SCOPE)
 205
 206         if(APPLE)
 207             set(IPP_LIBRARY_DIRS ${IPP_ROOT_DIR}/lib PARENT_SCOPE)
 208         else()
 209             if(IPP_X64)
 210                 if(NOT EXISTS ${IPP_ROOT_DIR}/lib/intel64)
 211                     message(SEND_ERROR "IPP EM64T libraries not found")
 212                 endif()
 213                 set(IPP_LIBRARY_DIRS ${IPP_ROOT_DIR}/lib/intel64 PARENT_SCOPE)
 214             else()
 215                 if(NOT EXISTS ${IPP_ROOT_DIR}/lib/ia32)
 216                     message(SEND_ERROR "IPP IA32 libraries not found")
 217                 endif()
 218                 set(IPP_LIBRARY_DIRS ${IPP_ROOT_DIR}/lib/ia32 PARENT_SCOPE)
 219             endif()
 220         endif()
 221
 222         # set IPP_LIBRARIES variable (7.x lib names)
 223         set_ipp_new_libraries()
 224         set(IPP_LIBRARIES ${IPP_LIBRARIES} PARENT_SCOPE)
 225         message(STATUS "IPP libs: ${IPP_LIBRARIES}")
 226
 227     endif()
 228
 229     return()
 230
 231 endfunction()
 232
 233
 234 # ------------------------------------------------------------------------
 235 # This section will look for IPP through IPPROOT env variable
 236 # Note, IPPROOT is not set by IPP installer, you may need to set it manually
 237 # ------------------------------------------------------------------------
 238 find_path(
 239     IPP_H_PATH
 240     NAMES ippversion.h
 241     PATHS $ENV{IPPROOT}
 242     PATH_SUFFIXES include
 243     DOC "The path to Intel(R) IPP header files"
 244     NO_DEFAULT_PATH
 245     NO_CMAKE_PATH)
 246
 247 if(IPP_H_PATH)
 248     set(IPP_FOUND 1)
 249
 250     # traverse up to IPPROOT level
 251     get_filename_component(IPP_ROOT_DIR ${IPP_H_PATH} PATH)
 252
 253     # extract IPP version info
 254     get_ipp_version(${IPP_ROOT_DIR})
 255
 256     # keep info in the same vars for auto search and search by IPPROOT
 257     set(IPP_LATEST_VERSION_STR   ${IPP_VERSION_STR})
 258     set(IPP_LATEST_VERSION_MAJOR ${IPP_VERSION_MAJOR})
 259     set(IPP_LATEST_VERSION_MINOR ${IPP_VERSION_MINOR})
 260     set(IPP_LATEST_VERSION_BUILD ${IPP_VERSION_BUILD})
 261
 262     # set IPP INCLUDE, LIB dirs and library names
 263     set_ipp_variables(${IPP_LATEST_VERSION_STR})
 264 endif()
 265
 266
 267 if(NOT IPP_FOUND)
 268     # reset var from previous search
 269     set(IPP_H_PATH)
 270
 271
 272     # ------------------------------------------------------------------------
 273     # This section will look for IPP through system program folders
 274     # Note, if several IPP installations found the newest version will be
 275     # selected
 276     # ------------------------------------------------------------------------
 277     foreach(curdir ${CMAKE_SYSTEM_PREFIX_PATH} /opt)
 278         set(curdir ${curdir}/intel)
 279         file(TO_CMAKE_PATH ${curdir} CURDIR)
 280
 281         if(EXISTS ${curdir})
 282             file(GLOB_RECURSE IPP_H_DIR ${curdir}/ippversion.h)
 283
 284             if(IPP_H_DIR)
 285                 set(IPP_FOUND 1)
 286             endif()
 287
 288             # init IPP_LATEST_VERSION  version with oldest detectable version (5.3.0.0)
 289             #   IPP prior 5.3 did not have ippversion.h file
 290             set(IPP_LATEST_VERSION_STR ${IPP_VERSION_STR})
 291
 292             # look through all dirs where ippversion.h was found
 293             foreach(item ${IPP_H_DIR})
 294
 295                 # traverse up to IPPROOT level
 296                 get_filename_component(_FILE_PATH ${item} PATH)
 297                 get_filename_component(_ROOT_DIR ${_FILE_PATH} PATH)
 298
 299                 # extract IPP version info
 300                 get_ipp_version(${_ROOT_DIR})
 301
 302                 # remember the latest version (if many found)
 303                 if(${IPP_LATEST_VERSION_STR} VERSION_LESS ${IPP_VERSION_STR})
 304                     set(IPP_LATEST_VERSION_STR   ${IPP_VERSION_STR})
 305                     set(IPP_LATEST_VERSION_MAJOR ${IPP_VERSION_MAJOR})
 306                     set(IPP_LATEST_VERSION_MINOR ${IPP_VERSION_MINOR})
 307                     set(IPP_LATEST_VERSION_BUILD ${IPP_VERSION_BUILD})
 308                     set(IPP_ROOT_DIR ${_ROOT_DIR})
 309                 endif()
 310             endforeach()
 311         endif()
 312     endforeach()
 313 endif()
 314
 315 if(IPP_FOUND)
 316     # set IPP INCLUDE, LIB dirs and library names
 317     set_ipp_variables(${IPP_LATEST_VERSION_STR})
 318
 319     # set CACHE variable IPP_H_PATH,
 320     # path to IPP header files for the latest version
 321     find_path(
 322         IPP_H_PATH
 323         NAMES ippversion.h
 324         PATHS ${IPP_ROOT_DIR}
 325         PATH_SUFFIXES include
 326         DOC "The path to Intel(R) IPP header files"
 327         NO_DEFAULT_PATH
 328         NO_CMAKE_PATH)
 329 endif()
 330
 331 if(WIN32 AND MINGW AND NOT IPP_LATEST_VERSION_MAJOR LESS 7)
 332     # Since IPP built with Microsoft compiler and /GS option
 333     # ======================================================
 334     # From Windows SDK 7.1
 335     #   (usually in "C:\Program Files\Microsoft Visual Studio 10.0\VC\lib"),
 336     # to avoid undefined reference to __security_cookie and _chkstk:
 337     set(MSV_RUNTMCHK "RunTmChk")
 338     set(IPP_LIBRARIES ${IPP_LIBRARIES} ${MSV_RUNTMCHK}${IPP_LIB_SUFFIX})
 339
 340     # To avoid undefined reference to _alldiv and _chkstk
 341     # ===================================================
 342     # NB: it may require a recompilation of w32api (after having modified
 343     #     the file ntdll.def) to export the required functions
 344     #     See http://code.opencv.org/issues/1906 for additional details
 345     set(MSV_NTDLL    "ntdll")
 346     set(IPP_LIBRARIES ${IPP_LIBRARIES} ${MSV_NTDLL}${IPP_LIB_SUFFIX})
 347 endif()
 348
 349 # ------------------------------------------------------------------------
 350 # This section will look for the IPP "compiler" dependent library
 351 # libiomp5.
 352 # ------------------------------------------------------------------------
 353 foreach(curdir ${CMAKE_SYSTEM_PREFIX_PATH} /opt)
 354     set(curdir ${curdir}/intel)
 355
 356     if(EXISTS ${curdir})
 357         file(GLOB_RECURSE liblist FOLLOW_SYMLINKS ${curdir}/libiomp5.*)
 358         foreach(lib ${liblist})
 359             get_filename_component(libdir ${lib} REALPATH)
 360             get_filename_component(libdir ${libdir} PATH)
 361
 362             if(${IPP_VERSION_MAJOR} VERSION_LESS "7")
 363                 set(IPP_COMPILER_LIBRARY_DIRS ${libdir})
 364                 set(IPP_COMPILER_LIBRARIES iomp5)
 365             else()
 366                 if(APPLE)
 367                     set(IPP_COMPILER_LIBRARY_DIRS ${libdir})
 368                     set(IPP_COMPILER_LIBRARIES iomp5)
 369                 else()
 370                     if(IPP_X64)
 371                         if(("${libdir}" MATCHES "intel64"))
 372                             set(IPP_COMPILER_LIBRARY_DIRS ${libdir})
 373                             set(IPP_COMPILER_LIBRARIES iomp5)
 374                         endif()
 375                     else()
 376                         set(IPP_COMPILER_LIBRARY_DIRS ${libdir})
 377                         set(IPP_COMPILER_LIBRARIES iomp5)
 378                     endif()
 379                 endif()
 380             endif()
 381         endforeach(lib)
 382     endif()
 383 endforeach(curdir)
 384
 385 # ------------------------------------------------------------------------
 386 # Build fullpath library list.
 387 # ------------------------------------------------------------------------
 388 find_library(LIB_IPPI ippi PATHS ${IPP_LIBRARY_DIRS})
 389 set(IPP_LIBRARY_LIST ${IPP_LIBRARY_LIST} ${LIB_IPPI})
 390 find_library(LIB_IPPS ipps PATHS ${IPP_LIBRARY_DIRS})
 391 set(IPP_LIBRARY_LIST ${IPP_LIBRARY_LIST} ${LIB_IPPS})
 392 find_library(LIB_IPPCORE ippcore PATHS ${IPP_LIBRARY_DIRS})
 393 set(IPP_LIBRARY_LIST ${IPP_LIBRARY_LIST} ${LIB_IPPCORE})
 394 find_library(LIB_IOMP5 iomp5 PATHS ${IPP_COMPILER_LIBRARY_DIRS})
 395 set(IPP_LIBRARY_LIST ${IPP_LIBRARY_LIST} ${LIB_IOMP5})
 396
 397