build-packages.cmd

   1 @if not defined _echo @echo off
   2 setlocal EnableDelayedExpansion
   3
   4 set "__ProjectDir=%~dp0"
   5
   6 set "__args=%*"
   7 set processedArgs=
   8 set unprocessedArgs=
   9 set __MSBuildArgs=
  10
  11 :Arg_Loop
  12 if "%1" == "" goto ArgsDone
  13 if /I [%1] == [/?] goto Usage
  14 if /I [%1] == [/help] goto Usage
  15
  16 REM CMD eats "=" on the argument list.
  17 REM TODO: remove all -Property=Value type arguments here once we get rid of them in buildpipeline.
  18 if /i "%1" == "-BuildArch"       (set processedArgs=!processedArgs! %1=%2&set __MSBuildArgs=!__MSBuildArgs! /p:__BuildArch=%2&shift&shift&goto Arg_Loop)
  19 if /i "%1" == "-BuildType"       (set processedArgs=!processedArgs! %1=%2&set __MSBuildArgs=!__MSBuildArgs! /p:__BuildType=%2&shift&shift&goto Arg_Loop)
  20 if /i "%1" == "-OfficialBuildId" (set processedArgs=!processedArgs! %1=%2&set __MSBuildArgs=!__MSBuildArgs! /p:OfficialBuildId=%2&shift&shift&goto Arg_Loop)
  21 if /i "%1" == "--"               (set processedArgs=!processedArgs! %1&shift)
  22
  23 REM handle any unprocessed arguments, assumed to go only after the processed arguments above
  24 if [!processedArgs!]==[] (
  25    set unprocessedArgs=%__args%
  26 ) else (
  27    set unprocessedArgs=%__args%
  28    for %%t in (!processedArgs!) do (
  29    REM strip out already-processed arguments from unprocessedArgs
  30    set unprocessedArgs=!unprocessedArgs:*%%t=!
  31    )
  32 )
  33
  34 :ArgsDone
  35
  36 set logFile=%__ProjectDir%bin\Logs\build-packages.binlog
  37 powershell -NoProfile -ExecutionPolicy ByPass -NoLogo -File "%__ProjectDir%eng\common\build.ps1"^
  38   -r -b -projects %__ProjectDir%src\.nuget\packages.builds^
  39   -verbosity minimal /bl:%logFile% /nodeReuse:false^
  40   /p:__BuildOS=Windows_NT /p:ArcadeBuild=true^
  41   /p:PortableBuild=true /p:FilterToOSGroup=Windows_NT^
  42   %__MSBuildArgs% %unprocessedArgs%
  43
  44 if NOT [!ERRORLEVEL!]==[0] (
  45   echo ERROR: An error occurred while building packages. See log for more details:
  46   echo     %logFile%
  47   exit /b !ERRORLEVEL!
  48 )
  49
  50 echo Done Building Packages.
  51 exit /b
  52
  53 :Usage
  54 echo.
  55 echo Builds the NuGet packages from the binaries that were built in the Build product binaries step.
  56 echo The following properties are required to define build architecture
  57 echo   -BuildArch=[architecture] -BuildType=[configuration]
  58 echo Architecture can be x64, x86, arm, or arm64
  59 echo Configuration can be Release, Debug, or Checked
  60 exit /b