automake.in

   1 #!@PERL@ -w
   2 # -*- perl -*-
   3 # @configure_input@
   4
   5 eval 'case $# in 0) exec @PERL@ -S "$0";; *) exec @PERL@ -S "$0" "$@";; esac'
   6     if 0;
   7
   8 # automake - create Makefile.in from Makefile.am
   9 # Copyright (C) 1994-2012 Free Software Foundation, Inc.
  10
  11 # This program is free software; you can redistribute it and/or modify
  12 # it under the terms of the GNU General Public License as published by
  13 # the Free Software Foundation; either version 2, or (at your option)
  14 # any later version.
  15
  16 # This program is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 # GNU General Public License for more details.
  20
  21 # You should have received a copy of the GNU General Public License
  22 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 # Originally written by David Mackenzie <djm@gnu.ai.mit.edu>.
  25 # Perl reimplementation by Tom Tromey <tromey@redhat.com>, and
  26 # Alexandre Duret-Lutz <adl@gnu.org>.
  27
  28 package Language;
  29
  30 BEGIN
  31 {
  32   my $perllibdir = $ENV{'perllibdir'} || '@datadir@/@PACKAGE@-@APIVERSION@';
  33   unshift @INC, (split '@PATH_SEPARATOR@', $perllibdir);
  34
  35   # Override SHELL.  This is required on DJGPP so that system() uses
  36   # bash, not COMMAND.COM which doesn't quote arguments properly.
  37   # Other systems aren't expected to use $SHELL when Automake
  38   # runs, but it should be safe to drop the "if DJGPP" guard if
  39   # it turns up other systems need the same thing.  After all,
  40   # if SHELL is used, ./configure's SHELL is always better than
  41   # the user's SHELL (which may be something like tcsh).
  42   $ENV{'SHELL'} = '@SHELL@' if exists $ENV{'DJDIR'};
  43 }
  44
  45 use Class::Struct ();
  46 Class::Struct::struct (
  47         # Short name of the language (c, f77...).
  48         'name' => "\$",
  49         # Nice name of the language (C, Fortran 77...).
  50         'Name' => "\$",
  51
  52         # List of configure variables which must be defined.
  53         'config_vars' => '@',
  54
  55         # 'pure' is '1' or ''.  A 'pure' language is one where, if
  56         # all the files in a directory are of that language, then we
  57         # do not require the C compiler or any code to call it.
  58         'pure'   => "\$",
  59
  60         'autodep' => "\$",
  61
  62         # Name of the compiling variable (COMPILE).
  63         'compiler'  => "\$",
  64         # Content of the compiling variable.
  65         'compile'  => "\$",
  66         # Flag to require compilation without linking (-c).
  67         'compile_flag' => "\$",
  68         'extensions' => '@',
  69         # A subroutine to compute a list of possible extensions of
  70         # the product given the input extensions.
  71         # (defaults to a subroutine which returns ('.$(OBJEXT)', '.lo'))
  72         'output_extensions' => "\$",
  73         # A list of flag variables used in 'compile'.
  74         # (defaults to [])
  75         'flags' => "@",
  76
  77         # Any tag to pass to libtool while compiling.
  78         'libtool_tag' => "\$",
  79
  80         # The file to use when generating rules for this language.
  81         # The default is 'depend2'.
  82         'rule_file' => "\$",
  83
  84         # Name of the linking variable (LINK).
  85         'linker' => "\$",
  86         # Content of the linking variable.
  87         'link' => "\$",
  88
  89         # Name of the compiler variable (CC).
  90         'ccer' => "\$",
  91
  92         # Name of the linker variable (LD).
  93         'lder' => "\$",
  94         # Content of the linker variable ($(CC)).
  95         'ld' => "\$",
  96
  97         # Flag to specify the output file (-o).
  98         'output_flag' => "\$",
  99         '_finish' => "\$",
 100
 101         # This is a subroutine which is called whenever we finally
 102         # determine the context in which a source file will be
 103         # compiled.
 104         '_target_hook' => "\$",
 105
 106         # If TRUE, nodist_ sources will be compiled using specific rules
 107         # (i.e. not inference rules).  The default is FALSE.
 108         'nodist_specific' => "\$");
 109
 110
 111 sub finish ($)
 112 {
 113   my ($self) = @_;
 114   if (defined $self->_finish)
 115     {
 116       &{$self->_finish} (@_);
 117     }
 118 }
 119
 120 sub target_hook ($$$$%)
 121 {
 122     my ($self) = @_;
 123     if (defined $self->_target_hook)
 124     {
 125         &{$self->_target_hook} (@_);
 126     }
 127 }
 128
 129 package Automake;
 130
 131 use strict;
 132 use Automake::Config;
 133 BEGIN
 134 {
 135   if ($perl_threads)
 136     {
 137       require threads;
 138       import threads;
 139       require Thread::Queue;
 140       import Thread::Queue;
 141     }
 142 }
 143 use Automake::General;
 144 use Automake::XFile;
 145 use Automake::Channels;
 146 use Automake::ChannelDefs;
 147 use Automake::Configure_ac;
 148 use Automake::FileUtils;
 149 use Automake::Location;
 150 use Automake::Condition qw/TRUE FALSE/;
 151 use Automake::DisjConditions;
 152 use Automake::Options;
 153 use Automake::Variable;
 154 use Automake::VarDef;
 155 use Automake::Rule;
 156 use Automake::RuleDef;
 157 use Automake::Wrap 'makefile_wrap';
 158 use File::Basename;
 159 use File::Spec;
 160 use Carp;
 161
 162 ## ----------- ##
 163 ## Constants.  ##
 164 ## ----------- ##
 165
 166 # Some regular expressions.  One reason to put them here is that it
 167 # makes indentation work better in Emacs.
 168
 169 # Writing singled-quoted-$-terminated regexes is a pain because
 170 # perl-mode thinks of $' as the ${'} variable (instead of a $ followed
 171 # by a closing quote.  Letting perl-mode think the quote is not closed
 172 # leads to all sort of misindentations.  On the other hand, defining
 173 # regexes as double-quoted strings is far less readable.  So usually
 174 # we will write:
 175 #
 176 #  $REGEX = '^regex_value' . "\$";
 177
 178 my $IGNORE_PATTERN = '^\s*##([^#\n].*)?\n';
 179 my $WHITE_PATTERN = '^\s*' . "\$";
 180 my $COMMENT_PATTERN = '^#';
 181 my $TARGET_PATTERN='[$a-zA-Z0-9_.@%][-.a-zA-Z0-9_(){}/$+@%]*';
 182 # A rule has three parts: a list of targets, a list of dependencies,
 183 # and optionally actions.
 184 my $RULE_PATTERN =
 185   "^($TARGET_PATTERN(?:(?:\\\\\n|\\s)+$TARGET_PATTERN)*) *:([^=].*|)\$";
 186
 187 # Only recognize leading spaces, not leading tabs.  If we recognize
 188 # leading tabs here then we need to make the reader smarter, because
 189 # otherwise it will think rules like 'foo=bar; \' are errors.
 190 my $ASSIGNMENT_PATTERN = '^ *([^ \t=:+]*)\s*([:+]?)=\s*(.*)' . "\$";
 191 # This pattern recognizes a Gnits version id and sets $1 if the
 192 # release is an alpha release.  We also allow a suffix which can be
 193 # used to extend the version number with a "fork" identifier.
 194 my $GNITS_VERSION_PATTERN = '\d+\.\d+([a-z]|\.\d+)?(-[A-Za-z0-9]+)?';
 195
 196 my $IF_PATTERN = '^if\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*)\s*(?:#.*)?' . "\$";
 197 my $ELSE_PATTERN =
 198   '^else(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 199 my $ENDIF_PATTERN =
 200   '^endif(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 201 my $PATH_PATTERN = '(\w|[+/.-])+';
 202 # This will pass through anything not of the prescribed form.
 203 my $INCLUDE_PATTERN = ('^include\s+'
 204                        . '((\$\(top_srcdir\)/' . $PATH_PATTERN . ')'
 205                        . '|(\$\(srcdir\)/' . $PATH_PATTERN . ')'
 206                        . '|([^/\$]' . $PATH_PATTERN . '))\s*(#.*)?' . "\$");
 207
 208 # Directories installed during 'install-exec' phase.
 209 my $EXEC_DIR_PATTERN =
 210   '^(?:bin|sbin|libexec|sysconf|localstate|lib|pkglib|.*exec.*)' . "\$";
 211
 212 # Values for AC_CANONICAL_*
 213 use constant AC_CANONICAL_BUILD  => 1;
 214 use constant AC_CANONICAL_HOST   => 2;
 215 use constant AC_CANONICAL_TARGET => 3;
 216
 217 # Values indicating when something should be cleaned.
 218 use constant MOSTLY_CLEAN     => 0;
 219 use constant CLEAN            => 1;
 220 use constant DIST_CLEAN       => 2;
 221 use constant MAINTAINER_CLEAN => 3;
 222
 223 # Libtool files.
 224 my @libtool_files = qw(ltmain.sh config.guess config.sub);
 225 # ltconfig appears here for compatibility with old versions of libtool.
 226 my @libtool_sometimes = qw(ltconfig ltcf-c.sh ltcf-cxx.sh ltcf-gcj.sh);
 227
 228 # Commonly found files we look for and automatically include in
 229 # DISTFILES.
 230 my @common_files =
 231     (qw(ABOUT-GNU ABOUT-NLS AUTHORS BACKLOG COPYING COPYING.DOC COPYING.LIB
 232         COPYING.LESSER ChangeLog INSTALL NEWS README THANKS TODO
 233         ar-lib compile config.guess config.rpath
 234         config.sub depcomp elisp-comp install-sh libversion.in mdate-sh
 235         missing mkinstalldirs py-compile texinfo.tex ylwrap),
 236      @libtool_files, @libtool_sometimes);
 237
 238 # Commonly used files we auto-include, but only sometimes.  This list
 239 # is used for the --help output only.
 240 my @common_sometimes =
 241   qw(aclocal.m4 acconfig.h config.h.top config.h.bot configure
 242      configure.ac configure.in stamp-vti);
 243
 244 # Standard directories from the GNU Coding Standards, and additional
 245 # pkg* directories from Automake.  Stored in a hash for fast member check.
 246 my %standard_prefix =
 247     map { $_ => 1 } (qw(bin data dataroot doc dvi exec html include info
 248                         lib libexec lisp locale localstate man man1 man2
 249                         man3 man4 man5 man6 man7 man8 man9 oldinclude pdf
 250                         pkgdata pkginclude pkglib pkglibexec ps sbin
 251                         sharedstate sysconf));
 252
 253 # Copyright on generated Makefile.ins.
 254 my $gen_copyright = "\
 255 # Copyright (C) 1994-$RELEASE_YEAR Free Software Foundation, Inc.
 256
 257 # This Makefile.in is free software; the Free Software Foundation
 258 # gives unlimited permission to copy and/or distribute it,
 259 # with or without modifications, as long as this notice is preserved.
 260
 261 # This program is distributed in the hope that it will be useful,
 262 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
 263 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 264 # PARTICULAR PURPOSE.
 265 ";
 266
 267 # These constants are returned by the lang_*_rewrite functions.
 268 # LANG_SUBDIR means that the resulting object file should be in a
 269 # subdir if the source file is.  In this case the file name cannot
 270 # have '..' components.
 271 use constant LANG_IGNORE  => 0;
 272 use constant LANG_PROCESS => 1;
 273 use constant LANG_SUBDIR  => 2;
 274
 275 # These are used when keeping track of whether an object can be built
 276 # by two different paths.
 277 use constant COMPILE_LIBTOOL  => 1;
 278 use constant COMPILE_ORDINARY => 2;
 279
 280 # We can't always associate a location to a variable or a rule,
 281 # when it's defined by Automake.  We use INTERNAL in this case.
 282 use constant INTERNAL => new Automake::Location;
 283
 284 # Serialization keys for message queues.
 285 use constant QUEUE_MESSAGE   => "msg";
 286 use constant QUEUE_CONF_FILE => "conf file";
 287 use constant QUEUE_LOCATION  => "location";
 288 use constant QUEUE_STRING    => "string";
 289
 290 ## ---------------------------------- ##
 291 ## Variables related to the options.  ##
 292 ## ---------------------------------- ##
 293
 294 # TRUE if we should always generate Makefile.in.
 295 my $force_generation = 1;
 296
 297 # From the Perl manual.
 298 my $symlink_exists = (eval 'symlink ("", "");', $@ eq '');
 299
 300 # TRUE if missing standard files should be installed.
 301 my $add_missing = 0;
 302
 303 # TRUE if we should copy missing files; otherwise symlink if possible.
 304 my $copy_missing = 0;
 305
 306 # TRUE if we should always update files that we know about.
 307 my $force_missing = 0;
 308
 309
 310 ## ---------------------------------------- ##
 311 ## Variables filled during files scanning.  ##
 312 ## ---------------------------------------- ##
 313
 314 # Name of the configure.ac file.
 315 my $configure_ac;
 316
 317 # Files found by scanning configure.ac for LIBOBJS.
 318 my %libsources = ();
 319
 320 # Names used in AC_CONFIG_HEADER call.
 321 my @config_headers = ();
 322
 323 # Names used in AC_CONFIG_LINKS call.
 324 my @config_links = ();
 325
 326 # List of Makefile.am's to process, and their corresponding outputs.
 327 my @input_files = ();
 328 my %output_files = ();
 329
 330 # Complete list of Makefile.am's that exist.
 331 my @configure_input_files = ();
 332
 333 # List of files in AC_CONFIG_FILES/AC_OUTPUT without Makefile.am's,
 334 # and their outputs.
 335 my @other_input_files = ();
 336 # Where each AC_CONFIG_FILES/AC_OUTPUT/AC_CONFIG_LINK/AC_CONFIG_HEADER appears.
 337 # The keys are the files created by these macros.
 338 my %ac_config_files_location = ();
 339 # The condition under which AC_CONFIG_FOOS appears.
 340 my %ac_config_files_condition = ();
 341
 342 # Directory to search for configure-required files.  This
 343 # will be computed by &locate_aux_dir and can be set using
 344 # AC_CONFIG_AUX_DIR in configure.ac.
 345 # $CONFIG_AUX_DIR is the 'raw' directory, valid only in the source-tree.
 346 my $config_aux_dir = '';
 347 my $config_aux_dir_set_in_configure_ac = 0;
 348 # $AM_CONFIG_AUX_DIR is prefixed with $(top_srcdir), so it can be used
 349 # in Makefiles.
 350 my $am_config_aux_dir = '';
 351
 352 # Directory to search for AC_LIBSOURCE files, as set by AC_CONFIG_LIBOBJ_DIR
 353 # in configure.ac.
 354 my $config_libobj_dir = '';
 355
 356 # Whether AM_GNU_GETTEXT has been seen in configure.ac.
 357 my $seen_gettext = 0;
 358 # Whether AM_GNU_GETTEXT([external]) is used.
 359 my $seen_gettext_external = 0;
 360 # Where AM_GNU_GETTEXT appears.
 361 my $ac_gettext_location;
 362 # Whether AM_GNU_GETTEXT_INTL_SUBDIR has been seen.
 363 my $seen_gettext_intl = 0;
 364
 365 # Lists of tags supported by Libtool.
 366 my %libtool_tags = ();
 367 # 1 if Libtool uses LT_SUPPORTED_TAG.  If it does, then it also
 368 # uses AC_REQUIRE_AUX_FILE.
 369 my $libtool_new_api = 0;
 370
 371 # Most important AC_CANONICAL_* macro seen so far.
 372 my $seen_canonical = 0;
 373 # Location of that macro.
 374 my $canonical_location;
 375
 376 # Where AM_MAINTAINER_MODE appears.
 377 my $seen_maint_mode;
 378
 379 # Actual version we've seen.
 380 my $package_version = '';
 381
 382 # Where version is defined.
 383 my $package_version_location;
 384
 385 # TRUE if we've seen AM_PROG_AR
 386 my $seen_ar = 0;
 387
 388 # TRUE if we've seen AM_PROG_CC_C_O
 389 my $seen_cc_c_o = 0;
 390
 391 # Location of AC_REQUIRE_AUX_FILE calls, indexed by their argument.
 392 my %required_aux_file = ();
 393
 394 # Where AM_INIT_AUTOMAKE is called;
 395 my $seen_init_automake = 0;
 396
 397 # TRUE if we've seen AM_AUTOMAKE_VERSION.
 398 my $seen_automake_version = 0;
 399
 400 # Hash table of discovered configure substitutions.  Keys are names,
 401 # values are 'FILE:LINE' strings which are used by error message
 402 # generation.
 403 my %configure_vars = ();
 404
 405 # Ignored configure substitutions (i.e., variables not to be output in
 406 # Makefile.in)
 407 my %ignored_configure_vars = ();
 408
 409 # Files included by $configure_ac.
 410 my @configure_deps = ();
 411
 412 # Greatest timestamp of configure's dependencies.
 413 my $configure_deps_greatest_timestamp = 0;
 414
 415 # Hash table of AM_CONDITIONAL variables seen in configure.
 416 my %configure_cond = ();
 417
 418 # This maps extensions onto language names.
 419 my %extension_map = ();
 420
 421 # List of the DIST_COMMON files we discovered while reading
 422 # configure.ac.
 423 my $configure_dist_common = '';
 424
 425 # This maps languages names onto objects.
 426 my %languages = ();
 427 # Maps each linker variable onto a language object.
 428 my %link_languages = ();
 429
 430 # maps extensions to needed source flags.
 431 my %sourceflags = ();
 432
 433 # List of targets we must always output.
 434 # FIXME: Complete, and remove falsely required targets.
 435 my %required_targets =
 436   (
 437    'all'          => 1,
 438    'dvi'          => 1,
 439    'pdf'          => 1,
 440    'ps'           => 1,
 441    'info'         => 1,
 442    'install-info' => 1,
 443    'install'      => 1,
 444    'install-data' => 1,
 445    'install-exec' => 1,
 446    'uninstall'    => 1,
 447
 448    # FIXME: Not required, temporary hacks.
 449    # Well, actually they are sort of required: the -recursive
 450    # targets will run them anyway...
 451    'html-am'         => 1,
 452    'dvi-am'          => 1,
 453    'pdf-am'          => 1,
 454    'ps-am'           => 1,
 455    'info-am'         => 1,
 456    'install-data-am' => 1,
 457    'install-exec-am' => 1,
 458    'install-html-am' => 1,
 459    'install-dvi-am'  => 1,
 460    'install-pdf-am'  => 1,
 461    'install-ps-am'   => 1,
 462    'install-info-am' => 1,
 463    'installcheck-am' => 1,
 464    'uninstall-am' => 1,
 465
 466    'install-man' => 1,
 467   );
 468
 469 # Queue to push require_conf_file requirements to.
 470 my $required_conf_file_queue;
 471
 472 # The name of the Makefile currently being processed.
 473 my $am_file = 'BUG';
 474
 475 ################################################################
 476
 477 ## ------------------------------------------ ##
 478 ## Variables reset by &initialize_per_input.  ##
 479 ## ------------------------------------------ ##
 480
 481 # Basename and relative dir of the input file.
 482 my $am_file_name;
 483 my $am_relative_dir;
 484
 485 # Same but wrt Makefile.in.
 486 my $in_file_name;
 487 my $relative_dir;
 488
 489 # Relative path to the top directory.
 490 my $topsrcdir;
 491
 492 # Greatest timestamp of the output's dependencies (excluding
 493 # configure's dependencies).
 494 my $output_deps_greatest_timestamp;
 495
 496 # These variables are used when generating each Makefile.in.
 497 # They hold the Makefile.in until it is ready to be printed.
 498 my $output_vars;
 499 my $output_all;
 500 my $output_header;
 501 my $output_rules;
 502 my $output_trailer;
 503
 504 # This is the conditional stack, updated on if/else/endif, and
 505 # used to build Condition objects.
 506 my @cond_stack;
 507
 508 # This holds the set of included files.
 509 my @include_stack;
 510
 511 # List of dependencies for the obvious targets.
 512 my @all;
 513 my @check;
 514 my @check_tests;
 515
 516 # Keys in this hash table are files to delete.  The associated
 517 # value tells when this should happen (MOSTLY_CLEAN, DIST_CLEAN, etc.)
 518 my %clean_files;
 519
 520 # Keys in this hash table are object files or other files in
 521 # subdirectories which need to be removed.  This only holds files
 522 # which are created by compilations.  The value in the hash indicates
 523 # when the file should be removed.
 524 my %compile_clean_files;
 525
 526 # Keys in this hash table are directories where we expect to build a
 527 # libtool object.  We use this information to decide what directories
 528 # to delete.
 529 my %libtool_clean_directories;
 530
 531 # Value of $(SOURCES), used by tags.am.
 532 my @sources;
 533 # Sources which go in the distribution.
 534 my @dist_sources;
 535
 536 # This hash maps object file names onto their corresponding source
 537 # file names.  This is used to ensure that each object is created
 538 # by a single source file.
 539 my %object_map;
 540
 541 # This hash maps object file names onto an integer value representing
 542 # whether this object has been built via ordinary compilation or
 543 # libtool compilation (the COMPILE_* constants).
 544 my %object_compilation_map;
 545
 546
 547 # This keeps track of the directories for which we've already
 548 # created dirstamp code.  Keys are directories, values are stamp files.
 549 # Several keys can share the same stamp files if they are equivalent
 550 # (as are './/foo' and 'foo').
 551 my %directory_map;
 552
 553 # All .P files.
 554 my %dep_files;
 555
 556 # This is a list of all targets to run during "make dist".
 557 my @dist_targets;
 558
 559 # Keep track of all programs declared in this Makefile, without
 560 # $(EXEEXT).  @substitutions@ are not listed.
 561 my %known_programs;
 562 my %known_libraries;
 563
 564 # This keeps track of which extensions we've seen (that we care
 565 # about).
 566 my %extension_seen;
 567
 568 # This is random scratch space for the language finish functions.
 569 # Don't randomly overwrite it; examine other uses of keys first.
 570 my %language_scratch;
 571
 572 # We keep track of which objects need special (per-executable)
 573 # handling on a per-language basis.
 574 my %lang_specific_files;
 575
 576 # This is set when 'handle_dist' has finished.  Once this happens,
 577 # we should no longer push on dist_common.
 578 my $handle_dist_run;
 579
 580 # Used to store a set of linkers needed to generate the sources currently
 581 # under consideration.
 582 my %linkers_used;
 583
 584 # True if we need 'LINK' defined.  This is a hack.
 585 my $need_link;
 586
 587 # Does the generated Makefile have to build some compiled object
 588 # (for binary programs, or plain or libtool libraries)?
 589 my $must_handle_compiled_objects;
 590
 591 # Record each file processed by make_paragraphs.
 592 my %transformed_files;
 593
 594 ################################################################
 595
 596 ## ---------------------------------------------- ##
 597 ## Variables not reset by &initialize_per_input.  ##
 598 ## ---------------------------------------------- ##
 599
 600 # Cache each file processed by make_paragraphs.
 601 # (This is different from %transformed_files because
 602 # %transformed_files is reset for each file while %am_file_cache
 603 # it global to the run.)
 604 my %am_file_cache;
 605
 606 ################################################################
 607
 608 # var_SUFFIXES_trigger ($TYPE, $VALUE)
 609 # ------------------------------------
 610 # This is called by Automake::Variable::define() when SUFFIXES
 611 # is defined ($TYPE eq '') or appended ($TYPE eq '+').
 612 # The work here needs to be performed as a side-effect of the
 613 # macro_define() call because SUFFIXES definitions impact
 614 # on $KNOWN_EXTENSIONS_PATTERN which is used used when parsing
 615 # the input am file.
 616 sub var_SUFFIXES_trigger ($$)
 617 {
 618     my ($type, $value) = @_;
 619     accept_extensions (split (' ', $value));
 620 }
 621 Automake::Variable::hook ('SUFFIXES', \&var_SUFFIXES_trigger);
 622
 623 ################################################################
 624
 625 ## --------------------------------- ##
 626 ## Forward subroutine declarations.  ##
 627 ## --------------------------------- ##
 628 sub register_language (%);
 629 sub file_contents_internal ($$$%);
 630 sub define_files_variable ($\@$$);
 631
 632
 633 # &initialize_per_input ()
 634 # ------------------------
 635 # (Re)-Initialize per-Makefile.am variables.
 636 sub initialize_per_input ()
 637 {
 638     reset_local_duplicates ();
 639
 640     $am_file_name = undef;
 641     $am_relative_dir = undef;
 642
 643     $in_file_name = undef;
 644     $relative_dir = undef;
 645     $topsrcdir = undef;
 646
 647     $output_deps_greatest_timestamp = 0;
 648
 649     $output_vars = '';
 650     $output_all = '';
 651     $output_header = '';
 652     $output_rules = '';
 653     $output_trailer = '';
 654
 655     Automake::Options::reset;
 656     Automake::Variable::reset;
 657     Automake::Rule::reset;
 658
 659     @cond_stack = ();
 660
 661     @include_stack = ();
 662
 663     @all = ();
 664     @check = ();
 665     @check_tests = ();
 666
 667     %clean_files = ();
 668     %compile_clean_files = ();
 669
 670     # We always include '.'.  This isn't strictly correct.
 671     %libtool_clean_directories = ('.' => 1);
 672
 673     @sources = ();
 674     @dist_sources = ();
 675
 676     %object_map = ();
 677     %object_compilation_map = ();
 678
 679     %directory_map = ();
 680
 681     %dep_files = ();
 682
 683     @dist_targets = ();
 684
 685     %known_programs = ();
 686     %known_libraries= ();
 687
 688     %extension_seen = ();
 689
 690     %language_scratch = ();
 691
 692     %lang_specific_files = ();
 693
 694     $handle_dist_run = 0;
 695
 696     $need_link = 0;
 697
 698     $must_handle_compiled_objects = 0;
 699
 700     %transformed_files = ();
 701 }
 702
 703
 704 ################################################################
 705
 706 # Initialize our list of languages that are internally supported.
 707
 708 # C.
 709 register_language ('name' => 'c',
 710                    'Name' => 'C',
 711                    'config_vars' => ['CC'],
 712                    'autodep' => '',
 713                    'flags' => ['CFLAGS', 'CPPFLAGS'],
 714                    'ccer' => 'CC',
 715                    'compiler' => 'COMPILE',
 716                    'compile' => '$(CC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CFLAGS) $(CFLAGS)',
 717                    'lder' => 'CCLD',
 718                    'ld' => '$(CC)',
 719                    'linker' => 'LINK',
 720                    'link' => '$(CCLD) $(AM_CFLAGS) $(CFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 721                    'compile_flag' => '-c',
 722                    'libtool_tag' => 'CC',
 723                    'extensions' => ['.c']);
 724
 725 # C++.
 726 register_language ('name' => 'cxx',
 727                    'Name' => 'C++',
 728                    'config_vars' => ['CXX'],
 729                    'linker' => 'CXXLINK',
 730                    'link' => '$(CXXLD) $(AM_CXXFLAGS) $(CXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 731                    'autodep' => 'CXX',
 732                    'flags' => ['CXXFLAGS', 'CPPFLAGS'],
 733                    'compile' => '$(CXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CXXFLAGS) $(CXXFLAGS)',
 734                    'ccer' => 'CXX',
 735                    'compiler' => 'CXXCOMPILE',
 736                    'compile_flag' => '-c',
 737                    'output_flag' => '-o',
 738                    'libtool_tag' => 'CXX',
 739                    'lder' => 'CXXLD',
 740                    'ld' => '$(CXX)',
 741                    'pure' => 1,
 742                    'extensions' => ['.c++', '.cc', '.cpp', '.cxx', '.C']);
 743
 744 # Objective C.
 745 register_language ('name' => 'objc',
 746                    'Name' => 'Objective C',
 747                    'config_vars' => ['OBJC'],
 748                    'linker' => 'OBJCLINK',
 749                    'link' => '$(OBJCLD) $(AM_OBJCFLAGS) $(OBJCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 750                    'autodep' => 'OBJC',
 751                    'flags' => ['OBJCFLAGS', 'CPPFLAGS'],
 752                    'compile' => '$(OBJC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCFLAGS) $(OBJCFLAGS)',
 753                    'ccer' => 'OBJC',
 754                    'compiler' => 'OBJCCOMPILE',
 755                    'compile_flag' => '-c',
 756                    'output_flag' => '-o',
 757                    'lder' => 'OBJCLD',
 758                    'ld' => '$(OBJC)',
 759                    'pure' => 1,
 760                    'extensions' => ['.m']);
 761
 762 # Objective C++.
 763 register_language ('name' => 'objcxx',
 764                    'Name' => 'Objective C++',
 765                    'config_vars' => ['OBJCXX'],
 766                    'linker' => 'OBJCXXLINK',
 767                    'link' => '$(OBJCXXLD) $(AM_OBJCXXFLAGS) $(OBJCXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 768                    'autodep' => 'OBJCXX',
 769                    'flags' => ['OBJCXXFLAGS', 'CPPFLAGS'],
 770                    'compile' => '$(OBJCXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCXXFLAGS) $(OBJCXXFLAGS)',
 771                    'ccer' => 'OBJCXX',
 772                    'compiler' => 'OBJCXXCOMPILE',
 773                    'compile_flag' => '-c',
 774                    'output_flag' => '-o',
 775                    'lder' => 'OBJCXXLD',
 776                    'ld' => '$(OBJCXX)',
 777                    'pure' => 1,
 778                    'extensions' => ['.mm']);
 779
 780 # Unified Parallel C.
 781 register_language ('name' => 'upc',
 782                    'Name' => 'Unified Parallel C',
 783                    'config_vars' => ['UPC'],
 784                    'linker' => 'UPCLINK',
 785                    'link' => '$(UPCLD) $(AM_UPCFLAGS) $(UPCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 786                    'autodep' => 'UPC',
 787                    'flags' => ['UPCFLAGS', 'CPPFLAGS'],
 788                    'compile' => '$(UPC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_UPCFLAGS) $(UPCFLAGS)',
 789                    'ccer' => 'UPC',
 790                    'compiler' => 'UPCCOMPILE',
 791                    'compile_flag' => '-c',
 792                    'output_flag' => '-o',
 793                    'lder' => 'UPCLD',
 794                    'ld' => '$(UPC)',
 795                    'pure' => 1,
 796                    'extensions' => ['.upc']);
 797
 798 # Headers.
 799 register_language ('name' => 'header',
 800                    'Name' => 'Header',
 801                    'extensions' => ['.h', '.H', '.hxx', '.h++', '.hh',
 802                                     '.hpp', '.inc'],
 803                    # No output.
 804                    'output_extensions' => sub { return () },
 805                    # Nothing to do.
 806                    '_finish' => sub { });
 807
 808 # Vala
 809 register_language ('name' => 'vala',
 810                    'Name' => 'Vala',
 811                    'config_vars' => ['VALAC'],
 812                    'flags' => [],
 813                    'compile' => '$(VALAC) $(AM_VALAFLAGS) $(VALAFLAGS)',
 814                    'ccer' => 'VALAC',
 815                    'compiler' => 'VALACOMPILE',
 816                    'extensions' => ['.vala'],
 817                    'output_extensions' => sub { (my $ext = $_[0]) =~ s/vala$/c/;
 818                                                 return ($ext,) },
 819                    'rule_file' => 'vala',
 820                    '_finish' => \&lang_vala_finish,
 821                    '_target_hook' => \&lang_vala_target_hook,
 822                    'nodist_specific' => 1);
 823
 824 # Yacc (C & C++).
 825 register_language ('name' => 'yacc',
 826                    'Name' => 'Yacc',
 827                    'config_vars' => ['YACC'],
 828                    'flags' => ['YFLAGS'],
 829                    'compile' => '$(YACC) $(AM_YFLAGS) $(YFLAGS)',
 830                    'ccer' => 'YACC',
 831                    'compiler' => 'YACCCOMPILE',
 832                    'extensions' => ['.y'],
 833                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 834                                                 return ($ext,) },
 835                    'rule_file' => 'yacc',
 836                    '_finish' => \&lang_yacc_finish,
 837                    '_target_hook' => \&lang_yacc_target_hook,
 838                    'nodist_specific' => 1);
 839 register_language ('name' => 'yaccxx',
 840                    'Name' => 'Yacc (C++)',
 841                    'config_vars' => ['YACC'],
 842                    'rule_file' => 'yacc',
 843                    'flags' => ['YFLAGS'],
 844                    'ccer' => 'YACC',
 845                    'compiler' => 'YACCCOMPILE',
 846                    'compile' => '$(YACC) $(AM_YFLAGS) $(YFLAGS)',
 847                    'extensions' => ['.y++', '.yy', '.yxx', '.ypp'],
 848                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 849                                                 return ($ext,) },
 850                    '_finish' => \&lang_yacc_finish,
 851                    '_target_hook' => \&lang_yacc_target_hook,
 852                    'nodist_specific' => 1);
 853
 854 # Lex (C & C++).
 855 register_language ('name' => 'lex',
 856                    'Name' => 'Lex',
 857                    'config_vars' => ['LEX'],
 858                    'rule_file' => 'lex',
 859                    'flags' => ['LFLAGS'],
 860                    'compile' => '$(LEX) $(AM_LFLAGS) $(LFLAGS)',
 861                    'ccer' => 'LEX',
 862                    'compiler' => 'LEXCOMPILE',
 863                    'extensions' => ['.l'],
 864                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 865                                                 return ($ext,) },
 866                    '_finish' => \&lang_lex_finish,
 867                    '_target_hook' => \&lang_lex_target_hook,
 868                    'nodist_specific' => 1);
 869 register_language ('name' => 'lexxx',
 870                    'Name' => 'Lex (C++)',
 871                    'config_vars' => ['LEX'],
 872                    'rule_file' => 'lex',
 873                    'flags' => ['LFLAGS'],
 874                    'compile' => '$(LEX) $(AM_LFLAGS) $(LFLAGS)',
 875                    'ccer' => 'LEX',
 876                    'compiler' => 'LEXCOMPILE',
 877                    'extensions' => ['.l++', '.ll', '.lxx', '.lpp'],
 878                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 879                                                 return ($ext,) },
 880                    '_finish' => \&lang_lex_finish,
 881                    '_target_hook' => \&lang_lex_target_hook,
 882                    'nodist_specific' => 1);
 883
 884 # Assembler.
 885 register_language ('name' => 'asm',
 886                    'Name' => 'Assembler',
 887                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 888
 889                    'flags' => ['CCASFLAGS'],
 890                    # Users can set AM_CCASFLAGS to include DEFS, INCLUDES,
 891                    # or anything else required.  They can also set CCAS.
 892                    # Or simply use Preprocessed Assembler.
 893                    'compile' => '$(CCAS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 894                    'ccer' => 'CCAS',
 895                    'compiler' => 'CCASCOMPILE',
 896                    'compile_flag' => '-c',
 897                    'output_flag' => '-o',
 898                    'extensions' => ['.s']);
 899
 900 # Preprocessed Assembler.
 901 register_language ('name' => 'cppasm',
 902                    'Name' => 'Preprocessed Assembler',
 903                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 904
 905                    'autodep' => 'CCAS',
 906                    'flags' => ['CCASFLAGS', 'CPPFLAGS'],
 907                    'compile' => '$(CCAS) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 908                    'ccer' => 'CPPAS',
 909                    'compiler' => 'CPPASCOMPILE',
 910                    'compile_flag' => '-c',
 911                    'output_flag' => '-o',
 912                    'extensions' => ['.S', '.sx']);
 913
 914 # Fortran 77
 915 register_language ('name' => 'f77',
 916                    'Name' => 'Fortran 77',
 917                    'config_vars' => ['F77'],
 918                    'linker' => 'F77LINK',
 919                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 920                    'flags' => ['FFLAGS'],
 921                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS)',
 922                    'ccer' => 'F77',
 923                    'compiler' => 'F77COMPILE',
 924                    'compile_flag' => '-c',
 925                    'output_flag' => '-o',
 926                    'libtool_tag' => 'F77',
 927                    'lder' => 'F77LD',
 928                    'ld' => '$(F77)',
 929                    'pure' => 1,
 930                    'extensions' => ['.f', '.for']);
 931
 932 # Fortran
 933 register_language ('name' => 'fc',
 934                    'Name' => 'Fortran',
 935                    'config_vars' => ['FC'],
 936                    'linker' => 'FCLINK',
 937                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 938                    'flags' => ['FCFLAGS'],
 939                    'compile' => '$(FC) $(AM_FCFLAGS) $(FCFLAGS)',
 940                    'ccer' => 'FC',
 941                    'compiler' => 'FCCOMPILE',
 942                    'compile_flag' => '-c',
 943                    'output_flag' => '-o',
 944                    'libtool_tag' => 'FC',
 945                    'lder' => 'FCLD',
 946                    'ld' => '$(FC)',
 947                    'pure' => 1,
 948                    'extensions' => ['.f90', '.f95', '.f03', '.f08']);
 949
 950 # Preprocessed Fortran
 951 register_language ('name' => 'ppfc',
 952                    'Name' => 'Preprocessed Fortran',
 953                    'config_vars' => ['FC'],
 954                    'linker' => 'FCLINK',
 955                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 956                    'lder' => 'FCLD',
 957                    'ld' => '$(FC)',
 958                    'flags' => ['FCFLAGS', 'CPPFLAGS'],
 959                    'ccer' => 'PPFC',
 960                    'compiler' => 'PPFCCOMPILE',
 961                    'compile' => '$(FC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FCFLAGS) $(FCFLAGS)',
 962                    'compile_flag' => '-c',
 963                    'output_flag' => '-o',
 964                    'libtool_tag' => 'FC',
 965                    'pure' => 1,
 966                    'extensions' => ['.F90','.F95', '.F03', '.F08']);
 967
 968 # Preprocessed Fortran 77
 969 #
 970 # The current support for preprocessing Fortran 77 just involves
 971 # passing "$(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS)
 972 # $(CPPFLAGS)" as additional flags to the Fortran 77 compiler, since
 973 # this is how GNU Make does it; see the "GNU Make Manual, Edition 0.51
 974 # for 'make' Version 3.76 Beta" (specifically, from info file
 975 # '(make)Catalogue of Rules').
 976 #
 977 # A better approach would be to write an Autoconf test
 978 # (i.e. AC_PROG_FPP) for a Fortran 77 preprocessor, because not all
 979 # Fortran 77 compilers know how to do preprocessing.  The Autoconf
 980 # macro AC_PROG_FPP should test the Fortran 77 compiler first for
 981 # preprocessing capabilities, and then fall back on cpp (if cpp were
 982 # available).
 983 register_language ('name' => 'ppf77',
 984                    'Name' => 'Preprocessed Fortran 77',
 985                    'config_vars' => ['F77'],
 986                    'linker' => 'F77LINK',
 987                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 988                    'lder' => 'F77LD',
 989                    'ld' => '$(F77)',
 990                    'flags' => ['FFLAGS', 'CPPFLAGS'],
 991                    'ccer' => 'PPF77',
 992                    'compiler' => 'PPF77COMPILE',
 993                    'compile' => '$(F77) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FFLAGS) $(FFLAGS)',
 994                    'compile_flag' => '-c',
 995                    'output_flag' => '-o',
 996                    'libtool_tag' => 'F77',
 997                    'pure' => 1,
 998                    'extensions' => ['.F']);
 999
1000 # Ratfor.
1001 register_language ('name' => 'ratfor',
1002                    'Name' => 'Ratfor',
1003                    'config_vars' => ['F77'],
1004                    'linker' => 'F77LINK',
1005                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
1006                    'lder' => 'F77LD',
1007                    'ld' => '$(F77)',
1008                    'flags' => ['RFLAGS', 'FFLAGS'],
1009                    # FIXME also FFLAGS.
1010                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS) $(AM_RFLAGS) $(RFLAGS)',
1011                    'ccer' => 'F77',
1012                    'compiler' => 'RCOMPILE',
1013                    'compile_flag' => '-c',
1014                    'output_flag' => '-o',
1015                    'libtool_tag' => 'F77',
1016                    'pure' => 1,
1017                    'extensions' => ['.r']);
1018
1019 # Java via gcj.
1020 register_language ('name' => 'java',
1021                    'Name' => 'Java',
1022                    'config_vars' => ['GCJ'],
1023                    'linker' => 'GCJLINK',
1024                    'link' => '$(GCJLD) $(AM_GCJFLAGS) $(GCJFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
1025                    'autodep' => 'GCJ',
1026                    'flags' => ['GCJFLAGS'],
1027                    'compile' => '$(GCJ) $(AM_GCJFLAGS) $(GCJFLAGS)',
1028                    'ccer' => 'GCJ',
1029                    'compiler' => 'GCJCOMPILE',
1030                    'compile_flag' => '-c',
1031                    'output_flag' => '-o',
1032                    'libtool_tag' => 'GCJ',
1033                    'lder' => 'GCJLD',
1034                    'ld' => '$(GCJ)',
1035                    'pure' => 1,
1036                    'extensions' => ['.java', '.class', '.zip', '.jar']);
1037
1038 ################################################################
1039
1040 # Error reporting functions.
1041
1042 # err_am ($MESSAGE, [%OPTIONS])
1043 # -----------------------------
1044 # Uncategorized errors about the current Makefile.am.
1045 sub err_am ($;%)
1046 {
1047   msg_am ('error', @_);
1048 }
1049
1050 # err_ac ($MESSAGE, [%OPTIONS])
1051 # -----------------------------
1052 # Uncategorized errors about configure.ac.
1053 sub err_ac ($;%)
1054 {
1055   msg_ac ('error', @_);
1056 }
1057
1058 # msg_am ($CHANNEL, $MESSAGE, [%OPTIONS])
1059 # ---------------------------------------
1060 # Messages about about the current Makefile.am.
1061 sub msg_am ($$;%)
1062 {
1063   my ($channel, $msg, %opts) = @_;
1064   msg $channel, "${am_file}.am", $msg, %opts;
1065 }
1066
1067 # msg_ac ($CHANNEL, $MESSAGE, [%OPTIONS])
1068 # ---------------------------------------
1069 # Messages about about configure.ac.
1070 sub msg_ac ($$;%)
1071 {
1072   my ($channel, $msg, %opts) = @_;
1073   msg $channel, $configure_ac, $msg, %opts;
1074 }
1075
1076 ################################################################
1077
1078 # subst ($TEXT)
1079 # -------------
1080 # Return a configure-style substitution using the indicated text.
1081 # We do this to avoid having the substitutions directly in automake.in;
1082 # when we do that they are sometimes removed and this causes confusion
1083 # and bugs.
1084 sub subst ($)
1085 {
1086     my ($text) = @_;
1087     return '@' . $text . '@';
1088 }
1089
1090 ################################################################
1091
1092
1093 # $BACKPATH
1094 # &backname ($RELDIR)
1095 # --------------------
1096 # If I "cd $RELDIR", then to come back, I should "cd $BACKPATH".
1097 # For instance 'src/foo' => '../..'.
1098 # Works with non strictly increasing paths, i.e., 'src/../lib' => '..'.
1099 sub backname ($)
1100 {
1101     my ($file) = @_;
1102     my @res;
1103     foreach (split (/\//, $file))
1104     {
1105         next if $_ eq '.' || $_ eq '';
1106         if ($_ eq '..')
1107         {
1108             pop @res
1109               or prog_error ("trying to reverse path '$file' pointing outside tree");
1110         }
1111         else
1112         {
1113             push (@res, '..');
1114         }
1115     }
1116     return join ('/', @res) || '.';
1117 }
1118
1119 ################################################################
1120
1121 # Silent rules handling functions.
1122
1123 # verbose_var (NAME)
1124 # ------------------
1125 # The public variable stem used to implement silent rules.
1126 sub verbose_var ($)
1127 {
1128     my ($name) = @_;
1129     return 'AM_V_' . $name;
1130 }
1131
1132 # verbose_private_var (NAME)
1133 # --------------------------
1134 # The naming policy for the private variables for silent rules.
1135 sub verbose_private_var ($)
1136 {
1137     my ($name) = @_;
1138     return 'am__v_' . $name;
1139 }
1140
1141 # define_verbose_var (NAME, VAL-IF-SILENT, [VAL-IF-VERBOSE])
1142 # ----------------------------------------------------------
1143 # For  silent rules, setup VAR and dispatcher, to expand to
1144 # VAL-IF-SILENT if silent, to VAL-IF-VERBOSE (defaulting to
1145 # empty) if not.
1146 sub define_verbose_var ($$;$)
1147 {
1148     my ($name, $silent_val, $verbose_val) = @_;
1149     $verbose_val = '' unless defined $verbose_val;
1150     my $var = verbose_var ($name);
1151     my $pvar = verbose_private_var ($name);
1152     my $silent_var = $pvar . '_0';
1153     my $verbose_var = $pvar . '_1';
1154     # For typical 'make's, 'configure' replaces AM_V (inside @@) with $(V)
1155     # and AM_DEFAULT_V (inside @@) with $(AM_DEFAULT_VERBOSITY).
1156     # For strict POSIX 2008 'make's, it replaces them with 0 or 1 instead.
1157     # See AM_SILENT_RULES in m4/silent.m4.
1158     define_variable ($var, '$(' . $pvar . '_@'.'AM_V'.'@)', INTERNAL);
1159     define_variable ($pvar . '_', '$(' . $pvar . '_@'.'AM_DEFAULT_V'.'@)',
1160                      INTERNAL);
1161     Automake::Variable::define ($silent_var, VAR_AUTOMAKE, '', TRUE,
1162                                 $silent_val, '', INTERNAL, VAR_ASIS)
1163       if (! vardef ($silent_var, TRUE));
1164     Automake::Variable::define ($verbose_var, VAR_AUTOMAKE, '', TRUE,
1165                                 $verbose_val, '', INTERNAL, VAR_ASIS)
1166       if (! vardef ($verbose_var, TRUE));
1167 }
1168
1169 # Above should not be needed in the general automake code.
1170
1171 # verbose_flag (NAME)
1172 # -------------------
1173 # Contents of %VERBOSE%: variable to expand before rule command.
1174 sub verbose_flag ($)
1175 {
1176     my ($name) = @_;
1177     return '$(' . verbose_var ($name) . ')';
1178 }
1179
1180 sub verbose_nodep_flag ($)
1181 {
1182     my ($name) = @_;
1183     return '$(' . verbose_var ($name) . subst ('am__nodep') . ')';
1184 }
1185
1186 # silent_flag
1187 # -----------
1188 # Contents of %SILENT%: variable to expand to '@' when silent.
1189 sub silent_flag ()
1190 {
1191     return verbose_flag ('at');
1192 }
1193
1194 # define_verbose_tagvar (NAME)
1195 # ----------------------------
1196 # Engage the needed silent rules machinery for tag NAME.
1197 sub define_verbose_tagvar ($)
1198 {
1199     my ($name) = @_;
1200     define_verbose_var ($name, '@echo "  '. $name . ' ' x (8 - length ($name)) . '" $@;');
1201 }
1202
1203 # define_verbose_texinfo
1204 # ----------------------
1205 # Engage the needed silent rules machinery for assorted texinfo commands.
1206 sub define_verbose_texinfo ()
1207 {
1208   my @tagvars = ('DVIPS', 'MAKEINFO', 'INFOHTML', 'TEXI2DVI', 'TEXI2PDF');
1209   foreach my $tag (@tagvars)
1210     {
1211       define_verbose_tagvar($tag);
1212     }
1213   define_verbose_var('texinfo', '-q');
1214   define_verbose_var('texidevnull', '> /dev/null');
1215 }
1216
1217 # define_verbose_libtool
1218 # ----------------------
1219 # Engage the needed silent rules machinery for 'libtool --silent'.
1220 sub define_verbose_libtool ()
1221 {
1222     define_verbose_var ('lt', '--silent');
1223     return verbose_flag ('lt');
1224 }
1225
1226 sub handle_silent ()
1227 {
1228     # Define "$(AM_V_P)", expanding to a shell conditional that can be
1229     # used in make recipes to determine whether we are being run in
1230     # silent mode or not.  The choice of the name derives from the LISP
1231     # convention of appending the letter 'P' to denote a predicate (see
1232     # also "the '-P' convention" in the Jargon File); we do so for lack
1233     # of a better convention.
1234     define_verbose_var ('P', 'false', ':');
1235     # *Always* provide the user with '$(AM_V_GEN)', unconditionally.
1236     define_verbose_tagvar ('GEN');
1237     define_verbose_var ('at', '@');
1238 }
1239
1240
1241 ################################################################
1242
1243
1244 # Handle AUTOMAKE_OPTIONS variable.  Return 1 on error, 0 otherwise.
1245 sub handle_options
1246 {
1247   my $var = var ('AUTOMAKE_OPTIONS');
1248   if ($var)
1249     {
1250       if ($var->has_conditional_contents)
1251         {
1252           msg_var ('unsupported', $var,
1253                    "'AUTOMAKE_OPTIONS' cannot have conditional contents");
1254         }
1255       my @options = map { { option => $_->[1], where => $_->[0] } }
1256                         $var->value_as_list_recursive (cond_filter => TRUE,
1257                                                        location => 1);
1258       return 1 if process_option_list (@options);
1259     }
1260
1261   if ($strictness == GNITS)
1262     {
1263       set_option ('readme-alpha', INTERNAL);
1264       set_option ('std-options', INTERNAL);
1265       set_option ('check-news', INTERNAL);
1266     }
1267
1268   return 0;
1269 }
1270
1271 # shadow_unconditionally ($varname, $where)
1272 # -----------------------------------------
1273 # Return a $(variable) that contains all possible values
1274 # $varname can take.
1275 # If the VAR wasn't defined conditionally, return $(VAR).
1276 # Otherwise we create an am__VAR_DIST variable which contains
1277 # all possible values, and return $(am__VAR_DIST).
1278 sub shadow_unconditionally ($$)
1279 {
1280   my ($varname, $where) = @_;
1281   my $var = var $varname;
1282   if ($var->has_conditional_contents)
1283     {
1284       $varname = "am__${varname}_DIST";
1285       my @files = uniq ($var->value_as_list_recursive);
1286       define_pretty_variable ($varname, TRUE, $where, @files);
1287     }
1288   return "\$($varname)"
1289 }
1290
1291 # check_user_variables (@LIST)
1292 # ----------------------------
1293 # Make sure each variable VAR in @LIST does not exist, suggest using AM_VAR
1294 # otherwise.
1295 sub check_user_variables (@)
1296 {
1297   my @dont_override = @_;
1298   foreach my $flag (@dont_override)
1299     {
1300       my $var = var $flag;
1301       if ($var)
1302         {
1303           for my $cond ($var->conditions->conds)
1304             {
1305               if ($var->rdef ($cond)->owner == VAR_MAKEFILE)
1306                 {
1307                   msg_cond_var ('gnu', $cond, $flag,
1308                                 "'$flag' is a user variable, "
1309                                 . "you should not override it;\n"
1310                                 . "use 'AM_$flag' instead");
1311                 }
1312             }
1313         }
1314     }
1315 }
1316
1317 # Call finish function for each language that was used.
1318 sub handle_languages
1319 {
1320     if (! option 'no-dependencies')
1321     {
1322         # Include auto-dep code.  Don't include it if DEP_FILES would
1323         # be empty.
1324         if (keys %extension_seen && keys %dep_files)
1325         {
1326             # Set location of depcomp.
1327             &define_variable ('depcomp',
1328                               "\$(SHELL) $am_config_aux_dir/depcomp",
1329                               INTERNAL);
1330             &define_variable ('am__depfiles_maybe', 'depfiles', INTERNAL);
1331
1332             require_conf_file ("$am_file.am", FOREIGN, 'depcomp');
1333
1334             my @deplist = sort keys %dep_files;
1335             # Generate each 'include' individually.  Irix 6 make will
1336             # not properly include several files resulting from a
1337             # variable expansion; generating many separate includes
1338             # seems safest.
1339             $output_rules .= "\n";
1340             foreach my $iter (@deplist)
1341             {
1342                 $output_rules .= (subst ('AMDEP_TRUE')
1343                                   . subst ('am__include')
1344                                   . ' '
1345                                   . subst ('am__quote')
1346                                   . $iter
1347                                   . subst ('am__quote')
1348                                   . "\n");
1349             }
1350
1351             # Compute the set of directories to remove in distclean-depend.
1352             my @depdirs = uniq (map { dirname ($_) } @deplist);
1353             $output_rules .= &file_contents ('depend',
1354                                              new Automake::Location,
1355                                              DEPDIRS => "@depdirs");
1356         }
1357     }
1358     else
1359     {
1360         &define_variable ('depcomp', '', INTERNAL);
1361         &define_variable ('am__depfiles_maybe', '', INTERNAL);
1362     }
1363
1364     my %done;
1365
1366     # Is the C linker needed?
1367     my $needs_c = 0;
1368     foreach my $ext (sort keys %extension_seen)
1369     {
1370         next unless $extension_map{$ext};
1371
1372         my $lang = $languages{$extension_map{$ext}};
1373
1374         my $rule_file = $lang->rule_file || 'depend2';
1375
1376         # Get information on $LANG.
1377         my $pfx = $lang->autodep;
1378         my $fpfx = ($pfx eq '') ? 'CC' : $pfx;
1379
1380         my ($AMDEP, $FASTDEP) =
1381           (option 'no-dependencies' || $lang->autodep eq 'no')
1382           ? ('FALSE', 'FALSE') : ('AMDEP', "am__fastdep$fpfx");
1383
1384         my $verbose = verbose_flag ($lang->ccer || 'GEN');
1385         my $verbose_nodep = ($AMDEP eq 'FALSE')
1386           ? $verbose : verbose_nodep_flag ($lang->ccer || 'GEN');
1387         my $silent = silent_flag ();
1388
1389         my %transform = ('EXT'     => $ext,
1390                          'PFX'     => $pfx,
1391                          'FPFX'    => $fpfx,
1392                          'AMDEP'   => $AMDEP,
1393                          'FASTDEP' => $FASTDEP,
1394                          '-c'      => $lang->compile_flag || '',
1395                          # These are not used, but they need to be defined
1396                          # so &transform do not complain.
1397                          SUBDIROBJ     => 0,
1398                          'DERIVED-EXT' => 'BUG',
1399                          DIST_SOURCE   => 1,
1400                          VERBOSE   => $verbose,
1401                          'VERBOSE-NODEP' => $verbose_nodep,
1402                          SILENT    => $silent,
1403                         );
1404
1405         # Generate the appropriate rules for this extension.
1406         if (((! option 'no-dependencies') && $lang->autodep ne 'no')
1407             || defined $lang->compile)
1408         {
1409             # Some C compilers don't support -c -o.  Use it only if really
1410             # needed.
1411             my $output_flag = $lang->output_flag || '';
1412             $output_flag = '-o'
1413               if (! $output_flag
1414                   && $lang->name eq 'c'
1415                   && option 'subdir-objects');
1416
1417             # Compute a possible derived extension.
1418             # This is not used by depend2.am.
1419             my $der_ext = (&{$lang->output_extensions} ($ext))[0];
1420
1421             # When we output an inference rule like '.c.o:' we
1422             # have two cases to consider: either subdir-objects
1423             # is used, or it is not.
1424             #
1425             # In the latter case the rule is used to build objects
1426             # in the current directory, and dependencies always
1427             # go into './$(DEPDIR)/'.  We can hard-code this value.
1428             #
1429             # In the former case the rule can be used to build
1430             # objects in sub-directories too.  Dependencies should
1431             # go into the appropriate sub-directories, e.g.,
1432             # 'sub/$(DEPDIR)/'.  The value of this directory
1433             # needs to be computed on-the-fly.
1434             #
1435             # DEPBASE holds the name of this directory, plus the
1436             # basename part of the object file (extensions Po, TPo,
1437             # Plo, TPlo will be added later as appropriate).  It is
1438             # either hardcoded, or a shell variable ('$depbase') that
1439             # will be computed by the rule.
1440             my $depbase =
1441               option ('subdir-objects') ? '$$depbase' : '$(DEPDIR)/$*';
1442             $output_rules .=
1443               file_contents ($rule_file,
1444                              new Automake::Location,
1445                              %transform,
1446                              GENERIC   => 1,
1447
1448                              'DERIVED-EXT' => $der_ext,
1449
1450                              DEPBASE   => $depbase,
1451                              BASE      => '$*',
1452                              SOURCE    => '$<',
1453                              SOURCEFLAG => $sourceflags{$ext} || '',
1454                              OBJ       => '$@',
1455                              OBJOBJ    => '$@',
1456                              LTOBJ     => '$@',
1457
1458                              COMPILE   => '$(' . $lang->compiler . ')',
1459                              LTCOMPILE => '$(LT' . $lang->compiler . ')',
1460                              -o        => $output_flag,
1461                              SUBDIROBJ => !! option 'subdir-objects');
1462         }
1463
1464         # Now include code for each specially handled object with this
1465         # language.
1466         my %seen_files = ();
1467         foreach my $file (@{$lang_specific_files{$lang->name}})
1468         {
1469             my ($derived, $source, $obj, $myext, $srcext, %file_transform) = @$file;
1470
1471             # We might see a given object twice, for instance if it is
1472             # used under different conditions.
1473             next if defined $seen_files{$obj};
1474             $seen_files{$obj} = 1;
1475
1476             prog_error ("found " . $lang->name .
1477                         " in handle_languages, but compiler not defined")
1478               unless defined $lang->compile;
1479
1480             my $obj_compile = $lang->compile;
1481
1482             # Rewrite each occurrence of 'AM_$flag' in the compile
1483             # rule into '${derived}_$flag' if it exists.
1484             for my $flag (@{$lang->flags})
1485               {
1486                 my $val = "${derived}_$flag";
1487                 $obj_compile =~ s/\(AM_$flag\)/\($val\)/
1488                   if set_seen ($val);
1489               }
1490
1491             my $libtool_tag = '';
1492             if ($lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag})
1493               {
1494                 $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
1495               }
1496
1497             my $ptltflags = "${derived}_LIBTOOLFLAGS";
1498             $ptltflags = 'AM_LIBTOOLFLAGS' unless set_seen $ptltflags;
1499
1500             my $ltverbose = define_verbose_libtool ();
1501             my $obj_ltcompile =
1502               "\$(LIBTOOL) $ltverbose $libtool_tag\$($ptltflags) \$(LIBTOOLFLAGS) "
1503               . "--mode=compile $obj_compile";
1504
1505             # We _need_ '-o' for per object rules.
1506             my $output_flag = $lang->output_flag || '-o';
1507
1508             my $depbase = dirname ($obj);
1509             $depbase = ''
1510                 if $depbase eq '.';
1511             $depbase .= '/'
1512                 unless $depbase eq '';
1513             $depbase .= '$(DEPDIR)/' . basename ($obj);
1514
1515             $output_rules .=
1516               file_contents ($rule_file,
1517                              new Automake::Location,
1518                              %transform,
1519                              GENERIC   => 0,
1520
1521                              DEPBASE   => $depbase,
1522                              BASE      => $obj,
1523                              SOURCE    => $source,
1524                              SOURCEFLAG => $sourceflags{$srcext} || '',
1525                              # Use $myext and not '.o' here, in case
1526                              # we are actually building a new source
1527                              # file -- e.g. via yacc.
1528                              OBJ       => "$obj$myext",
1529                              OBJOBJ    => "$obj.obj",
1530                              LTOBJ     => "$obj.lo",
1531
1532                              VERBOSE   => $verbose,
1533                              'VERBOSE-NODEP'  => $verbose_nodep,
1534                              SILENT    => $silent,
1535                              COMPILE   => $obj_compile,
1536                              LTCOMPILE => $obj_ltcompile,
1537                              -o        => $output_flag,
1538                              %file_transform);
1539         }
1540
1541         # The rest of the loop is done once per language.
1542         next if defined $done{$lang};
1543         $done{$lang} = 1;
1544
1545         # Load the language dependent Makefile chunks.
1546         my %lang = map { uc ($_) => 0 } keys %languages;
1547         $lang{uc ($lang->name)} = 1;
1548         $output_rules .= file_contents ('lang-compile',
1549                                         new Automake::Location,
1550                                         %transform, %lang);
1551
1552         # If the source to a program consists entirely of code from a
1553         # 'pure' language, for instance C++ or Fortran 77, then we
1554         # don't need the C compiler code.  However if we run into
1555         # something unusual then we do generate the C code.  There are
1556         # probably corner cases here that do not work properly.
1557         # People linking Java code to Fortran code deserve pain.
1558         $needs_c ||= ! $lang->pure;
1559
1560         define_compiler_variable ($lang)
1561           if ($lang->compile);
1562
1563         define_linker_variable ($lang)
1564           if ($lang->link);
1565
1566         require_variables ("$am_file.am", $lang->Name . " source seen",
1567                            TRUE, @{$lang->config_vars});
1568
1569         # Call the finisher.
1570         $lang->finish;
1571
1572         # Flags listed in '->flags' are user variables (per GNU Standards),
1573         # they should not be overridden in the Makefile...
1574         my @dont_override = @{$lang->flags};
1575         # ... and so is LDFLAGS.
1576         push @dont_override, 'LDFLAGS' if $lang->link;
1577
1578         check_user_variables @dont_override;
1579     }
1580
1581     # If the project is entirely C++ or entirely Fortran 77 (i.e., 1
1582     # suffix rule was learned), don't bother with the C stuff.  But if
1583     # anything else creeps in, then use it.
1584     $needs_c = 1
1585       if $need_link || suffix_rules_count > 1;
1586
1587     if ($needs_c)
1588       {
1589         &define_compiler_variable ($languages{'c'})
1590           unless defined $done{$languages{'c'}};
1591         define_linker_variable ($languages{'c'});
1592       }
1593 }
1594
1595
1596 # append_exeext { PREDICATE } $MACRO
1597 # ----------------------------------
1598 # Append $(EXEEXT) to each filename in $F appearing in the Makefile
1599 # variable $MACRO if &PREDICATE($F) is true.  @substitutions@ are
1600 # ignored.
1601 #
1602 # This is typically used on all filenames of *_PROGRAMS, and filenames
1603 # of TESTS that are programs.
1604 sub append_exeext (&$)
1605 {
1606   my ($pred, $macro) = @_;
1607
1608   transform_variable_recursively
1609     ($macro, $macro, 'am__EXEEXT', 0, INTERNAL,
1610      sub {
1611        my ($subvar, $val, $cond, $full_cond) = @_;
1612        # Append $(EXEEXT) unless the user did it already, or it's a
1613        # @substitution@.
1614        $val .= '$(EXEEXT)'
1615          if $val !~ /(?:\$\(EXEEXT\)$|^[@]\w+[@]$)/ && &$pred ($val);
1616        return $val;
1617      });
1618 }
1619
1620
1621 # Check to make sure a source defined in LIBOBJS is not explicitly
1622 # mentioned.  This is a separate function (as opposed to being inlined
1623 # in handle_source_transform) because it isn't always appropriate to
1624 # do this check.
1625 sub check_libobjs_sources
1626 {
1627   my ($one_file, $unxformed) = @_;
1628
1629   foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1630                       'dist_EXTRA_', 'nodist_EXTRA_')
1631     {
1632       my @files;
1633       my $varname = $prefix . $one_file . '_SOURCES';
1634       my $var = var ($varname);
1635       if ($var)
1636         {
1637           @files = $var->value_as_list_recursive;
1638         }
1639       elsif ($prefix eq '')
1640         {
1641           @files = ($unxformed . '.c');
1642         }
1643       else
1644         {
1645           next;
1646         }
1647
1648       foreach my $file (@files)
1649         {
1650           err_var ($prefix . $one_file . '_SOURCES',
1651                    "automatically discovered file '$file' should not" .
1652                    " be explicitly mentioned")
1653             if defined $libsources{$file};
1654         }
1655     }
1656 }
1657
1658
1659 # @OBJECTS
1660 # handle_single_transform ($VAR, $TOPPARENT, $DERIVED, $OBJ, $FILE, %TRANSFORM)
1661 # -----------------------------------------------------------------------------
1662 # Does much of the actual work for handle_source_transform.
1663 # Arguments are:
1664 #   $VAR is the name of the variable that the source filenames come from
1665 #   $TOPPARENT is the name of the _SOURCES variable which is being processed
1666 #   $DERIVED is the name of resulting executable or library
1667 #   $OBJ is the object extension (e.g., '.lo')
1668 #   $FILE the source file to transform
1669 #   %TRANSFORM contains extras arguments to pass to file_contents
1670 #     when producing explicit rules
1671 # Result is a list of the names of objects
1672 # %linkers_used will be updated with any linkers needed
1673 sub handle_single_transform ($$$$$%)
1674 {
1675     my ($var, $topparent, $derived, $obj, $_file, %transform) = @_;
1676     my @files = ($_file);
1677     my @result = ();
1678
1679     # Turn sources into objects.  We use a while loop like this
1680     # because we might add to @files in the loop.
1681     while (scalar @files > 0)
1682     {
1683         $_ = shift @files;
1684
1685         # Configure substitutions in _SOURCES variables are errors.
1686         if (/^\@.*\@$/)
1687         {
1688           my $parent_msg = '';
1689           $parent_msg = "\nand is referred to from '$topparent'"
1690             if $topparent ne $var->name;
1691           err_var ($var,
1692                    "'" . $var->name . "' includes configure substitution '$_'"
1693                    . $parent_msg . ";\nconfigure " .
1694                    "substitutions are not allowed in _SOURCES variables");
1695           next;
1696         }
1697
1698         # If the source file is in a subdirectory then the '.o' is put
1699         # into the current directory, unless the subdir-objects option
1700         # is in effect.
1701
1702         # Split file name into base and extension.
1703         next if ! /^(?:(.*)\/)?([^\/]*)($KNOWN_EXTENSIONS_PATTERN)$/;
1704         my $full = $_;
1705         my $directory = $1 || '';
1706         my $base = $2;
1707         my $extension = $3;
1708
1709         # We must generate a rule for the object if it requires its own flags.
1710         my $renamed = 0;
1711         my ($linker, $object);
1712
1713         # This records whether we've seen a derived source file (e.g.
1714         # yacc output).
1715         my $derived_source = 0;
1716
1717         # This holds the 'aggregate context' of the file we are
1718         # currently examining.  If the file is compiled with
1719         # per-object flags, then it will be the name of the object.
1720         # Otherwise it will be 'AM'.  This is used by the target hook
1721         # language function.
1722         my $aggregate = 'AM';
1723
1724         $extension = &derive_suffix ($extension, $obj);
1725         my $lang;
1726         if ($extension_map{$extension} &&
1727             ($lang = $languages{$extension_map{$extension}}))
1728         {
1729             # Found the language, so see what it says.
1730             &saw_extension ($extension);
1731
1732             # Do we have per-executable flags for this executable?
1733             my $have_per_exec_flags = 0;
1734             my @peflags = @{$lang->flags};
1735             push @peflags, 'LIBTOOLFLAGS' if $obj eq '.lo';
1736             foreach my $flag (@peflags)
1737               {
1738                 if (set_seen ("${derived}_$flag"))
1739                   {
1740                     $have_per_exec_flags = 1;
1741                     last;
1742                   }
1743               }
1744
1745             # Note: computed subr call.  The language rewrite function
1746             # should return one of the LANG_* constants.  It could
1747             # also return a list whose first value is such a constant
1748             # and whose second value is a new source extension which
1749             # should be applied.  This means this particular language
1750             # generates another source file which we must then process
1751             # further.
1752             my $subr = \&{'lang_' . $lang->name . '_rewrite'};
1753             my ($r, $source_extension)
1754                 = &$subr ($directory, $base, $extension,
1755                           $obj, $have_per_exec_flags, $var);
1756             # Skip this entry if we were asked not to process it.
1757             next if $r == LANG_IGNORE;
1758
1759             # Now extract linker and other info.
1760             $linker = $lang->linker;
1761
1762             my $this_obj_ext;
1763             if (defined $source_extension)
1764             {
1765                 $this_obj_ext = $source_extension;
1766                 $derived_source = 1;
1767             }
1768             else
1769             {
1770                 $this_obj_ext = $obj;
1771             }
1772             $object = $base . $this_obj_ext;
1773
1774             if ($have_per_exec_flags)
1775             {
1776                 # We have a per-executable flag in effect for this
1777                 # object.  In this case we rewrite the object's
1778                 # name to ensure it is unique.
1779
1780                 # We choose the name 'DERIVED_OBJECT' to ensure
1781                 # (1) uniqueness, and (2) continuity between
1782                 # invocations.  However, this will result in a
1783                 # name that is too long for losing systems, in
1784                 # some situations.  So we provide _SHORTNAME to
1785                 # override.
1786
1787                 my $dname = $derived;
1788                 my $var = var ($derived . '_SHORTNAME');
1789                 if ($var)
1790                 {
1791                     # FIXME: should use the same Condition as
1792                     # the _SOURCES variable.  But this is really
1793                     # silly overkill -- nobody should have
1794                     # conditional shortnames.
1795                     $dname = $var->variable_value;
1796                 }
1797                 $object = $dname . '-' . $object;
1798
1799                 prog_error ($lang->name . " flags defined without compiler")
1800                   if ! defined $lang->compile;
1801
1802                 $renamed = 1;
1803             }
1804
1805             # If rewrite said it was ok, put the object into a
1806             # subdir.
1807             if ($r == LANG_SUBDIR && $directory ne '')
1808             {
1809                 $object = $directory . '/' . $object;
1810             }
1811
1812             # If the object file has been renamed (because per-target
1813             # flags are used) we cannot compile the file with an
1814             # inference rule: we need an explicit rule.
1815             #
1816             # If the source is in a subdirectory and the object is in
1817             # the current directory, we also need an explicit rule.
1818             #
1819             # If both source and object files are in a subdirectory
1820             # (this happens when the subdir-objects option is used),
1821             # then the inference will work.
1822             #
1823             # The latter case deserves a historical note.  When the
1824             # subdir-objects option was added on 1999-04-11 it was
1825             # thought that inferences rules would work for
1826             # subdirectory objects too.  Later, on 1999-11-22,
1827             # automake was changed to output explicit rules even for
1828             # subdir-objects.  Nobody remembers why, but this occurred
1829             # soon after the merge of the user-dep-gen-branch so it
1830             # might be related.  In late 2003 people complained about
1831             # the size of the generated Makefile.ins (libgcj, with
1832             # 2200+ subdir objects was reported to have a 9MB
1833             # Makefile), so we now rely on inference rules again.
1834             # Maybe we'll run across the same issue as in the past,
1835             # but at least this time we can document it.  However since
1836             # dependency tracking has evolved it is possible that
1837             # our old problem no longer exists.
1838             # Using inference rules for subdir-objects has been tested
1839             # with GNU make, Solaris make, Ultrix make, BSD make,
1840             # HP-UX make, and OSF1 make successfully.
1841             if ($renamed
1842                 || ($directory ne '' && ! option 'subdir-objects')
1843                 # We must also use specific rules for a nodist_ source
1844                 # if its language requests it.
1845                 || ($lang->nodist_specific && ! $transform{'DIST_SOURCE'}))
1846             {
1847                 my $obj_sans_ext = substr ($object, 0,
1848                                            - length ($this_obj_ext));
1849                 my $full_ansi;
1850                 if ($directory ne '')
1851                   {
1852                         $full_ansi = $directory . '/' . $base . $extension;
1853                   }
1854                 else
1855                   {
1856                         $full_ansi = $base . $extension;
1857                   }
1858
1859                 my @specifics = ($full_ansi, $obj_sans_ext,
1860                                  # Only use $this_obj_ext in the derived
1861                                  # source case because in the other case we
1862                                  # *don't* want $(OBJEXT) to appear here.
1863                                  ($derived_source ? $this_obj_ext : '.o'),
1864                                  $extension);
1865
1866                 # If we renamed the object then we want to use the
1867                 # per-executable flag name.  But if this is simply a
1868                 # subdir build then we still want to use the AM_ flag
1869                 # name.
1870                 if ($renamed)
1871                   {
1872                     unshift @specifics, $derived;
1873                     $aggregate = $derived;
1874                   }
1875                 else
1876                   {
1877                     unshift @specifics, 'AM';
1878                   }
1879
1880                 # Each item on this list is a reference to a list consisting
1881                 # of four values followed by additional transform flags for
1882                 # file_contents.  The four values are the derived flag prefix
1883                 # (e.g. for 'foo_CFLAGS', it is 'foo'), the name of the
1884                 # source file, the base name of the output file, and
1885                 # the extension for the object file.
1886                 push (@{$lang_specific_files{$lang->name}},
1887                       [@specifics, %transform]);
1888             }
1889         }
1890         elsif ($extension eq $obj)
1891         {
1892             # This is probably the result of a direct suffix rule.
1893             # In this case we just accept the rewrite.
1894             $object = "$base$extension";
1895             $object = "$directory/$object" if $directory ne '';
1896             $linker = '';
1897         }
1898         else
1899         {
1900             # No error message here.  Used to have one, but it was
1901             # very unpopular.
1902             # FIXME: we could potentially do more processing here,
1903             # perhaps treating the new extension as though it were a
1904             # new source extension (as above).  This would require
1905             # more restructuring than is appropriate right now.
1906             next;
1907         }
1908
1909         err_am "object '$object' created by '$full' and '$object_map{$object}'"
1910           if (defined $object_map{$object}
1911               && $object_map{$object} ne $full);
1912
1913         my $comp_val = (($object =~ /\.lo$/)
1914                         ? COMPILE_LIBTOOL : COMPILE_ORDINARY);
1915         (my $comp_obj = $object) =~ s/\.lo$/.\$(OBJEXT)/;
1916         if (defined $object_compilation_map{$comp_obj}
1917             && $object_compilation_map{$comp_obj} != 0
1918             # Only see the error once.
1919             && ($object_compilation_map{$comp_obj}
1920                 != (COMPILE_LIBTOOL | COMPILE_ORDINARY))
1921             && $object_compilation_map{$comp_obj} != $comp_val)
1922           {
1923             err_am "object '$comp_obj' created both with libtool and without";
1924           }
1925         $object_compilation_map{$comp_obj} |= $comp_val;
1926
1927         if (defined $lang)
1928         {
1929             # Let the language do some special magic if required.
1930             $lang->target_hook ($aggregate, $object, $full, %transform);
1931         }
1932
1933         if ($derived_source)
1934           {
1935             prog_error ($lang->name . " has automatic dependency tracking")
1936               if $lang->autodep ne 'no';
1937             # Make sure this new source file is handled next.  That will
1938             # make it appear to be at the right place in the list.
1939             unshift (@files, $object);
1940             # Distribute derived sources unless the source they are
1941             # derived from is not.
1942             &push_dist_common ($object)
1943               unless ($topparent =~ /^(?:nobase_)?nodist_/);
1944             next;
1945           }
1946
1947         $linkers_used{$linker} = 1;
1948
1949         push (@result, $object);
1950
1951         if (! defined $object_map{$object})
1952         {
1953             my @dep_list = ();
1954             $object_map{$object} = $full;
1955
1956             # If resulting object is in subdir, we need to make
1957             # sure the subdir exists at build time.
1958             if ($object =~ /\//)
1959             {
1960                 # FIXME: check that $DIRECTORY is somewhere in the
1961                 # project
1962
1963                 # For Java, the way we're handling it right now, a
1964                 # '..' component doesn't make sense.
1965                 if ($lang && $lang->name eq 'java' && $object =~ /(\/|^)\.\.\//)
1966                   {
1967                     err_am "'$full' should not contain a '..' component";
1968                   }
1969
1970                 # Make sure *all* objects files in the subdirectory are
1971                 # removed by "make mostlyclean".  Not only this is more
1972                 # efficient than listing the object files to be removed
1973                 # individually (which would cause an 'rm' invocation for
1974                 # each of them -- very inefficient, see bug#10697), it
1975                 # would also leave stale object files in the subdirectory
1976                 # whenever a source file there is removed or renamed.
1977                 $compile_clean_files{"$directory/*.\$(OBJEXT)"} = MOSTLY_CLEAN;
1978                 if ($object =~ /\.lo$/)
1979                   {
1980                     # If we have a libtool object, then we also must remove
1981                     # any '.lo' objects in its same subdirectory.
1982                     $compile_clean_files{"$directory/*.lo"} = MOSTLY_CLEAN;
1983                     # Remember to cleanup .libs/ in this directory.
1984                     $libtool_clean_directories{$directory} = 1;
1985                   }
1986
1987                 push (@dep_list, require_build_directory ($directory));
1988
1989                 # If we're generating dependencies, we also want
1990                 # to make sure that the appropriate subdir of the
1991                 # .deps directory is created.
1992                 push (@dep_list,
1993                       require_build_directory ($directory . '/$(DEPDIR)'))
1994                   unless option 'no-dependencies';
1995             }
1996
1997             &pretty_print_rule ($object . ':', "\t", @dep_list)
1998                 if scalar @dep_list > 0;
1999         }
2000
2001         # Transform .o or $o file into .P file (for automatic
2002         # dependency code).
2003         # Properly flatten multiple adjacent slashes, as Solaris 10 make
2004         # might fail over them in an include statement.
2005         # Leading double slashes may be special, as per Posix, so deal
2006         # with them carefully.
2007         if ($lang && $lang->autodep ne 'no')
2008         {
2009             my $depfile = $object;
2010             $depfile =~ s/\.([^.]*)$/.P$1/;
2011             $depfile =~ s/\$\(OBJEXT\)$/o/;
2012             my $maybe_extra_leading_slash = '';
2013             $maybe_extra_leading_slash = '/' if $depfile =~ m,^//[^/],;
2014             $depfile =~ s,/+,/,g;
2015             my $basename = basename ($depfile);
2016             # This might make $dirname empty, but we account for that below.
2017             (my $dirname = dirname ($depfile)) =~ s/\/*$//;
2018             $dirname = $maybe_extra_leading_slash . $dirname;
2019             $dep_files{$dirname . '/$(DEPDIR)/' . $basename} = 1;
2020         }
2021     }
2022
2023     return @result;
2024 }
2025
2026
2027 # $LINKER
2028 # define_objects_from_sources ($VAR, $OBJVAR, $NODEFINE, $ONE_FILE,
2029 #                              $OBJ, $PARENT, $TOPPARENT, $WHERE, %TRANSFORM)
2030 # ---------------------------------------------------------------------------
2031 # Define an _OBJECTS variable for a _SOURCES variable (or subvariable)
2032 #
2033 # Arguments are:
2034 #   $VAR is the name of the _SOURCES variable
2035 #   $OBJVAR is the name of the _OBJECTS variable if known (otherwise
2036 #     it will be generated and returned).
2037 #   $NODEFINE is a boolean: if true, $OBJVAR will not be defined (but
2038 #     work done to determine the linker will be).
2039 #   $ONE_FILE is the canonical (transformed) name of object to build
2040 #   $OBJ is the object extension (i.e. either '.o' or '.lo').
2041 #   $TOPPARENT is the _SOURCES variable being processed.
2042 #   $WHERE context into which this definition is done
2043 #   %TRANSFORM extra arguments to pass to file_contents when producing
2044 #     rules
2045 #
2046 # Result is a pair ($LINKER, $OBJVAR):
2047 #    $LINKER is a boolean, true if a linker is needed to deal with the objects
2048 sub define_objects_from_sources ($$$$$$$%)
2049 {
2050   my ($var, $objvar, $nodefine, $one_file,
2051       $obj, $topparent, $where, %transform) = @_;
2052
2053   my $needlinker = "";
2054
2055   transform_variable_recursively
2056     ($var, $objvar, 'am__objects', $nodefine, $where,
2057      # The transform code to run on each filename.
2058      sub {
2059        my ($subvar, $val, $cond, $full_cond) = @_;
2060        my @trans = handle_single_transform ($subvar, $topparent,
2061                                             $one_file, $obj, $val,
2062                                             %transform);
2063        $needlinker = "true" if @trans;
2064        return @trans;
2065      });
2066
2067   return $needlinker;
2068 }
2069
2070
2071 # handle_source_transform ($CANON_TARGET, $TARGET, $OBJEXT, $WHERE, %TRANSFORM)
2072 # -----------------------------------------------------------------------------
2073 # Handle SOURCE->OBJECT transform for one program or library.
2074 # Arguments are:
2075 #   canonical (transformed) name of target to build
2076 #   actual target of object to build
2077 #   object extension (i.e., either '.o' or '$o')
2078 #   location of the source variable
2079 #   extra arguments to pass to file_contents when producing rules
2080 # Return the name of the linker variable that must be used.
2081 # Empty return means just use 'LINK'.
2082 sub handle_source_transform ($$$$%)
2083 {
2084     # one_file is canonical name.  unxformed is given name.  obj is
2085     # object extension.
2086     my ($one_file, $unxformed, $obj, $where, %transform) = @_;
2087
2088     my $linker = '';
2089
2090     # No point in continuing if _OBJECTS is defined.
2091     return if reject_var ($one_file . '_OBJECTS',
2092                           $one_file . '_OBJECTS should not be defined');
2093
2094     my %used_pfx = ();
2095     my $needlinker;
2096     %linkers_used = ();
2097     foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
2098                         'dist_EXTRA_', 'nodist_EXTRA_')
2099     {
2100         my $varname = $prefix . $one_file . "_SOURCES";
2101         my $var = var $varname;
2102         next unless $var;
2103
2104         # We are going to define _OBJECTS variables using the prefix.
2105         # Then we glom them all together.  So we can't use the null
2106         # prefix here as we need it later.
2107         my $xpfx = ($prefix eq '') ? 'am_' : $prefix;
2108
2109         # Keep track of which prefixes we saw.
2110         $used_pfx{$xpfx} = 1
2111           unless $prefix =~ /EXTRA_/;
2112
2113         push @sources, "\$($varname)";
2114         push @dist_sources, shadow_unconditionally ($varname, $where)
2115           unless (option ('no-dist') || $prefix =~ /^nodist_/);
2116
2117         $needlinker |=
2118             define_objects_from_sources ($varname,
2119                                          $xpfx . $one_file . '_OBJECTS',
2120                                          $prefix =~ /EXTRA_/,
2121                                          $one_file, $obj, $varname, $where,
2122                                          DIST_SOURCE => ($prefix !~ /^nodist_/),
2123                                          %transform);
2124     }
2125     if ($needlinker)
2126     {
2127         $linker ||= &resolve_linker (%linkers_used);
2128     }
2129
2130     my @keys = sort keys %used_pfx;
2131     if (scalar @keys == 0)
2132     {
2133         # The default source for libfoo.la is libfoo.c, but for
2134         # backward compatibility we first look at libfoo_la.c,
2135         # if no default source suffix is given.
2136         my $old_default_source = "$one_file.c";
2137         my $ext_var = var ('AM_DEFAULT_SOURCE_EXT');
2138         my $default_source_ext = $ext_var ? variable_value ($ext_var) : '.c';
2139         msg_var ('unsupported', $ext_var, $ext_var->name . " can assume at most one value")
2140           if $default_source_ext =~ /[\t ]/;
2141         (my $default_source = $unxformed) =~ s,(\.[^./\\]*)?$,$default_source_ext,;
2142         if ($old_default_source ne $default_source
2143             && !$ext_var
2144             && (rule $old_default_source
2145                 || rule '$(srcdir)/' . $old_default_source
2146                 || rule '${srcdir}/' . $old_default_source
2147                 || -f $old_default_source))
2148           {
2149             my $loc = $where->clone;
2150             $loc->pop_context;
2151             msg ('obsolete', $loc,
2152                  "the default source for '$unxformed' has been changed "
2153                  . "to '$default_source'.\n(Using '$old_default_source' for "
2154                  . "backward compatibility.)");
2155             $default_source = $old_default_source;
2156           }
2157         # If a rule exists to build this source with a $(srcdir)
2158         # prefix, use that prefix in our variables too.  This is for
2159         # the sake of BSD Make.
2160         if (rule '$(srcdir)/' . $default_source
2161             || rule '${srcdir}/' . $default_source)
2162           {
2163             $default_source = '$(srcdir)/' . $default_source;
2164           }
2165
2166         &define_variable ($one_file . "_SOURCES", $default_source, $where);
2167         push (@sources, $default_source);
2168         push (@dist_sources, $default_source);
2169
2170         %linkers_used = ();
2171         my (@result) =
2172           handle_single_transform ($one_file . '_SOURCES',
2173                                    $one_file . '_SOURCES',
2174                                    $one_file, $obj,
2175                                    $default_source, %transform);
2176         $linker ||= &resolve_linker (%linkers_used);
2177         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @result);
2178     }
2179     else
2180     {
2181         @keys = map { '$(' . $_ . $one_file . '_OBJECTS)' } @keys;
2182         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @keys);
2183     }
2184
2185     # If we want to use 'LINK' we must make sure it is defined.
2186     if ($linker eq '')
2187     {
2188         $need_link = 1;
2189     }
2190
2191     return $linker;
2192 }
2193
2194
2195 # handle_lib_objects ($XNAME, $VAR)
2196 # ---------------------------------
2197 # Special-case ALLOCA and LIBOBJS substitutions in _LDADD or _LIBADD variables.
2198 # Also, generate _DEPENDENCIES variable if appropriate.
2199 # Arguments are:
2200 #   transformed name of object being built, or empty string if no object
2201 #   name of _LDADD/_LIBADD-type variable to examine
2202 # Returns 1 if LIBOBJS seen, 0 otherwise.
2203 sub handle_lib_objects
2204 {
2205   my ($xname, $varname) = @_;
2206
2207   my $var = var ($varname);
2208   prog_error "'$varname' undefined"
2209     unless $var;
2210   prog_error "unexpected variable name '$varname'"
2211     unless $varname =~ /^(.*)(?:LIB|LD)ADD$/;
2212   my $prefix = $1 || 'AM_';
2213
2214   my $seen_libobjs = 0;
2215   my $flagvar = 0;
2216
2217   transform_variable_recursively
2218     ($varname, $xname . '_DEPENDENCIES', 'am__DEPENDENCIES',
2219      ! $xname, INTERNAL,
2220      # Transformation function, run on each filename.
2221      sub {
2222        my ($subvar, $val, $cond, $full_cond) = @_;
2223
2224        if ($val =~ /^-/)
2225          {
2226            # Skip -lfoo and -Ldir silently; these are explicitly allowed.
2227            if ($val !~ /^-[lL]/ &&
2228                # Skip -dlopen and -dlpreopen; these are explicitly allowed
2229                # for Libtool libraries or programs.  (Actually we are a bit
2230                # lax here since this code also applies to non-libtool
2231                # libraries or programs, for which -dlopen and -dlopreopen
2232                # are pure nonsense.  Diagnosing this doesn't seem very
2233                # important: the developer will quickly get complaints from
2234                # the linker.)
2235                $val !~ /^-dl(?:pre)?open$/ &&
2236                # Only get this error once.
2237                ! $flagvar)
2238              {
2239                $flagvar = 1;
2240                # FIXME: should display a stack of nested variables
2241                # as context when $var != $subvar.
2242                err_var ($var, "linker flags such as '$val' belong in "
2243                         . "'${prefix}LDFLAGS'");
2244              }
2245            return ();
2246          }
2247        elsif ($val !~ /^\@.*\@$/)
2248          {
2249            # Assume we have a file of some sort, and output it into the
2250            # dependency variable.  Autoconf substitutions are not output;
2251            # rarely is a new dependency substituted into e.g. foo_LDADD
2252            # -- but bad things (e.g. -lX11) are routinely substituted.
2253            # Note that LIBOBJS and ALLOCA are exceptions to this rule,
2254            # and handled specially below.
2255            return $val;
2256          }
2257        elsif ($val =~ /^\@(LT)?LIBOBJS\@$/)
2258          {
2259            handle_LIBOBJS ($subvar, $cond, $1);
2260            $seen_libobjs = 1;
2261            return $val;
2262          }
2263        elsif ($val =~ /^\@(LT)?ALLOCA\@$/)
2264          {
2265            handle_ALLOCA ($subvar, $cond, $1);
2266            return $val;
2267          }
2268        else
2269          {
2270            return ();
2271          }
2272      });
2273
2274   return $seen_libobjs;
2275 }
2276
2277 # handle_LIBOBJS_or_ALLOCA ($VAR)
2278 # -------------------------------
2279 # Definitions common to LIBOBJS and ALLOCA.
2280 # VAR should be one of LIBOBJS, LTLIBOBJS, ALLOCA, or LTALLOCA.
2281 sub handle_LIBOBJS_or_ALLOCA ($)
2282 {
2283   my ($var) = @_;
2284
2285   my $dir = '';
2286
2287   # If LIBOBJS files must be built in another directory we have
2288   # to define LIBOBJDIR and ensure the files get cleaned.
2289   # Otherwise LIBOBJDIR can be left undefined, and the cleaning
2290   # is achieved by 'rm -f *.$(OBJEXT)' in compile.am.
2291   if ($config_libobj_dir
2292       && $relative_dir ne $config_libobj_dir)
2293     {
2294       if (option 'subdir-objects')
2295         {
2296           # In the top-level Makefile we do not use $(top_builddir), because
2297           # we are already there, and since the targets are built without
2298           # a $(top_builddir), it helps BSD Make to match them with
2299           # dependencies.
2300           $dir = "$config_libobj_dir/" if $config_libobj_dir ne '.';
2301           $dir = "$topsrcdir/$dir" if $relative_dir ne '.';
2302           define_variable ('LIBOBJDIR', "$dir", INTERNAL);
2303           $clean_files{"\$($var)"} = MOSTLY_CLEAN;
2304           # If LTLIBOBJS is used, we must also clear LIBOBJS (which might
2305           # be created by libtool as a side-effect of creating LTLIBOBJS).
2306           $clean_files{"\$($var)"} = MOSTLY_CLEAN if $var =~ s/^LT//;
2307         }
2308       else
2309         {
2310           error ("'\$($var)' cannot be used outside '$config_libobj_dir' if"
2311                  . " 'subdir-objects' is not set");
2312         }
2313     }
2314
2315   return $dir;
2316 }
2317
2318 sub handle_LIBOBJS ($$$)
2319 {
2320   my ($var, $cond, $lt) = @_;
2321   my $myobjext = $lt ? 'lo' : 'o';
2322   $lt ||= '';
2323
2324   $var->requires_variables ("\@${lt}LIBOBJS\@ used", $lt . 'LIBOBJS')
2325     if ! keys %libsources;
2326
2327   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}LIBOBJS";
2328
2329   foreach my $iter (keys %libsources)
2330     {
2331       if ($iter =~ /\.[cly]$/)
2332         {
2333           &saw_extension ($&);
2334           &saw_extension ('.c');
2335         }
2336
2337       if ($iter =~ /\.h$/)
2338         {
2339           require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2340         }
2341       elsif ($iter ne 'alloca.c')
2342         {
2343           my $rewrite = $iter;
2344           $rewrite =~ s/\.c$/.P$myobjext/;
2345           $dep_files{$dir . '$(DEPDIR)/' . $rewrite} = 1;
2346           $rewrite = "^" . quotemeta ($iter) . "\$";
2347           # Only require the file if it is not a built source.
2348           my $bs = var ('BUILT_SOURCES');
2349           if (! $bs || ! grep (/$rewrite/, $bs->value_as_list_recursive))
2350             {
2351               require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2352             }
2353         }
2354     }
2355 }
2356
2357 sub handle_ALLOCA ($$$)
2358 {
2359   my ($var, $cond, $lt) = @_;
2360   my $myobjext = $lt ? 'lo' : 'o';
2361   $lt ||= '';
2362   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}ALLOCA";
2363
2364   $var->requires_variables ("\@${lt}ALLOCA\@ used", $lt . 'ALLOCA');
2365   $dep_files{$dir . '$(DEPDIR)/alloca.P' . $myobjext} = 1;
2366   require_libsource_with_macro ($cond, $var, FOREIGN, 'alloca.c');
2367   &saw_extension ('.c');
2368 }
2369
2370 # Canonicalize the input parameter
2371 sub canonicalize
2372 {
2373     my ($string) = @_;
2374     $string =~ tr/A-Za-z0-9_\@/_/c;
2375     return $string;
2376 }
2377
2378 # Canonicalize a name, and check to make sure the non-canonical name
2379 # is never used.  Returns canonical name.  Arguments are name and a
2380 # list of suffixes to check for.
2381 sub check_canonical_spelling
2382 {
2383   my ($name, @suffixes) = @_;
2384
2385   my $xname = &canonicalize ($name);
2386   if ($xname ne $name)
2387     {
2388       foreach my $xt (@suffixes)
2389         {
2390           reject_var ("$name$xt", "use '$xname$xt', not '$name$xt'");
2391         }
2392     }
2393
2394   return $xname;
2395 }
2396
2397
2398 # handle_compile ()
2399 # -----------------
2400 # Set up the compile suite.
2401 sub handle_compile ()
2402 {
2403    return if ! $must_handle_compiled_objects;
2404
2405     # Boilerplate.
2406     my $default_includes = '';
2407     if (! option 'nostdinc')
2408       {
2409         my @incs = ('-I.', subst ('am__isrc'));
2410
2411         my $var = var 'CONFIG_HEADER';
2412         if ($var)
2413           {
2414             foreach my $hdr (split (' ', $var->variable_value))
2415               {
2416                 push @incs, '-I' . dirname ($hdr);
2417               }
2418           }
2419         # We want '-I. -I$(srcdir)', but the latter -I is redundant
2420         # and unaesthetic in non-VPATH builds.  We use `-I.@am__isrc@`
2421         # instead.  It will be replaced by '-I.' or '-I. -I$(srcdir)'.
2422         # Items in CONFIG_HEADER are never in $(srcdir) so it is safe
2423         # to just put @am__isrc@ right after '-I.', without a space.
2424         ($default_includes = ' ' . uniq (@incs)) =~ s/ @/@/;
2425       }
2426
2427     my (@mostly_rms, @dist_rms);
2428     foreach my $item (sort keys %compile_clean_files)
2429     {
2430         if ($compile_clean_files{$item} == MOSTLY_CLEAN)
2431         {
2432             push (@mostly_rms, "\t-rm -f $item");
2433         }
2434         elsif ($compile_clean_files{$item} == DIST_CLEAN)
2435         {
2436             push (@dist_rms, "\t-rm -f $item");
2437         }
2438         else
2439         {
2440           prog_error 'invalid entry in %compile_clean_files';
2441         }
2442     }
2443
2444     my ($coms, $vars, $rules) =
2445       &file_contents_internal (1, "$libdir/am/compile.am",
2446                                new Automake::Location,
2447                                ('DEFAULT_INCLUDES' => $default_includes,
2448                                 'MOSTLYRMS' => join ("\n", @mostly_rms),
2449                                 'DISTRMS' => join ("\n", @dist_rms)));
2450     $output_vars .= $vars;
2451     $output_rules .= "$coms$rules";
2452 }
2453
2454 # handle_libtool ()
2455 # -----------------
2456 # Handle libtool rules.
2457 sub handle_libtool
2458 {
2459   return unless var ('LIBTOOL');
2460
2461   # Libtool requires some files, but only at top level.
2462   # (Starting with Libtool 2.0 we do not have to bother.  These
2463   # requirements are done with AC_REQUIRE_AUX_FILE.)
2464   require_conf_file_with_macro (TRUE, 'LIBTOOL', FOREIGN, @libtool_files)
2465     if $relative_dir eq '.' && ! $libtool_new_api;
2466
2467   my @libtool_rms;
2468   foreach my $item (sort keys %libtool_clean_directories)
2469     {
2470       my $dir = ($item eq '.') ? '' : "$item/";
2471       # .libs is for Unix, _libs for DOS.
2472       push (@libtool_rms, "\t-rm -rf ${dir}.libs ${dir}_libs");
2473     }
2474
2475   check_user_variables 'LIBTOOLFLAGS';
2476
2477   # Output the libtool compilation rules.
2478   $output_rules .= &file_contents ('libtool',
2479                                    new Automake::Location,
2480                                    LTRMS => join ("\n", @libtool_rms));
2481 }
2482
2483 # handle_programs ()
2484 # ------------------
2485 # Handle C programs.
2486 sub handle_programs
2487 {
2488   my @proglist = &am_install_var ('progs', 'PROGRAMS',
2489                                   'bin', 'sbin', 'libexec', 'pkglibexec',
2490                                   'noinst', 'check');
2491   return if ! @proglist;
2492   $must_handle_compiled_objects = 1;
2493
2494   my $seen_global_libobjs =
2495     var ('LDADD') && &handle_lib_objects ('', 'LDADD');
2496
2497   foreach my $pair (@proglist)
2498     {
2499       my ($where, $one_file) = @$pair;
2500
2501       my $seen_libobjs = 0;
2502       my $obj = '.$(OBJEXT)';
2503
2504       $known_programs{$one_file} = $where;
2505
2506       # Canonicalize names and check for misspellings.
2507       my $xname = &check_canonical_spelling ($one_file, '_LDADD', '_LDFLAGS',
2508                                              '_SOURCES', '_OBJECTS',
2509                                              '_DEPENDENCIES');
2510
2511       $where->push_context ("while processing program '$one_file'");
2512       $where->set (INTERNAL->get);
2513
2514       my $linker = &handle_source_transform ($xname, $one_file, $obj, $where,
2515                                              NONLIBTOOL => 1, LIBTOOL => 0);
2516
2517       if (var ($xname . "_LDADD"))
2518         {
2519           $seen_libobjs = &handle_lib_objects ($xname, $xname . '_LDADD');
2520         }
2521       else
2522         {
2523           # User didn't define prog_LDADD override.  So do it.
2524           &define_variable ($xname . '_LDADD', '$(LDADD)', $where);
2525
2526           # This does a bit too much work.  But we need it to
2527           # generate _DEPENDENCIES when appropriate.
2528           if (var ('LDADD'))
2529             {
2530               $seen_libobjs = &handle_lib_objects ($xname, 'LDADD');
2531             }
2532         }
2533
2534       reject_var ($xname . '_LIBADD',
2535                   "use '${xname}_LDADD', not '${xname}_LIBADD'");
2536
2537       set_seen ($xname . '_DEPENDENCIES');
2538       set_seen ('EXTRA_' . $xname . '_DEPENDENCIES');
2539       set_seen ($xname . '_LDFLAGS');
2540
2541       # Determine program to use for link.
2542       my($xlink, $vlink) = &define_per_target_linker_variable ($linker, $xname);
2543       $vlink = verbose_flag ($vlink || 'GEN');
2544
2545       # If the resulting program lies into a subdirectory,
2546       # make sure this directory will exist.
2547       my $dirstamp = require_build_directory_maybe ($one_file);
2548
2549       $libtool_clean_directories{dirname ($one_file)} = 1;
2550
2551       $output_rules .= &file_contents ('program',
2552                                        $where,
2553                                        PROGRAM  => $one_file,
2554                                        XPROGRAM => $xname,
2555                                        XLINK    => $xlink,
2556                                        VERBOSE  => $vlink,
2557                                        DIRSTAMP => $dirstamp,
2558                                        EXEEXT   => '$(EXEEXT)');
2559
2560       if ($seen_libobjs || $seen_global_libobjs)
2561         {
2562           if (var ($xname . '_LDADD'))
2563             {
2564               &check_libobjs_sources ($xname, $xname . '_LDADD');
2565             }
2566           elsif (var ('LDADD'))
2567             {
2568               &check_libobjs_sources ($xname, 'LDADD');
2569             }
2570         }
2571     }
2572 }
2573
2574
2575 # handle_libraries ()
2576 # -------------------
2577 # Handle libraries.
2578 sub handle_libraries
2579 {
2580   my @liblist = &am_install_var ('libs', 'LIBRARIES',
2581                                  'lib', 'pkglib', 'noinst', 'check');
2582   return if ! @liblist;
2583   $must_handle_compiled_objects = 1;
2584
2585   my @prefix = am_primary_prefixes ('LIBRARIES', 0, 'lib', 'pkglib',
2586                                     'noinst', 'check');
2587
2588   if (@prefix)
2589     {
2590       my $var = rvar ($prefix[0] . '_LIBRARIES');
2591       $var->requires_variables ('library used', 'RANLIB');
2592     }
2593
2594   &define_variable ('AR', 'ar', INTERNAL);
2595   &define_variable ('ARFLAGS', 'cru', INTERNAL);
2596   &define_verbose_tagvar ('AR');
2597
2598   foreach my $pair (@liblist)
2599     {
2600       my ($where, $onelib) = @$pair;
2601
2602       my $seen_libobjs = 0;
2603       # Check that the library fits the standard naming convention.
2604       my $bn = basename ($onelib);
2605       if ($bn !~ /^lib.*\.a$/)
2606         {
2607           $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.a/;
2608           my $suggestion = dirname ($onelib) . "/$bn";
2609           $suggestion =~ s|^\./||g;
2610           msg ('error-gnu/warn', $where,
2611                "'$onelib' is not a standard library name\n"
2612                . "did you mean '$suggestion'?")
2613         }
2614
2615       ($known_libraries{$onelib} = $bn) =~ s/\.a$//;
2616
2617       $where->push_context ("while processing library '$onelib'");
2618       $where->set (INTERNAL->get);
2619
2620       my $obj = '.$(OBJEXT)';
2621
2622       # Canonicalize names and check for misspellings.
2623       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_SOURCES',
2624                                             '_OBJECTS', '_DEPENDENCIES',
2625                                             '_AR');
2626
2627       if (! var ($xlib . '_AR'))
2628         {
2629           &define_variable ($xlib . '_AR', '$(AR) $(ARFLAGS)', $where);
2630         }
2631
2632       # Generate support for conditional object inclusion in
2633       # libraries.
2634       if (var ($xlib . '_LIBADD'))
2635         {
2636           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2637             {
2638               $seen_libobjs = 1;
2639             }
2640         }
2641       else
2642         {
2643           &define_variable ($xlib . "_LIBADD", '', $where);
2644         }
2645
2646       reject_var ($xlib . '_LDADD',
2647                   "use '${xlib}_LIBADD', not '${xlib}_LDADD'");
2648
2649       # Make sure we at look at this.
2650       set_seen ($xlib . '_DEPENDENCIES');
2651       set_seen ('EXTRA_' . $xlib . '_DEPENDENCIES');
2652
2653       &handle_source_transform ($xlib, $onelib, $obj, $where,
2654                                 NONLIBTOOL => 1, LIBTOOL => 0);
2655
2656       # If the resulting library lies into a subdirectory,
2657       # make sure this directory will exist.
2658       my $dirstamp = require_build_directory_maybe ($onelib);
2659       my $verbose = verbose_flag ('AR');
2660       my $silent = silent_flag ();
2661
2662       $output_rules .= &file_contents ('library',
2663                                        $where,
2664                                        VERBOSE  => $verbose,
2665                                        SILENT   => $silent,
2666                                        LIBRARY  => $onelib,
2667                                        XLIBRARY => $xlib,
2668                                        DIRSTAMP => $dirstamp);
2669
2670       if ($seen_libobjs)
2671         {
2672           if (var ($xlib . '_LIBADD'))
2673             {
2674               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2675             }
2676         }
2677
2678       if (! $seen_ar)
2679         {
2680           msg ('extra-portability', $where,
2681                "'$onelib': linking libraries using a non-POSIX\n"
2682                . "archiver requires 'AM_PROG_AR' in '$configure_ac'")
2683         }
2684     }
2685 }
2686
2687
2688 # handle_ltlibraries ()
2689 # ---------------------
2690 # Handle shared libraries.
2691 sub handle_ltlibraries
2692 {
2693   my @liblist = &am_install_var ('ltlib', 'LTLIBRARIES',
2694                                  'noinst', 'lib', 'pkglib', 'check');
2695   return if ! @liblist;
2696   $must_handle_compiled_objects = 1;
2697
2698   my @prefix = am_primary_prefixes ('LTLIBRARIES', 0, 'lib', 'pkglib',
2699                                     'noinst', 'check');
2700
2701   if (@prefix)
2702     {
2703       my $var = rvar ($prefix[0] . '_LTLIBRARIES');
2704       $var->requires_variables ('Libtool library used', 'LIBTOOL');
2705     }
2706
2707   my %instdirs = ();
2708   my %instsubdirs = ();
2709   my %instconds = ();
2710   my %liblocations = ();        # Location (in Makefile.am) of each library.
2711
2712   foreach my $key (@prefix)
2713     {
2714       # Get the installation directory of each library.
2715       my $dir = $key;
2716       my $strip_subdir = 1;
2717       if ($dir =~ /^nobase_/)
2718         {
2719           $dir =~ s/^nobase_//;
2720           $strip_subdir = 0;
2721         }
2722       my $var = rvar ($key . '_LTLIBRARIES');
2723
2724       # We reject libraries which are installed in several places
2725       # in the same condition, because we can only specify one
2726       # '-rpath' option.
2727       $var->traverse_recursively
2728         (sub
2729          {
2730            my ($var, $val, $cond, $full_cond) = @_;
2731            my $hcond = $full_cond->human;
2732            my $where = $var->rdef ($cond)->location;
2733            my $ldir = '';
2734            $ldir = '/' . dirname ($val)
2735              if (!$strip_subdir);
2736            # A library cannot be installed in different directories
2737            # in overlapping conditions.
2738            if (exists $instconds{$val})
2739              {
2740                my ($msg, $acond) =
2741                  $instconds{$val}->ambiguous_p ($val, $full_cond);
2742
2743                if ($msg)
2744                  {
2745                    error ($where, $msg, partial => 1);
2746                    my $dirtxt = "installed " . ($strip_subdir ? "in" : "below") . " '$dir'";
2747                    $dirtxt = "built for '$dir'"
2748                      if $dir eq 'EXTRA' || $dir eq 'noinst' || $dir eq 'check';
2749                    my $dircond =
2750                      $full_cond->true ? "" : " in condition $hcond";
2751
2752                    error ($where, "'$val' should be $dirtxt$dircond ...",
2753                           partial => 1);
2754
2755                    my $hacond = $acond->human;
2756                    my $adir = $instdirs{$val}{$acond};
2757                    my $adirtxt = "installed in '$adir'";
2758                    $adirtxt = "built for '$adir'"
2759                      if ($adir eq 'EXTRA' || $adir eq 'noinst'
2760                          || $adir eq 'check');
2761                    my $adircond = $acond->true ? "" : " in condition $hacond";
2762
2763                    my $onlyone = ($dir ne $adir) ?
2764                      ("\nLibtool libraries can be built for only one "
2765                       . "destination") : "";
2766
2767                    error ($liblocations{$val}{$acond},
2768                           "... and should also be $adirtxt$adircond.$onlyone");
2769                    return;
2770                  }
2771              }
2772            else
2773              {
2774                $instconds{$val} = new Automake::DisjConditions;
2775              }
2776            $instdirs{$val}{$full_cond} = $dir;
2777            $instsubdirs{$val}{$full_cond} = $ldir;
2778            $liblocations{$val}{$full_cond} = $where;
2779            $instconds{$val} = $instconds{$val}->merge ($full_cond);
2780          },
2781          sub
2782          {
2783            return ();
2784          },
2785          skip_ac_subst => 1);
2786     }
2787
2788   foreach my $pair (@liblist)
2789     {
2790       my ($where, $onelib) = @$pair;
2791
2792       my $seen_libobjs = 0;
2793       my $obj = '.lo';
2794
2795       # Canonicalize names and check for misspellings.
2796       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_LDFLAGS',
2797                                             '_SOURCES', '_OBJECTS',
2798                                             '_DEPENDENCIES');
2799
2800       # Check that the library fits the standard naming convention.
2801       my $libname_rx = '^lib.*\.la';
2802       my $ldvar = var ("${xlib}_LDFLAGS") || var ('AM_LDFLAGS');
2803       my $ldvar2 = var ('LDFLAGS');
2804       if (($ldvar && grep (/-module/, $ldvar->value_as_list_recursive))
2805           || ($ldvar2 && grep (/-module/, $ldvar2->value_as_list_recursive)))
2806         {
2807           # Relax name checking for libtool modules.
2808           $libname_rx = '\.la';
2809         }
2810
2811       my $bn = basename ($onelib);
2812       if ($bn !~ /$libname_rx$/)
2813         {
2814           my $type = 'library';
2815           if ($libname_rx eq '\.la')
2816             {
2817               $bn =~ s/^(lib|)(.*?)(?:\.[^.]*)?$/$1$2.la/;
2818               $type = 'module';
2819             }
2820           else
2821             {
2822               $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.la/;
2823             }
2824           my $suggestion = dirname ($onelib) . "/$bn";
2825           $suggestion =~ s|^\./||g;
2826           msg ('error-gnu/warn', $where,
2827                "'$onelib' is not a standard libtool $type name\n"
2828                . "did you mean '$suggestion'?")
2829         }
2830
2831       ($known_libraries{$onelib} = $bn) =~ s/\.la$//;
2832
2833       $where->push_context ("while processing Libtool library '$onelib'");
2834       $where->set (INTERNAL->get);
2835
2836       # Make sure we look at these.
2837       set_seen ($xlib . '_LDFLAGS');
2838       set_seen ($xlib . '_DEPENDENCIES');
2839       set_seen ('EXTRA_' . $xlib . '_DEPENDENCIES');
2840
2841       # Generate support for conditional object inclusion in
2842       # libraries.
2843       if (var ($xlib . '_LIBADD'))
2844         {
2845           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2846             {
2847               $seen_libobjs = 1;
2848             }
2849         }
2850       else
2851         {
2852           &define_variable ($xlib . "_LIBADD", '', $where);
2853         }
2854
2855       reject_var ("${xlib}_LDADD",
2856                   "use '${xlib}_LIBADD', not '${xlib}_LDADD'");
2857
2858
2859       my $linker = &handle_source_transform ($xlib, $onelib, $obj, $where,
2860                                              NONLIBTOOL => 0, LIBTOOL => 1);
2861
2862       # Determine program to use for link.
2863       my($xlink, $vlink) = &define_per_target_linker_variable ($linker, $xlib);
2864       $vlink = verbose_flag ($vlink || 'GEN');
2865
2866       my $rpathvar = "am_${xlib}_rpath";
2867       my $rpath = "\$($rpathvar)";
2868       foreach my $rcond ($instconds{$onelib}->conds)
2869         {
2870           my $val;
2871           if ($instdirs{$onelib}{$rcond} eq 'EXTRA'
2872               || $instdirs{$onelib}{$rcond} eq 'noinst'
2873               || $instdirs{$onelib}{$rcond} eq 'check')
2874             {
2875               # It's an EXTRA_ library, so we can't specify -rpath,
2876               # because we don't know where the library will end up.
2877               # The user probably knows, but generally speaking automake
2878               # doesn't -- and in fact configure could decide
2879               # dynamically between two different locations.
2880               $val = '';
2881             }
2882           else
2883             {
2884               $val = ('-rpath $(' . $instdirs{$onelib}{$rcond} . 'dir)');
2885               $val .= $instsubdirs{$onelib}{$rcond}
2886                 if defined $instsubdirs{$onelib}{$rcond};
2887             }
2888           if ($rcond->true)
2889             {
2890               # If $rcond is true there is only one condition and
2891               # there is no point defining an helper variable.
2892               $rpath = $val;
2893             }
2894           else
2895             {
2896               define_pretty_variable ($rpathvar, $rcond, INTERNAL, $val);
2897             }
2898         }
2899
2900       # If the resulting library lies into a subdirectory,
2901       # make sure this directory will exist.
2902       my $dirstamp = require_build_directory_maybe ($onelib);
2903
2904       # Remember to cleanup .libs/ in this directory.
2905       my $dirname = dirname $onelib;
2906       $libtool_clean_directories{$dirname} = 1;
2907
2908       $output_rules .= &file_contents ('ltlibrary',
2909                                        $where,
2910                                        LTLIBRARY  => $onelib,
2911                                        XLTLIBRARY => $xlib,
2912                                        RPATH      => $rpath,
2913                                        XLINK      => $xlink,
2914                                        VERBOSE    => $vlink,
2915                                        DIRSTAMP   => $dirstamp);
2916       if ($seen_libobjs)
2917         {
2918           if (var ($xlib . '_LIBADD'))
2919             {
2920               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2921             }
2922         }
2923
2924       if (! $seen_ar)
2925         {
2926           msg ('extra-portability', $where,
2927                "'$onelib': linking libtool libraries using a non-POSIX\n"
2928                . "archiver requires 'AM_PROG_AR' in '$configure_ac'")
2929         }
2930     }
2931 }
2932
2933 # See if any _SOURCES variable were misspelled.
2934 sub check_typos ()
2935 {
2936   # It is ok if the user sets this particular variable.
2937   set_seen 'AM_LDFLAGS';
2938
2939   foreach my $primary ('SOURCES', 'LIBADD', 'LDADD', 'LDFLAGS', 'DEPENDENCIES')
2940     {
2941       foreach my $var (variables $primary)
2942         {
2943           my $varname = $var->name;
2944           # A configure variable is always legitimate.
2945           next if exists $configure_vars{$varname};
2946
2947           for my $cond ($var->conditions->conds)
2948             {
2949               $varname =~ /^(?:EXTRA_)?(?:nobase_)?(?:dist_|nodist_)?(.*)_[[:alnum:]]+$/;
2950               msg_var ('syntax', $var, "variable '$varname' is defined but no"
2951                        . " program or\nlibrary has '$1' as canonical name"
2952                        . " (possible typo)")
2953                 unless $var->rdef ($cond)->seen;
2954             }
2955         }
2956     }
2957 }
2958
2959
2960 # Handle scripts.
2961 sub handle_scripts
2962 {
2963     # NOTE we no longer automatically clean SCRIPTS, because it is
2964     # useful to sometimes distribute scripts verbatim.  This happens
2965     # e.g. in Automake itself.
2966     &am_install_var ('-candist', 'scripts', 'SCRIPTS',
2967                      'bin', 'sbin', 'libexec', 'pkglibexec', 'pkgdata',
2968                      'noinst', 'check');
2969 }
2970
2971
2972
2973
2974 ## ------------------------ ##
2975 ## Handling Texinfo files.  ##
2976 ## ------------------------ ##
2977
2978 # ($OUTFILE, $VFILE, @CLEAN_FILES)
2979 # &scan_texinfo_file ($FILENAME)
2980 # ------------------------------
2981 # $OUTFILE     - name of the info file produced by $FILENAME.
2982 # $VFILE       - name of the version.texi file used (undef if none).
2983 # @CLEAN_FILES - list of byproducts (indexes etc.)
2984 sub scan_texinfo_file ($)
2985 {
2986   my ($filename) = @_;
2987
2988   # Some of the following extensions are always created, no matter
2989   # whether indexes are used or not.  Other (like cps, fns, ... pgs)
2990   # are only created when they are used.  We used to scan $FILENAME
2991   # for their use, but that is not enough: they could be used in
2992   # included files.  We can't scan included files because we don't
2993   # know the include path.  Therefore we always erase these files, no
2994   # matter whether they are used or not.
2995   #
2996   # (tmp is only created if an @macro is used and a certain e-TeX
2997   # feature is not available.)
2998   my %clean_suffixes =
2999     map { $_ => 1 } (qw(aux log toc tmp
3000                         cp cps
3001                         fn fns
3002                         ky kys
3003                         vr vrs
3004                         tp tps
3005                         pg pgs)); # grep 'new.*index' texinfo.tex
3006
3007   my $texi = new Automake::XFile "< $filename";
3008   verb "reading $filename";
3009
3010   my ($outfile, $vfile);
3011   while ($_ = $texi->getline)
3012     {
3013       if (/^\@setfilename +(\S+)/)
3014         {
3015           # Honor only the first @setfilename.  (It's possible to have
3016           # more occurrences later if the manual shows examples of how
3017           # to use @setfilename...)
3018           next if $outfile;
3019
3020           $outfile = $1;
3021           if ($outfile =~ /\.([^.]+)$/ && $1 ne 'info')
3022             {
3023               error ("$filename:$.",
3024                      "output '$outfile' has unrecognized extension");
3025               return;
3026             }
3027         }
3028       # A "version.texi" file is actually any file whose name matches
3029       # "vers*.texi".
3030       elsif (/^\@include\s+(vers[^.]*\.texi)\s*$/)
3031         {
3032           $vfile = $1;
3033         }
3034
3035       # Try to find new or unused indexes.
3036
3037       # Creating a new category of index.
3038       elsif (/^\@def(code)?index (\w+)/)
3039         {
3040           $clean_suffixes{$2} = 1;
3041           $clean_suffixes{"$2s"} = 1;
3042         }
3043
3044       # Merging an index into an another.
3045       elsif (/^\@syn(code)?index (\w+) (\w+)/)
3046         {
3047           delete $clean_suffixes{"$2s"};
3048           $clean_suffixes{"$3s"} = 1;
3049         }
3050
3051     }
3052
3053   if (! $outfile)
3054     {
3055       err_am "'$filename' missing \@setfilename";
3056       return;
3057     }
3058
3059   my $infobase = basename ($filename);
3060   $infobase =~ s/\.te?xi(nfo)?$//;
3061   return ($outfile, $vfile,
3062           map { "$infobase.$_" } (sort keys %clean_suffixes));
3063 }
3064
3065
3066 # ($DIRSTAMP, @CLEAN_FILES)
3067 # output_texinfo_build_rules ($SOURCE, $DEST, $INSRC, @DEPENDENCIES)
3068 # ------------------------------------------------------------------
3069 # SOURCE - the source Texinfo file
3070 # DEST - the destination Info file
3071 # INSRC - whether DEST should be built in the source tree
3072 # DEPENDENCIES - known dependencies
3073 sub output_texinfo_build_rules ($$$@)
3074 {
3075   my ($source, $dest, $insrc, @deps) = @_;
3076
3077   # Split 'a.texi' into 'a' and '.texi'.
3078   my ($spfx, $ssfx) = ($source =~ /^(.*?)(\.[^.]*)?$/);
3079   my ($dpfx, $dsfx) = ($dest =~ /^(.*?)(\.[^.]*)?$/);
3080
3081   $ssfx ||= "";
3082   $dsfx ||= "";
3083
3084   # We can output two kinds of rules: the "generic" rules use Make
3085   # suffix rules and are appropriate when $source and $dest do not lie
3086   # in a sub-directory; the "specific" rules are needed in the other
3087   # case.
3088   #
3089   # The former are output only once (this is not really apparent here,
3090   # but just remember that some logic deeper in Automake will not
3091   # output the same rule twice); while the later need to be output for
3092   # each Texinfo source.
3093   my $generic;
3094   my $makeinfoflags;
3095   my $sdir = dirname $source;
3096   if ($sdir eq '.' && dirname ($dest) eq '.')
3097     {
3098       $generic = 1;
3099       $makeinfoflags = '-I $(srcdir)';
3100     }
3101   else
3102     {
3103       $generic = 0;
3104       $makeinfoflags = "-I $sdir -I \$(srcdir)/$sdir";
3105     }
3106
3107   # A directory can contain two kinds of info files: some built in the
3108   # source tree, and some built in the build tree.  The rules are
3109   # different in each case.  However we cannot output two different
3110   # set of generic rules.  Because in-source builds are more usual, we
3111   # use generic rules in this case and fall back to "specific" rules
3112   # for build-dir builds.  (It should not be a problem to invert this
3113   # if needed.)
3114   $generic = 0 unless $insrc;
3115
3116   # We cannot use a suffix rule to build info files with an empty
3117   # extension.  Otherwise we would output a single suffix inference
3118   # rule, with separate dependencies, as in
3119   #
3120   #    .texi:
3121   #             $(MAKEINFO) ...
3122   #    foo.info: foo.texi
3123   #
3124   # which confuse Solaris make.  (See the Autoconf manual for
3125   # details.)  Therefore we use a specific rule in this case.  This
3126   # applies to info files only (dvi and pdf files always have an
3127   # extension).
3128   my $generic_info = ($generic && $dsfx) ? 1 : 0;
3129
3130   # If the resulting file lie into a subdirectory,
3131   # make sure this directory will exist.
3132   my $dirstamp = require_build_directory_maybe ($dest);
3133
3134   my $dipfx = ($insrc ? '$(srcdir)/' : '') . $dpfx;
3135
3136   $output_rules .= file_contents ('texibuild',
3137                                   new Automake::Location,
3138                                   AM_V_MAKEINFO    => verbose_flag('MAKEINFO'),
3139                                   AM_V_TEXI2DVI    => verbose_flag('TEXI2DVI'),
3140                                   AM_V_TEXI2PDF    => verbose_flag('TEXI2PDF'),
3141                                   DEPS             => "@deps",
3142                                   DEST_PREFIX      => $dpfx,
3143                                   DEST_INFO_PREFIX => $dipfx,
3144                                   DEST_SUFFIX      => $dsfx,
3145                                   DIRSTAMP         => $dirstamp,
3146                                   GENERIC          => $generic,
3147                                   GENERIC_INFO     => $generic_info,
3148                                   INSRC            => $insrc,
3149                                   MAKEINFOFLAGS    => $makeinfoflags,
3150                                   SILENT           => silent_flag(),
3151                                   SOURCE           => ($generic
3152                                                        ? '$<' : $source),
3153                                   SOURCE_INFO      => ($generic_info
3154                                                        ? '$<' : $source),
3155                                   SOURCE_REAL      => $source,
3156                                   SOURCE_SUFFIX    => $ssfx,
3157                                   TEXIQUIET        => verbose_flag('texinfo'),
3158                                   TEXIDEVNULL      => verbose_flag('texidevnull'),
3159                                   );
3160   return ($dirstamp, "$dpfx.dvi", "$dpfx.pdf", "$dpfx.ps", "$dpfx.html");
3161 }
3162
3163
3164 # ($MOSTLYCLEAN, $TEXICLEAN, $MAINTCLEAN)
3165 # handle_texinfo_helper ($info_texinfos)
3166 # --------------------------------------
3167 # Handle all Texinfo source; helper for handle_texinfo.
3168 sub handle_texinfo_helper ($)
3169 {
3170   my ($info_texinfos) = @_;
3171   my (@infobase, @info_deps_list, @texi_deps);
3172   my %versions;
3173   my $done = 0;
3174   my (@mostly_cleans, @texi_cleans, @maint_cleans) = ('', '', '');
3175
3176   # Build a regex matching user-cleaned files.
3177   my $d = var 'DISTCLEANFILES';
3178   my $c = var 'CLEANFILES';
3179   my @f = ();
3180   push @f, $d->value_as_list_recursive (inner_expand => 1) if $d;
3181   push @f, $c->value_as_list_recursive (inner_expand => 1) if $c;
3182   @f = map { s|[^A-Za-z_0-9*\[\]\-]|\\$&|g; s|\*|[^/]*|g; $_; } @f;
3183   my $user_cleaned_files = '^(?:' . join ('|', @f) . ')$';
3184
3185   foreach my $texi
3186       ($info_texinfos->value_as_list_recursive (inner_expand => 1))
3187     {
3188       my $infobase = $texi;
3189       $infobase =~ s/\.(txi|texinfo|texi)$//;
3190
3191       if ($infobase eq $texi)
3192         {
3193           # FIXME: report line number.
3194           err_am "texinfo file '$texi' has unrecognized extension";
3195           next;
3196         }
3197
3198       push @infobase, $infobase;
3199
3200       # If 'version.texi' is referenced by input file, then include
3201       # automatic versioning capability.
3202       my ($out_file, $vtexi, @clean_files) =
3203         scan_texinfo_file ("$relative_dir/$texi")
3204         or next;
3205       push (@mostly_cleans, @clean_files);
3206
3207       # If the Texinfo source is in a subdirectory, create the
3208       # resulting info in this subdirectory.  If it is in the current
3209       # directory, try hard to not prefix "./" because it breaks the
3210       # generic rules.
3211       my $outdir = dirname ($texi) . '/';
3212       $outdir = "" if $outdir eq './';
3213       $out_file =  $outdir . $out_file;
3214
3215       # Until Automake 1.6.3, .info files were built in the
3216       # source tree.  This was an obstacle to the support of
3217       # non-distributed .info files, and non-distributed .texi
3218       # files.
3219       #
3220       # * Non-distributed .texi files is important in some packages
3221       #   where .texi files are built at make time, probably using
3222       #   other binaries built in the package itself, maybe using
3223       #   tools or information found on the build host.  Because
3224       #   these files are not distributed they are always rebuilt
3225       #   at make time; they should therefore not lie in the source
3226       #   directory.  One plan was to support this using
3227       #   nodist_info_TEXINFOS or something similar.  (Doing this
3228       #   requires some sanity checks.  For instance Automake should
3229       #   not allow:
3230       #      dist_info_TEXINFOS = foo.texi
3231       #      nodist_foo_TEXINFOS = included.texi
3232       #   because a distributed file should never depend on a
3233       #   non-distributed file.)
3234       #
3235       # * If .texi files are not distributed, then .info files should
3236       #   not be distributed either.  There are also cases where one
3237       #   wants to distribute .texi files, but does not want to
3238       #   distribute the .info files.  For instance the Texinfo package
3239       #   distributes the tool used to build these files; it would
3240       #   be a waste of space to distribute them.  It's not clear
3241       #   which syntax we should use to indicate that .info files should
3242       #   not be distributed.  Akim Demaille suggested that eventually
3243       #   we switch to a new syntax:
3244       #   |  Maybe we should take some inspiration from what's already
3245       #   |  done in the rest of Automake.  Maybe there is too much
3246       #   |  syntactic sugar here, and you want
3247       #   |     nodist_INFO = bar.info
3248       #   |     dist_bar_info_SOURCES = bar.texi
3249       #   |     bar_texi_DEPENDENCIES = foo.texi
3250       #   |  with a bit of magic to have bar.info represent the whole
3251       #   |  bar*info set.  That's a lot more verbose that the current
3252       #   |  situation, but it is # not new, hence the user has less
3253       #   |  to learn.
3254       #   |
3255       #   |  But there is still too much room for meaningless specs:
3256       #   |     nodist_INFO = bar.info
3257       #   |     dist_bar_info_SOURCES = bar.texi
3258       #   |     dist_PS = bar.ps something-written-by-hand.ps
3259       #   |     nodist_bar_ps_SOURCES = bar.texi
3260       #   |     bar_texi_DEPENDENCIES = foo.texi
3261       #   |  here bar.texi is dist_ in line 2, and nodist_ in 4.
3262       #
3263       # Back to the point, it should be clear that in order to support
3264       # non-distributed .info files, we need to build them in the
3265       # build tree, not in the source tree (non-distributed .texi
3266       # files are less of a problem, because we do not output build
3267       # rules for them).  In Automake 1.7 .info build rules have been
3268       # largely cleaned up so that .info files get always build in the
3269       # build tree, even when distributed.  The idea was that
3270       #   (1) if during a VPATH build the .info file was found to be
3271       #       absent or out-of-date (in the source tree or in the
3272       #       build tree), Make would rebuild it in the build tree.
3273       #       If an up-to-date source-tree of the .info file existed,
3274       #       make would not rebuild it in the build tree.
3275       #   (2) having two copies of .info files, one in the source tree
3276       #       and one (newer) in the build tree is not a problem
3277       #       because 'make dist' always pick files in the build tree
3278       #       first.
3279       # However it turned out the be a bad idea for several reasons:
3280       #   * Tru64, OpenBSD, and FreeBSD (not NetBSD) Make do not behave
3281       #     like GNU Make on point (1) above.  These implementations
3282       #     of Make would always rebuild .info files in the build
3283       #     tree, even if such files were up to date in the source
3284       #     tree.  Consequently, it was impossible to perform a VPATH
3285       #     build of a package containing Texinfo files using these
3286       #     Make implementations.
3287       #     (Refer to the Autoconf Manual, section "Limitation of
3288       #     Make", paragraph "VPATH", item "target lookup", for
3289       #     an account of the differences between these
3290       #     implementations.)
3291       #   * The GNU Coding Standards require these files to be built
3292       #     in the source-tree (when they are distributed, that is).
3293       #   * Keeping a fresher copy of distributed files in the
3294       #     build tree can be annoying during development because
3295       #     - if the files is kept under CVS, you really want it
3296       #       to be updated in the source tree
3297       #     - it is confusing that 'make distclean' does not erase
3298       #       all files in the build tree.
3299       #
3300       # Consequently, starting with Automake 1.8, .info files are
3301       # built in the source tree again.  Because we still plan to
3302       # support non-distributed .info files at some point, we
3303       # have a single variable ($INSRC) that controls whether
3304       # the current .info file must be built in the source tree
3305       # or in the build tree.  Actually this variable is switched
3306       # off for .info files that appear to be cleaned; this is
3307       # for backward compatibility with package such as Texinfo,
3308       # which do things like
3309       #   info_TEXINFOS = texinfo.txi info-stnd.texi info.texi
3310       #   DISTCLEANFILES = texinfo texinfo-* info*.info*
3311       #   # Do not create info files for distribution.
3312       #   dist-info:
3313       # in order not to distribute .info files.
3314       my $insrc = ($out_file =~ $user_cleaned_files) ? 0 : 1;
3315
3316       my $soutdir = '$(srcdir)/' . $outdir;
3317       $outdir = $soutdir if $insrc;
3318
3319       # If user specified file_TEXINFOS, then use that as explicit
3320       # dependency list.
3321       @texi_deps = ();
3322       push (@texi_deps, "$soutdir$vtexi") if $vtexi;
3323
3324       my $canonical = canonicalize ($infobase);
3325       if (var ($canonical . "_TEXINFOS"))
3326         {
3327           push (@texi_deps, '$(' . $canonical . '_TEXINFOS)');
3328           push_dist_common ('$(' . $canonical . '_TEXINFOS)');
3329         }
3330
3331       my ($dirstamp, @cfiles) =
3332         output_texinfo_build_rules ($texi, $out_file, $insrc, @texi_deps);
3333       push (@texi_cleans, @cfiles);
3334
3335       push (@info_deps_list, $out_file);
3336
3337       # If a vers*.texi file is needed, emit the rule.
3338       if ($vtexi)
3339         {
3340           err_am ("'$vtexi', included in '$texi', "
3341                   . "also included in '$versions{$vtexi}'")
3342             if defined $versions{$vtexi};
3343           $versions{$vtexi} = $texi;
3344
3345           # We number the stamp-vti files.  This is doable since the
3346           # actual names don't matter much.  We only number starting
3347           # with the second one, so that the common case looks nice.
3348           my $vti = ($done ? $done : 'vti');
3349           ++$done;
3350
3351           # This is ugly, but it is our historical practice.
3352           if ($config_aux_dir_set_in_configure_ac)
3353             {
3354               require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3355                                             'mdate-sh');
3356             }
3357           else
3358             {
3359               require_file_with_macro (TRUE, 'info_TEXINFOS',
3360                                        FOREIGN, 'mdate-sh');
3361             }
3362
3363           my $conf_dir;
3364           if ($config_aux_dir_set_in_configure_ac)
3365             {
3366               $conf_dir = "$am_config_aux_dir/";
3367             }
3368           else
3369             {
3370               $conf_dir = '$(srcdir)/';
3371             }
3372           $output_rules .= file_contents ('texi-vers',
3373                                           new Automake::Location,
3374                                           TEXI     => $texi,
3375                                           VTI      => $vti,
3376                                           STAMPVTI => "${soutdir}stamp-$vti",
3377                                           VTEXI    => "$soutdir$vtexi",
3378                                           MDDIR    => $conf_dir,
3379                                           DIRSTAMP => $dirstamp);
3380         }
3381     }
3382
3383   # Handle location of texinfo.tex.
3384   my $need_texi_file = 0;
3385   my $texinfodir;
3386   if (var ('TEXINFO_TEX'))
3387     {
3388       # The user defined TEXINFO_TEX so assume he knows what he is
3389       # doing.
3390       $texinfodir = ('$(srcdir)/'
3391                      . dirname (variable_value ('TEXINFO_TEX')));
3392     }
3393   elsif ($config_aux_dir_set_in_configure_ac)
3394     {
3395       $texinfodir = $am_config_aux_dir;
3396       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3397       $need_texi_file = 2; # so that we require_conf_file later
3398     }
3399   else
3400     {
3401       $texinfodir = '$(srcdir)';
3402       $need_texi_file = 1;
3403     }
3404   define_variable ('am__TEXINFO_TEX_DIR', $texinfodir, INTERNAL);
3405
3406   push (@dist_targets, 'dist-info');
3407
3408   if (! option 'no-installinfo')
3409     {
3410       # Make sure documentation is made and installed first.  Use
3411       # $(INFO_DEPS), not 'info', because otherwise recursive makes
3412       # get run twice during "make all".
3413       unshift (@all, '$(INFO_DEPS)');
3414     }
3415
3416   define_files_variable ("DVIS", @infobase, 'dvi', INTERNAL);
3417   define_files_variable ("PDFS", @infobase, 'pdf', INTERNAL);
3418   define_files_variable ("PSS", @infobase, 'ps', INTERNAL);
3419   define_files_variable ("HTMLS", @infobase, 'html', INTERNAL);
3420
3421   # This next isn't strictly needed now -- the places that look here
3422   # could easily be changed to look in info_TEXINFOS.  But this is
3423   # probably better, in case noinst_TEXINFOS is ever supported.
3424   define_variable ("TEXINFOS", variable_value ('info_TEXINFOS'), INTERNAL);
3425
3426   # Do some error checking.  Note that this file is not required
3427   # when in Cygnus mode; instead we defined TEXINFO_TEX explicitly
3428   # up above.
3429   if ($need_texi_file && ! option 'no-texinfo.tex')
3430     {
3431       if ($need_texi_file > 1)
3432         {
3433           require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3434                                         'texinfo.tex');
3435         }
3436       else
3437         {
3438           require_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3439                                    'texinfo.tex');
3440         }
3441     }
3442
3443   return (makefile_wrap ("", "\t  ", @mostly_cleans),
3444           makefile_wrap ("", "\t  ", @texi_cleans),
3445           makefile_wrap ("", "\t  ", @maint_cleans));
3446 }
3447
3448
3449 # handle_texinfo ()
3450 # -----------------
3451 # Handle all Texinfo source.
3452 sub handle_texinfo ()
3453 {
3454   reject_var 'TEXINFOS', "'TEXINFOS' is an anachronism; use 'info_TEXINFOS'";
3455   # FIXME: I think this is an obsolete future feature name.
3456   reject_var 'html_TEXINFOS', "HTML generation not yet supported";
3457
3458   my $info_texinfos = var ('info_TEXINFOS');
3459   my ($mostlyclean, $clean, $maintclean) = ('', '', '');
3460   if ($info_texinfos)
3461     {
3462       define_verbose_texinfo;
3463       ($mostlyclean, $clean, $maintclean) = handle_texinfo_helper ($info_texinfos);
3464       chomp $mostlyclean;
3465       chomp $clean;
3466       chomp $maintclean;
3467     }
3468
3469   $output_rules .=  file_contents ('texinfos',
3470                                    new Automake::Location,
3471                                    AM_V_DVIPS    => verbose_flag('DVIPS'),
3472                                    MOSTLYCLEAN   => $mostlyclean,
3473                                    TEXICLEAN     => $clean,
3474                                    MAINTCLEAN    => $maintclean,
3475                                    'LOCAL-TEXIS' => !!$info_texinfos,
3476                                    TEXIQUIET     => verbose_flag('texinfo'));
3477 }
3478
3479
3480 # Handle any man pages.
3481 sub handle_man_pages
3482 {
3483   reject_var 'MANS', "'MANS' is an anachronism; use 'man_MANS'";
3484
3485   # Find all the sections in use.  We do this by first looking for
3486   # "standard" sections, and then looking for any additional
3487   # sections used in man_MANS.
3488   my (%sections, %notrans_sections, %trans_sections,
3489       %notrans_vars, %trans_vars, %notrans_sect_vars, %trans_sect_vars);
3490   # We handle nodist_ for uniformity.  man pages aren't distributed
3491   # by default so it isn't actually very important.
3492   foreach my $npfx ('', 'notrans_')
3493     {
3494       foreach my $pfx ('', 'dist_', 'nodist_')
3495         {
3496           # Add more sections as needed.
3497           foreach my $section ('0'..'9', 'n', 'l')
3498             {
3499               my $varname = $npfx . $pfx . 'man' . $section . '_MANS';
3500               if (var ($varname))
3501                 {
3502                   $sections{$section} = 1;
3503                   $varname = '$(' . $varname . ')';
3504                   if ($npfx eq 'notrans_')
3505                     {
3506                       $notrans_sections{$section} = 1;
3507                       $notrans_sect_vars{$varname} = 1;
3508                     }
3509                   else
3510                     {
3511                       $trans_sections{$section} = 1;
3512                       $trans_sect_vars{$varname} = 1;
3513                     }
3514
3515                   &push_dist_common ($varname)
3516                     if $pfx eq 'dist_';
3517                 }
3518             }
3519
3520           my $varname = $npfx . $pfx . 'man_MANS';
3521           my $var = var ($varname);
3522           if ($var)
3523             {
3524               foreach ($var->value_as_list_recursive)
3525                 {
3526                   # A page like 'foo.1c' goes into man1dir.
3527                   if (/\.([0-9a-z])([a-z]*)$/)
3528                     {
3529                       $sections{$1} = 1;
3530                       if ($npfx eq 'notrans_')
3531                         {
3532                           $notrans_sections{$1} = 1;
3533                         }
3534                       else
3535                         {
3536                           $trans_sections{$1} = 1;
3537                         }
3538                     }
3539                 }
3540
3541               $varname = '$(' . $varname . ')';
3542               if ($npfx eq 'notrans_')
3543                 {
3544                   $notrans_vars{$varname} = 1;
3545                 }
3546               else
3547                 {
3548                   $trans_vars{$varname} = 1;
3549                 }
3550               &push_dist_common ($varname)
3551                 if $pfx eq 'dist_';
3552             }
3553         }
3554     }
3555
3556   return unless %sections;
3557
3558   my @unsorted_deps;
3559
3560   # Build section independent variables.
3561   my $have_notrans = %notrans_vars;
3562   my @notrans_list = sort keys %notrans_vars;
3563   my $have_trans = %trans_vars;
3564   my @trans_list = sort keys %trans_vars;
3565
3566   # Now for each section, generate an install and uninstall rule.
3567   # Sort sections so output is deterministic.
3568   foreach my $section (sort keys %sections)
3569     {
3570       # Build section dependent variables.
3571       my $notrans_mans = $have_notrans || exists $notrans_sections{$section};
3572       my $trans_mans = $have_trans || exists $trans_sections{$section};
3573       my (%notrans_this_sect, %trans_this_sect);
3574       my $expr = 'man' . $section . '_MANS';
3575       foreach my $varname (keys %notrans_sect_vars)
3576         {
3577           if ($varname =~ /$expr/)
3578             {
3579               $notrans_this_sect{$varname} = 1;
3580             }
3581         }
3582       foreach my $varname (keys %trans_sect_vars)
3583         {
3584           if ($varname =~ /$expr/)
3585             {
3586               $trans_this_sect{$varname} = 1;
3587             }
3588         }
3589       my @notrans_sect_list = sort keys %notrans_this_sect;
3590       my @trans_sect_list = sort keys %trans_this_sect;
3591       @unsorted_deps = (keys %notrans_vars, keys %trans_vars,
3592                         keys %notrans_this_sect, keys %trans_this_sect);
3593       my @deps = sort @unsorted_deps;
3594       $output_rules .= &file_contents ('mans',
3595                                        new Automake::Location,
3596                                        SECTION           => $section,
3597                                        DEPS              => "@deps",
3598                                        NOTRANS_MANS      => $notrans_mans,
3599                                        NOTRANS_SECT_LIST => "@notrans_sect_list",
3600                                        HAVE_NOTRANS      => $have_notrans,
3601                                        NOTRANS_LIST      => "@notrans_list",
3602                                        TRANS_MANS        => $trans_mans,
3603                                        TRANS_SECT_LIST   => "@trans_sect_list",
3604                                        HAVE_TRANS        => $have_trans,
3605                                        TRANS_LIST        => "@trans_list");
3606     }
3607
3608   @unsorted_deps  = (keys %notrans_vars, keys %trans_vars,
3609                      keys %notrans_sect_vars, keys %trans_sect_vars);
3610   my @mans = sort @unsorted_deps;
3611   $output_vars .= file_contents ('mans-vars',
3612                                  new Automake::Location,
3613                                  MANS => "@mans");
3614
3615   push (@all, '$(MANS)')
3616     unless option 'no-installman';
3617 }
3618
3619 # Handle DATA variables.
3620 sub handle_data
3621 {
3622     &am_install_var ('-noextra', '-candist', 'data', 'DATA',
3623                      'data', 'dataroot', 'doc', 'dvi', 'html', 'pdf',
3624                      'ps', 'sysconf', 'sharedstate', 'localstate',
3625                      'pkgdata', 'lisp', 'noinst', 'check');
3626 }
3627
3628 # Handle TAGS.
3629 sub handle_tags
3630 {
3631     my @config;
3632     foreach my $spec (@config_headers)
3633       {
3634         my ($out, @ins) = split_config_file_spec ($spec);
3635         foreach my $in (@ins)
3636           {
3637             # If the config header source is in this directory,
3638             # require it.
3639             push @config, basename ($in)
3640               if $relative_dir eq dirname ($in);
3641            }
3642       }
3643
3644     define_variable ('am__tagged_files',
3645                      '$(HEADERS) $(SOURCES) $(TAGS_FILES) $(LISP)'
3646                      . "@config", INTERNAL);
3647
3648     my @tag_deps = ();
3649     my @ctag_deps = ();
3650     my @cscope_deps = ();
3651     if (var ('SUBDIRS'))
3652     {
3653         $output_rules .= ("tags-recursive:\n"
3654                           . "\tlist='\$(SUBDIRS)'; for subdir in \$\$list; do \\\n"
3655                           # Never fail here if a subdir fails; it
3656                           # isn't important.
3657                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3658                           . " && \$(MAKE) \$(AM_MAKEFLAGS) tags); \\\n"
3659                           . "\tdone\n");
3660         push (@tag_deps, 'tags-recursive');
3661         &depend ('.PHONY', 'tags-recursive');
3662         &depend ('.MAKE', 'tags-recursive');
3663
3664         $output_rules .= ("ctags-recursive:\n"
3665                           . "\tlist='\$(SUBDIRS)'; for subdir in \$\$list; do \\\n"
3666                           # Never fail here if a subdir fails; it
3667                           # isn't important.
3668                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3669                           . " && \$(MAKE) \$(AM_MAKEFLAGS) ctags); \\\n"
3670                           . "\tdone\n");
3671         push (@ctag_deps, 'ctags-recursive');
3672         &depend ('.PHONY', 'ctags-recursive');
3673         &depend ('.MAKE', 'ctags-recursive');
3674
3675         $output_rules .= ("cscopelist-recursive:\n"
3676                           . "\tlist='\$(SUBDIRS)'; for subdir in \$\$list; do \\\n"
3677                           # Never fail here if a subdir fails; it
3678                           # isn't important.
3679                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3680                           . " && \$(MAKE) \$(AM_MAKEFLAGS) cscopelist); \\\n"
3681                           . "\tdone\n");
3682         push (@cscope_deps, 'cscopelist-recursive');
3683         &depend ('.PHONY', 'cscopelist-recursive');
3684         &depend ('.MAKE', 'cscopelist-recursive');
3685     }
3686
3687     if (rvar('am__tagged_files')->value_as_list_recursive
3688           || var ('ETAGS_ARGS') || @tag_deps)
3689     {
3690         $output_rules .= &file_contents ('tags',
3691                                          new Automake::Location,
3692                                          TAGSDIRS  => "@tag_deps",
3693                                          CTAGSDIRS => "@ctag_deps",
3694                                          CSCOPEDIRS => "@cscope_deps");
3695
3696         set_seen 'TAGS_DEPENDENCIES';
3697     }
3698     elsif (reject_var ('TAGS_DEPENDENCIES',
3699                        "it doesn't make sense to define 'TAGS_DEPENDENCIES'"
3700                        . " without\nsources or 'ETAGS_ARGS'"))
3701     {
3702     }
3703     else
3704     {
3705         # Every Makefile must define some sort of TAGS rule.
3706         # Otherwise, it would be possible for a top-level "make TAGS"
3707         # to fail because some subdirectory failed.
3708         $output_rules .= "tags: TAGS\nTAGS:\n\n";
3709         # Ditto ctags and cscope.
3710         $output_rules .= "ctags: CTAGS\nCTAGS:\n\n";
3711         $output_rules .= "cscope cscopelist:\n\n";
3712     }
3713 }
3714
3715
3716 # user_phony_rule ($NAME)
3717 # -----------------------
3718 # Return false if rule $NAME does not exist.  Otherwise,
3719 # declare it as phony, complete its definition (in case it is
3720 # conditional), and return its Automake::Rule instance.
3721 sub user_phony_rule ($)
3722 {
3723   my ($name) = @_;
3724   my $rule = rule $name;
3725   if ($rule)
3726     {
3727       depend ('.PHONY', $name);
3728       # Define $NAME in all condition where it is not already defined,
3729       # so that it is always OK to depend on $NAME.
3730       for my $c ($rule->not_always_defined_in_cond (TRUE)->conds)
3731         {
3732           Automake::Rule::define ($name, 'internal', RULE_AUTOMAKE,
3733                                   $c, INTERNAL);
3734           $output_rules .= $c->subst_string . "$name:\n";
3735         }
3736     }
3737   return $rule;
3738 }
3739
3740
3741 # handle_dist
3742 # -----------
3743 # Handle 'dist' target.
3744 sub handle_dist ()
3745 {
3746   # Substitutions for distdir.am
3747   my %transform;
3748
3749   # Define DIST_SUBDIRS.  This must always be done, regardless of the
3750   # no-dist setting: target like 'distclean' or 'maintainer-clean' use it.
3751   my $subdirs = var ('SUBDIRS');
3752   if ($subdirs)
3753     {
3754       # If SUBDIRS is conditionally defined, then set DIST_SUBDIRS
3755       # to all possible directories, and use it.  If DIST_SUBDIRS is
3756       # defined, just use it.
3757
3758       # Note that we check DIST_SUBDIRS first on purpose, so that
3759       # we don't call has_conditional_contents for now reason.
3760       # (In the past one project used so many conditional subdirectories
3761       # that calling has_conditional_contents on SUBDIRS caused
3762       # automake to grow to 150Mb -- this should not happen with
3763       # the current implementation of has_conditional_contents,
3764       # but it's more efficient to avoid the call anyway.)
3765       if (var ('DIST_SUBDIRS'))
3766         {
3767         }
3768       elsif ($subdirs->has_conditional_contents)
3769         {
3770           define_pretty_variable
3771             ('DIST_SUBDIRS', TRUE, INTERNAL,
3772              uniq ($subdirs->value_as_list_recursive));
3773         }
3774       else
3775         {
3776           # We always define this because that is what 'distclean'
3777           # wants.
3778           define_pretty_variable ('DIST_SUBDIRS', TRUE, INTERNAL,
3779                                   '$(SUBDIRS)');
3780         }
3781     }
3782
3783   # The remaining definitions are only required when a dist target is used.
3784   return if option 'no-dist';
3785
3786   # At least one of the archive formats must be enabled.
3787   if ($relative_dir eq '.')
3788     {
3789       my $archive_defined = option 'no-dist-gzip' ? 0 : 1;
3790       $archive_defined ||=
3791         grep { option "dist-$_" } qw(shar zip tarZ bzip2 lzip lzma xz);
3792       error (option 'no-dist-gzip',
3793              "no-dist-gzip specified but no dist-* specified,\n"
3794              . "at least one archive format must be enabled")
3795         unless $archive_defined;
3796     }
3797
3798   # Look for common files that should be included in distribution.
3799   # If the aux dir is set, and it does not have a Makefile.am, then
3800   # we check for these files there as well.
3801   my $check_aux = 0;
3802   if ($relative_dir eq '.'
3803       && $config_aux_dir_set_in_configure_ac)
3804     {
3805       if (! &is_make_dir ($config_aux_dir))
3806         {
3807           $check_aux = 1;
3808         }
3809     }
3810   foreach my $cfile (@common_files)
3811     {
3812       if (dir_has_case_matching_file ($relative_dir, $cfile)
3813           # The file might be absent, but if it can be built it's ok.
3814           || rule $cfile)
3815         {
3816           &push_dist_common ($cfile);
3817         }
3818
3819       # Don't use 'elsif' here because a file might meaningfully
3820       # appear in both directories.
3821       if ($check_aux && dir_has_case_matching_file ($config_aux_dir, $cfile))
3822         {
3823           &push_dist_common ("$config_aux_dir/$cfile")
3824         }
3825     }
3826
3827   # We might copy elements from $configure_dist_common to
3828   # %dist_common if we think we need to.  If the file appears in our
3829   # directory, we would have discovered it already, so we don't
3830   # check that.  But if the file is in a subdir without a Makefile,
3831   # we want to distribute it here if we are doing '.'.  Ugly!
3832   # Also, in some corner cases, it's possible that the following code
3833   # will cause the same file to appear in the $(DIST_COMMON) variables
3834   # of two distinct Makefiles; but this is not a problem, since the
3835   # 'distdir' target in 'lib/am/distdir.am' can deal with the same
3836   # file being distributed multiple times.
3837   # See also automake bug#9651.
3838   if ($relative_dir eq '.')
3839     {
3840       foreach my $file (split (' ' , $configure_dist_common))
3841         {
3842           my $dir = dirname ($file);
3843           push_dist_common ($file)
3844             if ($dir eq '.' || ! is_make_dir ($dir));
3845         }
3846     }
3847
3848   # Files to distributed.  Don't use ->value_as_list_recursive
3849   # as it recursively expands '$(dist_pkgdata_DATA)' etc.
3850   my @dist_common = split (' ', rvar ('DIST_COMMON')->variable_value);
3851   @dist_common = uniq @dist_common;
3852   variable_delete 'DIST_COMMON';
3853   define_pretty_variable ('DIST_COMMON', TRUE, INTERNAL, @dist_common);
3854
3855   # Now that we've processed DIST_COMMON, disallow further attempts
3856   # to set it.
3857   $handle_dist_run = 1;
3858
3859   # Scan EXTRA_DIST to see if we need to distribute anything from a
3860   # subdir.  If so, add it to the list.  I didn't want to do this
3861   # originally, but there were so many requests that I finally
3862   # relented.
3863   my $extra_dist = var ('EXTRA_DIST');
3864
3865   $transform{'DISTCHECK-HOOK'} = !! rule 'distcheck-hook';
3866   $transform{'GETTEXT'} = $seen_gettext && !$seen_gettext_external;
3867
3868   # If the target 'dist-hook' exists, make sure it is run.  This
3869   # allows users to do random weird things to the distribution
3870   # before it is packaged up.
3871   push (@dist_targets, 'dist-hook')
3872     if user_phony_rule 'dist-hook';
3873   $transform{'DIST-TARGETS'} = join (' ', @dist_targets);
3874
3875   my $flm = option ('filename-length-max');
3876   my $filename_filter = $flm ? '.' x $flm->[1] : '';
3877
3878   $output_rules .= &file_contents ('distdir',
3879                                    new Automake::Location,
3880                                    %transform,
3881                                    FILENAME_FILTER => $filename_filter);
3882 }
3883
3884
3885 # check_directory ($NAME, $WHERE [, $RELATIVE_DIR = "."])
3886 # -------------------------------------------------------
3887 # Ensure $NAME is a directory (in $RELATIVE_DIR), and that it uses a sane
3888 # name.  Use $WHERE as a location in the diagnostic, if any.
3889 sub check_directory ($$;$)
3890 {
3891   my ($dir, $where, $reldir) = @_;
3892   $reldir = '.' unless defined $reldir;
3893
3894   error $where, "required directory $reldir/$dir does not exist"
3895     unless -d "$reldir/$dir";
3896
3897   # If an 'obj/' directory exists, BSD make will enter it before
3898   # reading 'Makefile'.  Hence the 'Makefile' in the current directory
3899   # will not be read.
3900   #
3901   #  % cat Makefile
3902   #  all:
3903   #          echo Hello
3904   #  % cat obj/Makefile
3905   #  all:
3906   #          echo World
3907   #  % make      # GNU make
3908   #  echo Hello
3909   #  Hello
3910   #  % pmake     # BSD make
3911   #  echo World
3912   #  World
3913   msg ('portability', $where,
3914        "naming a subdirectory 'obj' causes troubles with BSD make")
3915     if $dir eq 'obj';
3916
3917   # 'aux' is probably the most important of the following forbidden name,
3918   # since it's tempting to use it as an AC_CONFIG_AUX_DIR.
3919   msg ('portability', $where,
3920        "name '$dir' is reserved on W32 and DOS platforms")
3921     if grep (/^\Q$dir\E$/i, qw/aux lpt1 lpt2 lpt3 com1 com2 com3 com4 con prn/);
3922 }
3923
3924 # check_directories_in_var ($VARIABLE)
3925 # ------------------------------------
3926 # Recursively check all items in variables $VARIABLE as directories
3927 sub check_directories_in_var ($)
3928 {
3929   my ($var) = @_;
3930   $var->traverse_recursively
3931     (sub
3932      {
3933        my ($var, $val, $cond, $full_cond) = @_;
3934        check_directory ($val, $var->rdef ($cond)->location, $relative_dir);
3935        return ();
3936      },
3937      undef,
3938      skip_ac_subst => 1);
3939 }
3940
3941 # &handle_subdirs ()
3942 # ------------------
3943 # Handle subdirectories.
3944 sub handle_subdirs ()
3945 {
3946   my $subdirs = var ('SUBDIRS');
3947   return
3948     unless $subdirs;
3949
3950   check_directories_in_var $subdirs;
3951
3952   my $dsubdirs = var ('DIST_SUBDIRS');
3953   check_directories_in_var $dsubdirs
3954     if $dsubdirs;
3955
3956   $output_rules .= &file_contents ('subdirs', new Automake::Location);
3957   rvar ('RECURSIVE_TARGETS')->rdef (TRUE)->{'pretty'} = VAR_SORTED; # Gross!
3958 }
3959
3960
3961 # ($REGEN, @DEPENDENCIES)
3962 # &scan_aclocal_m4
3963 # ----------------
3964 # If aclocal.m4 creation is automated, return the list of its dependencies.
3965 sub scan_aclocal_m4 ()
3966 {
3967   my $regen_aclocal = 0;
3968
3969   set_seen 'CONFIG_STATUS_DEPENDENCIES';
3970   set_seen 'CONFIGURE_DEPENDENCIES';
3971
3972   if (-f 'aclocal.m4')
3973     {
3974       &define_variable ("ACLOCAL_M4", '$(top_srcdir)/aclocal.m4', INTERNAL);
3975
3976       my $aclocal = new Automake::XFile "< aclocal.m4";
3977       my $line = $aclocal->getline;
3978       $regen_aclocal = $line =~ 'generated automatically by aclocal';
3979     }
3980
3981   my @ac_deps = ();
3982
3983   if (set_seen ('ACLOCAL_M4_SOURCES'))
3984     {
3985       push (@ac_deps, '$(ACLOCAL_M4_SOURCES)');
3986       msg_var ('obsolete', 'ACLOCAL_M4_SOURCES',
3987                "'ACLOCAL_M4_SOURCES' is obsolete.\n"
3988                . "It should be safe to simply remove it");
3989     }
3990
3991   # Note that it might be possible that aclocal.m4 doesn't exist but
3992   # should be auto-generated.  This case probably isn't very
3993   # important.
3994
3995   return ($regen_aclocal, @ac_deps);
3996 }
3997
3998
3999 # Helper function for substitute_ac_subst_variables.
4000 sub substitute_ac_subst_variables_worker($)
4001 {
4002   my ($token) = @_;
4003   return "\@$token\@" if var $token;
4004   return "\${$token\}";
4005 }
4006
4007 # substitute_ac_subst_variables ($TEXT)
4008 # -------------------------------------
4009 # Replace any occurrence of ${FOO} in $TEXT by @FOO@ if FOO is an AC_SUBST
4010 # variable.
4011 sub substitute_ac_subst_variables ($)
4012 {
4013   my ($text) = @_;
4014   $text =~ s/\${([^ \t=:+{}]+)}/&substitute_ac_subst_variables_worker ($1)/ge;
4015   return $text;
4016 }
4017
4018 # @DEPENDENCIES
4019 # &prepend_srcdir (@INPUTS)
4020 # -------------------------
4021 # Prepend $(srcdir) or $(top_srcdir) to all @INPUTS.  The idea is that
4022 # if an input file has a directory part the same as the current
4023 # directory, then the directory part is simply replaced by $(srcdir).
4024 # But if the directory part is different, then $(top_srcdir) is
4025 # prepended.
4026 sub prepend_srcdir (@)
4027 {
4028   my (@inputs) = @_;
4029   my @newinputs;
4030
4031   foreach my $single (@inputs)
4032     {
4033       if (dirname ($single) eq $relative_dir)
4034         {
4035           push (@newinputs, '$(srcdir)/' . basename ($single));
4036         }
4037       else
4038         {
4039           push (@newinputs, '$(top_srcdir)/' . $single);
4040         }
4041     }
4042   return @newinputs;
4043 }
4044
4045 # @DEPENDENCIES
4046 # rewrite_inputs_into_dependencies ($OUTPUT, @INPUTS)
4047 # ---------------------------------------------------
4048 # Compute a list of dependencies appropriate for the rebuild
4049 # rule of
4050 #   AC_CONFIG_FILES($OUTPUT:$INPUT[0]:$INPUTS[1]:...)
4051 # Also distribute $INPUTs which are not built by another AC_CONFIG_FOOs.
4052 sub rewrite_inputs_into_dependencies ($@)
4053 {
4054   my ($file, @inputs) = @_;
4055   my @res = ();
4056
4057   for my $i (@inputs)
4058     {
4059       # We cannot create dependencies on shell variables.
4060       next if (substitute_ac_subst_variables $i) =~ /\$/;
4061
4062       if (exists $ac_config_files_location{$i} && $i ne $file)
4063         {
4064           my $di = dirname $i;
4065           if ($di eq $relative_dir)
4066             {
4067               $i = basename $i;
4068             }
4069           # In the top-level Makefile we do not use $(top_builddir), because
4070           # we are already there, and since the targets are built without
4071           # a $(top_builddir), it helps BSD Make to match them with
4072           # dependencies.
4073           elsif ($relative_dir ne '.')
4074             {
4075               $i = '$(top_builddir)/' . $i;
4076             }
4077         }
4078       else
4079         {
4080           msg ('error', $ac_config_files_location{$file},
4081                "required file '$i' not found")
4082             unless $i =~ /\$/ || exists $output_files{$i} || -f $i;
4083           ($i) = prepend_srcdir ($i);
4084           push_dist_common ($i);
4085         }
4086       push @res, $i;
4087     }
4088   return @res;
4089 }
4090
4091
4092
4093 # &handle_configure ($MAKEFILE_AM, $MAKEFILE_IN, $MAKEFILE, @INPUTS)
4094 # ------------------------------------------------------------------
4095 # Handle remaking and configure stuff.
4096 # We need the name of the input file, to do proper remaking rules.
4097 sub handle_configure ($$$@)
4098 {
4099   my ($makefile_am, $makefile_in, $makefile, @inputs) = @_;
4100
4101   prog_error 'empty @inputs'
4102     unless @inputs;
4103
4104   my ($rel_makefile_am, $rel_makefile_in) = prepend_srcdir ($makefile_am,
4105                                                             $makefile_in);
4106   my $rel_makefile = basename $makefile;
4107
4108   my $colon_infile = ':' . join (':', @inputs);
4109   $colon_infile = '' if $colon_infile eq ":$makefile.in";
4110   my @rewritten = rewrite_inputs_into_dependencies ($makefile, @inputs);
4111   my ($regen_aclocal_m4, @aclocal_m4_deps) = scan_aclocal_m4;
4112   define_pretty_variable ('am__aclocal_m4_deps', TRUE, INTERNAL,
4113                           @configure_deps, @aclocal_m4_deps,
4114                           '$(top_srcdir)/' . $configure_ac);
4115   my @configuredeps = ('$(am__aclocal_m4_deps)', '$(CONFIGURE_DEPENDENCIES)');
4116   push @configuredeps, '$(ACLOCAL_M4)' if -f 'aclocal.m4';
4117   define_pretty_variable ('am__configure_deps', TRUE, INTERNAL,
4118                           @configuredeps);
4119
4120   my $automake_options = '--' . $strictness_name .
4121                          (global_option 'no-dependencies' ? ' --ignore-deps' : '');
4122
4123   $output_rules .= file_contents
4124     ('configure',
4125      new Automake::Location,
4126      MAKEFILE              => $rel_makefile,
4127      'MAKEFILE-DEPS'       => "@rewritten",
4128      'CONFIG-MAKEFILE'     => ($relative_dir eq '.') ? '$@' : '$(subdir)/$@',
4129      'MAKEFILE-IN'         => $rel_makefile_in,
4130      'HAVE-MAKEFILE-IN-DEPS' => (@include_stack > 0),
4131      'MAKEFILE-IN-DEPS'    => "@include_stack",
4132      'MAKEFILE-AM'         => $rel_makefile_am,
4133      'AUTOMAKE-OPTIONS'    => $automake_options,
4134      'MAKEFILE-AM-SOURCES' => "$makefile$colon_infile",
4135      'REGEN-ACLOCAL-M4'    => $regen_aclocal_m4,
4136      VERBOSE               => verbose_flag ('GEN'));
4137
4138   if ($relative_dir eq '.')
4139     {
4140       &push_dist_common ('acconfig.h')
4141         if -f 'acconfig.h';
4142     }
4143
4144   # If we have a configure header, require it.
4145   my $hdr_index = 0;
4146   my @distclean_config;
4147   foreach my $spec (@config_headers)
4148     {
4149       $hdr_index += 1;
4150       # $CONFIG_H_PATH: config.h from top level.
4151       my ($config_h_path, @ins) = split_config_file_spec ($spec);
4152       my $config_h_dir = dirname ($config_h_path);
4153
4154       # If the header is in the current directory we want to build
4155       # the header here.  Otherwise, if we're at the topmost
4156       # directory and the header's directory doesn't have a
4157       # Makefile, then we also want to build the header.
4158       if ($relative_dir eq $config_h_dir
4159           || ($relative_dir eq '.' && ! &is_make_dir ($config_h_dir)))
4160         {
4161           my ($cn_sans_dir, $stamp_dir);
4162           if ($relative_dir eq $config_h_dir)
4163             {
4164               $cn_sans_dir = basename ($config_h_path);
4165               $stamp_dir = '';
4166             }
4167           else
4168             {
4169               $cn_sans_dir = $config_h_path;
4170               if ($config_h_dir eq '.')
4171                 {
4172                   $stamp_dir = '';
4173                 }
4174               else
4175                 {
4176                   $stamp_dir = $config_h_dir . '/';
4177                 }
4178             }
4179
4180           # This will also distribute all inputs.
4181           @ins = rewrite_inputs_into_dependencies ($config_h_path, @ins);
4182
4183           # Cannot define rebuild rules for filenames with shell variables.
4184           next if (substitute_ac_subst_variables $config_h_path) =~ /\$/;
4185
4186           # Header defined in this directory.
4187           my @files;
4188           if (-f $config_h_path . '.top')
4189             {
4190               push (@files, "$cn_sans_dir.top");
4191             }
4192           if (-f $config_h_path . '.bot')
4193             {
4194               push (@files, "$cn_sans_dir.bot");
4195             }
4196
4197           push_dist_common (@files);
4198
4199           # For now, acconfig.h can only appear in the top srcdir.
4200           if (-f 'acconfig.h')
4201             {
4202               push (@files, '$(top_srcdir)/acconfig.h');
4203             }
4204
4205           my $stamp = "${stamp_dir}stamp-h${hdr_index}";
4206           $output_rules .=
4207             file_contents ('remake-hdr',
4208                            new Automake::Location,
4209                            FILES            => "@files",
4210                            CONFIG_H         => $cn_sans_dir,
4211                            CONFIG_HIN       => $ins[0],
4212                            CONFIG_H_DEPS    => "@ins",
4213                            CONFIG_H_PATH    => $config_h_path,
4214                            STAMP            => "$stamp");
4215
4216           push @distclean_config, $cn_sans_dir, $stamp;
4217         }
4218     }
4219
4220   $output_rules .= file_contents ('clean-hdr',
4221                                   new Automake::Location,
4222                                   FILES => "@distclean_config")
4223     if @distclean_config;
4224
4225   # Distribute and define mkinstalldirs only if it is already present
4226   # in the package, for backward compatibility (some people may still
4227   # use $(mkinstalldirs)).
4228   my $mkidpath = "$config_aux_dir/mkinstalldirs";
4229   if (-f $mkidpath)
4230     {
4231       # Use require_file so that any existing script gets updated
4232       # by --force-missing.
4233       require_conf_file ($mkidpath, FOREIGN, 'mkinstalldirs');
4234       define_variable ('mkinstalldirs',
4235                        "\$(SHELL) $am_config_aux_dir/mkinstalldirs", INTERNAL);
4236     }
4237   else
4238     {
4239       # Use $(install_sh), not $(MKDIR_P) because the latter requires
4240       # at least one argument, and $(mkinstalldirs) used to work
4241       # even without arguments (e.g. $(mkinstalldirs) $(conditional_dir)).
4242       define_variable ('mkinstalldirs', '$(install_sh) -d', INTERNAL);
4243     }
4244
4245   reject_var ('CONFIG_HEADER',
4246               "'CONFIG_HEADER' is an anachronism; now determined "
4247               . "automatically\nfrom '$configure_ac'");
4248
4249   my @config_h;
4250   foreach my $spec (@config_headers)
4251     {
4252       my ($out, @ins) = split_config_file_spec ($spec);
4253       # Generate CONFIG_HEADER define.
4254       if ($relative_dir eq dirname ($out))
4255         {
4256           push @config_h, basename ($out);
4257         }
4258       else
4259         {
4260           push @config_h, "\$(top_builddir)/$out";
4261         }
4262     }
4263   define_variable ("CONFIG_HEADER", "@config_h", INTERNAL)
4264     if @config_h;
4265
4266   # Now look for other files in this directory which must be remade
4267   # by config.status, and generate rules for them.
4268   my @actual_other_files = ();
4269   # These get cleaned only in a VPATH build.
4270   my @actual_other_vpath_files = ();
4271   foreach my $lfile (@other_input_files)
4272     {
4273       my $file;
4274       my @inputs;
4275       if ($lfile =~ /^([^:]*):(.*)$/)
4276         {
4277           # This is the ":" syntax of AC_OUTPUT.
4278           $file = $1;
4279           @inputs = split (':', $2);
4280         }
4281       else
4282         {
4283           # Normal usage.
4284           $file = $lfile;
4285           @inputs = $file . '.in';
4286         }
4287
4288       # Automake files should not be stored in here, but in %MAKE_LIST.
4289       prog_error ("$lfile in \@other_input_files\n"
4290                   . "\@other_input_files = (@other_input_files)")
4291         if -f $file . '.am';
4292
4293       my $local = basename ($file);
4294
4295       # We skip files that aren't in this directory.  However, if
4296       # the file's directory does not have a Makefile, and we are
4297       # currently doing '.', then we create a rule to rebuild the
4298       # file in the subdir.
4299       my $fd = dirname ($file);
4300       if ($fd ne $relative_dir)
4301         {
4302           if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4303             {
4304               $local = $file;
4305             }
4306           else
4307             {
4308               next;
4309             }
4310         }
4311
4312       my @rewritten_inputs = rewrite_inputs_into_dependencies ($file, @inputs);
4313
4314       # Cannot output rules for shell variables.
4315       next if (substitute_ac_subst_variables $local) =~ /\$/;
4316
4317       my $condstr = '';
4318       my $cond = $ac_config_files_condition{$lfile};
4319       if (defined $cond)
4320         {
4321           $condstr = $cond->subst_string;
4322           Automake::Rule::define ($local, $configure_ac, RULE_AUTOMAKE, $cond,
4323                                   $ac_config_files_location{$file});
4324         }
4325       $output_rules .= ($condstr . $local . ': '
4326                         . '$(top_builddir)/config.status '
4327                         . "@rewritten_inputs\n"
4328                         . $condstr . "\t"
4329                         . 'cd $(top_builddir) && '
4330                         . '$(SHELL) ./config.status '
4331                         . ($relative_dir eq '.' ? '' : '$(subdir)/')
4332                         . '$@'
4333                         . "\n");
4334       push (@actual_other_files, $local);
4335     }
4336
4337   # For links we should clean destinations and distribute sources.
4338   foreach my $spec (@config_links)
4339     {
4340       my ($link, $file) = split /:/, $spec;
4341       # Some people do AC_CONFIG_LINKS($computed).  We only handle
4342       # the DEST:SRC form.
4343       next unless $file;
4344       my $where = $ac_config_files_location{$link};
4345
4346       # Skip destinations that contain shell variables.
4347       if ((substitute_ac_subst_variables $link) !~ /\$/)
4348         {
4349           # We skip links that aren't in this directory.  However, if
4350           # the link's directory does not have a Makefile, and we are
4351           # currently doing '.', then we add the link to CONFIG_CLEAN_FILES
4352           # in '.'s Makefile.in.
4353           my $local = basename ($link);
4354           my $fd = dirname ($link);
4355           if ($fd ne $relative_dir)
4356             {
4357               if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4358                 {
4359                   $local = $link;
4360                 }
4361               else
4362                 {
4363                   $local = undef;
4364                 }
4365             }
4366           if ($file ne $link)
4367             {
4368               push @actual_other_files, $local if $local;
4369             }
4370           else
4371             {
4372               push @actual_other_vpath_files, $local if $local;
4373             }
4374         }
4375
4376       # Do not process sources that contain shell variables.
4377       if ((substitute_ac_subst_variables $file) !~ /\$/)
4378         {
4379           my $fd = dirname ($file);
4380
4381           # We distribute files that are in this directory.
4382           # At the top-level ('.') we also distribute files whose
4383           # directory does not have a Makefile.
4384           if (($fd eq $relative_dir)
4385               || ($relative_dir eq '.' && ! &is_make_dir ($fd)))
4386             {
4387               # The following will distribute $file as a side-effect when
4388               # it is appropriate (i.e., when $file is not already an output).
4389               # We do not need the result, just the side-effect.
4390               rewrite_inputs_into_dependencies ($link, $file);
4391             }
4392         }
4393     }
4394
4395   # These files get removed by "make distclean".
4396   define_pretty_variable ('CONFIG_CLEAN_FILES', TRUE, INTERNAL,
4397                           @actual_other_files);
4398   define_pretty_variable ('CONFIG_CLEAN_VPATH_FILES', TRUE, INTERNAL,
4399                           @actual_other_vpath_files);
4400 }
4401
4402 # Handle C headers.
4403 sub handle_headers
4404 {
4405     my @r = &am_install_var ('-defaultdist', 'header', 'HEADERS', 'include',
4406                              'oldinclude', 'pkginclude',
4407                              'noinst', 'check');
4408     foreach (@r)
4409     {
4410       next unless $_->[1] =~ /\..*$/;
4411       &saw_extension ($&);
4412     }
4413 }
4414
4415 sub handle_gettext
4416 {
4417   return if ! $seen_gettext || $relative_dir ne '.';
4418
4419   my $subdirs = var 'SUBDIRS';
4420
4421   if (! $subdirs)
4422     {
4423       err_ac "AM_GNU_GETTEXT used but SUBDIRS not defined";
4424       return;
4425     }
4426
4427   # Perform some sanity checks to help users get the right setup.
4428   # We disable these tests when po/ doesn't exist in order not to disallow
4429   # unusual gettext setups.
4430   #
4431   # Bruno Haible:
4432   # | The idea is:
4433   # |
4434   # |  1) If a package doesn't have a directory po/ at top level, it
4435   # |     will likely have multiple po/ directories in subpackages.
4436   # |
4437   # |  2) It is useful to warn for the absence of intl/ if AM_GNU_GETTEXT
4438   # |     is used without 'external'. It is also useful to warn for the
4439   # |     presence of intl/ if AM_GNU_GETTEXT([external]) is used. Both
4440   # |     warnings apply only to the usual layout of packages, therefore
4441   # |     they should both be disabled if no po/ directory is found at
4442   # |     top level.
4443
4444   if (-d 'po')
4445     {
4446       my @subdirs = $subdirs->value_as_list_recursive;
4447
4448       msg_var ('syntax', $subdirs,
4449                "AM_GNU_GETTEXT used but 'po' not in SUBDIRS")
4450         if ! grep ($_ eq 'po', @subdirs);
4451
4452       # intl/ is not required when AM_GNU_GETTEXT is called with the
4453       # 'external' option and AM_GNU_GETTEXT_INTL_SUBDIR is not called.
4454       msg_var ('syntax', $subdirs,
4455                "AM_GNU_GETTEXT used but 'intl' not in SUBDIRS")
4456         if (! ($seen_gettext_external && ! $seen_gettext_intl)
4457             && ! grep ($_ eq 'intl', @subdirs));
4458
4459       # intl/ should not be used with AM_GNU_GETTEXT([external]), except
4460       # if AM_GNU_GETTEXT_INTL_SUBDIR is called.
4461       msg_var ('syntax', $subdirs,
4462                "'intl' should not be in SUBDIRS when "
4463                . "AM_GNU_GETTEXT([external]) is used")
4464         if ($seen_gettext_external && ! $seen_gettext_intl
4465             && grep ($_ eq 'intl', @subdirs));
4466     }
4467
4468   require_file ($ac_gettext_location, GNU, 'ABOUT-NLS');
4469 }
4470
4471 # Handle footer elements.
4472 sub handle_footer
4473 {
4474     reject_rule ('.SUFFIXES',
4475                  "use variable 'SUFFIXES', not target '.SUFFIXES'");
4476
4477     # Note: AIX 4.1 /bin/make will fail if any suffix rule appears
4478     # before .SUFFIXES.  So we make sure that .SUFFIXES appears before
4479     # anything else, by sticking it right after the default: target.
4480     $output_header .= ".SUFFIXES:\n";
4481     my $suffixes = var 'SUFFIXES';
4482     my @suffixes = Automake::Rule::suffixes;
4483     if (@suffixes || $suffixes)
4484     {
4485         # Make sure SUFFIXES has unique elements.  Sort them to ensure
4486         # the output remains consistent.  However, $(SUFFIXES) is
4487         # always at the start of the list, unsorted.  This is done
4488         # because make will choose rules depending on the ordering of
4489         # suffixes, and this lets the user have some control.  Push
4490         # actual suffixes, and not $(SUFFIXES).  Some versions of make
4491         # do not like variable substitutions on the .SUFFIXES line.
4492         my @user_suffixes = ($suffixes
4493                              ? $suffixes->value_as_list_recursive : ());
4494
4495         my %suffixes = map { $_ => 1 } @suffixes;
4496         delete @suffixes{@user_suffixes};
4497
4498         $output_header .= (".SUFFIXES: "
4499                            . join (' ', @user_suffixes, sort keys %suffixes)
4500                            . "\n");
4501     }
4502
4503     $output_trailer .= file_contents ('footer', new Automake::Location);
4504 }
4505
4506
4507 # Generate 'make install' rules.
4508 sub handle_install ()
4509 {
4510   $output_rules .= &file_contents
4511     ('install',
4512      new Automake::Location,
4513      maybe_BUILT_SOURCES => (set_seen ('BUILT_SOURCES')
4514                              ? (" \$(BUILT_SOURCES)\n"
4515                                 . "\t\$(MAKE) \$(AM_MAKEFLAGS)")
4516                              : ''),
4517      'installdirs-local' => (user_phony_rule 'installdirs-local'
4518                              ? ' installdirs-local' : ''),
4519      am__installdirs => variable_value ('am__installdirs') || '');
4520 }
4521
4522
4523 # Deal with all and all-am.
4524 sub handle_all ($)
4525 {
4526     my ($makefile) = @_;
4527
4528     # Output 'all-am'.
4529
4530     # Put this at the beginning for the sake of non-GNU makes.  This
4531     # is still wrong if these makes can run parallel jobs.  But it is
4532     # right enough.
4533     unshift (@all, basename ($makefile));
4534
4535     foreach my $spec (@config_headers)
4536       {
4537         my ($out, @ins) = split_config_file_spec ($spec);
4538         push (@all, basename ($out))
4539           if dirname ($out) eq $relative_dir;
4540       }
4541
4542     # Install 'all' hooks.
4543     push (@all, "all-local")
4544       if user_phony_rule "all-local";
4545
4546     &pretty_print_rule ("all-am:", "\t\t", @all);
4547     &depend ('.PHONY', 'all-am', 'all');
4548
4549
4550     # Output 'all'.
4551
4552     my @local_headers = ();
4553     push @local_headers, '$(BUILT_SOURCES)'
4554       if var ('BUILT_SOURCES');
4555     foreach my $spec (@config_headers)
4556       {
4557         my ($out, @ins) = split_config_file_spec ($spec);
4558         push @local_headers, basename ($out)
4559           if dirname ($out) eq $relative_dir;
4560       }
4561
4562     if (@local_headers)
4563       {
4564         # We need to make sure config.h is built before we recurse.
4565         # We also want to make sure that built sources are built
4566         # before any ordinary 'all' targets are run.  We can't do this
4567         # by changing the order of dependencies to the "all" because
4568         # that breaks when using parallel makes.  Instead we handle
4569         # things explicitly.
4570         $output_all .= ("all: @local_headers"
4571                         . "\n\t"
4572                         . '$(MAKE) $(AM_MAKEFLAGS) '
4573                         . (var ('SUBDIRS') ? 'all-recursive' : 'all-am')
4574                         . "\n\n");
4575         depend ('.MAKE', 'all');
4576       }
4577     else
4578       {
4579         $output_all .= "all: " . (var ('SUBDIRS')
4580                                   ? 'all-recursive' : 'all-am') . "\n\n";
4581       }
4582 }
4583
4584
4585 # &do_check_merge_target ()
4586 # -------------------------
4587 # Handle check merge target specially.
4588 sub do_check_merge_target ()
4589 {
4590   # Include user-defined local form of target.
4591   push @check_tests, 'check-local'
4592     if user_phony_rule 'check-local';
4593
4594   # The check target must depend on the local equivalent of
4595   # 'all', to ensure all the primary targets are built.  Then it
4596   # must build the local check rules.
4597   $output_rules .= "check-am: all-am\n";
4598   if (@check)
4599     {
4600       pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ", @check);
4601       depend ('.MAKE', 'check-am');
4602     }
4603
4604   if (@check_tests)
4605     {
4606       pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4607                          @check_tests);
4608       depend ('.MAKE', 'check-am');
4609     }
4610
4611   depend '.PHONY', 'check', 'check-am';
4612   # Handle recursion.  We have to honor BUILT_SOURCES like for 'all:'.
4613   $output_rules .= ("check: "
4614                     . (var ('BUILT_SOURCES')
4615                        ? "\$(BUILT_SOURCES)\n\t\$(MAKE) \$(AM_MAKEFLAGS) "
4616                        : '')
4617                     . (var ('SUBDIRS') ? 'check-recursive' : 'check-am')
4618                     . "\n");
4619   depend ('.MAKE', 'check')
4620     if var ('BUILT_SOURCES');
4621 }
4622
4623 # handle_clean ($MAKEFILE)
4624 # ------------------------
4625 # Handle all 'clean' targets.
4626 sub handle_clean ($)
4627 {
4628   my ($makefile) = @_;
4629
4630   # Clean the files listed in user variables if they exist.
4631   $clean_files{'$(MOSTLYCLEANFILES)'} = MOSTLY_CLEAN
4632     if var ('MOSTLYCLEANFILES');
4633   $clean_files{'$(CLEANFILES)'} = CLEAN
4634     if var ('CLEANFILES');
4635   $clean_files{'$(DISTCLEANFILES)'} = DIST_CLEAN
4636     if var ('DISTCLEANFILES');
4637   $clean_files{'$(MAINTAINERCLEANFILES)'} = MAINTAINER_CLEAN
4638     if var ('MAINTAINERCLEANFILES');
4639
4640   # Built sources are automatically removed by maintainer-clean.
4641   $clean_files{'$(BUILT_SOURCES)'} = MAINTAINER_CLEAN
4642     if var ('BUILT_SOURCES');
4643
4644   # Compute a list of "rm"s to run for each target.
4645   my %rms = (MOSTLY_CLEAN, [],
4646              CLEAN, [],
4647              DIST_CLEAN, [],
4648              MAINTAINER_CLEAN, []);
4649
4650   foreach my $file (keys %clean_files)
4651     {
4652       my $when = $clean_files{$file};
4653       prog_error 'invalid entry in %clean_files'
4654         unless exists $rms{$when};
4655
4656       my $rm = "rm -f $file";
4657       # If file is a variable, make sure when don't call 'rm -f' without args.
4658       $rm ="test -z \"$file\" || $rm"
4659         if ($file =~ /^\s*\$(\(.*\)|\{.*\})\s*$/);
4660
4661       push @{$rms{$when}}, "\t-$rm\n";
4662     }
4663
4664   $output_rules .= &file_contents
4665     ('clean',
4666      new Automake::Location,
4667      MOSTLYCLEAN_RMS      => join ('', sort @{$rms{&MOSTLY_CLEAN}}),
4668      CLEAN_RMS            => join ('', sort @{$rms{&CLEAN}}),
4669      DISTCLEAN_RMS        => join ('', sort @{$rms{&DIST_CLEAN}}),
4670      MAINTAINER_CLEAN_RMS => join ('', sort @{$rms{&MAINTAINER_CLEAN}}),
4671      MAKEFILE             => basename $makefile,
4672      );
4673 }
4674
4675
4676 # &target_cmp ($A, $B)
4677 # --------------------
4678 # Subroutine for &handle_factored_dependencies to let '.PHONY' and
4679 # other '.TARGETS' be last.
4680 sub target_cmp
4681 {
4682   return 0 if $a eq $b;
4683
4684   my $a1 = substr ($a, 0, 1);
4685   my $b1 = substr ($b, 0, 1);
4686   if ($a1 ne $b1)
4687     {
4688       return -1 if $b1 eq '.';
4689       return 1 if $a1 eq '.';
4690     }
4691   return $a cmp $b;
4692 }
4693
4694
4695 # &handle_factored_dependencies ()
4696 # --------------------------------
4697 # Handle everything related to gathered targets.
4698 sub handle_factored_dependencies
4699 {
4700   # Reject bad hooks.
4701   foreach my $utarg ('uninstall-data-local', 'uninstall-data-hook',
4702                      'uninstall-exec-local', 'uninstall-exec-hook',
4703                      'uninstall-dvi-local',
4704                      'uninstall-html-local',
4705                      'uninstall-info-local',
4706                      'uninstall-pdf-local',
4707                      'uninstall-ps-local')
4708     {
4709       my $x = $utarg;
4710       $x =~ s/-.*-/-/;
4711       reject_rule ($utarg, "use '$x', not '$utarg'");
4712     }
4713
4714   reject_rule ('install-local',
4715                "use 'install-data-local' or 'install-exec-local', "
4716                . "not 'install-local'");
4717
4718   reject_rule ('install-hook',
4719                "use 'install-data-hook' or 'install-exec-hook', "
4720                . "not 'install-hook'");
4721
4722   # Install the -local hooks.
4723   foreach (keys %dependencies)
4724     {
4725       # Hooks are installed on the -am targets.
4726       s/-am$// or next;
4727       depend ("$_-am", "$_-local")
4728         if user_phony_rule "$_-local";
4729     }
4730
4731   # Install the -hook hooks.
4732   # FIXME: Why not be as liberal as we are with -local hooks?
4733   foreach ('install-exec', 'install-data', 'uninstall')
4734     {
4735       if (user_phony_rule "$_-hook")
4736         {
4737           depend ('.MAKE', "$_-am");
4738           register_action("$_-am",
4739                           ("\t\@\$(NORMAL_INSTALL)\n"
4740                            . "\t\$(MAKE) \$(AM_MAKEFLAGS) $_-hook"));
4741         }
4742     }
4743
4744   # All the required targets are phony.
4745   depend ('.PHONY', keys %required_targets);
4746
4747   # Actually output gathered targets.
4748   foreach (sort target_cmp keys %dependencies)
4749     {
4750       # If there is nothing about this guy, skip it.
4751       next
4752         unless (@{$dependencies{$_}}
4753                 || $actions{$_}
4754                 || $required_targets{$_});
4755
4756       # Define gathered targets in undefined conditions.
4757       # FIXME: Right now we must handle .PHONY as an exception,
4758       # because people write things like
4759       #    .PHONY: myphonytarget
4760       # to append dependencies.  This would not work if Automake
4761       # refrained from defining its own .PHONY target as it does
4762       # with other overridden targets.
4763       # Likewise for '.MAKE'.
4764       my @undefined_conds = (TRUE,);
4765       if ($_ ne '.PHONY' && $_ ne '.MAKE')
4766         {
4767           @undefined_conds =
4768             Automake::Rule::define ($_, 'internal',
4769                                     RULE_AUTOMAKE, TRUE, INTERNAL);
4770         }
4771       my @uniq_deps = uniq (sort @{$dependencies{$_}});
4772       foreach my $cond (@undefined_conds)
4773         {
4774           my $condstr = $cond->subst_string;
4775           &pretty_print_rule ("$condstr$_:", "$condstr\t", @uniq_deps);
4776           $output_rules .= $actions{$_} if defined $actions{$_};
4777           $output_rules .= "\n";
4778         }
4779     }
4780 }
4781
4782
4783 # &handle_tests_dejagnu ()
4784 # ------------------------
4785 sub handle_tests_dejagnu
4786 {
4787     push (@check_tests, 'check-DEJAGNU');
4788     $output_rules .= file_contents ('dejagnu', new Automake::Location);
4789 }
4790
4791 sub handle_per_suffix_test
4792 {
4793   my ($test_suffix, %transform) = @_;
4794   my ($pfx, $generic, $am_exeext);
4795   if ($test_suffix eq '')
4796     {
4797       $pfx = '';
4798       $generic = 0;
4799       $am_exeext = 'FALSE';
4800     }
4801   else
4802     {
4803       prog_error ("test suffix '$test_suffix' lacks leading dot")
4804         unless $test_suffix =~ m/^\.(.*)/;
4805       $pfx = uc ($1) . '_';
4806       $generic = 1;
4807       $am_exeext = exists $configure_vars{'EXEEXT'} ? 'am__EXEEXT'
4808                                                     : 'FALSE';
4809     }
4810   # The "test driver" program, deputed to handle tests protocol used by
4811   # test scripts.  By default, it's assumed that no protocol is used, so
4812   # we fall back to the old behaviour, implemented by the 'test-driver'
4813   # auxiliary script.
4814   if (! var "${pfx}LOG_DRIVER")
4815     {
4816       require_conf_file ("parallel-tests", FOREIGN, 'test-driver');
4817       define_variable ("${pfx}LOG_DRIVER",
4818                        "\$(SHELL) $am_config_aux_dir/test-driver",
4819                        INTERNAL);
4820     }
4821   my $driver = '$(' . $pfx . 'LOG_DRIVER)';
4822   my $driver_flags = '$(AM_' . $pfx . 'LOG_DRIVER_FLAGS)'
4823                        . ' $(' . $pfx . 'LOG_DRIVER_FLAGS)';
4824   my $compile = "${pfx}LOG_COMPILE";
4825   define_variable ($compile,
4826                    '$(' . $pfx . 'LOG_COMPILER)'
4827                       . ' $(AM_' .  $pfx . 'LOG_FLAGS)'
4828                       . ' $(' . $pfx . 'LOG_FLAGS)',
4829                      INTERNAL);
4830   $output_rules .= file_contents ('check2', new Automake::Location,
4831                                    GENERIC => $generic,
4832                                    DRIVER => $driver,
4833                                    DRIVER_FLAGS => $driver_flags,
4834                                    COMPILE => '$(' . $compile . ')',
4835                                    EXT => $test_suffix,
4836                                    am__EXEEXT => $am_exeext,
4837                                    %transform);
4838 }
4839
4840 # is_valid_test_extension ($EXT)
4841 # ------------------------------
4842 # Return true if $EXT can appear in $(TEST_EXTENSIONS), return false
4843 # otherwise.
4844 sub is_valid_test_extension ($)
4845 {
4846   my $ext = shift;
4847   return 1
4848     if ($ext =~ /^\.[a-zA-Z_][a-zA-Z0-9_]*$/);
4849   return 1
4850     if (exists $configure_vars{'EXEEXT'} && $ext eq subst ('EXEEXT'));
4851   return 0;
4852 }
4853
4854 # Handle TESTS variable and other checks.
4855 sub handle_tests
4856 {
4857   if (option 'dejagnu')
4858     {
4859       &handle_tests_dejagnu;
4860     }
4861   else
4862     {
4863       foreach my $c ('DEJATOOL', 'RUNTEST', 'RUNTESTFLAGS')
4864         {
4865           reject_var ($c, "'$c' defined but 'dejagnu' not in "
4866                       . "'AUTOMAKE_OPTIONS'");
4867         }
4868     }
4869
4870   if (var ('TESTS'))
4871     {
4872       push (@check_tests, 'check-TESTS');
4873       my $check_deps = "@check";
4874       $output_rules .= &file_contents ('check', new Automake::Location,
4875                                        COLOR => !! option 'color-tests',
4876                                        SERIAL_TESTS => !! option 'serial-tests',
4877                                        CHECK_DEPS => $check_deps);
4878
4879       # Tests that are known programs should have $(EXEEXT) appended.
4880       # For matching purposes, we need to adjust XFAIL_TESTS as well.
4881       append_exeext { exists $known_programs{$_[0]} } 'TESTS';
4882       append_exeext { exists $known_programs{$_[0]} } 'XFAIL_TESTS'
4883         if (var ('XFAIL_TESTS'));
4884
4885       if (! option 'serial-tests')
4886         {
4887           define_variable ('TEST_SUITE_LOG', 'test-suite.log', INTERNAL);
4888           my $suff = '.test';
4889           my $at_exeext = '';
4890           my $handle_exeext = exists $configure_vars{'EXEEXT'};
4891           if ($handle_exeext)
4892             {
4893               $at_exeext = subst ('EXEEXT');
4894               $suff = $at_exeext  . ' ' . $suff;
4895             }
4896           if (! var 'TEST_EXTENSIONS')
4897             {
4898               define_variable ('TEST_EXTENSIONS', $suff, INTERNAL);
4899             }
4900           my $var = var 'TEST_EXTENSIONS';
4901           # Currently, we are not able to deal with conditional contents
4902           # in TEST_EXTENSIONS.
4903           if ($var->has_conditional_contents)
4904            {
4905              msg_var 'unsupported', $var,
4906                      "'TEST_EXTENSIONS' cannot have conditional contents";
4907            }
4908           my @test_suffixes = $var->value_as_list_recursive;
4909           if ((my @invalid_test_suffixes =
4910                   grep { !is_valid_test_extension $_ } @test_suffixes) > 0)
4911             {
4912               error $var->rdef (TRUE)->location,
4913                     "invalid test extensions: @invalid_test_suffixes";
4914             }
4915           @test_suffixes = grep { is_valid_test_extension $_ } @test_suffixes;
4916           if ($handle_exeext)
4917             {
4918               unshift (@test_suffixes, $at_exeext)
4919                 unless $test_suffixes[0] eq $at_exeext;
4920             }
4921           unshift (@test_suffixes, '');
4922
4923           transform_variable_recursively
4924             ('TESTS', 'TEST_LOGS', 'am__testlogs', 1, INTERNAL,
4925               sub {
4926                 my ($subvar, $val, $cond, $full_cond) = @_;
4927                 my $obj = $val;
4928                 return $obj
4929                   if $val =~ /^\@.*\@$/;
4930                 $obj =~ s/\$\(EXEEXT\)$//o;
4931
4932                 if ($val =~ /(\$\((top_)?srcdir\))\//o)
4933                   {
4934                     msg ('error', $subvar->rdef ($cond)->location,
4935                          "using '$1' in TESTS is currently broken: '$val'");
4936                   }
4937
4938                 foreach my $test_suffix (@test_suffixes)
4939                   {
4940                     next
4941                       if $test_suffix eq $at_exeext || $test_suffix eq '';
4942                     return substr ($obj, 0, length ($obj) - length ($test_suffix)) . '.log'
4943                       if substr ($obj, - length ($test_suffix)) eq $test_suffix;
4944                   }
4945                 my $base = $obj;
4946                 $obj .= '.log';
4947                 handle_per_suffix_test ('',
4948                                         OBJ => $obj,
4949                                         BASE => $base,
4950                                         SOURCE => $val);
4951                 return $obj;
4952               });
4953
4954           my $nhelper=1;
4955           my $prev = 'TESTS';
4956           my $post = '';
4957           my $last_suffix = $test_suffixes[$#test_suffixes];
4958           my $cur = '';
4959           foreach my $test_suffix (@test_suffixes)
4960             {
4961               if ($test_suffix eq $last_suffix)
4962                 {
4963                   $cur = 'TEST_LOGS';
4964                 }
4965               else
4966                 {
4967                   $cur = 'am__test_logs' . $nhelper;
4968                 }
4969               define_variable ($cur,
4970                 '$(' . $prev . ':' . $test_suffix . $post . '=.log)', INTERNAL);
4971               $post = '.log';
4972               $prev = $cur;
4973               $nhelper++;
4974               if ($test_suffix ne $at_exeext && $test_suffix ne '')
4975                 {
4976                   handle_per_suffix_test ($test_suffix,
4977                                           OBJ => '',
4978                                           BASE => '$*',
4979                                           SOURCE => '$<');
4980                 }
4981             }
4982           $clean_files{'$(TEST_LOGS)'} = MOSTLY_CLEAN;
4983           $clean_files{'$(TEST_LOGS:.log=.trs)'} = MOSTLY_CLEAN;
4984           $clean_files{'$(TEST_SUITE_LOG)'} = MOSTLY_CLEAN;
4985         }
4986     }
4987 }
4988
4989 # Handle Emacs Lisp.
4990 sub handle_emacs_lisp
4991 {
4992   my @elfiles = &am_install_var ('-candist', 'lisp', 'LISP',
4993                                  'lisp', 'noinst');
4994
4995   return if ! @elfiles;
4996
4997   define_pretty_variable ('am__ELFILES', TRUE, INTERNAL,
4998                           map { $_->[1] } @elfiles);
4999   define_pretty_variable ('am__ELCFILES', TRUE, INTERNAL,
5000                           '$(am__ELFILES:.el=.elc)');
5001   # This one can be overridden by users.
5002   define_pretty_variable ('ELCFILES', TRUE, INTERNAL, '$(LISP:.el=.elc)');
5003
5004   push @all, '$(ELCFILES)';
5005
5006   require_variables ($elfiles[0][0], "Emacs Lisp sources seen", TRUE,
5007                      'EMACS', 'lispdir');
5008   require_conf_file ($elfiles[0][0], FOREIGN, 'elisp-comp');
5009   &define_variable ('elisp_comp', "$am_config_aux_dir/elisp-comp", INTERNAL);
5010 }
5011
5012 # Handle Python
5013 sub handle_python
5014 {
5015   my @pyfiles = &am_install_var ('-defaultdist', 'python', 'PYTHON',
5016                                  'noinst');
5017   return if ! @pyfiles;
5018
5019   require_variables ($pyfiles[0][0], "Python sources seen", TRUE, 'PYTHON');
5020   require_conf_file ($pyfiles[0][0], FOREIGN, 'py-compile');
5021   &define_variable ('py_compile', "$am_config_aux_dir/py-compile", INTERNAL);
5022 }
5023
5024 # Handle Java.
5025 sub handle_java
5026 {
5027     my @sourcelist = &am_install_var ('-candist',
5028                                       'java', 'JAVA',
5029                                       'noinst', 'check');
5030     return if ! @sourcelist;
5031
5032     my @prefixes = am_primary_prefixes ('JAVA', 1,
5033                                         'noinst', 'check');
5034
5035     my $dir;
5036     my @java_sources = ();
5037     foreach my $prefix (@prefixes)
5038       {
5039         (my $curs = $prefix) =~ s/^(?:nobase_)?(?:dist_|nodist_)?//;
5040
5041         next
5042           if $curs eq 'EXTRA';
5043
5044         push @java_sources, '$(' . $prefix . '_JAVA' . ')';
5045
5046         if (defined $dir)
5047           {
5048             err_var "${curs}_JAVA", "multiple _JAVA primaries in use"
5049              unless $curs eq $dir;
5050           }
5051
5052         $dir = $curs;
5053       }
5054
5055     define_pretty_variable ('am__java_sources', TRUE, INTERNAL,
5056                             "@java_sources");
5057
5058     if ($dir eq 'check')
5059       {
5060         push (@check, "class$dir.stamp");
5061       }
5062     else
5063       {
5064         push (@all, "class$dir.stamp");
5065       }
5066 }
5067
5068
5069 # Handle some of the minor options.
5070 sub handle_minor_options
5071 {
5072   if (option 'readme-alpha')
5073     {
5074       if ($relative_dir eq '.')
5075         {
5076           if ($package_version !~ /^$GNITS_VERSION_PATTERN$/)
5077             {
5078               msg ('error-gnits', $package_version_location,
5079                    "version '$package_version' doesn't follow " .
5080                    "Gnits standards");
5081             }
5082           if (defined $1 && -f 'README-alpha')
5083             {
5084               # This means we have an alpha release.  See
5085               # GNITS_VERSION_PATTERN for details.
5086               push_dist_common ('README-alpha');
5087             }
5088         }
5089     }
5090 }
5091
5092 ################################################################
5093
5094 # ($OUTPUT, @INPUTS)
5095 # &split_config_file_spec ($SPEC)
5096 # -------------------------------
5097 # Decode the Autoconf syntax for config files (files, headers, links
5098 # etc.).
5099 sub split_config_file_spec ($)
5100 {
5101   my ($spec) = @_;
5102   my ($output, @inputs) = split (/:/, $spec);
5103
5104   push @inputs, "$output.in"
5105     unless @inputs;
5106
5107   return ($output, @inputs);
5108 }
5109
5110 # $input
5111 # locate_am (@POSSIBLE_SOURCES)
5112 # -----------------------------
5113 # AC_CONFIG_FILES allow specifications such as Makefile:top.in:mid.in:bot.in
5114 # This functions returns the first *.in file for which a *.am exists.
5115 # It returns undef otherwise.
5116 sub locate_am (@)
5117 {
5118   my (@rest) = @_;
5119   my $input;
5120   foreach my $file (@rest)
5121     {
5122       if (($file =~ /^(.*)\.in$/) && -f "$1.am")
5123         {
5124           $input = $file;
5125           last;
5126         }
5127     }
5128   return $input;
5129 }
5130
5131 my %make_list;
5132
5133 # &scan_autoconf_config_files ($WHERE, $CONFIG-FILES)
5134 # ---------------------------------------------------
5135 # Study $CONFIG-FILES which is the first argument to AC_CONFIG_FILES
5136 # (or AC_OUTPUT).
5137 sub scan_autoconf_config_files ($$)
5138 {
5139   my ($where, $config_files) = @_;
5140
5141   # Look at potential Makefile.am's.
5142   foreach (split ' ', $config_files)
5143     {
5144       # Must skip empty string for Perl 4.
5145       next if $_ eq "\\" || $_ eq '';
5146
5147       # Handle $local:$input syntax.
5148       my ($local, @rest) = split (/:/);
5149       @rest = ("$local.in",) unless @rest;
5150       # Keep in sync with 'conffile-leading-dot.test'.
5151       msg ('unsupported', $where,
5152            "omit leading './' from config file names such as '$local';"
5153            . "\nremake rules might be subtly broken otherwise")
5154         if ($local =~ /^\.\//);
5155       my $input = locate_am @rest;
5156       if ($input)
5157         {
5158           # We have a file that automake should generate.
5159           $make_list{$input} = join (':', ($local, @rest));
5160         }
5161       else
5162         {
5163           # We have a file that automake should cause to be
5164           # rebuilt, but shouldn't generate itself.
5165           push (@other_input_files, $_);
5166         }
5167       $ac_config_files_location{$local} = $where;
5168       $ac_config_files_condition{$local} =
5169         new Automake::Condition (@cond_stack)
5170           if (@cond_stack);
5171     }
5172 }
5173
5174
5175 # &scan_autoconf_traces ($FILENAME)
5176 # ---------------------------------
5177 sub scan_autoconf_traces ($)
5178 {
5179   my ($filename) = @_;
5180
5181   # Macros to trace, with their minimal number of arguments.
5182   #
5183   # IMPORTANT: If you add a macro here, you should also add this macro
5184   # =========  to Automake-preselection in autoconf/lib/autom4te.in.
5185   my %traced = (
5186                 AC_CANONICAL_BUILD => 0,
5187                 AC_CANONICAL_HOST => 0,
5188                 AC_CANONICAL_TARGET => 0,
5189                 AC_CONFIG_AUX_DIR => 1,
5190                 AC_CONFIG_FILES => 1,
5191                 AC_CONFIG_HEADERS => 1,
5192                 AC_CONFIG_LIBOBJ_DIR => 1,
5193                 AC_CONFIG_LINKS => 1,
5194                 AC_FC_SRCEXT => 1,
5195                 AC_INIT => 0,
5196                 AC_LIBSOURCE => 1,
5197                 AC_REQUIRE_AUX_FILE => 1,
5198                 AC_SUBST_TRACE => 1,
5199                 AM_AUTOMAKE_VERSION => 1,
5200                 AM_CONDITIONAL => 2,
5201                 AM_GNU_GETTEXT => 0,
5202                 AM_GNU_GETTEXT_INTL_SUBDIR => 0,
5203                 AM_INIT_AUTOMAKE => 0,
5204                 AM_MAINTAINER_MODE => 0,
5205                 AM_PROG_AR => 0,
5206                 AM_PROG_CC_C_O => 0,
5207                 _AM_SUBST_NOTMAKE => 1,
5208                 _AM_COND_IF => 1,
5209                 _AM_COND_ELSE => 1,
5210                 _AM_COND_ENDIF => 1,
5211                 LT_SUPPORTED_TAG => 1,
5212                 _LT_AC_TAGCONFIG => 0,
5213                 m4_include => 1,
5214                 m4_sinclude => 1,
5215                 sinclude => 1,
5216               );
5217
5218   my $traces = ($ENV{AUTOCONF} || '@am_AUTOCONF@') . " ";
5219
5220   # Use a separator unlikely to be used, not ':', the default, which
5221   # has a precise meaning for AC_CONFIG_FILES and so on.
5222   $traces .= join (' ',
5223                    map { "--trace=$_" . ':\$f:\$l::\$d::\$n::\${::}%' }
5224                    (keys %traced));
5225
5226   my $tracefh = new Automake::XFile ("$traces $filename |");
5227   verb "reading $traces";
5228
5229   @cond_stack = ();
5230   my $where;
5231
5232   while ($_ = $tracefh->getline)
5233     {
5234       chomp;
5235       my ($here, $depth, @args) = split (/::/);
5236       $where = new Automake::Location $here;
5237       my $macro = $args[0];
5238
5239       prog_error ("unrequested trace '$macro'")
5240         unless exists $traced{$macro};
5241
5242       # Skip and diagnose malformed calls.
5243       if ($#args < $traced{$macro})
5244         {
5245           msg ('syntax', $where, "not enough arguments for $macro");
5246           next;
5247         }
5248
5249       # Alphabetical ordering please.
5250       if ($macro eq 'AC_CANONICAL_BUILD')
5251         {
5252           if ($seen_canonical <= AC_CANONICAL_BUILD)
5253             {
5254               $seen_canonical = AC_CANONICAL_BUILD;
5255               $canonical_location = $where;
5256             }
5257         }
5258       elsif ($macro eq 'AC_CANONICAL_HOST')
5259         {
5260           if ($seen_canonical <= AC_CANONICAL_HOST)
5261             {
5262               $seen_canonical = AC_CANONICAL_HOST;
5263               $canonical_location = $where;
5264             }
5265         }
5266       elsif ($macro eq 'AC_CANONICAL_TARGET')
5267         {
5268           $seen_canonical = AC_CANONICAL_TARGET;
5269           $canonical_location = $where;
5270         }
5271       elsif ($macro eq 'AC_CONFIG_AUX_DIR')
5272         {
5273           if ($seen_init_automake)
5274             {
5275               error ($where, "AC_CONFIG_AUX_DIR must be called before "
5276                      . "AM_INIT_AUTOMAKE ...", partial => 1);
5277               error ($seen_init_automake, "... AM_INIT_AUTOMAKE called here");
5278             }
5279           $config_aux_dir = $args[1];
5280           $config_aux_dir_set_in_configure_ac = 1;
5281           check_directory ($config_aux_dir, $where);
5282         }
5283       elsif ($macro eq 'AC_CONFIG_FILES')
5284         {
5285           # Look at potential Makefile.am's.
5286           scan_autoconf_config_files ($where, $args[1]);
5287         }
5288       elsif ($macro eq 'AC_CONFIG_HEADERS')
5289         {
5290           foreach my $spec (split (' ', $args[1]))
5291             {
5292               my ($dest, @src) = split (':', $spec);
5293               $ac_config_files_location{$dest} = $where;
5294               push @config_headers, $spec;
5295             }
5296         }
5297       elsif ($macro eq 'AC_CONFIG_LIBOBJ_DIR')
5298         {
5299           $config_libobj_dir = $args[1];
5300           check_directory ($config_libobj_dir, $where);
5301         }
5302       elsif ($macro eq 'AC_CONFIG_LINKS')
5303         {
5304           foreach my $spec (split (' ', $args[1]))
5305             {
5306               my ($dest, $src) = split (':', $spec);
5307               $ac_config_files_location{$dest} = $where;
5308               push @config_links, $spec;
5309             }
5310         }
5311       elsif ($macro eq 'AC_FC_SRCEXT')
5312         {
5313           my $suffix = $args[1];
5314           # These flags are used as %SOURCEFLAG% in depend2.am,
5315           # where the trailing space is important.
5316           $sourceflags{'.' . $suffix} = '$(FCFLAGS_' . $suffix . ') '
5317             if ($suffix eq 'f90' || $suffix eq 'f95' || $suffix eq 'f03' || $suffix eq 'f08');
5318         }
5319       elsif ($macro eq 'AC_INIT')
5320         {
5321           if (defined $args[2])
5322             {
5323               $package_version = $args[2];
5324               $package_version_location = $where;
5325             }
5326         }
5327       elsif ($macro eq 'AC_LIBSOURCE')
5328         {
5329           $libsources{$args[1]} = $here;
5330         }
5331       elsif ($macro eq 'AC_REQUIRE_AUX_FILE')
5332         {
5333           # Only remember the first time a file is required.
5334           $required_aux_file{$args[1]} = $where
5335             unless exists $required_aux_file{$args[1]};
5336         }
5337       elsif ($macro eq 'AC_SUBST_TRACE')
5338         {
5339           # Just check for alphanumeric in AC_SUBST_TRACE.  If you do
5340           # AC_SUBST(5), then too bad.
5341           $configure_vars{$args[1]} = $where
5342             if $args[1] =~ /^\w+$/;
5343         }
5344       elsif ($macro eq 'AM_AUTOMAKE_VERSION')
5345         {
5346           error ($where,
5347                  "version mismatch.  This is Automake $VERSION,\n" .
5348                  "but the definition used by this AM_INIT_AUTOMAKE\n" .
5349                  "comes from Automake $args[1].  You should recreate\n" .
5350                  "aclocal.m4 with aclocal and run automake again.\n",
5351                  # $? = 63 is used to indicate version mismatch to missing.
5352                  exit_code => 63)
5353             if $VERSION ne $args[1];
5354
5355           $seen_automake_version = 1;
5356         }
5357       elsif ($macro eq 'AM_CONDITIONAL')
5358         {
5359           $configure_cond{$args[1]} = $where;
5360         }
5361       elsif ($macro eq 'AM_GNU_GETTEXT')
5362         {
5363           $seen_gettext = $where;
5364           $ac_gettext_location = $where;
5365           $seen_gettext_external = grep ($_ eq 'external', @args);
5366         }
5367       elsif ($macro eq 'AM_GNU_GETTEXT_INTL_SUBDIR')
5368         {
5369           $seen_gettext_intl = $where;
5370         }
5371       elsif ($macro eq 'AM_INIT_AUTOMAKE')
5372         {
5373           $seen_init_automake = $where;
5374           if (defined $args[2])
5375             {
5376               msg 'obsolete', $where, <<'EOF';
5377 AM_INIT_AUTOMAKE: two- and three-arguments forms are deprecated.  For more info, see:
5378 http://www.gnu.org/software/automake/manual/automake.html#Modernize-AM_INIT_AUTOMAKE-invocation
5379 EOF
5380               $package_version = $args[2];
5381               $package_version_location = $where;
5382             }
5383           elsif (defined $args[1])
5384             {
5385               my @opts = split (' ', $args[1]);
5386               @opts = map { { option => $_, where => $where } } @opts;
5387               exit $exit_code if process_global_option_list (@opts);
5388             }
5389         }
5390       elsif ($macro eq 'AM_MAINTAINER_MODE')
5391         {
5392           $seen_maint_mode = $where;
5393         }
5394       elsif ($macro eq 'AM_PROG_AR')
5395         {
5396           $seen_ar = $where;
5397         }
5398       elsif ($macro eq 'AM_PROG_CC_C_O')
5399         {
5400           $seen_cc_c_o = $where;
5401         }
5402       elsif ($macro eq '_AM_COND_IF')
5403         {
5404           cond_stack_if ('', $args[1], $where);
5405           error ($where, "missing m4 quoting, macro depth $depth")
5406             if ($depth != 1);
5407         }
5408       elsif ($macro eq '_AM_COND_ELSE')
5409         {
5410           cond_stack_else ('!', $args[1], $where);
5411           error ($where, "missing m4 quoting, macro depth $depth")
5412             if ($depth != 1);
5413         }
5414       elsif ($macro eq '_AM_COND_ENDIF')
5415         {
5416           cond_stack_endif (undef, undef, $where);
5417           error ($where, "missing m4 quoting, macro depth $depth")
5418             if ($depth != 1);
5419         }
5420       elsif ($macro eq '_AM_SUBST_NOTMAKE')
5421         {
5422           $ignored_configure_vars{$args[1]} = $where;
5423         }
5424       elsif ($macro eq 'm4_include'
5425              || $macro eq 'm4_sinclude'
5426              || $macro eq 'sinclude')
5427         {
5428           # Skip missing 'sinclude'd files.
5429           next if $macro ne 'm4_include' && ! -f $args[1];
5430
5431           # Some modified versions of Autoconf don't use
5432           # frozen files.  Consequently it's possible that we see all
5433           # m4_include's performed during Autoconf's startup.
5434           # Obviously we don't want to distribute Autoconf's files
5435           # so we skip absolute filenames here.
5436           push @configure_deps, '$(top_srcdir)/' . $args[1]
5437             unless $here =~ m,^(?:\w:)?[\\/],;
5438           # Keep track of the greatest timestamp.
5439           if (-e $args[1])
5440             {
5441               my $mtime = mtime $args[1];
5442               $configure_deps_greatest_timestamp = $mtime
5443                 if $mtime > $configure_deps_greatest_timestamp;
5444             }
5445         }
5446       elsif ($macro eq 'LT_SUPPORTED_TAG')
5447         {
5448           $libtool_tags{$args[1]} = 1;
5449           $libtool_new_api = 1;
5450         }
5451       elsif ($macro eq '_LT_AC_TAGCONFIG')
5452         {
5453           # _LT_AC_TAGCONFIG is an old macro present in Libtool 1.5.
5454           # We use it to detect whether tags are supported.  Our
5455           # preferred interface is LT_SUPPORTED_TAG, but it was
5456           # introduced in Libtool 1.6.
5457           if (0 == keys %libtool_tags)
5458             {
5459               # Hardcode the tags supported by Libtool 1.5.
5460               %libtool_tags = (CC => 1, CXX => 1, GCJ => 1, F77 => 1);
5461             }
5462         }
5463     }
5464
5465   error ($where, "condition stack not properly closed")
5466     if (@cond_stack);
5467
5468   $tracefh->close;
5469 }
5470
5471
5472 # &scan_autoconf_files ()
5473 # -----------------------
5474 # Check whether we use 'configure.ac' or 'configure.in'.
5475 # Scan it (and possibly 'aclocal.m4') for interesting things.
5476 # We must scan aclocal.m4 because there might be AC_SUBSTs and such there.
5477 sub scan_autoconf_files ()
5478 {
5479   # Reinitialize libsources here.  This isn't really necessary,
5480   # since we currently assume there is only one configure.ac.  But
5481   # that won't always be the case.
5482   %libsources = ();
5483
5484   # Keep track of the youngest configure dependency.
5485   $configure_deps_greatest_timestamp = mtime $configure_ac;
5486   if (-e 'aclocal.m4')
5487     {
5488       my $mtime = mtime 'aclocal.m4';
5489       $configure_deps_greatest_timestamp = $mtime
5490         if $mtime > $configure_deps_greatest_timestamp;
5491     }
5492
5493   scan_autoconf_traces ($configure_ac);
5494
5495   @configure_input_files = sort keys %make_list;
5496   # Set input and output files if not specified by user.
5497   if (! @input_files)
5498     {
5499       @input_files = @configure_input_files;
5500       %output_files = %make_list;
5501     }
5502
5503
5504   if (! $seen_init_automake)
5505     {
5506       err_ac ("no proper invocation of AM_INIT_AUTOMAKE was found.\nYou "
5507               . "should verify that $configure_ac invokes AM_INIT_AUTOMAKE,"
5508               . "\nthat aclocal.m4 is present in the top-level directory,\n"
5509               . "and that aclocal.m4 was recently regenerated "
5510               . "(using aclocal)");
5511     }
5512   else
5513     {
5514       if (! $seen_automake_version)
5515         {
5516           if (-f 'aclocal.m4')
5517             {
5518               error ($seen_init_automake,
5519                      "your implementation of AM_INIT_AUTOMAKE comes from " .
5520                      "an\nold Automake version.  You should recreate " .
5521                      "aclocal.m4\nwith aclocal and run automake again",
5522                      # $? = 63 is used to indicate version mismatch to missing.
5523                      exit_code => 63);
5524             }
5525           else
5526             {
5527               error ($seen_init_automake,
5528                      "no proper implementation of AM_INIT_AUTOMAKE was " .
5529                      "found,\nprobably because aclocal.m4 is missing.\n" .
5530                      "You should run aclocal to create this file, then\n" .
5531                      "run automake again");
5532             }
5533         }
5534     }
5535
5536   locate_aux_dir ();
5537
5538   # Look for some files we need.  Always check for these.  This
5539   # check must be done for every run, even those where we are only
5540   # looking at a subdir Makefile.  We must set relative_dir for
5541   # push_required_file to work.
5542   # Sort the files for stable verbose output.
5543   $relative_dir = '.';
5544   foreach my $file (sort keys %required_aux_file)
5545     {
5546       require_conf_file ($required_aux_file{$file}->get, FOREIGN, $file)
5547     }
5548   err_am "'install.sh' is an anachronism; use 'install-sh' instead"
5549     if -f $config_aux_dir . '/install.sh';
5550
5551   # Preserve dist_common for later.
5552   $configure_dist_common = variable_value ('DIST_COMMON') || '';
5553
5554 }
5555
5556 ################################################################
5557
5558 # Do any extra checking for GNU standards.
5559 sub check_gnu_standards
5560 {
5561   if ($relative_dir eq '.')
5562     {
5563       # In top level (or only) directory.
5564       require_file ("$am_file.am", GNU,
5565                     qw/INSTALL NEWS README AUTHORS ChangeLog/);
5566
5567       # Accept one of these three licenses; default to COPYING.
5568       # Make sure we do not overwrite an existing license.
5569       my $license;
5570       foreach (qw /COPYING COPYING.LIB COPYING.LESSER/)
5571         {
5572           if (-f $_)
5573             {
5574               $license = $_;
5575               last;
5576             }
5577         }
5578       require_file ("$am_file.am", GNU, 'COPYING')
5579         unless $license;
5580     }
5581
5582   for my $opt ('no-installman', 'no-installinfo')
5583     {
5584       msg ('error-gnu', option $opt,
5585            "option '$opt' disallowed by GNU standards")
5586         if option $opt;
5587     }
5588 }
5589
5590 # Do any extra checking for GNITS standards.
5591 sub check_gnits_standards
5592 {
5593   if ($relative_dir eq '.')
5594     {
5595       # In top level (or only) directory.
5596       require_file ("$am_file.am", GNITS, 'THANKS');
5597     }
5598 }
5599
5600 ################################################################
5601 #
5602 # Functions to handle files of each language.
5603
5604 # Each 'lang_X_rewrite($DIRECTORY, $BASE, $EXT)' function follows a
5605 # simple formula: Return value is LANG_SUBDIR if the resulting object
5606 # file should be in a subdir if the source file is, LANG_PROCESS if
5607 # file is to be dealt with, LANG_IGNORE otherwise.
5608
5609 # Much of the actual processing is handled in
5610 # handle_single_transform.  These functions exist so that
5611 # auxiliary information can be recorded for a later cleanup pass.
5612 # Note that the calls to these functions are computed, so don't bother
5613 # searching for their precise names in the source.
5614
5615 # This is just a convenience function that can be used to determine
5616 # when a subdir object should be used.
5617 sub lang_sub_obj
5618 {
5619     return option 'subdir-objects' ? LANG_SUBDIR : LANG_PROCESS;
5620 }
5621
5622 # Rewrite a single C source file.
5623 sub lang_c_rewrite
5624 {
5625   my ($directory, $base, $ext, $obj, $have_per_exec_flags, $var) = @_;
5626
5627   my $r = LANG_PROCESS;
5628   if (option 'subdir-objects')
5629     {
5630       $r = LANG_SUBDIR;
5631       if ($directory && $directory ne '.')
5632         {
5633           $base = $directory . '/' . $base;
5634
5635           # libtool is always able to put the object at the proper place,
5636           # so we do not have to require AM_PROG_CC_C_O when building .lo files.
5637           msg_var ('portability', $var,
5638                    "compiling '$base.c' in subdir requires "
5639                    . "'AM_PROG_CC_C_O' in '$configure_ac'",
5640                    uniq_scope => US_GLOBAL,
5641                    uniq_part => 'AM_PROG_CC_C_O subdir')
5642             unless $seen_cc_c_o || $obj eq '.lo';
5643         }
5644     }
5645
5646   if (! $seen_cc_c_o
5647       && $have_per_exec_flags
5648       && ! option 'subdir-objects'
5649       && $obj ne '.lo')
5650     {
5651       msg_var ('portability',
5652                $var, "compiling '$base.c' with per-target flags requires "
5653                . "'AM_PROG_CC_C_O' in '$configure_ac'",
5654                uniq_scope => US_GLOBAL,
5655                uniq_part => 'AM_PROG_CC_C_O per-target')
5656     }
5657
5658     return $r;
5659 }
5660
5661 # Rewrite a single C++ source file.
5662 sub lang_cxx_rewrite
5663 {
5664     return &lang_sub_obj;
5665 }
5666
5667 # Rewrite a single header file.
5668 sub lang_header_rewrite
5669 {
5670     # Header files are simply ignored.
5671     return LANG_IGNORE;
5672 }
5673
5674 # Rewrite a single Vala source file.
5675 sub lang_vala_rewrite
5676 {
5677     my ($directory, $base, $ext) = @_;
5678
5679     (my $newext = $ext) =~ s/vala$/c/;
5680     return (LANG_SUBDIR, $newext);
5681 }
5682
5683 # Rewrite a single yacc file.
5684 sub lang_yacc_rewrite
5685 {
5686     my ($directory, $base, $ext) = @_;
5687
5688     my $r = &lang_sub_obj;
5689     (my $newext = $ext) =~ tr/y/c/;
5690     return ($r, $newext);
5691 }
5692
5693 # Rewrite a single yacc++ file.
5694 sub lang_yaccxx_rewrite
5695 {
5696     my ($directory, $base, $ext) = @_;
5697
5698     my $r = &lang_sub_obj;
5699     (my $newext = $ext) =~ tr/y/c/;
5700     return ($r, $newext);
5701 }
5702
5703 # Rewrite a single lex file.
5704 sub lang_lex_rewrite
5705 {
5706     my ($directory, $base, $ext) = @_;
5707
5708     my $r = &lang_sub_obj;
5709     (my $newext = $ext) =~ tr/l/c/;
5710     return ($r, $newext);
5711 }
5712
5713 # Rewrite a single lex++ file.
5714 sub lang_lexxx_rewrite
5715 {
5716     my ($directory, $base, $ext) = @_;
5717
5718     my $r = &lang_sub_obj;
5719     (my $newext = $ext) =~ tr/l/c/;
5720     return ($r, $newext);
5721 }
5722
5723 # Rewrite a single assembly file.
5724 sub lang_asm_rewrite
5725 {
5726     return &lang_sub_obj;
5727 }
5728
5729 # Rewrite a single preprocessed assembly file.
5730 sub lang_cppasm_rewrite
5731 {
5732     return &lang_sub_obj;
5733 }
5734
5735 # Rewrite a single Fortran 77 file.
5736 sub lang_f77_rewrite
5737 {
5738     return &lang_sub_obj;
5739 }
5740
5741 # Rewrite a single Fortran file.
5742 sub lang_fc_rewrite
5743 {
5744     return &lang_sub_obj;
5745 }
5746
5747 # Rewrite a single preprocessed Fortran file.
5748 sub lang_ppfc_rewrite
5749 {
5750     return &lang_sub_obj;
5751 }
5752
5753 # Rewrite a single preprocessed Fortran 77 file.
5754 sub lang_ppf77_rewrite
5755 {
5756     return &lang_sub_obj;
5757 }
5758
5759 # Rewrite a single ratfor file.
5760 sub lang_ratfor_rewrite
5761 {
5762     return &lang_sub_obj;
5763 }
5764
5765 # Rewrite a single Objective C file.
5766 sub lang_objc_rewrite
5767 {
5768     return &lang_sub_obj;
5769 }
5770
5771 # Rewrite a single Objective C++ file.
5772 sub lang_objcxx_rewrite
5773 {
5774     return &lang_sub_obj;
5775 }
5776
5777 # Rewrite a single Unified Parallel C file.
5778 sub lang_upc_rewrite
5779 {
5780     return &lang_sub_obj;
5781 }
5782
5783 # Rewrite a single Java file.
5784 sub lang_java_rewrite
5785 {
5786     return LANG_SUBDIR;
5787 }
5788
5789 # The lang_X_finish functions are called after all source file
5790 # processing is done.  Each should handle defining rules for the
5791 # language, etc.  A finish function is only called if a source file of
5792 # the appropriate type has been seen.
5793
5794 sub lang_vala_finish_target ($$)
5795 {
5796   my ($self, $name) = @_;
5797
5798   my $derived = canonicalize ($name);
5799   my $var = var "${derived}_SOURCES";
5800   return unless $var;
5801
5802   my @vala_sources = grep { /\.(vala|vapi)$/ } ($var->value_as_list_recursive);
5803
5804   # For automake bug#11229.
5805   return unless @vala_sources;
5806
5807   foreach my $vala_file (@vala_sources)
5808     {
5809       my $c_file = $vala_file;
5810       if ($c_file =~ s/(.*)\.vala$/$1.c/)
5811         {
5812           $c_file = "\$(srcdir)/$c_file";
5813           $output_rules .= "$c_file: \$(srcdir)/${derived}_vala.stamp\n"
5814             . "\t\@if test -f \$@; then :; else rm -f \$(srcdir)/${derived}_vala.stamp; fi\n"
5815             . "\t\@if test -f \$@; then :; else \\\n"
5816             . "\t  \$(MAKE) \$(AM_MAKEFLAGS) \$(srcdir)/${derived}_vala.stamp; \\\n"
5817             . "\tfi\n";
5818           $clean_files{$c_file} = MAINTAINER_CLEAN;
5819         }
5820     }
5821
5822   # Add rebuild rules for generated header and vapi files
5823   my $flags = var ($derived . '_VALAFLAGS');
5824   if ($flags)
5825     {
5826       my $lastflag = '';
5827       foreach my $flag ($flags->value_as_list_recursive)
5828         {
5829           if (grep (/$lastflag/, ('-H', '-h', '--header', '--internal-header',
5830                                   '--vapi', '--internal-vapi', '--gir')))
5831             {
5832               my $headerfile = "\$(srcdir)/$flag";
5833               $output_rules .= "$headerfile: \$(srcdir)/${derived}_vala.stamp\n"
5834                 . "\t\@if test -f \$@; then :; else rm -f \$(srcdir)/${derived}_vala.stamp; fi\n"
5835                 . "\t\@if test -f \$@; then :; else \\\n"
5836                 . "\t  \$(MAKE) \$(AM_MAKEFLAGS) \$(srcdir)/${derived}_vala.stamp; \\\n"
5837                 . "\tfi\n";
5838
5839               # valac is not used when building from dist tarballs
5840               # distribute the generated files
5841               push_dist_common ($headerfile);
5842               $clean_files{$headerfile} = MAINTAINER_CLEAN;
5843             }
5844           $lastflag = $flag;
5845         }
5846     }
5847
5848   my $compile = $self->compile;
5849
5850   # Rewrite each occurrence of 'AM_VALAFLAGS' in the compile
5851   # rule into '${derived}_VALAFLAGS' if it exists.
5852   my $val = "${derived}_VALAFLAGS";
5853   $compile =~ s/\(AM_VALAFLAGS\)/\($val\)/
5854     if set_seen ($val);
5855
5856   # VALAFLAGS is a user variable (per GNU Standards),
5857   # it should not be overridden in the Makefile...
5858   check_user_variables 'VALAFLAGS';
5859
5860   my $dirname = dirname ($name);
5861
5862   # Only generate C code, do not run C compiler
5863   $compile .= " -C";
5864
5865   my $verbose = verbose_flag ('VALAC');
5866   my $silent = silent_flag ();
5867   my $stampfile = "\$(srcdir)/${derived}_vala.stamp";
5868
5869   $output_rules .=
5870     "\$(srcdir)/${derived}_vala.stamp: @vala_sources\n".
5871 # Since the C files generated from the vala sources depend on the
5872 # ${derived}_vala.stamp file, we must ensure its timestamp is older than
5873 # those of the C files generated by the valac invocation below (this is
5874 # especially important on systems with sub-second timestamp resolution).
5875 # Thus we need to create the stamp file *before* invoking valac, and to
5876 # move it to its final location only after valac has been invoked.
5877     "\t${silent}rm -f \$\@ && echo stamp > \$\@-t\n".
5878     "\t${verbose}\$(am__cd) \$(srcdir) && $compile @vala_sources\n".
5879     "\t${silent}mv -f \$\@-t \$\@\n";
5880
5881   push_dist_common ($stampfile);
5882
5883   $clean_files{$stampfile} = MAINTAINER_CLEAN;
5884 }
5885
5886 # Add output rules to invoke valac and create stamp file as a witness
5887 # to handle multiple outputs. This function is called after all source
5888 # file processing is done.
5889 sub lang_vala_finish
5890 {
5891   my ($self) = @_;
5892
5893   foreach my $prog (keys %known_programs)
5894     {
5895       lang_vala_finish_target ($self, $prog);
5896     }
5897
5898   while (my ($name) = each %known_libraries)
5899     {
5900       lang_vala_finish_target ($self, $name);
5901     }
5902 }
5903
5904 # The built .c files should be cleaned only on maintainer-clean
5905 # as the .c files are distributed. This function is called for each
5906 # .vala source file.
5907 sub lang_vala_target_hook
5908 {
5909   my ($self, $aggregate, $output, $input, %transform) = @_;
5910
5911   $clean_files{$output} = MAINTAINER_CLEAN;
5912 }
5913
5914 # This is a yacc helper which is called whenever we have decided to
5915 # compile a yacc file.
5916 sub lang_yacc_target_hook
5917 {
5918     my ($self, $aggregate, $output, $input, %transform) = @_;
5919
5920     # If some relevant *YFLAGS variable contains the '-d' flag, we'll
5921     # have to to generate special code.
5922     my $yflags_contains_minus_d = 0;
5923
5924     foreach my $pfx ("", "${aggregate}_")
5925       {
5926         my $yflagsvar = var ("${pfx}YFLAGS");
5927         next unless $yflagsvar;
5928         # We cannot work reliably with conditionally-defined YFLAGS.
5929         if ($yflagsvar->has_conditional_contents)
5930           {
5931             msg_var ('unsupported', $yflagsvar,
5932                      "'${pfx}YFLAGS' cannot have conditional contents");
5933           }
5934         else
5935           {
5936             $yflags_contains_minus_d = 1
5937               if grep (/^-d$/, $yflagsvar->value_as_list_recursive);
5938           }
5939       }
5940
5941     if ($yflags_contains_minus_d)
5942       {
5943         # Found a '-d' that applies to the compilation of this file.
5944         # Add a dependency for the generated header file, and arrange
5945         # for that file to be included in the distribution.
5946
5947         # The extension of the output file (e.g., '.c' or '.cxx').
5948         # We'll need it to compute the name of the generated header file.
5949         (my $output_ext = basename ($output)) =~ s/.*(\.[^.]+)$/$1/;
5950
5951         # We know that a yacc input should be turned into either a C or
5952         # C++ output file.  We depend on this fact (here and in yacc.am),
5953         # so check that it really holds.
5954         my $lang = $languages{$extension_map{$output_ext}};
5955         prog_error "invalid output name '$output' for yacc file '$input'"
5956           if (!$lang || ($lang->name ne 'c' && $lang->name ne 'cxx'));
5957
5958         (my $header_ext = $output_ext) =~ s/c/h/g;
5959         # Quote $output_ext in the regexp, so that dots in it are taken
5960         # as literal dots, not as metacharacters.
5961         (my $header = $output) =~ s/\Q$output_ext\E$/$header_ext/;
5962
5963         foreach my $cond (Automake::Rule::define (${header}, 'internal',
5964                                                   RULE_AUTOMAKE, TRUE,
5965                                                   INTERNAL))
5966           {
5967             my $condstr = $cond->subst_string;
5968             $output_rules .=
5969               "$condstr${header}: $output\n"
5970               # Recover from removal of $header
5971               . "$condstr\t\@if test ! -f \$@; then rm -f $output; else :; fi\n"
5972               . "$condstr\t\@if test ! -f \$@; then \$(MAKE) \$(AM_MAKEFLAGS) $output; else :; fi\n";
5973           }
5974         # Distribute the generated file, unless its .y source was
5975         # listed in a nodist_ variable.  (&handle_source_transform
5976         # will set DIST_SOURCE.)
5977         &push_dist_common ($header)
5978           if $transform{'DIST_SOURCE'};
5979
5980         # The GNU rules say that yacc/lex output files should be removed
5981         # by maintainer-clean.  However, if the files are not distributed,
5982         # then we want to remove them with "make clean"; otherwise,
5983         # "make distcheck" will fail.
5984         $clean_files{$header} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
5985       }
5986     # See the comment above for $HEADER.
5987     $clean_files{$output} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
5988 }
5989
5990 # This is a lex helper which is called whenever we have decided to
5991 # compile a lex file.
5992 sub lang_lex_target_hook
5993 {
5994     my ($self, $aggregate, $output, $input, %transform) = @_;
5995     # The GNU rules say that yacc/lex output files should be removed
5996     # by maintainer-clean.  However, if the files are not distributed,
5997     # then we want to remove them with "make clean"; otherwise,
5998     # "make distcheck" will fail.
5999     $clean_files{$output} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
6000 }
6001
6002 # This is a helper for both lex and yacc.
6003 sub yacc_lex_finish_helper
6004 {
6005   return if defined $language_scratch{'lex-yacc-done'};
6006   $language_scratch{'lex-yacc-done'} = 1;
6007
6008   # FIXME: for now, no line number.
6009   require_conf_file ($configure_ac, FOREIGN, 'ylwrap');
6010   &define_variable ('YLWRAP', "$am_config_aux_dir/ylwrap", INTERNAL);
6011 }
6012
6013 sub lang_yacc_finish
6014 {
6015   return if defined $language_scratch{'yacc-done'};
6016   $language_scratch{'yacc-done'} = 1;
6017
6018   reject_var 'YACCFLAGS', "'YACCFLAGS' obsolete; use 'YFLAGS' instead";
6019
6020   yacc_lex_finish_helper;
6021 }
6022
6023
6024 sub lang_lex_finish
6025 {
6026   return if defined $language_scratch{'lex-done'};
6027   $language_scratch{'lex-done'} = 1;
6028
6029   yacc_lex_finish_helper;
6030 }
6031
6032
6033 # Given a hash table of linker names, pick the name that has the most
6034 # precedence.  This is lame, but something has to have global
6035 # knowledge in order to eliminate the conflict.  Add more linkers as
6036 # required.
6037 sub resolve_linker
6038 {
6039     my (%linkers) = @_;
6040
6041     foreach my $l (qw(GCJLINK OBJCXXLINK CXXLINK F77LINK FCLINK OBJCLINK UPCLINK))
6042     {
6043         return $l if defined $linkers{$l};
6044     }
6045     return 'LINK';
6046 }
6047
6048 # Called to indicate that an extension was used.
6049 sub saw_extension
6050 {
6051     my ($ext) = @_;
6052     $extension_seen{$ext} = 1;
6053 }
6054
6055 # register_language (%ATTRIBUTE)
6056 # ------------------------------
6057 # Register a single language.
6058 # Each %ATTRIBUTE is of the form ATTRIBUTE => VALUE.
6059 sub register_language (%)
6060 {
6061   my (%option) = @_;
6062
6063   # Set the defaults.
6064   $option{'autodep'} = 'no'
6065     unless defined $option{'autodep'};
6066   $option{'linker'} = ''
6067     unless defined $option{'linker'};
6068   $option{'flags'} = []
6069     unless defined $option{'flags'};
6070   $option{'output_extensions'} = sub { return ( '.$(OBJEXT)', '.lo' ) }
6071     unless defined $option{'output_extensions'};
6072   $option{'nodist_specific'} = 0
6073     unless defined $option{'nodist_specific'};
6074
6075   my $lang = new Language (%option);
6076
6077   # Fill indexes.
6078   $extension_map{$_} = $lang->name foreach @{$lang->extensions};
6079   $languages{$lang->name} = $lang;
6080   my $link = $lang->linker;
6081   if ($link)
6082     {
6083       if (exists $link_languages{$link})
6084         {
6085           prog_error ("'$link' has different definitions in "
6086                       . $lang->name . " and " . $link_languages{$link}->name)
6087             if $lang->link ne $link_languages{$link}->link;
6088         }
6089       else
6090         {
6091           $link_languages{$link} = $lang;
6092         }
6093     }
6094
6095   # Update the pattern of known extensions.
6096   accept_extensions (@{$lang->extensions});
6097
6098   # Upate the $suffix_rule map.
6099   foreach my $suffix (@{$lang->extensions})
6100     {
6101       foreach my $dest (&{$lang->output_extensions} ($suffix))
6102         {
6103           register_suffix_rule (INTERNAL, $suffix, $dest);
6104         }
6105     }
6106 }
6107
6108 # derive_suffix ($EXT, $OBJ)
6109 # --------------------------
6110 # This function is used to find a path from a user-specified suffix $EXT
6111 # to $OBJ or to some other suffix we recognize internally, e.g. 'cc'.
6112 sub derive_suffix ($$)
6113 {
6114   my ($source_ext, $obj) = @_;
6115
6116   while (! $extension_map{$source_ext}
6117          && $source_ext ne $obj
6118          && exists $suffix_rules->{$source_ext}
6119          && exists $suffix_rules->{$source_ext}{$obj})
6120     {
6121       $source_ext = $suffix_rules->{$source_ext}{$obj}[0];
6122     }
6123
6124   return $source_ext;
6125 }
6126
6127
6128 ################################################################
6129
6130 # Pretty-print something and append to output_rules.
6131 sub pretty_print_rule
6132 {
6133     $output_rules .= &makefile_wrap (@_);
6134 }
6135
6136
6137 ################################################################
6138
6139
6140 ## -------------------------------- ##
6141 ## Handling the conditional stack.  ##
6142 ## -------------------------------- ##
6143
6144
6145 # $STRING
6146 # make_conditional_string ($NEGATE, $COND)
6147 # ----------------------------------------
6148 sub make_conditional_string ($$)
6149 {
6150   my ($negate, $cond) = @_;
6151   $cond = "${cond}_TRUE"
6152     unless $cond =~ /^TRUE|FALSE$/;
6153   $cond = Automake::Condition::conditional_negate ($cond)
6154     if $negate;
6155   return $cond;
6156 }
6157
6158
6159 my %_am_macro_for_cond =
6160   (
6161   AMDEP => "one of the compiler tests\n"
6162            . "    AC_PROG_CC, AC_PROG_CXX, AC_PROG_OBJC, AC_PROG_OBJCXX,\n"
6163            . "    AM_PROG_AS, AM_PROG_GCJ, AM_PROG_UPC",
6164   am__fastdepCC => 'AC_PROG_CC',
6165   am__fastdepCCAS => 'AM_PROG_AS',
6166   am__fastdepCXX => 'AC_PROG_CXX',
6167   am__fastdepGCJ => 'AM_PROG_GCJ',
6168   am__fastdepOBJC => 'AC_PROG_OBJC',
6169   am__fastdepOBJCXX => 'AC_PROG_OBJCXX',
6170   am__fastdepUPC => 'AM_PROG_UPC'
6171   );
6172
6173 # $COND
6174 # cond_stack_if ($NEGATE, $COND, $WHERE)
6175 # --------------------------------------
6176 sub cond_stack_if ($$$)
6177 {
6178   my ($negate, $cond, $where) = @_;
6179
6180   if (! $configure_cond{$cond} && $cond !~ /^TRUE|FALSE$/)
6181     {
6182       my $text = "$cond does not appear in AM_CONDITIONAL";
6183       my $scope = US_LOCAL;
6184       if (exists $_am_macro_for_cond{$cond})
6185         {
6186           my $mac = $_am_macro_for_cond{$cond};
6187           $text .= "\n  The usual way to define '$cond' is to add ";
6188           $text .= ($mac =~ / /) ? $mac : "'$mac'";
6189           $text .= "\n  to '$configure_ac' and run 'aclocal' and 'autoconf' again";
6190           # These warnings appear in Automake files (depend2.am),
6191           # so there is no need to display them more than once:
6192           $scope = US_GLOBAL;
6193         }
6194       error $where, $text, uniq_scope => $scope;
6195     }
6196
6197   push (@cond_stack, make_conditional_string ($negate, $cond));
6198
6199   return new Automake::Condition (@cond_stack);
6200 }
6201
6202
6203 # $COND
6204 # cond_stack_else ($NEGATE, $COND, $WHERE)
6205 # ----------------------------------------
6206 sub cond_stack_else ($$$)
6207 {
6208   my ($negate, $cond, $where) = @_;
6209
6210   if (! @cond_stack)
6211     {
6212       error $where, "else without if";
6213       return FALSE;
6214     }
6215
6216   $cond_stack[$#cond_stack] =
6217     Automake::Condition::conditional_negate ($cond_stack[$#cond_stack]);
6218
6219   # If $COND is given, check against it.
6220   if (defined $cond)
6221     {
6222       $cond = make_conditional_string ($negate, $cond);
6223
6224       error ($where, "else reminder ($negate$cond) incompatible with "
6225              . "current conditional: $cond_stack[$#cond_stack]")
6226         if $cond_stack[$#cond_stack] ne $cond;
6227     }
6228
6229   return new Automake::Condition (@cond_stack);
6230 }
6231
6232
6233 # $COND
6234 # cond_stack_endif ($NEGATE, $COND, $WHERE)
6235 # -----------------------------------------
6236 sub cond_stack_endif ($$$)
6237 {
6238   my ($negate, $cond, $where) = @_;
6239   my $old_cond;
6240
6241   if (! @cond_stack)
6242     {
6243       error $where, "endif without if";
6244       return TRUE;
6245     }
6246
6247   # If $COND is given, check against it.
6248   if (defined $cond)
6249     {
6250       $cond = make_conditional_string ($negate, $cond);
6251
6252       error ($where, "endif reminder ($negate$cond) incompatible with "
6253              . "current conditional: $cond_stack[$#cond_stack]")
6254         if $cond_stack[$#cond_stack] ne $cond;
6255     }
6256
6257   pop @cond_stack;
6258
6259   return new Automake::Condition (@cond_stack);
6260 }
6261
6262
6263
6264
6265
6266 ## ------------------------ ##
6267 ## Handling the variables.  ##
6268 ## ------------------------ ##
6269
6270
6271 # &define_pretty_variable ($VAR, $COND, $WHERE, @VALUE)
6272 # -----------------------------------------------------
6273 # Like define_variable, but the value is a list, and the variable may
6274 # be defined conditionally.  The second argument is the condition
6275 # under which the value should be defined; this should be the empty
6276 # string to define the variable unconditionally.  The third argument
6277 # is a list holding the values to use for the variable.  The value is
6278 # pretty printed in the output file.
6279 sub define_pretty_variable ($$$@)
6280 {
6281     my ($var, $cond, $where, @value) = @_;
6282
6283     if (! vardef ($var, $cond))
6284     {
6285         Automake::Variable::define ($var, VAR_AUTOMAKE, '', $cond, "@value",
6286                                     '', $where, VAR_PRETTY);
6287         rvar ($var)->rdef ($cond)->set_seen;
6288     }
6289 }
6290
6291
6292 # define_variable ($VAR, $VALUE, $WHERE)
6293 # --------------------------------------
6294 # Define a new Automake Makefile variable VAR to VALUE, but only if
6295 # not already defined.
6296 sub define_variable ($$$)
6297 {
6298     my ($var, $value, $where) = @_;
6299     define_pretty_variable ($var, TRUE, $where, $value);
6300 }
6301
6302
6303 # define_files_variable ($VAR, \@BASENAME, $EXTENSION, $WHERE)
6304 # ------------------------------------------------------------
6305 # Define the $VAR which content is the list of file names composed of
6306 # a @BASENAME and the $EXTENSION.
6307 sub define_files_variable ($\@$$)
6308 {
6309   my ($var, $basename, $extension, $where) = @_;
6310   define_variable ($var,
6311                    join (' ', map { "$_.$extension" } @$basename),
6312                    $where);
6313 }
6314
6315
6316 # Like define_variable, but define a variable to be the configure
6317 # substitution by the same name.
6318 sub define_configure_variable ($)
6319 {
6320   my ($var) = @_;
6321   # Some variables we do not want to output.  For instance it
6322   # would be a bad idea to output `U = @U@` when `@U@` can be
6323   # substituted as `\`.
6324   my $pretty = exists $ignored_configure_vars{$var} ? VAR_SILENT : VAR_ASIS;
6325   Automake::Variable::define ($var, VAR_CONFIGURE, '', TRUE, subst $var,
6326                               '', $configure_vars{$var}, $pretty);
6327 }
6328
6329
6330 # define_compiler_variable ($LANG)
6331 # --------------------------------
6332 # Define a compiler variable.  We also handle defining the 'LT'
6333 # version of the command when using libtool.
6334 sub define_compiler_variable ($)
6335 {
6336     my ($lang) = @_;
6337
6338     my ($var, $value) = ($lang->compiler, $lang->compile);
6339     my $libtool_tag = '';
6340     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6341       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6342     &define_variable ($var, $value, INTERNAL);
6343     if (var ('LIBTOOL'))
6344       {
6345         my $verbose = define_verbose_libtool ();
6346         &define_variable ("LT$var",
6347                           "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) "
6348                           . "\$(LIBTOOLFLAGS) --mode=compile $value",
6349                           INTERNAL);
6350       }
6351     define_verbose_tagvar ($lang->ccer || 'GEN');
6352 }
6353
6354
6355 # define_linker_variable ($LANG)
6356 # ------------------------------
6357 # Define linker variables.
6358 sub define_linker_variable ($)
6359 {
6360     my ($lang) = @_;
6361
6362     my $libtool_tag = '';
6363     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6364       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6365     # CCLD = $(CC).
6366     &define_variable ($lang->lder, $lang->ld, INTERNAL);
6367     # CCLINK = $(CCLD) blah blah...
6368     my $link = '';
6369     if (var ('LIBTOOL'))
6370       {
6371         my $verbose = define_verbose_libtool ();
6372         $link = "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) "
6373                 . "\$(LIBTOOLFLAGS) --mode=link ";
6374       }
6375     &define_variable ($lang->linker, $link . $lang->link, INTERNAL);
6376     &define_variable ($lang->compiler,  $lang);
6377     &define_verbose_tagvar ($lang->lder || 'GEN');
6378 }
6379
6380 sub define_per_target_linker_variable ($$)
6381 {
6382   my ($linker, $target) = @_;
6383
6384   # If the user wrote a custom link command, we don't define ours.
6385   return "${target}_LINK"
6386     if set_seen "${target}_LINK";
6387
6388   my $xlink = $linker ? $linker : 'LINK';
6389
6390   my $lang = $link_languages{$xlink};
6391   prog_error "Unknown language for linker variable '$xlink'"
6392     unless $lang;
6393
6394   my $link_command = $lang->link;
6395   if (var 'LIBTOOL')
6396     {
6397       my $libtool_tag = '';
6398       $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6399         if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6400
6401       my $verbose = define_verbose_libtool ();
6402       $link_command =
6403         "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) \$(LIBTOOLFLAGS) "
6404         . "--mode=link " . $link_command;
6405     }
6406
6407   # Rewrite each occurrence of 'AM_$flag' in the link
6408   # command into '${derived}_$flag' if it exists.
6409   my $orig_command = $link_command;
6410   my @flags = (@{$lang->flags}, 'LDFLAGS');
6411   push @flags, 'LIBTOOLFLAGS' if var 'LIBTOOL';
6412   for my $flag (@flags)
6413     {
6414       my $val = "${target}_$flag";
6415       $link_command =~ s/\(AM_$flag\)/\($val\)/
6416         if set_seen ($val);
6417     }
6418
6419   # If the computed command is the same as the generic command, use
6420   # the command linker variable.
6421   return ($lang->linker, $lang->lder)
6422     if $link_command eq $orig_command;
6423
6424   &define_variable ("${target}_LINK", $link_command, INTERNAL);
6425   return ("${target}_LINK", $lang->lder);
6426 }
6427
6428 ################################################################
6429
6430 # &check_trailing_slash ($WHERE, $LINE)
6431 # -------------------------------------
6432 # Return 1 iff $LINE ends with a slash.
6433 # Might modify $LINE.
6434 sub check_trailing_slash ($\$)
6435 {
6436   my ($where, $line) = @_;
6437
6438   # Ignore '##' lines.
6439   return 0 if $$line =~ /$IGNORE_PATTERN/o;
6440
6441   # Catch and fix a common error.
6442   msg "syntax", $where, "whitespace following trailing backslash"
6443     if $$line =~ s/\\\s+\n$/\\\n/;
6444
6445   return $$line =~ /\\$/;
6446 }
6447
6448
6449 # &read_am_file ($AMFILE, $WHERE)
6450 # -------------------------------
6451 # Read Makefile.am and set up %contents.  Simultaneously copy lines
6452 # from Makefile.am into $output_trailer, or define variables as
6453 # appropriate.  NOTE we put rules in the trailer section.  We want
6454 # user rules to come after our generated stuff.
6455 sub read_am_file ($$)
6456 {
6457     my ($amfile, $where) = @_;
6458
6459     my $am_file = new Automake::XFile ("< $amfile");
6460     verb "reading $amfile";
6461
6462     # Keep track of the youngest output dependency.
6463     my $mtime = mtime $amfile;
6464     $output_deps_greatest_timestamp = $mtime
6465       if $mtime > $output_deps_greatest_timestamp;
6466
6467     my $spacing = '';
6468     my $comment = '';
6469     my $blank = 0;
6470     my $saw_bk = 0;
6471     my $var_look = VAR_ASIS;
6472
6473     use constant IN_VAR_DEF => 0;
6474     use constant IN_RULE_DEF => 1;
6475     use constant IN_COMMENT => 2;
6476     my $prev_state = IN_RULE_DEF;
6477
6478     while ($_ = $am_file->getline)
6479     {
6480         $where->set ("$amfile:$.");
6481         if (/$IGNORE_PATTERN/o)
6482         {
6483             # Merely delete comments beginning with two hashes.
6484         }
6485         elsif (/$WHITE_PATTERN/o)
6486         {
6487             error $where, "blank line following trailing backslash"
6488               if $saw_bk;
6489             # Stick a single white line before the incoming macro or rule.
6490             $spacing = "\n";
6491             $blank = 1;
6492             # Flush all comments seen so far.
6493             if ($comment ne '')
6494             {
6495                 $output_vars .= $comment;
6496                 $comment = '';
6497             }
6498         }
6499         elsif (/$COMMENT_PATTERN/o)
6500         {
6501             # Stick comments before the incoming macro or rule.  Make
6502             # sure a blank line precedes the first block of comments.
6503             $spacing = "\n" unless $blank;
6504             $blank = 1;
6505             $comment .= $spacing . $_;
6506             $spacing = '';
6507             $prev_state = IN_COMMENT;
6508         }
6509         else
6510         {
6511             last;
6512         }
6513         $saw_bk = check_trailing_slash ($where, $_);
6514     }
6515
6516     # We save the conditional stack on entry, and then check to make
6517     # sure it is the same on exit.  This lets us conditionally include
6518     # other files.
6519     my @saved_cond_stack = @cond_stack;
6520     my $cond = new Automake::Condition (@cond_stack);
6521
6522     my $last_var_name = '';
6523     my $last_var_type = '';
6524     my $last_var_value = '';
6525     my $last_where;
6526     # FIXME: shouldn't use $_ in this loop; it is too big.
6527     while ($_)
6528     {
6529         $where->set ("$amfile:$.");
6530
6531         # Make sure the line is \n-terminated.
6532         chomp;
6533         $_ .= "\n";
6534
6535         # Don't look at MAINTAINER_MODE_TRUE here.  That shouldn't be
6536         # used by users.  @MAINT@ is an anachronism now.
6537         $_ =~ s/\@MAINT\@//g
6538             unless $seen_maint_mode;
6539
6540         my $new_saw_bk = check_trailing_slash ($where, $_);
6541
6542         if (/$IGNORE_PATTERN/o)
6543         {
6544             # Merely delete comments beginning with two hashes.
6545
6546             # Keep any backslash from the previous line.
6547             $new_saw_bk = $saw_bk;
6548         }
6549         elsif (/$WHITE_PATTERN/o)
6550         {
6551             # Stick a single white line before the incoming macro or rule.
6552             $spacing = "\n";
6553             error $where, "blank line following trailing backslash"
6554               if $saw_bk;
6555         }
6556         elsif (/$COMMENT_PATTERN/o)
6557         {
6558             error $where, "comment following trailing backslash"
6559               if $saw_bk && $prev_state != IN_COMMENT;
6560
6561             # Stick comments before the incoming macro or rule.
6562             $comment .= $spacing . $_;
6563             $spacing = '';
6564             $prev_state = IN_COMMENT;
6565         }
6566         elsif ($saw_bk)
6567         {
6568             if ($prev_state == IN_RULE_DEF)
6569             {
6570               my $cond = new Automake::Condition @cond_stack;
6571               $output_trailer .= $cond->subst_string;
6572               $output_trailer .= $_;
6573             }
6574             elsif ($prev_state == IN_COMMENT)
6575             {
6576                 # If the line doesn't start with a '#', add it.
6577                 # We do this because a continued comment like
6578                 #   # A = foo \
6579                 #         bar \
6580                 #         baz
6581                 # is not portable.  BSD make doesn't honor
6582                 # escaped newlines in comments.
6583                 s/^#?/#/;
6584                 $comment .= $spacing . $_;
6585             }
6586             else # $prev_state == IN_VAR_DEF
6587             {
6588               $last_var_value .= ' '
6589                 unless $last_var_value =~ /\s$/;
6590               $last_var_value .= $_;
6591
6592               if (!/\\$/)
6593                 {
6594                   Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6595                                               $last_var_type, $cond,
6596                                               $last_var_value, $comment,
6597                                               $last_where, VAR_ASIS)
6598                     if $cond != FALSE;
6599                   $comment = $spacing = '';
6600                 }
6601             }
6602         }
6603
6604         elsif (/$IF_PATTERN/o)
6605           {
6606             $cond = cond_stack_if ($1, $2, $where);
6607           }
6608         elsif (/$ELSE_PATTERN/o)
6609           {
6610             $cond = cond_stack_else ($1, $2, $where);
6611           }
6612         elsif (/$ENDIF_PATTERN/o)
6613           {
6614             $cond = cond_stack_endif ($1, $2, $where);
6615           }
6616
6617         elsif (/$RULE_PATTERN/o)
6618         {
6619             # Found a rule.
6620             $prev_state = IN_RULE_DEF;
6621
6622             # For now we have to output all definitions of user rules
6623             # and can't diagnose duplicates (see the comment in
6624             # Automake::Rule::define). So we go on and ignore the return value.
6625             Automake::Rule::define ($1, $amfile, RULE_USER, $cond, $where);
6626
6627             check_variable_expansions ($_, $where);
6628
6629             $output_trailer .= $comment . $spacing;
6630             my $cond = new Automake::Condition @cond_stack;
6631             $output_trailer .= $cond->subst_string;
6632             $output_trailer .= $_;
6633             $comment = $spacing = '';
6634         }
6635         elsif (/$ASSIGNMENT_PATTERN/o)
6636         {
6637             # Found a macro definition.
6638             $prev_state = IN_VAR_DEF;
6639             $last_var_name = $1;
6640             $last_var_type = $2;
6641             $last_var_value = $3;
6642             $last_where = $where->clone;
6643             if ($3 ne '' && substr ($3, -1) eq "\\")
6644               {
6645                 # We preserve the '\' because otherwise the long lines
6646                 # that are generated will be truncated by broken
6647                 # 'sed's.
6648                 $last_var_value = $3 . "\n";
6649               }
6650             # Normally we try to output variable definitions in the
6651             # same format they were input.  However, POSIX compliant
6652             # systems are not required to support lines longer than
6653             # 2048 bytes (most notably, some sed implementation are
6654             # limited to 4000 bytes, and sed is used by config.status
6655             # to rewrite Makefile.in into Makefile).  Moreover nobody
6656             # would really write such long lines by hand since it is
6657             # hardly maintainable.  So if a line is longer that 1000
6658             # bytes (an arbitrary limit), assume it has been
6659             # automatically generated by some tools, and flatten the
6660             # variable definition.  Otherwise, keep the variable as it
6661             # as been input.
6662             $var_look = VAR_PRETTY if length ($last_var_value) >= 1000;
6663
6664             if (!/\\$/)
6665               {
6666                 Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6667                                             $last_var_type, $cond,
6668                                             $last_var_value, $comment,
6669                                             $last_where, $var_look)
6670                   if $cond != FALSE;
6671                 $comment = $spacing = '';
6672                 $var_look = VAR_ASIS;
6673               }
6674         }
6675         elsif (/$INCLUDE_PATTERN/o)
6676         {
6677             my $path = $1;
6678
6679             if ($path =~ s/^\$\(top_srcdir\)\///)
6680               {
6681                 push (@include_stack, "\$\(top_srcdir\)/$path");
6682                 # Distribute any included file.
6683
6684                 # Always use the $(top_srcdir) prefix in DIST_COMMON,
6685                 # otherwise OSF make will implicitly copy the included
6686                 # file in the build tree during "make distdir" to satisfy
6687                 # the dependency.
6688                 # (subdircond2.test and subdircond3.test will fail.)
6689                 push_dist_common ("\$\(top_srcdir\)/$path");
6690               }
6691             else
6692               {
6693                 $path =~ s/\$\(srcdir\)\///;
6694                 push (@include_stack, "\$\(srcdir\)/$path");
6695                 # Always use the $(srcdir) prefix in DIST_COMMON,
6696                 # otherwise OSF make will implicitly copy the included
6697                 # file in the build tree during "make distdir" to satisfy
6698                 # the dependency.
6699                 # (subdircond2.test and subdircond3.test will fail.)
6700                 push_dist_common ("\$\(srcdir\)/$path");
6701                 $path = $relative_dir . "/" . $path if $relative_dir ne '.';
6702               }
6703             $where->push_context ("'$path' included from here");
6704             &read_am_file ($path, $where);
6705             $where->pop_context;
6706         }
6707         else
6708         {
6709             # This isn't an error; it is probably a continued rule.
6710             # In fact, this is what we assume.
6711             $prev_state = IN_RULE_DEF;
6712             check_variable_expansions ($_, $where);
6713             $output_trailer .= $comment . $spacing;
6714             my $cond = new Automake::Condition @cond_stack;
6715             $output_trailer .= $cond->subst_string;
6716             $output_trailer .= $_;
6717             $comment = $spacing = '';
6718             error $where, "'#' comment at start of rule is unportable"
6719               if $_ =~ /^\t\s*\#/;
6720         }
6721
6722         $saw_bk = $new_saw_bk;
6723         $_ = $am_file->getline;
6724     }
6725
6726     $output_trailer .= $comment;
6727
6728     error ($where, "trailing backslash on last line")
6729       if $saw_bk;
6730
6731     error ($where, (@cond_stack ? "unterminated conditionals: @cond_stack"
6732                     : "too many conditionals closed in include file"))
6733       if "@saved_cond_stack" ne "@cond_stack";
6734 }
6735
6736
6737 # define_standard_variables ()
6738 # ----------------------------
6739 # A helper for read_main_am_file which initializes configure variables
6740 # and variables from header-vars.am.
6741 sub define_standard_variables
6742 {
6743   my $saved_output_vars = $output_vars;
6744   my ($comments, undef, $rules) =
6745     file_contents_internal (1, "$libdir/am/header-vars.am",
6746                             new Automake::Location);
6747
6748   foreach my $var (sort keys %configure_vars)
6749     {
6750       &define_configure_variable ($var);
6751     }
6752
6753   $output_vars .= $comments . $rules;
6754 }
6755
6756 # Read main am file.
6757 sub read_main_am_file
6758 {
6759     my ($amfile) = @_;
6760
6761     # This supports the strange variable tricks we are about to play.
6762     prog_error ("variable defined before read_main_am_file\n" . variables_dump ())
6763       if (scalar (variables) > 0);
6764
6765     # Generate copyright header for generated Makefile.in.
6766     # We do discard the output of predefined variables, handled below.
6767     $output_vars = ("# $in_file_name generated by automake "
6768                    . $VERSION . " from $am_file_name.\n");
6769     $output_vars .= '# ' . subst ('configure_input') . "\n";
6770     $output_vars .= $gen_copyright;
6771
6772     # We want to predefine as many variables as possible.  This lets
6773     # the user set them with '+=' in Makefile.am.
6774     &define_standard_variables;
6775
6776     # Read user file, which might override some of our values.
6777     &read_am_file ($amfile, new Automake::Location);
6778 }
6779
6780
6781
6782 ################################################################
6783
6784 # $FLATTENED
6785 # &flatten ($STRING)
6786 # ------------------
6787 # Flatten the $STRING and return the result.
6788 sub flatten
6789 {
6790   $_ = shift;
6791
6792   s/\\\n//somg;
6793   s/\s+/ /g;
6794   s/^ //;
6795   s/ $//;
6796
6797   return $_;
6798 }
6799
6800
6801 # transform_token ($TOKEN, \%PAIRS, $KEY)
6802 # =======================================
6803 # Return the value associated to $KEY in %PAIRS, as used on $TOKEN
6804 # (which should be ?KEY? or any of the special %% requests)..
6805 sub transform_token ($$$)
6806 {
6807   my ($token, $transform, $key) = @_;
6808   my $res = $transform->{$key};
6809   prog_error "Unknown key '$key' in '$token'" unless defined $res;
6810   return $res;
6811 }
6812
6813
6814 # transform ($TOKEN, \%PAIRS)
6815 # ===========================
6816 # If ($TOKEN, $VAL) is in %PAIRS:
6817 #   - replaces %KEY% with $VAL,
6818 #   - enables/disables ?KEY? and ?!KEY?,
6819 #   - replaces %?KEY% with TRUE or FALSE.
6820 #   - replaces %KEY?IFTRUE%, %KEY:IFFALSE%, and %KEY?IFTRUE:IFFALSE% with
6821 #     IFTRUE / IFFALSE, as appropriate.
6822 sub transform ($$)
6823 {
6824   my ($token, $transform) = @_;
6825
6826   # %KEY%.
6827   # Must be before the following pattern to exclude the case
6828   # when there is neither IFTRUE nor IFFALSE.
6829   if ($token =~ /^%([\w\-]+)%$/)
6830     {
6831       return transform_token ($token, $transform, $1);
6832     }
6833   # %KEY?IFTRUE%, %KEY:IFFALSE%, and %KEY?IFTRUE:IFFALSE%.
6834   elsif ($token =~ /^%([\w\-]+)(?:\?([^?:%]+))?(?::([^?:%]+))?%$/)
6835     {
6836       return transform_token ($token, $transform, $1) ? ($2 || '') : ($3 || '');
6837     }
6838   # %?KEY%.
6839   elsif ($token =~ /^%\?([\w\-]+)%$/)
6840     {
6841       return transform_token ($token, $transform, $1) ? 'TRUE' : 'FALSE';
6842     }
6843   # ?KEY? and ?!KEY?.
6844   elsif ($token =~ /^ \? (!?) ([\w\-]+) \? $/x)
6845     {
6846       my $neg = ($1 eq '!') ? 1 : 0;
6847       my $val = transform_token ($token, $transform, $2);
6848       return (!!$val == $neg) ? '##%' : '';
6849     }
6850   else
6851     {
6852       prog_error "Unknown request format: $token";
6853     }
6854 }
6855
6856 # $TEXT
6857 # preprocess_file ($MAKEFILE, [%TRANSFORM])
6858 # -----------------------------------------
6859 # Load a $MAKEFILE, apply the %TRANSFORM, and return the result.
6860 # No extra parsing of post-processing is done (i.e., recognition of
6861 # rules declaration or of make variables definitions).
6862 sub preprocess_file ($%)
6863 {
6864   my ($file, %transform) = @_;
6865
6866   # Complete %transform with global options.
6867   # Note that %transform goes last, so it overrides global options.
6868   %transform = ( 'MAINTAINER-MODE'
6869                  => $seen_maint_mode ? subst ('MAINTAINER_MODE_TRUE') : '',
6870
6871                  'XZ'          => !! option 'dist-xz',
6872                  'LZMA'        => !! option 'dist-lzma',
6873                  'LZIP'        => !! option 'dist-lzip',
6874                  'BZIP2'       => !! option 'dist-bzip2',
6875                  'COMPRESS'    => !! option 'dist-tarZ',
6876                  'GZIP'        =>  ! option 'no-dist-gzip',
6877                  'SHAR'        => !! option 'dist-shar',
6878                  'ZIP'         => !! option 'dist-zip',
6879
6880                  'INSTALL-INFO' =>  ! option 'no-installinfo',
6881                  'INSTALL-MAN'  =>  ! option 'no-installman',
6882                  'HAVE-MANS'    => !! var ('MANS'),
6883                  'CK-NEWS'      => !! option 'check-news',
6884
6885                  'SUBDIRS'      => !! var ('SUBDIRS'),
6886                  'TOPDIR_P'     => $relative_dir eq '.',
6887
6888                  'BUILD'    => ($seen_canonical >= AC_CANONICAL_BUILD),
6889                  'HOST'     => ($seen_canonical >= AC_CANONICAL_HOST),
6890                  'TARGET'   => ($seen_canonical >= AC_CANONICAL_TARGET),
6891
6892                  'LIBTOOL'      => !! var ('LIBTOOL'),
6893                  'NONLIBTOOL'   => 1,
6894                 %transform);
6895
6896   if (! defined ($_ = $am_file_cache{$file}))
6897     {
6898       verb "reading $file";
6899       # Swallow the whole file.
6900       my $fc_file = new Automake::XFile "< $file";
6901       my $saved_dollar_slash = $/;
6902       undef $/;
6903       $_ = $fc_file->getline;
6904       $/ = $saved_dollar_slash;
6905       $fc_file->close;
6906       # Remove ##-comments.
6907       # Besides we don't need more than two consecutive new-lines.
6908       s/(?:$IGNORE_PATTERN|(?<=\n\n)\n+)//gom;
6909       # Remember the contents of the just-read file.
6910       $am_file_cache{$file} = $_;
6911     }
6912
6913   # Substitute Automake template tokens.
6914   s/(?: % \?? [\w\-]+ %
6915       | % [\w\-]+ (?:\?[^?:%]+)? (?::[^?:%]+)? %
6916       | \? !? [\w\-]+ \?
6917     )/transform($&, \%transform)/gex;
6918   # transform() may have added some ##%-comments to strip.
6919   # (we use '##%' instead of '##' so we can distinguish ##%##%##% from
6920   # ####### and do not remove the latter.)
6921   s/^[ \t]*(?:##%)+.*\n//gm;
6922
6923   return $_;
6924 }
6925
6926
6927 # @PARAGRAPHS
6928 # &make_paragraphs ($MAKEFILE, [%TRANSFORM])
6929 # ------------------------------------------
6930 # Load a $MAKEFILE, apply the %TRANSFORM, and return it as a list of
6931 # paragraphs.
6932 sub make_paragraphs ($%)
6933 {
6934   my ($file, %transform) = @_;
6935   $transform{FIRST} = !$transformed_files{$file};
6936   $transformed_files{$file} = 1;
6937
6938   my @lines = split /(?<!\\)\n/, preprocess_file ($file, %transform);
6939   my @res;
6940
6941   while (defined ($_ = shift @lines))
6942     {
6943       my $paragraph = $_;
6944       # If we are a rule, eat as long as we start with a tab.
6945       if (/$RULE_PATTERN/smo)
6946         {
6947           while (defined ($_ = shift @lines) && $_ =~ /^\t/)
6948             {
6949               $paragraph .= "\n$_";
6950             }
6951           unshift (@lines, $_);
6952         }
6953
6954       # If we are a comments, eat as much comments as you can.
6955       elsif (/$COMMENT_PATTERN/smo)
6956         {
6957           while (defined ($_ = shift @lines)
6958                  && $_ =~ /$COMMENT_PATTERN/smo)
6959             {
6960               $paragraph .= "\n$_";
6961             }
6962           unshift (@lines, $_);
6963         }
6964
6965       push @res, $paragraph;
6966     }
6967
6968   return @res;
6969 }
6970
6971
6972
6973 # ($COMMENT, $VARIABLES, $RULES)
6974 # &file_contents_internal ($IS_AM, $FILE, $WHERE, [%TRANSFORM])
6975 # -------------------------------------------------------------
6976 # Return contents of a file from $libdir/am, automatically skipping
6977 # macros or rules which are already known. $IS_AM iff the caller is
6978 # reading an Automake file (as opposed to the user's Makefile.am).
6979 sub file_contents_internal ($$$%)
6980 {
6981     my ($is_am, $file, $where, %transform) = @_;
6982
6983     $where->set ($file);
6984
6985     my $result_vars = '';
6986     my $result_rules = '';
6987     my $comment = '';
6988     my $spacing = '';
6989
6990     # The following flags are used to track rules spanning across
6991     # multiple paragraphs.
6992     my $is_rule = 0;            # 1 if we are processing a rule.
6993     my $discard_rule = 0;       # 1 if the current rule should not be output.
6994
6995     # We save the conditional stack on entry, and then check to make
6996     # sure it is the same on exit.  This lets us conditionally include
6997     # other files.
6998     my @saved_cond_stack = @cond_stack;
6999     my $cond = new Automake::Condition (@cond_stack);
7000
7001     foreach (make_paragraphs ($file, %transform))
7002     {
7003         # FIXME: no line number available.
7004         $where->set ($file);
7005
7006         # Sanity checks.
7007         error $where, "blank line following trailing backslash:\n$_"
7008           if /\\$/;
7009         error $where, "comment following trailing backslash:\n$_"
7010           if /\\#/;
7011
7012         if (/^$/)
7013         {
7014             $is_rule = 0;
7015             # Stick empty line before the incoming macro or rule.
7016             $spacing = "\n";
7017         }
7018         elsif (/$COMMENT_PATTERN/mso)
7019         {
7020             $is_rule = 0;
7021             # Stick comments before the incoming macro or rule.
7022             $comment = "$_\n";
7023         }
7024
7025         # Handle inclusion of other files.
7026         elsif (/$INCLUDE_PATTERN/o)
7027         {
7028             if ($cond != FALSE)
7029               {
7030                 my $file = ($is_am ? "$libdir/am/" : '') . $1;
7031                 $where->push_context ("'$file' included from here");
7032                 # N-ary '.=' fails.
7033                 my ($com, $vars, $rules)
7034                   = file_contents_internal ($is_am, $file, $where, %transform);
7035                 $where->pop_context;
7036                 $comment .= $com;
7037                 $result_vars .= $vars;
7038                 $result_rules .= $rules;
7039               }
7040         }
7041
7042         # Handling the conditionals.
7043         elsif (/$IF_PATTERN/o)
7044           {
7045             $cond = cond_stack_if ($1, $2, $file);
7046           }
7047         elsif (/$ELSE_PATTERN/o)
7048           {
7049             $cond = cond_stack_else ($1, $2, $file);
7050           }
7051         elsif (/$ENDIF_PATTERN/o)
7052           {
7053             $cond = cond_stack_endif ($1, $2, $file);
7054           }
7055
7056         # Handling rules.
7057         elsif (/$RULE_PATTERN/mso)
7058         {
7059           $is_rule = 1;
7060           $discard_rule = 0;
7061           # Separate relationship from optional actions: the first
7062           # `new-line tab" not preceded by backslash (continuation
7063           # line).
7064           my $paragraph = $_;
7065           /^(.*?)(?:(?<!\\)\n(\t.*))?$/s;
7066           my ($relationship, $actions) = ($1, $2 || '');
7067
7068           # Separate targets from dependencies: the first colon.
7069           $relationship =~ /^([^:]+\S+) *: *(.*)$/som;
7070           my ($targets, $dependencies) = ($1, $2);
7071           # Remove the escaped new lines.
7072           # I don't know why, but I have to use a tmp $flat_deps.
7073           my $flat_deps = &flatten ($dependencies);
7074           my @deps = split (' ', $flat_deps);
7075
7076           foreach (split (' ', $targets))
7077             {
7078               # FIXME: 1. We are not robust to people defining several targets
7079               # at once, only some of them being in %dependencies.  The
7080               # actions from the targets in %dependencies are usually generated
7081               # from the content of %actions, but if some targets in $targets
7082               # are not in %dependencies the ELSE branch will output
7083               # a rule for all $targets (i.e. the targets which are both
7084               # in %dependencies and $targets will have two rules).
7085
7086               # FIXME: 2. The logic here is not able to output a
7087               # multi-paragraph rule several time (e.g. for each condition
7088               # it is defined for) because it only knows the first paragraph.
7089
7090               # FIXME: 3. We are not robust to people defining a subset
7091               # of a previously defined "multiple-target" rule.  E.g.
7092               # 'foo:' after 'foo bar:'.
7093
7094               # Output only if not in FALSE.
7095               if (defined $dependencies{$_} && $cond != FALSE)
7096                 {
7097                   &depend ($_, @deps);
7098                   register_action ($_, $actions);
7099                 }
7100               else
7101                 {
7102                   # Free-lance dependency.  Output the rule for all the
7103                   # targets instead of one by one.
7104                   my @undefined_conds =
7105                     Automake::Rule::define ($targets, $file,
7106                                             $is_am ? RULE_AUTOMAKE : RULE_USER,
7107                                             $cond, $where);
7108                   for my $undefined_cond (@undefined_conds)
7109                     {
7110                       my $condparagraph = $paragraph;
7111                       $condparagraph =~ s/^/$undefined_cond->subst_string/gme;
7112                       $result_rules .= "$spacing$comment$condparagraph\n";
7113                     }
7114                   if (scalar @undefined_conds == 0)
7115                     {
7116                       # Remember to discard next paragraphs
7117                       # if they belong to this rule.
7118                       # (but see also FIXME: #2 above.)
7119                       $discard_rule = 1;
7120                     }
7121                   $comment = $spacing = '';
7122                   last;
7123                 }
7124             }
7125         }
7126
7127         elsif (/$ASSIGNMENT_PATTERN/mso)
7128         {
7129             my ($var, $type, $val) = ($1, $2, $3);
7130             error $where, "variable '$var' with trailing backslash"
7131               if /\\$/;
7132
7133             $is_rule = 0;
7134
7135             Automake::Variable::define ($var,
7136                                         $is_am ? VAR_AUTOMAKE : VAR_MAKEFILE,
7137                                         $type, $cond, $val, $comment, $where,
7138                                         VAR_ASIS)
7139               if $cond != FALSE;
7140
7141             $comment = $spacing = '';
7142         }
7143         else
7144         {
7145             # This isn't an error; it is probably some tokens which
7146             # configure is supposed to replace, such as '@SET-MAKE@',
7147             # or some part of a rule cut by an if/endif.
7148             if (! $cond->false && ! ($is_rule && $discard_rule))
7149               {
7150                 s/^/$cond->subst_string/gme;
7151                 $result_rules .= "$spacing$comment$_\n";
7152               }
7153             $comment = $spacing = '';
7154         }
7155     }
7156
7157     error ($where, @cond_stack ?
7158            "unterminated conditionals: @cond_stack" :
7159            "too many conditionals closed in include file")
7160       if "@saved_cond_stack" ne "@cond_stack";
7161
7162     return ($comment, $result_vars, $result_rules);
7163 }
7164
7165
7166 # $CONTENTS
7167 # &file_contents ($BASENAME, $WHERE, [%TRANSFORM])
7168 # ------------------------------------------------
7169 # Return contents of a file from $libdir/am, automatically skipping
7170 # macros or rules which are already known.
7171 sub file_contents ($$%)
7172 {
7173     my ($basename, $where, %transform) = @_;
7174     my ($comments, $variables, $rules) =
7175       file_contents_internal (1, "$libdir/am/$basename.am", $where,
7176                               %transform);
7177     return "$comments$variables$rules";
7178 }
7179
7180
7181 # @PREFIX
7182 # &am_primary_prefixes ($PRIMARY, $CAN_DIST, @PREFIXES)
7183 # -----------------------------------------------------
7184 # Find all variable prefixes that are used for install directories.  A
7185 # prefix 'zar' qualifies iff:
7186 #
7187 # * 'zardir' is a variable.
7188 # * 'zar_PRIMARY' is a variable.
7189 #
7190 # As a side effect, it looks for misspellings.  It is an error to have
7191 # a variable ending in a "reserved" suffix whose prefix is unknown, e.g.
7192 # "bni_PROGRAMS".  However, unusual prefixes are allowed if a variable
7193 # of the same name (with "dir" appended) exists.  For instance, if the
7194 # variable "zardir" is defined, then "zar_PROGRAMS" becomes valid.
7195 # This is to provide a little extra flexibility in those cases which
7196 # need it.
7197 sub am_primary_prefixes ($$@)
7198 {
7199   my ($primary, $can_dist, @prefixes) = @_;
7200
7201   local $_;
7202   my %valid = map { $_ => 0 } @prefixes;
7203   $valid{'EXTRA'} = 0;
7204   foreach my $var (variables $primary)
7205     {
7206       # Automake is allowed to define variables that look like primaries
7207       # but which aren't.  E.g. INSTALL_sh_DATA.
7208       # Autoconf can also define variables like INSTALL_DATA, so
7209       # ignore all configure variables (at least those which are not
7210       # redefined in Makefile.am).
7211       # FIXME: We should make sure that these variables are not
7212       # conditionally defined (or else adjust the condition below).
7213       my $def = $var->def (TRUE);
7214       next if $def && $def->owner != VAR_MAKEFILE;
7215
7216       my $varname = $var->name;
7217
7218       if ($varname =~ /^(nobase_)?(dist_|nodist_)?(.*)_[[:alnum:]]+$/)
7219         {
7220           my ($base, $dist, $X) = ($1 || '', $2 || '', $3 || '');
7221           if ($dist ne '' && ! $can_dist)
7222             {
7223               err_var ($var,
7224                        "invalid variable '$varname': 'dist' is forbidden");
7225             }
7226           # Standard directories must be explicitly allowed.
7227           elsif (! defined $valid{$X} && exists $standard_prefix{$X})
7228             {
7229               err_var ($var,
7230                        "'${X}dir' is not a legitimate directory " .
7231                        "for '$primary'");
7232             }
7233           # A not explicitly valid directory is allowed if Xdir is defined.
7234           elsif (! defined $valid{$X} &&
7235                  $var->requires_variables ("'$varname' is used", "${X}dir"))
7236             {
7237               # Nothing to do.  Any error message has been output
7238               # by $var->requires_variables.
7239             }
7240           else
7241             {
7242               # Ensure all extended prefixes are actually used.
7243               $valid{"$base$dist$X"} = 1;
7244             }
7245         }
7246       else
7247         {
7248           prog_error "unexpected variable name: $varname";
7249         }
7250     }
7251
7252   # Return only those which are actually defined.
7253   return sort grep { var ($_ . '_' . $primary) } keys %valid;
7254 }
7255
7256
7257 # Handle 'where_HOW' variable magic.  Does all lookups, generates
7258 # install code, and possibly generates code to define the primary
7259 # variable.  The first argument is the name of the .am file to munge,
7260 # the second argument is the primary variable (e.g. HEADERS), and all
7261 # subsequent arguments are possible installation locations.
7262 #
7263 # Returns list of [$location, $value] pairs, where
7264 # $value's are the values in all where_HOW variable, and $location
7265 # there associated location (the place here their parent variables were
7266 # defined).
7267 #
7268 # FIXME: this should be rewritten to be cleaner.  It should be broken
7269 # up into multiple functions.
7270 #
7271 # Usage is: am_install_var (OPTION..., file, HOW, where...)
7272 sub am_install_var
7273 {
7274   my (@args) = @_;
7275
7276   my $do_require = 1;
7277   my $can_dist = 0;
7278   my $default_dist = 0;
7279   while (@args)
7280     {
7281       if ($args[0] eq '-noextra')
7282         {
7283           $do_require = 0;
7284         }
7285       elsif ($args[0] eq '-candist')
7286         {
7287           $can_dist = 1;
7288         }
7289       elsif ($args[0] eq '-defaultdist')
7290         {
7291           $default_dist = 1;
7292           $can_dist = 1;
7293         }
7294       elsif ($args[0] !~ /^-/)
7295         {
7296           last;
7297         }
7298       shift (@args);
7299     }
7300
7301   my ($file, $primary, @prefix) = @args;
7302
7303   # Now that configure substitutions are allowed in where_HOW
7304   # variables, it is an error to actually define the primary.  We
7305   # allow 'JAVA', as it is customarily used to mean the Java
7306   # interpreter.  This is but one of several Java hacks.  Similarly,
7307   # 'PYTHON' is customarily used to mean the Python interpreter.
7308   reject_var $primary, "'$primary' is an anachronism"
7309     unless $primary eq 'JAVA' || $primary eq 'PYTHON';
7310
7311   # Get the prefixes which are valid and actually used.
7312   @prefix = am_primary_prefixes ($primary, $can_dist, @prefix);
7313
7314   # If a primary includes a configure substitution, then the EXTRA_
7315   # form is required.  Otherwise we can't properly do our job.
7316   my $require_extra;
7317
7318   my @used = ();
7319   my @result = ();
7320
7321   foreach my $X (@prefix)
7322     {
7323       my $nodir_name = $X;
7324       my $one_name = $X . '_' . $primary;
7325       my $one_var = var $one_name;
7326
7327       my $strip_subdir = 1;
7328       # If subdir prefix should be preserved, do so.
7329       if ($nodir_name =~ /^nobase_/)
7330         {
7331           $strip_subdir = 0;
7332           $nodir_name =~ s/^nobase_//;
7333         }
7334
7335       # If files should be distributed, do so.
7336       my $dist_p = 0;
7337       if ($can_dist)
7338         {
7339           $dist_p = (($default_dist && $nodir_name !~ /^nodist_/)
7340                      || (! $default_dist && $nodir_name =~ /^dist_/));
7341           $nodir_name =~ s/^(dist|nodist)_//;
7342         }
7343
7344
7345       # Use the location of the currently processed variable.
7346       # We are not processing a particular condition, so pick the first
7347       # available.
7348       my $tmpcond = $one_var->conditions->one_cond;
7349       my $where = $one_var->rdef ($tmpcond)->location->clone;
7350
7351       # Append actual contents of where_PRIMARY variable to
7352       # @result, skipping @substitutions@.
7353       foreach my $locvals ($one_var->value_as_list_recursive (location => 1))
7354         {
7355           my ($loc, $value) = @$locvals;
7356           # Skip configure substitutions.
7357           if ($value =~ /^\@.*\@$/)
7358             {
7359               if ($nodir_name eq 'EXTRA')
7360                 {
7361                   error ($where,
7362                          "'$one_name' contains configure substitution, "
7363                          . "but shouldn't");
7364                 }
7365               # Check here to make sure variables defined in
7366               # configure.ac do not imply that EXTRA_PRIMARY
7367               # must be defined.
7368               elsif (! defined $configure_vars{$one_name})
7369                 {
7370                   $require_extra = $one_name
7371                     if $do_require;
7372                 }
7373             }
7374           else
7375             {
7376               # Strip any $(EXEEXT) suffix the user might have added, or this
7377               # will confuse &handle_source_transform and &check_canonical_spelling.
7378               # We'll add $(EXEEXT) back later anyway.
7379               # Do it here rather than in handle_programs so the uniquifying at the
7380               # end of this function works.
7381               ${$locvals}[1] =~ s/\$\(EXEEXT\)$//
7382                 if $primary eq 'PROGRAMS';
7383
7384               push (@result, $locvals);
7385             }
7386         }
7387       # A blatant hack: we rewrite each _PROGRAMS primary to include
7388       # EXEEXT.
7389       append_exeext { 1 } $one_name
7390         if $primary eq 'PROGRAMS';
7391       # "EXTRA" shouldn't be used when generating clean targets,
7392       # all, or install targets.  We used to warn if EXTRA_FOO was
7393       # defined uselessly, but this was annoying.
7394       next
7395         if $nodir_name eq 'EXTRA';
7396
7397       if ($nodir_name eq 'check')
7398         {
7399           push (@check, '$(' . $one_name . ')');
7400         }
7401       else
7402         {
7403           push (@used, '$(' . $one_name . ')');
7404         }
7405
7406       # Is this to be installed?
7407       my $install_p = $nodir_name ne 'noinst' && $nodir_name ne 'check';
7408
7409       # If so, with install-exec? (or install-data?).
7410       my $exec_p = ($nodir_name =~ /$EXEC_DIR_PATTERN/o);
7411
7412       my $check_options_p = $install_p && !! option 'std-options';
7413
7414       # Use the location of the currently processed variable as context.
7415       $where->push_context ("while processing '$one_name'");
7416
7417       # The variable containing all files to distribute.
7418       my $distvar = "\$($one_name)";
7419       $distvar = shadow_unconditionally ($one_name, $where)
7420         if ($dist_p && $one_var->has_conditional_contents);
7421
7422       # Singular form of $PRIMARY.
7423       (my $one_primary = $primary) =~ s/S$//;
7424       $output_rules .= &file_contents ($file, $where,
7425                                        PRIMARY     => $primary,
7426                                        ONE_PRIMARY => $one_primary,
7427                                        DIR         => $X,
7428                                        NDIR        => $nodir_name,
7429                                        BASE        => $strip_subdir,
7430
7431                                        EXEC      => $exec_p,
7432                                        INSTALL   => $install_p,
7433                                        DIST      => $dist_p,
7434                                        DISTVAR   => $distvar,
7435                                        'CK-OPTS' => $check_options_p);
7436     }
7437
7438   # The JAVA variable is used as the name of the Java interpreter.
7439   # The PYTHON variable is used as the name of the Python interpreter.
7440   if (@used && $primary ne 'JAVA' && $primary ne 'PYTHON')
7441     {
7442       # Define it.
7443       define_pretty_variable ($primary, TRUE, INTERNAL, @used);
7444       $output_vars .= "\n";
7445     }
7446
7447   err_var ($require_extra,
7448            "'$require_extra' contains configure substitution,\n"
7449            . "but 'EXTRA_$primary' not defined")
7450     if ($require_extra && ! var ('EXTRA_' . $primary));
7451
7452   # Push here because PRIMARY might be configure time determined.
7453   push (@all, '$(' . $primary . ')')
7454     if @used && $primary ne 'JAVA' && $primary ne 'PYTHON';
7455
7456   # Make the result unique.  This lets the user use conditionals in
7457   # a natural way, but still lets us program lazily -- we don't have
7458   # to worry about handling a particular object more than once.
7459   # We will keep only one location per object.
7460   my %result = ();
7461   for my $pair (@result)
7462     {
7463       my ($loc, $val) = @$pair;
7464       $result{$val} = $loc;
7465     }
7466   my @l = sort keys %result;
7467   return map { [$result{$_}->clone, $_] } @l;
7468 }
7469
7470
7471 ################################################################
7472
7473 # Each key in this hash is the name of a directory holding a
7474 # Makefile.in.  These variables are local to 'is_make_dir'.
7475 my %make_dirs = ();
7476 my $make_dirs_set = 0;
7477
7478 sub is_make_dir
7479 {
7480     my ($dir) = @_;
7481     if (! $make_dirs_set)
7482     {
7483         foreach my $iter (@configure_input_files)
7484         {
7485             $make_dirs{dirname ($iter)} = 1;
7486         }
7487         # We also want to notice Makefile.in's.
7488         foreach my $iter (@other_input_files)
7489         {
7490             if ($iter =~ /Makefile\.in$/)
7491             {
7492                 $make_dirs{dirname ($iter)} = 1;
7493             }
7494         }
7495         $make_dirs_set = 1;
7496     }
7497     return defined $make_dirs{$dir};
7498 }
7499
7500 ################################################################
7501
7502 # Find the aux dir.  This should match the algorithm used by
7503 # ./configure. (See the Autoconf documentation for for
7504 # AC_CONFIG_AUX_DIR.)
7505 sub locate_aux_dir ()
7506 {
7507   if (! $config_aux_dir_set_in_configure_ac)
7508     {
7509       # The default auxiliary directory is the first
7510       # of ., .., or ../.. that contains install-sh.
7511       # Assume . if install-sh doesn't exist yet.
7512       for my $dir (qw (. .. ../..))
7513         {
7514           if (-f "$dir/install-sh")
7515             {
7516               $config_aux_dir = $dir;
7517               last;
7518             }
7519         }
7520       $config_aux_dir = '.' unless $config_aux_dir;
7521     }
7522   # Avoid unsightly '/.'s.
7523   $am_config_aux_dir =
7524     '$(top_srcdir)' . ($config_aux_dir eq '.' ? "" : "/$config_aux_dir");
7525   $am_config_aux_dir =~ s,/*$,,;
7526 }
7527
7528
7529 # &push_required_file ($DIR, $FILE, $FULLFILE)
7530 # --------------------------------------------------
7531 # Push the given file onto DIST_COMMON.
7532 sub push_required_file
7533 {
7534   my ($dir, $file, $fullfile) = @_;
7535
7536   # If the file to be distributed is in the same directory of the
7537   # currently processed Makefile.am, then we want to distribute it
7538   # from this same Makefile.am.
7539   if ($dir eq $relative_dir)
7540     {
7541       push_dist_common ($file);
7542     }
7543   # This is needed to allow a construct in a non-top-level Makefile.am
7544   # to require a file in the build-aux directory (see at least the test
7545   # script 'test-driver-is-distributed.test').  This is related to the
7546   # automake bug#9546.  Note that the use of $config_aux_dir instead
7547   # of $am_config_aux_dir here is deliberate and necessary.
7548   elsif ($dir eq $config_aux_dir)
7549     {
7550       push_dist_common ("$am_config_aux_dir/$file");
7551     }
7552   # FIXME: another spacial case, for AC_LIBOBJ/AC_LIBSOURCE support.
7553   # We probably need some refactoring of this function and its callers,
7554   # to have a more explicit and systematic handling of all the special
7555   # cases; but, since there are only two of them, this is low-priority
7556   # ATM.
7557   elsif ($config_libobj_dir && $dir eq $config_libobj_dir)
7558     {
7559       # Avoid unsightly '/.'s.
7560       my $am_config_libobj_dir =
7561         '$(top_srcdir)' .
7562         ($config_libobj_dir eq '.' ? "" : "/$config_libobj_dir");
7563       $am_config_libobj_dir =~ s|/*$||;
7564       push_dist_common ("$am_config_libobj_dir/$file");
7565     }
7566   elsif ($relative_dir eq '.' && ! &is_make_dir ($dir))
7567     {
7568       # If we are doing the topmost directory, and the file is in a
7569       # subdir which does not have a Makefile, then we distribute it
7570       # here.
7571
7572       # If a required file is above the source tree, it is important
7573       # to prefix it with '$(srcdir)' so that no VPATH search is
7574       # performed.  Otherwise problems occur with Make implementations
7575       # that rewrite and simplify rules whose dependencies are found in a
7576       # VPATH location.  Here is an example with OSF1/Tru64 Make.
7577       #
7578       #   % cat Makefile
7579       #   VPATH = sub
7580       #   distdir: ../a
7581       #           echo ../a
7582       #   % ls
7583       #   Makefile a
7584       #   % make
7585       #   echo a
7586       #   a
7587       #
7588       # Dependency '../a' was found in 'sub/../a', but this make
7589       # implementation simplified it as 'a'.  (Note that the sub/
7590       # directory does not even exist.)
7591       #
7592       # This kind of VPATH rewriting seems hard to cancel.  The
7593       # distdir.am hack against VPATH rewriting works only when no
7594       # simplification is done, i.e., for dependencies which are in
7595       # subdirectories, not in enclosing directories.  Hence, in
7596       # the latter case we use a full path to make sure no VPATH
7597       # search occurs.
7598       $fullfile = '$(srcdir)/' . $fullfile
7599         if $dir =~ m,^\.\.(?:$|/),;
7600
7601       push_dist_common ($fullfile);
7602     }
7603   else
7604     {
7605       prog_error "a Makefile in relative directory $relative_dir " .
7606                  "can't add files in directory $dir to DIST_COMMON";
7607     }
7608 }
7609
7610
7611 # If a file name appears as a key in this hash, then it has already
7612 # been checked for.  This allows us not to report the same error more
7613 # than once.
7614 my %required_file_not_found = ();
7615
7616 # &required_file_check_or_copy ($WHERE, $DIRECTORY, $FILE)
7617 # --------------------------------------------------------
7618 # Verify that the file must exist in $DIRECTORY, or install it.
7619 sub required_file_check_or_copy ($$$)
7620 {
7621   my ($where, $dir, $file) = @_;
7622
7623   my $fullfile = "$dir/$file";
7624   my $found_it = 0;
7625   my $dangling_sym = 0;
7626
7627   if (-l $fullfile && ! -f $fullfile)
7628     {
7629       $dangling_sym = 1;
7630     }
7631   elsif (dir_has_case_matching_file ($dir, $file))
7632     {
7633       $found_it = 1;
7634     }
7635
7636   # '--force-missing' only has an effect if '--add-missing' is
7637   # specified.
7638   return
7639     if $found_it && (! $add_missing || ! $force_missing);
7640
7641   # If we've already looked for it, we're done.  You might
7642   # wonder why we don't do this before searching for the
7643   # file.  If we do that, then something like
7644   # AC_OUTPUT(subdir/foo foo) will fail to put foo.in into
7645   # DIST_COMMON.
7646   if (! $found_it)
7647     {
7648       return if defined $required_file_not_found{$fullfile};
7649       $required_file_not_found{$fullfile} = 1;
7650     }
7651   if ($dangling_sym && $add_missing)
7652     {
7653       unlink ($fullfile);
7654     }
7655
7656   my $trailer = '';
7657   my $trailer2 = '';
7658   my $suppress = 0;
7659
7660   # Only install missing files according to our desired
7661   # strictness level.
7662   my $message = "required file '$fullfile' not found";
7663   if ($add_missing)
7664     {
7665       if (-f "$libdir/$file")
7666         {
7667           $suppress = 1;
7668
7669           # Install the missing file.  Symlink if we
7670           # can, copy if we must.  Note: delete the file
7671           # first, in case it is a dangling symlink.
7672           $message = "installing '$fullfile'";
7673
7674           # The license file should not be volatile.
7675           if ($file eq "COPYING")
7676             {
7677               $message .= " using GNU General Public License v3 file";
7678               $trailer2 = "\n    Consider adding the COPYING file"
7679                         . " to the version control system"
7680                         . "\n    for your code, to avoid questions"
7681                         . " about which license your project uses";
7682             }
7683
7684           # Windows Perl will hang if we try to delete a
7685           # file that doesn't exist.
7686           unlink ($fullfile) if -f $fullfile;
7687           if ($symlink_exists && ! $copy_missing)
7688             {
7689               if (! symlink ("$libdir/$file", $fullfile)
7690                   || ! -e $fullfile)
7691                 {
7692                   $suppress = 0;
7693                   $trailer = "; error while making link: $!";
7694                 }
7695             }
7696           elsif (system ('cp', "$libdir/$file", $fullfile))
7697             {
7698               $suppress = 0;
7699               $trailer = "\n    error while copying";
7700             }
7701           set_dir_cache_file ($dir, $file);
7702         }
7703     }
7704   else
7705     {
7706       $trailer = "\n  'automake --add-missing' can install '$file'"
7707         if -f "$libdir/$file";
7708     }
7709
7710   # If --force-missing was specified, and we have
7711   # actually found the file, then do nothing.
7712   return
7713     if $found_it && $force_missing;
7714
7715   # If we couldn't install the file, but it is a target in
7716   # the Makefile, don't print anything.  This allows files
7717   # like README, AUTHORS, or THANKS to be generated.
7718   return
7719     if !$suppress && rule $file;
7720
7721   msg ($suppress ? 'note' : 'error', $where, "$message$trailer$trailer2");
7722 }
7723
7724
7725 # &require_file_internal ($WHERE, $MYSTRICT, $DIRECTORY, $QUEUE, @FILES)
7726 # ----------------------------------------------------------------------
7727 # Verify that the file must exist in $DIRECTORY, or install it.
7728 # $MYSTRICT is the strictness level at which this file becomes required.
7729 # Worker threads may queue up the action to be serialized by the master,
7730 # if $QUEUE is true
7731 sub require_file_internal ($$$@)
7732 {
7733   my ($where, $mystrict, $dir, $queue, @files) = @_;
7734
7735   return
7736     unless $strictness >= $mystrict;
7737
7738   foreach my $file (@files)
7739     {
7740       push_required_file ($dir, $file, "$dir/$file");
7741       if ($queue)
7742         {
7743           queue_required_file_check_or_copy ($required_conf_file_queue,
7744                                              QUEUE_CONF_FILE, $relative_dir,
7745                                              $where, $mystrict, @files);
7746         }
7747       else
7748         {
7749           required_file_check_or_copy ($where, $dir, $file);
7750         }
7751     }
7752 }
7753
7754 # &require_file ($WHERE, $MYSTRICT, @FILES)
7755 # -----------------------------------------
7756 sub require_file ($$@)
7757 {
7758     my ($where, $mystrict, @files) = @_;
7759     require_file_internal ($where, $mystrict, $relative_dir, 0, @files);
7760 }
7761
7762 # &require_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7763 # -----------------------------------------------------------
7764 sub require_file_with_macro ($$$@)
7765 {
7766     my ($cond, $macro, $mystrict, @files) = @_;
7767     $macro = rvar ($macro) unless ref $macro;
7768     require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7769 }
7770
7771 # &require_libsource_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7772 # ----------------------------------------------------------------
7773 # Require an AC_LIBSOURCEd file.  If AC_CONFIG_LIBOBJ_DIR was called, it
7774 # must be in that directory.  Otherwise expect it in the current directory.
7775 sub require_libsource_with_macro ($$$@)
7776 {
7777     my ($cond, $macro, $mystrict, @files) = @_;
7778     $macro = rvar ($macro) unless ref $macro;
7779     if ($config_libobj_dir)
7780       {
7781         require_file_internal ($macro->rdef ($cond)->location, $mystrict,
7782                                $config_libobj_dir, 0, @files);
7783       }
7784     else
7785       {
7786         require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7787       }
7788 }
7789
7790 # &queue_required_file_check_or_copy ($QUEUE, $KEY, $DIR, $WHERE,
7791 #                                     $MYSTRICT, @FILES)
7792 # ---------------------------------------------------------------
7793 sub queue_required_file_check_or_copy ($$$$@)
7794 {
7795     my ($queue, $key, $dir, $where, $mystrict, @files) = @_;
7796     my @serial_loc;
7797     if (ref $where)
7798       {
7799         @serial_loc = (QUEUE_LOCATION, $where->serialize ());
7800       }
7801     else
7802       {
7803         @serial_loc = (QUEUE_STRING, $where);
7804       }
7805     $queue->enqueue ($key, $dir, @serial_loc, $mystrict, 0 + @files, @files);
7806 }
7807
7808 # &require_queued_file_check_or_copy ($QUEUE)
7809 # -------------------------------------------
7810 sub require_queued_file_check_or_copy ($)
7811 {
7812     my ($queue) = @_;
7813     my $where;
7814     my $dir = $queue->dequeue ();
7815     my $loc_key = $queue->dequeue ();
7816     if ($loc_key eq QUEUE_LOCATION)
7817       {
7818         $where = Automake::Location::deserialize ($queue);
7819       }
7820     elsif ($loc_key eq QUEUE_STRING)
7821       {
7822         $where = $queue->dequeue ();
7823       }
7824     else
7825       {
7826         prog_error "unexpected key $loc_key";
7827       }
7828     my $mystrict = $queue->dequeue ();
7829     my $nfiles = $queue->dequeue ();
7830     my @files;
7831     push @files, $queue->dequeue ()
7832       foreach (1 .. $nfiles);
7833     return
7834       unless $strictness >= $mystrict;
7835     foreach my $file (@files)
7836       {
7837         required_file_check_or_copy ($where, $config_aux_dir, $file);
7838       }
7839 }
7840
7841 # &require_conf_file ($WHERE, $MYSTRICT, @FILES)
7842 # ----------------------------------------------
7843 # Looks in configuration path, as specified by AC_CONFIG_AUX_DIR.
7844 sub require_conf_file ($$@)
7845 {
7846     my ($where, $mystrict, @files) = @_;
7847     my $queue = defined $required_conf_file_queue ? 1 : 0;
7848     require_file_internal ($where, $mystrict, $config_aux_dir,
7849                            $queue, @files);
7850 }
7851
7852
7853 # &require_conf_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7854 # ----------------------------------------------------------------
7855 sub require_conf_file_with_macro ($$$@)
7856 {
7857     my ($cond, $macro, $mystrict, @files) = @_;
7858     require_conf_file (rvar ($macro)->rdef ($cond)->location,
7859                        $mystrict, @files);
7860 }
7861
7862 ################################################################
7863
7864 # &require_build_directory ($DIRECTORY)
7865 # -------------------------------------
7866 # Emit rules to create $DIRECTORY if needed, and return
7867 # the file that any target requiring this directory should be made
7868 # dependent upon.
7869 # We don't want to emit the rule twice, and want to reuse it
7870 # for directories with equivalent names (e.g., 'foo/bar' and './foo//bar').
7871 sub require_build_directory ($)
7872 {
7873   my $directory = shift;
7874
7875   return $directory_map{$directory} if exists $directory_map{$directory};
7876
7877   my $cdir = File::Spec->canonpath ($directory);
7878
7879   if (exists $directory_map{$cdir})
7880     {
7881       my $stamp = $directory_map{$cdir};
7882       $directory_map{$directory} = $stamp;
7883       return $stamp;
7884     }
7885
7886   my $dirstamp = "$cdir/\$(am__dirstamp)";
7887
7888   $directory_map{$directory} = $dirstamp;
7889   $directory_map{$cdir} = $dirstamp;
7890
7891   # Set a variable for the dirstamp basename.
7892   define_pretty_variable ('am__dirstamp', TRUE, INTERNAL,
7893                           '$(am__leading_dot)dirstamp');
7894
7895   # Directory must be removed by 'make distclean'.
7896   $clean_files{$dirstamp} = DIST_CLEAN;
7897
7898   $output_rules .= ("$dirstamp:\n"
7899                     . "\t\@\$(MKDIR_P) $directory\n"
7900                     . "\t\@: > $dirstamp\n");
7901
7902   return $dirstamp;
7903 }
7904
7905 # &require_build_directory_maybe ($FILE)
7906 # --------------------------------------
7907 # If $FILE lies in a subdirectory, emit a rule to create this
7908 # directory and return the file that $FILE should be made
7909 # dependent upon.  Otherwise, just return the empty string.
7910 sub require_build_directory_maybe ($)
7911 {
7912     my $file = shift;
7913     my $directory = dirname ($file);
7914
7915     if ($directory ne '.')
7916     {
7917         return require_build_directory ($directory);
7918     }
7919     else
7920     {
7921         return '';
7922     }
7923 }
7924
7925 ################################################################
7926
7927 # Push a list of files onto dist_common.
7928 sub push_dist_common
7929 {
7930   prog_error "push_dist_common run after handle_dist"
7931     if $handle_dist_run;
7932   Automake::Variable::define ('DIST_COMMON', VAR_AUTOMAKE, '+', TRUE, "@_",
7933                               '', INTERNAL, VAR_PRETTY);
7934 }
7935
7936
7937 ################################################################
7938
7939 # generate_makefile ($MAKEFILE_AM, $MAKEFILE_IN)
7940 # ----------------------------------------------
7941 # Generate a Makefile.in given the name of the corresponding Makefile and
7942 # the name of the file output by config.status.
7943 sub generate_makefile ($$)
7944 {
7945   my ($makefile_am, $makefile_in) = @_;
7946
7947   # Reset all the Makefile.am related variables.
7948   initialize_per_input;
7949
7950   # AUTOMAKE_OPTIONS can contains -W flags to disable or enable
7951   # warnings for this file.  So hold any warning issued before
7952   # we have processed AUTOMAKE_OPTIONS.
7953   buffer_messages ('warning');
7954
7955   # Name of input file ("Makefile.am") and output file
7956   # ("Makefile.in").  These have no directory components.
7957   $am_file_name = basename ($makefile_am);
7958   $in_file_name = basename ($makefile_in);
7959
7960   # $OUTPUT is encoded.  If it contains a ":" then the first element
7961   # is the real output file, and all remaining elements are input
7962   # files.  We don't scan or otherwise deal with these input files,
7963   # other than to mark them as dependencies.  See
7964   # &scan_autoconf_files for details.
7965   my ($makefile, @inputs) = split (/:/, $output_files{$makefile_in});
7966
7967   $relative_dir = dirname ($makefile);
7968   $am_relative_dir = dirname ($makefile_am);
7969   $topsrcdir = backname ($relative_dir);
7970
7971   read_main_am_file ($makefile_am);
7972   if (handle_options)
7973     {
7974       # Process buffered warnings.
7975       flush_messages;
7976       # Fatal error.  Just return, so we can continue with next file.
7977       return;
7978     }
7979   # Process buffered warnings.
7980   flush_messages;
7981
7982   # There are a few install-related variables that you should not define.
7983   foreach my $var ('PRE_INSTALL', 'POST_INSTALL', 'NORMAL_INSTALL')
7984     {
7985       my $v = var $var;
7986       if ($v)
7987         {
7988           my $def = $v->def (TRUE);
7989           prog_error "$var not defined in condition TRUE"
7990             unless $def;
7991           reject_var $var, "'$var' should not be defined"
7992             if $def->owner != VAR_AUTOMAKE;
7993         }
7994     }
7995
7996   # Catch some obsolete variables.
7997   msg_var ('obsolete', 'INCLUDES',
7998            "'INCLUDES' is the old name for 'AM_CPPFLAGS' (or '*_CPPFLAGS')")
7999     if var ('INCLUDES');
8000
8001   # Must do this after reading .am file.
8002   define_variable ('subdir', $relative_dir, INTERNAL);
8003
8004   # If DIST_SUBDIRS is defined, make sure SUBDIRS is, so that
8005   # recursive rules are enabled.
8006   define_pretty_variable ('SUBDIRS', TRUE, INTERNAL, '')
8007     if var 'DIST_SUBDIRS' && ! var 'SUBDIRS';
8008
8009   # Check first, because we might modify some state.
8010   check_gnu_standards;
8011   check_gnits_standards;
8012
8013   handle_configure ($makefile_am, $makefile_in, $makefile, @inputs);
8014   handle_gettext;
8015   handle_libraries;
8016   handle_ltlibraries;
8017   handle_programs;
8018   handle_scripts;
8019
8020   handle_silent;
8021
8022   # These must be run after all the sources are scanned.  They
8023   # use variables defined by &handle_libraries, &handle_ltlibraries,
8024   # or &handle_programs.
8025   handle_compile;
8026   handle_languages;
8027   handle_libtool;
8028
8029   # Variables used by distdir.am and tags.am.
8030   define_pretty_variable ('SOURCES', TRUE, INTERNAL, @sources);
8031   if (! option 'no-dist')
8032     {
8033       define_pretty_variable ('DIST_SOURCES', TRUE, INTERNAL, @dist_sources);
8034     }
8035
8036   handle_texinfo;
8037   handle_emacs_lisp;
8038   handle_python;
8039   handle_java;
8040   handle_man_pages;
8041   handle_data;
8042   handle_headers;
8043   handle_subdirs;
8044   handle_tags;
8045   handle_minor_options;
8046   # Must come after handle_programs so that %known_programs is up-to-date.
8047   handle_tests;
8048
8049   # This must come after most other rules.
8050   handle_dist;
8051
8052   handle_footer;
8053   do_check_merge_target;
8054   handle_all ($makefile);
8055
8056   # FIXME: Gross!
8057   if (var ('lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
8058     {
8059       $output_rules .= "install-binPROGRAMS: install-libLTLIBRARIES\n\n";
8060     }
8061   if (var ('nobase_lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
8062     {
8063       $output_rules .= "install-binPROGRAMS: install-nobase_libLTLIBRARIES\n\n";
8064     }
8065
8066   handle_install;
8067   handle_clean ($makefile);
8068   handle_factored_dependencies;
8069
8070   # Comes last, because all the above procedures may have
8071   # defined or overridden variables.
8072   $output_vars .= output_variables;
8073
8074   check_typos;
8075
8076   if ($exit_code != 0)
8077     {
8078       verb "not writing $makefile_in because of earlier errors";
8079       return;
8080     }
8081
8082   mkdir ($am_relative_dir, 0755) if ! -d $am_relative_dir;
8083
8084   # We make sure that 'all:' is the first target.
8085   my $output =
8086     "$output_vars$output_all$output_header$output_rules$output_trailer";
8087
8088   # Decide whether we must update the output file or not.
8089   # We have to update in the following situations.
8090   #  * $force_generation is set.
8091   #  * any of the output dependencies is younger than the output
8092   #  * the contents of the output is different (this can happen
8093   #    if the project has been populated with a file listed in
8094   #    @common_files since the last run).
8095   # Output's dependencies are split in two sets:
8096   #  * dependencies which are also configure dependencies
8097   #    These do not change between each Makefile.am
8098   #  * other dependencies, specific to the Makefile.am being processed
8099   #    (such as the Makefile.am itself, or any Makefile fragment
8100   #    it includes).
8101   my $timestamp = mtime $makefile_in;
8102   if (! $force_generation
8103       && $configure_deps_greatest_timestamp < $timestamp
8104       && $output_deps_greatest_timestamp < $timestamp
8105       && $output eq contents ($makefile_in))
8106     {
8107       verb "$makefile_in unchanged";
8108       # No need to update.
8109       return;
8110     }
8111
8112   if (-e $makefile_in)
8113     {
8114       unlink ($makefile_in)
8115         or fatal "cannot remove $makefile_in: $!";
8116     }
8117
8118   my $gm_file = new Automake::XFile "> $makefile_in";
8119   verb "creating $makefile_in";
8120   print $gm_file $output;
8121 }
8122
8123 ################################################################
8124
8125
8126
8127
8128 ################################################################
8129
8130 # Helper function for usage().
8131 sub print_autodist_files (@)
8132 {
8133   my @lcomm = sort (&uniq (@_));
8134
8135   my @four;
8136   format USAGE_FORMAT =
8137   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<
8138   $four[0],           $four[1],           $four[2],           $four[3]
8139 .
8140   local $~ = "USAGE_FORMAT";
8141
8142   my $cols = 4;
8143   my $rows = int(@lcomm / $cols);
8144   my $rest = @lcomm % $cols;
8145
8146   if ($rest)
8147     {
8148       $rows++;
8149     }
8150   else
8151     {
8152       $rest = $cols;
8153     }
8154
8155   for (my $y = 0; $y < $rows; $y++)
8156     {
8157       @four = ("", "", "", "");
8158       for (my $x = 0; $x < $cols; $x++)
8159         {
8160           last if $y + 1 == $rows && $x == $rest;
8161
8162           my $idx = (($x > $rest)
8163                ?  ($rows * $rest + ($rows - 1) * ($x - $rest))
8164                : ($rows * $x));
8165
8166           $idx += $y;
8167           $four[$x] = $lcomm[$idx];
8168         }
8169       write;
8170     }
8171 }
8172
8173
8174 # Print usage information.
8175 sub usage ()
8176 {
8177     print "Usage: $0 [OPTION]... [Makefile]...
8178
8179 Generate Makefile.in for configure from Makefile.am.
8180
8181 Operation modes:
8182       --help               print this help, then exit
8183       --version            print version number, then exit
8184   -v, --verbose            verbosely list files processed
8185       --no-force           only update Makefile.in's that are out of date
8186   -W, --warnings=CATEGORY  report the warnings falling in CATEGORY
8187
8188 Dependency tracking:
8189   -i, --ignore-deps      disable dependency tracking code
8190       --include-deps     enable dependency tracking code
8191
8192 Flavors:
8193       --foreign          set strictness to foreign
8194       --gnits            set strictness to gnits
8195       --gnu              set strictness to gnu
8196
8197 Library files:
8198   -a, --add-missing      add missing standard files to package
8199       --libdir=DIR       set directory storing library files
8200       --print-libdir     print directory storing library files
8201   -c, --copy             with -a, copy missing files (default is symlink)
8202   -f, --force-missing    force update of standard files
8203
8204 ";
8205     Automake::ChannelDefs::usage;
8206
8207     print "\nFiles automatically distributed if found " .
8208           "(always):\n";
8209     print_autodist_files @common_files;
8210     print "\nFiles automatically distributed if found " .
8211           "(under certain conditions):\n";
8212     print_autodist_files @common_sometimes;
8213
8214     print '
8215 Report bugs to <@PACKAGE_BUGREPORT@>.
8216 GNU Automake home page: <@PACKAGE_URL@>.
8217 General help using GNU software: <http://www.gnu.org/gethelp/>.
8218 ';
8219
8220     # --help always returns 0 per GNU standards.
8221     exit 0;
8222 }
8223
8224
8225 # &version ()
8226 # -----------
8227 # Print version information
8228 sub version ()
8229 {
8230   print <<EOF;
8231 automake (GNU $PACKAGE) $VERSION
8232 Copyright (C) $RELEASE_YEAR Free Software Foundation, Inc.
8233 License GPLv2+: GNU GPL version 2 or later <http://gnu.org/licenses/gpl-2.0.html>
8234 This is free software: you are free to change and redistribute it.
8235 There is NO WARRANTY, to the extent permitted by law.
8236
8237 Written by Tom Tromey <tromey\@redhat.com>
8238        and Alexandre Duret-Lutz <adl\@gnu.org>.
8239 EOF
8240   # --version always returns 0 per GNU standards.
8241   exit 0;
8242 }
8243
8244 ################################################################
8245
8246 # Parse command line.
8247 sub parse_arguments ()
8248 {
8249   my $strict = 'gnu';
8250   my $ignore_deps = 0;
8251   my @warnings = ();
8252
8253   my %cli_options =
8254     (
8255      'version' => \&version,
8256      'help'    => \&usage,
8257      'libdir=s' => \$libdir,
8258      'print-libdir'     => sub { print "$libdir\n"; exit 0; },
8259      'gnu'              => sub { $strict = 'gnu'; },
8260      'gnits'            => sub { $strict = 'gnits'; },
8261      'foreign'          => sub { $strict = 'foreign'; },
8262      'include-deps'     => sub { $ignore_deps = 0; },
8263      'i|ignore-deps'    => sub { $ignore_deps = 1; },
8264      'no-force' => sub { $force_generation = 0; },
8265      'f|force-missing'  => \$force_missing,
8266      'a|add-missing'    => \$add_missing,
8267      'c|copy'           => \$copy_missing,
8268      'v|verbose'        => sub { setup_channel 'verb', silent => 0; },
8269      'W|warnings=s'     => \@warnings,
8270      );
8271
8272   use Automake::Getopt ();
8273   Automake::Getopt::parse_options %cli_options;
8274
8275   set_strictness ($strict);
8276   my $cli_where = new Automake::Location;
8277   set_global_option ('no-dependencies', $cli_where) if $ignore_deps;
8278   for my $warning (@warnings)
8279     {
8280       &parse_warnings ('-W', $warning);
8281     }
8282
8283   return unless @ARGV;
8284
8285   my $errspec = 0;
8286   foreach my $arg (@ARGV)
8287     {
8288       fatal ("empty argument\nTry '$0 --help' for more information")
8289         if ($arg eq '');
8290
8291       # Handle $local:$input syntax.
8292       my ($local, @rest) = split (/:/, $arg);
8293       @rest = ("$local.in",) unless @rest;
8294       my $input = locate_am @rest;
8295       if ($input)
8296         {
8297           push @input_files, $input;
8298           $output_files{$input} = join (':', ($local, @rest));
8299         }
8300       else
8301         {
8302           error "no Automake input file found for '$arg'";
8303           $errspec = 1;
8304         }
8305     }
8306   fatal "no input file found among supplied arguments"
8307     if $errspec && ! @input_files;
8308 }
8309
8310
8311 # handle_makefile ($MAKEFILE_IN)
8312 # ------------------------------
8313 # Deal with $MAKEFILE_IN.
8314 sub handle_makefile ($)
8315 {
8316   my ($file) =  @_;
8317   ($am_file = $file) =~ s/\.in$//;
8318   if (! -f ($am_file . '.am'))
8319     {
8320       error "'$am_file.am' does not exist";
8321     }
8322   else
8323     {
8324       # Any warning setting now local to this Makefile.am.
8325       dup_channel_setup;
8326
8327       generate_makefile ($am_file . '.am', $file);
8328
8329       # Back out any warning setting.
8330       drop_channel_setup;
8331     }
8332 }
8333
8334 # handle_makefiles_serial ()
8335 # --------------------------
8336 # Deal with all makefiles, without threads.
8337 sub handle_makefiles_serial ()
8338 {
8339   foreach my $file (@input_files)
8340     {
8341       handle_makefile ($file);
8342     }
8343 }
8344
8345 # get_number_of_threads ()
8346 # ------------------------
8347 # Logic for deciding how many worker threads to use.
8348 sub get_number_of_threads
8349 {
8350   my $nthreads = $ENV{'AUTOMAKE_JOBS'} || 0;
8351
8352   $nthreads = 0
8353     unless $nthreads =~ /^[0-9]+$/;
8354
8355   # It doesn't make sense to use more threads than makefiles,
8356   my $max_threads = @input_files;
8357
8358   if ($nthreads > $max_threads)
8359     {
8360       $nthreads = $max_threads;
8361     }
8362   return $nthreads;
8363 }
8364
8365 # handle_makefiles_threaded ($NTHREADS)
8366 # -------------------------------------
8367 # Deal with all makefiles, using threads.  The general strategy is to
8368 # spawn NTHREADS worker threads, dispatch makefiles to them, and let the
8369 # worker threads push back everything that needs serialization:
8370 # * warning and (normal) error messages, for stable stderr output
8371 #   order and content (avoiding duplicates, for example),
8372 # * races when installing aux files (and respective messages),
8373 # * races when collecting aux files for distribution.
8374 #
8375 # The latter requires that the makefile that deals with the aux dir
8376 # files be handled last, done by the master thread.
8377 sub handle_makefiles_threaded ($)
8378 {
8379   my ($nthreads) = @_;
8380
8381   # The file queue distributes all makefiles, the message queues
8382   # collect all serializations needed for respective files.
8383   my $file_queue = Thread::Queue->new;
8384   my %msg_queues;
8385   foreach my $file (@input_files)
8386     {
8387       $msg_queues{$file} = Thread::Queue->new;
8388     }
8389
8390   verb "spawning $nthreads worker threads";
8391   my @threads = (1 .. $nthreads);
8392   foreach my $t (@threads)
8393     {
8394       $t = threads->new (sub
8395         {
8396           while (my $file = $file_queue->dequeue)
8397             {
8398               verb "handling $file";
8399               my $queue = $msg_queues{$file};
8400               setup_channel_queue ($queue, QUEUE_MESSAGE);
8401               $required_conf_file_queue = $queue;
8402               handle_makefile ($file);
8403               $queue->enqueue (undef);
8404               setup_channel_queue (undef, undef);
8405               $required_conf_file_queue = undef;
8406             }
8407           return $exit_code;
8408         });
8409     }
8410
8411   # Queue all makefiles.
8412   verb "queuing " . @input_files . " input files";
8413   $file_queue->enqueue (@input_files, (undef) x @threads);
8414
8415   # Collect and process serializations.
8416   foreach my $file (@input_files)
8417     {
8418       verb "dequeuing messages for " . $file;
8419       reset_local_duplicates ();
8420       my $queue = $msg_queues{$file};
8421       while (my $key = $queue->dequeue)
8422         {
8423           if ($key eq QUEUE_MESSAGE)
8424             {
8425               pop_channel_queue ($queue);
8426             }
8427           elsif ($key eq QUEUE_CONF_FILE)
8428             {
8429               require_queued_file_check_or_copy ($queue);
8430             }
8431           else
8432             {
8433               prog_error "unexpected key $key";
8434             }
8435         }
8436     }
8437
8438   foreach my $t (@threads)
8439     {
8440       my @exit_thread = $t->join;
8441       $exit_code = $exit_thread[0]
8442         if ($exit_thread[0] > $exit_code);
8443     }
8444 }
8445
8446 ################################################################
8447
8448 # Parse the WARNINGS environment variable.
8449 parse_WARNINGS;
8450
8451 # Parse command line.
8452 parse_arguments;
8453
8454 $configure_ac = require_configure_ac;
8455
8456 # Do configure.ac scan only once.
8457 scan_autoconf_files;
8458
8459 if (! @input_files)
8460   {
8461     my $msg = '';
8462     $msg = "\nDid you forget AC_CONFIG_FILES([Makefile]) in $configure_ac?"
8463       if -f 'Makefile.am';
8464     fatal ("no 'Makefile.am' found for any configure output$msg");
8465   }
8466
8467 my $nthreads = get_number_of_threads ();
8468
8469 if ($perl_threads && $nthreads >= 1)
8470   {
8471     handle_makefiles_threaded ($nthreads);
8472   }
8473 else
8474   {
8475     handle_makefiles_serial ();
8476   }
8477
8478 exit $exit_code;
8479
8480
8481 ### Setup "GNU" style for perl-mode and cperl-mode.
8482 ## Local Variables:
8483 ## perl-indent-level: 2
8484 ## perl-continued-statement-offset: 2
8485 ## perl-continued-brace-offset: 0
8486 ## perl-brace-offset: 0
8487 ## perl-brace-imaginary-offset: 0
8488 ## perl-label-offset: -2
8489 ## cperl-indent-level: 2
8490 ## cperl-brace-offset: 0
8491 ## cperl-continued-brace-offset: 0
8492 ## cperl-label-offset: -2
8493 ## cperl-extra-newline-before-brace: t
8494 ## cperl-merge-trailing-else: nil
8495 ## cperl-continued-statement-offset: 2
8496 ## End: