binutils/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR(ar.c)
   6
   7 AC_CANONICAL_TARGET
   8 AC_ISC_POSIX
   9
  10 changequote(,)dnl
  11 BFD_VERSION=`${srcdir}/../bfd/configure --version | sed -n -e '1s,.* ,,p'`
  12 changequote([,])dnl
  13 AM_INIT_AUTOMAKE(binutils, ${BFD_VERSION})
  14
  15 AC_PROG_CC
  16 AC_GNU_SOURCE
  17 AC_USE_SYSTEM_EXTENSIONS
  18
  19 ACX_LARGEFILE
  20 LT_INIT
  21
  22 AC_ARG_ENABLE(targets,
  23 [  --enable-targets        alternative target configurations],
  24 [case "${enableval}" in
  25   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  26             ;;
  27   no)       enable_targets= ;;
  28   *)        enable_targets=$enableval ;;
  29 esac])dnl
  30
  31 AC_ARG_ENABLE(deterministic-archives,
  32 [AS_HELP_STRING([--enable-deterministic-archives],
  33                 [ar and ranlib default to -D behavior])], [
  34 if test "${enableval}" = no; then
  35   default_ar_deterministic=0
  36 else
  37   default_ar_deterministic=1
  38 fi], [default_ar_deterministic=0])
  39
  40 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  41                    [Should ar and ranlib use -D behavior by default?])
  42
  43 AM_BINUTILS_WARNINGS
  44
  45 AC_CONFIG_HEADERS(config.h:config.in)
  46
  47 AH_VERBATIM([00_CONFIG_H_CHECK],
  48 [/* Check that config.h is #included before system headers
  49    (this works only for glibc, but that should be enough).  */
  50 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
  51 #  error config.h must be #included before system headers
  52 #endif
  53 #define __CONFIG_H__ 1])
  54
  55 if test -z "$target" ; then
  56     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  57 fi
  58 if test -z "$host" ; then
  59     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  60 fi
  61
  62 AC_PROG_YACC
  63 AM_PROG_LEX
  64
  65 ALL_LINGUAS="bg da es fi fr id it ja ro ru rw sk sv tr uk vi zh_CN zh_TW hr"
  66 ZW_GNU_GETTEXT_SISTER_DIR
  67 AM_PO_SUBDIRS
  68
  69 AM_MAINTAINER_MODE
  70 AM_CONDITIONAL(GENINSRC_NEVER, false)
  71 AC_EXEEXT
  72 if test -n "$EXEEXT"; then
  73   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
  74             [Does the platform use an executable suffix?])
  75 fi
  76 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
  77                    [Suffix used for executables, if any.])
  78
  79 # host-specific stuff:
  80
  81 HDEFINES=
  82
  83 . ${srcdir}/../bfd/configure.host
  84
  85 AC_SUBST(HDEFINES)
  86 AR=${AR-ar}
  87 AC_SUBST(AR)
  88 AC_PROG_RANLIB
  89 AC_PROG_INSTALL
  90
  91 BFD_CC_FOR_BUILD
  92
  93 DEMANGLER_NAME=c++filt
  94 case "${host}" in
  95   *-*-go32* | *-*-msdos*)
  96     DEMANGLER_NAME=cxxfilt
  97 esac
  98 AC_SUBST(DEMANGLER_NAME)
  99
 100 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h fcntl.h sys/file.h limits.h locale.h sys/param.h wchar.h)
 101 AC_HEADER_SYS_WAIT
 102 ACX_HEADER_STRING
 103 AC_FUNC_ALLOCA
 104 AC_CHECK_FUNCS(sbrk utimes setmode getc_unlocked strcoll setlocale)
 105 AC_CHECK_FUNC([mkstemp],
 106               AC_DEFINE([HAVE_MKSTEMP], 1,
 107               [Define to 1 if you have the `mkstemp' function.]))
 108 AC_CHECK_FUNC([mkdtemp],
 109               AC_DEFINE([HAVE_MKDTEMP], 1,
 110               [Define to 1 if you have the `mkdtemp' function.]))
 111   AC_MSG_CHECKING([for mbstate_t])
 112   AC_TRY_COMPILE([#include <wchar.h>],
 113   [mbstate_t teststate;],
 114   have_mbstate_t=yes, have_mbstate_t=no)
 115   AC_MSG_RESULT($have_mbstate_t)
 116   if test x"$have_mbstate_t" = xyes; then
 117     AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
 118   fi
 119
 120 # Some systems have frexp only in -lm, not in -lc.
 121 AC_SEARCH_LIBS(frexp, m)
 122
 123 AM_LC_MESSAGES
 124
 125 AC_MSG_CHECKING(for time_t in time.h)
 126 AC_CACHE_VAL(bu_cv_decl_time_t_time_h,
 127 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>], [time_t i;])],
 128 bu_cv_decl_time_t_time_h=yes, bu_cv_decl_time_t_time_h=no)])
 129 AC_MSG_RESULT($bu_cv_decl_time_t_time_h)
 130 if test $bu_cv_decl_time_t_time_h = yes; then
 131   AC_DEFINE([HAVE_TIME_T_IN_TIME_H], 1,
 132             [Is the type time_t defined in <time.h>?])
 133 fi
 134
 135 AC_MSG_CHECKING(for time_t in sys/types.h)
 136 AC_CACHE_VAL(bu_cv_decl_time_t_types_h,
 137 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>], [time_t i;])],
 138 bu_cv_decl_time_t_types_h=yes, bu_cv_decl_time_t_types_h=no)])
 139 AC_MSG_RESULT($bu_cv_decl_time_t_types_h)
 140 if test $bu_cv_decl_time_t_types_h = yes; then
 141   AC_DEFINE([HAVE_TIME_T_IN_TYPES_H], 1,
 142             [Is the type time_t defined in <sys/types.h>?])
 143 fi
 144
 145 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 146 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 147 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 148 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 149 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 150 if test $bu_cv_decl_getopt_unistd_h = yes; then
 151   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 152             [Is the prototype for getopt in <unistd.h> in the expected format?])
 153 fi
 154
 155 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 156 # by default.
 157 AC_MSG_CHECKING([for utime.h])
 158 AC_CACHE_VAL(bu_cv_header_utime_h,
 159 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 160 #ifdef HAVE_TIME_H
 161 #include <time.h>
 162 #endif
 163 #include <utime.h>],
 164 [struct utimbuf s;])],
 165 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 166 AC_MSG_RESULT($bu_cv_header_utime_h)
 167 if test $bu_cv_header_utime_h = yes; then
 168   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 169 fi
 170
 171 AC_CHECK_DECLS([fprintf, stpcpy, strstr, sbrk, getenv, environ, getc_unlocked,
 172                 snprintf, vsnprintf])
 173
 174 # Link in zlib if we can.  This allows us to read compressed debug
 175 # sections.  This is used only by readelf.c (objdump uses bfd for
 176 # reading compressed sections).
 177 AM_ZLIB
 178
 179 BFD_BINARY_FOPEN
 180
 181 # target-specific stuff:
 182
 183 # Canonicalize the secondary target names.
 184 if test -n "$enable_targets"; then
 185     for targ in `echo $enable_targets | sed 's/,/ /g'`
 186     do
 187         result=`$ac_config_sub $targ 2>/dev/null`
 188         if test -n "$result"; then
 189             canon_targets="$canon_targets $result"
 190         else
 191             # Allow targets that config.sub doesn't recognize, like "all".
 192             canon_targets="$canon_targets $targ"
 193         fi
 194     done
 195 fi
 196
 197 AC_CHECK_HEADER(iconv.h)
 198 AM_ICONV
 199
 200 all_targets=false
 201 BUILD_NLMCONV=
 202 NLMCONV_DEFS=
 203 BUILD_SRCONV=
 204 BUILD_DLLTOOL=
 205 DLLTOOL_DEFS=
 206 DLLTOOL_DEFAULT=
 207 BUILD_WINDRES=
 208 BUILD_WINDMC=
 209 BUILD_DLLWRAP=
 210 BUILD_MISC=
 211 BUILD_INSTALL_MISC=
 212 OBJDUMP_DEFS=
 213 OBJDUMP_PRIVATE_VECTORS=
 214 OBJDUMP_PRIVATE_OFILES=
 215 od_vectors=
 216
 217 for targ in $target $canon_targets
 218 do
 219     if test "x$targ" = "xall"; then
 220         all_targets=true
 221         BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 222         BUILD_SRCONV='$(SRCONV_PROG)'
 223         NLMCONV_DEFS="-DNLMCONV_I386 -DNLMCONV_ALPHA -DNLMCONV_POWERPC -DNLMCONV_SPARC"
 224         BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 225         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 226         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 227         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 228         if test -z "$DLLTOOL_DEFAULT"; then
 229           DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 230         fi
 231         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 232         BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 233         od_vectors="$od_vectors objdump_private_desc_xcoff"
 234     else
 235         case $targ in
 236 changequote(,)dnl
 237         i[3-7]86*-*-netware*)
 238 changequote([,])dnl
 239           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 240           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_I386"
 241           ;;
 242         alpha*-*-netware*)
 243           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 244           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_ALPHA"
 245           ;;
 246         powerpc*-*-netware*)
 247           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 248           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_POWERPC"
 249           ;;
 250         sparc*-*-netware*)
 251           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 252           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_SPARC"
 253           ;;
 254         esac
 255
 256         case $targ in
 257         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 258         esac
 259
 260         case $targ in
 261         arm-epoc-pe*)
 262           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 263           if test -z "$DLLTOOL_DEFAULT"; then
 264             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_EPOC"
 265           fi
 266           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_EPOC -DDLLTOOL_ARM"
 267           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 268           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 269           ;;
 270         arm-wince-pe* | arm-*-wince | arm*-*-cegcc* | arm*-*-mingw32ce*)
 271           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 272           if test -z "$DLLTOOL_DEFAULT"; then
 273             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_WINCE"
 274           fi
 275           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_WINCE -DDLLTOOL_ARM"
 276           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 277           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 278           ;;
 279         arm-*-pe*)
 280           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 281           if test -z "$DLLTOOL_DEFAULT"; then
 282             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 283           fi
 284           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 285           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 286           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 287           ;;
 288         x86_64-*-mingw*)
 289           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 290           if test -z "$DLLTOOL_DEFAULT"; then
 291             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MX86_64"
 292           fi
 293           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MX86_64"
 294           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 295           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 296           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 297           ;;
 298 changequote(,)dnl
 299         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32** | i[3-7]86-*-netbsdpe*)
 300 changequote([,])dnl
 301           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 302           if test -z "$DLLTOOL_DEFAULT"; then
 303             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 304           fi
 305           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 306           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 307           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 308           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 309           ;;
 310 changequote(,)dnl
 311         i[3-7]86-*-interix)
 312 changequote([,])dnl
 313           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 314           if test -z "$DLLTOOL_DEFAULT"; then
 315             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 316           fi
 317           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 318           ;;
 319 changequote(,)dnl
 320         powerpc*-aix5.[01])
 321 changequote([,])dnl
 322           ;;
 323 changequote(,)dnl
 324         powerpc*-aix[5-9].*)
 325 changequote([,])dnl
 326           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 327           ;;
 328         powerpc*-*-pe* | powerpc*-*-cygwin*)
 329           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 330           if test -z "$DLLTOOL_DEFAULT"; then
 331             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_PPC"
 332           fi
 333           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_PPC"
 334           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 335           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 336           ;;
 337         powerpc*-*-linux* | powerpc*-*-elf* | powerpc*-*-eabi*)
 338           case "$BUILD_INSTALL_MISC" in
 339             *embedspu*) ;;
 340             *) BUILD_INSTALL_MISC="${BUILD_INSTALL_MISC} embedspu"
 341           esac
 342           ;;
 343         sh*-*-pe)
 344           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 345           if test -z "$DLLTOOL_DEFAULT"; then
 346             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_SH"
 347           fi
 348           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 349           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 350           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 351           ;;
 352         spu-*-*)
 353           BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 354           ;;
 355         mips*-*-pe)
 356           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 357           if test -z "$DLLTOOL_DEFAULT"; then
 358             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MIPS"
 359           fi
 360           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 361           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 362           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 363           ;;
 364         mcore-*-pe)
 365           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 366           if test -z "$DLLTOOL_DEFAULT"; then
 367             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE"
 368           fi
 369           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 370           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 371           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 372           ;;
 373         mcore-*-elf)
 374           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 375           if test -z "$DLLTOOL_DEFAULT"; then
 376             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE_ELF"
 377           fi
 378           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 379           ;;
 380         mep-*)
 381           OBJDUMP_DEFS="-DSKIP_ZEROES=256 -DSKIP_ZEROES_AT_END=0"
 382           ;;
 383         esac
 384
 385         # Add objdump private vectors.
 386         case $targ in
 387         powerpc-*-aix*)
 388           od_vectors="$od_vectors objdump_private_desc_xcoff"
 389           ;;
 390         *-*-darwin*)
 391           od_vectors="$od_vectors objdump_private_desc_mach_o"
 392           ;;
 393         esac
 394     fi
 395 done
 396
 397 # Uniq objdump private vector, build objdump target ofiles.
 398 od_files=
 399 f=""
 400 for i in $od_vectors ; do
 401     case " $f " in
 402     *" $i "*) ;;
 403     *)
 404         f="$f $i"
 405         OBJDUMP_PRIVATE_VECTORS="$OBJDUMP_PRIVATE_VECTORS &$i,"
 406         case $i in
 407         objdump_private_desc_xcoff)
 408             od_files="$od_files od-xcoff" ;;
 409         objdump_private_desc_mach_o)
 410             od_files="$od_files od-macho" ;;
 411         *) AC_MSG_ERROR(*** unknown private vector $i) ;;
 412         esac
 413         ;;
 414     esac
 415 done
 416
 417 # Uniq objdump target ofiles
 418 f=""
 419 for i in $od_files ; do
 420     case " $f " in
 421     *" $i "*) ;;
 422     *)
 423         f="$f $i"
 424         OBJDUMP_PRIVATE_OFILES="$OBJDUMP_PRIVATE_OFILES $i.$objext"
 425         ;;
 426     esac
 427 done
 428
 429 DLLTOOL_DEFS="$DLLTOOL_DEFS $DLLTOOL_DEFAULT"
 430
 431 if test "${with_windres+set}" = set; then
 432           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 433 fi
 434
 435 if test "${with_windmc+set}" = set; then
 436           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 437 fi
 438
 439 OBJDUMP_DEFS="${OBJDUMP_DEFS} -DOBJDUMP_PRIVATE_VECTORS=\"${OBJDUMP_PRIVATE_VECTORS}\""
 440
 441 AC_SUBST(NLMCONV_DEFS)
 442 AC_SUBST(BUILD_NLMCONV)
 443 AC_SUBST(BUILD_SRCONV)
 444 AC_SUBST(BUILD_DLLTOOL)
 445 AC_SUBST(DLLTOOL_DEFS)
 446 AC_SUBST(BUILD_WINDRES)
 447 AC_SUBST(BUILD_WINDMC)
 448 AC_SUBST(BUILD_DLLWRAP)
 449 AC_SUBST(BUILD_MISC)
 450 AC_SUBST(BUILD_INSTALL_MISC)
 451 AC_SUBST(OBJDUMP_DEFS)
 452 AC_SUBST(OBJDUMP_PRIVATE_OFILES)
 453
 454 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 455
 456 targ=$target
 457 . $srcdir/../bfd/config.bfd
 458 if test "x$targ_underscore" = "xyes"; then
 459     UNDERSCORE=1
 460 else
 461     UNDERSCORE=0
 462 fi
 463 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 464  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 465
 466 # Emulation
 467 targ=$target
 468 . ${srcdir}/configure.tgt
 469 EMULATION=$targ_emul
 470 EMULATION_VECTOR=$targ_emul_vector
 471
 472 AC_SUBST(EMULATION)
 473 AC_SUBST(EMULATION_VECTOR)
 474
 475 # Required for html and install-html
 476 AC_SUBST(datarootdir)
 477 AC_SUBST(docdir)
 478 AC_SUBST(htmldir)
 479 AC_SUBST(pdfdir)
 480
 481 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 482 AC_OUTPUT