build/tizen/configure.ac

   1 #
   2 # Copyright (c) 2014 Samsung Electronics Co., Ltd.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License");
   5 # you may not use this file except in compliance with the License.
   6 # You may obtain a copy of the License at
   7 #
   8 # http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS,
  12 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 # See the License for the specific language governing permissions and
  14 # limitations under the License.
  15 #
  16
  17 m4_define([dali_version],[0.1.0])
  18 AC_INIT([dali], [dali_version])
  19 AM_INIT_AUTOMAKE([-Wall foreign])
  20
  21 AC_PROG_CXX
  22 AC_PROG_LIBTOOL
  23 AC_PROG_MKDIR_P
  24
  25 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  26
  27 LT_INIT
  28
  29 DALI_ADAPTOR_VERSION=dali_version
  30 AC_SUBST(DALI_ADAPTOR_VERSION)
  31
  32 FREETYPE_REQUIRED=9.16.3
  33
  34 PKG_CHECK_MODULES(CAPI_APPFW_APPLICATION, capi-appfw-application)
  35 PKG_CHECK_MODULES(DALICORE, dali-core)
  36 PKG_CHECK_MODULES(DLOG, dlog)
  37 PKG_CHECK_MODULES(ELEMENTARY, elementary)
  38 PKG_CHECK_MODULES(ECORE, ecore)
  39 PKG_CHECK_MODULES(ECORE_X, ecore-x)
  40 PKG_CHECK_MODULES(ECORE_IPC, ecore-ipc)
  41 PKG_CHECK_MODULES(EXIF, libexif)
  42 PKG_CHECK_MODULES(FREETYPE, [freetype2 >= $FREETYPE_REQUIRED])
  43 PKG_CHECK_MODULES(FEEDBACK, feedback)
  44 PKG_CHECK_MODULES(FONTCONFIG, fontconfig)
  45 PKG_CHECK_MODULES(MMFSOUND, mm-sound)
  46 PKG_CHECK_MODULES(PNG, libpng)
  47 PKG_CHECK_MODULES(SENSOR, sensor)
  48 PKG_CHECK_MODULES(TTS, tts)
  49 PKG_CHECK_MODULES(VCONF, vconf)
  50 PKG_CHECK_MODULES(X11, x11)
  51 PKG_CHECK_MODULES(XML, libxml-2.0)
  52 PKG_CHECK_MODULES(LIBDRM, libdrm)
  53 PKG_CHECK_MODULES(LIBEXIF, libexif)
  54 PKG_CHECK_MODULES(CAPI_SYSTEM_SYSTEM_SETTINGS, capi-system-system-settings)
  55
  56 # Check for availability of BulletPhysics
  57 PKG_CHECK_EXISTS(bullet, [
  58   BULLET_CFLAGS=`pkg-config --cflags bullet`
  59   BULLET_LIBS=`pkg-config --libs bullet`
  60   BULLET=yes
  61 ], [
  62   AC_MSG_WARN([BulletPhysics development files not found, not building bullet plugin])
  63   BULLET_CFLAGS=
  64   BULLET_LIBS=
  65   BULLET=no
  66 ])
  67
  68 AC_SUBST(BULLET_CFLAGS)
  69 AC_SUBST(BULLET_LIBS)
  70 AM_CONDITIONAL([USE_BULLET], [test x$BULLET = xyes])
  71
  72 DALI_ADAPTOR_CFLAGS=-DPLATFORM_SLP
  73
  74 AC_ARG_ENABLE(exportall,
  75               [AC_HELP_STRING([--enable-exportall],
  76                               [enables the exporting of all the symbols in the library])],
  77               [enable_exportall=yes],
  78               [enable_exportall=no])
  79
  80 AC_ARG_ENABLE([debug],
  81               [AC_HELP_STRING([--enable-debug],
  82                               [Turns on debugging])],
  83               [enable_debug=$enableval],
  84               [enable_debug=no])
  85
  86 if test "x$enable_debug" = "xyes"; then
  87   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DDEBUG_ENABLED"
  88 fi
  89
  90 if test "x$enable_debug" = "xno" -a "x$enable_exportall" = "xno"; then
  91   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -fvisibility=hidden -DHIDE_DALI_INTERNALS"
  92 fi
  93
  94 AC_ARG_ENABLE([gles],
  95               [AC_HELP_STRING([--enable-gles],
  96                               [Specify the OpenGL ES version for backwards compatibility])],
  97               [enable_gles=$enableval],
  98               [enable_gles=30])
  99
 100 DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DDALI_GLES_VERSION=${enable_gles}"
 101
 102 AC_ARG_WITH([jpeg-turbo],
 103             [AC_HELP_STRING([--with-jpeg-turbo],
 104                             [Use the JPEG Turbo library])],
 105             [with_jpeg_turbo=$withval],
 106             [with_jpeg_turbo=yes])
 107
 108 AM_CONDITIONAL(TURBO_JPEG_IS_ON, test $with_jpeg_turbo = yes)
 109
 110 # Tizen Profile options
 111 AC_ARG_ENABLE([profile],
 112               [AC_HELP_STRING([--enable-profile=COMMON,MOBILE,TV],
 113                             [Select the variant of tizen])],
 114               [dali_profile=$enableval],
 115               [dali_profile=COMMON])
 116
 117 if test "x$enable_profile" = "xyes"; then
 118   dali_profile=COMMON
 119 fi
 120 if test "x$enable_profile" = "x"; then
 121   dali_profile=COMMON
 122 fi
 123
 124 DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DDALI_PROFILE_${dali_profile}"
 125 DALI_PROFILE_CFLAGS=" -DDALI_PROFILE_${dali_profile}"
 126 AM_CONDITIONAL([COMMON_PROFILE], [test x$dali_profile = xCOMMON])
 127 AM_CONDITIONAL([MOBILE_PROFILE], [test x$dali_profile = xMOBILE])
 128 AM_CONDITIONAL([TV_PROFILE], [test x$dali_profile = xTV])
 129
 130 if test "x$enable_profile" = "xMOBILE"; then
 131 PKG_CHECK_MODULES(OPENGLES20, opengl-es-20)
 132 PKG_CHECK_MODULES(ASSIMP, assimp)
 133 PKG_CHECK_MODULES(DEVICED, deviced)
 134 PKG_CHECK_MODULES(EVAS, evas)
 135 PKG_CHECK_MODULES(NATIVE_BUFFER, native-buffer)
 136 PKG_CHECK_MODULES(NATIVE_BUFFER_POOL, native-buffer-pool)
 137 fi
 138
 139 if test "x$enable_profile" = "xTV"; then
 140 PKG_CHECK_MODULES(OPENGLES20, gles20)
 141 PKG_CHECK_MODULES(ASSIMP, assimp)
 142 PKG_CHECK_MODULES(HAPTIC, haptic)
 143 fi
 144
 145 if test "x$enable_profile" = "xCOMMON"; then
 146 PKG_CHECK_MODULES(OPENGLES20, gles20)
 147 PKG_CHECK_MODULES(HAPTIC, haptic)
 148 fi
 149
 150 if test x$DALI_DATA_RW_DIR != x; then
 151   dataReadWriteDir=$DALI_DATA_RW_DIR
 152 else
 153   dataReadWriteDir=${prefix}/share/dali/
 154 fi
 155
 156 if test x$DALI_DATA_RO_DIR != x; then
 157   dataReadOnlyDir=$DALI_DATA_RO_DIR
 158 else
 159   dataReadOnlyDir=${prefix}/share/dali/
 160 fi
 161
 162 if test x$FONT_PRELOADED_PATH != x; then
 163   fontPreloadedPath=$FONT_PRELOADED_PATH
 164 else
 165   fontPreloadedPath=/usr/share/fonts/
 166 fi
 167
 168 if test x$FONT_DOWNLOADED_PATH != x; then
 169   fontDownloadedPath=$FONT_DOWNLOADED_PATH
 170 else
 171   fontDownloadedPath=/opt/share/fonts/
 172 fi
 173
 174 if test x$FONT_APPLICATION_PATH != x; then
 175   fontApplicationPath=$FONT_APPLICATION_PATH
 176 else
 177   fontApplicationPath=~/.fonts/
 178 fi
 179
 180 if test x$FONT_CONFIGURATION_FILE != x; then
 181   fontConfigurationFilePath=$FONT_CONFIGURATION_FILE
 182 fi
 183
 184 AC_SUBST(dataReadWriteDir)
 185 AC_SUBST(dataReadOnlyDir)
 186 AC_SUBST(fontPreloadedPath)
 187 AC_SUBST(fontDownloadedPath)
 188 AC_SUBST(fontApplicationPath)
 189 AC_SUBST(fontConfigurationFilePath)
 190 AC_SUBST(DALI_ADAPTOR_CFLAGS)
 191 AC_SUBST(DALI_PROFILE_CFLAGS)
 192
 193 # Specify the include directory for development headers
 194 #devincludepath=${includedir}/dali/internal
 195 devincludepath=${includedir}
 196 AC_SUBST(devincludepath)
 197
 198
 199 AC_CONFIG_FILES([
 200  Makefile
 201  common/Makefile
 202  dali-adaptor/Makefile
 203  dali.pc
 204  dali-application/Makefile
 205  dali-application.pc
 206  dali-evas/Makefile
 207  dali-evas.pc
 208  dali-native-buffer/Makefile
 209  dali-native-buffer.pc
 210  plugins/Makefile
 211 ])
 212
 213 AC_OUTPUT
 214
 215 echo "
 216 Configuration
 217 -------------
 218   Prefix:                           $prefix
 219   Debug Build:                      $enable_debug
 220   Compile flags                     $DALI_ADAPTOR_CFLAGS
 221   Using JPEG Turbo Library:         $with_jpeg_turbo
 222   Profile:                          $dali_profile
 223   Data Dir (Read/Write):            $dataReadWriteDir
 224   Data Dir (Read Only):             $dataReadOnlyDir
 225   Font Path (Preloaded):            $fontPreloadedPath
 226   Font Path (Downloaded):           $fontDownloadedPath
 227   Font Path (Application):          $fontApplicationPath
 228   Font Configuration File:          $fontConfigurationFilePath
 229 "