build/configure.ac.warnings

   1 dnl Use lots of warning flags with with gcc and compatible compilers
   2
   3 dnl Note: if you change the following variable, the cache is automatically
   4 dnl skipped and all flags rechecked.  So there's no need to do anything
   5 dnl else.  If for any reason you need to force a recheck, just change
   6 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
   7
   8 # -Wcast-align generates lots of false positive reports we need to
   9 # cast image data from uint8_t to uin32_t.
  10
  11 # -Wlogical-op causes too much noise from strcmp("literal", str)
  12
  13 MAYBE_WARN="-Wall -Wextra \
  14 -Wold-style-definition -Wdeclaration-after-statement \
  15 -Wmissing-declarations -Werror-implicit-function-declaration \
  16 -Wnested-externs -Wpointer-arith -Wwrite-strings \
  17 -Wsign-compare -Wstrict-prototypes -Wmissing-prototypes \
  18 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
  19 -Wbad-function-cast -Wvolatile-register-var \
  20 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
  21 -Wno-missing-field-initializers -Wno-unused-parameter \
  22 -Wno-attributes -Wno-long-long -Winline"
  23
  24 dnl Sun Studio 12 likes to rag at us for abusing enums like
  25 dnl having cairo_status_t variables hold cairo_int_status_t
  26 dnl values.  It's bad, we know.  Now please be quiet.
  27 MAYBE_WARN="$MAYBE_WARN -erroff=E_ENUM_TYPE_MISMATCH_ARG \
  28                         -erroff=E_ENUM_TYPE_MISMATCH_OP"
  29
  30 dnl We also abuse the warning-flag facility to enable other compiler
  31 dnl options.  Namely, the following:
  32 MAYBE_WARN="$MAYBE_WARN -fno-strict-aliasing -fno-common -flto"
  33
  34 dnl Also to turn various gcc/glibc-specific preprocessor checks
  35 MAYBE_WARN="$MAYBE_WARN -Wp,-D_FORTIFY_SOURCE=2"
  36
  37 # invalidate cached value if MAYBE_WARN has changed
  38 if test "x$cairo_cv_warn_maybe" != "x$MAYBE_WARN"; then
  39         unset cairo_cv_warn_cflags
  40 fi
  41 AC_CACHE_CHECK([for supported warning flags], cairo_cv_warn_cflags, [
  42         echo
  43         WARN_CFLAGS=""
  44
  45         # Some warning options are not supported by all versions of
  46         # gcc, so test all desired options against the current
  47         # compiler.
  48         #
  49         # Note that there are some order dependencies
  50         # here. Specifically, an option that disables a warning will
  51         # have no net effect if a later option then enables that
  52         # warnings, (perhaps implicitly). So we put some grouped
  53         # options (-Wall and -Wextra) up front and the -Wno options
  54         # last.
  55
  56         for W in $MAYBE_WARN; do
  57                 CAIRO_CC_TRY_FLAG([$W],, [WARN_CFLAGS="$WARN_CFLAGS $W"])
  58         done
  59
  60         cairo_cv_warn_cflags=$WARN_CFLAGS
  61         cairo_cv_warn_maybe=$MAYBE_WARN
  62
  63         AC_MSG_CHECKING([which warning flags were supported])
  64 ])
  65 WARN_CFLAGS="$cairo_cv_warn_cflags"
  66 CAIRO_CFLAGS="$CAIRO_CFLAGS $WARN_CFLAGS"
  67
  68 # We only wish to enable attribute(warn_unused_result) if we can prevent
  69 # gcc from generating thousands of warnings about the misapplication of the
  70 # attribute to void functions and variables.
  71 AC_CACHE_CHECK([how to enable unused result warnings], cairo_cv_warn_unused_result, [
  72         AC_REQUIRE([AC_PROG_GREP])
  73         cairo_cv_warn_unused_result=""
  74         if echo $WARN_CFLAGS | $GREP -e '-Wno-attributes' >/dev/null; then
  75             CAIRO_CC_TRY_FLAG_SILENT(
  76                         [-Wno-attributes],
  77                         [__attribute__((__warn_unused_result__)) void f (void) {}
  78                          __attribute__((__warn_unused_result__)) int g;],
  79                         [cairo_cv_warn_unused_result="__attribute__((__warn_unused_result__))"])
  80         fi
  81 ])
  82 AC_DEFINE_UNQUOTED([WARN_UNUSED_RESULT], [$cairo_cv_warn_unused_result],
  83           [Define to the value your compiler uses to support the warn-unused-result attribute])
  84
  85 dnl check linker flags
  86 AC_CACHE_CHECK([how to allow undefined symbols in shared libraries used by test suite], cairo_cv_test_undefined_ldflags,
  87                [CAIRO_CC_TRY_FLAG([-Wl,--allow-shlib-undefined], [],
  88                                   [cairo_cv_test_undefined_ldflags="-Wl,--allow-shlib-undefined]")])
  89 CAIRO_TEST_UNDEFINED_LDFLAGS="$cairo_cv_test_undefined_ldflags"
  90 AC_SUBST(CAIRO_TEST_UNDEFINED_LDFLAGS)