automake.in

   1 #!@PERL@ -w
   2 # -*- perl -*-
   3 # @configure_input@
   4
   5 eval 'case $# in 0) exec @PERL@ -S "$0";; *) exec @PERL@ -S "$0" "$@";; esac'
   6     if 0;
   7
   8 # automake - create Makefile.in from Makefile.am
   9 # Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
  10 # 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011 Free Software
  11 # Foundation, Inc.
  12
  13 # This program is free software; you can redistribute it and/or modify
  14 # it under the terms of the GNU General Public License as published by
  15 # the Free Software Foundation; either version 2, or (at your option)
  16 # any later version.
  17
  18 # This program is distributed in the hope that it will be useful,
  19 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 # GNU General Public License for more details.
  22
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 # Originally written by David Mackenzie <djm@gnu.ai.mit.edu>.
  27 # Perl reimplementation by Tom Tromey <tromey@redhat.com>, and
  28 # Alexandre Duret-Lutz <adl@gnu.org>.
  29
  30 package Language;
  31
  32 BEGIN
  33 {
  34   my $perllibdir = $ENV{'perllibdir'} || '@datadir@/@PACKAGE@-@APIVERSION@';
  35   unshift @INC, (split '@PATH_SEPARATOR@', $perllibdir);
  36
  37   # Override SHELL.  This is required on DJGPP so that system() uses
  38   # bash, not COMMAND.COM which doesn't quote arguments properly.
  39   # Other systems aren't expected to use $SHELL when Automake
  40   # runs, but it should be safe to drop the `if DJGPP' guard if
  41   # it turns up other systems need the same thing.  After all,
  42   # if SHELL is used, ./configure's SHELL is always better than
  43   # the user's SHELL (which may be something like tcsh).
  44   $ENV{'SHELL'} = '@SHELL@' if exists $ENV{'DJDIR'};
  45 }
  46
  47 use Automake::Struct;
  48 struct (# Short name of the language (c, f77...).
  49         'name' => "\$",
  50         # Nice name of the language (C, Fortran 77...).
  51         'Name' => "\$",
  52
  53         # List of configure variables which must be defined.
  54         'config_vars' => '@',
  55
  56         'ansi'    => "\$",
  57         # `pure' is `1' or `'.  A `pure' language is one where, if
  58         # all the files in a directory are of that language, then we
  59         # do not require the C compiler or any code to call it.
  60         'pure'   => "\$",
  61
  62         'autodep' => "\$",
  63
  64         # Name of the compiling variable (COMPILE).
  65         'compiler'  => "\$",
  66         # Content of the compiling variable.
  67         'compile'  => "\$",
  68         # Flag to require compilation without linking (-c).
  69         'compile_flag' => "\$",
  70         'extensions' => '@',
  71         # A subroutine to compute a list of possible extensions of
  72         # the product given the input extensions.
  73         # (defaults to a subroutine which returns ('.$(OBJEXT)', '.lo'))
  74         'output_extensions' => "\$",
  75         # A list of flag variables used in 'compile'.
  76         # (defaults to [])
  77         'flags' => "@",
  78
  79         # Any tag to pass to libtool while compiling.
  80         'libtool_tag' => "\$",
  81
  82         # The file to use when generating rules for this language.
  83         # The default is 'depend2'.
  84         'rule_file' => "\$",
  85
  86         # Name of the linking variable (LINK).
  87         'linker' => "\$",
  88         # Content of the linking variable.
  89         'link' => "\$",
  90
  91         # Name of the compiler variable (CC).
  92         'ccer' => "\$",
  93
  94         # Name of the linker variable (LD).
  95         'lder' => "\$",
  96         # Content of the linker variable ($(CC)).
  97         'ld' => "\$",
  98
  99         # Flag to specify the output file (-o).
 100         'output_flag' => "\$",
 101         '_finish' => "\$",
 102
 103         # This is a subroutine which is called whenever we finally
 104         # determine the context in which a source file will be
 105         # compiled.
 106         '_target_hook' => "\$",
 107
 108         # If TRUE, nodist_ sources will be compiled using specific rules
 109         # (i.e. not inference rules).  The default is FALSE.
 110         'nodist_specific' => "\$");
 111
 112
 113 sub finish ($)
 114 {
 115   my ($self) = @_;
 116   if (defined $self->_finish)
 117     {
 118       &{$self->_finish} (@_);
 119     }
 120 }
 121
 122 sub target_hook ($$$$%)
 123 {
 124     my ($self) = @_;
 125     if (defined $self->_target_hook)
 126     {
 127         &{$self->_target_hook} (@_);
 128     }
 129 }
 130
 131 package Automake;
 132
 133 use strict;
 134 use Automake::Config;
 135 BEGIN
 136 {
 137   if ($perl_threads)
 138     {
 139       require threads;
 140       import threads;
 141       require Thread::Queue;
 142       import Thread::Queue;
 143     }
 144 }
 145 use Automake::General;
 146 use Automake::XFile;
 147 use Automake::Channels;
 148 use Automake::ChannelDefs;
 149 use Automake::Configure_ac;
 150 use Automake::FileUtils;
 151 use Automake::Location;
 152 use Automake::Condition qw/TRUE FALSE/;
 153 use Automake::DisjConditions;
 154 use Automake::Options;
 155 use Automake::Version;
 156 use Automake::Variable;
 157 use Automake::VarDef;
 158 use Automake::Rule;
 159 use Automake::RuleDef;
 160 use Automake::Wrap 'makefile_wrap';
 161 use File::Basename;
 162 use File::Spec;
 163 use Carp;
 164
 165 ## ----------- ##
 166 ## Constants.  ##
 167 ## ----------- ##
 168
 169 # Some regular expressions.  One reason to put them here is that it
 170 # makes indentation work better in Emacs.
 171
 172 # Writing singled-quoted-$-terminated regexes is a pain because
 173 # perl-mode thinks of $' as the ${'} variable (instead of a $ followed
 174 # by a closing quote.  Letting perl-mode think the quote is not closed
 175 # leads to all sort of misindentations.  On the other hand, defining
 176 # regexes as double-quoted strings is far less readable.  So usually
 177 # we will write:
 178 #
 179 #  $REGEX = '^regex_value' . "\$";
 180
 181 my $IGNORE_PATTERN = '^\s*##([^#\n].*)?\n';
 182 my $WHITE_PATTERN = '^\s*' . "\$";
 183 my $COMMENT_PATTERN = '^#';
 184 my $TARGET_PATTERN='[$a-zA-Z0-9_.@%][-.a-zA-Z0-9_(){}/$+@%]*';
 185 # A rule has three parts: a list of targets, a list of dependencies,
 186 # and optionally actions.
 187 my $RULE_PATTERN =
 188   "^($TARGET_PATTERN(?:(?:\\\\\n|\\s)+$TARGET_PATTERN)*) *:([^=].*|)\$";
 189
 190 # Only recognize leading spaces, not leading tabs.  If we recognize
 191 # leading tabs here then we need to make the reader smarter, because
 192 # otherwise it will think rules like `foo=bar; \' are errors.
 193 my $ASSIGNMENT_PATTERN = '^ *([^ \t=:+]*)\s*([:+]?)=\s*(.*)' . "\$";
 194 # This pattern recognizes a Gnits version id and sets $1 if the
 195 # release is an alpha release.  We also allow a suffix which can be
 196 # used to extend the version number with a "fork" identifier.
 197 my $GNITS_VERSION_PATTERN = '\d+\.\d+([a-z]|\.\d+)?(-[A-Za-z0-9]+)?';
 198
 199 my $IF_PATTERN = '^if\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*)\s*(?:#.*)?' . "\$";
 200 my $ELSE_PATTERN =
 201   '^else(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 202 my $ENDIF_PATTERN =
 203   '^endif(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 204 my $PATH_PATTERN = '(\w|[+/.-])+';
 205 # This will pass through anything not of the prescribed form.
 206 my $INCLUDE_PATTERN = ('^include\s+'
 207                        . '((\$\(top_srcdir\)/' . $PATH_PATTERN . ')'
 208                        . '|(\$\(srcdir\)/' . $PATH_PATTERN . ')'
 209                        . '|([^/\$]' . $PATH_PATTERN . '))\s*(#.*)?' . "\$");
 210
 211 # Directories installed during 'install-exec' phase.
 212 my $EXEC_DIR_PATTERN =
 213   '^(?:bin|sbin|libexec|sysconf|localstate|lib|pkglib|.*exec.*)' . "\$";
 214
 215 # Values for AC_CANONICAL_*
 216 use constant AC_CANONICAL_BUILD  => 1;
 217 use constant AC_CANONICAL_HOST   => 2;
 218 use constant AC_CANONICAL_TARGET => 3;
 219
 220 # Values indicating when something should be cleaned.
 221 use constant MOSTLY_CLEAN     => 0;
 222 use constant CLEAN            => 1;
 223 use constant DIST_CLEAN       => 2;
 224 use constant MAINTAINER_CLEAN => 3;
 225
 226 # Libtool files.
 227 my @libtool_files = qw(ltmain.sh config.guess config.sub);
 228 # ltconfig appears here for compatibility with old versions of libtool.
 229 my @libtool_sometimes = qw(ltconfig ltcf-c.sh ltcf-cxx.sh ltcf-gcj.sh);
 230
 231 # Commonly found files we look for and automatically include in
 232 # DISTFILES.
 233 my @common_files =
 234     (qw(ABOUT-GNU ABOUT-NLS AUTHORS BACKLOG COPYING COPYING.DOC COPYING.LIB
 235         COPYING.LESSER ChangeLog INSTALL NEWS README THANKS TODO
 236         ansi2knr.1 ansi2knr.c ar-lib compile config.guess config.rpath
 237         config.sub depcomp elisp-comp install-sh libversion.in mdate-sh
 238         missing mkinstalldirs py-compile texinfo.tex ylwrap),
 239      @libtool_files, @libtool_sometimes);
 240
 241 # Commonly used files we auto-include, but only sometimes.  This list
 242 # is used for the --help output only.
 243 my @common_sometimes =
 244   qw(aclocal.m4 acconfig.h config.h.top config.h.bot configure
 245      configure.ac configure.in stamp-vti);
 246
 247 # Standard directories from the GNU Coding Standards, and additional
 248 # pkg* directories from Automake.  Stored in a hash for fast member check.
 249 my %standard_prefix =
 250     map { $_ => 1 } (qw(bin data dataroot dvi exec html include info
 251                         lib libexec lisp localstate man man1 man2 man3
 252                         man4 man5 man6 man7 man8 man9 oldinclude pdf
 253                         pkgdatadir pkgincludedir pkglibdir pkglibexecdir
 254                         ps sbin sharedstate sysconf));
 255
 256 # Copyright on generated Makefile.ins.
 257 my $gen_copyright = "\
 258 # Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
 259 # 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011 Free Software
 260 # Foundation, Inc.
 261 # This Makefile.in is free software; the Free Software Foundation
 262 # gives unlimited permission to copy and/or distribute it,
 263 # with or without modifications, as long as this notice is preserved.
 264
 265 # This program is distributed in the hope that it will be useful,
 266 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
 267 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 268 # PARTICULAR PURPOSE.
 269 ";
 270
 271 # These constants are returned by the lang_*_rewrite functions.
 272 # LANG_SUBDIR means that the resulting object file should be in a
 273 # subdir if the source file is.  In this case the file name cannot
 274 # have `..' components.
 275 use constant LANG_IGNORE  => 0;
 276 use constant LANG_PROCESS => 1;
 277 use constant LANG_SUBDIR  => 2;
 278
 279 # These are used when keeping track of whether an object can be built
 280 # by two different paths.
 281 use constant COMPILE_LIBTOOL  => 1;
 282 use constant COMPILE_ORDINARY => 2;
 283
 284 # We can't always associate a location to a variable or a rule,
 285 # when it's defined by Automake.  We use INTERNAL in this case.
 286 use constant INTERNAL => new Automake::Location;
 287
 288 # Serialization keys for message queues.
 289 use constant QUEUE_MESSAGE   => "msg";
 290 use constant QUEUE_CONF_FILE => "conf file";
 291 use constant QUEUE_LOCATION  => "location";
 292 use constant QUEUE_STRING    => "string";
 293 \f
 294
 295 ## ---------------------------------- ##
 296 ## Variables related to the options.  ##
 297 ## ---------------------------------- ##
 298
 299 # TRUE if we should always generate Makefile.in.
 300 my $force_generation = 1;
 301
 302 # From the Perl manual.
 303 my $symlink_exists = (eval 'symlink ("", "");', $@ eq '');
 304
 305 # TRUE if missing standard files should be installed.
 306 my $add_missing = 0;
 307
 308 # TRUE if we should copy missing files; otherwise symlink if possible.
 309 my $copy_missing = 0;
 310
 311 # TRUE if we should always update files that we know about.
 312 my $force_missing = 0;
 313
 314
 315 ## ---------------------------------------- ##
 316 ## Variables filled during files scanning.  ##
 317 ## ---------------------------------------- ##
 318
 319 # Name of the configure.ac file.
 320 my $configure_ac;
 321
 322 # Files found by scanning configure.ac for LIBOBJS.
 323 my %libsources = ();
 324
 325 # Names used in AC_CONFIG_HEADER call.
 326 my @config_headers = ();
 327
 328 # Names used in AC_CONFIG_LINKS call.
 329 my @config_links = ();
 330
 331 # List of Makefile.am's to process, and their corresponding outputs.
 332 my @input_files = ();
 333 my %output_files = ();
 334
 335 # Complete list of Makefile.am's that exist.
 336 my @configure_input_files = ();
 337
 338 # List of files in AC_CONFIG_FILES/AC_OUTPUT without Makefile.am's,
 339 # and their outputs.
 340 my @other_input_files = ();
 341 # Where each AC_CONFIG_FILES/AC_OUTPUT/AC_CONFIG_LINK/AC_CONFIG_HEADER appears.
 342 # The keys are the files created by these macros.
 343 my %ac_config_files_location = ();
 344 # The condition under which AC_CONFIG_FOOS appears.
 345 my %ac_config_files_condition = ();
 346
 347 # Directory to search for configure-required files.  This
 348 # will be computed by &locate_aux_dir and can be set using
 349 # AC_CONFIG_AUX_DIR in configure.ac.
 350 # $CONFIG_AUX_DIR is the `raw' directory, valid only in the source-tree.
 351 my $config_aux_dir = '';
 352 my $config_aux_dir_set_in_configure_ac = 0;
 353 # $AM_CONFIG_AUX_DIR is prefixed with $(top_srcdir), so it can be used
 354 # in Makefiles.
 355 my $am_config_aux_dir = '';
 356
 357 # Directory to search for AC_LIBSOURCE files, as set by AC_CONFIG_LIBOBJ_DIR
 358 # in configure.ac.
 359 my $config_libobj_dir = '';
 360
 361 # Whether AM_GNU_GETTEXT has been seen in configure.ac.
 362 my $seen_gettext = 0;
 363 # Whether AM_GNU_GETTEXT([external]) is used.
 364 my $seen_gettext_external = 0;
 365 # Where AM_GNU_GETTEXT appears.
 366 my $ac_gettext_location;
 367 # Whether AM_GNU_GETTEXT_INTL_SUBDIR has been seen.
 368 my $seen_gettext_intl = 0;
 369
 370 # Lists of tags supported by Libtool.
 371 my %libtool_tags = ();
 372 # 1 if Libtool uses LT_SUPPORTED_TAG.  If it does, then it also
 373 # uses AC_REQUIRE_AUX_FILE.
 374 my $libtool_new_api = 0;
 375
 376 # Most important AC_CANONICAL_* macro seen so far.
 377 my $seen_canonical = 0;
 378 # Location of that macro.
 379 my $canonical_location;
 380
 381 # Where AM_MAINTAINER_MODE appears.
 382 my $seen_maint_mode;
 383
 384 # Actual version we've seen.
 385 my $package_version = '';
 386
 387 # Where version is defined.
 388 my $package_version_location;
 389
 390 # TRUE if we've seen AM_ENABLE_MULTILIB.
 391 my $seen_multilib = 0;
 392
 393 # TRUE if we've seen AM_PROG_CC_C_O
 394 my $seen_cc_c_o = 0;
 395
 396 # Location of AC_REQUIRE_AUX_FILE calls, indexed by their argument.
 397 my %required_aux_file = ();
 398
 399 # Where AM_INIT_AUTOMAKE is called;
 400 my $seen_init_automake = 0;
 401
 402 # TRUE if we've seen AM_AUTOMAKE_VERSION.
 403 my $seen_automake_version = 0;
 404
 405 # Hash table of discovered configure substitutions.  Keys are names,
 406 # values are `FILE:LINE' strings which are used by error message
 407 # generation.
 408 my %configure_vars = ();
 409
 410 # Ignored configure substitutions (i.e., variables not to be output in
 411 # Makefile.in)
 412 my %ignored_configure_vars = ();
 413
 414 # Files included by $configure_ac.
 415 my @configure_deps = ();
 416
 417 # Greatest timestamp of configure's dependencies.
 418 my $configure_deps_greatest_timestamp = 0;
 419
 420 # Hash table of AM_CONDITIONAL variables seen in configure.
 421 my %configure_cond = ();
 422
 423 # This maps extensions onto language names.
 424 my %extension_map = ();
 425
 426 # List of the DIST_COMMON files we discovered while reading
 427 # configure.in
 428 my $configure_dist_common = '';
 429
 430 # This maps languages names onto objects.
 431 my %languages = ();
 432 # Maps each linker variable onto a language object.
 433 my %link_languages = ();
 434
 435 # maps extensions to needed source flags.
 436 my %sourceflags = ();
 437
 438 # List of targets we must always output.
 439 # FIXME: Complete, and remove falsely required targets.
 440 my %required_targets =
 441   (
 442    'all'          => 1,
 443    'dvi'          => 1,
 444    'pdf'          => 1,
 445    'ps'           => 1,
 446    'info'         => 1,
 447    'install-info' => 1,
 448    'install'      => 1,
 449    'install-data' => 1,
 450    'install-exec' => 1,
 451    'uninstall'    => 1,
 452
 453    # FIXME: Not required, temporary hacks.
 454    # Well, actually they are sort of required: the -recursive
 455    # targets will run them anyway...
 456    'html-am'         => 1,
 457    'dvi-am'          => 1,
 458    'pdf-am'          => 1,
 459    'ps-am'           => 1,
 460    'info-am'         => 1,
 461    'install-data-am' => 1,
 462    'install-exec-am' => 1,
 463    'install-html-am' => 1,
 464    'install-dvi-am'  => 1,
 465    'install-pdf-am'  => 1,
 466    'install-ps-am'   => 1,
 467    'install-info-am' => 1,
 468    'installcheck-am' => 1,
 469    'uninstall-am' => 1,
 470
 471    'install-man' => 1,
 472   );
 473
 474 # Set to 1 if this run will create the Makefile.in that distributes
 475 # the files in config_aux_dir.
 476 my $automake_will_process_aux_dir = 0;
 477
 478 # The name of the Makefile currently being processed.
 479 my $am_file = 'BUG';
 480 \f
 481
 482 ################################################################
 483
 484 ## ------------------------------------------ ##
 485 ## Variables reset by &initialize_per_input.  ##
 486 ## ------------------------------------------ ##
 487
 488 # Basename and relative dir of the input file.
 489 my $am_file_name;
 490 my $am_relative_dir;
 491
 492 # Same but wrt Makefile.in.
 493 my $in_file_name;
 494 my $relative_dir;
 495
 496 # Relative path to the top directory.
 497 my $topsrcdir;
 498
 499 # Greatest timestamp of the output's dependencies (excluding
 500 # configure's dependencies).
 501 my $output_deps_greatest_timestamp;
 502
 503 # These variables are used when generating each Makefile.in.
 504 # They hold the Makefile.in until it is ready to be printed.
 505 my $output_vars;
 506 my $output_all;
 507 my $output_header;
 508 my $output_rules;
 509 my $output_trailer;
 510
 511 # This is the conditional stack, updated on if/else/endif, and
 512 # used to build Condition objects.
 513 my @cond_stack;
 514
 515 # This holds the set of included files.
 516 my @include_stack;
 517
 518 # List of dependencies for the obvious targets.
 519 my @all;
 520 my @check;
 521 my @check_tests;
 522
 523 # Keys in this hash table are files to delete.  The associated
 524 # value tells when this should happen (MOSTLY_CLEAN, DIST_CLEAN, etc.)
 525 my %clean_files;
 526
 527 # Keys in this hash table are object files or other files in
 528 # subdirectories which need to be removed.  This only holds files
 529 # which are created by compilations.  The value in the hash indicates
 530 # when the file should be removed.
 531 my %compile_clean_files;
 532
 533 # Keys in this hash table are directories where we expect to build a
 534 # libtool object.  We use this information to decide what directories
 535 # to delete.
 536 my %libtool_clean_directories;
 537
 538 # Value of `$(SOURCES)', used by tags.am.
 539 my @sources;
 540 # Sources which go in the distribution.
 541 my @dist_sources;
 542
 543 # This hash maps object file names onto their corresponding source
 544 # file names.  This is used to ensure that each object is created
 545 # by a single source file.
 546 my %object_map;
 547
 548 # This hash maps object file names onto an integer value representing
 549 # whether this object has been built via ordinary compilation or
 550 # libtool compilation (the COMPILE_* constants).
 551 my %object_compilation_map;
 552
 553
 554 # This keeps track of the directories for which we've already
 555 # created dirstamp code.  Keys are directories, values are stamp files.
 556 # Several keys can share the same stamp files if they are equivalent
 557 # (as are `.//foo' and `foo').
 558 my %directory_map;
 559
 560 # All .P files.
 561 my %dep_files;
 562
 563 # This is a list of all targets to run during "make dist".
 564 my @dist_targets;
 565
 566 # Keep track of all programs declared in this Makefile, without
 567 # $(EXEEXT).  @substitutions@ are not listed.
 568 my %known_programs;
 569 my %known_libraries;
 570
 571 # Keys in this hash are the basenames of files which must depend on
 572 # ansi2knr.  Values are either the empty string, or the directory in
 573 # which the ANSI source file appears; the directory must have a
 574 # trailing `/'.
 575 my %de_ansi_files;
 576
 577 # This keeps track of which extensions we've seen (that we care
 578 # about).
 579 my %extension_seen;
 580
 581 # This is random scratch space for the language finish functions.
 582 # Don't randomly overwrite it; examine other uses of keys first.
 583 my %language_scratch;
 584
 585 # We keep track of which objects need special (per-executable)
 586 # handling on a per-language basis.
 587 my %lang_specific_files;
 588
 589 # This is set when `handle_dist' has finished.  Once this happens,
 590 # we should no longer push on dist_common.
 591 my $handle_dist_run;
 592
 593 # Used to store a set of linkers needed to generate the sources currently
 594 # under consideration.
 595 my %linkers_used;
 596
 597 # True if we need `LINK' defined.  This is a hack.
 598 my $need_link;
 599
 600 # Was get_object_extension run?
 601 # FIXME: This is a hack. a better switch should be found.
 602 my $get_object_extension_was_run;
 603
 604 # Record each file processed by make_paragraphs.
 605 my %transformed_files;
 606 \f
 607
 608 ################################################################
 609
 610 ## ---------------------------------------------- ##
 611 ## Variables not reset by &initialize_per_input.  ##
 612 ## ---------------------------------------------- ##
 613
 614 # Cache each file processed by make_paragraphs.
 615 # (This is different from %transformed_files because
 616 # %transformed_files is reset for each file while %am_file_cache
 617 # it global to the run.)
 618 my %am_file_cache;
 619
 620 ################################################################
 621
 622 # var_SUFFIXES_trigger ($TYPE, $VALUE)
 623 # ------------------------------------
 624 # This is called by Automake::Variable::define() when SUFFIXES
 625 # is defined ($TYPE eq '') or appended ($TYPE eq '+').
 626 # The work here needs to be performed as a side-effect of the
 627 # macro_define() call because SUFFIXES definitions impact
 628 # on $KNOWN_EXTENSIONS_PATTERN which is used used when parsing
 629 # the input am file.
 630 sub var_SUFFIXES_trigger ($$)
 631 {
 632     my ($type, $value) = @_;
 633     accept_extensions (split (' ', $value));
 634 }
 635 Automake::Variable::hook ('SUFFIXES', \&var_SUFFIXES_trigger);
 636
 637 ################################################################
 638
 639 ## --------------------------------- ##
 640 ## Forward subroutine declarations.  ##
 641 ## --------------------------------- ##
 642 sub register_language (%);
 643 sub file_contents_internal ($$$%);
 644 sub define_files_variable ($\@$$);
 645
 646
 647 # &initialize_per_input ()
 648 # ------------------------
 649 # (Re)-Initialize per-Makefile.am variables.
 650 sub initialize_per_input ()
 651 {
 652     reset_local_duplicates ();
 653
 654     $am_file_name = undef;
 655     $am_relative_dir = undef;
 656
 657     $in_file_name = undef;
 658     $relative_dir = undef;
 659     $topsrcdir = undef;
 660
 661     $output_deps_greatest_timestamp = 0;
 662
 663     $output_vars = '';
 664     $output_all = '';
 665     $output_header = '';
 666     $output_rules = '';
 667     $output_trailer = '';
 668
 669     Automake::Options::reset;
 670     Automake::Variable::reset;
 671     Automake::Rule::reset;
 672
 673     @cond_stack = ();
 674
 675     @include_stack = ();
 676
 677     @all = ();
 678     @check = ();
 679     @check_tests = ();
 680
 681     %clean_files = ();
 682     %compile_clean_files = ();
 683
 684     # We always include `.'.  This isn't strictly correct.
 685     %libtool_clean_directories = ('.' => 1);
 686
 687     @sources = ();
 688     @dist_sources = ();
 689
 690     %object_map = ();
 691     %object_compilation_map = ();
 692
 693     %directory_map = ();
 694
 695     %dep_files = ();
 696
 697     @dist_targets = ();
 698
 699     %known_programs = ();
 700     %known_libraries= ();
 701
 702     %de_ansi_files = ();
 703
 704     %extension_seen = ();
 705
 706     %language_scratch = ();
 707
 708     %lang_specific_files = ();
 709
 710     $handle_dist_run = 0;
 711
 712     $need_link = 0;
 713
 714     $get_object_extension_was_run = 0;
 715
 716     %transformed_files = ();
 717 }
 718
 719
 720 ################################################################
 721
 722 # Initialize our list of languages that are internally supported.
 723
 724 # C.
 725 register_language ('name' => 'c',
 726                    'Name' => 'C',
 727                    'config_vars' => ['CC'],
 728                    'ansi' => 1,
 729                    'autodep' => '',
 730                    'flags' => ['CFLAGS', 'CPPFLAGS'],
 731                    'ccer' => 'CC',
 732                    'compiler' => 'COMPILE',
 733                    'compile' => '$(CC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CFLAGS) $(CFLAGS)',
 734                    'lder' => 'CCLD',
 735                    'ld' => '$(CC)',
 736                    'linker' => 'LINK',
 737                    'link' => '$(CCLD) $(AM_CFLAGS) $(CFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 738                    'compile_flag' => '-c',
 739                    'libtool_tag' => 'CC',
 740                    'extensions' => ['.c'],
 741                    '_finish' => \&lang_c_finish);
 742
 743 # C++.
 744 register_language ('name' => 'cxx',
 745                    'Name' => 'C++',
 746                    'config_vars' => ['CXX'],
 747                    'linker' => 'CXXLINK',
 748                    'link' => '$(CXXLD) $(AM_CXXFLAGS) $(CXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 749                    'autodep' => 'CXX',
 750                    'flags' => ['CXXFLAGS', 'CPPFLAGS'],
 751                    'compile' => '$(CXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CXXFLAGS) $(CXXFLAGS)',
 752                    'ccer' => 'CXX',
 753                    'compiler' => 'CXXCOMPILE',
 754                    'compile_flag' => '-c',
 755                    'output_flag' => '-o',
 756                    'libtool_tag' => 'CXX',
 757                    'lder' => 'CXXLD',
 758                    'ld' => '$(CXX)',
 759                    'pure' => 1,
 760                    'extensions' => ['.c++', '.cc', '.cpp', '.cxx', '.C']);
 761
 762 # Objective C.
 763 register_language ('name' => 'objc',
 764                    'Name' => 'Objective C',
 765                    'config_vars' => ['OBJC'],
 766                    'linker' => 'OBJCLINK',
 767                    'link' => '$(OBJCLD) $(AM_OBJCFLAGS) $(OBJCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 768                    'autodep' => 'OBJC',
 769                    'flags' => ['OBJCFLAGS', 'CPPFLAGS'],
 770                    'compile' => '$(OBJC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCFLAGS) $(OBJCFLAGS)',
 771                    'ccer' => 'OBJC',
 772                    'compiler' => 'OBJCCOMPILE',
 773                    'compile_flag' => '-c',
 774                    'output_flag' => '-o',
 775                    'lder' => 'OBJCLD',
 776                    'ld' => '$(OBJC)',
 777                    'pure' => 1,
 778                    'extensions' => ['.m']);
 779
 780 # Unified Parallel C.
 781 register_language ('name' => 'upc',
 782                    'Name' => 'Unified Parallel C',
 783                    'config_vars' => ['UPC'],
 784                    'linker' => 'UPCLINK',
 785                    'link' => '$(UPCLD) $(AM_UPCFLAGS) $(UPCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 786                    'autodep' => 'UPC',
 787                    'flags' => ['UPCFLAGS', 'CPPFLAGS'],
 788                    'compile' => '$(UPC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_UPCFLAGS) $(UPCFLAGS)',
 789                    'ccer' => 'UPC',
 790                    'compiler' => 'UPCCOMPILE',
 791                    'compile_flag' => '-c',
 792                    'output_flag' => '-o',
 793                    'lder' => 'UPCLD',
 794                    'ld' => '$(UPC)',
 795                    'pure' => 1,
 796                    'extensions' => ['.upc']);
 797
 798 # Headers.
 799 register_language ('name' => 'header',
 800                    'Name' => 'Header',
 801                    'extensions' => ['.h', '.H', '.hxx', '.h++', '.hh',
 802                                     '.hpp', '.inc'],
 803                    # No output.
 804                    'output_extensions' => sub { return () },
 805                    # Nothing to do.
 806                    '_finish' => sub { });
 807
 808 # Vala
 809 register_language ('name' => 'vala',
 810                    'Name' => 'Vala',
 811                    'config_vars' => ['VALAC'],
 812                    'flags' => [],
 813                    'compile' => '$(VALAC) $(AM_VALAFLAGS) $(VALAFLAGS)',
 814                    'ccer' => 'VALAC',
 815                    'compiler' => 'VALACOMPILE',
 816                    'extensions' => ['.vala'],
 817                    'output_extensions' => sub { (my $ext = $_[0]) =~ s/vala$/c/;
 818                                                 return ($ext,) },
 819                    'rule_file' => 'vala',
 820                    '_finish' => \&lang_vala_finish,
 821                    '_target_hook' => \&lang_vala_target_hook,
 822                    'nodist_specific' => 1);
 823
 824 # Yacc (C & C++).
 825 register_language ('name' => 'yacc',
 826                    'Name' => 'Yacc',
 827                    'config_vars' => ['YACC'],
 828                    'flags' => ['YFLAGS'],
 829                    'compile' => '$(YACC) $(AM_YFLAGS) $(YFLAGS)',
 830                    'ccer' => 'YACC',
 831                    'compiler' => 'YACCCOMPILE',
 832                    'extensions' => ['.y'],
 833                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 834                                                 return ($ext,) },
 835                    'rule_file' => 'yacc',
 836                    '_finish' => \&lang_yacc_finish,
 837                    '_target_hook' => \&lang_yacc_target_hook,
 838                    'nodist_specific' => 1);
 839 register_language ('name' => 'yaccxx',
 840                    'Name' => 'Yacc (C++)',
 841                    'config_vars' => ['YACC'],
 842                    'rule_file' => 'yacc',
 843                    'flags' => ['YFLAGS'],
 844                    'ccer' => 'YACC',
 845                    'compiler' => 'YACCCOMPILE',
 846                    'compile' => '$(YACC) $(AM_YFLAGS) $(YFLAGS)',
 847                    'extensions' => ['.y++', '.yy', '.yxx', '.ypp'],
 848                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 849                                                 return ($ext,) },
 850                    '_finish' => \&lang_yacc_finish,
 851                    '_target_hook' => \&lang_yacc_target_hook,
 852                    'nodist_specific' => 1);
 853
 854 # Lex (C & C++).
 855 register_language ('name' => 'lex',
 856                    'Name' => 'Lex',
 857                    'config_vars' => ['LEX'],
 858                    'rule_file' => 'lex',
 859                    'flags' => ['LFLAGS'],
 860                    'compile' => '$(LEX) $(AM_LFLAGS) $(LFLAGS)',
 861                    'ccer' => 'LEX',
 862                    'compiler' => 'LEXCOMPILE',
 863                    'extensions' => ['.l'],
 864                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 865                                                 return ($ext,) },
 866                    '_finish' => \&lang_lex_finish,
 867                    '_target_hook' => \&lang_lex_target_hook,
 868                    'nodist_specific' => 1);
 869 register_language ('name' => 'lexxx',
 870                    'Name' => 'Lex (C++)',
 871                    'config_vars' => ['LEX'],
 872                    'rule_file' => 'lex',
 873                    'flags' => ['LFLAGS'],
 874                    'compile' => '$(LEX) $(AM_LFLAGS) $(LFLAGS)',
 875                    'ccer' => 'LEX',
 876                    'compiler' => 'LEXCOMPILE',
 877                    'extensions' => ['.l++', '.ll', '.lxx', '.lpp'],
 878                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 879                                                 return ($ext,) },
 880                    '_finish' => \&lang_lex_finish,
 881                    '_target_hook' => \&lang_lex_target_hook,
 882                    'nodist_specific' => 1);
 883
 884 # Assembler.
 885 register_language ('name' => 'asm',
 886                    'Name' => 'Assembler',
 887                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 888
 889                    'flags' => ['CCASFLAGS'],
 890                    # Users can set AM_CCASFLAGS to include DEFS, INCLUDES,
 891                    # or anything else required.  They can also set CCAS.
 892                    # Or simply use Preprocessed Assembler.
 893                    'compile' => '$(CCAS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 894                    'ccer' => 'CCAS',
 895                    'compiler' => 'CCASCOMPILE',
 896                    'compile_flag' => '-c',
 897                    'output_flag' => '-o',
 898                    'extensions' => ['.s'],
 899
 900                    # With assembly we still use the C linker.
 901                    '_finish' => \&lang_c_finish);
 902
 903 # Preprocessed Assembler.
 904 register_language ('name' => 'cppasm',
 905                    'Name' => 'Preprocessed Assembler',
 906                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 907
 908                    'autodep' => 'CCAS',
 909                    'flags' => ['CCASFLAGS', 'CPPFLAGS'],
 910                    'compile' => '$(CCAS) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 911                    'ccer' => 'CPPAS',
 912                    'compiler' => 'CPPASCOMPILE',
 913                    'compile_flag' => '-c',
 914                    'output_flag' => '-o',
 915                    'extensions' => ['.S', '.sx'],
 916
 917                    # With assembly we still use the C linker.
 918                    '_finish' => \&lang_c_finish);
 919
 920 # Fortran 77
 921 register_language ('name' => 'f77',
 922                    'Name' => 'Fortran 77',
 923                    'config_vars' => ['F77'],
 924                    'linker' => 'F77LINK',
 925                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 926                    'flags' => ['FFLAGS'],
 927                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS)',
 928                    'ccer' => 'F77',
 929                    'compiler' => 'F77COMPILE',
 930                    'compile_flag' => '-c',
 931                    'output_flag' => '-o',
 932                    'libtool_tag' => 'F77',
 933                    'lder' => 'F77LD',
 934                    'ld' => '$(F77)',
 935                    'pure' => 1,
 936                    'extensions' => ['.f', '.for']);
 937
 938 # Fortran
 939 register_language ('name' => 'fc',
 940                    'Name' => 'Fortran',
 941                    'config_vars' => ['FC'],
 942                    'linker' => 'FCLINK',
 943                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 944                    'flags' => ['FCFLAGS'],
 945                    'compile' => '$(FC) $(AM_FCFLAGS) $(FCFLAGS)',
 946                    'ccer' => 'FC',
 947                    'compiler' => 'FCCOMPILE',
 948                    'compile_flag' => '-c',
 949                    'output_flag' => '-o',
 950                    'libtool_tag' => 'FC',
 951                    'lder' => 'FCLD',
 952                    'ld' => '$(FC)',
 953                    'pure' => 1,
 954                    'extensions' => ['.f90', '.f95', '.f03', '.f08']);
 955
 956 # Preprocessed Fortran
 957 register_language ('name' => 'ppfc',
 958                    'Name' => 'Preprocessed Fortran',
 959                    'config_vars' => ['FC'],
 960                    'linker' => 'FCLINK',
 961                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 962                    'lder' => 'FCLD',
 963                    'ld' => '$(FC)',
 964                    'flags' => ['FCFLAGS', 'CPPFLAGS'],
 965                    'ccer' => 'PPFC',
 966                    'compiler' => 'PPFCCOMPILE',
 967                    'compile' => '$(FC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FCFLAGS) $(FCFLAGS)',
 968                    'compile_flag' => '-c',
 969                    'output_flag' => '-o',
 970                    'libtool_tag' => 'FC',
 971                    'pure' => 1,
 972                    'extensions' => ['.F90','.F95', '.F03', '.F08']);
 973
 974 # Preprocessed Fortran 77
 975 #
 976 # The current support for preprocessing Fortran 77 just involves
 977 # passing `$(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS)
 978 # $(CPPFLAGS)' as additional flags to the Fortran 77 compiler, since
 979 # this is how GNU Make does it; see the `GNU Make Manual, Edition 0.51
 980 # for `make' Version 3.76 Beta' (specifically, from info file
 981 # `(make)Catalogue of Rules').
 982 #
 983 # A better approach would be to write an Autoconf test
 984 # (i.e. AC_PROG_FPP) for a Fortran 77 preprocessor, because not all
 985 # Fortran 77 compilers know how to do preprocessing.  The Autoconf
 986 # macro AC_PROG_FPP should test the Fortran 77 compiler first for
 987 # preprocessing capabilities, and then fall back on cpp (if cpp were
 988 # available).
 989 register_language ('name' => 'ppf77',
 990                    'Name' => 'Preprocessed Fortran 77',
 991                    'config_vars' => ['F77'],
 992                    'linker' => 'F77LINK',
 993                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 994                    'lder' => 'F77LD',
 995                    'ld' => '$(F77)',
 996                    'flags' => ['FFLAGS', 'CPPFLAGS'],
 997                    'ccer' => 'PPF77',
 998                    'compiler' => 'PPF77COMPILE',
 999                    'compile' => '$(F77) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FFLAGS) $(FFLAGS)',
1000                    'compile_flag' => '-c',
1001                    'output_flag' => '-o',
1002                    'libtool_tag' => 'F77',
1003                    'pure' => 1,
1004                    'extensions' => ['.F']);
1005
1006 # Ratfor.
1007 register_language ('name' => 'ratfor',
1008                    'Name' => 'Ratfor',
1009                    'config_vars' => ['F77'],
1010                    'linker' => 'F77LINK',
1011                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
1012                    'lder' => 'F77LD',
1013                    'ld' => '$(F77)',
1014                    'flags' => ['RFLAGS', 'FFLAGS'],
1015                    # FIXME also FFLAGS.
1016                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS) $(AM_RFLAGS) $(RFLAGS)',
1017                    'ccer' => 'F77',
1018                    'compiler' => 'RCOMPILE',
1019                    'compile_flag' => '-c',
1020                    'output_flag' => '-o',
1021                    'libtool_tag' => 'F77',
1022                    'pure' => 1,
1023                    'extensions' => ['.r']);
1024
1025 # Java via gcj.
1026 register_language ('name' => 'java',
1027                    'Name' => 'Java',
1028                    'config_vars' => ['GCJ'],
1029                    'linker' => 'GCJLINK',
1030                    'link' => '$(GCJLD) $(AM_GCJFLAGS) $(GCJFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
1031                    'autodep' => 'GCJ',
1032                    'flags' => ['GCJFLAGS'],
1033                    'compile' => '$(GCJ) $(AM_GCJFLAGS) $(GCJFLAGS)',
1034                    'ccer' => 'GCJ',
1035                    'compiler' => 'GCJCOMPILE',
1036                    'compile_flag' => '-c',
1037                    'output_flag' => '-o',
1038                    'libtool_tag' => 'GCJ',
1039                    'lder' => 'GCJLD',
1040                    'ld' => '$(GCJ)',
1041                    'pure' => 1,
1042                    'extensions' => ['.java', '.class', '.zip', '.jar']);
1043
1044 ################################################################
1045
1046 # Error reporting functions.
1047
1048 # err_am ($MESSAGE, [%OPTIONS])
1049 # -----------------------------
1050 # Uncategorized errors about the current Makefile.am.
1051 sub err_am ($;%)
1052 {
1053   msg_am ('error', @_);
1054 }
1055
1056 # err_ac ($MESSAGE, [%OPTIONS])
1057 # -----------------------------
1058 # Uncategorized errors about configure.ac.
1059 sub err_ac ($;%)
1060 {
1061   msg_ac ('error', @_);
1062 }
1063
1064 # msg_am ($CHANNEL, $MESSAGE, [%OPTIONS])
1065 # ---------------------------------------
1066 # Messages about about the current Makefile.am.
1067 sub msg_am ($$;%)
1068 {
1069   my ($channel, $msg, %opts) = @_;
1070   msg $channel, "${am_file}.am", $msg, %opts;
1071 }
1072
1073 # msg_ac ($CHANNEL, $MESSAGE, [%OPTIONS])
1074 # ---------------------------------------
1075 # Messages about about configure.ac.
1076 sub msg_ac ($$;%)
1077 {
1078   my ($channel, $msg, %opts) = @_;
1079   msg $channel, $configure_ac, $msg, %opts;
1080 }
1081
1082 ################################################################
1083
1084 # subst ($TEXT)
1085 # -------------
1086 # Return a configure-style substitution using the indicated text.
1087 # We do this to avoid having the substitutions directly in automake.in;
1088 # when we do that they are sometimes removed and this causes confusion
1089 # and bugs.
1090 sub subst ($)
1091 {
1092     my ($text) = @_;
1093     return '@' . $text . '@';
1094 }
1095
1096 ################################################################
1097
1098
1099 # $BACKPATH
1100 # &backname ($REL-DIR)
1101 # --------------------
1102 # If I `cd $REL-DIR', then to come back, I should `cd $BACKPATH'.
1103 # For instance `src/foo' => `../..'.
1104 # Works with non strictly increasing paths, i.e., `src/../lib' => `..'.
1105 sub backname ($)
1106 {
1107     my ($file) = @_;
1108     my @res;
1109     foreach (split (/\//, $file))
1110     {
1111         next if $_ eq '.' || $_ eq '';
1112         if ($_ eq '..')
1113         {
1114             pop @res
1115               or prog_error ("trying to reverse path `$file' pointing outside tree");
1116         }
1117         else
1118         {
1119             push (@res, '..');
1120         }
1121     }
1122     return join ('/', @res) || '.';
1123 }
1124
1125 ################################################################
1126
1127 # `silent-rules' mode handling functions.
1128
1129 # verbose_var (NAME)
1130 # ------------------
1131 # The public variable stem used to implement `silent-rules'.
1132 sub verbose_var ($)
1133 {
1134     my ($name) = @_;
1135     return 'AM_V_' . $name;
1136 }
1137
1138 # verbose_private_var (NAME)
1139 # --------------------------
1140 # The naming policy for the private variables for `silent-rules'.
1141 sub verbose_private_var ($)
1142 {
1143     my ($name) = @_;
1144     return 'am__v_' . $name;
1145 }
1146
1147 # define_verbose_var (NAME, VAL)
1148 # ------------------------------
1149 # For `silent-rules' mode, setup VAR and dispatcher, to expand to VAL if silent.
1150 sub define_verbose_var ($$)
1151 {
1152     my ($name, $val) = @_;
1153     my $var = verbose_var ($name);
1154     my $pvar = verbose_private_var ($name);
1155     my $silent_var = $pvar . '_0';
1156     if (option 'silent-rules')
1157       {
1158         # Using `$V' instead of `$(V)' breaks IRIX make.
1159         define_variable ($var, '$(' . $pvar . '_$(V))', INTERNAL);
1160         define_variable ($pvar . '_', '$(' . $pvar . '_$(AM_DEFAULT_VERBOSITY))', INTERNAL);
1161         Automake::Variable::define ($silent_var, VAR_AUTOMAKE, '', TRUE, $val,
1162                                     '', INTERNAL, VAR_ASIS)
1163           if (! vardef ($silent_var, TRUE));
1164       }
1165 }
1166
1167 # Above should not be needed in the general automake code.
1168
1169 # verbose_flag (NAME)
1170 # -------------------
1171 # Contents of %VERBOSE%: variable to expand before rule command.
1172 sub verbose_flag ($)
1173 {
1174     my ($name) = @_;
1175     return '$(' . verbose_var ($name) . ')'
1176       if (option 'silent-rules');
1177     return '';
1178 }
1179
1180 sub verbose_nodep_flag ($)
1181 {
1182     my ($name) = @_;
1183     return '$(' . verbose_var ($name) . subst ('am__nodep') . ')'
1184       if (option 'silent-rules');
1185     return '';
1186 }
1187
1188 # silent_flag
1189 # -----------
1190 # Contents of %SILENT%: variable to expand to `@' when silent.
1191 sub silent_flag ()
1192 {
1193     return verbose_flag ('at');
1194 }
1195
1196 # define_verbose_tagvar (NAME)
1197 # ----------------------------
1198 # Engage the needed `silent-rules' machinery for tag NAME.
1199 sub define_verbose_tagvar ($)
1200 {
1201     my ($name) = @_;
1202     if (option 'silent-rules')
1203       {
1204         define_verbose_var ($name, '@echo "  '. $name . ' ' x (8 - length ($name)) . '" $@;');
1205         define_verbose_var ('at', '@');
1206       }
1207 }
1208
1209 # define_verbose_texinfo
1210 # ----------------------
1211 # Engage the needed `silent-rules' machinery for assorted texinfo commands.
1212 sub define_verbose_texinfo ()
1213 {
1214   my @tagvars = ('DVIPS', 'MAKEINFO', 'INFOHTML', 'TEXI2DVI', 'TEXI2PDF');
1215   foreach my $tag (@tagvars)
1216     {
1217       define_verbose_tagvar($tag);
1218     }
1219   define_verbose_var('texinfo', '-q');
1220   define_verbose_var('texidevnull', '> /dev/null');
1221 }
1222
1223 # define_verbose_libtool
1224 # ----------------------
1225 # Engage the needed `silent-rules' machinery for `libtool --silent'.
1226 sub define_verbose_libtool ()
1227 {
1228     define_verbose_var ('lt', '--silent');
1229     return verbose_flag ('lt');
1230 }
1231
1232
1233 ################################################################
1234
1235
1236 # Handle AUTOMAKE_OPTIONS variable.  Return 1 on error, 0 otherwise.
1237 sub handle_options
1238 {
1239   my $var = var ('AUTOMAKE_OPTIONS');
1240   if ($var)
1241     {
1242       if ($var->has_conditional_contents)
1243         {
1244           msg_var ('unsupported', $var,
1245                    "`AUTOMAKE_OPTIONS' cannot have conditional contents");
1246         }
1247       foreach my $locvals ($var->value_as_list_recursive (cond_filter => TRUE,
1248                                                           location => 1))
1249         {
1250           my ($loc, $value) = @$locvals;
1251           return 1 if (process_option_list ($loc, $value))
1252         }
1253     }
1254
1255   # Override portability-recursive warning.
1256   switch_warning ('no-portability-recursive')
1257     if option 'silent-rules';
1258
1259   if ($strictness == GNITS)
1260     {
1261       set_option ('readme-alpha', INTERNAL);
1262       set_option ('std-options', INTERNAL);
1263       set_option ('check-news', INTERNAL);
1264     }
1265
1266   return 0;
1267 }
1268
1269 # shadow_unconditionally ($varname, $where)
1270 # -----------------------------------------
1271 # Return a $(variable) that contains all possible values
1272 # $varname can take.
1273 # If the VAR wasn't defined conditionally, return $(VAR).
1274 # Otherwise we create an am__VAR_DIST variable which contains
1275 # all possible values, and return $(am__VAR_DIST).
1276 sub shadow_unconditionally ($$)
1277 {
1278   my ($varname, $where) = @_;
1279   my $var = var $varname;
1280   if ($var->has_conditional_contents)
1281     {
1282       $varname = "am__${varname}_DIST";
1283       my @files = uniq ($var->value_as_list_recursive);
1284       define_pretty_variable ($varname, TRUE, $where, @files);
1285     }
1286   return "\$($varname)"
1287 }
1288
1289 # get_object_extension ($EXTENSION)
1290 # ---------------------------------
1291 # Prefix $EXTENSION with $U if ansi2knr is in use.
1292 sub get_object_extension ($)
1293 {
1294     my ($extension) = @_;
1295
1296     # Check for automatic de-ANSI-fication.
1297     $extension = '$U' . $extension
1298       if option 'ansi2knr';
1299
1300     $get_object_extension_was_run = 1;
1301
1302     return $extension;
1303 }
1304
1305 # check_user_variables (@LIST)
1306 # ----------------------------
1307 # Make sure each variable VAR in @LIST does not exist, suggest using AM_VAR
1308 # otherwise.
1309 sub check_user_variables (@)
1310 {
1311   my @dont_override = @_;
1312   foreach my $flag (@dont_override)
1313     {
1314       my $var = var $flag;
1315       if ($var)
1316         {
1317           for my $cond ($var->conditions->conds)
1318             {
1319               if ($var->rdef ($cond)->owner == VAR_MAKEFILE)
1320                 {
1321                   msg_cond_var ('gnu', $cond, $flag,
1322                                 "`$flag' is a user variable, "
1323                                 . "you should not override it;\n"
1324                                 . "use `AM_$flag' instead");
1325                 }
1326             }
1327         }
1328     }
1329 }
1330
1331 # Call finish function for each language that was used.
1332 sub handle_languages
1333 {
1334     if (! option 'no-dependencies')
1335     {
1336         # Include auto-dep code.  Don't include it if DEP_FILES would
1337         # be empty.
1338         if (&saw_sources_p (0) && keys %dep_files)
1339         {
1340             # Set location of depcomp.
1341             &define_variable ('depcomp',
1342                               "\$(SHELL) $am_config_aux_dir/depcomp",
1343                               INTERNAL);
1344             &define_variable ('am__depfiles_maybe', 'depfiles', INTERNAL);
1345
1346             require_conf_file ("$am_file.am", FOREIGN, 'depcomp');
1347
1348             my @deplist = sort keys %dep_files;
1349             # Generate each `include' individually.  Irix 6 make will
1350             # not properly include several files resulting from a
1351             # variable expansion; generating many separate includes
1352             # seems safest.
1353             $output_rules .= "\n";
1354             foreach my $iter (@deplist)
1355             {
1356                 $output_rules .= (subst ('AMDEP_TRUE')
1357                                   . subst ('am__include')
1358                                   . ' '
1359                                   . subst ('am__quote')
1360                                   . $iter
1361                                   . subst ('am__quote')
1362                                   . "\n");
1363             }
1364
1365             # Compute the set of directories to remove in distclean-depend.
1366             my @depdirs = uniq (map { dirname ($_) } @deplist);
1367             $output_rules .= &file_contents ('depend',
1368                                              new Automake::Location,
1369                                              DEPDIRS => "@depdirs");
1370         }
1371     }
1372     else
1373     {
1374         &define_variable ('depcomp', '', INTERNAL);
1375         &define_variable ('am__depfiles_maybe', '', INTERNAL);
1376     }
1377
1378     my %done;
1379
1380     # Is the C linker needed?
1381     my $needs_c = 0;
1382     foreach my $ext (sort keys %extension_seen)
1383     {
1384         next unless $extension_map{$ext};
1385
1386         my $lang = $languages{$extension_map{$ext}};
1387
1388         my $rule_file = $lang->rule_file || 'depend2';
1389
1390         # Get information on $LANG.
1391         my $pfx = $lang->autodep;
1392         my $fpfx = ($pfx eq '') ? 'CC' : $pfx;
1393
1394         my ($AMDEP, $FASTDEP) =
1395           (option 'no-dependencies' || $lang->autodep eq 'no')
1396           ? ('FALSE', 'FALSE') : ('AMDEP', "am__fastdep$fpfx");
1397
1398         my $verbose = verbose_flag ($lang->ccer || 'GEN');
1399         my $verbose_nodep = ($AMDEP eq 'FALSE')
1400           ? $verbose : verbose_nodep_flag ($lang->ccer || 'GEN');
1401         my $silent = silent_flag ();
1402
1403         my %transform = ('EXT'     => $ext,
1404                          'PFX'     => $pfx,
1405                          'FPFX'    => $fpfx,
1406                          'AMDEP'   => $AMDEP,
1407                          'FASTDEP' => $FASTDEP,
1408                          '-c'      => $lang->compile_flag || '',
1409                          # These are not used, but they need to be defined
1410                          # so &transform do not complain.
1411                          SUBDIROBJ     => 0,
1412                          'DERIVED-EXT' => 'BUG',
1413                          DIST_SOURCE   => 1,
1414                          VERBOSE   => $verbose,
1415                          'VERBOSE-NODEP' => $verbose_nodep,
1416                          SILENT    => $silent,
1417                         );
1418
1419         # Generate the appropriate rules for this extension.
1420         if (((! option 'no-dependencies') && $lang->autodep ne 'no')
1421             || defined $lang->compile)
1422         {
1423             # Some C compilers don't support -c -o.  Use it only if really
1424             # needed.
1425             my $output_flag = $lang->output_flag || '';
1426             $output_flag = '-o'
1427               if (! $output_flag
1428                   && $lang->name eq 'c'
1429                   && option 'subdir-objects');
1430
1431             # Compute a possible derived extension.
1432             # This is not used by depend2.am.
1433             my $der_ext = (&{$lang->output_extensions} ($ext))[0];
1434
1435             # When we output an inference rule like `.c.o:' we
1436             # have two cases to consider: either subdir-objects
1437             # is used, or it is not.
1438             #
1439             # In the latter case the rule is used to build objects
1440             # in the current directory, and dependencies always
1441             # go into `./$(DEPDIR)/'.  We can hard-code this value.
1442             #
1443             # In the former case the rule can be used to build
1444             # objects in sub-directories too.  Dependencies should
1445             # go into the appropriate sub-directories, e.g.,
1446             # `sub/$(DEPDIR)/'.  The value of this directory
1447             # needs to be computed on-the-fly.
1448             #
1449             # DEPBASE holds the name of this directory, plus the
1450             # basename part of the object file (extensions Po, TPo,
1451             # Plo, TPlo will be added later as appropriate).  It is
1452             # either hardcoded, or a shell variable (`$depbase') that
1453             # will be computed by the rule.
1454             my $depbase =
1455               option ('subdir-objects') ? '$$depbase' : '$(DEPDIR)/$*';
1456             $output_rules .=
1457               file_contents ($rule_file,
1458                              new Automake::Location,
1459                              %transform,
1460                              GENERIC   => 1,
1461
1462                              'DERIVED-EXT' => $der_ext,
1463
1464                              DEPBASE   => $depbase,
1465                              BASE      => '$*',
1466                              SOURCE    => '$<',
1467                              SOURCEFLAG => $sourceflags{$ext} || '',
1468                              OBJ       => '$@',
1469                              OBJOBJ    => '$@',
1470                              LTOBJ     => '$@',
1471
1472                              COMPILE   => '$(' . $lang->compiler . ')',
1473                              LTCOMPILE => '$(LT' . $lang->compiler . ')',
1474                              -o        => $output_flag,
1475                              SUBDIROBJ => !! option 'subdir-objects');
1476         }
1477
1478         # Now include code for each specially handled object with this
1479         # language.
1480         my %seen_files = ();
1481         foreach my $file (@{$lang_specific_files{$lang->name}})
1482         {
1483             my ($derived, $source, $obj, $myext, $srcext, %file_transform) = @$file;
1484
1485             # We might see a given object twice, for instance if it is
1486             # used under different conditions.
1487             next if defined $seen_files{$obj};
1488             $seen_files{$obj} = 1;
1489
1490             prog_error ("found " . $lang->name .
1491                         " in handle_languages, but compiler not defined")
1492               unless defined $lang->compile;
1493
1494             my $obj_compile = $lang->compile;
1495
1496             # Rewrite each occurrence of `AM_$flag' in the compile
1497             # rule into `${derived}_$flag' if it exists.
1498             for my $flag (@{$lang->flags})
1499               {
1500                 my $val = "${derived}_$flag";
1501                 $obj_compile =~ s/\(AM_$flag\)/\($val\)/
1502                   if set_seen ($val);
1503               }
1504
1505             my $libtool_tag = '';
1506             if ($lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag})
1507               {
1508                 $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
1509               }
1510
1511             my $ptltflags = "${derived}_LIBTOOLFLAGS";
1512             $ptltflags = 'AM_LIBTOOLFLAGS' unless set_seen $ptltflags;
1513
1514             my $ltverbose = define_verbose_libtool ();
1515             my $obj_ltcompile =
1516               "\$(LIBTOOL) $ltverbose $libtool_tag\$($ptltflags) \$(LIBTOOLFLAGS) "
1517               . "--mode=compile $obj_compile";
1518
1519             # We _need_ `-o' for per object rules.
1520             my $output_flag = $lang->output_flag || '-o';
1521
1522             my $depbase = dirname ($obj);
1523             $depbase = ''
1524                 if $depbase eq '.';
1525             $depbase .= '/'
1526                 unless $depbase eq '';
1527             $depbase .= '$(DEPDIR)/' . basename ($obj);
1528
1529             # Support for deansified files in subdirectories is ugly
1530             # enough to deserve an explanation.
1531             #
1532             # A Note about normal ansi2knr processing first.  On
1533             #
1534             #   AUTOMAKE_OPTIONS = ansi2knr
1535             #   bin_PROGRAMS = foo
1536             #   foo_SOURCES = foo.c
1537             #
1538             # we generate rules similar to:
1539             #
1540             #   foo: foo$U.o; link ...
1541             #   foo$U.o: foo$U.c; compile ...
1542             #   foo_.c: foo.c; ansi2knr ...
1543             #
1544             # this is fairly compact, and will call ansi2knr depending
1545             # on the value of $U (`' or `_').
1546             #
1547             # It's harder with subdir sources. On
1548             #
1549             #   AUTOMAKE_OPTIONS = ansi2knr
1550             #   bin_PROGRAMS = foo
1551             #   foo_SOURCES = sub/foo.c
1552             #
1553             # we have to create foo_.c in the current directory.
1554             # (Unless the user asks 'subdir-objects'.)  This is important
1555             # in case the same file (`foo.c') is compiled from other
1556             # directories with different cpp options: foo_.c would
1557             # be preprocessed for only one set of options if it were
1558             # put in the subdirectory.
1559             #
1560             # Because foo$U.o must be built from either foo_.c or
1561             # sub/foo.c we can't be as concise as in the first example.
1562             # Instead we output
1563             #
1564             #   foo: foo$U.o; link ...
1565             #   foo_.o: foo_.c; compile ...
1566             #   foo.o: sub/foo.c; compile ...
1567             #   foo_.c: foo.c; ansi2knr ...
1568             #
1569             # This is why we'll now transform $rule_file twice
1570             # if we detect this case.
1571             # A first time we output the compile rule with `$U'
1572             # replaced by `_' and the source directory removed,
1573             # and another time we simply remove `$U'.
1574             #
1575             # Note that at this point $source (as computed by
1576             # &handle_single_transform) is `sub/foo$U.c'.
1577             # This can be confusing: it can be used as-is when
1578             # subdir-objects is set, otherwise you have to know
1579             # it really means `foo_.c' or `sub/foo.c'.
1580             my $objdir = dirname ($obj);
1581             my $srcdir = dirname ($source);
1582             if ($lang->ansi && $obj =~ /\$U/)
1583               {
1584                 prog_error "`$obj' contains \$U, but `$source' doesn't"
1585                   if $source !~ /\$U/;
1586
1587                 (my $source_ = $source) =~ s/\$U/_/g;
1588                 # Output an additional rule if _.c and .c are not in
1589                 # the same directory.  (_.c is always in $objdir.)
1590                 if ($objdir ne $srcdir)
1591                   {
1592                     (my $obj_ = $obj) =~ s/\$U/_/g;
1593                     (my $depbase_ = $depbase) =~ s/\$U/_/g;
1594                     $source_ = basename ($source_);
1595
1596                     $output_rules .=
1597                       file_contents ($rule_file,
1598                                      new Automake::Location,
1599                                      %transform,
1600                                      GENERIC   => 0,
1601
1602                                      DEPBASE   => $depbase_,
1603                                      BASE      => $obj_,
1604                                      SOURCE    => $source_,
1605                                      SOURCEFLAG => $sourceflags{$srcext} || '',
1606                                      OBJ       => "$obj_$myext",
1607                                      OBJOBJ    => "$obj_.obj",
1608                                      LTOBJ     => "$obj_.lo",
1609
1610                                      COMPILE   => $obj_compile,
1611                                      LTCOMPILE => $obj_ltcompile,
1612                                      -o        => $output_flag,
1613                                      %file_transform);
1614                     $obj =~ s/\$U//g;
1615                     $depbase =~ s/\$U//g;
1616                     $source =~ s/\$U//g;
1617                   }
1618               }
1619
1620             $output_rules .=
1621               file_contents ($rule_file,
1622                              new Automake::Location,
1623                              %transform,
1624                              GENERIC   => 0,
1625
1626                              DEPBASE   => $depbase,
1627                              BASE      => $obj,
1628                              SOURCE    => $source,
1629                              SOURCEFLAG => $sourceflags{$srcext} || '',
1630                              # Use $myext and not `.o' here, in case
1631                              # we are actually building a new source
1632                              # file -- e.g. via yacc.
1633                              OBJ       => "$obj$myext",
1634                              OBJOBJ    => "$obj.obj",
1635                              LTOBJ     => "$obj.lo",
1636
1637                              VERBOSE   => $verbose,
1638                              'VERBOSE-NODEP'  => $verbose_nodep,
1639                              SILENT    => $silent,
1640                              COMPILE   => $obj_compile,
1641                              LTCOMPILE => $obj_ltcompile,
1642                              -o        => $output_flag,
1643                              %file_transform);
1644         }
1645
1646         # The rest of the loop is done once per language.
1647         next if defined $done{$lang};
1648         $done{$lang} = 1;
1649
1650         # Load the language dependent Makefile chunks.
1651         my %lang = map { uc ($_) => 0 } keys %languages;
1652         $lang{uc ($lang->name)} = 1;
1653         $output_rules .= file_contents ('lang-compile',
1654                                         new Automake::Location,
1655                                         %transform, %lang);
1656
1657         # If the source to a program consists entirely of code from a
1658         # `pure' language, for instance C++ or Fortran 77, then we
1659         # don't need the C compiler code.  However if we run into
1660         # something unusual then we do generate the C code.  There are
1661         # probably corner cases here that do not work properly.
1662         # People linking Java code to Fortran code deserve pain.
1663         $needs_c ||= ! $lang->pure;
1664
1665         define_compiler_variable ($lang)
1666           if ($lang->compile);
1667
1668         define_linker_variable ($lang)
1669           if ($lang->link);
1670
1671         require_variables ("$am_file.am", $lang->Name . " source seen",
1672                            TRUE, @{$lang->config_vars});
1673
1674         # Call the finisher.
1675         $lang->finish;
1676
1677         # Flags listed in `->flags' are user variables (per GNU Standards),
1678         # they should not be overridden in the Makefile...
1679         my @dont_override = @{$lang->flags};
1680         # ... and so is LDFLAGS.
1681         push @dont_override, 'LDFLAGS' if $lang->link;
1682
1683         check_user_variables @dont_override;
1684     }
1685
1686     # If the project is entirely C++ or entirely Fortran 77 (i.e., 1
1687     # suffix rule was learned), don't bother with the C stuff.  But if
1688     # anything else creeps in, then use it.
1689     $needs_c = 1
1690       if $need_link || suffix_rules_count > 1;
1691
1692     if ($needs_c)
1693       {
1694         &define_compiler_variable ($languages{'c'})
1695           unless defined $done{$languages{'c'}};
1696         define_linker_variable ($languages{'c'});
1697       }
1698
1699     # Always provide the user with `AM_V_GEN' for `silent-rules' mode.
1700     define_verbose_tagvar ('GEN');
1701 }
1702
1703
1704 # append_exeext { PREDICATE } $MACRO
1705 # ----------------------------------
1706 # Append $(EXEEXT) to each filename in $F appearing in the Makefile
1707 # variable $MACRO if &PREDICATE($F) is true.  @substitutions@ are
1708 # ignored.
1709 #
1710 # This is typically used on all filenames of *_PROGRAMS, and filenames
1711 # of TESTS that are programs.
1712 sub append_exeext (&$)
1713 {
1714   my ($pred, $macro) = @_;
1715
1716   transform_variable_recursively
1717     ($macro, $macro, 'am__EXEEXT', 0, INTERNAL,
1718      sub {
1719        my ($subvar, $val, $cond, $full_cond) = @_;
1720        # Append $(EXEEXT) unless the user did it already, or it's a
1721        # @substitution@.
1722        $val .= '$(EXEEXT)'
1723          if $val !~ /(?:\$\(EXEEXT\)$|^[@]\w+[@]$)/ && &$pred ($val);
1724        return $val;
1725      });
1726 }
1727
1728
1729 # Check to make sure a source defined in LIBOBJS is not explicitly
1730 # mentioned.  This is a separate function (as opposed to being inlined
1731 # in handle_source_transform) because it isn't always appropriate to
1732 # do this check.
1733 sub check_libobjs_sources
1734 {
1735   my ($one_file, $unxformed) = @_;
1736
1737   foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1738                       'dist_EXTRA_', 'nodist_EXTRA_')
1739     {
1740       my @files;
1741       my $varname = $prefix . $one_file . '_SOURCES';
1742       my $var = var ($varname);
1743       if ($var)
1744         {
1745           @files = $var->value_as_list_recursive;
1746         }
1747       elsif ($prefix eq '')
1748         {
1749           @files = ($unxformed . '.c');
1750         }
1751       else
1752         {
1753           next;
1754         }
1755
1756       foreach my $file (@files)
1757         {
1758           err_var ($prefix . $one_file . '_SOURCES',
1759                    "automatically discovered file `$file' should not" .
1760                    " be explicitly mentioned")
1761             if defined $libsources{$file};
1762         }
1763     }
1764 }
1765
1766
1767 # @OBJECTS
1768 # handle_single_transform ($VAR, $TOPPARENT, $DERIVED, $OBJ, $FILE, %TRANSFORM)
1769 # -----------------------------------------------------------------------------
1770 # Does much of the actual work for handle_source_transform.
1771 # Arguments are:
1772 #   $VAR is the name of the variable that the source filenames come from
1773 #   $TOPPARENT is the name of the _SOURCES variable which is being processed
1774 #   $DERIVED is the name of resulting executable or library
1775 #   $OBJ is the object extension (e.g., `$U.lo')
1776 #   $FILE the source file to transform
1777 #   %TRANSFORM contains extras arguments to pass to file_contents
1778 #     when producing explicit rules
1779 # Result is a list of the names of objects
1780 # %linkers_used will be updated with any linkers needed
1781 sub handle_single_transform ($$$$$%)
1782 {
1783     my ($var, $topparent, $derived, $obj, $_file, %transform) = @_;
1784     my @files = ($_file);
1785     my @result = ();
1786     my $nonansi_obj = $obj;
1787     $nonansi_obj =~ s/\$U//g;
1788
1789     # Turn sources into objects.  We use a while loop like this
1790     # because we might add to @files in the loop.
1791     while (scalar @files > 0)
1792     {
1793         $_ = shift @files;
1794
1795         # Configure substitutions in _SOURCES variables are errors.
1796         if (/^\@.*\@$/)
1797         {
1798           my $parent_msg = '';
1799           $parent_msg = "\nand is referred to from `$topparent'"
1800             if $topparent ne $var->name;
1801           err_var ($var,
1802                    "`" . $var->name . "' includes configure substitution `$_'"
1803                    . $parent_msg . ";\nconfigure " .
1804                    "substitutions are not allowed in _SOURCES variables");
1805           next;
1806         }
1807
1808         # If the source file is in a subdirectory then the `.o' is put
1809         # into the current directory, unless the subdir-objects option
1810         # is in effect.
1811
1812         # Split file name into base and extension.
1813         next if ! /^(?:(.*)\/)?([^\/]*)($KNOWN_EXTENSIONS_PATTERN)$/;
1814         my $full = $_;
1815         my $directory = $1 || '';
1816         my $base = $2;
1817         my $extension = $3;
1818
1819         # We must generate a rule for the object if it requires its own flags.
1820         my $renamed = 0;
1821         my ($linker, $object);
1822
1823         # This records whether we've seen a derived source file (e.g.
1824         # yacc output).
1825         my $derived_source = 0;
1826
1827         # This holds the `aggregate context' of the file we are
1828         # currently examining.  If the file is compiled with
1829         # per-object flags, then it will be the name of the object.
1830         # Otherwise it will be `AM'.  This is used by the target hook
1831         # language function.
1832         my $aggregate = 'AM';
1833
1834         $extension = &derive_suffix ($extension, $nonansi_obj);
1835         my $lang;
1836         if ($extension_map{$extension} &&
1837             ($lang = $languages{$extension_map{$extension}}))
1838         {
1839             # Found the language, so see what it says.
1840             &saw_extension ($extension);
1841
1842             # Do we have per-executable flags for this executable?
1843             my $have_per_exec_flags = 0;
1844             my @peflags = @{$lang->flags};
1845             push @peflags, 'LIBTOOLFLAGS' if $nonansi_obj eq '.lo';
1846             foreach my $flag (@peflags)
1847               {
1848                 if (set_seen ("${derived}_$flag"))
1849                   {
1850                     $have_per_exec_flags = 1;
1851                     last;
1852                   }
1853               }
1854
1855             # Note: computed subr call.  The language rewrite function
1856             # should return one of the LANG_* constants.  It could
1857             # also return a list whose first value is such a constant
1858             # and whose second value is a new source extension which
1859             # should be applied.  This means this particular language
1860             # generates another source file which we must then process
1861             # further.
1862             my $subr = \&{'lang_' . $lang->name . '_rewrite'};
1863             my ($r, $source_extension)
1864                 = &$subr ($directory, $base, $extension,
1865                           $nonansi_obj, $have_per_exec_flags, $var);
1866             # Skip this entry if we were asked not to process it.
1867             next if $r == LANG_IGNORE;
1868
1869             # Now extract linker and other info.
1870             $linker = $lang->linker;
1871
1872             my $this_obj_ext;
1873             if (defined $source_extension)
1874             {
1875                 $this_obj_ext = $source_extension;
1876                 $derived_source = 1;
1877             }
1878             elsif ($lang->ansi)
1879             {
1880                 $this_obj_ext = $obj;
1881             }
1882             else
1883             {
1884                 $this_obj_ext = $nonansi_obj;
1885             }
1886             $object = $base . $this_obj_ext;
1887
1888             if ($have_per_exec_flags)
1889             {
1890                 # We have a per-executable flag in effect for this
1891                 # object.  In this case we rewrite the object's
1892                 # name to ensure it is unique.
1893
1894                 # We choose the name `DERIVED_OBJECT' to ensure
1895                 # (1) uniqueness, and (2) continuity between
1896                 # invocations.  However, this will result in a
1897                 # name that is too long for losing systems, in
1898                 # some situations.  So we provide _SHORTNAME to
1899                 # override.
1900
1901                 my $dname = $derived;
1902                 my $var = var ($derived . '_SHORTNAME');
1903                 if ($var)
1904                 {
1905                     # FIXME: should use the same Condition as
1906                     # the _SOURCES variable.  But this is really
1907                     # silly overkill -- nobody should have
1908                     # conditional shortnames.
1909                     $dname = $var->variable_value;
1910                 }
1911                 $object = $dname . '-' . $object;
1912
1913                 prog_error ($lang->name . " flags defined without compiler")
1914                   if ! defined $lang->compile;
1915
1916                 $renamed = 1;
1917             }
1918
1919             # If rewrite said it was ok, put the object into a
1920             # subdir.
1921             if ($r == LANG_SUBDIR && $directory ne '')
1922             {
1923                 $object = $directory . '/' . $object;
1924             }
1925
1926             # If the object file has been renamed (because per-target
1927             # flags are used) we cannot compile the file with an
1928             # inference rule: we need an explicit rule.
1929             #
1930             # If the source is in a subdirectory and the object is in
1931             # the current directory, we also need an explicit rule.
1932             #
1933             # If both source and object files are in a subdirectory
1934             # (this happens when the subdir-objects option is used),
1935             # then the inference will work.
1936             #
1937             # The latter case deserves a historical note.  When the
1938             # subdir-objects option was added on 1999-04-11 it was
1939             # thought that inferences rules would work for
1940             # subdirectory objects too.  Later, on 1999-11-22,
1941             # automake was changed to output explicit rules even for
1942             # subdir-objects.  Nobody remembers why, but this occurred
1943             # soon after the merge of the user-dep-gen-branch so it
1944             # might be related.  In late 2003 people complained about
1945             # the size of the generated Makefile.ins (libgcj, with
1946             # 2200+ subdir objects was reported to have a 9MB
1947             # Makefile), so we now rely on inference rules again.
1948             # Maybe we'll run across the same issue as in the past,
1949             # but at least this time we can document it.  However since
1950             # dependency tracking has evolved it is possible that
1951             # our old problem no longer exists.
1952             # Using inference rules for subdir-objects has been tested
1953             # with GNU make, Solaris make, Ultrix make, BSD make,
1954             # HP-UX make, and OSF1 make successfully.
1955             if ($renamed
1956                 || ($directory ne '' && ! option 'subdir-objects')
1957                 # We must also use specific rules for a nodist_ source
1958                 # if its language requests it.
1959                 || ($lang->nodist_specific && ! $transform{'DIST_SOURCE'}))
1960             {
1961                 my $obj_sans_ext = substr ($object, 0,
1962                                            - length ($this_obj_ext));
1963                 my $full_ansi;
1964                 if ($directory ne '')
1965                   {
1966                         $full_ansi = $directory . '/' . $base . $extension;
1967                   }
1968                 else
1969                   {
1970                         $full_ansi = $base . $extension;
1971                   }
1972
1973                 if ($lang->ansi && option 'ansi2knr')
1974                   {
1975                     $full_ansi =~ s/$KNOWN_EXTENSIONS_PATTERN$/\$U$&/;
1976                     $obj_sans_ext .= '$U';
1977                   }
1978
1979                 my @specifics = ($full_ansi, $obj_sans_ext,
1980                                  # Only use $this_obj_ext in the derived
1981                                  # source case because in the other case we
1982                                  # *don't* want $(OBJEXT) to appear here.
1983                                  ($derived_source ? $this_obj_ext : '.o'),
1984                                  $extension);
1985
1986                 # If we renamed the object then we want to use the
1987                 # per-executable flag name.  But if this is simply a
1988                 # subdir build then we still want to use the AM_ flag
1989                 # name.
1990                 if ($renamed)
1991                   {
1992                     unshift @specifics, $derived;
1993                     $aggregate = $derived;
1994                   }
1995                 else
1996                   {
1997                     unshift @specifics, 'AM';
1998                   }
1999
2000                 # Each item on this list is a reference to a list consisting
2001                 # of four values followed by additional transform flags for
2002                 # file_contents.  The four values are the derived flag prefix
2003                 # (e.g. for `foo_CFLAGS', it is `foo'), the name of the
2004                 # source file, the base name of the output file, and
2005                 # the extension for the object file.
2006                 push (@{$lang_specific_files{$lang->name}},
2007                       [@specifics, %transform]);
2008             }
2009         }
2010         elsif ($extension eq $nonansi_obj)
2011         {
2012             # This is probably the result of a direct suffix rule.
2013             # In this case we just accept the rewrite.
2014             $object = "$base$extension";
2015             $object = "$directory/$object" if $directory ne '';
2016             $linker = '';
2017         }
2018         else
2019         {
2020             # No error message here.  Used to have one, but it was
2021             # very unpopular.
2022             # FIXME: we could potentially do more processing here,
2023             # perhaps treating the new extension as though it were a
2024             # new source extension (as above).  This would require
2025             # more restructuring than is appropriate right now.
2026             next;
2027         }
2028
2029         err_am "object `$object' created by `$full' and `$object_map{$object}'"
2030           if (defined $object_map{$object}
2031               && $object_map{$object} ne $full);
2032
2033         my $comp_val = (($object =~ /\.lo$/)
2034                         ? COMPILE_LIBTOOL : COMPILE_ORDINARY);
2035         (my $comp_obj = $object) =~ s/\.lo$/.\$(OBJEXT)/;
2036         if (defined $object_compilation_map{$comp_obj}
2037             && $object_compilation_map{$comp_obj} != 0
2038             # Only see the error once.
2039             && ($object_compilation_map{$comp_obj}
2040                 != (COMPILE_LIBTOOL | COMPILE_ORDINARY))
2041             && $object_compilation_map{$comp_obj} != $comp_val)
2042           {
2043             err_am "object `$comp_obj' created both with libtool and without";
2044           }
2045         $object_compilation_map{$comp_obj} |= $comp_val;
2046
2047         if (defined $lang)
2048         {
2049             # Let the language do some special magic if required.
2050             $lang->target_hook ($aggregate, $object, $full, %transform);
2051         }
2052
2053         if ($derived_source)
2054           {
2055             prog_error ($lang->name . " has automatic dependency tracking")
2056               if $lang->autodep ne 'no';
2057             # Make sure this new source file is handled next.  That will
2058             # make it appear to be at the right place in the list.
2059             unshift (@files, $object);
2060             # Distribute derived sources unless the source they are
2061             # derived from is not.
2062             &push_dist_common ($object)
2063               unless ($topparent =~ /^(?:nobase_)?nodist_/);
2064             next;
2065           }
2066
2067         $linkers_used{$linker} = 1;
2068
2069         push (@result, $object);
2070
2071         if (! defined $object_map{$object})
2072         {
2073             my @dep_list = ();
2074             $object_map{$object} = $full;
2075
2076             # If resulting object is in subdir, we need to make
2077             # sure the subdir exists at build time.
2078             if ($object =~ /\//)
2079             {
2080                 # FIXME: check that $DIRECTORY is somewhere in the
2081                 # project
2082
2083                 # For Java, the way we're handling it right now, a
2084                 # `..' component doesn't make sense.
2085                 if ($lang && $lang->name eq 'java' && $object =~ /(\/|^)\.\.\//)
2086                   {
2087                     err_am "`$full' should not contain a `..' component";
2088                   }
2089
2090                 # Make sure object is removed by `make mostlyclean'.
2091                 $compile_clean_files{$object} = MOSTLY_CLEAN;
2092                 # If we have a libtool object then we also must remove
2093                 # the ordinary .o.
2094                 if ($object =~ /\.lo$/)
2095                 {
2096                     (my $xobj = $object) =~ s,lo$,\$(OBJEXT),;
2097                     $compile_clean_files{$xobj} = MOSTLY_CLEAN;
2098
2099                     # Remove any libtool object in this directory.
2100                     $libtool_clean_directories{$directory} = 1;
2101                 }
2102
2103                 push (@dep_list, require_build_directory ($directory));
2104
2105                 # If we're generating dependencies, we also want
2106                 # to make sure that the appropriate subdir of the
2107                 # .deps directory is created.
2108                 push (@dep_list,
2109                       require_build_directory ($directory . '/$(DEPDIR)'))
2110                   unless option 'no-dependencies';
2111             }
2112
2113             &pretty_print_rule ($object . ':', "\t", @dep_list)
2114                 if scalar @dep_list > 0;
2115         }
2116
2117         # Transform .o or $o file into .P file (for automatic
2118         # dependency code).
2119         # Properly flatten multiple adjacent slashes, as Solaris 10 make
2120         # might fail over them in an include statement.
2121         # Leading double slashes may be special, as per Posix, so deal
2122         # with them carefully.
2123         if ($lang && $lang->autodep ne 'no')
2124         {
2125             my $depfile = $object;
2126             $depfile =~ s/\.([^.]*)$/.P$1/;
2127             $depfile =~ s/\$\(OBJEXT\)$/o/;
2128             my $maybe_extra_leading_slash = '';
2129             $maybe_extra_leading_slash = '/' if $depfile =~ m,^//[^/],;
2130             $depfile =~ s,/+,/,g;
2131             my $basename = basename ($depfile);
2132             # This might make $dirname empty, but we account for that below.
2133             (my $dirname = dirname ($depfile)) =~ s/\/*$//;
2134             $dirname = $maybe_extra_leading_slash . $dirname;
2135             $dep_files{$dirname . '/$(DEPDIR)/' . $basename} = 1;
2136         }
2137     }
2138
2139     return @result;
2140 }
2141
2142
2143 # $LINKER
2144 # define_objects_from_sources ($VAR, $OBJVAR, $NODEFINE, $ONE_FILE,
2145 #                              $OBJ, $PARENT, $TOPPARENT, $WHERE, %TRANSFORM)
2146 # ---------------------------------------------------------------------------
2147 # Define an _OBJECTS variable for a _SOURCES variable (or subvariable)
2148 #
2149 # Arguments are:
2150 #   $VAR is the name of the _SOURCES variable
2151 #   $OBJVAR is the name of the _OBJECTS variable if known (otherwise
2152 #     it will be generated and returned).
2153 #   $NODEFINE is a boolean: if true, $OBJVAR will not be defined (but
2154 #     work done to determine the linker will be).
2155 #   $ONE_FILE is the canonical (transformed) name of object to build
2156 #   $OBJ is the object extension (i.e. either `.o' or `.lo').
2157 #   $TOPPARENT is the _SOURCES variable being processed.
2158 #   $WHERE context into which this definition is done
2159 #   %TRANSFORM extra arguments to pass to file_contents when producing
2160 #     rules
2161 #
2162 # Result is a pair ($LINKER, $OBJVAR):
2163 #    $LINKER is a boolean, true if a linker is needed to deal with the objects
2164 sub define_objects_from_sources ($$$$$$$%)
2165 {
2166   my ($var, $objvar, $nodefine, $one_file,
2167       $obj, $topparent, $where, %transform) = @_;
2168
2169   my $needlinker = "";
2170
2171   transform_variable_recursively
2172     ($var, $objvar, 'am__objects', $nodefine, $where,
2173      # The transform code to run on each filename.
2174      sub {
2175        my ($subvar, $val, $cond, $full_cond) = @_;
2176        my @trans = handle_single_transform ($subvar, $topparent,
2177                                             $one_file, $obj, $val,
2178                                             %transform);
2179        $needlinker = "true" if @trans;
2180        return @trans;
2181      });
2182
2183   return $needlinker;
2184 }
2185
2186
2187 # handle_source_transform ($CANON_TARGET, $TARGET, $OBJEXT, $WHERE, %TRANSFORM)
2188 # -----------------------------------------------------------------------------
2189 # Handle SOURCE->OBJECT transform for one program or library.
2190 # Arguments are:
2191 #   canonical (transformed) name of target to build
2192 #   actual target of object to build
2193 #   object extension (i.e., either `.o' or `$o')
2194 #   location of the source variable
2195 #   extra arguments to pass to file_contents when producing rules
2196 # Return the name of the linker variable that must be used.
2197 # Empty return means just use `LINK'.
2198 sub handle_source_transform ($$$$%)
2199 {
2200     # one_file is canonical name.  unxformed is given name.  obj is
2201     # object extension.
2202     my ($one_file, $unxformed, $obj, $where, %transform) = @_;
2203
2204     my $linker = '';
2205
2206     # No point in continuing if _OBJECTS is defined.
2207     return if reject_var ($one_file . '_OBJECTS',
2208                           $one_file . '_OBJECTS should not be defined');
2209
2210     my %used_pfx = ();
2211     my $needlinker;
2212     %linkers_used = ();
2213     foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
2214                         'dist_EXTRA_', 'nodist_EXTRA_')
2215     {
2216         my $varname = $prefix . $one_file . "_SOURCES";
2217         my $var = var $varname;
2218         next unless $var;
2219
2220         # We are going to define _OBJECTS variables using the prefix.
2221         # Then we glom them all together.  So we can't use the null
2222         # prefix here as we need it later.
2223         my $xpfx = ($prefix eq '') ? 'am_' : $prefix;
2224
2225         # Keep track of which prefixes we saw.
2226         $used_pfx{$xpfx} = 1
2227           unless $prefix =~ /EXTRA_/;
2228
2229         push @sources, "\$($varname)";
2230         push @dist_sources, shadow_unconditionally ($varname, $where)
2231           unless (option ('no-dist') || $prefix =~ /^nodist_/);
2232
2233         $needlinker |=
2234             define_objects_from_sources ($varname,
2235                                          $xpfx . $one_file . '_OBJECTS',
2236                                          $prefix =~ /EXTRA_/,
2237                                          $one_file, $obj, $varname, $where,
2238                                          DIST_SOURCE => ($prefix !~ /^nodist_/),
2239                                          %transform);
2240     }
2241     if ($needlinker)
2242     {
2243         $linker ||= &resolve_linker (%linkers_used);
2244     }
2245
2246     my @keys = sort keys %used_pfx;
2247     if (scalar @keys == 0)
2248     {
2249         # The default source for libfoo.la is libfoo.c, but for
2250         # backward compatibility we first look at libfoo_la.c,
2251         # if no default source suffix is given.
2252         my $old_default_source = "$one_file.c";
2253         my $ext_var = var ('AM_DEFAULT_SOURCE_EXT');
2254         my $default_source_ext = $ext_var ? variable_value ($ext_var) : '.c';
2255         msg_var ('unsupported', $ext_var, $ext_var->name . " can assume at most one value")
2256           if $default_source_ext =~ /[\t ]/;
2257         (my $default_source = $unxformed) =~ s,(\.[^./\\]*)?$,$default_source_ext,;
2258         if ($old_default_source ne $default_source
2259             && !$ext_var
2260             && (rule $old_default_source
2261                 || rule '$(srcdir)/' . $old_default_source
2262                 || rule '${srcdir}/' . $old_default_source
2263                 || -f $old_default_source))
2264           {
2265             my $loc = $where->clone;
2266             $loc->pop_context;
2267             msg ('obsolete', $loc,
2268                  "the default source for `$unxformed' has been changed "
2269                  . "to `$default_source'.\n(Using `$old_default_source' for "
2270                  . "backward compatibility.)");
2271             $default_source = $old_default_source;
2272           }
2273         # If a rule exists to build this source with a $(srcdir)
2274         # prefix, use that prefix in our variables too.  This is for
2275         # the sake of BSD Make.
2276         if (rule '$(srcdir)/' . $default_source
2277             || rule '${srcdir}/' . $default_source)
2278           {
2279             $default_source = '$(srcdir)/' . $default_source;
2280           }
2281
2282         &define_variable ($one_file . "_SOURCES", $default_source, $where);
2283         push (@sources, $default_source);
2284         push (@dist_sources, $default_source);
2285
2286         %linkers_used = ();
2287         my (@result) =
2288           handle_single_transform ($one_file . '_SOURCES',
2289                                    $one_file . '_SOURCES',
2290                                    $one_file, $obj,
2291                                    $default_source, %transform);
2292         $linker ||= &resolve_linker (%linkers_used);
2293         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @result);
2294     }
2295     else
2296     {
2297         @keys = map { '$(' . $_ . $one_file . '_OBJECTS)' } @keys;
2298         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @keys);
2299     }
2300
2301     # If we want to use `LINK' we must make sure it is defined.
2302     if ($linker eq '')
2303     {
2304         $need_link = 1;
2305     }
2306
2307     return $linker;
2308 }
2309
2310
2311 # handle_lib_objects ($XNAME, $VAR)
2312 # ---------------------------------
2313 # Special-case ALLOCA and LIBOBJS substitutions in _LDADD or _LIBADD variables.
2314 # Also, generate _DEPENDENCIES variable if appropriate.
2315 # Arguments are:
2316 #   transformed name of object being built, or empty string if no object
2317 #   name of _LDADD/_LIBADD-type variable to examine
2318 # Returns 1 if LIBOBJS seen, 0 otherwise.
2319 sub handle_lib_objects
2320 {
2321   my ($xname, $varname) = @_;
2322
2323   my $var = var ($varname);
2324   prog_error "`$varname' undefined"
2325     unless $var;
2326   prog_error "unexpected variable name `$varname'"
2327     unless $varname =~ /^(.*)(?:LIB|LD)ADD$/;
2328   my $prefix = $1 || 'AM_';
2329
2330   my $seen_libobjs = 0;
2331   my $flagvar = 0;
2332
2333   transform_variable_recursively
2334     ($varname, $xname . '_DEPENDENCIES', 'am__DEPENDENCIES',
2335      ! $xname, INTERNAL,
2336      # Transformation function, run on each filename.
2337      sub {
2338        my ($subvar, $val, $cond, $full_cond) = @_;
2339
2340        if ($val =~ /^-/)
2341          {
2342            # Skip -lfoo and -Ldir silently; these are explicitly allowed.
2343            if ($val !~ /^-[lL]/ &&
2344                # Skip -dlopen and -dlpreopen; these are explicitly allowed
2345                # for Libtool libraries or programs.  (Actually we are a bit
2346                # lax here since this code also applies to non-libtool
2347                # libraries or programs, for which -dlopen and -dlopreopen
2348                # are pure nonsense.  Diagnosing this doesn't seem very
2349                # important: the developer will quickly get complaints from
2350                # the linker.)
2351                $val !~ /^-dl(?:pre)?open$/ &&
2352                # Only get this error once.
2353                ! $flagvar)
2354              {
2355                $flagvar = 1;
2356                # FIXME: should display a stack of nested variables
2357                # as context when $var != $subvar.
2358                err_var ($var, "linker flags such as `$val' belong in "
2359                         . "`${prefix}LDFLAGS'");
2360              }
2361            return ();
2362          }
2363        elsif ($val !~ /^\@.*\@$/)
2364          {
2365            # Assume we have a file of some sort, and output it into the
2366            # dependency variable.  Autoconf substitutions are not output;
2367            # rarely is a new dependency substituted into e.g. foo_LDADD
2368            # -- but bad things (e.g. -lX11) are routinely substituted.
2369            # Note that LIBOBJS and ALLOCA are exceptions to this rule,
2370            # and handled specially below.
2371            return $val;
2372          }
2373        elsif ($val =~ /^\@(LT)?LIBOBJS\@$/)
2374          {
2375            handle_LIBOBJS ($subvar, $cond, $1);
2376            $seen_libobjs = 1;
2377            return $val;
2378          }
2379        elsif ($val =~ /^\@(LT)?ALLOCA\@$/)
2380          {
2381            handle_ALLOCA ($subvar, $cond, $1);
2382            return $val;
2383          }
2384        else
2385          {
2386            return ();
2387          }
2388      });
2389
2390   return $seen_libobjs;
2391 }
2392
2393 # handle_LIBOBJS_or_ALLOCA ($VAR)
2394 # -------------------------------
2395 # Definitions common to LIBOBJS and ALLOCA.
2396 # VAR should be one of LIBOBJS, LTLIBOBJS, ALLOCA, or LTALLOCA.
2397 sub handle_LIBOBJS_or_ALLOCA ($)
2398 {
2399   my ($var) = @_;
2400
2401   my $dir = '';
2402
2403   # If LIBOBJS files must be built in another directory we have
2404   # to define LIBOBJDIR and ensure the files get cleaned.
2405   # Otherwise LIBOBJDIR can be left undefined, and the cleaning
2406   # is achieved by `rm -f *.$(OBJEXT)' in compile.am.
2407   if ($config_libobj_dir
2408       && $relative_dir ne $config_libobj_dir)
2409     {
2410       if (option 'subdir-objects')
2411         {
2412           # In the top-level Makefile we do not use $(top_builddir), because
2413           # we are already there, and since the targets are built without
2414           # a $(top_builddir), it helps BSD Make to match them with
2415           # dependencies.
2416           $dir = "$config_libobj_dir/" if $config_libobj_dir ne '.';
2417           $dir = "$topsrcdir/$dir" if $relative_dir ne '.';
2418           define_variable ('LIBOBJDIR', "$dir", INTERNAL);
2419           $clean_files{"\$($var)"} = MOSTLY_CLEAN;
2420           # If LTLIBOBJS is used, we must also clear LIBOBJS (which might
2421           # be created by libtool as a side-effect of creating LTLIBOBJS).
2422           $clean_files{"\$($var)"} = MOSTLY_CLEAN if $var =~ s/^LT//;
2423         }
2424       else
2425         {
2426           error ("`\$($var)' cannot be used outside `$config_libobj_dir' if"
2427                  . " `subdir-objects' is not set");
2428         }
2429     }
2430
2431   return $dir;
2432 }
2433
2434 sub handle_LIBOBJS ($$$)
2435 {
2436   my ($var, $cond, $lt) = @_;
2437   my $myobjext = $lt ? 'lo' : 'o';
2438   $lt ||= '';
2439
2440   $var->requires_variables ("\@${lt}LIBOBJS\@ used", $lt . 'LIBOBJS')
2441     if ! keys %libsources;
2442
2443   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}LIBOBJS";
2444
2445   foreach my $iter (keys %libsources)
2446     {
2447       if ($iter =~ /\.[cly]$/)
2448         {
2449           &saw_extension ($&);
2450           &saw_extension ('.c');
2451         }
2452
2453       if ($iter =~ /\.h$/)
2454         {
2455           require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2456         }
2457       elsif ($iter ne 'alloca.c')
2458         {
2459           my $rewrite = $iter;
2460           $rewrite =~ s/\.c$/.P$myobjext/;
2461           $dep_files{$dir . '$(DEPDIR)/' . $rewrite} = 1;
2462           $rewrite = "^" . quotemeta ($iter) . "\$";
2463           # Only require the file if it is not a built source.
2464           my $bs = var ('BUILT_SOURCES');
2465           if (! $bs || ! grep (/$rewrite/, $bs->value_as_list_recursive))
2466             {
2467               require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2468             }
2469         }
2470     }
2471 }
2472
2473 sub handle_ALLOCA ($$$)
2474 {
2475   my ($var, $cond, $lt) = @_;
2476   my $myobjext = $lt ? 'lo' : 'o';
2477   $lt ||= '';
2478   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}ALLOCA";
2479
2480   $var->requires_variables ("\@${lt}ALLOCA\@ used", $lt . 'ALLOCA');
2481   $dep_files{$dir . '$(DEPDIR)/alloca.P' . $myobjext} = 1;
2482   require_libsource_with_macro ($cond, $var, FOREIGN, 'alloca.c');
2483   &saw_extension ('.c');
2484 }
2485
2486 # Canonicalize the input parameter
2487 sub canonicalize
2488 {
2489     my ($string) = @_;
2490     $string =~ tr/A-Za-z0-9_\@/_/c;
2491     return $string;
2492 }
2493
2494 # Canonicalize a name, and check to make sure the non-canonical name
2495 # is never used.  Returns canonical name.  Arguments are name and a
2496 # list of suffixes to check for.
2497 sub check_canonical_spelling
2498 {
2499   my ($name, @suffixes) = @_;
2500
2501   my $xname = &canonicalize ($name);
2502   if ($xname ne $name)
2503     {
2504       foreach my $xt (@suffixes)
2505         {
2506           reject_var ("$name$xt", "use `$xname$xt', not `$name$xt'");
2507         }
2508     }
2509
2510   return $xname;
2511 }
2512
2513
2514 # handle_compile ()
2515 # -----------------
2516 # Set up the compile suite.
2517 sub handle_compile ()
2518 {
2519     return
2520       unless $get_object_extension_was_run;
2521
2522     # Boilerplate.
2523     my $default_includes = '';
2524     if (! option 'nostdinc')
2525       {
2526         my @incs = ('-I.', subst ('am__isrc'));
2527
2528         my $var = var 'CONFIG_HEADER';
2529         if ($var)
2530           {
2531             foreach my $hdr (split (' ', $var->variable_value))
2532               {
2533                 push @incs, '-I' . dirname ($hdr);
2534               }
2535           }
2536         # We want `-I. -I$(srcdir)', but the latter -I is redundant
2537         # and unaesthetic in non-VPATH builds.  We use `-I.@am__isrc@`
2538         # instead.  It will be replaced by '-I.' or '-I. -I$(srcdir)'.
2539         # Items in CONFIG_HEADER are never in $(srcdir) so it is safe
2540         # to just put @am__isrc@ right after `-I.', without a space.
2541         ($default_includes = ' ' . uniq (@incs)) =~ s/ @/@/;
2542       }
2543
2544     my (@mostly_rms, @dist_rms);
2545     foreach my $item (sort keys %compile_clean_files)
2546     {
2547         if ($compile_clean_files{$item} == MOSTLY_CLEAN)
2548         {
2549             push (@mostly_rms, "\t-rm -f $item");
2550         }
2551         elsif ($compile_clean_files{$item} == DIST_CLEAN)
2552         {
2553             push (@dist_rms, "\t-rm -f $item");
2554         }
2555         else
2556         {
2557           prog_error 'invalid entry in %compile_clean_files';
2558         }
2559     }
2560
2561     my ($coms, $vars, $rules) =
2562       &file_contents_internal (1, "$libdir/am/compile.am",
2563                                new Automake::Location,
2564                                ('DEFAULT_INCLUDES' => $default_includes,
2565                                 'MOSTLYRMS' => join ("\n", @mostly_rms),
2566                                 'DISTRMS' => join ("\n", @dist_rms)));
2567     $output_vars .= $vars;
2568     $output_rules .= "$coms$rules";
2569
2570     # Check for automatic de-ANSI-fication.
2571     if (option 'ansi2knr')
2572       {
2573         my ($ansi2knr_filename, $ansi2knr_where) = @{option 'ansi2knr'};
2574         my $ansi2knr_dir = '';
2575
2576         require_variables ($ansi2knr_where, "option `ansi2knr' is used",
2577                            TRUE, "ANSI2KNR", "U");
2578
2579         # topdir is where ansi2knr should be.
2580         if ($ansi2knr_filename eq 'ansi2knr')
2581           {
2582             # Only require ansi2knr files if they should appear in
2583             # this directory.
2584             require_file ($ansi2knr_where, FOREIGN,
2585                           'ansi2knr.c', 'ansi2knr.1');
2586
2587             # ansi2knr needs to be built before subdirs, so unshift it
2588             # rather then pushing it.
2589             unshift (@all, '$(ANSI2KNR)');
2590           }
2591         else
2592           {
2593             $ansi2knr_dir = dirname ($ansi2knr_filename);
2594           }
2595
2596         $output_rules .= &file_contents ('ansi2knr',
2597                                          new Automake::Location,
2598                                          'ANSI2KNR-DIR' => $ansi2knr_dir);
2599
2600     }
2601 }
2602
2603 # handle_libtool ()
2604 # -----------------
2605 # Handle libtool rules.
2606 sub handle_libtool
2607 {
2608   return unless var ('LIBTOOL');
2609
2610   # Libtool requires some files, but only at top level.
2611   # (Starting with Libtool 2.0 we do not have to bother.  These
2612   # requirements are done with AC_REQUIRE_AUX_FILE.)
2613   require_conf_file_with_macro (TRUE, 'LIBTOOL', FOREIGN, @libtool_files)
2614     if $relative_dir eq '.' && ! $libtool_new_api;
2615
2616   my @libtool_rms;
2617   foreach my $item (sort keys %libtool_clean_directories)
2618     {
2619       my $dir = ($item eq '.') ? '' : "$item/";
2620       # .libs is for Unix, _libs for DOS.
2621       push (@libtool_rms, "\t-rm -rf ${dir}.libs ${dir}_libs");
2622     }
2623
2624   check_user_variables 'LIBTOOLFLAGS';
2625
2626   # Output the libtool compilation rules.
2627   $output_rules .= &file_contents ('libtool',
2628                                    new Automake::Location,
2629                                    LTRMS => join ("\n", @libtool_rms));
2630 }
2631
2632 # handle_programs ()
2633 # ------------------
2634 # Handle C programs.
2635 sub handle_programs
2636 {
2637   my @proglist = &am_install_var ('progs', 'PROGRAMS',
2638                                   'bin', 'sbin', 'libexec', 'pkglib',
2639                                   'noinst', 'check');
2640   return if ! @proglist;
2641
2642   my $seen_global_libobjs =
2643     var ('LDADD') && &handle_lib_objects ('', 'LDADD');
2644
2645   foreach my $pair (@proglist)
2646     {
2647       my ($where, $one_file) = @$pair;
2648
2649       my $seen_libobjs = 0;
2650       my $obj = get_object_extension '.$(OBJEXT)';
2651
2652       $known_programs{$one_file} = $where;
2653
2654       # Canonicalize names and check for misspellings.
2655       my $xname = &check_canonical_spelling ($one_file, '_LDADD', '_LDFLAGS',
2656                                              '_SOURCES', '_OBJECTS',
2657                                              '_DEPENDENCIES');
2658
2659       $where->push_context ("while processing program `$one_file'");
2660       $where->set (INTERNAL->get);
2661
2662       my $linker = &handle_source_transform ($xname, $one_file, $obj, $where,
2663                                              NONLIBTOOL => 1, LIBTOOL => 0);
2664
2665       if (var ($xname . "_LDADD"))
2666         {
2667           $seen_libobjs = &handle_lib_objects ($xname, $xname . '_LDADD');
2668         }
2669       else
2670         {
2671           # User didn't define prog_LDADD override.  So do it.
2672           &define_variable ($xname . '_LDADD', '$(LDADD)', $where);
2673
2674           # This does a bit too much work.  But we need it to
2675           # generate _DEPENDENCIES when appropriate.
2676           if (var ('LDADD'))
2677             {
2678               $seen_libobjs = &handle_lib_objects ($xname, 'LDADD');
2679             }
2680         }
2681
2682       reject_var ($xname . '_LIBADD',
2683                   "use `${xname}_LDADD', not `${xname}_LIBADD'");
2684
2685       set_seen ($xname . '_DEPENDENCIES');
2686       set_seen ('EXTRA_' . $xname . '_DEPENDENCIES');
2687       set_seen ($xname . '_LDFLAGS');
2688
2689       # Determine program to use for link.
2690       my($xlink, $vlink) = &define_per_target_linker_variable ($linker, $xname);
2691       $vlink = verbose_flag ($vlink || 'GEN');
2692
2693       # If the resulting program lies into a subdirectory,
2694       # make sure this directory will exist.
2695       my $dirstamp = require_build_directory_maybe ($one_file);
2696
2697       $libtool_clean_directories{dirname ($one_file)} = 1;
2698
2699       $output_rules .= &file_contents ('program',
2700                                        $where,
2701                                        PROGRAM  => $one_file,
2702                                        XPROGRAM => $xname,
2703                                        XLINK    => $xlink,
2704                                        VERBOSE  => $vlink,
2705                                        DIRSTAMP => $dirstamp,
2706                                        EXEEXT   => '$(EXEEXT)');
2707
2708       if ($seen_libobjs || $seen_global_libobjs)
2709         {
2710           if (var ($xname . '_LDADD'))
2711             {
2712               &check_libobjs_sources ($xname, $xname . '_LDADD');
2713             }
2714           elsif (var ('LDADD'))
2715             {
2716               &check_libobjs_sources ($xname, 'LDADD');
2717             }
2718         }
2719     }
2720 }
2721
2722
2723 # handle_libraries ()
2724 # -------------------
2725 # Handle libraries.
2726 sub handle_libraries
2727 {
2728   my @liblist = &am_install_var ('libs', 'LIBRARIES',
2729                                  'lib', 'pkglib', 'noinst', 'check');
2730   return if ! @liblist;
2731
2732   my @prefix = am_primary_prefixes ('LIBRARIES', 0, 'lib', 'pkglib',
2733                                     'noinst', 'check');
2734
2735   if (@prefix)
2736     {
2737       my $var = rvar ($prefix[0] . '_LIBRARIES');
2738       $var->requires_variables ('library used', 'RANLIB');
2739     }
2740
2741   &define_variable ('AR', 'ar', INTERNAL);
2742   &define_variable ('ARFLAGS', 'cru', INTERNAL);
2743   &define_verbose_tagvar ('AR');
2744
2745   foreach my $pair (@liblist)
2746     {
2747       my ($where, $onelib) = @$pair;
2748
2749       my $seen_libobjs = 0;
2750       # Check that the library fits the standard naming convention.
2751       my $bn = basename ($onelib);
2752       if ($bn !~ /^lib.*\.a$/)
2753         {
2754           $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.a/;
2755           my $suggestion = dirname ($onelib) . "/$bn";
2756           $suggestion =~ s|^\./||g;
2757           msg ('error-gnu/warn', $where,
2758                "`$onelib' is not a standard library name\n"
2759                . "did you mean `$suggestion'?")
2760         }
2761
2762       ($known_libraries{$onelib} = $bn) =~ s/\.a$//;
2763
2764       $where->push_context ("while processing library `$onelib'");
2765       $where->set (INTERNAL->get);
2766
2767       my $obj = get_object_extension '.$(OBJEXT)';
2768
2769       # Canonicalize names and check for misspellings.
2770       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_SOURCES',
2771                                             '_OBJECTS', '_DEPENDENCIES',
2772                                             '_AR');
2773
2774       if (! var ($xlib . '_AR'))
2775         {
2776           &define_variable ($xlib . '_AR', '$(AR) $(ARFLAGS)', $where);
2777         }
2778
2779       # Generate support for conditional object inclusion in
2780       # libraries.
2781       if (var ($xlib . '_LIBADD'))
2782         {
2783           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2784             {
2785               $seen_libobjs = 1;
2786             }
2787         }
2788       else
2789         {
2790           &define_variable ($xlib . "_LIBADD", '', $where);
2791         }
2792
2793       reject_var ($xlib . '_LDADD',
2794                   "use `${xlib}_LIBADD', not `${xlib}_LDADD'");
2795
2796       # Make sure we at look at this.
2797       set_seen ($xlib . '_DEPENDENCIES');
2798       set_seen ('EXTRA_' . $xlib . '_DEPENDENCIES');
2799
2800       &handle_source_transform ($xlib, $onelib, $obj, $where,
2801                                 NONLIBTOOL => 1, LIBTOOL => 0);
2802
2803       # If the resulting library lies into a subdirectory,
2804       # make sure this directory will exist.
2805       my $dirstamp = require_build_directory_maybe ($onelib);
2806       my $verbose = verbose_flag ('AR');
2807       my $silent = silent_flag ();
2808
2809       $output_rules .= &file_contents ('library',
2810                                        $where,
2811                                        VERBOSE  => $verbose,
2812                                        SILENT   => $silent,
2813                                        LIBRARY  => $onelib,
2814                                        XLIBRARY => $xlib,
2815                                        DIRSTAMP => $dirstamp);
2816
2817       if ($seen_libobjs)
2818         {
2819           if (var ($xlib . '_LIBADD'))
2820             {
2821               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2822             }
2823         }
2824     }
2825 }
2826
2827
2828 # handle_ltlibraries ()
2829 # ---------------------
2830 # Handle shared libraries.
2831 sub handle_ltlibraries
2832 {
2833   my @liblist = &am_install_var ('ltlib', 'LTLIBRARIES',
2834                                  'noinst', 'lib', 'pkglib', 'check');
2835   return if ! @liblist;
2836
2837   my @prefix = am_primary_prefixes ('LTLIBRARIES', 0, 'lib', 'pkglib',
2838                                     'noinst', 'check');
2839
2840   if (@prefix)
2841     {
2842       my $var = rvar ($prefix[0] . '_LTLIBRARIES');
2843       $var->requires_variables ('Libtool library used', 'LIBTOOL');
2844     }
2845
2846   my %instdirs = ();
2847   my %instsubdirs = ();
2848   my %instconds = ();
2849   my %liblocations = ();        # Location (in Makefile.am) of each library.
2850
2851   foreach my $key (@prefix)
2852     {
2853       # Get the installation directory of each library.
2854       my $dir = $key;
2855       my $strip_subdir = 1;
2856       if ($dir =~ /^nobase_/)
2857         {
2858           $dir =~ s/^nobase_//;
2859           $strip_subdir = 0;
2860         }
2861       my $var = rvar ($key . '_LTLIBRARIES');
2862
2863       # We reject libraries which are installed in several places
2864       # in the same condition, because we can only specify one
2865       # `-rpath' option.
2866       $var->traverse_recursively
2867         (sub
2868          {
2869            my ($var, $val, $cond, $full_cond) = @_;
2870            my $hcond = $full_cond->human;
2871            my $where = $var->rdef ($cond)->location;
2872            my $ldir = '';
2873            $ldir = '/' . dirname ($val)
2874              if (!$strip_subdir);
2875            # A library cannot be installed in different directories
2876            # in overlapping conditions.
2877            if (exists $instconds{$val})
2878              {
2879                my ($msg, $acond) =
2880                  $instconds{$val}->ambiguous_p ($val, $full_cond);
2881
2882                if ($msg)
2883                  {
2884                    error ($where, $msg, partial => 1);
2885                    my $dirtxt = "installed " . ($strip_subdir ? "in" : "below") . " `$dir'";
2886                    $dirtxt = "built for `$dir'"
2887                      if $dir eq 'EXTRA' || $dir eq 'noinst' || $dir eq 'check';
2888                    my $dircond =
2889                      $full_cond->true ? "" : " in condition $hcond";
2890
2891                    error ($where, "`$val' should be $dirtxt$dircond ...",
2892                           partial => 1);
2893
2894                    my $hacond = $acond->human;
2895                    my $adir = $instdirs{$val}{$acond};
2896                    my $adirtxt = "installed in `$adir'";
2897                    $adirtxt = "built for `$adir'"
2898                      if ($adir eq 'EXTRA' || $adir eq 'noinst'
2899                          || $adir eq 'check');
2900                    my $adircond = $acond->true ? "" : " in condition $hacond";
2901
2902                    my $onlyone = ($dir ne $adir) ?
2903                      ("\nLibtool libraries can be built for only one "
2904                       . "destination") : "";
2905
2906                    error ($liblocations{$val}{$acond},
2907                           "... and should also be $adirtxt$adircond.$onlyone");
2908                    return;
2909                  }
2910              }
2911            else
2912              {
2913                $instconds{$val} = new Automake::DisjConditions;
2914              }
2915            $instdirs{$val}{$full_cond} = $dir;
2916            $instsubdirs{$val}{$full_cond} = $ldir;
2917            $liblocations{$val}{$full_cond} = $where;
2918            $instconds{$val} = $instconds{$val}->merge ($full_cond);
2919          },
2920          sub
2921          {
2922            return ();
2923          },
2924          skip_ac_subst => 1);
2925     }
2926
2927   foreach my $pair (@liblist)
2928     {
2929       my ($where, $onelib) = @$pair;
2930
2931       my $seen_libobjs = 0;
2932       my $obj = get_object_extension '.lo';
2933
2934       # Canonicalize names and check for misspellings.
2935       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_LDFLAGS',
2936                                             '_SOURCES', '_OBJECTS',
2937                                             '_DEPENDENCIES');
2938
2939       # Check that the library fits the standard naming convention.
2940       my $libname_rx = '^lib.*\.la';
2941       my $ldvar = var ("${xlib}_LDFLAGS") || var ('AM_LDFLAGS');
2942       my $ldvar2 = var ('LDFLAGS');
2943       if (($ldvar && grep (/-module/, $ldvar->value_as_list_recursive))
2944           || ($ldvar2 && grep (/-module/, $ldvar2->value_as_list_recursive)))
2945         {
2946           # Relax name checking for libtool modules.
2947           $libname_rx = '\.la';
2948         }
2949
2950       my $bn = basename ($onelib);
2951       if ($bn !~ /$libname_rx$/)
2952         {
2953           my $type = 'library';
2954           if ($libname_rx eq '\.la')
2955             {
2956               $bn =~ s/^(lib|)(.*?)(?:\.[^.]*)?$/$1$2.la/;
2957               $type = 'module';
2958             }
2959           else
2960             {
2961               $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.la/;
2962             }
2963           my $suggestion = dirname ($onelib) . "/$bn";
2964           $suggestion =~ s|^\./||g;
2965           msg ('error-gnu/warn', $where,
2966                "`$onelib' is not a standard libtool $type name\n"
2967                . "did you mean `$suggestion'?")
2968         }
2969
2970       ($known_libraries{$onelib} = $bn) =~ s/\.la$//;
2971
2972       $where->push_context ("while processing Libtool library `$onelib'");
2973       $where->set (INTERNAL->get);
2974
2975       # Make sure we look at these.
2976       set_seen ($xlib . '_LDFLAGS');
2977       set_seen ($xlib . '_DEPENDENCIES');
2978       set_seen ('EXTRA_' . $xlib . '_DEPENDENCIES');
2979
2980       # Generate support for conditional object inclusion in
2981       # libraries.
2982       if (var ($xlib . '_LIBADD'))
2983         {
2984           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2985             {
2986               $seen_libobjs = 1;
2987             }
2988         }
2989       else
2990         {
2991           &define_variable ($xlib . "_LIBADD", '', $where);
2992         }
2993
2994       reject_var ("${xlib}_LDADD",
2995                   "use `${xlib}_LIBADD', not `${xlib}_LDADD'");
2996
2997
2998       my $linker = &handle_source_transform ($xlib, $onelib, $obj, $where,
2999                                              NONLIBTOOL => 0, LIBTOOL => 1);
3000
3001       # Determine program to use for link.
3002       my($xlink, $vlink) = &define_per_target_linker_variable ($linker, $xlib);
3003       $vlink = verbose_flag ($vlink || 'GEN');
3004
3005       my $rpathvar = "am_${xlib}_rpath";
3006       my $rpath = "\$($rpathvar)";
3007       foreach my $rcond ($instconds{$onelib}->conds)
3008         {
3009           my $val;
3010           if ($instdirs{$onelib}{$rcond} eq 'EXTRA'
3011               || $instdirs{$onelib}{$rcond} eq 'noinst'
3012               || $instdirs{$onelib}{$rcond} eq 'check')
3013             {
3014               # It's an EXTRA_ library, so we can't specify -rpath,
3015               # because we don't know where the library will end up.
3016               # The user probably knows, but generally speaking automake
3017               # doesn't -- and in fact configure could decide
3018               # dynamically between two different locations.
3019               $val = '';
3020             }
3021           else
3022             {
3023               $val = ('-rpath $(' . $instdirs{$onelib}{$rcond} . 'dir)');
3024               $val .= $instsubdirs{$onelib}{$rcond}
3025                 if defined $instsubdirs{$onelib}{$rcond};
3026             }
3027           if ($rcond->true)
3028             {
3029               # If $rcond is true there is only one condition and
3030               # there is no point defining an helper variable.
3031               $rpath = $val;
3032             }
3033           else
3034             {
3035               define_pretty_variable ($rpathvar, $rcond, INTERNAL, $val);
3036             }
3037         }
3038
3039       # If the resulting library lies into a subdirectory,
3040       # make sure this directory will exist.
3041       my $dirstamp = require_build_directory_maybe ($onelib);
3042
3043       # Remember to cleanup .libs/ in this directory.
3044       my $dirname = dirname $onelib;
3045       $libtool_clean_directories{$dirname} = 1;
3046
3047       $output_rules .= &file_contents ('ltlibrary',
3048                                        $where,
3049                                        LTLIBRARY  => $onelib,
3050                                        XLTLIBRARY => $xlib,
3051                                        RPATH      => $rpath,
3052                                        XLINK      => $xlink,
3053                                        VERBOSE    => $vlink,
3054                                        DIRSTAMP   => $dirstamp);
3055       if ($seen_libobjs)
3056         {
3057           if (var ($xlib . '_LIBADD'))
3058             {
3059               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
3060             }
3061         }
3062     }
3063 }
3064
3065 # See if any _SOURCES variable were misspelled.
3066 sub check_typos ()
3067 {
3068   # It is ok if the user sets this particular variable.
3069   set_seen 'AM_LDFLAGS';
3070
3071   foreach my $primary ('SOURCES', 'LIBADD', 'LDADD', 'LDFLAGS', 'DEPENDENCIES')
3072     {
3073       foreach my $var (variables $primary)
3074         {
3075           my $varname = $var->name;
3076           # A configure variable is always legitimate.
3077           next if exists $configure_vars{$varname};
3078
3079           for my $cond ($var->conditions->conds)
3080             {
3081               $varname =~ /^(?:EXTRA_)?(?:nobase_)?(?:dist_|nodist_)?(.*)_[[:alnum:]]+$/;
3082               msg_var ('syntax', $var, "variable `$varname' is defined but no"
3083                        . " program or\nlibrary has `$1' as canonical name"
3084                        . " (possible typo)")
3085                 unless $var->rdef ($cond)->seen;
3086             }
3087         }
3088     }
3089 }
3090
3091
3092 # Handle scripts.
3093 sub handle_scripts
3094 {
3095     # NOTE we no longer automatically clean SCRIPTS, because it is
3096     # useful to sometimes distribute scripts verbatim.  This happens
3097     # e.g. in Automake itself.
3098     &am_install_var ('-candist', 'scripts', 'SCRIPTS',
3099                      'bin', 'sbin', 'libexec', 'pkgdata',
3100                      'noinst', 'check');
3101 }
3102
3103
3104
3105
3106 ## ------------------------ ##
3107 ## Handling Texinfo files.  ##
3108 ## ------------------------ ##
3109
3110 # ($OUTFILE, $VFILE, @CLEAN_FILES)
3111 # &scan_texinfo_file ($FILENAME)
3112 # ------------------------------
3113 # $OUTFILE     - name of the info file produced by $FILENAME.
3114 # $VFILE       - name of the version.texi file used (undef if none).
3115 # @CLEAN_FILES - list of byproducts (indexes etc.)
3116 sub scan_texinfo_file ($)
3117 {
3118   my ($filename) = @_;
3119
3120   # Some of the following extensions are always created, no matter
3121   # whether indexes are used or not.  Other (like cps, fns, ... pgs)
3122   # are only created when they are used.  We used to scan $FILENAME
3123   # for their use, but that is not enough: they could be used in
3124   # included files.  We can't scan included files because we don't
3125   # know the include path.  Therefore we always erase these files, no
3126   # matter whether they are used or not.
3127   #
3128   # (tmp is only created if an @macro is used and a certain e-TeX
3129   # feature is not available.)
3130   my %clean_suffixes =
3131     map { $_ => 1 } (qw(aux log toc tmp
3132                         cp cps
3133                         fn fns
3134                         ky kys
3135                         vr vrs
3136                         tp tps
3137                         pg pgs)); # grep 'new.*index' texinfo.tex
3138
3139   my $texi = new Automake::XFile "< $filename";
3140   verb "reading $filename";
3141
3142   my ($outfile, $vfile);
3143   while ($_ = $texi->getline)
3144     {
3145       if (/^\@setfilename +(\S+)/)
3146         {
3147           # Honor only the first @setfilename.  (It's possible to have
3148           # more occurrences later if the manual shows examples of how
3149           # to use @setfilename...)
3150           next if $outfile;
3151
3152           $outfile = $1;
3153           if ($outfile =~ /\.([^.]+)$/ && $1 ne 'info')
3154             {
3155               error ("$filename:$.",
3156                      "output `$outfile' has unrecognized extension");
3157               return;
3158             }
3159         }
3160       # A "version.texi" file is actually any file whose name matches
3161       # "vers*.texi".
3162       elsif (/^\@include\s+(vers[^.]*\.texi)\s*$/)
3163         {
3164           $vfile = $1;
3165         }
3166
3167       # Try to find new or unused indexes.
3168
3169       # Creating a new category of index.
3170       elsif (/^\@def(code)?index (\w+)/)
3171         {
3172           $clean_suffixes{$2} = 1;
3173           $clean_suffixes{"$2s"} = 1;
3174         }
3175
3176       # Merging an index into an another.
3177       elsif (/^\@syn(code)?index (\w+) (\w+)/)
3178         {
3179           delete $clean_suffixes{"$2s"};
3180           $clean_suffixes{"$3s"} = 1;
3181         }
3182
3183     }
3184
3185   if (! $outfile)
3186     {
3187       err_am "`$filename' missing \@setfilename";
3188       return;
3189     }
3190
3191   my $infobase = basename ($filename);
3192   $infobase =~ s/\.te?xi(nfo)?$//;
3193   return ($outfile, $vfile,
3194           map { "$infobase.$_" } (sort keys %clean_suffixes));
3195 }
3196
3197
3198 # ($DIRSTAMP, @CLEAN_FILES)
3199 # output_texinfo_build_rules ($SOURCE, $DEST, $INSRC, @DEPENDENCIES)
3200 # ------------------------------------------------------------------
3201 # SOURCE - the source Texinfo file
3202 # DEST - the destination Info file
3203 # INSRC - whether DEST should be built in the source tree
3204 # DEPENDENCIES - known dependencies
3205 sub output_texinfo_build_rules ($$$@)
3206 {
3207   my ($source, $dest, $insrc, @deps) = @_;
3208
3209   # Split `a.texi' into `a' and `.texi'.
3210   my ($spfx, $ssfx) = ($source =~ /^(.*?)(\.[^.]*)?$/);
3211   my ($dpfx, $dsfx) = ($dest =~ /^(.*?)(\.[^.]*)?$/);
3212
3213   $ssfx ||= "";
3214   $dsfx ||= "";
3215
3216   # We can output two kinds of rules: the "generic" rules use Make
3217   # suffix rules and are appropriate when $source and $dest do not lie
3218   # in a sub-directory; the "specific" rules are needed in the other
3219   # case.
3220   #
3221   # The former are output only once (this is not really apparent here,
3222   # but just remember that some logic deeper in Automake will not
3223   # output the same rule twice); while the later need to be output for
3224   # each Texinfo source.
3225   my $generic;
3226   my $makeinfoflags;
3227   my $sdir = dirname $source;
3228   if ($sdir eq '.' && dirname ($dest) eq '.')
3229     {
3230       $generic = 1;
3231       $makeinfoflags = '-I $(srcdir)';
3232     }
3233   else
3234     {
3235       $generic = 0;
3236       $makeinfoflags = "-I $sdir -I \$(srcdir)/$sdir";
3237     }
3238
3239   # A directory can contain two kinds of info files: some built in the
3240   # source tree, and some built in the build tree.  The rules are
3241   # different in each case.  However we cannot output two different
3242   # set of generic rules.  Because in-source builds are more usual, we
3243   # use generic rules in this case and fall back to "specific" rules
3244   # for build-dir builds.  (It should not be a problem to invert this
3245   # if needed.)
3246   $generic = 0 unless $insrc;
3247
3248   # We cannot use a suffix rule to build info files with an empty
3249   # extension.  Otherwise we would output a single suffix inference
3250   # rule, with separate dependencies, as in
3251   #
3252   #    .texi:
3253   #             $(MAKEINFO) ...
3254   #    foo.info: foo.texi
3255   #
3256   # which confuse Solaris make.  (See the Autoconf manual for
3257   # details.)  Therefore we use a specific rule in this case.  This
3258   # applies to info files only (dvi and pdf files always have an
3259   # extension).
3260   my $generic_info = ($generic && $dsfx) ? 1 : 0;
3261
3262   # If the resulting file lie into a subdirectory,
3263   # make sure this directory will exist.
3264   my $dirstamp = require_build_directory_maybe ($dest);
3265
3266   my $dipfx = ($insrc ? '$(srcdir)/' : '') . $dpfx;
3267
3268   $output_rules .= file_contents ('texibuild',
3269                                   new Automake::Location,
3270                                   AM_V_MAKEINFO    => verbose_flag('MAKEINFO'),
3271                                   AM_V_TEXI2DVI    => verbose_flag('TEXI2DVI'),
3272                                   AM_V_TEXI2PDF    => verbose_flag('TEXI2PDF'),
3273                                   DEPS             => "@deps",
3274                                   DEST_PREFIX      => $dpfx,
3275                                   DEST_INFO_PREFIX => $dipfx,
3276                                   DEST_SUFFIX      => $dsfx,
3277                                   DIRSTAMP         => $dirstamp,
3278                                   GENERIC          => $generic,
3279                                   GENERIC_INFO     => $generic_info,
3280                                   INSRC            => $insrc,
3281                                   MAKEINFOFLAGS    => $makeinfoflags,
3282                                   SILENT           => silent_flag(),
3283                                   SOURCE           => ($generic
3284                                                        ? '$<' : $source),
3285                                   SOURCE_INFO      => ($generic_info
3286                                                        ? '$<' : $source),
3287                                   SOURCE_REAL      => $source,
3288                                   SOURCE_SUFFIX    => $ssfx,
3289                                   TEXIQUIET        => verbose_flag('texinfo'),
3290                                   TEXIDEVNULL      => verbose_flag('texidevnull'),
3291                                   );
3292   return ($dirstamp, "$dpfx.dvi", "$dpfx.pdf", "$dpfx.ps", "$dpfx.html");
3293 }
3294
3295
3296 # ($MOSTLYCLEAN, $TEXICLEAN, $MAINTCLEAN)
3297 # handle_texinfo_helper ($info_texinfos)
3298 # --------------------------------------
3299 # Handle all Texinfo source; helper for handle_texinfo.
3300 sub handle_texinfo_helper ($)
3301 {
3302   my ($info_texinfos) = @_;
3303   my (@infobase, @info_deps_list, @texi_deps);
3304   my %versions;
3305   my $done = 0;
3306   my (@mostly_cleans, @texi_cleans, @maint_cleans) = ('', '', '');
3307
3308   # Build a regex matching user-cleaned files.
3309   my $d = var 'DISTCLEANFILES';
3310   my $c = var 'CLEANFILES';
3311   my @f = ();
3312   push @f, $d->value_as_list_recursive (inner_expand => 1) if $d;
3313   push @f, $c->value_as_list_recursive (inner_expand => 1) if $c;
3314   @f = map { s|[^A-Za-z_0-9*\[\]\-]|\\$&|g; s|\*|[^/]*|g; $_; } @f;
3315   my $user_cleaned_files = '^(?:' . join ('|', @f) . ')$';
3316
3317   foreach my $texi
3318       ($info_texinfos->value_as_list_recursive (inner_expand => 1))
3319     {
3320       my $infobase = $texi;
3321       $infobase =~ s/\.(txi|texinfo|texi)$//;
3322
3323       if ($infobase eq $texi)
3324         {
3325           # FIXME: report line number.
3326           err_am "texinfo file `$texi' has unrecognized extension";
3327           next;
3328         }
3329
3330       push @infobase, $infobase;
3331
3332       # If 'version.texi' is referenced by input file, then include
3333       # automatic versioning capability.
3334       my ($out_file, $vtexi, @clean_files) =
3335         scan_texinfo_file ("$relative_dir/$texi")
3336         or next;
3337       push (@mostly_cleans, @clean_files);
3338
3339       # If the Texinfo source is in a subdirectory, create the
3340       # resulting info in this subdirectory.  If it is in the current
3341       # directory, try hard to not prefix "./" because it breaks the
3342       # generic rules.
3343       my $outdir = dirname ($texi) . '/';
3344       $outdir = "" if $outdir eq './';
3345       $out_file =  $outdir . $out_file;
3346
3347       # Until Automake 1.6.3, .info files were built in the
3348       # source tree.  This was an obstacle to the support of
3349       # non-distributed .info files, and non-distributed .texi
3350       # files.
3351       #
3352       # * Non-distributed .texi files is important in some packages
3353       #   where .texi files are built at make time, probably using
3354       #   other binaries built in the package itself, maybe using
3355       #   tools or information found on the build host.  Because
3356       #   these files are not distributed they are always rebuilt
3357       #   at make time; they should therefore not lie in the source
3358       #   directory.  One plan was to support this using
3359       #   nodist_info_TEXINFOS or something similar.  (Doing this
3360       #   requires some sanity checks.  For instance Automake should
3361       #   not allow:
3362       #      dist_info_TEXINFOS = foo.texi
3363       #      nodist_foo_TEXINFOS = included.texi
3364       #   because a distributed file should never depend on a
3365       #   non-distributed file.)
3366       #
3367       # * If .texi files are not distributed, then .info files should
3368       #   not be distributed either.  There are also cases where one
3369       #   wants to distribute .texi files, but does not want to
3370       #   distribute the .info files.  For instance the Texinfo package
3371       #   distributes the tool used to build these files; it would
3372       #   be a waste of space to distribute them.  It's not clear
3373       #   which syntax we should use to indicate that .info files should
3374       #   not be distributed.  Akim Demaille suggested that eventually
3375       #   we switch to a new syntax:
3376       #   |  Maybe we should take some inspiration from what's already
3377       #   |  done in the rest of Automake.  Maybe there is too much
3378       #   |  syntactic sugar here, and you want
3379       #   |     nodist_INFO = bar.info
3380       #   |     dist_bar_info_SOURCES = bar.texi
3381       #   |     bar_texi_DEPENDENCIES = foo.texi
3382       #   |  with a bit of magic to have bar.info represent the whole
3383       #   |  bar*info set.  That's a lot more verbose that the current
3384       #   |  situation, but it is # not new, hence the user has less
3385       #   |  to learn.
3386       #   |
3387       #   |  But there is still too much room for meaningless specs:
3388       #   |     nodist_INFO = bar.info
3389       #   |     dist_bar_info_SOURCES = bar.texi
3390       #   |     dist_PS = bar.ps something-written-by-hand.ps
3391       #   |     nodist_bar_ps_SOURCES = bar.texi
3392       #   |     bar_texi_DEPENDENCIES = foo.texi
3393       #   |  here bar.texi is dist_ in line 2, and nodist_ in 4.
3394       #
3395       # Back to the point, it should be clear that in order to support
3396       # non-distributed .info files, we need to build them in the
3397       # build tree, not in the source tree (non-distributed .texi
3398       # files are less of a problem, because we do not output build
3399       # rules for them).  In Automake 1.7 .info build rules have been
3400       # largely cleaned up so that .info files get always build in the
3401       # build tree, even when distributed.  The idea was that
3402       #   (1) if during a VPATH build the .info file was found to be
3403       #       absent or out-of-date (in the source tree or in the
3404       #       build tree), Make would rebuild it in the build tree.
3405       #       If an up-to-date source-tree of the .info file existed,
3406       #       make would not rebuild it in the build tree.
3407       #   (2) having two copies of .info files, one in the source tree
3408       #       and one (newer) in the build tree is not a problem
3409       #       because `make dist' always pick files in the build tree
3410       #       first.
3411       # However it turned out the be a bad idea for several reasons:
3412       #   * Tru64, OpenBSD, and FreeBSD (not NetBSD) Make do not behave
3413       #     like GNU Make on point (1) above.  These implementations
3414       #     of Make would always rebuild .info files in the build
3415       #     tree, even if such files were up to date in the source
3416       #     tree.  Consequently, it was impossible to perform a VPATH
3417       #     build of a package containing Texinfo files using these
3418       #     Make implementations.
3419       #     (Refer to the Autoconf Manual, section "Limitation of
3420       #     Make", paragraph "VPATH", item "target lookup", for
3421       #     an account of the differences between these
3422       #     implementations.)
3423       #   * The GNU Coding Standards require these files to be built
3424       #     in the source-tree (when they are distributed, that is).
3425       #   * Keeping a fresher copy of distributed files in the
3426       #     build tree can be annoying during development because
3427       #     - if the files is kept under CVS, you really want it
3428       #       to be updated in the source tree
3429       #     - it is confusing that `make distclean' does not erase
3430       #       all files in the build tree.
3431       #
3432       # Consequently, starting with Automake 1.8, .info files are
3433       # built in the source tree again.  Because we still plan to
3434       # support non-distributed .info files at some point, we
3435       # have a single variable ($INSRC) that controls whether
3436       # the current .info file must be built in the source tree
3437       # or in the build tree.  Actually this variable is switched
3438       # off for .info files that appear to be cleaned; this is
3439       # for backward compatibility with package such as Texinfo,
3440       # which do things like
3441       #   info_TEXINFOS = texinfo.txi info-stnd.texi info.texi
3442       #   DISTCLEANFILES = texinfo texinfo-* info*.info*
3443       #   # Do not create info files for distribution.
3444       #   dist-info:
3445       # in order not to distribute .info files.
3446       my $insrc = ($out_file =~ $user_cleaned_files) ? 0 : 1;
3447
3448       my $soutdir = '$(srcdir)/' . $outdir;
3449       $outdir = $soutdir if $insrc;
3450
3451       # If user specified file_TEXINFOS, then use that as explicit
3452       # dependency list.
3453       @texi_deps = ();
3454       push (@texi_deps, "$soutdir$vtexi") if $vtexi;
3455
3456       my $canonical = canonicalize ($infobase);
3457       if (var ($canonical . "_TEXINFOS"))
3458         {
3459           push (@texi_deps, '$(' . $canonical . '_TEXINFOS)');
3460           push_dist_common ('$(' . $canonical . '_TEXINFOS)');
3461         }
3462
3463       my ($dirstamp, @cfiles) =
3464         output_texinfo_build_rules ($texi, $out_file, $insrc, @texi_deps);
3465       push (@texi_cleans, @cfiles);
3466
3467       push (@info_deps_list, $out_file);
3468
3469       # If a vers*.texi file is needed, emit the rule.
3470       if ($vtexi)
3471         {
3472           err_am ("`$vtexi', included in `$texi', "
3473                   . "also included in `$versions{$vtexi}'")
3474             if defined $versions{$vtexi};
3475           $versions{$vtexi} = $texi;
3476
3477           # We number the stamp-vti files.  This is doable since the
3478           # actual names don't matter much.  We only number starting
3479           # with the second one, so that the common case looks nice.
3480           my $vti = ($done ? $done : 'vti');
3481           ++$done;
3482
3483           # This is ugly, but it is our historical practice.
3484           if ($config_aux_dir_set_in_configure_ac)
3485             {
3486               require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3487                                             'mdate-sh');
3488             }
3489           else
3490             {
3491               require_file_with_macro (TRUE, 'info_TEXINFOS',
3492                                        FOREIGN, 'mdate-sh');
3493             }
3494
3495           my $conf_dir;
3496           if ($config_aux_dir_set_in_configure_ac)
3497             {
3498               $conf_dir = "$am_config_aux_dir/";
3499             }
3500           else
3501             {
3502               $conf_dir = '$(srcdir)/';
3503             }
3504           $output_rules .= file_contents ('texi-vers',
3505                                           new Automake::Location,
3506                                           TEXI     => $texi,
3507                                           VTI      => $vti,
3508                                           STAMPVTI => "${soutdir}stamp-$vti",
3509                                           VTEXI    => "$soutdir$vtexi",
3510                                           MDDIR    => $conf_dir,
3511                                           DIRSTAMP => $dirstamp);
3512         }
3513     }
3514
3515   # Handle location of texinfo.tex.
3516   my $need_texi_file = 0;
3517   my $texinfodir;
3518   if (var ('TEXINFO_TEX'))
3519     {
3520       # The user defined TEXINFO_TEX so assume he knows what he is
3521       # doing.
3522       $texinfodir = ('$(srcdir)/'
3523                      . dirname (variable_value ('TEXINFO_TEX')));
3524     }
3525   elsif (option 'cygnus')
3526     {
3527       $texinfodir = '$(top_srcdir)/../texinfo';
3528       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3529     }
3530   elsif ($config_aux_dir_set_in_configure_ac)
3531     {
3532       $texinfodir = $am_config_aux_dir;
3533       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3534       $need_texi_file = 2; # so that we require_conf_file later
3535     }
3536   else
3537     {
3538       $texinfodir = '$(srcdir)';
3539       $need_texi_file = 1;
3540     }
3541   define_variable ('am__TEXINFO_TEX_DIR', $texinfodir, INTERNAL);
3542
3543   push (@dist_targets, 'dist-info');
3544
3545   if (! option 'no-installinfo')
3546     {
3547       # Make sure documentation is made and installed first.  Use
3548       # $(INFO_DEPS), not 'info', because otherwise recursive makes
3549       # get run twice during "make all".
3550       unshift (@all, '$(INFO_DEPS)');
3551     }
3552
3553   define_files_variable ("DVIS", @infobase, 'dvi', INTERNAL);
3554   define_files_variable ("PDFS", @infobase, 'pdf', INTERNAL);
3555   define_files_variable ("PSS", @infobase, 'ps', INTERNAL);
3556   define_files_variable ("HTMLS", @infobase, 'html', INTERNAL);
3557
3558   # This next isn't strictly needed now -- the places that look here
3559   # could easily be changed to look in info_TEXINFOS.  But this is
3560   # probably better, in case noinst_TEXINFOS is ever supported.
3561   define_variable ("TEXINFOS", variable_value ('info_TEXINFOS'), INTERNAL);
3562
3563   # Do some error checking.  Note that this file is not required
3564   # when in Cygnus mode; instead we defined TEXINFO_TEX explicitly
3565   # up above.
3566   if ($need_texi_file && ! option 'no-texinfo.tex')
3567     {
3568       if ($need_texi_file > 1)
3569         {
3570           require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3571                                         'texinfo.tex');
3572         }
3573       else
3574         {
3575           require_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3576                                    'texinfo.tex');
3577         }
3578     }
3579
3580   return (makefile_wrap ("", "\t  ", @mostly_cleans),
3581           makefile_wrap ("", "\t  ", @texi_cleans),
3582           makefile_wrap ("", "\t  ", @maint_cleans));
3583 }
3584
3585
3586 # handle_texinfo ()
3587 # -----------------
3588 # Handle all Texinfo source.
3589 sub handle_texinfo ()
3590 {
3591   reject_var 'TEXINFOS', "`TEXINFOS' is an anachronism; use `info_TEXINFOS'";
3592   # FIXME: I think this is an obsolete future feature name.
3593   reject_var 'html_TEXINFOS', "HTML generation not yet supported";
3594
3595   my $info_texinfos = var ('info_TEXINFOS');
3596   my ($mostlyclean, $clean, $maintclean) = ('', '', '');
3597   if ($info_texinfos)
3598     {
3599       define_verbose_texinfo;
3600       ($mostlyclean, $clean, $maintclean) = handle_texinfo_helper ($info_texinfos);
3601       chomp $mostlyclean;
3602       chomp $clean;
3603       chomp $maintclean;
3604     }
3605
3606   $output_rules .=  file_contents ('texinfos',
3607                                    new Automake::Location,
3608                                    AM_V_DVIPS    => verbose_flag('DVIPS'),
3609                                    MOSTLYCLEAN   => $mostlyclean,
3610                                    TEXICLEAN     => $clean,
3611                                    MAINTCLEAN    => $maintclean,
3612                                    'LOCAL-TEXIS' => !!$info_texinfos,
3613                                    TEXIQUIET     => verbose_flag('texinfo'));
3614 }
3615
3616
3617 # Handle any man pages.
3618 sub handle_man_pages
3619 {
3620   reject_var 'MANS', "`MANS' is an anachronism; use `man_MANS'";
3621
3622   # Find all the sections in use.  We do this by first looking for
3623   # "standard" sections, and then looking for any additional
3624   # sections used in man_MANS.
3625   my (%sections, %notrans_sections, %trans_sections,
3626       %notrans_vars, %trans_vars, %notrans_sect_vars, %trans_sect_vars);
3627   # We handle nodist_ for uniformity.  man pages aren't distributed
3628   # by default so it isn't actually very important.
3629   foreach my $npfx ('', 'notrans_')
3630     {
3631       foreach my $pfx ('', 'dist_', 'nodist_')
3632         {
3633           # Add more sections as needed.
3634           foreach my $section ('0'..'9', 'n', 'l')
3635             {
3636               my $varname = $npfx . $pfx . 'man' . $section . '_MANS';
3637               if (var ($varname))
3638                 {
3639                   $sections{$section} = 1;
3640                   $varname = '$(' . $varname . ')';
3641                   if ($npfx eq 'notrans_')
3642                     {
3643                       $notrans_sections{$section} = 1;
3644                       $notrans_sect_vars{$varname} = 1;
3645                     }
3646                   else
3647                     {
3648                       $trans_sections{$section} = 1;
3649                       $trans_sect_vars{$varname} = 1;
3650                     }
3651
3652                   &push_dist_common ($varname)
3653                     if $pfx eq 'dist_';
3654                 }
3655             }
3656
3657           my $varname = $npfx . $pfx . 'man_MANS';
3658           my $var = var ($varname);
3659           if ($var)
3660             {
3661               foreach ($var->value_as_list_recursive)
3662                 {
3663                   # A page like `foo.1c' goes into man1dir.
3664                   if (/\.([0-9a-z])([a-z]*)$/)
3665                     {
3666                       $sections{$1} = 1;
3667                       if ($npfx eq 'notrans_')
3668                         {
3669                           $notrans_sections{$1} = 1;
3670                         }
3671                       else
3672                         {
3673                           $trans_sections{$1} = 1;
3674                         }
3675                     }
3676                 }
3677
3678               $varname = '$(' . $varname . ')';
3679               if ($npfx eq 'notrans_')
3680                 {
3681                   $notrans_vars{$varname} = 1;
3682                 }
3683               else
3684                 {
3685                   $trans_vars{$varname} = 1;
3686                 }
3687               &push_dist_common ($varname)
3688                 if $pfx eq 'dist_';
3689             }
3690         }
3691     }
3692
3693   return unless %sections;
3694
3695   my @unsorted_deps;
3696
3697   # Build section independent variables.
3698   my $have_notrans = %notrans_vars;
3699   my @notrans_list = sort keys %notrans_vars;
3700   my $have_trans = %trans_vars;
3701   my @trans_list = sort keys %trans_vars;
3702
3703   # Now for each section, generate an install and uninstall rule.
3704   # Sort sections so output is deterministic.
3705   foreach my $section (sort keys %sections)
3706     {
3707       # Build section dependent variables.
3708       my $notrans_mans = $have_notrans || exists $notrans_sections{$section};
3709       my $trans_mans = $have_trans || exists $trans_sections{$section};
3710       my (%notrans_this_sect, %trans_this_sect);
3711       my $expr = 'man' . $section . '_MANS';
3712       foreach my $varname (keys %notrans_sect_vars)
3713         {
3714           if ($varname =~ /$expr/)
3715             {
3716               $notrans_this_sect{$varname} = 1;
3717             }
3718         }
3719       foreach my $varname (keys %trans_sect_vars)
3720         {
3721           if ($varname =~ /$expr/)
3722             {
3723               $trans_this_sect{$varname} = 1;
3724             }
3725         }
3726       my @notrans_sect_list = sort keys %notrans_this_sect;
3727       my @trans_sect_list = sort keys %trans_this_sect;
3728       @unsorted_deps = (keys %notrans_vars, keys %trans_vars,
3729                         keys %notrans_this_sect, keys %trans_this_sect);
3730       my @deps = sort @unsorted_deps;
3731       $output_rules .= &file_contents ('mans',
3732                                        new Automake::Location,
3733                                        SECTION           => $section,
3734                                        DEPS              => "@deps",
3735                                        NOTRANS_MANS      => $notrans_mans,
3736                                        NOTRANS_SECT_LIST => "@notrans_sect_list",
3737                                        HAVE_NOTRANS      => $have_notrans,
3738                                        NOTRANS_LIST      => "@notrans_list",
3739                                        TRANS_MANS        => $trans_mans,
3740                                        TRANS_SECT_LIST   => "@trans_sect_list",
3741                                        HAVE_TRANS        => $have_trans,
3742                                        TRANS_LIST        => "@trans_list");
3743     }
3744
3745   @unsorted_deps  = (keys %notrans_vars, keys %trans_vars,
3746                      keys %notrans_sect_vars, keys %trans_sect_vars);
3747   my @mans = sort @unsorted_deps;
3748   $output_vars .= file_contents ('mans-vars',
3749                                  new Automake::Location,
3750                                  MANS => "@mans");
3751
3752   push (@all, '$(MANS)')
3753     unless option 'no-installman';
3754 }
3755
3756 # Handle DATA variables.
3757 sub handle_data
3758 {
3759     &am_install_var ('-noextra', '-candist', 'data', 'DATA',
3760                      'data', 'dataroot', 'dvi', 'html', 'pdf', 'ps',
3761                      'sysconf', 'sharedstate', 'localstate',
3762                      'pkgdata', 'lisp', 'noinst', 'check');
3763 }
3764
3765 # Handle TAGS.
3766 sub handle_tags
3767 {
3768     my @tag_deps = ();
3769     my @ctag_deps = ();
3770     my @cscope_deps = ();
3771     if (var ('SUBDIRS'))
3772     {
3773         $output_rules .= ("tags-recursive:\n"
3774                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
3775                           # Never fail here if a subdir fails; it
3776                           # isn't important.
3777                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3778                           . " && \$(MAKE) \$(AM_MAKEFLAGS) tags); \\\n"
3779                           . "\tdone\n");
3780         push (@tag_deps, 'tags-recursive');
3781         &depend ('.PHONY', 'tags-recursive');
3782         &depend ('.MAKE', 'tags-recursive');
3783
3784         $output_rules .= ("ctags-recursive:\n"
3785                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
3786                           # Never fail here if a subdir fails; it
3787                           # isn't important.
3788                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3789                           . " && \$(MAKE) \$(AM_MAKEFLAGS) ctags); \\\n"
3790                           . "\tdone\n");
3791         push (@ctag_deps, 'ctags-recursive');
3792         &depend ('.PHONY', 'ctags-recursive');
3793         &depend ('.MAKE', 'ctags-recursive');
3794
3795         $output_rules .= ("cscopelist-recursive:\n"
3796                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
3797                           # Never fail here if a subdir fails; it
3798                           # isn't important.
3799                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3800                           . " && \$(MAKE) \$(AM_MAKEFLAGS) cscopelist); \\\n"
3801                           . "\tdone\n");
3802         push (@cscope_deps, 'cscopelist-recursive');
3803         &depend ('.PHONY', 'cscopelist-recursive');
3804         &depend ('.MAKE', 'cscopelist-recursive');
3805     }
3806
3807     if (&saw_sources_p (1)
3808         || var ('ETAGS_ARGS')
3809         || @tag_deps)
3810     {
3811         my @config;
3812         foreach my $spec (@config_headers)
3813         {
3814             my ($out, @ins) = split_config_file_spec ($spec);
3815             foreach my $in (@ins)
3816               {
3817                 # If the config header source is in this directory,
3818                 # require it.
3819                 push @config, basename ($in)
3820                   if $relative_dir eq dirname ($in);
3821               }
3822         }
3823         $output_rules .= &file_contents ('tags',
3824                                          new Automake::Location,
3825                                          CONFIG    => "@config",
3826                                          TAGSDIRS  => "@tag_deps",
3827                                          CTAGSDIRS => "@ctag_deps",
3828                                          CSCOPEDIRS => "@cscope_deps");
3829
3830         set_seen 'TAGS_DEPENDENCIES';
3831     }
3832     elsif (reject_var ('TAGS_DEPENDENCIES',
3833                        "it doesn't make sense to define `TAGS_DEPENDENCIES'"
3834                        . " without\nsources or `ETAGS_ARGS'"))
3835     {
3836     }
3837     else
3838     {
3839         # Every Makefile must define some sort of TAGS rule.
3840         # Otherwise, it would be possible for a top-level "make TAGS"
3841         # to fail because some subdirectory failed.
3842         $output_rules .= "tags: TAGS\nTAGS:\n\n";
3843         # Ditto ctags and cscope.
3844         $output_rules .= "ctags: CTAGS\nCTAGS:\n\n";
3845         $output_rules .= "cscope cscopelist:\n\n";
3846     }
3847 }
3848
3849 # Handle multilib support.
3850 sub handle_multilib
3851 {
3852   if ($seen_multilib && $relative_dir eq '.')
3853     {
3854       $output_rules .= &file_contents ('multilib', new Automake::Location);
3855       push (@all, 'all-multi');
3856     }
3857 }
3858
3859
3860 # user_phony_rule ($NAME)
3861 # -----------------------
3862 # Return false if rule $NAME does not exist.  Otherwise,
3863 # declare it as phony, complete its definition (in case it is
3864 # conditional), and return its Automake::Rule instance.
3865 sub user_phony_rule ($)
3866 {
3867   my ($name) = @_;
3868   my $rule = rule $name;
3869   if ($rule)
3870     {
3871       depend ('.PHONY', $name);
3872       # Define $NAME in all condition where it is not already defined,
3873       # so that it is always OK to depend on $NAME.
3874       for my $c ($rule->not_always_defined_in_cond (TRUE)->conds)
3875         {
3876           Automake::Rule::define ($name, 'internal', RULE_AUTOMAKE,
3877                                   $c, INTERNAL);
3878           $output_rules .= $c->subst_string . "$name:\n";
3879         }
3880     }
3881   return $rule;
3882 }
3883
3884
3885 # $BOOLEAN
3886 # &for_dist_common ($A, $B)
3887 # -------------------------
3888 # Subroutine for &handle_dist: sort files to dist.
3889 #
3890 # We put README first because it then becomes easier to make a
3891 # Usenet-compliant shar file (in these, README must be first).
3892 #
3893 # FIXME: do more ordering of files here.
3894 sub for_dist_common
3895 {
3896     return 0
3897         if $a eq $b;
3898     return -1
3899         if $a eq 'README';
3900     return 1
3901         if $b eq 'README';
3902     return $a cmp $b;
3903 }
3904
3905 # handle_dist
3906 # -----------
3907 # Handle 'dist' target.
3908 sub handle_dist ()
3909 {
3910   # Substitutions for distdir.am
3911   my %transform;
3912
3913   # Define DIST_SUBDIRS.  This must always be done, regardless of the
3914   # no-dist setting: target like `distclean' or `maintainer-clean' use it.
3915   my $subdirs = var ('SUBDIRS');
3916   if ($subdirs)
3917     {
3918       # If SUBDIRS is conditionally defined, then set DIST_SUBDIRS
3919       # to all possible directories, and use it.  If DIST_SUBDIRS is
3920       # defined, just use it.
3921
3922       # Note that we check DIST_SUBDIRS first on purpose, so that
3923       # we don't call has_conditional_contents for now reason.
3924       # (In the past one project used so many conditional subdirectories
3925       # that calling has_conditional_contents on SUBDIRS caused
3926       # automake to grow to 150Mb -- this should not happen with
3927       # the current implementation of has_conditional_contents,
3928       # but it's more efficient to avoid the call anyway.)
3929       if (var ('DIST_SUBDIRS'))
3930         {
3931         }
3932       elsif ($subdirs->has_conditional_contents)
3933         {
3934           define_pretty_variable
3935             ('DIST_SUBDIRS', TRUE, INTERNAL,
3936              uniq ($subdirs->value_as_list_recursive));
3937         }
3938       else
3939         {
3940           # We always define this because that is what `distclean'
3941           # wants.
3942           define_pretty_variable ('DIST_SUBDIRS', TRUE, INTERNAL,
3943                                   '$(SUBDIRS)');
3944         }
3945     }
3946
3947   # The remaining definitions are only required when a dist target is used.
3948   return if option 'no-dist';
3949
3950   # At least one of the archive formats must be enabled.
3951   if ($relative_dir eq '.')
3952     {
3953       my $archive_defined = option 'no-dist-gzip' ? 0 : 1;
3954       $archive_defined ||=
3955         grep { option "dist-$_" } qw(shar zip tarZ bzip2 lzip lzma xz);
3956       error (option 'no-dist-gzip',
3957              "no-dist-gzip specified but no dist-* specified,\n"
3958              . "at least one archive format must be enabled")
3959         unless $archive_defined;
3960     }
3961
3962   # Look for common files that should be included in distribution.
3963   # If the aux dir is set, and it does not have a Makefile.am, then
3964   # we check for these files there as well.
3965   my $check_aux = 0;
3966   if ($relative_dir eq '.'
3967       && $config_aux_dir_set_in_configure_ac)
3968     {
3969       if (! &is_make_dir ($config_aux_dir))
3970         {
3971           $check_aux = 1;
3972         }
3973     }
3974   foreach my $cfile (@common_files)
3975     {
3976       if (dir_has_case_matching_file ($relative_dir, $cfile)
3977           # The file might be absent, but if it can be built it's ok.
3978           || rule $cfile)
3979         {
3980           &push_dist_common ($cfile);
3981         }
3982
3983       # Don't use `elsif' here because a file might meaningfully
3984       # appear in both directories.
3985       if ($check_aux && dir_has_case_matching_file ($config_aux_dir, $cfile))
3986         {
3987           &push_dist_common ("$config_aux_dir/$cfile")
3988         }
3989     }
3990
3991   # We might copy elements from $configure_dist_common to
3992   # %dist_common if we think we need to.  If the file appears in our
3993   # directory, we would have discovered it already, so we don't
3994   # check that.  But if the file is in a subdir without a Makefile,
3995   # we want to distribute it here if we are doing `.'.  Ugly!
3996   if ($relative_dir eq '.')
3997     {
3998       foreach my $file (split (' ' , $configure_dist_common))
3999         {
4000           push_dist_common ($file)
4001             unless is_make_dir (dirname ($file));
4002         }
4003     }
4004
4005   # Files to distributed.  Don't use ->value_as_list_recursive
4006   # as it recursively expands `$(dist_pkgdata_DATA)' etc.
4007   my @dist_common = split (' ', rvar ('DIST_COMMON')->variable_value);
4008   @dist_common = uniq (sort for_dist_common (@dist_common));
4009   variable_delete 'DIST_COMMON';
4010   define_pretty_variable ('DIST_COMMON', TRUE, INTERNAL, @dist_common);
4011
4012   # Now that we've processed DIST_COMMON, disallow further attempts
4013   # to set it.
4014   $handle_dist_run = 1;
4015
4016   # Scan EXTRA_DIST to see if we need to distribute anything from a
4017   # subdir.  If so, add it to the list.  I didn't want to do this
4018   # originally, but there were so many requests that I finally
4019   # relented.
4020   my $extra_dist = var ('EXTRA_DIST');
4021
4022   $transform{'DISTCHECK-HOOK'} = !! rule 'distcheck-hook';
4023   $transform{'GETTEXT'} = $seen_gettext && !$seen_gettext_external;
4024
4025   # If the target `dist-hook' exists, make sure it is run.  This
4026   # allows users to do random weird things to the distribution
4027   # before it is packaged up.
4028   push (@dist_targets, 'dist-hook')
4029     if user_phony_rule 'dist-hook';
4030   $transform{'DIST-TARGETS'} = join (' ', @dist_targets);
4031
4032   my $flm = option ('filename-length-max');
4033   my $filename_filter = $flm ? '.' x $flm->[1] : '';
4034
4035   $output_rules .= &file_contents ('distdir',
4036                                    new Automake::Location,
4037                                    %transform,
4038                                    FILENAME_FILTER => $filename_filter);
4039 }
4040
4041
4042 # check_directory ($NAME, $WHERE)
4043 # -------------------------------
4044 # Ensure $NAME is a directory, and that it uses a sane name.
4045 # Use $WHERE as a location in the diagnostic, if any.
4046 sub check_directory ($$)
4047 {
4048   my ($dir, $where) = @_;
4049
4050   error $where, "required directory $relative_dir/$dir does not exist"
4051     unless -d "$relative_dir/$dir";
4052
4053   # If an `obj/' directory exists, BSD make will enter it before
4054   # reading `Makefile'.  Hence the `Makefile' in the current directory
4055   # will not be read.
4056   #
4057   #  % cat Makefile
4058   #  all:
4059   #          echo Hello
4060   #  % cat obj/Makefile
4061   #  all:
4062   #          echo World
4063   #  % make      # GNU make
4064   #  echo Hello
4065   #  Hello
4066   #  % pmake     # BSD make
4067   #  echo World
4068   #  World
4069   msg ('portability', $where,
4070        "naming a subdirectory `obj' causes troubles with BSD make")
4071     if $dir eq 'obj';
4072
4073   # `aux' is probably the most important of the following forbidden name,
4074   # since it's tempting to use it as an AC_CONFIG_AUX_DIR.
4075   msg ('portability', $where,
4076        "name `$dir' is reserved on W32 and DOS platforms")
4077     if grep (/^\Q$dir\E$/i, qw/aux lpt1 lpt2 lpt3 com1 com2 com3 com4 con prn/);
4078 }
4079
4080 # check_directories_in_var ($VARIABLE)
4081 # ------------------------------------
4082 # Recursively check all items in variables $VARIABLE as directories
4083 sub check_directories_in_var ($)
4084 {
4085   my ($var) = @_;
4086   $var->traverse_recursively
4087     (sub
4088      {
4089        my ($var, $val, $cond, $full_cond) = @_;
4090        check_directory ($val, $var->rdef ($cond)->location);
4091        return ();
4092      },
4093      undef,
4094      skip_ac_subst => 1);
4095 }
4096
4097 # &handle_subdirs ()
4098 # ------------------
4099 # Handle subdirectories.
4100 sub handle_subdirs ()
4101 {
4102   my $subdirs = var ('SUBDIRS');
4103   return
4104     unless $subdirs;
4105
4106   check_directories_in_var $subdirs;
4107
4108   my $dsubdirs = var ('DIST_SUBDIRS');
4109   check_directories_in_var $dsubdirs
4110     if $dsubdirs;
4111
4112   $output_rules .= &file_contents ('subdirs', new Automake::Location);
4113   rvar ('RECURSIVE_TARGETS')->rdef (TRUE)->{'pretty'} = VAR_SORTED; # Gross!
4114 }
4115
4116
4117 # ($REGEN, @DEPENDENCIES)
4118 # &scan_aclocal_m4
4119 # ----------------
4120 # If aclocal.m4 creation is automated, return the list of its dependencies.
4121 sub scan_aclocal_m4 ()
4122 {
4123   my $regen_aclocal = 0;
4124
4125   set_seen 'CONFIG_STATUS_DEPENDENCIES';
4126   set_seen 'CONFIGURE_DEPENDENCIES';
4127
4128   if (-f 'aclocal.m4')
4129     {
4130       &define_variable ("ACLOCAL_M4", '$(top_srcdir)/aclocal.m4', INTERNAL);
4131
4132       my $aclocal = new Automake::XFile "< aclocal.m4";
4133       my $line = $aclocal->getline;
4134       $regen_aclocal = $line =~ 'generated automatically by aclocal';
4135     }
4136
4137   my @ac_deps = ();
4138
4139   if (set_seen ('ACLOCAL_M4_SOURCES'))
4140     {
4141       push (@ac_deps, '$(ACLOCAL_M4_SOURCES)');
4142       msg_var ('obsolete', 'ACLOCAL_M4_SOURCES',
4143                "`ACLOCAL_M4_SOURCES' is obsolete.\n"
4144                . "It should be safe to simply remove it");
4145     }
4146
4147   # Note that it might be possible that aclocal.m4 doesn't exist but
4148   # should be auto-generated.  This case probably isn't very
4149   # important.
4150
4151   return ($regen_aclocal, @ac_deps);
4152 }
4153
4154
4155 # Helper function for substitute_ac_subst_variables.
4156 sub substitute_ac_subst_variables_worker($)
4157 {
4158   my ($token) = @_;
4159   return "\@$token\@" if var $token;
4160   return "\${$token\}";
4161 }
4162
4163 # substitute_ac_subst_variables ($TEXT)
4164 # -------------------------------------
4165 # Replace any occurrence of ${FOO} in $TEXT by @FOO@ if FOO is an AC_SUBST
4166 # variable.
4167 sub substitute_ac_subst_variables ($)
4168 {
4169   my ($text) = @_;
4170   $text =~ s/\${([^ \t=:+{}]+)}/&substitute_ac_subst_variables_worker ($1)/ge;
4171   return $text;
4172 }
4173
4174 # @DEPENDENCIES
4175 # &prepend_srcdir (@INPUTS)
4176 # -------------------------
4177 # Prepend $(srcdir) or $(top_srcdir) to all @INPUTS.  The idea is that
4178 # if an input file has a directory part the same as the current
4179 # directory, then the directory part is simply replaced by $(srcdir).
4180 # But if the directory part is different, then $(top_srcdir) is
4181 # prepended.
4182 sub prepend_srcdir (@)
4183 {
4184   my (@inputs) = @_;
4185   my @newinputs;
4186
4187   foreach my $single (@inputs)
4188     {
4189       if (dirname ($single) eq $relative_dir)
4190         {
4191           push (@newinputs, '$(srcdir)/' . basename ($single));
4192         }
4193       else
4194         {
4195           push (@newinputs, '$(top_srcdir)/' . $single);
4196         }
4197     }
4198   return @newinputs;
4199 }
4200
4201 # @DEPENDENCIES
4202 # rewrite_inputs_into_dependencies ($OUTPUT, @INPUTS)
4203 # ---------------------------------------------------
4204 # Compute a list of dependencies appropriate for the rebuild
4205 # rule of
4206 #   AC_CONFIG_FILES($OUTPUT:$INPUT[0]:$INPUTS[1]:...)
4207 # Also distribute $INPUTs which are not built by another AC_CONFIG_FOOs.
4208 sub rewrite_inputs_into_dependencies ($@)
4209 {
4210   my ($file, @inputs) = @_;
4211   my @res = ();
4212
4213   for my $i (@inputs)
4214     {
4215       # We cannot create dependencies on shell variables.
4216       next if (substitute_ac_subst_variables $i) =~ /\$/;
4217
4218       if (exists $ac_config_files_location{$i} && $i ne $file)
4219         {
4220           my $di = dirname $i;
4221           if ($di eq $relative_dir)
4222             {
4223               $i = basename $i;
4224             }
4225           # In the top-level Makefile we do not use $(top_builddir), because
4226           # we are already there, and since the targets are built without
4227           # a $(top_builddir), it helps BSD Make to match them with
4228           # dependencies.
4229           elsif ($relative_dir ne '.')
4230             {
4231               $i = '$(top_builddir)/' . $i;
4232             }
4233         }
4234       else
4235         {
4236           msg ('error', $ac_config_files_location{$file},
4237                "required file `$i' not found")
4238             unless $i =~ /\$/ || exists $output_files{$i} || -f $i;
4239           ($i) = prepend_srcdir ($i);
4240           push_dist_common ($i);
4241         }
4242       push @res, $i;
4243     }
4244   return @res;
4245 }
4246
4247
4248
4249 # &handle_configure ($MAKEFILE_AM, $MAKEFILE_IN, $MAKEFILE, @INPUTS)
4250 # ------------------------------------------------------------------
4251 # Handle remaking and configure stuff.
4252 # We need the name of the input file, to do proper remaking rules.
4253 sub handle_configure ($$$@)
4254 {
4255   my ($makefile_am, $makefile_in, $makefile, @inputs) = @_;
4256
4257   prog_error 'empty @inputs'
4258     unless @inputs;
4259
4260   my ($rel_makefile_am, $rel_makefile_in) = prepend_srcdir ($makefile_am,
4261                                                             $makefile_in);
4262   my $rel_makefile = basename $makefile;
4263
4264   my $colon_infile = ':' . join (':', @inputs);
4265   $colon_infile = '' if $colon_infile eq ":$makefile.in";
4266   my @rewritten = rewrite_inputs_into_dependencies ($makefile, @inputs);
4267   my ($regen_aclocal_m4, @aclocal_m4_deps) = scan_aclocal_m4;
4268   define_pretty_variable ('am__aclocal_m4_deps', TRUE, INTERNAL,
4269                           @configure_deps, @aclocal_m4_deps,
4270                           '$(top_srcdir)/' . $configure_ac);
4271   my @configuredeps = ('$(am__aclocal_m4_deps)', '$(CONFIGURE_DEPENDENCIES)');
4272   push @configuredeps, '$(ACLOCAL_M4)' if -f 'aclocal.m4';
4273   define_pretty_variable ('am__configure_deps', TRUE, INTERNAL,
4274                           @configuredeps);
4275
4276   my $automake_options = '--' . (global_option 'cygnus' ? 'cygnus' : $strictness_name)
4277                          . (global_option 'no-dependencies' ? ' --ignore-deps' : '');
4278
4279   $output_rules .= file_contents
4280     ('configure',
4281      new Automake::Location,
4282      MAKEFILE              => $rel_makefile,
4283      'MAKEFILE-DEPS'       => "@rewritten",
4284      'CONFIG-MAKEFILE'     => ($relative_dir eq '.') ? '$@' : '$(subdir)/$@',
4285      'MAKEFILE-IN'         => $rel_makefile_in,
4286      'MAKEFILE-IN-DEPS'    => "@include_stack",
4287      'MAKEFILE-AM'         => $rel_makefile_am,
4288      'AUTOMAKE-OPTIONS'    => $automake_options,
4289      'MAKEFILE-AM-SOURCES' => "$makefile$colon_infile",
4290      'REGEN-ACLOCAL-M4'    => $regen_aclocal_m4,
4291      VERBOSE               => verbose_flag ('GEN'));
4292
4293   if ($relative_dir eq '.')
4294     {
4295       &push_dist_common ('acconfig.h')
4296         if -f 'acconfig.h';
4297     }
4298
4299   # If we have a configure header, require it.
4300   my $hdr_index = 0;
4301   my @distclean_config;
4302   foreach my $spec (@config_headers)
4303     {
4304       $hdr_index += 1;
4305       # $CONFIG_H_PATH: config.h from top level.
4306       my ($config_h_path, @ins) = split_config_file_spec ($spec);
4307       my $config_h_dir = dirname ($config_h_path);
4308
4309       # If the header is in the current directory we want to build
4310       # the header here.  Otherwise, if we're at the topmost
4311       # directory and the header's directory doesn't have a
4312       # Makefile, then we also want to build the header.
4313       if ($relative_dir eq $config_h_dir
4314           || ($relative_dir eq '.' && ! &is_make_dir ($config_h_dir)))
4315         {
4316           my ($cn_sans_dir, $stamp_dir);
4317           if ($relative_dir eq $config_h_dir)
4318             {
4319               $cn_sans_dir = basename ($config_h_path);
4320               $stamp_dir = '';
4321             }
4322           else
4323             {
4324               $cn_sans_dir = $config_h_path;
4325               if ($config_h_dir eq '.')
4326                 {
4327                   $stamp_dir = '';
4328                 }
4329               else
4330                 {
4331                   $stamp_dir = $config_h_dir . '/';
4332                 }
4333             }
4334
4335           # This will also distribute all inputs.
4336           @ins = rewrite_inputs_into_dependencies ($config_h_path, @ins);
4337
4338           # Cannot define rebuild rules for filenames with shell variables.
4339           next if (substitute_ac_subst_variables $config_h_path) =~ /\$/;
4340
4341           # Header defined in this directory.
4342           my @files;
4343           if (-f $config_h_path . '.top')
4344             {
4345               push (@files, "$cn_sans_dir.top");
4346             }
4347           if (-f $config_h_path . '.bot')
4348             {
4349               push (@files, "$cn_sans_dir.bot");
4350             }
4351
4352           push_dist_common (@files);
4353
4354           # For now, acconfig.h can only appear in the top srcdir.
4355           if (-f 'acconfig.h')
4356             {
4357               push (@files, '$(top_srcdir)/acconfig.h');
4358             }
4359
4360           my $stamp = "${stamp_dir}stamp-h${hdr_index}";
4361           $output_rules .=
4362             file_contents ('remake-hdr',
4363                            new Automake::Location,
4364                            FILES            => "@files",
4365                            CONFIG_H         => $cn_sans_dir,
4366                            CONFIG_HIN       => $ins[0],
4367                            CONFIG_H_DEPS    => "@ins",
4368                            CONFIG_H_PATH    => $config_h_path,
4369                            STAMP            => "$stamp");
4370
4371           push @distclean_config, $cn_sans_dir, $stamp;
4372         }
4373     }
4374
4375   $output_rules .= file_contents ('clean-hdr',
4376                                   new Automake::Location,
4377                                   FILES => "@distclean_config")
4378     if @distclean_config;
4379
4380   # Distribute and define mkinstalldirs only if it is already present
4381   # in the package, for backward compatibility (some people may still
4382   # use $(mkinstalldirs)).
4383   my $mkidpath = "$config_aux_dir/mkinstalldirs";
4384   if (-f $mkidpath)
4385     {
4386       # Use require_file so that any existing script gets updated
4387       # by --force-missing.
4388       require_conf_file ($mkidpath, FOREIGN, 'mkinstalldirs');
4389       define_variable ('mkinstalldirs',
4390                        "\$(SHELL) $am_config_aux_dir/mkinstalldirs", INTERNAL);
4391     }
4392   else
4393     {
4394       # Use $(install_sh), not $(MKDIR_P) because the latter requires
4395       # at least one argument, and $(mkinstalldirs) used to work
4396       # even without arguments (e.g. $(mkinstalldirs) $(conditional_dir)).
4397       define_variable ('mkinstalldirs', '$(install_sh) -d', INTERNAL);
4398     }
4399
4400   reject_var ('CONFIG_HEADER',
4401               "`CONFIG_HEADER' is an anachronism; now determined "
4402               . "automatically\nfrom `$configure_ac'");
4403
4404   my @config_h;
4405   foreach my $spec (@config_headers)
4406     {
4407       my ($out, @ins) = split_config_file_spec ($spec);
4408       # Generate CONFIG_HEADER define.
4409       if ($relative_dir eq dirname ($out))
4410         {
4411           push @config_h, basename ($out);
4412         }
4413       else
4414         {
4415           push @config_h, "\$(top_builddir)/$out";
4416         }
4417     }
4418   define_variable ("CONFIG_HEADER", "@config_h", INTERNAL)
4419     if @config_h;
4420
4421   # Now look for other files in this directory which must be remade
4422   # by config.status, and generate rules for them.
4423   my @actual_other_files = ();
4424   # These get cleaned only in a VPATH build.
4425   my @actual_other_vpath_files = ();
4426   foreach my $lfile (@other_input_files)
4427     {
4428       my $file;
4429       my @inputs;
4430       if ($lfile =~ /^([^:]*):(.*)$/)
4431         {
4432           # This is the ":" syntax of AC_OUTPUT.
4433           $file = $1;
4434           @inputs = split (':', $2);
4435         }
4436       else
4437         {
4438           # Normal usage.
4439           $file = $lfile;
4440           @inputs = $file . '.in';
4441         }
4442
4443       # Automake files should not be stored in here, but in %MAKE_LIST.
4444       prog_error ("$lfile in \@other_input_files\n"
4445                   . "\@other_input_files = (@other_input_files)")
4446         if -f $file . '.am';
4447
4448       my $local = basename ($file);
4449
4450       # We skip files that aren't in this directory.  However, if
4451       # the file's directory does not have a Makefile, and we are
4452       # currently doing `.', then we create a rule to rebuild the
4453       # file in the subdir.
4454       my $fd = dirname ($file);
4455       if ($fd ne $relative_dir)
4456         {
4457           if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4458             {
4459               $local = $file;
4460             }
4461           else
4462             {
4463               next;
4464             }
4465         }
4466
4467       my @rewritten_inputs = rewrite_inputs_into_dependencies ($file, @inputs);
4468
4469       # Cannot output rules for shell variables.
4470       next if (substitute_ac_subst_variables $local) =~ /\$/;
4471
4472       my $condstr = '';
4473       my $cond = $ac_config_files_condition{$lfile};
4474       if (defined $cond)
4475         {
4476           $condstr = $cond->subst_string;
4477           Automake::Rule::define ($local, $configure_ac, RULE_AUTOMAKE, $cond,
4478                                   $ac_config_files_location{$file});
4479         }
4480       $output_rules .= ($condstr . $local . ': '
4481                         . '$(top_builddir)/config.status '
4482                         . "@rewritten_inputs\n"
4483                         . $condstr . "\t"
4484                         . 'cd $(top_builddir) && '
4485                         . '$(SHELL) ./config.status '
4486                         . ($relative_dir eq '.' ? '' : '$(subdir)/')
4487                         . '$@'
4488                         . "\n");
4489       push (@actual_other_files, $local);
4490     }
4491
4492   # For links we should clean destinations and distribute sources.
4493   foreach my $spec (@config_links)
4494     {
4495       my ($link, $file) = split /:/, $spec;
4496       # Some people do AC_CONFIG_LINKS($computed).  We only handle
4497       # the DEST:SRC form.
4498       next unless $file;
4499       my $where = $ac_config_files_location{$link};
4500
4501       # Skip destinations that contain shell variables.
4502       if ((substitute_ac_subst_variables $link) !~ /\$/)
4503         {
4504           # We skip links that aren't in this directory.  However, if
4505           # the link's directory does not have a Makefile, and we are
4506           # currently doing `.', then we add the link to CONFIG_CLEAN_FILES
4507           # in `.'s Makefile.in.
4508           my $local = basename ($link);
4509           my $fd = dirname ($link);
4510           if ($fd ne $relative_dir)
4511             {
4512               if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4513                 {
4514                   $local = $link;
4515                 }
4516               else
4517                 {
4518                   $local = undef;
4519                 }
4520             }
4521           if ($file ne $link)
4522             {
4523               push @actual_other_files, $local if $local;
4524             }
4525           else
4526             {
4527               push @actual_other_vpath_files, $local if $local;
4528             }
4529         }
4530
4531       # Do not process sources that contain shell variables.
4532       if ((substitute_ac_subst_variables $file) !~ /\$/)
4533         {
4534           my $fd = dirname ($file);
4535
4536           # We distribute files that are in this directory.
4537           # At the top-level (`.') we also distribute files whose
4538           # directory does not have a Makefile.
4539           if (($fd eq $relative_dir)
4540               || ($relative_dir eq '.' && ! &is_make_dir ($fd)))
4541             {
4542               # The following will distribute $file as a side-effect when
4543               # it is appropriate (i.e., when $file is not already an output).
4544               # We do not need the result, just the side-effect.
4545               rewrite_inputs_into_dependencies ($link, $file);
4546             }
4547         }
4548     }
4549
4550   # These files get removed by "make distclean".
4551   define_pretty_variable ('CONFIG_CLEAN_FILES', TRUE, INTERNAL,
4552                           @actual_other_files);
4553   define_pretty_variable ('CONFIG_CLEAN_VPATH_FILES', TRUE, INTERNAL,
4554                           @actual_other_vpath_files);
4555 }
4556
4557 # Handle C headers.
4558 sub handle_headers
4559 {
4560     my @r = &am_install_var ('-defaultdist', 'header', 'HEADERS', 'include',
4561                              'oldinclude', 'pkginclude',
4562                              'noinst', 'check');
4563     foreach (@r)
4564     {
4565       next unless $_->[1] =~ /\..*$/;
4566       &saw_extension ($&);
4567     }
4568 }
4569
4570 sub handle_gettext
4571 {
4572   return if ! $seen_gettext || $relative_dir ne '.';
4573
4574   my $subdirs = var 'SUBDIRS';
4575
4576   if (! $subdirs)
4577     {
4578       err_ac "AM_GNU_GETTEXT used but SUBDIRS not defined";
4579       return;
4580     }
4581
4582   # Perform some sanity checks to help users get the right setup.
4583   # We disable these tests when po/ doesn't exist in order not to disallow
4584   # unusual gettext setups.
4585   #
4586   # Bruno Haible:
4587   # | The idea is:
4588   # |
4589   # |  1) If a package doesn't have a directory po/ at top level, it
4590   # |     will likely have multiple po/ directories in subpackages.
4591   # |
4592   # |  2) It is useful to warn for the absence of intl/ if AM_GNU_GETTEXT
4593   # |     is used without 'external'. It is also useful to warn for the
4594   # |     presence of intl/ if AM_GNU_GETTEXT([external]) is used. Both
4595   # |     warnings apply only to the usual layout of packages, therefore
4596   # |     they should both be disabled if no po/ directory is found at
4597   # |     top level.
4598
4599   if (-d 'po')
4600     {
4601       my @subdirs = $subdirs->value_as_list_recursive;
4602
4603       msg_var ('syntax', $subdirs,
4604                "AM_GNU_GETTEXT used but `po' not in SUBDIRS")
4605         if ! grep ($_ eq 'po', @subdirs);
4606
4607       # intl/ is not required when AM_GNU_GETTEXT is called with the
4608       # `external' option and AM_GNU_GETTEXT_INTL_SUBDIR is not called.
4609       msg_var ('syntax', $subdirs,
4610                "AM_GNU_GETTEXT used but `intl' not in SUBDIRS")
4611         if (! ($seen_gettext_external && ! $seen_gettext_intl)
4612             && ! grep ($_ eq 'intl', @subdirs));
4613
4614       # intl/ should not be used with AM_GNU_GETTEXT([external]), except
4615       # if AM_GNU_GETTEXT_INTL_SUBDIR is called.
4616       msg_var ('syntax', $subdirs,
4617                "`intl' should not be in SUBDIRS when "
4618                . "AM_GNU_GETTEXT([external]) is used")
4619         if ($seen_gettext_external && ! $seen_gettext_intl
4620             && grep ($_ eq 'intl', @subdirs));
4621     }
4622
4623   require_file ($ac_gettext_location, GNU, 'ABOUT-NLS');
4624 }
4625
4626 # Handle footer elements.
4627 sub handle_footer
4628 {
4629     reject_rule ('.SUFFIXES',
4630                  "use variable `SUFFIXES', not target `.SUFFIXES'");
4631
4632     # Note: AIX 4.1 /bin/make will fail if any suffix rule appears
4633     # before .SUFFIXES.  So we make sure that .SUFFIXES appears before
4634     # anything else, by sticking it right after the default: target.
4635     $output_header .= ".SUFFIXES:\n";
4636     my $suffixes = var 'SUFFIXES';
4637     my @suffixes = Automake::Rule::suffixes;
4638     if (@suffixes || $suffixes)
4639     {
4640         # Make sure SUFFIXES has unique elements.  Sort them to ensure
4641         # the output remains consistent.  However, $(SUFFIXES) is
4642         # always at the start of the list, unsorted.  This is done
4643         # because make will choose rules depending on the ordering of
4644         # suffixes, and this lets the user have some control.  Push
4645         # actual suffixes, and not $(SUFFIXES).  Some versions of make
4646         # do not like variable substitutions on the .SUFFIXES line.
4647         my @user_suffixes = ($suffixes
4648                              ? $suffixes->value_as_list_recursive : ());
4649
4650         my %suffixes = map { $_ => 1 } @suffixes;
4651         delete @suffixes{@user_suffixes};
4652
4653         $output_header .= (".SUFFIXES: "
4654                            . join (' ', @user_suffixes, sort keys %suffixes)
4655                            . "\n");
4656     }
4657
4658     $output_trailer .= file_contents ('footer', new Automake::Location);
4659 }
4660
4661
4662 # Generate `make install' rules.
4663 sub handle_install ()
4664 {
4665   $output_rules .= &file_contents
4666     ('install',
4667      new Automake::Location,
4668      maybe_BUILT_SOURCES => (set_seen ('BUILT_SOURCES')
4669                              ? (" \$(BUILT_SOURCES)\n"
4670                                 . "\t\$(MAKE) \$(AM_MAKEFLAGS)")
4671                              : ''),
4672      'installdirs-local' => (user_phony_rule 'installdirs-local'
4673                              ? ' installdirs-local' : ''),
4674      am__installdirs => variable_value ('am__installdirs') || '');
4675 }
4676
4677
4678 # Deal with all and all-am.
4679 sub handle_all ($)
4680 {
4681     my ($makefile) = @_;
4682
4683     # Output `all-am'.
4684
4685     # Put this at the beginning for the sake of non-GNU makes.  This
4686     # is still wrong if these makes can run parallel jobs.  But it is
4687     # right enough.
4688     unshift (@all, basename ($makefile));
4689
4690     foreach my $spec (@config_headers)
4691       {
4692         my ($out, @ins) = split_config_file_spec ($spec);
4693         push (@all, basename ($out))
4694           if dirname ($out) eq $relative_dir;
4695       }
4696
4697     # Install `all' hooks.
4698     push (@all, "all-local")
4699       if user_phony_rule "all-local";
4700
4701     &pretty_print_rule ("all-am:", "\t\t", @all);
4702     &depend ('.PHONY', 'all-am', 'all');
4703
4704
4705     # Output `all'.
4706
4707     my @local_headers = ();
4708     push @local_headers, '$(BUILT_SOURCES)'
4709       if var ('BUILT_SOURCES');
4710     foreach my $spec (@config_headers)
4711       {
4712         my ($out, @ins) = split_config_file_spec ($spec);
4713         push @local_headers, basename ($out)
4714           if dirname ($out) eq $relative_dir;
4715       }
4716
4717     if (@local_headers)
4718       {
4719         # We need to make sure config.h is built before we recurse.
4720         # We also want to make sure that built sources are built
4721         # before any ordinary `all' targets are run.  We can't do this
4722         # by changing the order of dependencies to the "all" because
4723         # that breaks when using parallel makes.  Instead we handle
4724         # things explicitly.
4725         $output_all .= ("all: @local_headers"
4726                         . "\n\t"
4727                         . '$(MAKE) $(AM_MAKEFLAGS) '
4728                         . (var ('SUBDIRS') ? 'all-recursive' : 'all-am')
4729                         . "\n\n");
4730         depend ('.MAKE', 'all');
4731       }
4732     else
4733       {
4734         $output_all .= "all: " . (var ('SUBDIRS')
4735                                   ? 'all-recursive' : 'all-am') . "\n\n";
4736       }
4737 }
4738
4739
4740 # &do_check_merge_target ()
4741 # -------------------------
4742 # Handle check merge target specially.
4743 sub do_check_merge_target ()
4744 {
4745   # Include user-defined local form of target.
4746   push @check_tests, 'check-local'
4747     if user_phony_rule 'check-local';
4748
4749   # In --cygnus mode, check doesn't depend on all.
4750   if (option 'cygnus')
4751     {
4752       # Just run the local check rules.
4753       pretty_print_rule ('check-am:', "\t\t", @check);
4754     }
4755   else
4756     {
4757       # The check target must depend on the local equivalent of
4758       # `all', to ensure all the primary targets are built.  Then it
4759       # must build the local check rules.
4760       $output_rules .= "check-am: all-am\n";
4761       if (@check)
4762         {
4763           pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4764                              @check);
4765           depend ('.MAKE', 'check-am');
4766         }
4767     }
4768   if (@check_tests)
4769     {
4770       pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4771                          @check_tests);
4772       depend ('.MAKE', 'check-am');
4773     }
4774
4775   depend '.PHONY', 'check', 'check-am';
4776   # Handle recursion.  We have to honor BUILT_SOURCES like for `all:'.
4777   $output_rules .= ("check: "
4778                     . (var ('BUILT_SOURCES')
4779                        ? "\$(BUILT_SOURCES)\n\t\$(MAKE) \$(AM_MAKEFLAGS) "
4780                        : '')
4781                     . (var ('SUBDIRS') ? 'check-recursive' : 'check-am')
4782                     . "\n");
4783   depend ('.MAKE', 'check')
4784     if var ('BUILT_SOURCES');
4785 }
4786
4787 # handle_clean ($MAKEFILE)
4788 # ------------------------
4789 # Handle all 'clean' targets.
4790 sub handle_clean ($)
4791 {
4792   my ($makefile) = @_;
4793
4794   # Clean the files listed in user variables if they exist.
4795   $clean_files{'$(MOSTLYCLEANFILES)'} = MOSTLY_CLEAN
4796     if var ('MOSTLYCLEANFILES');
4797   $clean_files{'$(CLEANFILES)'} = CLEAN
4798     if var ('CLEANFILES');
4799   $clean_files{'$(DISTCLEANFILES)'} = DIST_CLEAN
4800     if var ('DISTCLEANFILES');
4801   $clean_files{'$(MAINTAINERCLEANFILES)'} = MAINTAINER_CLEAN
4802     if var ('MAINTAINERCLEANFILES');
4803
4804   # Built sources are automatically removed by maintainer-clean.
4805   $clean_files{'$(BUILT_SOURCES)'} = MAINTAINER_CLEAN
4806     if var ('BUILT_SOURCES');
4807
4808   # Compute a list of "rm"s to run for each target.
4809   my %rms = (MOSTLY_CLEAN, [],
4810              CLEAN, [],
4811              DIST_CLEAN, [],
4812              MAINTAINER_CLEAN, []);
4813
4814   foreach my $file (keys %clean_files)
4815     {
4816       my $when = $clean_files{$file};
4817       prog_error 'invalid entry in %clean_files'
4818         unless exists $rms{$when};
4819
4820       my $rm = "rm -f $file";
4821       # If file is a variable, make sure when don't call `rm -f' without args.
4822       $rm ="test -z \"$file\" || $rm"
4823         if ($file =~ /^\s*\$(\(.*\)|\{.*\})\s*$/);
4824
4825       push @{$rms{$when}}, "\t-$rm\n";
4826     }
4827
4828   $output_rules .= &file_contents
4829     ('clean',
4830      new Automake::Location,
4831      MOSTLYCLEAN_RMS      => join ('', sort @{$rms{&MOSTLY_CLEAN}}),
4832      CLEAN_RMS            => join ('', sort @{$rms{&CLEAN}}),
4833      DISTCLEAN_RMS        => join ('', sort @{$rms{&DIST_CLEAN}}),
4834      MAINTAINER_CLEAN_RMS => join ('', sort @{$rms{&MAINTAINER_CLEAN}}),
4835      MAKEFILE             => basename $makefile,
4836      );
4837 }
4838
4839
4840 # &target_cmp ($A, $B)
4841 # --------------------
4842 # Subroutine for &handle_factored_dependencies to let `.PHONY' and
4843 # other `.TARGETS' be last.
4844 sub target_cmp
4845 {
4846   return 0 if $a eq $b;
4847
4848   my $a1 = substr ($a, 0, 1);
4849   my $b1 = substr ($b, 0, 1);
4850   if ($a1 ne $b1)
4851     {
4852       return -1 if $b1 eq '.';
4853       return 1 if $a1 eq '.';
4854     }
4855   return $a cmp $b;
4856 }
4857
4858
4859 # &handle_factored_dependencies ()
4860 # --------------------------------
4861 # Handle everything related to gathered targets.
4862 sub handle_factored_dependencies
4863 {
4864   # Reject bad hooks.
4865   foreach my $utarg ('uninstall-data-local', 'uninstall-data-hook',
4866                      'uninstall-exec-local', 'uninstall-exec-hook',
4867                      'uninstall-dvi-local',
4868                      'uninstall-html-local',
4869                      'uninstall-info-local',
4870                      'uninstall-pdf-local',
4871                      'uninstall-ps-local')
4872     {
4873       my $x = $utarg;
4874       $x =~ s/-.*-/-/;
4875       reject_rule ($utarg, "use `$x', not `$utarg'");
4876     }
4877
4878   reject_rule ('install-local',
4879                "use `install-data-local' or `install-exec-local', "
4880                . "not `install-local'");
4881
4882   reject_rule ('install-hook',
4883                "use `install-data-hook' or `install-exec-hook', "
4884                . "not `install-hook'");
4885
4886   # Install the -local hooks.
4887   foreach (keys %dependencies)
4888     {
4889       # Hooks are installed on the -am targets.
4890       s/-am$// or next;
4891       depend ("$_-am", "$_-local")
4892         if user_phony_rule "$_-local";
4893     }
4894
4895   # Install the -hook hooks.
4896   # FIXME: Why not be as liberal as we are with -local hooks?
4897   foreach ('install-exec', 'install-data', 'uninstall')
4898     {
4899       if (user_phony_rule "$_-hook")
4900         {
4901           depend ('.MAKE', "$_-am");
4902           register_action("$_-am",
4903                           ("\t\@\$(NORMAL_INSTALL)\n"
4904                            . "\t\$(MAKE) \$(AM_MAKEFLAGS) $_-hook"));
4905         }
4906     }
4907
4908   # All the required targets are phony.
4909   depend ('.PHONY', keys %required_targets);
4910
4911   # Actually output gathered targets.
4912   foreach (sort target_cmp keys %dependencies)
4913     {
4914       # If there is nothing about this guy, skip it.
4915       next
4916         unless (@{$dependencies{$_}}
4917                 || $actions{$_}
4918                 || $required_targets{$_});
4919
4920       # Define gathered targets in undefined conditions.
4921       # FIXME: Right now we must handle .PHONY as an exception,
4922       # because people write things like
4923       #    .PHONY: myphonytarget
4924       # to append dependencies.  This would not work if Automake
4925       # refrained from defining its own .PHONY target as it does
4926       # with other overridden targets.
4927       # Likewise for `.MAKE'.
4928       my @undefined_conds = (TRUE,);
4929       if ($_ ne '.PHONY' && $_ ne '.MAKE')
4930         {
4931           @undefined_conds =
4932             Automake::Rule::define ($_, 'internal',
4933                                     RULE_AUTOMAKE, TRUE, INTERNAL);
4934         }
4935       my @uniq_deps = uniq (sort @{$dependencies{$_}});
4936       foreach my $cond (@undefined_conds)
4937         {
4938           my $condstr = $cond->subst_string;
4939           &pretty_print_rule ("$condstr$_:", "$condstr\t", @uniq_deps);
4940           $output_rules .= $actions{$_} if defined $actions{$_};
4941           $output_rules .= "\n";
4942         }
4943     }
4944 }
4945
4946
4947 # &handle_tests_dejagnu ()
4948 # ------------------------
4949 sub handle_tests_dejagnu
4950 {
4951     push (@check_tests, 'check-DEJAGNU');
4952     $output_rules .= file_contents ('dejagnu', new Automake::Location);
4953 }
4954
4955
4956 # Handle TESTS variable and other checks.
4957 sub handle_tests
4958 {
4959   if (option 'dejagnu')
4960     {
4961       &handle_tests_dejagnu;
4962     }
4963   else
4964     {
4965       foreach my $c ('DEJATOOL', 'RUNTEST', 'RUNTESTFLAGS')
4966         {
4967           reject_var ($c, "`$c' defined but `dejagnu' not in "
4968                       . "`AUTOMAKE_OPTIONS'");
4969         }
4970     }
4971
4972   if (var ('TESTS'))
4973     {
4974       push (@check_tests, 'check-TESTS');
4975       $output_rules .= &file_contents ('check', new Automake::Location,
4976                                        COLOR => !! option 'color-tests',
4977                                        PARALLEL_TESTS => !! option 'parallel-tests');
4978
4979       # Tests that are known programs should have $(EXEEXT) appended.
4980       # For matching purposes, we need to adjust XFAIL_TESTS as well.
4981       append_exeext { exists $known_programs{$_[0]} } 'TESTS';
4982       append_exeext { exists $known_programs{$_[0]} } 'XFAIL_TESTS'
4983         if (var ('XFAIL_TESTS'));
4984
4985       if (option 'parallel-tests')
4986         {
4987           define_variable ('TEST_SUITE_LOG', 'test-suite.log', INTERNAL);
4988           define_variable ('TEST_SUITE_HTML', '$(TEST_SUITE_LOG:.log=.html)', INTERNAL);
4989           my $suff = '.test';
4990           my $at_exeext = '';
4991           my $handle_exeext = exists $configure_vars{'EXEEXT'};
4992           if ($handle_exeext)
4993             {
4994               $at_exeext = subst ('EXEEXT');
4995               $suff = $at_exeext  . ' ' . $suff;
4996             }
4997           define_variable ('TEST_EXTENSIONS', $suff, INTERNAL);
4998           # FIXME: this mishandles conditions.
4999           my @test_suffixes = (var 'TEST_EXTENSIONS')->value_as_list_recursive;
5000           if ($handle_exeext)
5001             {
5002               unshift (@test_suffixes, $at_exeext)
5003                 unless $test_suffixes[0] eq $at_exeext;
5004             }
5005           unshift (@test_suffixes, '');
5006
5007           transform_variable_recursively
5008             ('TESTS', 'TEST_LOGS', 'am__testlogs', 1, INTERNAL,
5009               sub {
5010                 my ($subvar, $val, $cond, $full_cond) = @_;
5011                 my $obj = $val;
5012                 return $obj
5013                   if $val =~ /^\@.*\@$/;
5014                 $obj =~ s/\$\(EXEEXT\)$//o;
5015
5016                 if ($val =~ /(\$\((top_)?srcdir\))\//o)
5017                   {
5018                     msg ('error', $subvar->rdef ($cond)->location,
5019                          "parallel-tests: using `$1' in TESTS is currently broken: `$val'");
5020                   }
5021
5022                 foreach my $test_suffix (@test_suffixes)
5023                   {
5024                     next
5025                       if $test_suffix eq $at_exeext || $test_suffix eq '';
5026                     return substr ($obj, 0, length ($obj) - length ($test_suffix)) . '.log'
5027                       if substr ($obj, - length ($test_suffix)) eq $test_suffix;
5028                   }
5029                 $obj .= '.log';
5030                 my $compile = 'LOG_COMPILE';
5031                 define_variable ($compile,
5032                                  '$(LOG_COMPILER) $(AM_LOG_FLAGS) $(LOG_FLAGS)', INTERNAL);
5033                 $output_rules .= file_contents ('check2', new Automake::Location,
5034                                                 GENERIC => 0,
5035                                                 OBJ => $obj,
5036                                                 SOURCE => $val,
5037                                                 COMPILE =>'$(' . $compile . ')',
5038                                                 EXT => '',
5039                                                 am__EXEEXT => 'FALSE');
5040                 return $obj;
5041               });
5042
5043           my $nhelper=1;
5044           my $prev = 'TESTS';
5045           my $post = '';
5046           my $last_suffix = $test_suffixes[$#test_suffixes];
5047           my $cur = '';
5048           foreach my $test_suffix (@test_suffixes)
5049             {
5050               if ($test_suffix eq $last_suffix)
5051                 {
5052                   $cur = 'TEST_LOGS';
5053                 }
5054               else
5055                 {
5056                   $cur = 'am__test_logs' . $nhelper;
5057                 }
5058               define_variable ($cur,
5059                 '$(' . $prev . ':' . $test_suffix . $post . '=.log)', INTERNAL);
5060               $post = '.log';
5061               $prev = $cur;
5062               $nhelper++;
5063               if ($test_suffix ne $at_exeext && $test_suffix ne '')
5064                 {
5065                   (my $ext = $test_suffix) =~ s/^\.//;
5066                   $ext = uc $ext;
5067                   my $compile = $ext . '_LOG_COMPILE';
5068                   define_variable ($compile,
5069                                    '$(' . $ext . '_LOG_COMPILER) $(AM_' .  $ext . '_LOG_FLAGS)'
5070                                    . ' $(' . $ext . '_LOG_FLAGS)', INTERNAL);
5071                   my $am_exeext = $handle_exeext ? 'am__EXEEXT' : 'FALSE';
5072                   $output_rules .= file_contents ('check2', new Automake::Location,
5073                                                   GENERIC => 1,
5074                                                   OBJ => '',
5075                                                   SOURCE => '$<',
5076                                                   COMPILE => '$(' . $compile . ')',
5077                                                   EXT => $test_suffix,
5078                                                   am__EXEEXT => $am_exeext);
5079                 }
5080             }
5081
5082           define_variable ('TEST_LOGS_TMP', '$(TEST_LOGS:.log=.log-t)', INTERNAL);
5083
5084           $clean_files{'$(TEST_LOGS_TMP)'} = MOSTLY_CLEAN;
5085           $clean_files{'$(TEST_LOGS)'} = MOSTLY_CLEAN;
5086           $clean_files{'$(TEST_SUITE_LOG)'} = MOSTLY_CLEAN;
5087           $clean_files{'$(TEST_SUITE_HTML)'} = MOSTLY_CLEAN;
5088         }
5089     }
5090 }
5091
5092 # Handle Emacs Lisp.
5093 sub handle_emacs_lisp
5094 {
5095   my @elfiles = &am_install_var ('-candist', 'lisp', 'LISP',
5096                                  'lisp', 'noinst');
5097
5098   return if ! @elfiles;
5099
5100   define_pretty_variable ('am__ELFILES', TRUE, INTERNAL,
5101                           map { $_->[1] } @elfiles);
5102   define_pretty_variable ('am__ELCFILES', TRUE, INTERNAL,
5103                           '$(am__ELFILES:.el=.elc)');
5104   # This one can be overridden by users.
5105   define_pretty_variable ('ELCFILES', TRUE, INTERNAL, '$(LISP:.el=.elc)');
5106
5107   push @all, '$(ELCFILES)';
5108
5109   require_variables ($elfiles[0][0], "Emacs Lisp sources seen", TRUE,
5110                      'EMACS', 'lispdir');
5111   require_conf_file ($elfiles[0][0], FOREIGN, 'elisp-comp');
5112   &define_variable ('elisp_comp', "$am_config_aux_dir/elisp-comp", INTERNAL);
5113 }
5114
5115 # Handle Python
5116 sub handle_python
5117 {
5118   my @pyfiles = &am_install_var ('-defaultdist', 'python', 'PYTHON',
5119                                  'noinst');
5120   return if ! @pyfiles;
5121
5122   require_variables ($pyfiles[0][0], "Python sources seen", TRUE, 'PYTHON');
5123   require_conf_file ($pyfiles[0][0], FOREIGN, 'py-compile');
5124   &define_variable ('py_compile', "$am_config_aux_dir/py-compile", INTERNAL);
5125 }
5126
5127 # Handle Java.
5128 sub handle_java
5129 {
5130     my @sourcelist = &am_install_var ('-candist',
5131                                       'java', 'JAVA',
5132                                       'java', 'noinst', 'check');
5133     return if ! @sourcelist;
5134
5135     my @prefix = am_primary_prefixes ('JAVA', 1,
5136                                       'java', 'noinst', 'check');
5137
5138     my $dir;
5139     foreach my $curs (@prefix)
5140       {
5141         next
5142           if $curs eq 'EXTRA';
5143
5144         err_var "${curs}_JAVA", "multiple _JAVA primaries in use"
5145           if defined $dir;
5146         $dir = $curs;
5147       }
5148
5149
5150     push (@all, 'class' . $dir . '.stamp');
5151 }
5152
5153
5154 # Handle some of the minor options.
5155 sub handle_minor_options
5156 {
5157   if (option 'readme-alpha')
5158     {
5159       if ($relative_dir eq '.')
5160         {
5161           if ($package_version !~ /^$GNITS_VERSION_PATTERN$/)
5162             {
5163               msg ('error-gnits', $package_version_location,
5164                    "version `$package_version' doesn't follow " .
5165                    "Gnits standards");
5166             }
5167           if (defined $1 && -f 'README-alpha')
5168             {
5169               # This means we have an alpha release.  See
5170               # GNITS_VERSION_PATTERN for details.
5171               push_dist_common ('README-alpha');
5172             }
5173         }
5174     }
5175 }
5176
5177 ################################################################
5178
5179 # ($OUTPUT, @INPUTS)
5180 # &split_config_file_spec ($SPEC)
5181 # -------------------------------
5182 # Decode the Autoconf syntax for config files (files, headers, links
5183 # etc.).
5184 sub split_config_file_spec ($)
5185 {
5186   my ($spec) = @_;
5187   my ($output, @inputs) = split (/:/, $spec);
5188
5189   push @inputs, "$output.in"
5190     unless @inputs;
5191
5192   return ($output, @inputs);
5193 }
5194
5195 # $input
5196 # locate_am (@POSSIBLE_SOURCES)
5197 # -----------------------------
5198 # AC_CONFIG_FILES allow specifications such as Makefile:top.in:mid.in:bot.in
5199 # This functions returns the first *.in file for which a *.am exists.
5200 # It returns undef otherwise.
5201 sub locate_am (@)
5202 {
5203   my (@rest) = @_;
5204   my $input;
5205   foreach my $file (@rest)
5206     {
5207       if (($file =~ /^(.*)\.in$/) && -f "$1.am")
5208         {
5209           $input = $file;
5210           last;
5211         }
5212     }
5213   return $input;
5214 }
5215
5216 my %make_list;
5217
5218 # &scan_autoconf_config_files ($WHERE, $CONFIG-FILES)
5219 # ---------------------------------------------------
5220 # Study $CONFIG-FILES which is the first argument to AC_CONFIG_FILES
5221 # (or AC_OUTPUT).
5222 sub scan_autoconf_config_files ($$)
5223 {
5224   my ($where, $config_files) = @_;
5225
5226   # Look at potential Makefile.am's.
5227   foreach (split ' ', $config_files)
5228     {
5229       # Must skip empty string for Perl 4.
5230       next if $_ eq "\\" || $_ eq '';
5231
5232       # Handle $local:$input syntax.
5233       my ($local, @rest) = split (/:/);
5234       @rest = ("$local.in",) unless @rest;
5235       msg ('portability', $where,
5236           "omit leading `./' from config file names such as `$local',"
5237           . "\nas not all make implementations treat `file' and `./file' equally")
5238         if ($local =~ /^\.\//);
5239       my $input = locate_am @rest;
5240       if ($input)
5241         {
5242           # We have a file that automake should generate.
5243           $make_list{$input} = join (':', ($local, @rest));
5244         }
5245       else
5246         {
5247           # We have a file that automake should cause to be
5248           # rebuilt, but shouldn't generate itself.
5249           push (@other_input_files, $_);
5250         }
5251       $ac_config_files_location{$local} = $where;
5252       $ac_config_files_condition{$local} =
5253         new Automake::Condition (@cond_stack)
5254           if (@cond_stack);
5255     }
5256 }
5257
5258
5259 # &scan_autoconf_traces ($FILENAME)
5260 # ---------------------------------
5261 sub scan_autoconf_traces ($)
5262 {
5263   my ($filename) = @_;
5264
5265   # Macros to trace, with their minimal number of arguments.
5266   #
5267   # IMPORTANT: If you add a macro here, you should also add this macro
5268   # =========  to Automake-preselection in autoconf/lib/autom4te.in.
5269   my %traced = (
5270                 AC_CANONICAL_BUILD => 0,
5271                 AC_CANONICAL_HOST => 0,
5272                 AC_CANONICAL_TARGET => 0,
5273                 AC_CONFIG_AUX_DIR => 1,
5274                 AC_CONFIG_FILES => 1,
5275                 AC_CONFIG_HEADERS => 1,
5276                 AC_CONFIG_LIBOBJ_DIR => 1,
5277                 AC_CONFIG_LINKS => 1,
5278                 AC_FC_SRCEXT => 1,
5279                 AC_INIT => 0,
5280                 AC_LIBSOURCE => 1,
5281                 AC_REQUIRE_AUX_FILE => 1,
5282                 AC_SUBST_TRACE => 1,
5283                 AM_AUTOMAKE_VERSION => 1,
5284                 AM_CONDITIONAL => 2,
5285                 AM_ENABLE_MULTILIB => 0,
5286                 AM_GNU_GETTEXT => 0,
5287                 AM_GNU_GETTEXT_INTL_SUBDIR => 0,
5288                 AM_INIT_AUTOMAKE => 0,
5289                 AM_MAINTAINER_MODE => 0,
5290                 AM_PROG_CC_C_O => 0,
5291                 AM_SILENT_RULES => 0,
5292                 _AM_SUBST_NOTMAKE => 1,
5293                 _AM_COND_IF => 1,
5294                 _AM_COND_ELSE => 1,
5295                 _AM_COND_ENDIF => 1,
5296                 LT_SUPPORTED_TAG => 1,
5297                 _LT_AC_TAGCONFIG => 0,
5298                 m4_include => 1,
5299                 m4_sinclude => 1,
5300                 sinclude => 1,
5301               );
5302
5303   my $traces = ($ENV{AUTOCONF} || 'autoconf') . " ";
5304
5305   # Use a separator unlikely to be used, not `:', the default, which
5306   # has a precise meaning for AC_CONFIG_FILES and so on.
5307   $traces .= join (' ',
5308                    map { "--trace=$_" . ':\$f:\$l::\$d::\$n::\${::}%' }
5309                    (keys %traced));
5310
5311   my $tracefh = new Automake::XFile ("$traces $filename |");
5312   verb "reading $traces";
5313
5314   @cond_stack = ();
5315   my $where;
5316
5317   while ($_ = $tracefh->getline)
5318     {
5319       chomp;
5320       my ($here, $depth, @args) = split (/::/);
5321       $where = new Automake::Location $here;
5322       my $macro = $args[0];
5323
5324       prog_error ("unrequested trace `$macro'")
5325         unless exists $traced{$macro};
5326
5327       # Skip and diagnose malformed calls.
5328       if ($#args < $traced{$macro})
5329         {
5330           msg ('syntax', $where, "not enough arguments for $macro");
5331           next;
5332         }
5333
5334       # Alphabetical ordering please.
5335       if ($macro eq 'AC_CANONICAL_BUILD')
5336         {
5337           if ($seen_canonical <= AC_CANONICAL_BUILD)
5338             {
5339               $seen_canonical = AC_CANONICAL_BUILD;
5340               $canonical_location = $where;
5341             }
5342         }
5343       elsif ($macro eq 'AC_CANONICAL_HOST')
5344         {
5345           if ($seen_canonical <= AC_CANONICAL_HOST)
5346             {
5347               $seen_canonical = AC_CANONICAL_HOST;
5348               $canonical_location = $where;
5349             }
5350         }
5351       elsif ($macro eq 'AC_CANONICAL_TARGET')
5352         {
5353           $seen_canonical = AC_CANONICAL_TARGET;
5354           $canonical_location = $where;
5355         }
5356       elsif ($macro eq 'AC_CONFIG_AUX_DIR')
5357         {
5358           if ($seen_init_automake)
5359             {
5360               error ($where, "AC_CONFIG_AUX_DIR must be called before "
5361                      . "AM_INIT_AUTOMAKE ...", partial => 1);
5362               error ($seen_init_automake, "... AM_INIT_AUTOMAKE called here");
5363             }
5364           $config_aux_dir = $args[1];
5365           $config_aux_dir_set_in_configure_ac = 1;
5366           $relative_dir = '.';
5367           check_directory ($config_aux_dir, $where);
5368         }
5369       elsif ($macro eq 'AC_CONFIG_FILES')
5370         {
5371           # Look at potential Makefile.am's.
5372           scan_autoconf_config_files ($where, $args[1]);
5373         }
5374       elsif ($macro eq 'AC_CONFIG_HEADERS')
5375         {
5376           foreach my $spec (split (' ', $args[1]))
5377             {
5378               my ($dest, @src) = split (':', $spec);
5379               $ac_config_files_location{$dest} = $where;
5380               push @config_headers, $spec;
5381             }
5382         }
5383       elsif ($macro eq 'AC_CONFIG_LIBOBJ_DIR')
5384         {
5385           $config_libobj_dir = $args[1];
5386           $relative_dir = '.';
5387           check_directory ($config_libobj_dir, $where);
5388         }
5389       elsif ($macro eq 'AC_CONFIG_LINKS')
5390         {
5391           foreach my $spec (split (' ', $args[1]))
5392             {
5393               my ($dest, $src) = split (':', $spec);
5394               $ac_config_files_location{$dest} = $where;
5395               push @config_links, $spec;
5396             }
5397         }
5398       elsif ($macro eq 'AC_FC_SRCEXT')
5399         {
5400           my $suffix = $args[1];
5401           # These flags are used as %SOURCEFLAG% in depend2.am,
5402           # where the trailing space is important.
5403           $sourceflags{'.' . $suffix} = '$(FCFLAGS_' . $suffix . ') '
5404             if ($suffix eq 'f90' || $suffix eq 'f95' || $suffix eq 'f03' || $suffix eq 'f08');
5405         }
5406       elsif ($macro eq 'AC_INIT')
5407         {
5408           if (defined $args[2])
5409             {
5410               $package_version = $args[2];
5411               $package_version_location = $where;
5412             }
5413         }
5414       elsif ($macro eq 'AC_LIBSOURCE')
5415         {
5416           $libsources{$args[1]} = $here;
5417         }
5418       elsif ($macro eq 'AC_REQUIRE_AUX_FILE')
5419         {
5420           # Only remember the first time a file is required.
5421           $required_aux_file{$args[1]} = $where
5422             unless exists $required_aux_file{$args[1]};
5423         }
5424       elsif ($macro eq 'AC_SUBST_TRACE')
5425         {
5426           # Just check for alphanumeric in AC_SUBST_TRACE.  If you do
5427           # AC_SUBST(5), then too bad.
5428           $configure_vars{$args[1]} = $where
5429             if $args[1] =~ /^\w+$/;
5430         }
5431       elsif ($macro eq 'AM_AUTOMAKE_VERSION')
5432         {
5433           error ($where,
5434                  "version mismatch.  This is Automake $VERSION,\n" .
5435                  "but the definition used by this AM_INIT_AUTOMAKE\n" .
5436                  "comes from Automake $args[1].  You should recreate\n" .
5437                  "aclocal.m4 with aclocal and run automake again.\n",
5438                  # $? = 63 is used to indicate version mismatch to missing.
5439                  exit_code => 63)
5440             if $VERSION ne $args[1];
5441
5442           $seen_automake_version = 1;
5443         }
5444       elsif ($macro eq 'AM_CONDITIONAL')
5445         {
5446           $configure_cond{$args[1]} = $where;
5447         }
5448       elsif ($macro eq 'AM_ENABLE_MULTILIB')
5449         {
5450           $seen_multilib = $where;
5451         }
5452       elsif ($macro eq 'AM_GNU_GETTEXT')
5453         {
5454           $seen_gettext = $where;
5455           $ac_gettext_location = $where;
5456           $seen_gettext_external = grep ($_ eq 'external', @args);
5457         }
5458       elsif ($macro eq 'AM_GNU_GETTEXT_INTL_SUBDIR')
5459         {
5460           $seen_gettext_intl = $where;
5461         }
5462       elsif ($macro eq 'AM_INIT_AUTOMAKE')
5463         {
5464           $seen_init_automake = $where;
5465           if (defined $args[2])
5466             {
5467               $package_version = $args[2];
5468               $package_version_location = $where;
5469             }
5470           elsif (defined $args[1])
5471             {
5472               exit $exit_code
5473                 if (process_global_option_list ($where,
5474                                                 split (' ', $args[1])));
5475             }
5476         }
5477       elsif ($macro eq 'AM_MAINTAINER_MODE')
5478         {
5479           $seen_maint_mode = $where;
5480         }
5481       elsif ($macro eq 'AM_PROG_CC_C_O')
5482         {
5483           $seen_cc_c_o = $where;
5484         }
5485       elsif ($macro eq 'AM_SILENT_RULES')
5486         {
5487           set_global_option ('silent-rules', $where);
5488         }
5489       elsif ($macro eq '_AM_COND_IF')
5490         {
5491           cond_stack_if ('', $args[1], $where);
5492           error ($where, "missing m4 quoting, macro depth $depth")
5493             if ($depth != 1);
5494         }
5495       elsif ($macro eq '_AM_COND_ELSE')
5496         {
5497           cond_stack_else ('!', $args[1], $where);
5498           error ($where, "missing m4 quoting, macro depth $depth")
5499             if ($depth != 1);
5500         }
5501       elsif ($macro eq '_AM_COND_ENDIF')
5502         {
5503           cond_stack_endif (undef, undef, $where);
5504           error ($where, "missing m4 quoting, macro depth $depth")
5505             if ($depth != 1);
5506         }
5507       elsif ($macro eq '_AM_SUBST_NOTMAKE')
5508         {
5509           $ignored_configure_vars{$args[1]} = $where;
5510         }
5511       elsif ($macro eq 'm4_include'
5512              || $macro eq 'm4_sinclude'
5513              || $macro eq 'sinclude')
5514         {
5515           # Skip missing `sinclude'd files.
5516           next if $macro ne 'm4_include' && ! -f $args[1];
5517
5518           # Some modified versions of Autoconf don't use
5519           # frozen files.  Consequently it's possible that we see all
5520           # m4_include's performed during Autoconf's startup.
5521           # Obviously we don't want to distribute Autoconf's files
5522           # so we skip absolute filenames here.
5523           push @configure_deps, '$(top_srcdir)/' . $args[1]
5524             unless $here =~ m,^(?:\w:)?[\\/],;
5525           # Keep track of the greatest timestamp.
5526           if (-e $args[1])
5527             {
5528               my $mtime = mtime $args[1];
5529               $configure_deps_greatest_timestamp = $mtime
5530                 if $mtime > $configure_deps_greatest_timestamp;
5531             }
5532         }
5533       elsif ($macro eq 'LT_SUPPORTED_TAG')
5534         {
5535           $libtool_tags{$args[1]} = 1;
5536           $libtool_new_api = 1;
5537         }
5538       elsif ($macro eq '_LT_AC_TAGCONFIG')
5539         {
5540           # _LT_AC_TAGCONFIG is an old macro present in Libtool 1.5.
5541           # We use it to detect whether tags are supported.  Our
5542           # preferred interface is LT_SUPPORTED_TAG, but it was
5543           # introduced in Libtool 1.6.
5544           if (0 == keys %libtool_tags)
5545             {
5546               # Hardcode the tags supported by Libtool 1.5.
5547               %libtool_tags = (CC => 1, CXX => 1, GCJ => 1, F77 => 1);
5548             }
5549         }
5550     }
5551
5552   error ($where, "condition stack not properly closed")
5553     if (@cond_stack);
5554
5555   $tracefh->close;
5556 }
5557
5558
5559 # &scan_autoconf_files ()
5560 # -----------------------
5561 # Check whether we use `configure.ac' or `configure.in'.
5562 # Scan it (and possibly `aclocal.m4') for interesting things.
5563 # We must scan aclocal.m4 because there might be AC_SUBSTs and such there.
5564 sub scan_autoconf_files ()
5565 {
5566   # Reinitialize libsources here.  This isn't really necessary,
5567   # since we currently assume there is only one configure.ac.  But
5568   # that won't always be the case.
5569   %libsources = ();
5570
5571   # Keep track of the youngest configure dependency.
5572   $configure_deps_greatest_timestamp = mtime $configure_ac;
5573   if (-e 'aclocal.m4')
5574     {
5575       my $mtime = mtime 'aclocal.m4';
5576       $configure_deps_greatest_timestamp = $mtime
5577         if $mtime > $configure_deps_greatest_timestamp;
5578     }
5579
5580   scan_autoconf_traces ($configure_ac);
5581
5582   @configure_input_files = sort keys %make_list;
5583   # Set input and output files if not specified by user.
5584   if (! @input_files)
5585     {
5586       @input_files = @configure_input_files;
5587       %output_files = %make_list;
5588     }
5589
5590
5591   if (! $seen_init_automake)
5592     {
5593       err_ac ("no proper invocation of AM_INIT_AUTOMAKE was found.\nYou "
5594               . "should verify that $configure_ac invokes AM_INIT_AUTOMAKE,"
5595               . "\nthat aclocal.m4 is present in the top-level directory,\n"
5596               . "and that aclocal.m4 was recently regenerated "
5597               . "(using aclocal)");
5598     }
5599   else
5600     {
5601       if (! $seen_automake_version)
5602         {
5603           if (-f 'aclocal.m4')
5604             {
5605               error ($seen_init_automake,
5606                      "your implementation of AM_INIT_AUTOMAKE comes from " .
5607                      "an\nold Automake version.  You should recreate " .
5608                      "aclocal.m4\nwith aclocal and run automake again",
5609                      # $? = 63 is used to indicate version mismatch to missing.
5610                      exit_code => 63);
5611             }
5612           else
5613             {
5614               error ($seen_init_automake,
5615                      "no proper implementation of AM_INIT_AUTOMAKE was " .
5616                      "found,\nprobably because aclocal.m4 is missing.\n" .
5617                      "You should run aclocal to create this file, then\n" .
5618                      "run automake again");
5619             }
5620         }
5621     }
5622
5623   locate_aux_dir ();
5624
5625   # Reorder @input_files so that the Makefile that distributes aux
5626   # files is processed last.  This is important because each directory
5627   # can require auxiliary scripts and we should wait until they have
5628   # been installed before distributing them.
5629
5630   # The Makefile.in that distribute the aux files is the one in
5631   # $config_aux_dir or the top-level Makefile.
5632   my $auxdirdist = is_make_dir ($config_aux_dir) ? $config_aux_dir : '.';
5633   my @new_input_files = ();
5634   while (@input_files)
5635     {
5636       my $in = pop @input_files;
5637       my @ins = split (/:/, $output_files{$in});
5638       if (dirname ($ins[0]) eq $auxdirdist)
5639         {
5640           push @new_input_files, $in;
5641           $automake_will_process_aux_dir = 1;
5642         }
5643       else
5644         {
5645           unshift @new_input_files, $in;
5646         }
5647     }
5648   @input_files = @new_input_files;
5649
5650   # If neither the auxdir/Makefile nor the ./Makefile are generated
5651   # by Automake, we won't distribute the aux files anyway.  Assume
5652   # the user know what (s)he does, and pretend we will distribute
5653   # them to disable the error in require_file_internal.
5654   $automake_will_process_aux_dir = 1 if ! is_make_dir ($auxdirdist);
5655
5656   # Look for some files we need.  Always check for these.  This
5657   # check must be done for every run, even those where we are only
5658   # looking at a subdir Makefile.  We must set relative_dir for
5659   # maybe_push_required_file to work.
5660   # Sort the files for stable verbose output.
5661   $relative_dir = '.';
5662   foreach my $file (sort keys %required_aux_file)
5663     {
5664       require_conf_file ($required_aux_file{$file}->get, FOREIGN, $file)
5665     }
5666   err_am "`install.sh' is an anachronism; use `install-sh' instead"
5667     if -f $config_aux_dir . '/install.sh';
5668
5669   # Preserve dist_common for later.
5670   $configure_dist_common = variable_value ('DIST_COMMON') || '';
5671
5672 }
5673
5674 ################################################################
5675
5676 # Set up for Cygnus mode.
5677 sub check_cygnus
5678 {
5679   my $cygnus = option 'cygnus';
5680   return unless $cygnus;
5681
5682   set_strictness ('foreign');
5683   set_option ('no-installinfo', $cygnus);
5684   set_option ('no-dependencies', $cygnus);
5685   set_option ('no-dist', $cygnus);
5686
5687   err_ac "`AM_MAINTAINER_MODE' required when --cygnus specified"
5688     if !$seen_maint_mode;
5689 }
5690
5691 # Do any extra checking for GNU standards.
5692 sub check_gnu_standards
5693 {
5694   if ($relative_dir eq '.')
5695     {
5696       # In top level (or only) directory.
5697       require_file ("$am_file.am", GNU,
5698                     qw/INSTALL NEWS README AUTHORS ChangeLog/);
5699
5700       # Accept one of these three licenses; default to COPYING.
5701       # Make sure we do not overwrite an existing license.
5702       my $license;
5703       foreach (qw /COPYING COPYING.LIB COPYING.LESSER/)
5704         {
5705           if (-f $_)
5706             {
5707               $license = $_;
5708               last;
5709             }
5710         }
5711       require_file ("$am_file.am", GNU, 'COPYING')
5712         unless $license;
5713     }
5714
5715   for my $opt ('no-installman', 'no-installinfo')
5716     {
5717       msg ('error-gnu', option $opt,
5718            "option `$opt' disallowed by GNU standards")
5719         if option $opt;
5720     }
5721 }
5722
5723 # Do any extra checking for GNITS standards.
5724 sub check_gnits_standards
5725 {
5726   if ($relative_dir eq '.')
5727     {
5728       # In top level (or only) directory.
5729       require_file ("$am_file.am", GNITS, 'THANKS');
5730     }
5731 }
5732
5733 ################################################################
5734 #
5735 # Functions to handle files of each language.
5736
5737 # Each `lang_X_rewrite($DIRECTORY, $BASE, $EXT)' function follows a
5738 # simple formula: Return value is LANG_SUBDIR if the resulting object
5739 # file should be in a subdir if the source file is, LANG_PROCESS if
5740 # file is to be dealt with, LANG_IGNORE otherwise.
5741
5742 # Much of the actual processing is handled in
5743 # handle_single_transform.  These functions exist so that
5744 # auxiliary information can be recorded for a later cleanup pass.
5745 # Note that the calls to these functions are computed, so don't bother
5746 # searching for their precise names in the source.
5747
5748 # This is just a convenience function that can be used to determine
5749 # when a subdir object should be used.
5750 sub lang_sub_obj
5751 {
5752     return option 'subdir-objects' ? LANG_SUBDIR : LANG_PROCESS;
5753 }
5754
5755 # Rewrite a single C source file.
5756 sub lang_c_rewrite
5757 {
5758   my ($directory, $base, $ext, $nonansi_obj, $have_per_exec_flags, $var) = @_;
5759
5760   if (option 'ansi2knr' && $base =~ /_$/)
5761     {
5762       # FIXME: include line number in error.
5763       err_am "C source file `$base.c' would be deleted by ansi2knr rules";
5764     }
5765
5766   my $r = LANG_PROCESS;
5767   if (option 'subdir-objects')
5768     {
5769       $r = LANG_SUBDIR;
5770       if ($directory && $directory ne '.')
5771         {
5772           $base = $directory . '/' . $base;
5773
5774           # libtool is always able to put the object at the proper place,
5775           # so we do not have to require AM_PROG_CC_C_O when building .lo files.
5776           msg_var ('portability', $var,
5777                    "compiling `$base.c' in subdir requires "
5778                    . "`AM_PROG_CC_C_O' in `$configure_ac'",
5779                    uniq_scope => US_GLOBAL,
5780                    uniq_part => 'AM_PROG_CC_C_O subdir')
5781             unless $seen_cc_c_o || $nonansi_obj eq '.lo';
5782         }
5783
5784       # In this case we already have the directory information, so
5785       # don't add it again.
5786       $de_ansi_files{$base} = '';
5787     }
5788   else
5789     {
5790       $de_ansi_files{$base} = (($directory eq '.' || $directory eq '')
5791                                ? ''
5792                                : "$directory/");
5793     }
5794
5795   if (! $seen_cc_c_o
5796       && $have_per_exec_flags
5797       && ! option 'subdir-objects'
5798       && $nonansi_obj ne '.lo')
5799     {
5800       msg_var ('portability',
5801                $var, "compiling `$base.c' with per-target flags requires "
5802                . "`AM_PROG_CC_C_O' in `$configure_ac'",
5803                uniq_scope => US_GLOBAL,
5804                uniq_part => 'AM_PROG_CC_C_O per-target')
5805     }
5806
5807     return $r;
5808 }
5809
5810 # Rewrite a single C++ source file.
5811 sub lang_cxx_rewrite
5812 {
5813     return &lang_sub_obj;
5814 }
5815
5816 # Rewrite a single header file.
5817 sub lang_header_rewrite
5818 {
5819     # Header files are simply ignored.
5820     return LANG_IGNORE;
5821 }
5822
5823 # Rewrite a single Vala source file.
5824 sub lang_vala_rewrite
5825 {
5826     my ($directory, $base, $ext) = @_;
5827
5828     (my $newext = $ext) =~ s/vala$/c/;
5829     return (LANG_SUBDIR, $newext);
5830 }
5831
5832 # Rewrite a single yacc file.
5833 sub lang_yacc_rewrite
5834 {
5835     my ($directory, $base, $ext) = @_;
5836
5837     my $r = &lang_sub_obj;
5838     (my $newext = $ext) =~ tr/y/c/;
5839     return ($r, $newext);
5840 }
5841
5842 # Rewrite a single yacc++ file.
5843 sub lang_yaccxx_rewrite
5844 {
5845     my ($directory, $base, $ext) = @_;
5846
5847     my $r = &lang_sub_obj;
5848     (my $newext = $ext) =~ tr/y/c/;
5849     return ($r, $newext);
5850 }
5851
5852 # Rewrite a single lex file.
5853 sub lang_lex_rewrite
5854 {
5855     my ($directory, $base, $ext) = @_;
5856
5857     my $r = &lang_sub_obj;
5858     (my $newext = $ext) =~ tr/l/c/;
5859     return ($r, $newext);
5860 }
5861
5862 # Rewrite a single lex++ file.
5863 sub lang_lexxx_rewrite
5864 {
5865     my ($directory, $base, $ext) = @_;
5866
5867     my $r = &lang_sub_obj;
5868     (my $newext = $ext) =~ tr/l/c/;
5869     return ($r, $newext);
5870 }
5871
5872 # Rewrite a single assembly file.
5873 sub lang_asm_rewrite
5874 {
5875     return &lang_sub_obj;
5876 }
5877
5878 # Rewrite a single preprocessed assembly file.
5879 sub lang_cppasm_rewrite
5880 {
5881     return &lang_sub_obj;
5882 }
5883
5884 # Rewrite a single Fortran 77 file.
5885 sub lang_f77_rewrite
5886 {
5887     return &lang_sub_obj;
5888 }
5889
5890 # Rewrite a single Fortran file.
5891 sub lang_fc_rewrite
5892 {
5893     return &lang_sub_obj;
5894 }
5895
5896 # Rewrite a single preprocessed Fortran file.
5897 sub lang_ppfc_rewrite
5898 {
5899     return &lang_sub_obj;
5900 }
5901
5902 # Rewrite a single preprocessed Fortran 77 file.
5903 sub lang_ppf77_rewrite
5904 {
5905     return &lang_sub_obj;
5906 }
5907
5908 # Rewrite a single ratfor file.
5909 sub lang_ratfor_rewrite
5910 {
5911     return &lang_sub_obj;
5912 }
5913
5914 # Rewrite a single Objective C file.
5915 sub lang_objc_rewrite
5916 {
5917     return &lang_sub_obj;
5918 }
5919
5920 # Rewrite a single Unified Parallel C file.
5921 sub lang_upc_rewrite
5922 {
5923     return &lang_sub_obj;
5924 }
5925
5926 # Rewrite a single Java file.
5927 sub lang_java_rewrite
5928 {
5929     return LANG_SUBDIR;
5930 }
5931
5932 # The lang_X_finish functions are called after all source file
5933 # processing is done.  Each should handle defining rules for the
5934 # language, etc.  A finish function is only called if a source file of
5935 # the appropriate type has been seen.
5936
5937 sub lang_c_finish
5938 {
5939     # Push all libobjs files onto de_ansi_files.  We actually only
5940     # push files which exist in the current directory, and which are
5941     # genuine source files.
5942     foreach my $file (keys %libsources)
5943     {
5944         if ($file =~ /^(.*)\.[cly]$/ && -f "$relative_dir/$file")
5945         {
5946             $de_ansi_files{$1} = ''
5947         }
5948     }
5949
5950     if (option 'ansi2knr' && keys %de_ansi_files)
5951     {
5952         # Make all _.c files depend on their corresponding .c files.
5953         my @objects;
5954         foreach my $base (sort keys %de_ansi_files)
5955         {
5956             # Each _.c file must depend on ansi2knr; otherwise it
5957             # might be used in a parallel build before it is built.
5958             # We need to support files in the srcdir and in the build
5959             # dir (because these files might be auto-generated.  But
5960             # we can't use $< -- some makes only define $< during a
5961             # suffix rule.
5962             my $ansfile = $de_ansi_files{$base} . $base . '.c';
5963             $output_rules .= ($base . "_.c: $ansfile \$(ANSI2KNR)\n\t"
5964                               . '$(CPP) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) '
5965                               . '`if test -f $(srcdir)/' . $ansfile
5966                               . '; then echo $(srcdir)/' . $ansfile
5967                               . '; else echo ' . $ansfile . '; fi` '
5968                               . "| sed 's/^# \\([0-9]\\)/#line \\1/' "
5969                               . '| $(ANSI2KNR) > $@'
5970                               # If ansi2knr fails then we shouldn't
5971                               # create the _.c file
5972                               . " || rm -f \$\@\n");
5973             push (@objects, $base . '_.$(OBJEXT)');
5974             push (@objects, $base . '_.lo')
5975               if var ('LIBTOOL');
5976
5977             # Explicitly clean the _.c files if they are in a
5978             # subdirectory. (In the current directory they get erased
5979             # by a `rm -f *_.c' rule.)
5980             $clean_files{$base . '_.c'} = MOSTLY_CLEAN
5981               if dirname ($base) ne '.';
5982         }
5983
5984         # Make all _.o (and _.lo) files depend on ansi2knr.
5985         # Use a sneaky little hack to make it print nicely.
5986         &pretty_print_rule ('', '', @objects, ':', '$(ANSI2KNR)');
5987     }
5988 }
5989
5990 sub lang_vala_finish_target ($$)
5991 {
5992   my ($self, $name) = @_;
5993
5994   my $derived = canonicalize ($name);
5995   my $varname = $derived . '_SOURCES';
5996   my $var = var ($varname);
5997
5998   if ($var)
5999     {
6000       foreach my $file ($var->value_as_list_recursive)
6001         {
6002           $output_rules .= "\$(srcdir)/$file: \$(srcdir)/${derived}_vala.stamp\n"
6003             . "\t\@if test -f \$@; then :; else rm -f \$(srcdir)/${derived}_vala.stamp; fi\n"
6004             . "\t\@if test -f \$@; then :; else \\\n"
6005             . "\t  \$(am__cd) \$(srcdir) && \$(MAKE) \$(AM_MAKEFLAGS) ${derived}_vala.stamp; \\\n"
6006             . "\tfi\n"
6007             if $file =~ s/(.*)\.vala$/$1.c/;
6008         }
6009     }
6010
6011   # Add rebuild rules for generated header and vapi files
6012   my $flags = var ($derived . '_VALAFLAGS');
6013   if ($flags)
6014     {
6015       my $lastflag = '';
6016       foreach my $flag ($flags->value_as_list_recursive)
6017         {
6018           if (grep (/$lastflag/, ('-H', '-h', '--header', '--internal-header',
6019                                   '--vapi', '--internal-vapi', '--gir')))
6020             {
6021               my $headerfile = $flag;
6022               $output_rules .= "\$(srcdir)/$headerfile: \$(srcdir)/${derived}_vala.stamp\n"
6023                 . "\t\@if test -f \$@; then :; else rm -f \$(srcdir)/${derived}_vala.stamp; fi\n"
6024                 . "\t\@if test -f \$@; then :; else \\\n"
6025                 . "\t  \$(am__cd) \$(srcdir) && \$(MAKE) \$(AM_MAKEFLAGS) ${derived}_vala.stamp; \\\n"
6026                 . "\tfi\n";
6027
6028               # valac is not used when building from dist tarballs
6029               # distribute the generated files
6030               push_dist_common ($headerfile);
6031               $clean_files{$headerfile} = MAINTAINER_CLEAN;
6032             }
6033           $lastflag = $flag;
6034         }
6035     }
6036
6037   my $compile = $self->compile;
6038
6039   # Rewrite each occurrence of `AM_VALAFLAGS' in the compile
6040   # rule into `${derived}_VALAFLAGS' if it exists.
6041   my $val = "${derived}_VALAFLAGS";
6042   $compile =~ s/\(AM_VALAFLAGS\)/\($val\)/
6043     if set_seen ($val);
6044
6045   # VALAFLAGS is a user variable (per GNU Standards),
6046   # it should not be overridden in the Makefile...
6047   check_user_variables ['VALAFLAGS'];
6048
6049   my $dirname = dirname ($name);
6050
6051   # Only generate C code, do not run C compiler
6052   $compile .= " -C";
6053
6054   my $verbose = verbose_flag ('VALAC');
6055   my $silent = silent_flag ();
6056
6057   $output_rules .=
6058     "${derived}_vala.stamp: \$(${derived}_SOURCES)\n".
6059     "\t${verbose}${compile} \$(${derived}_SOURCES)\n".
6060     "\t${silent}touch \$@\n";
6061
6062   push_dist_common ("${derived}_vala.stamp");
6063
6064   $clean_files{"${derived}_vala.stamp"} = MAINTAINER_CLEAN;
6065 }
6066
6067 # Add output rules to invoke valac and create stamp file as a witness
6068 # to handle multiple outputs. This function is called after all source
6069 # file processing is done.
6070 sub lang_vala_finish
6071 {
6072   my ($self) = @_;
6073
6074   foreach my $prog (keys %known_programs)
6075     {
6076       lang_vala_finish_target ($self, $prog);
6077     }
6078
6079   while (my ($name) = each %known_libraries)
6080     {
6081       lang_vala_finish_target ($self, $name);
6082     }
6083 }
6084
6085 # The built .c files should be cleaned only on maintainer-clean
6086 # as the .c files are distributed. This function is called for each
6087 # .vala source file.
6088 sub lang_vala_target_hook
6089 {
6090   my ($self, $aggregate, $output, $input, %transform) = @_;
6091
6092   $clean_files{$output} = MAINTAINER_CLEAN;
6093 }
6094
6095 # This is a yacc helper which is called whenever we have decided to
6096 # compile a yacc file.
6097 sub lang_yacc_target_hook
6098 {
6099     my ($self, $aggregate, $output, $input, %transform) = @_;
6100
6101     # If some relevant *YFLAGS variable contains the `-d' flag, we'll
6102     # have to to generate special code.
6103     my $yflags_contains_minus_d = 0;
6104
6105     foreach my $pfx ("", "${aggregate}_")
6106       {
6107         my $yflagsvar = var ("${pfx}YFLAGS");
6108         next unless $yflagsvar;
6109         # We cannot work reliably with conditionally-defined YFLAGS.
6110         if ($yflagsvar->has_conditional_contents)
6111           {
6112             msg_var ('unsupported', $yflagsvar,
6113                      "`${pfx}YFLAGS' cannot have conditional contents");
6114           }
6115         else
6116           {
6117             $yflags_contains_minus_d = 1
6118               if grep (/^-d$/, $yflagsvar->value_as_list_recursive);
6119           }
6120       }
6121
6122     if ($yflags_contains_minus_d)
6123       {
6124         (my $output_base = $output) =~ s/$KNOWN_EXTENSIONS_PATTERN$//;
6125         my $header = $output_base . '.h';
6126
6127         # Found a `-d' that applies to the compilation of this file.
6128         # Add a dependency for the generated header file, and arrange
6129         # for that file to be included in the distribution.
6130         foreach my $cond (Automake::Rule::define (${header}, 'internal',
6131                                                   RULE_AUTOMAKE, TRUE,
6132                                                   INTERNAL))
6133           {
6134             my $condstr = $cond->subst_string;
6135             $output_rules .=
6136               "$condstr${header}: $output\n"
6137               # Recover from removal of $header
6138               . "$condstr\t\@if test ! -f \$@; then rm -f $output; else :; fi\n"
6139               . "$condstr\t\@if test ! -f \$@; then \$(MAKE) \$(AM_MAKEFLAGS) $output; else :; fi\n";
6140           }
6141         # Distribute the generated file, unless its .y source was
6142         # listed in a nodist_ variable.  (&handle_source_transform
6143         # will set DIST_SOURCE.)
6144         &push_dist_common ($header)
6145           if $transform{'DIST_SOURCE'};
6146
6147         # The GNU rules say that yacc/lex output files should be removed
6148         # by maintainer-clean.  However, if the files are not distributed,
6149         # then we want to remove them with "make clean"; otherwise,
6150         # "make distcheck" will fail.
6151         $clean_files{$header} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
6152       }
6153     # See the comment above for $HEADER.
6154     $clean_files{$output} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
6155 }
6156
6157 # This is a lex helper which is called whenever we have decided to
6158 # compile a lex file.
6159 sub lang_lex_target_hook
6160 {
6161     my ($self, $aggregate, $output, $input) = @_;
6162     # If the files are built in the build directory, then we want to
6163     # remove them with `make clean'.  If they are in srcdir they
6164     # shouldn't be touched.  However, we can't determine this
6165     # statically, and the GNU rules say that yacc/lex output files
6166     # should be removed by maintainer-clean.  So that's what we do.
6167     $clean_files{$output} = MAINTAINER_CLEAN;
6168 }
6169
6170 # This is a helper for both lex and yacc.
6171 sub yacc_lex_finish_helper
6172 {
6173   return if defined $language_scratch{'lex-yacc-done'};
6174   $language_scratch{'lex-yacc-done'} = 1;
6175
6176   # FIXME: for now, no line number.
6177   require_conf_file ($configure_ac, FOREIGN, 'ylwrap');
6178   &define_variable ('YLWRAP', "$am_config_aux_dir/ylwrap", INTERNAL);
6179 }
6180
6181 sub lang_yacc_finish
6182 {
6183   return if defined $language_scratch{'yacc-done'};
6184   $language_scratch{'yacc-done'} = 1;
6185
6186   reject_var 'YACCFLAGS', "`YACCFLAGS' obsolete; use `YFLAGS' instead";
6187
6188   yacc_lex_finish_helper;
6189 }
6190
6191
6192 sub lang_lex_finish
6193 {
6194   return if defined $language_scratch{'lex-done'};
6195   $language_scratch{'lex-done'} = 1;
6196
6197   yacc_lex_finish_helper;
6198 }
6199
6200
6201 # Given a hash table of linker names, pick the name that has the most
6202 # precedence.  This is lame, but something has to have global
6203 # knowledge in order to eliminate the conflict.  Add more linkers as
6204 # required.
6205 sub resolve_linker
6206 {
6207     my (%linkers) = @_;
6208
6209     foreach my $l (qw(GCJLINK CXXLINK F77LINK FCLINK OBJCLINK UPCLINK))
6210     {
6211         return $l if defined $linkers{$l};
6212     }
6213     return 'LINK';
6214 }
6215
6216 # Called to indicate that an extension was used.
6217 sub saw_extension
6218 {
6219     my ($ext) = @_;
6220     if (! defined $extension_seen{$ext})
6221     {
6222         $extension_seen{$ext} = 1;
6223     }
6224     else
6225     {
6226         ++$extension_seen{$ext};
6227     }
6228 }
6229
6230 # Return the number of files seen for a given language.  Knows about
6231 # special cases we care about.  FIXME: this is hideous.  We need
6232 # something that involves real language objects.  For instance yacc
6233 # and yaccxx could both derive from a common yacc class which would
6234 # know about the strange ylwrap requirement.  (Or better yet we could
6235 # just not support legacy yacc!)
6236 sub count_files_for_language
6237 {
6238     my ($name) = @_;
6239
6240     my @names;
6241     if ($name eq 'yacc' || $name eq 'yaccxx')
6242     {
6243         @names = ('yacc', 'yaccxx');
6244     }
6245     elsif ($name eq 'lex' || $name eq 'lexxx')
6246     {
6247         @names = ('lex', 'lexxx');
6248     }
6249     else
6250     {
6251         @names = ($name);
6252     }
6253
6254     my $r = 0;
6255     foreach $name (@names)
6256     {
6257         my $lang = $languages{$name};
6258         foreach my $ext (@{$lang->extensions})
6259         {
6260             $r += $extension_seen{$ext}
6261                 if defined $extension_seen{$ext};
6262         }
6263     }
6264
6265     return $r
6266 }
6267
6268 # Called to ask whether source files have been seen . If HEADERS is 1,
6269 # headers can be included.
6270 sub saw_sources_p
6271 {
6272     my ($headers) = @_;
6273
6274     # count all the sources
6275     my $count = 0;
6276     foreach my $val (values %extension_seen)
6277     {
6278         $count += $val;
6279     }
6280
6281     if (!$headers)
6282     {
6283         $count -= count_files_for_language ('header');
6284     }
6285
6286     return $count > 0;
6287 }
6288
6289
6290 # register_language (%ATTRIBUTE)
6291 # ------------------------------
6292 # Register a single language.
6293 # Each %ATTRIBUTE is of the form ATTRIBUTE => VALUE.
6294 sub register_language (%)
6295 {
6296   my (%option) = @_;
6297
6298   # Set the defaults.
6299   $option{'ansi'} = 0
6300     unless defined $option{'ansi'};
6301   $option{'autodep'} = 'no'
6302     unless defined $option{'autodep'};
6303   $option{'linker'} = ''
6304     unless defined $option{'linker'};
6305   $option{'flags'} = []
6306     unless defined $option{'flags'};
6307   $option{'output_extensions'} = sub { return ( '.$(OBJEXT)', '.lo' ) }
6308     unless defined $option{'output_extensions'};
6309   $option{'nodist_specific'} = 0
6310     unless defined $option{'nodist_specific'};
6311
6312   my $lang = new Language (%option);
6313
6314   # Fill indexes.
6315   $extension_map{$_} = $lang->name foreach @{$lang->extensions};
6316   $languages{$lang->name} = $lang;
6317   my $link = $lang->linker;
6318   if ($link)
6319     {
6320       if (exists $link_languages{$link})
6321         {
6322           prog_error ("`$link' has different definitions in "
6323                       . $lang->name . " and " . $link_languages{$link}->name)
6324             if $lang->link ne $link_languages{$link}->link;
6325         }
6326       else
6327         {
6328           $link_languages{$link} = $lang;
6329         }
6330     }
6331
6332   # Update the pattern of known extensions.
6333   accept_extensions (@{$lang->extensions});
6334
6335   # Upate the $suffix_rule map.
6336   foreach my $suffix (@{$lang->extensions})
6337     {
6338       foreach my $dest (&{$lang->output_extensions} ($suffix))
6339         {
6340           register_suffix_rule (INTERNAL, $suffix, $dest);
6341         }
6342     }
6343 }
6344
6345 # derive_suffix ($EXT, $OBJ)
6346 # --------------------------
6347 # This function is used to find a path from a user-specified suffix $EXT
6348 # to $OBJ or to some other suffix we recognize internally, e.g. `cc'.
6349 sub derive_suffix ($$)
6350 {
6351   my ($source_ext, $obj) = @_;
6352
6353   while (! $extension_map{$source_ext}
6354          && $source_ext ne $obj
6355          && exists $suffix_rules->{$source_ext}
6356          && exists $suffix_rules->{$source_ext}{$obj})
6357     {
6358       $source_ext = $suffix_rules->{$source_ext}{$obj}[0];
6359     }
6360
6361   return $source_ext;
6362 }
6363
6364
6365 ################################################################
6366
6367 # Pretty-print something and append to output_rules.
6368 sub pretty_print_rule
6369 {
6370     $output_rules .= &makefile_wrap (@_);
6371 }
6372
6373
6374 ################################################################
6375
6376
6377 ## -------------------------------- ##
6378 ## Handling the conditional stack.  ##
6379 ## -------------------------------- ##
6380
6381
6382 # $STRING
6383 # make_conditional_string ($NEGATE, $COND)
6384 # ----------------------------------------
6385 sub make_conditional_string ($$)
6386 {
6387   my ($negate, $cond) = @_;
6388   $cond = "${cond}_TRUE"
6389     unless $cond =~ /^TRUE|FALSE$/;
6390   $cond = Automake::Condition::conditional_negate ($cond)
6391     if $negate;
6392   return $cond;
6393 }
6394
6395
6396 my %_am_macro_for_cond =
6397   (
6398   AMDEP => "one of the compiler tests\n"
6399            . "    AC_PROG_CC, AC_PROG_CXX, AC_PROG_CXX, AC_PROG_OBJC,\n"
6400            . "    AM_PROG_AS, AM_PROG_GCJ, AM_PROG_UPC",
6401   am__fastdepCC => 'AC_PROG_CC',
6402   am__fastdepCCAS => 'AM_PROG_AS',
6403   am__fastdepCXX => 'AC_PROG_CXX',
6404   am__fastdepGCJ => 'AM_PROG_GCJ',
6405   am__fastdepOBJC => 'AC_PROG_OBJC',
6406   am__fastdepUPC => 'AM_PROG_UPC'
6407   );
6408
6409 # $COND
6410 # cond_stack_if ($NEGATE, $COND, $WHERE)
6411 # --------------------------------------
6412 sub cond_stack_if ($$$)
6413 {
6414   my ($negate, $cond, $where) = @_;
6415
6416   if (! $configure_cond{$cond} && $cond !~ /^TRUE|FALSE$/)
6417     {
6418       my $text = "$cond does not appear in AM_CONDITIONAL";
6419       my $scope = US_LOCAL;
6420       if (exists $_am_macro_for_cond{$cond})
6421         {
6422           my $mac = $_am_macro_for_cond{$cond};
6423           $text .= "\n  The usual way to define `$cond' is to add ";
6424           $text .= ($mac =~ / /) ? $mac : "`$mac'";
6425           $text .= "\n  to `$configure_ac' and run `aclocal' and `autoconf' again";
6426           # These warnings appear in Automake files (depend2.am),
6427           # so there is no need to display them more than once:
6428           $scope = US_GLOBAL;
6429         }
6430       error $where, $text, uniq_scope => $scope;
6431     }
6432
6433   push (@cond_stack, make_conditional_string ($negate, $cond));
6434
6435   return new Automake::Condition (@cond_stack);
6436 }
6437
6438
6439 # $COND
6440 # cond_stack_else ($NEGATE, $COND, $WHERE)
6441 # ----------------------------------------
6442 sub cond_stack_else ($$$)
6443 {
6444   my ($negate, $cond, $where) = @_;
6445
6446   if (! @cond_stack)
6447     {
6448       error $where, "else without if";
6449       return FALSE;
6450     }
6451
6452   $cond_stack[$#cond_stack] =
6453     Automake::Condition::conditional_negate ($cond_stack[$#cond_stack]);
6454
6455   # If $COND is given, check against it.
6456   if (defined $cond)
6457     {
6458       $cond = make_conditional_string ($negate, $cond);
6459
6460       error ($where, "else reminder ($negate$cond) incompatible with "
6461              . "current conditional: $cond_stack[$#cond_stack]")
6462         if $cond_stack[$#cond_stack] ne $cond;
6463     }
6464
6465   return new Automake::Condition (@cond_stack);
6466 }
6467
6468
6469 # $COND
6470 # cond_stack_endif ($NEGATE, $COND, $WHERE)
6471 # -----------------------------------------
6472 sub cond_stack_endif ($$$)
6473 {
6474   my ($negate, $cond, $where) = @_;
6475   my $old_cond;
6476
6477   if (! @cond_stack)
6478     {
6479       error $where, "endif without if";
6480       return TRUE;
6481     }
6482
6483   # If $COND is given, check against it.
6484   if (defined $cond)
6485     {
6486       $cond = make_conditional_string ($negate, $cond);
6487
6488       error ($where, "endif reminder ($negate$cond) incompatible with "
6489              . "current conditional: $cond_stack[$#cond_stack]")
6490         if $cond_stack[$#cond_stack] ne $cond;
6491     }
6492
6493   pop @cond_stack;
6494
6495   return new Automake::Condition (@cond_stack);
6496 }
6497
6498
6499
6500
6501
6502 ## ------------------------ ##
6503 ## Handling the variables.  ##
6504 ## ------------------------ ##
6505
6506
6507 # &define_pretty_variable ($VAR, $COND, $WHERE, @VALUE)
6508 # -----------------------------------------------------
6509 # Like define_variable, but the value is a list, and the variable may
6510 # be defined conditionally.  The second argument is the condition
6511 # under which the value should be defined; this should be the empty
6512 # string to define the variable unconditionally.  The third argument
6513 # is a list holding the values to use for the variable.  The value is
6514 # pretty printed in the output file.
6515 sub define_pretty_variable ($$$@)
6516 {
6517     my ($var, $cond, $where, @value) = @_;
6518
6519     if (! vardef ($var, $cond))
6520     {
6521         Automake::Variable::define ($var, VAR_AUTOMAKE, '', $cond, "@value",
6522                                     '', $where, VAR_PRETTY);
6523         rvar ($var)->rdef ($cond)->set_seen;
6524     }
6525 }
6526
6527
6528 # define_variable ($VAR, $VALUE, $WHERE)
6529 # --------------------------------------
6530 # Define a new Automake Makefile variable VAR to VALUE, but only if
6531 # not already defined.
6532 sub define_variable ($$$)
6533 {
6534     my ($var, $value, $where) = @_;
6535     define_pretty_variable ($var, TRUE, $where, $value);
6536 }
6537
6538
6539 # define_files_variable ($VAR, \@BASENAME, $EXTENSION, $WHERE)
6540 # ------------------------------------------------------------
6541 # Define the $VAR which content is the list of file names composed of
6542 # a @BASENAME and the $EXTENSION.
6543 sub define_files_variable ($\@$$)
6544 {
6545   my ($var, $basename, $extension, $where) = @_;
6546   define_variable ($var,
6547                    join (' ', map { "$_.$extension" } @$basename),
6548                    $where);
6549 }
6550
6551
6552 # Like define_variable, but define a variable to be the configure
6553 # substitution by the same name.
6554 sub define_configure_variable ($)
6555 {
6556   my ($var) = @_;
6557
6558   my $pretty = VAR_ASIS;
6559   my $owner = VAR_CONFIGURE;
6560
6561   # Some variables we do not want to output.  For instance it
6562   # would be a bad idea to output `U = @U@` when `@U@` can be
6563   # substituted as `\`.
6564   $pretty = VAR_SILENT if exists $ignored_configure_vars{$var};
6565
6566   # ANSI2KNR is a variable that Automake wants to redefine, so
6567   # it must be owned by Automake.  (It is also used as a proof
6568   # that AM_C_PROTOTYPES has been run, that's why we do not simply
6569   # omit the AC_SUBST.)
6570   $owner = VAR_AUTOMAKE if $var eq 'ANSI2KNR';
6571
6572   Automake::Variable::define ($var, $owner, '', TRUE, subst $var,
6573                               '', $configure_vars{$var}, $pretty);
6574 }
6575
6576
6577 # define_compiler_variable ($LANG)
6578 # --------------------------------
6579 # Define a compiler variable.  We also handle defining the `LT'
6580 # version of the command when using libtool.
6581 sub define_compiler_variable ($)
6582 {
6583     my ($lang) = @_;
6584
6585     my ($var, $value) = ($lang->compiler, $lang->compile);
6586     my $libtool_tag = '';
6587     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6588       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6589     &define_variable ($var, $value, INTERNAL);
6590     if (var ('LIBTOOL'))
6591       {
6592         my $verbose = define_verbose_libtool ();
6593         &define_variable ("LT$var",
6594                           "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) "
6595                           . "\$(LIBTOOLFLAGS) --mode=compile $value",
6596                           INTERNAL);
6597       }
6598     define_verbose_tagvar ($lang->ccer || 'GEN');
6599 }
6600
6601
6602 # define_linker_variable ($LANG)
6603 # ------------------------------
6604 # Define linker variables.
6605 sub define_linker_variable ($)
6606 {
6607     my ($lang) = @_;
6608
6609     my $libtool_tag = '';
6610     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6611       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6612     # CCLD = $(CC).
6613     &define_variable ($lang->lder, $lang->ld, INTERNAL);
6614     # CCLINK = $(CCLD) blah blah...
6615     my $link = '';
6616     if (var ('LIBTOOL'))
6617       {
6618         my $verbose = define_verbose_libtool ();
6619         $link = "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) "
6620                 . "\$(LIBTOOLFLAGS) --mode=link ";
6621       }
6622     &define_variable ($lang->linker, $link . $lang->link, INTERNAL);
6623     &define_variable ($lang->compiler,  $lang);
6624     &define_verbose_tagvar ($lang->lder || 'GEN');
6625 }
6626
6627 sub define_per_target_linker_variable ($$)
6628 {
6629   my ($linker, $target) = @_;
6630
6631   # If the user wrote a custom link command, we don't define ours.
6632   return "${target}_LINK"
6633     if set_seen "${target}_LINK";
6634
6635   my $xlink = $linker ? $linker : 'LINK';
6636
6637   my $lang = $link_languages{$xlink};
6638   prog_error "Unknown language for linker variable `$xlink'"
6639     unless $lang;
6640
6641   my $link_command = $lang->link;
6642   if (var 'LIBTOOL')
6643     {
6644       my $libtool_tag = '';
6645       $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6646         if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6647
6648       my $verbose = define_verbose_libtool ();
6649       $link_command =
6650         "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) \$(LIBTOOLFLAGS) "
6651         . "--mode=link " . $link_command;
6652     }
6653
6654   # Rewrite each occurrence of `AM_$flag' in the link
6655   # command into `${derived}_$flag' if it exists.
6656   my $orig_command = $link_command;
6657   my @flags = (@{$lang->flags}, 'LDFLAGS');
6658   push @flags, 'LIBTOOLFLAGS' if var 'LIBTOOL';
6659   for my $flag (@flags)
6660     {
6661       my $val = "${target}_$flag";
6662       $link_command =~ s/\(AM_$flag\)/\($val\)/
6663         if set_seen ($val);
6664     }
6665
6666   # If the computed command is the same as the generic command, use
6667   # the command linker variable.
6668   return ($lang->linker, $lang->lder)
6669     if $link_command eq $orig_command;
6670
6671   &define_variable ("${target}_LINK", $link_command, INTERNAL);
6672   return ("${target}_LINK", $lang->lder);
6673 }
6674
6675 ################################################################
6676
6677 # &check_trailing_slash ($WHERE, $LINE)
6678 # -------------------------------------
6679 # Return 1 iff $LINE ends with a slash.
6680 # Might modify $LINE.
6681 sub check_trailing_slash ($\$)
6682 {
6683   my ($where, $line) = @_;
6684
6685   # Ignore `##' lines.
6686   return 0 if $$line =~ /$IGNORE_PATTERN/o;
6687
6688   # Catch and fix a common error.
6689   msg "syntax", $where, "whitespace following trailing backslash"
6690     if $$line =~ s/\\\s+\n$/\\\n/;
6691
6692   return $$line =~ /\\$/;
6693 }
6694
6695
6696 # &read_am_file ($AMFILE, $WHERE)
6697 # -------------------------------
6698 # Read Makefile.am and set up %contents.  Simultaneously copy lines
6699 # from Makefile.am into $output_trailer, or define variables as
6700 # appropriate.  NOTE we put rules in the trailer section.  We want
6701 # user rules to come after our generated stuff.
6702 sub read_am_file ($$)
6703 {
6704     my ($amfile, $where) = @_;
6705
6706     my $am_file = new Automake::XFile ("< $amfile");
6707     verb "reading $amfile";
6708
6709     # Keep track of the youngest output dependency.
6710     my $mtime = mtime $amfile;
6711     $output_deps_greatest_timestamp = $mtime
6712       if $mtime > $output_deps_greatest_timestamp;
6713
6714     my $spacing = '';
6715     my $comment = '';
6716     my $blank = 0;
6717     my $saw_bk = 0;
6718     my $var_look = VAR_ASIS;
6719
6720     use constant IN_VAR_DEF => 0;
6721     use constant IN_RULE_DEF => 1;
6722     use constant IN_COMMENT => 2;
6723     my $prev_state = IN_RULE_DEF;
6724
6725     while ($_ = $am_file->getline)
6726     {
6727         $where->set ("$amfile:$.");
6728         if (/$IGNORE_PATTERN/o)
6729         {
6730             # Merely delete comments beginning with two hashes.
6731         }
6732         elsif (/$WHITE_PATTERN/o)
6733         {
6734             error $where, "blank line following trailing backslash"
6735               if $saw_bk;
6736             # Stick a single white line before the incoming macro or rule.
6737             $spacing = "\n";
6738             $blank = 1;
6739             # Flush all comments seen so far.
6740             if ($comment ne '')
6741             {
6742                 $output_vars .= $comment;
6743                 $comment = '';
6744             }
6745         }
6746         elsif (/$COMMENT_PATTERN/o)
6747         {
6748             # Stick comments before the incoming macro or rule.  Make
6749             # sure a blank line precedes the first block of comments.
6750             $spacing = "\n" unless $blank;
6751             $blank = 1;
6752             $comment .= $spacing . $_;
6753             $spacing = '';
6754             $prev_state = IN_COMMENT;
6755         }
6756         else
6757         {
6758             last;
6759         }
6760         $saw_bk = check_trailing_slash ($where, $_);
6761     }
6762
6763     # We save the conditional stack on entry, and then check to make
6764     # sure it is the same on exit.  This lets us conditionally include
6765     # other files.
6766     my @saved_cond_stack = @cond_stack;
6767     my $cond = new Automake::Condition (@cond_stack);
6768
6769     my $last_var_name = '';
6770     my $last_var_type = '';
6771     my $last_var_value = '';
6772     my $last_where;
6773     # FIXME: shouldn't use $_ in this loop; it is too big.
6774     while ($_)
6775     {
6776         $where->set ("$amfile:$.");
6777
6778         # Make sure the line is \n-terminated.
6779         chomp;
6780         $_ .= "\n";
6781
6782         # Don't look at MAINTAINER_MODE_TRUE here.  That shouldn't be
6783         # used by users.  @MAINT@ is an anachronism now.
6784         $_ =~ s/\@MAINT\@//g
6785             unless $seen_maint_mode;
6786
6787         my $new_saw_bk = check_trailing_slash ($where, $_);
6788
6789         if (/$IGNORE_PATTERN/o)
6790         {
6791             # Merely delete comments beginning with two hashes.
6792
6793             # Keep any backslash from the previous line.
6794             $new_saw_bk = $saw_bk;
6795         }
6796         elsif (/$WHITE_PATTERN/o)
6797         {
6798             # Stick a single white line before the incoming macro or rule.
6799             $spacing = "\n";
6800             error $where, "blank line following trailing backslash"
6801               if $saw_bk;
6802         }
6803         elsif (/$COMMENT_PATTERN/o)
6804         {
6805             error $where, "comment following trailing backslash"
6806               if $saw_bk && $prev_state != IN_COMMENT;
6807
6808             # Stick comments before the incoming macro or rule.
6809             $comment .= $spacing . $_;
6810             $spacing = '';
6811             $prev_state = IN_COMMENT;
6812         }
6813         elsif ($saw_bk)
6814         {
6815             if ($prev_state == IN_RULE_DEF)
6816             {
6817               my $cond = new Automake::Condition @cond_stack;
6818               $output_trailer .= $cond->subst_string;
6819               $output_trailer .= $_;
6820             }
6821             elsif ($prev_state == IN_COMMENT)
6822             {
6823                 # If the line doesn't start with a `#', add it.
6824                 # We do this because a continued comment like
6825                 #   # A = foo \
6826                 #         bar \
6827                 #         baz
6828                 # is not portable.  BSD make doesn't honor
6829                 # escaped newlines in comments.
6830                 s/^#?/#/;
6831                 $comment .= $spacing . $_;
6832             }
6833             else # $prev_state == IN_VAR_DEF
6834             {
6835               $last_var_value .= ' '
6836                 unless $last_var_value =~ /\s$/;
6837               $last_var_value .= $_;
6838
6839               if (!/\\$/)
6840                 {
6841                   Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6842                                               $last_var_type, $cond,
6843                                               $last_var_value, $comment,
6844                                               $last_where, VAR_ASIS)
6845                     if $cond != FALSE;
6846                   $comment = $spacing = '';
6847                 }
6848             }
6849         }
6850
6851         elsif (/$IF_PATTERN/o)
6852           {
6853             $cond = cond_stack_if ($1, $2, $where);
6854           }
6855         elsif (/$ELSE_PATTERN/o)
6856           {
6857             $cond = cond_stack_else ($1, $2, $where);
6858           }
6859         elsif (/$ENDIF_PATTERN/o)
6860           {
6861             $cond = cond_stack_endif ($1, $2, $where);
6862           }
6863
6864         elsif (/$RULE_PATTERN/o)
6865         {
6866             # Found a rule.
6867             $prev_state = IN_RULE_DEF;
6868
6869             # For now we have to output all definitions of user rules
6870             # and can't diagnose duplicates (see the comment in
6871             # Automake::Rule::define). So we go on and ignore the return value.
6872             Automake::Rule::define ($1, $amfile, RULE_USER, $cond, $where);
6873
6874             check_variable_expansions ($_, $where);
6875
6876             $output_trailer .= $comment . $spacing;
6877             my $cond = new Automake::Condition @cond_stack;
6878             $output_trailer .= $cond->subst_string;
6879             $output_trailer .= $_;
6880             $comment = $spacing = '';
6881         }
6882         elsif (/$ASSIGNMENT_PATTERN/o)
6883         {
6884             # Found a macro definition.
6885             $prev_state = IN_VAR_DEF;
6886             $last_var_name = $1;
6887             $last_var_type = $2;
6888             $last_var_value = $3;
6889             $last_where = $where->clone;
6890             if ($3 ne '' && substr ($3, -1) eq "\\")
6891               {
6892                 # We preserve the `\' because otherwise the long lines
6893                 # that are generated will be truncated by broken
6894                 # `sed's.
6895                 $last_var_value = $3 . "\n";
6896               }
6897             # Normally we try to output variable definitions in the
6898             # same format they were input.  However, POSIX compliant
6899             # systems are not required to support lines longer than
6900             # 2048 bytes (most notably, some sed implementation are
6901             # limited to 4000 bytes, and sed is used by config.status
6902             # to rewrite Makefile.in into Makefile).  Moreover nobody
6903             # would really write such long lines by hand since it is
6904             # hardly maintainable.  So if a line is longer that 1000
6905             # bytes (an arbitrary limit), assume it has been
6906             # automatically generated by some tools, and flatten the
6907             # variable definition.  Otherwise, keep the variable as it
6908             # as been input.
6909             $var_look = VAR_PRETTY if length ($last_var_value) >= 1000;
6910
6911             if (!/\\$/)
6912               {
6913                 Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6914                                             $last_var_type, $cond,
6915                                             $last_var_value, $comment,
6916                                             $last_where, $var_look)
6917                   if $cond != FALSE;
6918                 $comment = $spacing = '';
6919                 $var_look = VAR_ASIS;
6920               }
6921         }
6922         elsif (/$INCLUDE_PATTERN/o)
6923         {
6924             my $path = $1;
6925
6926             if ($path =~ s/^\$\(top_srcdir\)\///)
6927               {
6928                 push (@include_stack, "\$\(top_srcdir\)/$path");
6929                 # Distribute any included file.
6930
6931                 # Always use the $(top_srcdir) prefix in DIST_COMMON,
6932                 # otherwise OSF make will implicitly copy the included
6933                 # file in the build tree during `make distdir' to satisfy
6934                 # the dependency.
6935                 # (subdircond2.test and subdircond3.test will fail.)
6936                 push_dist_common ("\$\(top_srcdir\)/$path");
6937               }
6938             else
6939               {
6940                 $path =~ s/\$\(srcdir\)\///;
6941                 push (@include_stack, "\$\(srcdir\)/$path");
6942                 # Always use the $(srcdir) prefix in DIST_COMMON,
6943                 # otherwise OSF make will implicitly copy the included
6944                 # file in the build tree during `make distdir' to satisfy
6945                 # the dependency.
6946                 # (subdircond2.test and subdircond3.test will fail.)
6947                 push_dist_common ("\$\(srcdir\)/$path");
6948                 $path = $relative_dir . "/" . $path if $relative_dir ne '.';
6949               }
6950             $where->push_context ("`$path' included from here");
6951             &read_am_file ($path, $where);
6952             $where->pop_context;
6953         }
6954         else
6955         {
6956             # This isn't an error; it is probably a continued rule.
6957             # In fact, this is what we assume.
6958             $prev_state = IN_RULE_DEF;
6959             check_variable_expansions ($_, $where);
6960             $output_trailer .= $comment . $spacing;
6961             my $cond = new Automake::Condition @cond_stack;
6962             $output_trailer .= $cond->subst_string;
6963             $output_trailer .= $_;
6964             $comment = $spacing = '';
6965             error $where, "`#' comment at start of rule is unportable"
6966               if $_ =~ /^\t\s*\#/;
6967         }
6968
6969         $saw_bk = $new_saw_bk;
6970         $_ = $am_file->getline;
6971     }
6972
6973     $output_trailer .= $comment;
6974
6975     error ($where, "trailing backslash on last line")
6976       if $saw_bk;
6977
6978     error ($where, (@cond_stack ? "unterminated conditionals: @cond_stack"
6979                     : "too many conditionals closed in include file"))
6980       if "@saved_cond_stack" ne "@cond_stack";
6981 }
6982
6983
6984 # define_standard_variables ()
6985 # ----------------------------
6986 # A helper for read_main_am_file which initializes configure variables
6987 # and variables from header-vars.am.
6988 sub define_standard_variables
6989 {
6990   my $saved_output_vars = $output_vars;
6991   my ($comments, undef, $rules) =
6992     file_contents_internal (1, "$libdir/am/header-vars.am",
6993                             new Automake::Location);
6994
6995   foreach my $var (sort keys %configure_vars)
6996     {
6997       &define_configure_variable ($var);
6998     }
6999
7000   $output_vars .= $comments . $rules;
7001 }
7002
7003 # Read main am file.
7004 sub read_main_am_file
7005 {
7006     my ($amfile) = @_;
7007
7008     # This supports the strange variable tricks we are about to play.
7009     prog_error ("variable defined before read_main_am_file\n" . variables_dump ())
7010       if (scalar (variables) > 0);
7011
7012     # Generate copyright header for generated Makefile.in.
7013     # We do discard the output of predefined variables, handled below.
7014     $output_vars = ("# $in_file_name generated by automake "
7015                    . $VERSION . " from $am_file_name.\n");
7016     $output_vars .= '# ' . subst ('configure_input') . "\n";
7017     $output_vars .= $gen_copyright;
7018
7019     # We want to predefine as many variables as possible.  This lets
7020     # the user set them with `+=' in Makefile.am.
7021     &define_standard_variables;
7022
7023     # Read user file, which might override some of our values.
7024     &read_am_file ($amfile, new Automake::Location);
7025 }
7026
7027
7028
7029 ################################################################
7030
7031 # $FLATTENED
7032 # &flatten ($STRING)
7033 # ------------------
7034 # Flatten the $STRING and return the result.
7035 sub flatten
7036 {
7037   $_ = shift;
7038
7039   s/\\\n//somg;
7040   s/\s+/ /g;
7041   s/^ //;
7042   s/ $//;
7043
7044   return $_;
7045 }
7046
7047
7048 # transform_token ($TOKEN, \%PAIRS, $KEY)
7049 # =======================================
7050 # Return the value associated to $KEY in %PAIRS, as used on $TOKEN
7051 # (which should be ?KEY? or any of the special %% requests)..
7052 sub transform_token ($$$)
7053 {
7054   my ($token, $transform, $key) = @_;
7055   my $res = $transform->{$key};
7056   prog_error "Unknown key `$key' in `$token'" unless defined $res;
7057   return $res;
7058 }
7059
7060
7061 # transform ($TOKEN, \%PAIRS)
7062 # ===========================
7063 # If ($TOKEN, $VAL) is in %PAIRS:
7064 #   - replaces %KEY% with $VAL,
7065 #   - enables/disables ?KEY? and ?!KEY?,
7066 #   - replaces %?KEY% with TRUE or FALSE.
7067 #   - replaces %KEY?IFTRUE%, %KEY:IFFALSE%, and %KEY?IFTRUE:IFFALSE% with
7068 #     IFTRUE / IFFALSE, as appropriate.
7069 sub transform ($$)
7070 {
7071   my ($token, $transform) = @_;
7072
7073   # %KEY%.
7074   # Must be before the following pattern to exclude the case
7075   # when there is neither IFTRUE nor IFFALSE.
7076   if ($token =~ /^%([\w\-]+)%$/)
7077     {
7078       return transform_token ($token, $transform, $1);
7079     }
7080   # %KEY?IFTRUE%, %KEY:IFFALSE%, and %KEY?IFTRUE:IFFALSE%.
7081   elsif ($token =~ /^%([\w\-]+)(?:\?([^?:%]+))?(?::([^?:%]+))?%$/)
7082     {
7083       return transform_token ($token, $transform, $1) ? ($2 || '') : ($3 || '');
7084     }
7085   # %?KEY%.
7086   elsif ($token =~ /^%\?([\w\-]+)%$/)
7087     {
7088       return transform_token ($token, $transform, $1) ? 'TRUE' : 'FALSE';
7089     }
7090   # ?KEY? and ?!KEY?.
7091   elsif ($token =~ /^ \? (!?) ([\w\-]+) \? $/x)
7092     {
7093       my $neg = ($1 eq '!') ? 1 : 0;
7094       my $val = transform_token ($token, $transform, $2);
7095       return (!!$val == $neg) ? '##%' : '';
7096     }
7097   else
7098     {
7099       prog_error "Unknown request format: $token";
7100     }
7101 }
7102
7103
7104 # @PARAGRAPHS
7105 # &make_paragraphs ($MAKEFILE, [%TRANSFORM])
7106 # ------------------------------------------
7107 # Load a $MAKEFILE, apply the %TRANSFORM, and return it as a list of
7108 # paragraphs.
7109 sub make_paragraphs ($%)
7110 {
7111   my ($file, %transform) = @_;
7112
7113   # Complete %transform with global options.
7114   # Note that %transform goes last, so it overrides global options.
7115   %transform = ('CYGNUS'      => !! option 'cygnus',
7116                  'MAINTAINER-MODE'
7117                  => $seen_maint_mode ? subst ('MAINTAINER_MODE_TRUE') : '',
7118
7119                  'XZ'          => !! option 'dist-xz',
7120                  'LZMA'        => !! option 'dist-lzma',
7121                  'LZIP'        => !! option 'dist-lzip',
7122                  'BZIP2'       => !! option 'dist-bzip2',
7123                  'COMPRESS'    => !! option 'dist-tarZ',
7124                  'GZIP'        =>  ! option 'no-dist-gzip',
7125                  'SHAR'        => !! option 'dist-shar',
7126                  'ZIP'         => !! option 'dist-zip',
7127
7128                  'INSTALL-INFO' =>  ! option 'no-installinfo',
7129                  'INSTALL-MAN'  =>  ! option 'no-installman',
7130                  'HAVE-MANS'    => !! var ('MANS'),
7131                  'CK-NEWS'      => !! option 'check-news',
7132
7133                  'SUBDIRS'      => !! var ('SUBDIRS'),
7134                  'TOPDIR_P'     => $relative_dir eq '.',
7135
7136                  'BUILD'    => ($seen_canonical >= AC_CANONICAL_BUILD),
7137                  'HOST'     => ($seen_canonical >= AC_CANONICAL_HOST),
7138                  'TARGET'   => ($seen_canonical >= AC_CANONICAL_TARGET),
7139
7140                  'LIBTOOL'      => !! var ('LIBTOOL'),
7141                  'NONLIBTOOL'   => 1,
7142                  'FIRST'        => ! $transformed_files{$file},
7143                 %transform);
7144
7145   $transformed_files{$file} = 1;
7146   $_ = $am_file_cache{$file};
7147
7148   if (! defined $_)
7149     {
7150       verb "reading $file";
7151       # Swallow the whole file.
7152       my $fc_file = new Automake::XFile "< $file";
7153       my $saved_dollar_slash = $/;
7154       undef $/;
7155       $_ = $fc_file->getline;
7156       $/ = $saved_dollar_slash;
7157       $fc_file->close;
7158
7159       # Remove ##-comments.
7160       # Besides we don't need more than two consecutive new-lines.
7161       s/(?:$IGNORE_PATTERN|(?<=\n\n)\n+)//gom;
7162
7163       $am_file_cache{$file} = $_;
7164     }
7165
7166   # Substitute Automake template tokens.
7167   s/(?: % \?? [\w\-]+ %
7168       | % [\w\-]+ (?:\?[^?:%]+)? (?::[^?:%]+)? %
7169       | \? !? [\w\-]+ \?
7170     )/transform($&, \%transform)/gex;
7171   # transform() may have added some ##%-comments to strip.
7172   # (we use `##%' instead of `##' so we can distinguish ##%##%##% from
7173   # ####### and do not remove the latter.)
7174   s/^[ \t]*(?:##%)+.*\n//gm;
7175
7176   # Split at unescaped new lines.
7177   my @lines = split (/(?<!\\)\n/, $_);
7178   my @res;
7179
7180   while (defined ($_ = shift @lines))
7181     {
7182       my $paragraph = $_;
7183       # If we are a rule, eat as long as we start with a tab.
7184       if (/$RULE_PATTERN/smo)
7185         {
7186           while (defined ($_ = shift @lines) && $_ =~ /^\t/)
7187             {
7188               $paragraph .= "\n$_";
7189             }
7190           unshift (@lines, $_);
7191         }
7192
7193       # If we are a comments, eat as much comments as you can.
7194       elsif (/$COMMENT_PATTERN/smo)
7195         {
7196           while (defined ($_ = shift @lines)
7197                  && $_ =~ /$COMMENT_PATTERN/smo)
7198             {
7199               $paragraph .= "\n$_";
7200             }
7201           unshift (@lines, $_);
7202         }
7203
7204       push @res, $paragraph;
7205     }
7206
7207   return @res;
7208 }
7209
7210
7211
7212 # ($COMMENT, $VARIABLES, $RULES)
7213 # &file_contents_internal ($IS_AM, $FILE, $WHERE, [%TRANSFORM])
7214 # -------------------------------------------------------------
7215 # Return contents of a file from $libdir/am, automatically skipping
7216 # macros or rules which are already known. $IS_AM iff the caller is
7217 # reading an Automake file (as opposed to the user's Makefile.am).
7218 sub file_contents_internal ($$$%)
7219 {
7220     my ($is_am, $file, $where, %transform) = @_;
7221
7222     $where->set ($file);
7223
7224     my $result_vars = '';
7225     my $result_rules = '';
7226     my $comment = '';
7227     my $spacing = '';
7228
7229     # The following flags are used to track rules spanning across
7230     # multiple paragraphs.
7231     my $is_rule = 0;            # 1 if we are processing a rule.
7232     my $discard_rule = 0;       # 1 if the current rule should not be output.
7233
7234     # We save the conditional stack on entry, and then check to make
7235     # sure it is the same on exit.  This lets us conditionally include
7236     # other files.
7237     my @saved_cond_stack = @cond_stack;
7238     my $cond = new Automake::Condition (@cond_stack);
7239
7240     foreach (make_paragraphs ($file, %transform))
7241     {
7242         # FIXME: no line number available.
7243         $where->set ($file);
7244
7245         # Sanity checks.
7246         error $where, "blank line following trailing backslash:\n$_"
7247           if /\\$/;
7248         error $where, "comment following trailing backslash:\n$_"
7249           if /\\#/;
7250
7251         if (/^$/)
7252         {
7253             $is_rule = 0;
7254             # Stick empty line before the incoming macro or rule.
7255             $spacing = "\n";
7256         }
7257         elsif (/$COMMENT_PATTERN/mso)
7258         {
7259             $is_rule = 0;
7260             # Stick comments before the incoming macro or rule.
7261             $comment = "$_\n";
7262         }
7263
7264         # Handle inclusion of other files.
7265         elsif (/$INCLUDE_PATTERN/o)
7266         {
7267             if ($cond != FALSE)
7268               {
7269                 my $file = ($is_am ? "$libdir/am/" : '') . $1;
7270                 $where->push_context ("`$file' included from here");
7271                 # N-ary `.=' fails.
7272                 my ($com, $vars, $rules)
7273                   = file_contents_internal ($is_am, $file, $where, %transform);
7274                 $where->pop_context;
7275                 $comment .= $com;
7276                 $result_vars .= $vars;
7277                 $result_rules .= $rules;
7278               }
7279         }
7280
7281         # Handling the conditionals.
7282         elsif (/$IF_PATTERN/o)
7283           {
7284             $cond = cond_stack_if ($1, $2, $file);
7285           }
7286         elsif (/$ELSE_PATTERN/o)
7287           {
7288             $cond = cond_stack_else ($1, $2, $file);
7289           }
7290         elsif (/$ENDIF_PATTERN/o)
7291           {
7292             $cond = cond_stack_endif ($1, $2, $file);
7293           }
7294
7295         # Handling rules.
7296         elsif (/$RULE_PATTERN/mso)
7297         {
7298           $is_rule = 1;
7299           $discard_rule = 0;
7300           # Separate relationship from optional actions: the first
7301           # `new-line tab" not preceded by backslash (continuation
7302           # line).
7303           my $paragraph = $_;
7304           /^(.*?)(?:(?<!\\)\n(\t.*))?$/s;
7305           my ($relationship, $actions) = ($1, $2 || '');
7306
7307           # Separate targets from dependencies: the first colon.
7308           $relationship =~ /^([^:]+\S+) *: *(.*)$/som;
7309           my ($targets, $dependencies) = ($1, $2);
7310           # Remove the escaped new lines.
7311           # I don't know why, but I have to use a tmp $flat_deps.
7312           my $flat_deps = &flatten ($dependencies);
7313           my @deps = split (' ', $flat_deps);
7314
7315           foreach (split (' ', $targets))
7316             {
7317               # FIXME: 1. We are not robust to people defining several targets
7318               # at once, only some of them being in %dependencies.  The
7319               # actions from the targets in %dependencies are usually generated
7320               # from the content of %actions, but if some targets in $targets
7321               # are not in %dependencies the ELSE branch will output
7322               # a rule for all $targets (i.e. the targets which are both
7323               # in %dependencies and $targets will have two rules).
7324
7325               # FIXME: 2. The logic here is not able to output a
7326               # multi-paragraph rule several time (e.g. for each condition
7327               # it is defined for) because it only knows the first paragraph.
7328
7329               # FIXME: 3. We are not robust to people defining a subset
7330               # of a previously defined "multiple-target" rule.  E.g.
7331               # `foo:' after `foo bar:'.
7332
7333               # Output only if not in FALSE.
7334               if (defined $dependencies{$_} && $cond != FALSE)
7335                 {
7336                   &depend ($_, @deps);
7337                   register_action ($_, $actions);
7338                 }
7339               else
7340                 {
7341                   # Free-lance dependency.  Output the rule for all the
7342                   # targets instead of one by one.
7343                   my @undefined_conds =
7344                     Automake::Rule::define ($targets, $file,
7345                                             $is_am ? RULE_AUTOMAKE : RULE_USER,
7346                                             $cond, $where);
7347                   for my $undefined_cond (@undefined_conds)
7348                     {
7349                       my $condparagraph = $paragraph;
7350                       $condparagraph =~ s/^/$undefined_cond->subst_string/gme;
7351                       $result_rules .= "$spacing$comment$condparagraph\n";
7352                     }
7353                   if (scalar @undefined_conds == 0)
7354                     {
7355                       # Remember to discard next paragraphs
7356                       # if they belong to this rule.
7357                       # (but see also FIXME: #2 above.)
7358                       $discard_rule = 1;
7359                     }
7360                   $comment = $spacing = '';
7361                   last;
7362                 }
7363             }
7364         }
7365
7366         elsif (/$ASSIGNMENT_PATTERN/mso)
7367         {
7368             my ($var, $type, $val) = ($1, $2, $3);
7369             error $where, "variable `$var' with trailing backslash"
7370               if /\\$/;
7371
7372             $is_rule = 0;
7373
7374             Automake::Variable::define ($var,
7375                                         $is_am ? VAR_AUTOMAKE : VAR_MAKEFILE,
7376                                         $type, $cond, $val, $comment, $where,
7377                                         VAR_ASIS)
7378               if $cond != FALSE;
7379
7380             $comment = $spacing = '';
7381         }
7382         else
7383         {
7384             # This isn't an error; it is probably some tokens which
7385             # configure is supposed to replace, such as `@SET-MAKE@',
7386             # or some part of a rule cut by an if/endif.
7387             if (! $cond->false && ! ($is_rule && $discard_rule))
7388               {
7389                 s/^/$cond->subst_string/gme;
7390                 $result_rules .= "$spacing$comment$_\n";
7391               }
7392             $comment = $spacing = '';
7393         }
7394     }
7395
7396     error ($where, @cond_stack ?
7397            "unterminated conditionals: @cond_stack" :
7398            "too many conditionals closed in include file")
7399       if "@saved_cond_stack" ne "@cond_stack";
7400
7401     return ($comment, $result_vars, $result_rules);
7402 }
7403
7404
7405 # $CONTENTS
7406 # &file_contents ($BASENAME, $WHERE, [%TRANSFORM])
7407 # ------------------------------------------------
7408 # Return contents of a file from $libdir/am, automatically skipping
7409 # macros or rules which are already known.
7410 sub file_contents ($$%)
7411 {
7412     my ($basename, $where, %transform) = @_;
7413     my ($comments, $variables, $rules) =
7414       file_contents_internal (1, "$libdir/am/$basename.am", $where,
7415                               %transform);
7416     return "$comments$variables$rules";
7417 }
7418
7419
7420 # @PREFIX
7421 # &am_primary_prefixes ($PRIMARY, $CAN_DIST, @PREFIXES)
7422 # -----------------------------------------------------
7423 # Find all variable prefixes that are used for install directories.  A
7424 # prefix `zar' qualifies iff:
7425 #
7426 # * `zardir' is a variable.
7427 # * `zar_PRIMARY' is a variable.
7428 #
7429 # As a side effect, it looks for misspellings.  It is an error to have
7430 # a variable ending in a "reserved" suffix whose prefix is unknown, e.g.
7431 # "bni_PROGRAMS".  However, unusual prefixes are allowed if a variable
7432 # of the same name (with "dir" appended) exists.  For instance, if the
7433 # variable "zardir" is defined, then "zar_PROGRAMS" becomes valid.
7434 # This is to provide a little extra flexibility in those cases which
7435 # need it.
7436 sub am_primary_prefixes ($$@)
7437 {
7438   my ($primary, $can_dist, @prefixes) = @_;
7439
7440   local $_;
7441   my %valid = map { $_ => 0 } @prefixes;
7442   $valid{'EXTRA'} = 0;
7443   foreach my $var (variables $primary)
7444     {
7445       # Automake is allowed to define variables that look like primaries
7446       # but which aren't.  E.g. INSTALL_sh_DATA.
7447       # Autoconf can also define variables like INSTALL_DATA, so
7448       # ignore all configure variables (at least those which are not
7449       # redefined in Makefile.am).
7450       # FIXME: We should make sure that these variables are not
7451       # conditionally defined (or else adjust the condition below).
7452       my $def = $var->def (TRUE);
7453       next if $def && $def->owner != VAR_MAKEFILE;
7454
7455       my $varname = $var->name;
7456
7457       if ($varname =~ /^(nobase_)?(dist_|nodist_)?(.*)_[[:alnum:]]+$/)
7458         {
7459           my ($base, $dist, $X) = ($1 || '', $2 || '', $3 || '');
7460           if ($dist ne '' && ! $can_dist)
7461             {
7462               err_var ($var,
7463                        "invalid variable `$varname': `dist' is forbidden");
7464             }
7465           # Standard directories must be explicitly allowed.
7466           elsif (! defined $valid{$X} && exists $standard_prefix{$X})
7467             {
7468               err_var ($var,
7469                        "`${X}dir' is not a legitimate directory " .
7470                        "for `$primary'");
7471             }
7472           # A not explicitly valid directory is allowed if Xdir is defined.
7473           elsif (! defined $valid{$X} &&
7474                  $var->requires_variables ("`$varname' is used", "${X}dir"))
7475             {
7476               # Nothing to do.  Any error message has been output
7477               # by $var->requires_variables.
7478             }
7479           else
7480             {
7481               # Ensure all extended prefixes are actually used.
7482               $valid{"$base$dist$X"} = 1;
7483             }
7484         }
7485       else
7486         {
7487           prog_error "unexpected variable name: $varname";
7488         }
7489     }
7490
7491   # Return only those which are actually defined.
7492   return sort grep { var ($_ . '_' . $primary) } keys %valid;
7493 }
7494
7495
7496 # Handle `where_HOW' variable magic.  Does all lookups, generates
7497 # install code, and possibly generates code to define the primary
7498 # variable.  The first argument is the name of the .am file to munge,
7499 # the second argument is the primary variable (e.g. HEADERS), and all
7500 # subsequent arguments are possible installation locations.
7501 #
7502 # Returns list of [$location, $value] pairs, where
7503 # $value's are the values in all where_HOW variable, and $location
7504 # there associated location (the place here their parent variables were
7505 # defined).
7506 #
7507 # FIXME: this should be rewritten to be cleaner.  It should be broken
7508 # up into multiple functions.
7509 #
7510 # Usage is: am_install_var (OPTION..., file, HOW, where...)
7511 sub am_install_var
7512 {
7513   my (@args) = @_;
7514
7515   my $do_require = 1;
7516   my $can_dist = 0;
7517   my $default_dist = 0;
7518   while (@args)
7519     {
7520       if ($args[0] eq '-noextra')
7521         {
7522           $do_require = 0;
7523         }
7524       elsif ($args[0] eq '-candist')
7525         {
7526           $can_dist = 1;
7527         }
7528       elsif ($args[0] eq '-defaultdist')
7529         {
7530           $default_dist = 1;
7531           $can_dist = 1;
7532         }
7533       elsif ($args[0] !~ /^-/)
7534         {
7535           last;
7536         }
7537       shift (@args);
7538     }
7539
7540   my ($file, $primary, @prefix) = @args;
7541
7542   # Now that configure substitutions are allowed in where_HOW
7543   # variables, it is an error to actually define the primary.  We
7544   # allow `JAVA', as it is customarily used to mean the Java
7545   # interpreter.  This is but one of several Java hacks.  Similarly,
7546   # `PYTHON' is customarily used to mean the Python interpreter.
7547   reject_var $primary, "`$primary' is an anachronism"
7548     unless $primary eq 'JAVA' || $primary eq 'PYTHON';
7549
7550   # Get the prefixes which are valid and actually used.
7551   @prefix = am_primary_prefixes ($primary, $can_dist, @prefix);
7552
7553   # If a primary includes a configure substitution, then the EXTRA_
7554   # form is required.  Otherwise we can't properly do our job.
7555   my $require_extra;
7556
7557   my @used = ();
7558   my @result = ();
7559
7560   foreach my $X (@prefix)
7561     {
7562       my $nodir_name = $X;
7563       my $one_name = $X . '_' . $primary;
7564       my $one_var = var $one_name;
7565
7566       my $strip_subdir = 1;
7567       # If subdir prefix should be preserved, do so.
7568       if ($nodir_name =~ /^nobase_/)
7569         {
7570           $strip_subdir = 0;
7571           $nodir_name =~ s/^nobase_//;
7572         }
7573
7574       # If files should be distributed, do so.
7575       my $dist_p = 0;
7576       if ($can_dist)
7577         {
7578           $dist_p = (($default_dist && $nodir_name !~ /^nodist_/)
7579                      || (! $default_dist && $nodir_name =~ /^dist_/));
7580           $nodir_name =~ s/^(dist|nodist)_//;
7581         }
7582
7583
7584       # Use the location of the currently processed variable.
7585       # We are not processing a particular condition, so pick the first
7586       # available.
7587       my $tmpcond = $one_var->conditions->one_cond;
7588       my $where = $one_var->rdef ($tmpcond)->location->clone;
7589
7590       # Append actual contents of where_PRIMARY variable to
7591       # @result, skipping @substitutions@.
7592       foreach my $locvals ($one_var->value_as_list_recursive (location => 1))
7593         {
7594           my ($loc, $value) = @$locvals;
7595           # Skip configure substitutions.
7596           if ($value =~ /^\@.*\@$/)
7597             {
7598               if ($nodir_name eq 'EXTRA')
7599                 {
7600                   error ($where,
7601                          "`$one_name' contains configure substitution, "
7602                          . "but shouldn't");
7603                 }
7604               # Check here to make sure variables defined in
7605               # configure.ac do not imply that EXTRA_PRIMARY
7606               # must be defined.
7607               elsif (! defined $configure_vars{$one_name})
7608                 {
7609                   $require_extra = $one_name
7610                     if $do_require;
7611                 }
7612             }
7613           else
7614             {
7615               # Strip any $(EXEEXT) suffix the user might have added, or this
7616               # will confuse &handle_source_transform and &check_canonical_spelling.
7617               # We'll add $(EXEEXT) back later anyway.
7618               # Do it here rather than in handle_programs so the uniquifying at the
7619               # end of this function works.
7620               ${$locvals}[1] =~ s/\$\(EXEEXT\)$//
7621                 if $primary eq 'PROGRAMS';
7622
7623               push (@result, $locvals);
7624             }
7625         }
7626       # A blatant hack: we rewrite each _PROGRAMS primary to include
7627       # EXEEXT.
7628       append_exeext { 1 } $one_name
7629         if $primary eq 'PROGRAMS';
7630       # "EXTRA" shouldn't be used when generating clean targets,
7631       # all, or install targets.  We used to warn if EXTRA_FOO was
7632       # defined uselessly, but this was annoying.
7633       next
7634         if $nodir_name eq 'EXTRA';
7635
7636       if ($nodir_name eq 'check')
7637         {
7638           push (@check, '$(' . $one_name . ')');
7639         }
7640       else
7641         {
7642           push (@used, '$(' . $one_name . ')');
7643         }
7644
7645       # Is this to be installed?
7646       my $install_p = $nodir_name ne 'noinst' && $nodir_name ne 'check';
7647
7648       # If so, with install-exec? (or install-data?).
7649       my $exec_p = ($nodir_name =~ /$EXEC_DIR_PATTERN/o);
7650
7651       my $check_options_p = $install_p && !! option 'std-options';
7652
7653       # Use the location of the currently processed variable as context.
7654       $where->push_context ("while processing `$one_name'");
7655
7656       # The variable containing all files to distribute.
7657       my $distvar = "\$($one_name)";
7658       $distvar = shadow_unconditionally ($one_name, $where)
7659         if ($dist_p && $one_var->has_conditional_contents);
7660
7661       # Singular form of $PRIMARY.
7662       (my $one_primary = $primary) =~ s/S$//;
7663       $output_rules .= &file_contents ($file, $where,
7664                                        PRIMARY     => $primary,
7665                                        ONE_PRIMARY => $one_primary,
7666                                        DIR         => $X,
7667                                        NDIR        => $nodir_name,
7668                                        BASE        => $strip_subdir,
7669
7670                                        EXEC      => $exec_p,
7671                                        INSTALL   => $install_p,
7672                                        DIST      => $dist_p,
7673                                        DISTVAR   => $distvar,
7674                                        'CK-OPTS' => $check_options_p);
7675     }
7676
7677   # The JAVA variable is used as the name of the Java interpreter.
7678   # The PYTHON variable is used as the name of the Python interpreter.
7679   if (@used && $primary ne 'JAVA' && $primary ne 'PYTHON')
7680     {
7681       # Define it.
7682       define_pretty_variable ($primary, TRUE, INTERNAL, @used);
7683       $output_vars .= "\n";
7684     }
7685
7686   err_var ($require_extra,
7687            "`$require_extra' contains configure substitution,\n"
7688            . "but `EXTRA_$primary' not defined")
7689     if ($require_extra && ! var ('EXTRA_' . $primary));
7690
7691   # Push here because PRIMARY might be configure time determined.
7692   push (@all, '$(' . $primary . ')')
7693     if @used && $primary ne 'JAVA' && $primary ne 'PYTHON';
7694
7695   # Make the result unique.  This lets the user use conditionals in
7696   # a natural way, but still lets us program lazily -- we don't have
7697   # to worry about handling a particular object more than once.
7698   # We will keep only one location per object.
7699   my %result = ();
7700   for my $pair (@result)
7701     {
7702       my ($loc, $val) = @$pair;
7703       $result{$val} = $loc;
7704     }
7705   my @l = sort keys %result;
7706   return map { [$result{$_}->clone, $_] } @l;
7707 }
7708
7709
7710 ################################################################
7711
7712 # Each key in this hash is the name of a directory holding a
7713 # Makefile.in.  These variables are local to `is_make_dir'.
7714 my %make_dirs = ();
7715 my $make_dirs_set = 0;
7716
7717 sub is_make_dir
7718 {
7719     my ($dir) = @_;
7720     if (! $make_dirs_set)
7721     {
7722         foreach my $iter (@configure_input_files)
7723         {
7724             $make_dirs{dirname ($iter)} = 1;
7725         }
7726         # We also want to notice Makefile.in's.
7727         foreach my $iter (@other_input_files)
7728         {
7729             if ($iter =~ /Makefile\.in$/)
7730             {
7731                 $make_dirs{dirname ($iter)} = 1;
7732             }
7733         }
7734         $make_dirs_set = 1;
7735     }
7736     return defined $make_dirs{$dir};
7737 }
7738
7739 ################################################################
7740
7741 # Find the aux dir.  This should match the algorithm used by
7742 # ./configure. (See the Autoconf documentation for for
7743 # AC_CONFIG_AUX_DIR.)
7744 sub locate_aux_dir ()
7745 {
7746   if (! $config_aux_dir_set_in_configure_ac)
7747     {
7748       # The default auxiliary directory is the first
7749       # of ., .., or ../.. that contains install-sh.
7750       # Assume . if install-sh doesn't exist yet.
7751       for my $dir (qw (. .. ../..))
7752         {
7753           if (-f "$dir/install-sh")
7754             {
7755               $config_aux_dir = $dir;
7756               last;
7757             }
7758         }
7759       $config_aux_dir = '.' unless $config_aux_dir;
7760     }
7761   # Avoid unsightly '/.'s.
7762   $am_config_aux_dir =
7763     '$(top_srcdir)' . ($config_aux_dir eq '.' ? "" : "/$config_aux_dir");
7764   $am_config_aux_dir =~ s,/*$,,;
7765 }
7766
7767
7768 # &maybe_push_required_file ($DIR, $FILE, $FULLFILE)
7769 # --------------------------------------------------
7770 # See if we want to push this file onto dist_common.  This function
7771 # encodes the rules for deciding when to do so.
7772 sub maybe_push_required_file
7773 {
7774   my ($dir, $file, $fullfile) = @_;
7775
7776   if ($dir eq $relative_dir)
7777     {
7778       push_dist_common ($file);
7779       return 1;
7780     }
7781   elsif ($relative_dir eq '.' && ! &is_make_dir ($dir))
7782     {
7783       # If we are doing the topmost directory, and the file is in a
7784       # subdir which does not have a Makefile, then we distribute it
7785       # here.
7786
7787       # If a required file is above the source tree, it is important
7788       # to prefix it with `$(srcdir)' so that no VPATH search is
7789       # performed.  Otherwise problems occur with Make implementations
7790       # that rewrite and simplify rules whose dependencies are found in a
7791       # VPATH location.  Here is an example with OSF1/Tru64 Make.
7792       #
7793       #   % cat Makefile
7794       #   VPATH = sub
7795       #   distdir: ../a
7796       #           echo ../a
7797       #   % ls
7798       #   Makefile a
7799       #   % make
7800       #   echo a
7801       #   a
7802       #
7803       # Dependency `../a' was found in `sub/../a', but this make
7804       # implementation simplified it as `a'.  (Note that the sub/
7805       # directory does not even exist.)
7806       #
7807       # This kind of VPATH rewriting seems hard to cancel.  The
7808       # distdir.am hack against VPATH rewriting works only when no
7809       # simplification is done, i.e., for dependencies which are in
7810       # subdirectories, not in enclosing directories.  Hence, in
7811       # the latter case we use a full path to make sure no VPATH
7812       # search occurs.
7813       $fullfile = '$(srcdir)/' . $fullfile
7814         if $dir =~ m,^\.\.(?:$|/),;
7815
7816       push_dist_common ($fullfile);
7817       return 1;
7818     }
7819   return 0;
7820 }
7821
7822
7823 # If a file name appears as a key in this hash, then it has already
7824 # been checked for.  This allows us not to report the same error more
7825 # than once.
7826 my %required_file_not_found = ();
7827
7828 # &require_file_internal ($WHERE, $MYSTRICT, $DIRECTORY, @FILES)
7829 # --------------------------------------------------------------
7830 # Verify that the file must exist in $DIRECTORY, or install it.
7831 # $MYSTRICT is the strictness level at which this file becomes required.
7832 sub require_file_internal ($$$@)
7833 {
7834   my ($where, $mystrict, $dir, @files) = @_;
7835
7836   foreach my $file (@files)
7837     {
7838       my $fullfile = "$dir/$file";
7839       my $found_it = 0;
7840       my $dangling_sym = 0;
7841
7842       if (-l $fullfile && ! -f $fullfile)
7843         {
7844           $dangling_sym = 1;
7845         }
7846       elsif (dir_has_case_matching_file ($dir, $file))
7847         {
7848           $found_it = 1;
7849           maybe_push_required_file ($dir, $file, $fullfile);
7850         }
7851
7852       # `--force-missing' only has an effect if `--add-missing' is
7853       # specified.
7854       if ($found_it && (! $add_missing || ! $force_missing))
7855         {
7856           next;
7857         }
7858       else
7859         {
7860           # If we've already looked for it, we're done.  You might
7861           # wonder why we don't do this before searching for the
7862           # file.  If we do that, then something like
7863           # AC_OUTPUT(subdir/foo foo) will fail to put foo.in into
7864           # DIST_COMMON.
7865           if (! $found_it)
7866             {
7867               next if defined $required_file_not_found{$fullfile};
7868               $required_file_not_found{$fullfile} = 1;
7869             }
7870
7871           if ($strictness >= $mystrict)
7872             {
7873               if ($dangling_sym && $add_missing)
7874                 {
7875                   unlink ($fullfile);
7876                 }
7877
7878               my $trailer = '';
7879               my $trailer2 = '';
7880               my $suppress = 0;
7881
7882               # Only install missing files according to our desired
7883               # strictness level.
7884               my $message = "required file `$fullfile' not found";
7885               if ($add_missing)
7886                 {
7887                   if (-f "$libdir/$file")
7888                     {
7889                       $suppress = 1;
7890
7891                       # Install the missing file.  Symlink if we
7892                       # can, copy if we must.  Note: delete the file
7893                       # first, in case it is a dangling symlink.
7894                       $message = "installing `$fullfile'";
7895
7896                       # The license file should not be volatile.
7897                       if ($file eq "COPYING")
7898                         {
7899                           $message .= " using GNU General Public License v3 file";
7900                           $trailer2 = "\n    Consider adding the COPYING file"
7901                                     . " to the version control system"
7902                                     . "\n    for your code, to avoid questions"
7903                                     . " about which license your project uses";
7904                         }
7905
7906                       # Windows Perl will hang if we try to delete a
7907                       # file that doesn't exist.
7908                       unlink ($fullfile) if -f $fullfile;
7909                       if ($symlink_exists && ! $copy_missing)
7910                         {
7911                           if (! symlink ("$libdir/$file", $fullfile)
7912                               || ! -e $fullfile)
7913                             {
7914                               $suppress = 0;
7915                               $trailer = "; error while making link: $!";
7916                             }
7917                         }
7918                       elsif (system ('cp', "$libdir/$file", $fullfile))
7919                         {
7920                           $suppress = 0;
7921                           $trailer = "\n    error while copying";
7922                         }
7923                       set_dir_cache_file ($dir, $file);
7924                     }
7925
7926                   if (! maybe_push_required_file (dirname ($fullfile),
7927                                                   $file, $fullfile))
7928                     {
7929                       if (! $found_it && ! $automake_will_process_aux_dir)
7930                         {
7931                           # We have added the file but could not push it
7932                           # into DIST_COMMON, probably because this is
7933                           # an auxiliary file and we are not processing
7934                           # the top level Makefile.  Furthermore Automake
7935                           # hasn't been asked to create the Makefile.in
7936                           # that distributes the aux dir files.
7937                           error ($where, 'please rerun automake without '
7938                                  . "Makefile arguments\n"
7939                                  . "so $fullfile gets distributed");
7940                         }
7941                     }
7942                 }
7943               else
7944                 {
7945                   $trailer = "\n  `automake --add-missing' can install `$file'"
7946                     if -f "$libdir/$file";
7947                 }
7948
7949               # If --force-missing was specified, and we have
7950               # actually found the file, then do nothing.
7951               next
7952                 if $found_it && $force_missing;
7953
7954               # If we couldn't install the file, but it is a target in
7955               # the Makefile, don't print anything.  This allows files
7956               # like README, AUTHORS, or THANKS to be generated.
7957               next
7958                 if !$suppress && rule $file;
7959
7960               msg ($suppress ? 'note' : 'error', $where, "$message$trailer$trailer2");
7961             }
7962         }
7963     }
7964 }
7965
7966 # &require_file ($WHERE, $MYSTRICT, @FILES)
7967 # -----------------------------------------
7968 sub require_file ($$@)
7969 {
7970     my ($where, $mystrict, @files) = @_;
7971     require_file_internal ($where, $mystrict, $relative_dir, @files);
7972 }
7973
7974 # &require_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7975 # -----------------------------------------------------------
7976 sub require_file_with_macro ($$$@)
7977 {
7978     my ($cond, $macro, $mystrict, @files) = @_;
7979     $macro = rvar ($macro) unless ref $macro;
7980     require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7981 }
7982
7983 # &require_libsource_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7984 # ----------------------------------------------------------------
7985 # Require an AC_LIBSOURCEd file.  If AC_CONFIG_LIBOBJ_DIR was called, it
7986 # must be in that directory.  Otherwise expect it in the current directory.
7987 sub require_libsource_with_macro ($$$@)
7988 {
7989     my ($cond, $macro, $mystrict, @files) = @_;
7990     $macro = rvar ($macro) unless ref $macro;
7991     if ($config_libobj_dir)
7992       {
7993         require_file_internal ($macro->rdef ($cond)->location, $mystrict,
7994                                $config_libobj_dir, @files);
7995       }
7996     else
7997       {
7998         require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7999       }
8000 }
8001
8002 # Queue to push require_conf_file requirements to.
8003 my $required_conf_file_queue;
8004
8005 # &queue_required_conf_file ($QUEUE, $KEY, $DIR, $WHERE, $MYSTRICT, @FILES)
8006 # -------------------------------------------------------------------------
8007 sub queue_required_conf_file ($$$$@)
8008 {
8009     my ($queue, $key, $dir, $where, $mystrict, @files) = @_;
8010     my @serial_loc;
8011     if (ref $where)
8012       {
8013         @serial_loc = (QUEUE_LOCATION, $where->serialize ());
8014       }
8015     else
8016       {
8017         @serial_loc = (QUEUE_STRING, $where);
8018       }
8019     $queue->enqueue ($key, $dir, @serial_loc, $mystrict, 0 + @files, @files);
8020 }
8021
8022 # &require_queued_conf_file ($QUEUE)
8023 # ----------------------------------
8024 sub require_queued_conf_file ($)
8025 {
8026     my ($queue) = @_;
8027     my $where;
8028     my $dir = $queue->dequeue ();
8029     my $loc_key = $queue->dequeue ();
8030     if ($loc_key eq QUEUE_LOCATION)
8031       {
8032         $where = Automake::Location::deserialize ($queue);
8033       }
8034     elsif ($loc_key eq QUEUE_STRING)
8035       {
8036         $where = $queue->dequeue ();
8037       }
8038     else
8039       {
8040         prog_error "unexpected key $loc_key";
8041       }
8042     my $mystrict = $queue->dequeue ();
8043     my $nfiles = $queue->dequeue ();
8044     my @files;
8045     push @files, $queue->dequeue ()
8046       foreach (1 .. $nfiles);
8047
8048     # Dequeuing happens outside of per-makefile context, so we have to
8049     # set the variables used by require_file_internal and the functions
8050     # it calls.  Gross!
8051     $relative_dir = $dir;
8052     require_file_internal ($where, $mystrict, $config_aux_dir, @files);
8053 }
8054
8055 # &require_conf_file ($WHERE, $MYSTRICT, @FILES)
8056 # ----------------------------------------------
8057 # Looks in configuration path, as specified by AC_CONFIG_AUX_DIR;
8058 # worker threads may queue up the action to be serialized by the master.
8059 #
8060 # FIXME: this seriously relies on the semantics of require_file_internal
8061 # and maybe_push_required_file, in that we exploit the fact that only the
8062 # contents of the last handled output file may be impacted (which in turn
8063 # is dealt with by the master thread).
8064 sub require_conf_file ($$@)
8065 {
8066     my ($where, $mystrict, @files) = @_;
8067     if (defined $required_conf_file_queue)
8068       {
8069         queue_required_conf_file ($required_conf_file_queue, QUEUE_CONF_FILE,
8070                                   $relative_dir, $where, $mystrict, @files);
8071       }
8072     else
8073       {
8074         require_file_internal ($where, $mystrict, $config_aux_dir, @files);
8075       }
8076 }
8077
8078
8079 # &require_conf_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
8080 # ----------------------------------------------------------------
8081 sub require_conf_file_with_macro ($$$@)
8082 {
8083     my ($cond, $macro, $mystrict, @files) = @_;
8084     require_conf_file (rvar ($macro)->rdef ($cond)->location,
8085                        $mystrict, @files);
8086 }
8087
8088 ################################################################
8089
8090 # &require_build_directory ($DIRECTORY)
8091 # -------------------------------------
8092 # Emit rules to create $DIRECTORY if needed, and return
8093 # the file that any target requiring this directory should be made
8094 # dependent upon.
8095 # We don't want to emit the rule twice, and want to reuse it
8096 # for directories with equivalent names (e.g., `foo/bar' and `./foo//bar').
8097 sub require_build_directory ($)
8098 {
8099   my $directory = shift;
8100
8101   return $directory_map{$directory} if exists $directory_map{$directory};
8102
8103   my $cdir = File::Spec->canonpath ($directory);
8104
8105   if (exists $directory_map{$cdir})
8106     {
8107       my $stamp = $directory_map{$cdir};
8108       $directory_map{$directory} = $stamp;
8109       return $stamp;
8110     }
8111
8112   my $dirstamp = "$cdir/\$(am__dirstamp)";
8113
8114   $directory_map{$directory} = $dirstamp;
8115   $directory_map{$cdir} = $dirstamp;
8116
8117   # Set a variable for the dirstamp basename.
8118   define_pretty_variable ('am__dirstamp', TRUE, INTERNAL,
8119                           '$(am__leading_dot)dirstamp');
8120
8121   # Directory must be removed by `make distclean'.
8122   $clean_files{$dirstamp} = DIST_CLEAN;
8123
8124   $output_rules .= ("$dirstamp:\n"
8125                     . "\t\@\$(MKDIR_P) $directory\n"
8126                     . "\t\@: > $dirstamp\n");
8127
8128   return $dirstamp;
8129 }
8130
8131 # &require_build_directory_maybe ($FILE)
8132 # --------------------------------------
8133 # If $FILE lies in a subdirectory, emit a rule to create this
8134 # directory and return the file that $FILE should be made
8135 # dependent upon.  Otherwise, just return the empty string.
8136 sub require_build_directory_maybe ($)
8137 {
8138     my $file = shift;
8139     my $directory = dirname ($file);
8140
8141     if ($directory ne '.')
8142     {
8143         return require_build_directory ($directory);
8144     }
8145     else
8146     {
8147         return '';
8148     }
8149 }
8150
8151 ################################################################
8152
8153 # Push a list of files onto dist_common.
8154 sub push_dist_common
8155 {
8156   prog_error "push_dist_common run after handle_dist"
8157     if $handle_dist_run;
8158   Automake::Variable::define ('DIST_COMMON', VAR_AUTOMAKE, '+', TRUE, "@_",
8159                               '', INTERNAL, VAR_PRETTY);
8160 }
8161
8162
8163 ################################################################
8164
8165 # generate_makefile ($MAKEFILE_AM, $MAKEFILE_IN)
8166 # ----------------------------------------------
8167 # Generate a Makefile.in given the name of the corresponding Makefile and
8168 # the name of the file output by config.status.
8169 sub generate_makefile ($$)
8170 {
8171   my ($makefile_am, $makefile_in) = @_;
8172
8173   # Reset all the Makefile.am related variables.
8174   initialize_per_input;
8175
8176   # AUTOMAKE_OPTIONS can contains -W flags to disable or enable
8177   # warnings for this file.  So hold any warning issued before
8178   # we have processed AUTOMAKE_OPTIONS.
8179   buffer_messages ('warning');
8180
8181   # Name of input file ("Makefile.am") and output file
8182   # ("Makefile.in").  These have no directory components.
8183   $am_file_name = basename ($makefile_am);
8184   $in_file_name = basename ($makefile_in);
8185
8186   # $OUTPUT is encoded.  If it contains a ":" then the first element
8187   # is the real output file, and all remaining elements are input
8188   # files.  We don't scan or otherwise deal with these input files,
8189   # other than to mark them as dependencies.  See
8190   # &scan_autoconf_files for details.
8191   my ($makefile, @inputs) = split (/:/, $output_files{$makefile_in});
8192
8193   $relative_dir = dirname ($makefile);
8194   $am_relative_dir = dirname ($makefile_am);
8195   $topsrcdir = backname ($relative_dir);
8196
8197   read_main_am_file ($makefile_am);
8198   if (handle_options)
8199     {
8200       # Process buffered warnings.
8201       flush_messages;
8202       # Fatal error.  Just return, so we can continue with next file.
8203       return;
8204     }
8205   # Process buffered warnings.
8206   flush_messages;
8207
8208   # There are a few install-related variables that you should not define.
8209   foreach my $var ('PRE_INSTALL', 'POST_INSTALL', 'NORMAL_INSTALL')
8210     {
8211       my $v = var $var;
8212       if ($v)
8213         {
8214           my $def = $v->def (TRUE);
8215           prog_error "$var not defined in condition TRUE"
8216             unless $def;
8217           reject_var $var, "`$var' should not be defined"
8218             if $def->owner != VAR_AUTOMAKE;
8219         }
8220     }
8221
8222   # Catch some obsolete variables.
8223   msg_var ('obsolete', 'INCLUDES',
8224            "`INCLUDES' is the old name for `AM_CPPFLAGS' (or `*_CPPFLAGS')")
8225     if var ('INCLUDES');
8226
8227   # Must do this after reading .am file.
8228   define_variable ('subdir', $relative_dir, INTERNAL);
8229
8230   # If DIST_SUBDIRS is defined, make sure SUBDIRS is, so that
8231   # recursive rules are enabled.
8232   define_pretty_variable ('SUBDIRS', TRUE, INTERNAL, '')
8233     if var 'DIST_SUBDIRS' && ! var 'SUBDIRS';
8234
8235   # Check first, because we might modify some state.
8236   check_cygnus;
8237   check_gnu_standards;
8238   check_gnits_standards;
8239
8240   handle_configure ($makefile_am, $makefile_in, $makefile, @inputs);
8241   handle_gettext;
8242   handle_libraries;
8243   handle_ltlibraries;
8244   handle_programs;
8245   handle_scripts;
8246
8247   # These must be run after all the sources are scanned.  They
8248   # use variables defined by &handle_libraries, &handle_ltlibraries,
8249   # or &handle_programs.
8250   handle_compile;
8251   handle_languages;
8252   handle_libtool;
8253
8254   # Variables used by distdir.am and tags.am.
8255   define_pretty_variable ('SOURCES', TRUE, INTERNAL, @sources);
8256   if (! option 'no-dist')
8257     {
8258       define_pretty_variable ('DIST_SOURCES', TRUE, INTERNAL, @dist_sources);
8259     }
8260
8261   handle_multilib;
8262   handle_texinfo;
8263   handle_emacs_lisp;
8264   handle_python;
8265   handle_java;
8266   handle_man_pages;
8267   handle_data;
8268   handle_headers;
8269   handle_subdirs;
8270   handle_tags;
8271   handle_minor_options;
8272   # Must come after handle_programs so that %known_programs is up-to-date.
8273   handle_tests;
8274
8275   # This must come after most other rules.
8276   handle_dist;
8277
8278   handle_footer;
8279   do_check_merge_target;
8280   handle_all ($makefile);
8281
8282   # FIXME: Gross!
8283   if (var ('lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
8284     {
8285       $output_rules .= "install-binPROGRAMS: install-libLTLIBRARIES\n\n";
8286     }
8287   if (var ('nobase_lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
8288     {
8289       $output_rules .= "install-binPROGRAMS: install-nobase_libLTLIBRARIES\n\n";
8290     }
8291
8292   handle_install;
8293   handle_clean ($makefile);
8294   handle_factored_dependencies;
8295
8296   # Comes last, because all the above procedures may have
8297   # defined or overridden variables.
8298   $output_vars .= output_variables;
8299
8300   check_typos;
8301
8302   if ($exit_code != 0)
8303     {
8304       verb "not writing $makefile_in because of earlier errors";
8305       return;
8306     }
8307
8308   mkdir ($am_relative_dir, 0755) if ! -d $am_relative_dir;
8309
8310   # We make sure that `all:' is the first target.
8311   my $output =
8312     "$output_vars$output_all$output_header$output_rules$output_trailer";
8313
8314   # Decide whether we must update the output file or not.
8315   # We have to update in the following situations.
8316   #  * $force_generation is set.
8317   #  * any of the output dependencies is younger than the output
8318   #  * the contents of the output is different (this can happen
8319   #    if the project has been populated with a file listed in
8320   #    @common_files since the last run).
8321   # Output's dependencies are split in two sets:
8322   #  * dependencies which are also configure dependencies
8323   #    These do not change between each Makefile.am
8324   #  * other dependencies, specific to the Makefile.am being processed
8325   #    (such as the Makefile.am itself, or any Makefile fragment
8326   #    it includes).
8327   my $timestamp = mtime $makefile_in;
8328   if (! $force_generation
8329       && $configure_deps_greatest_timestamp < $timestamp
8330       && $output_deps_greatest_timestamp < $timestamp
8331       && $output eq contents ($makefile_in))
8332     {
8333       verb "$makefile_in unchanged";
8334       # No need to update.
8335       return;
8336     }
8337
8338   if (-e $makefile_in)
8339     {
8340       unlink ($makefile_in)
8341         or fatal "cannot remove $makefile_in: $!";
8342     }
8343
8344   my $gm_file = new Automake::XFile "> $makefile_in";
8345   verb "creating $makefile_in";
8346   print $gm_file $output;
8347 }
8348
8349 ################################################################
8350
8351
8352
8353
8354 ################################################################
8355
8356 # Print usage information.
8357 sub usage ()
8358 {
8359     print "Usage: $0 [OPTION]... [Makefile]...
8360
8361 Generate Makefile.in for configure from Makefile.am.
8362
8363 Operation modes:
8364       --help               print this help, then exit
8365       --version            print version number, then exit
8366   -v, --verbose            verbosely list files processed
8367       --no-force           only update Makefile.in's that are out of date
8368   -W, --warnings=CATEGORY  report the warnings falling in CATEGORY
8369
8370 Dependency tracking:
8371   -i, --ignore-deps      disable dependency tracking code
8372       --include-deps     enable dependency tracking code
8373
8374 Flavors:
8375       --cygnus           assume program is part of Cygnus-style tree
8376       --foreign          set strictness to foreign
8377       --gnits            set strictness to gnits
8378       --gnu              set strictness to gnu
8379
8380 Library files:
8381   -a, --add-missing      add missing standard files to package
8382       --libdir=DIR       directory storing library files
8383   -c, --copy             with -a, copy missing files (default is symlink)
8384   -f, --force-missing    force update of standard files
8385
8386 ";
8387     Automake::ChannelDefs::usage;
8388
8389     my ($last, @lcomm);
8390     $last = '';
8391     foreach my $iter (sort ((@common_files, @common_sometimes)))
8392     {
8393         push (@lcomm, $iter) unless $iter eq $last;
8394         $last = $iter;
8395     }
8396
8397     my @four;
8398     print "\nFiles which are automatically distributed, if found:\n";
8399     format USAGE_FORMAT =
8400   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<
8401   $four[0],           $four[1],           $four[2],           $four[3]
8402 .
8403     $~ = "USAGE_FORMAT";
8404
8405     my $cols = 4;
8406     my $rows = int(@lcomm / $cols);
8407     my $rest = @lcomm % $cols;
8408
8409     if ($rest)
8410     {
8411         $rows++;
8412     }
8413     else
8414     {
8415         $rest = $cols;
8416     }
8417
8418     for (my $y = 0; $y < $rows; $y++)
8419     {
8420         @four = ("", "", "", "");
8421         for (my $x = 0; $x < $cols; $x++)
8422         {
8423             last if $y + 1 == $rows && $x == $rest;
8424
8425             my $idx = (($x > $rest)
8426                        ?  ($rows * $rest + ($rows - 1) * ($x - $rest))
8427                        : ($rows * $x));
8428
8429             $idx += $y;
8430             $four[$x] = $lcomm[$idx];
8431         }
8432         write;
8433     }
8434
8435     print '
8436 Report bugs to <@PACKAGE_BUGREPORT@>.
8437 GNU Automake home page: <@PACKAGE_URL@>.
8438 General help using GNU software: <http://www.gnu.org/gethelp/>.
8439 ';
8440
8441     # --help always returns 0 per GNU standards.
8442     exit 0;
8443 }
8444
8445
8446 # &version ()
8447 # -----------
8448 # Print version information
8449 sub version ()
8450 {
8451   print <<EOF;
8452 automake (GNU $PACKAGE) $VERSION
8453 Copyright (C) 2011 Free Software Foundation, Inc.
8454 License GPLv2+: GNU GPL version 2 or later <http://gnu.org/licenses/gpl-2.0.html>
8455 This is free software: you are free to change and redistribute it.
8456 There is NO WARRANTY, to the extent permitted by law.
8457
8458 Written by Tom Tromey <tromey\@redhat.com>
8459        and Alexandre Duret-Lutz <adl\@gnu.org>.
8460 EOF
8461   # --version always returns 0 per GNU standards.
8462   exit 0;
8463 }
8464
8465 ################################################################
8466
8467 # Parse command line.
8468 sub parse_arguments ()
8469 {
8470   # Start off as gnu.
8471   set_strictness ('gnu');
8472
8473   my $cli_where = new Automake::Location;
8474   my %cli_options =
8475     (
8476      'libdir=s' => \$libdir,
8477      'gnu'              => sub { set_strictness ('gnu'); },
8478      'gnits'            => sub { set_strictness ('gnits'); },
8479      'cygnus'           => sub { set_global_option ('cygnus', $cli_where); },
8480      'foreign'          => sub { set_strictness ('foreign'); },
8481      'include-deps'     => sub { unset_global_option ('no-dependencies'); },
8482      'i|ignore-deps'    => sub { set_global_option ('no-dependencies',
8483                                                     $cli_where); },
8484      'no-force' => sub { $force_generation = 0; },
8485      'f|force-missing'  => \$force_missing,
8486      'a|add-missing'    => \$add_missing,
8487      'c|copy'           => \$copy_missing,
8488      'v|verbose'        => sub { setup_channel 'verb', silent => 0; },
8489      'W|warnings=s'     => \&parse_warnings,
8490      );
8491   use Getopt::Long;
8492   Getopt::Long::config ("bundling", "pass_through");
8493
8494   # See if --version or --help is used.  We want to process these before
8495   # anything else because the GNU Coding Standards require us to
8496   # `exit 0' after processing these options, and we can't guarantee this
8497   # if we treat other options first.  (Handling other options first
8498   # could produce error diagnostics, and in this condition it is
8499   # confusing if Automake does `exit 0'.)
8500   my %cli_options_1st_pass =
8501     (
8502      'version' => \&version,
8503      'help'    => \&usage,
8504      # Recognize all other options (and their arguments) but do nothing.
8505      map { $_ => sub {} } (keys %cli_options)
8506      );
8507   my @ARGV_backup = @ARGV;
8508   Getopt::Long::GetOptions %cli_options_1st_pass
8509     or exit 1;
8510   @ARGV = @ARGV_backup;
8511
8512   # Now *really* process the options.  This time we know that --help
8513   # and --version are not present, but we specify them nonetheless so
8514   # that ambiguous abbreviation are diagnosed.
8515   Getopt::Long::GetOptions %cli_options, 'version' => sub {}, 'help' => sub {}
8516     or exit 1;
8517
8518   return unless @ARGV;
8519
8520   if ($ARGV[0] =~ /^-./)
8521     {
8522       my %argopts;
8523       for my $k (keys %cli_options)
8524         {
8525           if ($k =~ /(.*)=s$/)
8526             {
8527               map { $argopts{(length ($_) == 1)
8528                              ? "-$_" : "--$_" } = 1; } (split (/\|/, $1));
8529             }
8530         }
8531       if ($ARGV[0] eq '--')
8532         {
8533           shift @ARGV;
8534         }
8535       elsif (exists $argopts{$ARGV[0]})
8536         {
8537           fatal ("option `$ARGV[0]' requires an argument.\n"
8538                  . "Try `$0 --help' for more information");
8539         }
8540       else
8541         {
8542           fatal ("unrecognized option `$ARGV[0]'.\n"
8543                  . "Try `$0 --help' for more information");
8544         }
8545     }
8546
8547   my $errspec = 0;
8548   foreach my $arg (@ARGV)
8549     {
8550       fatal ("empty argument\nTry `$0 --help' for more information")
8551         if ($arg eq '');
8552
8553       # Handle $local:$input syntax.
8554       my ($local, @rest) = split (/:/, $arg);
8555       @rest = ("$local.in",) unless @rest;
8556       my $input = locate_am @rest;
8557       if ($input)
8558         {
8559           push @input_files, $input;
8560           $output_files{$input} = join (':', ($local, @rest));
8561         }
8562       else
8563         {
8564           error "no Automake input file found for `$arg'";
8565           $errspec = 1;
8566         }
8567     }
8568   fatal "no input file found among supplied arguments"
8569     if $errspec && ! @input_files;
8570 }
8571
8572
8573 # handle_makefile ($MAKEFILE_IN)
8574 # ------------------------------
8575 # Deal with $MAKEFILE_IN.
8576 sub handle_makefile ($)
8577 {
8578   my ($file) =  @_;
8579   ($am_file = $file) =~ s/\.in$//;
8580   if (! -f ($am_file . '.am'))
8581     {
8582       error "`$am_file.am' does not exist";
8583     }
8584   else
8585     {
8586       # Any warning setting now local to this Makefile.am.
8587       dup_channel_setup;
8588
8589       generate_makefile ($am_file . '.am', $file);
8590
8591       # Back out any warning setting.
8592       drop_channel_setup;
8593     }
8594 }
8595
8596 # handle_makefiles_serial ()
8597 # --------------------------
8598 # Deal with all makefiles, without threads.
8599 sub handle_makefiles_serial ()
8600 {
8601   foreach my $file (@input_files)
8602     {
8603       handle_makefile ($file);
8604     }
8605 }
8606
8607 # get_number_of_threads ()
8608 # ------------------------
8609 # Logic for deciding how many worker threads to use.
8610 sub get_number_of_threads
8611 {
8612   my $nthreads = $ENV{'AUTOMAKE_JOBS'} || 0;
8613
8614   $nthreads = 0
8615     unless $nthreads =~ /^[0-9]+$/;
8616
8617   # It doesn't make sense to use more threads than makefiles,
8618   my $max_threads = @input_files;
8619
8620   # but a single worker thread is helpful for exposing bugs.
8621   if ($automake_will_process_aux_dir && $max_threads > 1)
8622     {
8623       $max_threads--;
8624     }
8625   if ($nthreads > $max_threads)
8626     {
8627       $nthreads = $max_threads;
8628     }
8629   return $nthreads;
8630 }
8631
8632 # handle_makefiles_threaded ($NTHREADS)
8633 # -------------------------------------
8634 # Deal with all makefiles, using threads.  The general strategy is to
8635 # spawn NTHREADS worker threads, dispatch makefiles to them, and let the
8636 # worker threads push back everything that needs serialization:
8637 # * warning and (normal) error messages, for stable stderr output
8638 #   order and content (avoiding duplicates, for example),
8639 # * races when installing aux files (and respective messages),
8640 # * races when collecting aux files for distribution.
8641 #
8642 # The latter requires that the makefile that deals with the aux dir
8643 # files be handled last, done by the master thread.
8644 sub handle_makefiles_threaded ($)
8645 {
8646   my ($nthreads) = @_;
8647
8648   my @queued_input_files = @input_files;
8649   my $last_input_file = undef;
8650   if ($automake_will_process_aux_dir)
8651     {
8652       $last_input_file = pop @queued_input_files;
8653     }
8654
8655   # The file queue distributes all makefiles, the message queues
8656   # collect all serializations needed for respective files.
8657   my $file_queue = Thread::Queue->new;
8658   my %msg_queues;
8659   foreach my $file (@queued_input_files)
8660     {
8661       $msg_queues{$file} = Thread::Queue->new;
8662     }
8663
8664   verb "spawning $nthreads worker threads";
8665   my @threads = (1 .. $nthreads);
8666   foreach my $t (@threads)
8667     {
8668       $t = threads->new (sub
8669         {
8670           while (my $file = $file_queue->dequeue)
8671             {
8672               verb "handling $file";
8673               my $queue = $msg_queues{$file};
8674               setup_channel_queue ($queue, QUEUE_MESSAGE);
8675               $required_conf_file_queue = $queue;
8676               handle_makefile ($file);
8677               $queue->enqueue (undef);
8678               setup_channel_queue (undef, undef);
8679               $required_conf_file_queue = undef;
8680             }
8681           return $exit_code;
8682         });
8683     }
8684
8685   # Queue all normal makefiles.
8686   verb "queuing " . @queued_input_files . " input files";
8687   $file_queue->enqueue (@queued_input_files, (undef) x @threads);
8688
8689   # Collect and process serializations.
8690   foreach my $file (@queued_input_files)
8691     {
8692       verb "dequeuing messages for " . $file;
8693       reset_local_duplicates ();
8694       my $queue = $msg_queues{$file};
8695       while (my $key = $queue->dequeue)
8696         {
8697           if ($key eq QUEUE_MESSAGE)
8698             {
8699               pop_channel_queue ($queue);
8700             }
8701           elsif ($key eq QUEUE_CONF_FILE)
8702             {
8703               require_queued_conf_file ($queue);
8704             }
8705           else
8706             {
8707               prog_error "unexpected key $key";
8708             }
8709         }
8710     }
8711
8712   foreach my $t (@threads)
8713     {
8714       my @exit_thread = $t->join;
8715       $exit_code = $exit_thread[0]
8716         if ($exit_thread[0] > $exit_code);
8717     }
8718
8719   # The master processes the last file.
8720   if ($automake_will_process_aux_dir)
8721     {
8722       verb "processing last input file";
8723       handle_makefile ($last_input_file);
8724     }
8725 }
8726
8727 ################################################################
8728
8729 # Parse the WARNINGS environment variable.
8730 parse_WARNINGS;
8731
8732 # Parse command line.
8733 parse_arguments;
8734
8735 $configure_ac = require_configure_ac;
8736
8737 # Do configure.ac scan only once.
8738 scan_autoconf_files;
8739
8740 if (! @input_files)
8741   {
8742     my $msg = '';
8743     $msg = "\nDid you forget AC_CONFIG_FILES([Makefile]) in $configure_ac?"
8744       if -f 'Makefile.am';
8745     fatal ("no `Makefile.am' found for any configure output$msg");
8746   }
8747
8748 my $nthreads = get_number_of_threads ();
8749
8750 if ($perl_threads && $nthreads >= 1)
8751   {
8752     handle_makefiles_threaded ($nthreads);
8753   }
8754 else
8755   {
8756     handle_makefiles_serial ();
8757   }
8758
8759 exit $exit_code;
8760
8761
8762 ### Setup "GNU" style for perl-mode and cperl-mode.
8763 ## Local Variables:
8764 ## perl-indent-level: 2
8765 ## perl-continued-statement-offset: 2
8766 ## perl-continued-brace-offset: 0
8767 ## perl-brace-offset: 0
8768 ## perl-brace-imaginary-offset: 0
8769 ## perl-label-offset: -2
8770 ## cperl-indent-level: 2
8771 ## cperl-brace-offset: 0
8772 ## cperl-continued-brace-offset: 0
8773 ## cperl-label-offset: -2
8774 ## cperl-extra-newline-before-brace: t
8775 ## cperl-merge-trailing-else: nil
8776 ## cperl-continued-statement-offset: 2
8777 ## End: