board/samsung/universal/lowlevel_init.S

   1 /*
   2  * Memory Setup stuff - taken from blob memsetup.S
   3  *
   4  * Copyright (C) 2009 Samsung Electronics
   5  * Kyungmin Park <kyungmin.park@samsung.com>
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 #include <config.h>
  27 #include <version.h>
  28 #include <asm/arch/cpu.h>
  29 #include <asm/arch/mem.h>
  30 #include <asm/arch/clock.h>
  31 #include <asm/arch/power.h>
  32 #include <asm/arch/watchdog.h>
  33 #include <asm/arch/interrupt.h>
  34
  35 #define DEBUG_PM_C110
  36 #undef DEBUG_PM_C110
  37
  38 /*
  39  * Register usages:
  40  *
  41  * r5 has zero always
  42  * r7 has S5PC100 GPIO base, 0xE0300000
  43  * r8 has real GPIO base, 0xE0300000, 0xE0200000 at S5PC100, S5PC110 repectively
  44  * r9 has Mobile DDR size, 1 means 1GiB, 2 means 2GiB and so on
  45  */
  46
  47 _TEXT_BASE:
  48         .word   TEXT_BASE
  49
  50         .globl lowlevel_init
  51 lowlevel_init:
  52         mov     r11, lr
  53
  54         /* r5 has always zero */
  55         mov     r5, #0
  56
  57         ldr     r7, =S5PC100_GPIO_BASE
  58         ldr     r8, =S5PC100_GPIO_BASE
  59         /* Read CPU ID */
  60         ldr     r2, =S5PC1XX_PRO_ID
  61         ldr     r0, [r2]
  62         mov     r1, #0x00010000
  63         and     r0, r0, r1
  64         cmp     r0, r5
  65         beq     100f
  66         ldr     r8, =S5PC110_GPIO_BASE
  67 100:
  68         /* Turn on KEY_LED_ON [GPJ4(1)] XMSMWEN */
  69         cmp     r7, r8
  70 #ifndef DEBUG_PM_C110
  71         addeq   r0, r8, #0x280                          @S5PC100_GPIO_J4_OFFSET
  72         addne   r0, r8, #0x2C0                          @S5PC110_GPIO_J4_OFFSET
  73         ldr     r1, [r0, #0x0]                          @S5PC1XX_GPIO_CON_OFFSET
  74         bic     r1, r1, #(0xf << 4)                     @ 1 * 4-bit
  75         orr     r1, r1, #(0x1 << 4)
  76         str     r1, [r0, #0x0]                          @S5PC1XX_GPIO_CON_OFFSET
  77
  78         ldr     r1, [r0, #0x4]                          @S5PC1XX_GPIO_DAT_OFFSET
  79 #ifdef CONFIG_ONENAND_IPL
  80         orr     r1, r1, #(1 << 1)                       @ 1 * 1-bit
  81 #else
  82         bic     r1, r1, #(1 << 1)
  83 #endif
  84         str     r1, [r0, #0x4]                          @S5PC1XX_GPIO_DAT_OFFSET
  85 #endif
  86
  87         /* IO retension release */
  88         ldreq   r0, =S5PC100_OTHERS                     @0xE0108200
  89         ldrne   r0, =S5PC110_OTHERS                     @0xE010E000
  90         ldr     r1, [r0]
  91         ldreq   r2, =(1 << 31)                          @IO_RET_REL
  92         ldrne   r2, =((1 << 31) | (1 << 29) | (1 << 28))        @ GPIO, UART_IO
  93         orr     r1, r1, r2
  94         str     r1, [r0]
  95
  96 #ifndef CONFIG_ONENAND_IPL
  97         /* Disable Watchdog */
  98         ldreq   r0, =S5PC100_WATCHDOG_BASE              @0xEA200000
  99         ldrne   r0, =S5PC110_WATCHDOG_BASE              @0xE2700000
 100         str     r5, [r0]
 101
 102         /* setting SRAM */
 103         ldreq   r0, =S5PC100_SROMC_BASE
 104         ldrne   r0, =S5PC110_SROMC_BASE
 105         ldr     r1, =0x9
 106         str     r1, [r0]
 107 #endif
 108
 109         /* S5PC100 has 3 groups of interrupt sources */
 110         ldreq   r0, =S5PC100_VIC0_BASE                  @0xE4000000
 111         ldrne   r0, =S5PC110_VIC0_BASE                  @0xF2000000
 112         add     r1, r0, #0x00100000
 113         add     r2, r0, #0x00200000
 114
 115         /* Disable all interrupts (VIC0, VIC1 and VIC2) */
 116         mvn     r3, #0x0
 117         str     r3, [r0, #VIC_INTENCLEAR_OFFSET]
 118         str     r3, [r1, #VIC_INTENCLEAR_OFFSET]
 119         str     r3, [r2, #VIC_INTENCLEAR_OFFSET]
 120
 121 #ifndef CONFIG_ONENAND_IPL
 122         /* Set all interrupts as IRQ */
 123         str     r5, [r0, #VIC_INTSELECT_OFFSET]
 124         str     r5, [r1, #VIC_INTSELECT_OFFSET]
 125         str     r5, [r2, #VIC_INTSELECT_OFFSET]
 126
 127         /* Pending Interrupt Clear */
 128         str     r5, [r0, #VIC_INTADDRESS_OFFSET]
 129         str     r5, [r1, #VIC_INTADDRESS_OFFSET]
 130         str     r5, [r2, #VIC_INTADDRESS_OFFSET]
 131 #endif
 132
 133 #ifndef CONFIG_ONENAND_IPL
 134         /* for UART */
 135         bl      uart_asm_init
 136
 137         bl      internal_ram_init
 138 #endif
 139
 140 #ifdef CONFIG_ONENAND_IPL
 141         /* init system clock */
 142         bl      system_clock_init
 143
 144         /* Board detection to set proper memory configuration */
 145         cmp     r7, r8
 146         moveq   r9, #1          /* r9 has 1Gib default at s5pc100 */
 147         movne   r9, #2          /* r9 has 2Gib default at s5pc110 */
 148         /* FIXME 1Gib detection: Limo Universal */
 149         /* Check Limo Real board
 150          *      LR (suspend)    LU              J1B2
 151          * 0x04 0x01 (0x01)     0x01 (0x01)     0x01 (0x01)
 152          * 0x24 0x28 (0xA8)     0x28 (0x6A)     0x1C (0x1C)
 153          * 0x44 0x00 (0xC7)     0x00 (0x47)     0x00 (0x47)
 154          * 0x64 0x03 (0x1F)     0x07 (0x1F)     0x0f (0x0F)
 155          *
 156          * Check (0 << 3) at 0x64 at boot
 157          * Check 0x47 at 0x44 at suspend
 158          */
 159         ldrne   r2, =0xE0200C00
 160         ldrne   r1, [r2, #0x64]
 161         and     r1, r1, #(1 << 2)
 162         cmp     r1, #(1 << 2)
 163         moveq   r9, #1
 164         ldr     r1, [r2, #0x44]
 165         cmp     r1, #0x47
 166         moveq   r9, #1
 167         /*
 168          * Aquila Rev 0.5 : 4G3G1G x16 for Infineon ES3.1
 169          * Aquila Rev 0.6 : 4G1G1G x32 for MSM6290
 170          * Aquila Rev 0.7 : 4G3G1G x16 for Infineon ES3.1
 171          */
 172         ldr     r2, =0xE0200200
 173         ldr     r4, [r2, #0x48]
 174         bic     r1, r4, #(0xFF << 2)    /* PULLUP_DISABLE: 4 * 2-bit */
 175         str     r1, [r2, #0x48]
 176         /* For write completion */
 177         nop
 178         nop
 179
 180         ldr     r3, [r2, #0x44]
 181         and     r1, r3, #(0x5 << 2)
 182         cmp     r1, #(0x5 << 2)
 183         moveq   r9, #3
 184         and     r1, r3, #(0x6 << 2)
 185         cmp     r1, #(0x6 << 2)
 186         moveq   r9, #1
 187         and     r1, r3, #(0x7 << 2)
 188         cmp     r1, #(0x7 << 2)
 189         moveq   r9, #3
 190         str     r4, [r2, #0x48]         /* Restore PULLUP configuration */
 191
 192         bl      mem_ctrl_asm_init
 193
 194         /* OneNAND Sync Read Support at S5PC110 only
 195          * RM[15]       : Sync Read
 196          * BRWL[14:12]  : 7 CLK
 197          * BL[11:9]     : Continuous
 198          * VHF[3]       : Very High Frequency Enable (Over 83MHz)
 199          * HF[2]        : High Frequency Enable (Over 66MHz)
 200          */
 201         cmp     r7, r8
 202         ldrne   r1, =0xE00C
 203
 204         ldrne   r0, =0xB001E442
 205         strneh  r1, [r0]
 206
 207         ldrne   r0, =0xB0600000
 208         strne   r1, [r0, #0x100]                        @ ONENAND_IF_CTRL
 209
 210         /* Wakeup support. Don't know if it's going to be used, untested. */
 211         ldreq   r0, =S5PC100_RST_STAT
 212         ldrne   r0, =S5PC110_RST_STAT
 213         ldr     r1, [r0]
 214         biceq   r1, r1, #0xfffffff7
 215         moveq   r2, #(1 << 3)
 216         bicne   r1, r1, #0xfffeffff
 217         movne   r2, #(1 << 16)
 218         cmp     r1, r2
 219         bne     1f
 220 wakeup:
 221 #ifdef DEBUG_PM_C110
 222         mov     r0, r8
 223         ldr     r1, =0x22222222
 224         str     r1, [r0, #0x0]                  @S5PC100_GPIO_A0_OFFSET
 225         ldr     r1, =0x00002222
 226         str     r1, [r0, #0x20]                 @S5PC100_GPIO_A1_OFFSET
 227
 228         /* UART_SEL MP0_5[7] at S5PC110 */
 229         add     r0, r8, #0x360                  @S5PC110_GPIO_MP0_5_OFFSET
 230         ldr     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 231         bic     r1, r1, #(0xf << 28)            @ 28 = 7 * 4-bit
 232         orr     r1, r1, #(0x1 << 28)            @ Output
 233         str     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 234
 235         ldr     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 236         bic     r1, r1, #(0x3 << 14)            @ 14 = 7 * 2-bit
 237         orr     r1, r1, #(0x2 << 14)            @ Pull-up enabled
 238         str     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 239
 240         ldr     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 241         orr     r1, r1, #(1 << 7)               @ 7 = 7 * 1-bit
 242         str     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 243
 244         ldr     r0, =0xE2900000                 @ S5PC110_PA_UART
 245         orr     r0, r0, #0x800
 246         mov     r1, #0x3
 247         str     r1, [r0, #0x000]                @ ULCON
 248         ldr     r1, =0x245
 249         str     r1, [r0, #0x004]                @ UCON
 250         mov     r1, #0x23
 251         str     r1, [r0, #0x028]                @ UBRDIV
 252         mov     r1, #0x3
 253         str     r1, [r0, #0x02C]                @ UDIVSLOT
 254
 255         mov     r2, #'W'
 256         strb    r2, [r0, #0x020]                @ UTXH
 257 1001:
 258         ldrb    r3, [r0, #0x010]                @ UTRSTAT
 259         tst     r3, #(1 << 2)
 260         beq     1001b
 261 #endif
 262
 263         /* turn off L2 cache */
 264         bl      l2_cache_disable
 265
 266         cmp     r7, r8
 267         ldreq   r0, =0xC100
 268         ldrne   r0, =0xC110
 269
 270         /* invalidate L2 cache also */
 271         bl      invalidate_dcache
 272
 273         /* turn on L2 cache */
 274         bl      l2_cache_enable
 275
 276         cmp     r7, r8
 277         /* Load return address and jump to kernel */
 278         ldreq   r0, =S5PC100_INFORM0
 279         ldrne   r0, =S5PC110_INFORM0
 280
 281         /* r1 = physical address of s5pc1xx_cpu_resume function */
 282         ldr     r1, [r0]
 283
 284         /* Jump to kernel (sleep-s5pc1xx.S) */
 285         mov     pc, r1
 286         nop
 287         nop
 288 #else
 289         cmp     r7, r8
 290         /* Clear wakeup status register */
 291         ldreq   r0, =S5PC100_WAKEUP_STAT
 292         ldrne   r0, =S5PC110_WAKEUP_STAT
 293         ldr     r1, [r0]
 294         str     r1, [r0]
 295 #endif
 296 1:
 297         mov     lr, r11
 298         mov     pc, lr
 299
 300 /*
 301  * system_clock_init: Initialize core clock and bus clock.
 302  * void system_clock_init(void)
 303  */
 304 system_clock_init:
 305         ldr     r0, =S5PC1XX_CLOCK_BASE         @ 0xE0100000
 306
 307         /* Check S5PC100 */
 308         cmp     r7, r8
 309         bne     110f
 310 100:
 311 #ifndef DEBUG_PM_C110
 312         /* Set Lock Time */
 313         ldr     r1, =0xe10                      @ Locktime : 0xe10 = 3600
 314         str     r1, [r0, #0x000]                @ S5PC100_APLL_LOCK
 315         str     r1, [r0, #0x004]                @ S5PC100_MPLL_LOCK
 316         str     r1, [r0, #0x008]                @ S5PC100_EPLL_LOCK
 317         str     r1, [r0, #0x00C]                @ S5PC100_HPLL_LOCK
 318
 319         /* S5P_APLL_CON */
 320 #ifdef CONFIG_CLK_667_166_83
 321         ldr     r1, =0x81bc0400         @ SDIV 0, PDIV 4, MDIV 444 (1333MHz)
 322 #elif defined(CONFIG_CLK_666_166_66)
 323         ldr     r1, =0x814d0301         @ SDIV 1, PDIV 3, MDIV 333 (1333MHz)
 324 #elif defined(CONFIG_CLK_600_150_75)
 325         ldr     r1, =0x812C0300         @ SDIV 0, PDIV 3, MDIV 300 (1200MHz)
 326 #elif defined(CONFIG_CLK_533_133_66)
 327         ldr     r1, =0x810b0300         @ SDIV 0, PDIV 3, MDIV 267 (1066MHz)
 328 #elif defined(CONFIG_CLK_500_166_66)
 329         ldr     r1, =0x81f40301         @ SDIV 1, PDIV 3, MDIV 500 (1000MHz)
 330 #elif defined(CONFIG_CLK_467_117_59)
 331         ldr     r1, =0x826E0401         @ SDIV 1, PDIV 4, MDIV 622 (933MHz)
 332 #elif defined(CONFIG_CLK_400_100_50)
 333         ldr     r1, =0x81900301         @ SDIV 1, PDIV 3, MDIV 400 (800MHz)
 334 #else
 335 #error you should set the correct clock configuration
 336 #endif
 337         str     r1, [r0, #0x100]
 338         /* S5P_MPLL_CON */
 339         ldr     r1, =0x80590201         @ SDIV 1, PDIV 2, MDIV 89 (267MHz)
 340         str     r1, [r0, #0x104]
 341         /* S5P_EPLL_CON */
 342         ldr     r1, =0x80870303         @ SDIV 3, PDIV 3, MDIV 135 (67.5MHz)
 343         str     r1, [r0, #0x108]
 344         /* S5P_HPLL_CON */
 345         ldr     r1, =0x80600603         @ SDIV 3, PDIV 6, MDIV 96
 346         str     r1, [r0, #0x10C]
 347
 348         ldr     r1, [r0, #0x300]
 349         ldr     r2, =0x00003fff
 350         bic     r1, r1, r2
 351 #ifdef CONFIG_CLK_800_166_66
 352         ldr     r2, =0x00011401
 353 #elif defined(CONFIG_CLK_500_166_66)
 354         ldr     r2, =0x00011201
 355 #elif defined(CONFIG_CLK_666_166_66)
 356         ldr     r2, =0x00011300
 357 #else
 358         ldr     r2, =0x00011301
 359 #endif
 360         orr     r1, r1, r2
 361         str     r1, [r0, #0x300]
 362         ldr     r1, [r0, #0x304]
 363         ldr     r2, =0x00011110
 364         orr     r1, r1, r2
 365         str     r1, [r0, #0x304]
 366         ldr     r1, =0x00000001
 367         str     r1, [r0, #0x308]
 368
 369         /* Set Source Clock */
 370         ldr     r1, =0x00001111                 @ A, M, E, HPLL Muxing
 371         str     r1, [r0, #0x200]                @ S5PC1XX_CLK_SRC0
 372 #endif
 373         b       200f
 374 110:
 375         /* Set Clock divider */
 376         ldr     r1, =0x14131330                 @ 1:1:4:4, 1:4:5
 377         str     r1, [r0, #0x300]
 378         ldr     r1, =0x11110111                 @ UART[3210]: MMC[3210]
 379         str     r1, [r0, #0x310]
 380
 381         /* Set Lock Time */
 382         ldr     r1, =0xe10                      @ Locktime : 0xe10 = 3600
 383         str     r1, [r0, #0x000]                @ S5PC110_APLL_LOCK
 384         str     r1, [r0, #0x010]                @ S5PC110_MPLL_LOCK
 385         str     r1, [r0, #0x018]                @ S5PC110_EPLL_LOCK
 386         str     r1, [r0, #0x020]                @ S5PC110_VPLL_LOCK
 387
 388         /* S5PC110_APLL_CON */
 389         ldr     r1, =0x80C80601                 @ 800MHz
 390         str     r1, [r0, #0x100]
 391         /* S5PC110_MPLL_CON */
 392         ldr     r1, =0x829B0C01                 @ 667MHz
 393         str     r1, [r0, #0x108]
 394         /* S5PC110_EPLL_CON */
 395         ldr     r1, =0x80600602                 @  96MHz VSEL 0 P 6 M 96 S 2
 396         str     r1, [r0, #0x110]
 397         /* S5PC110_VPLL_CON */
 398         ldr     r1, =0x806C0603                 @  54MHz
 399         str     r1, [r0, #0x120]
 400
 401         /* Set Source Clock */
 402         ldr     r1, =0x10001111                 @ A, M, E, VPLL Muxing
 403         str     r1, [r0, #0x200]                @ S5PC1XX_CLK_SRC0
 404
 405         /* OneDRAM(DMC0) clock setting */
 406         ldr     r1, =0x01000000                 @ ONEDRAM_SEL[25:24] 1 SCLKMPLL
 407         str     r1, [r0, #0x218]                @ S5PC110_CLK_SRC6
 408         ldr     r1, =0x30000000                 @ ONEDRAM_RATIO[31:28] 3 + 1
 409         str     r1, [r0, #0x318]                @ S5PC110_CLK_DIV6
 410
 411         /* XCLKOUT = XUSBXTI 24MHz */
 412         add     r2, r0, #0xE000                 @ S5PC110_OTHERS
 413         ldr     r1, [r2]
 414         orr     r1, r1, #(0x3 << 8)             @ CLKOUT[9:8] 3 XUSBXTI
 415         str     r1, [r2]
 416
 417 200:
 418         /* wait at least 200us to stablize all clock */
 419         mov     r2, #0x10000
 420 1:      subs    r2, r2, #1
 421         bne     1b
 422
 423         mov     pc, lr
 424
 425 #ifndef CONFIG_ONENAND_IPL
 426 internal_ram_init:
 427         ldreq   r0, =0xE3800000
 428         ldrne   r0, =0xF1500000
 429         ldr     r1, =0x0
 430         str     r1, [r0]
 431
 432         mov     pc, lr
 433 #endif
 434
 435 #ifndef CONFIG_ONENAND_IPL
 436 /*
 437  * uart_asm_init: Initialize UART's pins
 438  */
 439 uart_asm_init:
 440         /* set GPIO to enable UART0-UART4 */
 441         mov     r0, r8
 442         ldr     r1, =0x22222222
 443         str     r1, [r0, #0x0]                  @S5PC100_GPIO_A0_OFFSET
 444         ldr     r1, =0x00002222
 445         str     r1, [r0, #0x20]                 @S5PC100_GPIO_A1_OFFSET
 446
 447         /* Check S5PC100 */
 448         cmp     r7, r8
 449         bne     110f
 450
 451 #ifndef DEBUG_PM_C110
 452         /* UART_SEL GPK0[5] at S5PC100 */
 453         add     r0, r8, #0x2A0                  @S5PC100_GPIO_K0_OFFSET
 454         ldr     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 455         bic     r1, r1, #(0xf << 20)            @ 20 = 5 * 4-bit
 456         orr     r1, r1, #(0x1 << 20)            @ Output
 457         str     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 458
 459         ldr     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 460         bic     r1, r1, #(0x3 << 10)            @ 10 = 5 * 2-bit
 461         orr     r1, r1, #(0x2 << 10)            @ Pull-up enabled
 462         str     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 463
 464         ldr     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 465         orr     r1, r1, #(1 << 5)               @ 5 = 5 * 1-bit
 466         str     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 467 #endif
 468         b       200f
 469 110:
 470         /*
 471          * Note that the following address
 472          * 0xE020'0360 is reserved address at S5PC100
 473          */
 474         /* UART_SEL MP0_5[7] at S5PC110 */
 475         add     r0, r8, #0x360                  @S5PC110_GPIO_MP0_5_OFFSET
 476         ldr     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 477         bic     r1, r1, #(0xf << 28)            @ 28 = 7 * 4-bit
 478         orr     r1, r1, #(0x1 << 28)            @ Output
 479         str     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 480
 481         ldr     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 482         bic     r1, r1, #(0x3 << 14)            @ 14 = 7 * 2-bit
 483         orr     r1, r1, #(0x2 << 14)            @ Pull-up enabled
 484         str     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 485
 486         ldr     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 487         orr     r1, r1, #(1 << 7)               @ 7 = 7 * 1-bit
 488         str     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 489 200:
 490         mov     pc, lr
 491 #endif