build-test.cmd

   1 @if not defined _echo @echo off
   2 setlocal EnableDelayedExpansion
   3
   4 :: Set the default arguments for build
   5 set __BuildArch=x64
   6 set __VCBuildArch=x86_amd64
   7 set __BuildType=Debug
   8 set __BuildOS=Windows_NT
   9
  10 :: Default to highest Visual Studio version available
  11 ::
  12 :: For VS2015 (and prior), only a single instance is allowed to be installed on a box
  13 :: and VS140COMNTOOLS is set as a global environment variable by the installer. This
  14 :: allows users to locate where the instance of VS2015 is installed.
  15 ::
  16 :: For VS2017, multiple instances can be installed on the same box SxS and VS150COMNTOOLS
  17 :: is no longer set as a global environment variable and is instead only set if the user
  18 :: has launched the VS2017 Developer Command Prompt.
  19 ::
  20 :: Following this logic, we will default to the VS2017 toolset if VS150COMNTOOLS tools is
  21 :: set, as this indicates the user is running from the VS2017 Developer Command Prompt and
  22 :: is already configured to use that toolset. Otherwise, we will fallback to using the VS2015
  23 :: toolset if it is installed. Finally, we will fail the script if no supported VS instance
  24 :: can be found.
  25 if defined VS150COMNTOOLS (
  26   set "__VSToolsRoot=%VS150COMNTOOLS%"
  27   set "__VCToolsRoot=%VS150COMNTOOLS%\..\..\VC\Auxiliary\Build"
  28   set __VSVersion=vs2017
  29 ) else (
  30   set "__VSToolsRoot=%VS140COMNTOOLS%"
  31   set "__VCToolsRoot=%VS140COMNTOOLS%\..\..\VC"
  32   set __VSVersion=vs2015
  33 )
  34
  35 :: Define a prefix for most output progress messages that come from this script. That makes
  36 :: it easier to see where these are coming from. Note that there is a trailing space here.
  37 set __MsgPrefix=BUILDTEST:
  38
  39 set "__ProjectDir=%~dp0"
  40 :: remove trailing slash
  41 if %__ProjectDir:~-1%==\ set "__ProjectDir=%__ProjectDir:~0,-1%"
  42 set "__TestDir=%__ProjectDir%\tests"
  43 set "__ProjectFilesDir=%__TestDir%"
  44 set "__SourceDir=%__ProjectDir%\src"
  45 set "__PackagesDir=%__ProjectDir%\packages"
  46 set "__RootBinDir=%__ProjectDir%\bin"
  47 set "__LogsDir=%__RootBinDir%\Logs"
  48
  49 :: Default __Exclude to issues.targets
  50 set __Exclude=%__TestDir%\issues.targets
  51
  52 REM __unprocessedBuildArgs are args that we pass to msbuild (e.g. /p:__BuildArch=x64)
  53 set "__args= %*"
  54 set processedArgs=
  55 set __unprocessedBuildArgs=
  56 set __RunArgs=
  57 set __BuildAgainstPackagesArg=
  58 set __RuntimeId=
  59 set __ZipTests=
  60 set __TargetsWindows=1
  61 set __DoCrossgen=
  62
  63 :Arg_Loop
  64 if "%1" == "" goto ArgsDone
  65
  66 if /i "%1" == "-?"    goto Usage
  67 if /i "%1" == "-h"    goto Usage
  68 if /i "%1" == "-help" goto Usage
  69
  70 if /i "%1" == "x64"                   (set __BuildArch=x64&set __VCBuildArch=x86_amd64&set processedArgs=!processedArgs! %1&shift&goto Arg_Loop)
  71 if /i "%1" == "x86"                   (set __BuildArch=x86&set __VCBuildArch=x86&set processedArgs=!processedArgs! %1&shift&goto Arg_Loop)
  72 if /i "%1" == "arm"                   (set __BuildArch=arm&set __VCBuildArch=x86_arm&set processedArgs=!processedArgs! %1&shift&goto Arg_Loop)
  73 if /i "%1" == "arm64"                 (set __BuildArch=arm64&set processedArgs=!processedArgs! %1&shift&goto Arg_Loop)
  74
  75 if /i "%1" == "debug"                 (set __BuildType=Debug&set processedArgs=!processedArgs! %1&shift&goto Arg_Loop)
  76 if /i "%1" == "release"               (set __BuildType=Release&set processedArgs=!processedArgs! %1&shift&goto Arg_Loop)
  77 if /i "%1" == "checked"               (set __BuildType=Checked&set processedArgs=!processedArgs! %1&shift&goto Arg_Loop)
  78
  79 if /i "%1" == "skipmanaged"           (set __SkipManaged=1&set processedArgs=!processedArgs! %1&shift&goto Arg_Loop)
  80 if /i "%1" == "toolset_dir"           (set __ToolsetDir=%2&set __PassThroughArgs=%__PassThroughArgs% %2&set processedArgs=!processedArgs! %1 %2&shift&shift&goto Arg_Loop)
  81 if /i "%1" == "buildagainstpackages"  (set __ZipTests=1&set __BuildAgainstPackagesArg=-BuildTestsAgainstPackages&set processedArgs=!processedArgs! %1&shift&goto Arg_Loop)
  82 if /i "%1" == "ziptests"              (set __ZipTests=1&set processedArgs=!processedArgs! %1&shift&goto Arg_Loop)
  83 if /i "%1" == "crossgen"              (set __DoCrossgen=1&set processedArgs=!processedArgs! %1&shift&goto Arg_Loop)
  84 if /i "%1" == "runtimeid"             (set __RuntimeId=%2&set processedArgs=!processedArgs! %1 %2&shift&shift&goto Arg_Loop)
  85 if /i "%1" == "targetsNonWindows"     (set __TargetsWindows=0&set processedArgs=!processedArgs! %1&shift&goto Arg_Loop)
  86 if /i "%1" == "Exclude"               (set __Exclude=%2&set processedArgs=!processedArgs! %1 %2&shift&shift&goto Arg_Loop)
  87
  88 if [!processedArgs!]==[] (
  89   set __UnprocessedBuildArgs=%__args%
  90 ) else (
  91   set __UnprocessedBuildArgs=%__args%
  92   for %%t in (!processedArgs!) do (
  93     set __UnprocessedBuildArgs=!__UnprocessedBuildArgs:*%%t=!
  94   )
  95 )
  96
  97 :ArgsDone
  98
  99 if defined __BuildAgainstPackagesArg (
 100     if not defined __RuntimeID (
 101         echo %__MsgPrefix%Error: When building against packages, you must supply a target Runtime ID.
 102         exit /b 1
 103     )
 104 )
 105
 106 echo %__MsgPrefix%Using environment: "%__VSToolsRoot%\VsDevCmd.bat"
 107 call                                 "%__VSToolsRoot%\VsDevCmd.bat"
 108
 109 set __RunArgs=-BuildOS=%__BuildOS% -BuildType=%__BuildType% -BuildArch=%__BuildArch%
 110
 111 rem arm64 builds currently use private toolset which has not been released yet
 112 REM TODO, remove once the toolset is open.
 113 if /i "%__BuildArch%" == "arm64" call :PrivateToolSet
 114
 115 echo %__MsgPrefix%Commencing CoreCLR repo test build
 116
 117 set "__BinDir=%__RootBinDir%\Product\%__BuildOS%.%__BuildArch%.%__BuildType%"
 118 set "__TestRootDir=%__RootBinDir%\tests"
 119 set "__TestBinDir=%__TestRootDir%\%__BuildOS%.%__BuildArch%.%__BuildType%"
 120 :: We have different managed and native intermediate dirs because the managed bits will include
 121 :: the configuration information deeper in the intermediates path.
 122 :: These variables are used by the msbuild project files.
 123
 124 if not defined __TestIntermediateDir (
 125     set "__TestIntermediateDir=tests\obj\%__BuildOS%.%__BuildArch%.%__BuildType%"
 126 )
 127 set "__NativeTestIntermediatesDir=%__RootBinDir%\%__TestIntermediateDir%\Native"
 128 set "__ManagedTestIntermediatesDir=%__RootBinDir%\%__TestIntermediateDir%\Managed"
 129
 130 :: Generate path to be set for CMAKE_INSTALL_PREFIX to contain forward slash
 131 set "__CMakeBinDir=%__TestBinDir%"
 132 set "__CMakeBinDir=%__CMakeBinDir:\=/%"
 133
 134 if not exist "%__TestBinDir%"                   md "%__TestBinDir%"
 135 if not exist "%__NativeTestIntermediatesDir%"   md "%__NativeTestIntermediatesDir%"
 136 if not exist "%__ManagedTestIntermediatesDir%"  md "%__ManagedTestIntermediatesDir%"
 137 if not exist "%__LogsDir%"                      md "%__LogsDir%"
 138
 139 echo %__MsgPrefix%Checking prerequisites
 140
 141 :: Eval the output from probe-win1.ps1
 142 for /f "delims=" %%a in ('powershell -NoProfile -ExecutionPolicy ByPass "& ""%__SourceDir%\pal\tools\probe-win.ps1"""') do %%a
 143
 144 REM =========================================================================================
 145 REM ===
 146 REM === Restore Build Tools
 147 REM ===
 148 REM =========================================================================================
 149 call "%__ProjectDir%\init-tools.cmd"
 150
 151 REM =========================================================================================
 152 REM ===
 153 REM === Resolve runtime dependences
 154 REM ===
 155 REM =========================================================================================
 156
 157 call "%__TestDir%\setup-stress-dependencies.cmd" /arch %__BuildArch% /outputdir %__BinDir%
 158
 159 REM =========================================================================================
 160 REM ===
 161 REM === Native test build section
 162 REM ===
 163 REM =========================================================================================
 164
 165 echo %__MsgPrefix%Commencing build of native test components for %__BuildArch%/%__BuildType%
 166
 167 if defined __ToolsetDir (
 168  echo %__MsgPrefix%ToolsetDir is defined to be :%__ToolsetDir%
 169  goto GenVSSolution :: Private ToolSet is Defined
 170 )
 171
 172 :: Set the environment for the native build
 173 echo %__MsgPrefix%Using environment: "%__VCToolsRoot%\vcvarsall.bat" %__VCBuildArch%
 174 call                                 "%__VCToolsRoot%\vcvarsall.bat" %__VCBuildArch%
 175 @if defined _echo @echo on
 176
 177 if not defined VSINSTALLDIR (
 178     echo %__MsgPrefix%Error: VSINSTALLDIR variable not defined.
 179     exit /b 1
 180 )
 181 if not exist "%VSINSTALLDIR%DIA SDK" goto NoDIA
 182
 183 :GenVSSolution
 184
 185 pushd "%__NativeTestIntermediatesDir%"
 186 call "%__SourceDir%\pal\tools\gen-buildsys-win.bat" ""%__ProjectFilesDir%"" %__VSVersion% %__BuildArch%
 187 @if defined _echo @echo on
 188 popd
 189
 190 if not exist "%__NativeTestIntermediatesDir%\install.vcxproj" (
 191     echo %__MsgPrefix%Failed to generate test native component build project!
 192     exit /b 1
 193 )
 194
 195 set __msbuildNativeArgs=-configuration=%__BuildType%
 196
 197 if defined __ToolsetDir (
 198     set __msbuildNativeArgs=%__msbuildNativeArgs% -UseEnv
 199 ) else (
 200     set __msbuildNativeArgs=%__msbuildNativeArgs% -platform=%__BuildArch%
 201 )
 202
 203 set __BuildLogRootName=Tests_Native
 204 set __BuildLog=%__LogsDir%\%__BuildLogRootName%_%__BuildOS%__%__BuildArch%__%__BuildType%.log
 205 set __BuildWrn=%__LogsDir%\%__BuildLogRootName%_%__BuildOS%__%__BuildArch%__%__BuildType%.wrn
 206 set __BuildErr=%__LogsDir%\%__BuildLogRootName%_%__BuildOS%__%__BuildArch%__%__BuildType%.err
 207 set __msbuildLog=/flp:Verbosity=normal;LogFile="%__BuildLog%"
 208 set __msbuildWrn=/flp1:WarningsOnly;LogFile="%__BuildWrn%"
 209 set __msbuildErr=/flp2:ErrorsOnly;LogFile="%__BuildErr%"
 210
 211 call "%__ProjectDir%\run.cmd" build -Project="%__NativeTestIntermediatesDir%\install.vcxproj" -MsBuildLog=!__msbuildLog! -MsBuildWrn=!__msbuildWrn! -MsBuildErr=!__msbuildErr! %__msbuildNativeArgs% %__RunArgs% %__unprocessedBuildArgs%
 212 if errorlevel 1 (
 213     echo %__MsgPrefix%Error: build failed. Refer to the build log files for details:
 214     echo     %__BuildLog%
 215     echo     %__BuildWrn%
 216     echo     %__BuildErr%
 217     exit /b 1
 218 )
 219
 220 :skipnative
 221
 222 set __BuildLogRootName=Restore_Product
 223 set __BuildLog=%__LogsDir%\%__BuildLogRootName%_%__BuildOS%__%__BuildArch%__%__BuildType%.log
 224 set __BuildWrn=%__LogsDir%\%__BuildLogRootName%_%__BuildOS%__%__BuildArch%__%__BuildType%.wrn
 225 set __BuildErr=%__LogsDir%\%__BuildLogRootName%_%__BuildOS%__%__BuildArch%__%__BuildType%.err
 226 set __msbuildLog=/flp:Verbosity=normal;LogFile="%__BuildLog%"
 227 set __msbuildWrn=/flp1:WarningsOnly;LogFile="%__BuildWrn%"
 228 set __msbuildErr=/flp2:ErrorsOnly;LogFile="%__BuildErr%"
 229
 230 set "__TestWorkingDir=%__RootBinDir%\tests\%__BuildOS%.%__BuildArch%.%__BuildType%"
 231
 232 if not defined __BuildAgainstPackagesArg goto SkipRestoreProduct
 233 REM =========================================================================================
 234 REM ===
 235 REM === Restore product binaries from packages
 236 REM ===
 237 REM =========================================================================================
 238
 239 if not defined XunitTestBinBase       set  XunitTestBinBase=%__TestWorkingDir%
 240 set "CORE_ROOT=%XunitTestBinBase%\Tests\Core_Root"
 241
 242 call "%__ProjectDir%\run.cmd" build -Project=%__ProjectDir%\tests\build.proj -BatchRestorePackages -MsBuildLog=!__msbuildLog! -MsBuildWrn=!__msbuildWrn! -MsBuildErr=!__msbuildErr! %__RunArgs% %__BuildAgainstPackagesArg% %__unprocessedBuildArgs%
 243
 244 set __BuildLogRootName=Tests_GenerateRuntimeLayout
 245
 246 call "%__ProjectDir%\run.cmd" build -Project=%__ProjectDir%\tests\runtest.proj -BinPlaceRef -BinPlaceProduct -CopyCrossgenToProduct -RuntimeId="%__RuntimeId%" -MsBuildLog=!__msbuildLog! -MsBuildWrn=!__msbuildWrn! -MsBuildErr=!__msbuildErr! %__RunArgs% %__BuildAgainstPackagesArg% %__unprocessedBuildArgs%
 247 if errorlevel 1 (
 248     echo BinPlace of mscorlib.dll failed
 249     exit /b 1
 250 )
 251
 252 echo %__MsgPrefix% Restored CoreCLR product from packages
 253
 254 :SkipRestoreProduct
 255
 256 if defined __SkipManaged exit /b 0
 257
 258 set __BuildLogRootName=Tests_Managed
 259 set __BuildLog=%__LogsDir%\%__BuildLogRootName%_%__BuildOS%__%__BuildArch%__%__BuildType%.log
 260 set __BuildWrn=%__LogsDir%\%__BuildLogRootName%_%__BuildOS%__%__BuildArch%__%__BuildType%.wrn
 261 set __BuildErr=%__LogsDir%\%__BuildLogRootName%_%__BuildOS%__%__BuildArch%__%__BuildType%.err
 262 set __msbuildLog=/flp:Verbosity=normal;LogFile="%__BuildLog%"
 263 set __msbuildWrn=/flp1:WarningsOnly;LogFile="%__BuildWrn%"
 264 set __msbuildErr=/flp2:ErrorsOnly;LogFile="%__BuildErr%"
 265
 266 REM =========================================================================================
 267 REM ===
 268 REM === Managed test build section
 269 REM ===
 270 REM =========================================================================================
 271
 272 echo %__MsgPrefix%Starting the Managed Tests Build
 273
 274 if not defined VSINSTALLDIR (
 275     echo %__MsgPrefix%Error: buildtest.cmd should be run from a Visual Studio Command Prompt.  Please see https://github.com/dotnet/coreclr/blob/master/Documentation/project-docs/developer-guide.md for build instructions.
 276     exit /b 1
 277 )
 278
 279 call "%__ProjectDir%\run.cmd" build -Project=%__ProjectDir%\tests\build.proj -MsBuildLog=!__msbuildLog! -MsBuildWrn=!__msbuildWrn! -MsBuildErr=!__msbuildErr! %__RunArgs% %__BuildAgainstPackagesArg% %__unprocessedBuildArgs%
 280 if errorlevel 1 (
 281     echo %__MsgPrefix%Error: build failed. Refer to the build log files for details:
 282     echo     %__BuildLog%
 283     echo     %__BuildWrn%
 284     echo     %__BuildErr%
 285     exit /b 1
 286 )
 287
 288 REM Prepare the Test Drop
 289 REM Cleans any NI from the last run
 290 powershell "Get-ChildItem -path %__TestWorkingDir% -Include '*.ni.*' -Recurse -Force | Remove-Item -force"
 291 REM Cleans up any lock folder used for synchronization from last run
 292 powershell "Get-ChildItem -path %__TestWorkingDir% -Include 'lock' -Recurse -Force |  where {$_.Attributes -eq 'Directory'}| Remove-Item -force -Recurse"
 293
 294 set CORE_ROOT=%__TestBinDir%\Tests\Core_Root
 295 set CORE_ROOT_STAGE=%__TestBinDir%\Tests\Core_Root_Stage
 296 if exist "%CORE_ROOT%" rd /s /q "%CORE_ROOT%"
 297 if exist "%CORE_ROOT_STAGE%" rd /s /q "%CORE_ROOT_STAGE%"
 298 md "%CORE_ROOT%"
 299 md "%CORE_ROOT_STAGE%"
 300 xcopy "%__BinDir%" "%CORE_ROOT_STAGE%"
 301
 302
 303 if defined __BuildAgainstPackagesArg (
 304   if "%__TargetsWindows%"=="0" (
 305
 306     if not exist %__PackagesDir%\TestNativeBins (
 307         echo %__MsgPrefix%Error: Ensure you have run sync.cmd -ab before building a non-Windows test overlay against packages
 308         exit /b 1
 309     )
 310
 311     for /R %__PackagesDir%\TestNativeBins\%__RuntimeId%\%__BuildType% %%f in (*.so) do copy %%f %CORE_ROOT_STAGE%
 312     for /R %__PackagesDir%\TestNativeBins\%__RuntimeId%\%__BuildType% %%f in (*.dylib) do copy %%f %CORE_ROOT_STAGE%
 313   )
 314 )
 315
 316 echo %__MsgPrefix%Creating test wrappers...
 317
 318 set RuntimeIdArg=
 319 set TargetsWindowsArg=
 320
 321 if defined __RuntimeId (
 322     set RuntimeIdArg=-RuntimeID="%__RuntimeId%"
 323 )
 324
 325 if "%__TargetsWindows%"=="1" (
 326     set TargetsWindowsArg=-TargetsWindows=true
 327 ) else if "%__TargetsWindows%"=="0" (
 328     set TargetsWindowsArg=-TargetsWindows=false
 329 )
 330
 331 set __BuildLogRootName=Tests_XunitWrapper
 332 set __BuildLog=%__LogsDir%\%__BuildLogRootName%_%__BuildOS%__%__BuildArch%__%__BuildType%.log
 333 set __BuildWrn=%__LogsDir%\%__BuildLogRootName%_%__BuildOS%__%__BuildArch%__%__BuildType%.wrn
 334 set __BuildErr=%__LogsDir%\%__BuildLogRootName%_%__BuildOS%__%__BuildArch%__%__BuildType%.err
 335 set __msbuildLog=/flp:Verbosity=normal;LogFile="%__BuildLog%"
 336 set __msbuildWrn=/flp1:WarningsOnly;LogFile="%__BuildWrn%"
 337 set __msbuildErr=/flp2:ErrorsOnly;LogFile="%__BuildErr%"
 338
 339 call %__ProjectDir%\run.cmd build -Project=%__ProjectDir%\tests\runtest.proj -BuildWrappers -MsBuildEventLogging=" " -MsBuildLog=!__msbuildLog! -MsBuildWrn=!__msbuildWrn! -MsBuildErr=!__msbuildErr! %__RunArgs% %__BuildAgainstPackagesArg% %TargetsWindowsArg% %__unprocessedBuildArgs%
 340 if errorlevel 1 (
 341     echo Xunit Wrapper build failed
 342     exit /b 1
 343 )
 344
 345 echo %__MsgPrefix%Creating test overlay...
 346
 347 set __BuildLogRootName=Tests_Overlay_Managed
 348 set __BuildLog=%__LogsDir%\%__BuildLogRootName%_%__BuildOS%__%__BuildArch%__%__BuildType%.log
 349 set __BuildWrn=%__LogsDir%\%__BuildLogRootName%_%__BuildOS%__%__BuildArch%__%__BuildType%.wrn
 350 set __BuildErr=%__LogsDir%\%__BuildLogRootName%_%__BuildOS%__%__BuildArch%__%__BuildType%.err
 351 set __msbuildLog=/flp:Verbosity=normal;LogFile="%__BuildLog%"
 352 set __msbuildWrn=/flp1:WarningsOnly;LogFile="%__BuildWrn%"
 353 set __msbuildErr=/flp2:ErrorsOnly;LogFile="%__BuildErr%"
 354
 355 call %__ProjectDir%\run.cmd build -Project=%__ProjectDir%\tests\runtest.proj -testOverlay -MsBuildLog=!__msbuildLog! -MsBuildWrn=!__msbuildWrn! -MsBuildErr=!__msbuildErr! %__RunArgs% %RuntimeIdArg% %__unprocessedBuildArgs%
 356 if errorlevel 1 (
 357     echo %__MsgPrefix%Error: build failed. Refer to the build log files for details:
 358     echo     %__BuildLog%
 359     echo     %__BuildWrn%
 360     echo     %__BuildErr%
 361     exit /b 1
 362 )
 363
 364 xcopy /s /y "%CORE_ROOT_STAGE%" "%CORE_ROOT%"
 365
 366 set __CrossgenArg = ""
 367 if defined __DoCrossgen (
 368   set __CrossgenArg="-Crossgen"
 369   if "%__TargetsWindows%" == "1" (
 370     call :PrecompileFX
 371   ) else (
 372     echo "%__MsgPrefix% Crossgen only supported on Windows, for now"
 373   )
 374 )
 375
 376 rd /s /q "%CORE_ROOT_STAGE%"
 377
 378 if not defined __ZipTests goto SkipPrepForPublish
 379
 380 set __BuildLogRootName=Helix_Prep
 381 set __BuildLog=%__LogsDir%\%__BuildLogRootName%_%__BuildOS%__%__BuildArch%__%__BuildType%.log
 382 set __BuildWrn=%__LogsDir%\%__BuildLogRootName%_%__BuildOS%__%__BuildArch%__%__BuildType%.wrn
 383 set __BuildErr=%__LogsDir%\%__BuildLogRootName%_%__BuildOS%__%__BuildArch%__%__BuildType%.err
 384 set __msbuildLog=/flp:Verbosity=normal;LogFile="%__BuildLog%"
 385 set __msbuildWrn=/flp1:WarningsOnly;LogFile="%__BuildWrn%"
 386 set __msbuildErr=/flp2:ErrorsOnly;LogFile="%__BuildErr%"
 387
 388 REM =========================================================================================
 389 REM ===
 390 REM === Prep test binaries for Helix publishing
 391 REM ===
 392 REM =========================================================================================
 393
 394 call %__ProjectDir%\run.cmd build -Project=%__ProjectDir%\tests\helixprep.proj  -MsBuildLog=!__msbuildLog! -MsBuildWrn=!__msbuildWrn! -MsBuildErr=!__msbuildErr! %__RunArgs% %__BuildAgainstPackagesArg% %RuntimeIdArg% %TargetsWindowsArg% %__CrossgenArg% %__unprocessedBuildArgs%
 395 if errorlevel 1 (
 396     echo %__MsgPrefix%Error: build failed. Refer to the build log files for details:
 397     echo     %__BuildLog%
 398     echo     %__BuildWrn%
 399     echo     %__BuildErr%
 400     exit /b 1
 401 )
 402
 403 echo %__MsgPrefix% Prepped test binaries for publishing
 404
 405 :SkipPrepForPublish
 406
 407 REM =========================================================================================
 408 REM ===
 409 REM === All builds complete!
 410 REM ===
 411 REM =========================================================================================
 412
 413 echo %__MsgPrefix%Test build successful.
 414 echo %__MsgPrefix%Test binaries are available at !__TestBinDir!
 415 exit /b 0
 416
 417 :Usage
 418 echo.
 419 echo Usage:
 420 echo     %0 [option1] [option2] ...
 421 echo All arguments are optional. Options are case-insensitive. The options are:
 422 echo.
 423 echo. -? -h -help: view this message.
 424 echo Build architecture: -buildArch: only x64 is currently allowed ^(default: x64^).
 425 echo Build type: -buildType: one of Debug, Checked, Release ^(default: Debug^).
 426 echo buildagainstpackages: builds tests against restored packages, instead of against a built product.
 427 echo runtimeid ^<ID^>: Builds a test overlay for the specified OS (Only supported when building against packages). Supported IDs are:
 428 echo     alpine.3.4.3-x64: Builds overlay for Alpine 3.4.3
 429 echo     debian.8-x64: Builds overlay for Debian 8
 430 echo     fedora.24-x64: Builds overlay for Fedora 24
 431 echo     linux-x64: Builds overlay for portable linux
 432 echo     opensuse.42.1-x64: Builds overlay for OpenSUSE 42.1
 433 echo     osx.10.12-x64: Builds overlay for OSX 10.12
 434 echo     osx-x64: Builds overlay for portable OSX
 435 echo     rhel.7-x64: Builds overlay for RHEL 7 or CentOS
 436 echo     ubuntu.14.04-x64: Builds overlay for Ubuntu 14.04
 437 echo     ubuntu.16.04-x64: Builds overlay for Ubuntu 16.04
 438 echo     ubuntu.16.10-x64: Builds overlay for Ubuntu 16.10
 439 echo     win-x64: Builds overlay for portable Windows
 440 echo     win7-x64: Builds overlay for Windows 7
 441 echo ziptests: zips CoreCLR tests & Core_Root for a Helix run
 442 echo crossgen: Precompiles the framework managed assemblies
 443 echo Exclude- Optional parameter - specify location of default exclusion file (defaults to tests\issues.targets if not specified)
 444 echo     Set to "" to disable default exclusion file.
 445 echo -- ... : all arguments following this tag will be passed directly to msbuild.
 446 echo -priority=^<N^> : specify a set of test that will be built and run, with priority N.
 447 echo     0: Build only priority 0 cases as essential testcases (default)
 448 echo     1: Build all tests with priority 0 and 1
 449 echo     666: Build all tests with priority 0, 1 ... 666
 450 echo -sequential: force a non-parallel build ^(default is to build in parallel
 451 echo     using all processors^).
 452 echo -verbose: enables detailed file logging for the msbuild tasks into the msbuild log file.
 453 exit /b 1
 454
 455 :NoDIA
 456 echo Error: DIA SDK is missing at "%VSINSTALLDIR%DIA SDK". ^
 457 This is due to a bug in the Visual Studio installer. It does not install DIA SDK at "%VSINSTALLDIR%" but rather ^
 458 at the install location of previous Visual Studio version. The workaround is to copy the DIA SDK folder from the Visual Studio install location ^
 459 of the previous version to "%VSINSTALLDIR%" and then build.
 460 :: DIA SDK not included in Express editions
 461 echo Visual Studio Express does not include the DIA SDK. ^
 462 You need Visual Studio 2015 or 2017 (Community is free).
 463 echo See: https://github.com/dotnet/coreclr/blob/master/Documentation/project-docs/developer-guide.md#prerequisites
 464 exit /b 1
 465
 466
 467 :PrivateToolSet
 468
 469 echo %__MsgPrefix% Setting Up the usage of __ToolsetDir:%__ToolsetDir%
 470
 471 if /i "%__ToolsetDir%" == "" (
 472     echo %__MsgPrefix%Error: A toolset directory is required for the Arm64 Windows build. Use the toolset_dir argument.
 473     exit /b 1
 474 )
 475
 476 if not exist "%__ToolsetDir%"\buildenv_arm64.cmd goto :Not_EWDK
 477 call "%__ToolsetDir%"\buildenv_arm64.cmd
 478 exit /b 0
 479
 480 :Not_EWDK
 481 set PATH=%__ToolsetDir%\VC_sdk\bin;%PATH%
 482 set LIB=%__ToolsetDir%\VC_sdk\lib\arm64;%__ToolsetDir%\sdpublic\sdk\lib\arm64
 483 set INCLUDE=^
 484 %__ToolsetDir%\VC_sdk\inc;^
 485 %__ToolsetDir%\sdpublic\sdk\inc;^
 486 %__ToolsetDir%\sdpublic\shared\inc;^
 487 %__ToolsetDir%\sdpublic\shared\inc\minwin;^
 488 %__ToolsetDir%\sdpublic\sdk\inc\ucrt;^
 489 %__ToolsetDir%\sdpublic\sdk\inc\minwin;^
 490 %__ToolsetDir%\sdpublic\sdk\inc\mincore;^
 491 %__ToolsetDir%\sdpublic\sdk\inc\abi;^
 492 %__ToolsetDir%\sdpublic\sdk\inc\clientcore;^
 493 %__ToolsetDir%\diasdk\include
 494 exit /b 0
 495
 496 :PrecompileFX
 497 for %%F in (%CORE_ROOT%\*.dll) do call :PrecompileAssembly "%%F" %%~nF%%~xF
 498 exit /b 0
 499
 500 REM Compile the managed assemblies in Core_ROOT before running the tests
 501 :PrecompileAssembly
 502
 503 REM Skip mscorlib since it is already precompiled.
 504 if /I "%2" == "mscorlib.dll" exit /b 0
 505 if /I "%2" == "mscorlib.ni.dll" exit /b 0
 506 REM don't precompile anything from CoreCLR
 507 if /I exist %CORE_ROOT_STAGE%\%2 exit /b 0
 508
 509 "%CORE_ROOT_STAGE%\crossgen.exe" /Platform_Assemblies_Paths "%CORE_ROOT%" /in "%1" /out "%CORE_ROOT%/temp.ni.dll" >nul 2>nul
 510 set /a __exitCode = %errorlevel%
 511 if "%__exitCode%" == "-2146230517" (
 512     echo %2 is not a managed assembly.
 513     exit /b 0
 514 )
 515
 516 if %__exitCode% neq 0 (
 517     echo Unable to precompile %2
 518     exit /b 0
 519 )
 520
 521 :: Delete original .dll & replace it with the Crossgened .dll
 522 del %1
 523 ren "%CORE_ROOT%\temp.ni.dll" %2
 524
 525 echo Successfully precompiled %2
 526 exit /b 0