bindings/python/CMakeLists.txt

   1 IF (ENABLE_PYTHON3 AND NOT DEFINED PythonLibs_FIND_VERSION)
   2     # if we build both for python2 and python3, make this the python2 build.
   3     # see comment in the python3 CMakeLists.txt file
   4     SET (PythonLibs_FIND_VERSION 2)
   5     SET (PythonLibs_FIND_VERSION_MAJOR 2)
   6 ENDIF (ENABLE_PYTHON3 AND NOT DEFINED PythonLibs_FIND_VERSION)
   7
   8 FIND_PACKAGE (PythonLibs REQUIRED)
   9 FIND_PACKAGE (PythonInterp ${PYTHONLIBS_VERSION_STRING} REQUIRED)
  10
  11 EXECUTE_PROCESS(COMMAND ${PYTHON_EXECUTABLE} -c "from sys import stdout; from distutils import sysconfig; stdout.write(sysconfig.get_python_lib(True))" OUTPUT_VARIABLE PYTHON_INSTALL_DIR)
  12
  13 IF (NOT DEFINED PYTHON_VERSION_MAJOR)
  14     SET (PYTHON_VERSION_MAJOR 2)
  15 ENDIF (NOT DEFINED PYTHON_VERSION_MAJOR)
  16 IF (${PYTHON_VERSION_MAJOR} GREATER 2)
  17     SET (SWIG_PY_FLAGS -DPYTHON3=1)
  18 ENDIF (${PYTHON_VERSION_MAJOR} GREATER 2)
  19
  20 MESSAGE (STATUS "Python executable: ${PYTHON_EXECUTABLE}")
  21 MESSAGE (STATUS "Python installation dir: ${PYTHON_INSTALL_DIR}")
  22 MESSAGE (STATUS "Python include path: ${PYTHON_INCLUDE_PATH}")
  23
  24 ADD_CUSTOM_COMMAND (
  25     OUTPUT solv_python.c
  26     COMMAND ${SWIG_EXECUTABLE} ${SWIG_FLAGS} -python ${SWIG_PY_FLAGS} -I${CMAKE_SOURCE_DIR}/src -o solv_python.c ${CMAKE_SOURCE_DIR}/bindings/solv.i
  27     WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
  28     DEPENDS ${CMAKE_SOURCE_DIR}/bindings/solv.i
  29 )
  30
  31 ADD_DEFINITIONS(-Wno-unused)
  32 INCLUDE_DIRECTORIES (${PYTHON_INCLUDE_PATH})
  33
  34 ADD_LIBRARY (bindings_python MODULE solv_python.c)
  35 SET_TARGET_PROPERTIES (bindings_python PROPERTIES PREFIX "" OUTPUT_NAME "_solv")
  36 TARGET_LINK_LIBRARIES (bindings_python libsolvext libsolv ${SYSTEM_LIBRARIES})
  37
  38 INSTALL (TARGETS bindings_python LIBRARY DESTINATION ${PYTHON_INSTALL_DIR})
  39 INSTALL (FILES ${CMAKE_CURRENT_BINARY_DIR}/solv.py DESTINATION ${PYTHON_INSTALL_DIR})
  40