automake.in

   1 #!@PERL@ -w
   2 # -*- perl -*-
   3 # @configure_input@
   4
   5 eval 'case $# in 0) exec @PERL@ -S "$0";; *) exec @PERL@ -S "$0" "$@";; esac'
   6     if 0;
   7
   8 # automake - create Makefile.in from Makefile.am
   9 # Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
  10 # 2003, 2004, 2005, 2006, 2007  Free Software Foundation, Inc.
  11
  12 # This program is free software; you can redistribute it and/or modify
  13 # it under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 3, or (at your option)
  15 # any later version.
  16
  17 # This program is distributed in the hope that it will be useful,
  18 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 # GNU General Public License for more details.
  21
  22 # You should have received a copy of the GNU General Public License
  23 # along with this program; if not, write to the Free Software
  24 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  25 # 02110-1301, USA.
  26
  27 # Originally written by David Mackenzie <djm@gnu.ai.mit.edu>.
  28 # Perl reimplementation by Tom Tromey <tromey@redhat.com>, and
  29 # Alexandre Duret-Lutz <adl@gnu.org>.
  30
  31 package Language;
  32
  33 BEGIN
  34 {
  35   my $perllibdir = $ENV{'perllibdir'} || '@datadir@/@PACKAGE@-@APIVERSION@';
  36   unshift @INC, (split '@PATH_SEPARATOR@', $perllibdir);
  37
  38   # Override SHELL.  This is required on DJGPP so that system() uses
  39   # bash, not COMMAND.COM which doesn't quote arguments properly.
  40   # Other systems aren't expected to use $SHELL when Automake
  41   # runs, but it should be safe to drop the `if DJGPP' guard if
  42   # it turns up other systems need the same thing.  After all,
  43   # if SHELL is used, ./configure's SHELL is always better than
  44   # the user's SHELL (which may be something like tcsh).
  45   $ENV{'SHELL'} = '@SHELL@' if exists $ENV{'DJGPP'};
  46 }
  47
  48 use Automake::Struct;
  49 struct (# Short name of the language (c, f77...).
  50         'name' => "\$",
  51         # Nice name of the language (C, Fortran 77...).
  52         'Name' => "\$",
  53
  54         # List of configure variables which must be defined.
  55         'config_vars' => '@',
  56
  57         'ansi'    => "\$",
  58         # `pure' is `1' or `'.  A `pure' language is one where, if
  59         # all the files in a directory are of that language, then we
  60         # do not require the C compiler or any code to call it.
  61         'pure'   => "\$",
  62
  63         'autodep' => "\$",
  64
  65         # Name of the compiling variable (COMPILE).
  66         'compiler'  => "\$",
  67         # Content of the compiling variable.
  68         'compile'  => "\$",
  69         # Flag to require compilation without linking (-c).
  70         'compile_flag' => "\$",
  71         'extensions' => '@',
  72         # A subroutine to compute a list of possible extensions of
  73         # the product given the input extensions.
  74         # (defaults to a subroutine which returns ('.$(OBJEXT)', '.lo'))
  75         'output_extensions' => "\$",
  76         # A list of flag variables used in 'compile'.
  77         # (defaults to [])
  78         'flags' => "@",
  79
  80         # Any tag to pass to libtool while compiling.
  81         'libtool_tag' => "\$",
  82
  83         # The file to use when generating rules for this language.
  84         # The default is 'depend2'.
  85         'rule_file' => "\$",
  86
  87         # Name of the linking variable (LINK).
  88         'linker' => "\$",
  89         # Content of the linking variable.
  90         'link' => "\$",
  91
  92         # Name of the linker variable (LD).
  93         'lder' => "\$",
  94         # Content of the linker variable ($(CC)).
  95         'ld' => "\$",
  96
  97         # Flag to specify the output file (-o).
  98         'output_flag' => "\$",
  99         '_finish' => "\$",
 100
 101         # This is a subroutine which is called whenever we finally
 102         # determine the context in which a source file will be
 103         # compiled.
 104         '_target_hook' => "\$",
 105
 106         # If TRUE, nodist_ sources will be compiled using specific rules
 107         # (i.e. not inference rules).  The default is FALSE.
 108         'nodist_specific' => "\$");
 109
 110
 111 sub finish ($)
 112 {
 113   my ($self) = @_;
 114   if (defined $self->_finish)
 115     {
 116       &{$self->_finish} ();
 117     }
 118 }
 119
 120 sub target_hook ($$$$%)
 121 {
 122     my ($self) = @_;
 123     if (defined $self->_target_hook)
 124     {
 125         &{$self->_target_hook} (@_);
 126     }
 127 }
 128
 129 package Automake;
 130
 131 use strict;
 132 use Automake::Config;
 133 use Automake::General;
 134 use Automake::XFile;
 135 use Automake::Channels;
 136 use Automake::ChannelDefs;
 137 use Automake::Configure_ac;
 138 use Automake::FileUtils;
 139 use Automake::Location;
 140 use Automake::Condition qw/TRUE FALSE/;
 141 use Automake::DisjConditions;
 142 use Automake::Options;
 143 use Automake::Version;
 144 use Automake::Variable;
 145 use Automake::VarDef;
 146 use Automake::Rule;
 147 use Automake::RuleDef;
 148 use Automake::Wrap 'makefile_wrap';
 149 use File::Basename;
 150 use File::Spec;
 151 use Carp;
 152
 153 ## ----------- ##
 154 ## Constants.  ##
 155 ## ----------- ##
 156
 157 # Some regular expressions.  One reason to put them here is that it
 158 # makes indentation work better in Emacs.
 159
 160 # Writing singled-quoted-$-terminated regexes is a pain because
 161 # perl-mode thinks of $' as the ${'} variable (instead of a $ followed
 162 # by a closing quote.  Letting perl-mode think the quote is not closed
 163 # leads to all sort of misindentations.  On the other hand, defining
 164 # regexes as double-quoted strings is far less readable.  So usually
 165 # we will write:
 166 #
 167 #  $REGEX = '^regex_value' . "\$";
 168
 169 my $IGNORE_PATTERN = '^\s*##([^#\n].*)?\n';
 170 my $WHITE_PATTERN = '^\s*' . "\$";
 171 my $COMMENT_PATTERN = '^#';
 172 my $TARGET_PATTERN='[$a-zA-Z0-9_.@%][-.a-zA-Z0-9_(){}/$+@%]*';
 173 # A rule has three parts: a list of targets, a list of dependencies,
 174 # and optionally actions.
 175 my $RULE_PATTERN =
 176   "^($TARGET_PATTERN(?:(?:\\\\\n|\\s)+$TARGET_PATTERN)*) *:([^=].*|)\$";
 177
 178 # Only recognize leading spaces, not leading tabs.  If we recognize
 179 # leading tabs here then we need to make the reader smarter, because
 180 # otherwise it will think rules like `foo=bar; \' are errors.
 181 my $ASSIGNMENT_PATTERN = '^ *([^ \t=:+]*)\s*([:+]?)=\s*(.*)' . "\$";
 182 # This pattern recognizes a Gnits version id and sets $1 if the
 183 # release is an alpha release.  We also allow a suffix which can be
 184 # used to extend the version number with a "fork" identifier.
 185 my $GNITS_VERSION_PATTERN = '\d+\.\d+([a-z]|\.\d+)?(-[A-Za-z0-9]+)?';
 186
 187 my $IF_PATTERN = '^if\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*)\s*(?:#.*)?' . "\$";
 188 my $ELSE_PATTERN =
 189   '^else(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 190 my $ENDIF_PATTERN =
 191   '^endif(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 192 my $PATH_PATTERN = '(\w|[+/.-])+';
 193 # This will pass through anything not of the prescribed form.
 194 my $INCLUDE_PATTERN = ('^include\s+'
 195                        . '((\$\(top_srcdir\)/' . $PATH_PATTERN . ')'
 196                        . '|(\$\(srcdir\)/' . $PATH_PATTERN . ')'
 197                        . '|([^/\$]' . $PATH_PATTERN . '))\s*(#.*)?' . "\$");
 198
 199 # Match `-d' as a command-line argument in a string.
 200 my $DASH_D_PATTERN = "(^|\\s)-d(\\s|\$)";
 201 # Directories installed during 'install-exec' phase.
 202 my $EXEC_DIR_PATTERN =
 203   '^(?:bin|sbin|libexec|sysconf|localstate|lib|pkglib|.*exec.*)' . "\$";
 204
 205 # Values for AC_CANONICAL_*
 206 use constant AC_CANONICAL_BUILD  => 1;
 207 use constant AC_CANONICAL_HOST   => 2;
 208 use constant AC_CANONICAL_TARGET => 3;
 209
 210 # Values indicating when something should be cleaned.
 211 use constant MOSTLY_CLEAN     => 0;
 212 use constant CLEAN            => 1;
 213 use constant DIST_CLEAN       => 2;
 214 use constant MAINTAINER_CLEAN => 3;
 215
 216 # Libtool files.
 217 my @libtool_files = qw(ltmain.sh config.guess config.sub);
 218 # ltconfig appears here for compatibility with old versions of libtool.
 219 my @libtool_sometimes = qw(ltconfig ltcf-c.sh ltcf-cxx.sh ltcf-gcj.sh);
 220
 221 # Commonly found files we look for and automatically include in
 222 # DISTFILES.
 223 my @common_files =
 224     (qw(ABOUT-GNU ABOUT-NLS AUTHORS BACKLOG COPYING COPYING.DOC COPYING.LIB
 225         COPYING.LESSER ChangeLog INSTALL NEWS README THANKS TODO
 226         ansi2knr.1 ansi2knr.c compile config.guess config.rpath config.sub
 227         depcomp elisp-comp install-sh libversion.in mdate-sh missing
 228         mkinstalldirs py-compile texinfo.tex ylwrap),
 229      @libtool_files, @libtool_sometimes);
 230
 231 # Commonly used files we auto-include, but only sometimes.  This list
 232 # is used for the --help output only.
 233 my @common_sometimes =
 234   qw(aclocal.m4 acconfig.h config.h.top config.h.bot configure
 235      configure.ac configure.in stamp-vti);
 236
 237 # Standard directories from the GNU Coding Standards, and additional
 238 # pkg* directories from Automake.  Stored in a hash for fast member check.
 239 my %standard_prefix =
 240     map { $_ => 1 } (qw(bin data dataroot dvi exec html include info
 241                         lib libexec lisp localstate man man1 man2 man3
 242                         man4 man5 man6 man7 man8 man9 oldinclude pdf
 243                         pkgdatadir pkgincludedir pkglibdir pkglibexecdir
 244                         ps sbin sharedstate sysconf));
 245
 246 # Copyright on generated Makefile.ins.
 247 my $gen_copyright = "\
 248 # Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
 249 # 2003, 2004, 2005, 2006, 2007  Free Software Foundation, Inc.
 250 # This Makefile.in is free software; the Free Software Foundation
 251 # gives unlimited permission to copy and/or distribute it,
 252 # with or without modifications, as long as this notice is preserved.
 253
 254 # This program is distributed in the hope that it will be useful,
 255 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
 256 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 257 # PARTICULAR PURPOSE.
 258 ";
 259
 260 # These constants are returned by the lang_*_rewrite functions.
 261 # LANG_SUBDIR means that the resulting object file should be in a
 262 # subdir if the source file is.  In this case the file name cannot
 263 # have `..' components.
 264 use constant LANG_IGNORE  => 0;
 265 use constant LANG_PROCESS => 1;
 266 use constant LANG_SUBDIR  => 2;
 267
 268 # These are used when keeping track of whether an object can be built
 269 # by two different paths.
 270 use constant COMPILE_LIBTOOL  => 1;
 271 use constant COMPILE_ORDINARY => 2;
 272
 273 # We can't always associate a location to a variable or a rule,
 274 # when it's defined by Automake.  We use INTERNAL in this case.
 275 use constant INTERNAL => new Automake::Location;
 276 \f
 277
 278 ## ---------------------------------- ##
 279 ## Variables related to the options.  ##
 280 ## ---------------------------------- ##
 281
 282 # TRUE if we should always generate Makefile.in.
 283 my $force_generation = 1;
 284
 285 # From the Perl manual.
 286 my $symlink_exists = (eval 'symlink ("", "");', $@ eq '');
 287
 288 # TRUE if missing standard files should be installed.
 289 my $add_missing = 0;
 290
 291 # TRUE if we should copy missing files; otherwise symlink if possible.
 292 my $copy_missing = 0;
 293
 294 # TRUE if we should always update files that we know about.
 295 my $force_missing = 0;
 296
 297
 298 ## ---------------------------------------- ##
 299 ## Variables filled during files scanning.  ##
 300 ## ---------------------------------------- ##
 301
 302 # Name of the configure.ac file.
 303 my $configure_ac;
 304
 305 # Files found by scanning configure.ac for LIBOBJS.
 306 my %libsources = ();
 307
 308 # Names used in AC_CONFIG_HEADER call.
 309 my @config_headers = ();
 310
 311 # Names used in AC_CONFIG_LINKS call.
 312 my @config_links = ();
 313
 314 # Directory where output files go.  Actually, output files are
 315 # relative to this directory.
 316 my $output_directory;
 317
 318 # List of Makefile.am's to process, and their corresponding outputs.
 319 my @input_files = ();
 320 my %output_files = ();
 321
 322 # Complete list of Makefile.am's that exist.
 323 my @configure_input_files = ();
 324
 325 # List of files in AC_CONFIG_FILES/AC_OUTPUT without Makefile.am's,
 326 # and their outputs.
 327 my @other_input_files = ();
 328 # Where each AC_CONFIG_FILES/AC_OUTPUT/AC_CONFIG_LINK/AC_CONFIG_HEADER appears.
 329 # The keys are the files created by these macros.
 330 my %ac_config_files_location = ();
 331
 332 # Directory to search for configure-required files.  This
 333 # will be computed by &locate_aux_dir and can be set using
 334 # AC_CONFIG_AUX_DIR in configure.ac.
 335 # $CONFIG_AUX_DIR is the `raw' directory, valid only in the source-tree.
 336 my $config_aux_dir = '';
 337 my $config_aux_dir_set_in_configure_ac = 0;
 338 # $AM_CONFIG_AUX_DIR is prefixed with $(top_srcdir), so it can be used
 339 # in Makefiles.
 340 my $am_config_aux_dir = '';
 341
 342 # Directory to search for AC_LIBSOURCE files, as set by AC_CONFIG_LIBOBJ_DIR
 343 # in configure.ac.
 344 my $config_libobj_dir = '';
 345
 346 # Whether AM_GNU_GETTEXT has been seen in configure.ac.
 347 my $seen_gettext = 0;
 348 # Whether AM_GNU_GETTEXT([external]) is used.
 349 my $seen_gettext_external = 0;
 350 # Where AM_GNU_GETTEXT appears.
 351 my $ac_gettext_location;
 352 # Whether AM_GNU_GETTEXT_INTL_SUBDIR has been seen.
 353 my $seen_gettext_intl = 0;
 354
 355 # Lists of tags supported by Libtool.
 356 my %libtool_tags = ();
 357 # 1 if Libtool uses LT_SUPPORTED_TAG.  If it does, then it also
 358 # uses AC_REQUIRE_AUX_FILE.
 359 my $libtool_new_api = 0;
 360
 361 # Most important AC_CANONICAL_* macro seen so far.
 362 my $seen_canonical = 0;
 363 # Location of that macro.
 364 my $canonical_location;
 365
 366 # Where AM_MAINTAINER_MODE appears.
 367 my $seen_maint_mode;
 368
 369 # Actual version we've seen.
 370 my $package_version = '';
 371
 372 # Where version is defined.
 373 my $package_version_location;
 374
 375 # TRUE if we've seen AM_ENABLE_MULTILIB.
 376 my $seen_multilib = 0;
 377
 378 # TRUE if we've seen AM_PROG_CC_C_O
 379 my $seen_cc_c_o = 0;
 380
 381 # Location of AC_REQUIRE_AUX_FILE calls, indexed by their argument.
 382 my %required_aux_file = ();
 383
 384 # Where AM_INIT_AUTOMAKE is called;
 385 my $seen_init_automake = 0;
 386
 387 # TRUE if we've seen AM_AUTOMAKE_VERSION.
 388 my $seen_automake_version = 0;
 389
 390 # Hash table of discovered configure substitutions.  Keys are names,
 391 # values are `FILE:LINE' strings which are used by error message
 392 # generation.
 393 my %configure_vars = ();
 394
 395 # Ignored configure substitutions (i.e., variables not to be output in
 396 # Makefile.in)
 397 my %ignored_configure_vars = ();
 398
 399 # Files included by $configure_ac.
 400 my @configure_deps = ();
 401
 402 # Greatest timestamp of configure's dependencies.
 403 my $configure_deps_greatest_timestamp = 0;
 404
 405 # Hash table of AM_CONDITIONAL variables seen in configure.
 406 my %configure_cond = ();
 407
 408 # This maps extensions onto language names.
 409 my %extension_map = ();
 410
 411 # List of the DIST_COMMON files we discovered while reading
 412 # configure.in
 413 my $configure_dist_common = '';
 414
 415 # This maps languages names onto objects.
 416 my %languages = ();
 417 # Maps each linker variable onto a language object.
 418 my %link_languages = ();
 419
 420 # maps extensions to needed source flags.
 421 my %sourceflags = ();
 422
 423 # List of targets we must always output.
 424 # FIXME: Complete, and remove falsely required targets.
 425 my %required_targets =
 426   (
 427    'all'          => 1,
 428    'dvi'          => 1,
 429    'pdf'          => 1,
 430    'ps'           => 1,
 431    'info'         => 1,
 432    'install-info' => 1,
 433    'install'      => 1,
 434    'install-data' => 1,
 435    'install-exec' => 1,
 436    'uninstall'    => 1,
 437
 438    # FIXME: Not required, temporary hacks.
 439    # Well, actually they are sort of required: the -recursive
 440    # targets will run them anyway...
 441    'dvi-am'          => 1,
 442    'pdf-am'          => 1,
 443    'ps-am'           => 1,
 444    'info-am'         => 1,
 445    'install-data-am' => 1,
 446    'install-exec-am' => 1,
 447    'installcheck-am' => 1,
 448    'uninstall-am' => 1,
 449
 450    'install-man' => 1,
 451   );
 452
 453 # Set to 1 if this run will create the Makefile.in that distribute
 454 # the files in config_aux_dir.
 455 my $automake_will_process_aux_dir = 0;
 456
 457 # The name of the Makefile currently being processed.
 458 my $am_file = 'BUG';
 459 \f
 460
 461 ################################################################
 462
 463 ## ------------------------------------------ ##
 464 ## Variables reset by &initialize_per_input.  ##
 465 ## ------------------------------------------ ##
 466
 467 # Basename and relative dir of the input file.
 468 my $am_file_name;
 469 my $am_relative_dir;
 470
 471 # Same but wrt Makefile.in.
 472 my $in_file_name;
 473 my $relative_dir;
 474
 475 # Relative path to the top directory.
 476 my $topsrcdir;
 477
 478 # Greatest timestamp of the output's dependencies (excluding
 479 # configure's dependencies).
 480 my $output_deps_greatest_timestamp;
 481
 482 # These two variables are used when generating each Makefile.in.
 483 # They hold the Makefile.in until it is ready to be printed.
 484 my $output_rules;
 485 my $output_vars;
 486 my $output_trailer;
 487 my $output_all;
 488 my $output_header;
 489
 490 # This is the conditional stack, updated on if/else/endif, and
 491 # used to build Condition objects.
 492 my @cond_stack;
 493
 494 # This holds the set of included files.
 495 my @include_stack;
 496
 497 # List of dependencies for the obvious targets.
 498 my @all;
 499 my @check;
 500 my @check_tests;
 501
 502 # Keys in this hash table are files to delete.  The associated
 503 # value tells when this should happen (MOSTLY_CLEAN, DIST_CLEAN, etc.)
 504 my %clean_files;
 505
 506 # Keys in this hash table are object files or other files in
 507 # subdirectories which need to be removed.  This only holds files
 508 # which are created by compilations.  The value in the hash indicates
 509 # when the file should be removed.
 510 my %compile_clean_files;
 511
 512 # Keys in this hash table are directories where we expect to build a
 513 # libtool object.  We use this information to decide what directories
 514 # to delete.
 515 my %libtool_clean_directories;
 516
 517 # Value of `$(SOURCES)', used by tags.am.
 518 my @sources;
 519 # Sources which go in the distribution.
 520 my @dist_sources;
 521
 522 # This hash maps object file names onto their corresponding source
 523 # file names.  This is used to ensure that each object is created
 524 # by a single source file.
 525 my %object_map;
 526
 527 # This hash maps object file names onto an integer value representing
 528 # whether this object has been built via ordinary compilation or
 529 # libtool compilation (the COMPILE_* constants).
 530 my %object_compilation_map;
 531
 532
 533 # This keeps track of the directories for which we've already
 534 # created dirstamp code.  Keys are directories, values are stamp files.
 535 # Several keys can share the same stamp files if they are equivalent
 536 # (as are `.//foo' and `foo').
 537 my %directory_map;
 538
 539 # All .P files.
 540 my %dep_files;
 541
 542 # This is a list of all targets to run during "make dist".
 543 my @dist_targets;
 544
 545 # Keep track of all programs declared in this Makefile, without
 546 # $(EXEEXT).  @substitution@ are not listed.
 547 my %known_programs;
 548
 549 # Keys in this hash are the basenames of files which must depend on
 550 # ansi2knr.  Values are either the empty string, or the directory in
 551 # which the ANSI source file appears; the directory must have a
 552 # trailing `/'.
 553 my %de_ansi_files;
 554
 555 # This is the name of the redirect `all' target to use.
 556 my $all_target;
 557
 558 # This keeps track of which extensions we've seen (that we care
 559 # about).
 560 my %extension_seen;
 561
 562 # This is random scratch space for the language finish functions.
 563 # Don't randomly overwrite it; examine other uses of keys first.
 564 my %language_scratch;
 565
 566 # We keep track of which objects need special (per-executable)
 567 # handling on a per-language basis.
 568 my %lang_specific_files;
 569
 570 # This is set when `handle_dist' has finished.  Once this happens,
 571 # we should no longer push on dist_common.
 572 my $handle_dist_run;
 573
 574 # Used to store a set of linkers needed to generate the sources currently
 575 # under consideration.
 576 my %linkers_used;
 577
 578 # True if we need `LINK' defined.  This is a hack.
 579 my $need_link;
 580
 581 # Was get_object_extension run?
 582 # FIXME: This is a hack. a better switch should be found.
 583 my $get_object_extension_was_run;
 584
 585 # Record each file processed by make_paragraphs.
 586 my %transformed_files;
 587
 588 # Cache each file processed by make_paragraphs.
 589 # (This is different from %transformed_files because
 590 # %transformed_files is reset for each file while %am_file_cache
 591 # it global to the run.)
 592 my %am_file_cache;
 593
 594 ################################################################
 595
 596 # var_SUFFIXES_trigger ($TYPE, $VALUE)
 597 # ------------------------------------
 598 # This is called by Automake::Variable::define() when SUFFIXES
 599 # is defined ($TYPE eq '') or appended ($TYPE eq '+').
 600 # The work here needs to be performed as a side-effect of the
 601 # macro_define() call because SUFFIXES definitions impact
 602 # on $KNOWN_EXTENSIONS_PATTERN which is used used when parsing
 603 # the input am file.
 604 sub var_SUFFIXES_trigger ($$)
 605 {
 606     my ($type, $value) = @_;
 607     accept_extensions (split (' ', $value));
 608 }
 609 Automake::Variable::hook ('SUFFIXES', \&var_SUFFIXES_trigger);
 610
 611 ################################################################
 612
 613 ## --------------------------------- ##
 614 ## Forward subroutine declarations.  ##
 615 ## --------------------------------- ##
 616 sub register_language (%);
 617 sub file_contents_internal ($$$%);
 618 sub define_files_variable ($\@$$);
 619
 620
 621 # &initialize_per_input ()
 622 # ------------------------
 623 # (Re)-Initialize per-Makefile.am variables.
 624 sub initialize_per_input ()
 625 {
 626     reset_local_duplicates ();
 627
 628     $am_file_name = '';
 629     $am_relative_dir = '';
 630
 631     $in_file_name = '';
 632     $relative_dir = '';
 633
 634     $output_deps_greatest_timestamp = 0;
 635
 636     $output_rules = '';
 637     $output_vars = '';
 638     $output_trailer = '';
 639     $output_all = '';
 640     $output_header = '';
 641
 642     Automake::Options::reset;
 643     Automake::Variable::reset;
 644     Automake::Rule::reset;
 645
 646     @cond_stack = ();
 647
 648     @include_stack = ();
 649
 650     @all = ();
 651     @check = ();
 652     @check_tests = ();
 653
 654     %clean_files = ();
 655
 656     @sources = ();
 657     @dist_sources = ();
 658
 659     %object_map = ();
 660     %object_compilation_map = ();
 661
 662     %directory_map = ();
 663
 664     %dep_files = ();
 665
 666     @dist_targets = ();
 667
 668     %known_programs = ();
 669
 670     %de_ansi_files = ();
 671
 672     $all_target = '';
 673
 674     %extension_seen = ();
 675
 676     %language_scratch = ();
 677
 678     %lang_specific_files = ();
 679
 680     $handle_dist_run = 0;
 681
 682     $need_link = 0;
 683
 684     $get_object_extension_was_run = 0;
 685
 686     %compile_clean_files = ();
 687
 688     # We always include `.'.  This isn't strictly correct.
 689     %libtool_clean_directories = ('.' => 1);
 690
 691     %transformed_files = ();
 692 }
 693
 694
 695 ################################################################
 696
 697 # Initialize our list of languages that are internally supported.
 698
 699 # C.
 700 register_language ('name' => 'c',
 701                    'Name' => 'C',
 702                    'config_vars' => ['CC'],
 703                    'ansi' => 1,
 704                    'autodep' => '',
 705                    'flags' => ['CFLAGS', 'CPPFLAGS'],
 706                    'compiler' => 'COMPILE',
 707                    'compile' => '$(CC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CFLAGS) $(CFLAGS)',
 708                    'lder' => 'CCLD',
 709                    'ld' => '$(CC)',
 710                    'linker' => 'LINK',
 711                    'link' => '$(CCLD) $(AM_CFLAGS) $(CFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 712                    'compile_flag' => '-c',
 713                    'libtool_tag' => 'CC',
 714                    'extensions' => ['.c'],
 715                    '_finish' => \&lang_c_finish);
 716
 717 # C++.
 718 register_language ('name' => 'cxx',
 719                    'Name' => 'C++',
 720                    'config_vars' => ['CXX'],
 721                    'linker' => 'CXXLINK',
 722                    'link' => '$(CXXLD) $(AM_CXXFLAGS) $(CXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 723                    'autodep' => 'CXX',
 724                    'flags' => ['CXXFLAGS', 'CPPFLAGS'],
 725                    'compile' => '$(CXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CXXFLAGS) $(CXXFLAGS)',
 726                    'compiler' => 'CXXCOMPILE',
 727                    'compile_flag' => '-c',
 728                    'output_flag' => '-o',
 729                    'libtool_tag' => 'CXX',
 730                    'lder' => 'CXXLD',
 731                    'ld' => '$(CXX)',
 732                    'pure' => 1,
 733                    'extensions' => ['.c++', '.cc', '.cpp', '.cxx', '.C']);
 734
 735 # Objective C.
 736 register_language ('name' => 'objc',
 737                    'Name' => 'Objective C',
 738                    'config_vars' => ['OBJC'],
 739                    'linker' => 'OBJCLINK',
 740                    'link' => '$(OBJCLD) $(AM_OBJCFLAGS) $(OBJCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 741                    'autodep' => 'OBJC',
 742                    'flags' => ['OBJCFLAGS', 'CPPFLAGS'],
 743                    'compile' => '$(OBJC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCFLAGS) $(OBJCFLAGS)',
 744                    'compiler' => 'OBJCCOMPILE',
 745                    'compile_flag' => '-c',
 746                    'output_flag' => '-o',
 747                    'lder' => 'OBJCLD',
 748                    'ld' => '$(OBJC)',
 749                    'pure' => 1,
 750                    'extensions' => ['.m']);
 751
 752 # Unified Parallel C.
 753 register_language ('name' => 'upc',
 754                    'Name' => 'Unified Parallel C',
 755                    'config_vars' => ['UPC'],
 756                    'linker' => 'UPCLINK',
 757                    'link' => '$(UPCLD) $(AM_UPCFLAGS) $(UPCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 758                    'autodep' => 'UPC',
 759                    'flags' => ['UPCFLAGS', 'CPPFLAGS'],
 760                    'compile' => '$(UPC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_UPCFLAGS) $(UPCFLAGS)',
 761                    'compiler' => 'UPCCOMPILE',
 762                    'compile_flag' => '-c',
 763                    'output_flag' => '-o',
 764                    'lder' => 'UPCLD',
 765                    'ld' => '$(UPC)',
 766                    'pure' => 1,
 767                    'extensions' => ['.upc']);
 768
 769 # Headers.
 770 register_language ('name' => 'header',
 771                    'Name' => 'Header',
 772                    'extensions' => ['.h', '.H', '.hxx', '.h++', '.hh',
 773                                     '.hpp', '.inc'],
 774                    # No output.
 775                    'output_extensions' => sub { return () },
 776                    # Nothing to do.
 777                    '_finish' => sub { });
 778
 779 # Yacc (C & C++).
 780 register_language ('name' => 'yacc',
 781                    'Name' => 'Yacc',
 782                    'config_vars' => ['YACC'],
 783                    'flags' => ['YFLAGS'],
 784                    'compile' => '$(YACC) $(YFLAGS) $(AM_YFLAGS)',
 785                    'compiler' => 'YACCCOMPILE',
 786                    'extensions' => ['.y'],
 787                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 788                                                 return ($ext,) },
 789                    'rule_file' => 'yacc',
 790                    '_finish' => \&lang_yacc_finish,
 791                    '_target_hook' => \&lang_yacc_target_hook,
 792                    'nodist_specific' => 1);
 793 register_language ('name' => 'yaccxx',
 794                    'Name' => 'Yacc (C++)',
 795                    'config_vars' => ['YACC'],
 796                    'rule_file' => 'yacc',
 797                    'flags' => ['YFLAGS'],
 798                    'compiler' => 'YACCCOMPILE',
 799                    'compile' => '$(YACC) $(YFLAGS) $(AM_YFLAGS)',
 800                    'extensions' => ['.y++', '.yy', '.yxx', '.ypp'],
 801                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 802                                                 return ($ext,) },
 803                    '_finish' => \&lang_yacc_finish,
 804                    '_target_hook' => \&lang_yacc_target_hook,
 805                    'nodist_specific' => 1);
 806
 807 # Lex (C & C++).
 808 register_language ('name' => 'lex',
 809                    'Name' => 'Lex',
 810                    'config_vars' => ['LEX'],
 811                    'rule_file' => 'lex',
 812                    'flags' => ['LFLAGS'],
 813                    'compile' => '$(LEX) $(LFLAGS) $(AM_LFLAGS)',
 814                    'compiler' => 'LEXCOMPILE',
 815                    'extensions' => ['.l'],
 816                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 817                                                 return ($ext,) },
 818                    '_finish' => \&lang_lex_finish,
 819                    '_target_hook' => \&lang_lex_target_hook,
 820                    'nodist_specific' => 1);
 821 register_language ('name' => 'lexxx',
 822                    'Name' => 'Lex (C++)',
 823                    'config_vars' => ['LEX'],
 824                    'rule_file' => 'lex',
 825                    'flags' => ['LFLAGS'],
 826                    'compile' => '$(LEX) $(LFLAGS) $(AM_LFLAGS)',
 827                    'compiler' => 'LEXCOMPILE',
 828                    'extensions' => ['.l++', '.ll', '.lxx', '.lpp'],
 829                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 830                                                 return ($ext,) },
 831                    '_finish' => \&lang_lex_finish,
 832                    '_target_hook' => \&lang_lex_target_hook,
 833                    'nodist_specific' => 1);
 834
 835 # Assembler.
 836 register_language ('name' => 'asm',
 837                    'Name' => 'Assembler',
 838                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 839
 840                    'flags' => ['CCASFLAGS'],
 841                    # Users can set AM_CCASFLAGS to include DEFS, INCLUDES,
 842                    # or anything else required.  They can also set CCAS.
 843                    # Or simply use Preprocessed Assembler.
 844                    'compile' => '$(CCAS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 845                    'compiler' => 'CCASCOMPILE',
 846                    'compile_flag' => '-c',
 847                    'output_flag' => '-o',
 848                    'extensions' => ['.s'],
 849
 850                    # With assembly we still use the C linker.
 851                    '_finish' => \&lang_c_finish);
 852
 853 # Preprocessed Assembler.
 854 register_language ('name' => 'cppasm',
 855                    'Name' => 'Preprocessed Assembler',
 856                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 857
 858                    'autodep' => 'CCAS',
 859                    'flags' => ['CCASFLAGS', 'CPPFLAGS'],
 860                    'compile' => '$(CCAS) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 861                    'compiler' => 'CPPASCOMPILE',
 862                    'compile_flag' => '-c',
 863                    'output_flag' => '-o',
 864                    'extensions' => ['.S', '.sx'],
 865
 866                    # With assembly we still use the C linker.
 867                    '_finish' => \&lang_c_finish);
 868
 869 # Fortran 77
 870 register_language ('name' => 'f77',
 871                    'Name' => 'Fortran 77',
 872                    'config_vars' => ['F77'],
 873                    'linker' => 'F77LINK',
 874                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 875                    'flags' => ['FFLAGS'],
 876                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS)',
 877                    'compiler' => 'F77COMPILE',
 878                    'compile_flag' => '-c',
 879                    'output_flag' => '-o',
 880                    'libtool_tag' => 'F77',
 881                    'lder' => 'F77LD',
 882                    'ld' => '$(F77)',
 883                    'pure' => 1,
 884                    'extensions' => ['.f', '.for']);
 885
 886 # Fortran
 887 register_language ('name' => 'fc',
 888                    'Name' => 'Fortran',
 889                    'config_vars' => ['FC'],
 890                    'linker' => 'FCLINK',
 891                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 892                    'flags' => ['FCFLAGS'],
 893                    'compile' => '$(FC) $(AM_FCFLAGS) $(FCFLAGS)',
 894                    'compiler' => 'FCCOMPILE',
 895                    'compile_flag' => '-c',
 896                    'output_flag' => '-o',
 897                    'lder' => 'FCLD',
 898                    'ld' => '$(FC)',
 899                    'pure' => 1,
 900                    'extensions' => ['.f90', '.f95']);
 901
 902 # Preprocessed Fortran
 903 register_language ('name' => 'ppfc',
 904                    'Name' => 'Preprocessed Fortran',
 905                    'config_vars' => ['FC'],
 906                    'linker' => 'FCLINK',
 907                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 908                    'lder' => 'FCLD',
 909                    'ld' => '$(FC)',
 910                    'flags' => ['FCFLAGS', 'CPPFLAGS'],
 911                    'compiler' => 'PPFCCOMPILE',
 912                    'compile' => '$(FC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FCFLAGS) $(FCFLAGS)',
 913                    'compile_flag' => '-c',
 914                    'output_flag' => '-o',
 915                    'libtool_tag' => 'FC',
 916                    'pure' => 1,
 917                    'extensions' => ['.F90','.F95']);
 918
 919 # Preprocessed Fortran 77
 920 #
 921 # The current support for preprocessing Fortran 77 just involves
 922 # passing `$(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS)
 923 # $(CPPFLAGS)' as additional flags to the Fortran 77 compiler, since
 924 # this is how GNU Make does it; see the `GNU Make Manual, Edition 0.51
 925 # for `make' Version 3.76 Beta' (specifically, from info file
 926 # `(make)Catalogue of Rules').
 927 #
 928 # A better approach would be to write an Autoconf test
 929 # (i.e. AC_PROG_FPP) for a Fortran 77 preprocessor, because not all
 930 # Fortran 77 compilers know how to do preprocessing.  The Autoconf
 931 # macro AC_PROG_FPP should test the Fortran 77 compiler first for
 932 # preprocessing capabilities, and then fall back on cpp (if cpp were
 933 # available).
 934 register_language ('name' => 'ppf77',
 935                    'Name' => 'Preprocessed Fortran 77',
 936                    'config_vars' => ['F77'],
 937                    'linker' => 'F77LINK',
 938                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 939                    'lder' => 'F77LD',
 940                    'ld' => '$(F77)',
 941                    'flags' => ['FFLAGS', 'CPPFLAGS'],
 942                    'compiler' => 'PPF77COMPILE',
 943                    'compile' => '$(F77) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FFLAGS) $(FFLAGS)',
 944                    'compile_flag' => '-c',
 945                    'output_flag' => '-o',
 946                    'libtool_tag' => 'F77',
 947                    'pure' => 1,
 948                    'extensions' => ['.F']);
 949
 950 # Ratfor.
 951 register_language ('name' => 'ratfor',
 952                    'Name' => 'Ratfor',
 953                    'config_vars' => ['F77'],
 954                    'linker' => 'F77LINK',
 955                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 956                    'lder' => 'F77LD',
 957                    'ld' => '$(F77)',
 958                    'flags' => ['RFLAGS', 'FFLAGS'],
 959                    # FIXME also FFLAGS.
 960                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS) $(AM_RFLAGS) $(RFLAGS)',
 961                    'compiler' => 'RCOMPILE',
 962                    'compile_flag' => '-c',
 963                    'output_flag' => '-o',
 964                    'libtool_tag' => 'F77',
 965                    'pure' => 1,
 966                    'extensions' => ['.r']);
 967
 968 # Java via gcj.
 969 register_language ('name' => 'java',
 970                    'Name' => 'Java',
 971                    'config_vars' => ['GCJ'],
 972                    'linker' => 'GCJLINK',
 973                    'link' => '$(GCJLD) $(AM_GCJFLAGS) $(GCJFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 974                    'autodep' => 'GCJ',
 975                    'flags' => ['GCJFLAGS'],
 976                    'compile' => '$(GCJ) $(AM_GCJFLAGS) $(GCJFLAGS)',
 977                    'compiler' => 'GCJCOMPILE',
 978                    'compile_flag' => '-c',
 979                    'output_flag' => '-o',
 980                    'libtool_tag' => 'GCJ',
 981                    'lder' => 'GCJLD',
 982                    'ld' => '$(GCJ)',
 983                    'pure' => 1,
 984                    'extensions' => ['.java', '.class', '.zip', '.jar']);
 985
 986 ################################################################
 987
 988 # Error reporting functions.
 989
 990 # err_am ($MESSAGE, [%OPTIONS])
 991 # -----------------------------
 992 # Uncategorized errors about the current Makefile.am.
 993 sub err_am ($;%)
 994 {
 995   msg_am ('error', @_);
 996 }
 997
 998 # err_ac ($MESSAGE, [%OPTIONS])
 999 # -----------------------------
1000 # Uncategorized errors about configure.ac.
1001 sub err_ac ($;%)
1002 {
1003   msg_ac ('error', @_);
1004 }
1005
1006 # msg_am ($CHANNEL, $MESSAGE, [%OPTIONS])
1007 # ---------------------------------------
1008 # Messages about about the current Makefile.am.
1009 sub msg_am ($$;%)
1010 {
1011   my ($channel, $msg, %opts) = @_;
1012   msg $channel, "${am_file}.am", $msg, %opts;
1013 }
1014
1015 # msg_ac ($CHANNEL, $MESSAGE, [%OPTIONS])
1016 # ---------------------------------------
1017 # Messages about about configure.ac.
1018 sub msg_ac ($$;%)
1019 {
1020   my ($channel, $msg, %opts) = @_;
1021   msg $channel, $configure_ac, $msg, %opts;
1022 }
1023
1024 ################################################################
1025
1026 # subst ($TEXT)
1027 # -------------
1028 # Return a configure-style substitution using the indicated text.
1029 # We do this to avoid having the substitutions directly in automake.in;
1030 # when we do that they are sometimes removed and this causes confusion
1031 # and bugs.
1032 sub subst ($)
1033 {
1034     my ($text) = @_;
1035     return '@' . $text . '@';
1036 }
1037
1038 ################################################################
1039
1040
1041 # $BACKPATH
1042 # &backname ($REL-DIR)
1043 # --------------------
1044 # If I `cd $REL-DIR', then to come back, I should `cd $BACKPATH'.
1045 # For instance `src/foo' => `../..'.
1046 # Works with non strictly increasing paths, i.e., `src/../lib' => `..'.
1047 sub backname ($)
1048 {
1049     my ($file) = @_;
1050     my @res;
1051     foreach (split (/\//, $file))
1052     {
1053         next if $_ eq '.' || $_ eq '';
1054         if ($_ eq '..')
1055         {
1056             pop @res;
1057         }
1058         else
1059         {
1060             push (@res, '..');
1061         }
1062     }
1063     return join ('/', @res) || '.';
1064 }
1065
1066 ################################################################
1067
1068
1069 # Handle AUTOMAKE_OPTIONS variable.  Return 1 on error, 0 otherwise.
1070 sub handle_options
1071 {
1072   my $var = var ('AUTOMAKE_OPTIONS');
1073   if ($var)
1074     {
1075       if ($var->has_conditional_contents)
1076         {
1077           msg_var ('unsupported', $var,
1078                    "`AUTOMAKE_OPTIONS' cannot have conditional contents");
1079         }
1080       foreach my $locvals ($var->value_as_list_recursive (cond_filter => TRUE,
1081                                                           location => 1))
1082         {
1083           my ($loc, $value) = @$locvals;
1084           return 1 if (process_option_list ($loc, $value))
1085         }
1086     }
1087
1088   if ($strictness == GNITS)
1089     {
1090       set_option ('readme-alpha', INTERNAL);
1091       set_option ('std-options', INTERNAL);
1092       set_option ('check-news', INTERNAL);
1093     }
1094
1095   return 0;
1096 }
1097
1098 # shadow_unconditionally ($varname, $where)
1099 # -----------------------------------------
1100 # Return a $(variable) that contains all possible values
1101 # $varname can take.
1102 # If the VAR wasn't defined conditionally, return $(VAR).
1103 # Otherwise we create a am__VAR_DIST variable which contains
1104 # all possible values, and return $(am__VAR_DIST).
1105 sub shadow_unconditionally ($$)
1106 {
1107   my ($varname, $where) = @_;
1108   my $var = var $varname;
1109   if ($var->has_conditional_contents)
1110     {
1111       $varname = "am__${varname}_DIST";
1112       my @files = uniq ($var->value_as_list_recursive);
1113       define_pretty_variable ($varname, TRUE, $where, @files);
1114     }
1115   return "\$($varname)"
1116 }
1117
1118 # get_object_extension ($EXTENSION)
1119 # ---------------------------------
1120 # Prefix $EXTENSION with $U if ansi2knr is in use.
1121 sub get_object_extension ($)
1122 {
1123     my ($extension) = @_;
1124
1125     # Check for automatic de-ANSI-fication.
1126     $extension = '$U' . $extension
1127       if option 'ansi2knr';
1128
1129     $get_object_extension_was_run = 1;
1130
1131     return $extension;
1132 }
1133
1134 # check_user_variables (@LIST)
1135 # ----------------------------
1136 # Make sure each variable VAR in @LIST does not exist, suggest using AM_VAR
1137 # otherwise.
1138 sub check_user_variables (@)
1139 {
1140   my @dont_override = @_;
1141   foreach my $flag (@dont_override)
1142     {
1143       my $var = var $flag;
1144       if ($var)
1145         {
1146           for my $cond ($var->conditions->conds)
1147             {
1148               if ($var->rdef ($cond)->owner == VAR_MAKEFILE)
1149                 {
1150                   msg_cond_var ('gnu', $cond, $flag,
1151                                 "`$flag' is a user variable, "
1152                                 . "you should not override it;\n"
1153                                 . "use `AM_$flag' instead.");
1154                 }
1155             }
1156         }
1157     }
1158 }
1159
1160 # Call finish function for each language that was used.
1161 sub handle_languages
1162 {
1163     if (! option 'no-dependencies')
1164     {
1165         # Include auto-dep code.  Don't include it if DEP_FILES would
1166         # be empty.
1167         if (&saw_sources_p (0) && keys %dep_files)
1168         {
1169             # Set location of depcomp.
1170             &define_variable ('depcomp',
1171                               "\$(SHELL) $am_config_aux_dir/depcomp",
1172                               INTERNAL);
1173             &define_variable ('am__depfiles_maybe', 'depfiles', INTERNAL);
1174
1175             require_conf_file ("$am_file.am", FOREIGN, 'depcomp');
1176
1177             my @deplist = sort keys %dep_files;
1178             # Generate each `include' individually.  Irix 6 make will
1179             # not properly include several files resulting from a
1180             # variable expansion; generating many separate includes
1181             # seems safest.
1182             $output_rules .= "\n";
1183             foreach my $iter (@deplist)
1184             {
1185                 $output_rules .= (subst ('AMDEP_TRUE')
1186                                   . subst ('am__include')
1187                                   . ' '
1188                                   . subst ('am__quote')
1189                                   . $iter
1190                                   . subst ('am__quote')
1191                                   . "\n");
1192             }
1193
1194             # Compute the set of directories to remove in distclean-depend.
1195             my @depdirs = uniq (map { dirname ($_) } @deplist);
1196             $output_rules .= &file_contents ('depend',
1197                                              new Automake::Location,
1198                                              DEPDIRS => "@depdirs");
1199         }
1200     }
1201     else
1202     {
1203         &define_variable ('depcomp', '', INTERNAL);
1204         &define_variable ('am__depfiles_maybe', '', INTERNAL);
1205     }
1206
1207     my %done;
1208
1209     # Is the c linker needed?
1210     my $needs_c = 0;
1211     foreach my $ext (sort keys %extension_seen)
1212     {
1213         next unless $extension_map{$ext};
1214
1215         my $lang = $languages{$extension_map{$ext}};
1216
1217         my $rule_file = $lang->rule_file || 'depend2';
1218
1219         # Get information on $LANG.
1220         my $pfx = $lang->autodep;
1221         my $fpfx = ($pfx eq '') ? 'CC' : $pfx;
1222
1223         my ($AMDEP, $FASTDEP) =
1224           (option 'no-dependencies' || $lang->autodep eq 'no')
1225           ? ('FALSE', 'FALSE') : ('AMDEP', "am__fastdep$fpfx");
1226
1227         my %transform = ('EXT'     => $ext,
1228                          'PFX'     => $pfx,
1229                          'FPFX'    => $fpfx,
1230                          'AMDEP'   => $AMDEP,
1231                          'FASTDEP' => $FASTDEP,
1232                          '-c'      => $lang->compile_flag || '',
1233                          # These are not used, but they need to be defined
1234                          # so &transform do not complain.
1235                          SUBDIROBJ     => 0,
1236                          'DERIVED-EXT' => 'BUG',
1237                          DIST_SOURCE   => 1,
1238                         );
1239
1240         # Generate the appropriate rules for this extension.
1241         if (((! option 'no-dependencies') && $lang->autodep ne 'no')
1242             || defined $lang->compile)
1243         {
1244             # Some C compilers don't support -c -o.  Use it only if really
1245             # needed.
1246             my $output_flag = $lang->output_flag || '';
1247             $output_flag = '-o'
1248               if (! $output_flag
1249                   && $lang->name eq 'c'
1250                   && option 'subdir-objects');
1251
1252             # Compute a possible derived extension.
1253             # This is not used by depend2.am.
1254             my $der_ext = (&{$lang->output_extensions} ($ext))[0];
1255
1256             # When we output an inference rule like `.c.o:' we
1257             # have two cases to consider: either subdir-objects
1258             # is used, or it is not.
1259             #
1260             # In the latter case the rule is used to build objects
1261             # in the current directory, and dependencies always
1262             # go into `./$(DEPDIR)/'.  We can hard-code this value.
1263             #
1264             # In the former case the rule can be used to build
1265             # objects in sub-directories too.  Dependencies should
1266             # go into the appropriate sub-directories, e.g.,
1267             # `sub/$(DEPDIR)/'.  The value of this directory
1268             # needs to be computed on-the-fly.
1269             #
1270             # DEPBASE holds the name of this directory, plus the
1271             # basename part of the object file (extensions Po, TPo,
1272             # Plo, TPlo will be added later as appropriate).  It is
1273             # either hardcoded, or a shell variable (`$depbase') that
1274             # will be computed by the rule.
1275             my $depbase =
1276               option ('subdir-objects') ? '$$depbase' : '$(DEPDIR)/$*';
1277             $output_rules .=
1278               file_contents ($rule_file,
1279                              new Automake::Location,
1280                              %transform,
1281                              GENERIC   => 1,
1282
1283                              'DERIVED-EXT' => $der_ext,
1284
1285                              DEPBASE   => $depbase,
1286                              BASE      => '$*',
1287                              SOURCE    => '$<',
1288                              SOURCEFLAG => $sourceflags{$ext} || '',
1289                              OBJ       => '$@',
1290                              OBJOBJ    => '$@',
1291                              LTOBJ     => '$@',
1292
1293                              COMPILE   => '$(' . $lang->compiler . ')',
1294                              LTCOMPILE => '$(LT' . $lang->compiler . ')',
1295                              -o        => $output_flag,
1296                              SUBDIROBJ => !! option 'subdir-objects');
1297         }
1298
1299         # Now include code for each specially handled object with this
1300         # language.
1301         my %seen_files = ();
1302         foreach my $file (@{$lang_specific_files{$lang->name}})
1303         {
1304             my ($derived, $source, $obj, $myext, $srcext, %file_transform) = @$file;
1305
1306             # We might see a given object twice, for instance if it is
1307             # used under different conditions.
1308             next if defined $seen_files{$obj};
1309             $seen_files{$obj} = 1;
1310
1311             prog_error ("found " . $lang->name .
1312                         " in handle_languages, but compiler not defined")
1313               unless defined $lang->compile;
1314
1315             my $obj_compile = $lang->compile;
1316
1317             # Rewrite each occurrence of `AM_$flag' in the compile
1318             # rule into `${derived}_$flag' if it exists.
1319             for my $flag (@{$lang->flags})
1320               {
1321                 my $val = "${derived}_$flag";
1322                 $obj_compile =~ s/\(AM_$flag\)/\($val\)/
1323                   if set_seen ($val);
1324               }
1325
1326             my $libtool_tag = '';
1327             if ($lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag})
1328               {
1329                 $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
1330               }
1331
1332             my $ptltflags = "${derived}_LIBTOOLFLAGS";
1333             $ptltflags = 'AM_LIBTOOLFLAGS' unless set_seen $ptltflags;
1334
1335             my $obj_ltcompile =
1336               "\$(LIBTOOL) $libtool_tag\$($ptltflags) \$(LIBTOOLFLAGS) "
1337               . "--mode=compile $obj_compile";
1338
1339             # We _need_ `-o' for per object rules.
1340             my $output_flag = $lang->output_flag || '-o';
1341
1342             my $depbase = dirname ($obj);
1343             $depbase = ''
1344                 if $depbase eq '.';
1345             $depbase .= '/'
1346                 unless $depbase eq '';
1347             $depbase .= '$(DEPDIR)/' . basename ($obj);
1348
1349             # Support for deansified files in subdirectories is ugly
1350             # enough to deserve an explanation.
1351             #
1352             # A Note about normal ansi2knr processing first.  On
1353             #
1354             #   AUTOMAKE_OPTIONS = ansi2knr
1355             #   bin_PROGRAMS = foo
1356             #   foo_SOURCES = foo.c
1357             #
1358             # we generate rules similar to:
1359             #
1360             #   foo: foo$U.o; link ...
1361             #   foo$U.o: foo$U.c; compile ...
1362             #   foo_.c: foo.c; ansi2knr ...
1363             #
1364             # this is fairly compact, and will call ansi2knr depending
1365             # on the value of $U (`' or `_').
1366             #
1367             # It's harder with subdir sources. On
1368             #
1369             #   AUTOMAKE_OPTIONS = ansi2knr
1370             #   bin_PROGRAMS = foo
1371             #   foo_SOURCES = sub/foo.c
1372             #
1373             # we have to create foo_.c in the current directory.
1374             # (Unless the user asks 'subdir-objects'.)  This is important
1375             # in case the same file (`foo.c') is compiled from other
1376             # directories with different cpp options: foo_.c would
1377             # be preprocessed for only one set of options if it were
1378             # put in the subdirectory.
1379             #
1380             # Because foo$U.o must be built from either foo_.c or
1381             # sub/foo.c we can't be as concise as in the first example.
1382             # Instead we output
1383             #
1384             #   foo: foo$U.o; link ...
1385             #   foo_.o: foo_.c; compile ...
1386             #   foo.o: sub/foo.c; compile ...
1387             #   foo_.c: foo.c; ansi2knr ...
1388             #
1389             # This is why we'll now transform $rule_file twice
1390             # if we detect this case.
1391             # A first time we output the compile rule with `$U'
1392             # replaced by `_' and the source directory removed,
1393             # and another time we simply remove `$U'.
1394             #
1395             # Note that at this point $source (as computed by
1396             # &handle_single_transform) is `sub/foo$U.c'.
1397             # This can be confusing: it can be used as-is when
1398             # subdir-objects is set, otherwise you have to know
1399             # it really means `foo_.c' or `sub/foo.c'.
1400             my $objdir = dirname ($obj);
1401             my $srcdir = dirname ($source);
1402             if ($lang->ansi && $obj =~ /\$U/)
1403               {
1404                 prog_error "`$obj' contains \$U, but `$source' doesn't."
1405                   if $source !~ /\$U/;
1406
1407                 (my $source_ = $source) =~ s/\$U/_/g;
1408                 # Output an additional rule if _.c and .c are not in
1409                 # the same directory.  (_.c is always in $objdir.)
1410                 if ($objdir ne $srcdir)
1411                   {
1412                     (my $obj_ = $obj) =~ s/\$U/_/g;
1413                     (my $depbase_ = $depbase) =~ s/\$U/_/g;
1414                     $source_ = basename ($source_);
1415
1416                     $output_rules .=
1417                       file_contents ($rule_file,
1418                                      new Automake::Location,
1419                                      %transform,
1420                                      GENERIC   => 0,
1421
1422                                      DEPBASE   => $depbase_,
1423                                      BASE      => $obj_,
1424                                      SOURCE    => $source_,
1425                                      SOURCEFLAG => $sourceflags{$srcext} || '',
1426                                      OBJ       => "$obj_$myext",
1427                                      OBJOBJ    => "$obj_.obj",
1428                                      LTOBJ     => "$obj_.lo",
1429
1430                                      COMPILE   => $obj_compile,
1431                                      LTCOMPILE => $obj_ltcompile,
1432                                      -o        => $output_flag,
1433                                      %file_transform);
1434                     $obj =~ s/\$U//g;
1435                     $depbase =~ s/\$U//g;
1436                     $source =~ s/\$U//g;
1437                   }
1438               }
1439
1440             $output_rules .=
1441               file_contents ($rule_file,
1442                              new Automake::Location,
1443                              %transform,
1444                              GENERIC   => 0,
1445
1446                              DEPBASE   => $depbase,
1447                              BASE      => $obj,
1448                              SOURCE    => $source,
1449                              SOURCEFLAG => $sourceflags{$srcext} || '',
1450                              # Use $myext and not `.o' here, in case
1451                              # we are actually building a new source
1452                              # file -- e.g. via yacc.
1453                              OBJ       => "$obj$myext",
1454                              OBJOBJ    => "$obj.obj",
1455                              LTOBJ     => "$obj.lo",
1456
1457                              COMPILE   => $obj_compile,
1458                              LTCOMPILE => $obj_ltcompile,
1459                              -o        => $output_flag,
1460                              %file_transform);
1461         }
1462
1463         # The rest of the loop is done once per language.
1464         next if defined $done{$lang};
1465         $done{$lang} = 1;
1466
1467         # Load the language dependent Makefile chunks.
1468         my %lang = map { uc ($_) => 0 } keys %languages;
1469         $lang{uc ($lang->name)} = 1;
1470         $output_rules .= file_contents ('lang-compile',
1471                                         new Automake::Location,
1472                                         %transform, %lang);
1473
1474         # If the source to a program consists entirely of code from a
1475         # `pure' language, for instance C++ or Fortran 77, then we
1476         # don't need the C compiler code.  However if we run into
1477         # something unusual then we do generate the C code.  There are
1478         # probably corner cases here that do not work properly.
1479         # People linking Java code to Fortran code deserve pain.
1480         $needs_c ||= ! $lang->pure;
1481
1482         define_compiler_variable ($lang)
1483           if ($lang->compile);
1484
1485         define_linker_variable ($lang)
1486           if ($lang->link);
1487
1488         require_variables ("$am_file.am", $lang->Name . " source seen",
1489                            TRUE, @{$lang->config_vars});
1490
1491         # Call the finisher.
1492         $lang->finish;
1493
1494         # Flags listed in `->flags' are user variables (per GNU Standards),
1495         # they should not be overridden in the Makefile...
1496         my @dont_override = @{$lang->flags};
1497         # ... and so is LDFLAGS.
1498         push @dont_override, 'LDFLAGS' if $lang->link;
1499
1500         check_user_variables @dont_override;
1501     }
1502
1503     # If the project is entirely C++ or entirely Fortran 77 (i.e., 1
1504     # suffix rule was learned), don't bother with the C stuff.  But if
1505     # anything else creeps in, then use it.
1506     $needs_c = 1
1507       if $need_link || suffix_rules_count > 1;
1508
1509     if ($needs_c)
1510       {
1511         &define_compiler_variable ($languages{'c'})
1512           unless defined $done{$languages{'c'}};
1513         define_linker_variable ($languages{'c'});
1514       }
1515 }
1516
1517
1518 # append_exeext { PREDICATE } $MACRO
1519 # ----------------------------------
1520 # Append $(EXEEXT) to each filename in $F appearing in the Makefile
1521 # variable $MACRO if &PREDICATE($F) is true.  @substitutions@ are
1522 # ignored.
1523 #
1524 # This is typically used on all filenames of *_PROGRAMS, and filenames
1525 # of TESTS that are programs.
1526 sub append_exeext (&$)
1527 {
1528   my ($pred, $macro) = @_;
1529
1530   transform_variable_recursively
1531     ($macro, $macro, 'am__EXEEXT', 0, INTERNAL,
1532      sub {
1533        my ($subvar, $val, $cond, $full_cond) = @_;
1534        # Append $(EXEEXT) unless the user did it already, or it's a
1535        # @substitution@.
1536        $val .= '$(EXEEXT)'
1537          if $val !~ /(?:\$\(EXEEXT\)$|^[@]\w+[@]$)/ && &$pred ($val);
1538        return $val;
1539      });
1540 }
1541
1542
1543 # Check to make sure a source defined in LIBOBJS is not explicitly
1544 # mentioned.  This is a separate function (as opposed to being inlined
1545 # in handle_source_transform) because it isn't always appropriate to
1546 # do this check.
1547 sub check_libobjs_sources
1548 {
1549   my ($one_file, $unxformed) = @_;
1550
1551   foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1552                       'dist_EXTRA_', 'nodist_EXTRA_')
1553     {
1554       my @files;
1555       my $varname = $prefix . $one_file . '_SOURCES';
1556       my $var = var ($varname);
1557       if ($var)
1558         {
1559           @files = $var->value_as_list_recursive;
1560         }
1561       elsif ($prefix eq '')
1562         {
1563           @files = ($unxformed . '.c');
1564         }
1565       else
1566         {
1567           next;
1568         }
1569
1570       foreach my $file (@files)
1571         {
1572           err_var ($prefix . $one_file . '_SOURCES',
1573                    "automatically discovered file `$file' should not" .
1574                    " be explicitly mentioned")
1575             if defined $libsources{$file};
1576         }
1577     }
1578 }
1579
1580
1581 # @OBJECTS
1582 # handle_single_transform ($VAR, $TOPPARENT, $DERIVED, $OBJ, $FILE, %TRANSFORM)
1583 # -----------------------------------------------------------------------------
1584 # Does much of the actual work for handle_source_transform.
1585 # Arguments are:
1586 #   $VAR is the name of the variable that the source filenames come from
1587 #   $TOPPARENT is the name of the _SOURCES variable which is being processed
1588 #   $DERIVED is the name of resulting executable or library
1589 #   $OBJ is the object extension (e.g., `$U.lo')
1590 #   $FILE the source file to transform
1591 #   %TRANSFORM contains extras arguments to pass to file_contents
1592 #     when producing explicit rules
1593 # Result is a list of the names of objects
1594 # %linkers_used will be updated with any linkers needed
1595 sub handle_single_transform ($$$$$%)
1596 {
1597     my ($var, $topparent, $derived, $obj, $_file, %transform) = @_;
1598     my @files = ($_file);
1599     my @result = ();
1600     my $nonansi_obj = $obj;
1601     $nonansi_obj =~ s/\$U//g;
1602
1603     # Turn sources into objects.  We use a while loop like this
1604     # because we might add to @files in the loop.
1605     while (scalar @files > 0)
1606     {
1607         $_ = shift @files;
1608
1609         # Configure substitutions in _SOURCES variables are errors.
1610         if (/^\@.*\@$/)
1611         {
1612           my $parent_msg = '';
1613           $parent_msg = "\nand is referred to from `$topparent'"
1614             if $topparent ne $var->name;
1615           err_var ($var,
1616                    "`" . $var->name . "' includes configure substitution `$_'"
1617                    . $parent_msg . ";\nconfigure " .
1618                    "substitutions are not allowed in _SOURCES variables");
1619           next;
1620         }
1621
1622         # If the source file is in a subdirectory then the `.o' is put
1623         # into the current directory, unless the subdir-objects option
1624         # is in effect.
1625
1626         # Split file name into base and extension.
1627         next if ! /^(?:(.*)\/)?([^\/]*)($KNOWN_EXTENSIONS_PATTERN)$/;
1628         my $full = $_;
1629         my $directory = $1 || '';
1630         my $base = $2;
1631         my $extension = $3;
1632
1633         # We must generate a rule for the object if it requires its own flags.
1634         my $renamed = 0;
1635         my ($linker, $object);
1636
1637         # This records whether we've seen a derived source file (e.g.
1638         # yacc output).
1639         my $derived_source = 0;
1640
1641         # This holds the `aggregate context' of the file we are
1642         # currently examining.  If the file is compiled with
1643         # per-object flags, then it will be the name of the object.
1644         # Otherwise it will be `AM'.  This is used by the target hook
1645         # language function.
1646         my $aggregate = 'AM';
1647
1648         $extension = &derive_suffix ($extension, $nonansi_obj);
1649         my $lang;
1650         if ($extension_map{$extension} &&
1651             ($lang = $languages{$extension_map{$extension}}))
1652         {
1653             # Found the language, so see what it says.
1654             &saw_extension ($extension);
1655
1656             # Do we have per-executable flags for this executable?
1657             my $have_per_exec_flags = 0;
1658             my @peflags = @{$lang->flags};
1659             push @peflags, 'LIBTOOLFLAGS' if $nonansi_obj eq '.lo';
1660             foreach my $flag (@peflags)
1661               {
1662                 if (set_seen ("${derived}_$flag"))
1663                   {
1664                     $have_per_exec_flags = 1;
1665                     last;
1666                   }
1667               }
1668
1669             # Note: computed subr call.  The language rewrite function
1670             # should return one of the LANG_* constants.  It could
1671             # also return a list whose first value is such a constant
1672             # and whose second value is a new source extension which
1673             # should be applied.  This means this particular language
1674             # generates another source file which we must then process
1675             # further.
1676             my $subr = \&{'lang_' . $lang->name . '_rewrite'};
1677             my ($r, $source_extension)
1678                 = &$subr ($directory, $base, $extension,
1679                           $nonansi_obj, $have_per_exec_flags, $var);
1680             # Skip this entry if we were asked not to process it.
1681             next if $r == LANG_IGNORE;
1682
1683             # Now extract linker and other info.
1684             $linker = $lang->linker;
1685
1686             my $this_obj_ext;
1687             if (defined $source_extension)
1688             {
1689                 $this_obj_ext = $source_extension;
1690                 $derived_source = 1;
1691             }
1692             elsif ($lang->ansi)
1693             {
1694                 $this_obj_ext = $obj;
1695             }
1696             else
1697             {
1698                 $this_obj_ext = $nonansi_obj;
1699             }
1700             $object = $base . $this_obj_ext;
1701
1702             if ($have_per_exec_flags)
1703             {
1704                 # We have a per-executable flag in effect for this
1705                 # object.  In this case we rewrite the object's
1706                 # name to ensure it is unique.
1707
1708                 # We choose the name `DERIVED_OBJECT' to ensure
1709                 # (1) uniqueness, and (2) continuity between
1710                 # invocations.  However, this will result in a
1711                 # name that is too long for losing systems, in
1712                 # some situations.  So we provide _SHORTNAME to
1713                 # override.
1714
1715                 my $dname = $derived;
1716                 my $var = var ($derived . '_SHORTNAME');
1717                 if ($var)
1718                 {
1719                     # FIXME: should use the same Condition as
1720                     # the _SOURCES variable.  But this is really
1721                     # silly overkill -- nobody should have
1722                     # conditional shortnames.
1723                     $dname = $var->variable_value;
1724                 }
1725                 $object = $dname . '-' . $object;
1726
1727                 prog_error ($lang->name . " flags defined without compiler")
1728                   if ! defined $lang->compile;
1729
1730                 $renamed = 1;
1731             }
1732
1733             # If rewrite said it was ok, put the object into a
1734             # subdir.
1735             if ($r == LANG_SUBDIR && $directory ne '')
1736             {
1737                 $object = $directory . '/' . $object;
1738             }
1739
1740             # If the object file has been renamed (because per-target
1741             # flags are used) we cannot compile the file with an
1742             # inference rule: we need an explicit rule.
1743             #
1744             # If the source is in a subdirectory and the object is in
1745             # the current directory, we also need an explicit rule.
1746             #
1747             # If both source and object files are in a subdirectory
1748             # (this happens when the subdir-objects option is used),
1749             # then the inference will work.
1750             #
1751             # The latter case deserves a historical note.  When the
1752             # subdir-objects option was added on 1999-04-11 it was
1753             # thought that inferences rules would work for
1754             # subdirectory objects too.  Later, on 1999-11-22,
1755             # automake was changed to output explicit rules even for
1756             # subdir-objects.  Nobody remembers why, but this occurred
1757             # soon after the merge of the user-dep-gen-branch so it
1758             # might be related.  In late 2003 people complained about
1759             # the size of the generated Makefile.ins (libgcj, with
1760             # 2200+ subdir objects was reported to have a 9MB
1761             # Makefile), so we now rely on inference rules again.
1762             # Maybe we'll run across the same issue as in the past,
1763             # but at least this time we can document it.  However since
1764             # dependency tracking has evolved it is possible that
1765             # our old problem no longer exists.
1766             # Using inference rules for subdir-objects has been tested
1767             # with GNU make, Solaris make, Ultrix make, BSD make,
1768             # HP-UX make, and OSF1 make successfully.
1769             if ($renamed
1770                 || ($directory ne '' && ! option 'subdir-objects')
1771                 # We must also use specific rules for a nodist_ source
1772                 # if its language requests it.
1773                 || ($lang->nodist_specific && ! $transform{'DIST_SOURCE'}))
1774             {
1775                 my $obj_sans_ext = substr ($object, 0,
1776                                            - length ($this_obj_ext));
1777                 my $full_ansi = $full;
1778                 if ($lang->ansi && option 'ansi2knr')
1779                   {
1780                     $full_ansi =~ s/$KNOWN_EXTENSIONS_PATTERN$/\$U$&/;
1781                     $obj_sans_ext .= '$U';
1782                   }
1783
1784                 my @specifics = ($full_ansi, $obj_sans_ext,
1785                                  # Only use $this_obj_ext in the derived
1786                                  # source case because in the other case we
1787                                  # *don't* want $(OBJEXT) to appear here.
1788                                  ($derived_source ? $this_obj_ext : '.o'),
1789                                  $extension);
1790
1791                 # If we renamed the object then we want to use the
1792                 # per-executable flag name.  But if this is simply a
1793                 # subdir build then we still want to use the AM_ flag
1794                 # name.
1795                 if ($renamed)
1796                   {
1797                     unshift @specifics, $derived;
1798                     $aggregate = $derived;
1799                   }
1800                 else
1801                   {
1802                     unshift @specifics, 'AM';
1803                   }
1804
1805                 # Each item on this list is a reference to a list consisting
1806                 # of four values followed by additional transform flags for
1807                 # file_contents.   The four values are the derived flag prefix
1808                 # (e.g. for `foo_CFLAGS', it is `foo'), the name of the
1809                 # source file, the base name of the output file, and
1810                 # the extension for the object file.
1811                 push (@{$lang_specific_files{$lang->name}},
1812                       [@specifics, %transform]);
1813             }
1814         }
1815         elsif ($extension eq $nonansi_obj)
1816         {
1817             # This is probably the result of a direct suffix rule.
1818             # In this case we just accept the rewrite.
1819             $object = "$base$extension";
1820             $object = "$directory/$object" if $directory ne '';
1821             $linker = '';
1822         }
1823         else
1824         {
1825             # No error message here.  Used to have one, but it was
1826             # very unpopular.
1827             # FIXME: we could potentially do more processing here,
1828             # perhaps treating the new extension as though it were a
1829             # new source extension (as above).  This would require
1830             # more restructuring than is appropriate right now.
1831             next;
1832         }
1833
1834         err_am "object `$object' created by `$full' and `$object_map{$object}'"
1835           if (defined $object_map{$object}
1836               && $object_map{$object} ne $full);
1837
1838         my $comp_val = (($object =~ /\.lo$/)
1839                         ? COMPILE_LIBTOOL : COMPILE_ORDINARY);
1840         (my $comp_obj = $object) =~ s/\.lo$/.\$(OBJEXT)/;
1841         if (defined $object_compilation_map{$comp_obj}
1842             && $object_compilation_map{$comp_obj} != 0
1843             # Only see the error once.
1844             && ($object_compilation_map{$comp_obj}
1845                 != (COMPILE_LIBTOOL | COMPILE_ORDINARY))
1846             && $object_compilation_map{$comp_obj} != $comp_val)
1847           {
1848             err_am "object `$comp_obj' created both with libtool and without";
1849           }
1850         $object_compilation_map{$comp_obj} |= $comp_val;
1851
1852         if (defined $lang)
1853         {
1854             # Let the language do some special magic if required.
1855             $lang->target_hook ($aggregate, $object, $full, %transform);
1856         }
1857
1858         if ($derived_source)
1859           {
1860             prog_error ($lang->name . " has automatic dependency tracking")
1861               if $lang->autodep ne 'no';
1862             # Make sure this new source file is handled next.  That will
1863             # make it appear to be at the right place in the list.
1864             unshift (@files, $object);
1865             # Distribute derived sources unless the source they are
1866             # derived from is not.
1867             &push_dist_common ($object)
1868               unless ($topparent =~ /^(?:nobase_)?nodist_/);
1869             next;
1870           }
1871
1872         $linkers_used{$linker} = 1;
1873
1874         push (@result, $object);
1875
1876         if (! defined $object_map{$object})
1877         {
1878             my @dep_list = ();
1879             $object_map{$object} = $full;
1880
1881             # If resulting object is in subdir, we need to make
1882             # sure the subdir exists at build time.
1883             if ($object =~ /\//)
1884             {
1885                 # FIXME: check that $DIRECTORY is somewhere in the
1886                 # project
1887
1888                 # For Java, the way we're handling it right now, a
1889                 # `..' component doesn't make sense.
1890                 if ($lang && $lang->name eq 'java' && $object =~ /(\/|^)\.\.\//)
1891                   {
1892                     err_am "`$full' should not contain a `..' component";
1893                   }
1894
1895                 # Make sure object is removed by `make mostlyclean'.
1896                 $compile_clean_files{$object} = MOSTLY_CLEAN;
1897                 # If we have a libtool object then we also must remove
1898                 # the ordinary .o.
1899                 if ($object =~ /\.lo$/)
1900                 {
1901                     (my $xobj = $object) =~ s,lo$,\$(OBJEXT),;
1902                     $compile_clean_files{$xobj} = MOSTLY_CLEAN;
1903
1904                     # Remove any libtool object in this directory.
1905                     $libtool_clean_directories{$directory} = 1;
1906                 }
1907
1908                 push (@dep_list, require_build_directory ($directory));
1909
1910                 # If we're generating dependencies, we also want
1911                 # to make sure that the appropriate subdir of the
1912                 # .deps directory is created.
1913                 push (@dep_list,
1914                       require_build_directory ($directory . '/$(DEPDIR)'))
1915                   unless option 'no-dependencies';
1916             }
1917
1918             &pretty_print_rule ($object . ':', "\t", @dep_list)
1919                 if scalar @dep_list > 0;
1920         }
1921
1922         # Transform .o or $o file into .P file (for automatic
1923         # dependency code).
1924         if ($lang && $lang->autodep ne 'no')
1925         {
1926             my $depfile = $object;
1927             $depfile =~ s/\.([^.]*)$/.P$1/;
1928             $depfile =~ s/\$\(OBJEXT\)$/o/;
1929             $dep_files{dirname ($depfile) . '/$(DEPDIR)/'
1930                          . basename ($depfile)} = 1;
1931         }
1932     }
1933
1934     return @result;
1935 }
1936
1937
1938 # $LINKER
1939 # define_objects_from_sources ($VAR, $OBJVAR, $NODEFINE, $ONE_FILE,
1940 #                              $OBJ, $PARENT, $TOPPARENT, $WHERE, %TRANSFORM)
1941 # ---------------------------------------------------------------------------
1942 # Define an _OBJECTS variable for a _SOURCES variable (or subvariable)
1943 #
1944 # Arguments are:
1945 #   $VAR is the name of the _SOURCES variable
1946 #   $OBJVAR is the name of the _OBJECTS variable if known (otherwise
1947 #     it will be generated and returned).
1948 #   $NODEFINE is a boolean: if true, $OBJVAR will not be defined (but
1949 #     work done to determine the linker will be).
1950 #   $ONE_FILE is the canonical (transformed) name of object to build
1951 #   $OBJ is the object extension (i.e. either `.o' or `.lo').
1952 #   $TOPPARENT is the _SOURCES variable being processed.
1953 #   $WHERE context into which this definition is done
1954 #   %TRANSFORM extra arguments to pass to file_contents when producing
1955 #     rules
1956 #
1957 # Result is a pair ($LINKER, $OBJVAR):
1958 #    $LINKER is a boolean, true if a linker is needed to deal with the objects
1959 sub define_objects_from_sources ($$$$$$$%)
1960 {
1961   my ($var, $objvar, $nodefine, $one_file,
1962       $obj, $topparent, $where, %transform) = @_;
1963
1964   my $needlinker = "";
1965
1966   transform_variable_recursively
1967     ($var, $objvar, 'am__objects', $nodefine, $where,
1968      # The transform code to run on each filename.
1969      sub {
1970        my ($subvar, $val, $cond, $full_cond) = @_;
1971        my @trans = handle_single_transform ($subvar, $topparent,
1972                                             $one_file, $obj, $val,
1973                                             %transform);
1974        $needlinker = "true" if @trans;
1975        return @trans;
1976      });
1977
1978   return $needlinker;
1979 }
1980
1981
1982 # handle_source_transform ($CANON_TARGET, $TARGET, $OBJEXT, $WHERE, %TRANSFORM)
1983 # -----------------------------------------------------------------------------
1984 # Handle SOURCE->OBJECT transform for one program or library.
1985 # Arguments are:
1986 #   canonical (transformed) name of target to build
1987 #   actual target of object to build
1988 #   object extension (i.e., either `.o' or `$o')
1989 #   location of the source variable
1990 #   extra arguments to pass to file_contents when producing rules
1991 # Return the name of the linker variable that must be used.
1992 # Empty return means just use `LINK'.
1993 sub handle_source_transform ($$$$%)
1994 {
1995     # one_file is canonical name.  unxformed is given name.  obj is
1996     # object extension.
1997     my ($one_file, $unxformed, $obj, $where, %transform) = @_;
1998
1999     my $linker = '';
2000
2001     # No point in continuing if _OBJECTS is defined.
2002     return if reject_var ($one_file . '_OBJECTS',
2003                           $one_file . '_OBJECTS should not be defined');
2004
2005     my %used_pfx = ();
2006     my $needlinker;
2007     %linkers_used = ();
2008     foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
2009                         'dist_EXTRA_', 'nodist_EXTRA_')
2010     {
2011         my $varname = $prefix . $one_file . "_SOURCES";
2012         my $var = var $varname;
2013         next unless $var;
2014
2015         # We are going to define _OBJECTS variables using the prefix.
2016         # Then we glom them all together.  So we can't use the null
2017         # prefix here as we need it later.
2018         my $xpfx = ($prefix eq '') ? 'am_' : $prefix;
2019
2020         # Keep track of which prefixes we saw.
2021         $used_pfx{$xpfx} = 1
2022           unless $prefix =~ /EXTRA_/;
2023
2024         push @sources, "\$($varname)";
2025         push @dist_sources, shadow_unconditionally ($varname, $where)
2026           unless (option ('no-dist') || $prefix =~ /^nodist_/);
2027
2028         $needlinker |=
2029             define_objects_from_sources ($varname,
2030                                          $xpfx . $one_file . '_OBJECTS',
2031                                          $prefix =~ /EXTRA_/,
2032                                          $one_file, $obj, $varname, $where,
2033                                          DIST_SOURCE => ($prefix !~ /^nodist_/),
2034                                          %transform);
2035     }
2036     if ($needlinker)
2037     {
2038         $linker ||= &resolve_linker (%linkers_used);
2039     }
2040
2041     my @keys = sort keys %used_pfx;
2042     if (scalar @keys == 0)
2043     {
2044         # The default source for libfoo.la is libfoo.c, but for
2045         # backward compatibility we first look at libfoo_la.c
2046         my $old_default_source = "$one_file.c";
2047         (my $default_source = $unxformed) =~ s,(\.[^./\\]*)?$,.c,;
2048         if ($old_default_source ne $default_source
2049             && (rule $old_default_source
2050                 || rule '$(srcdir)/' . $old_default_source
2051                 || rule '${srcdir}/' . $old_default_source
2052                 || -f $old_default_source))
2053           {
2054             my $loc = $where->clone;
2055             $loc->pop_context;
2056             msg ('obsolete', $loc,
2057                  "the default source for `$unxformed' has been changed "
2058                  . "to `$default_source'.\n(Using `$old_default_source' for "
2059                  . "backward compatibility.)");
2060             $default_source = $old_default_source;
2061           }
2062         # If a rule exists to build this source with a $(srcdir)
2063         # prefix, use that prefix in our variables too.  This is for
2064         # the sake of BSD Make.
2065         if (rule '$(srcdir)/' . $default_source
2066             || rule '${srcdir}/' . $default_source)
2067           {
2068             $default_source = '$(srcdir)/' . $default_source;
2069           }
2070
2071         &define_variable ($one_file . "_SOURCES", $default_source, $where);
2072         push (@sources, $default_source);
2073         push (@dist_sources, $default_source);
2074
2075         %linkers_used = ();
2076         my (@result) =
2077           handle_single_transform ($one_file . '_SOURCES',
2078                                    $one_file . '_SOURCES',
2079                                    $one_file, $obj,
2080                                    $default_source, %transform);
2081         $linker ||= &resolve_linker (%linkers_used);
2082         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @result);
2083     }
2084     else
2085     {
2086         @keys = map { '$(' . $_ . $one_file . '_OBJECTS)' } @keys;
2087         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @keys);
2088     }
2089
2090     # If we want to use `LINK' we must make sure it is defined.
2091     if ($linker eq '')
2092     {
2093         $need_link = 1;
2094     }
2095
2096     return $linker;
2097 }
2098
2099
2100 # handle_lib_objects ($XNAME, $VAR)
2101 # ---------------------------------
2102 # Special-case ALLOCA and LIBOBJS substitutions in _LDADD or _LIBADD variables.
2103 # Also, generate _DEPENDENCIES variable if appropriate.
2104 # Arguments are:
2105 #   transformed name of object being built, or empty string if no object
2106 #   name of _LDADD/_LIBADD-type variable to examine
2107 # Returns 1 if LIBOBJS seen, 0 otherwise.
2108 sub handle_lib_objects
2109 {
2110   my ($xname, $varname) = @_;
2111
2112   my $var = var ($varname);
2113   prog_error "handle_lib_objects: `$varname' undefined"
2114     unless $var;
2115   prog_error "handle_lib_objects: unexpected variable name `$varname'"
2116     unless $varname =~ /^(.*)(?:LIB|LD)ADD$/;
2117   my $prefix = $1 || 'AM_';
2118
2119   my $seen_libobjs = 0;
2120   my $flagvar = 0;
2121
2122   transform_variable_recursively
2123     ($varname, $xname . '_DEPENDENCIES', 'am__DEPENDENCIES',
2124      ! $xname, INTERNAL,
2125      # Transformation function, run on each filename.
2126      sub {
2127        my ($subvar, $val, $cond, $full_cond) = @_;
2128
2129        if ($val =~ /^-/)
2130          {
2131            # Skip -lfoo and -Ldir silently; these are explicitly allowed.
2132            if ($val !~ /^-[lL]/ &&
2133                # Skip -dlopen and -dlpreopen; these are explicitly allowed
2134                # for Libtool libraries or programs.  (Actually we are a bit
2135                # laxe here since this code also applies to non-libtool
2136                # libraries or programs, for which -dlopen and -dlopreopen
2137                # are pure nonsense.  Diagnosing this doesn't seems very
2138                # important: the developer will quickly get complaints from
2139                # the linker.)
2140                $val !~ /^-dl(?:pre)?open$/ &&
2141                # Only get this error once.
2142                ! $flagvar)
2143              {
2144                $flagvar = 1;
2145                # FIXME: should display a stack of nested variables
2146                # as context when $var != $subvar.
2147                err_var ($var, "linker flags such as `$val' belong in "
2148                         . "`${prefix}LDFLAGS");
2149              }
2150            return ();
2151          }
2152        elsif ($val !~ /^\@.*\@$/)
2153          {
2154            # Assume we have a file of some sort, and output it into the
2155            # dependency variable.  Autoconf substitutions are not output;
2156            # rarely is a new dependency substituted into e.g. foo_LDADD
2157            # -- but bad things (e.g. -lX11) are routinely substituted.
2158            # Note that LIBOBJS and ALLOCA are exceptions to this rule,
2159            # and handled specially below.
2160            return $val;
2161          }
2162        elsif ($val =~ /^\@(LT)?LIBOBJS\@$/)
2163          {
2164            handle_LIBOBJS ($subvar, $cond, $1);
2165            $seen_libobjs = 1;
2166            return $val;
2167          }
2168        elsif ($val =~ /^\@(LT)?ALLOCA\@$/)
2169          {
2170            handle_ALLOCA ($subvar, $cond, $1);
2171            return $val;
2172          }
2173        else
2174          {
2175            return ();
2176          }
2177      });
2178
2179   return $seen_libobjs;
2180 }
2181
2182 # handle_LIBOBJS_or_ALLOCA ($VAR)
2183 # -------------------------------
2184 # Definitions common to LIBOBJS and ALLOCA.
2185 # VAR should be one of LIBOBJS, LTLIBOBJS, ALLOCA, or LTALLOCA.
2186 sub handle_LIBOBJS_or_ALLOCA ($)
2187 {
2188   my ($var) = @_;
2189
2190   my $dir = '';
2191
2192   # If LIBOBJS files must be built in another directory we have
2193   # to define LIBOBJDIR and ensure the files get cleaned.
2194   # Otherwise LIBOBJDIR can be left undefined, and the cleaning
2195   # is achieved by `rm -f *.$(OBJEXT)' in compile.am.
2196   if ($config_libobj_dir
2197       && $relative_dir ne $config_libobj_dir)
2198     {
2199       if (option 'subdir-objects')
2200         {
2201           # In the top-level Makefile we do not use $(top_builddir), because
2202           # we are already there, and since the targets are built without
2203           # a $(top_builddir), it helps BSD Make to match them with
2204           # dependencies.
2205           $dir = "$config_libobj_dir/" if $config_libobj_dir ne '.';
2206           $dir = "$topsrcdir/$dir" if $relative_dir ne '.';
2207           define_variable ('LIBOBJDIR', "$dir", INTERNAL);
2208           $clean_files{"\$($var)"} = MOSTLY_CLEAN;
2209           # If LTLIBOBJS is used, we must also clear LIBOBJS (which might
2210           # be created by libtool as a side-effect of creating LTLIBOBJS).
2211           $clean_files{"\$($var)"} = MOSTLY_CLEAN if $var =~ s/^LT//;
2212         }
2213       else
2214         {
2215           error ("`\$($var)' cannot be used outside `$config_libobj_dir' if"
2216                  . " `subdir-objects' is not set");
2217         }
2218     }
2219
2220   return $dir;
2221 }
2222
2223 sub handle_LIBOBJS ($$$)
2224 {
2225   my ($var, $cond, $lt) = @_;
2226   my $myobjext = $lt ? 'lo' : 'o';
2227   $lt ||= '';
2228
2229   $var->requires_variables ("\@${lt}LIBOBJS\@ used", $lt . 'LIBOBJS')
2230     if ! keys %libsources;
2231
2232   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}LIBOBJS";
2233
2234   foreach my $iter (keys %libsources)
2235     {
2236       if ($iter =~ /\.[cly]$/)
2237         {
2238           &saw_extension ($&);
2239           &saw_extension ('.c');
2240         }
2241
2242       if ($iter =~ /\.h$/)
2243         {
2244           require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2245         }
2246       elsif ($iter ne 'alloca.c')
2247         {
2248           my $rewrite = $iter;
2249           $rewrite =~ s/\.c$/.P$myobjext/;
2250           $dep_files{$dir . '$(DEPDIR)/' . $rewrite} = 1;
2251           $rewrite = "^" . quotemeta ($iter) . "\$";
2252           # Only require the file if it is not a built source.
2253           my $bs = var ('BUILT_SOURCES');
2254           if (! $bs || ! grep (/$rewrite/, $bs->value_as_list_recursive))
2255             {
2256               require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2257             }
2258         }
2259     }
2260 }
2261
2262 sub handle_ALLOCA ($$$)
2263 {
2264   my ($var, $cond, $lt) = @_;
2265   my $myobjext = $lt ? 'lo' : 'o';
2266   $lt ||= '';
2267   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}ALLOCA";
2268
2269   $var->requires_variables ("\@${lt}ALLOCA\@ used", $lt . 'ALLOCA');
2270   $dep_files{$dir . '$(DEPDIR)/alloca.P' . $myobjext} = 1;
2271   require_libsource_with_macro ($cond, $var, FOREIGN, 'alloca.c');
2272   &saw_extension ('.c');
2273 }
2274
2275 # Canonicalize the input parameter
2276 sub canonicalize
2277 {
2278     my ($string) = @_;
2279     $string =~ tr/A-Za-z0-9_\@/_/c;
2280     return $string;
2281 }
2282
2283 # Canonicalize a name, and check to make sure the non-canonical name
2284 # is never used.  Returns canonical name.  Arguments are name and a
2285 # list of suffixes to check for.
2286 sub check_canonical_spelling
2287 {
2288   my ($name, @suffixes) = @_;
2289
2290   my $xname = &canonicalize ($name);
2291   if ($xname ne $name)
2292     {
2293       foreach my $xt (@suffixes)
2294         {
2295           reject_var ("$name$xt", "use `$xname$xt', not `$name$xt'");
2296         }
2297     }
2298
2299   return $xname;
2300 }
2301
2302
2303 # handle_compile ()
2304 # -----------------
2305 # Set up the compile suite.
2306 sub handle_compile ()
2307 {
2308     return
2309       unless $get_object_extension_was_run;
2310
2311     # Boilerplate.
2312     my $default_includes = '';
2313     if (! option 'nostdinc')
2314       {
2315         my @incs = ('-I.', subst ('am__isrc'));
2316
2317         my $var = var 'CONFIG_HEADER';
2318         if ($var)
2319           {
2320             foreach my $hdr (split (' ', $var->variable_value))
2321               {
2322                 push @incs, '-I' . dirname ($hdr);
2323               }
2324           }
2325         # We want `-I. -I$(srcdir)', but the latter -I is redundant
2326         # and unaesthetic in non-VPATH builds.  We use `-I.@am__isrc@`
2327         # instead.  It will be replaced by '-I.' or '-I. -I$(srcdir)'.
2328         # Items in CONFIG_HEADER are never in $(srcdir) so it is safe
2329         # to just put @am__isrc@ right after `-I.', without a space.
2330         ($default_includes = ' ' . uniq (@incs)) =~ s/ @/@/;
2331         print "D: $default_includes";
2332       }
2333
2334     my (@mostly_rms, @dist_rms);
2335     foreach my $item (sort keys %compile_clean_files)
2336     {
2337         if ($compile_clean_files{$item} == MOSTLY_CLEAN)
2338         {
2339             push (@mostly_rms, "\t-rm -f $item");
2340         }
2341         elsif ($compile_clean_files{$item} == DIST_CLEAN)
2342         {
2343             push (@dist_rms, "\t-rm -f $item");
2344         }
2345         else
2346         {
2347           prog_error 'invalid entry in %compile_clean_files';
2348         }
2349     }
2350
2351     my ($coms, $vars, $rules) =
2352       &file_contents_internal (1, "$libdir/am/compile.am",
2353                                new Automake::Location,
2354                                ('DEFAULT_INCLUDES' => $default_includes,
2355                                 'MOSTLYRMS' => join ("\n", @mostly_rms),
2356                                 'DISTRMS' => join ("\n", @dist_rms)));
2357     $output_vars .= $vars;
2358     $output_rules .= "$coms$rules";
2359
2360     # Check for automatic de-ANSI-fication.
2361     if (option 'ansi2knr')
2362       {
2363         my ($ansi2knr_filename, $ansi2knr_where) = @{option 'ansi2knr'};
2364         my $ansi2knr_dir = '';
2365
2366         require_variables ($ansi2knr_where, "option `ansi2knr' is used",
2367                            TRUE, "ANSI2KNR", "U");
2368
2369         # topdir is where ansi2knr should be.
2370         if ($ansi2knr_filename eq 'ansi2knr')
2371           {
2372             # Only require ansi2knr files if they should appear in
2373             # this directory.
2374             require_file ($ansi2knr_where, FOREIGN,
2375                           'ansi2knr.c', 'ansi2knr.1');
2376
2377             # ansi2knr needs to be built before subdirs, so unshift it.
2378             unshift (@all, '$(ANSI2KNR)');
2379           }
2380         else
2381           {
2382             $ansi2knr_dir = dirname ($ansi2knr_filename);
2383           }
2384
2385         $output_rules .= &file_contents ('ansi2knr',
2386                                          new Automake::Location,
2387                                          'ANSI2KNR-DIR' => $ansi2knr_dir);
2388
2389     }
2390 }
2391
2392 # handle_libtool ()
2393 # -----------------
2394 # Handle libtool rules.
2395 sub handle_libtool
2396 {
2397   return unless var ('LIBTOOL');
2398
2399   # Libtool requires some files, but only at top level.
2400   # (Starting with Libtool 2.0 we do not have to bother.  These
2401   # requirements are done with AC_REQUIRE_AUX_FILE.)
2402   require_conf_file_with_macro (TRUE, 'LIBTOOL', FOREIGN, @libtool_files)
2403     if $relative_dir eq '.' && ! $libtool_new_api;
2404
2405   my @libtool_rms;
2406   foreach my $item (sort keys %libtool_clean_directories)
2407     {
2408       my $dir = ($item eq '.') ? '' : "$item/";
2409       # .libs is for Unix, _libs for DOS.
2410       push (@libtool_rms, "\t-rm -rf ${dir}.libs ${dir}_libs");
2411     }
2412
2413   check_user_variables 'LIBTOOLFLAGS';
2414
2415   # Output the libtool compilation rules.
2416   $output_rules .= &file_contents ('libtool',
2417                                    new Automake::Location,
2418                                    LTRMS => join ("\n", @libtool_rms));
2419 }
2420
2421 # handle_programs ()
2422 # ------------------
2423 # Handle C programs.
2424 sub handle_programs
2425 {
2426   my @proglist = &am_install_var ('progs', 'PROGRAMS',
2427                                   'bin', 'sbin', 'libexec', 'pkglib',
2428                                   'noinst', 'check');
2429   return if ! @proglist;
2430
2431   my $seen_global_libobjs =
2432     var ('LDADD') && &handle_lib_objects ('', 'LDADD');
2433
2434   foreach my $pair (@proglist)
2435     {
2436       my ($where, $one_file) = @$pair;
2437
2438       my $seen_libobjs = 0;
2439       my $obj = get_object_extension '.$(OBJEXT)';
2440
2441       # Strip any $(EXEEXT) suffix the user might have added, or this
2442       # will confuse &handle_source_transform and &check_canonical_spelling.
2443       # We'll add $(EXEEXT) back later anyway.
2444       $one_file =~ s/\$\(EXEEXT\)$//;
2445
2446       $known_programs{$one_file} = $where;
2447
2448       # Canonicalize names and check for misspellings.
2449       my $xname = &check_canonical_spelling ($one_file, '_LDADD', '_LDFLAGS',
2450                                              '_SOURCES', '_OBJECTS',
2451                                              '_DEPENDENCIES');
2452
2453       $where->push_context ("while processing program `$one_file'");
2454       $where->set (INTERNAL->get);
2455
2456       my $linker = &handle_source_transform ($xname, $one_file, $obj, $where,
2457                                              NONLIBTOOL => 1, LIBTOOL => 0);
2458
2459       if (var ($xname . "_LDADD"))
2460         {
2461           $seen_libobjs = &handle_lib_objects ($xname, $xname . '_LDADD');
2462         }
2463       else
2464         {
2465           # User didn't define prog_LDADD override.  So do it.
2466           &define_variable ($xname . '_LDADD', '$(LDADD)', $where);
2467
2468           # This does a bit too much work.  But we need it to
2469           # generate _DEPENDENCIES when appropriate.
2470           if (var ('LDADD'))
2471             {
2472               $seen_libobjs = &handle_lib_objects ($xname, 'LDADD');
2473             }
2474         }
2475
2476       reject_var ($xname . '_LIBADD',
2477                   "use `${xname}_LDADD', not `${xname}_LIBADD'");
2478
2479       set_seen ($xname . '_DEPENDENCIES');
2480       set_seen ($xname . '_LDFLAGS');
2481
2482       # Determine program to use for link.
2483       my $xlink = &define_per_target_linker_variable ($linker, $xname);
2484
2485       # If the resulting program lies into a subdirectory,
2486       # make sure this directory will exist.
2487       my $dirstamp = require_build_directory_maybe ($one_file);
2488
2489       $libtool_clean_directories{dirname ($one_file)} = 1;
2490
2491       $output_rules .= &file_contents ('program',
2492                                        $where,
2493                                        PROGRAM  => $one_file,
2494                                        XPROGRAM => $xname,
2495                                        XLINK    => $xlink,
2496                                        DIRSTAMP => $dirstamp,
2497                                        EXEEXT   => '$(EXEEXT)');
2498
2499       if ($seen_libobjs || $seen_global_libobjs)
2500         {
2501           if (var ($xname . '_LDADD'))
2502             {
2503               &check_libobjs_sources ($xname, $xname . '_LDADD');
2504             }
2505           elsif (var ('LDADD'))
2506             {
2507               &check_libobjs_sources ($xname, 'LDADD');
2508             }
2509         }
2510     }
2511 }
2512
2513
2514 # handle_libraries ()
2515 # -------------------
2516 # Handle libraries.
2517 sub handle_libraries
2518 {
2519   my @liblist = &am_install_var ('libs', 'LIBRARIES',
2520                                  'lib', 'pkglib', 'noinst', 'check');
2521   return if ! @liblist;
2522
2523   my @prefix = am_primary_prefixes ('LIBRARIES', 0, 'lib', 'pkglib',
2524                                     'noinst', 'check');
2525
2526   if (@prefix)
2527     {
2528       my $var = rvar ($prefix[0] . '_LIBRARIES');
2529       $var->requires_variables ('library used', 'RANLIB');
2530     }
2531
2532   &define_variable ('AR', 'ar', INTERNAL);
2533   &define_variable ('ARFLAGS', 'cru', INTERNAL);
2534
2535   foreach my $pair (@liblist)
2536     {
2537       my ($where, $onelib) = @$pair;
2538
2539       my $seen_libobjs = 0;
2540       # Check that the library fits the standard naming convention.
2541       my $bn = basename ($onelib);
2542       if ($bn !~ /^lib.*\.a$/)
2543         {
2544           $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.a/;
2545           my $suggestion = dirname ($onelib) . "/$bn";
2546           $suggestion =~ s|^\./||g;
2547           msg ('error-gnu/warn', $where,
2548                "`$onelib' is not a standard library name\n"
2549                . "did you mean `$suggestion'?")
2550         }
2551
2552       $where->push_context ("while processing library `$onelib'");
2553       $where->set (INTERNAL->get);
2554
2555       my $obj = get_object_extension '.$(OBJEXT)';
2556
2557       # Canonicalize names and check for misspellings.
2558       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_SOURCES',
2559                                             '_OBJECTS', '_DEPENDENCIES',
2560                                             '_AR');
2561
2562       if (! var ($xlib . '_AR'))
2563         {
2564           &define_variable ($xlib . '_AR', '$(AR) $(ARFLAGS)', $where);
2565         }
2566
2567       # Generate support for conditional object inclusion in
2568       # libraries.
2569       if (var ($xlib . '_LIBADD'))
2570         {
2571           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2572             {
2573               $seen_libobjs = 1;
2574             }
2575         }
2576       else
2577         {
2578           &define_variable ($xlib . "_LIBADD", '', $where);
2579         }
2580
2581       reject_var ($xlib . '_LDADD',
2582                   "use `${xlib}_LIBADD', not `${xlib}_LDADD'");
2583
2584       # Make sure we at look at this.
2585       set_seen ($xlib . '_DEPENDENCIES');
2586
2587       &handle_source_transform ($xlib, $onelib, $obj, $where,
2588                                 NONLIBTOOL => 1, LIBTOOL => 0);
2589
2590       # If the resulting library lies into a subdirectory,
2591       # make sure this directory will exist.
2592       my $dirstamp = require_build_directory_maybe ($onelib);
2593
2594       $output_rules .= &file_contents ('library',
2595                                        $where,
2596                                        LIBRARY  => $onelib,
2597                                        XLIBRARY => $xlib,
2598                                        DIRSTAMP => $dirstamp);
2599
2600       if ($seen_libobjs)
2601         {
2602           if (var ($xlib . '_LIBADD'))
2603             {
2604               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2605             }
2606         }
2607     }
2608 }
2609
2610
2611 # handle_ltlibraries ()
2612 # ---------------------
2613 # Handle shared libraries.
2614 sub handle_ltlibraries
2615 {
2616   my @liblist = &am_install_var ('ltlib', 'LTLIBRARIES',
2617                                  'noinst', 'lib', 'pkglib', 'check');
2618   return if ! @liblist;
2619
2620   my @prefix = am_primary_prefixes ('LTLIBRARIES', 0, 'lib', 'pkglib',
2621                                     'noinst', 'check');
2622
2623   if (@prefix)
2624     {
2625       my $var = rvar ($prefix[0] . '_LTLIBRARIES');
2626       $var->requires_variables ('Libtool library used', 'LIBTOOL');
2627     }
2628
2629   my %instdirs = ();
2630   my %instconds = ();
2631   my %liblocations = ();        # Location (in Makefile.am) of each library.
2632
2633   foreach my $key (@prefix)
2634     {
2635       # Get the installation directory of each library.
2636       (my $dir = $key) =~ s/^nobase_//;
2637       my $var = rvar ($key . '_LTLIBRARIES');
2638
2639       # We reject libraries which are installed in several places
2640       # in the same condition, because we can only specify one
2641       # `-rpath' option.
2642       $var->traverse_recursively
2643         (sub
2644          {
2645            my ($var, $val, $cond, $full_cond) = @_;
2646            my $hcond = $full_cond->human;
2647            my $where = $var->rdef ($cond)->location;
2648            # A library cannot be installed in different directory
2649            # in overlapping conditions.
2650            if (exists $instconds{$val})
2651              {
2652                my ($msg, $acond) =
2653                  $instconds{$val}->ambiguous_p ($val, $full_cond);
2654
2655                if ($msg)
2656                  {
2657                    error ($where, $msg, partial => 1);
2658
2659                    my $dirtxt = "installed in `$dir'";
2660                    $dirtxt = "built for `$dir'"
2661                      if $dir eq 'EXTRA' || $dir eq 'noinst' || $dir eq 'check';
2662                    my $dircond =
2663                      $full_cond->true ? "" : " in condition $hcond";
2664
2665                    error ($where, "`$val' should be $dirtxt$dircond ...",
2666                           partial => 1);
2667
2668                    my $hacond = $acond->human;
2669                    my $adir = $instdirs{$val}{$acond};
2670                    my $adirtxt = "installed in `$adir'";
2671                    $adirtxt = "built for `$adir'"
2672                      if ($adir eq 'EXTRA' || $adir eq 'noinst'
2673                          || $adir eq 'check');
2674                    my $adircond = $acond->true ? "" : " in condition $hacond";
2675
2676                    my $onlyone = ($dir ne $adir) ?
2677                      ("\nLibtool libraries can be built for only one "
2678                       . "destination.") : "";
2679
2680                    error ($liblocations{$val}{$acond},
2681                           "... and should also be $adirtxt$adircond.$onlyone");
2682                    return;
2683                  }
2684              }
2685            else
2686              {
2687                $instconds{$val} = new Automake::DisjConditions;
2688              }
2689            $instdirs{$val}{$full_cond} = $dir;
2690            $liblocations{$val}{$full_cond} = $where;
2691            $instconds{$val} = $instconds{$val}->merge ($full_cond);
2692          },
2693          sub
2694          {
2695            return ();
2696          },
2697          skip_ac_subst => 1);
2698     }
2699
2700   foreach my $pair (@liblist)
2701     {
2702       my ($where, $onelib) = @$pair;
2703
2704       my $seen_libobjs = 0;
2705       my $obj = get_object_extension '.lo';
2706
2707       # Canonicalize names and check for misspellings.
2708       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_LDFLAGS',
2709                                             '_SOURCES', '_OBJECTS',
2710                                             '_DEPENDENCIES');
2711
2712       # Check that the library fits the standard naming convention.
2713       my $libname_rx = '^lib.*\.la';
2714       my $ldvar = var ("${xlib}_LDFLAGS") || var ('AM_LDFLAGS');
2715       my $ldvar2 = var ('LDFLAGS');
2716       if (($ldvar && grep (/-module/, $ldvar->value_as_list_recursive))
2717           || ($ldvar2 && grep (/-module/, $ldvar2->value_as_list_recursive)))
2718         {
2719           # Relax name checking for libtool modules.
2720           $libname_rx = '\.la';
2721         }
2722
2723       my $bn = basename ($onelib);
2724       if ($bn !~ /$libname_rx$/)
2725         {
2726           my $type = 'library';
2727           if ($libname_rx eq '\.la')
2728             {
2729               $bn =~ s/^(lib|)(.*?)(?:\.[^.]*)?$/$1$2.la/;
2730               $type = 'module';
2731             }
2732           else
2733             {
2734               $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.la/;
2735             }
2736           my $suggestion = dirname ($onelib) . "/$bn";
2737           $suggestion =~ s|^\./||g;
2738           msg ('error-gnu/warn', $where,
2739                "`$onelib' is not a standard libtool $type name\n"
2740                . "did you mean `$suggestion'?")
2741         }
2742
2743       $where->push_context ("while processing Libtool library `$onelib'");
2744       $where->set (INTERNAL->get);
2745
2746       # Make sure we look at these.
2747       set_seen ($xlib . '_LDFLAGS');
2748       set_seen ($xlib . '_DEPENDENCIES');
2749
2750       # Generate support for conditional object inclusion in
2751       # libraries.
2752       if (var ($xlib . '_LIBADD'))
2753         {
2754           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2755             {
2756               $seen_libobjs = 1;
2757             }
2758         }
2759       else
2760         {
2761           &define_variable ($xlib . "_LIBADD", '', $where);
2762         }
2763
2764       reject_var ("${xlib}_LDADD",
2765                   "use `${xlib}_LIBADD', not `${xlib}_LDADD'");
2766
2767
2768       my $linker = &handle_source_transform ($xlib, $onelib, $obj, $where,
2769                                              NONLIBTOOL => 0, LIBTOOL => 1);
2770
2771       # Determine program to use for link.
2772       my $xlink = &define_per_target_linker_variable ($linker, $xlib);
2773
2774       my $rpathvar = "am_${xlib}_rpath";
2775       my $rpath = "\$($rpathvar)";
2776       foreach my $rcond ($instconds{$onelib}->conds)
2777         {
2778           my $val;
2779           if ($instdirs{$onelib}{$rcond} eq 'EXTRA'
2780               || $instdirs{$onelib}{$rcond} eq 'noinst'
2781               || $instdirs{$onelib}{$rcond} eq 'check')
2782             {
2783               # It's an EXTRA_ library, so we can't specify -rpath,
2784               # because we don't know where the library will end up.
2785               # The user probably knows, but generally speaking automake
2786               # doesn't -- and in fact configure could decide
2787               # dynamically between two different locations.
2788               $val = '';
2789             }
2790           else
2791             {
2792               $val = ('-rpath $(' . $instdirs{$onelib}{$rcond} . 'dir)');
2793             }
2794           if ($rcond->true)
2795             {
2796               # If $rcond is true there is only one condition and
2797               # there is no point defining an helper variable.
2798               $rpath = $val;
2799             }
2800           else
2801             {
2802               define_pretty_variable ($rpathvar, $rcond, INTERNAL, $val);
2803             }
2804         }
2805
2806       # If the resulting library lies into a subdirectory,
2807       # make sure this directory will exist.
2808       my $dirstamp = require_build_directory_maybe ($onelib);
2809
2810       # Remember to cleanup .libs/ in this directory.
2811       my $dirname = dirname $onelib;
2812       $libtool_clean_directories{$dirname} = 1;
2813
2814       $output_rules .= &file_contents ('ltlibrary',
2815                                        $where,
2816                                        LTLIBRARY  => $onelib,
2817                                        XLTLIBRARY => $xlib,
2818                                        RPATH      => $rpath,
2819                                        XLINK      => $xlink,
2820                                        DIRSTAMP   => $dirstamp);
2821       if ($seen_libobjs)
2822         {
2823           if (var ($xlib . '_LIBADD'))
2824             {
2825               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2826             }
2827         }
2828     }
2829 }
2830
2831 # See if any _SOURCES variable were misspelled.
2832 sub check_typos ()
2833 {
2834   # It is ok if the user sets this particular variable.
2835   set_seen 'AM_LDFLAGS';
2836
2837   foreach my $primary ('SOURCES', 'LIBADD', 'LDADD', 'LDFLAGS', 'DEPENDENCIES')
2838     {
2839       foreach my $var (variables $primary)
2840         {
2841           my $varname = $var->name;
2842           # A configure variable is always legitimate.
2843           next if exists $configure_vars{$varname};
2844
2845           for my $cond ($var->conditions->conds)
2846             {
2847               $varname =~ /^(?:nobase_)?(?:dist_|nodist_)?(.*)_[[:alnum:]]+$/;
2848               msg_var ('syntax', $var, "variable `$varname' is defined but no"
2849                        . " program or\nlibrary has `$1' as canonic name"
2850                        . " (possible typo)")
2851                 unless $var->rdef ($cond)->seen;
2852             }
2853         }
2854     }
2855 }
2856
2857
2858 # Handle scripts.
2859 sub handle_scripts
2860 {
2861     # NOTE we no longer automatically clean SCRIPTS, because it is
2862     # useful to sometimes distribute scripts verbatim.  This happens
2863     # e.g. in Automake itself.
2864     &am_install_var ('-candist', 'scripts', 'SCRIPTS',
2865                      'bin', 'sbin', 'libexec', 'pkgdata',
2866                      'noinst', 'check');
2867 }
2868
2869
2870
2871
2872 ## ------------------------ ##
2873 ## Handling Texinfo files.  ##
2874 ## ------------------------ ##
2875
2876 # ($OUTFILE, $VFILE, @CLEAN_FILES)
2877 # &scan_texinfo_file ($FILENAME)
2878 # ------------------------------
2879 # $OUTFILE     - name of the info file produced by $FILENAME.
2880 # $VFILE       - name of the version.texi file used (undef if none).
2881 # @CLEAN_FILES - list of byproducts (indexes etc.)
2882 sub scan_texinfo_file ($)
2883 {
2884   my ($filename) = @_;
2885
2886   # Some of the following extensions are always created, no matter
2887   # whether indexes are used or not.  Other (like cps, fns, ... pgs)
2888   # are only created when they are used.  We used to scan $FILENAME
2889   # for their use, but that is not enough: they could be used in
2890   # included files.  We can't scan included files because we don't
2891   # know the include path.  Therefore we always erase these files, no
2892   # matter whether they are used or not.
2893   #
2894   # (tmp is only created if an @macro is used and a certain e-TeX
2895   # feature is not available.)
2896   my %clean_suffixes =
2897     map { $_ => 1 } (qw(aux log toc tmp
2898                         cp cps
2899                         fn fns
2900                         ky kys
2901                         vr vrs
2902                         tp tps
2903                         pg pgs)); # grep 'new.*index' texinfo.tex
2904
2905   my $texi = new Automake::XFile "< $filename";
2906   verb "reading $filename";
2907
2908   my ($outfile, $vfile);
2909   while ($_ = $texi->getline)
2910     {
2911       if (/^\@setfilename +(\S+)/)
2912         {
2913           # Honor only the first @setfilename.  (It's possible to have
2914           # more occurrences later if the manual shows examples of how
2915           # to use @setfilename...)
2916           next if $outfile;
2917
2918           $outfile = $1;
2919           if ($outfile =~ /\.([^.]+)$/ && $1 ne 'info')
2920             {
2921               error ("$filename:$.",
2922                      "output `$outfile' has unrecognized extension");
2923               return;
2924             }
2925         }
2926       # A "version.texi" file is actually any file whose name matches
2927       # "vers*.texi".
2928       elsif (/^\@include\s+(vers[^.]*\.texi)\s*$/)
2929         {
2930           $vfile = $1;
2931         }
2932
2933       # Try to find new or unused indexes.
2934
2935       # Creating a new category of index.
2936       elsif (/^\@def(code)?index (\w+)/)
2937         {
2938           $clean_suffixes{$2} = 1;
2939           $clean_suffixes{"$2s"} = 1;
2940         }
2941
2942       # Merging an index into an another.
2943       elsif (/^\@syn(code)?index (\w+) (\w+)/)
2944         {
2945           delete $clean_suffixes{"$2s"};
2946           $clean_suffixes{"$3s"} = 1;
2947         }
2948
2949     }
2950
2951   if (! $outfile)
2952     {
2953       err_am "`$filename' missing \@setfilename";
2954       return;
2955     }
2956
2957   my $infobase = basename ($filename);
2958   $infobase =~ s/\.te?xi(nfo)?$//;
2959   return ($outfile, $vfile,
2960           map { "$infobase.$_" } (sort keys %clean_suffixes));
2961 }
2962
2963
2964 # ($DIRSTAMP, @CLEAN_FILES)
2965 # output_texinfo_build_rules ($SOURCE, $DEST, $INSRC, @DEPENDENCIES)
2966 # ------------------------------------------------------------------
2967 # SOURCE - the source Texinfo file
2968 # DEST - the destination Info file
2969 # INSRC - wether DEST should be built in the source tree
2970 # DEPENDENCIES - known dependencies
2971 sub output_texinfo_build_rules ($$$@)
2972 {
2973   my ($source, $dest, $insrc, @deps) = @_;
2974
2975   # Split `a.texi' into `a' and `.texi'.
2976   my ($spfx, $ssfx) = ($source =~ /^(.*?)(\.[^.]*)?$/);
2977   my ($dpfx, $dsfx) = ($dest =~ /^(.*?)(\.[^.]*)?$/);
2978
2979   $ssfx ||= "";
2980   $dsfx ||= "";
2981
2982   # We can output two kinds of rules: the "generic" rules use Make
2983   # suffix rules and are appropriate when $source and $dest do not lie
2984   # in a sub-directory; the "specific" rules are needed in the other
2985   # case.
2986   #
2987   # The former are output only once (this is not really apparent here,
2988   # but just remember that some logic deeper in Automake will not
2989   # output the same rule twice); while the later need to be output for
2990   # each Texinfo source.
2991   my $generic;
2992   my $makeinfoflags;
2993   my $sdir = dirname $source;
2994   if ($sdir eq '.' && dirname ($dest) eq '.')
2995     {
2996       $generic = 1;
2997       $makeinfoflags = '-I $(srcdir)';
2998     }
2999   else
3000     {
3001       $generic = 0;
3002       $makeinfoflags = "-I $sdir -I \$(srcdir)/$sdir";
3003     }
3004
3005   # A directory can contain two kinds of info files: some built in the
3006   # source tree, and some built in the build tree.  The rules are
3007   # different in each case.  However we cannot output two different
3008   # set of generic rules.  Because in-source builds are more usual, we
3009   # use generic rules in this case and fall back to "specific" rules
3010   # for build-dir builds.  (It should not be a problem to invert this
3011   # if needed.)
3012   $generic = 0 unless $insrc;
3013
3014   # We cannot use a suffix rule to build info files with an empty
3015   # extension.  Otherwise we would output a single suffix inference
3016   # rule, with separate dependencies, as in
3017   #
3018   #    .texi:
3019   #             $(MAKEINFO) ...
3020   #    foo.info: foo.texi
3021   #
3022   # which confuse Solaris make.  (See the Autoconf manual for
3023   # details.)  Therefore we use a specific rule in this case.  This
3024   # applies to info files only (dvi and pdf files always have an
3025   # extension).
3026   my $generic_info = ($generic && $dsfx) ? 1 : 0;
3027
3028   # If the resulting file lie into a subdirectory,
3029   # make sure this directory will exist.
3030   my $dirstamp = require_build_directory_maybe ($dest);
3031
3032   my $dipfx = ($insrc ? '$(srcdir)/' : '') . $dpfx;
3033
3034   $output_rules .= file_contents ('texibuild',
3035                                   new Automake::Location,
3036                                   DEPS             => "@deps",
3037                                   DEST_PREFIX      => $dpfx,
3038                                   DEST_INFO_PREFIX => $dipfx,
3039                                   DEST_SUFFIX      => $dsfx,
3040                                   DIRSTAMP         => $dirstamp,
3041                                   GENERIC          => $generic,
3042                                   GENERIC_INFO     => $generic_info,
3043                                   INSRC            => $insrc,
3044                                   MAKEINFOFLAGS    => $makeinfoflags,
3045                                   SOURCE           => ($generic
3046                                                        ? '$<' : $source),
3047                                   SOURCE_INFO      => ($generic_info
3048                                                        ? '$<' : $source),
3049                                   SOURCE_REAL      => $source,
3050                                   SOURCE_SUFFIX    => $ssfx,
3051                                   );
3052   return ($dirstamp, "$dpfx.dvi", "$dpfx.pdf", "$dpfx.ps", "$dpfx.html");
3053 }
3054
3055
3056 # $TEXICLEANS
3057 # handle_texinfo_helper ($info_texinfos)
3058 # --------------------------------------
3059 # Handle all Texinfo source; helper for handle_texinfo.
3060 sub handle_texinfo_helper ($)
3061 {
3062   my ($info_texinfos) = @_;
3063   my (@infobase, @info_deps_list, @texi_deps);
3064   my %versions;
3065   my $done = 0;
3066   my @texi_cleans;
3067
3068   # Build a regex matching user-cleaned files.
3069   my $d = var 'DISTCLEANFILES';
3070   my $c = var 'CLEANFILES';
3071   my @f = ();
3072   push @f, $d->value_as_list_recursive (inner_expand => 1) if $d;
3073   push @f, $c->value_as_list_recursive (inner_expand => 1) if $c;
3074   @f = map { s|[^A-Za-z_0-9*\[\]\-]|\\$&|g; s|\*|[^/]*|g; $_; } @f;
3075   my $user_cleaned_files = '^(?:' . join ('|', @f) . ')$';
3076
3077   foreach my $texi
3078       ($info_texinfos->value_as_list_recursive (inner_expand => 1))
3079     {
3080       my $infobase = $texi;
3081       $infobase =~ s/\.(txi|texinfo|texi)$//;
3082
3083       if ($infobase eq $texi)
3084         {
3085           # FIXME: report line number.
3086           err_am "texinfo file `$texi' has unrecognized extension";
3087           next;
3088         }
3089
3090       push @infobase, $infobase;
3091
3092       # If 'version.texi' is referenced by input file, then include
3093       # automatic versioning capability.
3094       my ($out_file, $vtexi, @clean_files) =
3095         scan_texinfo_file ("$relative_dir/$texi")
3096         or next;
3097       push (@texi_cleans, @clean_files);
3098
3099       # If the Texinfo source is in a subdirectory, create the
3100       # resulting info in this subdirectory.  If it is in the current
3101       # directory, try hard to not prefix "./" because it breaks the
3102       # generic rules.
3103       my $outdir = dirname ($texi) . '/';
3104       $outdir = "" if $outdir eq './';
3105       $out_file =  $outdir . $out_file;
3106
3107       # Until Automake 1.6.3, .info files were built in the
3108       # source tree.  This was an obstacle to the support of
3109       # non-distributed .info files, and non-distributed .texi
3110       # files.
3111       #
3112       # * Non-distributed .texi files is important in some packages
3113       #   where .texi files are built at make time, probably using
3114       #   other binaries built in the package itself, maybe using
3115       #   tools or information found on the build host.  Because
3116       #   these files are not distributed they are always rebuilt
3117       #   at make time; they should therefore not lie in the source
3118       #   directory.  One plan was to support this using
3119       #   nodist_info_TEXINFOS or something similar.  (Doing this
3120       #   requires some sanity checks.  For instance Automake should
3121       #   not allow:
3122       #      dist_info_TEXINFO = foo.texi
3123       #      nodist_foo_TEXINFO = included.texi
3124       #   because a distributed file should never depend on a
3125       #   non-distributed file.)
3126       #
3127       # * If .texi files are not distributed, then .info files should
3128       #   not be distributed either.  There are also cases where one
3129       #   want to distribute .texi files, but do not want to
3130       #   distribute the .info files.  For instance the Texinfo package
3131       #   distributes the tool used to build these files; it would
3132       #   be a waste of space to distribute them.  It's not clear
3133       #   which syntax we should use to indicate that .info files should
3134       #   not be distributed.  Akim Demaille suggested that eventually
3135       #   we switch to a new syntax:
3136       #   |  Maybe we should take some inspiration from what's already
3137       #   |  done in the rest of Automake.  Maybe there is too much
3138       #   |  syntactic sugar here, and you want
3139       #   |     nodist_INFO = bar.info
3140       #   |     dist_bar_info_SOURCES = bar.texi
3141       #   |     bar_texi_DEPENDENCIES = foo.texi
3142       #   |  with a bit of magic to have bar.info represent the whole
3143       #   |  bar*info set.  That's a lot more verbose that the current
3144       #   |  situation, but it is # not new, hence the user has less
3145       #   |  to learn.
3146       #   |
3147       #   |  But there is still too much room for meaningless specs:
3148       #   |     nodist_INFO = bar.info
3149       #   |     dist_bar_info_SOURCES = bar.texi
3150       #   |     dist_PS = bar.ps something-written-by-hand.ps
3151       #   |     nodist_bar_ps_SOURCES = bar.texi
3152       #   |     bar_texi_DEPENDENCIES = foo.texi
3153       #   |  here bar.texi is dist_ in line 2, and nodist_ in 4.
3154       #
3155       # Back to the point, it should be clear that in order to support
3156       # non-distributed .info files, we need to build them in the
3157       # build tree, not in the source tree (non-distributed .texi
3158       # files are less of a problem, because we do not output build
3159       # rules for them).  In Automake 1.7 .info build rules have been
3160       # largely cleaned up so that .info files get always build in the
3161       # build tree, even when distributed.  The idea was that
3162       #   (1) if during a VPATH build the .info file was found to be
3163       #       absent or out-of-date (in the source tree or in the
3164       #       build tree), Make would rebuild it in the build tree.
3165       #       If an up-to-date source-tree of the .info file existed,
3166       #       make would not rebuild it in the build tree.
3167       #   (2) having two copies of .info files, one in the source tree
3168       #       and one (newer) in the build tree is not a problem
3169       #       because `make dist' always pick files in the build tree
3170       #       first.
3171       # However it turned out the be a bad idea for several reasons:
3172       #   * Tru64, OpenBSD, and FreeBSD (not NetBSD) Make do not behave
3173       #     like GNU Make on point (1) above.  These implementations
3174       #     of Make would always rebuild .info files in the build
3175       #     tree, even if such files were up to date in the source
3176       #     tree.  Consequently, it was impossible to perform a VPATH
3177       #     build of a package containing Texinfo files using these
3178       #     Make implementations.
3179       #     (Refer to the Autoconf Manual, section "Limitation of
3180       #     Make", paragraph "VPATH", item "target lookup", for
3181       #     an account of the differences between these
3182       #     implementations.)
3183       #   * The GNU Coding Standards require these files to be built
3184       #     in the source-tree (when they are distributed, that is).
3185       #   * Keeping a fresher copy of distributed files in the
3186       #     build tree can be annoying during development because
3187       #     - if the files is kept under CVS, you really want it
3188       #       to be updated in the source tree
3189       #     - it is confusing that `make distclean' does not erase
3190       #       all files in the build tree.
3191       #
3192       # Consequently, starting with Automake 1.8, .info files are
3193       # built in the source tree again.  Because we still plan to
3194       # support non-distributed .info files at some point, we
3195       # have a single variable ($INSRC) that controls whether
3196       # the current .info file must be built in the source tree
3197       # or in the build tree.  Actually this variable is switched
3198       # off for .info files that appear to be cleaned; this is
3199       # for backward compatibility with package such as Texinfo,
3200       # which do things like
3201       #   info_TEXINFOS = texinfo.txi info-stnd.texi info.texi
3202       #   DISTCLEANFILES = texinfo texinfo-* info*.info*
3203       #   # Do not create info files for distribution.
3204       #   dist-info:
3205       # in order not to distribute .info files.
3206       my $insrc = ($out_file =~ $user_cleaned_files) ? 0 : 1;
3207
3208       my $soutdir = '$(srcdir)/' . $outdir;
3209       $outdir = $soutdir if $insrc;
3210
3211       # If user specified file_TEXINFOS, then use that as explicit
3212       # dependency list.
3213       @texi_deps = ();
3214       push (@texi_deps, "$soutdir$vtexi") if $vtexi;
3215
3216       my $canonical = canonicalize ($infobase);
3217       if (var ($canonical . "_TEXINFOS"))
3218         {
3219           push (@texi_deps, '$(' . $canonical . '_TEXINFOS)');
3220           push_dist_common ('$(' . $canonical . '_TEXINFOS)');
3221         }
3222
3223       my ($dirstamp, @cfiles) =
3224         output_texinfo_build_rules ($texi, $out_file, $insrc, @texi_deps);
3225       push (@texi_cleans, @cfiles);
3226
3227       push (@info_deps_list, $out_file);
3228
3229       # If a vers*.texi file is needed, emit the rule.
3230       if ($vtexi)
3231         {
3232           err_am ("`$vtexi', included in `$texi', "
3233                   . "also included in `$versions{$vtexi}'")
3234             if defined $versions{$vtexi};
3235           $versions{$vtexi} = $texi;
3236
3237           # We number the stamp-vti files.  This is doable since the
3238           # actual names don't matter much.  We only number starting
3239           # with the second one, so that the common case looks nice.
3240           my $vti = ($done ? $done : 'vti');
3241           ++$done;
3242
3243           # This is ugly, but it is our historical practice.
3244           if ($config_aux_dir_set_in_configure_ac)
3245             {
3246               require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3247                                             'mdate-sh');
3248             }
3249           else
3250             {
3251               require_file_with_macro (TRUE, 'info_TEXINFOS',
3252                                        FOREIGN, 'mdate-sh');
3253             }
3254
3255           my $conf_dir;
3256           if ($config_aux_dir_set_in_configure_ac)
3257             {
3258               $conf_dir = "$am_config_aux_dir/";
3259             }
3260           else
3261             {
3262               $conf_dir = '$(srcdir)/';
3263             }
3264           $output_rules .= file_contents ('texi-vers',
3265                                           new Automake::Location,
3266                                           TEXI     => $texi,
3267                                           VTI      => $vti,
3268                                           STAMPVTI => "${soutdir}stamp-$vti",
3269                                           VTEXI    => "$soutdir$vtexi",
3270                                           MDDIR    => $conf_dir,
3271                                           DIRSTAMP => $dirstamp);
3272         }
3273     }
3274
3275   # Handle location of texinfo.tex.
3276   my $need_texi_file = 0;
3277   my $texinfodir;
3278   if (var ('TEXINFO_TEX'))
3279     {
3280       # The user defined TEXINFO_TEX so assume he knows what he is
3281       # doing.
3282       $texinfodir = ('$(srcdir)/'
3283                      . dirname (variable_value ('TEXINFO_TEX')));
3284     }
3285   elsif (option 'cygnus')
3286     {
3287       $texinfodir = '$(top_srcdir)/../texinfo';
3288       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3289     }
3290   elsif ($config_aux_dir_set_in_configure_ac)
3291     {
3292       $texinfodir = $am_config_aux_dir;
3293       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3294       $need_texi_file = 2; # so that we require_conf_file later
3295     }
3296   else
3297     {
3298       $texinfodir = '$(srcdir)';
3299       $need_texi_file = 1;
3300     }
3301   define_variable ('am__TEXINFO_TEX_DIR', $texinfodir, INTERNAL);
3302
3303   push (@dist_targets, 'dist-info');
3304
3305   if (! option 'no-installinfo')
3306     {
3307       # Make sure documentation is made and installed first.  Use
3308       # $(INFO_DEPS), not 'info', because otherwise recursive makes
3309       # get run twice during "make all".
3310       unshift (@all, '$(INFO_DEPS)');
3311     }
3312
3313   define_files_variable ("DVIS", @infobase, 'dvi', INTERNAL);
3314   define_files_variable ("PDFS", @infobase, 'pdf', INTERNAL);
3315   define_files_variable ("PSS", @infobase, 'ps', INTERNAL);
3316   define_files_variable ("HTMLS", @infobase, 'html', INTERNAL);
3317
3318   # This next isn't strictly needed now -- the places that look here
3319   # could easily be changed to look in info_TEXINFOS.  But this is
3320   # probably better, in case noinst_TEXINFOS is ever supported.
3321   define_variable ("TEXINFOS", variable_value ('info_TEXINFOS'), INTERNAL);
3322
3323   # Do some error checking.  Note that this file is not required
3324   # when in Cygnus mode; instead we defined TEXINFO_TEX explicitly
3325   # up above.
3326   if ($need_texi_file && ! option 'no-texinfo.tex')
3327     {
3328       if ($need_texi_file > 1)
3329         {
3330           require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3331                                         'texinfo.tex');
3332         }
3333       else
3334         {
3335           require_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3336                                    'texinfo.tex');
3337         }
3338     }
3339
3340   return makefile_wrap ("", "\t  ", @texi_cleans);
3341 }
3342
3343
3344 # handle_texinfo ()
3345 # -----------------
3346 # Handle all Texinfo source.
3347 sub handle_texinfo ()
3348 {
3349   reject_var 'TEXINFOS', "`TEXINFOS' is an anachronism; use `info_TEXINFOS'";
3350   # FIXME: I think this is an obsolete future feature name.
3351   reject_var 'html_TEXINFOS', "HTML generation not yet supported";
3352
3353   my $info_texinfos = var ('info_TEXINFOS');
3354   my $texiclean = "";
3355   if ($info_texinfos)
3356     {
3357       $texiclean = handle_texinfo_helper ($info_texinfos);
3358     }
3359   $output_rules .=  file_contents ('texinfos',
3360                                    new Automake::Location,
3361                                    TEXICLEAN     => $texiclean,
3362                                    'LOCAL-TEXIS' => !!$info_texinfos);
3363 }
3364
3365
3366 # Handle any man pages.
3367 sub handle_man_pages
3368 {
3369   reject_var 'MANS', "`MANS' is an anachronism; use `man_MANS'";
3370
3371   # Find all the sections in use.  We do this by first looking for
3372   # "standard" sections, and then looking for any additional
3373   # sections used in man_MANS.
3374   my (%sections, %vlist);
3375   # We handle nodist_ for uniformity.  man pages aren't distributed
3376   # by default so it isn't actually very important.
3377   foreach my $pfx ('', 'dist_', 'nodist_')
3378     {
3379       # Add more sections as needed.
3380       foreach my $section ('0'..'9', 'n', 'l')
3381         {
3382           my $varname = $pfx . 'man' . $section . '_MANS';
3383           if (var ($varname))
3384             {
3385               $sections{$section} = 1;
3386               $varname = '$(' . $varname . ')';
3387               $vlist{$varname} = 1;
3388
3389               &push_dist_common ($varname)
3390                 if $pfx eq 'dist_';
3391             }
3392         }
3393
3394       my $varname = $pfx . 'man_MANS';
3395       my $var = var ($varname);
3396       if ($var)
3397         {
3398           foreach ($var->value_as_list_recursive)
3399             {
3400               # A page like `foo.1c' goes into man1dir.
3401               if (/\.([0-9a-z])([a-z]*)$/)
3402                 {
3403                   $sections{$1} = 1;
3404                 }
3405             }
3406
3407           $varname = '$(' . $varname . ')';
3408           $vlist{$varname} = 1;
3409           &push_dist_common ($varname)
3410             if $pfx eq 'dist_';
3411         }
3412     }
3413
3414   return unless %sections;
3415
3416   # Now for each section, generate an install and uninstall rule.
3417   # Sort sections so output is deterministic.
3418   foreach my $section (sort keys %sections)
3419     {
3420       $output_rules .= &file_contents ('mans',
3421                                        new Automake::Location,
3422                                        SECTION => $section);
3423     }
3424
3425   my @mans = sort keys %vlist;
3426   $output_vars .= file_contents ('mans-vars',
3427                                  new Automake::Location,
3428                                  MANS => "@mans");
3429
3430   push (@all, '$(MANS)')
3431     unless option 'no-installman';
3432 }
3433
3434 # Handle DATA variables.
3435 sub handle_data
3436 {
3437     &am_install_var ('-noextra', '-candist', 'data', 'DATA',
3438                      'data', 'dataroot', 'dvi', 'html', 'pdf', 'ps',
3439                      'sysconf', 'sharedstate', 'localstate',
3440                      'pkgdata', 'lisp', 'noinst', 'check');
3441 }
3442
3443 # Handle TAGS.
3444 sub handle_tags
3445 {
3446     my @tag_deps = ();
3447     my @ctag_deps = ();
3448     if (var ('SUBDIRS'))
3449     {
3450         $output_rules .= ("tags-recursive:\n"
3451                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
3452                           # Never fail here if a subdir fails; it
3453                           # isn't important.
3454                           . "\t  test \"\$\$subdir\" = . || (cd \$\$subdir"
3455                           . " && \$(MAKE) \$(AM_MAKEFLAGS) tags); \\\n"
3456                           . "\tdone\n");
3457         push (@tag_deps, 'tags-recursive');
3458         &depend ('.PHONY', 'tags-recursive');
3459
3460         $output_rules .= ("ctags-recursive:\n"
3461                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
3462                           # Never fail here if a subdir fails; it
3463                           # isn't important.
3464                           . "\t  test \"\$\$subdir\" = . || (cd \$\$subdir"
3465                           . " && \$(MAKE) \$(AM_MAKEFLAGS) ctags); \\\n"
3466                           . "\tdone\n");
3467         push (@ctag_deps, 'ctags-recursive');
3468         &depend ('.PHONY', 'ctags-recursive');
3469     }
3470
3471     if (&saw_sources_p (1)
3472         || var ('ETAGS_ARGS')
3473         || @tag_deps)
3474     {
3475         my @config;
3476         foreach my $spec (@config_headers)
3477         {
3478             my ($out, @ins) = split_config_file_spec ($spec);
3479             foreach my $in (@ins)
3480               {
3481                 # If the config header source is in this directory,
3482                 # require it.
3483                 push @config, basename ($in)
3484                   if $relative_dir eq dirname ($in);
3485               }
3486         }
3487         $output_rules .= &file_contents ('tags',
3488                                          new Automake::Location,
3489                                          CONFIG    => "@config",
3490                                          TAGSDIRS  => "@tag_deps",
3491                                          CTAGSDIRS => "@ctag_deps");
3492
3493         set_seen 'TAGS_DEPENDENCIES';
3494     }
3495     elsif (reject_var ('TAGS_DEPENDENCIES',
3496                        "doesn't make sense to define `TAGS_DEPENDENCIES'"
3497                        . "without\nsources or `ETAGS_ARGS'"))
3498     {
3499     }
3500     else
3501     {
3502         # Every Makefile must define some sort of TAGS rule.
3503         # Otherwise, it would be possible for a top-level "make TAGS"
3504         # to fail because some subdirectory failed.
3505         $output_rules .= "tags: TAGS\nTAGS:\n\n";
3506         # Ditto ctags.
3507         $output_rules .= "ctags: CTAGS\nCTAGS:\n\n";
3508     }
3509 }
3510
3511 # Handle multilib support.
3512 sub handle_multilib
3513 {
3514   if ($seen_multilib && $relative_dir eq '.')
3515     {
3516       $output_rules .= &file_contents ('multilib', new Automake::Location);
3517       push (@all, 'all-multi');
3518     }
3519 }
3520
3521
3522 # user_phony_rule ($NAME)
3523 # -----------------------
3524 # Return false if rule $NAME does not exist.  Otherwise,
3525 # declare it as phony, complete its definition (in case it is
3526 # conditional), and return its Automake::Rule instance.
3527 sub user_phony_rule ($)
3528 {
3529   my ($name) = @_;
3530   my $rule = rule $name;
3531   if ($rule)
3532     {
3533       depend ('.PHONY', $name);
3534       # Define $NAME in all condition where it is not already defined,
3535       # so that it is always OK to depend on $NAME.
3536       for my $c ($rule->not_always_defined_in_cond (TRUE)->conds)
3537         {
3538           Automake::Rule::define ($name, 'internal', RULE_AUTOMAKE,
3539                                   $c, INTERNAL);
3540           $output_rules .= $c->subst_string . "$name:\n";
3541         }
3542     }
3543   return $rule;
3544 }
3545
3546
3547 # $BOOLEAN
3548 # &for_dist_common ($A, $B)
3549 # -------------------------
3550 # Subroutine for &handle_dist: sort files to dist.
3551 #
3552 # We put README first because it then becomes easier to make a
3553 # Usenet-compliant shar file (in these, README must be first).
3554 #
3555 # FIXME: do more ordering of files here.
3556 sub for_dist_common
3557 {
3558     return 0
3559         if $a eq $b;
3560     return -1
3561         if $a eq 'README';
3562     return 1
3563         if $b eq 'README';
3564     return $a cmp $b;
3565 }
3566
3567 # handle_dist
3568 # -----------
3569 # Handle 'dist' target.
3570 sub handle_dist ()
3571 {
3572   # Substitutions for distdir.am
3573   my %transform;
3574
3575   # Define DIST_SUBDIRS.  This must always be done, regardless of the
3576   # no-dist setting: target like `distclean' or `maintainer-clean' use it.
3577   my $subdirs = var ('SUBDIRS');
3578   if ($subdirs)
3579     {
3580       # If SUBDIRS is conditionally defined, then set DIST_SUBDIRS
3581       # to all possible directories, and use it.  If DIST_SUBDIRS is
3582       # defined, just use it.
3583
3584       # Note that we check DIST_SUBDIRS first on purpose, so that
3585       # we don't call has_conditional_contents for now reason.
3586       # (In the past one project used so many conditional subdirectories
3587       # that calling has_conditional_contents on SUBDIRS caused
3588       # automake to grow to 150Mb -- this should not happen with
3589       # the current implementation of has_conditional_contents,
3590       # but it's more efficient to avoid the call anyway.)
3591       if (var ('DIST_SUBDIRS'))
3592         {
3593         }
3594       elsif ($subdirs->has_conditional_contents)
3595         {
3596           define_pretty_variable
3597             ('DIST_SUBDIRS', TRUE, INTERNAL,
3598              uniq ($subdirs->value_as_list_recursive));
3599         }
3600       else
3601         {
3602           # We always define this because that is what `distclean'
3603           # wants.
3604           define_pretty_variable ('DIST_SUBDIRS', TRUE, INTERNAL,
3605                                   '$(SUBDIRS)');
3606         }
3607     }
3608
3609   # The remaining definitions are only required when a dist target is used.
3610   return if option 'no-dist';
3611
3612   # At least one of the archive formats must be enabled.
3613   if ($relative_dir eq '.')
3614     {
3615       my $archive_defined = option 'no-dist-gzip' ? 0 : 1;
3616       $archive_defined ||=
3617         grep { option "dist-$_" } qw(shar zip tarZ bzip2 lzma);
3618       error (option 'no-dist-gzip',
3619              "no-dist-gzip specified but no dist-* specified, "
3620              . "at least one archive format must be enabled")
3621         unless $archive_defined;
3622     }
3623
3624   # Look for common files that should be included in distribution.
3625   # If the aux dir is set, and it does not have a Makefile.am, then
3626   # we check for these files there as well.
3627   my $check_aux = 0;
3628   if ($relative_dir eq '.'
3629       && $config_aux_dir_set_in_configure_ac)
3630     {
3631       if (! &is_make_dir ($config_aux_dir))
3632         {
3633           $check_aux = 1;
3634         }
3635     }
3636   foreach my $cfile (@common_files)
3637     {
3638       if (dir_has_case_matching_file ($relative_dir, $cfile)
3639           # The file might be absent, but if it can be built it's ok.
3640           || rule $cfile)
3641         {
3642           &push_dist_common ($cfile);
3643         }
3644
3645       # Don't use `elsif' here because a file might meaningfully
3646       # appear in both directories.
3647       if ($check_aux && dir_has_case_matching_file ($config_aux_dir, $cfile))
3648         {
3649           &push_dist_common ("$config_aux_dir/$cfile")
3650         }
3651     }
3652
3653   # We might copy elements from $configure_dist_common to
3654   # %dist_common if we think we need to.  If the file appears in our
3655   # directory, we would have discovered it already, so we don't
3656   # check that.  But if the file is in a subdir without a Makefile,
3657   # we want to distribute it here if we are doing `.'.  Ugly!
3658   if ($relative_dir eq '.')
3659     {
3660       foreach my $file (split (' ' , $configure_dist_common))
3661         {
3662           push_dist_common ($file)
3663             unless is_make_dir (dirname ($file));
3664         }
3665     }
3666
3667   # Files to distributed.  Don't use ->value_as_list_recursive
3668   # as it recursively expands `$(dist_pkgdata_DATA)' etc.
3669   my @dist_common = split (' ', rvar ('DIST_COMMON')->variable_value);
3670   @dist_common = uniq (sort for_dist_common (@dist_common));
3671   variable_delete 'DIST_COMMON';
3672   define_pretty_variable ('DIST_COMMON', TRUE, INTERNAL, @dist_common);
3673
3674   # Now that we've processed DIST_COMMON, disallow further attempts
3675   # to set it.
3676   $handle_dist_run = 1;
3677
3678   # Scan EXTRA_DIST to see if we need to distribute anything from a
3679   # subdir.  If so, add it to the list.  I didn't want to do this
3680   # originally, but there were so many requests that I finally
3681   # relented.
3682   my $extra_dist = var ('EXTRA_DIST');
3683
3684   $transform{'DISTCHECK-HOOK'} = !! rule 'distcheck-hook';
3685   $transform{'GETTEXT'} = $seen_gettext && !$seen_gettext_external;
3686
3687   # If the target `dist-hook' exists, make sure it is run.  This
3688   # allows users to do random weird things to the distribution
3689   # before it is packaged up.
3690   push (@dist_targets, 'dist-hook')
3691     if user_phony_rule 'dist-hook';
3692   $transform{'DIST-TARGETS'} = join (' ', @dist_targets);
3693
3694   my $flm = option ('filename-length-max');
3695   my $filename_filter = $flm ? '.' x $flm->[1] : '';
3696
3697   $output_rules .= &file_contents ('distdir',
3698                                    new Automake::Location,
3699                                    %transform,
3700                                    FILENAME_FILTER => $filename_filter);
3701 }
3702
3703
3704 # check_directory ($NAME, $WHERE)
3705 # -------------------------------
3706 # Ensure $NAME is a directory, and that it uses sane name.
3707 # Use $WHERE as a location in the diagnostic, if any.
3708 sub check_directory ($$)
3709 {
3710   my ($dir, $where) = @_;
3711
3712   error $where, "required directory $relative_dir/$dir does not exist"
3713     unless -d "$relative_dir/$dir";
3714
3715   # If an `obj/' directory exists, BSD make will enter it before
3716   # reading `Makefile'.  Hence the `Makefile' in the current directory
3717   # will not be read.
3718   #
3719   #  % cat Makefile
3720   #  all:
3721   #          echo Hello
3722   #  % cat obj/Makefile
3723   #  all:
3724   #          echo World
3725   #  % make      # GNU make
3726   #  echo Hello
3727   #  Hello
3728   #  % pmake     # BSD make
3729   #  echo World
3730   #  World
3731   msg ('portability', $where,
3732        "naming a subdirectory `obj' causes troubles with BSD make")
3733     if $dir eq 'obj';
3734
3735   # `aux' is probably the most important of the following forbidden name,
3736   # since it's tempting to use it as an AC_CONFIG_AUX_DIR.
3737   msg ('portability', $where,
3738        "name `$dir' is reserved on W32 and DOS platforms")
3739     if grep (/^\Q$dir\E$/i, qw/aux lpt1 lpt2 lpt3 com1 com2 com3 com4 con prn/);
3740 }
3741
3742 # check_directories_in_var ($VARIABLE)
3743 # ------------------------------------
3744 # Recursively check all items in variables $VARIABLE as directories
3745 sub check_directories_in_var ($)
3746 {
3747   my ($var) = @_;
3748   $var->traverse_recursively
3749     (sub
3750      {
3751        my ($var, $val, $cond, $full_cond) = @_;
3752        check_directory ($val, $var->rdef ($cond)->location);
3753        return ();
3754      },
3755      undef,
3756      skip_ac_subst => 1);
3757 }
3758
3759 # &handle_subdirs ()
3760 # ------------------
3761 # Handle subdirectories.
3762 sub handle_subdirs ()
3763 {
3764   my $subdirs = var ('SUBDIRS');
3765   return
3766     unless $subdirs;
3767
3768   check_directories_in_var $subdirs;
3769
3770   my $dsubdirs = var ('DIST_SUBDIRS');
3771   check_directories_in_var $dsubdirs
3772     if $dsubdirs;
3773
3774   $output_rules .= &file_contents ('subdirs', new Automake::Location);
3775   rvar ('RECURSIVE_TARGETS')->rdef (TRUE)->{'pretty'} = VAR_SORTED; # Gross!
3776 }
3777
3778
3779 # ($REGEN, @DEPENDENCIES)
3780 # &scan_aclocal_m4
3781 # ----------------
3782 # If aclocal.m4 creation is automated, return the list of its dependencies.
3783 sub scan_aclocal_m4 ()
3784 {
3785   my $regen_aclocal = 0;
3786
3787   set_seen 'CONFIG_STATUS_DEPENDENCIES';
3788   set_seen 'CONFIGURE_DEPENDENCIES';
3789
3790   if (-f 'aclocal.m4')
3791     {
3792       &define_variable ("ACLOCAL_M4", '$(top_srcdir)/aclocal.m4', INTERNAL);
3793
3794       my $aclocal = new Automake::XFile "< aclocal.m4";
3795       my $line = $aclocal->getline;
3796       $regen_aclocal = $line =~ 'generated automatically by aclocal';
3797     }
3798
3799   my @ac_deps = ();
3800
3801   if (set_seen ('ACLOCAL_M4_SOURCES'))
3802     {
3803       push (@ac_deps, '$(ACLOCAL_M4_SOURCES)');
3804       msg_var ('obsolete', 'ACLOCAL_M4_SOURCES',
3805                "`ACLOCAL_M4_SOURCES' is obsolete.\n"
3806                . "It should be safe to simply remove it.");
3807     }
3808
3809   # Note that it might be possible that aclocal.m4 doesn't exist but
3810   # should be auto-generated.  This case probably isn't very
3811   # important.
3812
3813   return ($regen_aclocal, @ac_deps);
3814 }
3815
3816
3817 # Helper function for substitute_ac_subst_variables.
3818 sub substitute_ac_subst_variables_worker($)
3819 {
3820   my ($token) = @_;
3821   return "\@$token\@" if var $token;
3822   return "\${$token\}";
3823 }
3824
3825 # substitute_ac_subst_variables ($TEXT)
3826 # -------------------------------------
3827 # Replace any occurrence of ${FOO} in $TEXT by @FOO@ if FOO is an AC_SUBST
3828 # variable.
3829 sub substitute_ac_subst_variables ($)
3830 {
3831   my ($text) = @_;
3832   $text =~ s/\${([^ \t=:+{}]+)}/&substitute_ac_subst_variables_worker ($1)/ge;
3833   return $text;
3834 }
3835
3836 # @DEPENDENCIES
3837 # &prepend_srcdir (@INPUTS)
3838 # -------------------------
3839 # Prepend $(srcdir) or $(top_srcdir) to all @INPUTS.  The idea is that
3840 # if an input file has a directory part the same as the current
3841 # directory, then the directory part is simply replaced by $(srcdir).
3842 # But if the directory part is different, then $(top_srcdir) is
3843 # prepended.
3844 sub prepend_srcdir (@)
3845 {
3846   my (@inputs) = @_;
3847   my @newinputs;
3848
3849   foreach my $single (@inputs)
3850     {
3851       if (dirname ($single) eq $relative_dir)
3852         {
3853           push (@newinputs, '$(srcdir)/' . basename ($single));
3854         }
3855       else
3856         {
3857           push (@newinputs, '$(top_srcdir)/' . $single);
3858         }
3859     }
3860   return @newinputs;
3861 }
3862
3863 # @DEPENDENCIES
3864 # rewrite_inputs_into_dependencies ($OUTPUT, @INPUTS)
3865 # ---------------------------------------------------
3866 # Compute a list of dependencies appropriate for the rebuild
3867 # rule of
3868 #   AC_CONFIG_FILES($OUTPUT:$INPUT[0]:$INPUTS[1]:...)
3869 # Also distribute $INPUTs which are not build by another AC_CONFIG_FILES.
3870 sub rewrite_inputs_into_dependencies ($@)
3871 {
3872   my ($file, @inputs) = @_;
3873   my @res = ();
3874
3875   for my $i (@inputs)
3876     {
3877       # We cannot create dependencies on shell variables.
3878       next if (substitute_ac_subst_variables $i) =~ /\$/;
3879
3880       if (exists $ac_config_files_location{$i})
3881         {
3882           my $di = dirname $i;
3883           if ($di eq $relative_dir)
3884             {
3885               $i = basename $i;
3886             }
3887           # In the top-level Makefile we do not use $(top_builddir), because
3888           # we are already there, and since the targets are built without
3889           # a $(top_builddir), it helps BSD Make to match them with
3890           # dependencies.
3891           elsif ($relative_dir ne '.')
3892             {
3893               $i = '$(top_builddir)/' . $i;
3894             }
3895         }
3896       else
3897         {
3898           msg ('error', $ac_config_files_location{$file},
3899                "required file `$i' not found")
3900             unless $i =~ /\$/ || exists $output_files{$i} || -f $i;
3901           ($i) = prepend_srcdir ($i);
3902           push_dist_common ($i);
3903         }
3904       push @res, $i;
3905     }
3906   return @res;
3907 }
3908
3909
3910
3911 # &handle_configure ($MAKEFILE_AM, $MAKEFILE_IN, $MAKEFILE, @INPUTS)
3912 # ------------------------------------------------------------------
3913 # Handle remaking and configure stuff.
3914 # We need the name of the input file, to do proper remaking rules.
3915 sub handle_configure ($$$@)
3916 {
3917   my ($makefile_am, $makefile_in, $makefile, @inputs) = @_;
3918
3919   prog_error 'empty @inputs'
3920     unless @inputs;
3921
3922   my ($rel_makefile_am, $rel_makefile_in) = prepend_srcdir ($makefile_am,
3923                                                             $makefile_in);
3924   my $rel_makefile = basename $makefile;
3925
3926   my $colon_infile = ':' . join (':', @inputs);
3927   $colon_infile = '' if $colon_infile eq ":$makefile.in";
3928   my @rewritten = rewrite_inputs_into_dependencies ($makefile, @inputs);
3929   my ($regen_aclocal_m4, @aclocal_m4_deps) = scan_aclocal_m4;
3930   define_pretty_variable ('am__aclocal_m4_deps', TRUE, INTERNAL,
3931                           @configure_deps, @aclocal_m4_deps,
3932                           '$(top_srcdir)/' . $configure_ac);
3933   my @configuredeps = ('$(am__aclocal_m4_deps)', '$(CONFIGURE_DEPENDENCIES)');
3934   push @configuredeps, '$(ACLOCAL_M4)' if -f 'aclocal.m4';
3935   define_pretty_variable ('am__configure_deps', TRUE, INTERNAL,
3936                           @configuredeps);
3937
3938   $output_rules .= file_contents
3939     ('configure',
3940      new Automake::Location,
3941      MAKEFILE              => $rel_makefile,
3942      'MAKEFILE-DEPS'       => "@rewritten",
3943      'CONFIG-MAKEFILE'     => ($relative_dir eq '.') ? '$@' : '$(subdir)/$@',
3944      'MAKEFILE-IN'         => $rel_makefile_in,
3945      'MAKEFILE-IN-DEPS'    => "@include_stack",
3946      'MAKEFILE-AM'         => $rel_makefile_am,
3947      STRICTNESS            => global_option 'cygnus'
3948                                 ? 'cygnus' : $strictness_name,
3949      'USE-DEPS'            => global_option 'no-dependencies'
3950                                 ? ' --ignore-deps' : '',
3951      'MAKEFILE-AM-SOURCES' => "$makefile$colon_infile",
3952      'REGEN-ACLOCAL-M4'    => $regen_aclocal_m4);
3953
3954   if ($relative_dir eq '.')
3955     {
3956       &push_dist_common ('acconfig.h')
3957         if -f 'acconfig.h';
3958     }
3959
3960   # If we have a configure header, require it.
3961   my $hdr_index = 0;
3962   my @distclean_config;
3963   foreach my $spec (@config_headers)
3964     {
3965       $hdr_index += 1;
3966       # $CONFIG_H_PATH: config.h from top level.
3967       my ($config_h_path, @ins) = split_config_file_spec ($spec);
3968       my $config_h_dir = dirname ($config_h_path);
3969
3970       # If the header is in the current directory we want to build
3971       # the header here.  Otherwise, if we're at the topmost
3972       # directory and the header's directory doesn't have a
3973       # Makefile, then we also want to build the header.
3974       if ($relative_dir eq $config_h_dir
3975           || ($relative_dir eq '.' && ! &is_make_dir ($config_h_dir)))
3976         {
3977           my ($cn_sans_dir, $stamp_dir);
3978           if ($relative_dir eq $config_h_dir)
3979             {
3980               $cn_sans_dir = basename ($config_h_path);
3981               $stamp_dir = '';
3982             }
3983           else
3984             {
3985               $cn_sans_dir = $config_h_path;
3986               if ($config_h_dir eq '.')
3987                 {
3988                   $stamp_dir = '';
3989                 }
3990               else
3991                 {
3992                   $stamp_dir = $config_h_dir . '/';
3993                 }
3994             }
3995
3996           # This will also distribute all inputs.
3997           @ins = rewrite_inputs_into_dependencies ($config_h_path, @ins);
3998
3999           # Cannot define rebuild rules for filenames with shell variables.
4000           next if (substitute_ac_subst_variables $config_h_path) =~ /\$/;
4001
4002           # Header defined in this directory.
4003           my @files;
4004           if (-f $config_h_path . '.top')
4005             {
4006               push (@files, "$cn_sans_dir.top");
4007             }
4008           if (-f $config_h_path . '.bot')
4009             {
4010               push (@files, "$cn_sans_dir.bot");
4011             }
4012
4013           push_dist_common (@files);
4014
4015           # For now, acconfig.h can only appear in the top srcdir.
4016           if (-f 'acconfig.h')
4017             {
4018               push (@files, '$(top_srcdir)/acconfig.h');
4019             }
4020
4021           my $stamp = "${stamp_dir}stamp-h${hdr_index}";
4022           $output_rules .=
4023             file_contents ('remake-hdr',
4024                            new Automake::Location,
4025                            FILES            => "@files",
4026                            CONFIG_H         => $cn_sans_dir,
4027                            CONFIG_HIN       => $ins[0],
4028                            CONFIG_H_DEPS    => "@ins",
4029                            CONFIG_H_PATH    => $config_h_path,
4030                            STAMP            => "$stamp");
4031
4032           push @distclean_config, $cn_sans_dir, $stamp;
4033         }
4034     }
4035
4036   $output_rules .= file_contents ('clean-hdr',
4037                                   new Automake::Location,
4038                                   FILES => "@distclean_config")
4039     if @distclean_config;
4040
4041   # Distribute and define mkinstalldirs only if it is already present
4042   # in the package, for backward compatibility (some people may still
4043   # use $(mkinstalldirs)).
4044   my $mkidpath = "$config_aux_dir/mkinstalldirs";
4045   if (-f $mkidpath)
4046     {
4047       # Use require_file so that any existing script gets updated
4048       # by --force-missing.
4049       require_conf_file ($mkidpath, FOREIGN, 'mkinstalldirs');
4050       define_variable ('mkinstalldirs',
4051                        "\$(SHELL) $am_config_aux_dir/mkinstalldirs", INTERNAL);
4052     }
4053   else
4054     {
4055       # Use $(install_sh), not $(MKDIR_P) because the latter requires
4056       # at least one argument, and $(mkinstalldirs) used to work
4057       # even without arguments (e.g. $(mkinstalldirs) $(conditional_dir)).
4058       define_variable ('mkinstalldirs', '$(install_sh) -d', INTERNAL);
4059     }
4060
4061   reject_var ('CONFIG_HEADER',
4062               "`CONFIG_HEADER' is an anachronism; now determined "
4063               . "automatically\nfrom `$configure_ac'");
4064
4065   my @config_h;
4066   foreach my $spec (@config_headers)
4067     {
4068       my ($out, @ins) = split_config_file_spec ($spec);
4069       # Generate CONFIG_HEADER define.
4070       if ($relative_dir eq dirname ($out))
4071         {
4072           push @config_h, basename ($out);
4073         }
4074       else
4075         {
4076           push @config_h, "\$(top_builddir)/$out";
4077         }
4078     }
4079   define_variable ("CONFIG_HEADER", "@config_h", INTERNAL)
4080     if @config_h;
4081
4082   # Now look for other files in this directory which must be remade
4083   # by config.status, and generate rules for them.
4084   my @actual_other_files = ();
4085   foreach my $lfile (@other_input_files)
4086     {
4087       my $file;
4088       my @inputs;
4089       if ($lfile =~ /^([^:]*):(.*)$/)
4090         {
4091           # This is the ":" syntax of AC_OUTPUT.
4092           $file = $1;
4093           @inputs = split (':', $2);
4094         }
4095       else
4096         {
4097           # Normal usage.
4098           $file = $lfile;
4099           @inputs = $file . '.in';
4100         }
4101
4102       # Automake files should not be stored in here, but in %MAKE_LIST.
4103       prog_error ("$lfile in \@other_input_files\n"
4104                   . "\@other_input_files = (@other_input_files)")
4105         if -f $file . '.am';
4106
4107       my $local = basename ($file);
4108
4109       # We skip files that aren't in this directory.  However, if
4110       # the file's directory does not have a Makefile, and we are
4111       # currently doing `.', then we create a rule to rebuild the
4112       # file in the subdir.
4113       my $fd = dirname ($file);
4114       if ($fd ne $relative_dir)
4115         {
4116           if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4117             {
4118               $local = $file;
4119             }
4120           else
4121             {
4122               next;
4123             }
4124         }
4125
4126       my @rewritten_inputs = rewrite_inputs_into_dependencies ($file, @inputs);
4127
4128       # Cannot output rules for shell variables.
4129       next if (substitute_ac_subst_variables $local) =~ /\$/;
4130
4131       $output_rules .= ($local . ': '
4132                         . '$(top_builddir)/config.status '
4133                         . "@rewritten_inputs\n"
4134                         . "\t"
4135                         . 'cd $(top_builddir) && '
4136                         . '$(SHELL) ./config.status '
4137                         . ($relative_dir eq '.' ? '' : '$(subdir)/')
4138                         . '$@'
4139                         . "\n");
4140       push (@actual_other_files, $local);
4141     }
4142
4143   # For links we should clean destinations and distribute sources.
4144   foreach my $spec (@config_links)
4145     {
4146       my ($link, $file) = split /:/, $spec;
4147       # Some people do AC_CONFIG_LINKS($computed).  We only handle
4148       # the DEST:SRC form.
4149       next unless $file;
4150       my $where = $ac_config_files_location{$link};
4151
4152       # Skip destinations that contain shell variables.
4153       if ((substitute_ac_subst_variables $link) !~ /\$/)
4154         {
4155           # We skip links that aren't in this directory.  However, if
4156           # the link's directory does not have a Makefile, and we are
4157           # currently doing `.', then we add the link to CONFIG_CLEAN_FILES
4158           # in `.'s Makefile.in.
4159           my $local = basename ($link);
4160           my $fd = dirname ($link);
4161           if ($fd ne $relative_dir)
4162             {
4163               if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4164                 {
4165                   $local = $link;
4166                 }
4167               else
4168                 {
4169                   $local = undef;
4170                 }
4171             }
4172           push @actual_other_files, $local if $local;
4173         }
4174
4175       # Do not process sources that contain shell variables.
4176       if ((substitute_ac_subst_variables $file) !~ /\$/)
4177         {
4178           my $fd = dirname ($file);
4179
4180           # We distribute files that are in this directory.
4181           # At the top-level (`.') we also distribute files whose
4182           # directory does not have a Makefile.
4183           if (($fd eq $relative_dir)
4184               || ($relative_dir eq '.' && ! &is_make_dir ($fd)))
4185             {
4186               # The following will distribute $file as a side-effect when
4187               # it is appropriate (i.e., when $file is not already an output).
4188               # We do not need the result, just the side-effect.
4189               rewrite_inputs_into_dependencies ($link, $file);
4190             }
4191         }
4192     }
4193
4194   # These files get removed by "make distclean".
4195   define_pretty_variable ('CONFIG_CLEAN_FILES', TRUE, INTERNAL,
4196                           @actual_other_files);
4197 }
4198
4199 # Handle C headers.
4200 sub handle_headers
4201 {
4202     my @r = &am_install_var ('-defaultdist', 'header', 'HEADERS', 'include',
4203                              'oldinclude', 'pkginclude',
4204                              'noinst', 'check');
4205     foreach (@r)
4206     {
4207       next unless $_->[1] =~ /\..*$/;
4208       &saw_extension ($&);
4209     }
4210 }
4211
4212 sub handle_gettext
4213 {
4214   return if ! $seen_gettext || $relative_dir ne '.';
4215
4216   my $subdirs = var 'SUBDIRS';
4217
4218   if (! $subdirs)
4219     {
4220       err_ac "AM_GNU_GETTEXT used but SUBDIRS not defined";
4221       return;
4222     }
4223
4224   # Perform some sanity checks to help users get the right setup.
4225   # We disable these tests when po/ doesn't exist in order not to disallow
4226   # unusual gettext setups.
4227   #
4228   # Bruno Haible:
4229   # | The idea is:
4230   # |
4231   # |  1) If a package doesn't have a directory po/ at top level, it
4232   # |     will likely have multiple po/ directories in subpackages.
4233   # |
4234   # |  2) It is useful to warn for the absence of intl/ if AM_GNU_GETTEXT
4235   # |     is used without 'external'. It is also useful to warn for the
4236   # |     presence of intl/ if AM_GNU_GETTEXT([external]) is used. Both
4237   # |     warnings apply only to the usual layout of packages, therefore
4238   # |     they should both be disabled if no po/ directory is found at
4239   # |     top level.
4240
4241   if (-d 'po')
4242     {
4243       my @subdirs = $subdirs->value_as_list_recursive;
4244
4245       msg_var ('syntax', $subdirs,
4246                "AM_GNU_GETTEXT used but `po' not in SUBDIRS")
4247         if ! grep ($_ eq 'po', @subdirs);
4248
4249       # intl/ is not required when AM_GNU_GETTEXT is called with the
4250       # `external' option and AM_GNU_GETTEXT_INTL_SUBDIR is not called.
4251       msg_var ('syntax', $subdirs,
4252                "AM_GNU_GETTEXT used but `intl' not in SUBDIRS")
4253         if (! ($seen_gettext_external && ! $seen_gettext_intl)
4254             && ! grep ($_ eq 'intl', @subdirs));
4255
4256       # intl/ should not be used with AM_GNU_GETTEXT([external]), except
4257       # if AM_GNU_GETTEXT_INTL_SUBDIR is called.
4258       msg_var ('syntax', $subdirs,
4259                "`intl' should not be in SUBDIRS when "
4260                . "AM_GNU_GETTEXT([external]) is used")
4261         if ($seen_gettext_external && ! $seen_gettext_intl
4262             && grep ($_ eq 'intl', @subdirs));
4263     }
4264
4265   require_file ($ac_gettext_location, GNU, 'ABOUT-NLS');
4266 }
4267
4268 # Handle footer elements.
4269 sub handle_footer
4270 {
4271     reject_rule ('.SUFFIXES',
4272                  "use variable `SUFFIXES', not target `.SUFFIXES'");
4273
4274     # Note: AIX 4.1 /bin/make will fail if any suffix rule appears
4275     # before .SUFFIXES.  So we make sure that .SUFFIXES appears before
4276     # anything else, by sticking it right after the default: target.
4277     $output_header .= ".SUFFIXES:\n";
4278     my $suffixes = var 'SUFFIXES';
4279     my @suffixes = Automake::Rule::suffixes;
4280     if (@suffixes || $suffixes)
4281     {
4282         # Make sure SUFFIXES has unique elements.  Sort them to ensure
4283         # the output remains consistent.  However, $(SUFFIXES) is
4284         # always at the start of the list, unsorted.  This is done
4285         # because make will choose rules depending on the ordering of
4286         # suffixes, and this lets the user have some control.  Push
4287         # actual suffixes, and not $(SUFFIXES).  Some versions of make
4288         # do not like variable substitutions on the .SUFFIXES line.
4289         my @user_suffixes = ($suffixes
4290                              ? $suffixes->value_as_list_recursive : ());
4291
4292         my %suffixes = map { $_ => 1 } @suffixes;
4293         delete @suffixes{@user_suffixes};
4294
4295         $output_header .= (".SUFFIXES: "
4296                            . join (' ', @user_suffixes, sort keys %suffixes)
4297                            . "\n");
4298     }
4299
4300     $output_trailer .= file_contents ('footer', new Automake::Location);
4301 }
4302
4303
4304 # Generate `make install' rules.
4305 sub handle_install ()
4306 {
4307   $output_rules .= &file_contents
4308     ('install',
4309      new Automake::Location,
4310      maybe_BUILT_SOURCES => (set_seen ('BUILT_SOURCES')
4311                              ? (" \$(BUILT_SOURCES)\n"
4312                                 . "\t\$(MAKE) \$(AM_MAKEFLAGS)")
4313                              : ''),
4314      'installdirs-local' => (user_phony_rule 'installdirs-local'
4315                              ? ' installdirs-local' : ''),
4316      am__installdirs => variable_value ('am__installdirs') || '');
4317 }
4318
4319
4320 # Deal with all and all-am.
4321 sub handle_all ($)
4322 {
4323     my ($makefile) = @_;
4324
4325     # Output `all-am'.
4326
4327     # Put this at the beginning for the sake of non-GNU makes.  This
4328     # is still wrong if these makes can run parallel jobs.  But it is
4329     # right enough.
4330     unshift (@all, basename ($makefile));
4331
4332     foreach my $spec (@config_headers)
4333       {
4334         my ($out, @ins) = split_config_file_spec ($spec);
4335         push (@all, basename ($out))
4336           if dirname ($out) eq $relative_dir;
4337       }
4338
4339     # Install `all' hooks.
4340     push (@all, "all-local")
4341       if user_phony_rule "all-local";
4342
4343     &pretty_print_rule ("all-am:", "\t\t", @all);
4344     &depend ('.PHONY', 'all-am', 'all');
4345
4346
4347     # Output `all'.
4348
4349     my @local_headers = ();
4350     push @local_headers, '$(BUILT_SOURCES)'
4351       if var ('BUILT_SOURCES');
4352     foreach my $spec (@config_headers)
4353       {
4354         my ($out, @ins) = split_config_file_spec ($spec);
4355         push @local_headers, basename ($out)
4356           if dirname ($out) eq $relative_dir;
4357       }
4358
4359     if (@local_headers)
4360       {
4361         # We need to make sure config.h is built before we recurse.
4362         # We also want to make sure that built sources are built
4363         # before any ordinary `all' targets are run.  We can't do this
4364         # by changing the order of dependencies to the "all" because
4365         # that breaks when using parallel makes.  Instead we handle
4366         # things explicitly.
4367         $output_all .= ("all: @local_headers"
4368                         . "\n\t"
4369                         . '$(MAKE) $(AM_MAKEFLAGS) '
4370                         . (var ('SUBDIRS') ? 'all-recursive' : 'all-am')
4371                         . "\n\n");
4372       }
4373     else
4374       {
4375         $output_all .= "all: " . (var ('SUBDIRS')
4376                                   ? 'all-recursive' : 'all-am') . "\n\n";
4377       }
4378 }
4379
4380
4381 # &do_check_merge_target ()
4382 # -------------------------
4383 # Handle check merge target specially.
4384 sub do_check_merge_target ()
4385 {
4386   # Include user-defined local form of target.
4387   push @check_tests, 'check-local'
4388     if user_phony_rule 'check-local';
4389
4390   # In --cygnus mode, check doesn't depend on all.
4391   if (option 'cygnus')
4392     {
4393       # Just run the local check rules.
4394       pretty_print_rule ('check-am:', "\t\t", @check);
4395     }
4396   else
4397     {
4398       # The check target must depend on the local equivalent of
4399       # `all', to ensure all the primary targets are built.  Then it
4400       # must build the local check rules.
4401       $output_rules .= "check-am: all-am\n";
4402       pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4403                          @check)
4404         if @check;
4405     }
4406   pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4407                      @check_tests)
4408     if @check_tests;
4409
4410   depend '.PHONY', 'check', 'check-am';
4411   # Handle recursion.  We have to honor BUILT_SOURCES like for `all:'.
4412   $output_rules .= ("check: "
4413                     . (var ('BUILT_SOURCES')
4414                        ? "\$(BUILT_SOURCES)\n\t\$(MAKE) \$(AM_MAKEFLAGS) "
4415                        : '')
4416                     . (var ('SUBDIRS') ? 'check-recursive' : 'check-am')
4417                     . "\n");
4418 }
4419
4420 # handle_clean ($MAKEFILE)
4421 # ------------------------
4422 # Handle all 'clean' targets.
4423 sub handle_clean ($)
4424 {
4425   my ($makefile) = @_;
4426
4427   # Clean the files listed in user variables if they exist.
4428   $clean_files{'$(MOSTLYCLEANFILES)'} = MOSTLY_CLEAN
4429     if var ('MOSTLYCLEANFILES');
4430   $clean_files{'$(CLEANFILES)'} = CLEAN
4431     if var ('CLEANFILES');
4432   $clean_files{'$(DISTCLEANFILES)'} = DIST_CLEAN
4433     if var ('DISTCLEANFILES');
4434   $clean_files{'$(MAINTAINERCLEANFILES)'} = MAINTAINER_CLEAN
4435     if var ('MAINTAINERCLEANFILES');
4436
4437   # Built sources are automatically removed by maintainer-clean.
4438   $clean_files{'$(BUILT_SOURCES)'} = MAINTAINER_CLEAN
4439     if var ('BUILT_SOURCES');
4440
4441   # Compute a list of "rm"s to run for each target.
4442   my %rms = (MOSTLY_CLEAN, [],
4443              CLEAN, [],
4444              DIST_CLEAN, [],
4445              MAINTAINER_CLEAN, []);
4446
4447   foreach my $file (keys %clean_files)
4448     {
4449       my $when = $clean_files{$file};
4450       prog_error 'invalid entry in %clean_files'
4451         unless exists $rms{$when};
4452
4453       my $rm = "rm -f $file";
4454       # If file is a variable, make sure when don't call `rm -f' without args.
4455       $rm ="test -z \"$file\" || $rm"
4456         if ($file =~ /^\s*\$(\(.*\)|\{.*\})\s*$/);
4457
4458       push @{$rms{$when}}, "\t-$rm\n";
4459     }
4460
4461   $output_rules .= &file_contents
4462     ('clean',
4463      new Automake::Location,
4464      MOSTLYCLEAN_RMS      => join ('', sort @{$rms{&MOSTLY_CLEAN}}),
4465      CLEAN_RMS            => join ('', sort @{$rms{&CLEAN}}),
4466      DISTCLEAN_RMS        => join ('', sort @{$rms{&DIST_CLEAN}}),
4467      MAINTAINER_CLEAN_RMS => join ('', sort @{$rms{&MAINTAINER_CLEAN}}),
4468      MAKEFILE             => basename $makefile,
4469      );
4470 }
4471
4472
4473 # &target_cmp ($A, $B)
4474 # --------------------
4475 # Subroutine for &handle_factored_dependencies to let `.PHONY' and
4476 # other `.TARGETS' be last.
4477 sub target_cmp
4478 {
4479   return 0 if $a eq $b;
4480
4481   my $a1 = substr ($a, 0, 1);
4482   my $b1 = substr ($b, 0, 1);
4483   if ($a1 ne $b1)
4484     {
4485       return -1 if $b1 eq '.';
4486       return 1 if $a1 eq '.';
4487     }
4488   return $a cmp $b;
4489 }
4490
4491
4492 # &handle_factored_dependencies ()
4493 # --------------------------------
4494 # Handle everything related to gathered targets.
4495 sub handle_factored_dependencies
4496 {
4497   # Reject bad hooks.
4498   foreach my $utarg ('uninstall-data-local', 'uninstall-data-hook',
4499                      'uninstall-exec-local', 'uninstall-exec-hook',
4500                      'uninstall-dvi-local',
4501                      'uninstall-html-local',
4502                      'uninstall-info-local',
4503                      'uninstall-pdf-local',
4504                      'uninstall-ps-local')
4505     {
4506       my $x = $utarg;
4507       $x =~ s/-.*-/-/;
4508       reject_rule ($utarg, "use `$x', not `$utarg'");
4509     }
4510
4511   reject_rule ('install-local',
4512                "use `install-data-local' or `install-exec-local', "
4513                . "not `install-local'");
4514
4515   reject_rule ('install-hook',
4516                "use `install-data-hook' or `install-exec-hook', "
4517                . "not `install-hook'");
4518
4519   # Install the -local hooks.
4520   foreach (keys %dependencies)
4521     {
4522       # Hooks are installed on the -am targets.
4523       s/-am$// or next;
4524       depend ("$_-am", "$_-local")
4525         if user_phony_rule "$_-local";
4526     }
4527
4528   # Install the -hook hooks.
4529   # FIXME: Why not be as liberal as we are with -local hooks?
4530   foreach ('install-exec', 'install-data', 'uninstall')
4531     {
4532       if (user_phony_rule "$_-hook")
4533         {
4534           $actions{"$_-am"} .=
4535             ("\t\@\$(NORMAL_INSTALL)\n"
4536              . "\t" . '$(MAKE) $(AM_MAKEFLAGS) ' . "$_-hook\n");
4537           depend ('.MAKE', "$_-am");
4538         }
4539     }
4540
4541   # All the required targets are phony.
4542   depend ('.PHONY', keys %required_targets);
4543
4544   # Actually output gathered targets.
4545   foreach (sort target_cmp keys %dependencies)
4546     {
4547       # If there is nothing about this guy, skip it.
4548       next
4549         unless (@{$dependencies{$_}}
4550                 || $actions{$_}
4551                 || $required_targets{$_});
4552
4553       # Define gathered targets in undefined conditions.
4554       # FIXME: Right now we must handle .PHONY as an exception,
4555       # because people write things like
4556       #    .PHONY: myphonytarget
4557       # to append dependencies.  This would not work if Automake
4558       # refrained from defining its own .PHONY target as it does
4559       # with other overridden targets.
4560       # Likewise for `.MAKE'.
4561       my @undefined_conds = (TRUE,);
4562       if ($_ ne '.PHONY' && $_ ne '.MAKE')
4563         {
4564           @undefined_conds =
4565             Automake::Rule::define ($_, 'internal',
4566                                     RULE_AUTOMAKE, TRUE, INTERNAL);
4567         }
4568       my @uniq_deps = uniq (sort @{$dependencies{$_}});
4569       foreach my $cond (@undefined_conds)
4570         {
4571           my $condstr = $cond->subst_string;
4572           &pretty_print_rule ("$condstr$_:", "$condstr\t", @uniq_deps);
4573           $output_rules .= $actions{$_} if defined $actions{$_};
4574           $output_rules .= "\n";
4575         }
4576     }
4577 }
4578
4579
4580 # &handle_tests_dejagnu ()
4581 # ------------------------
4582 sub handle_tests_dejagnu
4583 {
4584     push (@check_tests, 'check-DEJAGNU');
4585     $output_rules .= file_contents ('dejagnu', new Automake::Location);
4586 }
4587
4588
4589 # Handle TESTS variable and other checks.
4590 sub handle_tests
4591 {
4592   if (option 'dejagnu')
4593     {
4594       &handle_tests_dejagnu;
4595     }
4596   else
4597     {
4598       foreach my $c ('DEJATOOL', 'RUNTEST', 'RUNTESTFLAGS')
4599         {
4600           reject_var ($c, "`$c' defined but `dejagnu' not in "
4601                       . "`AUTOMAKE_OPTIONS'");
4602         }
4603     }
4604
4605   if (var ('TESTS'))
4606     {
4607       push (@check_tests, 'check-TESTS');
4608       $output_rules .= &file_contents ('check', new Automake::Location,
4609                                        COLOR => !! option 'color-tests');
4610
4611       # Tests that are known programs should have $(EXEEXT) appended.
4612       # For matching purposes, we need to adjust XFAIL_TESTS as well.
4613       append_exeext { exists $known_programs{$_[0]} } 'TESTS';
4614       append_exeext { exists $known_programs{$_[0]} } 'XFAIL_TESTS'
4615         if (var ('XFAIL_TESTS'));
4616     }
4617 }
4618
4619 # Handle Emacs Lisp.
4620 sub handle_emacs_lisp
4621 {
4622   my @elfiles = &am_install_var ('-candist', 'lisp', 'LISP',
4623                                  'lisp', 'noinst');
4624
4625   return if ! @elfiles;
4626
4627   define_pretty_variable ('am__ELFILES', TRUE, INTERNAL,
4628                           map { $_->[1] } @elfiles);
4629   define_pretty_variable ('am__ELCFILES', TRUE, INTERNAL,
4630                           '$(am__ELFILES:.el=.elc)');
4631   # This one can be overridden by users.
4632   define_pretty_variable ('ELCFILES', TRUE, INTERNAL, '$(LISP:.el=.elc)');
4633
4634   push @all, '$(ELCFILES)';
4635
4636   require_variables ($elfiles[0][0], "Emacs Lisp sources seen", TRUE,
4637                      'EMACS', 'lispdir');
4638   require_conf_file ($elfiles[0][0], FOREIGN, 'elisp-comp');
4639   &define_variable ('elisp_comp', "$am_config_aux_dir/elisp-comp", INTERNAL);
4640 }
4641
4642 # Handle Python
4643 sub handle_python
4644 {
4645   my @pyfiles = &am_install_var ('-defaultdist', 'python', 'PYTHON',
4646                                  'noinst');
4647   return if ! @pyfiles;
4648
4649   require_variables ($pyfiles[0][0], "Python sources seen", TRUE, 'PYTHON');
4650   require_conf_file ($pyfiles[0][0], FOREIGN, 'py-compile');
4651   &define_variable ('py_compile', "$am_config_aux_dir/py-compile", INTERNAL);
4652 }
4653
4654 # Handle Java.
4655 sub handle_java
4656 {
4657     my @sourcelist = &am_install_var ('-candist',
4658                                       'java', 'JAVA',
4659                                       'java', 'noinst', 'check');
4660     return if ! @sourcelist;
4661
4662     my @prefix = am_primary_prefixes ('JAVA', 1,
4663                                       'java', 'noinst', 'check');
4664
4665     my $dir;
4666     foreach my $curs (@prefix)
4667       {
4668         next
4669           if $curs eq 'EXTRA';
4670
4671         err_var "${curs}_JAVA", "multiple _JAVA primaries in use"
4672           if defined $dir;
4673         $dir = $curs;
4674       }
4675
4676
4677     push (@all, 'class' . $dir . '.stamp');
4678 }
4679
4680
4681 # Handle some of the minor options.
4682 sub handle_minor_options
4683 {
4684   if (option 'readme-alpha')
4685     {
4686       if ($relative_dir eq '.')
4687         {
4688           if ($package_version !~ /^$GNITS_VERSION_PATTERN$/)
4689             {
4690               msg ('error-gnits', $package_version_location,
4691                    "version `$package_version' doesn't follow " .
4692                    "Gnits standards");
4693             }
4694           if (defined $1 && -f 'README-alpha')
4695             {
4696               # This means we have an alpha release.  See
4697               # GNITS_VERSION_PATTERN for details.
4698               push_dist_common ('README-alpha');
4699             }
4700         }
4701     }
4702 }
4703
4704 ################################################################
4705
4706 # ($OUTPUT, @INPUTS)
4707 # &split_config_file_spec ($SPEC)
4708 # -------------------------------
4709 # Decode the Autoconf syntax for config files (files, headers, links
4710 # etc.).
4711 sub split_config_file_spec ($)
4712 {
4713   my ($spec) = @_;
4714   my ($output, @inputs) = split (/:/, $spec);
4715
4716   push @inputs, "$output.in"
4717     unless @inputs;
4718
4719   return ($output, @inputs);
4720 }
4721
4722 # $input
4723 # locate_am (@POSSIBLE_SOURCES)
4724 # -----------------------------
4725 # AC_CONFIG_FILES allow specifications such as Makefile:top.in:mid.in:bot.in
4726 # This functions returns the first *.in file for which a *.am exists.
4727 # It returns undef otherwise.
4728 sub locate_am (@)
4729 {
4730   my (@rest) = @_;
4731   my $input;
4732   foreach my $file (@rest)
4733     {
4734       if (($file =~ /^(.*)\.in$/) && -f "$1.am")
4735         {
4736           $input = $file;
4737           last;
4738         }
4739     }
4740   return $input;
4741 }
4742
4743 my %make_list;
4744
4745 # &scan_autoconf_config_files ($WHERE, $CONFIG-FILES)
4746 # ---------------------------------------------------
4747 # Study $CONFIG-FILES which is the first argument to AC_CONFIG_FILES
4748 # (or AC_OUTPUT).
4749 sub scan_autoconf_config_files ($$)
4750 {
4751   my ($where, $config_files) = @_;
4752
4753   # Look at potential Makefile.am's.
4754   foreach (split ' ', $config_files)
4755     {
4756       # Must skip empty string for Perl 4.
4757       next if $_ eq "\\" || $_ eq '';
4758
4759       # Handle $local:$input syntax.
4760       my ($local, @rest) = split (/:/);
4761       @rest = ("$local.in",) unless @rest;
4762       msg ('portability', $where,
4763           "Omit leading `./' from config file names such as `$local',"
4764           . "\nas not all make implementations treat `file' and `./file' equally.")
4765         if ($local =~ /^\.\//);
4766       my $input = locate_am @rest;
4767       if ($input)
4768         {
4769           # We have a file that automake should generate.
4770           $make_list{$input} = join (':', ($local, @rest));
4771         }
4772       else
4773         {
4774           # We have a file that automake should cause to be
4775           # rebuilt, but shouldn't generate itself.
4776           push (@other_input_files, $_);
4777         }
4778       $ac_config_files_location{$local} = $where;
4779     }
4780 }
4781
4782
4783 # &scan_autoconf_traces ($FILENAME)
4784 # ---------------------------------
4785 sub scan_autoconf_traces ($)
4786 {
4787   my ($filename) = @_;
4788
4789   # Macros to trace, with their minimal number of arguments.
4790   #
4791   # IMPORTANT: If you add a macro here, you should also add this macro
4792   # =========  to Automake-preselection in autoconf/lib/autom4te.in.
4793   my %traced = (
4794                 AC_CANONICAL_BUILD => 0,
4795                 AC_CANONICAL_HOST => 0,
4796                 AC_CANONICAL_TARGET => 0,
4797                 AC_CONFIG_AUX_DIR => 1,
4798                 AC_CONFIG_FILES => 1,
4799                 AC_CONFIG_HEADERS => 1,
4800                 AC_CONFIG_LIBOBJ_DIR => 1,
4801                 AC_CONFIG_LINKS => 1,
4802                 AC_FC_SRCEXT => 1,
4803                 AC_INIT => 0,
4804                 AC_LIBSOURCE => 1,
4805                 AC_REQUIRE_AUX_FILE => 1,
4806                 AC_SUBST_TRACE => 1,
4807                 AM_AUTOMAKE_VERSION => 1,
4808                 AM_CONDITIONAL => 2,
4809                 AM_ENABLE_MULTILIB => 0,
4810                 AM_GNU_GETTEXT => 0,
4811                 AM_GNU_GETTEXT_INTL_SUBDIR => 0,
4812                 AM_INIT_AUTOMAKE => 0,
4813                 AM_MAINTAINER_MODE => 0,
4814                 AM_PROG_CC_C_O => 0,
4815                 _AM_SUBST_NOTMAKE => 1,
4816                 LT_SUPPORTED_TAG => 1,
4817                 _LT_AC_TAGCONFIG => 0,
4818                 m4_include => 1,
4819                 m4_sinclude => 1,
4820                 sinclude => 1,
4821               );
4822
4823   my $traces = ($ENV{AUTOCONF} || 'autoconf') . " ";
4824
4825   # Use a separator unlikely to be used, not `:', the default, which
4826   # has a precise meaning for AC_CONFIG_FILES and so on.
4827   $traces .= join (' ',
4828                    map { "--trace=$_" . ':\$f:\$l::\$n::\${::}%' }
4829                    (keys %traced));
4830
4831   my $tracefh = new Automake::XFile ("$traces $filename |");
4832   verb "reading $traces";
4833
4834   while ($_ = $tracefh->getline)
4835     {
4836       chomp;
4837       my ($here, @args) = split (/::/);
4838       my $where = new Automake::Location $here;
4839       my $macro = $args[0];
4840
4841       prog_error ("unrequested trace `$macro'")
4842         unless exists $traced{$macro};
4843
4844       # Skip and diagnose malformed calls.
4845       if ($#args < $traced{$macro})
4846         {
4847           msg ('syntax', $where, "not enough arguments for $macro");
4848           next;
4849         }
4850
4851       # Alphabetical ordering please.
4852       if ($macro eq 'AC_CANONICAL_BUILD')
4853         {
4854           if ($seen_canonical <= AC_CANONICAL_BUILD)
4855             {
4856               $seen_canonical = AC_CANONICAL_BUILD;
4857               $canonical_location = $where;
4858             }
4859         }
4860       elsif ($macro eq 'AC_CANONICAL_HOST')
4861         {
4862           if ($seen_canonical <= AC_CANONICAL_HOST)
4863             {
4864               $seen_canonical = AC_CANONICAL_HOST;
4865               $canonical_location = $where;
4866             }
4867         }
4868       elsif ($macro eq 'AC_CANONICAL_TARGET')
4869         {
4870           $seen_canonical = AC_CANONICAL_TARGET;
4871           $canonical_location = $where;
4872         }
4873       elsif ($macro eq 'AC_CONFIG_AUX_DIR')
4874         {
4875           if ($seen_init_automake)
4876             {
4877               error ($where, "AC_CONFIG_AUX_DIR must be called before "
4878                      . "AM_INIT_AUTOMAKE...", partial => 1);
4879               error ($seen_init_automake, "... AM_INIT_AUTOMAKE called here");
4880             }
4881           $config_aux_dir = $args[1];
4882           $config_aux_dir_set_in_configure_ac = 1;
4883           $relative_dir = '.';
4884           check_directory ($config_aux_dir, $where);
4885         }
4886       elsif ($macro eq 'AC_CONFIG_FILES')
4887         {
4888           # Look at potential Makefile.am's.
4889           scan_autoconf_config_files ($where, $args[1]);
4890         }
4891       elsif ($macro eq 'AC_CONFIG_HEADERS')
4892         {
4893           foreach my $spec (split (' ', $args[1]))
4894             {
4895               my ($dest, @src) = split (':', $spec);
4896               $ac_config_files_location{$dest} = $where;
4897               push @config_headers, $spec;
4898             }
4899         }
4900       elsif ($macro eq 'AC_CONFIG_LIBOBJ_DIR')
4901         {
4902           $config_libobj_dir = $args[1];
4903           $relative_dir = '.';
4904           check_directory ($config_libobj_dir, $where);
4905         }
4906       elsif ($macro eq 'AC_CONFIG_LINKS')
4907         {
4908           foreach my $spec (split (' ', $args[1]))
4909             {
4910               my ($dest, $src) = split (':', $spec);
4911               $ac_config_files_location{$dest} = $where;
4912               push @config_links, $spec;
4913             }
4914         }
4915       elsif ($macro eq 'AC_FC_SRCEXT')
4916         {
4917           my $suffix = $args[1];
4918           # These flags are used as %SOURCEFLAG% in depend2.am,
4919           # where the trailing space is important.
4920           $sourceflags{'.' . $suffix} = '$(FCFLAGS_' . $suffix . ') '
4921             if ($suffix eq 'f90' || $suffix eq 'f95');
4922         }
4923       elsif ($macro eq 'AC_INIT')
4924         {
4925           if (defined $args[2])
4926             {
4927               $package_version = $args[2];
4928               $package_version_location = $where;
4929             }
4930         }
4931       elsif ($macro eq 'AC_LIBSOURCE')
4932         {
4933           $libsources{$args[1]} = $here;
4934         }
4935       elsif ($macro eq 'AC_REQUIRE_AUX_FILE')
4936         {
4937           # Only remember the first time a file is required.
4938           $required_aux_file{$args[1]} = $where
4939             unless exists $required_aux_file{$args[1]};
4940         }
4941       elsif ($macro eq 'AC_SUBST_TRACE')
4942         {
4943           # Just check for alphanumeric in AC_SUBST_TRACE.  If you do
4944           # AC_SUBST(5), then too bad.
4945           $configure_vars{$args[1]} = $where
4946             if $args[1] =~ /^\w+$/;
4947         }
4948       elsif ($macro eq 'AM_AUTOMAKE_VERSION')
4949         {
4950           error ($where,
4951                  "version mismatch.  This is Automake $VERSION,\n" .
4952                  "but the definition used by this AM_INIT_AUTOMAKE\n" .
4953                  "comes from Automake $args[1].  You should recreate\n" .
4954                  "aclocal.m4 with aclocal and run automake again.\n",
4955                  # $? = 63 is used to indicate version mismatch to missing.
4956                  exit_code => 63)
4957             if $VERSION ne $args[1];
4958
4959           $seen_automake_version = 1;
4960         }
4961       elsif ($macro eq 'AM_CONDITIONAL')
4962         {
4963           $configure_cond{$args[1]} = $where;
4964         }
4965       elsif ($macro eq 'AM_ENABLE_MULTILIB')
4966         {
4967           $seen_multilib = $where;
4968         }
4969       elsif ($macro eq 'AM_GNU_GETTEXT')
4970         {
4971           $seen_gettext = $where;
4972           $ac_gettext_location = $where;
4973           $seen_gettext_external = grep ($_ eq 'external', @args);
4974         }
4975       elsif ($macro eq 'AM_GNU_GETTEXT_INTL_SUBDIR')
4976         {
4977           $seen_gettext_intl = $where;
4978         }
4979       elsif ($macro eq 'AM_INIT_AUTOMAKE')
4980         {
4981           $seen_init_automake = $where;
4982           if (defined $args[2])
4983             {
4984               $package_version = $args[2];
4985               $package_version_location = $where;
4986             }
4987           elsif (defined $args[1])
4988             {
4989               exit $exit_code
4990                 if (process_global_option_list ($where,
4991                                                 split (' ', $args[1])));
4992             }
4993         }
4994       elsif ($macro eq 'AM_MAINTAINER_MODE')
4995         {
4996           $seen_maint_mode = $where;
4997         }
4998       elsif ($macro eq 'AM_PROG_CC_C_O')
4999         {
5000           $seen_cc_c_o = $where;
5001         }
5002       elsif ($macro eq '_AM_SUBST_NOTMAKE')
5003         {
5004           $ignored_configure_vars{$args[1]} = $where;
5005         }
5006       elsif ($macro eq 'm4_include'
5007              || $macro eq 'm4_sinclude'
5008              || $macro eq 'sinclude')
5009         {
5010           # Skip missing `sinclude'd files.
5011           next if $macro ne 'm4_include' && ! -f $args[1];
5012
5013           # Some modified versions of Autoconf don't use
5014           # frozen files.  Consequently it's possible that we see all
5015           # m4_include's performed during Autoconf's startup.
5016           # Obviously we don't want to distribute Autoconf's files
5017           # so we skip absolute filenames here.
5018           push @configure_deps, '$(top_srcdir)/' . $args[1]
5019             unless $here =~ m,^(?:\w:)?[\\/],;
5020           # Keep track of the greatest timestamp.
5021           if (-e $args[1])
5022             {
5023               my $mtime = mtime $args[1];
5024               $configure_deps_greatest_timestamp = $mtime
5025                 if $mtime > $configure_deps_greatest_timestamp;
5026             }
5027         }
5028       elsif ($macro eq 'LT_SUPPORTED_TAG')
5029         {
5030           $libtool_tags{$args[1]} = 1;
5031           $libtool_new_api = 1;
5032         }
5033       elsif ($macro eq '_LT_AC_TAGCONFIG')
5034         {
5035           # _LT_AC_TAGCONFIG is an old macro present in Libtool 1.5.
5036           # We use it to detect whether tags are supported.  Our
5037           # preferred interface is LT_SUPPORTED_TAG, but it was
5038           # introduced in Libtool 1.6.
5039           if (0 == keys %libtool_tags)
5040             {
5041               # Hardcode the tags supported by Libtool 1.5.
5042               %libtool_tags = (CC => 1, CXX => 1, GCJ => 1, F77 => 1);
5043             }
5044         }
5045     }
5046
5047   $tracefh->close;
5048 }
5049
5050
5051 # &scan_autoconf_files ()
5052 # -----------------------
5053 # Check whether we use `configure.ac' or `configure.in'.
5054 # Scan it (and possibly `aclocal.m4') for interesting things.
5055 # We must scan aclocal.m4 because there might be AC_SUBSTs and such there.
5056 sub scan_autoconf_files ()
5057 {
5058   # Reinitialize libsources here.  This isn't really necessary,
5059   # since we currently assume there is only one configure.ac.  But
5060   # that won't always be the case.
5061   %libsources = ();
5062
5063   # Keep track of the youngest configure dependency.
5064   $configure_deps_greatest_timestamp = mtime $configure_ac;
5065   if (-e 'aclocal.m4')
5066     {
5067       my $mtime = mtime 'aclocal.m4';
5068       $configure_deps_greatest_timestamp = $mtime
5069         if $mtime > $configure_deps_greatest_timestamp;
5070     }
5071
5072   scan_autoconf_traces ($configure_ac);
5073
5074   @configure_input_files = sort keys %make_list;
5075   # Set input and output files if not specified by user.
5076   if (! @input_files)
5077     {
5078       @input_files = @configure_input_files;
5079       %output_files = %make_list;
5080     }
5081
5082
5083   if (! $seen_init_automake)
5084     {
5085       err_ac ("no proper invocation of AM_INIT_AUTOMAKE was found.\nYou "
5086               . "should verify that $configure_ac invokes AM_INIT_AUTOMAKE,"
5087               . "\nthat aclocal.m4 is present in the top-level directory,\n"
5088               . "and that aclocal.m4 was recently regenerated "
5089               . "(using aclocal).");
5090     }
5091   else
5092     {
5093       if (! $seen_automake_version)
5094         {
5095           if (-f 'aclocal.m4')
5096             {
5097               error ($seen_init_automake,
5098                      "your implementation of AM_INIT_AUTOMAKE comes from " .
5099                      "an\nold Automake version.  You should recreate " .
5100                      "aclocal.m4\nwith aclocal and run automake again.\n",
5101                      # $? = 63 is used to indicate version mismatch to missing.
5102                      exit_code => 63);
5103             }
5104           else
5105             {
5106               error ($seen_init_automake,
5107                      "no proper implementation of AM_INIT_AUTOMAKE was " .
5108                      "found,\nprobably because aclocal.m4 is missing...\n" .
5109                      "You should run aclocal to create this file, then\n" .
5110                      "run automake again.\n");
5111             }
5112         }
5113     }
5114
5115   locate_aux_dir ();
5116
5117   # Reorder @input_files so that the Makefile that distributes aux
5118   # files is processed last.  This is important because each directory
5119   # can require auxiliary scripts and we should wait until they have
5120   # been installed before distributing them.
5121
5122   # The Makefile.in that distribute the aux files is the one in
5123   # $config_aux_dir or the top-level Makefile.
5124   my $auxdirdist = is_make_dir ($config_aux_dir) ? $config_aux_dir : '.';
5125   my @new_input_files = ();
5126   while (@input_files)
5127     {
5128       my $in = pop @input_files;
5129       my @ins = split (/:/, $output_files{$in});
5130       if (dirname ($ins[0]) eq $auxdirdist)
5131         {
5132           push @new_input_files, $in;
5133           $automake_will_process_aux_dir = 1;
5134         }
5135       else
5136         {
5137           unshift @new_input_files, $in;
5138         }
5139     }
5140   @input_files = @new_input_files;
5141
5142   # If neither the auxdir/Makefile nor the ./Makefile are generated
5143   # by Automake, we won't distribute the aux files anyway.  Assume
5144   # the user know what (s)he does, and pretend we will distribute
5145   # them to disable the error in require_file_internal.
5146   $automake_will_process_aux_dir = 1 if ! is_make_dir ($auxdirdist);
5147
5148   # Look for some files we need.  Always check for these.  This
5149   # check must be done for every run, even those where we are only
5150   # looking at a subdir Makefile.  We must set relative_dir for
5151   # maybe_push_required_file to work.
5152   $relative_dir = '.';
5153   foreach my $file (keys %required_aux_file)
5154     {
5155       require_conf_file ($required_aux_file{$file}->get, FOREIGN, $file)
5156     }
5157   err_am "`install.sh' is an anachronism; use `install-sh' instead"
5158     if -f $config_aux_dir . '/install.sh';
5159
5160   # Preserve dist_common for later.
5161   $configure_dist_common = variable_value ('DIST_COMMON') || '';
5162
5163 }
5164
5165 ################################################################
5166
5167 # Set up for Cygnus mode.
5168 sub check_cygnus
5169 {
5170   my $cygnus = option 'cygnus';
5171   return unless $cygnus;
5172
5173   set_strictness ('foreign');
5174   set_option ('no-installinfo', $cygnus);
5175   set_option ('no-dependencies', $cygnus);
5176   set_option ('no-dist', $cygnus);
5177
5178   err_ac "`AM_MAINTAINER_MODE' required when --cygnus specified"
5179     if !$seen_maint_mode;
5180 }
5181
5182 # Do any extra checking for GNU standards.
5183 sub check_gnu_standards
5184 {
5185   if ($relative_dir eq '.')
5186     {
5187       # In top level (or only) directory.
5188       require_file ("$am_file.am", GNU,
5189                     qw/INSTALL NEWS README AUTHORS ChangeLog/);
5190
5191       # Accept one of these three licenses; default to COPYING.
5192       # Make sure we do not overwrite an existing license.
5193       my $license;
5194       foreach (qw /COPYING COPYING.LIB COPYING.LESSER/)
5195         {
5196           if (-f $_)
5197             {
5198               $license = $_;
5199               last;
5200             }
5201         }
5202       require_file ("$am_file.am", GNU, 'COPYING')
5203         unless $license;
5204     }
5205
5206   for my $opt ('no-installman', 'no-installinfo')
5207     {
5208       msg ('error-gnu', option $opt,
5209            "option `$opt' disallowed by GNU standards")
5210         if option $opt;
5211     }
5212 }
5213
5214 # Do any extra checking for GNITS standards.
5215 sub check_gnits_standards
5216 {
5217   if ($relative_dir eq '.')
5218     {
5219       # In top level (or only) directory.
5220       require_file ("$am_file.am", GNITS, 'THANKS');
5221     }
5222 }
5223
5224 ################################################################
5225 #
5226 # Functions to handle files of each language.
5227
5228 # Each `lang_X_rewrite($DIRECTORY, $BASE, $EXT)' function follows a
5229 # simple formula: Return value is LANG_SUBDIR if the resulting object
5230 # file should be in a subdir if the source file is, LANG_PROCESS if
5231 # file is to be dealt with, LANG_IGNORE otherwise.
5232
5233 # Much of the actual processing is handled in
5234 # handle_single_transform.  These functions exist so that
5235 # auxiliary information can be recorded for a later cleanup pass.
5236 # Note that the calls to these functions are computed, so don't bother
5237 # searching for their precise names in the source.
5238
5239 # This is just a convenience function that can be used to determine
5240 # when a subdir object should be used.
5241 sub lang_sub_obj
5242 {
5243     return option 'subdir-objects' ? LANG_SUBDIR : LANG_PROCESS;
5244 }
5245
5246 # Rewrite a single C source file.
5247 sub lang_c_rewrite
5248 {
5249   my ($directory, $base, $ext, $nonansi_obj, $have_per_exec_flags, $var) = @_;
5250
5251   if (option 'ansi2knr' && $base =~ /_$/)
5252     {
5253       # FIXME: include line number in error.
5254       err_am "C source file `$base.c' would be deleted by ansi2knr rules";
5255     }
5256
5257   my $r = LANG_PROCESS;
5258   if (option 'subdir-objects')
5259     {
5260       $r = LANG_SUBDIR;
5261       if ($directory && $directory ne '.')
5262         {
5263           $base = $directory . '/' . $base;
5264
5265           # libtool is always able to put the object at the proper place,
5266           # so we do not have to require AM_PROG_CC_C_O when building .lo files.
5267           msg_var ('portability', $var,
5268                    "compiling `$base.c' in subdir requires "
5269                    . "`AM_PROG_CC_C_O' in `$configure_ac'",
5270                    uniq_scope => US_GLOBAL,
5271                    uniq_part => 'AM_PROG_CC_C_O subdir')
5272             unless $seen_cc_c_o || $nonansi_obj eq '.lo';
5273         }
5274
5275       # In this case we already have the directory information, so
5276       # don't add it again.
5277       $de_ansi_files{$base} = '';
5278     }
5279   else
5280     {
5281       $de_ansi_files{$base} = (($directory eq '.' || $directory eq '')
5282                                ? ''
5283                                : "$directory/");
5284     }
5285
5286   if (! $seen_cc_c_o
5287       && $have_per_exec_flags
5288       && ! option 'subdir-objects'
5289       && $nonansi_obj ne '.lo')
5290     {
5291       msg_var ('portability',
5292                $var, "compiling `$base.c' with per-target flags requires "
5293                . "`AM_PROG_CC_C_O' in `$configure_ac'",
5294                uniq_scope => US_GLOBAL,
5295                uniq_part => 'AM_PROG_CC_C_O per-target')
5296     }
5297
5298     return $r;
5299 }
5300
5301 # Rewrite a single C++ source file.
5302 sub lang_cxx_rewrite
5303 {
5304     return &lang_sub_obj;
5305 }
5306
5307 # Rewrite a single header file.
5308 sub lang_header_rewrite
5309 {
5310     # Header files are simply ignored.
5311     return LANG_IGNORE;
5312 }
5313
5314 # Rewrite a single yacc file.
5315 sub lang_yacc_rewrite
5316 {
5317     my ($directory, $base, $ext) = @_;
5318
5319     my $r = &lang_sub_obj;
5320     (my $newext = $ext) =~ tr/y/c/;
5321     return ($r, $newext);
5322 }
5323
5324 # Rewrite a single yacc++ file.
5325 sub lang_yaccxx_rewrite
5326 {
5327     my ($directory, $base, $ext) = @_;
5328
5329     my $r = &lang_sub_obj;
5330     (my $newext = $ext) =~ tr/y/c/;
5331     return ($r, $newext);
5332 }
5333
5334 # Rewrite a single lex file.
5335 sub lang_lex_rewrite
5336 {
5337     my ($directory, $base, $ext) = @_;
5338
5339     my $r = &lang_sub_obj;
5340     (my $newext = $ext) =~ tr/l/c/;
5341     return ($r, $newext);
5342 }
5343
5344 # Rewrite a single lex++ file.
5345 sub lang_lexxx_rewrite
5346 {
5347     my ($directory, $base, $ext) = @_;
5348
5349     my $r = &lang_sub_obj;
5350     (my $newext = $ext) =~ tr/l/c/;
5351     return ($r, $newext);
5352 }
5353
5354 # Rewrite a single assembly file.
5355 sub lang_asm_rewrite
5356 {
5357     return &lang_sub_obj;
5358 }
5359
5360 # Rewrite a single preprocessed assembly file.
5361 sub lang_cppasm_rewrite
5362 {
5363     return &lang_sub_obj;
5364 }
5365
5366 # Rewrite a single Fortran 77 file.
5367 sub lang_f77_rewrite
5368 {
5369     return &lang_sub_obj;
5370 }
5371
5372 # Rewrite a single Fortran file.
5373 sub lang_fc_rewrite
5374 {
5375     return &lang_sub_obj;
5376 }
5377
5378 # Rewrite a single preprocessed Fortran file.
5379 sub lang_ppfc_rewrite
5380 {
5381     return &lang_sub_obj;
5382 }
5383
5384 # Rewrite a single preprocessed Fortran 77 file.
5385 sub lang_ppf77_rewrite
5386 {
5387     return &lang_sub_obj;
5388 }
5389
5390 # Rewrite a single ratfor file.
5391 sub lang_ratfor_rewrite
5392 {
5393     return &lang_sub_obj;
5394 }
5395
5396 # Rewrite a single Objective C file.
5397 sub lang_objc_rewrite
5398 {
5399     return &lang_sub_obj;
5400 }
5401
5402 # Rewrite a single Unified Parallel C file.
5403 sub lang_upc_rewrite
5404 {
5405     return &lang_sub_obj;
5406 }
5407
5408 # Rewrite a single Java file.
5409 sub lang_java_rewrite
5410 {
5411     return LANG_SUBDIR;
5412 }
5413
5414 # The lang_X_finish functions are called after all source file
5415 # processing is done.  Each should handle defining rules for the
5416 # language, etc.  A finish function is only called if a source file of
5417 # the appropriate type has been seen.
5418
5419 sub lang_c_finish
5420 {
5421     # Push all libobjs files onto de_ansi_files.  We actually only
5422     # push files which exist in the current directory, and which are
5423     # genuine source files.
5424     foreach my $file (keys %libsources)
5425     {
5426         if ($file =~ /^(.*)\.[cly]$/ && -f "$relative_dir/$file")
5427         {
5428             $de_ansi_files{$1} = ''
5429         }
5430     }
5431
5432     if (option 'ansi2knr' && keys %de_ansi_files)
5433     {
5434         # Make all _.c files depend on their corresponding .c files.
5435         my @objects;
5436         foreach my $base (sort keys %de_ansi_files)
5437         {
5438             # Each _.c file must depend on ansi2knr; otherwise it
5439             # might be used in a parallel build before it is built.
5440             # We need to support files in the srcdir and in the build
5441             # dir (because these files might be auto-generated.  But
5442             # we can't use $< -- some makes only define $< during a
5443             # suffix rule.
5444             my $ansfile = $de_ansi_files{$base} . $base . '.c';
5445             $output_rules .= ($base . "_.c: $ansfile \$(ANSI2KNR)\n\t"
5446                               . '$(CPP) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) '
5447                               . '`if test -f $(srcdir)/' . $ansfile
5448                               . '; then echo $(srcdir)/' . $ansfile
5449                               . '; else echo ' . $ansfile . '; fi` '
5450                               . "| sed 's/^# \\([0-9]\\)/#line \\1/' "
5451                               . '| $(ANSI2KNR) > $@'
5452                               # If ansi2knr fails then we shouldn't
5453                               # create the _.c file
5454                               . " || rm -f \$\@\n");
5455             push (@objects, $base . '_.$(OBJEXT)');
5456             push (@objects, $base . '_.lo')
5457               if var ('LIBTOOL');
5458
5459             # Explicitly clean the _.c files if they are in a
5460             # subdirectory. (In the current directory they get erased
5461             # by a `rm -f *_.c' rule.)
5462             $clean_files{$base . '_.c'} = MOSTLY_CLEAN
5463               if dirname ($base) ne '.';
5464         }
5465
5466         # Make all _.o (and _.lo) files depend on ansi2knr.
5467         # Use a sneaky little hack to make it print nicely.
5468         &pretty_print_rule ('', '', @objects, ':', '$(ANSI2KNR)');
5469     }
5470 }
5471
5472 # This is a yacc helper which is called whenever we have decided to
5473 # compile a yacc file.
5474 sub lang_yacc_target_hook
5475 {
5476     my ($self, $aggregate, $output, $input, %transform) = @_;
5477
5478     my $flag = $aggregate . "_YFLAGS";
5479     my $flagvar = var $flag;
5480     my $YFLAGSvar = var 'YFLAGS';
5481     if (($flagvar && $flagvar->variable_value =~ /$DASH_D_PATTERN/o)
5482         || ($YFLAGSvar && $YFLAGSvar->variable_value =~ /$DASH_D_PATTERN/o))
5483     {
5484         (my $output_base = $output) =~ s/$KNOWN_EXTENSIONS_PATTERN$//;
5485         my $header = $output_base . '.h';
5486
5487         # Found a `-d' that applies to the compilation of this file.
5488         # Add a dependency for the generated header file, and arrange
5489         # for that file to be included in the distribution.
5490         foreach my $cond (Automake::Rule::define (${header}, 'internal',
5491                                                   RULE_AUTOMAKE, TRUE,
5492                                                   INTERNAL))
5493           {
5494             my $condstr = $cond->subst_string;
5495             $output_rules .=
5496               "$condstr${header}: $output\n"
5497               # Recover from removal of $header
5498               . "$condstr\t\@if test ! -f \$@; then \\\n"
5499               . "$condstr\t  rm -f $output; \\\n"
5500               . "$condstr\t  \$(MAKE) \$(AM_MAKEFLAGS) $output; \\\n"
5501               . "$condstr\telse :; fi\n";
5502           }
5503         # Distribute the generated file, unless its .y source was
5504         # listed in a nodist_ variable.  (&handle_source_transform
5505         # will set DIST_SOURCE.)
5506         &push_dist_common ($header)
5507           if $transform{'DIST_SOURCE'};
5508
5509         # If the files are built in the build directory, then we want
5510         # to remove them with `make clean'.  If they are in srcdir
5511         # they shouldn't be touched.  However, we can't determine this
5512         # statically, and the GNU rules say that yacc/lex output files
5513         # should be removed by maintainer-clean.  So that's what we
5514         # do.
5515         $clean_files{$header} = MAINTAINER_CLEAN;
5516     }
5517     # Erase $OUTPUT on `make maintainer-clean' (by GNU standards).
5518     # See the comment above for $HEADER.
5519     $clean_files{$output} = MAINTAINER_CLEAN;
5520 }
5521
5522 # This is a lex helper which is called whenever we have decided to
5523 # compile a lex file.
5524 sub lang_lex_target_hook
5525 {
5526     my ($self, $aggregate, $output, $input) = @_;
5527     # If the files are built in the build directory, then we want to
5528     # remove them with `make clean'.  If they are in srcdir they
5529     # shouldn't be touched.  However, we can't determine this
5530     # statically, and the GNU rules say that yacc/lex output files
5531     # should be removed by maintainer-clean.  So that's what we do.
5532     $clean_files{$output} = MAINTAINER_CLEAN;
5533 }
5534
5535 # This is a helper for both lex and yacc.
5536 sub yacc_lex_finish_helper
5537 {
5538   return if defined $language_scratch{'lex-yacc-done'};
5539   $language_scratch{'lex-yacc-done'} = 1;
5540
5541   # FIXME: for now, no line number.
5542   require_conf_file ($configure_ac, FOREIGN, 'ylwrap');
5543   &define_variable ('YLWRAP', "$am_config_aux_dir/ylwrap", INTERNAL);
5544 }
5545
5546 sub lang_yacc_finish
5547 {
5548   return if defined $language_scratch{'yacc-done'};
5549   $language_scratch{'yacc-done'} = 1;
5550
5551   reject_var 'YACCFLAGS', "`YACCFLAGS' obsolete; use `YFLAGS' instead";
5552
5553   yacc_lex_finish_helper;
5554 }
5555
5556
5557 sub lang_lex_finish
5558 {
5559   return if defined $language_scratch{'lex-done'};
5560   $language_scratch{'lex-done'} = 1;
5561
5562   yacc_lex_finish_helper;
5563 }
5564
5565
5566 # Given a hash table of linker names, pick the name that has the most
5567 # precedence.  This is lame, but something has to have global
5568 # knowledge in order to eliminate the conflict.  Add more linkers as
5569 # required.
5570 sub resolve_linker
5571 {
5572     my (%linkers) = @_;
5573
5574     foreach my $l (qw(GCJLINK CXXLINK F77LINK FCLINK OBJCLINK UPCLINK))
5575     {
5576         return $l if defined $linkers{$l};
5577     }
5578     return 'LINK';
5579 }
5580
5581 # Called to indicate that an extension was used.
5582 sub saw_extension
5583 {
5584     my ($ext) = @_;
5585     if (! defined $extension_seen{$ext})
5586     {
5587         $extension_seen{$ext} = 1;
5588     }
5589     else
5590     {
5591         ++$extension_seen{$ext};
5592     }
5593 }
5594
5595 # Return the number of files seen for a given language.  Knows about
5596 # special cases we care about.  FIXME: this is hideous.  We need
5597 # something that involves real language objects.  For instance yacc
5598 # and yaccxx could both derive from a common yacc class which would
5599 # know about the strange ylwrap requirement.  (Or better yet we could
5600 # just not support legacy yacc!)
5601 sub count_files_for_language
5602 {
5603     my ($name) = @_;
5604
5605     my @names;
5606     if ($name eq 'yacc' || $name eq 'yaccxx')
5607     {
5608         @names = ('yacc', 'yaccxx');
5609     }
5610     elsif ($name eq 'lex' || $name eq 'lexxx')
5611     {
5612         @names = ('lex', 'lexxx');
5613     }
5614     else
5615     {
5616         @names = ($name);
5617     }
5618
5619     my $r = 0;
5620     foreach $name (@names)
5621     {
5622         my $lang = $languages{$name};
5623         foreach my $ext (@{$lang->extensions})
5624         {
5625             $r += $extension_seen{$ext}
5626                 if defined $extension_seen{$ext};
5627         }
5628     }
5629
5630     return $r
5631 }
5632
5633 # Called to ask whether source files have been seen . If HEADERS is 1,
5634 # headers can be included.
5635 sub saw_sources_p
5636 {
5637     my ($headers) = @_;
5638
5639     # count all the sources
5640     my $count = 0;
5641     foreach my $val (values %extension_seen)
5642     {
5643         $count += $val;
5644     }
5645
5646     if (!$headers)
5647     {
5648         $count -= count_files_for_language ('header');
5649     }
5650
5651     return $count > 0;
5652 }
5653
5654
5655 # register_language (%ATTRIBUTE)
5656 # ------------------------------
5657 # Register a single language.
5658 # Each %ATTRIBUTE is of the form ATTRIBUTE => VALUE.
5659 sub register_language (%)
5660 {
5661   my (%option) = @_;
5662
5663   # Set the defaults.
5664   $option{'ansi'} = 0
5665     unless defined $option{'ansi'};
5666   $option{'autodep'} = 'no'
5667     unless defined $option{'autodep'};
5668   $option{'linker'} = ''
5669     unless defined $option{'linker'};
5670   $option{'flags'} = []
5671     unless defined $option{'flags'};
5672   $option{'output_extensions'} = sub { return ( '.$(OBJEXT)', '.lo' ) }
5673     unless defined $option{'output_extensions'};
5674   $option{'nodist_specific'} = 0
5675     unless defined $option{'nodist_specific'};
5676
5677   my $lang = new Language (%option);
5678
5679   # Fill indexes.
5680   $extension_map{$_} = $lang->name foreach @{$lang->extensions};
5681   $languages{$lang->name} = $lang;
5682   my $link = $lang->linker;
5683   if ($link)
5684     {
5685       if (exists $link_languages{$link})
5686         {
5687           prog_error ("`$link' has different definitions in "
5688                       . $lang->name . " and " . $link_languages{$link}->name)
5689             if $lang->link ne $link_languages{$link}->link;
5690         }
5691       else
5692         {
5693           $link_languages{$link} = $lang;
5694         }
5695     }
5696
5697   # Update the pattern of known extensions.
5698   accept_extensions (@{$lang->extensions});
5699
5700   # Upate the $suffix_rule map.
5701   foreach my $suffix (@{$lang->extensions})
5702     {
5703       foreach my $dest (&{$lang->output_extensions} ($suffix))
5704         {
5705           register_suffix_rule (INTERNAL, $suffix, $dest);
5706         }
5707     }
5708 }
5709
5710 # derive_suffix ($EXT, $OBJ)
5711 # --------------------------
5712 # This function is used to find a path from a user-specified suffix $EXT
5713 # to $OBJ or to some other suffix we recognize internally, e.g. `cc'.
5714 sub derive_suffix ($$)
5715 {
5716   my ($source_ext, $obj) = @_;
5717
5718   while (! $extension_map{$source_ext}
5719          && $source_ext ne $obj
5720          && exists $suffix_rules->{$source_ext}
5721          && exists $suffix_rules->{$source_ext}{$obj})
5722     {
5723       $source_ext = $suffix_rules->{$source_ext}{$obj}[0];
5724     }
5725
5726   return $source_ext;
5727 }
5728
5729
5730 ################################################################
5731
5732 # Pretty-print something and append to output_rules.
5733 sub pretty_print_rule
5734 {
5735     $output_rules .= &makefile_wrap (@_);
5736 }
5737
5738
5739 ################################################################
5740
5741
5742 ## -------------------------------- ##
5743 ## Handling the conditional stack.  ##
5744 ## -------------------------------- ##
5745
5746
5747 # $STRING
5748 # make_conditional_string ($NEGATE, $COND)
5749 # ----------------------------------------
5750 sub make_conditional_string ($$)
5751 {
5752   my ($negate, $cond) = @_;
5753   $cond = "${cond}_TRUE"
5754     unless $cond =~ /^TRUE|FALSE$/;
5755   $cond = Automake::Condition::conditional_negate ($cond)
5756     if $negate;
5757   return $cond;
5758 }
5759
5760
5761 my %_am_macro_for_cond =
5762   (
5763   AMDEP => "one of the compiler tests\n"
5764            . "    AC_PROG_CC, AC_PROG_CXX, AC_PROG_CXX, AC_PROG_OBJC,\n"
5765            . "    AM_PROG_AS, AM_PROG_GCJ, AM_PROG_UPC",
5766   am__fastdepCC => 'AC_PROG_CC',
5767   am__fastdepCCAS => 'AM_PROG_AS',
5768   am__fastdepCXX => 'AC_PROG_CXX',
5769   am__fastdepGCJ => 'AM_PROG_GCJ',
5770   am__fastdepOBJC => 'AC_PROG_OBJC',
5771   am__fastdepUPC => 'AM_PROG_UPC'
5772   );
5773
5774 # $COND
5775 # cond_stack_if ($NEGATE, $COND, $WHERE)
5776 # --------------------------------------
5777 sub cond_stack_if ($$$)
5778 {
5779   my ($negate, $cond, $where) = @_;
5780
5781   if (! $configure_cond{$cond} && $cond !~ /^TRUE|FALSE$/)
5782     {
5783       my $text = "$cond does not appear in AM_CONDITIONAL";
5784       my $scope = US_LOCAL;
5785       if (exists $_am_macro_for_cond{$cond})
5786         {
5787           my $mac = $_am_macro_for_cond{$cond};
5788           $text .= "\n  The usual way to define `$cond' is to add ";
5789           $text .= ($mac =~ / /) ? $mac : "`$mac'";
5790           $text .= "\n  to `$configure_ac' and run `aclocal' and `autoconf' again.";
5791           # These warnings appear in Automake files (depend2.am),
5792           # so there is no need to display them more than once:
5793           $scope = US_GLOBAL;
5794         }
5795       error $where, $text, uniq_scope => $scope;
5796     }
5797
5798   push (@cond_stack, make_conditional_string ($negate, $cond));
5799
5800   return new Automake::Condition (@cond_stack);
5801 }
5802
5803
5804 # $COND
5805 # cond_stack_else ($NEGATE, $COND, $WHERE)
5806 # ----------------------------------------
5807 sub cond_stack_else ($$$)
5808 {
5809   my ($negate, $cond, $where) = @_;
5810
5811   if (! @cond_stack)
5812     {
5813       error $where, "else without if";
5814       return FALSE;
5815     }
5816
5817   $cond_stack[$#cond_stack] =
5818     Automake::Condition::conditional_negate ($cond_stack[$#cond_stack]);
5819
5820   # If $COND is given, check against it.
5821   if (defined $cond)
5822     {
5823       $cond = make_conditional_string ($negate, $cond);
5824
5825       error ($where, "else reminder ($negate$cond) incompatible with "
5826              . "current conditional: $cond_stack[$#cond_stack]")
5827         if $cond_stack[$#cond_stack] ne $cond;
5828     }
5829
5830   return new Automake::Condition (@cond_stack);
5831 }
5832
5833
5834 # $COND
5835 # cond_stack_endif ($NEGATE, $COND, $WHERE)
5836 # -----------------------------------------
5837 sub cond_stack_endif ($$$)
5838 {
5839   my ($negate, $cond, $where) = @_;
5840   my $old_cond;
5841
5842   if (! @cond_stack)
5843     {
5844       error $where, "endif without if";
5845       return TRUE;
5846     }
5847
5848   # If $COND is given, check against it.
5849   if (defined $cond)
5850     {
5851       $cond = make_conditional_string ($negate, $cond);
5852
5853       error ($where, "endif reminder ($negate$cond) incompatible with "
5854              . "current conditional: $cond_stack[$#cond_stack]")
5855         if $cond_stack[$#cond_stack] ne $cond;
5856     }
5857
5858   pop @cond_stack;
5859
5860   return new Automake::Condition (@cond_stack);
5861 }
5862
5863
5864
5865
5866
5867 ## ------------------------ ##
5868 ## Handling the variables.  ##
5869 ## ------------------------ ##
5870
5871
5872 # &define_pretty_variable ($VAR, $COND, $WHERE, @VALUE)
5873 # -----------------------------------------------------
5874 # Like define_variable, but the value is a list, and the variable may
5875 # be defined conditionally.  The second argument is the Condition
5876 # under which the value should be defined; this should be the empty
5877 # string to define the variable unconditionally.  The third argument
5878 # is a list holding the values to use for the variable.  The value is
5879 # pretty printed in the output file.
5880 sub define_pretty_variable ($$$@)
5881 {
5882     my ($var, $cond, $where, @value) = @_;
5883
5884     if (! vardef ($var, $cond))
5885     {
5886         Automake::Variable::define ($var, VAR_AUTOMAKE, '', $cond, "@value",
5887                                     '', $where, VAR_PRETTY);
5888         rvar ($var)->rdef ($cond)->set_seen;
5889     }
5890 }
5891
5892
5893 # define_variable ($VAR, $VALUE, $WHERE)
5894 # --------------------------------------
5895 # Define a new Automake Makefile variable VAR to VALUE, but only if
5896 # not already defined.
5897 sub define_variable ($$$)
5898 {
5899     my ($var, $value, $where) = @_;
5900     define_pretty_variable ($var, TRUE, $where, $value);
5901 }
5902
5903
5904 # define_files_variable ($VAR, \@BASENAME, $EXTENSION, $WHERE)
5905 # -----------------------------------------------------------
5906 # Define the $VAR which content is the list of file names composed of
5907 # a @BASENAME and the $EXTENSION.
5908 sub define_files_variable ($\@$$)
5909 {
5910   my ($var, $basename, $extension, $where) = @_;
5911   define_variable ($var,
5912                    join (' ', map { "$_.$extension" } @$basename),
5913                    $where);
5914 }
5915
5916
5917 # Like define_variable, but define a variable to be the configure
5918 # substitution by the same name.
5919 sub define_configure_variable ($)
5920 {
5921   my ($var) = @_;
5922
5923   my $pretty = VAR_ASIS;
5924   my $owner = VAR_CONFIGURE;
5925
5926   # Some variables we do not want to output.  For instance it
5927   # would be a bad idea to output `U = @U@` when `@U@` can be
5928   # substituted as `\`.
5929   $pretty = VAR_SILENT if exists $ignored_configure_vars{$var};
5930
5931   # ANSI2KNR is a variable that Automake wants to redefine, so
5932   # it must be owned by Automake.  (It is also used as a proof
5933   # that AM_C_PROTOTYPES has been run, that's why we do not simply
5934   # omit the AC_SUBST.)
5935   $owner = VAR_AUTOMAKE if $var eq 'ANSI2KNR';
5936
5937   Automake::Variable::define ($var, $owner, '', TRUE, subst $var,
5938                               '', $configure_vars{$var}, $pretty);
5939 }
5940
5941
5942 # define_compiler_variable ($LANG)
5943 # --------------------------------
5944 # Define a compiler variable.  We also handle defining the `LT'
5945 # version of the command when using libtool.
5946 sub define_compiler_variable ($)
5947 {
5948     my ($lang) = @_;
5949
5950     my ($var, $value) = ($lang->compiler, $lang->compile);
5951     my $libtool_tag = '';
5952     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
5953       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
5954     &define_variable ($var, $value, INTERNAL);
5955     &define_variable ("LT$var",
5956                       "\$(LIBTOOL) $libtool_tag\$(AM_LIBTOOLFLAGS) "
5957                       . "\$(LIBTOOLFLAGS) --mode=compile $value",
5958                       INTERNAL)
5959       if var ('LIBTOOL');
5960 }
5961
5962
5963 # define_linker_variable ($LANG)
5964 # ------------------------------
5965 # Define linker variables.
5966 sub define_linker_variable ($)
5967 {
5968     my ($lang) = @_;
5969
5970     my $libtool_tag = '';
5971     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
5972       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
5973     # CCLD = $(CC).
5974     &define_variable ($lang->lder, $lang->ld, INTERNAL);
5975     # CCLINK = $(CCLD) blah blah...
5976     &define_variable ($lang->linker,
5977                       ((var ('LIBTOOL') ?
5978                         "\$(LIBTOOL) $libtool_tag\$(AM_LIBTOOLFLAGS) "
5979                         . "\$(LIBTOOLFLAGS) --mode=link " : '')
5980                        . $lang->link),
5981                       INTERNAL);
5982 }
5983
5984 sub define_per_target_linker_variable ($$)
5985 {
5986   my ($linker, $target) = @_;
5987
5988   # If the user wrote a custom link command, we don't define ours.
5989   return "${target}_LINK"
5990     if set_seen "${target}_LINK";
5991
5992   my $xlink = $linker ? $linker : 'LINK';
5993
5994   my $lang = $link_languages{$xlink};
5995   prog_error "Unknown language for linker variable `$xlink'"
5996     unless $lang;
5997
5998   my $link_command = $lang->link;
5999   if (var 'LIBTOOL')
6000     {
6001       my $libtool_tag = '';
6002       $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6003         if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6004
6005       $link_command =
6006         "\$(LIBTOOL) $libtool_tag\$(AM_LIBTOOLFLAGS) \$(LIBTOOLFLAGS) "
6007         . "--mode=link " . $link_command;
6008     }
6009
6010   # Rewrite each occurrence of `AM_$flag' in the link
6011   # command into `${derived}_$flag' if it exists.
6012   my $orig_command = $link_command;
6013   my @flags = (@{$lang->flags}, 'LDFLAGS');
6014   push @flags, 'LIBTOOLFLAGS' if var 'LIBTOOL';
6015   for my $flag (@flags)
6016     {
6017       my $val = "${target}_$flag";
6018       $link_command =~ s/\(AM_$flag\)/\($val\)/
6019         if set_seen ($val);
6020     }
6021
6022   # If the computed command is the same as the generic command, use
6023   # the command linker variable.
6024   return $lang->linker
6025     if $link_command eq $orig_command;
6026
6027   &define_variable ("${target}_LINK", $link_command, INTERNAL);
6028   return "${target}_LINK";
6029 }
6030
6031 ################################################################
6032
6033 # &check_trailing_slash ($WHERE, $LINE)
6034 # --------------------------------------
6035 # Return 1 iff $LINE ends with a slash.
6036 # Might modify $LINE.
6037 sub check_trailing_slash ($\$)
6038 {
6039   my ($where, $line) = @_;
6040
6041   # Ignore `##' lines.
6042   return 0 if $$line =~ /$IGNORE_PATTERN/o;
6043
6044   # Catch and fix a common error.
6045   msg "syntax", $where, "whitespace following trailing backslash"
6046     if $$line =~ s/\\\s+\n$/\\\n/;
6047
6048   return $$line =~ /\\$/;
6049 }
6050
6051
6052 # &read_am_file ($AMFILE, $WHERE)
6053 # -------------------------------
6054 # Read Makefile.am and set up %contents.  Simultaneously copy lines
6055 # from Makefile.am into $output_trailer, or define variables as
6056 # appropriate.  NOTE we put rules in the trailer section.  We want
6057 # user rules to come after our generated stuff.
6058 sub read_am_file ($$)
6059 {
6060     my ($amfile, $where) = @_;
6061
6062     my $am_file = new Automake::XFile ("< $amfile");
6063     verb "reading $amfile";
6064
6065     # Keep track of the youngest output dependency.
6066     my $mtime = mtime $amfile;
6067     $output_deps_greatest_timestamp = $mtime
6068       if $mtime > $output_deps_greatest_timestamp;
6069
6070     my $spacing = '';
6071     my $comment = '';
6072     my $blank = 0;
6073     my $saw_bk = 0;
6074     my $var_look = VAR_ASIS;
6075
6076     use constant IN_VAR_DEF => 0;
6077     use constant IN_RULE_DEF => 1;
6078     use constant IN_COMMENT => 2;
6079     my $prev_state = IN_RULE_DEF;
6080
6081     while ($_ = $am_file->getline)
6082     {
6083         $where->set ("$amfile:$.");
6084         if (/$IGNORE_PATTERN/o)
6085         {
6086             # Merely delete comments beginning with two hashes.
6087         }
6088         elsif (/$WHITE_PATTERN/o)
6089         {
6090             error $where, "blank line following trailing backslash"
6091               if $saw_bk;
6092             # Stick a single white line before the incoming macro or rule.
6093             $spacing = "\n";
6094             $blank = 1;
6095             # Flush all comments seen so far.
6096             if ($comment ne '')
6097             {
6098                 $output_vars .= $comment;
6099                 $comment = '';
6100             }
6101         }
6102         elsif (/$COMMENT_PATTERN/o)
6103         {
6104             # Stick comments before the incoming macro or rule.  Make
6105             # sure a blank line precedes the first block of comments.
6106             $spacing = "\n" unless $blank;
6107             $blank = 1;
6108             $comment .= $spacing . $_;
6109             $spacing = '';
6110             $prev_state = IN_COMMENT;
6111         }
6112         else
6113         {
6114             last;
6115         }
6116         $saw_bk = check_trailing_slash ($where, $_);
6117     }
6118
6119     # We save the conditional stack on entry, and then check to make
6120     # sure it is the same on exit.  This lets us conditionally include
6121     # other files.
6122     my @saved_cond_stack = @cond_stack;
6123     my $cond = new Automake::Condition (@cond_stack);
6124
6125     my $last_var_name = '';
6126     my $last_var_type = '';
6127     my $last_var_value = '';
6128     my $last_where;
6129     # FIXME: shouldn't use $_ in this loop; it is too big.
6130     while ($_)
6131     {
6132         $where->set ("$amfile:$.");
6133
6134         # Make sure the line is \n-terminated.
6135         chomp;
6136         $_ .= "\n";
6137
6138         # Don't look at MAINTAINER_MODE_TRUE here.  That shouldn't be
6139         # used by users.  @MAINT@ is an anachronism now.
6140         $_ =~ s/\@MAINT\@//g
6141             unless $seen_maint_mode;
6142
6143         my $new_saw_bk = check_trailing_slash ($where, $_);
6144
6145         if (/$IGNORE_PATTERN/o)
6146         {
6147             # Merely delete comments beginning with two hashes.
6148
6149             # Keep any backslash from the previous line.
6150             $new_saw_bk = $saw_bk;
6151         }
6152         elsif (/$WHITE_PATTERN/o)
6153         {
6154             # Stick a single white line before the incoming macro or rule.
6155             $spacing = "\n";
6156             error $where, "blank line following trailing backslash"
6157               if $saw_bk;
6158         }
6159         elsif (/$COMMENT_PATTERN/o)
6160         {
6161             error $where, "comment following trailing backslash"
6162               if $saw_bk && $comment eq '';
6163
6164             # Stick comments before the incoming macro or rule.
6165             $comment .= $spacing . $_;
6166             $spacing = '';
6167             $prev_state = IN_COMMENT;
6168         }
6169         elsif ($saw_bk)
6170         {
6171             if ($prev_state == IN_RULE_DEF)
6172             {
6173               my $cond = new Automake::Condition @cond_stack;
6174               $output_trailer .= $cond->subst_string;
6175               $output_trailer .= $_;
6176             }
6177             elsif ($prev_state == IN_COMMENT)
6178             {
6179                 # If the line doesn't start with a `#', add it.
6180                 # We do this because a continued comment like
6181                 #   # A = foo \
6182                 #         bar \
6183                 #         baz
6184                 # is not portable.  BSD make doesn't honor
6185                 # escaped newlines in comments.
6186                 s/^#?/#/;
6187                 $comment .= $spacing . $_;
6188             }
6189             else # $prev_state == IN_VAR_DEF
6190             {
6191               $last_var_value .= ' '
6192                 unless $last_var_value =~ /\s$/;
6193               $last_var_value .= $_;
6194
6195               if (!/\\$/)
6196                 {
6197                   Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6198                                               $last_var_type, $cond,
6199                                               $last_var_value, $comment,
6200                                               $last_where, VAR_ASIS)
6201                     if $cond != FALSE;
6202                   $comment = $spacing = '';
6203                 }
6204             }
6205         }
6206
6207         elsif (/$IF_PATTERN/o)
6208           {
6209             $cond = cond_stack_if ($1, $2, $where);
6210           }
6211         elsif (/$ELSE_PATTERN/o)
6212           {
6213             $cond = cond_stack_else ($1, $2, $where);
6214           }
6215         elsif (/$ENDIF_PATTERN/o)
6216           {
6217             $cond = cond_stack_endif ($1, $2, $where);
6218           }
6219
6220         elsif (/$RULE_PATTERN/o)
6221         {
6222             # Found a rule.
6223             $prev_state = IN_RULE_DEF;
6224
6225             # For now we have to output all definitions of user rules
6226             # and can't diagnose duplicates (see the comment in
6227             # Automake::Rule::define). So we go on and ignore the return value.
6228             Automake::Rule::define ($1, $amfile, RULE_USER, $cond, $where);
6229
6230             check_variable_expansions ($_, $where);
6231
6232             $output_trailer .= $comment . $spacing;
6233             my $cond = new Automake::Condition @cond_stack;
6234             $output_trailer .= $cond->subst_string;
6235             $output_trailer .= $_;
6236             $comment = $spacing = '';
6237         }
6238         elsif (/$ASSIGNMENT_PATTERN/o)
6239         {
6240             # Found a macro definition.
6241             $prev_state = IN_VAR_DEF;
6242             $last_var_name = $1;
6243             $last_var_type = $2;
6244             $last_var_value = $3;
6245             $last_where = $where->clone;
6246             if ($3 ne '' && substr ($3, -1) eq "\\")
6247               {
6248                 # We preserve the `\' because otherwise the long lines
6249                 # that are generated will be truncated by broken
6250                 # `sed's.
6251                 $last_var_value = $3 . "\n";
6252               }
6253             # Normally we try to output variable definitions in the
6254             # same format they were input.  However, POSIX compliant
6255             # systems are not required to support lines longer than
6256             # 2048 bytes (most notably, some sed implementation are
6257             # limited to 4000 bytes, and sed is used by config.status
6258             # to rewrite Makefile.in into Makefile).  Moreover nobody
6259             # would really write such long lines by hand since it is
6260             # hardly maintainable.  So if a line is longer that 1000
6261             # bytes (an arbitrary limit), assume it has been
6262             # automatically generated by some tools, and flatten the
6263             # variable definition.  Otherwise, keep the variable as it
6264             # as been input.
6265             $var_look = VAR_PRETTY if length ($last_var_value) >= 1000;
6266
6267             if (!/\\$/)
6268               {
6269                 Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6270                                             $last_var_type, $cond,
6271                                             $last_var_value, $comment,
6272                                             $last_where, $var_look)
6273                   if $cond != FALSE;
6274                 $comment = $spacing = '';
6275                 $var_look = VAR_ASIS;
6276               }
6277         }
6278         elsif (/$INCLUDE_PATTERN/o)
6279         {
6280             my $path = $1;
6281
6282             if ($path =~ s/^\$\(top_srcdir\)\///)
6283               {
6284                 push (@include_stack, "\$\(top_srcdir\)/$path");
6285                 # Distribute any included file.
6286
6287                 # Always use the $(top_srcdir) prefix in DIST_COMMON,
6288                 # otherwise OSF make will implicitly copy the included
6289                 # file in the build tree during `make distdir' to satisfy
6290                 # the dependency.
6291                 # (subdircond2.test and subdircond3.test will fail.)
6292                 push_dist_common ("\$\(top_srcdir\)/$path");
6293               }
6294             else
6295               {
6296                 $path =~ s/\$\(srcdir\)\///;
6297                 push (@include_stack, "\$\(srcdir\)/$path");
6298                 # Always use the $(srcdir) prefix in DIST_COMMON,
6299                 # otherwise OSF make will implicitly copy the included
6300                 # file in the build tree during `make distdir' to satisfy
6301                 # the dependency.
6302                 # (subdircond2.test and subdircond3.test will fail.)
6303                 push_dist_common ("\$\(srcdir\)/$path");
6304                 $path = $relative_dir . "/" . $path if $relative_dir ne '.';
6305               }
6306             $where->push_context ("`$path' included from here");
6307             &read_am_file ($path, $where);
6308             $where->pop_context;
6309         }
6310         else
6311         {
6312             # This isn't an error; it is probably a continued rule.
6313             # In fact, this is what we assume.
6314             $prev_state = IN_RULE_DEF;
6315             check_variable_expansions ($_, $where);
6316             $output_trailer .= $comment . $spacing;
6317             my $cond = new Automake::Condition @cond_stack;
6318             $output_trailer .= $cond->subst_string;
6319             $output_trailer .= $_;
6320             $comment = $spacing = '';
6321             error $where, "`#' comment at start of rule is unportable"
6322               if $_ =~ /^\t\s*\#/;
6323         }
6324
6325         $saw_bk = $new_saw_bk;
6326         $_ = $am_file->getline;
6327     }
6328
6329     $output_trailer .= $comment;
6330
6331     error ($where, "trailing backslash on last line")
6332       if $saw_bk;
6333
6334     error ($where, (@cond_stack ? "unterminated conditionals: @cond_stack"
6335                     : "too many conditionals closed in include file"))
6336       if "@saved_cond_stack" ne "@cond_stack";
6337 }
6338
6339
6340 # define_standard_variables ()
6341 # ----------------------------
6342 # A helper for read_main_am_file which initializes configure variables
6343 # and variables from header-vars.am.
6344 sub define_standard_variables
6345 {
6346   my $saved_output_vars = $output_vars;
6347   my ($comments, undef, $rules) =
6348     file_contents_internal (1, "$libdir/am/header-vars.am",
6349                             new Automake::Location);
6350
6351   foreach my $var (sort keys %configure_vars)
6352     {
6353       &define_configure_variable ($var);
6354     }
6355
6356   $output_vars .= $comments . $rules;
6357 }
6358
6359 # Read main am file.
6360 sub read_main_am_file
6361 {
6362     my ($amfile) = @_;
6363
6364     # This supports the strange variable tricks we are about to play.
6365     prog_error (macros_dump () . "variable defined before read_main_am_file")
6366       if (scalar (variables) > 0);
6367
6368     # Generate copyright header for generated Makefile.in.
6369     # We do discard the output of predefined variables, handled below.
6370     $output_vars = ("# $in_file_name generated by automake "
6371                    . $VERSION . " from $am_file_name.\n");
6372     $output_vars .= '# ' . subst ('configure_input') . "\n";
6373     $output_vars .= $gen_copyright;
6374
6375     # We want to predefine as many variables as possible.  This lets
6376     # the user set them with `+=' in Makefile.am.
6377     &define_standard_variables;
6378
6379     # Read user file, which might override some of our values.
6380     &read_am_file ($amfile, new Automake::Location);
6381 }
6382
6383
6384
6385 ################################################################
6386
6387 # $FLATTENED
6388 # &flatten ($STRING)
6389 # ------------------
6390 # Flatten the $STRING and return the result.
6391 sub flatten
6392 {
6393   $_ = shift;
6394
6395   s/\\\n//somg;
6396   s/\s+/ /g;
6397   s/^ //;
6398   s/ $//;
6399
6400   return $_;
6401 }
6402
6403 # transform($TOKEN, \%PAIRS)
6404 # ==========================
6405 # If ($TOKEN, $VAL) is in %PAIRS:
6406 #   - replaces %$TOKEN% with $VAL,
6407 #   - enables/disables ?$TOKEN? and ?!$TOKEN?,
6408 #   - replaces %?$TOKEN% with TRUE or FALSE.
6409 sub transform($$)
6410 {
6411   my ($token, $transform) = @_;
6412
6413   if (substr ($token, 0, 1) eq '%')
6414     {
6415       my $cond = (substr ($token, 1, 1) eq '?') ? 1 : 0;
6416       $token = substr ($token, 1 + $cond, -1);
6417       my $val = $transform->{$token};
6418       prog_error "Unknown %token% `$token'" unless defined $val;
6419       if ($cond)
6420         {
6421           return $val ? 'TRUE' : 'FALSE';
6422         }
6423       else
6424         {
6425           return $val;
6426         }
6427     }
6428   # Now $token is '?xxx?' or '?!xxx?'.
6429   my $neg = (substr ($token, 1, 1) eq '!') ? 1 : 0;
6430   $token = substr ($token, 1 + $neg, -1);
6431   my $val = $transform->{$token};
6432   prog_error "Unknown ?token? `$token' (neg = $neg)" unless defined $val;
6433   return (!!$val == $neg) ? '##%' : '';
6434 }
6435
6436 # @PARAGRAPHS
6437 # &make_paragraphs ($MAKEFILE, [%TRANSFORM])
6438 # ------------------------------------------
6439 # Load a $MAKEFILE, apply the %TRANSFORM, and return it as a list of
6440 # paragraphs.
6441 sub make_paragraphs ($%)
6442 {
6443   my ($file, %transform) = @_;
6444
6445   # Complete %transform with global options.
6446   # Note that %transform goes last, so it overrides global options.
6447   %transform = ('CYGNUS'      => !! option 'cygnus',
6448                  'MAINTAINER-MODE'
6449                  => $seen_maint_mode ? subst ('MAINTAINER_MODE_TRUE') : '',
6450
6451                  'LZMA'        => !! option 'dist-lzma',
6452                  'BZIP2'       => !! option 'dist-bzip2',
6453                  'COMPRESS'    => !! option 'dist-tarZ',
6454                  'GZIP'        =>  ! option 'no-dist-gzip',
6455                  'SHAR'        => !! option 'dist-shar',
6456                  'ZIP'         => !! option 'dist-zip',
6457
6458                  'INSTALL-INFO' =>  ! option 'no-installinfo',
6459                  'INSTALL-MAN'  =>  ! option 'no-installman',
6460                  'CK-NEWS'      => !! option 'check-news',
6461
6462                  'SUBDIRS'      => !! var ('SUBDIRS'),
6463                  'TOPDIR_P'     => $relative_dir eq '.',
6464
6465                  'BUILD'    => ($seen_canonical >= AC_CANONICAL_BUILD),
6466                  'HOST'     => ($seen_canonical >= AC_CANONICAL_HOST),
6467                  'TARGET'   => ($seen_canonical >= AC_CANONICAL_TARGET),
6468
6469                  'LIBTOOL'      => !! var ('LIBTOOL'),
6470                  'NONLIBTOOL'   => 1,
6471                  'FIRST'        => ! $transformed_files{$file},
6472                 %transform);
6473
6474   $transformed_files{$file} = 1;
6475   $_ = $am_file_cache{$file};
6476
6477   if (! defined $_)
6478     {
6479       verb "reading $file";
6480       # Swallow the whole file.
6481       my $fc_file = new Automake::XFile "< $file";
6482       my $saved_dollar_slash = $/;
6483       undef $/;
6484       $_ = $fc_file->getline;
6485       $/ = $saved_dollar_slash;
6486       $fc_file->close;
6487
6488       # Remove ##-comments.
6489       # Besides we don't need more than two consecutive new-lines.
6490       s/(?:$IGNORE_PATTERN|(?<=\n\n)\n+)//gom;
6491
6492       $am_file_cache{$file} = $_;
6493     }
6494
6495   # Substitute Automake template tokens.
6496   s/(?:%\??[\w\-]+%|\?!?[\w\-]+\?)/transform($&, \%transform)/ge;
6497   # transform() may have added some ##%-comments to strip.
6498   # (we use `##%' instead of `##' so we can distinguish ##%##%##% from
6499   # ####### and do not remove the latter.)
6500   s/^[ \t]*(?:##%)+.*\n//gm;
6501
6502   # Split at unescaped new lines.
6503   my @lines = split (/(?<!\\)\n/, $_);
6504   my @res;
6505
6506   while (defined ($_ = shift @lines))
6507     {
6508       my $paragraph = $_;
6509       # If we are a rule, eat as long as we start with a tab.
6510       if (/$RULE_PATTERN/smo)
6511         {
6512           while (defined ($_ = shift @lines) && $_ =~ /^\t/)
6513             {
6514               $paragraph .= "\n$_";
6515             }
6516           unshift (@lines, $_);
6517         }
6518
6519       # If we are a comments, eat as much comments as you can.
6520       elsif (/$COMMENT_PATTERN/smo)
6521         {
6522           while (defined ($_ = shift @lines)
6523                  && $_ =~ /$COMMENT_PATTERN/smo)
6524             {
6525               $paragraph .= "\n$_";
6526             }
6527           unshift (@lines, $_);
6528         }
6529
6530       push @res, $paragraph;
6531     }
6532
6533   return @res;
6534 }
6535
6536
6537
6538 # ($COMMENT, $VARIABLES, $RULES)
6539 # &file_contents_internal ($IS_AM, $FILE, $WHERE, [%TRANSFORM])
6540 # -------------------------------------------------------------
6541 # Return contents of a file from $libdir/am, automatically skipping
6542 # macros or rules which are already known. $IS_AM iff the caller is
6543 # reading an Automake file (as opposed to the user's Makefile.am).
6544 sub file_contents_internal ($$$%)
6545 {
6546     my ($is_am, $file, $where, %transform) = @_;
6547
6548     $where->set ($file);
6549
6550     my $result_vars = '';
6551     my $result_rules = '';
6552     my $comment = '';
6553     my $spacing = '';
6554
6555     # The following flags are used to track rules spanning across
6556     # multiple paragraphs.
6557     my $is_rule = 0;            # 1 if we are processing a rule.
6558     my $discard_rule = 0;       # 1 if the current rule should not be output.
6559
6560     # We save the conditional stack on entry, and then check to make
6561     # sure it is the same on exit.  This lets us conditionally include
6562     # other files.
6563     my @saved_cond_stack = @cond_stack;
6564     my $cond = new Automake::Condition (@cond_stack);
6565
6566     foreach (make_paragraphs ($file, %transform))
6567     {
6568         # FIXME: no line number available.
6569         $where->set ($file);
6570
6571         # Sanity checks.
6572         error $where, "blank line following trailing backslash:\n$_"
6573           if /\\$/;
6574         error $where, "comment following trailing backslash:\n$_"
6575           if /\\#/;
6576
6577         if (/^$/)
6578         {
6579             $is_rule = 0;
6580             # Stick empty line before the incoming macro or rule.
6581             $spacing = "\n";
6582         }
6583         elsif (/$COMMENT_PATTERN/mso)
6584         {
6585             $is_rule = 0;
6586             # Stick comments before the incoming macro or rule.
6587             $comment = "$_\n";
6588         }
6589
6590         # Handle inclusion of other files.
6591         elsif (/$INCLUDE_PATTERN/o)
6592         {
6593             if ($cond != FALSE)
6594               {
6595                 my $file = ($is_am ? "$libdir/am/" : '') . $1;
6596                 $where->push_context ("`$file' included from here");
6597                 # N-ary `.=' fails.
6598                 my ($com, $vars, $rules)
6599                   = file_contents_internal ($is_am, $file, $where, %transform);
6600                 $where->pop_context;
6601                 $comment .= $com;
6602                 $result_vars .= $vars;
6603                 $result_rules .= $rules;
6604               }
6605         }
6606
6607         # Handling the conditionals.
6608         elsif (/$IF_PATTERN/o)
6609           {
6610             $cond = cond_stack_if ($1, $2, $file);
6611           }
6612         elsif (/$ELSE_PATTERN/o)
6613           {
6614             $cond = cond_stack_else ($1, $2, $file);
6615           }
6616         elsif (/$ENDIF_PATTERN/o)
6617           {
6618             $cond = cond_stack_endif ($1, $2, $file);
6619           }
6620
6621         # Handling rules.
6622         elsif (/$RULE_PATTERN/mso)
6623         {
6624           $is_rule = 1;
6625           $discard_rule = 0;
6626           # Separate relationship from optional actions: the first
6627           # `new-line tab" not preceded by backslash (continuation
6628           # line).
6629           my $paragraph = $_;
6630           /^(.*?)(?:(?<!\\)\n(\t.*))?$/s;
6631           my ($relationship, $actions) = ($1, $2 || '');
6632
6633           # Separate targets from dependencies: the first colon.
6634           $relationship =~ /^([^:]+\S+) *: *(.*)$/som;
6635           my ($targets, $dependencies) = ($1, $2);
6636           # Remove the escaped new lines.
6637           # I don't know why, but I have to use a tmp $flat_deps.
6638           my $flat_deps = &flatten ($dependencies);
6639           my @deps = split (' ', $flat_deps);
6640
6641           foreach (split (' ' , $targets))
6642             {
6643               # FIXME: 1. We are not robust to people defining several targets
6644               # at once, only some of them being in %dependencies.  The
6645               # actions from the targets in %dependencies are usually generated
6646               # from the content of %actions, but if some targets in $targets
6647               # are not in %dependencies the ELSE branch will output
6648               # a rule for all $targets (i.e. the targets which are both
6649               # in %dependencies and $targets will have two rules).
6650
6651               # FIXME: 2. The logic here is not able to output a
6652               # multi-paragraph rule several time (e.g. for each condition
6653               # it is defined for) because it only knows the first paragraph.
6654
6655               # FIXME: 3. We are not robust to people defining a subset
6656               # of a previously defined "multiple-target" rule.  E.g.
6657               # `foo:' after `foo bar:'.
6658
6659               # Output only if not in FALSE.
6660               if (defined $dependencies{$_} && $cond != FALSE)
6661                 {
6662                   &depend ($_, @deps);
6663                   if ($actions{$_})
6664                     {
6665                       $actions{$_} .= "\n$actions" if $actions;
6666                     }
6667                   else
6668                     {
6669                       $actions{$_} = $actions;
6670                     }
6671                 }
6672               else
6673                 {
6674                   # Free-lance dependency.  Output the rule for all the
6675                   # targets instead of one by one.
6676                   my @undefined_conds =
6677                     Automake::Rule::define ($targets, $file,
6678                                             $is_am ? RULE_AUTOMAKE : RULE_USER,
6679                                             $cond, $where);
6680                   for my $undefined_cond (@undefined_conds)
6681                     {
6682                       my $condparagraph = $paragraph;
6683                       $condparagraph =~ s/^/$undefined_cond->subst_string/gme;
6684                       $result_rules .= "$spacing$comment$condparagraph\n";
6685                     }
6686                   if (scalar @undefined_conds == 0)
6687                     {
6688                       # Remember to discard next paragraphs
6689                       # if they belong to this rule.
6690                       # (but see also FIXME: #2 above.)
6691                       $discard_rule = 1;
6692                     }
6693                   $comment = $spacing = '';
6694                   last;
6695                 }
6696             }
6697         }
6698
6699         elsif (/$ASSIGNMENT_PATTERN/mso)
6700         {
6701             my ($var, $type, $val) = ($1, $2, $3);
6702             error $where, "variable `$var' with trailing backslash"
6703               if /\\$/;
6704
6705             $is_rule = 0;
6706
6707             Automake::Variable::define ($var,
6708                                         $is_am ? VAR_AUTOMAKE : VAR_MAKEFILE,
6709                                         $type, $cond, $val, $comment, $where,
6710                                         VAR_ASIS)
6711               if $cond != FALSE;
6712
6713             $comment = $spacing = '';
6714         }
6715         else
6716         {
6717             # This isn't an error; it is probably some tokens which
6718             # configure is supposed to replace, such as `@SET-MAKE@',
6719             # or some part of a rule cut by an if/endif.
6720             if (! $cond->false && ! ($is_rule && $discard_rule))
6721               {
6722                 s/^/$cond->subst_string/gme;
6723                 $result_rules .= "$spacing$comment$_\n";
6724               }
6725             $comment = $spacing = '';
6726         }
6727     }
6728
6729     error ($where, @cond_stack ?
6730            "unterminated conditionals: @cond_stack" :
6731            "too many conditionals closed in include file")
6732       if "@saved_cond_stack" ne "@cond_stack";
6733
6734     return ($comment, $result_vars, $result_rules);
6735 }
6736
6737
6738 # $CONTENTS
6739 # &file_contents ($BASENAME, $WHERE, [%TRANSFORM])
6740 # ------------------------------------------------
6741 # Return contents of a file from $libdir/am, automatically skipping
6742 # macros or rules which are already known.
6743 sub file_contents ($$%)
6744 {
6745     my ($basename, $where, %transform) = @_;
6746     my ($comments, $variables, $rules) =
6747       file_contents_internal (1, "$libdir/am/$basename.am", $where,
6748                               %transform);
6749     return "$comments$variables$rules";
6750 }
6751
6752
6753 # @PREFIX
6754 # &am_primary_prefixes ($PRIMARY, $CAN_DIST, @PREFIXES)
6755 # -----------------------------------------------------
6756 # Find all variable prefixes that are used for install directories.  A
6757 # prefix `zar' qualifies iff:
6758 #
6759 # * `zardir' is a variable.
6760 # * `zar_PRIMARY' is a variable.
6761 #
6762 # As a side effect, it looks for misspellings.  It is an error to have
6763 # a variable ending in a "reserved" suffix whose prefix is unknown, e.g.
6764 # "bni_PROGRAMS".  However, unusual prefixes are allowed if a variable
6765 # of the same name (with "dir" appended) exists.  For instance, if the
6766 # variable "zardir" is defined, then "zar_PROGRAMS" becomes valid.
6767 # This is to provide a little extra flexibility in those cases which
6768 # need it.
6769 sub am_primary_prefixes ($$@)
6770 {
6771   my ($primary, $can_dist, @prefixes) = @_;
6772
6773   local $_;
6774   my %valid = map { $_ => 0 } @prefixes;
6775   $valid{'EXTRA'} = 0;
6776   foreach my $var (variables $primary)
6777     {
6778       # Automake is allowed to define variables that look like primaries
6779       # but which aren't.  E.g. INSTALL_sh_DATA.
6780       # Autoconf can also define variables like INSTALL_DATA, so
6781       # ignore all configure variables (at least those which are not
6782       # redefined in Makefile.am).
6783       # FIXME: We should make sure that these variables are not
6784       # conditionally defined (or else adjust the condition below).
6785       my $def = $var->def (TRUE);
6786       next if $def && $def->owner != VAR_MAKEFILE;
6787
6788       my $varname = $var->name;
6789
6790       if ($varname =~ /^(nobase_)?(dist_|nodist_)?(.*)_[[:alnum:]]+$/)
6791         {
6792           my ($base, $dist, $X) = ($1 || '', $2 || '', $3 || '');
6793           if ($dist ne '' && ! $can_dist)
6794             {
6795               err_var ($var,
6796                        "invalid variable `$varname': `dist' is forbidden");
6797             }
6798           # Standard directories must be explicitly allowed.
6799           elsif (! defined $valid{$X} && exists $standard_prefix{$X})
6800             {
6801               err_var ($var,
6802                        "`${X}dir' is not a legitimate directory " .
6803                        "for `$primary'");
6804             }
6805           # A not explicitly valid directory is allowed if Xdir is defined.
6806           elsif (! defined $valid{$X} &&
6807                  $var->requires_variables ("`$varname' is used", "${X}dir"))
6808             {
6809               # Nothing to do.  Any error message has been output
6810               # by $var->requires_variables.
6811             }
6812           else
6813             {
6814               # Ensure all extended prefixes are actually used.
6815               $valid{"$base$dist$X"} = 1;
6816             }
6817         }
6818       else
6819         {
6820           prog_error "unexpected variable name: $varname";
6821         }
6822     }
6823
6824   # Return only those which are actually defined.
6825   return sort grep { var ($_ . '_' . $primary) } keys %valid;
6826 }
6827
6828
6829 # Handle `where_HOW' variable magic.  Does all lookups, generates
6830 # install code, and possibly generates code to define the primary
6831 # variable.  The first argument is the name of the .am file to munge,
6832 # the second argument is the primary variable (e.g. HEADERS), and all
6833 # subsequent arguments are possible installation locations.
6834 #
6835 # Returns list of [$location, $value] pairs, where
6836 # $value's are the values in all where_HOW variable, and $location
6837 # there associated location (the place here their parent variables were
6838 # defined).
6839 #
6840 # FIXME: this should be rewritten to be cleaner.  It should be broken
6841 # up into multiple functions.
6842 #
6843 # Usage is: am_install_var (OPTION..., file, HOW, where...)
6844 sub am_install_var
6845 {
6846   my (@args) = @_;
6847
6848   my $do_require = 1;
6849   my $can_dist = 0;
6850   my $default_dist = 0;
6851   while (@args)
6852     {
6853       if ($args[0] eq '-noextra')
6854         {
6855           $do_require = 0;
6856         }
6857       elsif ($args[0] eq '-candist')
6858         {
6859           $can_dist = 1;
6860         }
6861       elsif ($args[0] eq '-defaultdist')
6862         {
6863           $default_dist = 1;
6864           $can_dist = 1;
6865         }
6866       elsif ($args[0] !~ /^-/)
6867         {
6868           last;
6869         }
6870       shift (@args);
6871     }
6872
6873   my ($file, $primary, @prefix) = @args;
6874
6875   # Now that configure substitutions are allowed in where_HOW
6876   # variables, it is an error to actually define the primary.  We
6877   # allow `JAVA', as it is customarily used to mean the Java
6878   # interpreter.  This is but one of several Java hacks.  Similarly,
6879   # `PYTHON' is customarily used to mean the Python interpreter.
6880   reject_var $primary, "`$primary' is an anachronism"
6881     unless $primary eq 'JAVA' || $primary eq 'PYTHON';
6882
6883   # Get the prefixes which are valid and actually used.
6884   @prefix = am_primary_prefixes ($primary, $can_dist, @prefix);
6885
6886   # If a primary includes a configure substitution, then the EXTRA_
6887   # form is required.  Otherwise we can't properly do our job.
6888   my $require_extra;
6889
6890   my @used = ();
6891   my @result = ();
6892
6893   foreach my $X (@prefix)
6894     {
6895       my $nodir_name = $X;
6896       my $one_name = $X . '_' . $primary;
6897       my $one_var = var $one_name;
6898
6899       my $strip_subdir = 1;
6900       # If subdir prefix should be preserved, do so.
6901       if ($nodir_name =~ /^nobase_/)
6902         {
6903           $strip_subdir = 0;
6904           $nodir_name =~ s/^nobase_//;
6905         }
6906
6907       # If files should be distributed, do so.
6908       my $dist_p = 0;
6909       if ($can_dist)
6910         {
6911           $dist_p = (($default_dist && $nodir_name !~ /^nodist_/)
6912                      || (! $default_dist && $nodir_name =~ /^dist_/));
6913           $nodir_name =~ s/^(dist|nodist)_//;
6914         }
6915
6916
6917       # Use the location of the currently processed variable.
6918       # We are not processing a particular condition, so pick the first
6919       # available.
6920       my $tmpcond = $one_var->conditions->one_cond;
6921       my $where = $one_var->rdef ($tmpcond)->location->clone;
6922
6923       # Append actual contents of where_PRIMARY variable to
6924       # @result, skipping @substitutions@.
6925       foreach my $locvals ($one_var->value_as_list_recursive (location => 1))
6926         {
6927           my ($loc, $value) = @$locvals;
6928           # Skip configure substitutions.
6929           if ($value =~ /^\@.*\@$/)
6930             {
6931               if ($nodir_name eq 'EXTRA')
6932                 {
6933                   error ($where,
6934                          "`$one_name' contains configure substitution, "
6935                          . "but shouldn't");
6936                 }
6937               # Check here to make sure variables defined in
6938               # configure.ac do not imply that EXTRA_PRIMARY
6939               # must be defined.
6940               elsif (! defined $configure_vars{$one_name})
6941                 {
6942                   $require_extra = $one_name
6943                     if $do_require;
6944                 }
6945             }
6946           else
6947             {
6948               push (@result, $locvals);
6949             }
6950         }
6951       # A blatant hack: we rewrite each _PROGRAMS primary to include
6952       # EXEEXT.
6953       append_exeext { 1 } $one_name
6954         if $primary eq 'PROGRAMS';
6955       # "EXTRA" shouldn't be used when generating clean targets,
6956       # all, or install targets.  We used to warn if EXTRA_FOO was
6957       # defined uselessly, but this was annoying.
6958       next
6959         if $nodir_name eq 'EXTRA';
6960
6961       if ($nodir_name eq 'check')
6962         {
6963           push (@check, '$(' . $one_name . ')');
6964         }
6965       else
6966         {
6967           push (@used, '$(' . $one_name . ')');
6968         }
6969
6970       # Is this to be installed?
6971       my $install_p = $nodir_name ne 'noinst' && $nodir_name ne 'check';
6972
6973       # If so, with install-exec? (or install-data?).
6974       my $exec_p = ($nodir_name =~ /$EXEC_DIR_PATTERN/o);
6975
6976       my $check_options_p = $install_p && !! option 'std-options';
6977
6978       # Use the location of the currently processed variable as context.
6979       $where->push_context ("while processing `$one_name'");
6980
6981       # The variable containing all file to distribute.
6982       my $distvar = "\$($one_name)";
6983       $distvar = shadow_unconditionally ($one_name, $where)
6984         if ($dist_p && $one_var->has_conditional_contents);
6985
6986       # Singular form of $PRIMARY.
6987       (my $one_primary = $primary) =~ s/S$//;
6988       $output_rules .= &file_contents ($file, $where,
6989                                        PRIMARY     => $primary,
6990                                        ONE_PRIMARY => $one_primary,
6991                                        DIR         => $X,
6992                                        NDIR        => $nodir_name,
6993                                        BASE        => $strip_subdir,
6994
6995                                        EXEC      => $exec_p,
6996                                        INSTALL   => $install_p,
6997                                        DIST      => $dist_p,
6998                                        DISTVAR   => $distvar,
6999                                        'CK-OPTS' => $check_options_p);
7000     }
7001
7002   # The JAVA variable is used as the name of the Java interpreter.
7003   # The PYTHON variable is used as the name of the Python interpreter.
7004   if (@used && $primary ne 'JAVA' && $primary ne 'PYTHON')
7005     {
7006       # Define it.
7007       define_pretty_variable ($primary, TRUE, INTERNAL, @used);
7008       $output_vars .= "\n";
7009     }
7010
7011   err_var ($require_extra,
7012            "`$require_extra' contains configure substitution,\n"
7013            . "but `EXTRA_$primary' not defined")
7014     if ($require_extra && ! var ('EXTRA_' . $primary));
7015
7016   # Push here because PRIMARY might be configure time determined.
7017   push (@all, '$(' . $primary . ')')
7018     if @used && $primary ne 'JAVA' && $primary ne 'PYTHON';
7019
7020   # Make the result unique.  This lets the user use conditionals in
7021   # a natural way, but still lets us program lazily -- we don't have
7022   # to worry about handling a particular object more than once.
7023   # We will keep only one location per object.
7024   my %result = ();
7025   for my $pair (@result)
7026     {
7027       my ($loc, $val) = @$pair;
7028       $result{$val} = $loc;
7029     }
7030   my @l = sort keys %result;
7031   return map { [$result{$_}->clone, $_] } @l;
7032 }
7033
7034
7035 ################################################################
7036
7037 # Each key in this hash is the name of a directory holding a
7038 # Makefile.in.  These variables are local to `is_make_dir'.
7039 my %make_dirs = ();
7040 my $make_dirs_set = 0;
7041
7042 sub is_make_dir
7043 {
7044     my ($dir) = @_;
7045     if (! $make_dirs_set)
7046     {
7047         foreach my $iter (@configure_input_files)
7048         {
7049             $make_dirs{dirname ($iter)} = 1;
7050         }
7051         # We also want to notice Makefile.in's.
7052         foreach my $iter (@other_input_files)
7053         {
7054             if ($iter =~ /Makefile\.in$/)
7055             {
7056                 $make_dirs{dirname ($iter)} = 1;
7057             }
7058         }
7059         $make_dirs_set = 1;
7060     }
7061     return defined $make_dirs{$dir};
7062 }
7063
7064 ################################################################
7065
7066 # Find the aux dir.  This should match the algorithm used by
7067 # ./configure. (See the Autoconf documentation for for
7068 # AC_CONFIG_AUX_DIR.)
7069 sub locate_aux_dir ()
7070 {
7071   if (! $config_aux_dir_set_in_configure_ac)
7072     {
7073       # The default auxiliary directory is the first
7074       # of ., .., or ../.. that contains install-sh.
7075       # Assume . if install-sh doesn't exist yet.
7076       for my $dir (qw (. .. ../..))
7077         {
7078           if (-f "$dir/install-sh")
7079             {
7080               $config_aux_dir = $dir;
7081               last;
7082             }
7083         }
7084       $config_aux_dir = '.' unless $config_aux_dir;
7085     }
7086   # Avoid unsightly '/.'s.
7087   $am_config_aux_dir =
7088     '$(top_srcdir)' . ($config_aux_dir eq '.' ? "" : "/$config_aux_dir");
7089   $am_config_aux_dir =~ s,/*$,,;
7090 }
7091
7092
7093 # &maybe_push_required_file ($DIR, $FILE, $FULLFILE)
7094 # --------------------------------------------------
7095 # See if we want to push this file onto dist_common.  This function
7096 # encodes the rules for deciding when to do so.
7097 sub maybe_push_required_file
7098 {
7099   my ($dir, $file, $fullfile) = @_;
7100
7101   if ($dir eq $relative_dir)
7102     {
7103       push_dist_common ($file);
7104       return 1;
7105     }
7106   elsif ($relative_dir eq '.' && ! &is_make_dir ($dir))
7107     {
7108       # If we are doing the topmost directory, and the file is in a
7109       # subdir which does not have a Makefile, then we distribute it
7110       # here.
7111
7112       # If a required file is above the source tree, it is important
7113       # to prefix it with `$(srcdir)' so that no VPATH search is
7114       # performed.  Otherwise problems occur with Make implementations
7115       # that rewrite and simplify rules whose dependencies are found in a
7116       # VPATH location.  Here is an example with OSF1/Tru64 Make.
7117       #
7118       #   % cat Makefile
7119       #   VPATH = sub
7120       #   distdir: ../a
7121       #           echo ../a
7122       #   % ls
7123       #   Makefile a
7124       #   % make
7125       #   echo a
7126       #   a
7127       #
7128       # Dependency `../a' was found in `sub/../a', but this make
7129       # implementation simplified it as `a'.  (Note that the sub/
7130       # directory does not even exist.)
7131       #
7132       # This kind of VPATH rewriting seems hard to cancel.  The
7133       # distdir.am hack against VPATH rewriting works only when no
7134       # simplification is done, i.e., for dependencies which are in
7135       # subdirectories, not in enclosing directories.  Hence, in
7136       # the latter case we use a full path to make sure no VPATH
7137       # search occurs.
7138       $fullfile = '$(srcdir)/' . $fullfile
7139         if $dir =~ m,^\.\.(?:$|/),;
7140
7141       push_dist_common ($fullfile);
7142       return 1;
7143     }
7144   return 0;
7145 }
7146
7147
7148 # If a file name appears as a key in this hash, then it has already
7149 # been checked for.  This allows us not to report the same error more
7150 # than once.
7151 my %required_file_not_found = ();
7152
7153 # &require_file_internal ($WHERE, $MYSTRICT, $DIRECTORY, @FILES)
7154 # --------------------------------------------------------------
7155 # Verify that the file must exist in $DIRECTORY, or install it.
7156 # $MYSTRICT is the strictness level at which this file becomes required.
7157 sub require_file_internal ($$$@)
7158 {
7159   my ($where, $mystrict, $dir, @files) = @_;
7160
7161   foreach my $file (@files)
7162     {
7163       my $fullfile = "$dir/$file";
7164       my $found_it = 0;
7165       my $dangling_sym = 0;
7166
7167       if (-l $fullfile && ! -f $fullfile)
7168         {
7169           $dangling_sym = 1;
7170         }
7171       elsif (dir_has_case_matching_file ($dir, $file))
7172         {
7173           $found_it = 1;
7174           maybe_push_required_file ($dir, $file, $fullfile);
7175         }
7176
7177       # `--force-missing' only has an effect if `--add-missing' is
7178       # specified.
7179       if ($found_it && (! $add_missing || ! $force_missing))
7180         {
7181           next;
7182         }
7183       else
7184         {
7185           # If we've already looked for it, we're done.  You might
7186           # wonder why we don't do this before searching for the
7187           # file.  If we do that, then something like
7188           # AC_OUTPUT(subdir/foo foo) will fail to put foo.in into
7189           # DIST_COMMON.
7190           if (! $found_it)
7191             {
7192               next if defined $required_file_not_found{$fullfile};
7193               $required_file_not_found{$fullfile} = 1;
7194             }
7195
7196           if ($strictness >= $mystrict)
7197             {
7198               if ($dangling_sym && $add_missing)
7199                 {
7200                   unlink ($fullfile);
7201                 }
7202
7203               my $trailer = '';
7204               my $suppress = 0;
7205
7206               # Only install missing files according to our desired
7207               # strictness level.
7208               my $message = "required file `$fullfile' not found";
7209               if ($add_missing)
7210                 {
7211                   if (-f "$libdir/$file")
7212                     {
7213                       $suppress = 1;
7214
7215                       # Install the missing file.  Symlink if we
7216                       # can, copy if we must.  Note: delete the file
7217                       # first, in case it is a dangling symlink.
7218                       $message = "installing `$fullfile'";
7219                       # Windows Perl will hang if we try to delete a
7220                       # file that doesn't exist.
7221                       unlink ($fullfile) if -f $fullfile;
7222                       if ($symlink_exists && ! $copy_missing)
7223                         {
7224                           if (! symlink ("$libdir/$file", $fullfile))
7225                             {
7226                               $suppress = 0;
7227                               $trailer = "; error while making link: $!";
7228                             }
7229                         }
7230                       elsif (system ('cp', "$libdir/$file", $fullfile))
7231                         {
7232                           $suppress = 0;
7233                           $trailer = "\n    error while copying";
7234                         }
7235                       reset_dir_cache ($dir);
7236                     }
7237
7238                   if (! maybe_push_required_file (dirname ($fullfile),
7239                                                   $file, $fullfile))
7240                     {
7241                       if (! $found_it && ! $automake_will_process_aux_dir)
7242                         {
7243                           # We have added the file but could not push it
7244                           # into DIST_COMMON, probably because this is
7245                           # an auxiliary file and we are not processing
7246                           # the top level Makefile.  Furthermore Automake
7247                           # hasn't been asked to create the Makefile.in
7248                           # that distribute the aux dir files.
7249                           error ($where, 'Please make a full run of automake'
7250                                  . " so $fullfile gets distributed.");
7251                         }
7252                     }
7253                 }
7254               else
7255                 {
7256                   $trailer = "\n  `automake --add-missing' can install `$file'"
7257                     if -f "$libdir/$file";
7258                 }
7259
7260               # If --force-missing was specified, and we have
7261               # actually found the file, then do nothing.
7262               next
7263                 if $found_it && $force_missing;
7264
7265               # If we couldn't install the file, but it is a target in
7266               # the Makefile, don't print anything.  This allows files
7267               # like README, AUTHORS, or THANKS to be generated.
7268               next
7269                 if !$suppress && rule $file;
7270
7271               msg ($suppress ? 'note' : 'error', $where, "$message$trailer");
7272             }
7273         }
7274     }
7275 }
7276
7277 # &require_file ($WHERE, $MYSTRICT, @FILES)
7278 # -----------------------------------------
7279 sub require_file ($$@)
7280 {
7281     my ($where, $mystrict, @files) = @_;
7282     require_file_internal ($where, $mystrict, $relative_dir, @files);
7283 }
7284
7285 # &require_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7286 # -----------------------------------------------------------
7287 sub require_file_with_macro ($$$@)
7288 {
7289     my ($cond, $macro, $mystrict, @files) = @_;
7290     $macro = rvar ($macro) unless ref $macro;
7291     require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7292 }
7293
7294 # &require_libsource_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7295 # ----------------------------------------------------------------
7296 # Require an AC_LIBSOURCEd file.  If AC_CONFIG_LIBOBJ_DIR was called, it
7297 # must be in that directory.  Otherwise expect it in the current directory.
7298 sub require_libsource_with_macro ($$$@)
7299 {
7300     my ($cond, $macro, $mystrict, @files) = @_;
7301     $macro = rvar ($macro) unless ref $macro;
7302     if ($config_libobj_dir)
7303       {
7304         require_file_internal ($macro->rdef ($cond)->location, $mystrict,
7305                                $config_libobj_dir, @files);
7306       }
7307     else
7308       {
7309         require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7310       }
7311 }
7312
7313 # &require_conf_file ($WHERE, $MYSTRICT, @FILES)
7314 # ----------------------------------------------
7315 # Looks in configuration path, as specified by AC_CONFIG_AUX_DIR.
7316 sub require_conf_file ($$@)
7317 {
7318     my ($where, $mystrict, @files) = @_;
7319     require_file_internal ($where, $mystrict, $config_aux_dir, @files);
7320 }
7321
7322
7323 # &require_conf_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7324 # ----------------------------------------------------------------
7325 sub require_conf_file_with_macro ($$$@)
7326 {
7327     my ($cond, $macro, $mystrict, @files) = @_;
7328     require_conf_file (rvar ($macro)->rdef ($cond)->location,
7329                        $mystrict, @files);
7330 }
7331
7332 ################################################################
7333
7334 # &require_build_directory ($DIRECTORY)
7335 # ------------------------------------
7336 # Emit rules to create $DIRECTORY if needed, and return
7337 # the file that any target requiring this directory should be made
7338 # dependent upon.
7339 # We don't want to emit the rule twice, and want to reuse it
7340 # for directories with equivalent names (e.g., `foo/bar' and `./foo//bar').
7341 sub require_build_directory ($)
7342 {
7343   my $directory = shift;
7344
7345   return $directory_map{$directory} if exists $directory_map{$directory};
7346
7347   my $cdir = File::Spec->canonpath ($directory);
7348
7349   if (exists $directory_map{$cdir})
7350     {
7351       my $stamp = $directory_map{$cdir};
7352       $directory_map{$directory} = $stamp;
7353       return $stamp;
7354     }
7355
7356   my $dirstamp = "$cdir/\$(am__dirstamp)";
7357
7358   $directory_map{$directory} = $dirstamp;
7359   $directory_map{$cdir} = $dirstamp;
7360
7361   # Set a variable for the dirstamp basename.
7362   define_pretty_variable ('am__dirstamp', TRUE, INTERNAL,
7363                           '$(am__leading_dot)dirstamp');
7364
7365   # Directory must be removed by `make distclean'.
7366   $clean_files{$dirstamp} = DIST_CLEAN;
7367
7368   $output_rules .= ("$dirstamp:\n"
7369                     . "\t\@\$(MKDIR_P) $directory\n"
7370                     . "\t\@: > $dirstamp\n");
7371
7372   return $dirstamp;
7373 }
7374
7375 # &require_build_directory_maybe ($FILE)
7376 # --------------------------------------
7377 # If $FILE lies in a subdirectory, emit a rule to create this
7378 # directory and return the file that $FILE should be made
7379 # dependent upon.  Otherwise, just return the empty string.
7380 sub require_build_directory_maybe ($)
7381 {
7382     my $file = shift;
7383     my $directory = dirname ($file);
7384
7385     if ($directory ne '.')
7386     {
7387         return require_build_directory ($directory);
7388     }
7389     else
7390     {
7391         return '';
7392     }
7393 }
7394
7395 ################################################################
7396
7397 # Push a list of files onto dist_common.
7398 sub push_dist_common
7399 {
7400   prog_error "push_dist_common run after handle_dist"
7401     if $handle_dist_run;
7402   Automake::Variable::define ('DIST_COMMON', VAR_AUTOMAKE, '+', TRUE, "@_",
7403                               '', INTERNAL, VAR_PRETTY);
7404 }
7405
7406
7407 ################################################################
7408
7409 # generate_makefile ($MAKEFILE_AM, $MAKEFILE_IN)
7410 # ----------------------------------------------
7411 # Generate a Makefile.in given the name of the corresponding Makefile and
7412 # the name of the file output by config.status.
7413 sub generate_makefile ($$)
7414 {
7415   my ($makefile_am, $makefile_in) = @_;
7416
7417   # Reset all the Makefile.am related variables.
7418   initialize_per_input;
7419
7420   # AUTOMAKE_OPTIONS can contains -W flags to disable or enable
7421   # warnings for this file.  So hold any warning issued before
7422   # we have processed AUTOMAKE_OPTIONS.
7423   buffer_messages ('warning');
7424
7425   # Name of input file ("Makefile.am") and output file
7426   # ("Makefile.in").  These have no directory components.
7427   $am_file_name = basename ($makefile_am);
7428   $in_file_name = basename ($makefile_in);
7429
7430   # $OUTPUT is encoded.  If it contains a ":" then the first element
7431   # is the real output file, and all remaining elements are input
7432   # files.  We don't scan or otherwise deal with these input files,
7433   # other than to mark them as dependencies.  See
7434   # &scan_autoconf_files for details.
7435   my ($makefile, @inputs) = split (/:/, $output_files{$makefile_in});
7436
7437   $relative_dir = dirname ($makefile);
7438   $am_relative_dir = dirname ($makefile_am);
7439   $topsrcdir = backname ($relative_dir);
7440
7441   read_main_am_file ($makefile_am);
7442   if (handle_options)
7443     {
7444       # Process buffered warnings.
7445       flush_messages;
7446       # Fatal error.  Just return, so we can continue with next file.
7447       return;
7448     }
7449   # Process buffered warnings.
7450   flush_messages;
7451
7452   # There are a few install-related variables that you should not define.
7453   foreach my $var ('PRE_INSTALL', 'POST_INSTALL', 'NORMAL_INSTALL')
7454     {
7455       my $v = var $var;
7456       if ($v)
7457         {
7458           my $def = $v->def (TRUE);
7459           prog_error "$var not defined in condition TRUE"
7460             unless $def;
7461           reject_var $var, "`$var' should not be defined"
7462             if $def->owner != VAR_AUTOMAKE;
7463         }
7464     }
7465
7466   # Catch some obsolete variables.
7467   msg_var ('obsolete', 'INCLUDES',
7468            "`INCLUDES' is the old name for `AM_CPPFLAGS' (or `*_CPPFLAGS')")
7469     if var ('INCLUDES');
7470
7471   # Must do this after reading .am file.
7472   define_variable ('subdir', $relative_dir, INTERNAL);
7473
7474   # If DIST_SUBDIRS is defined, make sure SUBDIRS is, so that
7475   # recursive rules are enabled.
7476   define_pretty_variable ('SUBDIRS', TRUE, INTERNAL, '')
7477     if var 'DIST_SUBDIRS' && ! var 'SUBDIRS';
7478
7479   # Check first, because we might modify some state.
7480   check_cygnus;
7481   check_gnu_standards;
7482   check_gnits_standards;
7483
7484   handle_configure ($makefile_am, $makefile_in, $makefile, @inputs);
7485   handle_gettext;
7486   handle_libraries;
7487   handle_ltlibraries;
7488   handle_programs;
7489   handle_scripts;
7490
7491   # These must be run after all the sources are scanned.  They
7492   # use variables defined by &handle_libraries, &handle_ltlibraries,
7493   # or &handle_programs.
7494   handle_compile;
7495   handle_languages;
7496   handle_libtool;
7497
7498   # Variables used by distdir.am and tags.am.
7499   define_pretty_variable ('SOURCES', TRUE, INTERNAL, @sources);
7500   if (! option 'no-dist')
7501     {
7502       define_pretty_variable ('DIST_SOURCES', TRUE, INTERNAL, @dist_sources);
7503     }
7504
7505   handle_multilib;
7506   handle_texinfo;
7507   handle_emacs_lisp;
7508   handle_python;
7509   handle_java;
7510   handle_man_pages;
7511   handle_data;
7512   handle_headers;
7513   handle_subdirs;
7514   handle_tags;
7515   handle_minor_options;
7516   # Must come after handle_programs so that %known_programs is up-to-date.
7517   handle_tests;
7518
7519   # This must come after most other rules.
7520   handle_dist;
7521
7522   handle_footer;
7523   do_check_merge_target;
7524   handle_all ($makefile);
7525
7526   # FIXME: Gross!
7527   if (var ('lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
7528     {
7529       $output_rules .= "install-binPROGRAMS: install-libLTLIBRARIES\n\n";
7530     }
7531
7532   handle_install;
7533   handle_clean ($makefile);
7534   handle_factored_dependencies;
7535
7536   # Comes last, because all the above procedures may have
7537   # defined or overridden variables.
7538   $output_vars .= output_variables;
7539
7540   check_typos;
7541
7542   my ($out_file) = $output_directory . '/' . $makefile_in;
7543
7544   if ($exit_code != 0)
7545     {
7546       verb "not writing $out_file because of earlier errors";
7547       return;
7548     }
7549
7550   if (! -d ($output_directory . '/' . $am_relative_dir))
7551     {
7552       mkdir ($output_directory . '/' . $am_relative_dir, 0755);
7553     }
7554
7555   # We make sure that `all:' is the first target.
7556   my $output =
7557     "$output_vars$output_all$output_header$output_rules$output_trailer";
7558
7559   # Decide whether we must update the output file or not.
7560   # We have to update in the following situations.
7561   #  * $force_generation is set.
7562   #  * any of the output dependencies is younger than the output
7563   #  * the contents of the output is different (this can happen
7564   #    if the project has been populated with a file listed in
7565   #    @common_files since the last run).
7566   # Output's dependencies are split in two sets:
7567   #  * dependencies which are also configure dependencies
7568   #    These do not change between each Makefile.am
7569   #  * other dependencies, specific to the Makefile.am being processed
7570   #    (such as the Makefile.am itself, or any Makefile fragment
7571   #    it includes).
7572   my $timestamp = mtime $out_file;
7573   if (! $force_generation
7574       && $configure_deps_greatest_timestamp < $timestamp
7575       && $output_deps_greatest_timestamp < $timestamp
7576       && $output eq contents ($out_file))
7577     {
7578       verb "$out_file unchanged";
7579       # No need to update.
7580       return;
7581     }
7582
7583   if (-e $out_file)
7584     {
7585       unlink ($out_file)
7586         or fatal "cannot remove $out_file: $!\n";
7587     }
7588
7589   my $gm_file = new Automake::XFile "> $out_file";
7590   verb "creating $out_file";
7591   print $gm_file $output;
7592 }
7593
7594 ################################################################
7595
7596
7597
7598
7599 ################################################################
7600
7601 # Print usage information.
7602 sub usage ()
7603 {
7604     print "Usage: $0 [OPTION] ... [Makefile]...
7605
7606 Generate Makefile.in for configure from Makefile.am.
7607
7608 Operation modes:
7609       --help               print this help, then exit
7610       --version            print version number, then exit
7611   -v, --verbose            verbosely list files processed
7612       --no-force           only update Makefile.in's that are out of date
7613   -W, --warnings=CATEGORY  report the warnings falling in CATEGORY
7614
7615 Dependency tracking:
7616   -i, --ignore-deps      disable dependency tracking code
7617       --include-deps     enable dependency tracking code
7618
7619 Flavors:
7620       --cygnus           assume program is part of Cygnus-style tree
7621       --foreign          set strictness to foreign
7622       --gnits            set strictness to gnits
7623       --gnu              set strictness to gnu
7624
7625 Library files:
7626   -a, --add-missing      add missing standard files to package
7627       --libdir=DIR       directory storing library files
7628   -c, --copy             with -a, copy missing files (default is symlink)
7629   -f, --force-missing    force update of standard files
7630
7631 ";
7632     Automake::ChannelDefs::usage;
7633
7634     my ($last, @lcomm);
7635     $last = '';
7636     foreach my $iter (sort ((@common_files, @common_sometimes)))
7637     {
7638         push (@lcomm, $iter) unless $iter eq $last;
7639         $last = $iter;
7640     }
7641
7642     my @four;
7643     print "\nFiles which are automatically distributed, if found:\n";
7644     format USAGE_FORMAT =
7645   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<
7646   $four[0],           $four[1],           $four[2],           $four[3]
7647 .
7648     $~ = "USAGE_FORMAT";
7649
7650     my $cols = 4;
7651     my $rows = int(@lcomm / $cols);
7652     my $rest = @lcomm % $cols;
7653
7654     if ($rest)
7655     {
7656         $rows++;
7657     }
7658     else
7659     {
7660         $rest = $cols;
7661     }
7662
7663     for (my $y = 0; $y < $rows; $y++)
7664     {
7665         @four = ("", "", "", "");
7666         for (my $x = 0; $x < $cols; $x++)
7667         {
7668             last if $y + 1 == $rows && $x == $rest;
7669
7670             my $idx = (($x > $rest)
7671                        ?  ($rows * $rest + ($rows - 1) * ($x - $rest))
7672                        : ($rows * $x));
7673
7674             $idx += $y;
7675             $four[$x] = $lcomm[$idx];
7676         }
7677         write;
7678     }
7679
7680     print "\nReport bugs to <bug-automake\@gnu.org>.\n";
7681
7682     # --help always returns 0 per GNU standards.
7683     exit 0;
7684 }
7685
7686
7687 # &version ()
7688 # -----------
7689 # Print version information
7690 sub version ()
7691 {
7692   print <<EOF;
7693 automake (GNU $PACKAGE) $VERSION
7694 Copyright (C) 2007 Free Software Foundation, Inc.
7695 License GPLv3+: GNU GPL version 3 or later <http://gnu.org/licenses/gpl.html>
7696 This is free software: you are free to change and redistribute it.
7697 There is NO WARRANTY, to the extent permitted by law.
7698
7699 Written by Tom Tromey <tromey\@redhat.com>
7700        and Alexandre Duret-Lutz <adl\@gnu.org>.
7701 EOF
7702   # --version always returns 0 per GNU standards.
7703   exit 0;
7704 }
7705
7706 ################################################################
7707
7708 # Parse command line.
7709 sub parse_arguments ()
7710 {
7711   # Start off as gnu.
7712   set_strictness ('gnu');
7713
7714   my $cli_where = new Automake::Location;
7715   my %cli_options =
7716     (
7717      'libdir=s'         => \$libdir,
7718      'gnu'              => sub { set_strictness ('gnu'); },
7719      'gnits'            => sub { set_strictness ('gnits'); },
7720      'cygnus'           => sub { set_global_option ('cygnus', $cli_where); },
7721      'foreign'          => sub { set_strictness ('foreign'); },
7722      'include-deps'     => sub { unset_global_option ('no-dependencies'); },
7723      'i|ignore-deps'    => sub { set_global_option ('no-dependencies',
7724                                                     $cli_where); },
7725      'no-force'         => sub { $force_generation = 0; },
7726      'f|force-missing'  => \$force_missing,
7727      'o|output-dir=s'   => \$output_directory,
7728      'a|add-missing'    => \$add_missing,
7729      'c|copy'           => \$copy_missing,
7730      'v|verbose'        => sub { setup_channel 'verb', silent => 0; },
7731      'W|warnings=s'     => \&parse_warnings,
7732      # These long options (--Werror and --Wno-error) for backward
7733      # compatibility.  Use -Werror and -Wno-error today.
7734      'Werror'           => sub { parse_warnings 'W', 'error'; },
7735      'Wno-error'        => sub { parse_warnings 'W', 'no-error'; },
7736      );
7737   use Getopt::Long;
7738   Getopt::Long::config ("bundling", "pass_through");
7739
7740   # See if --version or --help is used.  We want to process these before
7741   # anything else because the GNU Coding Standards require us to
7742   # `exit 0' after processing these options, and we can't guarantee this
7743   # if we treat other options first.  (Handling other options first
7744   # could produce error diagnostics, and in this condition it is
7745   # confusing if Automake does `exit 0'.)
7746   my %cli_options_1st_pass =
7747     (
7748      'version' => \&version,
7749      'help'    => \&usage,
7750      # Recognize all other options (and their arguments) but do nothing.
7751      map { $_ => sub {} } (keys %cli_options)
7752      );
7753   my @ARGV_backup = @ARGV;
7754   Getopt::Long::GetOptions %cli_options_1st_pass
7755     or exit 1;
7756   @ARGV = @ARGV_backup;
7757
7758   # Now *really* process the options.  This time we know that --help
7759   # and --version are not present, but we specify them nonetheless so
7760   # that ambiguous abbreviation are diagnosed.
7761   Getopt::Long::GetOptions %cli_options, 'version' => sub {}, 'help' => sub {}
7762     or exit 1;
7763
7764   if (defined $output_directory)
7765     {
7766       msg 'obsolete', "`--output-dir' is deprecated\n";
7767     }
7768   else
7769     {
7770       # In the next release we'll remove this entirely.
7771       $output_directory = '.';
7772     }
7773
7774   return unless @ARGV;
7775
7776   if ($ARGV[0] =~ /^-./)
7777     {
7778       my %argopts;
7779       for my $k (keys %cli_options)
7780         {
7781           if ($k =~ /(.*)=s$/)
7782             {
7783               map { $argopts{(length ($_) == 1)
7784                              ? "-$_" : "--$_" } = 1; } (split (/\|/, $1));
7785             }
7786         }
7787       if ($ARGV[0] eq '--')
7788         {
7789           shift @ARGV;
7790         }
7791       elsif (exists $argopts{$ARGV[0]})
7792         {
7793           fatal ("option `$ARGV[0]' requires an argument\n"
7794                  . "Try `$0 --help' for more information.");
7795         }
7796       else
7797         {
7798           fatal ("unrecognized option `$ARGV[0]'.\n"
7799                  . "Try `$0 --help' for more information.");
7800         }
7801     }
7802
7803   my $errspec = 0;
7804   foreach my $arg (@ARGV)
7805     {
7806       fatal ("empty argument\nTry `$0 --help' for more information.")
7807         if ($arg eq '');
7808
7809       # Handle $local:$input syntax.
7810       my ($local, @rest) = split (/:/, $arg);
7811       @rest = ("$local.in",) unless @rest;
7812       my $input = locate_am @rest;
7813       if ($input)
7814         {
7815           push @input_files, $input;
7816           $output_files{$input} = join (':', ($local, @rest));
7817         }
7818       else
7819         {
7820           error "no Automake input file found for `$arg'";
7821           $errspec = 1;
7822         }
7823     }
7824   fatal "no input file found among supplied arguments"
7825     if $errspec && ! @input_files;
7826 }
7827
7828 ################################################################
7829
7830 # Parse the WARNINGS environment variable.
7831 parse_WARNINGS;
7832
7833 # Parse command line.
7834 parse_arguments;
7835
7836 $configure_ac = require_configure_ac;
7837
7838 # Do configure.ac scan only once.
7839 scan_autoconf_files;
7840
7841 if (! @input_files)
7842   {
7843     my $msg = '';
7844     $msg = "\nDid you forget AC_CONFIG_FILES([Makefile]) in $configure_ac?"
7845       if -f 'Makefile.am';
7846     fatal ("no `Makefile.am' found for any configure output$msg");
7847   }
7848
7849 # Now do all the work on each file.
7850 foreach my $file (@input_files)
7851   {
7852     ($am_file = $file) =~ s/\.in$//;
7853     if (! -f ($am_file . '.am'))
7854       {
7855         error "`$am_file.am' does not exist";
7856       }
7857     else
7858       {
7859         # Any warning setting now local to this Makefile.am.
7860         dup_channel_setup;
7861
7862         generate_makefile ($am_file . '.am', $file);
7863
7864         # Back out any warning setting.
7865         drop_channel_setup;
7866       }
7867   }
7868
7869 exit $exit_code;
7870
7871
7872 ### Setup "GNU" style for perl-mode and cperl-mode.
7873 ## Local Variables:
7874 ## perl-indent-level: 2
7875 ## perl-continued-statement-offset: 2
7876 ## perl-continued-brace-offset: 0
7877 ## perl-brace-offset: 0
7878 ## perl-brace-imaginary-offset: 0
7879 ## perl-label-offset: -2
7880 ## cperl-indent-level: 2
7881 ## cperl-brace-offset: 0
7882 ## cperl-continued-brace-offset: 0
7883 ## cperl-label-offset: -2
7884 ## cperl-extra-newline-before-brace: t
7885 ## cperl-merge-trailing-else: nil
7886 ## cperl-continued-statement-offset: 2
7887 ## End: