clean.cmd

   1 @if not defined __echo @echo off
   2 setlocal EnableDelayedExpansion
   3
   4 echo Running clean.cmd
   5
   6 set bin=false
   7 set packages=false
   8 set tools = false
   9
  10 if [%1]==[] (
  11   set bin=true
  12   set packages=true
  13   set tools=true
  14   goto Begin
  15 )
  16
  17 :Loop
  18 if [%1]==[] goto Begin
  19
  20 if /I [%1] == [/?] goto Usage
  21 if /I [%1] == [/help] goto Usage
  22
  23 if /I [%1] == [/p] (
  24     set packages=true
  25     set thisArgs=!thisArgs!%1
  26     goto Next
  27 )
  28
  29 if /I [%1] == [/b] (
  30     set bin=true
  31     set thisArgs=!thisArgs!%1
  32     goto Next
  33 )
  34
  35 if /I [%1] == [/t] (
  36     set tools=true
  37     set thisArgs=!thisArgs!%1
  38     goto Next
  39 )
  40
  41 if /I [%1] == [/all] (
  42     set tools=true
  43     set bin=true
  44     set packages=true
  45     goto Begin
  46 )
  47
  48 :Next
  49 shift /1
  50 goto Loop
  51
  52 :Begin
  53 :: Set __ProjectDir to be the directory of this script
  54 set "__ProjectDir=%~dp0"
  55 :: remove trailing slash
  56 if %__ProjectDir:~-1%==\ set "__ProjectDir=%__ProjectDir:~0,-1%"
  57 set "__RootBinDir=%__ProjectDir%\bin"
  58
  59 if [%bin%] == [true] (
  60         if exist "%__RootBinDir%" (
  61                 echo Deleting bin directory
  62                 rd /s /q "%__RootBinDir%"
  63                 if NOT [!ERRORLEVEL!]==[0] (
  64                         echo ERROR: An error occurred while deleting the bin directory - error code is !ERRORLEVEL!
  65                         exit /b 1
  66                 )
  67         )
  68 )
  69
  70 if [%tools%] == [true] (
  71         if exist "%__ProjectDir%\Tools" (
  72                 echo Deleting tools directory
  73                 rd /s /q "%__ProjectDir%\Tools"
  74                 if NOT [!ERRORLEVEL!]==[0] (
  75                         echo ERROR: An error occurred while deleting the Tools directory - error code is !ERRORLEVEL!
  76                         exit /b 1
  77                 )
  78         )
  79 )
  80
  81 if [%packages%] == [true] (
  82         if exist "%__ProjectDir%\packages" (
  83                 echo Deleting packages directory
  84                 rd /s /q "%__ProjectDir%\packages"
  85                 if NOT [!ERRORLEVEL!]==[0] (
  86                         echo ERROR: An error occurred while deleting the packages directory - error code is !ERRORLEVEL!
  87                         exit /b 1
  88                 )
  89         )
  90 )
  91
  92 echo Clean was successful
  93 exit /b 0
  94
  95 :Usage
  96 echo.
  97 echo Repository cleaning script.
  98 echo Options:
  99 echo     /b     - Cleans the bin directory
 100 echo     /p     - Cleans the packages directory
 101 echo     /t     - Cleans the tools directory
 102 echo     /all   - Cleans everything
 103 echo.
 104 echo If no option is specified then clean.cmd /b /p /t is implied.
 105 exit /b