build/tizen-cmake/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali-core")
   5
   6 PROJECT(${name})
   7 SET(PKG_NAME ${name})
   8
   9 # API VERSION (Not DALi release version)
  10 SET(${name}_VERSION_MAJOR 0)
  11 SET(${name}_VERSION_MINOR 1)
  12 SET(${name}_VERSION_PATCH 1)
  13 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  14
  15 SET(DALI_VERSION ${${name}_VERSION} )
  16
  17 # Define options to CMake
  18
  19 OPTION(ENABLE_EXPORTALL      "Enable Export all symbols" OFF)
  20 OPTION(ENABLE_DEBUG          "Enable Debug" OFF)
  21 OPTION(ENABLE_BACKTRACE      "Enable Backtrace" OFF)
  22 OPTION(ENABLE_LOCK_BACKTRACE "Enable" OFF)
  23 OPTION(ENABLE_COVERAGE       "Coverage" OFF)
  24
  25 # Set up compiler definitions
  26
  27 ADD_DEFINITIONS(-DPLATFORM_TIZEN -DDALI_COMPILATION)
  28 ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  29
  30 IF("${ARCH}" STREQUAL "arm")
  31     ADD_DEFINITIONS("-DTARGET")
  32 ENDIF("${ARCH}" STREQUAL "arm")
  33
  34 IF( NOT ${ENABLE_EXPORTALL} AND NOT ${ENABLE_DEBUG} )
  35   ADD_DEFINITIONS( "-fvisibility=hidden -DHIDE_DALI_INTERNALS" )
  36 ENDIF( NOT ${ENABLE_EXPORTALL} AND NOT ${ENABLE_DEBUG} )
  37
  38 IF( ENABLE_DEBUG )
  39   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
  40 ENDIF( ENABLE_DEBUG )
  41
  42 IF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  43   ADD_DEFINITIONS( "-DBACKTRACE_ENABLED" )
  44 ENDIF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  45
  46 IF( ENABLE_LOCK_BACKTRACE )
  47   ADD_DEFINITIONS( "-DLOCK_BACKTRACE_ENABLED" )
  48 ENDIF( ENABLE_LOCK_BACKTRACE )
  49
  50 # Deployment folder should come from spec file or command line:
  51 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  52 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  53
  54 # from root/build/tizen, get back to root
  55 SET(ROOT_SRC_DIR ${CMAKE_SOURCE_DIR}/../..)
  56
  57 # Requires the following variables to be setup
  58 # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIBDIR@ @DEV_INCLUDE_PATH@
  59 SET(INCLUDE_DIR $ENV{includedir})
  60 SET(DEV_INCLUDE_PATH ${INCLUDE_DIR})
  61 SET(LIB_DIR $ENV{libdir})
  62 CONFIGURE_FILE( dali-core.pc.in dali-core.pc )
  63
  64 MESSAGE( STATUS "CMAKE_BUILD_TYPE: " ${CMAKE_BUILD_TYPE} )
  65 if(CMAKE_BUILD_TYPE MATCHES Debug)
  66     MESSAGE("Setting variable: DEBUG_ENABLED")
  67     SET(DEBUG_ENABLED "1")
  68 ENDIF()
  69
  70 # Set up compiler flags and warnings
  71 #ADD_COMPILE_OPTIONS( -std=c++11 -ggdb )
  72 ADD_COMPILE_OPTIONS( -std=c++11 -gdwarf-4 )
  73 ADD_COMPILE_OPTIONS( -Wnon-virtual-dtor -Woverloaded-virtual -Wold-style-cast )
  74 ADD_COMPILE_OPTIONS( -Werror -Wall -Wextra -Wno-unused-parameter -Wfloat-equal )
  75
  76 IF( ENABLE_DEBUG )
  77   ADD_COMPILE_OPTIONS( -O0 )
  78 ELSE( ENABLE_DEBUG )
  79   ADD_COMPILE_OPTIONS( -Os )
  80 ENDIF( ENABLE_DEBUG )
  81
  82 IF( ENABLE_COVERAGE OR CXXFLAGS MATCHES --coverage)
  83   ADD_COMPILE_OPTIONS( --coverage )
  84   SET(COVERAGE --coverage)
  85 ENDIF()
  86
  87 INCLUDE_DIRECTORIES(
  88   ${ROOT_SRC_DIR}
  89 )
  90
  91 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
  92
  93 SET(SOURCES "")
  94
  95 # could use INCLUDE to get the source lists a different way;
  96 # would then need to specify a build folder somehow...
  97 ADD_SUBDIRECTORY( ${SOURCE_DIR}/internal dali/internal )
  98 ADD_SUBDIRECTORY( ${SOURCE_DIR}/integration-api dali/integration-api )
  99 ADD_SUBDIRECTORY( ${SOURCE_DIR}/public-api dali/public-api )
 100 ADD_SUBDIRECTORY( ${SOURCE_DIR}/devel-api dali/devel-api )
 101
 102 ADD_LIBRARY( ${name} SHARED ${SOURCES} )
 103
 104 TARGET_LINK_LIBRARIES( ${name}
 105   -lpthread
 106   ${COVERAGE}
 107 )
 108
 109 SET_TARGET_PROPERTIES( ${name}
 110   PROPERTIES
 111   VERSION ${DALI_VERSION}
 112   SOVERSION ${${name}_VERSION_MAJOR}
 113   CLEAN_DIRECT_OUPUT 1
 114 )
 115
 116 # Install the library so file and symlinks
 117 INSTALL( TARGETS ${name} DESTINATION ${PREFIX}/lib )
 118
 119 # macro for installing headers by replacing prefix. (TODO, investigate
 120 # if there is a CMAKE way of doing this automatically)
 121 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 122   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 123   FOREACH(HEADER ${${HEADER_LIST}})
 124     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 125     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 126     INSTALL(FILES ${HEADER} DESTINATION ${PREFIX}/include/${NEWDIR})
 127   ENDFOREACH(HEADER)
 128 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 129
 130 # Install headers using lists defined by ADD_SUBDIRECTORY
 131 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${SOURCE_DIR} "dali")
 132 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${SOURCE_DIR} "dali")
 133 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${SOURCE_DIR} "dali")
 134
 135 IF(UNIX)
 136   # Define custom rules for coverage
 137   SET(COVERAGE_DIR .cov)
 138   SET(COVERAGE_OUTPUT_DIR doc/coverage)
 139
 140   # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 141   # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 142   EXECUTE_PROCESS( COMMAND bash -c "lcov --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 143   STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 144   IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 145     SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 146   ENDIF()
 147
 148   ADD_CUSTOM_TARGET( cov_data lcov ${LCOV_OPTS} --base-directory dali --directory . -c -o dali.info
 149           COMMAND lcov ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"public-api/shader-effects/*\" \"*/image-actor*\" -o dali.info )
 150
 151   ADD_CUSTOM_TARGET( coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 152     DEPENDS cov_data )
 153
 154   ADD_CUSTOM_TARGET( reset_coverage @lcov -z --directory `pwd` )
 155
 156   # Define custom rule for distclean
 157   ADD_CUSTOM_TARGET( distclean @echo cleaning for source distribution )
 158   ADD_CUSTOM_COMMAND(
 159         DEPENDS clean
 160         COMMENT "distribution clean"
 161         COMMAND find
 162         ARGS    .
 163         -not -name config.cmake -and \(
 164         -name tester.c -or
 165         -name Testing -or
 166         -name CMakeFiles -or
 167         -name cmake.depends -or
 168         -name cmake.check_depends -or
 169         -name CMakeCache.txt -or
 170         -name cmake.check_cache -or
 171         -name *.cmake -or
 172         -name Makefile -or
 173         -name core -or
 174         -name core.* -or
 175         -name gmon.out -or
 176         -name install_manifest.txt -or
 177         -name *.pc -or
 178         -name *.gcov -or
 179         -name *.gcno -or
 180         -name *.gcda -or
 181         -name *~ \)
 182         | grep -v TC | xargs rm -rf
 183         TARGET  distclean
 184         VERBATIM
 185         )
 186
 187 ENDIF(UNIX)
 188
 189
 190 MESSAGE( STATUS "Configuration:\n" )
 191 MESSAGE( STATUS "Prefix:                " ${PREFIX} )
 192 MESSAGE( STATUS "Debug build:           " ${ENABLE_DEBUG} )
 193 MESSAGE( STATUS "Backtrace:             " ${ENABLE_BACKTRACE} )
 194 MESSAGE( STATUS "Scoped Lock backtrace: " ${ENABLE_LOCK_BACKTRACE} )
 195 MESSAGE( STATUS "Coverage:              " ${ENABLE_COVERAGE} )