bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.3)
   4 AC_INIT(libbfd.c)
   5
   6 AC_ARG_ENABLE(64-bit-bfd,
   7 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
   8 [case "${enableval}" in
   9   yes)  want64=true  ;;
  10   no)   want64=false ;;
  11   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  12 esac],[want64=false])dnl
  13 AC_ARG_ENABLE(targets,
  14 [  --enable-targets        alternative target configurations],
  15 [case "${enableval}" in
  16   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  17             ;;
  18   no)       enable_targets= ;;
  19   *)        enable_targets=$enableval ;;
  20 esac])dnl
  21
  22 AC_CONFIG_HEADER(config.h:config.in)
  23
  24 AC_CONFIG_AUX_DIR(`cd $srcdir/..;pwd`)
  25 AC_CANONICAL_SYSTEM
  26 if test -z "$target" ; then
  27     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  28 fi
  29 AC_ARG_PROGRAM
  30
  31 host64=false
  32 target64=false
  33
  34 # host stuff:
  35
  36 # Permit host specific settings.
  37 . ${srcdir}/configure.host
  38
  39 AC_PROG_CC
  40 AC_SUBST(CFLAGS)
  41 AC_SUBST(HDEFINES)
  42 AR=${AR-ar}
  43 AC_SUBST(AR)
  44 AC_PROG_RANLIB
  45 AC_PROG_INSTALL
  46
  47 HOST_64BIT_LONG=0
  48 if test "x${HOST_64BIT_TYPE}" = "xlong"; then
  49   HOST_64BIT_LONG=1
  50 fi
  51 AC_SUBST(HOST_64BIT_LONG)
  52
  53 BFD_CC_FOR_BUILD
  54
  55 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
  56 AC_CHECK_HEADERS(fcntl.h sys/file.h)
  57 AC_CHECK_FUNCS(fcntl getpagesize)
  58
  59 BFD_BINARY_FOPEN
  60
  61 AC_MSG_CHECKING([whether malloc must be declared])
  62 AC_CACHE_VAL(bfd_cv_decl_needed_malloc,
  63 [AC_TRY_COMPILE([
  64 #include <stdio.h>
  65 #ifdef HAVE_STDLIB_H
  66 #include <stdlib.h>
  67 #endif
  68 #ifdef HAVE_UNISTD_H
  69 #include <unistd.h>
  70 #endif],
  71 [char *(*pfn) = (char *(*)) malloc],
  72 bfd_cv_decl_needed_malloc=no, bfd_cv_decl_needed_malloc=yes)])
  73 AC_MSG_RESULT($bfd_cv_decl_needed_malloc)
  74 if test $bfd_cv_decl_needed_malloc = yes; then
  75   AC_DEFINE(NEED_DECLARATION_MALLOC)
  76 fi
  77
  78 AC_MSG_CHECKING([whether free must be declared])
  79 AC_CACHE_VAL(bfd_cv_decl_needed_free,
  80 [AC_TRY_COMPILE([
  81 #include <stdio.h>
  82 #ifdef HAVE_STDLIB_H
  83 #include <stdlib.h>
  84 #endif
  85 #ifdef HAVE_UNISTD_H
  86 #include <unistd.h>
  87 #endif],
  88 [int (*pfn) = (int (*)) free],
  89 bfd_cv_decl_needed_free=no, bfd_cv_decl_needed_free=yes)])
  90 AC_MSG_RESULT($bfd_cv_decl_needed_free)
  91 if test $bfd_cv_decl_needed_free = yes; then
  92   AC_DEFINE(NEED_DECLARATION_FREE)
  93 fi
  94
  95 # If we are configured native, pick a core file support file.
  96 COREFILE=
  97 COREFLAG=
  98 if test "${target}" = "${host}"; then
  99   case "${host}" in
 100   alpha-*-*)            COREFILE=osf-core.o ;;
 101   arm-*-riscix)         COREFILE=trad-core.o ;;
 102   hppa*-*-hpux*)        COREFILE=hpux-core.o ;;
 103   hppa*-*-hiux*)        COREFILE=hpux-core.o ;;
 104   hppa*-*-bsd*)         COREFILE="hpux-core.o hppabsd-core.o"
 105                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 106 changequote(,)dnl
 107   i[345]86-sequent-bsd*)
 108 changequote([,])dnl
 109         COREFILE=trad-core.o;
 110         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 111         ;;
 112 changequote(,)dnl
 113   i[345]86-sequent-sysv4*) ;;
 114   i[345]86-sequent-sysv*)
 115 changequote([,])dnl
 116         COREFILE=trad-core.o
 117         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 118         ;;
 119 changequote(,)dnl
 120   i[345]86-*-bsd* | i[345]86-*-freebsd* | i[345]86-*-netbsd*)
 121 changequote([,])dnl
 122         COREFILE=trad-core.o
 123         AC_DEFINE(TRAD_HEADER,"hosts/i386bsd.h")
 124         ;;
 125 changequote(,)dnl
 126   i[345]86-esix-sysv3*)
 127 changequote([,])dnl
 128         COREFILE=trad-core.o
 129         AC_DEFINE(TRAD_HEADER,"hosts/esix.h")
 130         ;;
 131 changequote(,)dnl
 132   i[345]86-*-sco* | i[345]86-*-isc*)
 133 changequote([,])dnl
 134         COREFILE=trad-core.o
 135         AC_DEFINE(TRAD_HEADER,"hosts/i386sco.h")
 136         ;;
 137 changequote(,)dnl
 138   i[345]86-*-mach3*)
 139 changequote([,])dnl
 140         COREFILE=trad-core.o
 141         AC_DEFINE(TRAD_HEADER,"hosts/i386mach3.h")
 142         ;;
 143 changequote(,)dnl
 144   i[345]86-*-linux*)
 145 changequote([,])dnl
 146         COREFILE=trad-core.o
 147         AC_DEFINE(TRAD_HEADER,"hosts/i386linux.h")
 148         ;;
 149 changequote(,)dnl
 150   i[345]86-*-isc*)      COREFILE=trad-core.o ;;
 151   i[345]86-*-aix*)      COREFILE=aix386-core.o ;;
 152 changequote([,])dnl
 153   mips-dec-bsd*)
 154         COREFILE=trad-core.o
 155         AC_DEFINE(TRAD_HEADER,"hosts/mipsbsd.h")
 156         ;;
 157   mips-dec-mach3*)
 158         COREFILE=trad-core.o
 159         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 160         ;;
 161   mips-dec-netbsd*)     ;;
 162   mips-dec-*)
 163         COREFILE=trad-core.o
 164         AC_DEFINE(TRAD_HEADER,"hosts/decstation.h")
 165         ;;
 166   mips-sgi-irix4*)      COREFILE=irix-core.o ;;
 167   mips-sgi-irix5*)      COREFILE=irix-core.o ;;
 168   mips-*-mach3*)
 169         COREFILE=trad-core.o
 170         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 171         ;;
 172   mips-*-sysv4*)        ;;
 173   mips-*-sysv* | mips-*-riscos*)
 174         COREFILE=trad-core.o
 175         AC_DEFINE(TRAD_HEADER,"hosts/riscos.h")
 176         ;;
 177   mips-sony-bsd*)
 178         COREFILE=trad-core.o
 179         AC_DEFINE(TRAD_HEADER,"hosts/news-mips".h)
 180         ;;
 181   m68*-bull*-sysv*)
 182         COREFILE=trad-core.o
 183         AC_DEFINE(TRAD_HEADER,"hosts/dpx2.h")
 184         ;;
 185   m68*-hp-hpux*)        COREFILE=hpux-core.o ;;
 186   m68*-hp-bsd*)
 187         COREFILE=trad-core.o
 188         AC_DEFINE(TRAD_HEADER,"hosts/hp300bsd.h")
 189         ;;
 190   m68*-motorola-sysv*)  COREFILE=ptrace-core.o ;;
 191   m68*-sony-*)
 192         COREFILE=trad-core.o
 193         AC_DEFINE(TRAD_HEADER,"hosts/news.h")
 194         ;;
 195   m88*-*-sysv4*)        ;;
 196   m88*-motorola-sysv*)  COREFILE=trad-core.o ;;
 197   m88*-*-mach3*)
 198         COREFILE=trad-core.o
 199         AC_DEFINE(TRAD_HEADER,"hosts/m88kmach3.h")
 200         ;;
 201   ns32k-pc532-mach)
 202         COREFILE=trad-core.o
 203         AC_DEFINE(TRAD_HEADER,"hosts/pc532mach.h")
 204         ;;
 205   rs6000-*-lynx*)       COREFILE=lynx-core.o ;;
 206   rs6000-*-aix4*)       COREFILE=rs6000-core.o ;;
 207   rs6000-*-*)           COREFILE=rs6000-core.o ;;
 208   powerpc-*-aix4*)      COREFILE=rs6000-core.o ;;
 209   powerpc-*-aix*)       COREFILE=rs6000-core.o ;;
 210   tahoe-*-*)
 211         COREFILE=trad-core.o
 212         AC_DEFINE(TRAD_HEADER,"hosts/tahoe.h")
 213         ;;
 214   vax-*-ultrix2*)
 215         COREFILE=trad-core.o
 216         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 217         ;;
 218   vax-*-ultrix*)
 219         COREFILE=trad-core.o
 220         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 221         ;;
 222   vax-*-*)
 223         COREFILE=trad-core.o
 224         AC_DEFINE(TRAD_HEADER,"hosts/vaxbsd.h")
 225         ;;
 226   esac
 227
 228   case "$COREFILE" in
 229   aix386-core.o)        COREFLAG=-DAIX386_CORE ;;
 230   hppabsd-core.o)       COREFLAG=-DHPPABSD_CORE ;;
 231   hpux-core.o)          COREFLAG=-DHPUX_CORE ;;
 232   irix-core.o)          COREFLAG=-DIRIX_CORE ;;
 233   lynx-core.o)          COREFLAG=-DLYNX_CORE ;;
 234   osf-core.o)           COREFLAG=-DOSF_CORE ;;
 235   ptrace-core.o)        COREFLAG=-DPTRACE_CORE ;;
 236   rs6000-core.o)        COREFLAG="$COREFLAG -DAIX_CORE" ;;
 237   trad-core.o)          COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 238   esac
 239
 240   # The ELF code uses the native <sys/procfs.h> to handle core files.
 241   # Define HAVE_SYS_PROCFS_H if the file exists and defines
 242   # prstatus_t.
 243   AC_MSG_CHECKING([for sys/procfs.h])
 244   AC_CACHE_VAL(bfd_cv_header_sys_procfs_h,
 245   [AC_TRY_COMPILE([#include <sys/procfs.h>],
 246   [prstatus_t t;],
 247   bfd_cv_header_sys_procfs_h=yes, bfd_cv_header_sys_procfs_h=no)])
 248   AC_MSG_RESULT($bfd_cv_header_sys_procfs_h)
 249   if test $bfd_cv_header_sys_procfs_h = yes; then
 250     AC_DEFINE(HAVE_SYS_PROCFS_H)
 251   fi
 252
 253 fi
 254 AC_SUBST(COREFILE)
 255 AC_SUBST(COREFLAG)
 256
 257 # target stuff:
 258
 259 # Canonicalize the secondary target names.
 260 if test -n "$enable_targets" ; then
 261     for targ in `echo $enable_targets | sed 's/,/ /g'`
 262     do
 263         result=`$ac_config_sub $targ 2>/dev/null`
 264         if test -n "$result" ; then
 265             canon_targets="$canon_targets $result"
 266         else
 267             # Allow targets that config.sub doesn't recognize, like "all".
 268             canon_targets="$canon_targets $targ"
 269         fi
 270     done
 271 fi
 272
 273 all_targets=false
 274 defvec=
 275 selvecs=
 276 selarchs=
 277 TDEFINES=
 278 for targ in $target $canon_targets
 279 do
 280     if test "x$targ" = "xall"; then
 281         all_targets=true
 282     else
 283         . $srcdir/config.bfd
 284         if test "x$targ" = "x$target"; then
 285             defvec=$targ_defvec
 286         fi
 287         selvecs="$selvecs $targ_defvec $targ_selvecs"
 288         selarchs="$selarchs $targ_archs"
 289         TDEFINES="$TDEFINES $targ_cflags"
 290     fi
 291 done
 292 AC_SUBST(TDEFINES)
 293
 294 # This processing still needs to be done if we're to decide properly whether
 295 # 64-bit support needs to be compiled in.  Currently, it will be included if
 296 # the default or any other explicitly requested target requires it; it
 297 # will not be included on a 32-bit host if no 64-bit target is requested, and
 298 # no "--with-64-bit-bfd" option is given, even if "--with-targets=all" is
 299 # used.
 300
 301 # uniq the default and selected vectors in all the configured targets.
 302 f=""
 303 for i in $selvecs ; do
 304     case " $f " in
 305     *" $i "*) ;;
 306     *) f="$f $i" ;;
 307     esac
 308 done
 309 selvecs="$f"
 310
 311 # uniq the architectures in all the configured targets.
 312 f=""
 313 for i in $selarchs ; do
 314     case " $f " in
 315     *" $i "*) ;;
 316     *) f="$f $i" ;;
 317     esac
 318 done
 319 selarchs="$f"
 320
 321 # Target backend .o files.
 322 tb=
 323
 324 elf="elf.o elflink.o"
 325
 326 for vec in $selvecs
 327 do
 328     case "$vec" in
 329     # This list is alphabetized to make it easy to compare
 330     # with the two vector lists in targets.c.
 331     a29kcoff_big_vec)           tb="$tb coff-a29k.o cofflink.o" ;;
 332     a_out_adobe_vec)            tb="$tb aout-adobe.o aout32.o stab-syms.o" ;;
 333     armcoff_little_vec)         tb="$tb coff-arm.o cofflink.o " ;;
 334     armcoff_big_vec)            tb="$tb coff-arm.o cofflink.o " ;;
 335     armpe_little_vec)           tb="$tb pe-arm.o cofflink.o " ;;
 336     armpe_big_vec)              tb="$tb pe-arm.o cofflink.o " ;;
 337     armpei_little_vec)          tb="$tb pei-arm.o cofflink.o " ;;
 338     armpei_big_vec)             tb="$tb pei-arm.o cofflink.o " ;;
 339     aout0_big_vec)              tb="$tb aout0.o aout32.o stab-syms.o" ;;
 340     aout_arm_big_vec)           tb="$tb aout-arm.o aout32.o stab-syms.o" ;;
 341     aout_arm_little_vec)        tb="$tb aout-arm.o aout32.o stab-syms.o" ;;
 342     aout_mips_big_vec)          tb="$tb mipsbsd.o aout32.o stab-syms.o" ;;
 343     aout_mips_little_vec)       tb="$tb mipsbsd.o aout32.o stab-syms.o" ;;
 344     apollocoff_vec)             tb="$tb coff-apollo.o" ;;
 345     b_out_vec_big_host)         tb="$tb bout.o aout32.o stab-syms.o" ;;
 346     b_out_vec_little_host)      tb="$tb bout.o aout32.o stab-syms.o" ;;
 347 # start-sanitize-arc
 348     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.o elf32.o $elf" ;;
 349     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.o elf32.o $elf" ;;
 350 # end-sanitize-arc
 351     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.o elf32.o $elf" ;;
 352     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.o elf32.o $elf ecofflink.o" ;;
 353     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.o elf32.o $elf" ;;
 354     bfd_elf32_i386_vec)         tb="$tb elf32-i386.o elf32.o $elf" ;;
 355     bfd_elf32_i860_vec)         tb="$tb elf32-i860.o elf32.o $elf" ;;
 356     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.o elf32.o $elf" ;;
 357     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.o elf32.o $elf ecofflink.o" ;;
 358     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.o elf32.o $elf" ;;
 359     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.o elf32.o $elf" ;;
 360     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.o elf32.o $elf" ;;
 361     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.o elf32.o $elf" ;;
 362     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.o elf32.o $elf" ;;
 363     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.o elf64.o $elf"
 364                                 target64=true ;;
 365     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.o elf64.o $elf"
 366                                 target64=true ;;
 367     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.o elf64.o $elf"
 368                                 target64=true ;;
 369     cisco_core_vec)             tb="$tb cisco-core.o" ;;
 370     demo_64_vec)                tb="$tb demo64.o aout64.o stab-syms.o"
 371                                 target64=true ;;
 372     ecoff_big_vec)              tb="$tb coff-mips.o ecoff.o ecofflink.o" ;;
 373     ecoff_little_vec)           tb="$tb coff-mips.o ecoff.o ecofflink.o" ;;
 374     ecoffalpha_little_vec)      tb="$tb coff-alpha.o ecoff.o ecofflink.o"
 375                                 target64=true ;;
 376     h8300coff_vec)              tb="$tb coff-h8300.o reloc16.o" ;;
 377     h8500coff_vec)              tb="$tb coff-h8500.o reloc16.o" ;;
 378     host_aout_vec)              tb="$tb host-aout.o aout32.o stab-syms.o" ;;
 379     hp300bsd_vec)               tb="$tb hp300bsd.o aout32.o stab-syms.o" ;;
 380     hp300hpux_vec)              tb="$tb hp300hpux.o aout32.o stab-syms.o" ;;
 381     i386aout_vec)               tb="$tb i386aout.o aout32.o stab-syms.o" ;;
 382     i386bsd_vec)                tb="$tb i386bsd.o aout32.o stab-syms.o" ;;
 383     i386dynix_vec)              tb="$tb i386dynix.o aout32.o stab-syms.o" ;;
 384     i386coff_vec)               tb="$tb coff-i386.o cofflink.o" ;;
 385     i386msdos_vec)              tb="$tb i386msdos.o" ;;
 386     i386pe_vec)                 tb="$tb pe-i386.o cofflink.o " ;;
 387     i386pei_vec)                tb="$tb pei-i386.o cofflink.o" ;;
 388     i386linux_vec)              tb="$tb i386linux.o aout32.o stab-syms.o" ;;
 389     i386lynx_aout_vec)          tb="$tb i386lynx.o lynx-core.o aout32.o stab-syms.o" ;;
 390     i386lynx_coff_vec)          tb="$tb cf-i386lynx.o cofflink.o lynx-core.o stab-syms.o" ;;
 391     i386mach3_vec)              tb="$tb i386mach3.o aout32.o stab-syms.o" ;;
 392     i386netbsd_vec)             tb="$tb i386netbsd.o aout32.o stab-syms.o" ;;
 393     i386os9k_vec)               tb="$tb i386os9k.o aout32.o stab-syms.o" ;;
 394     icoff_big_vec)              tb="$tb coff-i960.o cofflink.o" ;;
 395     icoff_little_vec)           tb="$tb coff-i960.o cofflink.o" ;;
 396     ieee_vec)                   tb="$tb ieee.o" ;;
 397     m68kcoff_vec)               tb="$tb coff-m68k.o cofflink.o" ;;
 398     m68kcoffun_vec)             tb="$tb coff-u68k.o coff-m68k.o cofflink.o" ;;
 399     m68klynx_aout_vec)          tb="$tb m68klynx.o lynx-core.o aout32.o stab-syms.o" ;;
 400     m68klynx_coff_vec)          tb="$tb cf-m68klynx.o coff-m68k.o cofflink.o lynx-core.o stab-syms.o" ;;
 401     m68knetbsd_vec)             tb="$tb m68knetbsd.o aout32.o stab-syms.o" ;;
 402     m88kbcs_vec)                tb="$tb coff-m88k.o" ;;
 403     newsos3_vec)                tb="$tb newsos3.o aout32.o stab-syms.o" ;;
 404     nlm32_i386_vec)             tb="$tb nlm32-i386.o nlm32.o nlm.o" ;;
 405     nlm32_sparc_vec)            tb="$tb nlm32-sparc.o nlm32.o nlm.o" ;;
 406     nlm32_alpha_vec)            tb="$tb nlm32-alpha.o nlm32.o nlm.o"
 407                                 target64=true ;;
 408     riscix_vec)                 tb="$tb aout32.o riscix.o stab-syms.o" ;;
 409     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.o nlm32.o nlm.o" ;;
 410     pc532netbsd_vec)            tb="$tb ns32knetbsd.o aout-ns32k.o stab-syms.o" ;;
 411     pc532machaout_vec)          tb="$tb pc532-mach.o aout-ns32k.o stab-syms.o" ;;
 412     pmac_xcoff_vec)             tb="$tb coff-pmac.o xcofflink.o" ;;
 413     rs6000coff_vec)             tb="$tb coff-rs6000.o xcofflink.o" ;;
 414     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.o cofflink.o" ;;
 415     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.o cofflink.o" ;;
 416     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.o cofflink.o" ;;
 417     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.o cofflink.o" ;;
 418     shcoff_vec)                 tb="$tb coff-sh.o cofflink.o" ;;
 419 # start-sanitize-rce
 420     rce_aout_vec)               tb="$tb aout-rce.o aout32.o stab-syms.o" ;;
 421 # end-sanitize-rce
 422     shlcoff_vec)                tb="$tb coff-sh.o cofflink.o" ;;
 423     som_vec)                    tb="$tb som.o" ;;
 424     sparclynx_aout_vec)         tb="$tb sparclynx.o lynx-core.o aout32.o stab-syms.o" ;;
 425     sparclynx_coff_vec)         tb="$tb cf-sparclynx.o lynx-core.o stab-syms.o" ;;
 426     sparcnetbsd_vec)            tb="$tb sparcnetbsd.o aout32.o stab-syms.o" ;;
 427     sparccoff_vec)              tb="$tb coff-sparc.o" ;;
 428     srec_vec)                   tb="$tb srec.o" ;;
 429     sunos_big_vec)              tb="$tb sunos.o aout32.o stab-syms.o" ;;
 430     symbolsrec_vec)             tb="$tb srec.o" ;;
 431     tekhex_vec)                 tb="$tb tekhex.o" ;;
 432     we32kcoff_vec)              tb="$tb coff-we32k.o" ;;
 433     z8kcoff_vec)                tb="$tb coff-z8k.o reloc16.o" ;;
 434     w65_vec)                    tb="$tb coff-w65.o reloc16.o" ;;
 435     versados_vec)               tb="$tb versados.o" ;;
 436
 437     "")                 ;;
 438     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 439     esac
 440 done
 441
 442 # Target architecture .o files.
 443 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.o/g`
 444
 445 # Weed out duplicate .o files.
 446 f=""
 447 for i in $tb ; do
 448     case " $f " in
 449     *" $i "*) ;;
 450     *) f="$f $i" ;;
 451     esac
 452 done
 453 tb="$f"
 454
 455 f=""
 456 for i in $ta ; do
 457     case " $f " in
 458     *" $i "*) ;;
 459     *) f="$f $i" ;;
 460     esac
 461 done
 462 ta="$f"
 463
 464 bfd_backends="$tb"
 465 bfd_machines="$ta"
 466
 467 if test x${all_targets} = xtrue ; then
 468   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 469   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 470   selvecs=
 471   selarchs=
 472 else    # all_targets is true
 473   # Only set these if they will be nonempty, for the clever echo.
 474   test -n "$selvecs" &&
 475     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 476   test -n "$selarchs" &&
 477     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 478 fi      # all_targets is true
 479
 480 case ${host64}-${target64}-${want64} in
 481   *true*)
 482     wordsize=64
 483     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 484     ;;
 485   false-false-false)
 486     wordsize=32
 487     all_backends='$(BFD32_BACKENDS)'
 488     ;;
 489 esac
 490
 491 AC_SUBST(wordsize)
 492 AC_SUBST(all_backends)
 493 AC_SUBST(bfd_backends)
 494 AC_SUBST(bfd_machines)
 495
 496 tdefaults=""
 497 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 498 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 499 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 500 AC_SUBST(tdefaults)
 501
 502 rm -f doc/config.status
 503 AC_OUTPUT(Makefile doc/Makefile,
 504 [case x$CONFIG_HEADERS in xconfig.h:config.in) echo > stamp-h ;; esac])