clients/meson.build

   1 wayland_tbm_client = dependency('wayland-tbm-client', required: false)
   2 libtbm = dependency('libtbm', required: false)
   3 tizen_extension_client = dependency('tizen-extension-client', required: true)
   4
   5 if not wayland_tbm_client.found() or not libtbm.found()
   6   subdir_done()
   7 endif
   8
   9 simple_tbm_files = ['simple-tbm.c']
  10 simple_tbm_deps = [
  11   dependency('wayland-client', required: true),
  12   wayland_tbm_client,
  13   libtbm,
  14   tizen_extension_client,
  15 ]
  16
  17 protocols = {
  18   'xdg-shell': wl_protocol_dir / 'stable/xdg-shell/xdg-shell.xml',
  19 }
  20
  21 protocols_code = {}
  22 protocols_client_header = {}
  23 foreach name, path : protocols
  24   code = custom_target(
  25     name.underscorify() + '_c',
  26     input: path,
  27     output: '@BASENAME@-protocol.c',
  28     command: [wayland_scanner, 'private-code', '@INPUT@', '@OUTPUT@'],
  29     )
  30   simple_tbm_files += code
  31
  32   client_header = custom_target(
  33     name.underscorify() + '_client_h',
  34     input: path,
  35     output: '@BASENAME@-client-protocol.h',
  36     command: [wayland_scanner, 'client-header', '@INPUT@', '@OUTPUT@'],
  37     build_by_default: false,
  38   )
  39   simple_tbm_files += client_header
  40 endforeach
  41
  42 executable('ds-simple-tbm',
  43   simple_tbm_files,
  44   dependencies: [simple_tbm_deps,
  45   deps_libds_tizen_text_input,
  46   ],
  47   install_dir: libds_tizen_bindir,
  48   install: true,
  49 )
  50
  51 executable('ds-simple-dpms',
  52   'simple-dpms.c',
  53   dependencies: [
  54       dependency('wayland-client', required: true),
  55       dependency('tizen-dpms-client', required: true),
  56     ],
  57   install_dir: libds_tizen_bindir,
  58   install: true,
  59 )
  60
  61 input_generator_files = ['input-generator.c']
  62 input_generator_deps = [
  63   dependency('wayland-client', required: true),
  64   tizen_extension_client,
  65 ]
  66
  67 executable('input-generator',
  68   input_generator_files,
  69   dependencies: [input_generator_deps,
  70   deps_libds_tizen_input_method,
  71   ],
  72   install_dir: libds_tizen_bindir,
  73   install: true,
  74 )