bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.13)
   5 AC_INIT(libbfd.c)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_ISC_POSIX
   9
  10 AM_INIT_AUTOMAKE(bfd, 2.15.91)
  11
  12 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  13 dnl to call AC_CHECK_PROG.
  14 AC_CHECK_TOOL(AR, ar)
  15 AC_CHECK_TOOL(RANLIB, ranlib, :)
  16
  17 dnl Default to a non shared library.  This may be overridden by the
  18 dnl configure option --enable-shared.
  19 AM_DISABLE_SHARED
  20
  21 AM_PROG_LIBTOOL
  22
  23 AC_ARG_ENABLE(64-bit-bfd,
  24 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  25 [case "${enableval}" in
  26   yes)  want64=true  ;;
  27   no)   want64=false ;;
  28   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  29 esac],[want64=false])dnl
  30 AC_ARG_ENABLE(targets,
  31 [  --enable-targets        alternative target configurations],
  32 [case "${enableval}" in
  33   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  34             ;;
  35   no)       enable_targets= ;;
  36   *)        enable_targets=$enableval ;;
  37 esac])dnl
  38 AC_ARG_ENABLE(commonbfdlib,
  39 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  40 [case "${enableval}" in
  41   yes) commonbfdlib=true ;;
  42   no)  commonbfdlib=false ;;
  43   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  44 esac])dnl
  45 AC_ARG_WITH(mmap,
  46 [  --with-mmap             try using mmap for BFD input files if available],
  47 [case "${withval}" in
  48   yes)  want_mmap=true ;;
  49   no)   want_mmap=false ;;
  50   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  51 esac],[want_mmap=false])dnl
  52
  53 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  54 AC_ARG_ENABLE(build-warnings,
  55 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  56 [case "${enableval}" in
  57   yes)  ;;
  58   no)   build_warnings="-w";;
  59   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  60         build_warnings="${build_warnings} ${t}";;
  61   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  62         build_warnings="${t} ${build_warnings}";;
  63   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  64 esac
  65 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  66   echo "Setting warning flags = $build_warnings" 6>&1
  67 fi])dnl
  68 WARN_CFLAGS=""
  69 if test "x${build_warnings}" != x && test "x$GCC" = xyes ; then
  70     WARN_CFLAGS="${build_warnings}"
  71 fi
  72 AC_SUBST(WARN_CFLAGS)
  73
  74 AM_CONFIG_HEADER(config.h:config.in)
  75
  76 if test -z "$target" ; then
  77     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  78 fi
  79
  80 AM_MAINTAINER_MODE
  81 AM_INSTALL_LIBBFD
  82 AC_EXEEXT
  83
  84 host64=false
  85 target64=false
  86 bfd_default_target_size=32
  87
  88 # host stuff:
  89
  90 AC_PROG_CC
  91
  92 ALL_LINGUAS="fr tr ja es sv da zh_CN ro"
  93 CY_GNU_GETTEXT
  94
  95 # Permit host specific settings.
  96 . ${srcdir}/configure.host
  97
  98 AC_SUBST(HDEFINES)
  99 AC_PROG_INSTALL
 100
 101 BFD_HOST_64BIT_LONG=0
 102 BFD_HOST_LONG_LONG=0
 103 BFD_HOST_64_BIT_DEFINED=0
 104 BFD_HOST_64_BIT=
 105 BFD_HOST_U_64_BIT=
 106
 107 AC_MSG_CHECKING([for long long])
 108 AC_CACHE_VAL(bfd_cv_has_long_long,
 109 [AC_TRY_COMPILE(,
 110 [unsigned long long ll = 18446744073709551615ULL;],
 111 bfd_cv_has_long_long=yes, bfd_cv_has_long_long=no)])
 112 AC_MSG_RESULT($bfd_cv_has_long_long)
 113 if test $bfd_cv_has_long_long = yes; then
 114   BFD_HOST_LONG_LONG=1
 115   AC_COMPILE_CHECK_SIZEOF(long long)
 116 fi
 117
 118 AC_COMPILE_CHECK_SIZEOF(long)
 119 if test "x${ac_cv_sizeof_long}" = "x8"; then
 120   host64=true
 121   BFD_HOST_64BIT_LONG=1
 122   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long"
 123   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long"
 124 elif test "x${ac_cv_sizeof_long_long}" = "x8"; then
 125   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long long"
 126   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long long"
 127 fi
 128
 129 if test -n "${HOST_64BIT_TYPE}" -a -n "${HOST_U_64BIT_TYPE}"; then
 130   BFD_HOST_64_BIT_DEFINED=1
 131   BFD_HOST_64_BIT="${HOST_64BIT_TYPE}"
 132   BFD_HOST_U_64_BIT="${HOST_U_64BIT_TYPE}"
 133 fi
 134
 135 AC_SUBST(BFD_HOST_64BIT_LONG)
 136 AC_SUBST(BFD_HOST_LONG_LONG)
 137 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 138 AC_SUBST(BFD_HOST_64_BIT)
 139 AC_SUBST(BFD_HOST_U_64_BIT)
 140
 141 BFD_CC_FOR_BUILD
 142
 143 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 144 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 145 AC_HEADER_TIME
 146 AC_HEADER_DIRENT
 147 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
 148 AC_CHECK_FUNCS(strtoull)
 149
 150 BFD_BINARY_FOPEN
 151
 152 BFD_NEED_DECLARATION(strstr)
 153 BFD_NEED_DECLARATION(malloc)
 154 BFD_NEED_DECLARATION(realloc)
 155 BFD_NEED_DECLARATION(free)
 156 BFD_NEED_DECLARATION(getenv)
 157
 158 # If we are configured native, pick a core file support file.
 159 COREFILE=
 160 COREFLAG=
 161 TRAD_HEADER=
 162 if test "${target}" = "${host}"; then
 163   case "${host}" in
 164   alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu)
 165         COREFILE=''
 166         ;;
 167   alpha*-*-linux-gnu*)
 168         COREFILE=trad-core.lo
 169         TRAD_HEADER='"hosts/alphalinux.h"'
 170         ;;
 171   alpha*-*-netbsd* | alpha*-*-openbsd*)
 172         COREFILE=netbsd-core.lo
 173         ;;
 174   alpha*-*-*)           COREFILE=osf-core.lo ;;
 175   arm-*-freebsd* | arm-*-kfreebsd*-gnu)
 176                         COREFILE='' ;;
 177   arm-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 178   arm-*-riscix)         COREFILE=trad-core.lo ;;
 179   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 180   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 181   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 182   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 183                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 184   i370-*-*)
 185         COREFILE=trad-core.lo
 186         TRAD_HEADER='"hosts/i370linux.h"'
 187         ;;
 188
 189 changequote(,)dnl
 190   i[3-7]86-sequent-bsd*)
 191 changequote([,])dnl
 192         COREFILE=trad-core.lo
 193         TRAD_HEADER='"hosts/symmetry.h"'
 194         ;;
 195 changequote(,)dnl
 196   i[3-7]86-sequent-sysv4*) ;;
 197   i[3-7]86-sequent-sysv*)
 198 changequote([,])dnl
 199         COREFILE=trad-core.lo
 200         TRAD_HEADER='"hosts/symmetry.h"'
 201         ;;
 202 changequote(,)dnl
 203   i[3-7]86-*-bsdi)
 204 changequote([,])dnl
 205         COREFILE=
 206         ;;
 207 changequote(,)dnl
 208   i[3-7]86-*-bsd* | i[3-7]86-*-freebsd[123] | i[3-7]86-*-freebsd[123]\.* | i[3-7]86-*-freebsd4\.[01234]* | i[3-7]86-*-freebsd*aout*)
 209 changequote([,])dnl
 210         COREFILE=trad-core.lo
 211         TRAD_HEADER='"hosts/i386bsd.h"'
 212         ;;
 213 changequote(,)dnl
 214   i[3-7]86-*-freebsd* | i[3-7]86-*-kfreebsd*-gnu)
 215 changequote([,])dnl
 216         COREFILE=''
 217         TRAD_HEADER='"hosts/i386bsd.h"'
 218         ;;
 219 changequote(,)dnl
 220   i[3-7]86-*-netbsd* | i[3-7]86-*-knetbsd*-gnu | i[3-7]86-*-openbsd*)
 221 changequote([,])dnl
 222         COREFILE=netbsd-core.lo
 223         ;;
 224 changequote(,)dnl
 225   i[3-7]86-esix-sysv3*)
 226 changequote([,])dnl
 227         COREFILE=trad-core.lo
 228         TRAD_HEADER='"hosts/esix.h"'
 229         ;;
 230 changequote(,)dnl
 231   i[3-7]86-*-sco3.2v5*)
 232 changequote([,])dnl
 233         COREFILE=sco5-core.lo
 234         ;;
 235 changequote(,)dnl
 236   i[3-7]86-*-sco* | i[3-7]86-*-isc*)
 237 changequote([,])dnl
 238         COREFILE=trad-core.lo
 239         TRAD_HEADER='"hosts/i386sco.h"'
 240         ;;
 241 changequote(,)dnl
 242   i[3-7]86-*-mach3*)
 243 changequote([,])dnl
 244         COREFILE=trad-core.lo
 245         TRAD_HEADER='"hosts/i386mach3.h"'
 246         ;;
 247 changequote(,)dnl
 248   i[3-7]86-*-linux-gnu*)
 249 changequote([,])dnl
 250         COREFILE=trad-core.lo
 251         TRAD_HEADER='"hosts/i386linux.h"'
 252         ;;
 253 changequote(,)dnl
 254   i[3-7]86-*-isc*)      COREFILE=trad-core.lo ;;
 255   i[3-7]86-*-aix*)      COREFILE=aix386-core.lo ;;
 256 changequote([,])dnl
 257   i860-*-mach3* | i860-*-osf1*)
 258         COREFILE=trad-core.lo
 259         TRAD_HEADER='"hosts/i860mach3.h"'
 260         ;;
 261   mips-*-netbsd* | mips*-*-openbsd*)
 262         COREFILE=netbsd-core.lo
 263         ;;
 264   mips-dec-*)
 265         COREFILE=trad-core.lo
 266         TRAD_HEADER='"hosts/decstation.h"'
 267         ;;
 268   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 269   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 270   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 271   mips-*-sysv4*)        ;;
 272   mips-*-sysv* | mips-*-riscos*)
 273         COREFILE=trad-core.lo
 274         TRAD_HEADER='"hosts/riscos.h"'
 275         ;;
 276   mips-sony-bsd*)
 277         COREFILE=trad-core.lo
 278         TRAD_HEADER='"hosts/news-mips.h"'
 279         ;;
 280   m68*-bull*-sysv*)
 281         COREFILE=trad-core.lo
 282         TRAD_HEADER='"hosts/dpx2.h"'
 283         ;;
 284   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 285   m68*-hp-bsd*)
 286         COREFILE=trad-core.lo
 287         TRAD_HEADER='"hosts/hp300bsd.h"'
 288         ;;
 289   m68*-*-linux-gnu*)
 290         COREFILE=trad-core.lo
 291         TRAD_HEADER='"hosts/m68klinux.h"'
 292         ;;
 293   m68*-motorola-sysv*)
 294         COREFILE=trad-core.lo
 295         TRAD_HEADER='"hosts/delta68.h"'
 296         ;;
 297   m68*-sony-*)
 298         COREFILE=trad-core.lo
 299         TRAD_HEADER='"hosts/news.h"'
 300         ;;
 301   m68*-*-netbsd* | m68*-*-openbsd*)
 302         COREFILE=netbsd-core.lo
 303         ;;
 304   m68*-apple-aux*)
 305         COREFILE=trad-core.lo
 306         TRAD_HEADER='"hosts/m68kaux.h"'
 307         ;;
 308   m88*-*-sysv4*)
 309         ;;
 310   m88*-motorola-sysv*)
 311         COREFILE=ptrace-core.lo
 312         ;;
 313   m88*-*-mach3*)
 314         COREFILE=trad-core.lo
 315         TRAD_HEADER='"hosts/m88kmach3.h"'
 316         ;;
 317   ns32k-pc532-mach)
 318         COREFILE=trad-core.lo
 319         TRAD_HEADER='"hosts/pc532mach.h"'
 320         ;;
 321   ns32k-*-netbsd* | ns32k-*-openbsd*)
 322         COREFILE=netbsd-core.lo
 323         ;;
 324   rs6000-*-lynx*)
 325         COREFILE=lynx-core.lo
 326         ;;
 327   rs6000-*-aix5.* | powerpc-*-aix5.*)
 328         COREFILE=rs6000-core.lo
 329         COREFLAG="$COREFLAG -DAIX_5_CORE -DAIX_CORE_DUMPX_CORE"
 330         ;;
 331 changequote(,)dnl
 332   rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
 333 changequote([,])dnl
 334         COREFILE=rs6000-core.lo
 335         COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
 336         # Not all versions of AIX with -DAIX_CORE_DUMPX_CORE
 337         # have c_impl as a member of struct core_dumpx
 338         AC_MSG_CHECKING([for c_impl in struct core_dumpx])
 339         AC_TRY_COMPILE([#include <core.h>],
 340           [struct core_dumpx c; c.c_impl = 0;],
 341           [AC_DEFINE(HAVE_ST_C_IMPL, 1,
 342             [Define if struct core_dumpx has member c_impl])
 343           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 344         ;;
 345   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 346   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 347   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 348   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 349   powerpc-*-beos*)      ;;
 350   powerpc-*-freebsd* | powerpc-*-kfreebsd*-gnu)
 351                         COREFILE='' ;;
 352   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 353   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 354   s390*-*-*)            COREFILE=trad-core.lo ;;
 355   sh*-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 356   sparc-*-netbsd* | sparc*-*-openbsd*)
 357         COREFILE=netbsd-core.lo
 358         ;;
 359   tahoe-*-*)
 360         COREFILE=trad-core.lo
 361         TRAD_HEADER='"hosts/tahoe.h"'
 362         ;;
 363   vax-*-netbsd* | vax-*-openbsd*)
 364         COREFILE=netbsd-core.lo
 365         ;;
 366   vax-*-ultrix2*)
 367         COREFILE=trad-core.lo
 368         TRAD_HEADER='"hosts/vaxult2.h"'
 369         ;;
 370   vax-*-ultrix*)
 371         COREFILE=trad-core.lo
 372         TRAD_HEADER='"hosts/vaxult2.h"'
 373         ;;
 374   vax-*-linux-gnu*)
 375         COREFILE=trad-core.lo
 376         TRAD_HEADER='"hosts/vaxlinux.h"'
 377         ;;
 378   vax-*-*)
 379         COREFILE=trad-core.lo
 380         TRAD_HEADER='"hosts/vaxbsd.h"'
 381         ;;
 382   x86_64-*-netbsd* | x86_64-*-openbsd*)
 383         COREFILE=netbsd-core.lo
 384         ;;
 385   esac
 386
 387   case "$COREFILE" in
 388   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 389   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 390   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 391   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 392   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 393   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 394   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 395   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 396   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 397   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 398   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 399   esac
 400
 401   # ELF corefile support has several flavors, but all of
 402   # them use something called <sys/procfs.h>
 403   AC_CHECK_HEADERS(sys/procfs.h)
 404   if test "$ac_cv_header_sys_procfs_h" = yes; then
 405     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 406     BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
 407     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 408     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
 409     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 410     BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
 411     BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
 412     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 413     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
 414     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 415     BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
 416     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 417     BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
 418     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 419     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 420     BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
 421   fi
 422 fi
 423 AC_SUBST(COREFILE)
 424 AC_SUBST(COREFLAG)
 425 if test -n "$TRAD_HEADER"; then
 426   AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
 427     [Name of host specific header file to include in trad-core.c.])
 428 fi
 429
 430 # Horrible hacks to build DLLs on Windows.
 431 WIN32LDFLAGS=
 432 WIN32LIBADD=
 433 case "${host}" in
 434 *-*-cygwin*)
 435   if test "$enable_shared" = "yes"; then
 436     WIN32LDFLAGS="-no-undefined"
 437     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 438   fi
 439   ;;
 440 *-*-linux*)
 441   # We borrow WIN32LIBADD so that the shared libbfd won't depend on
 442   # libiberty.a.
 443   case "${host}" in
 444   mips*-*-linux*)
 445     # Linux/MIPS uses PIC by default.
 446     if test "$enable_shared" = "yes"; then
 447       WIN32LIBADD="-L../libiberty -liberty"
 448     fi
 449     ;;
 450   *)
 451 changequote(,)dnl
 452     x=`sed -n -e 's/^[  ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 453 changequote([,])dnl
 454     if test -n "$x"; then
 455       WIN32LIBADD="-L../libiberty/pic -liberty"
 456     fi
 457   ;;
 458   esac
 459   ;;
 460 esac
 461 AC_SUBST(WIN32LDFLAGS)
 462 AC_SUBST(WIN32LIBADD)
 463
 464 # target stuff:
 465
 466 # Canonicalize the secondary target names.
 467 if test -n "$enable_targets" ; then
 468     for targ in `echo $enable_targets | sed 's/,/ /g'`
 469     do
 470         result=`$ac_config_sub $targ 2>/dev/null`
 471         if test -n "$result" ; then
 472             canon_targets="$canon_targets $result"
 473         else
 474             # Allow targets that config.sub doesn't recognize, like "all".
 475             canon_targets="$canon_targets $targ"
 476         fi
 477     done
 478 fi
 479
 480 all_targets=false
 481 defvec=
 482 selvecs=
 483 assocvecs=
 484 selarchs=
 485 TDEFINES=
 486 for targ in $target $canon_targets
 487 do
 488     if test "x$targ" = "xall"; then
 489         all_targets=true
 490         assocvecs="$assocvecs $targ_defvec $targ_selvecs"
 491     else
 492         . $srcdir/config.bfd
 493         if test "x$targ" = "x$target"; then
 494             defvec=$targ_defvec
 495         fi
 496         selvecs="$selvecs $targ_defvec $targ_selvecs"
 497         selarchs="$selarchs $targ_archs"
 498         TDEFINES="$TDEFINES $targ_cflags"
 499     fi
 500 done
 501 AC_SUBST(TDEFINES)
 502
 503 # This processing still needs to be done if we're to decide properly whether
 504 # 64-bit support needs to be compiled in.  Currently, it will be included if
 505 # the default or any other explicitly requested target requires it; it
 506 # will not be included on a 32-bit host if no 64-bit target is requested, and
 507 # no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
 508 # used.
 509
 510 # uniq the default and selected vectors in all the configured targets.
 511 f=""
 512 for i in $selvecs ; do
 513     case " $f " in
 514     *" $i "*) ;;
 515     *) f="$f $i" ;;
 516     esac
 517 done
 518 selvecs="$f"
 519
 520
 521 # uniq the associated vectors in all the configured targets.
 522 f=""
 523 for i in $assocvecs ; do
 524     case " $f " in
 525     *" $i "*) ;;
 526     *) f="$f $i" ;;
 527     esac
 528 done
 529 assocvecs="$f"
 530
 531
 532 # uniq the architectures in all the configured targets.
 533 f=""
 534 for i in $selarchs ; do
 535     case " $f " in
 536     *" $i "*) ;;
 537     *) f="$f $i" ;;
 538     esac
 539 done
 540 selarchs="$f"
 541
 542 # Target backend .o files.
 543 tb=
 544
 545 elf="elf.lo elflink.lo elf-strtab.lo elf-eh-frame.lo dwarf1.lo"
 546
 547 for vec in $selvecs
 548 do
 549     target_size=32
 550     case "$vec" in
 551     # This list is alphabetized to make it easy to compare
 552     # with the two vector lists in targets.c.  For the same reason,
 553     # use one entry per line, even though this leads to long lines.
 554     a29kcoff_big_vec)           tb="$tb coff-a29k.lo cofflink.lo" ;;
 555     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 556     aix5coff64_vec)             tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 557     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 558     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 559     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 560     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 561     arm_epoc_pe_big_vec)        tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 562     arm_epoc_pe_little_vec)     tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 563     arm_epoc_pei_big_vec)       tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 564     arm_epoc_pei_little_vec)    tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 565     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 566     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 567     armnetbsd_vec)              tb="$tb armnetbsd.lo aout32.lo" ;;
 568     armpe_big_vec)              tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 569     armpe_little_vec)           tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 570     armpei_big_vec)             tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 571     armpei_little_vec)          tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 572     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 573     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 574     bfd_efi_app_ia32_vec)       tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
 575     bfd_efi_app_ia64_vec)       tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"; target_size=64 ;;
 576     bfd_elf32_am33lin_vec)      tb="$tb elf32-am33lin.lo elf32.lo $elf" ;;
 577     bfd_elf32_avr_vec)          tb="$tb elf32-avr.lo elf32.lo $elf" ;;
 578     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 579     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 580     bfd_elf32_bigarm_oabi_vec)  tb="$tb elfarm-oabi.lo elf32.lo $elf" ;;
 581     bfd_elf32_bigarm_vec)       tb="$tb elfarm-nabi.lo elf32.lo $elf" ;;
 582     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 583     bfd_elf32_cr16c_vec)        tb="$tb elf32-cr16c.lo elf32.lo $elf" ;;
 584     bfd_elf32_cris_vec)         tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 585     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 586     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 587     bfd_elf32_dlx_big_vec)      tb="$tb elf32-dlx.lo elf32.lo $elf" ;;
 588     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 589     bfd_elf32_frv_vec)          tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 590     bfd_elf32_frvfdpic_vec)     tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 591     bfd_elf32_h8300_vec)        tb="$tb elf32-h8300.lo elf32.lo $elf" ;;
 592     bfd_elf32_hppa_linux_vec)   tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 593     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 594     bfd_elf32_i370_vec)         tb="$tb elf32-i370.lo elf32.lo $elf" ;;
 595     bfd_elf32_i386_freebsd_vec) tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 596     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 597     bfd_elf32_i860_little_vec)  tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 598     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 599     bfd_elf32_i960_vec)         tb="$tb elf32-i960.lo elf32.lo $elf" ;;
 600     bfd_elf32_ia64_big_vec)     tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
 601     bfd_elf32_ia64_hpux_big_vec) tb="$tb elf32-ia64.lo elf32.lo $elf";;
 602     bfd_elf32_ip2k_vec)         tb="$tb elf32-ip2k.lo elf32.lo $elf" ;;
 603     bfd_elf32_iq2000_vec)       tb="$tb elf32-iq2000.lo elf32.lo $elf" ;;
 604     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 605     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 606     bfd_elf32_littlearm_oabi_vec) tb="$tb elfarm-oabi.lo elf32.lo $elf" ;;
 607     bfd_elf32_littlearm_vec)    tb="$tb elfarm-nabi.lo elf32.lo $elf" ;;
 608     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 609     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 610     bfd_elf32_m32rle_vec)       tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 611     bfd_elf32_m32rlin_vec)      tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 612     bfd_elf32_m32rlelin_vec)    tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 613     bfd_elf32_m68hc11_vec)      tb="$tb elf32-m68hc11.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 614     bfd_elf32_m68hc12_vec)      tb="$tb elf32-m68hc12.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 615     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 616     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 617     bfd_elf32_mcore_big_vec)    tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 618     bfd_elf32_mcore_little_vec) tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 619     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 620     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 621     bfd_elf32_msp430_vec)       tb="$tb elf32-msp430.lo elf32.lo $elf" ;;
 622     bfd_elf32_nbigmips_vec)     tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 623     bfd_elf32_nlittlemips_vec)  tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 624     bfd_elf32_ntradbigmips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 625     bfd_elf32_ntradlittlemips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 626     bfd_elf32_openrisc_vec)     tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
 627     bfd_elf32_or32_big_vec)     tb="$tb elf32-or32.lo elf32.lo $elf" ;;
 628     bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
 629     bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
 630     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 631     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 632     bfd_elf32_s390_vec)         tb="$tb elf32-s390.lo elf32.lo $elf" ;;
 633     # FIXME: We include cofflink.lo not because it's needed for
 634     # bfd_elf32_sh64[l]_vec, but because we include bfd_elf32_sh[l]_vec
 635     # which needs it but does not list it.  Should be fixed in right place.
 636     bfd_elf32_sh64_vec)         tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 637     bfd_elf32_sh64l_vec)        tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 638     bfd_elf32_sh64lin_vec)      tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 639     bfd_elf32_sh64blin_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 640     bfd_elf32_sh64lnbsd_vec)    tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 641     bfd_elf32_sh64nbsd_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 642     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 643     bfd_elf32_shblin_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 644     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 645     bfd_elf32_shlin_vec)        tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 646     bfd_elf32_shlnbsd_vec)      tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 647     bfd_elf32_shnbsd_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 648     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elf32.lo $elf" ;;
 649     bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 650     bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 651     bfd_elf32_us_cris_vec)      tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 652     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 653     bfd_elf32_vax_vec)          tb="$tb elf32-vax.lo elf32.lo $elf" ;;
 654     bfd_elf32_xstormy16_vec)    tb="$tb elf32-xstormy16.lo elf32.lo $elf" ;;
 655     bfd_elf32_xtensa_le_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 656     bfd_elf32_xtensa_be_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 657     bfd_elf64_alpha_freebsd_vec) tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 658     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 659     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 660     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 661     bfd_elf64_hppa_linux_vec)   tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 662     bfd_elf64_hppa_vec)         tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 663     bfd_elf64_ia64_big_vec)     tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 664     bfd_elf64_ia64_hpux_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 665     bfd_elf64_ia64_little_vec)  tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 666     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 667     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 668     bfd_elf64_mmix_vec)         tb="$tb elf64-mmix.lo elf64.lo $elf" target_size=64 ;;
 669     bfd_elf64_powerpc_vec)      tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 670     bfd_elf64_powerpcle_vec)    tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf" target_size=64 ;;
 671     bfd_elf64_s390_vec)         tb="$tb elf64-s390.lo elf64.lo $elf"; target_size=64 ;;
 672     bfd_elf64_sh64_vec)         tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 673     bfd_elf64_sh64l_vec)        tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 674     bfd_elf64_sh64lin_vec)      tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 675     bfd_elf64_sh64blin_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 676     bfd_elf64_sh64lnbsd_vec)    tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 677     bfd_elf64_sh64nbsd_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 678     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elf64.lo $elf"; target_size=64 ;;
 679     bfd_elf64_tradbigmips_vec)  tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 680     bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 681     bfd_elf64_x86_64_vec)       tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
 682     bfd_mmo_vec)                tb="$tb mmo.lo" target_size=64 ;;
 683     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 684     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 685     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 686     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 687     cris_aout_vec)              tb="$tb aout-cris.lo" ;;
 688     demo_64_vec)                tb="$tb demo64.lo aout64.lo"; target_size=64 ;;
 689     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 690     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 691     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 692     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"; target_size=64 ;;
 693     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 694     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 695     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 696     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 697     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 698     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 699     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 700     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 701     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 702     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 703     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 704     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 705     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 706     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 707     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 708     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 709     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 710     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 711     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 712     i386pe_vec)                 tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
 713     i386pei_vec)                tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
 714     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 715     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 716     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 717     ieee_vec)                   tb="$tb ieee.lo" ;;
 718     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 719     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 720     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 721     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 722     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 723     m68klynx_aout_vec)          tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
 724     m68klynx_coff_vec)          tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
 725     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 726     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 727     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 728     m88kmach3_vec)              tb="$tb m88kmach3.lo aout32.lo" ;;
 729     mach_o_be_vec)              tb="$tb mach-o.lo" ;;
 730     mach_o_le_vec)              tb="$tb mach-o.lo" ;;
 731     mach_o_fat_vec)             tb="$tb mach-o.lo" ;;
 732     mcore_pe_big_vec)           tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 733     mcore_pe_little_vec)        tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 734     mcore_pei_big_vec)          tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 735     mcore_pei_little_vec)       tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 736     mipslpe_vec)                tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
 737     mipslpei_vec)               tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
 738     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 739     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"; target_size=64 ;;
 740     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 741     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 742     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 743     or32coff_big_vec)           tb="$tb coff-or32.lo cofflink.lo" ;;
 744     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 745     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 746     pef_vec)                    tb="$tb pef.lo" ;;
 747     pef_xlib_vec)               tb="$tb pef.lo" ;;
 748     pdp11_aout_vec)             tb="$tb pdp11.lo" ;;
 749     pmac_xcoff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 750     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 751     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 752     rs6000coff64_vec)           tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 753     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 754     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 755     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 756     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 757     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 758     shlpe_vec)                  tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 759     shlpei_vec)                 tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 760     som_vec)                    tb="$tb som.lo" ;;
 761     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 762     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 763     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 764     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 765     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 766     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 767     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 768     sym_vec)                    tb="$tb xsym.lo" ;;
 769     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 770     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 771     tic4x_coff0_vec)            tb="$tb coff-tic4x.lo" ;;
 772     tic4x_coff0_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 773     tic4x_coff1_vec)            tb="$tb coff-tic4x.lo" ;;
 774     tic4x_coff1_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 775     tic4x_coff2_vec)            tb="$tb coff-tic4x.lo" ;;
 776     tic4x_coff2_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 777     tic54x_coff0_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 778     tic54x_coff0_vec)           tb="$tb coff-tic54x.lo" ;;
 779     tic54x_coff1_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 780     tic54x_coff1_vec)           tb="$tb coff-tic54x.lo" ;;
 781     tic54x_coff2_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 782     tic54x_coff2_vec)           tb="$tb coff-tic54x.lo" ;;
 783     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 784     vaxnetbsd_vec)              tb="$tb vaxnetbsd.lo aout32.lo" ;;
 785     vax1knetbsd_vec)            tb="$tb vax1knetbsd.lo aout32.lo" ;;
 786     vaxbsd_vec)                 tb="$tb vaxbsd.lo aout32.lo" ;;
 787     versados_vec)               tb="$tb versados.lo" ;;
 788     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"; target_size=64 ;;
 789     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 790     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 791     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 792     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo" ;;
 793
 794     # These appear out of order in targets.c
 795     srec_vec)                   tb="$tb srec.lo" ;;
 796     symbolsrec_vec)             tb="$tb srec.lo" ;;
 797     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 798     cisco_core_big_vec)         tb="$tb cisco-core.lo" ;;
 799     cisco_core_little_vec)      tb="$tb cisco-core.lo" ;;
 800
 801     "")                 ;;
 802     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 803     esac
 804
 805     if test ${target_size} = 64; then
 806         target64=true
 807     fi
 808     if test x"${vec}" = x"${defvec}"; then
 809         bfd_default_target_size=${target_size}
 810     fi
 811 done
 812
 813 # Target architecture .o files.
 814 # A couple of CPUs use shorter file names to avoid problems on DOS
 815 # filesystems.
 816 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 817
 818 # Weed out duplicate .o files.
 819 f=""
 820 for i in $tb ; do
 821     case " $f " in
 822     *" $i "*) ;;
 823     *) f="$f $i" ;;
 824     esac
 825 done
 826 tb="$f"
 827
 828 f=""
 829 for i in $ta ; do
 830     case " $f " in
 831     *" $i "*) ;;
 832     *) f="$f $i" ;;
 833     esac
 834 done
 835 ta="$f"
 836
 837 bfd_backends="$tb"
 838 bfd_machines="$ta"
 839
 840 if test x${all_targets} = xtrue ; then
 841   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 842   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 843   selvecs=
 844   havevecs=
 845   selarchs=
 846   test -n "$assocvecs" &&
 847     assocvecs=`echo $assocvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 848 else    # all_targets is true
 849   # Only set these if they will be nonempty, for the clever echo.
 850   havevecs=
 851   assocvecs=
 852   test -n "$selvecs" &&
 853     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 854   test -n "$selvecs" &&
 855     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 856   test -n "$selarchs" &&
 857     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 858 fi      # all_targets is true
 859
 860 case ${host64}-${target64}-${want64} in
 861   *true*)
 862     wordsize=64
 863     bfd_libs='$(BFD64_LIBS) $(BFD32_LIBS)'
 864     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 865     if test $BFD_HOST_64_BIT_DEFINED = 0; then
 866       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 867       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 868     fi
 869     if test -n "$GCC" ; then
 870        bad_64bit_gcc=no;
 871        AC_MSG_CHECKING([for gcc version with buggy 64-bit support])
 872        # Add more tests for gcc versions with non-working 64-bit support here.
 873        AC_EGREP_CPP([: 2 : 91 : 1 :],[:__GNUC__:__GNUC_MINOR__:__i386__:],
 874                     bad_64bit_gcc=yes;
 875                     AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
 876                     AC_MSG_RESULT(no))
 877        if test $bad_64bit_gcc = yes ; then
 878          AC_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
 879        fi
 880     fi
 881     ;;
 882   false-false-false)
 883     wordsize=32
 884     bfd_libs='$(BFD32_LIBS)'
 885     all_backends='$(BFD32_BACKENDS)'
 886     ;;
 887 esac
 888
 889 AC_SUBST(wordsize)
 890 AC_SUBST(bfd_libs)
 891 AC_SUBST(all_backends)
 892 AC_SUBST(bfd_backends)
 893 AC_SUBST(bfd_machines)
 894 AC_SUBST(bfd_default_target_size)
 895
 896 # Determine the host dependant file_ptr a.k.a. off_t type.  In order
 897 # prefer: off64_t - if ftello64 and fseeko64, off_t - if ftello and
 898 # fseeko, long.  This assumes that sizeof off_t is .ge. sizeof long.
 899 # Hopefully a reasonable assumption since fseeko et.al. should be
 900 # upward compatible.
 901 AC_CHECK_FUNCS(ftello ftello64 fseeko fseeko64)
 902 if test x"$ac_cv_func_ftello" = xyes -a x"$ac_cv_func_fseeko" = xyes; then
 903     AC_COMPILE_CHECK_SIZEOF(off_t)
 904 fi
 905 AC_MSG_CHECKING([file_ptr type])
 906 bfd_file_ptr="long"
 907 bfd_ufile_ptr="unsigned long"
 908 if test x"$ac_cv_func_ftello64" = xyes -a x"$ac_cv_func_fseeko64" = xyes \
 909         -o x"${ac_cv_sizeof_off_t}" = x8; then
 910     bfd_file_ptr=BFD_HOST_64_BIT
 911     bfd_ufile_ptr=BFD_HOST_U_64_BIT
 912 fi
 913 AC_MSG_RESULT($bfd_file_ptr)
 914 AC_SUBST(bfd_file_ptr)
 915 AC_SUBST(bfd_ufile_ptr)
 916
 917
 918 tdefaults=""
 919 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 920 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 921 test -n "${assocvecs}" && tdefaults="${tdefaults} -DASSOCIATED_VECS='${assocvecs}'"
 922 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 923 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 924 AC_SUBST(tdefaults)
 925
 926 dnl AC_CHECK_HEADERS(sys/mman.h)
 927 AC_FUNC_MMAP
 928 AC_CHECK_FUNCS(madvise mprotect)
 929 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 930   true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
 931 esac
 932
 933 rm -f doc/config.status
 934 AC_OUTPUT(Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in,
 935 [sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' -e '/BLD-POTFILES =/r po/BLD-POTFILES' po/Makefile.in > po/Makefile])
 936