binutils/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR(ar.c)
   6
   7 AC_CANONICAL_TARGET
   8 AC_ISC_POSIX
   9
  10 changequote(,)dnl
  11 BFD_VERSION=`${srcdir}/../bfd/configure --version | sed -n -e '1s,.* ,,p'`
  12 changequote([,])dnl
  13 AM_INIT_AUTOMAKE(binutils, ${BFD_VERSION})
  14
  15 AC_PROG_CC
  16 AC_GNU_SOURCE
  17 AC_USE_SYSTEM_EXTENSIONS
  18
  19 ACX_LARGEFILE
  20 LT_INIT
  21
  22 AC_ARG_ENABLE(targets,
  23 [  --enable-targets        alternative target configurations],
  24 [case "${enableval}" in
  25   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  26             ;;
  27   no)       enable_targets= ;;
  28   *)        enable_targets=$enableval ;;
  29 esac])dnl
  30
  31 AC_ARG_ENABLE(deterministic-archives,
  32 [AS_HELP_STRING([--enable-deterministic-archives],
  33                 [ar and ranlib default to -D behavior])], [
  34 if test "${enableval}" = no; then
  35   default_ar_deterministic=0
  36 else
  37   default_ar_deterministic=1
  38 fi], [default_ar_deterministic=0])
  39
  40 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  41                    [Should ar and ranlib use -D behavior by default?])
  42
  43 AM_BINUTILS_WARNINGS
  44
  45 AC_CONFIG_HEADERS(config.h:config.in)
  46
  47 AH_VERBATIM([00_CONFIG_H_CHECK],
  48 [/* Check that config.h is #included before system headers
  49    (this works only for glibc, but that should be enough).  */
  50 #if defined(__GLIBC__)
  51 #  error config.h must be #included before system headers
  52 #endif])
  53
  54 if test -z "$target" ; then
  55     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  56 fi
  57 if test -z "$host" ; then
  58     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  59 fi
  60
  61 AC_PROG_YACC
  62 AM_PROG_LEX
  63
  64 ALL_LINGUAS="bg da es fi fr id it ja ro ru rw sk sv tr uk vi zh_CN zh_TW hr"
  65 ZW_GNU_GETTEXT_SISTER_DIR
  66 AM_PO_SUBDIRS
  67
  68 AM_MAINTAINER_MODE
  69 AM_CONDITIONAL(GENINSRC_NEVER, false)
  70 AC_EXEEXT
  71 if test -n "$EXEEXT"; then
  72   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
  73             [Does the platform use an executable suffix?])
  74 fi
  75 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
  76                    [Suffix used for executables, if any.])
  77
  78 # host-specific stuff:
  79
  80 HDEFINES=
  81
  82 . ${srcdir}/../bfd/configure.host
  83
  84 AC_SUBST(HDEFINES)
  85 AR=${AR-ar}
  86 AC_SUBST(AR)
  87 AC_PROG_RANLIB
  88 AC_PROG_INSTALL
  89
  90 BFD_CC_FOR_BUILD
  91
  92 DEMANGLER_NAME=c++filt
  93 case "${host}" in
  94   *-*-go32* | *-*-msdos*)
  95     DEMANGLER_NAME=cxxfilt
  96 esac
  97 AC_SUBST(DEMANGLER_NAME)
  98
  99 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h fcntl.h sys/file.h limits.h locale.h sys/param.h wchar.h)
 100 AC_HEADER_SYS_WAIT
 101 ACX_HEADER_STRING
 102 AC_FUNC_ALLOCA
 103 AC_CHECK_FUNCS(sbrk utimes setmode getc_unlocked strcoll setlocale)
 104 AC_CHECK_FUNC([mkstemp],
 105               AC_DEFINE([HAVE_MKSTEMP], 1,
 106               [Define to 1 if you have the `mkstemp' function.]))
 107 AC_CHECK_FUNC([mkdtemp],
 108               AC_DEFINE([HAVE_MKDTEMP], 1,
 109               [Define to 1 if you have the `mkdtemp' function.]))
 110   AC_MSG_CHECKING([for mbstate_t])
 111   AC_TRY_COMPILE([#include <wchar.h>],
 112   [mbstate_t teststate;],
 113   have_mbstate_t=yes, have_mbstate_t=no)
 114   AC_MSG_RESULT($have_mbstate_t)
 115   if test x"$have_mbstate_t" = xyes; then
 116     AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
 117   fi
 118
 119 # Some systems have frexp only in -lm, not in -lc.
 120 AC_SEARCH_LIBS(frexp, m)
 121
 122 AM_LC_MESSAGES
 123
 124 AC_MSG_CHECKING(for time_t in time.h)
 125 AC_CACHE_VAL(bu_cv_decl_time_t_time_h,
 126 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>], [time_t i;])],
 127 bu_cv_decl_time_t_time_h=yes, bu_cv_decl_time_t_time_h=no)])
 128 AC_MSG_RESULT($bu_cv_decl_time_t_time_h)
 129 if test $bu_cv_decl_time_t_time_h = yes; then
 130   AC_DEFINE([HAVE_TIME_T_IN_TIME_H], 1,
 131             [Is the type time_t defined in <time.h>?])
 132 fi
 133
 134 AC_MSG_CHECKING(for time_t in sys/types.h)
 135 AC_CACHE_VAL(bu_cv_decl_time_t_types_h,
 136 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>], [time_t i;])],
 137 bu_cv_decl_time_t_types_h=yes, bu_cv_decl_time_t_types_h=no)])
 138 AC_MSG_RESULT($bu_cv_decl_time_t_types_h)
 139 if test $bu_cv_decl_time_t_types_h = yes; then
 140   AC_DEFINE([HAVE_TIME_T_IN_TYPES_H], 1,
 141             [Is the type time_t defined in <sys/types.h>?])
 142 fi
 143
 144 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 145 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 146 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 147 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 148 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 149 if test $bu_cv_decl_getopt_unistd_h = yes; then
 150   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 151             [Is the prototype for getopt in <unistd.h> in the expected format?])
 152 fi
 153
 154 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 155 # by default.
 156 AC_MSG_CHECKING([for utime.h])
 157 AC_CACHE_VAL(bu_cv_header_utime_h,
 158 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 159 #ifdef HAVE_TIME_H
 160 #include <time.h>
 161 #endif
 162 #include <utime.h>],
 163 [struct utimbuf s;])],
 164 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 165 AC_MSG_RESULT($bu_cv_header_utime_h)
 166 if test $bu_cv_header_utime_h = yes; then
 167   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 168 fi
 169
 170 AC_CHECK_DECLS([fprintf, stpcpy, strstr, sbrk, getenv, environ, getc_unlocked,
 171                 snprintf, vsnprintf])
 172
 173 # Link in zlib if we can.  This allows us to read compressed debug
 174 # sections.  This is used only by readelf.c (objdump uses bfd for
 175 # reading compressed sections).
 176 AM_ZLIB
 177
 178 BFD_BINARY_FOPEN
 179
 180 # target-specific stuff:
 181
 182 # Canonicalize the secondary target names.
 183 if test -n "$enable_targets"; then
 184     for targ in `echo $enable_targets | sed 's/,/ /g'`
 185     do
 186         result=`$ac_config_sub $targ 2>/dev/null`
 187         if test -n "$result"; then
 188             canon_targets="$canon_targets $result"
 189         else
 190             # Allow targets that config.sub doesn't recognize, like "all".
 191             canon_targets="$canon_targets $targ"
 192         fi
 193     done
 194 fi
 195
 196 AC_CHECK_HEADER(iconv.h)
 197 AM_ICONV
 198
 199 all_targets=false
 200 BUILD_NLMCONV=
 201 NLMCONV_DEFS=
 202 BUILD_SRCONV=
 203 BUILD_DLLTOOL=
 204 DLLTOOL_DEFS=
 205 DLLTOOL_DEFAULT=
 206 BUILD_WINDRES=
 207 BUILD_WINDMC=
 208 BUILD_DLLWRAP=
 209 BUILD_MISC=
 210 BUILD_INSTALL_MISC=
 211 OBJDUMP_DEFS=
 212 OBJDUMP_PRIVATE_VECTORS=
 213 OBJDUMP_PRIVATE_OFILES=
 214 od_vectors=
 215
 216 for targ in $target $canon_targets
 217 do
 218     if test "x$targ" = "xall"; then
 219         all_targets=true
 220         BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 221         BUILD_SRCONV='$(SRCONV_PROG)'
 222         NLMCONV_DEFS="-DNLMCONV_I386 -DNLMCONV_ALPHA -DNLMCONV_POWERPC -DNLMCONV_SPARC"
 223         BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 224         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 225         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 226         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 227         if test -z "$DLLTOOL_DEFAULT"; then
 228           DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 229         fi
 230         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 231         BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 232         od_vectors="$od_vectors objdump_private_desc_xcoff"
 233     else
 234         case $targ in
 235 changequote(,)dnl
 236         i[3-7]86*-*-netware*)
 237 changequote([,])dnl
 238           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 239           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_I386"
 240           ;;
 241         alpha*-*-netware*)
 242           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 243           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_ALPHA"
 244           ;;
 245         powerpc*-*-netware*)
 246           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 247           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_POWERPC"
 248           ;;
 249         sparc*-*-netware*)
 250           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 251           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_SPARC"
 252           ;;
 253         esac
 254
 255         case $targ in
 256         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 257         esac
 258
 259         case $targ in
 260         arm-epoc-pe*)
 261           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 262           if test -z "$DLLTOOL_DEFAULT"; then
 263             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_EPOC"
 264           fi
 265           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_EPOC -DDLLTOOL_ARM"
 266           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 267           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 268           ;;
 269         arm-wince-pe* | arm-*-wince | arm*-*-cegcc* | arm*-*-mingw32ce*)
 270           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 271           if test -z "$DLLTOOL_DEFAULT"; then
 272             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_WINCE"
 273           fi
 274           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_WINCE -DDLLTOOL_ARM"
 275           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 276           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 277           ;;
 278         arm-*-pe*)
 279           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 280           if test -z "$DLLTOOL_DEFAULT"; then
 281             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 282           fi
 283           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 284           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 285           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 286           ;;
 287         x86_64-*-mingw*)
 288           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 289           if test -z "$DLLTOOL_DEFAULT"; then
 290             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MX86_64"
 291           fi
 292           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MX86_64"
 293           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 294           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 295           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 296           ;;
 297 changequote(,)dnl
 298         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32** | i[3-7]86-*-netbsdpe*)
 299 changequote([,])dnl
 300           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 301           if test -z "$DLLTOOL_DEFAULT"; then
 302             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 303           fi
 304           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 305           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 306           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 307           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 308           ;;
 309 changequote(,)dnl
 310         i[3-7]86-*-interix)
 311 changequote([,])dnl
 312           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 313           if test -z "$DLLTOOL_DEFAULT"; then
 314             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 315           fi
 316           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 317           ;;
 318 changequote(,)dnl
 319         powerpc*-aix5.[01])
 320 changequote([,])dnl
 321           ;;
 322 changequote(,)dnl
 323         powerpc*-aix[5-9].*)
 324 changequote([,])dnl
 325           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 326           ;;
 327         powerpc*-*-pe* | powerpc*-*-cygwin*)
 328           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 329           if test -z "$DLLTOOL_DEFAULT"; then
 330             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_PPC"
 331           fi
 332           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_PPC"
 333           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 334           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 335           ;;
 336         powerpc*-*-linux* | powerpc*-*-elf* | powerpc*-*-eabi*)
 337           case "$BUILD_INSTALL_MISC" in
 338             *embedspu*) ;;
 339             *) BUILD_INSTALL_MISC="${BUILD_INSTALL_MISC} embedspu"
 340           esac
 341           ;;
 342         sh*-*-pe)
 343           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 344           if test -z "$DLLTOOL_DEFAULT"; then
 345             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_SH"
 346           fi
 347           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 348           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 349           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 350           ;;
 351         spu-*-*)
 352           BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 353           ;;
 354         mips*-*-pe)
 355           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 356           if test -z "$DLLTOOL_DEFAULT"; then
 357             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MIPS"
 358           fi
 359           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 360           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 361           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 362           ;;
 363         mcore-*-pe)
 364           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 365           if test -z "$DLLTOOL_DEFAULT"; then
 366             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE"
 367           fi
 368           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 369           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 370           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 371           ;;
 372         mcore-*-elf)
 373           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 374           if test -z "$DLLTOOL_DEFAULT"; then
 375             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE_ELF"
 376           fi
 377           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 378           ;;
 379         mep-*)
 380           OBJDUMP_DEFS="-DSKIP_ZEROES=256 -DSKIP_ZEROES_AT_END=0"
 381           ;;
 382         esac
 383
 384         # Add objdump private vectors.
 385         case $targ in
 386         powerpc-*-aix*)
 387           od_vectors="$od_vectors objdump_private_desc_xcoff"
 388           ;;
 389         *-*-darwin*)
 390           od_vectors="$od_vectors objdump_private_desc_mach_o"
 391           ;;
 392         esac
 393     fi
 394 done
 395
 396 # Uniq objdump private vector, build objdump target ofiles.
 397 od_files=
 398 f=""
 399 for i in $od_vectors ; do
 400     case " $f " in
 401     *" $i "*) ;;
 402     *)
 403         f="$f $i"
 404         OBJDUMP_PRIVATE_VECTORS="$OBJDUMP_PRIVATE_VECTORS &$i,"
 405         case $i in
 406         objdump_private_desc_xcoff)
 407             od_files="$od_files od-xcoff" ;;
 408         objdump_private_desc_mach_o)
 409             od_files="$od_files od-macho" ;;
 410         *) AC_MSG_ERROR(*** unknown private vector $i) ;;
 411         esac
 412         ;;
 413     esac
 414 done
 415
 416 # Uniq objdump target ofiles
 417 f=""
 418 for i in $od_files ; do
 419     case " $f " in
 420     *" $i "*) ;;
 421     *)
 422         f="$f $i"
 423         OBJDUMP_PRIVATE_OFILES="$OBJDUMP_PRIVATE_OFILES $i.$objext"
 424         ;;
 425     esac
 426 done
 427
 428 DLLTOOL_DEFS="$DLLTOOL_DEFS $DLLTOOL_DEFAULT"
 429
 430 if test "${with_windres+set}" = set; then
 431           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 432 fi
 433
 434 if test "${with_windmc+set}" = set; then
 435           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 436 fi
 437
 438 OBJDUMP_DEFS="${OBJDUMP_DEFS} -DOBJDUMP_PRIVATE_VECTORS=\"${OBJDUMP_PRIVATE_VECTORS}\""
 439
 440 AC_SUBST(NLMCONV_DEFS)
 441 AC_SUBST(BUILD_NLMCONV)
 442 AC_SUBST(BUILD_SRCONV)
 443 AC_SUBST(BUILD_DLLTOOL)
 444 AC_SUBST(DLLTOOL_DEFS)
 445 AC_SUBST(BUILD_WINDRES)
 446 AC_SUBST(BUILD_WINDMC)
 447 AC_SUBST(BUILD_DLLWRAP)
 448 AC_SUBST(BUILD_MISC)
 449 AC_SUBST(BUILD_INSTALL_MISC)
 450 AC_SUBST(OBJDUMP_DEFS)
 451 AC_SUBST(OBJDUMP_PRIVATE_OFILES)
 452
 453 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 454
 455 targ=$target
 456 . $srcdir/../bfd/config.bfd
 457 if test "x$targ_underscore" = "xyes"; then
 458     UNDERSCORE=1
 459 else
 460     UNDERSCORE=0
 461 fi
 462 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 463  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 464
 465 # Emulation
 466 targ=$target
 467 . ${srcdir}/configure.tgt
 468 EMULATION=$targ_emul
 469 EMULATION_VECTOR=$targ_emul_vector
 470
 471 AC_SUBST(EMULATION)
 472 AC_SUBST(EMULATION_VECTOR)
 473
 474 # Required for html and install-html
 475 AC_SUBST(datarootdir)
 476 AC_SUBST(docdir)
 477 AC_SUBST(htmldir)
 478 AC_SUBST(pdfdir)
 479
 480 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 481 AC_OUTPUT