board/samsung/universal/lowlevel_init.S

   1 /*
   2  * Memory Setup stuff - taken from blob memsetup.S
   3  *
   4  * Copyright (C) 2009 Samsung Electronics
   5  * Kyungmin Park <kyungmin.park@samsung.com>
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 #include <config.h>
  27 #include <version.h>
  28 #include <asm/arch/cpu.h>
  29
  30 #ifdef CONFIG_SERIAL0
  31 #define UART_CONSOLE_BASE       UARTx_OFFSET(0)
  32 #elif defined(CONFIG_SERIAL1)
  33 #define UART_CONSOLE_BASE       UARTx_OFFSET(1)
  34 #elif defined(CONFIG_SERIAL2)
  35 #define UART_CONSOLE_BASE       UARTx_OFFSET(2)
  36 #else
  37 #define UART_CONSOLE_BASE       UARTx_OFFSET(3)
  38 #endif
  39
  40 /*
  41  * Register usages:
  42  *
  43  * r5 has zero always
  44  */
  45
  46 _TEXT_BASE:
  47         .word   TEXT_BASE
  48
  49         .globl lowlevel_init
  50 lowlevel_init:
  51         mov     r9, lr
  52
  53         /* Turn on KEY_LED_ON [GPJ4(1)] */
  54         ldr     r0, =S5PC100_GPIO_BASE(S5PC100_GPIO_J4_OFFSET)
  55         ldr     r1, [r0, #S5PC1XX_GPIO_CON_OFFSET]
  56         bic     r1, r1, #(0xf << 4)                     @ 1 * 4-bit
  57         orr     r1, r1, #(0x1 << 4)
  58         str     r1, [r0, #S5PC1XX_GPIO_CON_OFFSET]
  59
  60         ldr     r1, [r0, #S5PC1XX_GPIO_DAT_OFFSET]
  61 #ifdef CONFIG_ONENAND_IPL
  62         orr     r1, r1, #(1 << 1)                       @ 1 * 1-bit
  63 #else
  64         bic     r1, r1, #(1 << 1)
  65 #endif
  66         str     r1, [r0, #S5PC1XX_GPIO_DAT_OFFSET]
  67
  68         /* IO retension release */
  69         ldr     r0, =S5P_OTHERS                         @0xE0108200
  70         ldr     r1, [r0]
  71         ldr     r2, =(1 << 31)                          @IO_RET_REL
  72         orr     r1, r1, r2
  73         str     r1, [r0]
  74
  75         /* Disable Watchdog */
  76         ldr     r0, =S5P_WATCHDOG_BASE(0x0)             @0xEA200000
  77         orr     r0, r0, #0x0
  78         mov     r5, #0
  79         str     r5, [r0]
  80
  81 #ifndef CONFIG_ONENAND_IPL
  82         /* setting SRAM */
  83         ldr     r0, =S5P_SROMC_BASE(0x0)
  84         ldr     r1, =0x9
  85         str     r1, [r0]
  86 #endif
  87
  88         /* S5PC100 has 3 groups of interrupt sources */
  89         ldr     r0, =S5P_VIC0_BASE(0x0)                 @0xE4000000
  90         ldr     r1, =S5P_VIC1_BASE(0x0)                 @0xE4000000
  91         ldr     r2, =S5P_VIC2_BASE(0x0)                 @0xE4000000
  92
  93         /* Disable all interrupts (VIC0, VIC1 and VIC2) */
  94         mvn     r3, #0x0
  95         str     r3, [r0, #VIC_INTENCLEAR_OFFSET]
  96         str     r3, [r1, #VIC_INTENCLEAR_OFFSET]
  97         str     r3, [r2, #VIC_INTENCLEAR_OFFSET]
  98
  99 #ifndef CONFIG_ONENAND_IPL
 100         /* Set all interrupts as IRQ */
 101         str     r5, [r0, #VIC_INTSELECT_OFFSET]
 102         str     r5, [r1, #VIC_INTSELECT_OFFSET]
 103         str     r5, [r2, #VIC_INTSELECT_OFFSET]
 104
 105         /* Pending Interrupt Clear */
 106         str     r5, [r0, #VIC_INTADDRESS_OFFSET]
 107         str     r5, [r1, #VIC_INTADDRESS_OFFSET]
 108         str     r5, [r2, #VIC_INTADDRESS_OFFSET]
 109 #endif
 110
 111 #ifndef CONFIG_ONENAND_IPL
 112         /* for UART */
 113         bl      uart_asm_init
 114
 115         /* for DMA */
 116         bl      dma_asm_init
 117 #endif
 118
 119 #ifdef CONFIG_ONENAND_IPL
 120         /* init system clock */
 121         bl      system_clock_init
 122
 123         bl      mem_ctrl_asm_init
 124
 125         /* Wakeup support. Don't know if it's going to be used, untested. */
 126         ldr     r0, =S5P_RST_STAT
 127         ldr     r1, [r0]
 128         bic     r1, r1, #0xfffffff7
 129         cmp     r1, #0x8
 130         beq     wakeup_reset
 131 #endif
 132
 133 1:
 134         mov     lr, r9
 135         mov     pc, lr
 136
 137 #ifdef CONFIG_ONENAND_IPL
 138 wakeup_reset:
 139
 140         /* Turn on 7color [GPJ4(2)] at universal */
 141         ldr     r0, =S5PC100_GPIO_BASE(S5PC100_GPIO_J4_OFFSET)
 142         ldr     r1, [r0, #S5PC1XX_GPIO_CON_OFFSET]
 143         bic     r1, r1, #(0xf << 8)                     @ 2 * 4-bit
 144         orr     r1, r1, #(0x1 << 8)
 145         str     r1, [r0, #S5PC1XX_GPIO_CON_OFFSET]
 146
 147         ldr     r1, [r0, #S5PC1XX_GPIO_DAT_OFFSET]
 148         orr     r1, r1, #(1 << 2)                       @ 2 * 1-bit
 149         str     r1, [r0, #S5PC1XX_GPIO_DAT_OFFSET]
 150
 151         /* Clear wakeup status register */
 152         ldr     r0, =S5P_WAKEUP_STAT
 153         ldr     r1, [r0]
 154         str     r1, [r0]
 155
 156         /* Load return address and jump to kernel */
 157         ldr     r0, =S5P_INFORM0
 158
 159         /* r1 = physical address of s5pc100_cpu_resume function */
 160         ldr     r1, [r0]
 161
 162         /* Jump to kernel (sleep-s5pc100.S) */
 163         mov     pc, r1
 164         nop
 165         nop
 166 #endif
 167
 168 /*
 169  * system_clock_init: Initialize core clock and bus clock.
 170  * void system_clock_init(void)
 171  */
 172 system_clock_init:
 173         ldr     r8, =S5P_PA_CLK                 @ 0xE0100000
 174
 175         /* Set Lock Time */
 176         ldr     r1, =0xe10                      @ Locktime : 0xe10 = 3600
 177         str     r1, [r8, #0x000]                @ S5P_APLL_LOCK
 178         str     r1, [r8, #0x004]                @ S5P_MPLL_LOCK
 179         str     r1, [r8, #0x008]                @ S5P_EPLL_LOCK
 180         str     r1, [r8, #0x00C]                @ S5P_HPLL_LOCK
 181
 182         /* S5P_APLL_CON */
 183 #ifdef CONFIG_CLK_667_166_83
 184         ldr     r1, =0x81bc0400         @ SDIV 0, PDIV 4, MDIV 444 (1333MHz)
 185 #elif defined(CONFIG_CLK_666_166_66)
 186         ldr     r1, =0x814d0301         @ SDIV 1, PDIV 3, MDIV 333 (1333MHz)
 187 #elif defined(CONFIG_CLK_600_150_75)
 188         ldr     r1, =0x812C0300         @ SDIV 0, PDIV 3, MDIV 300 (1200MHz)
 189 #elif defined(CONFIG_CLK_533_133_66)
 190         ldr     r1, =0x810b0300         @ SDIV 0, PDIV 3, MDIV 267 (1066MHz)
 191 #elif defined(CONFIG_CLK_500_166_66)
 192         ldr     r1, =0x81f40301         @ SDIV 1, PDIV 3, MDIV 500 (1000MHz)
 193 #elif defined(CONFIG_CLK_467_117_59)
 194         ldr     r1, =0x826E0401         @ SDIV 1, PDIV 4, MDIV 622 (933MHz)
 195 #elif defined(CONFIG_CLK_400_100_50)
 196         ldr     r1, =0x81900301         @ SDIV 1, PDIV 3, MDIV 400 (800MHz)
 197 #else
 198 #error you should set the correct clock configuration
 199 #endif
 200         str     r1, [r8, #0x100]
 201         /* S5P_MPLL_CON */
 202         ldr     r1, =0x80590201         @ SDIV 1, PDIV 2, MDIV 89 (267MHz)
 203         str     r1, [r8, #0x104]
 204         /* S5P_EPLL_CON */
 205         ldr     r1, =0x80870303         @ SDIV 3, PDIV 3, MDIV 135 (67.5MHz)
 206         str     r1, [r8, #0x108]
 207         /* S5P_HPLL_CON */
 208         ldr     r1, =0x80600603         @ SDIV 3, PDIV 6, MDIV 96
 209         str     r1, [r8, #0x10C]
 210
 211         /* Set Clock divider */
 212         ldr     r1, [r8, #0x300]
 213         ldr     r2, =0x00003fff
 214         bic     r1, r1, r2
 215 #ifdef CONFIG_CLK_800_166_66
 216         ldr     r2, =0x00011401
 217 #elif defined(CONFIG_CLK_500_166_66)
 218         ldr     r2, =0x00011201
 219 #elif defined(CONFIG_CLK_666_166_66)
 220         ldr     r2, =0x00011300
 221 #else
 222         ldr     r2, =0x00011301
 223 #endif
 224         orr     r1, r1, r2
 225         str     r1, [r8, #0x300]
 226         ldr     r1, [r8, #0x304]
 227         ldr     r2, =0x00011110
 228         orr     r1, r1, r2
 229         str     r1, [r8, #0x304]
 230         ldr     r1, =0x00000001
 231         str     r1, [r8, #0x308]
 232
 233         /* Set Source Clock */
 234         ldr     r1, =0x1111                     @ A, M, E, HPLL Muxing
 235         str     r1, [r8, #0x200]                @ S5P_CLK_SRC0
 236
 237 #if 0
 238         ldr     r1, =0x1000001                  @ Uart Clock & CLK48M Muxing
 239         str     r1, [r8, #0x204]                @ S5P_CLK_SRC1
 240
 241         ldr     r1, =0x9000                     @ ARMCLK/4
 242         str     r1, [r8, #0x400]                @ S5P_CLK_OUT
 243 #endif
 244
 245         /* wait at least 200us to stablize all clock */
 246         mov     r2, #0x10000
 247 1:      subs    r2, r2, #1
 248         bne     1b
 249
 250         mov     pc, lr
 251
 252 #ifndef CONFIG_ONENAND_IPL
 253 /*
 254  * uart_asm_init: Initialize UART's pins
 255  */
 256 uart_asm_init:
 257         /* set GPIO to enable UART0-UART4 */
 258         ldr     r0, =S5PC100_GPIO_BASE(0)
 259         ldr     r1, =0x22222222
 260         str     r1, [r0, #S5PC100_GPIO_A0_OFFSET]               @ GPA0_CON
 261         ldr     r1, =0x00002222
 262         str     r1, [r0, #S5PC100_GPIO_A1_OFFSET]               @ GPA1_CON
 263
 264         /* UART_SEL GPK0[5] at S5PC100 */
 265         ldr     r0, =S5PC100_GPIO_BASE(S5PC100_GPIO_K0_OFFSET)
 266         ldr     r1, [r0, #S5PC1XX_GPIO_CON_OFFSET]
 267         bic     r1, r1, #(0xf << 20)            @ 20 = 5 * 4-bit
 268         orr     r1, r1, #(0x1 << 20)            @ Output
 269         str     r1, [r0, #S5PC1XX_GPIO_CON_OFFSET]
 270
 271         ldr     r1, [r0, #S5PC1XX_GPIO_PULL_OFFSET]
 272         bic     r1, r1, #(0x3 << 10)            @ 10 = 5 * 2-bit
 273         orr     r1, r1, #(0x2 << 10)            @ Pull-up enabled
 274         str     r1, [r0, #S5PC1XX_GPIO_PULL_OFFSET]
 275
 276         ldr     r1, [r0, #S5PC1XX_GPIO_DAT_OFFSET]
 277         orr     r1, r1, #(1 << 5)               @ 5 = 5 * 1-bit
 278         str     r1, [r0, #S5PC1XX_GPIO_DAT_OFFSET]
 279
 280         /*
 281          * Note that the following address
 282          * 0xE020'0360 is reserved address at S5PC100
 283          */
 284         /* UART_SEL MP0_5[7] at S5PC110 */
 285         ldr     r0, =S5PC110_GPIO_BASE(S5PC110_GPIO_MP0_5_OFFSET)
 286         ldr     r1, [r0, #S5PC1XX_GPIO_CON_OFFSET]
 287         bic     r1, r1, #(0xf << 28)            @ 28 = 7 * 4-bit
 288         orr     r1, r1, #(0x1 << 28)            @ Output
 289         str     r1, [r0, #S5PC1XX_GPIO_CON_OFFSET]
 290
 291         ldr     r1, [r0, #S5PC1XX_GPIO_PULL_OFFSET]
 292         bic     r1, r1, #(0x3 << 14)            @ 14 = 7 * 2-bit
 293         orr     r1, r1, #(0x2 << 14)            @ Pull-up enabled
 294         str     r1, [r0, #S5PC1XX_GPIO_PULL_OFFSET]
 295
 296         ldr     r1, [r0, #S5PC1XX_GPIO_DAT_OFFSET]
 297         orr     r1, r1, #(1 << 7)               @ 7 = 7 * 1-bit
 298         str     r1, [r0, #S5PC1XX_GPIO_DAT_OFFSET]
 299
 300         mov     pc, lr
 301
 302 /*
 303  * dma_asm_init: Initialize DMA
 304  */
 305 dma_asm_init:
 306         ldr     r0, =0xE3800000
 307         mov     r1, #0x0
 308         str     r1, [r0]
 309         mov     r1, #0xff
 310         str     r1, [r0, #0x804]
 311         str     r1, [r0, #0x810]
 312
 313         ldr     r0, =0xE2800000
 314         str     r1, [r0, #0x804]
 315         str     r1, [r0, #0x810]
 316         str     r1, [r0, #0x81C]
 317
 318         ldr     r0, =0xE2900000
 319         str     r1, [r0, #0x804]
 320         str     r1, [r0, #0x810]
 321
 322         mov     pc, lr
 323
 324 #endif