automake.in

   1 #!@PERL@ -w
   2 # -*- perl -*-
   3 # @configure_input@
   4
   5 eval 'case $# in 0) exec @PERL@ -S "$0";; *) exec @PERL@ -S "$0" "$@";; esac'
   6     if 0;
   7
   8 # automake - create Makefile.in from Makefile.am
   9 # Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
  10 # 2003, 2004  Free Software Foundation, Inc.
  11
  12 # This program is free software; you can redistribute it and/or modify
  13 # it under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 2, or (at your option)
  15 # any later version.
  16
  17 # This program is distributed in the hope that it will be useful,
  18 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 # GNU General Public License for more details.
  21
  22 # You should have received a copy of the GNU General Public License
  23 # along with this program; if not, write to the Free Software
  24 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  25 # 02111-1307, USA.
  26
  27 # Originally written by David Mackenzie <djm@gnu.ai.mit.edu>.
  28 # Perl reimplementation by Tom Tromey <tromey@redhat.com>.
  29
  30 package Language;
  31
  32 BEGIN
  33 {
  34   my $perllibdir = $ENV{'perllibdir'} || '@datadir@/@PACKAGE@-@APIVERSION@';
  35   unshift @INC, (split ':', $perllibdir);
  36
  37   # Override SHELL.  This is required on DJGPP so that system() uses
  38   # bash, not COMMAND.COM which doesn't quote arguments properly.
  39   # Other systems aren't expected to use $SHELL when Automake
  40   # runs, but it should be safe to drop the `if DJGPP' guard if
  41   # it turns up other systems need the same thing.  After all,
  42   # if SHELL is used, ./configure's SHELL is always better than
  43   # the user's SHELL (which may be something like tcsh).
  44   $ENV{'SHELL'} = '@SHELL@' if exists $ENV{'DJGPP'};
  45 }
  46
  47 use Automake::Struct;
  48 struct (# Short name of the language (c, f77...).
  49         'name' => "\$",
  50         # Nice name of the language (C, Fortran 77...).
  51         'Name' => "\$",
  52
  53         # List of configure variables which must be defined.
  54         'config_vars' => '@',
  55
  56         'ansi'    => "\$",
  57         # `pure' is `1' or `'.  A `pure' language is one where, if
  58         # all the files in a directory are of that language, then we
  59         # do not require the C compiler or any code to call it.
  60         'pure'   => "\$",
  61
  62         'autodep' => "\$",
  63
  64         # Name of the compiling variable (COMPILE).
  65         'compiler'  => "\$",
  66         # Content of the compiling variable.
  67         'compile'  => "\$",
  68         # Flag to require compilation without linking (-c).
  69         'compile_flag' => "\$",
  70         'extensions' => '@',
  71         # A subroutine to compute a list of possible extensions of
  72         # the product given the input extensions.
  73         # (defaults to a subroutine which returns ('.$(OBJEXT)', '.lo'))
  74         'output_extensions' => "\$",
  75         # A list of flag variables used in 'compile'.
  76         # (defaults to [])
  77         'flags' => "@",
  78
  79         # Any tag to pass to libtool while compiling.
  80         'libtool_tag' => "\$",
  81
  82         # The file to use when generating rules for this language.
  83         # The default is 'depend2'.
  84         'rule_file' => "\$",
  85
  86         # Name of the linking variable (LINK).
  87         'linker' => "\$",
  88         # Content of the linking variable.
  89         'link' => "\$",
  90
  91         # Name of the linker variable (LD).
  92         'lder' => "\$",
  93         # Content of the linker variable ($(CC)).
  94         'ld' => "\$",
  95
  96         # Flag to specify the output file (-o).
  97         'output_flag' => "\$",
  98         '_finish' => "\$",
  99
 100         # This is a subroutine which is called whenever we finally
 101         # determine the context in which a source file will be
 102         # compiled.
 103         '_target_hook' => "\$");
 104
 105
 106 sub finish ($)
 107 {
 108   my ($self) = @_;
 109   if (defined $self->_finish)
 110     {
 111       &{$self->_finish} ();
 112     }
 113 }
 114
 115 sub target_hook ($$$$)
 116 {
 117     my ($self) = @_;
 118     if (defined $self->_target_hook)
 119     {
 120         &{$self->_target_hook} (@_);
 121     }
 122 }
 123
 124 package Automake;
 125
 126 use strict;
 127 use Automake::Config;
 128 use Automake::General;
 129 use Automake::XFile;
 130 use Automake::Channels;
 131 use Automake::ChannelDefs;
 132 use Automake::Configure_ac;
 133 use Automake::FileUtils;
 134 use Automake::Location;
 135 use Automake::Condition qw/TRUE FALSE/;
 136 use Automake::DisjConditions;
 137 use Automake::Options;
 138 use Automake::Version;
 139 use Automake::Variable;
 140 use Automake::VarDef;
 141 use Automake::Rule;
 142 use Automake::RuleDef;
 143 use Automake::Wrap 'makefile_wrap';
 144 use File::Basename;
 145 use Carp;
 146
 147 ## ----------- ##
 148 ## Constants.  ##
 149 ## ----------- ##
 150
 151 # Some regular expressions.  One reason to put them here is that it
 152 # makes indentation work better in Emacs.
 153
 154 # Writing singled-quoted-$-terminated regexes is a pain because
 155 # perl-mode thinks of $' as the ${'} variable (instead of a $ followed
 156 # by a closing quote.  Letting perl-mode think the quote is not closed
 157 # leads to all sort of misindentations.  On the other hand, defining
 158 # regexes as double-quoted strings is far less readable.  So usually
 159 # we will write:
 160 #
 161 #  $REGEX = '^regex_value' . "\$";
 162
 163 my $IGNORE_PATTERN = '^\s*##([^#\n].*)?\n';
 164 my $WHITE_PATTERN = '^\s*' . "\$";
 165 my $COMMENT_PATTERN = '^#';
 166 my $TARGET_PATTERN='[$a-zA-Z_.@%][-.a-zA-Z0-9_(){}/$+@%]*';
 167 # A rule has three parts: a list of targets, a list of dependencies,
 168 # and optionally actions.
 169 my $RULE_PATTERN =
 170   "^($TARGET_PATTERN(?:(?:\\\\\n|\\s)+$TARGET_PATTERN)*) *:([^=].*|)\$";
 171
 172 # Only recognize leading spaces, not leading tabs.  If we recognize
 173 # leading tabs here then we need to make the reader smarter, because
 174 # otherwise it will think rules like `foo=bar; \' are errors.
 175 my $ASSIGNMENT_PATTERN = '^ *([^ \t=:+]*)\s*([:+]?)=\s*(.*)' . "\$";
 176 # This pattern recognizes a Gnits version id and sets $1 if the
 177 # release is an alpha release.  We also allow a suffix which can be
 178 # used to extend the version number with a "fork" identifier.
 179 my $GNITS_VERSION_PATTERN = '\d+\.\d+([a-z]|\.\d+)?(-[A-Za-z0-9]+)?';
 180
 181 my $IF_PATTERN = '^if\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*)\s*(?:#.*)?' . "\$";
 182 my $ELSE_PATTERN =
 183   '^else(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 184 my $ENDIF_PATTERN =
 185   '^endif(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 186 my $PATH_PATTERN = '(\w|[/.-])+';
 187 # This will pass through anything not of the prescribed form.
 188 my $INCLUDE_PATTERN = ('^include\s+'
 189                        . '((\$\(top_srcdir\)/' . $PATH_PATTERN . ')'
 190                        . '|(\$\(srcdir\)/' . $PATH_PATTERN . ')'
 191                        . '|([^/\$]' . $PATH_PATTERN . '))\s*(#.*)?' . "\$");
 192
 193 # Match `-d' as a command-line argument in a string.
 194 my $DASH_D_PATTERN = "(^|\\s)-d(\\s|\$)";
 195 # Directories installed during 'install-exec' phase.
 196 my $EXEC_DIR_PATTERN =
 197   '^(?:bin|sbin|libexec|sysconf|localstate|lib|pkglib|.*exec.*)' . "\$";
 198
 199 # Values for AC_CANONICAL_*
 200 use constant AC_CANONICAL_HOST   => 1;
 201 use constant AC_CANONICAL_SYSTEM => 2;
 202
 203 # Values indicating when something should be cleaned.
 204 use constant MOSTLY_CLEAN     => 0;
 205 use constant CLEAN            => 1;
 206 use constant DIST_CLEAN       => 2;
 207 use constant MAINTAINER_CLEAN => 3;
 208
 209 # Libtool files.
 210 my @libtool_files = qw(ltmain.sh config.guess config.sub);
 211 # ltconfig appears here for compatibility with old versions of libtool.
 212 my @libtool_sometimes = qw(ltconfig ltcf-c.sh ltcf-cxx.sh ltcf-gcj.sh);
 213
 214 # Commonly found files we look for and automatically include in
 215 # DISTFILES.
 216 my @common_files =
 217     (qw(ABOUT-GNU ABOUT-NLS AUTHORS BACKLOG COPYING COPYING.DOC COPYING.LIB
 218         COPYING.LESSER ChangeLog INSTALL NEWS README THANKS TODO
 219         ansi2knr.1 ansi2knr.c compile config.guess config.rpath config.sub
 220         depcomp elisp-comp install-sh libversion.in mdate-sh missing
 221         mkinstalldirs py-compile texinfo.tex ylwrap),
 222      @libtool_files, @libtool_sometimes);
 223
 224 # Commonly used files we auto-include, but only sometimes.  This list
 225 # is used for the --help output only.
 226 my @common_sometimes =
 227   qw(aclocal.m4 acconfig.h config.h.top config.h.bot configure
 228      configure.ac configure.in stamp-vti);
 229
 230 # Standard directories from the GNU Coding Standards, and additional
 231 # pkg* directories from Automake.  Stored in a hash for fast member check.
 232 my %standard_prefix =
 233     map { $_ => 1 } (qw(bin data exec include info lib libexec lisp
 234                         localstate man man1 man2 man3 man4 man5 man6
 235                         man7 man8 man9 oldinclude pkgdatadir
 236                         pkgincludedir pkglibdir sbin sharedstate
 237                         sysconf));
 238
 239 # Copyright on generated Makefile.ins.
 240 my $gen_copyright = "\
 241 # Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
 242 # 2003, 2004  Free Software Foundation, Inc.
 243 # This Makefile.in is free software; the Free Software Foundation
 244 # gives unlimited permission to copy and/or distribute it,
 245 # with or without modifications, as long as this notice is preserved.
 246
 247 # This program is distributed in the hope that it will be useful,
 248 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
 249 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 250 # PARTICULAR PURPOSE.
 251 ";
 252
 253 # These constants are returned by lang_*_rewrite functions.
 254 # LANG_SUBDIR means that the resulting object file should be in a
 255 # subdir if the source file is.  In this case the file name cannot
 256 # have `..' components.
 257 use constant LANG_IGNORE  => 0;
 258 use constant LANG_PROCESS => 1;
 259 use constant LANG_SUBDIR  => 2;
 260
 261 # These are used when keeping track of whether an object can be built
 262 # by two different paths.
 263 use constant COMPILE_LIBTOOL  => 1;
 264 use constant COMPILE_ORDINARY => 2;
 265
 266 # We can't always associate a location to a variable or a rule,
 267 # when its defined by Automake.  We use INTERNAL in this case.
 268 use constant INTERNAL => new Automake::Location;
 269 \f
 270
 271 ## ---------------------------------- ##
 272 ## Variables related to the options.  ##
 273 ## ---------------------------------- ##
 274
 275 # TRUE if we should always generate Makefile.in.
 276 my $force_generation = 1;
 277
 278 # From the Perl manual.
 279 my $symlink_exists = (eval 'symlink ("", "");', $@ eq '');
 280
 281 # TRUE if missing standard files should be installed.
 282 my $add_missing = 0;
 283
 284 # TRUE if we should copy missing files; otherwise symlink if possible.
 285 my $copy_missing = 0;
 286
 287 # TRUE if we should always update files that we know about.
 288 my $force_missing = 0;
 289
 290
 291 ## ---------------------------------------- ##
 292 ## Variables filled during files scanning.  ##
 293 ## ---------------------------------------- ##
 294
 295 # Name of the configure.ac file.
 296 my $configure_ac;
 297
 298 # Files found by scanning configure.ac for LIBOBJS.
 299 my %libsources = ();
 300
 301 # Names used in AC_CONFIG_HEADER call.
 302 my @config_headers = ();
 303
 304 # Names used in AC_CONFIG_LINKS call.
 305 my @config_links = ();
 306
 307 # Directory where output files go.  Actually, output files are
 308 # relative to this directory.
 309 my $output_directory;
 310
 311 # List of Makefile.am's to process, and their corresponding outputs.
 312 my @input_files = ();
 313 my %output_files = ();
 314
 315 # Complete list of Makefile.am's that exist.
 316 my @configure_input_files = ();
 317
 318 # List of files in AC_CONFIG_FILES/AC_OUTPUT without Makefile.am's,
 319 # and their outputs.
 320 my @other_input_files = ();
 321 # Where each AC_CONFIG_FILES/AC_OUTPUT/AC_CONFIG_LINK/AC_CONFIG_HEADER appears.
 322 # The keys are the files created by these macros.
 323 my %ac_config_files_location = ();
 324
 325 # List of directories to search for configure-required files.  This
 326 # can be set by AC_CONFIG_AUX_DIR.
 327 my @config_aux_path = qw(. .. ../..);
 328 my $config_aux_dir = '';
 329 my $config_aux_dir_set_in_configure_in = 0;
 330
 331 # Whether AM_GNU_GETTEXT has been seen in configure.ac.
 332 my $seen_gettext = 0;
 333 # Whether AM_GNU_GETTEXT([external]) is used.
 334 my $seen_gettext_external = 0;
 335 # Where AM_GNU_GETTEXT appears.
 336 my $ac_gettext_location;
 337
 338 # Lists of tags supported by Libtool.
 339 my %libtool_tags = ();
 340
 341 # TRUE if we've seen AC_CANONICAL_(HOST|SYSTEM).
 342 my $seen_canonical = 0;
 343 my $canonical_location;
 344
 345 # Where AM_MAINTAINER_MODE appears.
 346 my $seen_maint_mode;
 347
 348 # Actual version we've seen.
 349 my $package_version = '';
 350
 351 # Where version is defined.
 352 my $package_version_location;
 353
 354 # TRUE if we've seen AC_ENABLE_MULTILIB.
 355 my $seen_multilib = 0;
 356
 357 # TRUE if we've seen AM_PROG_CC_C_O
 358 my $seen_cc_c_o = 0;
 359
 360 # Where AM_INIT_AUTOMAKE is called;
 361 my $seen_init_automake = 0;
 362
 363 # TRUE if we've seen AM_AUTOMAKE_VERSION.
 364 my $seen_automake_version = 0;
 365
 366 # Hash table of discovered configure substitutions.  Keys are names,
 367 # values are `FILE:LINE' strings which are used by error message
 368 # generation.
 369 my %configure_vars = ();
 370
 371 # Files included by $configure_ac.
 372 my @configure_deps = ();
 373
 374 # Greatest timestamp of configure's dependencies.
 375 my $configure_deps_greatest_timestamp = 0;
 376
 377 # Hash table of AM_CONDITIONAL variables seen in configure.
 378 my %configure_cond = ();
 379
 380 # This maps extensions onto language names.
 381 my %extension_map = ();
 382
 383 # List of the DIST_COMMON files we discovered while reading
 384 # configure.in
 385 my $configure_dist_common = '';
 386
 387 # This maps languages names onto objects.
 388 my %languages = ();
 389
 390 # List of targets we must always output.
 391 # FIXME: Complete, and remove falsely required targets.
 392 my %required_targets =
 393   (
 394    'all'          => 1,
 395    'dvi'          => 1,
 396    'pdf'          => 1,
 397    'ps'           => 1,
 398    'info'         => 1,
 399    'install-info' => 1,
 400    'install'      => 1,
 401    'install-data' => 1,
 402    'install-exec' => 1,
 403    'uninstall'    => 1,
 404
 405    # FIXME: Not required, temporary hacks.
 406    # Well, actually they are sort of required: the -recursive
 407    # targets will run them anyway...
 408    'dvi-am'          => 1,
 409    'pdf-am'          => 1,
 410    'ps-am'           => 1,
 411    'info-am'         => 1,
 412    'install-data-am' => 1,
 413    'install-exec-am' => 1,
 414    'installcheck-am' => 1,
 415    'uninstall-am' => 1,
 416
 417    'install-man' => 1,
 418   );
 419
 420 # This is set to 1 when Automake needs to be run again.
 421 # (For instance, this happens when an auxiliary file such as
 422 # depcomp is added after the toplevel Makefile.in -- which
 423 # should distribute depcomp -- has been generated.)
 424 my $automake_needs_to_reprocess_all_files = 0;
 425
 426 # If a file name appears as a key in this hash, then it has already
 427 # been checked for.  This variable is local to the "require file"
 428 # functions.
 429 my %require_file_found = ();
 430
 431 # The name of the Makefile currently being processed.
 432 my $am_file = 'BUG';
 433 \f
 434
 435 ################################################################
 436
 437 ## ------------------------------------------ ##
 438 ## Variables reset by &initialize_per_input.  ##
 439 ## ------------------------------------------ ##
 440
 441 # Basename and relative dir of the input file.
 442 my $am_file_name;
 443 my $am_relative_dir;
 444
 445 # Same but wrt Makefile.in.
 446 my $in_file_name;
 447 my $relative_dir;
 448
 449 # Greatest timestamp of the output's dependencies (excluding
 450 # configure's dependencies).
 451 my $output_deps_greatest_timestamp;
 452
 453 # These two variables are used when generating each Makefile.in.
 454 # They hold the Makefile.in until it is ready to be printed.
 455 my $output_rules;
 456 my $output_vars;
 457 my $output_trailer;
 458 my $output_all;
 459 my $output_header;
 460
 461 # This is the conditional stack, updated on if/else/endif, and
 462 # used to build Condition objects.
 463 my @cond_stack;
 464
 465 # This holds the set of included files.
 466 my @include_stack;
 467
 468 # This holds a list of directories which we must create at `dist'
 469 # time.  This is used in some strange scenarios involving weird
 470 # AC_OUTPUT commands.
 471 my %dist_dirs;
 472
 473 # List of dependencies for the obvious targets.
 474 my @all;
 475 my @check;
 476 my @check_tests;
 477
 478 # Keys in this hash table are files to delete.  The associated
 479 # value tells when this should happen (MOSTLY_CLEAN, DIST_CLEAN, etc.)
 480 my %clean_files;
 481
 482 # Keys in this hash table are object files or other files in
 483 # subdirectories which need to be removed.  This only holds files
 484 # which are created by compilations.  The value in the hash indicates
 485 # when the file should be removed.
 486 my %compile_clean_files;
 487
 488 # Keys in this hash table are directories where we expect to build a
 489 # libtool object.  We use this information to decide what directories
 490 # to delete.
 491 my %libtool_clean_directories;
 492
 493 # Value of `$(SOURCES)', used by tags.am.
 494 my @sources;
 495 # Sources which go in the distribution.
 496 my @dist_sources;
 497
 498 # This hash maps object file names onto their corresponding source
 499 # file names.  This is used to ensure that each object is created
 500 # by a single source file.
 501 my %object_map;
 502
 503 # This hash maps object file names onto an integer value representing
 504 # whether this object has been built via ordinary compilation or
 505 # libtool compilation (the COMPILE_* constants).
 506 my %object_compilation_map;
 507
 508
 509 # This keeps track of the directories for which we've already
 510 # created dirstamp code.
 511 my %directory_map;
 512
 513 # All .P files.
 514 my %dep_files;
 515
 516 # This is a list of all targets to run during "make dist".
 517 my @dist_targets;
 518
 519 # Keys in this hash are the basenames of files which must depend on
 520 # ansi2knr.  Values are either the empty string, or the directory in
 521 # which the ANSI source file appears; the directory must have a
 522 # trailing `/'.
 523 my %de_ansi_files;
 524
 525 # This is the name of the redirect `all' target to use.
 526 my $all_target;
 527
 528 # This keeps track of which extensions we've seen (that we care
 529 # about).
 530 my %extension_seen;
 531
 532 # This is random scratch space for the language finish functions.
 533 # Don't randomly overwrite it; examine other uses of keys first.
 534 my %language_scratch;
 535
 536 # We keep track of which objects need special (per-executable)
 537 # handling on a per-language basis.
 538 my %lang_specific_files;
 539
 540 # This is set when `handle_dist' has finished.  Once this happens,
 541 # we should no longer push on dist_common.
 542 my $handle_dist_run;
 543
 544 # Used to store a set of linkers needed to generate the sources currently
 545 # under consideration.
 546 my %linkers_used;
 547
 548 # True if we need `LINK' defined.  This is a hack.
 549 my $need_link;
 550
 551 # Was get_object_extension run?
 552 # FIXME: This is a hack. a better switch should be found.
 553 my $get_object_extension_was_run;
 554
 555 # Record each file processed by make_paragraphs.
 556 my %transformed_files;
 557
 558 ################################################################
 559
 560 # var_SUFFIXES_trigger ($TYPE, $VALUE)
 561 # ------------------------------------
 562 # This is called by Automake::Variable::define() when SUFFIXES
 563 # is defined ($TYPE eq '') or appended ($TYPE eq '+').
 564 # The work here needs to be performed as a side-effect of the
 565 # macro_define() call because SUFFIXES definitions impact
 566 # on $KNOWN_EXTENSIONS_PATTERN which is used used when parsing
 567 # the input am file.
 568 sub var_SUFFIXES_trigger ($$)
 569 {
 570     my ($type, $value) = @_;
 571     accept_extensions (split (' ', $value));
 572 }
 573 Automake::Variable::hook ('SUFFIXES', \&var_SUFFIXES_trigger);
 574
 575 ################################################################
 576
 577 ## --------------------------------- ##
 578 ## Forward subroutine declarations.  ##
 579 ## --------------------------------- ##
 580 sub register_language (%);
 581 sub file_contents_internal ($$$%);
 582 sub define_files_variable ($\@$$);
 583
 584
 585 # &initialize_per_input ()
 586 # ------------------------
 587 # (Re)-Initialize per-Makefile.am variables.
 588 sub initialize_per_input ()
 589 {
 590     reset_local_duplicates ();
 591
 592     $am_file_name = '';
 593     $am_relative_dir = '';
 594
 595     $in_file_name = '';
 596     $relative_dir = '';
 597
 598     $output_deps_greatest_timestamp = 0;
 599
 600     $output_rules = '';
 601     $output_vars = '';
 602     $output_trailer = '';
 603     $output_all = '';
 604     $output_header = '';
 605
 606     Automake::Options::reset;
 607     Automake::Variable::reset;
 608     Automake::Rule::reset;
 609
 610     @cond_stack = ();
 611
 612     @include_stack = ();
 613
 614     %dist_dirs = ();
 615
 616     @all = ();
 617     @check = ();
 618     @check_tests = ();
 619
 620     %clean_files = ();
 621
 622     @sources = ();
 623     @dist_sources = ();
 624
 625     %object_map = ();
 626     %object_compilation_map = ();
 627
 628     %directory_map = ();
 629
 630     %dep_files = ();
 631
 632     @dist_targets = ();
 633
 634     %de_ansi_files = ();
 635
 636     $all_target = '';
 637
 638     %extension_seen = ();
 639
 640     %language_scratch = ();
 641
 642     %lang_specific_files = ();
 643
 644     $handle_dist_run = 0;
 645
 646     $need_link = 0;
 647
 648     $get_object_extension_was_run = 0;
 649
 650     %compile_clean_files = ();
 651
 652     # We always include `.'.  This isn't strictly correct.
 653     %libtool_clean_directories = ('.' => 1);
 654
 655     %transformed_files = ();
 656 }
 657
 658
 659 ################################################################
 660
 661 # Initialize our list of languages that are internally supported.
 662
 663 # C.
 664 register_language ('name' => 'c',
 665                    'Name' => 'C',
 666                    'config_vars' => ['CC'],
 667                    'ansi' => 1,
 668                    'autodep' => '',
 669                    'flags' => ['CFLAGS', 'CPPFLAGS'],
 670                    'compiler' => 'COMPILE',
 671                    'compile' => '$(CC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CFLAGS) $(CFLAGS)',
 672                    'lder' => 'CCLD',
 673                    'ld' => '$(CC)',
 674                    'linker' => 'LINK',
 675                    'link' => '$(CCLD) $(AM_CFLAGS) $(CFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 676                    'compile_flag' => '-c',
 677                    'libtool_tag' => 'CC',
 678                    'extensions' => ['.c'],
 679                    '_finish' => \&lang_c_finish);
 680
 681 # C++.
 682 register_language ('name' => 'cxx',
 683                    'Name' => 'C++',
 684                    'config_vars' => ['CXX'],
 685                    'linker' => 'CXXLINK',
 686                    'link' => '$(CXXLD) $(AM_CXXFLAGS) $(CXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 687                    'autodep' => 'CXX',
 688                    'flags' => ['CXXFLAGS', 'CPPFLAGS'],
 689                    'compile' => '$(CXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CXXFLAGS) $(CXXFLAGS)',
 690                    'compiler' => 'CXXCOMPILE',
 691                    'compile_flag' => '-c',
 692                    'output_flag' => '-o',
 693                    'libtool_tag' => 'CXX',
 694                    'lder' => 'CXXLD',
 695                    'ld' => '$(CXX)',
 696                    'pure' => 1,
 697                    'extensions' => ['.c++', '.cc', '.cpp', '.cxx', '.C']);
 698
 699 # Objective C.
 700 register_language ('name' => 'objc',
 701                    'Name' => 'Objective C',
 702                    'config_vars' => ['OBJC'],
 703                    'linker' => 'OBJCLINK',,
 704                    'link' => '$(OBJCLD) $(AM_OBJCFLAGS) $(OBJCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 705                    'autodep' => 'OBJC',
 706                    'flags' => ['OBJCFLAGS', 'CPPFLAGS'],
 707                    'compile' => '$(OBJC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCFLAGS) $(OBJCFLAGS)',
 708                    'compiler' => 'OBJCCOMPILE',
 709                    'compile_flag' => '-c',
 710                    'output_flag' => '-o',
 711                    'lder' => 'OBJCLD',
 712                    'ld' => '$(OBJC)',
 713                    'pure' => 1,
 714                    'extensions' => ['.m']);
 715
 716 # Headers.
 717 register_language ('name' => 'header',
 718                    'Name' => 'Header',
 719                    'extensions' => ['.h', '.H', '.hxx', '.h++', '.hh',
 720                                     '.hpp', '.inc'],
 721                    # No output.
 722                    'output_extensions' => sub { return () },
 723                    # Nothing to do.
 724                    '_finish' => sub { });
 725
 726 # Yacc (C & C++).
 727 register_language ('name' => 'yacc',
 728                    'Name' => 'Yacc',
 729                    'config_vars' => ['YACC'],
 730                    'flags' => ['YFLAGS'],
 731                    'compile' => '$(YACC) $(YFLAGS) $(AM_YFLAGS)',
 732                    'compiler' => 'YACCCOMPILE',
 733                    'extensions' => ['.y'],
 734                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 735                                                 return ($ext,) },
 736                    'rule_file' => 'yacc',
 737                    '_finish' => \&lang_yacc_finish,
 738                    '_target_hook' => \&lang_yacc_target_hook);
 739 register_language ('name' => 'yaccxx',
 740                    'Name' => 'Yacc (C++)',
 741                    'config_vars' => ['YACC'],
 742                    'rule_file' => 'yacc',
 743                    'flags' => ['YFLAGS'],
 744                    'compiler' => 'YACCCOMPILE',
 745                    'compile' => '$(YACC) $(YFLAGS) $(AM_YFLAGS)',
 746                    'extensions' => ['.y++', '.yy', '.yxx', '.ypp'],
 747                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 748                                                 return ($ext,) },
 749                    '_finish' => \&lang_yacc_finish,
 750                    '_target_hook' => \&lang_yacc_target_hook);
 751
 752 # Lex (C & C++).
 753 register_language ('name' => 'lex',
 754                    'Name' => 'Lex',
 755                    'config_vars' => ['LEX'],
 756                    'rule_file' => 'lex',
 757                    'flags' => ['LFLAGS'],
 758                    'compile' => '$(LEX) $(LFLAGS) $(AM_LFLAGS)',
 759                    'compiler' => 'LEXCOMPILE',
 760                    'extensions' => ['.l'],
 761                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 762                                                 return ($ext,) },
 763                    '_finish' => \&lang_lex_finish,
 764                    '_target_hook' => \&lang_lex_target_hook);
 765 register_language ('name' => 'lexxx',
 766                    'Name' => 'Lex (C++)',
 767                    'config_vars' => ['LEX'],
 768                    'rule_file' => 'lex',
 769                    'flags' => ['LFLAGS'],
 770                    'compile' => '$(LEX) $(LFLAGS) $(AM_LFLAGS)',
 771                    'compiler' => 'LEXCOMPILE',
 772                    'extensions' => ['.l++', '.ll', '.lxx', '.lpp'],
 773                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 774                                                 return ($ext,) },
 775                    '_finish' => \&lang_lex_finish,
 776                    '_target_hook' => \&lang_lex_target_hook);
 777
 778 # Assembler.
 779 register_language ('name' => 'asm',
 780                    'Name' => 'Assembler',
 781                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 782
 783                    'flags' => ['CCASFLAGS'],
 784                    # Users can set AM_ASFLAGS to includes DEFS, INCLUDES,
 785                    # or anything else required.  They can also set AS.
 786                    'compile' => '$(CCAS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 787                    'compiler' => 'CCASCOMPILE',
 788                    'compile_flag' => '-c',
 789                    'extensions' => ['.s', '.S'],
 790
 791                    # With assembly we still use the C linker.
 792                    '_finish' => \&lang_c_finish);
 793
 794 # Fortran 77
 795 register_language ('name' => 'f77',
 796                    'Name' => 'Fortran 77',
 797                    'linker' => 'F77LINK',
 798                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 799                    'flags' => ['FFLAGS'],
 800                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS)',
 801                    'compiler' => 'F77COMPILE',
 802                    'compile_flag' => '-c',
 803                    'output_flag' => '-o',
 804                    'libtool_tag' => 'F77',
 805                    'lder' => 'F77LD',
 806                    'ld' => '$(F77)',
 807                    'pure' => 1,
 808                    'extensions' => ['.f', '.for', '.f90']);
 809
 810 # Preprocessed Fortran 77
 811 #
 812 # The current support for preprocessing Fortran 77 just involves
 813 # passing `$(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS)
 814 # $(CPPFLAGS)' as additional flags to the Fortran 77 compiler, since
 815 # this is how GNU Make does it; see the `GNU Make Manual, Edition 0.51
 816 # for `make' Version 3.76 Beta' (specifically, from info file
 817 # `(make)Catalogue of Rules').
 818 #
 819 # A better approach would be to write an Autoconf test
 820 # (i.e. AC_PROG_FPP) for a Fortran 77 preprocessor, because not all
 821 # Fortran 77 compilers know how to do preprocessing.  The Autoconf
 822 # macro AC_PROG_FPP should test the Fortran 77 compiler first for
 823 # preprocessing capabilities, and then fall back on cpp (if cpp were
 824 # available).
 825 register_language ('name' => 'ppf77',
 826                    'Name' => 'Preprocessed Fortran 77',
 827                    'config_vars' => ['F77'],
 828                    'linker' => 'F77LINK',
 829                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 830                    'lder' => 'F77LD',
 831                    'ld' => '$(F77)',
 832                    'flags' => ['FFLAGS', 'CPPFLAGS'],
 833                    'compiler' => 'PPF77COMPILE',
 834                    'compile' => '$(F77) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FFLAGS) $(FFLAGS)',
 835                    'compile_flag' => '-c',
 836                    'output_flag' => '-o',
 837                    'libtool_tag' => 'F77',
 838                    'pure' => 1,
 839                    'extensions' => ['.F']);
 840
 841 # Ratfor.
 842 register_language ('name' => 'ratfor',
 843                    'Name' => 'Ratfor',
 844                    'config_vars' => ['F77'],
 845                    'linker' => 'F77LINK',
 846                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 847                    'lder' => 'F77LD',
 848                    'ld' => '$(F77)',
 849                    'flags' => ['RFLAGS', 'FFLAGS'],
 850                    # FIXME also FFLAGS.
 851                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS) $(AM_RFLAGS) $(RFLAGS)',
 852                    'compiler' => 'RCOMPILE',
 853                    'compile_flag' => '-c',
 854                    'output_flag' => '-o',
 855                    'libtool_tag' => 'F77',
 856                    'pure' => 1,
 857                    'extensions' => ['.r']);
 858
 859 # Java via gcj.
 860 register_language ('name' => 'java',
 861                    'Name' => 'Java',
 862                    'config_vars' => ['GCJ'],
 863                    'linker' => 'GCJLINK',
 864                    'link' => '$(GCJLD) $(AM_GCJFLAGS) $(GCJFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 865                    'autodep' => 'GCJ',
 866                    'flags' => ['GCJFLAGS'],
 867                    'compile' => '$(GCJ) $(AM_GCJFLAGS) $(GCJFLAGS)',
 868                    'compiler' => 'GCJCOMPILE',
 869                    'compile_flag' => '-c',
 870                    'output_flag' => '-o',
 871                    'libtool_tag' => 'GCJ',
 872                    'lder' => 'GCJLD',
 873                    'ld' => '$(GCJ)',
 874                    'pure' => 1,
 875                    'extensions' => ['.java', '.class', '.zip', '.jar']);
 876
 877 ################################################################
 878
 879 # Error reporting functions.
 880
 881 # err_am ($MESSAGE, [%OPTIONS])
 882 # -----------------------------
 883 # Uncategorized errors about the current Makefile.am.
 884 sub err_am ($;%)
 885 {
 886   msg_am ('error', @_);
 887 }
 888
 889 # err_ac ($MESSAGE, [%OPTIONS])
 890 # -----------------------------
 891 # Uncategorized errors about configure.ac.
 892 sub err_ac ($;%)
 893 {
 894   msg_ac ('error', @_);
 895 }
 896
 897 # msg_am ($CHANNEL, $MESSAGE, [%OPTIONS])
 898 # ---------------------------------------
 899 # Messages about about the current Makefile.am.
 900 sub msg_am ($$;%)
 901 {
 902   my ($channel, $msg, %opts) = @_;
 903   msg $channel, "${am_file}.am", $msg, %opts;
 904 }
 905
 906 # msg_ac ($CHANNEL, $MESSAGE, [%OPTIONS])
 907 # ---------------------------------------
 908 # Messages about about configure.ac.
 909 sub msg_ac ($$;%)
 910 {
 911   my ($channel, $msg, %opts) = @_;
 912   msg $channel, $configure_ac, $msg, %opts;
 913 }
 914
 915 ################################################################
 916
 917 # subst ($TEXT)
 918 # -------------
 919 # Return a configure-style substitution using the indicated text.
 920 # We do this to avoid having the substitutions directly in automake.in;
 921 # when we do that they are sometimes removed and this causes confusion
 922 # and bugs.
 923 sub subst ($)
 924 {
 925     my ($text) = @_;
 926     return '@' . $text . '@';
 927 }
 928
 929 ################################################################
 930
 931
 932 # $BACKPATH
 933 # &backname ($REL-DIR)
 934 # --------------------
 935 # If I `cd $REL-DIR', then to come back, I should `cd $BACKPATH'.
 936 # For instance `src/foo' => `../..'.
 937 # Works with non strictly increasing paths, i.e., `src/../lib' => `..'.
 938 sub backname ($)
 939 {
 940     my ($file) = @_;
 941     my @res;
 942     foreach (split (/\//, $file))
 943     {
 944         next if $_ eq '.' || $_ eq '';
 945         if ($_ eq '..')
 946         {
 947             pop @res;
 948         }
 949         else
 950         {
 951             push (@res, '..');
 952         }
 953     }
 954     return join ('/', @res) || '.';
 955 }
 956
 957 ################################################################
 958
 959
 960 # Handle AUTOMAKE_OPTIONS variable.  Return 1 on error, 0 otherwise.
 961 sub handle_options
 962 {
 963   my $var = var ('AUTOMAKE_OPTIONS');
 964   if ($var)
 965     {
 966       # FIXME: We should disallow conditional definitions of AUTOMAKE_OPTIONS.
 967       if (process_option_list ($var->rdef (TRUE)->location,
 968                                $var->value_as_list_recursive (cond_filter =>
 969                                                               TRUE)))
 970         {
 971           return 1;
 972         }
 973     }
 974
 975   if ($strictness == GNITS)
 976     {
 977       set_option ('readme-alpha', INTERNAL);
 978       set_option ('std-options', INTERNAL);
 979       set_option ('check-news', INTERNAL);
 980     }
 981
 982   return 0;
 983 }
 984
 985 # shadow_unconditionally ($varname, $where)
 986 # -----------------------------------------
 987 # Return a $(variable) that contains all possible values
 988 # $varname can take.
 989 # If the VAR wasn't defined conditionally, return $(VAR).
 990 # Otherwise we create a am__VAR_DIST variable which contains
 991 # all possible values, and return $(am__VAR_DIST).
 992 sub shadow_unconditionally ($$)
 993 {
 994   my ($varname, $where) = @_;
 995   my $var = var $varname;
 996   if ($var->has_conditional_contents)
 997     {
 998       $varname = "am__${varname}_DIST";
 999       my @files = uniq ($var->value_as_list_recursive);
1000       define_pretty_variable ($varname, TRUE, $where, @files);
1001     }
1002   return "\$($varname)"
1003 }
1004
1005 # get_object_extension ($OUT)
1006 # ---------------------------
1007 # Return object extension.  Just once, put some code into the output.
1008 # OUT is the name of the output file
1009 sub get_object_extension
1010 {
1011     my ($out) = @_;
1012
1013     # Maybe require libtool library object files.
1014     my $extension = '.$(OBJEXT)';
1015     $extension = '.lo' if ($out =~ /\.la$/);
1016
1017     # Check for automatic de-ANSI-fication.
1018     $extension = '$U' . $extension
1019       if option 'ansi2knr';
1020
1021     $get_object_extension_was_run = 1;
1022
1023     return $extension;
1024 }
1025
1026
1027 # Call finish function for each language that was used.
1028 sub handle_languages
1029 {
1030     if (! option 'no-dependencies')
1031     {
1032         # Include auto-dep code.  Don't include it if DEP_FILES would
1033         # be empty.
1034         if (&saw_sources_p (0) && keys %dep_files)
1035         {
1036             # Set location of depcomp.
1037             &define_variable ('depcomp', "\$(SHELL) $config_aux_dir/depcomp",
1038                               INTERNAL);
1039             &define_variable ('am__depfiles_maybe', 'depfiles', INTERNAL);
1040
1041             require_conf_file ("$am_file.am", FOREIGN, 'depcomp');
1042
1043             my @deplist = sort keys %dep_files;
1044             # Generate each `include' individually.  Irix 6 make will
1045             # not properly include several files resulting from a
1046             # variable expansion; generating many separate includes
1047             # seems safest.
1048             $output_rules .= "\n";
1049             foreach my $iter (@deplist)
1050             {
1051                 $output_rules .= (subst ('AMDEP_TRUE')
1052                                   . subst ('am__include')
1053                                   . ' '
1054                                   . subst ('am__quote')
1055                                   . $iter
1056                                   . subst ('am__quote')
1057                                   . "\n");
1058             }
1059
1060             # Compute the set of directories to remove in distclean-depend.
1061             my @depdirs = uniq (map { dirname ($_) } @deplist);
1062             $output_rules .= &file_contents ('depend',
1063                                              new Automake::Location,
1064                                              DEPDIRS => "@depdirs");
1065         }
1066     }
1067     else
1068     {
1069         &define_variable ('depcomp', '', INTERNAL);
1070         &define_variable ('am__depfiles_maybe', '', INTERNAL);
1071     }
1072
1073     my %done;
1074
1075     # Is the c linker needed?
1076     my $needs_c = 0;
1077     foreach my $ext (sort keys %extension_seen)
1078     {
1079         next unless $extension_map{$ext};
1080
1081         my $lang = $languages{$extension_map{$ext}};
1082
1083         my $rule_file = $lang->rule_file || 'depend2';
1084
1085         # Get information on $LANG.
1086         my $pfx = $lang->autodep;
1087         my $fpfx = ($pfx eq '') ? 'CC' : $pfx;
1088
1089         my ($AMDEP, $FASTDEP) =
1090           (option 'no-dependencies' || $lang->autodep eq 'no')
1091           ? ('FALSE', 'FALSE') : ('AMDEP', "am__fastdep$fpfx");
1092
1093         my %transform = ('EXT'     => $ext,
1094                          'PFX'     => $pfx,
1095                          'FPFX'    => $fpfx,
1096                          'AMDEP'   => $AMDEP,
1097                          'FASTDEP' => $FASTDEP,
1098                          '-c'      => $lang->compile_flag || '',
1099                          'MORE-THAN-ONE'
1100                                    => (count_files_for_language ($lang->name) > 1));
1101
1102         # Generate the appropriate rules for this extension.
1103         if (((! option 'no-dependencies') && $lang->autodep ne 'no')
1104             || defined $lang->compile)
1105         {
1106             # Some C compilers don't support -c -o.  Use it only if really
1107             # needed.
1108             my $output_flag = $lang->output_flag || '';
1109             $output_flag = '-o'
1110               if (! $output_flag
1111                   && $lang->name eq 'c'
1112                   && option 'subdir-objects');
1113
1114             # Compute a possible derived extension.
1115             # This is not used by depend2.am.
1116             my $der_ext = (&{$lang->output_extensions} ($ext))[0];
1117
1118             # When we output an inference rule like `.c.o:' we
1119             # have two cases to consider: either subdir-objects
1120             # is used, or it is not.
1121             #
1122             # In the latter case the rule is used to build objects
1123             # in the current directory, and dependencies always
1124             # go into `./$(DEPDIR)/'.  We can hard-code this value.
1125             #
1126             # In the former case the rule can be used to build
1127             # objects in sub-directories too.  Dependencies should
1128             # go into the appropriate sub-directories, e.g.,
1129             # `sub/$(DEPDIR)/'.  The value of this directory
1130             # need the be computed on-the-fly.
1131             #
1132             # DEPBASE holds the name of this directory, plus the
1133             # basename part of the object file (extensions Po, TPo,
1134             # Plo, TPlo will be added later as appropriate).  It is
1135             # either hardcoded, or a shell variable (`$depbase') that
1136             # will be computed by the rule.
1137             my $depbase =
1138               option ('subdir-objects') ? '$$depbase' : '$(DEPDIR)/$*';
1139             $output_rules .=
1140               file_contents ($rule_file,
1141                              new Automake::Location,
1142                              %transform,
1143                              GENERIC   => 1,
1144
1145                              'DERIVED-EXT' => $der_ext,
1146
1147                              DEPBASE   => $depbase,
1148                              BASE      => '$*',
1149                              SOURCE    => '$<',
1150                              OBJ       => '$@',
1151                              OBJOBJ    => '$@',
1152                              LTOBJ     => '$@',
1153
1154                              COMPILE   => '$(' . $lang->compiler . ')',
1155                              LTCOMPILE => '$(LT' . $lang->compiler . ')',
1156                              -o        => $output_flag,
1157                              SUBDIROBJ => !! option 'subdir-objects');
1158         }
1159
1160         # Now include code for each specially handled object with this
1161         # language.
1162         my %seen_files = ();
1163         foreach my $file (@{$lang_specific_files{$lang->name}})
1164         {
1165             my ($derived, $source, $obj, $myext, %file_transform) = @$file;
1166
1167             # We might see a given object twice, for instance if it is
1168             # used under different conditions.
1169             next if defined $seen_files{$obj};
1170             $seen_files{$obj} = 1;
1171
1172             prog_error ("found " . $lang->name .
1173                         " in handle_languages, but compiler not defined")
1174               unless defined $lang->compile;
1175
1176             my $obj_compile = $lang->compile;
1177
1178             # Rewrite each occurrence of `AM_$flag' in the compile
1179             # rule into `${derived}_$flag' if it exists.
1180             for my $flag (@{$lang->flags})
1181               {
1182                 my $val = "${derived}_$flag";
1183                 $obj_compile =~ s/\(AM_$flag\)/\($val\)/
1184                   if set_seen ($val);
1185               }
1186
1187             my $libtool_tag = '';
1188             if ($lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag})
1189               {
1190                 $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
1191               }
1192
1193             my $obj_ltcompile =
1194               '$(LIBTOOL) --mode=compile ' . $libtool_tag . $obj_compile;
1195
1196             # We _need_ `-o' for per object rules.
1197             my $output_flag = $lang->output_flag || '-o';
1198
1199             my $depbase = dirname ($obj);
1200             $depbase = ''
1201                 if $depbase eq '.';
1202             $depbase .= '/'
1203                 unless $depbase eq '';
1204             $depbase .= '$(DEPDIR)/' . basename ($obj);
1205
1206             # Support for deansified files in subdirectories is ugly
1207             # enough to deserve an explanation.
1208             #
1209             # A Note about normal ansi2knr processing first.  On
1210             #
1211             #   AUTOMAKE_OPTIONS = ansi2knr
1212             #   bin_PROGRAMS = foo
1213             #   foo_SOURCES = foo.c
1214             #
1215             # we generate rules similar to:
1216             #
1217             #   foo: foo$U.o; link ...
1218             #   foo$U.o: foo$U.c; compile ...
1219             #   foo_.c: foo.c; ansi2knr ...
1220             #
1221             # this is fairly compact, and will call ansi2knr depending
1222             # on the value of $U (`' or `_').
1223             #
1224             # It's harder with subdir sources. On
1225             #
1226             #   AUTOMAKE_OPTIONS = ansi2knr
1227             #   bin_PROGRAMS = foo
1228             #   foo_SOURCES = sub/foo.c
1229             #
1230             # we have to create foo_.c in the current directory.
1231             # (Unless the user asks 'subdir-objects'.)  This is important
1232             # in case the same file (`foo.c') is compiled from other
1233             # directories with different cpp options: foo_.c would
1234             # be preprocessed for only one set of options if it were
1235             # put in the subdirectory.
1236             #
1237             # Because foo$U.o must be built from either foo_.c or
1238             # sub/foo.c we can't be as concise as in the first example.
1239             # Instead we output
1240             #
1241             #   foo: foo$U.o; link ...
1242             #   foo_.o: foo_.c; compile ...
1243             #   foo.o: sub/foo.c; compile ...
1244             #   foo_.c: foo.c; ansi2knr ...
1245             #
1246             # This is why we'll now transform $rule_file twice
1247             # if we detect this case.
1248             # A first time we output the compile rule with `$U'
1249             # replaced by `_' and the source directory removed,
1250             # and another time we simply remove `$U'.
1251             #
1252             # Note that at this point $source (as computed by
1253             # &handle_single_transform) is `sub/foo$U.c'.
1254             # This can be confusing: it can be used as-is when
1255             # subdir-objects is set, otherwise you have to know
1256             # it really means `foo_.c' or `sub/foo.c'.
1257             my $objdir = dirname ($obj);
1258             my $srcdir = dirname ($source);
1259             if ($lang->ansi && $obj =~ /\$U/)
1260               {
1261                 prog_error "`$obj' contains \$U, but `$source' doesn't."
1262                   if $source !~ /\$U/;
1263
1264                 (my $source_ = $source) =~ s/\$U/_/g;
1265                 # Output an additional rule if _.c and .c are not in
1266                 # the same directory.  (_.c is always in $objdir.)
1267                 if ($objdir ne $srcdir)
1268                   {
1269                     (my $obj_ = $obj) =~ s/\$U/_/g;
1270                     (my $depbase_ = $depbase) =~ s/\$U/_/g;
1271                     $source_ = basename ($source_);
1272
1273                     $output_rules .=
1274                       file_contents ($rule_file,
1275                                      new Automake::Location,
1276                                      %transform,
1277                                      GENERIC   => 0,
1278
1279                                      DEPBASE   => $depbase_,
1280                                      BASE      => $obj_,
1281                                      SOURCE    => $source_,
1282                                      OBJ       => "$obj_$myext",
1283                                      OBJOBJ    => "$obj_.obj",
1284                                      LTOBJ     => "$obj_.lo",
1285
1286                                      COMPILE   => $obj_compile,
1287                                      LTCOMPILE => $obj_ltcompile,
1288                                      -o        => $output_flag,
1289                                      %file_transform);
1290                     $obj =~ s/\$U//g;
1291                     $depbase =~ s/\$U//g;
1292                     $source =~ s/\$U//g;
1293                   }
1294               }
1295
1296             $output_rules .=
1297               file_contents ($rule_file,
1298                              new Automake::Location,
1299                              %transform,
1300                              GENERIC   => 0,
1301
1302                              DEPBASE   => $depbase,
1303                              BASE      => $obj,
1304                              SOURCE    => $source,
1305                              # Use $myext and not `.o' here, in case
1306                              # we are actually building a new source
1307                              # file -- e.g. via yacc.
1308                              OBJ       => "$obj$myext",
1309                              OBJOBJ    => "$obj.obj",
1310                              LTOBJ     => "$obj.lo",
1311
1312                              COMPILE   => $obj_compile,
1313                              LTCOMPILE => $obj_ltcompile,
1314                              -o        => $output_flag,
1315                              %file_transform);
1316         }
1317
1318         # The rest of the loop is done once per language.
1319         next if defined $done{$lang};
1320         $done{$lang} = 1;
1321
1322         # Load the language dependent Makefile chunks.
1323         my %lang = map { uc ($_) => 0 } keys %languages;
1324         $lang{uc ($lang->name)} = 1;
1325         $output_rules .= file_contents ('lang-compile',
1326                                         new Automake::Location,
1327                                         %transform, %lang);
1328
1329         # If the source to a program consists entirely of code from a
1330         # `pure' language, for instance C++ for Fortran 77, then we
1331         # don't need the C compiler code.  However if we run into
1332         # something unusual then we do generate the C code.  There are
1333         # probably corner cases here that do not work properly.
1334         # People linking Java code to Fortran code deserve pain.
1335         $needs_c ||= ! $lang->pure;
1336
1337         define_compiler_variable ($lang)
1338           if ($lang->compile);
1339
1340         define_linker_variable ($lang)
1341           if ($lang->link);
1342
1343         require_variables ("$am_file.am", $lang->Name . " source seen",
1344                            TRUE, @{$lang->config_vars});
1345
1346         # Call the finisher.
1347         $lang->finish;
1348
1349         # Flags listed in `->flags' are user variables (per GNU Standards),
1350         # they should not be overridden in the Makefile...
1351         my @dont_override = @{$lang->flags};
1352         # ... and so is LDFLAGS.
1353         push @dont_override, 'LDFLAGS' if $lang->link;
1354
1355         foreach my $flag (@dont_override)
1356           {
1357             my $var = var $flag;
1358             if ($var)
1359               {
1360                 for my $cond ($var->conditions->conds)
1361                   {
1362                     if ($var->rdef ($cond)->owner == VAR_MAKEFILE)
1363                       {
1364                         msg_cond_var ('gnu', $cond, $flag,
1365                                       "`$flag' is a user variable, "
1366                                       . "you should not override it;\n"
1367                                       . "use `AM_$flag' instead.");
1368                       }
1369                   }
1370               }
1371           }
1372     }
1373
1374     # If the project is entirely C++ or entirely Fortran 77 (i.e., 1
1375     # suffix rule was learned), don't bother with the C stuff.  But if
1376     # anything else creeps in, then use it.
1377     $needs_c = 1
1378       if $need_link || suffix_rules_count > 1;
1379
1380     if ($needs_c)
1381       {
1382         &define_compiler_variable ($languages{'c'})
1383           unless defined $done{$languages{'c'}};
1384         define_linker_variable ($languages{'c'});
1385       }
1386 }
1387
1388 # Check to make sure a source defined in LIBOBJS is not explicitly
1389 # mentioned.  This is a separate function (as opposed to being inlined
1390 # in handle_source_transform) because it isn't always appropriate to
1391 # do this check.
1392 sub check_libobjs_sources
1393 {
1394   my ($one_file, $unxformed) = @_;
1395
1396   foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1397                       'dist_EXTRA_', 'nodist_EXTRA_')
1398     {
1399       my @files;
1400       my $varname = $prefix . $one_file . '_SOURCES';
1401       my $var = var ($varname);
1402       if ($var)
1403         {
1404           @files = $var->value_as_list_recursive;
1405         }
1406       elsif ($prefix eq '')
1407         {
1408           @files = ($unxformed . '.c');
1409         }
1410       else
1411         {
1412           next;
1413         }
1414
1415       foreach my $file (@files)
1416         {
1417           err_var ($prefix . $one_file . '_SOURCES',
1418                    "automatically discovered file `$file' should not" .
1419                    " be explicitly mentioned")
1420             if defined $libsources{$file};
1421         }
1422     }
1423 }
1424
1425
1426 # @OBJECTS
1427 # handle_single_transform ($VAR, $TOPPARENT, $DERIVED, $OBJ, $FILE, %TRANSFORM)
1428 # -----------------------------------------------------------------------------
1429 # Does much of the actual work for handle_source_transform.
1430 # Arguments are:
1431 #   $VAR is the name of the variable that the source filenames come from
1432 #   $TOPPARENT is the name of the _SOURCES variable which is being processed
1433 #   $DERIVED is the name of resulting executable or library
1434 #   $OBJ is the object extension (e.g., `$U.lo')
1435 #   $FILE the source file to transform
1436 #   %TRANSFORM contains extras arguments to pass to file_contents
1437 #     when producing explicit rules
1438 # Result is a list of the names of objects
1439 # %linkers_used will be updated with any linkers needed
1440 sub handle_single_transform ($$$$$%)
1441 {
1442     my ($var, $topparent, $derived, $obj, $_file, %transform) = @_;
1443     my @files = ($_file);
1444     my @result = ();
1445     my $nonansi_obj = $obj;
1446     $nonansi_obj =~ s/\$U//g;
1447
1448     # Turn sources into objects.  We use a while loop like this
1449     # because we might add to @files in the loop.
1450     while (scalar @files > 0)
1451     {
1452         $_ = shift @files;
1453
1454         # Configure substitutions in _SOURCES variables are errors.
1455         if (/^\@.*\@$/)
1456         {
1457           my $parent_msg = '';
1458           $parent_msg = "\nand is referred to from `$topparent'"
1459             if $topparent ne $var->name;
1460           err_var ($var,
1461                    "`" . $var->name . "' includes configure substitution `$_'"
1462                    . $parent_msg . ";\nconfigure " .
1463                    "substitutions are not allowed in _SOURCES variables");
1464           next;
1465         }
1466
1467         # If the source file is in a subdirectory then the `.o' is put
1468         # into the current directory, unless the subdir-objects option
1469         # is in effect.
1470
1471         # Split file name into base and extension.
1472         next if ! /^(?:(.*)\/)?([^\/]*)($KNOWN_EXTENSIONS_PATTERN)$/;
1473         my $full = $_;
1474         my $directory = $1 || '';
1475         my $base = $2;
1476         my $extension = $3;
1477
1478         # We must generate a rule for the object if it requires its own flags.
1479         my $renamed = 0;
1480         my ($linker, $object);
1481
1482         # This records whether we've seen a derived source file (e.g.
1483         # yacc output).
1484         my $derived_source = 0;
1485
1486         # This holds the `aggregate context' of the file we are
1487         # currently examining.  If the file is compiled with
1488         # per-object flags, then it will be the name of the object.
1489         # Otherwise it will be `AM'.  This is used by the target hook
1490         # language function.
1491         my $aggregate = 'AM';
1492
1493         $extension = &derive_suffix ($extension, $nonansi_obj);
1494         my $lang;
1495         if ($extension_map{$extension} &&
1496             ($lang = $languages{$extension_map{$extension}}))
1497         {
1498             # Found the language, so see what it says.
1499             &saw_extension ($extension);
1500
1501             # Note: computed subr call.  The language rewrite function
1502             # should return one of the LANG_* constants.  It could
1503             # also return a list whose first value is such a constant
1504             # and whose second value is a new source extension which
1505             # should be applied.  This means this particular language
1506             # generates another source file which we must then process
1507             # further.
1508             my $subr = \&{'lang_' . $lang->name . '_rewrite'};
1509             my ($r, $source_extension)
1510                 = &$subr ($directory, $base, $extension);
1511             # Skip this entry if we were asked not to process it.
1512             next if $r == LANG_IGNORE;
1513
1514             # Now extract linker and other info.
1515             $linker = $lang->linker;
1516
1517             my $this_obj_ext;
1518             if (defined $source_extension)
1519             {
1520                 $this_obj_ext = $source_extension;
1521                 $derived_source = 1;
1522             }
1523             elsif ($lang->ansi)
1524             {
1525                 $this_obj_ext = $obj;
1526             }
1527             else
1528             {
1529                 $this_obj_ext = $nonansi_obj;
1530             }
1531             $object = $base . $this_obj_ext;
1532
1533             # Do we have per-executable flags for this executable?
1534             my $have_per_exec_flags = 0;
1535             foreach my $flag (@{$lang->flags})
1536               {
1537                 if (set_seen ("${derived}_$flag"))
1538                   {
1539                     $have_per_exec_flags = 1;
1540                     last;
1541                   }
1542               }
1543
1544             if ($have_per_exec_flags)
1545             {
1546                 # We have a per-executable flag in effect for this
1547                 # object.  In this case we rewrite the object's
1548                 # name to ensure it is unique.  We also require
1549                 # the `compile' program to deal with compilers
1550                 # where `-c -o' does not work.
1551
1552                 # We choose the name `DERIVED_OBJECT' to ensure
1553                 # (1) uniqueness, and (2) continuity between
1554                 # invocations.  However, this will result in a
1555                 # name that is too long for losing systems, in
1556                 # some situations.  So we provide _SHORTNAME to
1557                 # override.
1558
1559                 my $dname = $derived;
1560                 my $var = var ($derived . '_SHORTNAME');
1561                 if ($var)
1562                 {
1563                     # FIXME: should use the same Condition as
1564                     # the _SOURCES variable.  But this is really
1565                     # silly overkill -- nobody should have
1566                     # conditional shortnames.
1567                     $dname = $var->variable_value;
1568                 }
1569                 $object = $dname . '-' . $object;
1570
1571                 require_conf_file ("$am_file.am", FOREIGN, 'compile')
1572                     if $lang->name eq 'c';
1573
1574                 prog_error ($lang->name . " flags defined without compiler")
1575                   if ! defined $lang->compile;
1576
1577                 $renamed = 1;
1578             }
1579
1580             # If rewrite said it was ok, put the object into a
1581             # subdir.
1582             if ($r == LANG_SUBDIR && $directory ne '')
1583             {
1584                 $object = $directory . '/' . $object;
1585             }
1586
1587             # If the object file has been renamed (because per-target
1588             # flags are used) we cannot compile the file with an
1589             # inference rule: we need an explicit rule.
1590             #
1591             # If the source is in a subdirectory and the object is in
1592             # the current directory, we also need an explicit rule.
1593             #
1594             # If both source and object files are in a subdirectory
1595             # (this happens when the subdir-objects option is used),
1596             # then the inference will work.
1597             #
1598             # The latter case deserves a historical note.  When the
1599             # subdir-objects option was added on 1999-04-11 it was
1600             # thought that inferences rules would work for
1601             # subdirectory objects too.  Later, on 1999-11-22,
1602             # automake was changed to output explicit rules even for
1603             # subdir-objects.  Nobody remembers why, but this occured
1604             # soon after the merge of the user-dep-gen-branch so it
1605             # might be related.  In late 2003 people complained about
1606             # the size of the generated Makefile.ins (libgcj, with
1607             # 2200+ subdir objects was reported to have a 9MB
1608             # Makefile), so we now rely on inference rules again.
1609             # Maybe we'll run across the same issue as in the past,
1610             # but at least this time we can document it.  However since
1611             # dependency tracking has evolved it is possible that
1612             # our old problem no longer exists.
1613             # Using inference rules for subdir-objects has been tested
1614             # with GNU make, Solaris make, Ultrix make, BSD make,
1615             # HP-UX make, and OSF1 make successfully.
1616             if ($renamed ||
1617                 ($directory ne '' && ! option 'subdir-objects'))
1618             {
1619                 my $obj_sans_ext = substr ($object, 0,
1620                                            - length ($this_obj_ext));
1621                 my $full_ansi = $full;
1622                 if ($lang->ansi && option 'ansi2knr')
1623                   {
1624                     $full_ansi =~ s/$KNOWN_EXTENSIONS_PATTERN$/\$U$&/;
1625                     $obj_sans_ext .= '$U';
1626                   }
1627
1628                 my @specifics = ($full_ansi, $obj_sans_ext,
1629                                  # Only use $this_obj_ext in the derived
1630                                  # source case because in the other case we
1631                                  # *don't* want $(OBJEXT) to appear here.
1632                                  ($derived_source ? $this_obj_ext : '.o'));
1633
1634                 # If we renamed the object then we want to use the
1635                 # per-executable flag name.  But if this is simply a
1636                 # subdir build then we still want to use the AM_ flag
1637                 # name.
1638                 if ($renamed)
1639                   {
1640                     unshift @specifics, $derived;
1641                     $aggregate = $derived;
1642                   }
1643                 else
1644                   {
1645                     unshift @specifics, 'AM';
1646                   }
1647
1648                 # Each item on this list is a reference to a list consisting
1649                 # of four values followed by additional transform flags for
1650                 # file_contents.   The four values are the derived flag prefix
1651                 # (e.g. for `foo_CFLAGS', it is `foo'), the name of the
1652                 # source file, the base name of the output file, and
1653                 # the extension for the object file.
1654                 push (@{$lang_specific_files{$lang->name}},
1655                       [@specifics, %transform]);
1656             }
1657         }
1658         elsif ($extension eq $nonansi_obj)
1659         {
1660             # This is probably the result of a direct suffix rule.
1661             # In this case we just accept the rewrite.
1662             $object = "$base$extension";
1663             $linker = '';
1664         }
1665         else
1666         {
1667             # No error message here.  Used to have one, but it was
1668             # very unpopular.
1669             # FIXME: we could potentially do more processing here,
1670             # perhaps treating the new extension as though it were a
1671             # new source extension (as above).  This would require
1672             # more restructuring than is appropriate right now.
1673             next;
1674         }
1675
1676         err_am "object `$object' created by `$full' and `$object_map{$object}'"
1677           if (defined $object_map{$object}
1678               && $object_map{$object} ne $full);
1679
1680         my $comp_val = (($object =~ /\.lo$/)
1681                         ? COMPILE_LIBTOOL : COMPILE_ORDINARY);
1682         (my $comp_obj = $object) =~ s/\.lo$/.\$(OBJEXT)/;
1683         if (defined $object_compilation_map{$comp_obj}
1684             && $object_compilation_map{$comp_obj} != 0
1685             # Only see the error once.
1686             && ($object_compilation_map{$comp_obj}
1687                 != (COMPILE_LIBTOOL | COMPILE_ORDINARY))
1688             && $object_compilation_map{$comp_obj} != $comp_val)
1689           {
1690             err_am "object `$comp_obj' created both with libtool and without";
1691           }
1692         $object_compilation_map{$comp_obj} |= $comp_val;
1693
1694         if (defined $lang)
1695         {
1696             # Let the language do some special magic if required.
1697             $lang->target_hook ($aggregate, $object, $full);
1698         }
1699
1700         if ($derived_source)
1701           {
1702             prog_error ($lang->name . " has automatic dependency tracking")
1703               if $lang->autodep ne 'no';
1704             # Make sure this new source file is handled next.  That will
1705             # make it appear to be at the right place in the list.
1706             unshift (@files, $object);
1707             # Distribute derived sources unless the source they are
1708             # derived from is not.
1709             &push_dist_common ($object)
1710               unless ($topparent =~ /^(?:nobase_)?nodist_/);
1711             next;
1712           }
1713
1714         $linkers_used{$linker} = 1;
1715
1716         push (@result, $object);
1717
1718         if (! defined $object_map{$object})
1719         {
1720             my @dep_list = ();
1721             $object_map{$object} = $full;
1722
1723             # If resulting object is in subdir, we need to make
1724             # sure the subdir exists at build time.
1725             if ($object =~ /\//)
1726             {
1727                 # FIXME: check that $DIRECTORY is somewhere in the
1728                 # project
1729
1730                 # For Java, the way we're handling it right now, a
1731                 # `..' component doesn't make sense.
1732                 if ($lang->name eq 'java' && $object =~ /(\/|^)\.\.\//)
1733                   {
1734                     err_am "`$full' should not contain a `..' component";
1735                   }
1736
1737                 # Make sure object is removed by `make mostlyclean'.
1738                 $compile_clean_files{$object} = MOSTLY_CLEAN;
1739                 # If we have a libtool object then we also must remove
1740                 # the ordinary .o.
1741                 if ($object =~ /\.lo$/)
1742                 {
1743                     (my $xobj = $object) =~ s,lo$,\$(OBJEXT),;
1744                     $compile_clean_files{$xobj} = MOSTLY_CLEAN;
1745
1746                     # Remove any libtool object in this directory.
1747                     $libtool_clean_directories{$directory} = 1;
1748                 }
1749
1750                 push (@dep_list, require_build_directory ($directory));
1751
1752                 # If we're generating dependencies, we also want
1753                 # to make sure that the appropriate subdir of the
1754                 # .deps directory is created.
1755                 push (@dep_list,
1756                       require_build_directory ($directory . '/$(DEPDIR)'))
1757                   unless option 'no-dependencies';
1758             }
1759
1760             &pretty_print_rule ($object . ':', "\t", @dep_list)
1761                 if scalar @dep_list > 0;
1762         }
1763
1764         # Transform .o or $o file into .P file (for automatic
1765         # dependency code).
1766         if ($lang && $lang->autodep ne 'no')
1767         {
1768             my $depfile = $object;
1769             $depfile =~ s/\.([^.]*)$/.P$1/;
1770             $depfile =~ s/\$\(OBJEXT\)$/o/;
1771             $dep_files{dirname ($depfile) . '/$(DEPDIR)/'
1772                            . basename ($depfile)} = 1;
1773         }
1774     }
1775
1776     return @result;
1777 }
1778
1779
1780 # $LINKER
1781 # define_objects_from_sources ($VAR, $OBJVAR, $NODEFINE, $ONE_FILE,
1782 #                              $OBJ, $PARENT, $TOPPARENT, $WHERE, %TRANSFORM)
1783 # ---------------------------------------------------------------------------
1784 # Define an _OBJECTS variable for a _SOURCES variable (or subvariable)
1785 #
1786 # Arguments are:
1787 #   $VAR is the name of the _SOURCES variable
1788 #   $OBJVAR is the name of the _OBJECTS variable if known (otherwise
1789 #     it will be generated and returned).
1790 #   $NODEFINE is a boolean: if true, $OBJVAR will not be defined (but
1791 #     work done to determine the linker will be).
1792 #   $ONE_FILE is the canonical (transformed) name of object to build
1793 #   $OBJ is the object extension (i.e. either `.o' or `.lo').
1794 #   $TOPPARENT is the _SOURCES variable being processed.
1795 #   $WHERE context into which this definition is done
1796 #   %TRANSFORM extra arguments to pass to file_contents when producing
1797 #     rules
1798 #
1799 # Result is a pair ($LINKER, $OBJVAR):
1800 #    $LINKER is a boolean, true if a linker is needed to deal with the objects
1801 sub define_objects_from_sources ($$$$$$$%)
1802 {
1803   my ($var, $objvar, $nodefine, $one_file,
1804       $obj, $topparent, $where, %transform) = @_;
1805
1806   my $needlinker = "";
1807
1808   transform_variable_recursively
1809     ($var, $objvar, 'am__objects', $nodefine, $where,
1810      # The transform code to run on each filename.
1811      sub {
1812        my ($subvar, $val, $cond, $full_cond) = @_;
1813        my @trans = handle_single_transform ($subvar, $topparent,
1814                                             $one_file, $obj, $val,
1815                                             %transform);
1816        $needlinker = "true" if @trans;
1817        return @trans;
1818      });
1819
1820   return $needlinker;
1821 }
1822
1823
1824 # handle_source_transform ($CANON_TARGET, $TARGET, $OBJEXT, $WHERE, %TRANSFORM)
1825 # -----------------------------------------------------------------------------
1826 # Handle SOURCE->OBJECT transform for one program or library.
1827 # Arguments are:
1828 #   canonical (transformed) name of target to build
1829 #   actual target of object to build
1830 #   object extension (i.e. either `.o' or `$o'.
1831 #   location of the source variable
1832 #   extra arguments to pass to file_contents when producing rules
1833 # Return result is name of linker variable that must be used.
1834 # Empty return means just use `LINK'.
1835 sub handle_source_transform ($$$$%)
1836 {
1837     # one_file is canonical name.  unxformed is given name.  obj is
1838     # object extension.
1839     my ($one_file, $unxformed, $obj, $where, %transform) = @_;
1840
1841     my ($linker) = '';
1842
1843     # No point in continuing if _OBJECTS is defined.
1844     return if reject_var ($one_file . '_OBJECTS',
1845                           $one_file . '_OBJECTS should not be defined');
1846
1847     my %used_pfx = ();
1848     my $needlinker;
1849     %linkers_used = ();
1850     foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1851                         'dist_EXTRA_', 'nodist_EXTRA_')
1852     {
1853         my $varname = $prefix . $one_file . "_SOURCES";
1854         my $var = var $varname;
1855         next unless $var;
1856
1857         # We are going to define _OBJECTS variables using the prefix.
1858         # Then we glom them all together.  So we can't use the null
1859         # prefix here as we need it later.
1860         my $xpfx = ($prefix eq '') ? 'am_' : $prefix;
1861
1862         # Keep track of which prefixes we saw.
1863         $used_pfx{$xpfx} = 1
1864           unless $prefix =~ /EXTRA_/;
1865
1866         push @sources, "\$($varname)";
1867         push @dist_sources, shadow_unconditionally ($varname, $where)
1868           unless (option ('no-dist') || $prefix =~ /^nodist_/);
1869
1870         $needlinker |=
1871             define_objects_from_sources ($varname,
1872                                          $xpfx . $one_file . '_OBJECTS',
1873                                          $prefix =~ /EXTRA_/,
1874                                          $one_file, $obj, $varname, $where,
1875                                          %transform);
1876     }
1877     if ($needlinker)
1878     {
1879         $linker ||= &resolve_linker (%linkers_used);
1880     }
1881
1882     my @keys = sort keys %used_pfx;
1883     if (scalar @keys == 0)
1884     {
1885         # The default source for libfoo.la is libfoo.c, but for
1886         # backward compatibility we first look at libfoo_la.c
1887         my $old_default_source = "$one_file.c";
1888         (my $default_source = $unxformed) =~ s,(\.[^./\\]*)?$,.c,;
1889         if ($old_default_source ne $default_source
1890             && (rule $old_default_source || -f $old_default_source))
1891           {
1892             my $loc = $where->clone;
1893             $loc->pop_context;
1894             msg ('obsolete', $loc,
1895                  "the default source for `$unxformed' has been changed "
1896                  . "to `$default_source'.\n(Using `$old_default_source' for "
1897                  . "backward compatibility.)");
1898             $default_source = $old_default_source;
1899           }
1900
1901         &define_variable ($one_file . "_SOURCES", $default_source, $where);
1902         push (@sources, $default_source);
1903         push (@dist_sources, $default_source);
1904
1905         %linkers_used = ();
1906         my (@result) =
1907           handle_single_transform ($one_file . '_SOURCES',
1908                                    $one_file . '_SOURCES',
1909                                    $one_file, $obj,
1910                                    $default_source, %transform);
1911         $linker ||= &resolve_linker (%linkers_used);
1912         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @result);
1913     }
1914     else
1915     {
1916         @keys = map { '$(' . $_ . $one_file . '_OBJECTS)' } @keys;
1917         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @keys);
1918     }
1919
1920     # If we want to use `LINK' we must make sure it is defined.
1921     if ($linker eq '')
1922     {
1923         $need_link = 1;
1924     }
1925
1926     return $linker;
1927 }
1928
1929
1930 # handle_lib_objects ($XNAME, $VAR)
1931 # ---------------------------------
1932 # Special-case ALLOCA and LIBOBJS substitutions in _LDADD or _LIBADD variables.
1933 # Also, generate _DEPENDENCIES variable if appropriate.
1934 # Arguments are:
1935 #   transformed name of object being built, or empty string if no object
1936 #   name of _LDADD/_LIBADD-type variable to examine
1937 # Returns 1 if LIBOBJS seen, 0 otherwise.
1938 sub handle_lib_objects
1939 {
1940   my ($xname, $varname) = @_;
1941
1942   my $var = var ($varname);
1943   prog_error "handle_lib_objects: `$varname' undefined"
1944     unless $var;
1945   prog_error "handle_lib_objects: unexpected variable name `$varname'"
1946     unless $varname =~ /^(.*)(?:LIB|LD)ADD$/;
1947   my $prefix = $1 || 'AM_';
1948
1949   my $seen_libobjs = 0;
1950   my $flagvar = 0;
1951
1952   transform_variable_recursively
1953     ($varname, $xname . '_DEPENDENCIES', 'am__DEPENDENCIES',
1954      ! $xname, INTERNAL,
1955      # Transformation function, run on each filename.
1956      sub {
1957        my ($subvar, $val, $cond, $full_cond) = @_;
1958
1959        if ($val =~ /^-/)
1960          {
1961            # Skip -lfoo and -Ldir silently; these are explicitly allowed.
1962            if ($val !~ /^-[lL]/ &&
1963                # Skip -dlopen and -dlpreopen; these are explicitly allowed
1964                # for Libtool libraries or programs.  (Actually we are a bit
1965                # laxest here since this code also applies to non-libtool
1966                # libraries or programs, for which -dlopen and -dlopreopen
1967                # are pure non-sence.  Diagnosting this doesn't seems very
1968                # important: the developer will quickly get complaints from
1969                # the linker.)
1970                $val !~ /^-dl(?:pre)?open$/ &&
1971                # Only get this error once.
1972                ! $flagvar)
1973              {
1974                $flagvar = 1;
1975                # FIXME: should display a stack of nested variables
1976                # as context when $var != $subvar.
1977                err_var ($var, "linker flags such as `$val' belong in "
1978                         . "`${prefix}LDFLAGS");
1979              }
1980            return ();
1981          }
1982        elsif ($val !~ /^\@.*\@$/)
1983          {
1984            # Assume we have a file of some sort, and output it into the
1985            # dependency variable.  Autoconf substitutions are not output;
1986            # rarely is a new dependency substituted into e.g. foo_LDADD
1987            # -- but bad things (e.g. -lX11) are routinely substituted.
1988            # Note that LIBOBJS and ALLOCA are exceptions to this rule,
1989            # and handled specially below.
1990            return $val;
1991          }
1992        elsif ($val =~ /^\@(LT)?LIBOBJS\@$/)
1993          {
1994            handle_LIBOBJS ($subvar, $full_cond, $1);
1995            $seen_libobjs = 1;
1996            return $val;
1997          }
1998        elsif ($val =~ /^\@(LT)?ALLOCA\@$/)
1999          {
2000            handle_ALLOCA ($subvar, $full_cond, $1);
2001            return $val;
2002          }
2003        else
2004          {
2005            return ();
2006          }
2007      });
2008
2009   return $seen_libobjs;
2010 }
2011
2012 sub handle_LIBOBJS ($$$)
2013 {
2014   my ($var, $cond, $lt) = @_;
2015   $lt ||= '';
2016   my $myobjext = ($1 ? 'l' : '') . 'o';
2017
2018   $var->requires_variables ("\@${lt}LIBOBJS\@ used", $lt . 'LIBOBJS')
2019     if ! keys %libsources;
2020
2021   foreach my $iter (keys %libsources)
2022     {
2023       if ($iter =~ /\.[cly]$/)
2024         {
2025           &saw_extension ($&);
2026           &saw_extension ('.c');
2027         }
2028
2029       if ($iter =~ /\.h$/)
2030         {
2031           require_file_with_macro ($cond, $var, FOREIGN, $iter);
2032         }
2033       elsif ($iter ne 'alloca.c')
2034         {
2035           my $rewrite = $iter;
2036           $rewrite =~ s/\.c$/.P$myobjext/;
2037           $dep_files{'$(DEPDIR)/' . $rewrite} = 1;
2038           $rewrite = "^" . quotemeta ($iter) . "\$";
2039           # Only require the file if it is not a built source.
2040           my $bs = var ('BUILT_SOURCES');
2041           if (! $bs || ! grep (/$rewrite/, $bs->value_as_list_recursive))
2042             {
2043               require_file_with_macro ($cond, $var, FOREIGN, $iter);
2044             }
2045         }
2046     }
2047 }
2048
2049 sub handle_ALLOCA ($$$)
2050 {
2051   my ($var, $cond, $lt) = @_;
2052   my $myobjext = ($lt ? 'l' : '') . 'o';
2053   $lt ||= '';
2054   $var->requires_variables ("\@${lt}ALLOCA\@ used", $lt . 'ALLOCA');
2055   $dep_files{'$(DEPDIR)/alloca.P' . $myobjext} = 1;
2056   require_file_with_macro ($cond, $var, FOREIGN, 'alloca.c');
2057   &saw_extension ('c');
2058 }
2059
2060 # Canonicalize the input parameter
2061 sub canonicalize
2062 {
2063     my ($string) = @_;
2064     $string =~ tr/A-Za-z0-9_\@/_/c;
2065     return $string;
2066 }
2067
2068 # Canonicalize a name, and check to make sure the non-canonical name
2069 # is never used.  Returns canonical name.  Arguments are name and a
2070 # list of suffixes to check for.
2071 sub check_canonical_spelling
2072 {
2073   my ($name, @suffixes) = @_;
2074
2075   my $xname = &canonicalize ($name);
2076   if ($xname ne $name)
2077     {
2078       foreach my $xt (@suffixes)
2079         {
2080           reject_var ("$name$xt", "use `$xname$xt', not `$name$xt'");
2081         }
2082     }
2083
2084   return $xname;
2085 }
2086
2087
2088 # handle_compile ()
2089 # -----------------
2090 # Set up the compile suite.
2091 sub handle_compile ()
2092 {
2093     return
2094       unless $get_object_extension_was_run;
2095
2096     # Boilerplate.
2097     my $default_includes = '';
2098     if (! option 'nostdinc')
2099       {
2100         $default_includes = ' -I. -I$(srcdir)';
2101
2102         my $var = var 'CONFIG_HEADER';
2103         if ($var)
2104           {
2105             foreach my $hdr (split (' ', $var->variable_value))
2106               {
2107                 $default_includes .= ' -I' . dirname ($hdr);
2108               }
2109           }
2110       }
2111
2112     my (@mostly_rms, @dist_rms);
2113     foreach my $item (sort keys %compile_clean_files)
2114     {
2115         if ($compile_clean_files{$item} == MOSTLY_CLEAN)
2116         {
2117             push (@mostly_rms, "\t-rm -f $item");
2118         }
2119         elsif ($compile_clean_files{$item} == DIST_CLEAN)
2120         {
2121             push (@dist_rms, "\t-rm -f $item");
2122         }
2123         else
2124         {
2125           prog_error 'invalid entry in %compile_clean_files';
2126         }
2127     }
2128
2129     my ($coms, $vars, $rules) =
2130       &file_contents_internal (1, "$libdir/am/compile.am",
2131                                new Automake::Location,
2132                                ('DEFAULT_INCLUDES' => $default_includes,
2133                                 'MOSTLYRMS' => join ("\n", @mostly_rms),
2134                                 'DISTRMS' => join ("\n", @dist_rms)));
2135     $output_vars .= $vars;
2136     $output_rules .= "$coms$rules";
2137
2138     # Check for automatic de-ANSI-fication.
2139     if (option 'ansi2knr')
2140       {
2141         my ($ansi2knr_filename, $ansi2knr_where) = @{option 'ansi2knr'};
2142         my $ansi2knr_dir = '';
2143
2144         require_variables ($ansi2knr_where, "option `ansi2knr' is used",
2145                            TRUE, "ANSI2KNR", "U");
2146
2147         # topdir is where ansi2knr should be.
2148         if ($ansi2knr_filename eq 'ansi2knr')
2149           {
2150             # Only require ansi2knr files if they should appear in
2151             # this directory.
2152             require_file ($ansi2knr_where, FOREIGN,
2153                           'ansi2knr.c', 'ansi2knr.1');
2154
2155             # ansi2knr needs to be built before subdirs, so unshift it.
2156             unshift (@all, '$(ANSI2KNR)');
2157           }
2158         else
2159           {
2160             $ansi2knr_dir = dirname ($ansi2knr_filename);
2161           }
2162
2163         $output_rules .= &file_contents ('ansi2knr',
2164                                          new Automake::Location,
2165                                          'ANSI2KNR-DIR' => $ansi2knr_dir);
2166
2167     }
2168 }
2169
2170 # handle_libtool ()
2171 # -----------------
2172 # Handle libtool rules.
2173 sub handle_libtool
2174 {
2175   return unless var ('LIBTOOL');
2176
2177   # Libtool requires some files, but only at top level.
2178   require_conf_file_with_macro (TRUE, 'LIBTOOL', FOREIGN, @libtool_files)
2179     if $relative_dir eq '.';
2180
2181   my @libtool_rms;
2182   foreach my $item (sort keys %libtool_clean_directories)
2183     {
2184       my $dir = ($item eq '.') ? '' : "$item/";
2185       # .libs is for Unix, _libs for DOS.
2186       push (@libtool_rms, "\t-rm -rf ${dir}.libs ${dir}_libs");
2187     }
2188
2189   # Output the libtool compilation rules.
2190   $output_rules .= &file_contents ('libtool',
2191                                    new Automake::Location,
2192                                    LTRMS => join ("\n", @libtool_rms));
2193 }
2194
2195 # handle_programs ()
2196 # ------------------
2197 # Handle C programs.
2198 sub handle_programs
2199 {
2200   my @proglist = &am_install_var ('progs', 'PROGRAMS',
2201                                   'bin', 'sbin', 'libexec', 'pkglib',
2202                                   'noinst', 'check');
2203   return if ! @proglist;
2204
2205   my $seen_global_libobjs =
2206     var ('LDADD') && &handle_lib_objects ('', 'LDADD');
2207
2208   foreach my $pair (@proglist)
2209     {
2210       my ($where, $one_file) = @$pair;
2211
2212       my $seen_libobjs = 0;
2213       my $obj = &get_object_extension ($one_file);
2214
2215       # Strip any $(EXEEXT) suffix the user might have added, or this
2216       # will confuse &handle_source_transform and &check_canonical_spelling.
2217       # We'll add $(EXEEXT) back later anyway.
2218       $one_file =~ s/\$\(EXEEXT\)$//;
2219
2220       # Canonicalize names and check for misspellings.
2221       my $xname = &check_canonical_spelling ($one_file, '_LDADD', '_LDFLAGS',
2222                                              '_SOURCES', '_OBJECTS',
2223                                              '_DEPENDENCIES');
2224
2225       $where->push_context ("while processing program `$one_file'");
2226       $where->set (INTERNAL->get);
2227
2228       my $linker = &handle_source_transform ($xname, $one_file, $obj, $where,
2229                                              NONLIBTOOL => 1, LIBTOOL => 0);
2230
2231       if (var ($xname . "_LDADD"))
2232         {
2233           $seen_libobjs = &handle_lib_objects ($xname, $xname . '_LDADD');
2234         }
2235       else
2236         {
2237           # User didn't define prog_LDADD override.  So do it.
2238           &define_variable ($xname . '_LDADD', '$(LDADD)', $where);
2239
2240           # This does a bit too much work.  But we need it to
2241           # generate _DEPENDENCIES when appropriate.
2242           if (var ('LDADD'))
2243             {
2244               $seen_libobjs = &handle_lib_objects ($xname, 'LDADD');
2245             }
2246         }
2247
2248       reject_var ($xname . '_LIBADD',
2249                   "use `${xname}_LDADD', not `${xname}_LIBADD'");
2250
2251       set_seen ($xname . '_DEPENDENCIES');
2252       set_seen ($xname . '_LDFLAGS');
2253
2254       # Determine program to use for link.
2255       my $xlink;
2256       if (var ($xname . '_LINK'))
2257         {
2258           $xlink = $xname . '_LINK';
2259         }
2260       else
2261         {
2262           $xlink = $linker ? $linker : 'LINK';
2263         }
2264
2265       # If the resulting program lies into a subdirectory,
2266       # make sure this directory will exist.
2267       my $dirstamp = require_build_directory_maybe ($one_file);
2268
2269       $output_rules .= &file_contents ('program',
2270                                        $where,
2271                                        PROGRAM  => $one_file,
2272                                        XPROGRAM => $xname,
2273                                        XLINK    => $xlink,
2274                                        DIRSTAMP => $dirstamp,
2275                                        EXEEXT   => '$(EXEEXT)');
2276
2277       if ($seen_libobjs || $seen_global_libobjs)
2278         {
2279           if (var ($xname . '_LDADD'))
2280             {
2281               &check_libobjs_sources ($xname, $xname . '_LDADD');
2282             }
2283           elsif (var ('LDADD'))
2284             {
2285               &check_libobjs_sources ($xname, 'LDADD');
2286             }
2287         }
2288     }
2289 }
2290
2291
2292 # handle_libraries ()
2293 # -------------------
2294 # Handle libraries.
2295 sub handle_libraries
2296 {
2297   my @liblist = &am_install_var ('libs', 'LIBRARIES',
2298                                  'lib', 'pkglib', 'noinst', 'check');
2299   return if ! @liblist;
2300
2301   my @prefix = am_primary_prefixes ('LIBRARIES', 0, 'lib', 'pkglib',
2302                                     'noinst', 'check');
2303
2304   if (@prefix)
2305     {
2306       my $var = rvar ($prefix[0] . '_LIBRARIES');
2307       $var->requires_variables ('library used', 'RANLIB');
2308     }
2309
2310   foreach my $pair (@liblist)
2311     {
2312       my ($where, $onelib) = @$pair;
2313
2314       my $seen_libobjs = 0;
2315       # Check that the library fits the standard naming convention.
2316       if (basename ($onelib) !~ /^lib.*\.a/)
2317         {
2318           error $where, "`$onelib' is not a standard library name";
2319         }
2320
2321       $where->push_context ("while processing library `$onelib'");
2322       $where->set (INTERNAL->get);
2323
2324       my $obj = &get_object_extension ($onelib);
2325
2326       # Canonicalize names and check for misspellings.
2327       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_SOURCES',
2328                                             '_OBJECTS', '_DEPENDENCIES',
2329                                             '_AR');
2330
2331       if (! var ($xlib . '_AR'))
2332         {
2333           &define_variable ($xlib . '_AR', '$(AR) $(ARFLAGS)', $where);
2334         }
2335
2336       # Generate support for conditional object inclusion in
2337       # libraries.
2338       if (var ($xlib . '_LIBADD'))
2339         {
2340           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2341             {
2342               $seen_libobjs = 1;
2343             }
2344         }
2345       else
2346         {
2347           &define_variable ($xlib . "_LIBADD", '', $where);
2348         }
2349
2350       reject_var ($xlib . '_LDADD',
2351                   "use `${xlib}_LIBADD', not `${xlib}_LDADD'");
2352
2353       # Make sure we at look at this.
2354       set_seen ($xlib . '_DEPENDENCIES');
2355
2356       &handle_source_transform ($xlib, $onelib, $obj, $where,
2357                                 NONLIBTOOL => 1, LIBTOOL => 0);
2358
2359       # If the resulting library lies into a subdirectory,
2360       # make sure this directory will exist.
2361       my $dirstamp = require_build_directory_maybe ($onelib);
2362
2363       $output_rules .= &file_contents ('library',
2364                                        $where,
2365                                        LIBRARY  => $onelib,
2366                                        XLIBRARY => $xlib,
2367                                        DIRSTAMP => $dirstamp);
2368
2369       if ($seen_libobjs)
2370         {
2371           if (var ($xlib . '_LIBADD'))
2372             {
2373               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2374             }
2375         }
2376     }
2377 }
2378
2379
2380 # handle_ltlibraries ()
2381 # ---------------------
2382 # Handle shared libraries.
2383 sub handle_ltlibraries
2384 {
2385   my @liblist = &am_install_var ('ltlib', 'LTLIBRARIES',
2386                                  'noinst', 'lib', 'pkglib', 'check');
2387   return if ! @liblist;
2388
2389   my %instdirs;
2390   my @prefix = am_primary_prefixes ('LTLIBRARIES', 0, 'lib', 'pkglib',
2391                                     'noinst', 'check');
2392
2393   if (@prefix)
2394     {
2395       my $var = rvar ($prefix[0] . '_LTLIBRARIES');
2396       $var->requires_variables ('Libtool library used', 'LIBTOOL');
2397     }
2398
2399   my %liblocations = ();        # Location (in Makefile.am) of each library.
2400
2401   foreach my $key (@prefix)
2402     {
2403       # Get the installation directory of each library.
2404       (my $dir = $key) =~ s/^nobase_//;
2405       my $var = rvar ($key . '_LTLIBRARIES');
2406       for my $pair ($var->value_as_list_recursive (location => 1))
2407         {
2408           my ($where, $lib) = @$pair;
2409           # We reject libraries which are installed in several places,
2410           # because we don't handle this in the rules (think `-rpath').
2411           #
2412           # However, we allow the same library to be listed many times
2413           # for the same directory.  This is for users who need setups
2414           # like
2415           #   if COND1
2416           #     lib_LTLIBRARIES = libfoo.la
2417           #   endif
2418           #   if COND2
2419           #     lib_LTLIBRARIES = libfoo.la
2420           #   endif
2421           #
2422           # Actually this will also allow
2423           #   lib_LTLIBRARIES = libfoo.la libfoo.la
2424           # Diagnosing this case doesn't seem worth the plain (we'd
2425           # have to fill $instdirs on a per-condition basis, check
2426           # implied conditions, etc.)
2427           if (defined $instdirs{$lib} && $instdirs{$lib} ne $dir)
2428             {
2429               error ($where, "`$lib' is already going to be installed in "
2430                      . "`$instdirs{$lib}'", partial => 1);
2431               error ($liblocations{$lib}, "`$lib' previously declared here");
2432             }
2433           else
2434             {
2435               $instdirs{$lib} = $dir;
2436               $liblocations{$lib} = $where->clone;
2437             }
2438         }
2439     }
2440
2441   foreach my $pair (@liblist)
2442     {
2443       my ($where, $onelib) = @$pair;
2444
2445       my $seen_libobjs = 0;
2446       my $obj = &get_object_extension ($onelib);
2447
2448       # Canonicalize names and check for misspellings.
2449       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_LDFLAGS',
2450                                             '_SOURCES', '_OBJECTS',
2451                                             '_DEPENDENCIES');
2452
2453       # Check that the library fits the standard naming convention.
2454       my $libname_rx = "^lib.*\.la";
2455       my $ldvar = var ("${xlib}_LDFLAGS") || var ('AM_LDFLAGS');
2456       my $ldvar2 = var ('LDFLAGS');
2457       if (($ldvar && grep (/-module/, $ldvar->value_as_list_recursive))
2458           || ($ldvar2 && grep (/-module/, $ldvar2->value_as_list_recursive)))
2459         {
2460           # Relax name checking for libtool modules.
2461           $libname_rx = "\.la";
2462         }
2463       if (basename ($onelib) !~ /$libname_rx$/)
2464         {
2465           msg ('error-gnu/warn', $where,
2466                "`$onelib' is not a standard libtool library name");
2467         }
2468
2469       $where->push_context ("while processing Libtool library `$onelib'");
2470       $where->set (INTERNAL->get);
2471
2472       # Make sure we at look at these.
2473       set_seen ($xlib . '_LDFLAGS');
2474       set_seen ($xlib . '_DEPENDENCIES');
2475
2476       # Generate support for conditional object inclusion in
2477       # libraries.
2478       if (var ($xlib . '_LIBADD'))
2479         {
2480           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2481             {
2482               $seen_libobjs = 1;
2483             }
2484         }
2485       else
2486         {
2487           &define_variable ($xlib . "_LIBADD", '', $where);
2488         }
2489
2490       reject_var ("${xlib}_LDADD",
2491                   "use `${xlib}_LIBADD', not `${xlib}_LDADD'");
2492
2493
2494       my $linker = &handle_source_transform ($xlib, $onelib, $obj, $where,
2495                                              NONLIBTOOL => 0, LIBTOOL => 1);
2496
2497       # Determine program to use for link.
2498       my $xlink;
2499       if (var ($xlib . '_LINK'))
2500         {
2501           $xlink = $xlib . '_LINK';
2502         }
2503       else
2504         {
2505           $xlink = $linker ? $linker : 'LINK';
2506         }
2507
2508       my $rpath;
2509       if ($instdirs{$onelib} eq 'EXTRA'
2510           || $instdirs{$onelib} eq 'noinst'
2511           || $instdirs{$onelib} eq 'check')
2512         {
2513           # It's an EXTRA_ library, so we can't specify -rpath,
2514           # because we don't know where the library will end up.
2515           # The user probably knows, but generally speaking automake
2516           # doesn't -- and in fact configure could decide
2517           # dynamically between two different locations.
2518           $rpath = '';
2519         }
2520       else
2521         {
2522           $rpath = ('-rpath $(' . $instdirs{$onelib} . 'dir)');
2523         }
2524
2525       # If the resulting library lies into a subdirectory,
2526       # make sure this directory will exist.
2527       my $dirstamp = require_build_directory_maybe ($onelib);
2528
2529       # Remember to cleanup .libs/ in this directory.
2530       my $dirname = dirname $onelib;
2531       $libtool_clean_directories{$dirname} = 1;
2532
2533       $output_rules .= &file_contents ('ltlibrary',
2534                                        $where,
2535                                        LTLIBRARY  => $onelib,
2536                                        XLTLIBRARY => $xlib,
2537                                        RPATH      => $rpath,
2538                                        XLINK      => $xlink,
2539                                        DIRSTAMP   => $dirstamp);
2540       if ($seen_libobjs)
2541         {
2542           if (var ($xlib . '_LIBADD'))
2543             {
2544               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2545             }
2546         }
2547     }
2548 }
2549
2550 # See if any _SOURCES variable were misspelled.
2551 sub check_typos ()
2552 {
2553   # It is ok if the user sets this particular variable.
2554   set_seen 'AM_LDFLAGS';
2555
2556   foreach my $var (variables)
2557     {
2558       my $varname = $var->name;
2559       # A configure variable is always legitimate.
2560       next if exists $configure_vars{$varname};
2561
2562       my $check = 0;
2563       foreach my $primary ('_SOURCES', '_LIBADD', '_LDADD', '_LDFLAGS',
2564                            '_DEPENDENCIES')
2565         {
2566           if ($varname =~ /$primary$/)
2567             {
2568               $check = 1;
2569               last;
2570             }
2571         }
2572       next unless $check;
2573
2574       for my $cond ($var->conditions->conds)
2575         {
2576           msg_var 'syntax', $var, "unused variable: `$varname'"
2577             unless $var->rdef ($cond)->seen;
2578         }
2579     }
2580 }
2581
2582
2583 # Handle scripts.
2584 sub handle_scripts
2585 {
2586     # NOTE we no longer automatically clean SCRIPTS, because it is
2587     # useful to sometimes distribute scripts verbatim.  This happens
2588     # e.g. in Automake itself.
2589     &am_install_var ('-candist', 'scripts', 'SCRIPTS',
2590                      'bin', 'sbin', 'libexec', 'pkgdata',
2591                      'noinst', 'check');
2592 }
2593
2594
2595
2596
2597 ## ------------------------ ##
2598 ## Handling Texinfo files.  ##
2599 ## ------------------------ ##
2600
2601 # ($OUTFILE, $VFILE, @CLEAN_FILES)
2602 # &scan_texinfo_file ($FILENAME)
2603 # ------------------------------
2604 # $OUTFILE     - name of the info file produced by $FILENAME.
2605 # $VFILE       - name of the version.texi file used (undef if none).
2606 # @CLEAN_FILES - list of byproducts (indexes etc.)
2607 sub scan_texinfo_file ($)
2608 {
2609   my ($filename) = @_;
2610
2611   # Some of the following extensions are always created, no matter
2612   # whether indexes are used or not.  Other (like cps, fns, ... pgs)
2613   # are only created when they are used.  We used to scan $FILENAME
2614   # for their use, but that is not enough: they could be used in
2615   # included files.  We can't scan included files because we don't
2616   # know the include path.  Therefore we always erase these files, no
2617   # matter whether they are used or not.
2618   #
2619   # (tmp is only created if an @macro is used and a certain e-TeX
2620   # feature is not available.)
2621   my %clean_suffixes =
2622     map { $_ => 1 } (qw(aux log toc tmp
2623                         cp cps
2624                         fn fns
2625                         ky kys
2626                         vr vrs
2627                         tp tps
2628                         pg pgs)); # grep 'new.*index' texinfo.tex
2629
2630   my $texi = new Automake::XFile "< $filename";
2631   verb "reading $filename";
2632
2633   my ($outfile, $vfile);
2634   while ($_ = $texi->getline)
2635     {
2636       if (/^\@setfilename +(\S+)/)
2637         {
2638           # Honor only the first @setfilename.  (It's possible to have
2639           # more occurrences later if the manual shows examples of how
2640           # to use @setfilename...)
2641           next if $outfile;
2642
2643           $outfile = $1;
2644           if ($outfile =~ /\.(.+)$/ && $1 ne 'info')
2645             {
2646               error ("$filename:$.",
2647                      "output `$outfile' has unrecognized extension");
2648               return;
2649             }
2650         }
2651       # A "version.texi" file is actually any file whose name matches
2652       # "vers*.texi".
2653       elsif (/^\@include\s+(vers[^.]*\.texi)\s*$/)
2654         {
2655           $vfile = $1;
2656         }
2657
2658       # Try to find new or unused indexes.
2659
2660       # Creating a new category of index.
2661       elsif (/^\@def(code)?index (\w+)/)
2662         {
2663           $clean_suffixes{$2} = 1;
2664           $clean_suffixes{"$2s"} = 1;
2665         }
2666
2667       # Merging an index into an another.
2668       elsif (/^\@syn(code)?index (\w+) (\w+)/)
2669         {
2670           delete $clean_suffixes{"$2s"};
2671           $clean_suffixes{"$3s"} = 1;
2672         }
2673
2674     }
2675
2676   if (! $outfile)
2677     {
2678       err_am "`$filename' missing \@setfilename";
2679       return;
2680     }
2681
2682   my $infobase = basename ($filename);
2683   $infobase =~ s/\.te?xi(nfo)?$//;
2684   return ($outfile, $vfile,
2685           map { "$infobase.$_" } (sort keys %clean_suffixes));
2686 }
2687
2688
2689 # ($DIRSTAMP, @CLEAN_FILES)
2690 # output_texinfo_build_rules ($SOURCE, $DEST, $INSRC, @DEPENDENCIES)
2691 # ------------------------------------------------------------------
2692 # SOURCE - the source Texinfo file
2693 # DEST - the destination Info file
2694 # INSRC - wether DEST should be built in the source tree
2695 # DEPENDENCIES - known dependencies
2696 sub output_texinfo_build_rules ($$$@)
2697 {
2698   my ($source, $dest, $insrc, @deps) = @_;
2699
2700   # Split `a.texi' into `a' and `.texi'.
2701   my ($spfx, $ssfx) = ($source =~ /^(.*?)(\.[^.]*)?$/);
2702   my ($dpfx, $dsfx) = ($dest =~ /^(.*?)(\.[^.]*)?$/);
2703
2704   $ssfx ||= "";
2705   $dsfx ||= "";
2706
2707   # We can output two kinds of rules: the "generic" rules use Make
2708   # suffix rules and are appropriate when $source and $dest do not lie
2709   # in a sub-directory; the "specific" rules are needed in the other
2710   # case.
2711   #
2712   # The former are output only once (this is not really apparent here,
2713   # but just remember that some logic deeper in Automake will not
2714   # output the same rule twice); while the later need to be output for
2715   # each Texinfo source.
2716   my $generic;
2717   my $makeinfoflags;
2718   my $sdir = dirname $source;
2719   if ($sdir eq '.' && dirname ($dest) eq '.')
2720     {
2721       $generic = 1;
2722       $makeinfoflags = '-I $(srcdir)';
2723     }
2724   else
2725     {
2726       $generic = 0;
2727       $makeinfoflags = "-I $sdir -I \$(srcdir)/$sdir";
2728     }
2729
2730   # A directory can contain two kinds of info files: some built in the
2731   # source tree, and some built in the build tree.  The rules are
2732   # different in each case.  However we cannot output two different
2733   # set of generic rules.  Because in-source builds are more usual, we
2734   # use generic rules in this case and fall back to "specific" rules
2735   # for build-dir builds.  (It should not be a problem to invert this
2736   # if needed.)
2737   $generic = 0 unless $insrc;
2738
2739   # We cannot use a suffix rule to build info files with an empty
2740   # extension.  Otherwise we would output a single suffix inference
2741   # rule, with separate dependencies, as in
2742   #
2743   #    .texi:
2744   #             $(MAKEINFO) ...
2745   #    foo.info: foo.texi
2746   #
2747   # which confuse Solaris make.  (See the Autoconf manual for
2748   # details.)  Therefore we use a specific rule in this case.  This
2749   # applies to info files only (dvi and pdf files always have an
2750   # extension).
2751   my $generic_info = ($generic && $dsfx) ? 1 : 0;
2752
2753   # If the resulting file lie into a subdirectory,
2754   # make sure this directory will exist.
2755   my $dirstamp = require_build_directory_maybe ($dest);
2756
2757   my $dipfx = ($insrc ? '$(srcdir)/' : '') . $dpfx;
2758
2759   $output_rules .= file_contents ('texibuild',
2760                                   new Automake::Location,
2761                                   DEPS             => "@deps",
2762                                   DEST_PREFIX      => $dpfx,
2763                                   DEST_INFO_PREFIX => $dipfx,
2764                                   DEST_SUFFIX      => $dsfx,
2765                                   DIRSTAMP         => $dirstamp,
2766                                   GENERIC          => $generic,
2767                                   GENERIC_INFO     => $generic_info,
2768                                   INSRC            => $insrc,
2769                                   MAKEINFOFLAGS    => $makeinfoflags,
2770                                   SOURCE           => ($generic
2771                                                        ? '$<' : $source),
2772                                   SOURCE_INFO      => ($generic_info
2773                                                        ? '$<' : $source),
2774                                   SOURCE_REAL      => $source,
2775                                   SOURCE_SUFFIX    => $ssfx,
2776                                   );
2777   return ($dirstamp, "$dpfx.dvi", "$dpfx.pdf", "$dpfx.ps", "$dpfx.html");
2778 }
2779
2780
2781 # $TEXICLEANS
2782 # handle_texinfo_helper ($info_texinfos)
2783 # --------------------------------------
2784 # Handle all Texinfo source; helper for handle_texinfo.
2785 sub handle_texinfo_helper ($)
2786 {
2787   my ($info_texinfos) = @_;
2788   my (@infobase, @info_deps_list, @texi_deps);
2789   my %versions;
2790   my $done = 0;
2791   my @texi_cleans;
2792
2793   # Build a regex matching user-cleaned files.
2794   my $d = var 'DISTCLEANFILES';
2795   my $c = var 'CLEANFILES';
2796   my @f = ();
2797   push @f, $d->value_as_list_recursive (inner_expand => 1) if $d;
2798   push @f, $c->value_as_list_recursive (inner_expand => 1) if $c;
2799   @f = map { s|[^A-Za-z_0-9*\[\]\-]|\\$&|g; s|\*|[^/]*|g; $_; } @f;
2800   my $user_cleaned_files = '^(?:' . join ('|', @f) . ')$';
2801
2802   foreach my $texi
2803       ($info_texinfos->value_as_list_recursive (inner_expand => 1))
2804     {
2805       my $infobase = $texi;
2806       $infobase =~ s/\.(txi|texinfo|texi)$//;
2807
2808       if ($infobase eq $texi)
2809         {
2810           # FIXME: report line number.
2811           err_am "texinfo file `$texi' has unrecognized extension";
2812           next;
2813         }
2814
2815       push @infobase, $infobase;
2816
2817       # If 'version.texi' is referenced by input file, then include
2818       # automatic versioning capability.
2819       my ($out_file, $vtexi, @clean_files) =
2820         scan_texinfo_file ("$relative_dir/$texi")
2821         or next;
2822       push (@texi_cleans, @clean_files);
2823
2824       # If the Texinfo source is in a subdirectory, create the
2825       # resulting info in this subdirectory.  If it is in the current
2826       # directory, try hard to not prefix "./" because it breaks the
2827       # generic rules.
2828       my $outdir = dirname ($texi) . '/';
2829       $outdir = "" if $outdir eq './';
2830       $out_file =  $outdir . $out_file;
2831
2832       # Until Automake 1.6.3, .info files were built in the
2833       # source tree.  This was an obstacle to the support of
2834       # non-distributed .info files, and non-distributed .texi
2835       # files.
2836       #
2837       # * Non-distributed .texi files is important in some packages
2838       #   where .texi files are built at make time, probably using
2839       #   other binaries built in the package itself, maybe using
2840       #   tools or information found on the build host.  Because
2841       #   these files are not distributed they are always rebuilt
2842       #   at make time; they should therefore not lie in the source
2843       #   directory.  One plan was to support this using
2844       #   nodist_info_TEXINFOS or something similar.  (Doing this
2845       #   requires some sanity checks.  For instance Automake should
2846       #   not allow:
2847       #      dist_info_TEXINFO = foo.texi
2848       #      nodist_foo_TEXINFO = included.texi
2849       #   because a distributed file should never depend on a
2850       #   non-distributed file.)
2851       #
2852       # * If .texi files are not distributed, then .info files should
2853       #   not be distributed either.  There are also cases where one
2854       #   want to distribute .texi files, but do not want to
2855       #   distribute the .info files.  For instance the Texinfo package
2856       #   distributes the tool used to build these files; it would
2857       #   be a waste of space to distribute them.  It's not clear
2858       #   which syntax we should use to indicate that .info files should
2859       #   not be distributed.  Akim Demaille suggested that eventually
2860       #   we switch to a new syntax:
2861       #   |  Maybe we should take some inspiration from what's already
2862       #   |  done in the rest of Automake.  Maybe there is too much
2863       #   |  syntactic sugar here, and you want
2864       #   |     nodist_INFO = bar.info
2865       #   |     dist_bar_info_SOURCES = bar.texi
2866       #   |     bar_texi_DEPENDENCIES = foo.texi
2867       #   |  with a bit of magic to have bar.info represent the whole
2868       #   |  bar*info set.  That's a lot more verbose that the current
2869       #   |  situation, but it is # not new, hence the user has less
2870       #   |  to learn.
2871       #   |
2872       #   |  But there is still too much room for meaningless specs:
2873       #   |     nodist_INFO = bar.info
2874       #   |     dist_bar_info_SOURCES = bar.texi
2875       #   |     dist_PS = bar.ps something-written-by-hand.ps
2876       #   |     nodist_bar_ps_SOURCES = bar.texi
2877       #   |     bar_texi_DEPENDENCIES = foo.texi
2878       #   |  here bar.texi is dist_ in line 2, and nodist_ in 4.
2879       #
2880       # Back to the point, it should be clear that in order to support
2881       # non-distributed .info files, we need to build them in the
2882       # build tree, not in the source tree (non-distributed .texi
2883       # files are less of a problem, because we do not output build
2884       # rules for them).  In Automake 1.7 .info build rules have been
2885       # largely cleaned up so that .info files get always build in the
2886       # build tree, even when distributed.  The idea was that
2887       #   (1) if during a VPATH build the .info file was found to be
2888       #       absent or out-of-date (in the source tree or in the
2889       #       build tree), Make would rebuild it in the build tree.
2890       #       If an up-to-date source-tree of the .info file existed,
2891       #       make would not rebuild it in the build tree.
2892       #   (2) having two copies of .info files, one in the source tree
2893       #       and one (newer) in the build tree is not a problem
2894       #       because `make dist' always pick files in the build tree
2895       #       first.
2896       # However it turned out the be a bad idea for several reasons:
2897       #   * Tru64, OpenBSD, and FreeBSD (not NetBSD) Make do behave
2898       #     like GNU Make on point (1) above.  These implementations
2899       #     of Make would always rebuild .info files in the build
2900       #     tree, even if such files were up to date in the source
2901       #     tree.  Consequently, it was impossible the perform a VPATH
2902       #     build of a package containing Texinfo files using these
2903       #     Make implementations.
2904       #     (Refer to the Autoconf Manual, section "Limitation of
2905       #     Make", paragraph "VPATH", item "target lookup", for
2906       #     an account of the differences between these
2907       #     implementations.)
2908       #   * The GNU Coding Standards require these files to be built
2909       #     in the source-tree (when they are distributed, that is).
2910       #   * Keeping a fresher copy of distributed files in the
2911       #     build tree can be annoying during development because
2912       #     - if the files is kept under CVS, you really want it
2913       #       to be updated in the source tree
2914       #     - it os confusing that `make distclean' does not erase
2915       #       all files in the build tree.
2916       #
2917       # Consequently, starting with Automake 1.8, .info files are
2918       # built in the source tree again.  Because we still plan to
2919       # support non-distributed .info files at some point, we
2920       # have a single variable ($INSRC) that controls whether
2921       # the current .info file must be built in the source tree
2922       # or in the build tree.  Actually this variable is switched
2923       # off for .info files that appear to be cleaned; this is
2924       # for backward compatibility with package such as Texinfo,
2925       # which do things like
2926       #   info_TEXINFOS = texinfo.txi info-stnd.texi info.texi
2927       #   DISTCLEANFILES = texinfo texinfo-* info*.info*
2928       #   # Do not create info files for distribution.
2929       #   dist-info:
2930       # in order not to distribute .info files.
2931       my $insrc = ($out_file =~ $user_cleaned_files) ? 0 : 1;
2932
2933       my $soutdir = '$(srcdir)/' . $outdir;
2934       $outdir = $soutdir if $insrc;
2935
2936       # If user specified file_TEXINFOS, then use that as explicit
2937       # dependency list.
2938       @texi_deps = ();
2939       push (@texi_deps, "$soutdir$vtexi") if $vtexi;
2940
2941       my $canonical = canonicalize ($infobase);
2942       if (var ($canonical . "_TEXINFOS"))
2943         {
2944           push (@texi_deps, '$(' . $canonical . '_TEXINFOS)');
2945           push_dist_common ('$(' . $canonical . '_TEXINFOS)');
2946         }
2947
2948       my ($dirstamp, @cfiles) =
2949         output_texinfo_build_rules ($texi, $out_file, $insrc, @texi_deps);
2950       push (@texi_cleans, @cfiles);
2951
2952       push (@info_deps_list, $out_file);
2953
2954       # If a vers*.texi file is needed, emit the rule.
2955       if ($vtexi)
2956         {
2957           err_am ("`$vtexi', included in `$texi', "
2958                   . "also included in `$versions{$vtexi}'")
2959             if defined $versions{$vtexi};
2960           $versions{$vtexi} = $texi;
2961
2962           # We number the stamp-vti files.  This is doable since the
2963           # actual names don't matter much.  We only number starting
2964           # with the second one, so that the common case looks nice.
2965           my $vti = ($done ? $done : 'vti');
2966           ++$done;
2967
2968           # This is ugly, but it is our historical practice.
2969           if ($config_aux_dir_set_in_configure_in)
2970             {
2971               require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
2972                                             'mdate-sh');
2973             }
2974           else
2975             {
2976               require_file_with_macro (TRUE, 'info_TEXINFOS',
2977                                        FOREIGN, 'mdate-sh');
2978             }
2979
2980           my $conf_dir;
2981           if ($config_aux_dir_set_in_configure_in)
2982             {
2983               $conf_dir = $config_aux_dir;
2984               $conf_dir .= '/' unless $conf_dir =~ /\/$/;
2985             }
2986           else
2987             {
2988               $conf_dir = '$(srcdir)/';
2989             }
2990           $output_rules .= file_contents ('texi-vers',
2991                                           new Automake::Location,
2992                                           TEXI     => $texi,
2993                                           VTI      => $vti,
2994                                           STAMPVTI => "${soutdir}stamp-$vti",
2995                                           VTEXI    => "$soutdir$vtexi",
2996                                           MDDIR    => $conf_dir,
2997                                           DIRSTAMP => $dirstamp);
2998         }
2999     }
3000
3001   # Handle location of texinfo.tex.
3002   my $need_texi_file = 0;
3003   my $texinfodir;
3004   if (var ('TEXINFO_TEX'))
3005     {
3006       # The user defined TEXINFO_TEX so assume he knows what he is
3007       # doing.
3008       $texinfodir = ('$(srcdir)/'
3009                      . dirname (variable_value ('TEXINFO_TEX')));
3010     }
3011   elsif (option 'cygnus')
3012     {
3013       $texinfodir = '$(top_srcdir)/../texinfo';
3014       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3015     }
3016   elsif ($config_aux_dir_set_in_configure_in)
3017     {
3018       $texinfodir = $config_aux_dir;
3019       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3020       $need_texi_file = 2; # so that we require_conf_file later
3021     }
3022   else
3023     {
3024       $texinfodir = '$(srcdir)';
3025       $need_texi_file = 1;
3026     }
3027   define_variable ('am__TEXINFO_TEX_DIR', $texinfodir, INTERNAL);
3028
3029   push (@dist_targets, 'dist-info');
3030
3031   if (! option 'no-installinfo')
3032     {
3033       # Make sure documentation is made and installed first.  Use
3034       # $(INFO_DEPS), not 'info', because otherwise recursive makes
3035       # get run twice during "make all".
3036       unshift (@all, '$(INFO_DEPS)');
3037     }
3038
3039   define_files_variable ("DVIS", @infobase, 'dvi', INTERNAL);
3040   define_files_variable ("PDFS", @infobase, 'pdf', INTERNAL);
3041   define_files_variable ("PSS", @infobase, 'ps', INTERNAL);
3042   define_files_variable ("HTMLS", @infobase, 'html', INTERNAL);
3043
3044   # This next isn't strictly needed now -- the places that look here
3045   # could easily be changed to look in info_TEXINFOS.  But this is
3046   # probably better, in case noinst_TEXINFOS is ever supported.
3047   define_variable ("TEXINFOS", variable_value ('info_TEXINFOS'), INTERNAL);
3048
3049   # Do some error checking.  Note that this file is not required
3050   # when in Cygnus mode; instead we defined TEXINFO_TEX explicitly
3051   # up above.
3052   if ($need_texi_file && ! option 'no-texinfo.tex')
3053     {
3054       if ($need_texi_file > 1)
3055         {
3056           require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3057                                         'texinfo.tex');
3058         }
3059       else
3060         {
3061           require_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3062                                    'texinfo.tex');
3063         }
3064     }
3065
3066   return makefile_wrap ("", "\t  ", @texi_cleans);
3067 }
3068
3069
3070 # handle_texinfo ()
3071 # -----------------
3072 # Handle all Texinfo source.
3073 sub handle_texinfo ()
3074 {
3075   reject_var 'TEXINFOS', "`TEXINFOS' is an anachronism; use `info_TEXINFOS'";
3076   # FIXME: I think this is an obsolete future feature name.
3077   reject_var 'html_TEXINFOS', "HTML generation not yet supported";
3078
3079   my $info_texinfos = var ('info_TEXINFOS');
3080   my $texiclean = "";
3081   if ($info_texinfos)
3082     {
3083       $texiclean = handle_texinfo_helper ($info_texinfos);
3084     }
3085   $output_rules .=  file_contents ('texinfos',
3086                                    new Automake::Location,
3087                                    TEXICLEAN     => $texiclean,
3088                                    'LOCAL-TEXIS' => !!$info_texinfos);
3089 }
3090
3091
3092 # Handle any man pages.
3093 sub handle_man_pages
3094 {
3095   reject_var 'MANS', "`MANS' is an anachronism; use `man_MANS'";
3096
3097   # Find all the sections in use.  We do this by first looking for
3098   # "standard" sections, and then looking for any additional
3099   # sections used in man_MANS.
3100   my (%sections, %vlist);
3101   # We handle nodist_ for uniformity.  man pages aren't distributed
3102   # by default so it isn't actually very important.
3103   foreach my $pfx ('', 'dist_', 'nodist_')
3104     {
3105       # Add more sections as needed.
3106       foreach my $section ('0'..'9', 'n', 'l')
3107         {
3108           my $varname = $pfx . 'man' . $section . '_MANS';
3109           if (var ($varname))
3110             {
3111               $sections{$section} = 1;
3112               $varname = '$(' . $varname . ')';
3113               $vlist{$varname} = 1;
3114
3115               &push_dist_common ($varname)
3116                 if $pfx eq 'dist_';
3117             }
3118         }
3119
3120       my $varname = $pfx . 'man_MANS';
3121       my $var = var ($varname);
3122       if ($var)
3123         {
3124           foreach ($var->value_as_list_recursive)
3125             {
3126               # A page like `foo.1c' goes into man1dir.
3127               if (/\.([0-9a-z])([a-z]*)$/)
3128                 {
3129                   $sections{$1} = 1;
3130                 }
3131             }
3132
3133           $varname = '$(' . $varname . ')';
3134           $vlist{$varname} = 1;
3135           &push_dist_common ($varname)
3136             if $pfx eq 'dist_';
3137         }
3138     }
3139
3140   return unless %sections;
3141
3142   # Now for each section, generate an install and uninstall rule.
3143   # Sort sections so output is deterministic.
3144   foreach my $section (sort keys %sections)
3145     {
3146       $output_rules .= &file_contents ('mans',
3147                                        new Automake::Location,
3148                                        SECTION => $section);
3149     }
3150
3151   my @mans = sort keys %vlist;
3152   $output_vars .= file_contents ('mans-vars',
3153                                  new Automake::Location,
3154                                  MANS => "@mans");
3155
3156   push (@all, '$(MANS)')
3157     unless option 'no-installman';
3158 }
3159
3160 # Handle DATA variables.
3161 sub handle_data
3162 {
3163     &am_install_var ('-noextra', '-candist', 'data', 'DATA',
3164                      'data', 'sysconf', 'sharedstate', 'localstate',
3165                      'pkgdata', 'lisp', 'noinst', 'check');
3166 }
3167
3168 # Handle TAGS.
3169 sub handle_tags
3170 {
3171     my @tag_deps = ();
3172     my @ctag_deps = ();
3173     if (var ('SUBDIRS'))
3174     {
3175         $output_rules .= ("tags-recursive:\n"
3176                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
3177                           # Never fail here if a subdir fails; it
3178                           # isn't important.
3179                           . "\t  test \"\$\$subdir\" = . || (cd \$\$subdir"
3180                           . " && \$(MAKE) \$(AM_MAKEFLAGS) tags); \\\n"
3181                           . "\tdone\n");
3182         push (@tag_deps, 'tags-recursive');
3183         &depend ('.PHONY', 'tags-recursive');
3184
3185         $output_rules .= ("ctags-recursive:\n"
3186                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
3187                           # Never fail here if a subdir fails; it
3188                           # isn't important.
3189                           . "\t  test \"\$\$subdir\" = . || (cd \$\$subdir"
3190                           . " && \$(MAKE) \$(AM_MAKEFLAGS) ctags); \\\n"
3191                           . "\tdone\n");
3192         push (@ctag_deps, 'ctags-recursive');
3193         &depend ('.PHONY', 'ctags-recursive');
3194     }
3195
3196     if (&saw_sources_p (1)
3197         || var ('ETAGS_ARGS')
3198         || @tag_deps)
3199     {
3200         my @config;
3201         foreach my $spec (@config_headers)
3202         {
3203             my ($out, @ins) = split_config_file_spec ($spec);
3204             foreach my $in (@ins)
3205               {
3206                 # If the config header source is in this directory,
3207                 # require it.
3208                 push @config, basename ($in)
3209                   if $relative_dir eq dirname ($in);
3210               }
3211         }
3212         $output_rules .= &file_contents ('tags',
3213                                          new Automake::Location,
3214                                          CONFIG    => "@config",
3215                                          TAGSDIRS  => "@tag_deps",
3216                                          CTAGSDIRS => "@ctag_deps");
3217
3218         set_seen 'TAGS_DEPENDENCIES';
3219     }
3220     elsif (reject_var ('TAGS_DEPENDENCIES',
3221                        "doesn't make sense to define `TAGS_DEPENDENCIES'"
3222                        . "without\nsources or `ETAGS_ARGS'"))
3223     {
3224     }
3225     else
3226     {
3227         # Every Makefile must define some sort of TAGS rule.
3228         # Otherwise, it would be possible for a top-level "make TAGS"
3229         # to fail because some subdirectory failed.
3230         $output_rules .= "tags: TAGS\nTAGS:\n\n";
3231         # Ditto ctags.
3232         $output_rules .= "ctags: CTAGS\nCTAGS:\n\n";
3233     }
3234 }
3235
3236 # Handle multilib support.
3237 sub handle_multilib
3238 {
3239   if ($seen_multilib && $relative_dir eq '.')
3240     {
3241       $output_rules .= &file_contents ('multilib', new Automake::Location);
3242       push (@all, 'all-multi');
3243     }
3244 }
3245
3246
3247 # $BOOLEAN
3248 # &for_dist_common ($A, $B)
3249 # -------------------------
3250 # Subroutine for &handle_dist: sort files to dist.
3251 #
3252 # We put README first because it then becomes easier to make a
3253 # Usenet-compliant shar file (in these, README must be first).
3254 #
3255 # FIXME: do more ordering of files here.
3256 sub for_dist_common
3257 {
3258     return 0
3259         if $a eq $b;
3260     return -1
3261         if $a eq 'README';
3262     return 1
3263         if $b eq 'README';
3264     return $a cmp $b;
3265 }
3266
3267
3268 # handle_dist
3269 # -----------
3270 # Handle 'dist' target.
3271 sub handle_dist ()
3272 {
3273   return if option 'no-dist';
3274
3275   # At least one of the archive formats must be enabled.
3276   if ($relative_dir eq '.')
3277     {
3278       my $archive_defined = option 'no-dist-gzip' ? 0 : 1;
3279       $archive_defined ||=
3280         grep { option "dist-$_" } ('shar', 'zip', 'tarZ', 'bzip2');
3281       error (option 'no-dist-gzip',
3282              "no-dist-gzip specified but no dist-* specified, "
3283              . "at least one archive format must be enabled")
3284         unless $archive_defined;
3285     }
3286
3287   # Look for common files that should be included in distribution.
3288   # If the aux dir is set, and it does not have a Makefile.am, then
3289   # we check for these files there as well.
3290   my $check_aux = 0;
3291   my $auxdir = '';
3292   if ($relative_dir eq '.'
3293       && $config_aux_dir_set_in_configure_in)
3294     {
3295       ($auxdir = $config_aux_dir) =~ s,^\$\(top_srcdir\)/,,;
3296       if (! &is_make_dir ($auxdir))
3297         {
3298           $check_aux = 1;
3299         }
3300     }
3301   foreach my $cfile (@common_files)
3302     {
3303       if (-f ($relative_dir . "/" . $cfile)
3304           # The file might be absent, but if it can be built it's ok.
3305           || rule $cfile)
3306         {
3307           &push_dist_common ($cfile);
3308         }
3309
3310       # Don't use `elsif' here because a file might meaningfully
3311       # appear in both directories.
3312       if ($check_aux && -f ($auxdir . '/' . $cfile))
3313         {
3314           &push_dist_common ($auxdir . '/' . $cfile);
3315         }
3316     }
3317
3318   # We might copy elements from $configure_dist_common to
3319   # %dist_common if we think we need to.  If the file appears in our
3320   # directory, we would have discovered it already, so we don't
3321   # check that.  But if the file is in a subdir without a Makefile,
3322   # we want to distribute it here if we are doing `.'.  Ugly!
3323   if ($relative_dir eq '.')
3324     {
3325       foreach my $file (split (' ' , $configure_dist_common))
3326         {
3327           push_dist_common ($file)
3328             unless is_make_dir (dirname ($file));
3329         }
3330     }
3331
3332   # Files to distributed.  Don't use ->value_as_list_recursive
3333   # as it recursively expands `$(dist_pkgdata_DATA)' etc.
3334   my @dist_common = split (' ', rvar ('DIST_COMMON')->variable_value);
3335   @dist_common = uniq (sort for_dist_common (@dist_common));
3336   variable_delete 'DIST_COMMON';
3337   define_pretty_variable ('DIST_COMMON', TRUE, INTERNAL, @dist_common);
3338
3339   # Now that we've processed DIST_COMMON, disallow further attempts
3340   # to set it.
3341   $handle_dist_run = 1;
3342
3343   # Scan EXTRA_DIST to see if we need to distribute anything from a
3344   # subdir.  If so, add it to the list.  I didn't want to do this
3345   # originally, but there were so many requests that I finally
3346   # relented.
3347   my $extra_dist = var ('EXTRA_DIST');
3348   if ($extra_dist)
3349     {
3350       # FIXME: This should be fixed to work with conditions.  That
3351       # will require only making the entries in %dist_dirs under the
3352       # appropriate condition.  This is meaningful if the nature of
3353       # the distribution should depend upon the configure options
3354       # used.
3355       foreach ($extra_dist->value_as_list_recursive)
3356         {
3357           next if /^\@.*\@$/;
3358           next unless s,/+[^/]+$,,;
3359           $dist_dirs{$_} = 1
3360             unless $_ eq '.';
3361         }
3362     }
3363
3364   # We have to check DIST_COMMON for extra directories in case the
3365   # user put a source used in AC_OUTPUT into a subdir.
3366   my $topsrcdir = backname ($relative_dir);
3367   foreach (rvar ('DIST_COMMON')->value_as_list_recursive)
3368     {
3369       next if /^\@.*\@$/;
3370       s/\$\(top_srcdir\)/$topsrcdir/;
3371       s/\$\(srcdir\)/./;
3372       # Strip any leading `./'.
3373       s,^(:?\./+)*,,;
3374       next unless s,/+[^/]+$,,;
3375       $dist_dirs{$_} = 1
3376         unless $_ eq '.';
3377     }
3378
3379   # Rule to check whether a distribution is viable.
3380   my %transform = ('DISTCHECK-HOOK' => !! rule 'distcheck-hook',
3381                    'GETTEXT' => $seen_gettext && !$seen_gettext_external);
3382
3383   # Prepend $(distdir) to each directory given.
3384   my %rewritten = map { '$(distdir)/' . "$_" => 1 } keys %dist_dirs;
3385   $transform{'DISTDIRS'} = join (' ', sort keys %rewritten);
3386
3387   # If we have SUBDIRS, create all dist subdirectories and do
3388   # recursive build.
3389   my $subdirs = var ('SUBDIRS');
3390   if ($subdirs)
3391     {
3392       # If SUBDIRS is conditionally defined, then set DIST_SUBDIRS
3393       # to all possible directories, and use it.  If DIST_SUBDIRS is
3394       # defined, just use it.
3395       my $dist_subdir_name;
3396       # Note that we check DIST_SUBDIRS first on purpose, so that
3397       # we don't call has_conditional_contents for now reason.
3398       # (In the past one project used so many conditional subdirectories
3399       # that calling has_conditional_contents on SUBDIRS caused
3400       # automake to grow to 150Mb -- this should not happen with
3401       # the current implementation of has_conditional_contents,
3402       # but it's more efficient to avoid the call anyway.)
3403       if (var ('DIST_SUBDIRS'))
3404         {
3405           $dist_subdir_name = 'DIST_SUBDIRS';
3406         }
3407       elsif ($subdirs->has_conditional_contents)
3408         {
3409           $dist_subdir_name = 'DIST_SUBDIRS';
3410           define_pretty_variable
3411             ('DIST_SUBDIRS', TRUE, INTERNAL,
3412              uniq ($subdirs->value_as_list_recursive));
3413         }
3414       else
3415         {
3416           $dist_subdir_name = 'SUBDIRS';
3417           # We always define this because that is what `distclean'
3418           # wants.
3419           define_pretty_variable ('DIST_SUBDIRS', TRUE, INTERNAL,
3420                                   '$(SUBDIRS)');
3421         }
3422
3423       $transform{'DIST_SUBDIR_NAME'} = $dist_subdir_name;
3424     }
3425
3426   # If the target `dist-hook' exists, make sure it is run.  This
3427   # allows users to do random weird things to the distribution
3428   # before it is packaged up.
3429   push (@dist_targets, 'dist-hook')
3430     if rule 'dist-hook';
3431   $transform{'DIST-TARGETS'} = join(' ', @dist_targets);
3432
3433   $output_rules .= &file_contents ('distdir',
3434                                    new Automake::Location,
3435                                    %transform);
3436 }
3437
3438
3439 # &handle_subdirs ()
3440 # ------------------
3441 # Handle subdirectories.
3442 sub handle_subdirs ()
3443 {
3444   my $subdirs = var ('SUBDIRS');
3445   return
3446     unless $subdirs;
3447
3448   my @subdirs = $subdirs->value_as_list_recursive;
3449   my @dsubdirs = ();
3450   my $dsubdirs = var ('DIST_SUBDIRS');
3451   @dsubdirs = $dsubdirs->value_as_list_recursive
3452     if $dsubdirs;
3453
3454   # If an `obj/' directory exists, BSD make will enter it before
3455   # reading `Makefile'.  Hence the `Makefile' in the current directory
3456   # will not be read.
3457   #
3458   #  % cat Makefile
3459   #  all:
3460   #          echo Hello
3461   #  % cat obj/Makefile
3462   #  all:
3463   #          echo World
3464   #  % make      # GNU make
3465   #  echo Hello
3466   #  Hello
3467   #  % pmake     # BSD make
3468   #  echo World
3469   #  World
3470   msg_var ('portability', 'SUBDIRS',
3471            "naming a subdirectory `obj' causes troubles with BSD make")
3472     if grep ($_ eq 'obj', @subdirs);
3473   msg_var ('portability', 'DIST_SUBDIRS',
3474            "naming a subdirectory `obj' causes troubles with BSD make")
3475     if grep ($_ eq 'obj', @dsubdirs);
3476
3477   # Make sure each directory mentioned in SUBDIRS actually exists.
3478   foreach my $dir (@subdirs)
3479     {
3480       # Skip directories substituted by configure.
3481       next if $dir =~ /^\@.*\@$/;
3482
3483       if (! -d $relative_dir . '/' . $dir)
3484         {
3485           err_var ('SUBDIRS', "required directory $relative_dir/$dir "
3486                    . "does not exist");
3487           next;
3488         }
3489
3490       err_var 'SUBDIRS', "directory should not contain `/'"
3491         if $dir =~ /\//;
3492     }
3493
3494   $output_rules .= &file_contents ('subdirs', new Automake::Location);
3495   rvar ('RECURSIVE_TARGETS')->rdef (TRUE)->{'pretty'} = VAR_SORTED; # Gross!
3496 }
3497
3498
3499 # ($REGEN, @DEPENDENCIES)
3500 # &scan_aclocal_m4
3501 # ----------------
3502 # If aclocal.m4 creation is automated, return the list of its dependencies.
3503 sub scan_aclocal_m4 ()
3504 {
3505   my $regen_aclocal = 0;
3506
3507   set_seen 'CONFIG_STATUS_DEPENDENCIES';
3508   set_seen 'CONFIGURE_DEPENDENCIES';
3509
3510   if (-f 'aclocal.m4')
3511     {
3512       &define_variable ("ACLOCAL_M4", '$(top_srcdir)/aclocal.m4', INTERNAL);
3513
3514       my $aclocal = new Automake::XFile "< aclocal.m4";
3515       my $line = $aclocal->getline;
3516       $regen_aclocal = $line =~ 'generated automatically by aclocal';
3517     }
3518
3519   my @ac_deps = ();
3520
3521   if (set_seen ('ACLOCAL_M4_SOURCES'))
3522     {
3523       push (@ac_deps, '$(ACLOCAL_M4_SOURCES)');
3524       msg_var ('obsolete', 'ACLOCAL_M4_SOURCES',
3525                "`ACLOCAL_M4_SOURCES' is obsolete.\n"
3526                . "It should be safe to simply remove it.");
3527     }
3528
3529   # Note that it might be possible that aclocal.m4 doesn't exist but
3530   # should be auto-generated.  This case probably isn't very
3531   # important.
3532
3533   return ($regen_aclocal, @ac_deps);
3534 }
3535
3536
3537 # @DEPENDENCIES
3538 # &prepend_srcdir (@INPUTS)
3539 # -------------------------
3540 # Prepend $(srcdir) or $(top_srcdir) to all @INPUTS.  The idea is that
3541 # if an input file has a directory part the same as the current
3542 # directory, then the directory part is simply replaced by $(srcdir).
3543 # But if the directory part is different, then $(top_srcdir) is
3544 # prepended.
3545 sub prepend_srcdir (@)
3546 {
3547   my (@inputs) = @_;
3548   my @newinputs;
3549
3550   foreach my $single (@inputs)
3551     {
3552       if (dirname ($single) eq $relative_dir)
3553         {
3554           push (@newinputs, '$(srcdir)/' . basename ($single));
3555         }
3556       else
3557         {
3558           push (@newinputs, '$(top_srcdir)/' . $single);
3559         }
3560     }
3561   return @newinputs;
3562 }
3563
3564 # @DEPENDENCIES
3565 # rewrite_inputs_into_dependencies ($OUTPUT, @INPUTS)
3566 # ---------------------------------------------------
3567 # Compute a list of dependencies appropriate for the rebuild
3568 # rule of
3569 #   AC_CONFIG_FILES($OUTPUT:$INPUT[0]:$INPUTS[1]:...)
3570 # Also distribute $INPUTs which are not build by another AC_CONFIG_FILES.
3571 sub rewrite_inputs_into_dependencies ($@)
3572 {
3573   my ($file, @inputs) = @_;
3574   my @res = ();
3575
3576   for my $i (@inputs)
3577     {
3578       if (exists $ac_config_files_location{$i})
3579         {
3580           my $di = dirname $i;
3581           if ($di eq $relative_dir)
3582             {
3583               $i = basename $i;
3584             }
3585           # In the top-level Makefile we do not use $(top_builddir), because
3586           # we are already there, and since the targets are built without
3587           # a $(top_builddir), it helps BSD Make to match them with
3588           # dependencies.
3589           elsif ($relative_dir ne '.')
3590             {
3591               $i = '$(top_builddir)/' . $i;
3592             }
3593         }
3594       else
3595         {
3596           msg ('error', $ac_config_files_location{$file},
3597                "required file `$i' not found")
3598             unless exists $output_files{$i} || -f $i;
3599           ($i) = prepend_srcdir ($i);
3600           push_dist_common ($i);
3601         }
3602       push @res, $i;
3603     }
3604   return @res;
3605 }
3606
3607
3608
3609 # &handle_configure ($MAKEFILE_AM, $MAKEFILE_IN, $MAKEFILE, @INPUTS)
3610 # ------------------------------------------------------------------
3611 # Handle remaking and configure stuff.
3612 # We need the name of the input file, to do proper remaking rules.
3613 sub handle_configure ($$$@)
3614 {
3615   my ($makefile_am, $makefile_in, $makefile, @inputs) = @_;
3616
3617   prog_error 'empty @inputs'
3618     unless @inputs;
3619
3620   my ($rel_makefile_am, $rel_makefile_in) = prepend_srcdir ($makefile_am,
3621                                                             $makefile_in);
3622   my $rel_makefile = basename $makefile;
3623
3624   my $colon_infile = ':' . join (':', @inputs);
3625   $colon_infile = '' if $colon_infile eq ":$makefile.in";
3626   my @rewritten = rewrite_inputs_into_dependencies ($makefile, @inputs);
3627   my ($regen_aclocal_m4, @aclocal_m4_deps) = scan_aclocal_m4;
3628   define_pretty_variable ('am__aclocal_m4_deps', TRUE, INTERNAL,
3629                           @configure_deps, @aclocal_m4_deps,
3630                           '$(top_srcdir)/' . $configure_ac);
3631   my @configuredeps = ('$(am__aclocal_m4_deps)', '$(CONFIGURE_DEPENDENCIES)');
3632   push @configuredeps, '$(ACLOCAL_M4)' if -f 'aclocal.m4';
3633   define_pretty_variable ('am__configure_deps', TRUE, INTERNAL,
3634                           @configuredeps);
3635
3636   $output_rules .= file_contents
3637     ('configure',
3638      new Automake::Location,
3639      MAKEFILE              => $rel_makefile,
3640      'MAKEFILE-DEPS'       => "@rewritten",
3641      'CONFIG-MAKEFILE'     => ($relative_dir eq '.') ? '$@' : '$(subdir)/$@',
3642      'MAKEFILE-IN'         => $rel_makefile_in,
3643      'MAKEFILE-IN-DEPS'    => "@include_stack",
3644      'MAKEFILE-AM'         => $rel_makefile_am,
3645      STRICTNESS            => global_option 'cygnus'
3646                                 ? 'cygnus' : $strictness_name,
3647      'USE-DEPS'            => global_option 'no-dependencies'
3648                                 ? ' --ignore-deps' : '',
3649      'MAKEFILE-AM-SOURCES' => "$makefile$colon_infile",
3650      'REGEN-ACLOCAL-M4'    => $regen_aclocal_m4);
3651
3652   if ($relative_dir eq '.')
3653     {
3654       &push_dist_common ('acconfig.h')
3655         if -f 'acconfig.h';
3656     }
3657
3658   # If we have a configure header, require it.
3659   my $hdr_index = 0;
3660   my @distclean_config;
3661   foreach my $spec (@config_headers)
3662     {
3663       $hdr_index += 1;
3664       # $CONFIG_H_PATH: config.h from top level.
3665       my ($config_h_path, @ins) = split_config_file_spec ($spec);
3666       my $config_h_dir = dirname ($config_h_path);
3667
3668       # If the header is in the current directory we want to build
3669       # the header here.  Otherwise, if we're at the topmost
3670       # directory and the header's directory doesn't have a
3671       # Makefile, then we also want to build the header.
3672       if ($relative_dir eq $config_h_dir
3673           || ($relative_dir eq '.' && ! &is_make_dir ($config_h_dir)))
3674         {
3675           my ($cn_sans_dir, $stamp_dir);
3676           if ($relative_dir eq $config_h_dir)
3677             {
3678               $cn_sans_dir = basename ($config_h_path);
3679               $stamp_dir = '';
3680             }
3681           else
3682             {
3683               $cn_sans_dir = $config_h_path;
3684               if ($config_h_dir eq '.')
3685                 {
3686                   $stamp_dir = '';
3687                 }
3688               else
3689                 {
3690                   $stamp_dir = $config_h_dir . '/';
3691                 }
3692             }
3693
3694           # This will also distribute all inputs.
3695           @ins = rewrite_inputs_into_dependencies ($config_h_path, @ins);
3696
3697           # Header defined and in this directory.
3698           my @files;
3699           if (-f $config_h_path . '.top')
3700             {
3701               push (@files, "$cn_sans_dir.top");
3702             }
3703           if (-f $config_h_path . '.bot')
3704             {
3705               push (@files, "$cn_sans_dir.bot");
3706             }
3707
3708           push_dist_common (@files);
3709
3710           # For now, acconfig.h can only appear in the top srcdir.
3711           if (-f 'acconfig.h')
3712             {
3713               push (@files, '$(top_srcdir)/acconfig.h');
3714             }
3715
3716           my $stamp = "${stamp_dir}stamp-h${hdr_index}";
3717           $output_rules .=
3718             file_contents ('remake-hdr',
3719                            new Automake::Location,
3720                            FILES            => "@files",
3721                            CONFIG_H         => $cn_sans_dir,
3722                            CONFIG_HIN       => $ins[0],
3723                            CONFIG_H_DEPS    => "@ins",
3724                            CONFIG_H_PATH    => $config_h_path,
3725                            STAMP            => "$stamp");
3726
3727           push @distclean_config, $cn_sans_dir, $stamp;
3728         }
3729     }
3730
3731   $output_rules .= file_contents ('clean-hdr',
3732                                   new Automake::Location,
3733                                   FILES => "@distclean_config")
3734     if @distclean_config;
3735
3736   # Distribute and define mkinstalldirs only if it is already present
3737   # in the package, for backward compatibility (some people my still
3738   # use $(mkinstalldirs)).
3739   my $mkidpath = $config_aux_path[0] . '/mkinstalldirs';
3740   if (-f $mkidpath)
3741     {
3742       # Use require_file so that any existingscript gets updated
3743       # by --force-missing.
3744       require_conf_file ($mkidpath, FOREIGN, 'mkinstalldirs');
3745       define_variable ('mkinstalldirs',
3746                        "\$(SHELL) $config_aux_dir/mkinstalldirs", INTERNAL);
3747     }
3748   else
3749     {
3750       define_variable ('mkinstalldirs', '$(mkdir_p)', INTERNAL);
3751     }
3752
3753   reject_var ('CONFIG_HEADER',
3754               "`CONFIG_HEADER' is an anachronism; now determined "
3755               . "automatically\nfrom `$configure_ac'");
3756
3757   my @config_h;
3758   foreach my $spec (@config_headers)
3759     {
3760       my ($out, @ins) = split_config_file_spec ($spec);
3761       # Generate CONFIG_HEADER define.
3762       if ($relative_dir eq dirname ($out))
3763         {
3764           push @config_h, basename ($out);
3765         }
3766       else
3767         {
3768           push @config_h, "\$(top_builddir)/$out";
3769         }
3770     }
3771   define_variable ("CONFIG_HEADER", "@config_h", INTERNAL)
3772     if @config_h;
3773
3774   # Now look for other files in this directory which must be remade
3775   # by config.status, and generate rules for them.
3776   my @actual_other_files = ();
3777   foreach my $lfile (@other_input_files)
3778     {
3779       my $file;
3780       my @inputs;
3781       if ($lfile =~ /^([^:]*):(.*)$/)
3782         {
3783           # This is the ":" syntax of AC_OUTPUT.
3784           $file = $1;
3785           @inputs = split (':', $2);
3786         }
3787       else
3788         {
3789           # Normal usage.
3790           $file = $lfile;
3791           @inputs = $file . '.in';
3792         }
3793
3794       # Automake files should not be stored in here, but in %MAKE_LIST.
3795       prog_error ("$lfile in \@other_input_files\n"
3796                   . "\@other_input_files = (@other_input_files)")
3797         if -f $file . '.am';
3798
3799       my $local = basename ($file);
3800
3801       # Make sure the dist directory for each input file is created.
3802       # We only have to do this at the topmost level though.  This
3803       # is a bit ugly but it easier than spreading out the logic,
3804       # especially in cases like AC_OUTPUT(foo/out:bar/in), where
3805       # there is no Makefile in bar/.
3806       if ($relative_dir eq '.')
3807         {
3808           foreach (@inputs)
3809             {
3810               $dist_dirs{dirname ($_)} = 1;
3811             }
3812         }
3813
3814       # We skip files that aren't in this directory.  However, if
3815       # the file's directory does not have a Makefile, and we are
3816       # currently doing `.', then we create a rule to rebuild the
3817       # file in the subdir.
3818       my $fd = dirname ($file);
3819       if ($fd ne $relative_dir)
3820         {
3821           if ($relative_dir eq '.' && ! &is_make_dir ($fd))
3822             {
3823               $local = $file;
3824             }
3825           else
3826             {
3827               next;
3828             }
3829         }
3830
3831       my @rewritten_inputs = rewrite_inputs_into_dependencies ($file, @inputs);
3832
3833       $output_rules .= ($local . ': '
3834                         . '$(top_builddir)/config.status '
3835                         . "@rewritten_inputs\n"
3836                         . "\t"
3837                         . 'cd $(top_builddir) && '
3838                         . '$(SHELL) ./config.status '
3839                         . ($relative_dir eq '.' ? '' : '$(subdir)/')
3840                         . '$@'
3841                         . "\n");
3842       push (@actual_other_files, $local);
3843     }
3844
3845   # For links we should clean destinations and distribute sources.
3846   foreach my $spec (@config_links)
3847     {
3848       my ($link, $file) = split /:/, $spec;
3849       # Some people do AC_CONFIG_LINKS($computed).  We only handle
3850       # the DEST:SRC form.
3851       next unless $file;
3852       my $where = $ac_config_files_location{$link};
3853
3854       # Skip destinations that contain shell variables.
3855       if ($link !~ /\$/)
3856         {
3857           # We skip links that aren't in this directory.  However, if
3858           # the link's directory does not have a Makefile, and we are
3859           # currently doing `.', then we add the link to CONFIG_CLEAN_FILES
3860           # in `.'s Makefile.in.
3861           my $local = basename ($link);
3862           my $fd = dirname ($link);
3863           if ($fd ne $relative_dir)
3864             {
3865               if ($relative_dir eq '.' && ! &is_make_dir ($fd))
3866                 {
3867                   $local = $link;
3868                 }
3869               else
3870                 {
3871                   $local = undef;
3872                 }
3873             }
3874           push @actual_other_files, $local if $local;
3875         }
3876
3877       # Do not process sources that contain shell variables.
3878       if ($file !~ /\$/)
3879         {
3880           my $fd = dirname ($file);
3881
3882           # Make sure the dist directory for each input file is created.
3883           # We only have to do this at the topmost level though.
3884           if ($relative_dir eq '.')
3885             {
3886               $dist_dirs{$fd} = 1;
3887             }
3888
3889           # We distribute files that are in this directory.
3890           # At the top-level (`.') we also distribute files whose
3891           # directory does not have a Makefile.
3892           if (($fd eq $relative_dir)
3893               || ($relative_dir eq '.' && ! &is_make_dir ($fd)))
3894             {
3895               # The following will distribute $file as a side-effect when
3896               # it is appropriate (i.e., when $file is not already an output).
3897               # We do not need the result, just the side-effect.
3898               rewrite_inputs_into_dependencies ($link, $file);
3899             }
3900         }
3901     }
3902
3903   # These files get removed by "make distclean".
3904   define_pretty_variable ('CONFIG_CLEAN_FILES', TRUE, INTERNAL,
3905                           @actual_other_files);
3906 }
3907
3908 # Handle C headers.
3909 sub handle_headers
3910 {
3911     my @r = &am_install_var ('-defaultdist', 'header', 'HEADERS', 'include',
3912                              'oldinclude', 'pkginclude',
3913                              'noinst', 'check');
3914     foreach (@r)
3915     {
3916       next unless $_->[1] =~ /\..*$/;
3917       &saw_extension ($&);
3918     }
3919 }
3920
3921 sub handle_gettext
3922 {
3923   return if ! $seen_gettext || $relative_dir ne '.';
3924
3925   my $subdirs = var 'SUBDIRS';
3926
3927   if (! $subdirs)
3928     {
3929       err_ac "AM_GNU_GETTEXT used but SUBDIRS not defined";
3930       return;
3931     }
3932
3933   # Perform some sanity checks to help users get the right setup.
3934   # We disable these tests when po/ doesn't exist in order not to disallow
3935   # unusual gettext setups.
3936   #
3937   # Bruno Haible:
3938   # | The idea is:
3939   # |
3940   # |  1) If a package doesn't have a directory po/ at top level, it
3941   # |     will likely have multiple po/ directories in subpackages.
3942   # |
3943   # |  2) It is useful to warn for the absence of intl/ if AM_GNU_GETTEXT
3944   # |     is used without 'external'. It is also useful to warn for the
3945   # |     presence of intl/ if AM_GNU_GETTEXT([external]) is used. Both
3946   # |     warnings apply only to the usual layout of packages, therefore
3947   # |     they should both be disabled if no po/ directory is found at
3948   # |     top level.
3949
3950   if (-d 'po')
3951     {
3952       my @subdirs = $subdirs->value_as_list_recursive;
3953
3954       msg_var ('syntax', $subdirs,
3955                "AM_GNU_GETTEXT used but `po' not in SUBDIRS")
3956         if ! grep ($_ eq 'po', @subdirs);
3957
3958       # intl/ is not required when AM_GNU_GETTEXT is called with
3959       # the `external' option.
3960       msg_var ('syntax', $subdirs,
3961                "AM_GNU_GETTEXT used but `intl' not in SUBDIRS")
3962         if (! $seen_gettext_external
3963             && ! grep ($_ eq 'intl', @subdirs));
3964
3965       # intl/ should not be used with AM_GNU_GETTEXT([external])
3966       msg_var ('syntax', $subdirs,
3967                "`intl' should not be in SUBDIRS when "
3968                . "AM_GNU_GETTEXT([external]) is used")
3969         if ($seen_gettext_external && grep ($_ eq 'intl', @subdirs));
3970     }
3971
3972   require_file ($ac_gettext_location, GNU, 'ABOUT-NLS');
3973 }
3974
3975 # Handle footer elements.
3976 sub handle_footer
3977 {
3978     # NOTE don't use define_pretty_variable here, because
3979     # $contents{...} is already defined.
3980     $output_vars .= 'SOURCES = ' . variable_value ('SOURCES') . "\n\n"
3981       if variable_value ('SOURCES');
3982
3983     reject_rule ('.SUFFIXES',
3984                  "use variable `SUFFIXES', not target `.SUFFIXES'");
3985
3986     # Note: AIX 4.1 /bin/make will fail if any suffix rule appears
3987     # before .SUFFIXES.  So we make sure that .SUFFIXES appears before
3988     # anything else, by sticking it right after the default: target.
3989     $output_header .= ".SUFFIXES:\n";
3990     my $suffixes = var 'SUFFIXES';
3991     my @suffixes = Automake::Rule::suffixes;
3992     if (@suffixes || $suffixes)
3993     {
3994         # Make sure SUFFIXES has unique elements.  Sort them to ensure
3995         # the output remains consistent.  However, $(SUFFIXES) is
3996         # always at the start of the list, unsorted.  This is done
3997         # because make will choose rules depending on the ordering of
3998         # suffixes, and this lets the user have some control.  Push
3999         # actual suffixes, and not $(SUFFIXES).  Some versions of make
4000         # do not like variable substitutions on the .SUFFIXES line.
4001         my @user_suffixes = ($suffixes
4002                              ? $suffixes->value_as_list_recursive : ());
4003
4004         my %suffixes = map { $_ => 1 } @suffixes;
4005         delete @suffixes{@user_suffixes};
4006
4007         $output_header .= (".SUFFIXES: "
4008                            . join (' ', @user_suffixes, sort keys %suffixes)
4009                            . "\n");
4010     }
4011
4012     $output_trailer .= file_contents ('footer', new Automake::Location);
4013 }
4014
4015
4016 # Generate `make install' rules.
4017 sub handle_install ()
4018 {
4019   $output_rules .= &file_contents
4020     ('install',
4021      new Automake::Location,
4022      maybe_BUILT_SOURCES => (set_seen ('BUILT_SOURCES')
4023                              ? (" \$(BUILT_SOURCES)\n"
4024                                 . "\t\$(MAKE) \$(AM_MAKEFLAGS)")
4025                              : ''),
4026      'installdirs-local' => (rule 'installdirs-local'
4027                              ? ' installdirs-local' : ''),
4028      am__installdirs => variable_value ('am__installdirs') || '');
4029 }
4030
4031
4032 # Deal with all and all-am.
4033 sub handle_all ($)
4034 {
4035     my ($makefile) = @_;
4036
4037     # Output `all-am'.
4038
4039     # Put this at the beginning for the sake of non-GNU makes.  This
4040     # is still wrong if these makes can run parallel jobs.  But it is
4041     # right enough.
4042     unshift (@all, basename ($makefile));
4043
4044     foreach my $spec (@config_headers)
4045       {
4046         my ($out, @ins) = split_config_file_spec ($spec);
4047         push (@all, basename ($out))
4048           if dirname ($out) eq $relative_dir;
4049       }
4050
4051     # Install `all' hooks.
4052     if (rule "all-local")
4053     {
4054       push (@all, "all-local");
4055       &depend ('.PHONY', "all-local");
4056     }
4057
4058     &pretty_print_rule ("all-am:", "\t\t", @all);
4059     &depend ('.PHONY', 'all-am', 'all');
4060
4061
4062     # Output `all'.
4063
4064     my @local_headers = ();
4065     push @local_headers, '$(BUILT_SOURCES)'
4066       if var ('BUILT_SOURCES');
4067     foreach my $spec (@config_headers)
4068       {
4069         my ($out, @ins) = split_config_file_spec ($spec);
4070         push @local_headers, basename ($out)
4071           if dirname ($out) eq $relative_dir;
4072       }
4073
4074     if (@local_headers)
4075       {
4076         # We need to make sure config.h is built before we recurse.
4077         # We also want to make sure that built sources are built
4078         # before any ordinary `all' targets are run.  We can't do this
4079         # by changing the order of dependencies to the "all" because
4080         # that breaks when using parallel makes.  Instead we handle
4081         # things explicitly.
4082         $output_all .= ("all: @local_headers"
4083                         . "\n\t"
4084                         . '$(MAKE) $(AM_MAKEFLAGS) '
4085                         . (var ('SUBDIRS') ? 'all-recursive' : 'all-am')
4086                         . "\n\n");
4087       }
4088     else
4089       {
4090         $output_all .= "all: " . (var ('SUBDIRS')
4091                                   ? 'all-recursive' : 'all-am') . "\n\n";
4092       }
4093 }
4094
4095
4096 # &do_check_merge_target ()
4097 # -------------------------
4098 # Handle check merge target specially.
4099 sub do_check_merge_target ()
4100 {
4101   if (rule 'check-local')
4102     {
4103       # User defined local form of target.  So include it.
4104       push @check_tests, 'check-local';
4105       depend '.PHONY', 'check-local';
4106     }
4107
4108   # In --cygnus mode, check doesn't depend on all.
4109   if (option 'cygnus')
4110     {
4111       # Just run the local check rules.
4112       pretty_print_rule ('check-am:', "\t\t", @check);
4113     }
4114   else
4115     {
4116       # The check target must depend on the local equivalent of
4117       # `all', to ensure all the primary targets are built.  Then it
4118       # must build the local check rules.
4119       $output_rules .= "check-am: all-am\n";
4120       pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4121                          @check)
4122         if @check;
4123     }
4124   pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4125                      @check_tests)
4126     if @check_tests;
4127
4128   depend '.PHONY', 'check', 'check-am';
4129   # Handle recursion.  We have to honor BUILT_SOURCES like for `all:'.
4130   $output_rules .= ("check: "
4131                     . (var ('BUILT_SOURCES')
4132                        ? "\$(BUILT_SOURCES)\n\t\$(MAKE) \$(AM_MAKEFLAGS) "
4133                        : '')
4134                     . (var ('SUBDIRS') ? 'check-recursive' : 'check-am')
4135                     . "\n");
4136 }
4137
4138 # handle_clean ($MAKEFILE)
4139 # ------------------------
4140 # Handle all 'clean' targets.
4141 sub handle_clean ($)
4142 {
4143   my ($makefile) = @_;
4144
4145   # Clean the files listed in user variables if they exist.
4146   $clean_files{'$(MOSTLYCLEANFILES)'} = MOSTLY_CLEAN
4147     if var ('MOSTLYCLEANFILES');
4148   $clean_files{'$(CLEANFILES)'} = CLEAN
4149     if var ('CLEANFILES');
4150   $clean_files{'$(DISTCLEANFILES)'} = DIST_CLEAN
4151     if var ('DISTCLEANFILES');
4152   $clean_files{'$(MAINTAINERCLEANFILES)'} = MAINTAINER_CLEAN
4153     if var ('MAINTAINERCLEANFILES');
4154
4155   # Built sources are automatically removed by maintainer-clean.
4156   $clean_files{'$(BUILT_SOURCES)'} = MAINTAINER_CLEAN
4157     if var ('BUILT_SOURCES');
4158
4159   # Compute a list of "rm"s to run for each target.
4160   my %rms = (MOSTLY_CLEAN, [],
4161              CLEAN, [],
4162              DIST_CLEAN, [],
4163              MAINTAINER_CLEAN, []);
4164
4165   foreach my $file (keys %clean_files)
4166     {
4167       my $when = $clean_files{$file};
4168       prog_error 'invalid entry in %clean_files'
4169         unless exists $rms{$when};
4170
4171       my $rm = "rm -f $file";
4172       # If file is a variable, make sure when don't call `rm -f' without args.
4173       $rm ="test -z \"$file\" || $rm"
4174         if ($file =~ /^\s*\$(\(.*\)|\{.*\})\s*$/);
4175
4176       push @{$rms{$when}}, "\t-$rm\n";
4177     }
4178
4179   $output_rules .= &file_contents
4180     ('clean',
4181      new Automake::Location,
4182      MOSTLYCLEAN_RMS      => join ('', @{$rms{&MOSTLY_CLEAN}}),
4183      CLEAN_RMS            => join ('', @{$rms{&CLEAN}}),
4184      DISTCLEAN_RMS        => join ('', @{$rms{&DIST_CLEAN}}),
4185      MAINTAINER_CLEAN_RMS => join ('', @{$rms{&MAINTAINER_CLEAN}}),
4186      MAKEFILE             => basename $makefile,
4187      );
4188 }
4189
4190
4191 # &target_cmp ($A, $B)
4192 # --------------------
4193 # Subroutine for &handle_factored_dependencies to let `.PHONY' be last.
4194 sub target_cmp
4195 {
4196     return 0
4197         if $a eq $b;
4198     return -1
4199         if $b eq '.PHONY';
4200     return 1
4201         if $a eq '.PHONY';
4202     return $a cmp $b;
4203 }
4204
4205
4206 # &handle_factored_dependencies ()
4207 # --------------------------------
4208 # Handle everything related to gathered targets.
4209 sub handle_factored_dependencies
4210 {
4211   # Reject bad hooks.
4212   foreach my $utarg ('uninstall-data-local', 'uninstall-data-hook',
4213                      'uninstall-exec-local', 'uninstall-exec-hook')
4214     {
4215       my $x = $utarg;
4216       $x =~ s/(data|exec)-//;
4217       reject_rule ($utarg, "use `$x', not `$utarg'");
4218     }
4219
4220   reject_rule ('install-local',
4221                "use `install-data-local' or `install-exec-local', "
4222                . "not `install-local'");
4223
4224   reject_rule ('install-info-local',
4225                "`install-info-local' target defined but "
4226                . "`no-installinfo' option not in use")
4227     unless option 'no-installinfo';
4228
4229   # Install the -local hooks.
4230   foreach (keys %dependencies)
4231     {
4232       # Hooks are installed on the -am targets.
4233       s/-am$// or next;
4234       if (rule "$_-local")
4235         {
4236           depend ("$_-am", "$_-local");
4237           depend ('.PHONY', "$_-local");
4238         }
4239     }
4240
4241   # Install the -hook hooks.
4242   # FIXME: Why not be as liberal as we are with -local hooks?
4243   foreach ('install-exec', 'install-data', 'uninstall')
4244     {
4245       if (rule ("$_-hook"))
4246         {
4247           $actions{"$_-am"} .=
4248             ("\t\@\$(NORMAL_INSTALL)\n"
4249              . "\t" . '$(MAKE) $(AM_MAKEFLAGS) ' . "$_-hook\n");
4250         }
4251     }
4252
4253   # All the required targets are phony.
4254   depend ('.PHONY', keys %required_targets);
4255
4256   # Actually output gathered targets.
4257   foreach (sort target_cmp keys %dependencies)
4258     {
4259       # If there is nothing about this guy, skip it.
4260       next
4261         unless (@{$dependencies{$_}}
4262                 || $actions{$_}
4263                 || $required_targets{$_});
4264
4265       # Define gathered targets in undefined conditions.
4266       # FIXME: Right now we must handle .PHONY as an exception,
4267       # because people write things like
4268       #    .PHONY: myphonytarget
4269       # to append dependencies.  This would not work if Automake
4270       # refrained from defining its own .PHONY target as it does
4271       # with other overridden targets.
4272       my @undefined_conds = (TRUE,);
4273       if ($_ ne '.PHONY')
4274         {
4275           @undefined_conds =
4276             Automake::Rule::define ($_, 'internal',
4277                                     RULE_AUTOMAKE, TRUE, INTERNAL);
4278         }
4279       my @uniq_deps = uniq (sort @{$dependencies{$_}});
4280       foreach my $cond (@undefined_conds)
4281         {
4282           my $condstr = $cond->subst_string;
4283           &pretty_print_rule ("$condstr$_:", "$condstr\t", @uniq_deps);
4284           $output_rules .= $actions{$_} if defined $actions{$_};
4285           $output_rules .= "\n";
4286         }
4287     }
4288 }
4289
4290
4291 # &handle_tests_dejagnu ()
4292 # ------------------------
4293 sub handle_tests_dejagnu
4294 {
4295     push (@check_tests, 'check-DEJAGNU');
4296     $output_rules .= file_contents ('dejagnu', new Automake::Location);
4297 }
4298
4299
4300 # Handle TESTS variable and other checks.
4301 sub handle_tests
4302 {
4303   if (option 'dejagnu')
4304     {
4305       &handle_tests_dejagnu;
4306     }
4307   else
4308     {
4309       foreach my $c ('DEJATOOL', 'RUNTEST', 'RUNTESTFLAGS')
4310         {
4311           reject_var ($c, "`$c' defined but `dejagnu' not in "
4312                       . "`AUTOMAKE_OPTIONS'");
4313         }
4314     }
4315
4316   if (var ('TESTS'))
4317     {
4318       push (@check_tests, 'check-TESTS');
4319       $output_rules .= &file_contents ('check', new Automake::Location);
4320     }
4321 }
4322
4323 # Handle Emacs Lisp.
4324 sub handle_emacs_lisp
4325 {
4326   my @elfiles = &am_install_var ('-candist', 'lisp', 'LISP',
4327                                  'lisp', 'noinst');
4328
4329   return if ! @elfiles;
4330
4331   define_pretty_variable ('am__ELFILES', TRUE, INTERNAL,
4332                           map { $_->[1] } @elfiles);
4333   define_pretty_variable ('am__ELCFILES', TRUE, INTERNAL,
4334                           '$(am__ELFILES:.el=.elc)');
4335   # This one can be overridden by users.
4336   define_pretty_variable ('ELCFILES', TRUE, INTERNAL, '$(LISP:.el=.elc)');
4337
4338   push @all, '$(ELCFILES)';
4339
4340   require_variables ($elfiles[0][0], "Emacs Lisp sources seen", TRUE,
4341                      'EMACS', 'lispdir');
4342   require_conf_file ($elfiles[0][0], FOREIGN, 'elisp-comp');
4343   &define_variable ('elisp_comp', $config_aux_dir . '/elisp-comp', INTERNAL);
4344 }
4345
4346 # Handle Python
4347 sub handle_python
4348 {
4349   my @pyfiles = &am_install_var ('-defaultdist', 'python', 'PYTHON',
4350                                  'noinst');
4351   return if ! @pyfiles;
4352
4353   require_variables ($pyfiles[0][0], "Python sources seen", TRUE, 'PYTHON');
4354   require_conf_file ($pyfiles[0][0], FOREIGN, 'py-compile');
4355   &define_variable ('py_compile', $config_aux_dir . '/py-compile', INTERNAL);
4356 }
4357
4358 # Handle Java.
4359 sub handle_java
4360 {
4361     my @sourcelist = &am_install_var ('-candist',
4362                                       'java', 'JAVA',
4363                                       'java', 'noinst', 'check');
4364     return if ! @sourcelist;
4365
4366     my @prefix = am_primary_prefixes ('JAVA', 1,
4367                                       'java', 'noinst', 'check');
4368
4369     my $dir;
4370     foreach my $curs (@prefix)
4371       {
4372         next
4373           if $curs eq 'EXTRA';
4374
4375         err_var "${curs}_JAVA", "multiple _JAVA primaries in use"
4376           if defined $dir;
4377         $dir = $curs;
4378       }
4379
4380
4381     push (@all, 'class' . $dir . '.stamp');
4382 }
4383
4384
4385 # Handle some of the minor options.
4386 sub handle_minor_options
4387 {
4388   if (option 'readme-alpha')
4389     {
4390       if ($relative_dir eq '.')
4391         {
4392           if ($package_version !~ /^$GNITS_VERSION_PATTERN$/)
4393             {
4394               msg ('error-gnits', $package_version_location,
4395                    "version `$package_version' doesn't follow " .
4396                    "Gnits standards");
4397             }
4398           if (defined $1 && -f 'README-alpha')
4399             {
4400               # This means we have an alpha release.  See
4401               # GNITS_VERSION_PATTERN for details.
4402               push_dist_common ('README-alpha');
4403             }
4404         }
4405     }
4406 }
4407
4408 ################################################################
4409
4410 # ($OUTPUT, @INPUTS)
4411 # &split_config_file_spec ($SPEC)
4412 # -------------------------------
4413 # Decode the Autoconf syntax for config files (files, headers, links
4414 # etc.).
4415 sub split_config_file_spec ($)
4416 {
4417   my ($spec) = @_;
4418   my ($output, @inputs) = split (/:/, $spec);
4419
4420   push @inputs, "$output.in"
4421     unless @inputs;
4422
4423   return ($output, @inputs);
4424 }
4425
4426 # $input
4427 # locate_am (@POSSIBLE_SOURCES)
4428 # -----------------------------
4429 # AC_CONFIG_FILES allow specifications such as Makefile:top.in:mid.in:bot.in
4430 # This functions returns the first *.in file for which a *.am exists.
4431 # It returns undef otherwise.
4432 sub locate_am (@)
4433 {
4434   my (@rest) = @_;
4435   my $input;
4436   foreach my $file (@rest)
4437     {
4438       if (($file =~ /^(.*)\.in$/) && -f "$1.am")
4439         {
4440           $input = $file;
4441           last;
4442         }
4443     }
4444   return $input;
4445 }
4446
4447 my %make_list;
4448
4449 # &scan_autoconf_config_files ($WHERE, $CONFIG-FILES)
4450 # ---------------------------------------------------
4451 # Study $CONFIG-FILES which is the first argument to AC_CONFIG_FILES
4452 # (or AC_OUTPUT).
4453 sub scan_autoconf_config_files ($$)
4454 {
4455   my ($where, $config_files) = @_;
4456
4457   # Look at potential Makefile.am's.
4458   foreach (split ' ', $config_files)
4459     {
4460       # Must skip empty string for Perl 4.
4461       next if $_ eq "\\" || $_ eq '';
4462
4463       # Handle $local:$input syntax.
4464       my ($local, @rest) = split (/:/);
4465       @rest = ("$local.in",) unless @rest;
4466       my $input = locate_am @rest;
4467       if ($input)
4468         {
4469           # We have a file that automake should generate.
4470           $make_list{$input} = join (':', ($local, @rest));
4471         }
4472       else
4473         {
4474           # We have a file that automake should cause to be
4475           # rebuilt, but shouldn't generate itself.
4476           push (@other_input_files, $_);
4477         }
4478       $ac_config_files_location{$local} = $where;
4479     }
4480 }
4481
4482
4483 # &scan_autoconf_traces ($FILENAME)
4484 # ---------------------------------
4485 sub scan_autoconf_traces ($)
4486 {
4487   my ($filename) = @_;
4488
4489   # Macros to trace, with their minimal number of arguments.
4490   #
4491   # IMPORTANT: If you add a macro here, you should also add this macro
4492   # =========  to Automake-preselection in autoconf/lib/autom4te.in.
4493   my %traced = (
4494                 AC_CANONICAL_HOST => 0,
4495                 AC_CANONICAL_SYSTEM => 0,
4496                 AC_CONFIG_AUX_DIR => 1,
4497                 AC_CONFIG_FILES => 1,
4498                 AC_CONFIG_HEADERS => 1,
4499                 AC_CONFIG_LINKS => 1,
4500                 AC_INIT => 0,
4501                 AC_LIBSOURCE => 1,
4502                 AC_LIBTOOL_TAGS => 0,
4503                 AC_SUBST => 1,
4504                 AM_AUTOMAKE_VERSION => 1,
4505                 AM_CONDITIONAL => 2,
4506                 AM_ENABLE_MULTILIB => 0,
4507                 AM_GNU_GETTEXT => 0,
4508                 AM_INIT_AUTOMAKE => 0,
4509                 AM_MAINTAINER_MODE => 0,
4510                 AM_PROG_CC_C_O => 0,
4511                 m4_include => 1,
4512                 m4_sinclude => 1,
4513                 sinclude => 1,
4514                 _LT_AC_TAGCONFIG => 0,
4515               );
4516
4517   my $traces = ($ENV{AUTOCONF} || 'autoconf') . " ";
4518
4519   # Use a separator unlikely to be used, not `:', the default, which
4520   # has a precise meaning for AC_CONFIG_FILES and so on.
4521   $traces .= join (' ',
4522                    map { "--trace=$_" . ':\$f:\$l::\$n::\${::}%' }
4523                    (keys %traced));
4524
4525   my $tracefh = new Automake::XFile ("$traces $filename |");
4526   verb "reading $traces";
4527
4528   while ($_ = $tracefh->getline)
4529     {
4530       chomp;
4531       my ($here, @args) = split /::/;
4532       my $where = new Automake::Location $here;
4533       my $macro = $args[0];
4534
4535       prog_error ("unrequested trace `$macro'")
4536         unless exists $traced{$macro};
4537
4538       # Skip and diagnose malformed calls.
4539       if ($#args < $traced{$macro})
4540         {
4541           msg ('syntax', $where, "not enough arguments for $macro");
4542           next;
4543         }
4544
4545       # Alphabetical ordering please.
4546       if ($macro eq 'AC_CANONICAL_HOST')
4547         {
4548           if (! $seen_canonical)
4549             {
4550               $seen_canonical = AC_CANONICAL_HOST;
4551               $canonical_location = $where;
4552             }
4553         }
4554       elsif ($macro eq 'AC_CANONICAL_SYSTEM')
4555         {
4556           $seen_canonical = AC_CANONICAL_SYSTEM;
4557           $canonical_location = $where;
4558         }
4559       elsif ($macro eq 'AC_CONFIG_AUX_DIR')
4560         {
4561           @config_aux_path = $args[1];
4562           $config_aux_dir_set_in_configure_in = 1;
4563         }
4564       elsif ($macro eq 'AC_CONFIG_FILES')
4565         {
4566           # Look at potential Makefile.am's.
4567           scan_autoconf_config_files ($where, $args[1]);
4568         }
4569       elsif ($macro eq 'AC_CONFIG_HEADERS')
4570         {
4571           foreach my $spec (split (' ', $args[1]))
4572             {
4573               my ($dest, @src) = split (':', $spec);
4574               $ac_config_files_location{$dest} = $where;
4575               push @config_headers, $spec;
4576             }
4577         }
4578       elsif ($macro eq 'AC_CONFIG_LINKS')
4579         {
4580           foreach my $spec (split (' ', $args[1]))
4581             {
4582               my ($dest, $src) = split (':', $spec);
4583               $ac_config_files_location{$dest} = $where;
4584               push @config_links, $spec;
4585             }
4586         }
4587       elsif ($macro eq 'AC_INIT')
4588         {
4589           if (defined $args[2])
4590             {
4591               $package_version = $args[2];
4592               $package_version_location = $where;
4593             }
4594         }
4595       elsif ($macro eq 'AC_LIBSOURCE')
4596         {
4597           $libsources{$args[1]} = $here;
4598         }
4599       elsif ($macro eq 'AC_LIBTOOL_TAGS')
4600         {
4601           # Reset %libtool_tags, in case AC_LIBTOOL_TAGS is
4602           # expansed after _LT_AC_TAGCONFIG.  We want to ignore
4603           # _LT_AC_TAGCONFIG if AC_LIBTOOL_TAGS is called.
4604           %libtool_tags = (CC => 1);
4605           $libtool_tags{$_} = 1 foreach split (' ', $args[1]);
4606         }
4607       elsif ($macro eq 'AC_SUBST')
4608         {
4609           # Just check for alphanumeric in AC_SUBST.  If you do
4610           # AC_SUBST(5), then too bad.
4611           $configure_vars{$args[1]} = $where
4612             if $args[1] =~ /^\w+$/;
4613         }
4614       elsif ($macro eq 'AM_AUTOMAKE_VERSION')
4615         {
4616           error ($where,
4617                  "version mismatch.  This is Automake $VERSION,\n" .
4618                  "but the definition used by this AM_INIT_AUTOMAKE\n" .
4619                  "comes from Automake $args[1].  You should recreate\n" .
4620                  "aclocal.m4 with aclocal and run automake again.\n",
4621                  # $? = 63 is used to indicate version mismatch to missing.
4622                  exit_code => 63)
4623             if $VERSION ne $args[1];
4624
4625           $seen_automake_version = 1;
4626         }
4627       elsif ($macro eq 'AM_CONDITIONAL')
4628         {
4629           $configure_cond{$args[1]} = $where;
4630         }
4631       elsif ($macro eq 'AM_ENABLE_MULTILIB')
4632         {
4633           $seen_multilib = $where;
4634         }
4635       elsif ($macro eq 'AM_GNU_GETTEXT')
4636         {
4637           $seen_gettext = $where;
4638           $ac_gettext_location = $where;
4639           $seen_gettext_external = grep ($_ eq 'external', @args);
4640         }
4641       elsif ($macro eq 'AM_INIT_AUTOMAKE')
4642         {
4643           $seen_init_automake = $where;
4644           if (defined $args[2])
4645             {
4646               $package_version = $args[2];
4647               $package_version_location = $where;
4648             }
4649           elsif (defined $args[1])
4650             {
4651               exit $exit_code
4652                 if (process_global_option_list ($where,
4653                                                 split (' ', $args[1])));
4654             }
4655         }
4656       elsif ($macro eq 'AM_MAINTAINER_MODE')
4657         {
4658           $seen_maint_mode = $where;
4659         }
4660       elsif ($macro eq 'AM_PROG_CC_C_O')
4661         {
4662           $seen_cc_c_o = $where;
4663         }
4664       elsif ($macro eq 'm4_include'
4665              || $macro eq 'm4_sinclude'
4666              || $macro eq 'sinclude')
4667         {
4668           # Some modified versions of Autoconf don't use
4669           # forzen files.  Consequently it's possible that we see all
4670           # m4_include's performed during Autoconf's startup.
4671           # Obviously we don't want to distribute Autoconf's files
4672           # so we skip absolute filenames here.
4673           push @configure_deps, '$(top_srcdir)/' . $args[1]
4674             unless $here =~ m,^(?:\w:)?[\\/],;
4675           # Keep track of the greatest timestamp.
4676           if (-e $args[1])
4677             {
4678               my $mtime = mtime $args[1];
4679               $configure_deps_greatest_timestamp = $mtime
4680                 if $mtime > $configure_deps_greatest_timestamp;
4681             }
4682         }
4683       elsif ($macro eq '_LT_AC_TAGCONFIG')
4684         {
4685           # _LT_AC_TAGCONFIG is an old macro present in Libtool 1.5.
4686           # We use it to detect whether tags are supported.  Our prefered
4687           # interface is AC_LIBTOOL_TAGS, but it was introduced in
4688           # Libtool 1.6.  Ignore _LT_AC_TAGCONFIG if AC_LIBTOOL_TAGS has
4689           # been called.
4690           if (0 == keys %libtool_tags)
4691             {
4692               # Hardcode the tags supported by Libtool 1.5.
4693               %libtool_tags = (CC => 1, CXX => 1, GCJ => 1, F77 => 1);
4694             }
4695         }
4696     }
4697
4698   $tracefh->close;
4699 }
4700
4701
4702 # &scan_autoconf_files ()
4703 # -----------------------
4704 # Check whether we use `configure.ac' or `configure.in'.
4705 # Scan it (and possibly `aclocal.m4') for interesting things.
4706 # We must scan aclocal.m4 because there might be AC_SUBSTs and such there.
4707 sub scan_autoconf_files ()
4708 {
4709   # Reinitialize libsources here.  This isn't really necessary,
4710   # since we currently assume there is only one configure.ac.  But
4711   # that won't always be the case.
4712   %libsources = ();
4713
4714   # Keep track of the youngest configure dependency.
4715   $configure_deps_greatest_timestamp = mtime $configure_ac;
4716   if (-e 'aclocal.m4')
4717     {
4718       my $mtime = mtime 'aclocal.m4';
4719       $configure_deps_greatest_timestamp = $mtime
4720         if $mtime > $configure_deps_greatest_timestamp;
4721     }
4722
4723   scan_autoconf_traces ($configure_ac);
4724
4725   @configure_input_files = sort keys %make_list;
4726   # Set input and output files if not specified by user.
4727   if (! @input_files)
4728     {
4729       @input_files = @configure_input_files;
4730       %output_files = %make_list;
4731     }
4732
4733
4734   if (! $seen_init_automake)
4735     {
4736       err_ac ("no proper invocation of AM_INIT_AUTOMAKE was found.\nYou "
4737               . "should verify that $configure_ac invokes AM_INIT_AUTOMAKE,"
4738               . "\nthat aclocal.m4 is present in the top-level directory,\n"
4739               . "and that aclocal.m4 was recently regenerated "
4740               . "(using aclocal).");
4741     }
4742   else
4743     {
4744       if (! $seen_automake_version)
4745         {
4746           if (-f 'aclocal.m4')
4747             {
4748               error ($seen_init_automake,
4749                      "your implementation of AM_INIT_AUTOMAKE comes from " .
4750                      "an\nold Automake version.  You should recreate " .
4751                      "aclocal.m4\nwith aclocal and run automake again.\n",
4752                      # $? = 63 is used to indicate version mismatch to missing.
4753                      exit_code => 63);
4754             }
4755           else
4756             {
4757               error ($seen_init_automake,
4758                      "no proper implementation of AM_INIT_AUTOMAKE was " .
4759                      "found,\nprobably because aclocal.m4 is missing...\n" .
4760                      "You should run aclocal to create this file, then\n" .
4761                      "run automake again.\n");
4762             }
4763         }
4764     }
4765
4766   # Look for some files we need.  Always check for these.  This
4767   # check must be done for every run, even those where we are only
4768   # looking at a subdir Makefile.  We must set relative_dir so that
4769   # the file-finding machinery works.
4770   # FIXME: Is this broken because it needs dynamic scopes.
4771   # My tests seems to show it's not the case.
4772   $relative_dir = '.';
4773   require_conf_file ($configure_ac, FOREIGN, 'install-sh', 'missing');
4774   err_am "`install.sh' is an anachronism; use `install-sh' instead"
4775     if -f $config_aux_path[0] . '/install.sh';
4776
4777   # Preserve dist_common for later.
4778   $configure_dist_common = variable_value ('DIST_COMMON') || '';
4779 }
4780
4781 ################################################################
4782
4783 # Set up for Cygnus mode.
4784 sub check_cygnus
4785 {
4786   my $cygnus = option 'cygnus';
4787   return unless $cygnus;
4788
4789   set_strictness ('foreign');
4790   set_option ('no-installinfo', $cygnus);
4791   set_option ('no-dependencies', $cygnus);
4792   set_option ('no-dist', $cygnus);
4793
4794   err_ac "`AM_MAINTAINER_MODE' required when --cygnus specified"
4795     if !$seen_maint_mode;
4796 }
4797
4798 # Do any extra checking for GNU standards.
4799 sub check_gnu_standards
4800 {
4801   if ($relative_dir eq '.')
4802     {
4803       # In top level (or only) directory.
4804       require_file ("$am_file.am", GNU,
4805                     qw/INSTALL NEWS README AUTHORS ChangeLog/);
4806
4807       # Accept one of these three licenses; default to COPYING.
4808       # Make sure we do not overwrite an existing license.
4809       my $license;
4810       foreach (qw /COPYING COPYING.LIB COPYING.LESSER/)
4811         {
4812           if (-f $_)
4813             {
4814               $license = $_;
4815               last;
4816             }
4817         }
4818       require_file ("$am_file.am", GNU, 'COPYING')
4819         unless $license;
4820     }
4821
4822   for my $opt ('no-installman', 'no-installinfo')
4823     {
4824       msg ('error-gnu', option $opt,
4825            "option `$opt' disallowed by GNU standards")
4826         if option $opt;
4827     }
4828 }
4829
4830 # Do any extra checking for GNITS standards.
4831 sub check_gnits_standards
4832 {
4833   if ($relative_dir eq '.')
4834     {
4835       # In top level (or only) directory.
4836       require_file ("$am_file.am", GNITS, 'THANKS');
4837     }
4838 }
4839
4840 ################################################################
4841 #
4842 # Functions to handle files of each language.
4843
4844 # Each `lang_X_rewrite($DIRECTORY, $BASE, $EXT)' function follows a
4845 # simple formula: Return value is LANG_SUBDIR if the resulting object
4846 # file should be in a subdir if the source file is, LANG_PROCESS if
4847 # file is to be dealt with, LANG_IGNORE otherwise.
4848
4849 # Much of the actual processing is handled in
4850 # handle_single_transform.  These functions exist so that
4851 # auxiliary information can be recorded for a later cleanup pass.
4852 # Note that the calls to these functions are computed, so don't bother
4853 # searching for their precise names in the source.
4854
4855 # This is just a convenience function that can be used to determine
4856 # when a subdir object should be used.
4857 sub lang_sub_obj
4858 {
4859     return option 'subdir-objects' ? LANG_SUBDIR : LANG_PROCESS;
4860 }
4861
4862 # Rewrite a single C source file.
4863 sub lang_c_rewrite
4864 {
4865   my ($directory, $base, $ext) = @_;
4866
4867   if (option 'ansi2knr' && $base =~ /_$/)
4868     {
4869       # FIXME: include line number in error.
4870       err_am "C source file `$base.c' would be deleted by ansi2knr rules";
4871     }
4872
4873   my $r = LANG_PROCESS;
4874   if (option 'subdir-objects')
4875     {
4876       $r = LANG_SUBDIR;
4877       $base = $directory . '/' . $base
4878         unless $directory eq '.' || $directory eq '';
4879
4880       err_am ("C objects in subdir but `AM_PROG_CC_C_O' "
4881               . "not in `$configure_ac'",
4882               uniq_scope => US_GLOBAL)
4883         unless $seen_cc_c_o;
4884
4885       require_conf_file ("$am_file.am", FOREIGN, 'compile');
4886
4887       # In this case we already have the directory information, so
4888       # don't add it again.
4889       $de_ansi_files{$base} = '';
4890     }
4891   else
4892     {
4893       $de_ansi_files{$base} = (($directory eq '.' || $directory eq '')
4894                                ? ''
4895                                : "$directory/");
4896     }
4897
4898     return $r;
4899 }
4900
4901 # Rewrite a single C++ source file.
4902 sub lang_cxx_rewrite
4903 {
4904     return &lang_sub_obj;
4905 }
4906
4907 # Rewrite a single header file.
4908 sub lang_header_rewrite
4909 {
4910     # Header files are simply ignored.
4911     return LANG_IGNORE;
4912 }
4913
4914 # Rewrite a single yacc file.
4915 sub lang_yacc_rewrite
4916 {
4917     my ($directory, $base, $ext) = @_;
4918
4919     my $r = &lang_sub_obj;
4920     (my $newext = $ext) =~ tr/y/c/;
4921     return ($r, $newext);
4922 }
4923
4924 # Rewrite a single yacc++ file.
4925 sub lang_yaccxx_rewrite
4926 {
4927     my ($directory, $base, $ext) = @_;
4928
4929     my $r = &lang_sub_obj;
4930     (my $newext = $ext) =~ tr/y/c/;
4931     return ($r, $newext);
4932 }
4933
4934 # Rewrite a single lex file.
4935 sub lang_lex_rewrite
4936 {
4937     my ($directory, $base, $ext) = @_;
4938
4939     my $r = &lang_sub_obj;
4940     (my $newext = $ext) =~ tr/l/c/;
4941     return ($r, $newext);
4942 }
4943
4944 # Rewrite a single lex++ file.
4945 sub lang_lexxx_rewrite
4946 {
4947     my ($directory, $base, $ext) = @_;
4948
4949     my $r = &lang_sub_obj;
4950     (my $newext = $ext) =~ tr/l/c/;
4951     return ($r, $newext);
4952 }
4953
4954 # Rewrite a single assembly file.
4955 sub lang_asm_rewrite
4956 {
4957     return &lang_sub_obj;
4958 }
4959
4960 # Rewrite a single Fortran 77 file.
4961 sub lang_f77_rewrite
4962 {
4963     return LANG_PROCESS;
4964 }
4965
4966 # Rewrite a single preprocessed Fortran 77 file.
4967 sub lang_ppf77_rewrite
4968 {
4969     return LANG_PROCESS;
4970 }
4971
4972 # Rewrite a single ratfor file.
4973 sub lang_ratfor_rewrite
4974 {
4975     return LANG_PROCESS;
4976 }
4977
4978 # Rewrite a single Objective C file.
4979 sub lang_objc_rewrite
4980 {
4981     return &lang_sub_obj;
4982 }
4983
4984 # Rewrite a single Java file.
4985 sub lang_java_rewrite
4986 {
4987     return LANG_SUBDIR;
4988 }
4989
4990 # The lang_X_finish functions are called after all source file
4991 # processing is done.  Each should handle defining rules for the
4992 # language, etc.  A finish function is only called if a source file of
4993 # the appropriate type has been seen.
4994
4995 sub lang_c_finish
4996 {
4997     # Push all libobjs files onto de_ansi_files.  We actually only
4998     # push files which exist in the current directory, and which are
4999     # genuine source files.
5000     foreach my $file (keys %libsources)
5001     {
5002         if ($file =~ /^(.*)\.[cly]$/ && -f "$relative_dir/$file")
5003         {
5004             $de_ansi_files{$1} = ''
5005         }
5006     }
5007
5008     if (option 'ansi2knr' && keys %de_ansi_files)
5009     {
5010         # Make all _.c files depend on their corresponding .c files.
5011         my @objects;
5012         foreach my $base (sort keys %de_ansi_files)
5013         {
5014             # Each _.c file must depend on ansi2knr; otherwise it
5015             # might be used in a parallel build before it is built.
5016             # We need to support files in the srcdir and in the build
5017             # dir (because these files might be auto-generated.  But
5018             # we can't use $< -- some makes only define $< during a
5019             # suffix rule.
5020             my $ansfile = $de_ansi_files{$base} . $base . '.c';
5021             $output_rules .= ($base . "_.c: $ansfile \$(ANSI2KNR)\n\t"
5022                               . '$(CPP) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) '
5023                               . '`if test -f $(srcdir)/' . $ansfile
5024                               . '; then echo $(srcdir)/' . $ansfile
5025                               . '; else echo ' . $ansfile . '; fi` '
5026                               . "| sed 's/^# \\([0-9]\\)/#line \\1/' "
5027                               . '| $(ANSI2KNR) > $@'
5028                               # If ansi2knr fails then we shouldn't
5029                               # create the _.c file
5030                               . " || rm -f \$\@\n");
5031             push (@objects, $base . '_.$(OBJEXT)');
5032             push (@objects, $base . '_.lo')
5033               if var ('LIBTOOL');
5034
5035             # Explicitly clean the _.c files if they are in a
5036             # subdirectory. (In the current directory they get erased
5037             # by a `rm -f *_.c' rule.)
5038             $clean_files{$base . '_.c'} = MOSTLY_CLEAN
5039               if dirname ($base) ne '.';
5040         }
5041
5042         # Make all _.o (and _.lo) files depend on ansi2knr.
5043         # Use a sneaky little hack to make it print nicely.
5044         &pretty_print_rule ('', '', @objects, ':', '$(ANSI2KNR)');
5045     }
5046 }
5047
5048 # This is a yacc helper which is called whenever we have decided to
5049 # compile a yacc file.
5050 sub lang_yacc_target_hook
5051 {
5052     my ($self, $aggregate, $output, $input) = @_;
5053
5054     my $flag = $aggregate . "_YFLAGS";
5055     my $flagvar = var $flag;
5056     my $YFLAGSvar = var 'YFLAGS';
5057     if (($flagvar && $flagvar->variable_value =~ /$DASH_D_PATTERN/o)
5058         || ($YFLAGSvar && $YFLAGSvar->variable_value =~ /$DASH_D_PATTERN/o))
5059     {
5060         (my $output_base = $output) =~ s/$KNOWN_EXTENSIONS_PATTERN$//;
5061         my $header = $output_base . '.h';
5062
5063         # Found a `-d' that applies to the compilation of this file.
5064         # Add a dependency for the generated header file, and arrange
5065         # for that file to be included in the distribution.
5066         # FIXME: this fails for `nodist_*_SOURCES'.
5067         $output_rules .= ("${header}: $output\n"
5068                           # Recover from removal of $header
5069                           . "\t\@if test ! -f \$@; then \\\n"
5070                           . "\t  rm -f $output; \\\n"
5071                           . "\t  \$(MAKE) $output; \\\n"
5072                           . "\telse :; fi\n");
5073         &push_dist_common ($header);
5074         # If the files are built in the build directory, then we want
5075         # to remove them with `make clean'.  If they are in srcdir
5076         # they shouldn't be touched.  However, we can't determine this
5077         # statically, and the GNU rules say that yacc/lex output files
5078         # should be removed by maintainer-clean.  So that's what we
5079         # do.
5080         $clean_files{$header} = MAINTAINER_CLEAN;
5081     }
5082     # Erase $OUTPUT on `make maintainer-clean' (by GNU standards).
5083     # See the comment above for $HEADER.
5084     $clean_files{$output} = MAINTAINER_CLEAN;
5085 }
5086
5087 # This is a lex helper which is called whenever we have decided to
5088 # compile a lex file.
5089 sub lang_lex_target_hook
5090 {
5091     my ($self, $aggregate, $output, $input) = @_;
5092     # If the files are built in the build directory, then we want to
5093     # remove them with `make clean'.  If they are in srcdir they
5094     # shouldn't be touched.  However, we can't determine this
5095     # statically, and the GNU rules say that yacc/lex output files
5096     # should be removed by maintainer-clean.  So that's what we do.
5097     $clean_files{$output} = MAINTAINER_CLEAN;
5098 }
5099
5100 # This is a helper for both lex and yacc.
5101 sub yacc_lex_finish_helper
5102 {
5103     return if defined $language_scratch{'lex-yacc-done'};
5104     $language_scratch{'lex-yacc-done'} = 1;
5105
5106     # If there is more than one distinct yacc (resp lex) source file
5107     # in a given directory, then the `ylwrap' program is required to
5108     # allow parallel builds to work correctly.  FIXME: for now, no
5109     # line number.
5110     require_conf_file ($configure_ac, FOREIGN, 'ylwrap');
5111     if ($config_aux_dir_set_in_configure_in)
5112     {
5113         &define_variable ('YLWRAP', $config_aux_dir . "/ylwrap", INTERNAL);
5114     }
5115     else
5116     {
5117         &define_variable ('YLWRAP', '$(top_srcdir)/ylwrap', INTERNAL);
5118     }
5119 }
5120
5121 sub lang_yacc_finish
5122 {
5123   return if defined $language_scratch{'yacc-done'};
5124   $language_scratch{'yacc-done'} = 1;
5125
5126   reject_var 'YACCFLAGS', "`YACCFLAGS' obsolete; use `YFLAGS' instead";
5127
5128   &yacc_lex_finish_helper
5129     if count_files_for_language ('yacc') > 1;
5130 }
5131
5132
5133 sub lang_lex_finish
5134 {
5135   return if defined $language_scratch{'lex-done'};
5136   $language_scratch{'lex-done'} = 1;
5137
5138   &yacc_lex_finish_helper
5139     if count_files_for_language ('lex') > 1;
5140 }
5141
5142
5143 # Given a hash table of linker names, pick the name that has the most
5144 # precedence.  This is lame, but something has to have global
5145 # knowledge in order to eliminate the conflict.  Add more linkers as
5146 # required.
5147 sub resolve_linker
5148 {
5149     my (%linkers) = @_;
5150
5151     foreach my $l (qw(GCJLINK CXXLINK F77LINK OBJCLINK))
5152     {
5153         return $l if defined $linkers{$l};
5154     }
5155     return 'LINK';
5156 }
5157
5158 # Called to indicate that an extension was used.
5159 sub saw_extension
5160 {
5161     my ($ext) = @_;
5162     if (! defined $extension_seen{$ext})
5163     {
5164         $extension_seen{$ext} = 1;
5165     }
5166     else
5167     {
5168         ++$extension_seen{$ext};
5169     }
5170 }
5171
5172 # Return the number of files seen for a given language.  Knows about
5173 # special cases we care about.  FIXME: this is hideous.  We need
5174 # something that involves real language objects.  For instance yacc
5175 # and yaccxx could both derive from a common yacc class which would
5176 # know about the strange ylwrap requirement.  (Or better yet we could
5177 # just not support legacy yacc!)
5178 sub count_files_for_language
5179 {
5180     my ($name) = @_;
5181
5182     my @names;
5183     if ($name eq 'yacc' || $name eq 'yaccxx')
5184     {
5185         @names = ('yacc', 'yaccxx');
5186     }
5187     elsif ($name eq 'lex' || $name eq 'lexxx')
5188     {
5189         @names = ('lex', 'lexxx');
5190     }
5191     else
5192     {
5193         @names = ($name);
5194     }
5195
5196     my $r = 0;
5197     foreach $name (@names)
5198     {
5199         my $lang = $languages{$name};
5200         foreach my $ext (@{$lang->extensions})
5201         {
5202             $r += $extension_seen{$ext}
5203                 if defined $extension_seen{$ext};
5204         }
5205     }
5206
5207     return $r
5208 }
5209
5210 # Called to ask whether source files have been seen . If HEADERS is 1,
5211 # headers can be included.
5212 sub saw_sources_p
5213 {
5214     my ($headers) = @_;
5215
5216     # count all the sources
5217     my $count = 0;
5218     foreach my $val (values %extension_seen)
5219     {
5220         $count += $val;
5221     }
5222
5223     if (!$headers)
5224     {
5225         $count -= count_files_for_language ('header');
5226     }
5227
5228     return $count > 0;
5229 }
5230
5231
5232 # register_language (%ATTRIBUTE)
5233 # ------------------------------
5234 # Register a single language.
5235 # Each %ATTRIBUTE is of the form ATTRIBUTE => VALUE.
5236 sub register_language (%)
5237 {
5238   my (%option) = @_;
5239
5240   # Set the defaults.
5241   $option{'ansi'} = 0
5242     unless defined $option{'ansi'};
5243   $option{'autodep'} = 'no'
5244     unless defined $option{'autodep'};
5245   $option{'linker'} = ''
5246     unless defined $option{'linker'};
5247   $option{'flags'} = []
5248     unless defined $option{'flags'};
5249   $option{'output_extensions'} = sub { return ( '.$(OBJEXT)', '.lo' ) }
5250     unless defined $option{'output_extensions'};
5251
5252   my $lang = new Language (%option);
5253
5254   # Fill indexes.
5255   $extension_map{$_} = $lang->name foreach @{$lang->extensions};
5256   $languages{$lang->name} = $lang;
5257
5258   # Update the pattern of known extensions.
5259   accept_extensions (@{$lang->extensions});
5260
5261   # Upate the $suffix_rule map.
5262   foreach my $suffix (@{$lang->extensions})
5263     {
5264       foreach my $dest (&{$lang->output_extensions} ($suffix))
5265         {
5266           register_suffix_rule (INTERNAL, $suffix, $dest);
5267         }
5268     }
5269 }
5270
5271 # derive_suffix ($EXT, $OBJ)
5272 # --------------------------
5273 # This function is used to find a path from a user-specified suffix $EXT
5274 # to $OBJ or to some other suffix we recognize internally, e.g. `cc'.
5275 sub derive_suffix ($$)
5276 {
5277   my ($source_ext, $obj) = @_;
5278
5279   while (! $extension_map{$source_ext}
5280          && $source_ext ne $obj
5281          && exists $suffix_rules->{$source_ext}
5282          && exists $suffix_rules->{$source_ext}{$obj})
5283     {
5284       $source_ext = $suffix_rules->{$source_ext}{$obj}[0];
5285     }
5286
5287   return $source_ext;
5288 }
5289
5290
5291 ################################################################
5292
5293 # Pretty-print something and append to output_rules.
5294 sub pretty_print_rule
5295 {
5296     $output_rules .= &makefile_wrap (@_);
5297 }
5298
5299
5300 ################################################################
5301
5302
5303 ## -------------------------------- ##
5304 ## Handling the conditional stack.  ##
5305 ## -------------------------------- ##
5306
5307
5308 # $STRING
5309 # make_conditional_string ($NEGATE, $COND)
5310 # ----------------------------------------
5311 sub make_conditional_string ($$)
5312 {
5313   my ($negate, $cond) = @_;
5314   $cond = "${cond}_TRUE"
5315     unless $cond =~ /^TRUE|FALSE$/;
5316   $cond = Automake::Condition::conditional_negate ($cond)
5317     if $negate;
5318   return $cond;
5319 }
5320
5321
5322 # $COND
5323 # cond_stack_if ($NEGATE, $COND, $WHERE)
5324 # --------------------------------------
5325 sub cond_stack_if ($$$)
5326 {
5327   my ($negate, $cond, $where) = @_;
5328
5329   error $where, "$cond does not appear in AM_CONDITIONAL"
5330     if ! $configure_cond{$cond} && $cond !~ /^TRUE|FALSE$/;
5331
5332   push (@cond_stack, make_conditional_string ($negate, $cond));
5333
5334   return new Automake::Condition (@cond_stack);
5335 }
5336
5337
5338 # $COND
5339 # cond_stack_else ($NEGATE, $COND, $WHERE)
5340 # ----------------------------------------
5341 sub cond_stack_else ($$$)
5342 {
5343   my ($negate, $cond, $where) = @_;
5344
5345   if (! @cond_stack)
5346     {
5347       error $where, "else without if";
5348       return FALSE;
5349     }
5350
5351   $cond_stack[$#cond_stack] =
5352     Automake::Condition::conditional_negate ($cond_stack[$#cond_stack]);
5353
5354   # If $COND is given, check against it.
5355   if (defined $cond)
5356     {
5357       $cond = make_conditional_string ($negate, $cond);
5358
5359       error ($where, "else reminder ($negate$cond) incompatible with "
5360              . "current conditional: $cond_stack[$#cond_stack]")
5361         if $cond_stack[$#cond_stack] ne $cond;
5362     }
5363
5364   return new Automake::Condition (@cond_stack);
5365 }
5366
5367
5368 # $COND
5369 # cond_stack_endif ($NEGATE, $COND, $WHERE)
5370 # -----------------------------------------
5371 sub cond_stack_endif ($$$)
5372 {
5373   my ($negate, $cond, $where) = @_;
5374   my $old_cond;
5375
5376   if (! @cond_stack)
5377     {
5378       error $where, "endif without if";
5379       return TRUE;
5380     }
5381
5382   # If $COND is given, check against it.
5383   if (defined $cond)
5384     {
5385       $cond = make_conditional_string ($negate, $cond);
5386
5387       error ($where, "endif reminder ($negate$cond) incompatible with "
5388              . "current conditional: $cond_stack[$#cond_stack]")
5389         if $cond_stack[$#cond_stack] ne $cond;
5390     }
5391
5392   pop @cond_stack;
5393
5394   return new Automake::Condition (@cond_stack);
5395 }
5396
5397
5398
5399
5400
5401 ## ------------------------ ##
5402 ## Handling the variables.  ##
5403 ## ------------------------ ##
5404
5405
5406 # &define_pretty_variable ($VAR, $COND, $WHERE, @VALUE)
5407 # -----------------------------------------------------
5408 # Like define_variable, but the value is a list, and the variable may
5409 # be defined conditionally.  The second argument is the Condition
5410 # under which the value should be defined; this should be the empty
5411 # string to define the variable unconditionally.  The third argument
5412 # is a list holding the values to use for the variable.  The value is
5413 # pretty printed in the output file.
5414 sub define_pretty_variable ($$$@)
5415 {
5416     my ($var, $cond, $where, @value) = @_;
5417
5418     if (! vardef ($var, $cond))
5419     {
5420         Automake::Variable::define ($var, VAR_AUTOMAKE, '', $cond, "@value",
5421                                     '', $where, VAR_PRETTY);
5422         rvar ($var)->rdef ($cond)->set_seen;
5423     }
5424 }
5425
5426
5427 # define_variable ($VAR, $VALUE, $WHERE)
5428 # --------------------------------------
5429 # Define a new user variable VAR to VALUE, but only if not already defined.
5430 sub define_variable ($$$)
5431 {
5432     my ($var, $value, $where) = @_;
5433     define_pretty_variable ($var, TRUE, $where, $value);
5434 }
5435
5436
5437 # define_files_variable ($VAR, \@BASENAME, $EXTENSION, $WHERE)
5438 # -----------------------------------------------------------
5439 # Define the $VAR which content is the list of file names composed of
5440 # a @BASENAME and the $EXTENSION.
5441 sub define_files_variable ($\@$$)
5442 {
5443   my ($var, $basename, $extension, $where) = @_;
5444   define_variable ($var,
5445                    join (' ', map { "$_.$extension" } @$basename),
5446                    $where);
5447 }
5448
5449
5450 # Like define_variable, but define a variable to be the configure
5451 # substitution by the same name.
5452 sub define_configure_variable ($)
5453 {
5454   my ($var) = @_;
5455
5456   my $pretty = VAR_ASIS;
5457   my $owner = VAR_CONFIGURE;
5458
5459   # Do not output the ANSI2KNR configure variable -- we AC_SUBST
5460   # it in protos.m4, but later redefine it elsewhere.  This is
5461   # pretty hacky.  We also don't output AMDEPBACKSLASH: it might
5462   # be subst'd by `\', which certainly would not be appreciated by
5463   # Make.
5464   if ($var eq 'ANSI2KNR' || $var eq 'AMDEPBACKSLASH')
5465     {
5466       $pretty = VAR_SILENT;
5467       $owner = VAR_AUTOMAKE;
5468     }
5469
5470   Automake::Variable::define ($var, $owner, '', TRUE, subst $var,
5471                               '', $configure_vars{$var}, $pretty);
5472 }
5473
5474
5475 # define_compiler_variable ($LANG)
5476 # --------------------------------
5477 # Define a compiler variable.  We also handle defining the `LT'
5478 # version of the command when using libtool.
5479 sub define_compiler_variable ($)
5480 {
5481     my ($lang) = @_;
5482
5483     my ($var, $value) = ($lang->compiler, $lang->compile);
5484     my $libtool_tag = '';
5485     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
5486       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
5487     &define_variable ($var, $value, INTERNAL);
5488     &define_variable ("LT$var",
5489                       "\$(LIBTOOL) --mode=compile $libtool_tag$value",
5490                       INTERNAL)
5491       if var ('LIBTOOL');
5492 }
5493
5494
5495 # define_linker_variable ($LANG)
5496 # ------------------------------
5497 # Define linker variables.
5498 sub define_linker_variable ($)
5499 {
5500     my ($lang) = @_;
5501
5502     my ($var, $value) = ($lang->lder, $lang->ld);
5503     my $libtool_tag = '';
5504     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
5505       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
5506     # CCLD = $(CC).
5507     &define_variable ($lang->lder, $lang->ld, INTERNAL);
5508     # CCLINK = $(CCLD) blah blah...
5509     &define_variable ($lang->linker,
5510                       ((var ('LIBTOOL') ?
5511                         '$(LIBTOOL) --mode=link ' . $libtool_tag  : '')
5512                        . $lang->link),
5513                       INTERNAL);
5514 }
5515
5516 ################################################################
5517
5518 # &check_trailing_slash ($WHERE, $LINE)
5519 # --------------------------------------
5520 # Return 1 iff $LINE ends with a slash.
5521 # Might modify $LINE.
5522 sub check_trailing_slash ($\$)
5523 {
5524   my ($where, $line) = @_;
5525
5526   # Ignore `##' lines.
5527   return 0 if $$line =~ /$IGNORE_PATTERN/o;
5528
5529   # Catch and fix a common error.
5530   msg "syntax", $where, "whitespace following trailing backslash"
5531     if $$line =~ s/\\\s+\n$/\\\n/;
5532
5533   return $$line =~ /\\$/;
5534 }
5535
5536
5537 # &read_am_file ($AMFILE, $WHERE)
5538 # -------------------------------
5539 # Read Makefile.am and set up %contents.  Simultaneously copy lines
5540 # from Makefile.am into $output_trailer, or define variables as
5541 # appropriate.  NOTE we put rules in the trailer section.  We want
5542 # user rules to come after our generated stuff.
5543 sub read_am_file ($$)
5544 {
5545     my ($amfile, $where) = @_;
5546
5547     my $am_file = new Automake::XFile ("< $amfile");
5548     verb "reading $amfile";
5549
5550     # Keep track of the youngest output dependency.
5551     my $mtime = mtime $amfile;
5552     $output_deps_greatest_timestamp = $mtime
5553       if $mtime > $output_deps_greatest_timestamp;
5554
5555     my $spacing = '';
5556     my $comment = '';
5557     my $blank = 0;
5558     my $saw_bk = 0;
5559
5560     use constant IN_VAR_DEF => 0;
5561     use constant IN_RULE_DEF => 1;
5562     use constant IN_COMMENT => 2;
5563     my $prev_state = IN_RULE_DEF;
5564
5565     while ($_ = $am_file->getline)
5566     {
5567         $where->set ("$amfile:$.");
5568         if (/$IGNORE_PATTERN/o)
5569         {
5570             # Merely delete comments beginning with two hashes.
5571         }
5572         elsif (/$WHITE_PATTERN/o)
5573         {
5574             error $where, "blank line following trailing backslash"
5575               if $saw_bk;
5576             # Stick a single white line before the incoming macro or rule.
5577             $spacing = "\n";
5578             $blank = 1;
5579             # Flush all comments seen so far.
5580             if ($comment ne '')
5581             {
5582                 $output_vars .= $comment;
5583                 $comment = '';
5584             }
5585         }
5586         elsif (/$COMMENT_PATTERN/o)
5587         {
5588             # Stick comments before the incoming macro or rule.  Make
5589             # sure a blank line precedes the first block of comments.
5590             $spacing = "\n" unless $blank;
5591             $blank = 1;
5592             $comment .= $spacing . $_;
5593             $spacing = '';
5594             $prev_state = IN_COMMENT;
5595         }
5596         else
5597         {
5598             last;
5599         }
5600         $saw_bk = check_trailing_slash ($where, $_);
5601     }
5602
5603     # We save the conditional stack on entry, and then check to make
5604     # sure it is the same on exit.  This lets us conditionally include
5605     # other files.
5606     my @saved_cond_stack = @cond_stack;
5607     my $cond = new Automake::Condition (@cond_stack);
5608
5609     my $last_var_name = '';
5610     my $last_var_type = '';
5611     my $last_var_value = '';
5612     my $last_where;
5613     # FIXME: shouldn't use $_ in this loop; it is too big.
5614     while ($_)
5615     {
5616         $where->set ("$amfile:$.");
5617
5618         # Make sure the line is \n-terminated.
5619         chomp;
5620         $_ .= "\n";
5621
5622         # Don't look at MAINTAINER_MODE_TRUE here.  That shouldn't be
5623         # used by users.  @MAINT@ is an anachronism now.
5624         $_ =~ s/\@MAINT\@//g
5625             unless $seen_maint_mode;
5626
5627         my $new_saw_bk = check_trailing_slash ($where, $_);
5628
5629         if (/$IGNORE_PATTERN/o)
5630         {
5631             # Merely delete comments beginning with two hashes.
5632         }
5633         elsif (/$WHITE_PATTERN/o)
5634         {
5635             # Stick a single white line before the incoming macro or rule.
5636             $spacing = "\n";
5637             error $where, "blank line following trailing backslash"
5638               if $saw_bk;
5639         }
5640         elsif (/$COMMENT_PATTERN/o)
5641         {
5642             # Stick comments before the incoming macro or rule.
5643             $comment .= $spacing . $_;
5644             $spacing = '';
5645             error $where, "comment following trailing backslash"
5646               if $saw_bk && $comment eq '';
5647             $prev_state = IN_COMMENT;
5648         }
5649         elsif ($saw_bk)
5650         {
5651             if ($prev_state == IN_RULE_DEF)
5652             {
5653               my $cond = new Automake::Condition @cond_stack;
5654               $output_trailer .= $cond->subst_string;
5655               $output_trailer .= $_;
5656             }
5657             elsif ($prev_state == IN_COMMENT)
5658             {
5659                 # If the line doesn't start with a `#', add it.
5660                 # We do this because a continued comment like
5661                 #   # A = foo \
5662                 #         bar \
5663                 #         baz
5664                 # is not portable.  BSD make doesn't honor
5665                 # escaped newlines in comments.
5666                 s/^#?/#/;
5667                 $comment .= $spacing . $_;
5668             }
5669             else # $prev_state == IN_VAR_DEF
5670             {
5671               $last_var_value .= ' '
5672                 unless $last_var_value =~ /\s$/;
5673               $last_var_value .= $_;
5674
5675               if (!/\\$/)
5676                 {
5677                   Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
5678                                               $last_var_type, $cond,
5679                                               $last_var_value, $comment,
5680                                               $last_where, VAR_ASIS)
5681                     if $cond != FALSE;
5682                   $comment = $spacing = '';
5683                 }
5684             }
5685         }
5686
5687         elsif (/$IF_PATTERN/o)
5688           {
5689             $cond = cond_stack_if ($1, $2, $where);
5690           }
5691         elsif (/$ELSE_PATTERN/o)
5692           {
5693             $cond = cond_stack_else ($1, $2, $where);
5694           }
5695         elsif (/$ENDIF_PATTERN/o)
5696           {
5697             $cond = cond_stack_endif ($1, $2, $where);
5698           }
5699
5700         elsif (/$RULE_PATTERN/o)
5701         {
5702             # Found a rule.
5703             $prev_state = IN_RULE_DEF;
5704
5705             # For now we have to output all definitions of user rules
5706             # and can't diagnose duplicates (see the comment in
5707             # rule_define). So we go on and ignore the return value.
5708             Automake::Rule::define ($1, $amfile, RULE_USER, $cond, $where);
5709
5710             check_variable_expansions ($_, $where);
5711
5712             $output_trailer .= $comment . $spacing;
5713             my $cond = new Automake::Condition @cond_stack;
5714             $output_trailer .= $cond->subst_string;
5715             $output_trailer .= $_;
5716             $comment = $spacing = '';
5717         }
5718         elsif (/$ASSIGNMENT_PATTERN/o)
5719         {
5720             # Found a macro definition.
5721             $prev_state = IN_VAR_DEF;
5722             $last_var_name = $1;
5723             $last_var_type = $2;
5724             $last_var_value = $3;
5725             $last_where = $where->clone;
5726             if ($3 ne '' && substr ($3, -1) eq "\\")
5727             {
5728                 # We preserve the `\' because otherwise the long lines
5729                 # that are generated will be truncated by broken
5730                 # `sed's.
5731                 $last_var_value = $3 . "\n";
5732             }
5733
5734             if (!/\\$/)
5735               {
5736                 Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
5737                                             $last_var_type, $cond,
5738                                             $last_var_value, $comment,
5739                                             $last_where, VAR_ASIS)
5740                   if $cond != FALSE;
5741                 $comment = $spacing = '';
5742               }
5743         }
5744         elsif (/$INCLUDE_PATTERN/o)
5745         {
5746             my $path = $1;
5747
5748             if ($path =~ s/^\$\(top_srcdir\)\///)
5749               {
5750                 push (@include_stack, "\$\(top_srcdir\)/$path");
5751                 # Distribute any included file.
5752
5753                 # Always use the $(top_srcdir) prefix in DIST_COMMON,
5754                 # otherwise OSF make will implicitly copy the included
5755                 # file in the build tree during `make distdir' to satisfy
5756                 # the dependency.
5757                 # (subdircond2.test and subdircond3.test will fail.)
5758                 push_dist_common ("\$\(top_srcdir\)/$path");
5759               }
5760             else
5761               {
5762                 $path =~ s/\$\(srcdir\)\///;
5763                 push (@include_stack, "\$\(srcdir\)/$path");
5764                 # Always use the $(srcdir) prefix in DIST_COMMON,
5765                 # otherwise OSF make will implicitly copy the included
5766                 # file in the build tree during `make distdir' to satisfy
5767                 # the dependency.
5768                 # (subdircond2.test and subdircond3.test will fail.)
5769                 push_dist_common ("\$\(srcdir\)/$path");
5770                 $path = $relative_dir . "/" . $path if $relative_dir ne '.';
5771               }
5772             $where->push_context ("`$path' included from here");
5773             &read_am_file ($path, $where);
5774             $where->pop_context;
5775         }
5776         else
5777         {
5778             # This isn't an error; it is probably a continued rule.
5779             # In fact, this is what we assume.
5780             $prev_state = IN_RULE_DEF;
5781             check_variable_expansions ($_, $where);
5782             $output_trailer .= $comment . $spacing;
5783             my $cond = new Automake::Condition @cond_stack;
5784             $output_trailer .= $cond->subst_string;
5785             $output_trailer .= $_;
5786             $comment = $spacing = '';
5787             error $where, "`#' comment at start of rule is unportable"
5788               if $_ =~ /^\t\s*\#/;
5789         }
5790
5791         $saw_bk = $new_saw_bk;
5792         $_ = $am_file->getline;
5793     }
5794
5795     $output_trailer .= $comment;
5796
5797     error ($where, "trailing backslash on last line")
5798       if $saw_bk;
5799
5800     error ($where, (@cond_stack ? "unterminated conditionals: @cond_stack"
5801                     : "too many conditionals closed in include file"))
5802       if "@saved_cond_stack" ne "@cond_stack";
5803 }
5804
5805
5806 # define_standard_variables ()
5807 # ----------------------------
5808 # A helper for read_main_am_file which initializes configure variables
5809 # and variables from header-vars.am.
5810 sub define_standard_variables
5811 {
5812   my $saved_output_vars = $output_vars;
5813   my ($comments, undef, $rules) =
5814     file_contents_internal (1, "$libdir/am/header-vars.am",
5815                             new Automake::Location);
5816
5817   foreach my $var (sort keys %configure_vars)
5818     {
5819       &define_configure_variable ($var);
5820     }
5821
5822   $output_vars .= $comments . $rules;
5823 }
5824
5825 # Read main am file.
5826 sub read_main_am_file
5827 {
5828     my ($amfile) = @_;
5829
5830     # This supports the strange variable tricks we are about to play.
5831     prog_error (macros_dump () . "variable defined before read_main_am_file")
5832       if (scalar (variables) > 0);
5833
5834     # Generate copyright header for generated Makefile.in.
5835     # We do discard the output of predefined variables, handled below.
5836     $output_vars = ("# $in_file_name generated by automake "
5837                    . $VERSION . " from $am_file_name.\n");
5838     $output_vars .= '# ' . subst ('configure_input') . "\n";
5839     $output_vars .= $gen_copyright;
5840
5841     # We want to predefine as many variables as possible.  This lets
5842     # the user set them with `+=' in Makefile.am.
5843     &define_standard_variables;
5844
5845     # Read user file, which might override some of our values.
5846     &read_am_file ($amfile, new Automake::Location);
5847 }
5848
5849
5850
5851 ################################################################
5852
5853 # $FLATTENED
5854 # &flatten ($STRING)
5855 # ------------------
5856 # Flatten the $STRING and return the result.
5857 sub flatten
5858 {
5859   $_ = shift;
5860
5861   s/\\\n//somg;
5862   s/\s+/ /g;
5863   s/^ //;
5864   s/ $//;
5865
5866   return $_;
5867 }
5868
5869
5870 # @PARAGRAPHS
5871 # &make_paragraphs ($MAKEFILE, [%TRANSFORM])
5872 # ------------------------------------------
5873 # Load a $MAKEFILE, apply the %TRANSFORM, and return it as a list of
5874 # paragraphs.
5875 sub make_paragraphs ($%)
5876 {
5877   my ($file, %transform) = @_;
5878
5879   # Complete %transform with global options and make it a Perl $command.
5880   # Note that %transform goes last, so it overrides global options.
5881   my $command =
5882     "s/$IGNORE_PATTERN//gm;"
5883     . transform ('CYGNUS'      => !! option 'cygnus',
5884                  'MAINTAINER-MODE'
5885                  => $seen_maint_mode ? subst ('MAINTAINER_MODE_TRUE') : '',
5886
5887                  'BZIP2'       => !! option 'dist-bzip2',
5888                  'COMPRESS'    => !! option 'dist-tarZ',
5889                  'GZIP'        =>  ! option 'no-dist-gzip',
5890                  'SHAR'        => !! option 'dist-shar',
5891                  'ZIP'         => !! option 'dist-zip',
5892
5893                  'INSTALL-INFO' =>  ! option 'no-installinfo',
5894                  'INSTALL-MAN'  =>  ! option 'no-installman',
5895                  'CK-NEWS'      => !! option 'check-news',
5896
5897                  'SUBDIRS'      => !! var ('SUBDIRS'),
5898                  'TOPDIR'       => backname ($relative_dir),
5899                  'TOPDIR_P'     => $relative_dir eq '.',
5900
5901                  'BUILD'    => $seen_canonical == AC_CANONICAL_SYSTEM,
5902                  'HOST'     => $seen_canonical,
5903                  'TARGET'   => $seen_canonical == AC_CANONICAL_SYSTEM,
5904
5905                  'LIBTOOL'      => !! var ('LIBTOOL'),
5906                  'NONLIBTOOL'   => 1,
5907                  'FIRST'        => ! $transformed_files{$file},
5908                  %transform)
5909     # We don't need more than two consecutive new-lines.
5910     . 's/\n{3,}/\n\n/g';
5911
5912   $transformed_files{$file} = 1;
5913
5914   # Swallow the file and apply the COMMAND.
5915   my $fc_file = new Automake::XFile "< $file";
5916   # Looks stupid?
5917   verb "reading $file";
5918   my $saved_dollar_slash = $/;
5919   undef $/;
5920   $_ = $fc_file->getline;
5921   $/ = $saved_dollar_slash;
5922   eval $command;
5923   $fc_file->close;
5924   my $content = $_;
5925
5926   # Split at unescaped new lines.
5927   my @lines = split (/(?<!\\)\n/, $content);
5928   my @res;
5929
5930   while (defined ($_ = shift @lines))
5931     {
5932       my $paragraph = "$_";
5933       # If we are a rule, eat as long as we start with a tab.
5934       if (/$RULE_PATTERN/smo)
5935         {
5936           while (defined ($_ = shift @lines) && $_ =~ /^\t/)
5937             {
5938               $paragraph .= "\n$_";
5939             }
5940           unshift (@lines, $_);
5941         }
5942
5943       # If we are a comments, eat as much comments as you can.
5944       elsif (/$COMMENT_PATTERN/smo)
5945         {
5946           while (defined ($_ = shift @lines)
5947                  && $_ =~ /$COMMENT_PATTERN/smo)
5948             {
5949               $paragraph .= "\n$_";
5950             }
5951           unshift (@lines, $_);
5952         }
5953
5954       push @res, $paragraph;
5955       $paragraph = '';
5956     }
5957
5958   return @res;
5959 }
5960
5961
5962
5963 # ($COMMENT, $VARIABLES, $RULES)
5964 # &file_contents_internal ($IS_AM, $FILE, $WHERE, [%TRANSFORM])
5965 # -------------------------------------------------------------
5966 # Return contents of a file from $libdir/am, automatically skipping
5967 # macros or rules which are already known. $IS_AM iff the caller is
5968 # reading an Automake file (as opposed to the user's Makefile.am).
5969 sub file_contents_internal ($$$%)
5970 {
5971     my ($is_am, $file, $where, %transform) = @_;
5972
5973     $where->set ($file);
5974
5975     my $result_vars = '';
5976     my $result_rules = '';
5977     my $comment = '';
5978     my $spacing = '';
5979
5980     # The following flags are used to track rules spanning across
5981     # multiple paragraphs.
5982     my $is_rule = 0;            # 1 if we are processing a rule.
5983     my $discard_rule = 0;       # 1 if the current rule should not be output.
5984
5985     # We save the conditional stack on entry, and then check to make
5986     # sure it is the same on exit.  This lets us conditionally include
5987     # other files.
5988     my @saved_cond_stack = @cond_stack;
5989     my $cond = new Automake::Condition (@cond_stack);
5990
5991     foreach (make_paragraphs ($file, %transform))
5992     {
5993         # FIXME: no line number available.
5994         $where->set ($file);
5995
5996         # Sanity checks.
5997         error $where, "blank line following trailing backslash:\n$_"
5998           if /\\$/;
5999         error $where, "comment following trailing backslash:\n$_"
6000           if /\\#/;
6001
6002         if (/^$/)
6003         {
6004             $is_rule = 0;
6005             # Stick empty line before the incoming macro or rule.
6006             $spacing = "\n";
6007         }
6008         elsif (/$COMMENT_PATTERN/mso)
6009         {
6010             $is_rule = 0;
6011             # Stick comments before the incoming macro or rule.
6012             $comment = "$_\n";
6013         }
6014
6015         # Handle inclusion of other files.
6016         elsif (/$INCLUDE_PATTERN/o)
6017         {
6018             if ($cond != FALSE)
6019               {
6020                 my $file = ($is_am ? "$libdir/am/" : '') . $1;
6021                 $where->push_context ("`$file' included from here");
6022                 # N-ary `.=' fails.
6023                 my ($com, $vars, $rules)
6024                   = file_contents_internal ($is_am, $file, $where, %transform);
6025                 $where->pop_context;
6026                 $comment .= $com;
6027                 $result_vars .= $vars;
6028                 $result_rules .= $rules;
6029               }
6030         }
6031
6032         # Handling the conditionals.
6033         elsif (/$IF_PATTERN/o)
6034           {
6035             $cond = cond_stack_if ($1, $2, $file);
6036           }
6037         elsif (/$ELSE_PATTERN/o)
6038           {
6039             $cond = cond_stack_else ($1, $2, $file);
6040           }
6041         elsif (/$ENDIF_PATTERN/o)
6042           {
6043             $cond = cond_stack_endif ($1, $2, $file);
6044           }
6045
6046         # Handling rules.
6047         elsif (/$RULE_PATTERN/mso)
6048         {
6049           $is_rule = 1;
6050           $discard_rule = 0;
6051           # Separate relationship from optional actions: the first
6052           # `new-line tab" not preceded by backslash (continuation
6053           # line).
6054           my $paragraph = $_;
6055           /^(.*?)(?:(?<!\\)\n(\t.*))?$/s;
6056           my ($relationship, $actions) = ($1, $2 || '');
6057
6058           # Separate targets from dependencies: the first colon.
6059           $relationship =~ /^([^:]+\S+) *: *(.*)$/som;
6060           my ($targets, $dependencies) = ($1, $2);
6061           # Remove the escaped new lines.
6062           # I don't know why, but I have to use a tmp $flat_deps.
6063           my $flat_deps = &flatten ($dependencies);
6064           my @deps = split (' ', $flat_deps);
6065
6066           foreach (split (' ' , $targets))
6067             {
6068               # FIXME: 1. We are not robust to people defining several targets
6069               # at once, only some of them being in %dependencies.  The
6070               # actions from the targets in %dependencies are usually generated
6071               # from the content of %actions, but if some targets in $targets
6072               # are not in %dependencies the ELSE branch will output
6073               # a rule for all $targets (i.e. the targets which are both
6074               # in %dependencies and $targets will have two rules).
6075
6076               # FIXME: 2. The logic here is not able to output a
6077               # multi-paragraph rule several time (e.g. for each condition
6078               # it is defined for) because it only knows the first paragraph.
6079
6080               # FIXME: 3. We are not robust to people defining a subset
6081               # of a previously defined "multiple-target" rule.  E.g.
6082               # `foo:' after `foo bar:'.
6083
6084               # Output only if not in FALSE.
6085               if (defined $dependencies{$_} && $cond != FALSE)
6086                 {
6087                   &depend ($_, @deps);
6088                   if ($actions{$_})
6089                     {
6090                       $actions{$_} .= "\n$actions" if $actions;
6091                     }
6092                   else
6093                     {
6094                       $actions{$_} = $actions;
6095                     }
6096                 }
6097               else
6098                 {
6099                   # Free-lance dependency.  Output the rule for all the
6100                   # targets instead of one by one.
6101                   my @undefined_conds =
6102                     Automake::Rule::define ($targets, $file,
6103                                             $is_am ? RULE_AUTOMAKE : RULE_USER,
6104                                             $cond, $where);
6105                   for my $undefined_cond (@undefined_conds)
6106                     {
6107                       my $condparagraph = $paragraph;
6108                       $condparagraph =~ s/^/$undefined_cond->subst_string/gme;
6109                       $result_rules .= "$spacing$comment$condparagraph\n";
6110                     }
6111                   if (scalar @undefined_conds == 0)
6112                     {
6113                       # Remember to discard next paragraphs
6114                       # if they belong to this rule.
6115                       # (but see also FIXME: #2 above.)
6116                       $discard_rule = 1;
6117                     }
6118                   $comment = $spacing = '';
6119                   last;
6120                 }
6121             }
6122         }
6123
6124         elsif (/$ASSIGNMENT_PATTERN/mso)
6125         {
6126             my ($var, $type, $val) = ($1, $2, $3);
6127             error $where, "variable `$var' with trailing backslash"
6128               if /\\$/;
6129
6130             $is_rule = 0;
6131
6132             Automake::Variable::define ($var,
6133                                         $is_am ? VAR_AUTOMAKE : VAR_MAKEFILE,
6134                                         $type, $cond, $val, $comment, $where,
6135                                         VAR_ASIS)
6136               if $cond != FALSE;
6137
6138             $comment = $spacing = '';
6139         }
6140         else
6141         {
6142             # This isn't an error; it is probably some tokens which
6143             # configure is supposed to replace, such as `@SET-MAKE@',
6144             # or some part of a rule cut by an if/endif.
6145             if (! $cond->false && ! ($is_rule && $discard_rule))
6146               {
6147                 s/^/$cond->subst_string/gme;
6148                 $result_rules .= "$spacing$comment$_\n";
6149               }
6150             $comment = $spacing = '';
6151         }
6152     }
6153
6154     error ($where, @cond_stack ?
6155            "unterminated conditionals: @cond_stack" :
6156            "too many conditionals closed in include file")
6157       if "@saved_cond_stack" ne "@cond_stack";
6158
6159     return ($comment, $result_vars, $result_rules);
6160 }
6161
6162
6163 # $CONTENTS
6164 # &file_contents ($BASENAME, $WHERE, [%TRANSFORM])
6165 # ------------------------------------------------
6166 # Return contents of a file from $libdir/am, automatically skipping
6167 # macros or rules which are already known.
6168 sub file_contents ($$%)
6169 {
6170     my ($basename, $where, %transform) = @_;
6171     my ($comments, $variables, $rules) =
6172       file_contents_internal (1, "$libdir/am/$basename.am", $where,
6173                               %transform);
6174     return "$comments$variables$rules";
6175 }
6176
6177
6178 # $REGEXP
6179 # &transform (%PAIRS)
6180 # -------------------
6181 # For each ($TOKEN, $VAL) in %PAIRS produce a replacement expression
6182 # suitable for file_contents which:
6183 #   - replaces %$TOKEN% with $VAL,
6184 #   - enables/disables ?$TOKEN? and ?!$TOKEN?,
6185 #   - replaces %?$TOKEN% with TRUE or FALSE.
6186 sub transform (%)
6187 {
6188   my (%pairs) = @_;
6189   my $result = '';
6190
6191   while (my ($token, $val) = each %pairs)
6192     {
6193       $result .= "s/\Q%$token%\E/\Q$val\E/gm;";
6194       if ($val)
6195         {
6196           $result .= "s/\Q?$token?\E//gm;s/^.*\Q?!$token?\E.*\\n//gm;";
6197           $result .= "s/\Q%?$token%\E/TRUE/gm;";
6198         }
6199       else
6200         {
6201           $result .= "s/\Q?!$token?\E//gm;s/^.*\Q?$token?\E.*\\n//gm;";
6202           $result .= "s/\Q%?$token%\E/FALSE/gm;";
6203         }
6204     }
6205
6206   return $result;
6207 }
6208
6209
6210 # &append_exeext ($MACRO)
6211 # -----------------------
6212 # Macro is an Automake magic macro which primary is PROGRAMS, e.g.
6213 # bin_PROGRAMS.  Make sure these programs have $(EXEEXT) appended.
6214 sub append_exeext ($)
6215 {
6216   my ($macro) = @_;
6217
6218   prog_error "append_exeext ($macro)"
6219     unless $macro =~ /_PROGRAMS$/;
6220
6221   transform_variable_recursively
6222     ($macro, $macro, 'am__EXEEXT', 0, INTERNAL,
6223      sub {
6224        my ($subvar, $val, $cond, $full_cond) = @_;
6225        # Append $(EXEEXT) unless the user did it already, or it's a
6226        # @substitution@.
6227        $val .= '$(EXEEXT)' unless $val =~ /(?:\$\(EXEEXT\)$|^[@]\w+[@]$)/;
6228        return $val;
6229      });
6230 }
6231
6232
6233 # @PREFIX
6234 # &am_primary_prefixes ($PRIMARY, $CAN_DIST, @PREFIXES)
6235 # -----------------------------------------------------
6236 # Find all variable prefixes that are used for install directories.  A
6237 # prefix `zar' qualifies iff:
6238 #
6239 # * `zardir' is a variable.
6240 # * `zar_PRIMARY' is a variable.
6241 #
6242 # As a side effect, it looks for misspellings.  It is an error to have
6243 # a variable ending in a "reserved" suffix whose prefix is unknown, e.g.
6244 # "bin_PROGRAMS".  However, unusual prefixes are allowed if a variable
6245 # of the same name (with "dir" appended) exists.  For instance, if the
6246 # variable "zardir" is defined, then "zar_PROGRAMS" becomes valid.
6247 # This is to provide a little extra flexibility in those cases which
6248 # need it.
6249 sub am_primary_prefixes ($$@)
6250 {
6251   my ($primary, $can_dist, @prefixes) = @_;
6252
6253   local $_;
6254   my %valid = map { $_ => 0 } @prefixes;
6255   $valid{'EXTRA'} = 0;
6256   foreach my $var (variables)
6257     {
6258       # Automake is allowed to define variables that look like primaries
6259       # but which aren't.  E.g. INSTALL_sh_DATA.
6260       # Autoconf can also define variables like INSTALL_DATA, so
6261       # ignore all configure variables (at least those which are not
6262       # redefined in Makefile.am).
6263       # FIXME: We should make sure that these variables are not
6264       # conditionally defined (or else adjust the condition below).
6265       my $def = $var->def (TRUE);
6266       next if $def && $def->owner != VAR_MAKEFILE;
6267
6268       my $varname = $var->name;
6269
6270       if ($varname =~ /^(nobase_)?(dist_|nodist_)?(.*)_$primary$/)
6271         {
6272           my ($base, $dist, $X) = ($1 || '', $2 || '', $3 || '');
6273           if ($dist ne '' && ! $can_dist)
6274             {
6275               err_var ($var,
6276                        "invalid variable `$varname': `dist' is forbidden");
6277             }
6278           # Standard directories must be explicitly allowed.
6279           elsif (! defined $valid{$X} && exists $standard_prefix{$X})
6280             {
6281               err_var ($var,
6282                        "`${X}dir' is not a legitimate directory " .
6283                        "for `$primary'");
6284             }
6285           # A not explicitly valid directory is allowed if Xdir is defined.
6286           elsif (! defined $valid{$X} &&
6287                  $var->requires_variables ("`$varname' is used", "${X}dir"))
6288             {
6289               # Nothing to do.  Any error message has been output
6290               # by $var->requires_variables.
6291             }
6292           else
6293             {
6294               # Ensure all extended prefixes are actually used.
6295               $valid{"$base$dist$X"} = 1;
6296             }
6297         }
6298     }
6299
6300   # Return only those which are actually defined.
6301   return sort grep { var ($_ . '_' . $primary) } keys %valid;
6302 }
6303
6304
6305 # Handle `where_HOW' variable magic.  Does all lookups, generates
6306 # install code, and possibly generates code to define the primary
6307 # variable.  The first argument is the name of the .am file to munge,
6308 # the second argument is the primary variable (e.g. HEADERS), and all
6309 # subsequent arguments are possible installation locations.
6310 #
6311 # Returns list of [$location, $value] pairs, where
6312 # $value's are the values in all where_HOW variable, and $location
6313 # there associated location (the place here their parent variables were
6314 # defined).
6315 #
6316 # FIXME: this should be rewritten to be cleaner.  It should be broken
6317 # up into multiple functions.
6318 #
6319 # Usage is: am_install_var (OPTION..., file, HOW, where...)
6320 sub am_install_var
6321 {
6322   my (@args) = @_;
6323
6324   my $do_require = 1;
6325   my $can_dist = 0;
6326   my $default_dist = 0;
6327   while (@args)
6328     {
6329       if ($args[0] eq '-noextra')
6330         {
6331           $do_require = 0;
6332         }
6333       elsif ($args[0] eq '-candist')
6334         {
6335           $can_dist = 1;
6336         }
6337       elsif ($args[0] eq '-defaultdist')
6338         {
6339           $default_dist = 1;
6340           $can_dist = 1;
6341         }
6342       elsif ($args[0] !~ /^-/)
6343         {
6344           last;
6345         }
6346       shift (@args);
6347     }
6348
6349   my ($file, $primary, @prefix) = @args;
6350
6351   # Now that configure substitutions are allowed in where_HOW
6352   # variables, it is an error to actually define the primary.  We
6353   # allow `JAVA', as it is customarily used to mean the Java
6354   # interpreter.  This is but one of several Java hacks.  Similarly,
6355   # `PYTHON' is customarily used to mean the Python interpreter.
6356   reject_var $primary, "`$primary' is an anachronism"
6357     unless $primary eq 'JAVA' || $primary eq 'PYTHON';
6358
6359   # Get the prefixes which are valid and actually used.
6360   @prefix = am_primary_prefixes ($primary, $can_dist, @prefix);
6361
6362   # If a primary includes a configure substitution, then the EXTRA_
6363   # form is required.  Otherwise we can't properly do our job.
6364   my $require_extra;
6365
6366   my @used = ();
6367   my @result = ();
6368
6369   foreach my $X (@prefix)
6370     {
6371       my $nodir_name = $X;
6372       my $one_name = $X . '_' . $primary;
6373       my $one_var = var $one_name;
6374
6375       my $strip_subdir = 1;
6376       # If subdir prefix should be preserved, do so.
6377       if ($nodir_name =~ /^nobase_/)
6378         {
6379           $strip_subdir = 0;
6380           $nodir_name =~ s/^nobase_//;
6381         }
6382
6383       # If files should be distributed, do so.
6384       my $dist_p = 0;
6385       if ($can_dist)
6386         {
6387           $dist_p = (($default_dist && $nodir_name !~ /^nodist_/)
6388                      || (! $default_dist && $nodir_name =~ /^dist_/));
6389           $nodir_name =~ s/^(dist|nodist)_//;
6390         }
6391
6392
6393       # Use the location of the currently processed variable.
6394       # We are not processing a particular condition, so pick the first
6395       # available.
6396       my $tmpcond = $one_var->conditions->one_cond;
6397       my $where = $one_var->rdef ($tmpcond)->location->clone;
6398
6399       # Append actual contents of where_PRIMARY variable to
6400       # @result, skipping @substitutions@.
6401       foreach my $locvals ($one_var->value_as_list_recursive (location => 1))
6402         {
6403           my ($loc, $value) = @$locvals;
6404           # Skip configure substitutions.
6405           if ($value =~ /^\@.*\@$/)
6406             {
6407               if ($nodir_name eq 'EXTRA')
6408                 {
6409                   error ($where,
6410                          "`$one_name' contains configure substitution, "
6411                          . "but shouldn't");
6412                 }
6413               # Check here to make sure variables defined in
6414               # configure.ac do not imply that EXTRA_PRIMARY
6415               # must be defined.
6416               elsif (! defined $configure_vars{$one_name})
6417                 {
6418                   $require_extra = $one_name
6419                     if $do_require;
6420                 }
6421             }
6422           else
6423             {
6424               push (@result, $locvals);
6425             }
6426         }
6427       # A blatant hack: we rewrite each _PROGRAMS primary to include
6428       # EXEEXT.
6429       append_exeext ($one_name)
6430         if $primary eq 'PROGRAMS';
6431       # "EXTRA" shouldn't be used when generating clean targets,
6432       # all, or install targets.  We used to warn if EXTRA_FOO was
6433       # defined uselessly, but this was annoying.
6434       next
6435         if $nodir_name eq 'EXTRA';
6436
6437       if ($nodir_name eq 'check')
6438         {
6439           push (@check, '$(' . $one_name . ')');
6440         }
6441       else
6442         {
6443           push (@used, '$(' . $one_name . ')');
6444         }
6445
6446       # Is this to be installed?
6447       my $install_p = $nodir_name ne 'noinst' && $nodir_name ne 'check';
6448
6449       # If so, with install-exec? (or install-data?).
6450       my $exec_p = ($nodir_name =~ /$EXEC_DIR_PATTERN/o);
6451
6452       my $check_options_p = $install_p && !! option 'std-options';
6453
6454       # Use the location of the currently processed variable as context.
6455       $where->push_context ("while processing `$one_name'");
6456
6457       # The variable containing all file to distribute.
6458       my $distvar = "\$($one_name)";
6459       $distvar = shadow_unconditionally ($one_name, $where)
6460         if ($dist_p && $one_var->has_conditional_contents);
6461
6462       # Singular form of $PRIMARY.
6463       (my $one_primary = $primary) =~ s/S$//;
6464       $output_rules .= &file_contents ($file, $where,
6465                                        PRIMARY     => $primary,
6466                                        ONE_PRIMARY => $one_primary,
6467                                        DIR         => $X,
6468                                        NDIR        => $nodir_name,
6469                                        BASE        => $strip_subdir,
6470
6471                                        EXEC      => $exec_p,
6472                                        INSTALL   => $install_p,
6473                                        DIST      => $dist_p,
6474                                        DISTVAR   => $distvar,
6475                                        'CK-OPTS' => $check_options_p);
6476     }
6477
6478   # The JAVA variable is used as the name of the Java interpreter.
6479   # The PYTHON variable is used as the name of the Python interpreter.
6480   if (@used && $primary ne 'JAVA' && $primary ne 'PYTHON')
6481     {
6482       # Define it.
6483       define_pretty_variable ($primary, TRUE, INTERNAL, @used);
6484       $output_vars .= "\n";
6485     }
6486
6487   err_var ($require_extra,
6488            "`$require_extra' contains configure substitution,\n"
6489            . "but `EXTRA_$primary' not defined")
6490     if ($require_extra && ! var ('EXTRA_' . $primary));
6491
6492   # Push here because PRIMARY might be configure time determined.
6493   push (@all, '$(' . $primary . ')')
6494     if @used && $primary ne 'JAVA' && $primary ne 'PYTHON';
6495
6496   # Make the result unique.  This lets the user use conditionals in
6497   # a natural way, but still lets us program lazily -- we don't have
6498   # to worry about handling a particular object more than once.
6499   # We will keep only one location per object.
6500   my %result = ();
6501   for my $pair (@result)
6502     {
6503       my ($loc, $val) = @$pair;
6504       $result{$val} = $loc;
6505     }
6506   my @l = sort keys %result;
6507   return map { [$result{$_}->clone, $_] } @l;
6508 }
6509
6510
6511 ################################################################
6512
6513 # Each key in this hash is the name of a directory holding a
6514 # Makefile.in.  These variables are local to `is_make_dir'.
6515 my %make_dirs = ();
6516 my $make_dirs_set = 0;
6517
6518 sub is_make_dir
6519 {
6520     my ($dir) = @_;
6521     if (! $make_dirs_set)
6522     {
6523         foreach my $iter (@configure_input_files)
6524         {
6525             $make_dirs{dirname ($iter)} = 1;
6526         }
6527         # We also want to notice Makefile.in's.
6528         foreach my $iter (@other_input_files)
6529         {
6530             if ($iter =~ /Makefile\.in$/)
6531             {
6532                 $make_dirs{dirname ($iter)} = 1;
6533             }
6534         }
6535         $make_dirs_set = 1;
6536     }
6537     return defined $make_dirs{$dir};
6538 }
6539
6540 ################################################################
6541
6542 # This variable is local to the "require file" set of functions.
6543 my @require_file_paths = ();
6544
6545
6546 # &maybe_push_required_file ($DIR, $FILE, $FULLFILE)
6547 # --------------------------------------------------
6548 # See if we want to push this file onto dist_common.  This function
6549 # encodes the rules for deciding when to do so.
6550 sub maybe_push_required_file
6551 {
6552   my ($dir, $file, $fullfile) = @_;
6553
6554   if ($dir eq $relative_dir)
6555     {
6556       push_dist_common ($file);
6557       return 1;
6558     }
6559   elsif ($relative_dir eq '.' && ! &is_make_dir ($dir))
6560     {
6561       # If we are doing the topmost directory, and the file is in a
6562       # subdir which does not have a Makefile, then we distribute it
6563       # here.
6564
6565       # If a required file is above the source tree, it is important
6566       # to prefix it with `$(srcdir)' so that no VPATH search is
6567       # performed.  Otherwise problems occur with Make implementations
6568       # that rewrite and simplify rules whose dependencies are found in a
6569       # VPATH location.  Here is an example with OSF1/Tru64 Make.
6570       #
6571       #   % cat Makefile
6572       #   VPATH = sub
6573       #   distdir: ../a
6574       #           echo ../a
6575       #   % ls
6576       #   Makefile a
6577       #   % make
6578       #   echo a
6579       #   a
6580       #
6581       # Dependency `../a' was found in `sub/../a', but this make
6582       # implementation simplified it as `a'.  (Note that the sub/
6583       # directory does not even exist.)
6584       #
6585       # This kind of VPATH rewriting seems hard to cancel.  The
6586       # distdir.am hack against VPATH rewriting works only when no
6587       # simplification is done, i.e., for dependencies which are in
6588       # subdirectories, not in enclosing directories.  Hence, in
6589       # the latter case we use a full path to make sure no VPATH
6590       # search occurs.
6591       $fullfile = '$(srcdir)/' . $fullfile
6592         if $dir =~ m,^\.\.(?:$|/),;
6593
6594       push_dist_common ($fullfile);
6595       return 1;
6596     }
6597   return 0;
6598 }
6599
6600
6601 # &require_file_internal ($WHERE, $MYSTRICT, @FILES)
6602 # --------------------------------------------------
6603 # Verify that the file must exist in the current directory.
6604 # $MYSTRICT is the strictness level at which this file becomes required.
6605 #
6606 # Must set require_file_paths before calling this function.
6607 # require_file_paths is set to hold a single directory (the one in
6608 # which the first file was found) before return.
6609 sub require_file_internal ($$@)
6610 {
6611     my ($where, $mystrict, @files) = @_;
6612
6613     foreach my $file (@files)
6614     {
6615         my $fullfile;
6616         my $errdir;
6617         my $errfile;
6618         my $save_dir;
6619
6620         my $found_it = 0;
6621         my $dangling_sym = 0;
6622         foreach my $dir (@require_file_paths)
6623         {
6624             $fullfile = $dir . "/" . $file;
6625             $errdir = $dir unless $errdir;
6626
6627             # Use different name for "error filename".  Otherwise on
6628             # an error the bad file will be reported as e.g.
6629             # `../../install-sh' when using the default
6630             # config_aux_path.
6631             $errfile = $errdir . '/' . $file;
6632
6633             if (-l $fullfile && ! -f $fullfile)
6634             {
6635                 $dangling_sym = 1;
6636                 last;
6637             }
6638             elsif (-f $fullfile)
6639             {
6640                 $found_it = 1;
6641                 maybe_push_required_file ($dir, $file, $fullfile);
6642                 $save_dir = $dir;
6643                 last;
6644             }
6645         }
6646
6647         # `--force-missing' only has an effect if `--add-missing' is
6648         # specified.
6649         if ($found_it && (! $add_missing || ! $force_missing))
6650         {
6651             # Prune the path list.
6652             @require_file_paths = $save_dir;
6653         }
6654         else
6655         {
6656             # If we've already looked for it, we're done.  You might
6657             # wonder why we don't do this before searching for the
6658             # file.  If we do that, then something like
6659             # AC_OUTPUT(subdir/foo foo) will fail to put foo.in into
6660             # DIST_COMMON.
6661             if (! $found_it)
6662             {
6663                 next if defined $require_file_found{$fullfile};
6664                 $require_file_found{$fullfile} = 1;
6665             }
6666
6667             if ($strictness >= $mystrict)
6668             {
6669                 if ($dangling_sym && $add_missing)
6670                 {
6671                     unlink ($fullfile);
6672                 }
6673
6674                 my $trailer = '';
6675                 my $suppress = 0;
6676
6677                 # Only install missing files according to our desired
6678                 # strictness level.
6679                 my $message = "required file `$errfile' not found";
6680                 if ($add_missing)
6681                 {
6682                     if (-f ("$libdir/$file"))
6683                     {
6684                         $suppress = 1;
6685
6686                         # Install the missing file.  Symlink if we
6687                         # can, copy if we must.  Note: delete the file
6688                         # first, in case it is a dangling symlink.
6689                         $message = "installing `$errfile'";
6690                         # Windows Perl will hang if we try to delete a
6691                         # file that doesn't exist.
6692                         unlink ($errfile) if -f $errfile;
6693                         if ($symlink_exists && ! $copy_missing)
6694                         {
6695                             if (! symlink ("$libdir/$file", $errfile))
6696                             {
6697                                 $suppress = 0;
6698                                 $trailer = "; error while making link: $!";
6699                             }
6700                         }
6701                         elsif (system ('cp', "$libdir/$file", $errfile))
6702                         {
6703                             $suppress = 0;
6704                             $trailer = "\n    error while copying";
6705                         }
6706                     }
6707
6708                     if (! maybe_push_required_file (dirname ($errfile),
6709                                                     $file, $errfile))
6710                     {
6711                         if (! $found_it)
6712                         {
6713                             # We have added the file but could not push it
6714                             # into DIST_COMMON (probably because this is
6715                             # an auxiliary file and we are not processing
6716                             # the top level Makefile). This is unfortunate,
6717                             # since it means we are using a file which is not
6718                             # distributed!
6719
6720                             # Get Automake to be run again: on the second
6721                             # run the file will be found, and pushed into
6722                             # the toplevel DIST_COMMON automatically.
6723                             $automake_needs_to_reprocess_all_files = 1;
6724                         }
6725                     }
6726
6727                     # Prune the path list.
6728                     @require_file_paths = &dirname ($errfile);
6729                 }
6730
6731                 # If --force-missing was specified, and we have
6732                 # actually found the file, then do nothing.
6733                 next
6734                     if $found_it && $force_missing;
6735
6736                 # If we couldn' install the file, but it is a target in
6737                 # the Makefile, don't print anything.  This allows files
6738                 # like README, AUTHORS, or THANKS to be generated.
6739                 next
6740                   if !$suppress && rule $file;
6741
6742                 msg ($suppress ? 'note' : 'error', $where, "$message$trailer");
6743             }
6744         }
6745     }
6746 }
6747
6748 # &require_file ($WHERE, $MYSTRICT, @FILES)
6749 # -----------------------------------------
6750 sub require_file ($$@)
6751 {
6752     my ($where, $mystrict, @files) = @_;
6753     @require_file_paths = $relative_dir;
6754     require_file_internal ($where, $mystrict, @files);
6755 }
6756
6757 # &require_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
6758 # -----------------------------------------------------------
6759 sub require_file_with_macro ($$$@)
6760 {
6761     my ($cond, $macro, $mystrict, @files) = @_;
6762     $macro = rvar ($macro) unless ref $macro;
6763     require_file ($macro->rdef ($cond)->location, $mystrict, @files);
6764 }
6765
6766
6767 # &require_conf_file ($WHERE, $MYSTRICT, @FILES)
6768 # ----------------------------------------------
6769 # Looks in configuration path, as specified by AC_CONFIG_AUX_DIR.
6770 sub require_conf_file ($$@)
6771 {
6772     my ($where, $mystrict, @files) = @_;
6773     @require_file_paths = @config_aux_path;
6774     require_file_internal ($where, $mystrict, @files);
6775     my $dir = $require_file_paths[0];
6776     @config_aux_path = @require_file_paths;
6777      # Avoid unsightly '/.'s.
6778     $config_aux_dir = '$(top_srcdir)' . ($dir eq '.' ? "" : "/$dir");
6779 }
6780
6781
6782 # &require_conf_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
6783 # ----------------------------------------------------------------
6784 sub require_conf_file_with_macro ($$$@)
6785 {
6786     my ($cond, $macro, $mystrict, @files) = @_;
6787     require_conf_file (rvar ($macro)->rdef ($cond)->location,
6788                        $mystrict, @files);
6789 }
6790
6791 ################################################################
6792
6793 # &require_build_directory ($DIRECTORY)
6794 # ------------------------------------
6795 # Emit rules to create $DIRECTORY if needed, and return
6796 # the file that any target requiring this directory should be made
6797 # dependent upon.
6798 sub require_build_directory ($)
6799 {
6800   my $directory = shift;
6801   my $dirstamp = "$directory/\$(am__dirstamp)";
6802
6803   # Don't emit the rule twice.
6804   if (! defined $directory_map{$directory})
6805     {
6806       $directory_map{$directory} = 1;
6807
6808       # Set a variable for the dirstamp basename.
6809       define_pretty_variable ('am__dirstamp', TRUE, INTERNAL,
6810                               '$(am__leading_dot)dirstamp');
6811
6812       # Directory must be removed by `make distclean'.
6813       $clean_files{$dirstamp} = DIST_CLEAN;
6814
6815       $output_rules .= ("$dirstamp:\n"
6816                         . "\t\@\$(mkdir_p) $directory\n"
6817                         . "\t\@: > $dirstamp\n");
6818     }
6819
6820   return $dirstamp;
6821 }
6822
6823 # &require_build_directory_maybe ($FILE)
6824 # --------------------------------------
6825 # If $FILE lies in a subdirectory, emit a rule to create this
6826 # directory and return the file that $FILE should be made
6827 # dependent upon.  Otherwise, just return the empty string.
6828 sub require_build_directory_maybe ($)
6829 {
6830     my $file = shift;
6831     my $directory = dirname ($file);
6832
6833     if ($directory ne '.')
6834     {
6835         return require_build_directory ($directory);
6836     }
6837     else
6838     {
6839         return '';
6840     }
6841 }
6842
6843 ################################################################
6844
6845 # Push a list of files onto dist_common.
6846 sub push_dist_common
6847 {
6848   prog_error "push_dist_common run after handle_dist"
6849     if $handle_dist_run;
6850   Automake::Variable::define ('DIST_COMMON', VAR_AUTOMAKE, '+', TRUE, "@_",
6851                               '', INTERNAL, VAR_PRETTY);
6852 }
6853
6854
6855 ################################################################
6856
6857 # generate_makefile ($MAKEFILE_AM, $MAKEFILE_IN)
6858 # ----------------------------------------------
6859 # Generate a Makefile.in given the name of the corresponding Makefile and
6860 # the name of the file output by config.status.
6861 sub generate_makefile ($$)
6862 {
6863   my ($makefile_am, $makefile_in) = @_;
6864
6865   # Reset all the Makefile.am related variables.
6866   initialize_per_input;
6867
6868   # AUTOMAKE_OPTIONS can contains -W flags to disable or enable
6869   # warnings for this file.  So hold any warning issued before
6870   # we have processed AUTOMAKE_OPTIONS.
6871   buffer_messages ('warning');
6872
6873   # Name of input file ("Makefile.am") and output file
6874   # ("Makefile.in").  These have no directory components.
6875   $am_file_name = basename ($makefile_am);
6876   $in_file_name = basename ($makefile_in);
6877
6878   # $OUTPUT is encoded.  If it contains a ":" then the first element
6879   # is the real output file, and all remaining elements are input
6880   # files.  We don't scan or otherwise deal with these input files,
6881   # other than to mark them as dependencies.  See
6882   # &scan_autoconf_files for details.
6883   my ($makefile, @inputs) = split (/:/, $output_files{$makefile_in});
6884
6885   $relative_dir = dirname ($makefile);
6886   $am_relative_dir = dirname ($makefile_am);
6887
6888   read_main_am_file ($makefile_am);
6889   if (handle_options)
6890     {
6891       # Process buffered warnings.
6892       flush_messages;
6893       # Fatal error.  Just return, so we can continue with next file.
6894       return;
6895     }
6896   # Process buffered warnings.
6897   flush_messages;
6898
6899   # There are a few install-related variables that you should not define.
6900   foreach my $var ('PRE_INSTALL', 'POST_INSTALL', 'NORMAL_INSTALL')
6901     {
6902       my $v = var $var;
6903       if ($v)
6904         {
6905           my $def = $v->def (TRUE);
6906           prog_error "$var not defined in condition TRUE"
6907             unless $def;
6908           reject_var $var, "`$var' should not be defined"
6909             if $def->owner != VAR_AUTOMAKE;
6910         }
6911     }
6912
6913   # Catch some obsolete variables.
6914   msg_var ('obsolete', 'INCLUDES',
6915            "`INCLUDES' is the old name for `AM_CPPFLAGS' (or `*_CPPFLAGS')")
6916     if var ('INCLUDES');
6917
6918   # At the toplevel directory, we might need config.guess, config.sub
6919   # or libtool scripts (ltconfig and ltmain.sh).
6920   if ($relative_dir eq '.')
6921     {
6922       # AC_CANONICAL_HOST and AC_CANONICAL_SYSTEM need config.guess and
6923       # config.sub.
6924       require_conf_file ($canonical_location, FOREIGN,
6925                          'config.guess', 'config.sub')
6926         if $seen_canonical;
6927     }
6928
6929   # Must do this after reading .am file.
6930   define_variable ('subdir', $relative_dir, INTERNAL);
6931
6932   # If DIST_SUBDIRS is defined, make sure SUBDIRS is, so that
6933   # recursive rules are enabled.
6934   define_pretty_variable ('SUBDIRS', TRUE, INTERNAL, '')
6935     if var 'DIST_SUBDIRS' && ! var 'SUBDIRS';
6936
6937   # Check first, because we might modify some state.
6938   check_cygnus;
6939   check_gnu_standards;
6940   check_gnits_standards;
6941
6942   handle_configure ($makefile_am, $makefile_in, $makefile, @inputs);
6943   handle_gettext;
6944   handle_libraries;
6945   handle_ltlibraries;
6946   handle_programs;
6947   handle_scripts;
6948
6949   # These must be run after all the sources are scanned.  They
6950   # use variables defined by &handle_libraries, &handle_ltlibraries,
6951   # or &handle_programs.
6952   handle_compile;
6953   handle_languages;
6954   handle_libtool;
6955
6956   # Variables used by distdir.am and tags.am.
6957   define_pretty_variable ('SOURCES', TRUE, INTERNAL, @sources);
6958   if (! option 'no-dist')
6959     {
6960       define_pretty_variable ('DIST_SOURCES', TRUE, INTERNAL, @dist_sources);
6961     }
6962
6963   handle_multilib;
6964   handle_texinfo;
6965   handle_emacs_lisp;
6966   handle_python;
6967   handle_java;
6968   handle_man_pages;
6969   handle_data;
6970   handle_headers;
6971   handle_subdirs;
6972   handle_tags;
6973   handle_minor_options;
6974   handle_tests;
6975
6976   # This must come after most other rules.
6977   handle_dist;
6978
6979   handle_footer;
6980   do_check_merge_target;
6981   handle_all ($makefile);
6982
6983   # FIXME: Gross!
6984   if (var ('lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
6985     {
6986       $output_rules .= "install-binPROGRAMS: install-libLTLIBRARIES\n\n";
6987     }
6988
6989   handle_install;
6990   handle_clean ($makefile);
6991   handle_factored_dependencies;
6992
6993   # Comes last, because all the above procedures may have
6994   # defined or overridden variables.
6995   $output_vars .= output_variables;
6996
6997   check_typos;
6998
6999   if (! -d ($output_directory . '/' . $am_relative_dir))
7000     {
7001       mkdir ($output_directory . '/' . $am_relative_dir, 0755);
7002     }
7003
7004   my ($out_file) = $output_directory . '/' . $makefile_in;
7005
7006   # We make sure that `all:' is the first target.
7007   my $output =
7008     "$output_vars$output_all$output_header$output_rules$output_trailer";
7009
7010   # Decide whether we must update the output file or not.
7011   # We have to update in the following situations.
7012   #  * $force_generation is set.
7013   #  * any of the output dependencies is younger than the output
7014   #  * the contents of the output is different (this can happen
7015   #    if the project has been populated with a file listed in
7016   #    @common_files since the last run).
7017   # Output's dependencies are split in two sets:
7018   #  * dependencies which are also configure dependencies
7019   #    These do not change between each Makefile.am
7020   #  * other dependencies, specific to the Makefile.am being processed
7021   #    (such as the Makefile.am itself, or any Makefile fragment
7022   #    it includes).
7023   my $timestamp = mtime $out_file;
7024   if (! $force_generation
7025       && $configure_deps_greatest_timestamp < $timestamp
7026       && $output_deps_greatest_timestamp < $timestamp
7027       && $output eq contents ($out_file))
7028   {
7029       verb "$out_file unchanged";
7030       # No need to update.
7031       return;
7032     }
7033
7034   if (-e $out_file)
7035     {
7036       unlink ($out_file)
7037         or fatal "cannot remove $out_file: $!\n";
7038     }
7039
7040   my $gm_file = new Automake::XFile "> $out_file";
7041   verb "creating $out_file";
7042   print $gm_file $output;
7043 }
7044
7045 ################################################################
7046
7047
7048
7049
7050 ################################################################
7051
7052 # Print usage information.
7053 sub usage ()
7054 {
7055     print "Usage: $0 [OPTION] ... [Makefile]...
7056
7057 Generate Makefile.in for configure from Makefile.am.
7058
7059 Operation modes:
7060       --help               print this help, then exit
7061       --version            print version number, then exit
7062   -v, --verbose            verbosely list files processed
7063       --no-force           only update Makefile.in's that are out of date
7064   -W, --warnings=CATEGORY  report the warnings falling in CATEGORY
7065
7066 Dependency tracking:
7067   -i, --ignore-deps      disable dependency tracking code
7068       --include-deps     enable dependency tracking code
7069
7070 Flavors:
7071       --cygnus           assume program is part of Cygnus-style tree
7072       --foreign          set strictness to foreign
7073       --gnits            set strictness to gnits
7074       --gnu              set strictness to gnu
7075
7076 Library files:
7077   -a, --add-missing      add missing standard files to package
7078       --libdir=DIR       directory storing library files
7079   -c, --copy             with -a, copy missing files (default is symlink)
7080   -f, --force-missing    force update of standard files
7081
7082 ";
7083     Automake::ChannelDefs::usage;
7084
7085     my ($last, @lcomm);
7086     $last = '';
7087     foreach my $iter (sort ((@common_files, @common_sometimes)))
7088     {
7089         push (@lcomm, $iter) unless $iter eq $last;
7090         $last = $iter;
7091     }
7092
7093     my @four;
7094     print "\nFiles which are automatically distributed, if found:\n";
7095     format USAGE_FORMAT =
7096   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<
7097   $four[0],           $four[1],           $four[2],           $four[3]
7098 .
7099     $~ = "USAGE_FORMAT";
7100
7101     my $cols = 4;
7102     my $rows = int(@lcomm / $cols);
7103     my $rest = @lcomm % $cols;
7104
7105     if ($rest)
7106     {
7107         $rows++;
7108     }
7109     else
7110     {
7111         $rest = $cols;
7112     }
7113
7114     for (my $y = 0; $y < $rows; $y++)
7115     {
7116         @four = ("", "", "", "");
7117         for (my $x = 0; $x < $cols; $x++)
7118         {
7119             last if $y + 1 == $rows && $x == $rest;
7120
7121             my $idx = (($x > $rest)
7122                        ?  ($rows * $rest + ($rows - 1) * ($x - $rest))
7123                        : ($rows * $x));
7124
7125             $idx += $y;
7126             $four[$x] = $lcomm[$idx];
7127         }
7128         write;
7129     }
7130
7131     print "\nReport bugs to <bug-automake\@gnu.org>.\n";
7132
7133     # --help always returns 0 per GNU standards.
7134     exit 0;
7135 }
7136
7137
7138 # &version ()
7139 # -----------
7140 # Print version information
7141 sub version ()
7142 {
7143   print <<EOF;
7144 automake (GNU $PACKAGE) $VERSION
7145 Written by Tom Tromey <tromey\@redhat.com>.
7146
7147 Copyright 2004 Free Software Foundation, Inc.
7148 This is free software; see the source for copying conditions.  There is NO
7149 warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
7150 EOF
7151   # --version always returns 0 per GNU standards.
7152   exit 0;
7153 }
7154
7155 ################################################################
7156
7157 # Parse command line.
7158 sub parse_arguments ()
7159 {
7160   # Start off as gnu.
7161   set_strictness ('gnu');
7162
7163   my $cli_where = new Automake::Location;
7164   my %cli_options =
7165     (
7166      'libdir:s'         => \$libdir,
7167      'gnu'              => sub { set_strictness ('gnu'); },
7168      'gnits'            => sub { set_strictness ('gnits'); },
7169      'cygnus'           => sub { set_global_option ('cygnus', $cli_where); },
7170      'foreign'          => sub { set_strictness ('foreign'); },
7171      'include-deps'     => sub { unset_global_option ('no-dependencies'); },
7172      'i|ignore-deps'    => sub { set_global_option ('no-dependencies',
7173                                                     $cli_where); },
7174      'no-force'         => sub { $force_generation = 0; },
7175      'f|force-missing'  => \$force_missing,
7176      'o|output-dir:s'   => \$output_directory,
7177      'a|add-missing'    => \$add_missing,
7178      'c|copy'           => \$copy_missing,
7179      'v|verbose'        => sub { setup_channel 'verb', silent => 0; },
7180      'W|warnings:s'     => \&parse_warnings,
7181      # These long options (--Werror and --Wno-error) for backward
7182      # compatibility.  Use -Werror and -Wno-error today.
7183      'Werror'           => sub { parse_warnings 'W', 'error'; },
7184      'Wno-error'        => sub { parse_warnings 'W', 'no-error'; },
7185      );
7186   use Getopt::Long;
7187   Getopt::Long::config ("bundling", "pass_through");
7188
7189   # See if --version or --help is used.  We want to process these before
7190   # anything else because the GNU Coding Standards require us to
7191   # `exit 0' after processing these options, and we can't guarantee this
7192   # if we treat other options first.  (Handling other options first
7193   # could produce error diagnostics, and in this condition it is
7194   # confusing if Automake does `exit 0'.)
7195   my %cli_options_1st_pass =
7196     (
7197      'version' => \&version,
7198      'help'    => \&usage,
7199      # Recognize all other options (and their arguments) but do nothing.
7200      map { $_ => sub {} } (keys %cli_options)
7201      );
7202   my @ARGV_backup = @ARGV;
7203   Getopt::Long::GetOptions %cli_options_1st_pass
7204     or exit 1;
7205   @ARGV = @ARGV_backup;
7206
7207   # Now *really* process the options.  This time we know
7208   # that --help and --version are not present.
7209   Getopt::Long::GetOptions %cli_options
7210     or exit 1;
7211
7212   if (defined $output_directory)
7213     {
7214       msg 'obsolete', "`--output-dir' is deprecated\n";
7215     }
7216   else
7217     {
7218       # In the next release we'll remove this entirely.
7219       $output_directory = '.';
7220     }
7221
7222   foreach my $arg (@ARGV)
7223     {
7224       if ($arg =~ /^-./)
7225         {
7226           fatal ("unrecognized option `$arg'\n"
7227                  . "Try `$0 --help' for more information.");
7228         }
7229
7230       # Handle $local:$input syntax.
7231       my ($local, @rest) = split (/:/, $arg);
7232       @rest = ("$local.in",) unless @rest;
7233       my $input = locate_am @rest;
7234       if ($input)
7235         {
7236           push @input_files, $input;
7237           $output_files{$input} = join (':', ($local, @rest));
7238         }
7239       else
7240         {
7241           error "no Automake input file found in `$arg'";
7242         }
7243     }
7244 }
7245
7246 ################################################################
7247
7248 # Parse the WARNINGS environment variable.
7249 parse_WARNINGS;
7250
7251 # Parse command line.
7252 parse_arguments;
7253
7254 $configure_ac = require_configure_ac;
7255
7256 # Do configure.ac scan only once.
7257 scan_autoconf_files;
7258
7259 fatal "no `Makefile.am' found or specified\n"
7260   if ! @input_files;
7261
7262 my $automake_has_run = 0;
7263
7264 do
7265 {
7266   if ($automake_has_run)
7267     {
7268       verb 'processing Makefiles another time to fix them up.';
7269       prog_error 'running more than two times should never be needed.'
7270         if $automake_has_run >= 2;
7271     }
7272   $automake_needs_to_reprocess_all_files = 0;
7273
7274   # Now do all the work on each file.
7275   foreach my $file (@input_files)
7276     {
7277       ($am_file = $file) =~ s/\.in$//;
7278       if (! -f ($am_file . '.am'))
7279         {
7280           error "`$am_file.am' does not exist";
7281         }
7282       else
7283         {
7284           # Any warning setting now local to this Makefile.am.
7285           dup_channel_setup;
7286
7287           generate_makefile ($am_file . '.am', $file);
7288
7289           # Back out any warning setting.
7290           drop_channel_setup;
7291         }
7292     }
7293   ++$automake_has_run;
7294 }
7295 while ($automake_needs_to_reprocess_all_files);
7296
7297 exit $exit_code;
7298
7299
7300 ### Setup "GNU" style for perl-mode and cperl-mode.
7301 ## Local Variables:
7302 ## perl-indent-level: 2
7303 ## perl-continued-statement-offset: 2
7304 ## perl-continued-brace-offset: 0
7305 ## perl-brace-offset: 0
7306 ## perl-brace-imaginary-offset: 0
7307 ## perl-label-offset: -2
7308 ## cperl-indent-level: 2
7309 ## cperl-brace-offset: 0
7310 ## cperl-continued-brace-offset: 0
7311 ## cperl-label-offset: -2
7312 ## cperl-extra-newline-before-brace: t
7313 ## cperl-merge-trailing-else: nil
7314 ## cperl-continued-statement-offset: 2
7315 ## End: