clang/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.13.4)
   2
   3 include(GNUInstallDirs)
   4
   5 # If we are not building as a part of LLVM, build Clang as an
   6 # standalone project, using LLVM as an external library:
   7 if(CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
   8   project(Clang)
   9
  10   set(CMAKE_CXX_STANDARD 14 CACHE STRING "C++ standard to conform to")
  11   set(CMAKE_CXX_STANDARD_REQUIRED YES)
  12   set(CMAKE_CXX_EXTENSIONS NO)
  13
  14   # Rely on llvm-config.
  15   set(LLVM_CONFIG_OUTPUT)
  16   if(LLVM_CONFIG)
  17     set (LLVM_CONFIG_FOUND 1)
  18     message(STATUS "Found LLVM_CONFIG as ${LLVM_CONFIG}")
  19     message(DEPRECATION "Using llvm-config to detect the LLVM installation is \
  20           deprecated.  The installed cmake files should be used \
  21           instead.  CMake should be able to detect your LLVM install \
  22           automatically, but you can also use LLVM_DIR to specify \
  23           the path containing LLVMConfig.cmake.")
  24     set(CONFIG_COMMAND ${LLVM_CONFIG}
  25       "--includedir"
  26       "--prefix"
  27       "--src-root"
  28       "--cmakedir"
  29       "--bindir"
  30       "--libdir"
  31       "--assertion-mode"
  32       )
  33     execute_process(
  34       COMMAND ${CONFIG_COMMAND}
  35       RESULT_VARIABLE HAD_ERROR
  36       OUTPUT_VARIABLE LLVM_CONFIG_OUTPUT
  37     )
  38     if(NOT HAD_ERROR)
  39       string(REGEX REPLACE
  40         "[ \t]*[\r\n]+[ \t]*" ";"
  41         LLVM_CONFIG_OUTPUT ${LLVM_CONFIG_OUTPUT})
  42     else()
  43       string(REPLACE ";" " " CONFIG_COMMAND_STR "${CONFIG_COMMAND}")
  44       message(STATUS "${CONFIG_COMMAND_STR}")
  45       message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
  46     endif()
  47
  48     list(GET LLVM_CONFIG_OUTPUT 0 MAIN_INCLUDE_DIR)
  49     list(GET LLVM_CONFIG_OUTPUT 1 LLVM_OBJ_ROOT)
  50     list(GET LLVM_CONFIG_OUTPUT 2 MAIN_SRC_DIR)
  51     list(GET LLVM_CONFIG_OUTPUT 3 LLVM_CONFIG_CMAKE_DIR)
  52     list(GET LLVM_CONFIG_OUTPUT 4 TOOLS_BINARY_DIR)
  53     list(GET LLVM_CONFIG_OUTPUT 5 LIBRARY_DIR)
  54     list(GET LLVM_CONFIG_OUTPUT 6 ENABLE_ASSERTIONS)
  55
  56     # Normalize LLVM_CMAKE_DIR. --cmakedir might contain backslashes.
  57     # CMake assumes slashes as PATH.
  58     file(TO_CMAKE_PATH ${LLVM_CONFIG_CMAKE_DIR} LLVM_CMAKE_DIR)
  59   endif()
  60
  61
  62   if(NOT MSVC_IDE)
  63     set(LLVM_ENABLE_ASSERTIONS ${ENABLE_ASSERTIONS}
  64       CACHE BOOL "Enable assertions")
  65     # Assertions should follow llvm-config's.
  66     mark_as_advanced(LLVM_ENABLE_ASSERTIONS)
  67   endif()
  68
  69   find_package(LLVM REQUIRED HINTS "${LLVM_CMAKE_DIR}")
  70   list(APPEND CMAKE_MODULE_PATH ${LLVM_DIR})
  71
  72   # We can't check LLVM_CONFIG here, because find_package(LLVM ...) also sets
  73   # LLVM_CONFIG.
  74   if (NOT LLVM_CONFIG_FOUND)
  75     # Pull values from LLVMConfig.cmake.  We can drop this once the llvm-config
  76     # path is removed.
  77     set(MAIN_INCLUDE_DIR ${LLVM_INCLUDE_DIR})
  78     set(LLVM_OBJ_DIR ${LLVM_BINARY_DIR})
  79     set(TOOLS_BINARY_DIR ${LLVM_TOOLS_BINARY_DIR})
  80     set(LIBRARY_DIR ${LLVM_LIBRARY_DIR})
  81   endif()
  82
  83   set(LLVM_MAIN_INCLUDE_DIR ${MAIN_INCLUDE_DIR} CACHE PATH "Path to llvm/include")
  84   set(LLVM_BINARY_DIR ${LLVM_OBJ_ROOT} CACHE PATH "Path to LLVM build tree")
  85   set(LLVM_MAIN_SRC_DIR ${MAIN_SRC_DIR} CACHE PATH "Path to LLVM source tree")
  86   set(LLVM_TOOLS_BINARY_DIR ${TOOLS_BINARY_DIR} CACHE PATH "Path to llvm/bin")
  87   set(LLVM_LIBRARY_DIR ${LIBRARY_DIR} CACHE PATH "Path to llvm/lib")
  88
  89   find_program(LLVM_TABLEGEN_EXE "llvm-tblgen" ${LLVM_TOOLS_BINARY_DIR}
  90     NO_DEFAULT_PATH)
  91
  92   # They are used as destination of target generators.
  93   set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
  94   set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
  95   if(WIN32 OR CYGWIN)
  96     # DLL platform -- put DLLs into bin.
  97     set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
  98   else()
  99     set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 100   endif()
 101
 102   option(LLVM_INSTALL_TOOLCHAIN_ONLY
 103     "Only include toolchain files in the 'install' target." OFF)
 104
 105   option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 106     "Set to ON to force using an old, unsupported host toolchain." OFF)
 107   option(CLANG_ENABLE_BOOTSTRAP "Generate the clang bootstrap target" OFF)
 108   option(LLVM_ENABLE_LIBXML2 "Use libxml2 if available." ON)
 109
 110   include(AddLLVM)
 111   include(TableGen)
 112   include(HandleLLVMOptions)
 113   include(VersionFromVCS)
 114   include(GetErrcMessages)
 115   include(LLVMDistributionSupport)
 116
 117   set(PACKAGE_VERSION "${LLVM_PACKAGE_VERSION}")
 118   set(BUG_REPORT_URL "${LLVM_PACKAGE_BUGREPORT}" CACHE STRING
 119     "Default URL where bug reports are to be submitted.")
 120
 121   if (NOT DEFINED LLVM_INCLUDE_TESTS)
 122     set(LLVM_INCLUDE_TESTS ON)
 123   endif()
 124
 125   include_directories("${LLVM_BINARY_DIR}/include" "${LLVM_MAIN_INCLUDE_DIR}")
 126   link_directories("${LLVM_LIBRARY_DIR}")
 127
 128   set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin )
 129   set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 130   set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 131
 132   if(LLVM_INCLUDE_TESTS)
 133     find_package(Python3 ${LLVM_MINIMUM_PYTHON_VERSION} REQUIRED
 134       COMPONENTS Interpreter)
 135
 136     # Check prebuilt llvm/utils.
 137     if(EXISTS ${LLVM_TOOLS_BINARY_DIR}/FileCheck${CMAKE_EXECUTABLE_SUFFIX}
 138         AND EXISTS ${LLVM_TOOLS_BINARY_DIR}/count${CMAKE_EXECUTABLE_SUFFIX}
 139         AND EXISTS ${LLVM_TOOLS_BINARY_DIR}/not${CMAKE_EXECUTABLE_SUFFIX})
 140       set(LLVM_UTILS_PROVIDED ON)
 141     endif()
 142
 143     if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 144       # Note: path not really used, except for checking if lit was found
 145       set(LLVM_LIT ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 146       if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/llvm-lit)
 147         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/llvm-lit utils/llvm-lit)
 148       endif()
 149       if(NOT LLVM_UTILS_PROVIDED)
 150         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/FileCheck utils/FileCheck)
 151         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/count utils/count)
 152         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/not utils/not)
 153         set(LLVM_UTILS_PROVIDED ON)
 154         set(CLANG_TEST_DEPS FileCheck count not)
 155       endif()
 156       set(UNITTEST_DIR ${LLVM_MAIN_SRC_DIR}/utils/unittest)
 157       if(EXISTS ${UNITTEST_DIR}/googletest/include/gtest/gtest.h
 158           AND NOT EXISTS ${LLVM_LIBRARY_DIR}/${CMAKE_STATIC_LIBRARY_PREFIX}gtest${CMAKE_STATIC_LIBRARY_SUFFIX}
 159           AND EXISTS ${UNITTEST_DIR}/CMakeLists.txt)
 160         add_subdirectory(${UNITTEST_DIR} utils/unittest)
 161       endif()
 162     else()
 163       # Seek installed Lit.
 164       find_program(LLVM_LIT
 165                    NAMES llvm-lit lit.py lit
 166                    PATHS "${LLVM_MAIN_SRC_DIR}/utils/lit"
 167                    DOC "Path to lit.py")
 168     endif()
 169
 170     if(LLVM_LIT)
 171       # Define the default arguments to use with 'lit', and an option for the user
 172       # to override.
 173       set(LIT_ARGS_DEFAULT "-sv")
 174       if (MSVC OR XCODE)
 175         set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 176       endif()
 177       set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 178
 179       get_errc_messages(LLVM_LIT_ERRC_MESSAGES)
 180
 181       # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 182       if( WIN32 AND NOT CYGWIN )
 183         set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 184       endif()
 185     else()
 186       set(LLVM_INCLUDE_TESTS OFF)
 187     endif()
 188   endif()
 189
 190   set(CLANG_BUILT_STANDALONE TRUE)
 191
 192   set(BACKEND_PACKAGE_STRING "LLVM ${LLVM_PACKAGE_VERSION}")
 193 else()
 194   set(BACKEND_PACKAGE_STRING "${PACKAGE_STRING}")
 195 endif() # standalone
 196
 197 if(NOT DEFINED LLVM_COMMON_CMAKE_UTILS)
 198   set(LLVM_COMMON_CMAKE_UTILS ${CMAKE_CURRENT_SOURCE_DIR}/../cmake)
 199 endif()
 200
 201 # Make sure that our source directory is on the current cmake module path so that
 202 # we can include cmake files from this directory.
 203 list(INSERT CMAKE_MODULE_PATH 0
 204   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 205   "${LLVM_COMMON_CMAKE_UTILS}/Modules"
 206   )
 207
 208 if(LLVM_ENABLE_LIBXML2)
 209   # Don't look for libxml if we're using MSan, since uninstrumented third party
 210   # code may call MSan interceptors like strlen, leading to false positives.
 211   if(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 212     set (LIBXML2_FOUND 0)
 213     find_package(LibXml2 2.5.3 QUIET)
 214     if (LIBXML2_FOUND)
 215       set(CLANG_HAVE_LIBXML 1)
 216     endif()
 217   endif()
 218 endif()
 219
 220 include(CheckIncludeFile)
 221 check_include_file(sys/resource.h CLANG_HAVE_RLIMITS)
 222
 223 set(CLANG_RESOURCE_DIR "" CACHE STRING
 224   "Relative directory from the Clang binary to its resource files.")
 225
 226 set(C_INCLUDE_DIRS "" CACHE STRING
 227   "Colon separated list of directories clang will search for headers.")
 228
 229 set(GCC_INSTALL_PREFIX "" CACHE PATH "Directory where gcc is installed." )
 230 set(DEFAULT_SYSROOT "" CACHE STRING
 231   "Default <path> to all compiler invocations for --sysroot=<path>." )
 232
 233 set(ENABLE_LINKER_BUILD_ID OFF CACHE BOOL "pass --build-id to ld")
 234
 235 set(ENABLE_X86_RELAX_RELOCATIONS ON CACHE BOOL
 236     "enable x86 relax relocations by default")
 237
 238 set(CLANG_SPAWN_CC1 OFF CACHE BOOL
 239     "Whether clang should use a new process for the CC1 invocation")
 240
 241 option(CLANG_DEFAULT_PIE_ON_LINUX "Default to -fPIE and -pie on Linux" OFF)
 242
 243 # TODO: verify the values against LangStandards.def?
 244 set(CLANG_DEFAULT_STD_C "" CACHE STRING
 245   "Default standard to use for C/ObjC code (IDENT from LangStandards.def, empty for platform default)")
 246 set(CLANG_DEFAULT_STD_CXX "" CACHE STRING
 247   "Default standard to use for C++/ObjC++ code (IDENT from LangStandards.def, empty for platform default)")
 248
 249 set(CLANG_DEFAULT_LINKER "" CACHE STRING
 250   "Default linker to use (linker name or absolute path, empty for platform default)")
 251
 252 set(CLANG_DEFAULT_CXX_STDLIB "" CACHE STRING
 253   "Default C++ stdlib to use (\"libstdc++\" or \"libc++\", empty for platform default")
 254 if (NOT(CLANG_DEFAULT_CXX_STDLIB STREQUAL "" OR
 255         CLANG_DEFAULT_CXX_STDLIB STREQUAL "libstdc++" OR
 256         CLANG_DEFAULT_CXX_STDLIB STREQUAL "libc++"))
 257   message(WARNING "Resetting default C++ stdlib to use platform default")
 258   set(CLANG_DEFAULT_CXX_STDLIB "" CACHE STRING
 259     "Default C++ stdlib to use (\"libstdc++\" or \"libc++\", empty for platform default" FORCE)
 260 endif()
 261
 262 set(CLANG_DEFAULT_RTLIB "" CACHE STRING
 263   "Default runtime library to use (\"libgcc\" or \"compiler-rt\", empty for platform default)")
 264 if (NOT(CLANG_DEFAULT_RTLIB STREQUAL "" OR
 265         CLANG_DEFAULT_RTLIB STREQUAL "libgcc" OR
 266         CLANG_DEFAULT_RTLIB STREQUAL "compiler-rt"))
 267   message(WARNING "Resetting default rtlib to use platform default")
 268   set(CLANG_DEFAULT_RTLIB "" CACHE STRING
 269     "Default runtime library to use (\"libgcc\" or \"compiler-rt\", empty for platform default)" FORCE)
 270 endif()
 271
 272 set(CLANG_DEFAULT_UNWINDLIB "" CACHE STRING
 273   "Default unwind library to use (\"none\" \"libgcc\" or \"libunwind\", empty to match runtime library.)")
 274 if (CLANG_DEFAULT_UNWINDLIB STREQUAL "")
 275   if (CLANG_DEFAULT_RTLIB STREQUAL "libgcc")
 276     set (CLANG_DEFAULT_UNWINDLIB "libgcc" CACHE STRING "" FORCE)
 277   endif()
 278 endif()
 279
 280 if (NOT(CLANG_DEFAULT_UNWINDLIB STREQUAL "" OR
 281         CLANG_DEFAULT_UNWINDLIB STREQUAL "none" OR
 282         CLANG_DEFAULT_UNWINDLIB STREQUAL "libgcc" OR
 283         CLANG_DEFAULT_UNWINDLIB STREQUAL "libunwind"))
 284   message(WARNING "Resetting default unwindlib to use platform default")
 285   set(CLANG_DEFAULT_UNWINDLIB "" CACHE STRING
 286     "Default unwind library to use (\"none\" \"libgcc\" or \"libunwind\", empty to match runtime library.)" FORCE)
 287 endif()
 288
 289 set(CLANG_DEFAULT_OBJCOPY "objcopy" CACHE STRING
 290   "Default objcopy executable to use.")
 291
 292 set(CLANG_DEFAULT_OPENMP_RUNTIME "libomp" CACHE STRING
 293   "Default OpenMP runtime used by -fopenmp.")
 294
 295 # OpenMP offloading requires at least sm_35 because we use shuffle instructions
 296 # to generate efficient code for reductions and the atomicMax instruction on
 297 # 64-bit integers in the implementation of conditional lastprivate.
 298 set(CUDA_ARCH_FLAGS "sm_35")
 299
 300 # Try to find the highest Nvidia GPU architecture the system supports
 301 if (NOT DEFINED CLANG_OPENMP_NVPTX_DEFAULT_ARCH)
 302   find_package(CUDA QUIET)
 303   if (CUDA_FOUND)
 304     cuda_select_nvcc_arch_flags(CUDA_ARCH_FLAGS)
 305   endif()
 306 else()
 307   set(CUDA_ARCH_FLAGS ${CLANG_OPENMP_NVPTX_DEFAULT_ARCH})
 308 endif()
 309
 310 string(REGEX MATCH "sm_([0-9]+)" CUDA_ARCH_MATCH ${CUDA_ARCH_FLAGS})
 311 if (NOT DEFINED CUDA_ARCH_MATCH OR "${CMAKE_MATCH_1}" LESS 35)
 312   set(CLANG_OPENMP_NVPTX_DEFAULT_ARCH "sm_35" CACHE STRING
 313     "Default architecture for OpenMP offloading to Nvidia GPUs." FORCE)
 314   message(WARNING "Resetting default architecture for OpenMP offloading to Nvidia GPUs to sm_35")
 315 else()
 316   set(CLANG_OPENMP_NVPTX_DEFAULT_ARCH ${CUDA_ARCH_MATCH} CACHE STRING
 317     "Default architecture for OpenMP offloading to Nvidia GPUs.")
 318 endif()
 319
 320 set(CLANG_SYSTEMZ_DEFAULT_ARCH "z10" CACHE STRING "SystemZ Default Arch")
 321
 322 set(CLANG_VENDOR ${PACKAGE_VENDOR} CACHE STRING
 323   "Vendor-specific text for showing with version information.")
 324
 325 set(CLANG_REPOSITORY_STRING "" CACHE STRING
 326   "Vendor-specific text for showing the repository the source is taken from.")
 327
 328 if(CLANG_REPOSITORY_STRING)
 329   add_definitions(-DCLANG_REPOSITORY_STRING="${CLANG_REPOSITORY_STRING}")
 330 endif()
 331
 332 set(CLANG_VENDOR_UTI "org.llvm.clang" CACHE STRING
 333   "Vendor-specific uti.")
 334
 335 set(CLANG_PYTHON_BINDINGS_VERSIONS "" CACHE STRING
 336     "Python versions to install libclang python bindings for")
 337
 338 set(CLANG_LINK_CLANG_DYLIB ${LLVM_LINK_LLVM_DYLIB} CACHE BOOL
 339     "Link tools against libclang-cpp.so")
 340
 341 if (NOT LLVM_LINK_LLVM_DYLIB AND CLANG_LINK_CLANG_DYLIB)
 342   message(FATAL_ERROR "Cannot set CLANG_LINK_CLANG_DYLIB=ON when "
 343                       "LLVM_LINK_LLVM_DYLIB=OFF")
 344 endif()
 345
 346 # The libdir suffix must exactly match whatever LLVM's configuration used.
 347 set(CLANG_LIBDIR_SUFFIX "${LLVM_LIBDIR_SUFFIX}")
 348
 349 set(CLANG_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 350 set(CLANG_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 351
 352 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 353   message(FATAL_ERROR "In-source builds are not allowed. "
 354 "Please create a directory and run cmake "
 355 "from there, passing the path to this source directory as the last argument. "
 356 "This process created the file `CMakeCache.txt' and the directory "
 357 "`CMakeFiles'. Please delete them.")
 358 endif()
 359
 360 # If CLANG_VERSION_* is specified, use it, if not use LLVM_VERSION_*.
 361 if(NOT DEFINED CLANG_VERSION_MAJOR)
 362   set(CLANG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 363 endif()
 364 if(NOT DEFINED CLANG_VERSION_MINOR)
 365   set(CLANG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 366 endif()
 367 if(NOT DEFINED CLANG_VERSION_PATCHLEVEL)
 368   set(CLANG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 369 endif()
 370 # Unlike PACKAGE_VERSION, CLANG_VERSION does not include LLVM_VERSION_SUFFIX.
 371 set(CLANG_VERSION "${CLANG_VERSION_MAJOR}.${CLANG_VERSION_MINOR}.${CLANG_VERSION_PATCHLEVEL}")
 372 message(STATUS "Clang version: ${CLANG_VERSION}")
 373
 374 # Configure the Version.inc file.
 375 configure_file(
 376   ${CMAKE_CURRENT_SOURCE_DIR}/include/clang/Basic/Version.inc.in
 377   ${CMAKE_CURRENT_BINARY_DIR}/include/clang/Basic/Version.inc)
 378
 379 # Add appropriate flags for GCC
 380 if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
 381   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-common -Woverloaded-virtual")
 382   if (NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
 383     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-strict-aliasing")
 384   endif ()
 385
 386   # Enable -pedantic for Clang even if it's not enabled for LLVM.
 387   if (NOT LLVM_ENABLE_PEDANTIC)
 388     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pedantic -Wno-long-long")
 389   endif ()
 390
 391   check_cxx_compiler_flag("-Werror -Wnested-anon-types" CXX_SUPPORTS_NO_NESTED_ANON_TYPES_FLAG)
 392   if( CXX_SUPPORTS_NO_NESTED_ANON_TYPES_FLAG )
 393     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-nested-anon-types" )
 394   endif()
 395 endif ()
 396
 397 # Determine HOST_LINK_VERSION on Darwin.
 398 set(HOST_LINK_VERSION)
 399 if (APPLE)
 400   set(LD_V_OUTPUT)
 401   execute_process(
 402     COMMAND sh -c "${CMAKE_LINKER} -v 2>&1 | head -1"
 403     RESULT_VARIABLE HAD_ERROR
 404     OUTPUT_VARIABLE LD_V_OUTPUT
 405   )
 406   if (HAD_ERROR)
 407     message(FATAL_ERROR "${CMAKE_LINKER} failed with status ${HAD_ERROR}")
 408   endif()
 409   if ("${LD_V_OUTPUT}" MATCHES ".*ld64-([0-9.]+).*")
 410     string(REGEX REPLACE ".*ld64-([0-9.]+).*" "\\1" HOST_LINK_VERSION ${LD_V_OUTPUT})
 411   elseif ("${LD_V_OUTPUT}" MATCHES "[^0-9]*([0-9.]+).*")
 412     string(REGEX REPLACE "[^0-9]*([0-9.]+).*" "\\1" HOST_LINK_VERSION ${LD_V_OUTPUT})
 413   endif()
 414   message(STATUS "Host linker version: ${HOST_LINK_VERSION}")
 415 endif()
 416
 417 include(CMakeParseArguments)
 418 include(AddClang)
 419
 420 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 421
 422 include_directories(BEFORE
 423   ${CMAKE_CURRENT_BINARY_DIR}/include
 424   ${CMAKE_CURRENT_SOURCE_DIR}/include
 425   )
 426
 427 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 428   install(DIRECTORY include/clang include/clang-c
 429     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
 430     COMPONENT clang-headers
 431     FILES_MATCHING
 432     PATTERN "*.def"
 433     PATTERN "*.h"
 434     PATTERN "config.h" EXCLUDE
 435     )
 436
 437   install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/clang
 438     DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
 439     COMPONENT clang-headers
 440     FILES_MATCHING
 441     PATTERN "CMakeFiles" EXCLUDE
 442     PATTERN "*.inc"
 443     PATTERN "*.h"
 444     )
 445
 446   # Installing the headers needs to depend on generating any public
 447   # tablegen'd headers.
 448   add_custom_target(clang-headers DEPENDS clang-tablegen-targets)
 449   set_target_properties(clang-headers PROPERTIES FOLDER "Misc")
 450   if(NOT LLVM_ENABLE_IDE)
 451     add_llvm_install_targets(install-clang-headers
 452                              DEPENDS clang-headers
 453                              COMPONENT clang-headers)
 454   endif()
 455
 456   add_custom_target(bash-autocomplete DEPENDS utils/bash-autocomplete.sh)
 457   install(PROGRAMS utils/bash-autocomplete.sh
 458           DESTINATION "${CMAKE_INSTALL_DATADIR}/clang"
 459           COMPONENT bash-autocomplete)
 460   if(NOT LLVM_ENABLE_IDE)
 461     add_llvm_install_targets(install-bash-autocomplete
 462                              DEPENDS bash-autocomplete
 463                              COMPONENT bash-autocomplete)
 464   endif()
 465 endif()
 466
 467 add_definitions( -D_GNU_SOURCE )
 468
 469 option(CLANG_BUILD_TOOLS
 470   "Build the Clang tools. If OFF, just generate build targets." ON)
 471
 472 option(CLANG_ENABLE_ARCMT "Build ARCMT." ON)
 473 option(CLANG_ENABLE_STATIC_ANALYZER
 474   "Include static analyzer in clang binary." ON)
 475
 476 option(CLANG_ENABLE_PROTO_FUZZER "Build Clang protobuf fuzzer." OFF)
 477
 478 if(NOT CLANG_ENABLE_STATIC_ANALYZER AND CLANG_ENABLE_ARCMT)
 479   message(FATAL_ERROR "Cannot disable static analyzer while enabling ARCMT or Z3")
 480 endif()
 481
 482 if(CLANG_ENABLE_ARCMT)
 483   set(CLANG_ENABLE_OBJC_REWRITER ON)
 484 endif()
 485
 486 # Clang version information
 487 set(CLANG_EXECUTABLE_VERSION
 488     "${CLANG_VERSION_MAJOR}" CACHE STRING
 489     "Major version number that will be appended to the clang executable name")
 490 set(LIBCLANG_LIBRARY_VERSION
 491     "${CLANG_VERSION_MAJOR}" CACHE STRING
 492     "Major version number that will be appended to the libclang library")
 493 mark_as_advanced(CLANG_EXECUTABLE_VERSION LIBCLANG_LIBRARY_VERSION)
 494
 495 option(CLANG_INCLUDE_TESTS
 496        "Generate build targets for the Clang unit tests."
 497        ${LLVM_INCLUDE_TESTS})
 498
 499 add_subdirectory(utils/TableGen)
 500
 501 add_subdirectory(include)
 502
 503 # All targets below may depend on all tablegen'd files.
 504 get_property(CLANG_TABLEGEN_TARGETS GLOBAL PROPERTY CLANG_TABLEGEN_TARGETS)
 505 add_custom_target(clang-tablegen-targets
 506   DEPENDS
 507   omp_gen
 508   ${CLANG_TABLEGEN_TARGETS})
 509 set_target_properties(clang-tablegen-targets PROPERTIES FOLDER "Misc")
 510 list(APPEND LLVM_COMMON_DEPENDS clang-tablegen-targets)
 511
 512 # Force target to be built as soon as possible. Clang modules builds depend
 513 # header-wise on it as they ship all headers from the umbrella folders. Building
 514 # an entire module might include header, which depends on intrinsics_gen.
 515 if(LLVM_ENABLE_MODULES)
 516   list(APPEND LLVM_COMMON_DEPENDS intrinsics_gen)
 517 endif()
 518
 519 add_subdirectory(lib)
 520 add_subdirectory(tools)
 521 add_subdirectory(runtime)
 522
 523 option(CLANG_BUILD_EXAMPLES "Build CLANG example programs by default." OFF)
 524 add_subdirectory(examples)
 525
 526 if(APPLE)
 527   # this line is needed as a cleanup to ensure that any CMakeCaches with the old
 528   # default value get updated to the new default.
 529   if(CLANG_ORDER_FILE STREQUAL "")
 530     unset(CLANG_ORDER_FILE CACHE)
 531     unset(CLANG_ORDER_FILE)
 532   endif()
 533
 534
 535   set(CLANG_ORDER_FILE ${CMAKE_CURRENT_BINARY_DIR}/clang.order CACHE FILEPATH
 536     "Order file to use when compiling clang in order to improve startup time (Darwin Only - requires ld64).")
 537
 538   if(NOT EXISTS ${CLANG_ORDER_FILE})
 539     string(FIND "${CLANG_ORDER_FILE}" "${CMAKE_CURRENT_BINARY_DIR}" PATH_START)
 540     if(PATH_START EQUAL 0)
 541       file(WRITE ${CLANG_ORDER_FILE} "\n")
 542     else()
 543       message(FATAL_ERROR "Specified order file '${CLANG_ORDER_FILE}' does not exist.")
 544     endif()
 545   endif()
 546 endif()
 547
 548
 549 if( CLANG_INCLUDE_TESTS )
 550   if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include/gtest/gtest.h)
 551     add_subdirectory(unittests)
 552     list(APPEND CLANG_TEST_DEPS ClangUnitTests)
 553     list(APPEND CLANG_TEST_PARAMS
 554       clang_unit_site_config=${CMAKE_CURRENT_BINARY_DIR}/test/Unit/lit.site.cfg
 555       )
 556   endif()
 557   add_subdirectory(test)
 558   add_subdirectory(bindings/python/tests)
 559
 560   if(CLANG_BUILT_STANDALONE)
 561     # Add a global check rule now that all subdirectories have been traversed
 562     # and we know the total set of lit testsuites.
 563     get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 564     get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 565     get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 566     get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 567     get_property(LLVM_ADDITIONAL_TEST_TARGETS
 568                  GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 569     add_lit_target(check-all
 570       "Running all regression tests"
 571       ${LLVM_LIT_TESTSUITES}
 572       PARAMS ${LLVM_LIT_PARAMS}
 573       DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 574       ARGS ${LLVM_LIT_EXTRA_ARGS}
 575       )
 576   endif()
 577   add_subdirectory(utils/perf-training)
 578 endif()
 579
 580 option(CLANG_INCLUDE_DOCS "Generate build targets for the Clang docs."
 581   ${LLVM_INCLUDE_DOCS})
 582 if( CLANG_INCLUDE_DOCS )
 583   add_subdirectory(docs)
 584 endif()
 585
 586 # Custom target to install all clang libraries.
 587 add_custom_target(clang-libraries)
 588 set_target_properties(clang-libraries PROPERTIES FOLDER "Misc")
 589
 590 if(NOT LLVM_ENABLE_IDE)
 591   add_llvm_install_targets(install-clang-libraries
 592                            DEPENDS clang-libraries
 593                            COMPONENT clang-libraries)
 594 endif()
 595
 596 get_property(CLANG_LIBS GLOBAL PROPERTY CLANG_LIBS)
 597 if(CLANG_LIBS)
 598   list(REMOVE_DUPLICATES CLANG_LIBS)
 599   foreach(lib ${CLANG_LIBS})
 600     add_dependencies(clang-libraries ${lib})
 601     if(NOT LLVM_ENABLE_IDE)
 602       add_dependencies(install-clang-libraries install-${lib})
 603       add_dependencies(install-clang-libraries-stripped install-${lib}-stripped)
 604     endif()
 605   endforeach()
 606 endif()
 607
 608 add_subdirectory(cmake/modules)
 609
 610 if(CLANG_STAGE)
 611   message(STATUS "Setting current clang stage to: ${CLANG_STAGE}")
 612 endif()
 613
 614 if (CLANG_ENABLE_BOOTSTRAP)
 615   include(ExternalProject)
 616
 617   add_custom_target(clang-bootstrap-deps DEPENDS clang)
 618
 619   if(NOT CLANG_STAGE)
 620     set(CLANG_STAGE stage1)
 621   endif()
 622
 623   string(REGEX MATCH "stage([0-9]*)" MATCHED_STAGE "${CLANG_STAGE}")
 624   if(MATCHED_STAGE)
 625     if(NOT LLVM_BUILD_INSTRUMENTED)
 626       math(EXPR STAGE_NUM "${CMAKE_MATCH_1} + 1")
 627       set(NEXT_CLANG_STAGE stage${STAGE_NUM})
 628     else()
 629       set(NEXT_CLANG_STAGE stage${CMAKE_MATCH_1})
 630     endif()
 631   else()
 632     set(NEXT_CLANG_STAGE bootstrap)
 633   endif()
 634
 635   if(BOOTSTRAP_LLVM_BUILD_INSTRUMENTED)
 636     set(NEXT_CLANG_STAGE ${NEXT_CLANG_STAGE}-instrumented)
 637   endif()
 638   message(STATUS "Setting next clang stage to: ${NEXT_CLANG_STAGE}")
 639
 640
 641   set(STAMP_DIR ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-stamps/)
 642   set(BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-bins/)
 643
 644   if(BOOTSTRAP_LLVM_ENABLE_LLD)
 645     # adding lld to clang-bootstrap-deps without having it enabled in
 646     # LLVM_ENABLE_PROJECTS just generates a cryptic error message.
 647     if (NOT "lld" IN_LIST LLVM_ENABLE_PROJECTS)
 648       message(FATAL_ERROR "LLD is enabled in the bootstrap build, but lld is not in LLVM_ENABLE_PROJECTS")
 649     endif()
 650     add_dependencies(clang-bootstrap-deps lld)
 651   endif()
 652
 653   # If the next stage is LTO we need to depend on LTO and possibly lld or LLVMgold
 654   if(BOOTSTRAP_LLVM_ENABLE_LTO OR LLVM_ENABLE_LTO AND NOT LLVM_BUILD_INSTRUMENTED)
 655     if(APPLE)
 656       add_dependencies(clang-bootstrap-deps LTO)
 657       # on Darwin we need to set DARWIN_LTO_LIBRARY so that -flto will work
 658       # using the just-built compiler, and we need to override DYLD_LIBRARY_PATH
 659       # so that the host object file tools will use the just-built libLTO.
 660       # However if System Integrity Protection is enabled the DYLD variables
 661       # will be scrubbed from the environment of any base system commands. This
 662       # includes /bin/sh, which ninja uses when executing build commands. To
 663       # work around the envar being filtered away we pass it in as a CMake
 664       # variable, and have LLVM's CMake append the envar to the archiver calls.
 665       set(LTO_LIBRARY -DDARWIN_LTO_LIBRARY=${LLVM_SHLIB_OUTPUT_INTDIR}/libLTO.dylib
 666         -DDYLD_LIBRARY_PATH=${LLVM_LIBRARY_OUTPUT_INTDIR})
 667     elseif(NOT WIN32)
 668       add_dependencies(clang-bootstrap-deps llvm-ar llvm-ranlib)
 669       if(NOT BOOTSTRAP_LLVM_ENABLE_LLD AND LLVM_BINUTILS_INCDIR)
 670         add_dependencies(clang-bootstrap-deps LLVMgold)
 671       endif()
 672       set(${CLANG_STAGE}_AR -DCMAKE_AR=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ar)
 673       set(${CLANG_STAGE}_RANLIB -DCMAKE_RANLIB=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ranlib)
 674     endif()
 675   endif()
 676
 677   if(CLANG_BOOTSTRAP_EXTRA_DEPS)
 678     add_dependencies(clang-bootstrap-deps ${CLANG_BOOTSTRAP_EXTRA_DEPS})
 679   endif()
 680
 681   add_custom_target(${NEXT_CLANG_STAGE}-clear
 682     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-cleared
 683     )
 684   add_custom_command(
 685     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-cleared
 686     DEPENDS clang-bootstrap-deps
 687     COMMAND ${CMAKE_COMMAND} -E remove_directory ${BINARY_DIR}
 688     COMMAND ${CMAKE_COMMAND} -E make_directory ${BINARY_DIR}
 689     COMMAND ${CMAKE_COMMAND} -E remove_directory ${STAMP_DIR}
 690     COMMAND ${CMAKE_COMMAND} -E make_directory ${STAMP_DIR}
 691     COMMENT "Clobberring ${NEXT_CLANG_STAGE} build and stamp directories"
 692     )
 693
 694   if(CMAKE_VERBOSE_MAKEFILE)
 695     set(verbose -DCMAKE_VERBOSE_MAKEFILE=On)
 696   endif()
 697
 698   set(_BOOTSTRAP_DEFAULT_PASSTHROUGH
 699     PACKAGE_VERSION
 700     PACKAGE_VENDOR
 701     LLVM_VERSION_MAJOR
 702     LLVM_VERSION_MINOR
 703     LLVM_VERSION_PATCH
 704     CLANG_VERSION_MAJOR
 705     CLANG_VERSION_MINOR
 706     CLANG_VERSION_PATCHLEVEL
 707     CLANG_VENDOR
 708     LLVM_VERSION_SUFFIX
 709     LLVM_BINUTILS_INCDIR
 710     CLANG_REPOSITORY_STRING
 711     CMAKE_C_COMPILER_LAUNCHER
 712     CMAKE_CXX_COMPILER_LAUNCHER
 713     CMAKE_MAKE_PROGRAM
 714     CMAKE_OSX_ARCHITECTURES
 715     CMAKE_BUILD_TYPE
 716     LLVM_ENABLE_PROJECTS
 717     LLVM_ENABLE_RUNTIMES)
 718
 719   # We don't need to depend on compiler-rt/libcxx if we're building instrumented
 720   # because the next stage will use the same compiler used to build this stage.
 721   if(NOT LLVM_BUILD_INSTRUMENTED)
 722     if(TARGET compiler-rt)
 723       add_dependencies(clang-bootstrap-deps compiler-rt)
 724     endif()
 725     if(TARGET cxx-headers)
 726       add_dependencies(clang-bootstrap-deps cxx-headers)
 727     endif()
 728   endif()
 729
 730   set(C_COMPILER "clang")
 731   set(CXX_COMPILER "clang++")
 732   if(WIN32)
 733     set(C_COMPILER "clang-cl.exe")
 734     set(CXX_COMPILER "clang-cl.exe")
 735   endif()
 736
 737   set(COMPILER_OPTIONS
 738     -DCMAKE_CXX_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${CXX_COMPILER}
 739     -DCMAKE_C_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${C_COMPILER}
 740     -DCMAKE_ASM_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${C_COMPILER}
 741     -DCMAKE_ASM_COMPILER_ID=Clang)
 742
 743   # cmake requires CMAKE_LINKER to be specified if the compiler is MSVC-like,
 744   # otherwise it defaults the linker to be link.exe.
 745   if(BOOTSTRAP_LLVM_ENABLE_LLD)
 746     if((WIN32 AND NOT BOOTSTRAP_CMAKE_SYSTEM_NAME) OR BOOTSTRAP_CMAKE_SYSTEM_NAME STREQUAL "Windows")
 747       set(${CLANG_STAGE}_LINKER -DCMAKE_LINKER=${LLVM_RUNTIME_OUTPUT_INTDIR}/lld-link${CMAKE_EXECUTABLE_SUFFIX})
 748     endif()
 749   endif()
 750
 751   if(BOOTSTRAP_CMAKE_SYSTEM_NAME)
 752     set(${CLANG_STAGE}_CONFIG -DLLVM_CONFIG_PATH=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-config)
 753     set(${CLANG_STAGE}_TABLEGEN
 754       -DLLVM_TABLEGEN=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-tblgen
 755       -DCLANG_TABLEGEN=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang-tblgen)
 756     if(BOOTSTRAP_CMAKE_SYSTEM_NAME STREQUAL "Linux")
 757       if(BOOTSTRAP_LLVM_ENABLE_LLD)
 758         set(${CLANG_STAGE}_LINKER -DCMAKE_LINKER=${LLVM_RUNTIME_OUTPUT_INTDIR}/ld.lld)
 759       endif()
 760       if(NOT BOOTSTRAP_LLVM_ENABLE_LTO)
 761         add_dependencies(clang-bootstrap-deps llvm-ar llvm-ranlib)
 762         set(${CLANG_STAGE}_AR -DCMAKE_AR=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ar)
 763         set(${CLANG_STAGE}_RANLIB -DCMAKE_RANLIB=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ranlib)
 764       endif()
 765       add_dependencies(clang-bootstrap-deps llvm-objcopy llvm-strip)
 766       set(${CLANG_STAGE}_OBJCOPY -DCMAKE_OBJCOPY=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-objcopy)
 767       set(${CLANG_STAGE}_STRIP -DCMAKE_STRIP=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-strip)
 768       set(${CLANG_STAGE}_READELF -DCMAKE_READELF=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-readelf)
 769     endif()
 770   endif()
 771
 772   if(BOOTSTRAP_LLVM_BUILD_INSTRUMENTED)
 773     add_dependencies(clang-bootstrap-deps llvm-profdata)
 774     set(PGO_OPT -DLLVM_PROFDATA=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-profdata)
 775   endif()
 776
 777   if(LLVM_BUILD_INSTRUMENTED)
 778     add_dependencies(clang-bootstrap-deps generate-profdata)
 779     set(PGO_OPT -DLLVM_PROFDATA_FILE=${CMAKE_CURRENT_BINARY_DIR}/utils/perf-training/clang.profdata)
 780     # Use the current tools for LTO instead of the instrumented ones
 781     list(APPEND _BOOTSTRAP_DEFAULT_PASSTHROUGH
 782       CMAKE_CXX_COMPILER
 783       CMAKE_C_COMPILER
 784       CMAKE_ASM_COMPILER
 785       CMAKE_AR
 786       CMAKE_RANLIB
 787       DARWIN_LTO_LIBRARY
 788       DYLD_LIBRARY_PATH)
 789
 790     set(COMPILER_OPTIONS)
 791     set(LTO_LIBRARY)
 792     set(LTO_AR)
 793     set(LTO_RANLIB)
 794   endif()
 795
 796   # Find all variables that start with BOOTSTRAP_ and populate a variable with
 797   # them.
 798   get_cmake_property(variableNames VARIABLES)
 799   foreach(variableName ${variableNames})
 800     if(variableName MATCHES "^BOOTSTRAP_")
 801       string(SUBSTRING ${variableName} 10 -1 varName)
 802       string(REPLACE ";" "|" value "${${variableName}}")
 803       list(APPEND PASSTHROUGH_VARIABLES
 804         -D${varName}=${value})
 805     endif()
 806     if(${variableName} AND variableName MATCHES "LLVM_EXTERNAL_.*_SOURCE_DIR")
 807       list(APPEND PASSTHROUGH_VARIABLES
 808         -D${variableName}=${${variableName}})
 809     endif()
 810   endforeach()
 811
 812   # Populate the passthrough variables
 813   foreach(variableName ${CLANG_BOOTSTRAP_PASSTHROUGH} ${_BOOTSTRAP_DEFAULT_PASSTHROUGH})
 814     if(DEFINED ${variableName})
 815       if("${${variableName}}" STREQUAL "")
 816         set(value "")
 817       else()
 818         string(REPLACE ";" "|" value "${${variableName}}")
 819       endif()
 820       list(APPEND PASSTHROUGH_VARIABLES
 821         -D${variableName}=${value})
 822     endif()
 823   endforeach()
 824
 825   ExternalProject_Add(${NEXT_CLANG_STAGE}
 826     DEPENDS clang-bootstrap-deps
 827     PREFIX ${NEXT_CLANG_STAGE}
 828     SOURCE_DIR ${CMAKE_SOURCE_DIR}
 829     STAMP_DIR ${STAMP_DIR}
 830     BINARY_DIR ${BINARY_DIR}
 831     EXCLUDE_FROM_ALL 1
 832     CMAKE_ARGS
 833                 # We shouldn't need to set this here, but INSTALL_DIR doesn't
 834                 # seem to work, so instead I'm passing this through
 835                 -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
 836                 ${PASSTHROUGH_VARIABLES}
 837                 ${CLANG_BOOTSTRAP_CMAKE_ARGS}
 838                  -DCLANG_STAGE=${NEXT_CLANG_STAGE}
 839                 ${COMPILER_OPTIONS}
 840                 ${${CLANG_STAGE}_CONFIG}
 841                 ${${CLANG_STAGE}_TABLEGEN}
 842                 ${LTO_LIBRARY} ${verbose} ${PGO_OPT}
 843                 ${${CLANG_STAGE}_LINKER}
 844                 ${${CLANG_STAGE}_AR}
 845                 ${${CLANG_STAGE}_RANLIB}
 846                 ${${CLANG_STAGE}_OBJCOPY}
 847                 ${${CLANG_STAGE}_STRIP}
 848     INSTALL_COMMAND ""
 849     STEP_TARGETS configure build
 850     USES_TERMINAL_CONFIGURE 1
 851     USES_TERMINAL_BUILD 1
 852     USES_TERMINAL_INSTALL 1
 853     LIST_SEPARATOR |
 854     )
 855
 856   # exclude really-install from main target
 857   set_target_properties(${NEXT_CLANG_STAGE} PROPERTIES _EP_really-install_EXCLUDE_FROM_MAIN On)
 858   ExternalProject_Add_Step(${NEXT_CLANG_STAGE} really-install
 859     COMMAND ${CMAKE_COMMAND} --build <BINARY_DIR> --target install
 860     COMMENT "Performing install step for '${NEXT_CLANG_STAGE}'"
 861     DEPENDEES build
 862     USES_TERMINAL 1
 863   )
 864   ExternalProject_Add_StepTargets(${NEXT_CLANG_STAGE} really-install)
 865   add_custom_target(${NEXT_CLANG_STAGE}-install DEPENDS ${NEXT_CLANG_STAGE}-really-install)
 866
 867   if(NOT CLANG_BOOTSTRAP_TARGETS)
 868     set(CLANG_BOOTSTRAP_TARGETS check-llvm check-clang check-all)
 869   endif()
 870   foreach(target ${CLANG_BOOTSTRAP_TARGETS})
 871     # Install targets have side effects, so we always want to execute them.
 872     # "install" is reserved by CMake and can't be used as a step name for
 873     # ExternalProject_Add_Step, so we can match against "^install-" instead of
 874     # "^install" to get a tighter match. CMake's installation scripts already
 875     # skip up-to-date files, so there's no behavior change if you install to the
 876     # same destination multiple times.
 877     if(target MATCHES "^install-")
 878       set(step_always ON)
 879     else()
 880       set(step_always OFF)
 881     endif()
 882
 883     ExternalProject_Add_Step(${NEXT_CLANG_STAGE} ${target}
 884       COMMAND ${CMAKE_COMMAND} --build <BINARY_DIR> --target ${target}
 885       COMMENT "Performing ${target} for '${NEXT_CLANG_STAGE}'"
 886       DEPENDEES configure
 887       ALWAYS ${step_always}
 888       EXCLUDE_FROM_MAIN ON
 889       USES_TERMINAL 1
 890     )
 891
 892     if(target MATCHES "^stage[0-9]*")
 893       add_custom_target(${target} DEPENDS ${NEXT_CLANG_STAGE}-${target})
 894     endif()
 895
 896     ExternalProject_Add_StepTargets(${NEXT_CLANG_STAGE} ${target})
 897   endforeach()
 898 endif()
 899
 900 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 901   add_subdirectory(utils/ClangVisualizers)
 902 endif()
 903 add_subdirectory(utils/hmaptool)
 904
 905 if(CLANG_BUILT_STANDALONE)
 906   llvm_distribution_add_targets()
 907   process_llvm_pass_plugins()
 908 endif()
 909
 910 configure_file(
 911   ${CLANG_SOURCE_DIR}/include/clang/Config/config.h.cmake
 912   ${CLANG_BINARY_DIR}/include/clang/Config/config.h)