board/samsung/universal/lowlevel_init.S

   1 /*
   2  * Memory Setup stuff - taken from blob memsetup.S
   3  *
   4  * Copyright (C) 2009 Samsung Electronics
   5  * Kyungmin Park <kyungmin.park@samsung.com>
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 #include <config.h>
  27 #include <version.h>
  28 #include <asm/arch/cpu.h>
  29 #include <asm/arch/mem.h>
  30 #include <asm/arch/clock.h>
  31 #include <asm/arch/power.h>
  32 #include <asm/arch/watchdog.h>
  33 #include <asm/arch/interrupt.h>
  34
  35 #define DEBUG_PM_C110
  36 #undef DEBUG_PM_C110
  37
  38 /*
  39  * Register usages:
  40  *
  41  * r5 has zero always
  42  * r7 has S5PC100 GPIO base, 0xE0300000
  43  * r8 has real GPIO base, 0xE0300000, 0xE0200000 at S5PC100, S5PC110 repectively
  44  * r9 has Mobile DDR size, 1 means 1GiB, 2 means 2GiB and so on
  45  */
  46
  47 _TEXT_BASE:
  48         .word   TEXT_BASE
  49
  50         .globl lowlevel_init
  51 lowlevel_init:
  52         mov     r11, lr
  53
  54         /* r5 has always zero */
  55         mov     r5, #0
  56
  57         ldr     r7, =S5PC100_GPIO_BASE
  58         ldr     r8, =S5PC100_GPIO_BASE
  59         /* Read CPU ID */
  60         ldr     r2, =S5PC1XX_PRO_ID
  61         ldr     r0, [r2]
  62         mov     r1, #0x00010000
  63         and     r0, r0, r1
  64         cmp     r0, r5
  65         beq     100f
  66         ldr     r8, =S5PC110_GPIO_BASE
  67 100:
  68         /* Turn on KEY_LED_ON [GPJ4(1)] XMSMWEN */
  69         cmp     r7, r8
  70 #ifndef DEBUG_PM_C110
  71         addeq   r0, r8, #0x280                          @S5PC100_GPIO_J4_OFFSET
  72         addne   r0, r8, #0x2C0                          @S5PC110_GPIO_J4_OFFSET
  73         ldr     r1, [r0, #0x0]                          @S5PC1XX_GPIO_CON_OFFSET
  74         bic     r1, r1, #(0xf << 4)                     @ 1 * 4-bit
  75         orr     r1, r1, #(0x1 << 4)
  76         str     r1, [r0, #0x0]                          @S5PC1XX_GPIO_CON_OFFSET
  77
  78         ldr     r1, [r0, #0x4]                          @S5PC1XX_GPIO_DAT_OFFSET
  79 #ifdef CONFIG_ONENAND_IPL
  80         orr     r1, r1, #(1 << 1)                       @ 1 * 1-bit
  81 #else
  82         bic     r1, r1, #(1 << 1)
  83 #endif
  84         str     r1, [r0, #0x4]                          @S5PC1XX_GPIO_DAT_OFFSET
  85 #endif
  86
  87         /* IO retension release */
  88         ldreq   r0, =S5PC100_OTHERS                     @0xE0108200
  89         ldrne   r0, =S5PC110_OTHERS                     @0xE010E000
  90         ldr     r1, [r0]
  91         ldreq   r2, =(1 << 31)                          @IO_RET_REL
  92         ldrne   r2, =((1 << 31) | (1 << 29) | (1 << 28))        @ GPIO, UART_IO
  93         orr     r1, r1, r2
  94         str     r1, [r0]
  95
  96 #ifndef CONFIG_ONENAND_IPL
  97         /* Disable Watchdog */
  98         ldreq   r0, =S5PC100_WATCHDOG_BASE              @0xEA200000
  99         ldrne   r0, =S5PC110_WATCHDOG_BASE              @0xE2700000
 100         str     r5, [r0]
 101
 102         /* setting SRAM */
 103         ldreq   r0, =S5PC100_SROMC_BASE
 104         ldrne   r0, =S5PC110_SROMC_BASE
 105         ldr     r1, =0x9
 106         str     r1, [r0]
 107 #endif
 108
 109         /* S5PC100 has 3 groups of interrupt sources */
 110         ldreq   r0, =S5PC100_VIC0_BASE                  @0xE4000000
 111         ldrne   r0, =S5PC110_VIC0_BASE                  @0xF2000000
 112         add     r1, r0, #0x00100000
 113         add     r2, r0, #0x00200000
 114
 115         /* Disable all interrupts (VIC0, VIC1 and VIC2) */
 116         mvn     r3, #0x0
 117         str     r3, [r0, #VIC_INTENCLEAR_OFFSET]
 118         str     r3, [r1, #VIC_INTENCLEAR_OFFSET]
 119         str     r3, [r2, #VIC_INTENCLEAR_OFFSET]
 120
 121 #ifndef CONFIG_ONENAND_IPL
 122         /* Set all interrupts as IRQ */
 123         str     r5, [r0, #VIC_INTSELECT_OFFSET]
 124         str     r5, [r1, #VIC_INTSELECT_OFFSET]
 125         str     r5, [r2, #VIC_INTSELECT_OFFSET]
 126
 127         /* Pending Interrupt Clear */
 128         str     r5, [r0, #VIC_INTADDRESS_OFFSET]
 129         str     r5, [r1, #VIC_INTADDRESS_OFFSET]
 130         str     r5, [r2, #VIC_INTADDRESS_OFFSET]
 131 #endif
 132
 133 #ifndef CONFIG_ONENAND_IPL
 134         /* for UART */
 135         bl      uart_asm_init
 136
 137         bl      internal_ram_init
 138 #endif
 139
 140 #ifdef CONFIG_ONENAND_IPL
 141         /* init system clock */
 142         bl      system_clock_init
 143
 144         /* Board detection to set proper memory configuration */
 145         cmp     r7, r8
 146         moveq   r9, #1          /* r9 has 1Gib default at s5pc100 */
 147         movne   r9, #2          /* r9 has 2Gib default at s5pc110 */
 148         /* FIXME 1Gib detection: Limo Universal */
 149         /* Check Limo Real board
 150          *      LR (suspend)    LU              J1B2
 151          * 0x04 0x01 (0x01)     0x01 (0x01)     0x01 (0x01)
 152          * 0x24 0x28 (0xA8)     0x28 (0x6A)     0x1C (0x1C)
 153          * 0x44 0x00 (0xC7)     0x00 (0x47)     0x00 (0x47)
 154          * 0x64 0x03 (0x1F)     0x07 (0x1F)     0x0f (0x0F)
 155          *
 156          * Check (0 << 3) at 0x64 at boot
 157          * Check 0x47 at 0x44 at suspend
 158          */
 159         ldrne   r2, =0xE0200C00
 160         ldrne   r1, [r2, #0x64]
 161         and     r1, r1, #(1 << 2)
 162         cmp     r1, #(1 << 2)
 163         moveq   r9, #1
 164         ldr     r1, [r2, #0x44]
 165         cmp     r1, #0x47
 166         moveq   r9, #1
 167
 168         bl      mem_ctrl_asm_init
 169
 170         /* OneNAND Sync Read Support at S5PC110 only
 171          * RM[15]       : Sync Read
 172          * BRWL[14:12]  : 7 CLK
 173          * BL[11:9]     : Continuous
 174          * VHF[3]       : Very High Frequency Enable (Over 83MHz)
 175          * HF[2]        : High Frequency Enable (Over 66MHz)
 176          */
 177         cmp     r7, r8
 178         ldrne   r1, =0xE00C
 179
 180         ldrne   r0, =0xB001E442
 181         strneh  r1, [r0]
 182
 183         ldrne   r0, =0xB0600000
 184         strne   r1, [r0, #0x100]                        @ ONENAND_IF_CTRL
 185
 186         /* Wakeup support. Don't know if it's going to be used, untested. */
 187         ldreq   r0, =S5PC100_RST_STAT
 188         ldrne   r0, =S5PC110_RST_STAT
 189         ldr     r1, [r0]
 190         biceq   r1, r1, #0xfffffff7
 191         moveq   r2, #(1 << 3)
 192         bicne   r1, r1, #0xfffeffff
 193         movne   r2, #(1 << 16)
 194         cmp     r1, r2
 195         bne     1f
 196 wakeup:
 197 #ifdef DEBUG_PM_C110
 198         mov     r0, r8
 199         ldr     r1, =0x22222222
 200         str     r1, [r0, #0x0]                  @S5PC100_GPIO_A0_OFFSET
 201         ldr     r1, =0x00002222
 202         str     r1, [r0, #0x20]                 @S5PC100_GPIO_A1_OFFSET
 203
 204         /* UART_SEL MP0_5[7] at S5PC110 */
 205         add     r0, r8, #0x360                  @S5PC110_GPIO_MP0_5_OFFSET
 206         ldr     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 207         bic     r1, r1, #(0xf << 28)            @ 28 = 7 * 4-bit
 208         orr     r1, r1, #(0x1 << 28)            @ Output
 209         str     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 210
 211         ldr     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 212         bic     r1, r1, #(0x3 << 14)            @ 14 = 7 * 2-bit
 213         orr     r1, r1, #(0x2 << 14)            @ Pull-up enabled
 214         str     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 215
 216         ldr     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 217         orr     r1, r1, #(1 << 7)               @ 7 = 7 * 1-bit
 218         str     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 219
 220         ldr     r0, =0xE2900000                 @ S5PC110_PA_UART
 221         orr     r0, r0, #0x800
 222         mov     r1, #0x3
 223         str     r1, [r0, #0x000]                @ ULCON
 224         ldr     r1, =0x245
 225         str     r1, [r0, #0x004]                @ UCON
 226         mov     r1, #0x23
 227         str     r1, [r0, #0x028]                @ UBRDIV
 228         mov     r1, #0x3
 229         str     r1, [r0, #0x02C]                @ UDIVSLOT
 230
 231         mov     r2, #'W'
 232         strb    r2, [r0, #0x020]                @ UTXH
 233 1001:
 234         ldrb    r3, [r0, #0x010]                @ UTRSTAT
 235         tst     r3, #(1 << 2)
 236         beq     1001b
 237 #endif
 238
 239         /* turn off L2 cache */
 240         bl      l2_cache_disable
 241
 242         cmp     r7, r8
 243         ldreq   r0, =0xC100
 244         ldrne   r0, =0xC110
 245
 246         /* invalidate L2 cache also */
 247         bl      invalidate_dcache
 248
 249         /* turn on L2 cache */
 250         bl      l2_cache_enable
 251
 252         cmp     r7, r8
 253         /* Load return address and jump to kernel */
 254         ldreq   r0, =S5PC100_INFORM0
 255         ldrne   r0, =S5PC110_INFORM0
 256
 257         /* r1 = physical address of s5pc1xx_cpu_resume function */
 258         ldr     r1, [r0]
 259
 260         /* Jump to kernel (sleep-s5pc1xx.S) */
 261         mov     pc, r1
 262         nop
 263         nop
 264 #else
 265         cmp     r7, r8
 266         /* Clear wakeup status register */
 267         ldreq   r0, =S5PC100_WAKEUP_STAT
 268         ldrne   r0, =S5PC110_WAKEUP_STAT
 269         ldr     r1, [r0]
 270         str     r1, [r0]
 271 #endif
 272 1:
 273         mov     lr, r11
 274         mov     pc, lr
 275
 276 /*
 277  * system_clock_init: Initialize core clock and bus clock.
 278  * void system_clock_init(void)
 279  */
 280 system_clock_init:
 281         ldr     r0, =S5PC1XX_CLOCK_BASE         @ 0xE0100000
 282
 283         /* Check S5PC100 */
 284         cmp     r7, r8
 285         bne     110f
 286 100:
 287 #ifndef DEBUG_PM_C110
 288         /* Set Lock Time */
 289         ldr     r1, =0xe10                      @ Locktime : 0xe10 = 3600
 290         str     r1, [r0, #0x000]                @ S5PC100_APLL_LOCK
 291         str     r1, [r0, #0x004]                @ S5PC100_MPLL_LOCK
 292         str     r1, [r0, #0x008]                @ S5PC100_EPLL_LOCK
 293         str     r1, [r0, #0x00C]                @ S5PC100_HPLL_LOCK
 294
 295         /* S5P_APLL_CON */
 296 #ifdef CONFIG_CLK_667_166_83
 297         ldr     r1, =0x81bc0400         @ SDIV 0, PDIV 4, MDIV 444 (1333MHz)
 298 #elif defined(CONFIG_CLK_666_166_66)
 299         ldr     r1, =0x814d0301         @ SDIV 1, PDIV 3, MDIV 333 (1333MHz)
 300 #elif defined(CONFIG_CLK_600_150_75)
 301         ldr     r1, =0x812C0300         @ SDIV 0, PDIV 3, MDIV 300 (1200MHz)
 302 #elif defined(CONFIG_CLK_533_133_66)
 303         ldr     r1, =0x810b0300         @ SDIV 0, PDIV 3, MDIV 267 (1066MHz)
 304 #elif defined(CONFIG_CLK_500_166_66)
 305         ldr     r1, =0x81f40301         @ SDIV 1, PDIV 3, MDIV 500 (1000MHz)
 306 #elif defined(CONFIG_CLK_467_117_59)
 307         ldr     r1, =0x826E0401         @ SDIV 1, PDIV 4, MDIV 622 (933MHz)
 308 #elif defined(CONFIG_CLK_400_100_50)
 309         ldr     r1, =0x81900301         @ SDIV 1, PDIV 3, MDIV 400 (800MHz)
 310 #else
 311 #error you should set the correct clock configuration
 312 #endif
 313         str     r1, [r0, #0x100]
 314         /* S5P_MPLL_CON */
 315         ldr     r1, =0x80590201         @ SDIV 1, PDIV 2, MDIV 89 (267MHz)
 316         str     r1, [r0, #0x104]
 317         /* S5P_EPLL_CON */
 318         ldr     r1, =0x80870303         @ SDIV 3, PDIV 3, MDIV 135 (67.5MHz)
 319         str     r1, [r0, #0x108]
 320         /* S5P_HPLL_CON */
 321         ldr     r1, =0x80600603         @ SDIV 3, PDIV 6, MDIV 96
 322         str     r1, [r0, #0x10C]
 323
 324         ldr     r1, [r0, #0x300]
 325         ldr     r2, =0x00003fff
 326         bic     r1, r1, r2
 327 #ifdef CONFIG_CLK_800_166_66
 328         ldr     r2, =0x00011401
 329 #elif defined(CONFIG_CLK_500_166_66)
 330         ldr     r2, =0x00011201
 331 #elif defined(CONFIG_CLK_666_166_66)
 332         ldr     r2, =0x00011300
 333 #else
 334         ldr     r2, =0x00011301
 335 #endif
 336         orr     r1, r1, r2
 337         str     r1, [r0, #0x300]
 338         ldr     r1, [r0, #0x304]
 339         ldr     r2, =0x00011110
 340         orr     r1, r1, r2
 341         str     r1, [r0, #0x304]
 342         ldr     r1, =0x00000001
 343         str     r1, [r0, #0x308]
 344
 345         /* Set Source Clock */
 346         ldr     r1, =0x00001111                 @ A, M, E, HPLL Muxing
 347         str     r1, [r0, #0x200]                @ S5PC1XX_CLK_SRC0
 348 #endif
 349         b       200f
 350 110:
 351         /* Set Clock divider */
 352         ldr     r1, =0x14131330                 @ 1:1:4:4, 1:4:5
 353         str     r1, [r0, #0x300]
 354         ldr     r1, =0x11110111                 @ UART[3210]: MMC[3210]
 355         str     r1, [r0, #0x310]
 356
 357         /* Set Lock Time */
 358         ldr     r1, =0xe10                      @ Locktime : 0xe10 = 3600
 359         str     r1, [r0, #0x000]                @ S5PC110_APLL_LOCK
 360         str     r1, [r0, #0x010]                @ S5PC110_MPLL_LOCK
 361         str     r1, [r0, #0x018]                @ S5PC110_EPLL_LOCK
 362         str     r1, [r0, #0x020]                @ S5PC110_VPLL_LOCK
 363
 364         /* S5PC110_APLL_CON */
 365         ldr     r1, =0x80C80601                 @ 800MHz
 366         str     r1, [r0, #0x100]
 367         /* S5PC110_MPLL_CON */
 368         ldr     r1, =0x829B0C01                 @ 667MHz
 369         str     r1, [r0, #0x108]
 370         /* S5PC110_EPLL_CON */
 371         ldr     r1, =0x80600602                 @  96MHz VSEL 0 P 6 M 96 S 2
 372         str     r1, [r0, #0x110]
 373         /* S5PC110_VPLL_CON */
 374         ldr     r1, =0x806C0603                 @  54MHz
 375         str     r1, [r0, #0x120]
 376
 377         /* Set Source Clock */
 378         ldr     r1, =0x10001111                 @ A, M, E, VPLL Muxing
 379         str     r1, [r0, #0x200]                @ S5PC1XX_CLK_SRC0
 380
 381         /* OneDRAM(DMC0) clock setting */
 382         ldr     r1, =0x01000000                 @ ONEDRAM_SEL[25:24] 1 SCLKMPLL
 383         str     r1, [r0, #0x218]                @ S5PC110_CLK_SRC6
 384         ldr     r1, =0x30000000                 @ ONEDRAM_RATIO[31:28] 3 + 1
 385         str     r1, [r0, #0x318]                @ S5PC110_CLK_DIV6
 386
 387         /* XCLKOUT = XUSBXTI 24MHz */
 388         add     r2, r0, #0xE000                 @ S5PC110_OTHERS
 389         ldr     r1, [r2]
 390         orr     r1, r1, #(0x3 << 8)             @ CLKOUT[9:8] 3 XUSBXTI
 391         str     r1, [r2]
 392
 393 200:
 394         /* wait at least 200us to stablize all clock */
 395         mov     r2, #0x10000
 396 1:      subs    r2, r2, #1
 397         bne     1b
 398
 399         mov     pc, lr
 400
 401 #ifndef CONFIG_ONENAND_IPL
 402 internal_ram_init:
 403         ldreq   r0, =0xE3800000
 404         ldrne   r0, =0xF1500000
 405         ldr     r1, =0x0
 406         str     r1, [r0]
 407
 408         mov     pc, lr
 409 #endif
 410
 411 #ifndef CONFIG_ONENAND_IPL
 412 /*
 413  * uart_asm_init: Initialize UART's pins
 414  */
 415 uart_asm_init:
 416         /* set GPIO to enable UART0-UART4 */
 417         mov     r0, r8
 418         ldr     r1, =0x22222222
 419         str     r1, [r0, #0x0]                  @S5PC100_GPIO_A0_OFFSET
 420         ldr     r1, =0x00002222
 421         str     r1, [r0, #0x20]                 @S5PC100_GPIO_A1_OFFSET
 422
 423         /* Check S5PC100 */
 424         cmp     r7, r8
 425         bne     110f
 426
 427 #ifndef DEBUG_PM_C110
 428         /* UART_SEL GPK0[5] at S5PC100 */
 429         add     r0, r8, #0x2A0                  @S5PC100_GPIO_K0_OFFSET
 430         ldr     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 431         bic     r1, r1, #(0xf << 20)            @ 20 = 5 * 4-bit
 432         orr     r1, r1, #(0x1 << 20)            @ Output
 433         str     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 434
 435         ldr     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 436         bic     r1, r1, #(0x3 << 10)            @ 10 = 5 * 2-bit
 437         orr     r1, r1, #(0x2 << 10)            @ Pull-up enabled
 438         str     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 439
 440         ldr     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 441         orr     r1, r1, #(1 << 5)               @ 5 = 5 * 1-bit
 442         str     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 443 #endif
 444         b       200f
 445 110:
 446         /*
 447          * Note that the following address
 448          * 0xE020'0360 is reserved address at S5PC100
 449          */
 450         /* UART_SEL MP0_5[7] at S5PC110 */
 451         add     r0, r8, #0x360                  @S5PC110_GPIO_MP0_5_OFFSET
 452         ldr     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 453         bic     r1, r1, #(0xf << 28)            @ 28 = 7 * 4-bit
 454         orr     r1, r1, #(0x1 << 28)            @ Output
 455         str     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 456
 457         ldr     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 458         bic     r1, r1, #(0x3 << 14)            @ 14 = 7 * 2-bit
 459         orr     r1, r1, #(0x2 << 14)            @ Pull-up enabled
 460         str     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 461
 462         ldr     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 463         orr     r1, r1, #(1 << 7)               @ 7 = 7 * 1-bit
 464         str     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 465 200:
 466         mov     pc, lr
 467 #endif