build/tizen/configure.ac

   1 # Copyright (c) 2014 Samsung Electronics Co., Ltd.
   2
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6
   7 # http://www.apache.org/licenses/LICENSE-2.0
   8
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15
  16 m4_define([dali_version],[0.1.1])
  17 AC_INIT([dali], [dali_version])
  18 AM_INIT_AUTOMAKE([-Wall foreign])
  19
  20 AC_PROG_CXX
  21 AC_PROG_LIBTOOL
  22 AC_PROG_MKDIR_P
  23
  24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  25
  26 LT_INIT
  27
  28 DALI_VERSION=dali_version
  29 AC_SUBST(DALI_VERSION)
  30
  31 DALI_CFLAGS=-DPLATFORM_TIZEN
  32
  33 AC_ARG_ENABLE(exportall,
  34               [AC_HELP_STRING([--enable-exportall],
  35                               [enables the exporting of all the symbols in the library])],
  36               [enable_exportall=yes],
  37               [enable_exportall=no])
  38
  39 AC_ARG_ENABLE([debug],
  40               [AC_HELP_STRING([--enable-debug],
  41                               [Turns on debugging])],
  42               [enable_debug=$enableval],
  43               [enable_debug=no])
  44
  45 AC_ARG_ENABLE([emscripten],
  46               [AC_HELP_STRING([--enable-emscripten],
  47                               [Emscripten builds])],
  48               [enable_emscripten=$enableval],
  49               [enable_emscripten=no])
  50
  51 AC_ARG_ENABLE([dynamics],
  52               [AC_HELP_STRING([--enable-dynamics],
  53                               [Builds with dynamics support])],
  54               [dynamics_support=$enableval],
  55               [dynamics_support=no])
  56
  57 if test "x$enable_debug" = "xyes"; then
  58   DALI_CFLAGS="$DALI_CFLAGS -DDEBUG_ENABLED -DDEBUG_BACKTRACE"
  59 fi
  60
  61 if test "x$enable_debug" = "xno" -a "x$enable_exportall" = "xno"; then
  62   DALI_CFLAGS="$DALI_CFLAGS -fvisibility=hidden -DHIDE_DALI_INTERNALS"
  63 fi
  64
  65 if test "x$enable_emscripten" = "xyes"; then
  66   DALI_CFLAGS="$DALI_CFLAGS -DEMSCRIPTEN -std=c++11"
  67 fi
  68
  69 if test "x$dynamics_support" = "xyes"; then
  70   DALI_CFLAGS="$DALI_CFLAGS -DDYNAMICS_SUPPORT"
  71 fi
  72
  73 AM_CONDITIONAL([DYNAMICS_SUPPORT], [test x$dynamics_support = xyes])
  74
  75 AC_ARG_ENABLE([performance-monitor],
  76               [AC_HELP_STRING([--enable-performance-monitor],
  77                               [Enables the performance monitor output])],
  78               [enable_performance_monitor=$enableval],
  79               [enable_performance_monitor=no])
  80
  81 if test "x$enable_performance_monitor" = "xyes"; then
  82   DALI_CFLAGS="$DALI_CFLAGS -DPERFORMANCE_MONITOR_ENABLED"
  83 fi
  84
  85 if test x$DALI_DATA_RW_DIR != x; then
  86   dataReadWriteDir=$DALI_DATA_RW_DIR
  87 else
  88   dataReadWriteDir=${prefix}/share/dali/
  89 fi
  90
  91 if test x$DALI_DATA_RO_DIR != x; then
  92   dataReadOnlyDir=$DALI_DATA_RO_DIR
  93 else
  94   dataReadOnlyDir=${prefix}/share/dali/
  95 fi
  96
  97 DALI_CFLAGS="$DALI_CFLAGS -I${includedir}"
  98 DALI_LDFLAGS="-L${libdir}"
  99
 100 AC_SUBST(dataReadWriteDir)
 101 AC_SUBST(dataReadOnlyDir)
 102 AC_SUBST(DALI_CFLAGS)
 103 AC_SUBST(DALI_LDFLAGS)
 104
 105 # Specify the include directory for development headers
 106 devincludepath=${includedir}
 107 AC_SUBST(devincludepath)
 108
 109 AC_CONFIG_FILES([
 110  Makefile
 111  dali-core/Makefile
 112  dali-core.pc
 113 ])
 114
 115 AC_OUTPUT
 116
 117 echo "
 118 Configuration
 119 -------------
 120   Prefix:                           $prefix
 121   Debug Build:                      $enable_debug
 122   Performance Monitor:              $enable_performance_monitor
 123   Data Dir (Read/Write):            $dataReadWriteDir
 124   Data Dir (Read Only):             $dataReadOnlyDir
 125   Emscripten:                       $enable_emscripten
 126 "