cmake/DBus1Config.pkgconfig.in

   1 # - Config file for the DBus1 package
   2 # It defines the following variables
   3 #  DBus1_FOUND - Flag for indicating that DBus1 package has been found
   4 #  DBus1_DEFINITIONS  - compile definitions for DBus1 [1]
   5 #  DBus1_INCLUDE_DIRS - include directories for DBus1 [1]
   6 #  DBus1_LIBRARIES    - cmake targets to link against
   7
   8 # [1] This variable is not required if DBus1_LIBRARIES is added
   9 #     to a target with target_link_libraries
  10
  11 get_filename_component(DBus1_PKGCONFIG_DIR "${CMAKE_CURRENT_LIST_DIR}/../../pkgconfig" ABSOLUTE)
  12 find_package(PkgConfig)
  13 if(DEFINED ENV{PKG_CONFIG_DIR})
  14     set(_dbus_pkgconfig_dir "$ENV{PKG_CONFIG_DIR}")
  15 endif()
  16 if(DEFINED ENV{PKG_CONFIG_PATH})
  17     set(_dbus_pkgconfig_path "$ENV{PKG_CONFIG_PATH}")
  18 endif()
  19 if(DEFINED ENV{PKG_CONFIG_LIBDIR})
  20     set(_dbus_pkgconfig_libdir "$ENV{PKG_CONFIG_LIBDIR}")
  21 endif()
  22 set(ENV{PKG_CONFIG_DIR})
  23 set(ENV{PKG_CONFIG_PATH} ${DBus1_PKGCONFIG_DIR})
  24 set(ENV{PKG_CONFIG_LIBDIR} ${DBus1_PKGCONFIG_DIR})
  25 # for debugging
  26 #set(ENV{PKG_CONFIG_DEBUG_SPEW} 1)
  27 pkg_check_modules(PC_DBUS1 QUIET dbus-1)
  28 if(DEFINED _dbus_pkgconfig_dir)
  29     set(ENV{PKG_CONFIG_DIR} "${_dbus_pkgconfig_dir}")
  30 else()
  31     unset(ENV{PKG_CONFIG_DIR})
  32 endif()
  33 if(DEFINED _dbus_pkgconfig_path)
  34     set(ENV{PKG_CONFIG_PATH} "${_dbus_pkgconfig_path}")
  35 else()
  36     unset(ENV{PKG_CONFIG_PATH})
  37 endif()
  38 if(DEFINED _dbus_pkgconfig_libdir)
  39     set(ENV{PKG_CONFIG_LIBDIR} "${_dbus_pkgconfig_libdir}")
  40 else()
  41     unset(ENV{PKG_CONFIG_LIBDIR})
  42 endif()
  43 unset(_dbus_pkgconfig_dir)
  44 unset(_dbus_pkgconfig_path)
  45 unset(_dbus_pkgconfig_libdir)
  46 set(DBus1_DEFINITIONS ${PC_DBUS1_CFLAGS_OTHER})
  47
  48 # find the real stuff and use pkgconfig variables as hints
  49 # because cmake provides more search options
  50 find_path(DBus1_INCLUDE_DIR dbus/dbus.h
  51     HINTS ${PC_DBUS1_INCLUDEDIR} ${PC_DBUS1_INCLUDE_DIRS}
  52     PATH_SUFFIXES dbus-1.0)
  53 find_path(DBus1_ARCH_INCLUDE_DIR dbus/dbus-arch-deps.h
  54     HINTS ${PC_DBUS1_INCLUDE_DIRS}
  55     PATH_SUFFIXES dbus-1.0)
  56 find_library(DBus1_LIBRARY NAMES ${PC_DBUS1_LIBRARIES}
  57     HINTS ${PC_DBUS1_LIBDIR} ${PC_DBUS1_LIBRARY_DIRS})
  58
  59 include(FindPackageHandleStandardArgs)
  60 # handle the QUIETLY and REQUIRED arguments and set DBus1_FOUND to TRUE
  61 # if all listed variables are TRUE
  62 find_package_handle_standard_args(DBus1 DEFAULT_MSG
  63     DBus1_LIBRARY DBus1_INCLUDE_DIR DBus1_ARCH_INCLUDE_DIR)
  64
  65 # make the mentioned variables only visible in cmake gui with "advanced" enabled
  66 mark_as_advanced(DBus1_INCLUDE_DIR DBus1_LIBRARY)
  67
  68 set(DBus1_LIBRARIES dbus-1)
  69 set(DBus1_INCLUDE_DIRS "${DBus1_INCLUDE_DIR}" "${DBus1_ARCH_INCLUDE_DIR}")
  70
  71 # setup imported target
  72 add_library(dbus-1 SHARED IMPORTED)
  73 set_property(TARGET dbus-1 APPEND PROPERTY IMPORTED_LOCATION ${DBus1_LIBRARY})
  74 set_property(TARGET dbus-1 APPEND PROPERTY INTERFACE_INCLUDE_DIRECTORIES ${DBus1_INCLUDE_DIRS})
  75 set_property(TARGET dbus-1 APPEND PROPERTY INTERFACE_COMPILE_DEFINITIONS ${DBus1_DEFINITIONS})