binutils/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR(ar.c)
   6
   7 AC_CANONICAL_TARGET
   8 AC_ISC_POSIX
   9
  10 changequote(,)dnl
  11 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  12 changequote([,])dnl
  13 AM_INIT_AUTOMAKE(binutils, ${BFD_VERSION})
  14
  15 AC_PROG_CC
  16 AC_GNU_SOURCE
  17 AC_USE_SYSTEM_EXTENSIONS
  18
  19 ACX_LARGEFILE
  20 LT_INIT
  21
  22 AC_ARG_ENABLE(targets,
  23 [  --enable-targets        alternative target configurations],
  24 [case "${enableval}" in
  25   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  26             ;;
  27   no)       enable_targets= ;;
  28   *)        enable_targets=$enableval ;;
  29 esac])dnl
  30
  31 AM_BINUTILS_WARNINGS
  32
  33 AC_CONFIG_HEADERS(config.h:config.in)
  34
  35 if test -z "$target" ; then
  36     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  37 fi
  38 if test -z "$host" ; then
  39     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  40 fi
  41
  42 AC_PROG_YACC
  43 AM_PROG_LEX
  44
  45 ALL_LINGUAS="da es fi fr id ja ro ru rw sk sv tr uk vi zh_CN zh_TW"
  46 ZW_GNU_GETTEXT_SISTER_DIR
  47 AM_PO_SUBDIRS
  48
  49 AM_MAINTAINER_MODE
  50 AM_CONDITIONAL(GENINSRC_NEVER, false)
  51 AC_EXEEXT
  52 if test -n "$EXEEXT"; then
  53   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
  54             [Does the platform use an executable suffix?])
  55 fi
  56 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
  57                    [Suffix used for executables, if any.])
  58
  59 # host-specific stuff:
  60
  61 HDEFINES=
  62
  63 . ${srcdir}/../bfd/configure.host
  64
  65 AC_SUBST(HDEFINES)
  66 AR=${AR-ar}
  67 AC_SUBST(AR)
  68 AC_PROG_RANLIB
  69 AC_PROG_INSTALL
  70
  71 BFD_CC_FOR_BUILD
  72
  73 DEMANGLER_NAME=c++filt
  74 case "${host}" in
  75   *-*-go32* | *-*-msdos*)
  76     DEMANGLER_NAME=cxxfilt
  77 esac
  78 AC_SUBST(DEMANGLER_NAME)
  79
  80 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h fcntl.h sys/file.h limits.h sys/param.h)
  81 AC_HEADER_SYS_WAIT
  82 AC_FUNC_ALLOCA
  83 AC_CHECK_FUNCS(sbrk utimes setmode getc_unlocked strcoll)
  84 AC_CHECK_FUNC([mkstemp],
  85               AC_DEFINE([HAVE_MKSTEMP], 1,
  86               [Define to 1 if you have the `mkstemp' function.]))
  87 AC_CHECK_FUNC([mkdtemp],
  88               AC_DEFINE([HAVE_MKDTEMP], 1,
  89               [Define to 1 if you have the `mkdtemp' function.]))
  90
  91 # Check whether fopen64 is available and whether _LARGEFILE64_SOURCE
  92 # needs to be defined for it
  93 AC_MSG_CHECKING([for fopen64])
  94 AC_CACHE_VAL(bu_cv_have_fopen64,
  95 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <stdio.h>], [FILE *f = fopen64 ("/tmp/foo","r");])],
  96 bu_cv_have_fopen64=yes,
  97 [saved_CPPFLAGS=$CPPFLAGS
  98  CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
  99  AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <stdio.h>], [FILE *f = fopen64 ("/tmp/foo","r");])],
 100  bu_cv_have_fopen64="need -D_LARGEFILE64_SOURCE",
 101  bu_cv_have_fopen64=no)
 102  CPPFLAGS=$saved_CPPFLAGS])])
 103 AC_MSG_RESULT($bu_cv_have_fopen64)
 104 if test "$bu_cv_have_fopen64" != no; then
 105   AC_DEFINE([HAVE_FOPEN64], 1,
 106             [Is fopen64 available?])
 107 fi
 108 AC_MSG_CHECKING([for stat64])
 109 AC_CACHE_VAL(bu_cv_have_stat64,
 110 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/stat.h>], [struct stat64 st; stat64 ("/tmp/foo", &st);])],
 111 bu_cv_have_stat64=yes,
 112 [saved_CPPFLAGS=$CPPFLAGS
 113  CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
 114  AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/stat.h>], [struct stat64 st; stat64 ("/tmp/foo", &st);])],
 115  bu_cv_have_stat64="need -D_LARGEFILE64_SOURCE",
 116  bu_cv_have_stat64=no)
 117  CPPFLAGS=$saved_CPPFLAGS])])
 118 AC_MSG_RESULT($bu_cv_have_stat64)
 119 if test "$bu_cv_have_stat64" != no; then
 120   AC_DEFINE([HAVE_STAT64], 1,
 121             [Is stat64 available?])
 122 fi
 123 if test "$bu_cv_have_fopen64" = "need -D_LARGEFILE64_SOURCE" \
 124    || test "$bu_cv_have_stat64" = "need -D_LARGEFILE64_SOURCE"; then
 125   AC_DEFINE([_LARGEFILE64_SOURCE], 1,
 126             [Enable LFS])
 127   CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
 128 fi
 129
 130 # Some systems have frexp only in -lm, not in -lc.
 131 AC_SEARCH_LIBS(frexp, m)
 132
 133 AC_MSG_CHECKING(for time_t in time.h)
 134 AC_CACHE_VAL(bu_cv_decl_time_t_time_h,
 135 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>], [time_t i;])],
 136 bu_cv_decl_time_t_time_h=yes, bu_cv_decl_time_t_time_h=no)])
 137 AC_MSG_RESULT($bu_cv_decl_time_t_time_h)
 138 if test $bu_cv_decl_time_t_time_h = yes; then
 139   AC_DEFINE([HAVE_TIME_T_IN_TIME_H], 1,
 140             [Is the type time_t defined in <time.h>?])
 141 fi
 142
 143 AC_MSG_CHECKING(for time_t in sys/types.h)
 144 AC_CACHE_VAL(bu_cv_decl_time_t_types_h,
 145 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>], [time_t i;])],
 146 bu_cv_decl_time_t_types_h=yes, bu_cv_decl_time_t_types_h=no)])
 147 AC_MSG_RESULT($bu_cv_decl_time_t_types_h)
 148 if test $bu_cv_decl_time_t_types_h = yes; then
 149   AC_DEFINE([HAVE_TIME_T_IN_TYPES_H], 1,
 150             [Is the type time_t defined in <sys/types.h>?])
 151 fi
 152
 153 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 154 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 155 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 156 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 157 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 158 if test $bu_cv_decl_getopt_unistd_h = yes; then
 159   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 160             [Is the prototype for getopt in <unistd.h> in the expected format?])
 161 fi
 162
 163 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 164 # by default.
 165 AC_MSG_CHECKING([for utime.h])
 166 AC_CACHE_VAL(bu_cv_header_utime_h,
 167 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 168 #ifdef HAVE_TIME_H
 169 #include <time.h>
 170 #endif
 171 #include <utime.h>],
 172 [struct utimbuf s;])],
 173 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 174 AC_MSG_RESULT($bu_cv_header_utime_h)
 175 if test $bu_cv_header_utime_h = yes; then
 176   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 177 fi
 178
 179 AC_CHECK_DECLS([fprintf, stpcpy, strstr, sbrk, getenv, environ, getc_unlocked,
 180                 snprintf, vsnprintf])
 181
 182 # Link in zlib if we can.  This allows us to read compressed debug
 183 # sections.  This is used only by readelf.c (objdump uses bfd for
 184 # reading compressed sections).
 185 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 186
 187 BFD_BINARY_FOPEN
 188
 189 # target-specific stuff:
 190
 191 # Canonicalize the secondary target names.
 192 if test -n "$enable_targets"; then
 193     for targ in `echo $enable_targets | sed 's/,/ /g'`
 194     do
 195         result=`$ac_config_sub $targ 2>/dev/null`
 196         if test -n "$result"; then
 197             canon_targets="$canon_targets $result"
 198         else
 199             # Allow targets that config.sub doesn't recognize, like "all".
 200             canon_targets="$canon_targets $targ"
 201         fi
 202     done
 203 fi
 204
 205 AC_CHECK_HEADER(iconv.h)
 206 AM_ICONV
 207
 208 all_targets=false
 209 BUILD_NLMCONV=
 210 NLMCONV_DEFS=
 211 BUILD_SRCONV=
 212 BUILD_DLLTOOL=
 213 DLLTOOL_DEFS=
 214 DLLTOOL_DEFAULT=
 215 BUILD_WINDRES=
 216 BUILD_WINDMC=
 217 BUILD_DLLWRAP=
 218 BUILD_MISC=
 219 BUILD_INSTALL_MISC=
 220 OBJDUMP_DEFS=
 221
 222 for targ in $target $canon_targets
 223 do
 224     if test "x$targ" = "xall"; then
 225         all_targets=true
 226         BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 227         BUILD_SRCONV='$(SRCONV_PROG)'
 228         NLMCONV_DEFS="-DNLMCONV_I386 -DNLMCONV_ALPHA -DNLMCONV_POWERPC -DNLMCONV_SPARC"
 229         BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 230         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 231         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 232         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 233         if test -z "$DLLTOOL_DEFAULT"; then
 234           DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 235         fi
 236         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 237         BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 238     else
 239         case $targ in
 240 changequote(,)dnl
 241         i[3-7]86*-*-netware*)
 242 changequote([,])dnl
 243           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 244           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_I386"
 245           ;;
 246         alpha*-*-netware*)
 247           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 248           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_ALPHA"
 249           ;;
 250         powerpc*-*-netware*)
 251           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 252           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_POWERPC"
 253           ;;
 254         sparc*-*-netware*)
 255           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 256           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_SPARC"
 257           ;;
 258         esac
 259         case $targ in
 260         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 261         esac
 262         case $targ in
 263         arm-epoc-pe*)
 264           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 265           if test -z "$DLLTOOL_DEFAULT"; then
 266             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_EPOC"
 267           fi
 268           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_EPOC -DDLLTOOL_ARM"
 269           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 270           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 271           ;;
 272         arm-wince-pe* | arm-*-wince | arm*-*-cegcc* | arm*-*-mingw32ce*)
 273           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 274           if test -z "$DLLTOOL_DEFAULT"; then
 275             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_WINCE"
 276           fi
 277           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_WINCE -DDLLTOOL_ARM"
 278           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 279           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 280           ;;
 281         arm-*-pe*)
 282           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 283           if test -z "$DLLTOOL_DEFAULT"; then
 284             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 285           fi
 286           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 287           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 288           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 289           ;;
 290         thumb-*-pe*)
 291           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 292           if test -z "$DLLTOOL_DEFAULT"; then
 293             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 294           fi
 295           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 296           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 297           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 298           ;;
 299         x86_64-*-mingw*)
 300           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 301           if test -z "$DLLTOOL_DEFAULT"; then
 302             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MX86_64"
 303           fi
 304           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MX86_64"
 305           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 306           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 307           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 308           ;;
 309 changequote(,)dnl
 310         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32** | i[3-7]86-*-netbsdpe*)
 311 changequote([,])dnl
 312           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 313           if test -z "$DLLTOOL_DEFAULT"; then
 314             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 315           fi
 316           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 317           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 318           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 319           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 320           ;;
 321 changequote(,)dnl
 322         i[3-7]86-*-interix)
 323 changequote([,])dnl
 324           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 325           if test -z "$DLLTOOL_DEFAULT"; then
 326             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 327           fi
 328           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 329           ;;
 330 changequote(,)dnl
 331         powerpc*-aix5.[01])
 332 changequote([,])dnl
 333           ;;
 334 changequote(,)dnl
 335         powerpc*-aix[5-9].*)
 336 changequote([,])dnl
 337           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 338           ;;
 339         powerpc*-*-pe* | powerpc*-*-cygwin*)
 340           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 341           if test -z "$DLLTOOL_DEFAULT"; then
 342             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_PPC"
 343           fi
 344           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_PPC"
 345           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 346           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 347           ;;
 348         powerpc*-*-linux* | powerpc*-*-elf* | powerpc*-*-eabi*)
 349           BUILD_INSTALL_MISC="${BUILD_INSTALL_MISC} embedspu"
 350           ;;
 351         sh*-*-pe)
 352           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 353           if test -z "$DLLTOOL_DEFAULT"; then
 354             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_SH"
 355           fi
 356           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 357           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 358           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 359           ;;
 360         spu-*-*)
 361           BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 362           ;;
 363         mips*-*-pe)
 364           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 365           if test -z "$DLLTOOL_DEFAULT"; then
 366             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MIPS"
 367           fi
 368           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 369           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 370           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 371           ;;
 372         mcore-*-pe)
 373           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 374           if test -z "$DLLTOOL_DEFAULT"; then
 375             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE"
 376           fi
 377           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 378           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 379           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 380           ;;
 381         mcore-*-elf)
 382           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 383           if test -z "$DLLTOOL_DEFAULT"; then
 384             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE_ELF"
 385           fi
 386           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 387           ;;
 388         mep-*)
 389           OBJDUMP_DEFS="-DSKIP_ZEROES=256 -DSKIP_ZEROES_AT_END=0"
 390           ;;
 391         esac
 392     fi
 393 done
 394
 395 DLLTOOL_DEFS="$DLLTOOL_DEFS $DLLTOOL_DEFAULT"
 396
 397 if test "${with_windres+set}" = set; then
 398           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 399 fi
 400
 401 if test "${with_windmc+set}" = set; then
 402           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 403 fi
 404
 405 AC_SUBST(NLMCONV_DEFS)
 406 AC_SUBST(BUILD_NLMCONV)
 407 AC_SUBST(BUILD_SRCONV)
 408 AC_SUBST(BUILD_DLLTOOL)
 409 AC_SUBST(DLLTOOL_DEFS)
 410 AC_SUBST(BUILD_WINDRES)
 411 AC_SUBST(BUILD_WINDMC)
 412 AC_SUBST(BUILD_DLLWRAP)
 413 AC_SUBST(BUILD_MISC)
 414 AC_SUBST(BUILD_INSTALL_MISC)
 415 AC_SUBST(OBJDUMP_DEFS)
 416
 417 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 418
 419 targ=$target
 420 . $srcdir/../bfd/config.bfd
 421 if test "x$targ_underscore" = "xyes"; then
 422     UNDERSCORE=1
 423 else
 424     UNDERSCORE=0
 425 fi
 426 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 427  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 428
 429 # Emulation
 430 targ=$target
 431 . ${srcdir}/configure.tgt
 432 EMULATION=$targ_emul
 433 EMULATION_VECTOR=$targ_emul_vector
 434
 435 AC_SUBST(EMULATION)
 436 AC_SUBST(EMULATION_VECTOR)
 437
 438 # Required for html and install-html
 439 AC_SUBST(datarootdir)
 440 AC_SUBST(docdir)
 441 AC_SUBST(htmldir)
 442 AC_SUBST(pdfdir)
 443
 444 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 445 AC_OUTPUT