cmake/CMakeLists.txt

   1 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
   3
   4 # we do not need to have WIN32 defined
   5 set(CMAKE_LEGACY_CYGWIN_WIN32 0)
   6
   7 project(dbus)
   8
   9 # we need to be up to date
  10 CMAKE_MINIMUM_REQUIRED(VERSION 2.4.4 FATAL_ERROR)
  11 if(COMMAND cmake_policy)
  12     cmake_policy(SET CMP0003 NEW)
  13 endif(COMMAND cmake_policy)
  14
  15
  16 # detect version
  17 include(MacrosAutotools)
  18 autoversion(../configure.ac dbus)
  19 # used by file version info
  20 set (DBUS_PATCH_VERSION "0")
  21
  22 include(Macros)
  23 TIMESTAMP(DBUS_BUILD_TIMESTAMP)
  24
  25 ########### basic vars ###############
  26
  27
  28 if (DBUSDIR)
  29         set(DBUS_INSTALL_DIR "${DBUSDIR}")
  30 endif (DBUSDIR)
  31 if ($ENV{DBUSDIR})
  32         set(DBUS_INSTALL_DIR "$ENV{DBUSDIR}")
  33 endif ($ENV{DBUSDIR})
  34
  35 if (DBUS_INSTALL_DIR)
  36         set(CMAKE_INSTALL_PREFIX "${DBUS_INSTALL_DIR}" CACHE PATH "install prefix" FORCE)
  37 else (DBUS_INSTALL_DIR)
  38         set(DBUS_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}")
  39 endif (DBUS_INSTALL_DIR)
  40
  41 # autotools style
  42 if (NOT DATAROOTDIR)
  43     set (DATAROOTDIR share)
  44 endif()
  45
  46 if (NOT DATADIR)
  47     set (DATADIR ${DATAROOTDIR})
  48 endif()
  49
  50 if (NOT DOCDIR)
  51     SET(DOCDIR ${DATAROOTDIR}/doc/dbus)
  52 endif()
  53
  54 if (NOT DBUS_DATADIR)
  55     SET(DBUS_DATADIR ${DATADIR})
  56 endif()
  57
  58 set(prefix                   ${DBUS_INSTALL_DIR})
  59 set(exec_prefix              ${prefix})
  60 set(EXPANDED_LIBDIR          ${DBUS_INSTALL_DIR}/lib)
  61 set(EXPANDED_INCLUDEDIR      ${DBUS_INSTALL_DIR}/include)
  62 set(EXPANDED_BINDIR          ${DBUS_INSTALL_DIR}/bin)
  63 set(EXPANDED_SYSCONFDIR      ${DBUS_INSTALL_DIR}/etc)
  64 set(EXPANDED_DATADIR         ${DBUS_INSTALL_DIR}/${DBUS_DATADIR})
  65 set(DBUS_MACHINE_UUID_FILE   ${DBUS_INSTALL_DIR}/lib/dbus/machine-id)
  66 set(DBUS_BINDIR              ${EXPANDED_BINDIR})
  67 set(DBUS_DAEMONDIR           ${EXPANDED_BINDIR})
  68
  69
  70 #enable building of shared library
  71 SET(BUILD_SHARED_LIBS ON)
  72
  73 if(WIN32)
  74     set(INSTALL_TARGETS_DEFAULT_ARGS  RUNTIME DESTINATION "bin" LIBRARY DESTINATION "lib" ARCHIVE DESTINATION "lib")
  75 else()
  76     set(INSTALL_TARGETS_DEFAULT_ARGS  RUNTIME DESTINATION "${EXPANDED_LIBDIR}" LIBRARY DESTINATION "${EXPANDED_LIBDIR}" ARCHIVE DESTINATION "${EXPANDED_LIBDIR}")
  77 endif()
  78
  79 if (CYGWIN)
  80    set (WIN32)
  81 endif (CYGWIN)
  82
  83 # search for required packages
  84 if (WIN32)
  85     # include local header first to avoid using old installed header
  86     set (CMAKE_INCLUDE_PATH ${CMAKE_INCLUDE_PATH} ${CMAKE_SOURCE_DIR}/..)
  87         find_package(LibIconv)
  88     include(Win32Macros)
  89     addExplorerWrapper(${CMAKE_PROJECT_NAME})
  90 endif (WIN32)
  91
  92 if(NOT WIN32)
  93         option (DBUS_ENABLE_ABSTRACT_SOCKETS "enable support for abstract sockets" ON)
  94         set (CMAKE_THREAD_PREFER_PTHREAD ON)
  95         include (FindThreads)
  96 endif(NOT WIN32)
  97
  98 option (DBUS_DISABLE_ASSERT "Disable assertion checking" OFF)
  99
 100 option (DBUS_ENABLE_STATS "enable bus daemon usage statistics" OFF)
 101
 102 find_package(EXPAT)
 103 find_package(X11)
 104
 105 # analogous to AC_USE_SYSTEM_EXTENSIONS in configure.ac
 106 add_definitions(-D_GNU_SOURCE)
 107
 108 # do config checks
 109 INCLUDE(ConfigureChecks.cmake)
 110
 111 # @TODO: how to remove last dir from ${CMAKE_SOURCE_DIR} ?
 112 SET(DBUS_SOURCE_DIR ${CMAKE_SOURCE_DIR}/..)
 113
 114 # make some more macros available
 115 include (MacroLibrary)
 116
 117 if(VCS)
 118         set(DBUS_VERBOSE_C_S 1 CACHE STRING "verbose mode" FORCE)
 119 endif(VCS)
 120
 121 if(WIN32)
 122         set(CMAKE_DEBUG_POSTFIX "d")
 123         if(MSVC)
 124                 # controll folders in msvc projects
 125                 include(ProjectSourceGroup)
 126                 if(NOT GROUP_CODE)
 127                         #set(GROUP_CODE split) #cmake default
 128                         set(GROUP_CODE flat)
 129                 endif(NOT GROUP_CODE)
 130                 ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 131
 132
 133                 # Use the highest warning level
 134                 if (WALL)
 135                         set(WALL 1 CACHE STRING "all warnings"  FORCE)
 136                         set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "warning level" FORCE)
 137
 138                         if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 139                                 STRING(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 140                         else(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 141                                 SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 142                         endif(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 143
 144                         if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 145                                 STRING(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 146                         else(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 147                                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 148                         endif(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 149                 else (WALL)
 150                         set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "warning level" FORCE)
 151                 endif (WALL)
 152
 153                 SET(MSVC_W_ERROR   " /we4028 /we4013 /we4133 /we4047 /we4031 /we4002 /we4003 /we4114")
 154                 SET(MSVC_W_DISABLE " /wd4127 /wd4090 /wd4101 /wd4244")
 155
 156                 SET(CMAKE_C_FLAGS_DEBUG   "${CMAKE_C_FLAGS_DEBUG}   /FIconfig.h ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 157                 SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} /FIconfig.h ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 158         endif(MSVC)
 159 endif(WIN32)
 160
 161 if (UNIX AND NOT DBUS_DISABLE_ASSERT)
 162         # required for backtrace
 163         SET(CMAKE_C_FLAGS_DEBUG   "${CMAKE_C_FLAGS_DEBUG}   -Wl,--export-dynamic")
 164         SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -Wl,--export-dynamic")
 165         add_definitions(-DDBUS_BUILT_R_DYNAMIC)
 166 endif (UNIX AND NOT DBUS_DISABLE_ASSERT)
 167
 168 SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG}  -D_DEBUG")
 169
 170 #########################################################################
 171 # Windows CE (>= 5.0.0)
 172 #
 173 # WinCE support now relies on the presence of platform files, found in cmake/modules/platform
 174 # Cmake 2.8.0 doesn't include WinCE platform files by default, but working ones can be found
 175 # on CMake's bugtracker :
 176 # http://public.kitware.com/Bug/view.php?id=7919
 177 #
 178 # for cmake 2.8.0 get the following patch only :
 179 # http://public.kitware.com/Bug/file_download.php?file_id=2944&type=bug
 180 #
 181 # after applying the patch, you can enable the WinCE build by specifying :
 182 # cmake [...] -DCMAKE_SYSTEM_NAME=WinCE -DCMAKE_SYSTEM_VERSION=X.XX
 183 # (where X.XX is your actual WinCE version, e.g. 5.02 for Windows Mobile 6)
 184 #
 185 # Note that you should have a proper cross-compilation environment set up prior to running
 186 # cmake, ie. the PATH, INCLUDE and LIB env vars pointing to your CE SDK/toolchain.
 187 #
 188 if(WINCE)
 189
 190 MESSAGE("Building for WinCE (${CMAKE_SYSTEM_VERSION})")
 191
 192 endif(WINCE)
 193 #########################################################################
 194
 195
 196 ENABLE_TESTING()
 197
 198 #########################################################################
 199 # Disallow in-source build
 200 #macro_ensure_out_of_source_build("dbus requires an out of source build. Please create a separate build directory and run 'cmake path_to_dbus [options]' there.")
 201
 202 # ... and warn in case of an earlier in-source build
 203 #set(generatedFileInSourceDir EXISTS ${dbus_SOURCE_DIR}/config.h)
 204 #if(${generatedFileInSourceDir})
 205 #   message(STATUS "config.h exists in your source directory.")
 206 #endif(${generatedFileInSourceDir})
 207 #########################################################################
 208
 209 if (WIN32 OR CYGWIN)
 210         set (LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
 211 else (WIN32 OR CYGWIN)
 212         set (LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
 213 endif (WIN32 OR CYGWIN)
 214
 215 set (EXECUTABLE_OUTPUT_PATH ${CMAKE_BINARY_DIR}/bin)
 216
 217 # for including config.h and for includes like <dir/foo.h>
 218 include_directories( ${CMAKE_SOURCE_DIR}/.. ${CMAKE_BINARY_DIR} ${CMAKE_INCLUDE_PATH} )
 219
 220 # linker search directories
 221 link_directories(${DBUS_LIB_DIR} ${LIBRARY_OUTPUT_PATH} )
 222 include_directories( ${CMAKE_LIBRARY_PATH}  )
 223
 224 set(DBUS_INCLUDES)
 225
 226 ENABLE_TESTING()
 227
 228 ########### command line options ###############
 229 # TODO: take check from configure.in
 230
 231 option (DBUS_BUILD_TESTS "enable unit test code" ON)
 232
 233 if(DBUS_BUILD_TESTS)
 234     set (DBUS_ENABLE_EMBEDDED_TESTS ON)
 235     set (DBUS_ENABLE_MODULAR_TESTS ON)
 236     add_definitions(-DDBUS_ENABLE_EMBEDDED_TESTS -DDBUS_ENABLE_MODULAR_TESTS)
 237 endif(DBUS_BUILD_TESTS)
 238
 239 option (DBUS_USE_OUTPUT_DEBUG_STRING "enable win32 debug port for message output" OFF)
 240 if(DBUS_USE_OUTPUT_DEBUG_STRING)
 241     add_definitions(-DDBUS_USE_OUTPUT_DEBUG_STRING)
 242 endif(DBUS_USE_OUTPUT_DEBUG_STRING)
 243
 244 if(WIN32)
 245         # win32 dbus service support - this support is not complete
 246         option (DBUS_SERVICE "enable dbus service installer" OFF)
 247 endif(WIN32)
 248
 249 option (DBUS_ENABLE_ANSI "enable -ansi -pedantic gcc flags" OFF)
 250 if(DBUS_ENABLE_ANSI)
 251    if(NOT MSVC)
 252         add_definitions(-ansi -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -pedantic)
 253    else(NOT MSVC)
 254         add_definitions(-Za -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -W4)
 255    endif(NOT MSVC)
 256 endif(DBUS_ENABLE_ANSI)
 257
 258 option (DBUS_ENABLE_VERBOSE_MODE "support verbose debug mode" ON)
 259
 260 option (DBUS_DISABLE_CHECKS "Disable public API sanity checking" OFF)
 261
 262 if(NOT MSVC)
 263     option (DBUS_GCOV_ENABLED "compile with coverage profiling instrumentation (gcc only)" OFF)
 264     if(DBUS_GCOV_ENABLED)
 265             add_definitions(-fprofile-arcs -ftest-coverage)
 266             # FIXME!!!!
 267             ## remove optimization
 268     #        CFLAGS=`echo "$CFLAGS" | sed -e 's/-O[0-9]*//g'`
 269     endif(DBUS_GCOV_ENABLED)
 270 endif(NOT MSVC)
 271
 272 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 273     option (DBUS_BUS_ENABLE_INOTIFY "build with inotify support (linux only)" ON)
 274     if(DBUS_BUS_ENABLE_INOTIFY)
 275         check_include_file(sys/inotify.h HAVE_SYS_INOTIFY_H)
 276         if(NOT HAVE_SYS_INOTIFY_H)
 277             message(FATAL_ERROR "sys/inotify.h not found!")
 278         endif(NOT HAVE_SYS_INOTIFY_H)
 279     endif(DBUS_BUS_ENABLE_INOTIFY)
 280 elseif("${CMAKE_SYSTEM_NAME}" MATCHES ".*BSD")
 281     option (DBUS_BUS_ENABLE_KQUEUE "build with kqueue support (FreeBSD only)" ON)
 282     if(DBUS_BUS_ENABLE_KQUEUE)
 283         # cmake check a header by compiling a test program with
 284         # the header, sys/event.h needs stdint.h and sys/types.h
 285         # to work.
 286         check_include_files("stdint.h;sys/types.h;sys/event.h" HAVE_SYS_EVENT_H)
 287         if(NOT HAVE_SYS_EVENT_H)
 288             message(FATAL_ERROR "sys/event.h not found!")
 289         endif(NOT HAVE_SYS_EVENT_H)
 290     endif(DBUS_BUS_ENABLE_KQUEUE)
 291 endif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 292
 293 STRING(TOUPPER ${CMAKE_SYSTEM_NAME} sysname)
 294 if("${sysname}" MATCHES ".*SOLARIS.*")
 295     option (HAVE_CONSOLE_OWNER_FILE "enable console owner file (solaris only)" ON)
 296     if(HAVE_CONSOLE_OWNER_FILE)
 297         set (DBUS_CONSOLE_OWNER_FILE "/dev/console" CACHE STRING "Directory to check for console ownerhip")
 298     endif(HAVE_CONSOLE_OWNER_FILE)
 299 endif("${sysname}" MATCHES ".*SOLARIS.*")
 300
 301 if(NOT EXPAT_FOUND)
 302     message(FATAL_ERROR "expat not found!")
 303 endif(NOT EXPAT_FOUND)
 304
 305 SET(XML_LIB "Expat")
 306 SET(XML_LIBRARY     ${EXPAT_LIBRARIES})
 307 SET(XML_INCLUDE_DIR ${EXPAT_INCLUDE_DIR})
 308
 309 # all missing or hardcoded for now
 310
 311 # 'hidden' ones
 312 set(atomic_int OFF)
 313 set(atomic_int486 OFF)
 314 if(CMAKE_COMPILER_IS_GNUCC AND NOT DBUS_ENABLE_ANSI)
 315     FIND_PROGRAM(UNAME_EXECUTABLE
 316                     NAMES uname
 317                     PATHS /bin /usr/bin /usr/local/bin c:/Programme/MSys/bin d:/Programme/MSys/bin)
 318
 319     if(UNAME_EXECUTABLE)
 320         EXECUTE_PROCESS(COMMAND ${UNAME_EXECUTABLE} "-m"
 321                         OUTPUT_VARIABLE UNAME_OUTPUT)
 322
 323         if("UNAME_OUTPUT" MATCHES "^.*i[0123]86.*$")
 324             set(atomic_int ON)
 325         else("UNAME_OUTPUT" MATCHES "^.*i[0123]86.*$")
 326             if("UNAME_OUTPUT" MATCHES "^.*i?86.*$")
 327                 set(atomic_int ON)
 328                 set(atomic_int_486 ON)
 329             endif("UNAME_OUTPUT" MATCHES "^.*i?86.*$")
 330         endif("UNAME_OUTPUT" MATCHES "^.*i[0123]86.*$")
 331     endif(UNAME_EXECUTABLE)
 332 endif(CMAKE_COMPILER_IS_GNUCC AND NOT DBUS_ENABLE_ANSI)
 333
 334 set (DBUS_HAVE_ATOMIC_INT ${atomic_int} CACHE STRING "Some atomic integer implementation present")
 335 set (DBUS_USE_ATOMIC_INT_486 ${atomic_int_486} CACHE STRING "Use atomic integer implementation for 486")
 336
 337 if(X11_FOUND)
 338   option (DBUS_BUILD_X11 "Build with X11 autolaunch support " ON)
 339 endif(X11_FOUND)
 340
 341 # test binary names
 342 if (WIN32)
 343         # Automake calls this EXEEXT, and CMake doesn't have a standard name
 344         # for it; follow Automake's naming convention so we can share .in files
 345         set (EXEEXT ".exe")
 346 endif(WIN32)
 347
 348 if (MSVC_IDE)
 349     if(CMAKE_BUILD_TYPE MATCHES Debug)
 350                 set(IDE_BIN /Debug )
 351                 message(STATUS)
 352                 message(STATUS "Visual Studio: test programs will only work with 'Debug' configuration!")
 353                 message(STATUS "To run tests with 'Release' configuration use -DCMAKE_BUILD_TYPE=Release")
 354                 message(STATUS "Add '..\\..\\test\\data' to the command line option of the test programs")
 355                 message(STATUS)
 356     else(CMAKE_BUILD_TYPE MATCHES Debug)
 357                 set(IDE_BIN /Release)
 358                 message(STATUS)
 359                 message(STATUS "Visual Studio: test programs will only work with 'Release' configuration!")
 360                 message(STATUS "To run tests with 'Debug' configuration use -DCMAKE_BUILD_TYPE=Debug")
 361                 message(STATUS "Add '..\\..\\test\\data' to the command line option of the test programs")
 362                 message(STATUS)
 363     endif(CMAKE_BUILD_TYPE MATCHES Debug)
 364         set (TEST_PATH_FORCE FORCE)
 365         FILE(REMOVE ${CMAKE_BINARY_DIR}/data/dbus-1/services)
 366 endif (MSVC_IDE)
 367
 368 #### Find socket directories
 369  if (NOT $ENV{TMPDIR} STREQUAL "")
 370      set (DBUS_SESSION_SOCKET_DIR $ENV{TMPDIR})
 371  else (NOT $ENV{TMPDIR} STREQUAL "")
 372      if (NOT $ENV{TEMP} STREQUAL "")
 373          set (DBUS_SESSION_SOCKET_DIR $ENV{TEMP})
 374      else (NOT $ENV{TEMP} STREQUAL "")
 375          if (NOT $ENV{TMP} STREQUAL "")
 376              set (DBUS_SESSION_SOCKET_DIR $ENV{TMP})
 377          else (NOT $ENV{TMP} STREQUAL "")
 378          if (WIN32)
 379              #Should never happen, both TMP and TEMP seem always set on Windows
 380              message(FATAL_ERROR "Could not determine a usable temporary directory")
 381          else(WIN32)
 382             set (DBUS_SESSION_SOCKET_DIR /tmp)
 383          endif(WIN32)
 384          endif (NOT $ENV{TMP} STREQUAL "")
 385      endif (NOT $ENV{TEMP} STREQUAL "")
 386  endif (NOT $ENV{TMPDIR} STREQUAL "")
 387
 388 # TODO: fix redhet
 389 if (WIN32)
 390   # bus-test expects a non empty string
 391         set (DBUS_SYSTEM_PID_FILE "/dbus-pid")
 392 else (WIN32)
 393         set (DBUS_SYSTEM_PID_FILE ${EXPANDED_LOCALSTATEDIR}/run/dbus/pid)
 394 endif (WIN32)
 395
 396 if (WIN32)
 397         set (DBUS_CONSOLE_AUTH_DIR "")
 398 else (WIN32)
 399         set (DBUS_CONSOLE_AUTH_DIR "/var/run/console/")
 400 endif (WIN32)
 401
 402 set (DBUS_USER )
 403
 404 # In Autotools this has a different default on QNX, but there seems little
 405 # point in replicating that here; if you're on an unusual Unix, use Autotools.
 406 set (DEFAULT_MESSAGE_UNIX_FDS 1024)
 407
 408 # This won't work on Windows. It's not meant to - the system bus is
 409 # meaningless on Windows anyway.
 410 #
 411 # This has to be suitable for hard-coding in client libraries as well as
 412 # in the dbus-daemon's configuration, so it has to be valid to listen on
 413 # and also to connect to. If this ever changes, it'll need to be split into
 414 # two variables, one for the listening address and one for the connecting
 415 # address.
 416 set (DBUS_SYSTEM_BUS_DEFAULT_ADDRESS "unix:path=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket" CACHE STRING "system bus default address")
 417
 418 if (WIN32)
 419   set (DBUS_SESSION_BUS_LISTEN_ADDRESS "autolaunch:" CACHE STRING "session bus default listening address")
 420   set (DBUS_SESSION_BUS_CONNECT_ADDRESS "autolaunch:" CACHE STRING "session bus fallback address for clients")
 421
 422   set (DBUS_SYSTEM_CONFIG_FILE "etc/dbus-1/system.conf")
 423   set (DBUS_SESSION_CONFIG_FILE "etc/dbus-1/session.conf")
 424   # bus-test expects a non empty string
 425   set (DBUS_USER "Administrator")
 426 else (WIN32)
 427   set (DBUS_SESSION_BUS_LISTEN_ADDRESS "unix:tmpdir=${DBUS_SESSION_SOCKET_DIR}" CACHE STRING "session bus default listening address")
 428   set (DBUS_SESSION_BUS_CONNECT_ADDRESS "autolaunch:" CACHE STRING "session bus fallback address for clients")
 429   set (sysconfdir "")
 430   set (configdir ${sysconfdir}/dbus-1 )
 431   set (DBUS_SYSTEM_CONFIG_FILE  ${configdir}/system.conf)
 432   set (DBUS_SESSION_CONFIG_FILE ${configdir}/session.conf)
 433   set (DBUS_USER "root")
 434 endif (WIN32)
 435
 436 set (DBUS_DAEMON_NAME "dbus-daemon" CACHE STRING "The name of the dbus daemon executable")
 437
 438 ########### create config.h ###############
 439
 440 #include(ConfigureChecks.cmake)
 441
 442 # better use flags for gcc
 443 if (MINGW)
 444         set (HAVE_GNUC_VARARGS 1)
 445 endif(MINGW)
 446
 447 # compiler definitions
 448 add_definitions(-DHAVE_CONFIG_H=1)
 449 add_definitions(${DBUS_BUS_CFLAGS})
 450
 451
 452 if (DBUS_BUILD_TESTS)
 453     # set variables used for the .in files (substituted by configure_file) in test/data:
 454     set(DBUS_TEST_EXEC ${EXECUTABLE_OUTPUT_PATH}${IDE_BIN})
 455     set(DBUS_TEST_DATA ${CMAKE_BINARY_DIR}/test/data)
 456     set(TEST_SOCKET_DIR ${DBUS_SESSION_SOCKET_DIR} )
 457     set(TEST_LAUNCH_HELPER_BINARY ${EXECUTABLE_OUTPUT_PATH}/dbus-daemon-launch-helper-test)
 458     if (UNIX)
 459         set (TEST_LISTEN "unix:tmpdir=${TEST_SOCKET_DIR}")
 460     endif (UNIX)
 461     if (WIN32)
 462         set (TEST_LISTEN "tcp:host=localhost")
 463     endif (WIN32)
 464 endif  (DBUS_BUILD_TESTS)
 465
 466 set(DBUS_LIBRARIES dbus-1)
 467 set(DBUS_INTERNAL_LIBRARIES dbus-internal)
 468
 469 # settings for building and using static internal lib
 470 # important note: DBUS_INTERNAL_xxxxx_DEFINITIONS must *not* be set when building dbus-1 library
 471 set (DBUS_INTERNAL_ADD_LIBRARY_OPTIONS STATIC)
 472 set (DBUS_INTERNAL_LIBRARY_DEFINITIONS "-DDBUS_STATIC_BUILD")
 473 set (DBUS_INTERNAL_CLIENT_DEFINITIONS "-DDBUS_STATIC_BUILD")
 474
 475 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h )
 476
 477 if (WIN32)
 478 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/dbus-env.bat.cmake ${CMAKE_BINARY_DIR}/bin/dbus-env.bat )
 479 install_files(/bin FILES ${CMAKE_BINARY_DIR}/bin/dbus-env.bat)
 480 endif()
 481
 482 add_definitions(-DHAVE_CONFIG_H=1)
 483
 484 ########### subdirs ###############
 485
 486 add_subdirectory( dbus )
 487 add_subdirectory( bus )
 488 if (DBUS_BUILD_TESTS)
 489         add_subdirectory( test )
 490 endif (DBUS_BUILD_TESTS)
 491 add_subdirectory( tools )
 492 add_subdirectory( doc )
 493
 494
 495 OPTION(DBUS_INSTALL_SYSTEM_LIBS "install required system libraries" OFF)
 496 MESSAGE(" ")
 497 MESSAGE("set -DDBUS_INSTALL_SYSTEM_LIBS=1 to install runtime libraries too")
 498 MESSAGE("set DBUSDIR (environment or cmake option) to overwrite the default install directory ")
 499 MESSAGE(" ")
 500 MESSAGE(" ")
 501 GET_FILENAME_COMPONENT(C_COMPILER ${CMAKE_C_COMPILER} NAME)
 502 GET_FILENAME_COMPONENT(CXX_COMPILER ${CMAKE_CXX_COMPILER} NAME)
 503
 504 message("                  D-BUS ${DBUS_VERSION}                               ")
 505 message("                  ===========                                         ")
 506 message("                                                                      ")
 507 message("        install prefix:           ${prefix}                           ")
 508 message("        install exec_prefix:      ${exec_prefix}                      ")
 509 message("        install libdir:           ${EXPANDED_LIBDIR}                  ")
 510 message("        install bindir:           ${EXPANDED_BINDIR}                  ")
 511 message("        install sysconfdir:       ${EXPANDED_SYSCONFDIR}              ")
 512 message("        install datadir:          ${EXPANDED_DATADIR}                 ")
 513 message("        source code location:     ${DBUS_SOURCE_DIR}                  ")
 514 message("        build dir:                ${CMAKE_BINARY_DIR}                 ")
 515 message("        c compiler:               ${C_COMPILER}                       ")
 516 message("        cflags:                   ${CMAKE_C_FLAGS}                    ")
 517 message("        cflags debug:             ${CMAKE_C_FLAGS_DEBUG}              ")
 518 message("        cflags release:           ${CMAKE_C_FLAGS_RELEASE}            ")
 519 message("        cxx compiler:             ${CXX_COMPILER}                     ")
 520 message("        cxxflags:                 ${CMAKE_CXX_FLAGS}                  ")
 521 message("        cxxflags debug:           ${CMAKE_CXX_FLAGS_DEBUG}            ")
 522 message("        cxxflags release:         ${CMAKE_CXX_FLAGS_RELEASE}          ")
 523 message("        64-bit int:               ${DBUS_INT64_TYPE}                  ")
 524 message("        32-bit int:               ${DBUS_INT32_TYPE}                  ")
 525 message("        16-bit int:               ${DBUS_INT16_TYPE}                  ")
 526 message("        Doxygen:                  ${DOXYGEN}                          ")
 527 message("        Docbook Generator:        ${DOCBOOK_GENERATOR_NAME}           ")
 528
 529
 530 message("        gcc coverage profiling:   ${DBUS_GCOV_ENABLED}                ")
 531 message("        Building unit tests:      ${DBUS_BUILD_TESTS}                 ")
 532 message("        Building verbose mode:    ${DBUS_ENABLE_VERBOSE_MODE}         ")
 533 message("        Building w/o assertions:  ${DBUS_DISABLE_ASSERT}             ")
 534 message("        Building w/o checks:      ${DBUS_DISABLE_CHECKS}              ")
 535 message("        Building bus stats API:   ${DBUS_ENABLE_STATS}                ")
 536 message("        installing system libs:   ${DBUS_INSTALL_SYSTEM_LIBS}         ")
 537 message("        Building inotify support: ${DBUS_BUS_ENABLE_INOTIFY}          ")
 538 message("        Building kqueue support: ${DBUS_BUS_ENABLE_KQUEUE}            ")
 539 message("        Building Doxygen docs:    ${DBUS_ENABLE_DOXYGEN_DOCS}         ")
 540 message("        Building XML docs:        ${DBUS_ENABLE_XML_DOCS}             ")
 541 message("        Daemon executable name:   ${DBUS_DAEMON_NAME}")
 542 if (WIN32)
 543 message("        System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}  ")
 544 message("        Session bus listens on:   ${DBUS_SESSION_BUS_LISTEN_ADDRESS} ")
 545 message("        Session clients connect to: ${DBUS_SESSION_BUS_CONNECT_ADDRESS} ")
 546 else (WIN32)
 547 message("        System bus socket:        ${DBUS_SYSTEM_SOCKET}               ")
 548 message("        System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}  ")
 549 message("        System bus PID file:      ${DBUS_SYSTEM_PID_FILE}             ")
 550 message("        Session bus socket dir:   ${DBUS_SESSION_SOCKET_DIR}          ")
 551 message("        Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}            ")
 552 message("        System bus user:          ${DBUS_USER}                        ")
 553 message("        'make check' socket dir:  ${TEST_SOCKET_DIR}                  ")
 554 endif (WIN32)
 555 message("        Test listen address:      ${TEST_LISTEN}                      ")
 556 if (MSVC)
 557 message("        build timestamp:          ${DBUS_BUILD_TIMESTAMP}             ")
 558 endif (MSVC)
 559
 560 MESSAGE(" ")
 561 if (DBUS_BUILD_TESTS)
 562     message("NOTE: building with unit tests increases the size of the installed library and renders it insecure.")
 563 endif(DBUS_BUILD_TESTS)
 564
 565 if (DBUS_BUILD_TESTS AND DBUS_DISABLE_ASSERT)
 566     message("NOTE: building with unit tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)")
 567 endif(DBUS_BUILD_TESTS AND DBUS_DISABLE_ASSERT)
 568
 569 if (DBUS_GCOV_ENABLED)
 570     message("NOTE: building with coverage profiling is definitely for developers only.")
 571 endif(DBUS_GCOV_ENABLED)
 572
 573 if (DBUS_ENABLE_VERBOSE_MODE)
 574     message("NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance.")
 575 endif(DBUS_ENABLE_VERBOSE_MODE)
 576
 577 if(NOT DBUS_DISABLE_ASSERT)
 578     message("NOTE: building with assertions increases library size and decreases performance.")
 579 endif(NOT DBUS_DISABLE_ASSERT)
 580
 581 if (DBUS_DISABLE_CHECKS)
 582     message("NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-BUS, but will slightly decrease D-BUS library size and _very_ slightly improve performance.")
 583 endif(DBUS_DISABLE_CHECKS)
 584 MESSAGE(" ")
 585
 586 INCLUDE(modules/CPackInstallConfig.cmake)
 587
 588 add_custom_target(help-options
 589     cmake -LH
 590     WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 591 )