board/samsung/universal/lowlevel_init.S

   1 /*
   2  * Memory Setup stuff - taken from blob memsetup.S
   3  *
   4  * Copyright (C) 2009 Samsung Electronics
   5  * Kyungmin Park <kyungmin.park@samsung.com>
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 #include <config.h>
  27 #include <version.h>
  28 #include <asm/arch/cpu.h>
  29 #include <asm/arch/mem.h>
  30 #include <asm/arch/clock.h>
  31 #include <asm/arch/power.h>
  32 #include <asm/arch/watchdog.h>
  33 #include <asm/arch/interrupt.h>
  34
  35 #define DEBUG_PM_C110
  36 #undef DEBUG_PM_C110
  37
  38 /*
  39  * Register usages:
  40  *
  41  * r5 has zero always
  42  * r7 has S5PC100 GPIO base, 0xE0300000
  43  * r8 has real GPIO base, 0xE0300000, 0xE0200000 at S5PC100, S5PC110 repectively
  44  * r9 has Mobile DDR size, 1 means 1GiB, 2 means 2GiB and so on
  45  */
  46
  47 _TEXT_BASE:
  48         .word   TEXT_BASE
  49
  50         .globl lowlevel_init
  51 lowlevel_init:
  52         mov     r11, lr
  53
  54         /* r5 has always zero */
  55         mov     r5, #0
  56
  57         ldr     r7, =S5PC100_GPIO_BASE
  58         ldr     r8, =S5PC100_GPIO_BASE
  59         /* Read CPU ID */
  60         ldr     r2, =S5PC1XX_PRO_ID
  61         ldr     r0, [r2]
  62         mov     r1, #0x00010000
  63         and     r0, r0, r1
  64         cmp     r0, r5
  65         beq     100f
  66         ldr     r8, =S5PC110_GPIO_BASE
  67 100:
  68         /* Turn on KEY_LED_ON [GPJ4(1)] XMSMWEN */
  69         cmp     r7, r8
  70 #ifndef DEBUG_PM_C110
  71         addeq   r0, r8, #0x280                          @S5PC100_GPIO_J4_OFFSET
  72         addne   r0, r8, #0x2C0                          @S5PC110_GPIO_J4_OFFSET
  73         ldr     r1, [r0, #0x0]                          @S5PC1XX_GPIO_CON_OFFSET
  74         bic     r1, r1, #(0xf << 4)                     @ 1 * 4-bit
  75         orr     r1, r1, #(0x1 << 4)
  76         str     r1, [r0, #0x0]                          @S5PC1XX_GPIO_CON_OFFSET
  77
  78         ldr     r1, [r0, #0x4]                          @S5PC1XX_GPIO_DAT_OFFSET
  79 #ifdef CONFIG_ONENAND_IPL
  80         orr     r1, r1, #(1 << 1)                       @ 1 * 1-bit
  81 #else
  82         bic     r1, r1, #(1 << 1)
  83 #endif
  84         str     r1, [r0, #0x4]                          @S5PC1XX_GPIO_DAT_OFFSET
  85 #endif
  86
  87         /* IO retension release */
  88         ldreq   r0, =S5PC100_OTHERS                     @0xE0108200
  89         ldrne   r0, =S5PC110_OTHERS                     @0xE010E000
  90         ldr     r1, [r0]
  91         ldreq   r2, =(1 << 31)                          @IO_RET_REL
  92         ldrne   r2, =((1 << 31) | (1 << 29) | (1 << 28))        @ GPIO, UART_IO
  93         orr     r1, r1, r2
  94         str     r1, [r0]
  95
  96 #ifndef CONFIG_ONENAND_IPL
  97         /* Disable Watchdog */
  98         ldreq   r0, =S5PC100_WATCHDOG_BASE              @0xEA200000
  99         ldrne   r0, =S5PC110_WATCHDOG_BASE              @0xE2700000
 100         str     r5, [r0]
 101
 102         /* setting SRAM */
 103         ldreq   r0, =S5PC100_SROMC_BASE
 104         ldrne   r0, =S5PC110_SROMC_BASE
 105         ldr     r1, =0x9
 106         str     r1, [r0]
 107 #endif
 108
 109         /* S5PC100 has 3 groups of interrupt sources */
 110         ldreq   r0, =S5PC100_VIC0_BASE                  @0xE4000000
 111         ldrne   r0, =S5PC110_VIC0_BASE                  @0xF2000000
 112         add     r1, r0, #0x00100000
 113         add     r2, r0, #0x00200000
 114
 115         /* Disable all interrupts (VIC0, VIC1 and VIC2) */
 116         mvn     r3, #0x0
 117         str     r3, [r0, #VIC_INTENCLEAR_OFFSET]
 118         str     r3, [r1, #VIC_INTENCLEAR_OFFSET]
 119         str     r3, [r2, #VIC_INTENCLEAR_OFFSET]
 120
 121 #ifndef CONFIG_ONENAND_IPL
 122         /* Set all interrupts as IRQ */
 123         str     r5, [r0, #VIC_INTSELECT_OFFSET]
 124         str     r5, [r1, #VIC_INTSELECT_OFFSET]
 125         str     r5, [r2, #VIC_INTSELECT_OFFSET]
 126
 127         /* Pending Interrupt Clear */
 128         str     r5, [r0, #VIC_INTADDRESS_OFFSET]
 129         str     r5, [r1, #VIC_INTADDRESS_OFFSET]
 130         str     r5, [r2, #VIC_INTADDRESS_OFFSET]
 131 #endif
 132
 133 #ifndef CONFIG_ONENAND_IPL
 134         /* for UART */
 135         bl      uart_asm_init
 136
 137         bl      internal_ram_init
 138 #endif
 139
 140 #ifdef CONFIG_ONENAND_IPL
 141         /* init system clock */
 142         bl      system_clock_init
 143
 144         /* Board detection to set proper memory configuration */
 145         cmp     r7, r8
 146         moveq   r9, #1          /* r9 has 1Gib default at s5pc100 */
 147         movne   r9, #2          /* r9 has 2Gib default at s5pc110 */
 148         /* FIXME 1Gib detection: Limo Universal */
 149         /* Check Limo Real board
 150          *      LR (suspend)    LU              J1B2
 151          * 0x04 0x01 (0x01)     0x01 (0x01)     0x01 (0x01)
 152          * 0x24 0x28 (0xA8)     0x28 (0x6A)     0x1C (0x1C)
 153          * 0x44 0x00 (0xC7)     0x00 (0x47)     0x00 (0x47)
 154          * 0x64 0x03 (0x1F)     0x07 (0x1F)     0x0f (0x0F)
 155          *
 156          * Check (0 << 3) at 0x64 at boot
 157          * Check 0x47 at 0x44 at suspend
 158          */
 159         ldrne   r2, =0xE0200C00
 160         ldrne   r1, [r2, #0x64]
 161         and     r1, r1, #(1 << 2)
 162         cmp     r1, #(1 << 2)
 163         moveq   r9, #1
 164         ldr     r1, [r2, #0x44]
 165         cmp     r1, #0x47
 166         moveq   r9, #1
 167         /*
 168          * Aquila Rev 0.5 : 4G3G1G x16 for Infineon ES3.1
 169          * Aquila Rev 0.6 : 4G1G1G x32 for MSM6290
 170          * Aquila Rev 0.7 : 4G3G1G x16 for Infineon ES3.1
 171          * Aquila Rev 0.8 : 4G3G1G x16 for Infineon ES3.1
 172          */
 173         ldr     r2, =0xE0200200
 174         ldr     r4, [r2, #0x48]
 175         bic     r1, r4, #(0xFF << 2)    /* PULLUP_DISABLE: 4 * 2-bit */
 176         str     r1, [r2, #0x48]
 177         /* For write completion */
 178         nop
 179         nop
 180
 181         ldr     r3, [r2, #0x44]
 182         and     r1, r3, #(0xf << 1)
 183         cmp     r1, #(0x5 << 2)
 184         moveq   r9, #3
 185         cmp     r1, #(0x6 << 2)
 186         moveq   r9, #1
 187         cmp     r1, #(0x7 << 2)
 188         moveq   r9, #3
 189         cmp     r1, #(0x1 << 1)
 190         moveq   r9, #3
 191         str     r4, [r2, #0x48]         /* Restore PULLUP configuration */
 192
 193         bl      mem_ctrl_asm_init
 194
 195         /* OneNAND Sync Read Support at S5PC110 only
 196          * RM[15]       : Sync Read
 197          * BRWL[14:12]  : 7 CLK
 198          * BL[11:9]     : Continuous
 199          * VHF[3]       : Very High Frequency Enable (Over 83MHz)
 200          * HF[2]        : High Frequency Enable (Over 66MHz)
 201          */
 202         cmp     r7, r8
 203         ldrne   r1, =0xE00C
 204
 205         ldrne   r0, =0xB001E442
 206         strneh  r1, [r0]
 207
 208         ldrne   r0, =0xB0600000
 209         strne   r1, [r0, #0x100]                        @ ONENAND_IF_CTRL
 210
 211         /* Wakeup support. Don't know if it's going to be used, untested. */
 212         ldreq   r0, =S5PC100_RST_STAT
 213         ldrne   r0, =S5PC110_RST_STAT
 214         ldr     r1, [r0]
 215         biceq   r1, r1, #0xfffffff7
 216         moveq   r2, #(1 << 3)
 217         bicne   r1, r1, #0xfffeffff
 218         movne   r2, #(1 << 16)
 219         cmp     r1, r2
 220         bne     1f
 221 wakeup:
 222 #ifdef DEBUG_PM_C110
 223         mov     r0, r8
 224         ldr     r1, =0x22222222
 225         str     r1, [r0, #0x0]                  @S5PC100_GPIO_A0_OFFSET
 226         ldr     r1, =0x00002222
 227         str     r1, [r0, #0x20]                 @S5PC100_GPIO_A1_OFFSET
 228
 229         /* UART_SEL MP0_5[7] at S5PC110 */
 230         add     r0, r8, #0x360                  @S5PC110_GPIO_MP0_5_OFFSET
 231         ldr     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 232         bic     r1, r1, #(0xf << 28)            @ 28 = 7 * 4-bit
 233         orr     r1, r1, #(0x1 << 28)            @ Output
 234         str     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 235
 236         ldr     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 237         bic     r1, r1, #(0x3 << 14)            @ 14 = 7 * 2-bit
 238         orr     r1, r1, #(0x2 << 14)            @ Pull-up enabled
 239         str     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 240
 241         ldr     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 242         orr     r1, r1, #(1 << 7)               @ 7 = 7 * 1-bit
 243         str     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 244
 245         ldr     r0, =0xE2900000                 @ S5PC110_PA_UART
 246         orr     r0, r0, #0x800
 247         mov     r1, #0x3
 248         str     r1, [r0, #0x000]                @ ULCON
 249         ldr     r1, =0x245
 250         str     r1, [r0, #0x004]                @ UCON
 251         mov     r1, #0x23
 252         str     r1, [r0, #0x028]                @ UBRDIV
 253         mov     r1, #0x3
 254         str     r1, [r0, #0x02C]                @ UDIVSLOT
 255
 256         mov     r2, #'W'
 257         strb    r2, [r0, #0x020]                @ UTXH
 258 1001:
 259         ldrb    r3, [r0, #0x010]                @ UTRSTAT
 260         tst     r3, #(1 << 2)
 261         beq     1001b
 262 #endif
 263
 264         /* turn off L2 cache */
 265         bl      l2_cache_disable
 266
 267         cmp     r7, r8
 268         ldreq   r0, =0xC100
 269         ldrne   r0, =0xC110
 270
 271         /* invalidate L2 cache also */
 272         bl      invalidate_dcache
 273
 274         /* turn on L2 cache */
 275         bl      l2_cache_enable
 276
 277         cmp     r7, r8
 278         /* Load return address and jump to kernel */
 279         ldreq   r0, =S5PC100_INFORM0
 280         ldrne   r0, =S5PC110_INFORM0
 281
 282         /* r1 = physical address of s5pc1xx_cpu_resume function */
 283         ldr     r1, [r0]
 284
 285         /* Jump to kernel (sleep-s5pc1xx.S) */
 286         mov     pc, r1
 287         nop
 288         nop
 289 #else
 290         cmp     r7, r8
 291         /* Clear wakeup status register */
 292         ldreq   r0, =S5PC100_WAKEUP_STAT
 293         ldrne   r0, =S5PC110_WAKEUP_STAT
 294         ldr     r1, [r0]
 295         str     r1, [r0]
 296 #endif
 297 1:
 298         mov     lr, r11
 299         mov     pc, lr
 300
 301 /*
 302  * system_clock_init: Initialize core clock and bus clock.
 303  * void system_clock_init(void)
 304  */
 305 system_clock_init:
 306         ldr     r0, =S5PC1XX_CLOCK_BASE         @ 0xE0100000
 307
 308         /* Check S5PC100 */
 309         cmp     r7, r8
 310         bne     110f
 311 100:
 312 #ifndef DEBUG_PM_C110
 313         /* Set Lock Time */
 314         ldr     r1, =0xe10                      @ Locktime : 0xe10 = 3600
 315         str     r1, [r0, #0x000]                @ S5PC100_APLL_LOCK
 316         str     r1, [r0, #0x004]                @ S5PC100_MPLL_LOCK
 317         str     r1, [r0, #0x008]                @ S5PC100_EPLL_LOCK
 318         str     r1, [r0, #0x00C]                @ S5PC100_HPLL_LOCK
 319
 320         /* S5P_APLL_CON */
 321 #ifdef CONFIG_CLK_667_166_83
 322         ldr     r1, =0x81bc0400         @ SDIV 0, PDIV 4, MDIV 444 (1333MHz)
 323 #elif defined(CONFIG_CLK_666_166_66)
 324         ldr     r1, =0x814d0301         @ SDIV 1, PDIV 3, MDIV 333 (1333MHz)
 325 #elif defined(CONFIG_CLK_600_150_75)
 326         ldr     r1, =0x812C0300         @ SDIV 0, PDIV 3, MDIV 300 (1200MHz)
 327 #elif defined(CONFIG_CLK_533_133_66)
 328         ldr     r1, =0x810b0300         @ SDIV 0, PDIV 3, MDIV 267 (1066MHz)
 329 #elif defined(CONFIG_CLK_500_166_66)
 330         ldr     r1, =0x81f40301         @ SDIV 1, PDIV 3, MDIV 500 (1000MHz)
 331 #elif defined(CONFIG_CLK_467_117_59)
 332         ldr     r1, =0x826E0401         @ SDIV 1, PDIV 4, MDIV 622 (933MHz)
 333 #elif defined(CONFIG_CLK_400_100_50)
 334         ldr     r1, =0x81900301         @ SDIV 1, PDIV 3, MDIV 400 (800MHz)
 335 #else
 336 #error you should set the correct clock configuration
 337 #endif
 338         str     r1, [r0, #0x100]
 339         /* S5P_MPLL_CON */
 340         ldr     r1, =0x80590201         @ SDIV 1, PDIV 2, MDIV 89 (267MHz)
 341         str     r1, [r0, #0x104]
 342         /* S5P_EPLL_CON */
 343         ldr     r1, =0x80870303         @ SDIV 3, PDIV 3, MDIV 135 (67.5MHz)
 344         str     r1, [r0, #0x108]
 345         /* S5P_HPLL_CON */
 346         ldr     r1, =0x80600603         @ SDIV 3, PDIV 6, MDIV 96
 347         str     r1, [r0, #0x10C]
 348
 349         ldr     r1, [r0, #0x300]
 350         ldr     r2, =0x00003fff
 351         bic     r1, r1, r2
 352 #ifdef CONFIG_CLK_800_166_66
 353         ldr     r2, =0x00011401
 354 #elif defined(CONFIG_CLK_500_166_66)
 355         ldr     r2, =0x00011201
 356 #elif defined(CONFIG_CLK_666_166_66)
 357         ldr     r2, =0x00011300
 358 #else
 359         ldr     r2, =0x00011301
 360 #endif
 361         orr     r1, r1, r2
 362         str     r1, [r0, #0x300]
 363         ldr     r1, [r0, #0x304]
 364         ldr     r2, =0x00011110
 365         orr     r1, r1, r2
 366         str     r1, [r0, #0x304]
 367         ldr     r1, =0x00000001
 368         str     r1, [r0, #0x308]
 369
 370         /* Set Source Clock */
 371         ldr     r1, =0x00001111                 @ A, M, E, HPLL Muxing
 372         str     r1, [r0, #0x200]                @ S5PC1XX_CLK_SRC0
 373 #endif
 374         b       200f
 375 110:
 376         /* Set Clock divider */
 377         ldr     r1, =0x14131330                 @ 1:1:4:4, 1:4:5
 378         str     r1, [r0, #0x300]
 379         ldr     r1, =0x11110111                 @ UART[3210]: MMC[3210]
 380         str     r1, [r0, #0x310]
 381
 382         /* Set Lock Time */
 383         ldr     r1, =0xe10                      @ Locktime : 0xe10 = 3600
 384         str     r1, [r0, #0x000]                @ S5PC110_APLL_LOCK
 385         str     r1, [r0, #0x010]                @ S5PC110_MPLL_LOCK
 386         str     r1, [r0, #0x018]                @ S5PC110_EPLL_LOCK
 387         str     r1, [r0, #0x020]                @ S5PC110_VPLL_LOCK
 388
 389         /* S5PC110_APLL_CON */
 390         ldr     r1, =0x80C80601                 @ 800MHz
 391         str     r1, [r0, #0x100]
 392         /* S5PC110_MPLL_CON */
 393         ldr     r1, =0x829B0C01                 @ 667MHz
 394         str     r1, [r0, #0x108]
 395         /* S5PC110_EPLL_CON */
 396         ldr     r1, =0x80600602                 @  96MHz VSEL 0 P 6 M 96 S 2
 397         str     r1, [r0, #0x110]
 398         /* S5PC110_VPLL_CON */
 399         ldr     r1, =0x806C0603                 @  54MHz
 400         str     r1, [r0, #0x120]
 401
 402         /* Set Source Clock */
 403         ldr     r1, =0x10001111                 @ A, M, E, VPLL Muxing
 404         str     r1, [r0, #0x200]                @ S5PC1XX_CLK_SRC0
 405
 406         /* OneDRAM(DMC0) clock setting */
 407         ldr     r1, =0x01000000                 @ ONEDRAM_SEL[25:24] 1 SCLKMPLL
 408         str     r1, [r0, #0x218]                @ S5PC110_CLK_SRC6
 409         ldr     r1, =0x30000000                 @ ONEDRAM_RATIO[31:28] 3 + 1
 410         str     r1, [r0, #0x318]                @ S5PC110_CLK_DIV6
 411
 412         /* XCLKOUT = XUSBXTI 24MHz */
 413         add     r2, r0, #0xE000                 @ S5PC110_OTHERS
 414         ldr     r1, [r2]
 415         orr     r1, r1, #(0x3 << 8)             @ CLKOUT[9:8] 3 XUSBXTI
 416         str     r1, [r2]
 417
 418         /* CLK_IP0 */
 419         ldr     r1, =0x8fefeeb                  @ DMC[1:0] PDMA0[3] IMEM[5]
 420         str     r1, [r0, #0x460]                @ S5PC110_CLK_IP0
 421
 422         /* CLK_IP1 */
 423         ldr     r1, =0xe9fdf0f9                 @ FIMD[0] USBOTG[16]
 424                                                 @ NANDXL[24]
 425         str     r1, [r0, #0x464]                @ S5PC110_CLK_IP1
 426
 427         /* CLK_IP2 */
 428         ldr     r1, =0xf75f7fc                  @ CORESIGHT[8] MODEM[9]
 429                                                 @ HOSTIF[10] HSMMC0[16]
 430                                                 @ HSMMC2[18] VIC[27:24]
 431         str     r1, [r0, #0x468]                @ S5PC110_CLK_IP2
 432
 433         /* CLK_IP3 */
 434         ldr     r1, =0x8edb000c                 @ SYSTIMER[16] UART0[17]
 435                                                 @ UART2[19] UART3[20] WDT[22]
 436                                                 @ PWM[23] GPIO[26] SYSCON[27]
 437         str     r1, [r0, #0x46c]                @ S5PC110_CLK_IP3
 438
 439         /* CLK_IP4 */
 440         ldr     r1, =0xfffffff1                 @ CHIP_ID[0] TZPC[8:5]
 441         str     r1, [r0, #0x470]                @ S5PC110_CLK_IP3
 442
 443 200:
 444         /* wait at least 200us to stablize all clock */
 445         mov     r2, #0x10000
 446 1:      subs    r2, r2, #1
 447         bne     1b
 448
 449         mov     pc, lr
 450
 451 #ifndef CONFIG_ONENAND_IPL
 452 internal_ram_init:
 453         ldreq   r0, =0xE3800000
 454         ldrne   r0, =0xF1500000
 455         ldr     r1, =0x0
 456         str     r1, [r0]
 457
 458         mov     pc, lr
 459 #endif
 460
 461 #ifndef CONFIG_ONENAND_IPL
 462 /*
 463  * uart_asm_init: Initialize UART's pins
 464  */
 465 uart_asm_init:
 466         /* set GPIO to enable UART0-UART4 */
 467         mov     r0, r8
 468         ldr     r1, =0x22222222
 469         str     r1, [r0, #0x0]                  @S5PC100_GPIO_A0_OFFSET
 470         ldr     r1, =0x00002222
 471         str     r1, [r0, #0x20]                 @S5PC100_GPIO_A1_OFFSET
 472
 473         /* Check S5PC100 */
 474         cmp     r7, r8
 475         bne     110f
 476
 477 #ifndef DEBUG_PM_C110
 478         /* UART_SEL GPK0[5] at S5PC100 */
 479         add     r0, r8, #0x2A0                  @S5PC100_GPIO_K0_OFFSET
 480         ldr     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 481         bic     r1, r1, #(0xf << 20)            @ 20 = 5 * 4-bit
 482         orr     r1, r1, #(0x1 << 20)            @ Output
 483         str     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 484
 485         ldr     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 486         bic     r1, r1, #(0x3 << 10)            @ 10 = 5 * 2-bit
 487         orr     r1, r1, #(0x2 << 10)            @ Pull-up enabled
 488         str     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 489
 490         ldr     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 491         orr     r1, r1, #(1 << 5)               @ 5 = 5 * 1-bit
 492         str     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 493 #endif
 494         b       200f
 495 110:
 496         /*
 497          * Note that the following address
 498          * 0xE020'0360 is reserved address at S5PC100
 499          */
 500         /* UART_SEL MP0_5[7] at S5PC110 */
 501         add     r0, r8, #0x360                  @S5PC110_GPIO_MP0_5_OFFSET
 502         ldr     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 503         bic     r1, r1, #(0xf << 28)            @ 28 = 7 * 4-bit
 504         orr     r1, r1, #(0x1 << 28)            @ Output
 505         str     r1, [r0, #0x0]                  @S5PC1XX_GPIO_CON_OFFSET
 506
 507         ldr     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 508         bic     r1, r1, #(0x3 << 14)            @ 14 = 7 * 2-bit
 509         orr     r1, r1, #(0x2 << 14)            @ Pull-up enabled
 510         str     r1, [r0, #0x8]                  @S5PC1XX_GPIO_PULL_OFFSET
 511
 512         ldr     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 513         orr     r1, r1, #(1 << 7)               @ 7 = 7 * 1-bit
 514         str     r1, [r0, #0x4]                  @S5PC1XX_GPIO_DAT_OFFSET
 515 200:
 516         mov     pc, lr
 517 #endif