build/tizen/configure.ac

   1 #
   2 # Copyright (c) 2014 Samsung Electronics Co., Ltd.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License");
   5 # you may not use this file except in compliance with the License.
   6 # You may obtain a copy of the License at
   7 #
   8 # http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS,
  12 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 # See the License for the specific language governing permissions and
  14 # limitations under the License.
  15 #
  16
  17 m4_define([dali_version],[0.1.0])
  18 AC_INIT([dali], [dali_version])
  19 AM_INIT_AUTOMAKE([-Wall foreign])
  20
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AC_PROG_CXX
  24 AC_PROG_LIBTOOL
  25 AC_PROG_MKDIR_P
  26
  27 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  28
  29 LT_INIT
  30
  31 DALI_ADAPTOR_VERSION=dali_version
  32 AC_SUBST(DALI_ADAPTOR_VERSION)
  33
  34 FREETYPE_REQUIRED=9.16.3
  35
  36 PKG_CHECK_MODULES(DALICORE, dali-core)
  37 PKG_CHECK_MODULES(ELEMENTARY, elementary)
  38 PKG_CHECK_MODULES(ECORE, ecore)
  39 PKG_CHECK_MODULES(ECORE_IPC, ecore-ipc)
  40 PKG_CHECK_MODULES(EXIF, libexif)
  41 PKG_CHECK_MODULES(FREETYPE, [freetype2 >= $FREETYPE_REQUIRED])
  42 PKG_CHECK_MODULES(FONTCONFIG, fontconfig)
  43 PKG_CHECK_MODULES(PNG, libpng)
  44 PKG_CHECK_MODULES(XML, libxml-2.0)
  45 PKG_CHECK_MODULES(LIBEXIF, libexif)
  46 PKG_CHECK_MODULES(LIBDRM, libdrm)
  47 PKG_CHECK_MODULES(LIBCURL, libcurl)
  48 PKG_CHECK_MODULES(HARFBUZZ, harfbuzz)
  49 PKG_CHECK_MODULES(FRIBIDI, fribidi)
  50
  51 # Check for availability of BulletPhysics
  52 PKG_CHECK_EXISTS(bullet, [
  53   BULLET_CFLAGS=`pkg-config --cflags bullet`
  54   BULLET_LIBS=`pkg-config --libs bullet`
  55   BULLET=yes
  56 ], [
  57   AC_MSG_WARN([BulletPhysics development files not found, not building bullet plugin])
  58   BULLET_CFLAGS=
  59   BULLET_LIBS=
  60   BULLET=no
  61 ])
  62
  63 AC_SUBST(BULLET_CFLAGS)
  64 AC_SUBST(BULLET_LIBS)
  65
  66 AC_ARG_ENABLE([bullet],
  67               [AC_HELP_STRING([ --enable-bullet],
  68                               [Enable bullet plugin])],
  69               [enable_bullet=yes],
  70               [enable_bullet=no])
  71
  72
  73 AC_ARG_ENABLE([feedback],
  74               [AC_HELP_STRING([ --enable-feedback],
  75                               [Enable feedback plugin])],
  76               [enable_feedback=yes],
  77               [enable_feedback=no])
  78
  79 AM_CONDITIONAL([USE_BULLET], [test x$BULLET = xyes && test x$enable_bullet = xyes])
  80 AM_CONDITIONAL([USE_FEEDBACK], [test x$enable_feedback = xyes])
  81
  82 DALI_ADAPTOR_CFLAGS=-DPLATFORM_TIZEN
  83
  84 AC_ARG_ENABLE(exportall,
  85               [AC_HELP_STRING([--enable-exportall],
  86                               [enables the exporting of all the symbols in the library])],
  87               [enable_exportall=yes],
  88               [enable_exportall=no])
  89
  90 AC_ARG_ENABLE([debug],
  91               [AC_HELP_STRING([--enable-debug],
  92                               [Turns on debugging])],
  93               [enable_debug=$enableval],
  94               [enable_debug=no])
  95
  96 AC_ARG_ENABLE(shaderbincache,
  97               [AC_HELP_STRING([--enable-shaderbincache],
  98                               [enables shader binary cache])],
  99               [enable_shaderbincache=$enableval],
 100               [enable_shaderbincache=DISABLE])
 101
 102 if test "x$enable_debug" = "xyes"; then
 103   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DDEBUG_ENABLED"
 104 fi
 105
 106 if test "x$enable_debug" = "xno" -a "x$enable_exportall" = "xno"; then
 107   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -fvisibility=hidden -DHIDE_DALI_INTERNALS"
 108 fi
 109
 110 if test "x$enable_shaderbincache" = "xENABLE"; then
 111   DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DSHADERBIN_CACHE_ENABLED"
 112 fi
 113
 114 AC_ARG_ENABLE([assimp],
 115               [AC_HELP_STRING([--enable-assimp],
 116                               [Enable assimp plugin, overriding platform defaults])],
 117               [enable_assimp=yes],
 118               [enable_assimp=no])
 119
 120 AC_ARG_ENABLE([gles],
 121               [AC_HELP_STRING([--enable-gles],
 122                               [Specify the OpenGL ES version for backwards compatibility])],
 123               [enable_gles=$enableval],
 124               [enable_gles=30])
 125
 126 DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DDALI_GLES_VERSION=${enable_gles}"
 127
 128 AC_ARG_WITH([jpeg-turbo],
 129             [AC_HELP_STRING([--with-jpeg-turbo],
 130                             [Use the JPEG Turbo library])],
 131             [with_jpeg_turbo=$withval],
 132             [with_jpeg_turbo=yes])
 133
 134 AM_CONDITIONAL(TURBO_JPEG_IS_ON, test $with_jpeg_turbo = yes)
 135
 136 # Tizen Profile options
 137 AC_ARG_ENABLE([profile],
 138               [AC_HELP_STRING([--enable-profile=COMMON,MOBILE,WEARABLE,TV,UBUNTU],
 139                             [Select the variant of tizen])],
 140               [enable_profile=$enableval],
 141               [enable_profile=COMMON])
 142
 143 # Ensure valid profile selected
 144 if test "x$enable_profile" != "xCOMMON" -a "x$enable_profile" != "xMOBILE" -a "x$enable_profile" != "xWEARABLE" -a "x$enable_profile" != "xTV" -a "x$enable_profile" != "xUBUNTU"; then
 145   AC_MSG_ERROR([$enable_profile is an invalid profile])
 146 fi
 147
 148 AC_ARG_ENABLE(wayland,
 149               [  --enable-wayland       Build on Wayland],
 150               enable_wayland=yes,
 151               enable_wayland=no)
 152
 153 DALI_ADAPTOR_CFLAGS="$DALI_ADAPTOR_CFLAGS -DDALI_PROFILE_${enable_profile}"
 154 DALI_PROFILE_CFLAGS=" -DDALI_PROFILE_${enable_profile}"
 155 AM_CONDITIONAL([COMMON_PROFILE], [test x$enable_profile = xCOMMON])
 156 AM_CONDITIONAL([MOBILE_PROFILE], [test x$enable_profile = xMOBILE])
 157 AM_CONDITIONAL([WEARABLE_PROFILE], [test x$enable_profile = xWEARABLE])
 158 AM_CONDITIONAL([TV_PROFILE], [test x$enable_profile = xTV])
 159 AM_CONDITIONAL([UBUNTU_PROFILE], [test x$enable_profile = xUBUNTU])
 160 AM_CONDITIONAL([WAYLAND], [test x$enable_wayland = xyes])
 161
 162 # Platforms should either enable features or remove them, they
 163 # should not disable features. This allows the developer to override
 164 # features through the command line.
 165
 166 PKG_CHECK_MODULES(OPENGLES20, glesv2 egl)
 167
 168 if test "x$enable_profile" != "xUBUNTU"; then
 169 PKG_CHECK_MODULES(CAPI_APPFW_APPLICATION, capi-appfw-application)
 170 PKG_CHECK_MODULES(DLOG, dlog)
 171 PKG_CHECK_MODULES(SENSOR, sensor)
 172 PKG_CHECK_MODULES(TTS, tts)
 173 PKG_CHECK_MODULES(VCONF, vconf)
 174 PKG_CHECK_MODULES(CAPI_SYSTEM_SYSTEM_SETTINGS, capi-system-system-settings)
 175 fi
 176
 177 if test "x$enable_wayland" = "xyes"; then
 178 PKG_CHECK_MODULES(WAYLAND, [ecore-wayland egl wayland-egl wayland-client >= 1.2.0 xkbcommon],
 179                   [DALI_HAS_ECOREWL=yes],
 180                   [DALI_HAS_ECOREWL=no])
 181 else
 182 PKG_CHECK_MODULES(ECORE_X, [ecore-x],
 183                   [DALI_HAS_ECOREX=yes],
 184                   [DALI_HAS_ECOREX=no])
 185 PKG_CHECK_MODULES(X11, [x11],
 186                   [DALI_HAS_X11=yes],
 187                   [DALI_HAS_X11=no])
 188 fi
 189
 190 if test "x$enable_feedback" = "xyes"; then
 191
 192 if test "x$enable_profile" = "xCOMMON" || test "x$enable_profile" = "xTV"; then
 193 PKG_CHECK_MODULES(HAPTIC, haptic)
 194 fi
 195
 196 if test "x$enable_profile" = "xMOBILE"; then
 197 PKG_CHECK_MODULES(DEVICED, deviced)
 198 fi
 199
 200 PKG_CHECK_MODULES(FEEDBACK, feedback)
 201 PKG_CHECK_MODULES(MMFSOUND, mm-sound)
 202 fi
 203
 204 if test "x$enable_assimp" = "xyes" ; then
 205   PKG_CHECK_MODULES(ASSIMP, assimp)
 206   ASSIMP_CFLAGS+=-DASSIMP_ENABLED
 207 fi
 208
 209 # Don't move this - it depends on the platform defaults above
 210 AM_CONDITIONAL([ASSIMP_ENABLED], [test x$enable_assimp = xyes])
 211
 212 if test x$DALI_DATA_RW_DIR != x; then
 213   dataReadWriteDir=$DALI_DATA_RW_DIR
 214 else
 215   dataReadWriteDir=${prefix}/share/dali/
 216 fi
 217
 218 if test x$DALI_DATA_RO_DIR != x; then
 219   dataReadOnlyDir=$DALI_DATA_RO_DIR
 220 else
 221   dataReadOnlyDir=${prefix}/share/dali/
 222 fi
 223
 224 if test x$FONT_PRELOADED_PATH != x; then
 225   fontPreloadedPath=$FONT_PRELOADED_PATH
 226 else
 227   fontPreloadedPath=/usr/share/fonts/
 228 fi
 229
 230 if test x$FONT_DOWNLOADED_PATH != x; then
 231   fontDownloadedPath=$FONT_DOWNLOADED_PATH
 232 else
 233   fontDownloadedPath=/opt/share/fonts/
 234 fi
 235
 236 if test x$FONT_APPLICATION_PATH != x; then
 237   fontApplicationPath=$FONT_APPLICATION_PATH
 238 else
 239   fontApplicationPath=~/.fonts/
 240 fi
 241
 242 if test x$FONT_CONFIGURATION_FILE != x; then
 243   fontConfigurationFilePath=$FONT_CONFIGURATION_FILE
 244 fi
 245
 246 AC_SUBST(dataReadWriteDir)
 247 AC_SUBST(dataReadOnlyDir)
 248 AC_SUBST(fontPreloadedPath)
 249 AC_SUBST(fontDownloadedPath)
 250 AC_SUBST(fontApplicationPath)
 251 AC_SUBST(fontConfigurationFilePath)
 252 AC_SUBST(DALI_ADAPTOR_CFLAGS)
 253 AC_SUBST(DALI_PROFILE_CFLAGS)
 254
 255 # Specify the include directory for development headers
 256 #devincludepath=${includedir}/dali/internal
 257 devincludepath=${includedir}
 258 AC_SUBST(devincludepath)
 259
 260 AC_CONFIG_FILES([
 261  Makefile
 262  adaptor/Makefile
 263  dali.pc
 264 ])
 265
 266 AM_CONDITIONAL([USE_PLUGIN], [test x$enable_feedback = xyes || test x$enable_bullet = xyes])
 267
 268 if test "x$enable_feedback" = "xyes" || test "x$enable_bullet" = "xyes"; then
 269 AC_CONFIG_FILES([
 270  plugins/Makefile
 271 ])
 272 fi
 273
 274 AC_OUTPUT
 275
 276
 277 echo "
 278 Configuration
 279 -------------
 280   Prefix:                           $prefix
 281   Debug Build:                      $enable_debug
 282   Compile flags                     $DALI_ADAPTOR_CFLAGS
 283   Using Assimp Library:             $enable_assimp
 284   Using JPEG Turbo Library:         $with_jpeg_turbo
 285   Profile:                          $enable_profile
 286   Data Dir (Read/Write):            $dataReadWriteDir
 287   Data Dir (Read Only):             $dataReadOnlyDir
 288   Font Path (Preloaded):            $fontPreloadedPath
 289   Font Path (Downloaded):           $fontDownloadedPath
 290   Font Path (Application):          $fontApplicationPath
 291   Font Configuration File:          $fontConfigurationFilePath
 292 "