cmake/FindGlib.cmake

   1 # - Try to find Glib-2.0 (with gobject)
   2 # Once done, this will define
   3 #
   4 #  Glib_FOUND - system has Glib
   5 #  Glib_INCLUDE_DIRS - the Glib include directories
   6 #  Glib_LIBRARIES - link these to use Glib
   7 #
   8 #  GLIB_ROOT_DIR - Primary search directory
   9 include(LibFindMacros)
  10
  11 # Use pkg-config to get hints about paths
  12 libfind_pkg_check_modules(Glib_PKGCONF glib-2.0)
  13
  14 # Main include dir
  15 find_path(Glib_INCLUDE_DIR
  16                   NAMES glib.h
  17                   PATHS ${Glib_PKGCONF_INCLUDE_DIRS} ${GLIB_ROOT_DIR}
  18                   PATH_SUFFIXES glib-2.0
  19                  )
  20
  21 # Finally the library itself
  22 find_library(Glib_LIBRARY
  23                          NAMES glib-2.0 gstreamer_android
  24                          PATHS ${Glib_PKGCONF_LIBRARY_DIRS} ${GLIB_ROOT_DIR}
  25                         )
  26 find_library(Gobject_LIBRARY
  27                          NAMES gobject-2.0 gstreamer_android
  28                          PATHS ${Glib_PKGCONF_LIBRARY_DIRS} ${GLIB_ROOT_DIR}
  29                         )
  30
  31 # Glib-related libraries also use a separate config header, which is relative to lib dir
  32 find_path(GlibConfig_INCLUDE_DIR
  33                   NAMES glibconfig.h
  34                   PATHS ${Glib_PKGCONF_INCLUDE_DIRS} ${GLIB_ROOT_DIR}
  35                  )
  36
  37 # Set the include dir variables and the libraries and let libfind_process do the rest.
  38 # NOTE: Singular variables for this library, plural for libraries this this lib depends on.
  39 set(Glib_PROCESS_INCLUDES Glib_INCLUDE_DIR GlibConfig_INCLUDE_DIR)
  40 set(Glib_PROCESS_LIBS Glib_LIBRARY Gobject_LIBRARY)
  41 libfind_process(Glib)
  42