bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([libbfd.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 AM_INIT_AUTOMAKE(bfd, 2.16.90)
  12
  13 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  14 dnl to call AC_CHECK_PROG.
  15 AC_CHECK_TOOL(AR, ar)
  16 AC_CHECK_TOOL(RANLIB, ranlib, :)
  17
  18 dnl Default to a non shared library.  This may be overridden by the
  19 dnl configure option --enable-shared.
  20 AM_DISABLE_SHARED
  21
  22 AM_PROG_LIBTOOL
  23
  24 AC_ARG_ENABLE(64-bit-bfd,
  25 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  26 [case "${enableval}" in
  27   yes)  want64=true  ;;
  28   no)   want64=false ;;
  29   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  30 esac],[want64=false])dnl
  31 AC_ARG_ENABLE(targets,
  32 [  --enable-targets        alternative target configurations],
  33 [case "${enableval}" in
  34   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  35             ;;
  36   no)       enable_targets= ;;
  37   *)        enable_targets=$enableval ;;
  38 esac])dnl
  39 AC_ARG_ENABLE(commonbfdlib,
  40 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  41 [case "${enableval}" in
  42   yes) commonbfdlib=true ;;
  43   no)  commonbfdlib=false ;;
  44   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  45 esac])dnl
  46 AC_ARG_WITH(mmap,
  47 [  --with-mmap             try using mmap for BFD input files if available],
  48 [case "${withval}" in
  49   yes)  want_mmap=true ;;
  50   no)   want_mmap=false ;;
  51   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  52 esac],[want_mmap=false])dnl
  53
  54 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  55
  56 AC_ARG_ENABLE(werror,
  57   [  --enable-werror    treat compile warnings as errors],
  58   [case "${enableval}" in
  59      yes | y) ERROR_ON_WARNING="yes" ;;
  60      no | n)  ERROR_ON_WARNING="no" ;;
  61      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
  62    esac])
  63
  64 # Enable -Werror by default, suppressing it only for --disable-werror
  65 # or --disable-build-warnings.
  66 if test "${ERROR_ON_WARNING}" != no
  67 then
  68   build_warnings="$build_warnings -Werror"
  69 fi
  70
  71 AC_ARG_ENABLE(build-warnings,
  72 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  73 [case "${enableval}" in
  74   yes)  ;;
  75   no)   build_warnings="-w";;
  76   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  77         build_warnings="${build_warnings} ${t}";;
  78   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  79         build_warnings="${t} ${build_warnings}";;
  80   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  81 esac
  82 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  83   echo "Setting warning flags = $build_warnings" 6>&1
  84 fi])dnl
  85 WARN_CFLAGS=""
  86 if test "x${build_warnings}" != x && test "x$GCC" = xyes ; then
  87     WARN_CFLAGS="${build_warnings}"
  88 fi
  89 AC_SUBST(WARN_CFLAGS)
  90
  91 AM_CONFIG_HEADER(config.h:config.in)
  92
  93 if test -z "$target" ; then
  94     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  95 fi
  96
  97 AM_MAINTAINER_MODE
  98 AM_INSTALL_LIBBFD
  99 AC_EXEEXT
 100
 101 host64=false
 102 target64=false
 103 bfd_default_target_size=32
 104
 105 # host stuff:
 106
 107 AC_PROG_CC
 108
 109 ALL_LINGUAS="fr tr ja es sv da zh_CN ro"
 110 CY_GNU_GETTEXT
 111
 112 # Permit host specific settings.
 113 . ${srcdir}/configure.host
 114
 115 AC_SUBST(HDEFINES)
 116 AC_PROG_INSTALL
 117
 118 BFD_HOST_64BIT_LONG=0
 119 BFD_HOST_LONG_LONG=0
 120 BFD_HOST_64_BIT_DEFINED=0
 121 BFD_HOST_64_BIT=
 122 BFD_HOST_U_64_BIT=
 123
 124 AC_MSG_CHECKING([for long long])
 125 AC_CACHE_VAL(bfd_cv_has_long_long,
 126 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[unsigned long long ll = 18446744073709551615ULL;]])],[bfd_cv_has_long_long=yes],[bfd_cv_has_long_long=no])])
 127 AC_MSG_RESULT($bfd_cv_has_long_long)
 128 if test $bfd_cv_has_long_long = yes; then
 129   BFD_HOST_LONG_LONG=1
 130   AC_COMPILE_CHECK_SIZEOF(long long)
 131 fi
 132
 133 AC_COMPILE_CHECK_SIZEOF(long)
 134 if test "x${ac_cv_sizeof_long}" = "x8"; then
 135   host64=true
 136   BFD_HOST_64BIT_LONG=1
 137   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long"
 138   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long"
 139 elif test "x${ac_cv_sizeof_long_long}" = "x8"; then
 140   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long long"
 141   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long long"
 142 fi
 143
 144 if test -n "${HOST_64BIT_TYPE}" -a -n "${HOST_U_64BIT_TYPE}"; then
 145   BFD_HOST_64_BIT_DEFINED=1
 146   BFD_HOST_64_BIT="${HOST_64BIT_TYPE}"
 147   BFD_HOST_U_64_BIT="${HOST_U_64BIT_TYPE}"
 148 fi
 149
 150 AC_SUBST(BFD_HOST_64BIT_LONG)
 151 AC_SUBST(BFD_HOST_LONG_LONG)
 152 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 153 AC_SUBST(BFD_HOST_64_BIT)
 154 AC_SUBST(BFD_HOST_U_64_BIT)
 155
 156 BFD_CC_FOR_BUILD
 157
 158 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 159 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 160 AC_HEADER_TIME
 161 AC_HEADER_DIRENT
 162 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
 163 AC_CHECK_FUNCS(strtoull)
 164
 165 BFD_BINARY_FOPEN
 166
 167 BFD_NEED_DECLARATION(ffs)
 168 BFD_NEED_DECLARATION(free)
 169 BFD_NEED_DECLARATION(getenv)
 170 BFD_NEED_DECLARATION(malloc)
 171 BFD_NEED_DECLARATION(realloc)
 172 BFD_NEED_DECLARATION(strstr)
 173
 174 # If we are configured native, pick a core file support file.
 175 COREFILE=
 176 COREFLAG=
 177 TRAD_HEADER=
 178 if test "${target}" = "${host}"; then
 179   case "${host}" in
 180   alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu)
 181         COREFILE=''
 182         ;;
 183   alpha*-*-linux-*)
 184         COREFILE=trad-core.lo
 185         TRAD_HEADER='"hosts/alphalinux.h"'
 186         ;;
 187   alpha*-*-netbsd* | alpha*-*-openbsd*)
 188         COREFILE=netbsd-core.lo
 189         ;;
 190   alpha*-*-*)           COREFILE=osf-core.lo ;;
 191   arm-*-freebsd* | arm-*-kfreebsd*-gnu)
 192                         COREFILE='' ;;
 193   arm-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 194   arm-*-riscix)         COREFILE=trad-core.lo ;;
 195   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 196   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 197   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 198   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 199                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 200   hppa*-*-netbsd* | hppa*-*-openbsd*)
 201         COREFILE=netbsd-core.lo
 202         ;;
 203
 204   i370-*-*)
 205         COREFILE=trad-core.lo
 206         TRAD_HEADER='"hosts/i370linux.h"'
 207         ;;
 208
 209 changequote(,)dnl
 210   i[3-7]86-sequent-bsd*)
 211 changequote([,])dnl
 212         COREFILE=trad-core.lo
 213         TRAD_HEADER='"hosts/symmetry.h"'
 214         ;;
 215 changequote(,)dnl
 216   i[3-7]86-sequent-sysv4*) ;;
 217   i[3-7]86-sequent-sysv*)
 218 changequote([,])dnl
 219         COREFILE=trad-core.lo
 220         TRAD_HEADER='"hosts/symmetry.h"'
 221         ;;
 222 changequote(,)dnl
 223   i[3-7]86-*-bsdi)
 224 changequote([,])dnl
 225         COREFILE=
 226         ;;
 227 changequote(,)dnl
 228   i[3-7]86-*-bsd* | i[3-7]86-*-freebsd[123] | i[3-7]86-*-freebsd[123]\.* | i[3-7]86-*-freebsd4\.[01234] | i[3-7]86-*-freebsd4\.[01234]\.* | i[3-7]86-*-freebsd*aout*)
 229 changequote([,])dnl
 230         COREFILE=trad-core.lo
 231         TRAD_HEADER='"hosts/i386bsd.h"'
 232         ;;
 233 changequote(,)dnl
 234   i[3-7]86-*-freebsd* | i[3-7]86-*-kfreebsd*-gnu)
 235 changequote([,])dnl
 236         COREFILE=''
 237         TRAD_HEADER='"hosts/i386bsd.h"'
 238         ;;
 239 changequote(,)dnl
 240   i[3-7]86-*-netbsd* | i[3-7]86-*-knetbsd*-gnu | i[3-7]86-*-openbsd*)
 241 changequote([,])dnl
 242         COREFILE=netbsd-core.lo
 243         ;;
 244 changequote(,)dnl
 245   i[3-7]86-esix-sysv3*)
 246 changequote([,])dnl
 247         COREFILE=trad-core.lo
 248         TRAD_HEADER='"hosts/esix.h"'
 249         ;;
 250 changequote(,)dnl
 251   i[3-7]86-*-sco3.2v5*)
 252 changequote([,])dnl
 253         COREFILE=sco5-core.lo
 254         ;;
 255 changequote(,)dnl
 256   i[3-7]86-*-sco* | i[3-7]86-*-isc*)
 257 changequote([,])dnl
 258         COREFILE=trad-core.lo
 259         TRAD_HEADER='"hosts/i386sco.h"'
 260         ;;
 261 changequote(,)dnl
 262   i[3-7]86-*-mach3*)
 263 changequote([,])dnl
 264         COREFILE=trad-core.lo
 265         TRAD_HEADER='"hosts/i386mach3.h"'
 266         ;;
 267 changequote(,)dnl
 268   i[3-7]86-*-linux-*)
 269 changequote([,])dnl
 270         COREFILE=trad-core.lo
 271         TRAD_HEADER='"hosts/i386linux.h"'
 272         ;;
 273 changequote(,)dnl
 274   i[3-7]86-*-isc*)      COREFILE=trad-core.lo ;;
 275   i[3-7]86-*-aix*)      COREFILE=aix386-core.lo ;;
 276 changequote([,])dnl
 277   i860-*-mach3* | i860-*-osf1*)
 278         COREFILE=trad-core.lo
 279         TRAD_HEADER='"hosts/i860mach3.h"'
 280         ;;
 281   mips-*-netbsd* | mips*-*-openbsd*)
 282         COREFILE=netbsd-core.lo
 283         ;;
 284   mips-dec-*)
 285         COREFILE=trad-core.lo
 286         TRAD_HEADER='"hosts/decstation.h"'
 287         ;;
 288   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 289   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 290   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 291   mips-*-sysv4*)        ;;
 292   mips-*-sysv* | mips-*-riscos*)
 293         COREFILE=trad-core.lo
 294         TRAD_HEADER='"hosts/riscos.h"'
 295         ;;
 296   mips-sony-bsd*)
 297         COREFILE=trad-core.lo
 298         TRAD_HEADER='"hosts/news-mips.h"'
 299         ;;
 300   m68*-bull*-sysv*)
 301         COREFILE=trad-core.lo
 302         TRAD_HEADER='"hosts/dpx2.h"'
 303         ;;
 304   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 305   m68*-hp-bsd*)
 306         COREFILE=trad-core.lo
 307         TRAD_HEADER='"hosts/hp300bsd.h"'
 308         ;;
 309   m68*-*-linux-*)
 310         COREFILE=trad-core.lo
 311         TRAD_HEADER='"hosts/m68klinux.h"'
 312         ;;
 313   m68*-motorola-sysv*)
 314         COREFILE=trad-core.lo
 315         TRAD_HEADER='"hosts/delta68.h"'
 316         ;;
 317   m68*-sony-*)
 318         COREFILE=trad-core.lo
 319         TRAD_HEADER='"hosts/news.h"'
 320         ;;
 321   m68*-*-netbsd* | m68*-*-openbsd*)
 322         COREFILE=netbsd-core.lo
 323         ;;
 324   m68*-apple-aux*)
 325         COREFILE=trad-core.lo
 326         TRAD_HEADER='"hosts/m68kaux.h"'
 327         ;;
 328   m88*-*-sysv4*)
 329         ;;
 330   m88*-motorola-sysv*)
 331         COREFILE=ptrace-core.lo
 332         ;;
 333   m88*-*-mach3*)
 334         COREFILE=trad-core.lo
 335         TRAD_HEADER='"hosts/m88kmach3.h"'
 336         ;;
 337   m88*-*-openbsd*)
 338         COREFILE=netbsd-core.lo
 339         ;;
 340   ns32k-pc532-mach)
 341         COREFILE=trad-core.lo
 342         TRAD_HEADER='"hosts/pc532mach.h"'
 343         ;;
 344   ns32k-*-netbsd* | ns32k-*-openbsd*)
 345         COREFILE=netbsd-core.lo
 346         ;;
 347   rs6000-*-lynx*)
 348         COREFILE=lynx-core.lo
 349         ;;
 350   rs6000-*-aix5.* | powerpc-*-aix5.*)
 351         COREFILE=rs6000-core.lo
 352         COREFLAG="$COREFLAG -DAIX_5_CORE -DAIX_CORE_DUMPX_CORE"
 353         ;;
 354 changequote(,)dnl
 355   rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
 356 changequote([,])dnl
 357         COREFILE=rs6000-core.lo
 358         COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
 359         # Not all versions of AIX with -DAIX_CORE_DUMPX_CORE
 360         # have c_impl as a member of struct core_dumpx
 361         AC_MSG_CHECKING([for c_impl in struct core_dumpx])
 362         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <core.h>]], [[struct core_dumpx c; c.c_impl = 0;]])],[AC_DEFINE(HAVE_ST_C_IMPL, 1,
 363             [Define if struct core_dumpx has member c_impl])
 364           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 365         ;;
 366   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 367   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 368   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 369   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 370   powerpc-*-beos*)      ;;
 371   powerpc-*-freebsd* | powerpc-*-kfreebsd*-gnu)
 372                         COREFILE='' ;;
 373   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 374   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 375   s390*-*-*)            COREFILE=trad-core.lo ;;
 376   sh*-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 377   sparc-*-netbsd* | sparc*-*-openbsd*)
 378         COREFILE=netbsd-core.lo
 379         ;;
 380   tahoe-*-*)
 381         COREFILE=trad-core.lo
 382         TRAD_HEADER='"hosts/tahoe.h"'
 383         ;;
 384   vax-*-netbsd* | vax-*-openbsd*)
 385         COREFILE=netbsd-core.lo
 386         ;;
 387   vax-*-ultrix2*)
 388         COREFILE=trad-core.lo
 389         TRAD_HEADER='"hosts/vaxult2.h"'
 390         ;;
 391   vax-*-ultrix*)
 392         COREFILE=trad-core.lo
 393         TRAD_HEADER='"hosts/vaxult2.h"'
 394         ;;
 395   vax-*-linux-*)
 396         COREFILE=trad-core.lo
 397         TRAD_HEADER='"hosts/vaxlinux.h"'
 398         ;;
 399   vax-*-*)
 400         COREFILE=trad-core.lo
 401         TRAD_HEADER='"hosts/vaxbsd.h"'
 402         ;;
 403   x86_64-*-netbsd* | x86_64-*-openbsd*)
 404         COREFILE=netbsd-core.lo
 405         ;;
 406   esac
 407
 408   case "$COREFILE" in
 409   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 410   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 411   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 412   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 413   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 414   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 415   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 416   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 417   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 418   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 419   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 420   esac
 421
 422   # ELF corefile support has several flavors, but all of
 423   # them use something called <sys/procfs.h>
 424   AC_CHECK_HEADERS(sys/procfs.h)
 425   if test "$ac_cv_header_sys_procfs_h" = yes; then
 426     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 427     BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
 428     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 429     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
 430     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 431     BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
 432     BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
 433     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 434     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
 435     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 436     BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
 437     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 438     BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
 439     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 440     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 441     BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
 442   fi
 443 fi
 444 AC_SUBST(COREFILE)
 445 AC_SUBST(COREFLAG)
 446 if test -n "$TRAD_HEADER"; then
 447   AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
 448     [Name of host specific header file to include in trad-core.c.])
 449 fi
 450
 451 # Horrible hacks to build DLLs on Windows.
 452 WIN32LDFLAGS=
 453 WIN32LIBADD=
 454 case "${host}" in
 455 *-*-cygwin*)
 456   if test "$enable_shared" = "yes"; then
 457     WIN32LDFLAGS="-no-undefined"
 458     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 459   fi
 460   ;;
 461 *-*-linux*)
 462   # We borrow WIN32LIBADD so that the shared libbfd won't depend on
 463   # libiberty.a.
 464   case "${host}" in
 465   mips*-*-linux*)
 466     # Linux/MIPS uses PIC by default.
 467     if test "$enable_shared" = "yes"; then
 468       WIN32LIBADD="-L../libiberty -liberty"
 469     fi
 470     ;;
 471   *)
 472 changequote(,)dnl
 473     x=`sed -n -e 's/^[  ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 474 changequote([,])dnl
 475     if test -n "$x"; then
 476       WIN32LIBADD="-L../libiberty/pic -liberty"
 477     fi
 478   ;;
 479   esac
 480   ;;
 481 esac
 482 AC_SUBST(WIN32LDFLAGS)
 483 AC_SUBST(WIN32LIBADD)
 484
 485 # target stuff:
 486
 487 # Canonicalize the secondary target names.
 488 if test -n "$enable_targets" ; then
 489     for targ in `echo $enable_targets | sed 's/,/ /g'`
 490     do
 491         result=`$ac_config_sub $targ 2>/dev/null`
 492         if test -n "$result" ; then
 493             canon_targets="$canon_targets $result"
 494         else
 495             # Allow targets that config.sub doesn't recognize, like "all".
 496             canon_targets="$canon_targets $targ"
 497         fi
 498     done
 499 fi
 500
 501 all_targets=false
 502 defvec=
 503 selvecs=
 504 assocvecs=
 505 selarchs=
 506 TDEFINES=
 507 for targ in $target $canon_targets
 508 do
 509     if test "x$targ" = "xall"; then
 510         all_targets=true
 511         assocvecs="$assocvecs $targ_defvec $targ_selvecs"
 512     else
 513         . $srcdir/config.bfd
 514         if test "x$targ" = "x$target"; then
 515             defvec=$targ_defvec
 516         fi
 517         selvecs="$selvecs $targ_defvec $targ_selvecs"
 518         selarchs="$selarchs $targ_archs"
 519         TDEFINES="$TDEFINES $targ_cflags"
 520     fi
 521 done
 522 AC_SUBST(TDEFINES)
 523
 524 # This processing still needs to be done if we're to decide properly whether
 525 # 64-bit support needs to be compiled in.  Currently, it will be included if
 526 # the default or any other explicitly requested target requires it; it
 527 # will not be included on a 32-bit host if no 64-bit target is requested, and
 528 # no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
 529 # used.
 530
 531 # uniq the default and selected vectors in all the configured targets.
 532 f=""
 533 for i in $selvecs ; do
 534     case " $f " in
 535     *" $i "*) ;;
 536     *) f="$f $i" ;;
 537     esac
 538 done
 539 selvecs="$f"
 540
 541
 542 # uniq the associated vectors in all the configured targets.
 543 f=""
 544 for i in $assocvecs ; do
 545     case " $f " in
 546     *" $i "*) ;;
 547     *) f="$f $i" ;;
 548     esac
 549 done
 550 assocvecs="$f"
 551
 552
 553 # uniq the architectures in all the configured targets.
 554 f=""
 555 for i in $selarchs ; do
 556     case " $f " in
 557     *" $i "*) ;;
 558     *) f="$f $i" ;;
 559     esac
 560 done
 561 selarchs="$f"
 562
 563 # Target backend .o files.
 564 tb=
 565
 566 elf="elf.lo elflink.lo elf-strtab.lo elf-eh-frame.lo dwarf1.lo"
 567
 568 for vec in $selvecs
 569 do
 570     target_size=32
 571     case "$vec" in
 572     # This list is alphabetized to make it easy to compare
 573     # with the two vector lists in targets.c.  For the same reason,
 574     # use one entry per line, even though this leads to long lines.
 575     a29kcoff_big_vec)           tb="$tb coff-a29k.lo cofflink.lo" ;;
 576     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 577     aix5coff64_vec)             tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 578     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 579     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 580     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 581     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 582     arm_epoc_pe_big_vec)        tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 583     arm_epoc_pe_little_vec)     tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 584     arm_epoc_pei_big_vec)       tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 585     arm_epoc_pei_little_vec)    tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 586     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 587     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 588     armnetbsd_vec)              tb="$tb armnetbsd.lo aout32.lo" ;;
 589     armpe_big_vec)              tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 590     armpe_little_vec)           tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 591     armpei_big_vec)             tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 592     armpei_little_vec)          tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 593     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 594     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 595     bfd_efi_app_ia32_vec)       tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
 596     bfd_efi_app_ia64_vec)       tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"; target_size=64 ;;
 597     bfd_elf32_am33lin_vec)      tb="$tb elf32-am33lin.lo elf32.lo $elf" ;;
 598     bfd_elf32_avr_vec)          tb="$tb elf32-avr.lo elf32.lo $elf" ;;
 599     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 600     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 601     bfd_elf32_bigarm_vec)       tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 602     bfd_elf32_bigarm_symbian_vec)
 603                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 604     bfd_elf32_bigarm_vxworks_vec)
 605                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 606     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 607     bfd_elf32_cr16c_vec)        tb="$tb elf32-cr16c.lo elf32.lo $elf" ;;
 608     bfd_elf32_cris_vec)         tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 609     bfd_elf32_crx_vec)          tb="$tb elf32-crx.lo elf32.lo $elf" ;;
 610     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 611     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 612     bfd_elf32_dlx_big_vec)      tb="$tb elf32-dlx.lo elf32.lo $elf" ;;
 613     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 614     bfd_elf32_frv_vec)          tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 615     bfd_elf32_frvfdpic_vec)     tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 616     bfd_elf32_h8300_vec)        tb="$tb elf32-h8300.lo elf32.lo $elf" ;;
 617     bfd_elf32_hppa_linux_vec)   tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 618     bfd_elf32_hppa_nbsd_vec)    tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 619     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 620     bfd_elf32_i370_vec)         tb="$tb elf32-i370.lo elf32.lo $elf" ;;
 621     bfd_elf32_i386_freebsd_vec) tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 622     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 623     bfd_elf32_i860_little_vec)  tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 624     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 625     bfd_elf32_i960_vec)         tb="$tb elf32-i960.lo elf32.lo $elf" ;;
 626     bfd_elf32_ia64_big_vec)     tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
 627     bfd_elf32_ia64_hpux_big_vec) tb="$tb elf32-ia64.lo elf32.lo $elf";;
 628     bfd_elf32_ip2k_vec)         tb="$tb elf32-ip2k.lo elf32.lo $elf" ;;
 629     bfd_elf32_iq2000_vec)       tb="$tb elf32-iq2000.lo elf32.lo $elf" ;;
 630     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 631     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 632     bfd_elf32_littlearm_symbian_vec)
 633                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 634     bfd_elf32_littlearm_vxworks_vec)
 635                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 636     bfd_elf32_littlearm_vec)    tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 637     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 638     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 639     bfd_elf32_m32rle_vec)       tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 640     bfd_elf32_m32rlin_vec)      tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 641     bfd_elf32_m32rlelin_vec)    tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 642     bfd_elf32_m68hc11_vec)      tb="$tb elf32-m68hc11.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 643     bfd_elf32_m68hc12_vec)      tb="$tb elf32-m68hc12.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 644     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 645     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 646     bfd_elf32_mcore_big_vec)    tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 647     bfd_elf32_mcore_little_vec) tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 648     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 649     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 650     bfd_elf32_msp430_vec)       tb="$tb elf32-msp430.lo elf32.lo $elf" ;;
 651     bfd_elf32_nbigmips_vec)     tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 652     bfd_elf32_nlittlemips_vec)  tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 653     bfd_elf32_ntradbigmips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 654     bfd_elf32_ntradlittlemips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 655     bfd_elf32_openrisc_vec)     tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
 656     bfd_elf32_or32_big_vec)     tb="$tb elf32-or32.lo elf32.lo $elf" ;;
 657     bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
 658     bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
 659     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 660     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 661     bfd_elf32_s390_vec)         tb="$tb elf32-s390.lo elf32.lo $elf" ;;
 662     # FIXME: We include cofflink.lo not because it's needed for
 663     # bfd_elf32_sh64[l]_vec, but because we include bfd_elf32_sh[l]_vec
 664     # which needs it but does not list it.  Should be fixed in right place.
 665     bfd_elf32_sh64_vec)         tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 666     bfd_elf32_sh64l_vec)        tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 667     bfd_elf32_sh64lin_vec)      tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 668     bfd_elf32_sh64blin_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 669     bfd_elf32_sh64lnbsd_vec)    tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 670     bfd_elf32_sh64nbsd_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 671     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 672     bfd_elf32_shblin_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 673     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 674     bfd_elf32_shl_symbian_vec)  tb="$tb elf32-sh-symbian.lo elf32-sh64-com.lo elf32.lo $elf coff-sh.lo" ;;
 675     bfd_elf32_shlin_vec)        tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 676     bfd_elf32_shlnbsd_vec)      tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 677     bfd_elf32_shnbsd_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 678     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elf32.lo $elf" ;;
 679     bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 680     bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 681     bfd_elf32_us_cris_vec)      tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 682     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 683     bfd_elf32_vax_vec)          tb="$tb elf32-vax.lo elf32.lo $elf" ;;
 684     bfd_elf32_xstormy16_vec)    tb="$tb elf32-xstormy16.lo elf32.lo $elf" ;;
 685     bfd_elf32_xtensa_le_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 686     bfd_elf32_xtensa_be_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 687     bfd_elf64_alpha_freebsd_vec) tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 688     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 689     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 690     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 691     bfd_elf64_hppa_linux_vec)   tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 692     bfd_elf64_hppa_vec)         tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 693     bfd_elf64_ia64_big_vec)     tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 694     bfd_elf64_ia64_hpux_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 695     bfd_elf64_ia64_little_vec)  tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 696     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 697     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 698     bfd_elf64_mmix_vec)         tb="$tb elf64-mmix.lo elf64.lo $elf" target_size=64 ;;
 699     bfd_elf64_powerpc_vec)      tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 700     bfd_elf64_powerpcle_vec)    tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf" target_size=64 ;;
 701     bfd_elf64_s390_vec)         tb="$tb elf64-s390.lo elf64.lo $elf"; target_size=64 ;;
 702     bfd_elf64_sh64_vec)         tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 703     bfd_elf64_sh64l_vec)        tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 704     bfd_elf64_sh64lin_vec)      tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 705     bfd_elf64_sh64blin_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 706     bfd_elf64_sh64lnbsd_vec)    tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 707     bfd_elf64_sh64nbsd_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 708     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elf64.lo $elf"; target_size=64 ;;
 709     bfd_elf64_tradbigmips_vec)  tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 710     bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 711     bfd_elf64_x86_64_vec)       tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
 712     bfd_mmo_vec)                tb="$tb mmo.lo" target_size=64 ;;
 713     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 714     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 715     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 716     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 717     cris_aout_vec)              tb="$tb aout-cris.lo" ;;
 718     demo_64_vec)                tb="$tb demo64.lo aout64.lo"; target_size=64 ;;
 719     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 720     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 721     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 722     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"; target_size=64 ;;
 723     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 724     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 725     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 726     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 727     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 728     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 729     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 730     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 731     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 732     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 733     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 734     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 735     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 736     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 737     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 738     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 739     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 740     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 741     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 742     i386pe_vec)                 tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
 743     i386pei_vec)                tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
 744     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 745     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 746     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 747     ieee_vec)                   tb="$tb ieee.lo" ;;
 748     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 749     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 750     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 751     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 752     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 753     m68klynx_aout_vec)          tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
 754     m68klynx_coff_vec)          tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
 755     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 756     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 757     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 758     m88kmach3_vec)              tb="$tb m88kmach3.lo aout32.lo" ;;
 759     m88kopenbsd_vec)            tb="$tb m88kopenbsd.lo aout32.lo" ;;
 760     maxqcoff_vec)               tb="$tb coff-maxq.lo" ;;
 761     mach_o_be_vec)              tb="$tb mach-o.lo" ;;
 762     mach_o_le_vec)              tb="$tb mach-o.lo" ;;
 763     mach_o_fat_vec)             tb="$tb mach-o.lo" ;;
 764     mcore_pe_big_vec)           tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 765     mcore_pe_little_vec)        tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 766     mcore_pei_big_vec)          tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 767     mcore_pei_little_vec)       tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 768     mipslpe_vec)                tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
 769     mipslpei_vec)               tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
 770     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 771     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"; target_size=64 ;;
 772     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 773     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 774     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 775     or32coff_big_vec)           tb="$tb coff-or32.lo cofflink.lo" ;;
 776     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 777     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 778     pef_vec)                    tb="$tb pef.lo" ;;
 779     pef_xlib_vec)               tb="$tb pef.lo" ;;
 780     pdp11_aout_vec)             tb="$tb pdp11.lo" ;;
 781     pmac_xcoff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 782     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 783     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 784     rs6000coff64_vec)           tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 785     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 786     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 787     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 788     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 789     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 790     shlpe_vec)                  tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 791     shlpei_vec)                 tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 792     som_vec)                    tb="$tb som.lo" ;;
 793     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 794     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 795     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 796     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 797     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 798     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 799     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 800     sym_vec)                    tb="$tb xsym.lo" ;;
 801     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 802     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 803     tic4x_coff0_vec)            tb="$tb coff-tic4x.lo" ;;
 804     tic4x_coff0_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 805     tic4x_coff1_vec)            tb="$tb coff-tic4x.lo" ;;
 806     tic4x_coff1_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 807     tic4x_coff2_vec)            tb="$tb coff-tic4x.lo" ;;
 808     tic4x_coff2_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 809     tic54x_coff0_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 810     tic54x_coff0_vec)           tb="$tb coff-tic54x.lo" ;;
 811     tic54x_coff1_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 812     tic54x_coff1_vec)           tb="$tb coff-tic54x.lo" ;;
 813     tic54x_coff2_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 814     tic54x_coff2_vec)           tb="$tb coff-tic54x.lo" ;;
 815     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 816     vaxnetbsd_vec)              tb="$tb vaxnetbsd.lo aout32.lo" ;;
 817     vax1knetbsd_vec)            tb="$tb vax1knetbsd.lo aout32.lo" ;;
 818     vaxbsd_vec)                 tb="$tb vaxbsd.lo aout32.lo" ;;
 819     versados_vec)               tb="$tb versados.lo" ;;
 820     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"; target_size=64 ;;
 821     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 822     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 823     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 824     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo" ;;
 825
 826     # These appear out of order in targets.c
 827     srec_vec)                   tb="$tb srec.lo" ;;
 828     symbolsrec_vec)             tb="$tb srec.lo" ;;
 829     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 830     cisco_core_big_vec)         tb="$tb cisco-core.lo" ;;
 831     cisco_core_little_vec)      tb="$tb cisco-core.lo" ;;
 832
 833     "")                 ;;
 834     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 835     esac
 836
 837     if test ${target_size} = 64; then
 838         target64=true
 839     fi
 840     if test x"${vec}" = x"${defvec}"; then
 841         bfd_default_target_size=${target_size}
 842     fi
 843 done
 844
 845 # Target architecture .o files.
 846 # A couple of CPUs use shorter file names to avoid problems on DOS
 847 # filesystems.
 848 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 849
 850 # Weed out duplicate .o files.
 851 f=""
 852 for i in $tb ; do
 853     case " $f " in
 854     *" $i "*) ;;
 855     *) f="$f $i" ;;
 856     esac
 857 done
 858 tb="$f"
 859
 860 f=""
 861 for i in $ta ; do
 862     case " $f " in
 863     *" $i "*) ;;
 864     *) f="$f $i" ;;
 865     esac
 866 done
 867 ta="$f"
 868
 869 bfd_backends="$tb"
 870 bfd_machines="$ta"
 871
 872 if test x${all_targets} = xtrue ; then
 873   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 874   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 875   selvecs=
 876   havevecs=
 877   selarchs=
 878   test -n "$assocvecs" &&
 879     assocvecs=`echo $assocvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 880 else    # all_targets is true
 881   # Only set these if they will be nonempty, for the clever echo.
 882   havevecs=
 883   assocvecs=
 884   test -n "$selvecs" &&
 885     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 886   test -n "$selvecs" &&
 887     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 888   test -n "$selarchs" &&
 889     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 890 fi      # all_targets is true
 891
 892 case ${host64}-${target64}-${want64} in
 893   *true*)
 894     wordsize=64
 895     bfd_libs='$(BFD64_LIBS) $(BFD32_LIBS)'
 896     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 897     if test $BFD_HOST_64_BIT_DEFINED = 0; then
 898       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 899       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 900     fi
 901     if test -n "$GCC" ; then
 902        bad_64bit_gcc=no;
 903        AC_MSG_CHECKING([for gcc version with buggy 64-bit support])
 904        # Add more tests for gcc versions with non-working 64-bit support here.
 905        AC_EGREP_CPP([: 2 : 91 : 1 :],[:__GNUC__:__GNUC_MINOR__:__i386__:],
 906                     bad_64bit_gcc=yes;
 907                     AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
 908                     AC_MSG_RESULT(no))
 909        if test $bad_64bit_gcc = yes ; then
 910          AC_MSG_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
 911        fi
 912     fi
 913     ;;
 914   false-false-false)
 915     wordsize=32
 916     bfd_libs='$(BFD32_LIBS)'
 917     all_backends='$(BFD32_BACKENDS)'
 918     ;;
 919 esac
 920
 921 AC_SUBST(wordsize)
 922 AC_SUBST(bfd_libs)
 923 AC_SUBST(all_backends)
 924 AC_SUBST(bfd_backends)
 925 AC_SUBST(bfd_machines)
 926 AC_SUBST(bfd_default_target_size)
 927
 928 # Determine the host dependant file_ptr a.k.a. off_t type.  In order
 929 # prefer: off64_t - if ftello64 and fseeko64, off_t - if ftello and
 930 # fseeko, long.  This assumes that sizeof off_t is .ge. sizeof long.
 931 # Hopefully a reasonable assumption since fseeko et.al. should be
 932 # upward compatible.
 933 AC_CHECK_FUNCS(ftello ftello64 fseeko fseeko64)
 934 if test x"$ac_cv_func_ftello" = xyes -a x"$ac_cv_func_fseeko" = xyes; then
 935     AC_COMPILE_CHECK_SIZEOF(off_t)
 936 fi
 937 AC_MSG_CHECKING([file_ptr type])
 938 bfd_file_ptr="long"
 939 bfd_ufile_ptr="unsigned long"
 940 if test x"$ac_cv_func_ftello64" = xyes -a x"$ac_cv_func_fseeko64" = xyes \
 941         -o x"${ac_cv_sizeof_off_t}" = x8; then
 942     bfd_file_ptr=BFD_HOST_64_BIT
 943     bfd_ufile_ptr=BFD_HOST_U_64_BIT
 944 fi
 945 AC_MSG_RESULT($bfd_file_ptr)
 946 AC_SUBST(bfd_file_ptr)
 947 AC_SUBST(bfd_ufile_ptr)
 948
 949
 950 tdefaults=""
 951 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 952 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 953 test -n "${assocvecs}" && tdefaults="${tdefaults} -DASSOCIATED_VECS='${assocvecs}'"
 954 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 955 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 956 AC_SUBST(tdefaults)
 957
 958 dnl AC_CHECK_HEADERS(sys/mman.h)
 959 AC_FUNC_MMAP
 960 AC_CHECK_FUNCS(madvise mprotect)
 961 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 962   true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
 963 esac
 964
 965 rm -f doc/config.status
 966 AC_CONFIG_FILES([Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in])
 967 AC_CONFIG_COMMANDS([default],[[sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' -e '/BLD-POTFILES =/r po/BLD-POTFILES' po/Makefile.in > po/Makefile]],[[]])
 968 AC_OUTPUT
 969