board/samsung/universal/lowlevel_init.S

   1 /*
   2  * Memory Setup stuff - taken from blob memsetup.S
   3  *
   4  * Copyright (C) 2009 Samsung Electronics
   5  * Kyungmin Park <kyungmin.park@samsung.com>
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 #include <config.h>
  27 #include <version.h>
  28 #include <asm/arch/cpu.h>
  29 #include <asm/arch/mem.h>
  30 #include <asm/arch/clock.h>
  31 #include <asm/arch/power.h>
  32 #include <asm/arch/watchdog.h>
  33 #include <asm/arch/interrupt.h>
  34
  35 #define DEBUG_PM_C110
  36 #undef DEBUG_PM_C110
  37
  38 /*
  39  * Register usages:
  40  *
  41  * r5 has zero always
  42  * r7 has S5PC100 GPIO base, 0xE0300000
  43  * r8 has real GPIO base, 0xE0300000, 0xE0200000 at S5PC100, S5PC110 repectively
  44  * r9 has Mobile DDR size, 1 means 1GiB, 2 means 2GiB and so on
  45  */
  46
  47 _TEXT_BASE:
  48         .word   TEXT_BASE
  49
  50         .globl lowlevel_init
  51 lowlevel_init:
  52         mov     r11, lr
  53
  54         /* r5 has always zero */
  55         mov     r5, #0
  56
  57         ldr     r7, =S5PC100_GPIO_BASE
  58         ldr     r8, =S5PC100_GPIO_BASE
  59         /* Read CPU ID */
  60         ldr     r2, =S5PC1XX_PRO_ID
  61         ldr     r0, [r2]
  62         mov     r1, #0x00010000
  63         and     r0, r0, r1
  64         cmp     r0, r5
  65         beq     100f
  66         ldr     r8, =S5PC110_GPIO_BASE
  67 100:
  68         /* Turn on KEY_LED_ON [GPJ4(1)] XMSMWEN */
  69         cmp     r7, r8
  70 #ifndef DEBUG_PM_C110
  71         addeq   r0, r8, #0x280                          @S5PC100_GPIO_J4_OFFSET
  72         addne   r0, r8, #0x2C0                          @S5PC110_GPIO_J4_OFFSET
  73         ldr     r1, [r0, #0x0]                          @S5PC1XX_GPIO_CON_OFFSET
  74         bic     r1, r1, #(0xf << 4)                     @ 1 * 4-bit
  75         orr     r1, r1, #(0x1 << 4)
  76         str     r1, [r0, #0x0]                          @S5PC1XX_GPIO_CON_OFFSET
  77
  78         ldr     r1, [r0, #0x4]                          @S5PC1XX_GPIO_DAT_OFFSET
  79 #ifdef CONFIG_ONENAND_IPL
  80         orr     r1, r1, #(1 << 1)                       @ 1 * 1-bit
  81 #else
  82         bic     r1, r1, #(1 << 1)
  83 #endif
  84         str     r1, [r0, #0x4]                          @S5PC1XX_GPIO_DAT_OFFSET
  85 #endif
  86
  87         /* IO retension release */
  88         ldreq   r0, =S5PC100_OTHERS                     @0xE0108200
  89         ldrne   r0, =S5PC110_OTHERS                     @0xE010E000
  90         ldr     r1, [r0]
  91         ldreq   r2, =(1 << 31)                          @IO_RET_REL
  92         ldrne   r2, =((1 << 31) | (1 << 29) | (1 << 28))        @ GPIO, UART_IO
  93         orr     r1, r1, r2
  94         str     r1, [r0]
  95
  96 #ifndef CONFIG_ONENAND_IPL
  97         /* Disable Watchdog */
  98         ldreq   r0, =S5PC100_WATCHDOG_BASE              @0xEA200000
  99         ldrne   r0, =S5PC110_WATCHDOG_BASE              @0xE2700000
 100         str     r5, [r0]
 101
 102         /* setting SRAM */
 103         ldreq   r0, =S5PC100_SROMC_BASE
 104         ldrne   r0, =S5PC110_SROMC_BASE
 105         ldr     r1, =0x9
 106         str     r1, [r0]
 107 #endif
 108
 109         /* S5PC100 has 3 groups of interrupt sources */
 110         ldreq   r0, =S5PC100_VIC0_BASE                  @0xE4000000
 111         ldrne   r0, =S5PC110_VIC0_BASE                  @0xF2000000
 112         add     r1, r0, #0x00100000
 113         add     r2, r0, #0x00200000
 114
 115         /* Disable all interrupts (VIC0, VIC1 and VIC2) */
 116         mvn     r3, #0x0
 117         str     r3, [r0, #VIC_INTENCLEAR_OFFSET]
 118         str     r3, [r1, #VIC_INTENCLEAR_OFFSET]
 119         str     r3, [r2, #VIC_INTENCLEAR_OFFSET]
 120
 121 #ifndef CONFIG_ONENAND_IPL
 122         /* Set all interrupts as IRQ */
 123         str     r5, [r0, #VIC_INTSELECT_OFFSET]
 124         str     r5, [r1, #VIC_INTSELECT_OFFSET]
 125         str     r5, [r2, #VIC_INTSELECT_OFFSET]
 126
 127         /* Pending Interrupt Clear */
 128         str     r5, [r0, #VIC_INTADDRESS_OFFSET]
 129         str     r5, [r1, #VIC_INTADDRESS_OFFSET]
 130         str     r5, [r2, #VIC_INTADDRESS_OFFSET]
 131 #endif
 132
 133 #ifndef CONFIG_ONENAND_IPL
 134         /* for UART */
 135         bl      uart_asm_init
 136
 137         bl      internal_ram_init
 138 #endif
 139
 140 #ifdef CONFIG_ONENAND_IPL
 141         /* init system clock */
 142         bl      system_clock_init
 143
 144         /* Board detection to set proper memory configuration */
 145         cmp     r7, r8
 146         moveq   r9, #1          /* r9 has 1Gib default at s5pc100 */
 147         movne   r9, #2          /* r9 has 2Gib default at s5pc110 */
 148         /* FIXME 1Gib detection: Limo Universal */
 149         /* Check Limo Real board
 150          *      LR (suspend)    LU              J1B2
 151          * 0x04 0x01 (0x01)     0x01 (0x01)     0x01 (0x01)
 152          * 0x24 0x28 (0xA8)     0x28 (0x6A)     0x1C (0x1C)
 153          * 0x44 0x00 (0xC7)     0x00 (0x47)     0x00 (0x47)
 154          * 0x64 0x03 (0x1F)     0x07 (0x1F)     0x0f (0x0F)
 155          *
 156          * Check (0 << 3) at 0x64 at boot
 157          * Check 0x47 at 0x44 at suspend
 158          */
 159         ldrne   r2, =0xE0200C00
 160         ldrne   r1, [r2, #0x64]
 161         and     r1, r1, #(1 << 2)
 162         cmp     r1, #(1 << 2)
 163         moveq   r9, #1
 164         ldr     r1, [r2, #0x44]
 165         cmp     r1, #0x47
 166         moveq   r9, #1
 167         /*
 168          * Aquila Rev 0.5 : 4G3G1G x16 for Infineon ES3.1
 169          * Aquila Rev 0.6 : 4G1G1G x32 for MSM6290
 170          * Aquila Rev 0.7 : 4G3G1G x16 for Infineon ES3.1
 171          */
 172         ldr     r2, =0xE0200200
 173         ldr     r4, [r2, #0x48]
 174         bic     r1, r4, #(0xFF << 2)    /* PULLUP_DISABLE: 4 * 2-bit */
 175         str     r1, [r2, #0x48]
 176         nop
 177         ldr     r3, [r2, #0x44]
 178         and     r1, r3, #(0x5 << 2)
 179         cmp     r1, #(0x5 << 2)
 180         moveq   r9, #3
 181         and     r1, r3, #(0x6 << 2)
 182         cmp     r1, #(0x6 << 2)
 183         moveq   r9, #1
 184         and     r1, r3, #(0x7 << 2)
 185         cmp     r1, #(0x7 << 2)
 186         moveq   r9, #3
 187         str     r4, [r2, #0x48]         /* Restore PULLUP configuration */
 188
 189         bl      mem_ctrl_asm_init
 190
 191         /* OneNAND Sync Read Support at S5PC110 only
 192          * RM[15]       : Sync Read
 193          * BRWL[14:12]  : 7 CLK
 194          * BL[11:9]     : Continuous
 195          * VHF[3]       : Very High Frequency Enable (Over 83MHz)
 196          * HF[2]        : High Frequency Enable (Over 66MHz)
 197          */
 198         cmp     r7, r8
 199         ldrne   r1, =0xE00C
 200
 201         ldrne   r0, =0xB001E442
 202         strneh  r1, [r0]
 203
 204         ldrne   r0, =0xB0600000
 205         strne   r1, [r0, #0x100]                        @ ONENAND_IF_CTRL
 206
 207         /* Wakeup support. Don't know if it's going to be used, untested. */
 208         ldreq   r0, =S5PC100_RST_STAT
 209         ldrne   r0, =S5PC110_RST_STAT
 210         ldr     r1, [r0]
 211         biceq   r1, r1, #0xfffffff7
 212         moveq   r2, #(1 << 3)
 213         bicne   r1, r1, #0xfffeffff
 214         movne   r2, #(1 << 16)
 215         cmp     r1, r2
 216         bne     1f
 217 wakeup:
 218 #ifdef DEBUG_PM_C110
 219         mov     r0, r8
 220         ldr     r1, =0x22222222
 221         str     r1, [r0, #0x0]                  @S5PC100_GPIO_A0_OFFSET
 222         ldr     r1, =0x00002222
 223         str     r1, [r0, #0x20]                 @S5PC100_GPIO_A1_OFFSET
 224
 225         /* UART_SEL MP0_5[7] at S5PC110 */
 226         add     r0, r8, #0x360                  @S5PC110_GPIO_MP0_5_OFFSET
 227         ldr     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 228         bic     r1, r1, #(0xf << 28)            @ 28 = 7 * 4-bit
 229         orr     r1, r1, #(0x1 << 28)            @ Output
 230         str     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 231
 232         ldr     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 233         bic     r1, r1, #(0x3 << 14)            @ 14 = 7 * 2-bit
 234         orr     r1, r1, #(0x2 << 14)            @ Pull-up enabled
 235         str     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 236
 237         ldr     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 238         orr     r1, r1, #(1 << 7)               @ 7 = 7 * 1-bit
 239         str     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 240
 241         ldr     r0, =0xE2900000                 @ S5PC110_PA_UART
 242         orr     r0, r0, #0x800
 243         mov     r1, #0x3
 244         str     r1, [r0, #0x000]                @ ULCON
 245         ldr     r1, =0x245
 246         str     r1, [r0, #0x004]                @ UCON
 247         mov     r1, #0x23
 248         str     r1, [r0, #0x028]                @ UBRDIV
 249         mov     r1, #0x3
 250         str     r1, [r0, #0x02C]                @ UDIVSLOT
 251
 252         mov     r2, #'W'
 253         strb    r2, [r0, #0x020]                @ UTXH
 254 1001:
 255         ldrb    r3, [r0, #0x010]                @ UTRSTAT
 256         tst     r3, #(1 << 2)
 257         beq     1001b
 258 #endif
 259
 260         /* turn off L2 cache */
 261         bl      l2_cache_disable
 262
 263         cmp     r7, r8
 264         ldreq   r0, =0xC100
 265         ldrne   r0, =0xC110
 266
 267         /* invalidate L2 cache also */
 268         bl      invalidate_dcache
 269
 270         /* turn on L2 cache */
 271         bl      l2_cache_enable
 272
 273         cmp     r7, r8
 274         /* Load return address and jump to kernel */
 275         ldreq   r0, =S5PC100_INFORM0
 276         ldrne   r0, =S5PC110_INFORM0
 277
 278         /* r1 = physical address of s5pc1xx_cpu_resume function */
 279         ldr     r1, [r0]
 280
 281         /* Jump to kernel (sleep-s5pc1xx.S) */
 282         mov     pc, r1
 283         nop
 284         nop
 285 #else
 286         cmp     r7, r8
 287         /* Clear wakeup status register */
 288         ldreq   r0, =S5PC100_WAKEUP_STAT
 289         ldrne   r0, =S5PC110_WAKEUP_STAT
 290         ldr     r1, [r0]
 291         str     r1, [r0]
 292 #endif
 293 1:
 294         mov     lr, r11
 295         mov     pc, lr
 296
 297 /*
 298  * system_clock_init: Initialize core clock and bus clock.
 299  * void system_clock_init(void)
 300  */
 301 system_clock_init:
 302         ldr     r0, =S5PC1XX_CLOCK_BASE         @ 0xE0100000
 303
 304         /* Check S5PC100 */
 305         cmp     r7, r8
 306         bne     110f
 307 100:
 308 #ifndef DEBUG_PM_C110
 309         /* Set Lock Time */
 310         ldr     r1, =0xe10                      @ Locktime : 0xe10 = 3600
 311         str     r1, [r0, #0x000]                @ S5PC100_APLL_LOCK
 312         str     r1, [r0, #0x004]                @ S5PC100_MPLL_LOCK
 313         str     r1, [r0, #0x008]                @ S5PC100_EPLL_LOCK
 314         str     r1, [r0, #0x00C]                @ S5PC100_HPLL_LOCK
 315
 316         /* S5P_APLL_CON */
 317 #ifdef CONFIG_CLK_667_166_83
 318         ldr     r1, =0x81bc0400         @ SDIV 0, PDIV 4, MDIV 444 (1333MHz)
 319 #elif defined(CONFIG_CLK_666_166_66)
 320         ldr     r1, =0x814d0301         @ SDIV 1, PDIV 3, MDIV 333 (1333MHz)
 321 #elif defined(CONFIG_CLK_600_150_75)
 322         ldr     r1, =0x812C0300         @ SDIV 0, PDIV 3, MDIV 300 (1200MHz)
 323 #elif defined(CONFIG_CLK_533_133_66)
 324         ldr     r1, =0x810b0300         @ SDIV 0, PDIV 3, MDIV 267 (1066MHz)
 325 #elif defined(CONFIG_CLK_500_166_66)
 326         ldr     r1, =0x81f40301         @ SDIV 1, PDIV 3, MDIV 500 (1000MHz)
 327 #elif defined(CONFIG_CLK_467_117_59)
 328         ldr     r1, =0x826E0401         @ SDIV 1, PDIV 4, MDIV 622 (933MHz)
 329 #elif defined(CONFIG_CLK_400_100_50)
 330         ldr     r1, =0x81900301         @ SDIV 1, PDIV 3, MDIV 400 (800MHz)
 331 #else
 332 #error you should set the correct clock configuration
 333 #endif
 334         str     r1, [r0, #0x100]
 335         /* S5P_MPLL_CON */
 336         ldr     r1, =0x80590201         @ SDIV 1, PDIV 2, MDIV 89 (267MHz)
 337         str     r1, [r0, #0x104]
 338         /* S5P_EPLL_CON */
 339         ldr     r1, =0x80870303         @ SDIV 3, PDIV 3, MDIV 135 (67.5MHz)
 340         str     r1, [r0, #0x108]
 341         /* S5P_HPLL_CON */
 342         ldr     r1, =0x80600603         @ SDIV 3, PDIV 6, MDIV 96
 343         str     r1, [r0, #0x10C]
 344
 345         ldr     r1, [r0, #0x300]
 346         ldr     r2, =0x00003fff
 347         bic     r1, r1, r2
 348 #ifdef CONFIG_CLK_800_166_66
 349         ldr     r2, =0x00011401
 350 #elif defined(CONFIG_CLK_500_166_66)
 351         ldr     r2, =0x00011201
 352 #elif defined(CONFIG_CLK_666_166_66)
 353         ldr     r2, =0x00011300
 354 #else
 355         ldr     r2, =0x00011301
 356 #endif
 357         orr     r1, r1, r2
 358         str     r1, [r0, #0x300]
 359         ldr     r1, [r0, #0x304]
 360         ldr     r2, =0x00011110
 361         orr     r1, r1, r2
 362         str     r1, [r0, #0x304]
 363         ldr     r1, =0x00000001
 364         str     r1, [r0, #0x308]
 365
 366         /* Set Source Clock */
 367         ldr     r1, =0x00001111                 @ A, M, E, HPLL Muxing
 368         str     r1, [r0, #0x200]                @ S5PC1XX_CLK_SRC0
 369 #endif
 370         b       200f
 371 110:
 372         /* Set Clock divider */
 373         ldr     r1, =0x14131330                 @ 1:1:4:4, 1:4:5
 374         str     r1, [r0, #0x300]
 375         ldr     r1, =0x11110111                 @ UART[3210]: MMC[3210]
 376         str     r1, [r0, #0x310]
 377
 378         /* Set Lock Time */
 379         ldr     r1, =0xe10                      @ Locktime : 0xe10 = 3600
 380         str     r1, [r0, #0x000]                @ S5PC110_APLL_LOCK
 381         str     r1, [r0, #0x010]                @ S5PC110_MPLL_LOCK
 382         str     r1, [r0, #0x018]                @ S5PC110_EPLL_LOCK
 383         str     r1, [r0, #0x020]                @ S5PC110_VPLL_LOCK
 384
 385         /* S5PC110_APLL_CON */
 386         ldr     r1, =0x80C80601                 @ 800MHz
 387         str     r1, [r0, #0x100]
 388         /* S5PC110_MPLL_CON */
 389         ldr     r1, =0x829B0C01                 @ 667MHz
 390         str     r1, [r0, #0x108]
 391         /* S5PC110_EPLL_CON */
 392         ldr     r1, =0x80600602                 @  96MHz VSEL 0 P 6 M 96 S 2
 393         str     r1, [r0, #0x110]
 394         /* S5PC110_VPLL_CON */
 395         ldr     r1, =0x806C0603                 @  54MHz
 396         str     r1, [r0, #0x120]
 397
 398         /* Set Source Clock */
 399         ldr     r1, =0x10001111                 @ A, M, E, VPLL Muxing
 400         str     r1, [r0, #0x200]                @ S5PC1XX_CLK_SRC0
 401
 402         /* OneDRAM(DMC0) clock setting */
 403         ldr     r1, =0x01000000                 @ ONEDRAM_SEL[25:24] 1 SCLKMPLL
 404         str     r1, [r0, #0x218]                @ S5PC110_CLK_SRC6
 405         ldr     r1, =0x30000000                 @ ONEDRAM_RATIO[31:28] 3 + 1
 406         str     r1, [r0, #0x318]                @ S5PC110_CLK_DIV6
 407
 408         /* XCLKOUT = XUSBXTI 24MHz */
 409         add     r2, r0, #0xE000                 @ S5PC110_OTHERS
 410         ldr     r1, [r2]
 411         orr     r1, r1, #(0x3 << 8)             @ CLKOUT[9:8] 3 XUSBXTI
 412         str     r1, [r2]
 413
 414 200:
 415         /* wait at least 200us to stablize all clock */
 416         mov     r2, #0x10000
 417 1:      subs    r2, r2, #1
 418         bne     1b
 419
 420         mov     pc, lr
 421
 422 #ifndef CONFIG_ONENAND_IPL
 423 internal_ram_init:
 424         ldreq   r0, =0xE3800000
 425         ldrne   r0, =0xF1500000
 426         ldr     r1, =0x0
 427         str     r1, [r0]
 428
 429         mov     pc, lr
 430 #endif
 431
 432 #ifndef CONFIG_ONENAND_IPL
 433 /*
 434  * uart_asm_init: Initialize UART's pins
 435  */
 436 uart_asm_init:
 437         /* set GPIO to enable UART0-UART4 */
 438         mov     r0, r8
 439         ldr     r1, =0x22222222
 440         str     r1, [r0, #0x0]                  @S5PC100_GPIO_A0_OFFSET
 441         ldr     r1, =0x00002222
 442         str     r1, [r0, #0x20]                 @S5PC100_GPIO_A1_OFFSET
 443
 444         /* Check S5PC100 */
 445         cmp     r7, r8
 446         bne     110f
 447
 448 #ifndef DEBUG_PM_C110
 449         /* UART_SEL GPK0[5] at S5PC100 */
 450         add     r0, r8, #0x2A0                  @S5PC100_GPIO_K0_OFFSET
 451         ldr     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 452         bic     r1, r1, #(0xf << 20)            @ 20 = 5 * 4-bit
 453         orr     r1, r1, #(0x1 << 20)            @ Output
 454         str     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 455
 456         ldr     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 457         bic     r1, r1, #(0x3 << 10)            @ 10 = 5 * 2-bit
 458         orr     r1, r1, #(0x2 << 10)            @ Pull-up enabled
 459         str     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 460
 461         ldr     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 462         orr     r1, r1, #(1 << 5)               @ 5 = 5 * 1-bit
 463         str     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 464 #endif
 465         b       200f
 466 110:
 467         /*
 468          * Note that the following address
 469          * 0xE020'0360 is reserved address at S5PC100
 470          */
 471         /* UART_SEL MP0_5[7] at S5PC110 */
 472         add     r0, r8, #0x360                  @S5PC110_GPIO_MP0_5_OFFSET
 473         ldr     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 474         bic     r1, r1, #(0xf << 28)            @ 28 = 7 * 4-bit
 475         orr     r1, r1, #(0x1 << 28)            @ Output
 476         str     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 477
 478         ldr     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 479         bic     r1, r1, #(0x3 << 14)            @ 14 = 7 * 2-bit
 480         orr     r1, r1, #(0x2 << 14)            @ Pull-up enabled
 481         str     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 482
 483         ldr     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 484         orr     r1, r1, #(1 << 7)               @ 7 = 7 * 1-bit
 485         str     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 486 200:
 487         mov     pc, lr
 488 #endif