binutils/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR(ar.c)
   6
   7 AC_CANONICAL_TARGET
   8 AC_ISC_POSIX
   9
  10 changequote(,)dnl
  11 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  12 changequote([,])dnl
  13 AM_INIT_AUTOMAKE(binutils, ${BFD_VERSION})
  14
  15 AC_PROG_CC
  16 AC_GNU_SOURCE
  17 AC_USE_SYSTEM_EXTENSIONS
  18
  19 ACX_LARGEFILE
  20 LT_INIT
  21
  22 AC_ARG_ENABLE(targets,
  23 [  --enable-targets        alternative target configurations],
  24 [case "${enableval}" in
  25   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  26             ;;
  27   no)       enable_targets= ;;
  28   *)        enable_targets=$enableval ;;
  29 esac])dnl
  30
  31 AC_ARG_ENABLE(deterministic-archives,
  32 [AS_HELP_STRING([--enable-deterministic-archives],
  33                 [ar and ranlib default to -D behavior])], [
  34 if test "${enableval}" = no; then
  35   default_ar_deterministic=0
  36 else
  37   default_ar_deterministic=1
  38 fi], [default_ar_deterministic=0])
  39
  40 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  41                    [Should ar and ranlib use -D behavior by default?])
  42
  43 AM_BINUTILS_WARNINGS
  44
  45 AC_CONFIG_HEADERS(config.h:config.in)
  46
  47 if test -z "$target" ; then
  48     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  49 fi
  50 if test -z "$host" ; then
  51     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  52 fi
  53
  54 AC_PROG_YACC
  55 AM_PROG_LEX
  56
  57 ALL_LINGUAS="da es fi fr id ja ro ru rw sk sv tr uk vi zh_CN zh_TW bg"
  58 ZW_GNU_GETTEXT_SISTER_DIR
  59 AM_PO_SUBDIRS
  60
  61 AM_MAINTAINER_MODE
  62 AM_CONDITIONAL(GENINSRC_NEVER, false)
  63 AC_EXEEXT
  64 if test -n "$EXEEXT"; then
  65   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
  66             [Does the platform use an executable suffix?])
  67 fi
  68 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
  69                    [Suffix used for executables, if any.])
  70
  71 # host-specific stuff:
  72
  73 HDEFINES=
  74
  75 . ${srcdir}/../bfd/configure.host
  76
  77 AC_SUBST(HDEFINES)
  78 AR=${AR-ar}
  79 AC_SUBST(AR)
  80 AC_PROG_RANLIB
  81 AC_PROG_INSTALL
  82
  83 BFD_CC_FOR_BUILD
  84
  85 DEMANGLER_NAME=c++filt
  86 case "${host}" in
  87   *-*-go32* | *-*-msdos*)
  88     DEMANGLER_NAME=cxxfilt
  89 esac
  90 AC_SUBST(DEMANGLER_NAME)
  91
  92 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h fcntl.h sys/file.h limits.h sys/param.h)
  93 AC_HEADER_SYS_WAIT
  94 AC_FUNC_ALLOCA
  95 AC_CHECK_FUNCS(sbrk utimes setmode getc_unlocked strcoll setlocale)
  96 AC_CHECK_FUNC([mkstemp],
  97               AC_DEFINE([HAVE_MKSTEMP], 1,
  98               [Define to 1 if you have the `mkstemp' function.]))
  99 AC_CHECK_FUNC([mkdtemp],
 100               AC_DEFINE([HAVE_MKDTEMP], 1,
 101               [Define to 1 if you have the `mkdtemp' function.]))
 102
 103 # Some systems have frexp only in -lm, not in -lc.
 104 AC_SEARCH_LIBS(frexp, m)
 105
 106 AM_LC_MESSAGES
 107
 108 AC_MSG_CHECKING(for time_t in time.h)
 109 AC_CACHE_VAL(bu_cv_decl_time_t_time_h,
 110 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>], [time_t i;])],
 111 bu_cv_decl_time_t_time_h=yes, bu_cv_decl_time_t_time_h=no)])
 112 AC_MSG_RESULT($bu_cv_decl_time_t_time_h)
 113 if test $bu_cv_decl_time_t_time_h = yes; then
 114   AC_DEFINE([HAVE_TIME_T_IN_TIME_H], 1,
 115             [Is the type time_t defined in <time.h>?])
 116 fi
 117
 118 AC_MSG_CHECKING(for time_t in sys/types.h)
 119 AC_CACHE_VAL(bu_cv_decl_time_t_types_h,
 120 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>], [time_t i;])],
 121 bu_cv_decl_time_t_types_h=yes, bu_cv_decl_time_t_types_h=no)])
 122 AC_MSG_RESULT($bu_cv_decl_time_t_types_h)
 123 if test $bu_cv_decl_time_t_types_h = yes; then
 124   AC_DEFINE([HAVE_TIME_T_IN_TYPES_H], 1,
 125             [Is the type time_t defined in <sys/types.h>?])
 126 fi
 127
 128 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 129 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 130 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 131 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 132 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 133 if test $bu_cv_decl_getopt_unistd_h = yes; then
 134   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 135             [Is the prototype for getopt in <unistd.h> in the expected format?])
 136 fi
 137
 138 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 139 # by default.
 140 AC_MSG_CHECKING([for utime.h])
 141 AC_CACHE_VAL(bu_cv_header_utime_h,
 142 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 143 #ifdef HAVE_TIME_H
 144 #include <time.h>
 145 #endif
 146 #include <utime.h>],
 147 [struct utimbuf s;])],
 148 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 149 AC_MSG_RESULT($bu_cv_header_utime_h)
 150 if test $bu_cv_header_utime_h = yes; then
 151   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 152 fi
 153
 154 AC_CHECK_DECLS([fprintf, stpcpy, strstr, sbrk, getenv, environ, getc_unlocked,
 155                 snprintf, vsnprintf])
 156
 157 # Link in zlib if we can.  This allows us to read compressed debug
 158 # sections.  This is used only by readelf.c (objdump uses bfd for
 159 # reading compressed sections).
 160 AM_ZLIB
 161
 162 BFD_BINARY_FOPEN
 163
 164 # target-specific stuff:
 165
 166 # Canonicalize the secondary target names.
 167 if test -n "$enable_targets"; then
 168     for targ in `echo $enable_targets | sed 's/,/ /g'`
 169     do
 170         result=`$ac_config_sub $targ 2>/dev/null`
 171         if test -n "$result"; then
 172             canon_targets="$canon_targets $result"
 173         else
 174             # Allow targets that config.sub doesn't recognize, like "all".
 175             canon_targets="$canon_targets $targ"
 176         fi
 177     done
 178 fi
 179
 180 AC_CHECK_HEADER(iconv.h)
 181 AM_ICONV
 182
 183 all_targets=false
 184 BUILD_NLMCONV=
 185 NLMCONV_DEFS=
 186 BUILD_SRCONV=
 187 BUILD_DLLTOOL=
 188 DLLTOOL_DEFS=
 189 DLLTOOL_DEFAULT=
 190 BUILD_WINDRES=
 191 BUILD_WINDMC=
 192 BUILD_DLLWRAP=
 193 BUILD_MISC=
 194 BUILD_INSTALL_MISC=
 195 OBJDUMP_DEFS=
 196 OBJDUMP_PRIVATE_VECTORS=
 197 OBJDUMP_PRIVATE_OFILES=
 198 od_vectors=
 199
 200 for targ in $target $canon_targets
 201 do
 202     if test "x$targ" = "xall"; then
 203         all_targets=true
 204         BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 205         BUILD_SRCONV='$(SRCONV_PROG)'
 206         NLMCONV_DEFS="-DNLMCONV_I386 -DNLMCONV_ALPHA -DNLMCONV_POWERPC -DNLMCONV_SPARC"
 207         BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 208         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 209         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 210         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 211         if test -z "$DLLTOOL_DEFAULT"; then
 212           DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 213         fi
 214         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 215         BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 216         od_vectors="$od_vectors objdump_private_desc_xcoff"
 217     else
 218         case $targ in
 219 changequote(,)dnl
 220         i[3-7]86*-*-netware*)
 221 changequote([,])dnl
 222           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 223           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_I386"
 224           ;;
 225         alpha*-*-netware*)
 226           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 227           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_ALPHA"
 228           ;;
 229         powerpc*-*-netware*)
 230           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 231           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_POWERPC"
 232           ;;
 233         sparc*-*-netware*)
 234           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 235           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_SPARC"
 236           ;;
 237         esac
 238
 239         case $targ in
 240         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 241         esac
 242
 243         case $targ in
 244         arm-epoc-pe*)
 245           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 246           if test -z "$DLLTOOL_DEFAULT"; then
 247             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_EPOC"
 248           fi
 249           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_EPOC -DDLLTOOL_ARM"
 250           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 251           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 252           ;;
 253         arm-wince-pe* | arm-*-wince | arm*-*-cegcc* | arm*-*-mingw32ce*)
 254           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 255           if test -z "$DLLTOOL_DEFAULT"; then
 256             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_WINCE"
 257           fi
 258           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_WINCE -DDLLTOOL_ARM"
 259           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 260           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 261           ;;
 262         arm-*-pe*)
 263           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 264           if test -z "$DLLTOOL_DEFAULT"; then
 265             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 266           fi
 267           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 268           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 269           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 270           ;;
 271         x86_64-*-mingw*)
 272           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 273           if test -z "$DLLTOOL_DEFAULT"; then
 274             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MX86_64"
 275           fi
 276           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MX86_64"
 277           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 278           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 279           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 280           ;;
 281 changequote(,)dnl
 282         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32** | i[3-7]86-*-netbsdpe*)
 283 changequote([,])dnl
 284           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 285           if test -z "$DLLTOOL_DEFAULT"; then
 286             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 287           fi
 288           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 289           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 290           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 291           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 292           ;;
 293 changequote(,)dnl
 294         i[3-7]86-*-interix)
 295 changequote([,])dnl
 296           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 297           if test -z "$DLLTOOL_DEFAULT"; then
 298             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 299           fi
 300           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 301           ;;
 302 changequote(,)dnl
 303         powerpc*-aix5.[01])
 304 changequote([,])dnl
 305           ;;
 306 changequote(,)dnl
 307         powerpc*-aix[5-9].*)
 308 changequote([,])dnl
 309           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 310           ;;
 311         powerpc*-*-pe* | powerpc*-*-cygwin*)
 312           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 313           if test -z "$DLLTOOL_DEFAULT"; then
 314             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_PPC"
 315           fi
 316           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_PPC"
 317           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 318           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 319           ;;
 320         powerpc*-*-linux* | powerpc*-*-elf* | powerpc*-*-eabi*)
 321           case "$BUILD_INSTALL_MISC" in
 322             *embedspu*) ;;
 323             *) BUILD_INSTALL_MISC="${BUILD_INSTALL_MISC} embedspu"
 324           esac
 325           ;;
 326         sh*-*-pe)
 327           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 328           if test -z "$DLLTOOL_DEFAULT"; then
 329             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_SH"
 330           fi
 331           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 332           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 333           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 334           ;;
 335         spu-*-*)
 336           BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 337           ;;
 338         mips*-*-pe)
 339           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 340           if test -z "$DLLTOOL_DEFAULT"; then
 341             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MIPS"
 342           fi
 343           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 344           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 345           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 346           ;;
 347         mcore-*-pe)
 348           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 349           if test -z "$DLLTOOL_DEFAULT"; then
 350             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE"
 351           fi
 352           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 353           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 354           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 355           ;;
 356         mcore-*-elf)
 357           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 358           if test -z "$DLLTOOL_DEFAULT"; then
 359             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE_ELF"
 360           fi
 361           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 362           ;;
 363         mep-*)
 364           OBJDUMP_DEFS="-DSKIP_ZEROES=256 -DSKIP_ZEROES_AT_END=0"
 365           ;;
 366         esac
 367
 368         # Add objdump private vectors.
 369         case $targ in
 370         powerpc-*-aix*)
 371           od_vectors="$od_vectors objdump_private_desc_xcoff"
 372           ;;
 373         *-*-darwin*)
 374           od_vectors="$od_vectors objdump_private_desc_mach_o"
 375           ;;
 376         esac
 377     fi
 378 done
 379
 380 # Uniq objdump private vector, build objdump target ofiles.
 381 od_files=
 382 f=""
 383 for i in $od_vectors ; do
 384     case " $f " in
 385     *" $i "*) ;;
 386     *)
 387         f="$f $i"
 388         OBJDUMP_PRIVATE_VECTORS="$OBJDUMP_PRIVATE_VECTORS &$i,"
 389         case $i in
 390         objdump_private_desc_xcoff)
 391             od_files="$od_files od-xcoff" ;;
 392         objdump_private_desc_mach_o)
 393             od_files="$od_files od-macho" ;;
 394         *) AC_MSG_ERROR(*** unknown private vector $i) ;;
 395         esac
 396         ;;
 397     esac
 398 done
 399
 400 # Uniq objdump target ofiles
 401 f=""
 402 for i in $od_files ; do
 403     case " $f " in
 404     *" $i "*) ;;
 405     *)
 406         f="$f $i"
 407         OBJDUMP_PRIVATE_OFILES="$OBJDUMP_PRIVATE_OFILES $i.$objext"
 408         ;;
 409     esac
 410 done
 411
 412 DLLTOOL_DEFS="$DLLTOOL_DEFS $DLLTOOL_DEFAULT"
 413
 414 if test "${with_windres+set}" = set; then
 415           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 416 fi
 417
 418 if test "${with_windmc+set}" = set; then
 419           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 420 fi
 421
 422 OBJDUMP_DEFS="${OBJDUMP_DEFS} -DOBJDUMP_PRIVATE_VECTORS=\"${OBJDUMP_PRIVATE_VECTORS}\""
 423
 424 AC_SUBST(NLMCONV_DEFS)
 425 AC_SUBST(BUILD_NLMCONV)
 426 AC_SUBST(BUILD_SRCONV)
 427 AC_SUBST(BUILD_DLLTOOL)
 428 AC_SUBST(DLLTOOL_DEFS)
 429 AC_SUBST(BUILD_WINDRES)
 430 AC_SUBST(BUILD_WINDMC)
 431 AC_SUBST(BUILD_DLLWRAP)
 432 AC_SUBST(BUILD_MISC)
 433 AC_SUBST(BUILD_INSTALL_MISC)
 434 AC_SUBST(OBJDUMP_DEFS)
 435 AC_SUBST(OBJDUMP_PRIVATE_OFILES)
 436
 437 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 438
 439 targ=$target
 440 . $srcdir/../bfd/config.bfd
 441 if test "x$targ_underscore" = "xyes"; then
 442     UNDERSCORE=1
 443 else
 444     UNDERSCORE=0
 445 fi
 446 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 447  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 448
 449 # Emulation
 450 targ=$target
 451 . ${srcdir}/configure.tgt
 452 EMULATION=$targ_emul
 453 EMULATION_VECTOR=$targ_emul_vector
 454
 455 AC_SUBST(EMULATION)
 456 AC_SUBST(EMULATION_VECTOR)
 457
 458 # Required for html and install-html
 459 AC_SUBST(datarootdir)
 460 AC_SUBST(docdir)
 461 AC_SUBST(htmldir)
 462 AC_SUBST(pdfdir)
 463
 464 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 465 AC_OUTPUT