cmake/CMakeLists.txt

   1 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
   3
   4 # we do not need to have WIN32 defined
   5 set(CMAKE_LEGACY_CYGWIN_WIN32 0)
   6
   7 project(dbus)
   8
   9 # we need to be up to date
  10 CMAKE_MINIMUM_REQUIRED(VERSION 2.4.4 FATAL_ERROR)
  11 if(COMMAND cmake_policy)
  12     cmake_policy(SET CMP0003 NEW)
  13 endif(COMMAND cmake_policy)
  14
  15
  16 # detect version
  17 include(MacrosAutotools)
  18 autoversion(../configure.ac dbus)
  19 # used by file version info
  20 set (DBUS_PATCH_VERSION "0")
  21
  22 include(Macros)
  23 TIMESTAMP(DBUS_BUILD_TIMESTAMP)
  24
  25 ########### basic vars ###############
  26
  27
  28 if (DBUSDIR)
  29         set(DBUS_INSTALL_DIR "${DBUSDIR}")
  30 endif (DBUSDIR)
  31 if ($ENV{DBUSDIR})
  32         set(DBUS_INSTALL_DIR "$ENV{DBUSDIR}")
  33 endif ($ENV{DBUSDIR})
  34
  35 if (DBUS_INSTALL_DIR)
  36         set(CMAKE_INSTALL_PREFIX "${DBUS_INSTALL_DIR}" CACHE PATH "install prefix" FORCE)
  37 else (DBUS_INSTALL_DIR)
  38         set(DBUS_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}")
  39 endif (DBUS_INSTALL_DIR)
  40
  41 # autotools style
  42 if (NOT DATAROOTDIR)
  43     set (DATAROOTDIR share)
  44 endif()
  45
  46 if (NOT DATADIR)
  47     set (DATADIR ${DATAROOTDIR})
  48 endif()
  49
  50 if (NOT DOCDIR)
  51     SET(DOCDIR ${DATAROOTDIR}/doc/dbus)
  52 endif()
  53
  54 if (NOT DBUS_DATADIR)
  55     SET(DBUS_DATADIR ${DATADIR})
  56 endif()
  57
  58 set(prefix                   ${DBUS_INSTALL_DIR})
  59 set(exec_prefix              ${prefix})
  60 set(EXPANDED_LIBDIR          ${DBUS_INSTALL_DIR}/lib)
  61 set(EXPANDED_INCLUDEDIR      ${DBUS_INSTALL_DIR}/include)
  62 set(EXPANDED_BINDIR          ${DBUS_INSTALL_DIR}/bin)
  63 set(EXPANDED_SYSCONFDIR      ${DBUS_INSTALL_DIR}/etc)
  64 set(EXPANDED_DATADIR         ${DBUS_INSTALL_DIR}/${DBUS_DATADIR})
  65 set(DBUS_MACHINE_UUID_FILE   ${DBUS_INSTALL_DIR}/lib/dbus/machine-id)
  66 set(DBUS_BINDIR              ${EXPANDED_BINDIR})
  67 set(DBUS_DAEMONDIR           ${EXPANDED_BINDIR})
  68
  69
  70 #enable building of shared library
  71 SET(BUILD_SHARED_LIBS ON)
  72
  73 if(WIN32)
  74     set(INSTALL_TARGETS_DEFAULT_ARGS  RUNTIME DESTINATION "bin" LIBRARY DESTINATION "lib" ARCHIVE DESTINATION "lib")
  75 else()
  76     set(INSTALL_TARGETS_DEFAULT_ARGS  RUNTIME DESTINATION "${EXPANDED_LIBDIR}" LIBRARY DESTINATION "${EXPANDED_LIBDIR}" ARCHIVE DESTINATION "${EXPANDED_LIBDIR}")
  77 endif()
  78
  79 if (CYGWIN)
  80    set (WIN32)
  81 endif (CYGWIN)
  82
  83 # search for required packages
  84 if (WIN32)
  85     # include local header first to avoid using old installed header
  86     set (CMAKE_INCLUDE_PATH ${CMAKE_INCLUDE_PATH} ${CMAKE_SOURCE_DIR}/..)
  87         find_package(LibIconv)
  88     include(Win32Macros)
  89     addExplorerWrapper(${CMAKE_PROJECT_NAME})
  90 endif (WIN32)
  91
  92 if(NOT WIN32)
  93         option (DBUS_ENABLE_ABSTRACT_SOCKETS "enable support for abstract sockets" ON)
  94         set (CMAKE_THREAD_PREFER_PTHREAD ON)
  95         include (FindThreads)
  96 endif(NOT WIN32)
  97
  98 option (DBUS_DISABLE_ASSERT "Disable assertion checking" OFF)
  99
 100 option (DBUS_ENABLE_STATS "enable bus daemon usage statistics" OFF)
 101
 102 find_package(EXPAT)
 103 find_package(X11)
 104
 105 # analogous to AC_USE_SYSTEM_EXTENSIONS in configure.ac
 106 add_definitions(-D_POSIX_C_SOURCE=199309L -D_GNU_SOURCE)
 107
 108 # do config checks
 109 INCLUDE(ConfigureChecks.cmake)
 110
 111 # @TODO: how to remove last dir from ${CMAKE_SOURCE_DIR} ?
 112 SET(DBUS_SOURCE_DIR ${CMAKE_SOURCE_DIR}/..)
 113
 114 # make some more macros available
 115 include (MacroLibrary)
 116
 117 if(VCS)
 118         set(DBUS_VERBOSE_C_S 1 CACHE STRING "verbose mode" FORCE)
 119 endif(VCS)
 120
 121 if(WIN32)
 122         set(CMAKE_DEBUG_POSTFIX "d")
 123         if(MSVC)
 124                 # controll folders in msvc projects
 125                 include(ProjectSourceGroup)
 126                 if(NOT GROUP_CODE)
 127                         #set(GROUP_CODE split) #cmake default
 128                         set(GROUP_CODE flat)
 129                 endif(NOT GROUP_CODE)
 130                 ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 131
 132
 133                 # Use the highest warning level
 134                 if (WALL)
 135                         set(WALL 1 CACHE STRING "all warnings"  FORCE)
 136                         set(CMAKE_CXX_WARNING_LEVEL 4 CACHE STRING "warning level" FORCE)
 137
 138                         if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 139                                 STRING(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 140                         else(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 141                                 SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 142                         endif(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 143
 144                         if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 145                                 STRING(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 146                         else(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 147                                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 148                         endif(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 149                 else (WALL)
 150                         set(CMAKE_CXX_WARNING_LEVEL 3 CACHE STRING "warning level" FORCE)
 151                 endif (WALL)
 152
 153                 SET(MSVC_W_ERROR   " /we4028 /we4013 /we4133 /we4047 /we4031 /we4002 /we4003 /we4114")
 154                 SET(MSVC_W_DISABLE " /wd4127 /wd4090 /wd4101 /wd4244")
 155
 156                 SET(CMAKE_C_FLAGS_DEBUG   "${CMAKE_C_FLAGS_DEBUG}   /FIconfig.h ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 157                 SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} /FIconfig.h ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 158         endif(MSVC)
 159 endif(WIN32)
 160
 161 if (UNIX AND NOT DBUS_DISABLE_ASSERT)
 162         # required for backtrace
 163         SET(CMAKE_C_FLAGS_DEBUG   "${CMAKE_C_FLAGS_DEBUG}   -Wl,--export-dynamic")
 164         SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -Wl,--export-dynamic")
 165         add_definitions(-DDBUS_BUILT_R_DYNAMIC)
 166 endif (UNIX AND NOT DBUS_DISABLE_ASSERT)
 167
 168 SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG}  -D_DEBUG")
 169
 170 #########################################################################
 171 # Windows CE (>= 5.0.0)
 172 #
 173 # WinCE support now relies on the presence of platform files, found in cmake/modules/platform
 174 # Cmake 2.8.0 doesn't include WinCE platform files by default, but working ones can be found
 175 # on CMake's bugtracker :
 176 # http://public.kitware.com/Bug/view.php?id=7919
 177 #
 178 # for cmake 2.8.0 get the following patch only :
 179 # http://public.kitware.com/Bug/file_download.php?file_id=2944&type=bug
 180 #
 181 # after applying the patch, you can enable the WinCE build by specifying :
 182 # cmake [...] -DCMAKE_SYSTEM_NAME=WinCE -DCMAKE_SYSTEM_VERSION=X.XX
 183 # (where X.XX is your actual WinCE version, e.g. 5.02 for Windows Mobile 6)
 184 #
 185 # Note that you should have a proper cross-compilation environment set up prior to running
 186 # cmake, ie. the PATH, INCLUDE and LIB env vars pointing to your CE SDK/toolchain.
 187 #
 188 if(WINCE)
 189
 190 MESSAGE("Building for WinCE (${CMAKE_SYSTEM_VERSION})")
 191
 192 endif(WINCE)
 193 #########################################################################
 194
 195
 196 ENABLE_TESTING()
 197
 198 #########################################################################
 199 # Disallow in-source build
 200 #macro_ensure_out_of_source_build("dbus requires an out of source build. Please create a separate build directory and run 'cmake path_to_dbus [options]' there.")
 201
 202 # ... and warn in case of an earlier in-source build
 203 #set(generatedFileInSourceDir EXISTS ${dbus_SOURCE_DIR}/config.h)
 204 #if(${generatedFileInSourceDir})
 205 #   message(STATUS "config.h exists in your source directory.")
 206 #endif(${generatedFileInSourceDir})
 207 #########################################################################
 208
 209 if (WIN32 OR CYGWIN)
 210         set (LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
 211 else (WIN32 OR CYGWIN)
 212         set (LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
 213 endif (WIN32 OR CYGWIN)
 214
 215 set (EXECUTABLE_OUTPUT_PATH ${CMAKE_BINARY_DIR}/bin)
 216
 217 # for including config.h and for includes like <dir/foo.h>
 218 include_directories( ${CMAKE_SOURCE_DIR}/.. ${CMAKE_BINARY_DIR} ${CMAKE_INCLUDE_PATH} )
 219
 220 # linker search directories
 221 link_directories(${DBUS_LIB_DIR} ${LIBRARY_OUTPUT_PATH} )
 222 include_directories( ${CMAKE_LIBRARY_PATH}  )
 223
 224 set(DBUS_INCLUDES)
 225
 226 ENABLE_TESTING()
 227
 228 ########### command line options ###############
 229 # TODO: take check from configure.in
 230
 231 option (DBUS_BUILD_TESTS "enable unit test code" ON)
 232
 233 if(DBUS_BUILD_TESTS)
 234     add_definitions(-DDBUS_BUILD_TESTS -DDBUS_ENABLE_EMBEDDED_TESTS)
 235 endif(DBUS_BUILD_TESTS)
 236
 237 option (DBUS_USE_OUTPUT_DEBUG_STRING "enable win32 debug port for message output" OFF)
 238 if(DBUS_USE_OUTPUT_DEBUG_STRING)
 239     add_definitions(-DDBUS_USE_OUTPUT_DEBUG_STRING)
 240 endif(DBUS_USE_OUTPUT_DEBUG_STRING)
 241
 242 if(WIN32)
 243         # win32 dbus service support - this support is not complete
 244         option (DBUS_SERVICE "enable dbus service installer" OFF)
 245 endif(WIN32)
 246
 247 option (DBUS_ENABLE_ANSI "enable -ansi -pedantic gcc flags" OFF)
 248 if(DBUS_ENABLE_ANSI)
 249    if(NOT MSVC)
 250         add_definitions(-ansi -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -pedantic)
 251    else(NOT MSVC)
 252         add_definitions(-Za -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -W4)
 253    endif(NOT MSVC)
 254 endif(DBUS_ENABLE_ANSI)
 255
 256 option (DBUS_ENABLE_VERBOSE_MODE "support verbose debug mode" ON)
 257
 258 option (DBUS_DISABLE_CHECKS "Disable public API sanity checking" OFF)
 259
 260 if(NOT MSVC)
 261     option (DBUS_GCOV_ENABLED "compile with coverage profiling instrumentation (gcc only)" OFF)
 262     if(DBUS_GCOV_ENABLED)
 263             add_definitions(-fprofile-arcs -ftest-coverage)
 264             # FIXME!!!!
 265             ## remove optimization
 266     #        CFLAGS=`echo "$CFLAGS" | sed -e 's/-O[0-9]*//g'`
 267     endif(DBUS_GCOV_ENABLED)
 268 endif(NOT MSVC)
 269
 270 STRING(TOUPPER ${CMAKE_SYSTEM_NAME} sysname)
 271 if("${sysname}" MATCHES ".*SOLARIS.*")
 272     option (HAVE_CONSOLE_OWNER_FILE "enable console owner file (solaris only)" ON)
 273     if(HAVE_CONSOLE_OWNER_FILE)
 274         set (DBUS_CONSOLE_OWNER_FILE "/dev/console" CACHE STRING "Directory to check for console ownerhip")
 275     endif(HAVE_CONSOLE_OWNER_FILE)
 276 endif("${sysname}" MATCHES ".*SOLARIS.*")
 277
 278 if(NOT EXPAT_FOUND)
 279     message(FATAL_ERROR "expat not found!")
 280 endif(NOT EXPAT_FOUND)
 281
 282 SET(XML_LIB "Expat")
 283 SET(XML_LIBRARY     ${EXPAT_LIBRARIES})
 284 SET(XML_INCLUDE_DIR ${EXPAT_INCLUDE_DIR})
 285
 286 # all missing or hardcoded for now
 287
 288 # 'hidden' ones
 289 set(atomic_int OFF)
 290 set(atomic_int486 OFF)
 291 if(CMAKE_COMPILER_IS_GNUCC AND NOT DBUS_ENABLE_ANSI)
 292     FIND_PROGRAM(UNAME_EXECUTABLE
 293                     NAMES uname
 294                     PATHS /bin /usr/bin /usr/local/bin c:/Programme/MSys/bin d:/Programme/MSys/bin)
 295
 296     if(UNAME_EXECUTABLE)
 297         EXECUTE_PROCESS(COMMAND ${UNAME_EXECUTABLE} "-m"
 298                         OUTPUT_VARIABLE UNAME_OUTPUT)
 299
 300         if("UNAME_OUTPUT" MATCHES "^.*i[0123]86.*$")
 301             set(atomic_int ON)
 302         else("UNAME_OUTPUT" MATCHES "^.*i[0123]86.*$")
 303             if("UNAME_OUTPUT" MATCHES "^.*i?86.*$")
 304                 set(atomic_int ON)
 305                 set(atomic_int_486 ON)
 306             endif("UNAME_OUTPUT" MATCHES "^.*i?86.*$")
 307         endif("UNAME_OUTPUT" MATCHES "^.*i[0123]86.*$")
 308     endif(UNAME_EXECUTABLE)
 309 endif(CMAKE_COMPILER_IS_GNUCC AND NOT DBUS_ENABLE_ANSI)
 310
 311 set (DBUS_HAVE_ATOMIC_INT ${atomic_int} CACHE STRING "Some atomic integer implementation present")
 312 set (DBUS_USE_ATOMIC_INT_486 ${atomic_int_486} CACHE STRING "Use atomic integer implementation for 486")
 313
 314 if(X11_FOUND)
 315   option (DBUS_BUILD_X11 "Build with X11 autolaunch support " ON)
 316 endif(X11_FOUND)
 317
 318 # test binary names
 319 if (WIN32)
 320         # Automake calls this EXEEXT, and CMake doesn't have a standard name
 321         # for it; follow Automake's naming convention so we can share .in files
 322         set (EXEEXT ".exe")
 323 endif(WIN32)
 324
 325 if (MSVC_IDE)
 326     if(CMAKE_BUILD_TYPE MATCHES Debug)
 327                 set(IDE_BIN /Debug )
 328                 message(STATUS)
 329                 message(STATUS "Visual Studio: test programs will only work with 'Debug' configuration!")
 330                 message(STATUS "To run tests with 'Release' configuration use -DCMAKE_BUILD_TYPE=Release")
 331                 message(STATUS "Add '..\\..\\test\\data' to the command line option of the test programs")
 332                 message(STATUS)
 333     else(CMAKE_BUILD_TYPE MATCHES Debug)
 334                 set(IDE_BIN /Release)
 335                 message(STATUS)
 336                 message(STATUS "Visual Studio: test programs will only work with 'Release' configuration!")
 337                 message(STATUS "To run tests with 'Debug' configuration use -DCMAKE_BUILD_TYPE=Debug")
 338                 message(STATUS "Add '..\\..\\test\\data' to the command line option of the test programs")
 339                 message(STATUS)
 340     endif(CMAKE_BUILD_TYPE MATCHES Debug)
 341         set (TEST_PATH_FORCE FORCE)
 342         FILE(REMOVE ${CMAKE_BINARY_DIR}/data/dbus-1/services)
 343 endif (MSVC_IDE)
 344
 345 #### Find socket directories
 346  if (NOT $ENV{TMPDIR} STREQUAL "")
 347      set (DBUS_SESSION_SOCKET_DIR $ENV{TMPDIR})
 348  else (NOT $ENV{TMPDIR} STREQUAL "")
 349      if (NOT $ENV{TEMP} STREQUAL "")
 350          set (DBUS_SESSION_SOCKET_DIR $ENV{TEMP})
 351      else (NOT $ENV{TEMP} STREQUAL "")
 352          if (NOT $ENV{TMP} STREQUAL "")
 353              set (DBUS_SESSION_SOCKET_DIR $ENV{TMP})
 354          else (NOT $ENV{TMP} STREQUAL "")
 355          if (WIN32)
 356              #Should never happen, both TMP and TEMP seem always set on Windows
 357              message(FATAL_ERROR "Could not determine a usable temporary directory")
 358          else(WIN32)
 359             set (DBUS_SESSION_SOCKET_DIR /tmp)
 360          endif(WIN32)
 361          endif (NOT $ENV{TMP} STREQUAL "")
 362      endif (NOT $ENV{TEMP} STREQUAL "")
 363  endif (NOT $ENV{TMPDIR} STREQUAL "")
 364
 365 # TODO: fix redhet
 366 if (WIN32)
 367   # bus-test expects a non empty string
 368         set (DBUS_SYSTEM_PID_FILE "/dbus-pid")
 369 else (WIN32)
 370         set (DBUS_SYSTEM_PID_FILE ${EXPANDED_LOCALSTATEDIR}/run/dbus/pid)
 371 endif (WIN32)
 372
 373 if (WIN32)
 374         set (DBUS_CONSOLE_AUTH_DIR "")
 375 else (WIN32)
 376         set (DBUS_CONSOLE_AUTH_DIR "/var/run/console/")
 377 endif (WIN32)
 378
 379 set (DBUS_USER )
 380
 381 # In Autotools this has a different default on QNX, but there seems little
 382 # point in replicating that here; if you're on an unusual Unix, use Autotools.
 383 set (DEFAULT_MESSAGE_UNIX_FDS 1024)
 384
 385 # This won't work on Windows. It's not meant to - the system bus is
 386 # meaningless on Windows anyway.
 387 #
 388 # This has to be suitable for hard-coding in client libraries as well as
 389 # in the dbus-daemon's configuration, so it has to be valid to listen on
 390 # and also to connect to. If this ever changes, it'll need to be split into
 391 # two variables, one for the listening address and one for the connecting
 392 # address.
 393 set (DBUS_SYSTEM_BUS_DEFAULT_ADDRESS "unix:path=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket" CACHE STRING "system bus default address")
 394
 395 if (WIN32)
 396   set (DBUS_SESSION_BUS_LISTEN_ADDRESS "autolaunch:" CACHE STRING "session bus default listening address")
 397   set (DBUS_SESSION_BUS_CONNECT_ADDRESS "autolaunch:" CACHE STRING "session bus fallback address for clients")
 398
 399   set (DBUS_SYSTEM_CONFIG_FILE "etc/dbus-1/system.conf")
 400   set (DBUS_SESSION_CONFIG_FILE "etc/dbus-1/session.conf")
 401   # bus-test expects a non empty string
 402   set (DBUS_USER "Administrator")
 403 else (WIN32)
 404   set (DBUS_SESSION_BUS_LISTEN_ADDRESS "unix:tmpdir=${DBUS_SESSION_SOCKET_DIR}" CACHE STRING "session bus default listening address")
 405   set (DBUS_SESSION_BUS_CONNECT_ADDRESS "autolaunch:" CACHE STRING "session bus fallback address for clients")
 406   set (sysconfdir "")
 407   set (configdir ${sysconfdir}/dbus-1 )
 408   set (DBUS_SYSTEM_CONFIG_FILE  ${configdir}/system.conf)
 409   set (DBUS_SESSION_CONFIG_FILE ${configdir}/session.conf)
 410   set (DBUS_USER "root")
 411 endif (WIN32)
 412
 413 set (DBUS_DAEMON_NAME "dbus-daemon" CACHE STRING "The name of the dbus daemon executable")
 414
 415 ########### create config.h ###############
 416
 417 #include(ConfigureChecks.cmake)
 418
 419 # better use flags for gcc
 420 if (MINGW)
 421         set (HAVE_GNUC_VARARGS 1)
 422 endif(MINGW)
 423
 424 # compiler definitions
 425 add_definitions(-DHAVE_CONFIG_H=1)
 426 add_definitions(${DBUS_BUS_CFLAGS})
 427
 428
 429 if (DBUS_BUILD_TESTS)
 430     # set variables used for the .in files (substituted by configure_file) in test/data:
 431     set(DBUS_TEST_EXEC ${EXECUTABLE_OUTPUT_PATH}${IDE_BIN})
 432     set(DBUS_TEST_DATA ${CMAKE_BINARY_DIR}/test/data)
 433     set(TEST_SOCKET_DIR ${DBUS_SESSION_SOCKET_DIR} )
 434     set(TEST_LAUNCH_HELPER_BINARY ${EXECUTABLE_OUTPUT_PATH}/dbus-daemon-launch-helper-test)
 435     if (UNIX)
 436         set (TEST_LISTEN "unix:tmpdir=${TEST_SOCKET_DIR}")
 437     endif (UNIX)
 438     if (WIN32)
 439         set (TEST_LISTEN "tcp:host=localhost")
 440     endif (WIN32)
 441 endif  (DBUS_BUILD_TESTS)
 442
 443 set(DBUS_LIBRARIES dbus-1)
 444 set(DBUS_INTERNAL_LIBRARIES dbus-internal)
 445
 446 # settings for building and using static internal lib
 447 # important note: DBUS_INTERNAL_xxxxx_DEFINITIONS must *not* be set when building dbus-1 library
 448 set (DBUS_INTERNAL_ADD_LIBRARY_OPTIONS STATIC)
 449 set (DBUS_INTERNAL_LIBRARY_DEFINITIONS "-DDBUS_STATIC_BUILD")
 450 set (DBUS_INTERNAL_CLIENT_DEFINITIONS "-DDBUS_STATIC_BUILD")
 451
 452 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h )
 453
 454 if (WIN32)
 455 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/dbus-env.bat.cmake ${CMAKE_BINARY_DIR}/bin/dbus-env.bat )
 456 install_files(/bin FILES ${CMAKE_BINARY_DIR}/bin/dbus-env.bat)
 457 endif()
 458
 459 add_definitions(-DHAVE_CONFIG_H=1)
 460
 461 ########### subdirs ###############
 462
 463 add_subdirectory( dbus )
 464 add_subdirectory( bus )
 465 if (DBUS_BUILD_TESTS)
 466         add_subdirectory( test )
 467 endif (DBUS_BUILD_TESTS)
 468 add_subdirectory( tools )
 469 add_subdirectory( doc )
 470
 471
 472 OPTION(DBUS_INSTALL_SYSTEM_LIBS "install required system libraries" OFF)
 473 MESSAGE(" ")
 474 MESSAGE("set -DDBUS_INSTALL_SYSTEM_LIBS=1 to install runtime libraries too")
 475 MESSAGE("set DBUSDIR (environment or cmake option) to overwrite the default install directory ")
 476 MESSAGE(" ")
 477 MESSAGE(" ")
 478 GET_FILENAME_COMPONENT(C_COMPILER ${CMAKE_C_COMPILER} NAME)
 479 GET_FILENAME_COMPONENT(CXX_COMPILER ${CMAKE_CXX_COMPILER} NAME)
 480
 481 message("                  D-BUS ${DBUS_VERSION}                               ")
 482 message("                  ===========                                         ")
 483 message("                                                                      ")
 484 message("        install prefix:           ${prefix}                           ")
 485 message("        install exec_prefix:      ${exec_prefix}                      ")
 486 message("        install libdir:           ${EXPANDED_LIBDIR}                  ")
 487 message("        install bindir:           ${EXPANDED_BINDIR}                  ")
 488 message("        install sysconfdir:       ${EXPANDED_SYSCONFDIR}              ")
 489 message("        install datadir:          ${EXPANDED_DATADIR}                 ")
 490 message("        source code location:     ${DBUS_SOURCE_DIR}                  ")
 491 message("        build dir:                ${CMAKE_BINARY_DIR}                 ")
 492 message("        c compiler:               ${C_COMPILER}                       ")
 493 message("        cflags:                   ${CMAKE_C_FLAGS}                    ")
 494 message("        cflags debug:             ${CMAKE_C_FLAGS_DEBUG}              ")
 495 message("        cflags release:           ${CMAKE_C_FLAGS_RELEASE}            ")
 496 message("        cxx compiler:             ${CXX_COMPILER}                     ")
 497 message("        cxxflags:                 ${CMAKE_CXX_FLAGS}                  ")
 498 message("        cxxflags debug:           ${CMAKE_CXX_FLAGS_DEBUG}            ")
 499 message("        cxxflags release:         ${CMAKE_CXX_FLAGS_RELEASE}          ")
 500 message("        64-bit int:               ${DBUS_INT64_TYPE}                  ")
 501 message("        32-bit int:               ${DBUS_INT32_TYPE}                  ")
 502 message("        16-bit int:               ${DBUS_INT16_TYPE}                  ")
 503 message("        Doxygen:                  ${DOXYGEN}                          ")
 504 message("        Docbook Generator:        ${DOCBOOK_GENERATOR_NAME}           ")
 505
 506
 507 message("        gcc coverage profiling:   ${DBUS_GCOV_ENABLED}                ")
 508 message("        Building unit tests:      ${DBUS_BUILD_TESTS}                 ")
 509 message("        Building verbose mode:    ${DBUS_ENABLE_VERBOSE_MODE}         ")
 510 message("        Building w/o assertions:  ${DBUS_DISABLE_ASSERT}             ")
 511 message("        Building w/o checks:      ${DBUS_DISABLE_CHECKS}              ")
 512 message("        Building bus stats API:   ${DBUS_ENABLE_STATS}                ")
 513 message("        installing system libs:   ${DBUS_INSTALL_SYSTEM_LIBS}         ")
 514 message("        Building Doxygen docs:    ${DBUS_ENABLE_DOXYGEN_DOCS}         ")
 515 message("        Building XML docs:        ${DBUS_ENABLE_XML_DOCS}             ")
 516 message("        Daemon executable name:   ${DBUS_DAEMON_NAME}")
 517 if (WIN32)
 518 message("        System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}  ")
 519 message("        Session bus listens on:   ${DBUS_SESSION_BUS_LISTEN_ADDRESS} ")
 520 message("        Session clients connect to: ${DBUS_SESSION_BUS_CONNECT_ADDRESS} ")
 521 else (WIN32)
 522 message("        System bus socket:        ${DBUS_SYSTEM_SOCKET}               ")
 523 message("        System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}  ")
 524 message("        System bus PID file:      ${DBUS_SYSTEM_PID_FILE}             ")
 525 message("        Session bus socket dir:   ${DBUS_SESSION_SOCKET_DIR}          ")
 526 message("        Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}            ")
 527 message("        System bus user:          ${DBUS_USER}                        ")
 528 message("        'make check' socket dir:  ${TEST_SOCKET_DIR}                  ")
 529 endif (WIN32)
 530 message("        Test listen address:      ${TEST_LISTEN}                      ")
 531 if (MSVC)
 532 message("        build timestamp:          ${DBUS_BUILD_TIMESTAMP}             ")
 533 endif (MSVC)
 534
 535 MESSAGE(" ")
 536 if (DBUS_BUILD_TESTS)
 537     message("NOTE: building with unit tests increases the size of the installed library and renders it insecure.")
 538 endif(DBUS_BUILD_TESTS)
 539
 540 if (DBUS_BUILD_TESTS AND DBUS_DISABLE_ASSERT)
 541     message("NOTE: building with unit tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)")
 542 endif(DBUS_BUILD_TESTS AND DBUS_DISABLE_ASSERT)
 543
 544 if (DBUS_GCOV_ENABLED)
 545     message("NOTE: building with coverage profiling is definitely for developers only.")
 546 endif(DBUS_GCOV_ENABLED)
 547
 548 if (DBUS_ENABLE_VERBOSE_MODE)
 549     message("NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance.")
 550 endif(DBUS_ENABLE_VERBOSE_MODE)
 551
 552 if(NOT DBUS_DISABLE_ASSERT)
 553     message("NOTE: building with assertions increases library size and decreases performance.")
 554 endif(NOT DBUS_DISABLE_ASSERT)
 555
 556 if (DBUS_DISABLE_CHECKS)
 557     message("NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-BUS, but will slightly decrease D-BUS library size and _very_ slightly improve performance.")
 558 endif(DBUS_DISABLE_CHECKS)
 559 MESSAGE(" ")
 560
 561 INCLUDE(modules/CPackInstallConfig.cmake)
 562
 563 add_custom_target(help-options
 564     cmake -LH
 565     WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 566 )