cmake/ConfigureChecks.cmake

   1 include(CheckIncludeFile)
   2 include(CheckIncludeFiles)
   3 include(CheckSymbolExists)
   4 include(CheckStructMember)
   5 include(CheckTypeSize)
   6
   7 check_include_file(alloca.h     HAVE_ALLOCA_H)
   8 check_include_file(byteswap.h     HAVE_BYTESWAP_H)
   9 check_include_file(crt/externs.h     HAVE_CRT_EXTERNS_H)
  10 check_include_file(dirent.h     HAVE_DIRENT_H)  # dbus-sysdeps-util.c
  11 check_include_file(dlfcn.h     HAVE_DLFCN_H)
  12 check_include_file(execinfo.h     HAVE_EXECINFO_H)
  13 check_include_file(errno.h     HAVE_ERRNO_H)    # dbus-sysdeps.c
  14 check_include_file(expat.h     HAVE_EXPAT_H)
  15 check_include_file(grp.h        HAVE_GRP_H)     # dbus-sysdeps-util-win.c
  16 check_include_file(inttypes.h     HAVE_INTTYPES_H)   # dbus-pipe.h
  17 check_include_file(io.h         HAVE_IO_H)      # internal
  18 check_include_file(locale.h     HAVE_LOCALE_H)
  19 check_include_file(memory.h     HAVE_MEMORY_H)
  20 check_include_file(signal.h     HAVE_SIGNAL_H)
  21 check_include_file(stdint.h     HAVE_STDINT_H)   # dbus-pipe.h
  22 check_include_file(stdlib.h     HAVE_STDLIB_H)
  23 check_include_file(stdio.h      HAVE_STDIO_H)   # dbus-sysdeps.h
  24 check_include_file(string.h     HAVE_STRING_H)
  25 check_include_file(strings.h     HAVE_STRINGS_H)
  26 check_include_file(syslog.h     HAVE_SYSLOG_H)
  27 check_include_files("stdint.h;sys/types.h;sys/event.h" HAVE_SYS_EVENT_H)
  28 check_include_file(sys/inotify.h     HAVE_SYS_INOTIFY_H)
  29 check_include_file(sys/resource.h     HAVE_SYS_RESOURCE_H)
  30 check_include_file(sys/stat.h     HAVE_SYS_STAT_H)
  31 check_include_file(sys/types.h     HAVE_SYS_TYPES_H)
  32 check_include_file(sys/uio.h     HAVE_SYS_UIO_H)
  33 check_include_file(sys/poll.h   HAVE_POLL)      # dbus-sysdeps.c, dbus-sysdeps-win.c
  34 check_include_file(sys/prctl.h  HAVE_SYS_PRCTL_H)
  35 check_include_file(sys/syslimits.h    HAVE_SYS_SYSLIMITS_H)   # dbus-sysdeps-unix.c
  36 check_include_file(sys/time.h   HAVE_SYS_TIME_H)# dbus-sysdeps-win.c
  37 check_include_file(sys/wait.h   HAVE_SYS_WAIT_H)# dbus-sysdeps-win.c
  38 check_include_file(time.h       HAVE_TIME_H)    # dbus-sysdeps-win.c
  39 check_include_file(ws2tcpip.h   HAVE_WS2TCPIP_H)# dbus-sysdeps-win.c
  40 check_include_file(unistd.h     HAVE_UNISTD_H)  # dbus-sysdeps-util-win.c
  41
  42 check_symbol_exists(backtrace    "execinfo.h"       HAVE_BACKTRACE)          #  dbus-sysdeps.c, dbus-sysdeps-win.c
  43 check_symbol_exists(getgrouplist "grp.h"            HAVE_GETGROUPLIST)       #  dbus-sysdeps.c
  44 check_symbol_exists(getpeerucred "ucred.h"          HAVE_GETPEERUCRED)       #  dbus-sysdeps.c, dbus-sysdeps-win.c
  45 check_symbol_exists(nanosleep    "time.h"           HAVE_NANOSLEEP)          #  dbus-sysdeps.c
  46 check_symbol_exists(getpwnam_r   "errno.h pwd.h"    HAVE_POSIX_GETPWNAM_R)   #  dbus-sysdeps-util-unix.c
  47 check_symbol_exists(setenv       "stdlib.h"         HAVE_SETENV)             #  dbus-sysdeps.c
  48 check_symbol_exists(unsetenv     "stdlib.h"         HAVE_UNSETENV)           #  dbus-sysdeps.c
  49 check_symbol_exists(clearenv     "stdlib.h"         HAVE_CLEARENV)           #  dbus-sysdeps.c
  50 check_symbol_exists(writev       "sys/uio.h"        HAVE_WRITEV)             #  dbus-sysdeps.c, dbus-sysdeps-win.c
  51 check_symbol_exists(setrlimit    "sys/resource.h"   HAVE_SETRLIMIT)          #  dbus-sysdeps.c, dbus-sysdeps-win.c, test/test-segfault.c
  52 check_symbol_exists(socketpair   "sys/socket.h"     HAVE_SOCKETPAIR)         #  dbus-sysdeps.c
  53 check_symbol_exists(setlocale    "locale.h"         HAVE_SETLOCALE)          #  dbus-test-main.c
  54 check_symbol_exists(localeconv   "locale.h"         HAVE_LOCALECONV)         #  dbus-sysdeps.c
  55 check_symbol_exists(strtoll      "stdlib.h"         HAVE_STRTOLL)            #  dbus-send.c
  56 check_symbol_exists(strtoull     "stdlib.h"         HAVE_STRTOULL)           #  dbus-send.c
  57 set(CMAKE_REQUIRED_DEFINITIONS -D_GNU_SOURCE)
  58 check_symbol_exists(pipe2        "fcntl.h;unistd.h"         HAVE_PIPE2)
  59 check_symbol_exists(accept4      "sys/socket.h"             HAVE_ACCEPT4)
  60 check_symbol_exists(dirfd        "dirent.h"                 HAVE_DIRFD)
  61 check_symbol_exists(inotify_init1 "sys/inotify.h"           HAVE_INOTIFY_INIT1)
  62 check_symbol_exists(SCM_RIGHTS    "sys/types.h;sys/socket.h;sys/un.h" HAVE_UNIX_FD_PASSING)
  63 check_symbol_exists(prctl        "sys/prctl.h"              HAVE_PRCTL)
  64 check_symbol_exists(raise        "signal.h"                 HAVE_RAISE)
  65
  66 check_struct_member(cmsgcred cmcred_pid "sys/types.h sys/socket.h" HAVE_CMSGCRED)   #  dbus-sysdeps.c
  67
  68 # missing:
  69 # DBUS_HAVE_GCC33_GCOV
  70
  71 check_type_size("short"     SIZEOF_SHORT)
  72 check_type_size("int"       SIZEOF_INT)
  73 check_type_size("long"      SIZEOF_LONG)
  74 check_type_size("long long" SIZEOF_LONG_LONG)
  75 check_type_size("__int64"   SIZEOF___INT64)
  76 set(CMAKE_EXTRA_INCLUDE_FILES "sys/socket.h")
  77 check_type_size("socklen_t" SOCKLEN_T)          #  dbus-sysdeps-unix.c
  78 set(CMAKE_EXTRA_INCLUDE_FILES)
  79
  80 # DBUS_INT64_TYPE
  81 if(SIZEOF_INT EQUAL 8)
  82     set (DBUS_INT64_TYPE "int")
  83     set (DBUS_INT64_CONSTANT  "(val)")
  84     set (DBUS_UINT64_CONSTANT "(val##U)")
  85 elseif(SIZEOF_LONG EQUAL 8)
  86     set (DBUS_INT64_TYPE "long")
  87     set (DBUS_INT64_CONSTANT  "(val##L)")
  88     set (DBUS_UINT64_CONSTANT "(val##UL)")
  89 elseif(SIZEOF_LONG_LONG EQUAL 8)
  90     set (DBUS_INT64_TYPE "long long")
  91     set (DBUS_INT64_CONSTANT  "(val##LL)")
  92     set (DBUS_UINT64_CONSTANT "(val##ULL)")
  93 elseif(SIZEOF___INT64 EQUAL 8)
  94     set (DBUS_INT64_TYPE "__int64")
  95     set (DBUS_INT64_CONSTANT  "(val##i64)")
  96     set (DBUS_UINT64_CONSTANT "(val##ui64)")
  97 else(SIZEOF_INT EQUAL 8)
  98     message (FATAL_ERROR "Could not find a 64-bit integer type")
  99 endif(SIZEOF_INT EQUAL 8)
 100
 101 # DBUS_INT32_TYPE
 102 if(SIZEOF_INT EQUAL 4)
 103     set (DBUS_INT32_TYPE "int")
 104 elseif(SIZEOF_LONG EQUAL 4)
 105     set (DBUS_INT32_TYPE "long")
 106 elseif(SIZEOF_LONG_LONG EQUAL 4)
 107     set (DBUS_INT32_TYPE "long long")
 108 endif(SIZEOF_INT EQUAL 4)
 109
 110 # DBUS_INT16_TYPE
 111 if(SIZEOF_INT EQUAL 2)
 112     set (DBUS_INT16_TYPE "int")
 113 elseif(SIZEOF_SHORT EQUAL 2)
 114     set (DBUS_INT16_TYPE "short")
 115 endif(SIZEOF_INT EQUAL 2)
 116
 117 find_program(DOXYGEN doxygen)
 118 find_program(XMLTO xmlto)
 119
 120 if(MSVC)
 121    SET(DBUS_VA_COPY_FUNC "_DBUS_VA_COPY_ASSIGN")
 122 else(MSVC)
 123 write_file("${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/cmake_try_compile.c" "#include <stdarg.h>
 124         #include <stdlib.h>
 125         static void f (int i, ...) {
 126         va_list args1, args2;
 127         va_start (args1, i);
 128         va_copy (args2, args1);
 129         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 130           exit (1);
 131         va_end (args1); va_end (args2);
 132         }
 133         int main() {
 134           f (0, 42);
 135           return 0;
 136         }
 137 ")
 138 try_compile(DBUS_HAVE_VA_COPY
 139             ${CMAKE_BINARY_DIR}
 140             ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/cmake_try_compile.c)
 141
 142 if(DBUS_HAVE_VA_COPY)
 143   SET(DBUS_VA_COPY_FUNC va_copy CACHE STRING "va_copy function")
 144 else(DBUS_HAVE_VA_COPY)
 145   write_file("${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/cmake_try_compile.c" "#include <stdarg.h>
 146           #include <stdlib.h>
 147           static void f (int i, ...) {
 148           va_list args1, args2;
 149           va_start (args1, i);
 150           __va_copy (args2, args1);
 151           if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 152             exit (1);
 153           va_end (args1); va_end (args2);
 154           }
 155           int main() {
 156             f (0, 42);
 157             return 0;
 158           }
 159   ")
 160   try_compile(DBUS_HAVE___VA_COPY
 161               ${CMAKE_BINARY_DIR}
 162               ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/cmake_try_compile.c)
 163   if(DBUS_HAVE___VA_COPY)
 164     SET(DBUS_VA_COPY_FUNC __va_copy CACHE STRING "va_copy function")
 165   else(DBUS_HAVE___VA_COPY)
 166     SET(DBUS_VA_COPY_AS_ARRAY "1" CACHE STRING "'va_lists' cannot be copies as values")
 167   endif(DBUS_HAVE___VA_COPY)
 168 endif(DBUS_HAVE_VA_COPY)
 169 endif(MSVC) # _not_ MSVC