automake.in

   1 #!@PERL@ -w
   2 # -*- perl -*-
   3 # @configure_input@
   4
   5 eval 'case $# in 0) exec @PERL@ -S "$0";; *) exec @PERL@ -S "$0" "$@";; esac'
   6     if 0;
   7
   8 # automake - create Makefile.in from Makefile.am
   9 # Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
  10 # 2003, 2004, 2005  Free Software Foundation, Inc.
  11
  12 # This program is free software; you can redistribute it and/or modify
  13 # it under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 2, or (at your option)
  15 # any later version.
  16
  17 # This program is distributed in the hope that it will be useful,
  18 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 # GNU General Public License for more details.
  21
  22 # You should have received a copy of the GNU General Public License
  23 # along with this program; if not, write to the Free Software
  24 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  25 # 02110-1301, USA.
  26
  27 # Originally written by David Mackenzie <djm@gnu.ai.mit.edu>.
  28 # Perl reimplementation by Tom Tromey <tromey@redhat.com>, and
  29 # Alexandre Duret-Lutz <adl@gnu.org>.
  30
  31 package Language;
  32
  33 BEGIN
  34 {
  35   my $perllibdir = $ENV{'perllibdir'} || '@datadir@/@PACKAGE@-@APIVERSION@';
  36   unshift @INC, (split '@PATH_SEPARATOR@', $perllibdir);
  37
  38   # Override SHELL.  This is required on DJGPP so that system() uses
  39   # bash, not COMMAND.COM which doesn't quote arguments properly.
  40   # Other systems aren't expected to use $SHELL when Automake
  41   # runs, but it should be safe to drop the `if DJGPP' guard if
  42   # it turns up other systems need the same thing.  After all,
  43   # if SHELL is used, ./configure's SHELL is always better than
  44   # the user's SHELL (which may be something like tcsh).
  45   $ENV{'SHELL'} = '@SHELL@' if exists $ENV{'DJGPP'};
  46 }
  47
  48 use Automake::Struct;
  49 struct (# Short name of the language (c, f77...).
  50         'name' => "\$",
  51         # Nice name of the language (C, Fortran 77...).
  52         'Name' => "\$",
  53
  54         # List of configure variables which must be defined.
  55         'config_vars' => '@',
  56
  57         'ansi'    => "\$",
  58         # `pure' is `1' or `'.  A `pure' language is one where, if
  59         # all the files in a directory are of that language, then we
  60         # do not require the C compiler or any code to call it.
  61         'pure'   => "\$",
  62
  63         'autodep' => "\$",
  64
  65         # Name of the compiling variable (COMPILE).
  66         'compiler'  => "\$",
  67         # Content of the compiling variable.
  68         'compile'  => "\$",
  69         # Flag to require compilation without linking (-c).
  70         'compile_flag' => "\$",
  71         'extensions' => '@',
  72         # A subroutine to compute a list of possible extensions of
  73         # the product given the input extensions.
  74         # (defaults to a subroutine which returns ('.$(OBJEXT)', '.lo'))
  75         'output_extensions' => "\$",
  76         # A list of flag variables used in 'compile'.
  77         # (defaults to [])
  78         'flags' => "@",
  79
  80         # Any tag to pass to libtool while compiling.
  81         'libtool_tag' => "\$",
  82
  83         # The file to use when generating rules for this language.
  84         # The default is 'depend2'.
  85         'rule_file' => "\$",
  86
  87         # Name of the linking variable (LINK).
  88         'linker' => "\$",
  89         # Content of the linking variable.
  90         'link' => "\$",
  91
  92         # Name of the linker variable (LD).
  93         'lder' => "\$",
  94         # Content of the linker variable ($(CC)).
  95         'ld' => "\$",
  96
  97         # Flag to specify the output file (-o).
  98         'output_flag' => "\$",
  99         '_finish' => "\$",
 100
 101         # This is a subroutine which is called whenever we finally
 102         # determine the context in which a source file will be
 103         # compiled.
 104         '_target_hook' => "\$",
 105
 106         # If TRUE, nodist_ sources will be compiled using specific rules
 107         # (i.e. not inference rules).  The default is FALSE.
 108         'nodist_specific' => "\$");
 109
 110
 111 sub finish ($)
 112 {
 113   my ($self) = @_;
 114   if (defined $self->_finish)
 115     {
 116       &{$self->_finish} ();
 117     }
 118 }
 119
 120 sub target_hook ($$$$%)
 121 {
 122     my ($self) = @_;
 123     if (defined $self->_target_hook)
 124     {
 125         &{$self->_target_hook} (@_);
 126     }
 127 }
 128
 129 package Automake;
 130
 131 use strict;
 132 use Automake::Config;
 133 use Automake::General;
 134 use Automake::XFile;
 135 use Automake::Channels;
 136 use Automake::ChannelDefs;
 137 use Automake::Configure_ac;
 138 use Automake::FileUtils;
 139 use Automake::Location;
 140 use Automake::Condition qw/TRUE FALSE/;
 141 use Automake::DisjConditions;
 142 use Automake::Options;
 143 use Automake::Version;
 144 use Automake::Variable;
 145 use Automake::VarDef;
 146 use Automake::Rule;
 147 use Automake::RuleDef;
 148 use Automake::Wrap 'makefile_wrap';
 149 use File::Basename;
 150 use File::Spec;
 151 use Carp;
 152
 153 ## ----------- ##
 154 ## Constants.  ##
 155 ## ----------- ##
 156
 157 # Some regular expressions.  One reason to put them here is that it
 158 # makes indentation work better in Emacs.
 159
 160 # Writing singled-quoted-$-terminated regexes is a pain because
 161 # perl-mode thinks of $' as the ${'} variable (instead of a $ followed
 162 # by a closing quote.  Letting perl-mode think the quote is not closed
 163 # leads to all sort of misindentations.  On the other hand, defining
 164 # regexes as double-quoted strings is far less readable.  So usually
 165 # we will write:
 166 #
 167 #  $REGEX = '^regex_value' . "\$";
 168
 169 my $IGNORE_PATTERN = '^\s*##([^#\n].*)?\n';
 170 my $WHITE_PATTERN = '^\s*' . "\$";
 171 my $COMMENT_PATTERN = '^#';
 172 my $TARGET_PATTERN='[$a-zA-Z_.@%][-.a-zA-Z0-9_(){}/$+@%]*';
 173 # A rule has three parts: a list of targets, a list of dependencies,
 174 # and optionally actions.
 175 my $RULE_PATTERN =
 176   "^($TARGET_PATTERN(?:(?:\\\\\n|\\s)+$TARGET_PATTERN)*) *:([^=].*|)\$";
 177
 178 # Only recognize leading spaces, not leading tabs.  If we recognize
 179 # leading tabs here then we need to make the reader smarter, because
 180 # otherwise it will think rules like `foo=bar; \' are errors.
 181 my $ASSIGNMENT_PATTERN = '^ *([^ \t=:+]*)\s*([:+]?)=\s*(.*)' . "\$";
 182 # This pattern recognizes a Gnits version id and sets $1 if the
 183 # release is an alpha release.  We also allow a suffix which can be
 184 # used to extend the version number with a "fork" identifier.
 185 my $GNITS_VERSION_PATTERN = '\d+\.\d+([a-z]|\.\d+)?(-[A-Za-z0-9]+)?';
 186
 187 my $IF_PATTERN = '^if\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*)\s*(?:#.*)?' . "\$";
 188 my $ELSE_PATTERN =
 189   '^else(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 190 my $ENDIF_PATTERN =
 191   '^endif(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 192 my $PATH_PATTERN = '(\w|[+/.-])+';
 193 # This will pass through anything not of the prescribed form.
 194 my $INCLUDE_PATTERN = ('^include\s+'
 195                        . '((\$\(top_srcdir\)/' . $PATH_PATTERN . ')'
 196                        . '|(\$\(srcdir\)/' . $PATH_PATTERN . ')'
 197                        . '|([^/\$]' . $PATH_PATTERN . '))\s*(#.*)?' . "\$");
 198
 199 # Match `-d' as a command-line argument in a string.
 200 my $DASH_D_PATTERN = "(^|\\s)-d(\\s|\$)";
 201 # Directories installed during 'install-exec' phase.
 202 my $EXEC_DIR_PATTERN =
 203   '^(?:bin|sbin|libexec|sysconf|localstate|lib|pkglib|.*exec.*)' . "\$";
 204
 205 # Values for AC_CANONICAL_*
 206 use constant AC_CANONICAL_BUILD  => 1;
 207 use constant AC_CANONICAL_HOST   => 2;
 208 use constant AC_CANONICAL_TARGET => 3;
 209
 210 # Values indicating when something should be cleaned.
 211 use constant MOSTLY_CLEAN     => 0;
 212 use constant CLEAN            => 1;
 213 use constant DIST_CLEAN       => 2;
 214 use constant MAINTAINER_CLEAN => 3;
 215
 216 # Libtool files.
 217 my @libtool_files = qw(ltmain.sh config.guess config.sub);
 218 # ltconfig appears here for compatibility with old versions of libtool.
 219 my @libtool_sometimes = qw(ltconfig ltcf-c.sh ltcf-cxx.sh ltcf-gcj.sh);
 220
 221 # Commonly found files we look for and automatically include in
 222 # DISTFILES.
 223 my @common_files =
 224     (qw(ABOUT-GNU ABOUT-NLS AUTHORS BACKLOG COPYING COPYING.DOC COPYING.LIB
 225         COPYING.LESSER ChangeLog INSTALL NEWS README THANKS TODO
 226         ansi2knr.1 ansi2knr.c compile config.guess config.rpath config.sub
 227         depcomp elisp-comp install-sh libversion.in mdate-sh missing
 228         mkinstalldirs py-compile texinfo.tex ylwrap),
 229      @libtool_files, @libtool_sometimes);
 230
 231 # Commonly used files we auto-include, but only sometimes.  This list
 232 # is used for the --help output only.
 233 my @common_sometimes =
 234   qw(aclocal.m4 acconfig.h config.h.top config.h.bot configure
 235      configure.ac configure.in stamp-vti);
 236
 237 # Standard directories from the GNU Coding Standards, and additional
 238 # pkg* directories from Automake.  Stored in a hash for fast member check.
 239 my %standard_prefix =
 240     map { $_ => 1 } (qw(bin data dataroot dvi exec html include info
 241                         lib libexec lisp localstate man man1 man2 man3
 242                         man4 man5 man6 man7 man8 man9 oldinclude pdf
 243                         pkgdatadir pkgincludedir pkglibdir ps sbin
 244                         sharedstate sysconf));
 245
 246 # Copyright on generated Makefile.ins.
 247 my $gen_copyright = "\
 248 # Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
 249 # 2003, 2004, 2005  Free Software Foundation, Inc.
 250 # This Makefile.in is free software; the Free Software Foundation
 251 # gives unlimited permission to copy and/or distribute it,
 252 # with or without modifications, as long as this notice is preserved.
 253
 254 # This program is distributed in the hope that it will be useful,
 255 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
 256 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 257 # PARTICULAR PURPOSE.
 258 ";
 259
 260 # These constants are returned by lang_*_rewrite functions.
 261 # LANG_SUBDIR means that the resulting object file should be in a
 262 # subdir if the source file is.  In this case the file name cannot
 263 # have `..' components.
 264 use constant LANG_IGNORE  => 0;
 265 use constant LANG_PROCESS => 1;
 266 use constant LANG_SUBDIR  => 2;
 267
 268 # These are used when keeping track of whether an object can be built
 269 # by two different paths.
 270 use constant COMPILE_LIBTOOL  => 1;
 271 use constant COMPILE_ORDINARY => 2;
 272
 273 # We can't always associate a location to a variable or a rule,
 274 # when its defined by Automake.  We use INTERNAL in this case.
 275 use constant INTERNAL => new Automake::Location;
 276 \f
 277
 278 ## ---------------------------------- ##
 279 ## Variables related to the options.  ##
 280 ## ---------------------------------- ##
 281
 282 # TRUE if we should always generate Makefile.in.
 283 my $force_generation = 1;
 284
 285 # From the Perl manual.
 286 my $symlink_exists = (eval 'symlink ("", "");', $@ eq '');
 287
 288 # TRUE if missing standard files should be installed.
 289 my $add_missing = 0;
 290
 291 # TRUE if we should copy missing files; otherwise symlink if possible.
 292 my $copy_missing = 0;
 293
 294 # TRUE if we should always update files that we know about.
 295 my $force_missing = 0;
 296
 297
 298 ## ---------------------------------------- ##
 299 ## Variables filled during files scanning.  ##
 300 ## ---------------------------------------- ##
 301
 302 # Name of the configure.ac file.
 303 my $configure_ac;
 304
 305 # Files found by scanning configure.ac for LIBOBJS.
 306 my %libsources = ();
 307
 308 # Names used in AC_CONFIG_HEADER call.
 309 my @config_headers = ();
 310
 311 # Names used in AC_CONFIG_LINKS call.
 312 my @config_links = ();
 313
 314 # Directory where output files go.  Actually, output files are
 315 # relative to this directory.
 316 my $output_directory;
 317
 318 # List of Makefile.am's to process, and their corresponding outputs.
 319 my @input_files = ();
 320 my %output_files = ();
 321
 322 # Complete list of Makefile.am's that exist.
 323 my @configure_input_files = ();
 324
 325 # List of files in AC_CONFIG_FILES/AC_OUTPUT without Makefile.am's,
 326 # and their outputs.
 327 my @other_input_files = ();
 328 # Where each AC_CONFIG_FILES/AC_OUTPUT/AC_CONFIG_LINK/AC_CONFIG_HEADER appears.
 329 # The keys are the files created by these macros.
 330 my %ac_config_files_location = ();
 331
 332 # Directory to search for configure-required files.  This
 333 # will be computed by &locate_aux_dir and can be set using
 334 # AC_CONFIG_AUX_DIR in configure.ac.
 335 # $CONFIG_AUX_DIR is the `raw' directory, valid only in the source-tree.
 336 my $config_aux_dir = '';
 337 my $config_aux_dir_set_in_configure_ac = 0;
 338 # $AM_CONFIG_AUX_DIR is prefixed with $(top_srcdir), so it can be used
 339 # in Makefiles.
 340 my $am_config_aux_dir = '';
 341
 342 # Directory to search for AC_LIBSOURCE files, as set by AC_CONFIG_LIBOBJ_DIR
 343 # in configure.ac.
 344 my $config_libobj_dir = '';
 345
 346 # Whether AM_GNU_GETTEXT has been seen in configure.ac.
 347 my $seen_gettext = 0;
 348 # Whether AM_GNU_GETTEXT([external]) is used.
 349 my $seen_gettext_external = 0;
 350 # Where AM_GNU_GETTEXT appears.
 351 my $ac_gettext_location;
 352
 353 # Lists of tags supported by Libtool.
 354 my %libtool_tags = ();
 355 # 1 if Libtool uses LT_SUPPORTED_TAG.  If it does, then it also
 356 # use AC_REQUIRE_AUX_FILE.
 357 my $libtool_new_api = 0;
 358
 359 # Most important AC_CANONICAL_* macro seen so far.
 360 my $seen_canonical = 0;
 361 # Location of that macro.
 362 my $canonical_location;
 363
 364 # Where AM_MAINTAINER_MODE appears.
 365 my $seen_maint_mode;
 366
 367 # Actual version we've seen.
 368 my $package_version = '';
 369
 370 # Where version is defined.
 371 my $package_version_location;
 372
 373 # TRUE if we've seen AC_ENABLE_MULTILIB.
 374 my $seen_multilib = 0;
 375
 376 # TRUE if we've seen AM_PROG_CC_C_O
 377 my $seen_cc_c_o = 0;
 378
 379 # Location of AC_REQUIRE_AUX_FILE calls, indexed by their argument.
 380 my %required_aux_file = ();
 381
 382 # Where AM_INIT_AUTOMAKE is called;
 383 my $seen_init_automake = 0;
 384
 385 # TRUE if we've seen AM_AUTOMAKE_VERSION.
 386 my $seen_automake_version = 0;
 387
 388 # Hash table of discovered configure substitutions.  Keys are names,
 389 # values are `FILE:LINE' strings which are used by error message
 390 # generation.
 391 my %configure_vars = ();
 392
 393 # Files included by $configure_ac.
 394 my @configure_deps = ();
 395
 396 # Greatest timestamp of configure's dependencies.
 397 my $configure_deps_greatest_timestamp = 0;
 398
 399 # Hash table of AM_CONDITIONAL variables seen in configure.
 400 my %configure_cond = ();
 401
 402 # This maps extensions onto language names.
 403 my %extension_map = ();
 404
 405 # List of the DIST_COMMON files we discovered while reading
 406 # configure.in
 407 my $configure_dist_common = '';
 408
 409 # This maps languages names onto objects.
 410 my %languages = ();
 411 # Maps each linker variable onto a language object.
 412 my %link_languages = ();
 413
 414 # List of targets we must always output.
 415 # FIXME: Complete, and remove falsely required targets.
 416 my %required_targets =
 417   (
 418    'all'          => 1,
 419    'dvi'          => 1,
 420    'pdf'          => 1,
 421    'ps'           => 1,
 422    'info'         => 1,
 423    'install-info' => 1,
 424    'install'      => 1,
 425    'install-data' => 1,
 426    'install-exec' => 1,
 427    'uninstall'    => 1,
 428
 429    # FIXME: Not required, temporary hacks.
 430    # Well, actually they are sort of required: the -recursive
 431    # targets will run them anyway...
 432    'dvi-am'          => 1,
 433    'pdf-am'          => 1,
 434    'ps-am'           => 1,
 435    'info-am'         => 1,
 436    'install-data-am' => 1,
 437    'install-exec-am' => 1,
 438    'installcheck-am' => 1,
 439    'uninstall-am' => 1,
 440
 441    'install-man' => 1,
 442   );
 443
 444 # Set to 1 if this run will create the Makefile.in that distribute
 445 # the files in config_aux_dir.
 446 my $automake_will_process_aux_dir = 0;
 447
 448 # The name of the Makefile currently being processed.
 449 my $am_file = 'BUG';
 450 \f
 451
 452 ################################################################
 453
 454 ## ------------------------------------------ ##
 455 ## Variables reset by &initialize_per_input.  ##
 456 ## ------------------------------------------ ##
 457
 458 # Basename and relative dir of the input file.
 459 my $am_file_name;
 460 my $am_relative_dir;
 461
 462 # Same but wrt Makefile.in.
 463 my $in_file_name;
 464 my $relative_dir;
 465
 466 # Greatest timestamp of the output's dependencies (excluding
 467 # configure's dependencies).
 468 my $output_deps_greatest_timestamp;
 469
 470 # These two variables are used when generating each Makefile.in.
 471 # They hold the Makefile.in until it is ready to be printed.
 472 my $output_rules;
 473 my $output_vars;
 474 my $output_trailer;
 475 my $output_all;
 476 my $output_header;
 477
 478 # This is the conditional stack, updated on if/else/endif, and
 479 # used to build Condition objects.
 480 my @cond_stack;
 481
 482 # This holds the set of included files.
 483 my @include_stack;
 484
 485 # This holds a list of directories which we must create at `dist'
 486 # time.  This is used in some strange scenarios involving weird
 487 # AC_OUTPUT commands.
 488 my %dist_dirs;
 489
 490 # List of dependencies for the obvious targets.
 491 my @all;
 492 my @check;
 493 my @check_tests;
 494
 495 # Keys in this hash table are files to delete.  The associated
 496 # value tells when this should happen (MOSTLY_CLEAN, DIST_CLEAN, etc.)
 497 my %clean_files;
 498
 499 # Keys in this hash table are object files or other files in
 500 # subdirectories which need to be removed.  This only holds files
 501 # which are created by compilations.  The value in the hash indicates
 502 # when the file should be removed.
 503 my %compile_clean_files;
 504
 505 # Keys in this hash table are directories where we expect to build a
 506 # libtool object.  We use this information to decide what directories
 507 # to delete.
 508 my %libtool_clean_directories;
 509
 510 # Value of `$(SOURCES)', used by tags.am.
 511 my @sources;
 512 # Sources which go in the distribution.
 513 my @dist_sources;
 514
 515 # This hash maps object file names onto their corresponding source
 516 # file names.  This is used to ensure that each object is created
 517 # by a single source file.
 518 my %object_map;
 519
 520 # This hash maps object file names onto an integer value representing
 521 # whether this object has been built via ordinary compilation or
 522 # libtool compilation (the COMPILE_* constants).
 523 my %object_compilation_map;
 524
 525
 526 # This keeps track of the directories for which we've already
 527 # created dirstamp code.  Keys are directories, values are stamp files.
 528 # Several keys can share the same stamp files if they are equivalent
 529 # (as are `.//foo' and `foo').
 530 my %directory_map;
 531
 532 # All .P files.
 533 my %dep_files;
 534
 535 # This is a list of all targets to run during "make dist".
 536 my @dist_targets;
 537
 538 # Keys in this hash are the basenames of files which must depend on
 539 # ansi2knr.  Values are either the empty string, or the directory in
 540 # which the ANSI source file appears; the directory must have a
 541 # trailing `/'.
 542 my %de_ansi_files;
 543
 544 # This is the name of the redirect `all' target to use.
 545 my $all_target;
 546
 547 # This keeps track of which extensions we've seen (that we care
 548 # about).
 549 my %extension_seen;
 550
 551 # This is random scratch space for the language finish functions.
 552 # Don't randomly overwrite it; examine other uses of keys first.
 553 my %language_scratch;
 554
 555 # We keep track of which objects need special (per-executable)
 556 # handling on a per-language basis.
 557 my %lang_specific_files;
 558
 559 # This is set when `handle_dist' has finished.  Once this happens,
 560 # we should no longer push on dist_common.
 561 my $handle_dist_run;
 562
 563 # Used to store a set of linkers needed to generate the sources currently
 564 # under consideration.
 565 my %linkers_used;
 566
 567 # True if we need `LINK' defined.  This is a hack.
 568 my $need_link;
 569
 570 # Was get_object_extension run?
 571 # FIXME: This is a hack. a better switch should be found.
 572 my $get_object_extension_was_run;
 573
 574 # Record each file processed by make_paragraphs.
 575 my %transformed_files;
 576
 577 # Cache each file processed by make_paragraphs.
 578 # (This is different from %transformed_files because
 579 # %transformed_files is reset for each file while %am_file_cache
 580 # it global to the run.)
 581 my %am_file_cache;
 582
 583 ################################################################
 584
 585 # var_SUFFIXES_trigger ($TYPE, $VALUE)
 586 # ------------------------------------
 587 # This is called by Automake::Variable::define() when SUFFIXES
 588 # is defined ($TYPE eq '') or appended ($TYPE eq '+').
 589 # The work here needs to be performed as a side-effect of the
 590 # macro_define() call because SUFFIXES definitions impact
 591 # on $KNOWN_EXTENSIONS_PATTERN which is used used when parsing
 592 # the input am file.
 593 sub var_SUFFIXES_trigger ($$)
 594 {
 595     my ($type, $value) = @_;
 596     accept_extensions (split (' ', $value));
 597 }
 598 Automake::Variable::hook ('SUFFIXES', \&var_SUFFIXES_trigger);
 599
 600 ################################################################
 601
 602 ## --------------------------------- ##
 603 ## Forward subroutine declarations.  ##
 604 ## --------------------------------- ##
 605 sub register_language (%);
 606 sub file_contents_internal ($$$%);
 607 sub define_files_variable ($\@$$);
 608
 609
 610 # &initialize_per_input ()
 611 # ------------------------
 612 # (Re)-Initialize per-Makefile.am variables.
 613 sub initialize_per_input ()
 614 {
 615     reset_local_duplicates ();
 616
 617     $am_file_name = '';
 618     $am_relative_dir = '';
 619
 620     $in_file_name = '';
 621     $relative_dir = '';
 622
 623     $output_deps_greatest_timestamp = 0;
 624
 625     $output_rules = '';
 626     $output_vars = '';
 627     $output_trailer = '';
 628     $output_all = '';
 629     $output_header = '';
 630
 631     Automake::Options::reset;
 632     Automake::Variable::reset;
 633     Automake::Rule::reset;
 634
 635     @cond_stack = ();
 636
 637     @include_stack = ();
 638
 639     %dist_dirs = ();
 640
 641     @all = ();
 642     @check = ();
 643     @check_tests = ();
 644
 645     %clean_files = ();
 646
 647     @sources = ();
 648     @dist_sources = ();
 649
 650     %object_map = ();
 651     %object_compilation_map = ();
 652
 653     %directory_map = ();
 654
 655     %dep_files = ();
 656
 657     @dist_targets = ();
 658
 659     %de_ansi_files = ();
 660
 661     $all_target = '';
 662
 663     %extension_seen = ();
 664
 665     %language_scratch = ();
 666
 667     %lang_specific_files = ();
 668
 669     $handle_dist_run = 0;
 670
 671     $need_link = 0;
 672
 673     $get_object_extension_was_run = 0;
 674
 675     %compile_clean_files = ();
 676
 677     # We always include `.'.  This isn't strictly correct.
 678     %libtool_clean_directories = ('.' => 1);
 679
 680     %transformed_files = ();
 681 }
 682
 683
 684 ################################################################
 685
 686 # Initialize our list of languages that are internally supported.
 687
 688 # C.
 689 register_language ('name' => 'c',
 690                    'Name' => 'C',
 691                    'config_vars' => ['CC'],
 692                    'ansi' => 1,
 693                    'autodep' => '',
 694                    'flags' => ['CFLAGS', 'CPPFLAGS'],
 695                    'compiler' => 'COMPILE',
 696                    'compile' => '$(CC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CFLAGS) $(CFLAGS)',
 697                    'lder' => 'CCLD',
 698                    'ld' => '$(CC)',
 699                    'linker' => 'LINK',
 700                    'link' => '$(CCLD) $(AM_CFLAGS) $(CFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 701                    'compile_flag' => '-c',
 702                    'libtool_tag' => 'CC',
 703                    'extensions' => ['.c'],
 704                    '_finish' => \&lang_c_finish);
 705
 706 # C++.
 707 register_language ('name' => 'cxx',
 708                    'Name' => 'C++',
 709                    'config_vars' => ['CXX'],
 710                    'linker' => 'CXXLINK',
 711                    'link' => '$(CXXLD) $(AM_CXXFLAGS) $(CXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 712                    'autodep' => 'CXX',
 713                    'flags' => ['CXXFLAGS', 'CPPFLAGS'],
 714                    'compile' => '$(CXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CXXFLAGS) $(CXXFLAGS)',
 715                    'compiler' => 'CXXCOMPILE',
 716                    'compile_flag' => '-c',
 717                    'output_flag' => '-o',
 718                    'libtool_tag' => 'CXX',
 719                    'lder' => 'CXXLD',
 720                    'ld' => '$(CXX)',
 721                    'pure' => 1,
 722                    'extensions' => ['.c++', '.cc', '.cpp', '.cxx', '.C']);
 723
 724 # Objective C.
 725 register_language ('name' => 'objc',
 726                    'Name' => 'Objective C',
 727                    'config_vars' => ['OBJC'],
 728                    'linker' => 'OBJCLINK',,
 729                    'link' => '$(OBJCLD) $(AM_OBJCFLAGS) $(OBJCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 730                    'autodep' => 'OBJC',
 731                    'flags' => ['OBJCFLAGS', 'CPPFLAGS'],
 732                    'compile' => '$(OBJC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCFLAGS) $(OBJCFLAGS)',
 733                    'compiler' => 'OBJCCOMPILE',
 734                    'compile_flag' => '-c',
 735                    'output_flag' => '-o',
 736                    'lder' => 'OBJCLD',
 737                    'ld' => '$(OBJC)',
 738                    'pure' => 1,
 739                    'extensions' => ['.m']);
 740
 741 # Headers.
 742 register_language ('name' => 'header',
 743                    'Name' => 'Header',
 744                    'extensions' => ['.h', '.H', '.hxx', '.h++', '.hh',
 745                                     '.hpp', '.inc'],
 746                    # No output.
 747                    'output_extensions' => sub { return () },
 748                    # Nothing to do.
 749                    '_finish' => sub { });
 750
 751 # Yacc (C & C++).
 752 register_language ('name' => 'yacc',
 753                    'Name' => 'Yacc',
 754                    'config_vars' => ['YACC'],
 755                    'flags' => ['YFLAGS'],
 756                    'compile' => '$(YACC) $(YFLAGS) $(AM_YFLAGS)',
 757                    'compiler' => 'YACCCOMPILE',
 758                    'extensions' => ['.y'],
 759                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 760                                                 return ($ext,) },
 761                    'rule_file' => 'yacc',
 762                    '_finish' => \&lang_yacc_finish,
 763                    '_target_hook' => \&lang_yacc_target_hook,
 764                    'nodist_specific' => 1);
 765 register_language ('name' => 'yaccxx',
 766                    'Name' => 'Yacc (C++)',
 767                    'config_vars' => ['YACC'],
 768                    'rule_file' => 'yacc',
 769                    'flags' => ['YFLAGS'],
 770                    'compiler' => 'YACCCOMPILE',
 771                    'compile' => '$(YACC) $(YFLAGS) $(AM_YFLAGS)',
 772                    'extensions' => ['.y++', '.yy', '.yxx', '.ypp'],
 773                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 774                                                 return ($ext,) },
 775                    '_finish' => \&lang_yacc_finish,
 776                    '_target_hook' => \&lang_yacc_target_hook,
 777                    'nodist_specific' => 1);
 778
 779 # Lex (C & C++).
 780 register_language ('name' => 'lex',
 781                    'Name' => 'Lex',
 782                    'config_vars' => ['LEX'],
 783                    'rule_file' => 'lex',
 784                    'flags' => ['LFLAGS'],
 785                    'compile' => '$(LEX) $(LFLAGS) $(AM_LFLAGS)',
 786                    'compiler' => 'LEXCOMPILE',
 787                    'extensions' => ['.l'],
 788                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 789                                                 return ($ext,) },
 790                    '_finish' => \&lang_lex_finish,
 791                    '_target_hook' => \&lang_lex_target_hook,
 792                    'nodist_specific' => 1);
 793 register_language ('name' => 'lexxx',
 794                    'Name' => 'Lex (C++)',
 795                    'config_vars' => ['LEX'],
 796                    'rule_file' => 'lex',
 797                    'flags' => ['LFLAGS'],
 798                    'compile' => '$(LEX) $(LFLAGS) $(AM_LFLAGS)',
 799                    'compiler' => 'LEXCOMPILE',
 800                    'extensions' => ['.l++', '.ll', '.lxx', '.lpp'],
 801                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 802                                                 return ($ext,) },
 803                    '_finish' => \&lang_lex_finish,
 804                    '_target_hook' => \&lang_lex_target_hook,
 805                    'nodist_specific' => 1);
 806
 807 # Assembler.
 808 register_language ('name' => 'asm',
 809                    'Name' => 'Assembler',
 810                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 811
 812                    'flags' => ['CCASFLAGS'],
 813                    # Users can set AM_CCASFLAGS to include DEFS, INCLUDES,
 814                    # or anything else required.  They can also set CCAS.
 815                    'compile' => '$(CCAS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 816                    'compiler' => 'CCASCOMPILE',
 817                    'compile_flag' => '-c',
 818                    'extensions' => ['.s'],
 819
 820                    # With assembly we still use the C linker.
 821                    '_finish' => \&lang_c_finish);
 822
 823 # Preprocessed Assembler.
 824 register_language ('name' => 'cppasm',
 825                    'Name' => 'Preprocessed Assembler',
 826                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 827
 828                    'autodep' => 'CCAS',
 829                    'flags' => ['CCASFLAGS', 'CPPFLAGS'],
 830                    # Users can set AM_CCASFLAGS to include DEFS, INCLUDES,
 831                    # or anything else required beyond AM_CPPFLAGS.  They
 832                    # can also set CCAS.
 833                    'compile' => '$(CCAS) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 834                    'compiler' => 'CPPASCOMPILE',
 835                    'compile_flag' => '-c',
 836                    'extensions' => ['.S'],
 837
 838                    # With assembly we still use the C linker.
 839                    '_finish' => \&lang_c_finish);
 840
 841 # Fortran 77
 842 register_language ('name' => 'f77',
 843                    'Name' => 'Fortran 77',
 844                    'linker' => 'F77LINK',
 845                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 846                    'flags' => ['FFLAGS'],
 847                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS)',
 848                    'compiler' => 'F77COMPILE',
 849                    'compile_flag' => '-c',
 850                    'output_flag' => '-o',
 851                    'libtool_tag' => 'F77',
 852                    'lder' => 'F77LD',
 853                    'ld' => '$(F77)',
 854                    'pure' => 1,
 855                    'extensions' => ['.f', '.for']);
 856
 857 # Fortran
 858 register_language ('name' => 'fc',
 859                    'Name' => 'Fortran',
 860                    'linker' => 'FCLINK',
 861                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 862                    'flags' => ['FCFLAGS'],
 863                    'compile' => '$(FC) $(AM_FCFLAGS) $(FCFLAGS)',
 864                    'compiler' => 'FCCOMPILE',
 865                    'compile_flag' => '-c',
 866                    'output_flag' => '-o',
 867                    'lder' => 'FCLD',
 868                    'ld' => '$(FC)',
 869                    'pure' => 1,
 870                    'extensions' => ['.f90', '.f95']);
 871
 872 # Preprocessed Fortran
 873 register_language ('name' => 'ppfc',
 874                    'Name' => 'Preprocessed Fortran',
 875                    'config_vars' => ['FC'],
 876                    'linker' => 'FCLINK',
 877                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 878                    'lder' => 'FCLD',
 879                    'ld' => '$(FC)',
 880                    'flags' => ['FCFLAGS', 'CPPFLAGS'],
 881                    'compiler' => 'PPFCCOMPILE',
 882                    'compile' => '$(FC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FCFLAGS) $(FCFLAGS)',
 883                    'compile_flag' => '-c',
 884                    'output_flag' => '-o',
 885                    'libtool_tag' => 'FC',
 886                    'pure' => 1,
 887                    'extensions' => ['.F90','.F95']);
 888
 889 # Preprocessed Fortran 77
 890 #
 891 # The current support for preprocessing Fortran 77 just involves
 892 # passing `$(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS)
 893 # $(CPPFLAGS)' as additional flags to the Fortran 77 compiler, since
 894 # this is how GNU Make does it; see the `GNU Make Manual, Edition 0.51
 895 # for `make' Version 3.76 Beta' (specifically, from info file
 896 # `(make)Catalogue of Rules').
 897 #
 898 # A better approach would be to write an Autoconf test
 899 # (i.e. AC_PROG_FPP) for a Fortran 77 preprocessor, because not all
 900 # Fortran 77 compilers know how to do preprocessing.  The Autoconf
 901 # macro AC_PROG_FPP should test the Fortran 77 compiler first for
 902 # preprocessing capabilities, and then fall back on cpp (if cpp were
 903 # available).
 904 register_language ('name' => 'ppf77',
 905                    'Name' => 'Preprocessed Fortran 77',
 906                    'config_vars' => ['F77'],
 907                    'linker' => 'F77LINK',
 908                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 909                    'lder' => 'F77LD',
 910                    'ld' => '$(F77)',
 911                    'flags' => ['FFLAGS', 'CPPFLAGS'],
 912                    'compiler' => 'PPF77COMPILE',
 913                    'compile' => '$(F77) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FFLAGS) $(FFLAGS)',
 914                    'compile_flag' => '-c',
 915                    'output_flag' => '-o',
 916                    'libtool_tag' => 'F77',
 917                    'pure' => 1,
 918                    'extensions' => ['.F']);
 919
 920 # Ratfor.
 921 register_language ('name' => 'ratfor',
 922                    'Name' => 'Ratfor',
 923                    'config_vars' => ['F77'],
 924                    'linker' => 'F77LINK',
 925                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 926                    'lder' => 'F77LD',
 927                    'ld' => '$(F77)',
 928                    'flags' => ['RFLAGS', 'FFLAGS'],
 929                    # FIXME also FFLAGS.
 930                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS) $(AM_RFLAGS) $(RFLAGS)',
 931                    'compiler' => 'RCOMPILE',
 932                    'compile_flag' => '-c',
 933                    'output_flag' => '-o',
 934                    'libtool_tag' => 'F77',
 935                    'pure' => 1,
 936                    'extensions' => ['.r']);
 937
 938 # Java via gcj.
 939 register_language ('name' => 'java',
 940                    'Name' => 'Java',
 941                    'config_vars' => ['GCJ'],
 942                    'linker' => 'GCJLINK',
 943                    'link' => '$(GCJLD) $(AM_GCJFLAGS) $(GCJFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 944                    'autodep' => 'GCJ',
 945                    'flags' => ['GCJFLAGS'],
 946                    'compile' => '$(GCJ) $(AM_GCJFLAGS) $(GCJFLAGS)',
 947                    'compiler' => 'GCJCOMPILE',
 948                    'compile_flag' => '-c',
 949                    'output_flag' => '-o',
 950                    'libtool_tag' => 'GCJ',
 951                    'lder' => 'GCJLD',
 952                    'ld' => '$(GCJ)',
 953                    'pure' => 1,
 954                    'extensions' => ['.java', '.class', '.zip', '.jar']);
 955
 956 ################################################################
 957
 958 # Error reporting functions.
 959
 960 # err_am ($MESSAGE, [%OPTIONS])
 961 # -----------------------------
 962 # Uncategorized errors about the current Makefile.am.
 963 sub err_am ($;%)
 964 {
 965   msg_am ('error', @_);
 966 }
 967
 968 # err_ac ($MESSAGE, [%OPTIONS])
 969 # -----------------------------
 970 # Uncategorized errors about configure.ac.
 971 sub err_ac ($;%)
 972 {
 973   msg_ac ('error', @_);
 974 }
 975
 976 # msg_am ($CHANNEL, $MESSAGE, [%OPTIONS])
 977 # ---------------------------------------
 978 # Messages about about the current Makefile.am.
 979 sub msg_am ($$;%)
 980 {
 981   my ($channel, $msg, %opts) = @_;
 982   msg $channel, "${am_file}.am", $msg, %opts;
 983 }
 984
 985 # msg_ac ($CHANNEL, $MESSAGE, [%OPTIONS])
 986 # ---------------------------------------
 987 # Messages about about configure.ac.
 988 sub msg_ac ($$;%)
 989 {
 990   my ($channel, $msg, %opts) = @_;
 991   msg $channel, $configure_ac, $msg, %opts;
 992 }
 993
 994 ################################################################
 995
 996 # subst ($TEXT)
 997 # -------------
 998 # Return a configure-style substitution using the indicated text.
 999 # We do this to avoid having the substitutions directly in automake.in;
1000 # when we do that they are sometimes removed and this causes confusion
1001 # and bugs.
1002 sub subst ($)
1003 {
1004     my ($text) = @_;
1005     return '@' . $text . '@';
1006 }
1007
1008 ################################################################
1009
1010
1011 # $BACKPATH
1012 # &backname ($REL-DIR)
1013 # --------------------
1014 # If I `cd $REL-DIR', then to come back, I should `cd $BACKPATH'.
1015 # For instance `src/foo' => `../..'.
1016 # Works with non strictly increasing paths, i.e., `src/../lib' => `..'.
1017 sub backname ($)
1018 {
1019     my ($file) = @_;
1020     my @res;
1021     foreach (split (/\//, $file))
1022     {
1023         next if $_ eq '.' || $_ eq '';
1024         if ($_ eq '..')
1025         {
1026             pop @res;
1027         }
1028         else
1029         {
1030             push (@res, '..');
1031         }
1032     }
1033     return join ('/', @res) || '.';
1034 }
1035
1036 ################################################################
1037
1038
1039 # Handle AUTOMAKE_OPTIONS variable.  Return 1 on error, 0 otherwise.
1040 sub handle_options
1041 {
1042   my $var = var ('AUTOMAKE_OPTIONS');
1043   if ($var)
1044     {
1045       # FIXME: We should disallow conditional definitions of AUTOMAKE_OPTIONS.
1046       if (process_option_list ($var->rdef (TRUE)->location,
1047                                $var->value_as_list_recursive (cond_filter =>
1048                                                               TRUE)))
1049         {
1050           return 1;
1051         }
1052     }
1053
1054   if ($strictness == GNITS)
1055     {
1056       set_option ('readme-alpha', INTERNAL);
1057       set_option ('std-options', INTERNAL);
1058       set_option ('check-news', INTERNAL);
1059     }
1060
1061   return 0;
1062 }
1063
1064 # shadow_unconditionally ($varname, $where)
1065 # -----------------------------------------
1066 # Return a $(variable) that contains all possible values
1067 # $varname can take.
1068 # If the VAR wasn't defined conditionally, return $(VAR).
1069 # Otherwise we create a am__VAR_DIST variable which contains
1070 # all possible values, and return $(am__VAR_DIST).
1071 sub shadow_unconditionally ($$)
1072 {
1073   my ($varname, $where) = @_;
1074   my $var = var $varname;
1075   if ($var->has_conditional_contents)
1076     {
1077       $varname = "am__${varname}_DIST";
1078       my @files = uniq ($var->value_as_list_recursive);
1079       define_pretty_variable ($varname, TRUE, $where, @files);
1080     }
1081   return "\$($varname)"
1082 }
1083
1084 # get_object_extension ($EXTENSION)
1085 # ---------------------------------
1086 # Prefix $EXTENSION with $U if ansi2knr is in use.
1087 sub get_object_extension ($)
1088 {
1089     my ($extension) = @_;
1090
1091     # Check for automatic de-ANSI-fication.
1092     $extension = '$U' . $extension
1093       if option 'ansi2knr';
1094
1095     $get_object_extension_was_run = 1;
1096
1097     return $extension;
1098 }
1099
1100 # check_user_variables (@LIST)
1101 # ----------------------------
1102 # Make sure each variable VAR in @LIST do not exist, suggest using AM_VAR
1103 # otherwise.
1104 sub check_user_variables (@)
1105 {
1106   my @dont_override = @_;
1107   foreach my $flag (@dont_override)
1108     {
1109       my $var = var $flag;
1110       if ($var)
1111         {
1112           for my $cond ($var->conditions->conds)
1113             {
1114               if ($var->rdef ($cond)->owner == VAR_MAKEFILE)
1115                 {
1116                   msg_cond_var ('gnu', $cond, $flag,
1117                                 "`$flag' is a user variable, "
1118                                 . "you should not override it;\n"
1119                                 . "use `AM_$flag' instead.");
1120                 }
1121             }
1122         }
1123     }
1124 }
1125
1126 # Call finish function for each language that was used.
1127 sub handle_languages
1128 {
1129     if (! option 'no-dependencies')
1130     {
1131         # Include auto-dep code.  Don't include it if DEP_FILES would
1132         # be empty.
1133         if (&saw_sources_p (0) && keys %dep_files)
1134         {
1135             # Set location of depcomp.
1136             &define_variable ('depcomp',
1137                               "\$(SHELL) $am_config_aux_dir/depcomp",
1138                               INTERNAL);
1139             &define_variable ('am__depfiles_maybe', 'depfiles', INTERNAL);
1140
1141             require_conf_file ("$am_file.am", FOREIGN, 'depcomp');
1142
1143             my @deplist = sort keys %dep_files;
1144             # Generate each `include' individually.  Irix 6 make will
1145             # not properly include several files resulting from a
1146             # variable expansion; generating many separate includes
1147             # seems safest.
1148             $output_rules .= "\n";
1149             foreach my $iter (@deplist)
1150             {
1151                 $output_rules .= (subst ('AMDEP_TRUE')
1152                                   . subst ('am__include')
1153                                   . ' '
1154                                   . subst ('am__quote')
1155                                   . $iter
1156                                   . subst ('am__quote')
1157                                   . "\n");
1158             }
1159
1160             # Compute the set of directories to remove in distclean-depend.
1161             my @depdirs = uniq (map { dirname ($_) } @deplist);
1162             $output_rules .= &file_contents ('depend',
1163                                              new Automake::Location,
1164                                              DEPDIRS => "@depdirs");
1165         }
1166     }
1167     else
1168     {
1169         &define_variable ('depcomp', '', INTERNAL);
1170         &define_variable ('am__depfiles_maybe', '', INTERNAL);
1171     }
1172
1173     my %done;
1174
1175     # Is the c linker needed?
1176     my $needs_c = 0;
1177     foreach my $ext (sort keys %extension_seen)
1178     {
1179         next unless $extension_map{$ext};
1180
1181         my $lang = $languages{$extension_map{$ext}};
1182
1183         my $rule_file = $lang->rule_file || 'depend2';
1184
1185         # Get information on $LANG.
1186         my $pfx = $lang->autodep;
1187         my $fpfx = ($pfx eq '') ? 'CC' : $pfx;
1188
1189         my ($AMDEP, $FASTDEP) =
1190           (option 'no-dependencies' || $lang->autodep eq 'no')
1191           ? ('FALSE', 'FALSE') : ('AMDEP', "am__fastdep$fpfx");
1192
1193         my %transform = ('EXT'     => $ext,
1194                          'PFX'     => $pfx,
1195                          'FPFX'    => $fpfx,
1196                          'AMDEP'   => $AMDEP,
1197                          'FASTDEP' => $FASTDEP,
1198                          '-c'      => $lang->compile_flag || '',
1199                          'MORE-THAN-ONE'
1200                                    => (count_files_for_language ($lang->name) > 1),
1201                          # These are not used, but they need to be defined
1202                          # so &transform do not complain.
1203                          SUBDIROBJ     => 0,
1204                          'DERIVED-EXT' => 'BUG',
1205                          DIST_SOURCE   => 1,
1206                         );
1207
1208         # Generate the appropriate rules for this extension.
1209         if (((! option 'no-dependencies') && $lang->autodep ne 'no')
1210             || defined $lang->compile)
1211         {
1212             # Some C compilers don't support -c -o.  Use it only if really
1213             # needed.
1214             my $output_flag = $lang->output_flag || '';
1215             $output_flag = '-o'
1216               if (! $output_flag
1217                   && $lang->name eq 'c'
1218                   && option 'subdir-objects');
1219
1220             # Compute a possible derived extension.
1221             # This is not used by depend2.am.
1222             my $der_ext = (&{$lang->output_extensions} ($ext))[0];
1223
1224             # When we output an inference rule like `.c.o:' we
1225             # have two cases to consider: either subdir-objects
1226             # is used, or it is not.
1227             #
1228             # In the latter case the rule is used to build objects
1229             # in the current directory, and dependencies always
1230             # go into `./$(DEPDIR)/'.  We can hard-code this value.
1231             #
1232             # In the former case the rule can be used to build
1233             # objects in sub-directories too.  Dependencies should
1234             # go into the appropriate sub-directories, e.g.,
1235             # `sub/$(DEPDIR)/'.  The value of this directory
1236             # need the be computed on-the-fly.
1237             #
1238             # DEPBASE holds the name of this directory, plus the
1239             # basename part of the object file (extensions Po, TPo,
1240             # Plo, TPlo will be added later as appropriate).  It is
1241             # either hardcoded, or a shell variable (`$depbase') that
1242             # will be computed by the rule.
1243             my $depbase =
1244               option ('subdir-objects') ? '$$depbase' : '$(DEPDIR)/$*';
1245             $output_rules .=
1246               file_contents ($rule_file,
1247                              new Automake::Location,
1248                              %transform,
1249                              GENERIC   => 1,
1250
1251                              'DERIVED-EXT' => $der_ext,
1252
1253                              DEPBASE   => $depbase,
1254                              BASE      => '$*',
1255                              SOURCE    => '$<',
1256                              OBJ       => '$@',
1257                              OBJOBJ    => '$@',
1258                              LTOBJ     => '$@',
1259
1260                              COMPILE   => '$(' . $lang->compiler . ')',
1261                              LTCOMPILE => '$(LT' . $lang->compiler . ')',
1262                              -o        => $output_flag,
1263                              SUBDIROBJ => !! option 'subdir-objects');
1264         }
1265
1266         # Now include code for each specially handled object with this
1267         # language.
1268         my %seen_files = ();
1269         foreach my $file (@{$lang_specific_files{$lang->name}})
1270         {
1271             my ($derived, $source, $obj, $myext, %file_transform) = @$file;
1272
1273             # We might see a given object twice, for instance if it is
1274             # used under different conditions.
1275             next if defined $seen_files{$obj};
1276             $seen_files{$obj} = 1;
1277
1278             prog_error ("found " . $lang->name .
1279                         " in handle_languages, but compiler not defined")
1280               unless defined $lang->compile;
1281
1282             my $obj_compile = $lang->compile;
1283
1284             # Rewrite each occurrence of `AM_$flag' in the compile
1285             # rule into `${derived}_$flag' if it exists.
1286             for my $flag (@{$lang->flags})
1287               {
1288                 my $val = "${derived}_$flag";
1289                 $obj_compile =~ s/\(AM_$flag\)/\($val\)/
1290                   if set_seen ($val);
1291               }
1292
1293             my $libtool_tag = '';
1294             if ($lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag})
1295               {
1296                 $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
1297               }
1298
1299             my $ptltflags = "${derived}_LIBTOOLFLAGS";
1300             $ptltflags = 'AM_LIBTOOLFLAGS' unless set_seen $ptltflags;
1301
1302             my $obj_ltcompile =
1303               "\$(LIBTOOL) $libtool_tag\$($ptltflags) \$(LIBTOOLFLAGS) "
1304               . "--mode=compile $obj_compile";
1305
1306             # We _need_ `-o' for per object rules.
1307             my $output_flag = $lang->output_flag || '-o';
1308
1309             my $depbase = dirname ($obj);
1310             $depbase = ''
1311                 if $depbase eq '.';
1312             $depbase .= '/'
1313                 unless $depbase eq '';
1314             $depbase .= '$(DEPDIR)/' . basename ($obj);
1315
1316             # Support for deansified files in subdirectories is ugly
1317             # enough to deserve an explanation.
1318             #
1319             # A Note about normal ansi2knr processing first.  On
1320             #
1321             #   AUTOMAKE_OPTIONS = ansi2knr
1322             #   bin_PROGRAMS = foo
1323             #   foo_SOURCES = foo.c
1324             #
1325             # we generate rules similar to:
1326             #
1327             #   foo: foo$U.o; link ...
1328             #   foo$U.o: foo$U.c; compile ...
1329             #   foo_.c: foo.c; ansi2knr ...
1330             #
1331             # this is fairly compact, and will call ansi2knr depending
1332             # on the value of $U (`' or `_').
1333             #
1334             # It's harder with subdir sources. On
1335             #
1336             #   AUTOMAKE_OPTIONS = ansi2knr
1337             #   bin_PROGRAMS = foo
1338             #   foo_SOURCES = sub/foo.c
1339             #
1340             # we have to create foo_.c in the current directory.
1341             # (Unless the user asks 'subdir-objects'.)  This is important
1342             # in case the same file (`foo.c') is compiled from other
1343             # directories with different cpp options: foo_.c would
1344             # be preprocessed for only one set of options if it were
1345             # put in the subdirectory.
1346             #
1347             # Because foo$U.o must be built from either foo_.c or
1348             # sub/foo.c we can't be as concise as in the first example.
1349             # Instead we output
1350             #
1351             #   foo: foo$U.o; link ...
1352             #   foo_.o: foo_.c; compile ...
1353             #   foo.o: sub/foo.c; compile ...
1354             #   foo_.c: foo.c; ansi2knr ...
1355             #
1356             # This is why we'll now transform $rule_file twice
1357             # if we detect this case.
1358             # A first time we output the compile rule with `$U'
1359             # replaced by `_' and the source directory removed,
1360             # and another time we simply remove `$U'.
1361             #
1362             # Note that at this point $source (as computed by
1363             # &handle_single_transform) is `sub/foo$U.c'.
1364             # This can be confusing: it can be used as-is when
1365             # subdir-objects is set, otherwise you have to know
1366             # it really means `foo_.c' or `sub/foo.c'.
1367             my $objdir = dirname ($obj);
1368             my $srcdir = dirname ($source);
1369             if ($lang->ansi && $obj =~ /\$U/)
1370               {
1371                 prog_error "`$obj' contains \$U, but `$source' doesn't."
1372                   if $source !~ /\$U/;
1373
1374                 (my $source_ = $source) =~ s/\$U/_/g;
1375                 # Output an additional rule if _.c and .c are not in
1376                 # the same directory.  (_.c is always in $objdir.)
1377                 if ($objdir ne $srcdir)
1378                   {
1379                     (my $obj_ = $obj) =~ s/\$U/_/g;
1380                     (my $depbase_ = $depbase) =~ s/\$U/_/g;
1381                     $source_ = basename ($source_);
1382
1383                     $output_rules .=
1384                       file_contents ($rule_file,
1385                                      new Automake::Location,
1386                                      %transform,
1387                                      GENERIC   => 0,
1388
1389                                      DEPBASE   => $depbase_,
1390                                      BASE      => $obj_,
1391                                      SOURCE    => $source_,
1392                                      OBJ       => "$obj_$myext",
1393                                      OBJOBJ    => "$obj_.obj",
1394                                      LTOBJ     => "$obj_.lo",
1395
1396                                      COMPILE   => $obj_compile,
1397                                      LTCOMPILE => $obj_ltcompile,
1398                                      -o        => $output_flag,
1399                                      %file_transform);
1400                     $obj =~ s/\$U//g;
1401                     $depbase =~ s/\$U//g;
1402                     $source =~ s/\$U//g;
1403                   }
1404               }
1405
1406             $output_rules .=
1407               file_contents ($rule_file,
1408                              new Automake::Location,
1409                              %transform,
1410                              GENERIC   => 0,
1411
1412                              DEPBASE   => $depbase,
1413                              BASE      => $obj,
1414                              SOURCE    => $source,
1415                              # Use $myext and not `.o' here, in case
1416                              # we are actually building a new source
1417                              # file -- e.g. via yacc.
1418                              OBJ       => "$obj$myext",
1419                              OBJOBJ    => "$obj.obj",
1420                              LTOBJ     => "$obj.lo",
1421
1422                              COMPILE   => $obj_compile,
1423                              LTCOMPILE => $obj_ltcompile,
1424                              -o        => $output_flag,
1425                              %file_transform);
1426         }
1427
1428         # The rest of the loop is done once per language.
1429         next if defined $done{$lang};
1430         $done{$lang} = 1;
1431
1432         # Load the language dependent Makefile chunks.
1433         my %lang = map { uc ($_) => 0 } keys %languages;
1434         $lang{uc ($lang->name)} = 1;
1435         $output_rules .= file_contents ('lang-compile',
1436                                         new Automake::Location,
1437                                         %transform, %lang);
1438
1439         # If the source to a program consists entirely of code from a
1440         # `pure' language, for instance C++ or Fortran 77, then we
1441         # don't need the C compiler code.  However if we run into
1442         # something unusual then we do generate the C code.  There are
1443         # probably corner cases here that do not work properly.
1444         # People linking Java code to Fortran code deserve pain.
1445         $needs_c ||= ! $lang->pure;
1446
1447         define_compiler_variable ($lang)
1448           if ($lang->compile);
1449
1450         define_linker_variable ($lang)
1451           if ($lang->link);
1452
1453         require_variables ("$am_file.am", $lang->Name . " source seen",
1454                            TRUE, @{$lang->config_vars});
1455
1456         # Call the finisher.
1457         $lang->finish;
1458
1459         # Flags listed in `->flags' are user variables (per GNU Standards),
1460         # they should not be overridden in the Makefile...
1461         my @dont_override = @{$lang->flags};
1462         # ... and so is LDFLAGS.
1463         push @dont_override, 'LDFLAGS' if $lang->link;
1464
1465         check_user_variables @dont_override;
1466     }
1467
1468     # If the project is entirely C++ or entirely Fortran 77 (i.e., 1
1469     # suffix rule was learned), don't bother with the C stuff.  But if
1470     # anything else creeps in, then use it.
1471     $needs_c = 1
1472       if $need_link || suffix_rules_count > 1;
1473
1474     if ($needs_c)
1475       {
1476         &define_compiler_variable ($languages{'c'})
1477           unless defined $done{$languages{'c'}};
1478         define_linker_variable ($languages{'c'});
1479       }
1480 }
1481
1482 # Check to make sure a source defined in LIBOBJS is not explicitly
1483 # mentioned.  This is a separate function (as opposed to being inlined
1484 # in handle_source_transform) because it isn't always appropriate to
1485 # do this check.
1486 sub check_libobjs_sources
1487 {
1488   my ($one_file, $unxformed) = @_;
1489
1490   foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1491                       'dist_EXTRA_', 'nodist_EXTRA_')
1492     {
1493       my @files;
1494       my $varname = $prefix . $one_file . '_SOURCES';
1495       my $var = var ($varname);
1496       if ($var)
1497         {
1498           @files = $var->value_as_list_recursive;
1499         }
1500       elsif ($prefix eq '')
1501         {
1502           @files = ($unxformed . '.c');
1503         }
1504       else
1505         {
1506           next;
1507         }
1508
1509       foreach my $file (@files)
1510         {
1511           err_var ($prefix . $one_file . '_SOURCES',
1512                    "automatically discovered file `$file' should not" .
1513                    " be explicitly mentioned")
1514             if defined $libsources{$file};
1515         }
1516     }
1517 }
1518
1519
1520 # @OBJECTS
1521 # handle_single_transform ($VAR, $TOPPARENT, $DERIVED, $OBJ, $FILE, %TRANSFORM)
1522 # -----------------------------------------------------------------------------
1523 # Does much of the actual work for handle_source_transform.
1524 # Arguments are:
1525 #   $VAR is the name of the variable that the source filenames come from
1526 #   $TOPPARENT is the name of the _SOURCES variable which is being processed
1527 #   $DERIVED is the name of resulting executable or library
1528 #   $OBJ is the object extension (e.g., `$U.lo')
1529 #   $FILE the source file to transform
1530 #   %TRANSFORM contains extras arguments to pass to file_contents
1531 #     when producing explicit rules
1532 # Result is a list of the names of objects
1533 # %linkers_used will be updated with any linkers needed
1534 sub handle_single_transform ($$$$$%)
1535 {
1536     my ($var, $topparent, $derived, $obj, $_file, %transform) = @_;
1537     my @files = ($_file);
1538     my @result = ();
1539     my $nonansi_obj = $obj;
1540     $nonansi_obj =~ s/\$U//g;
1541
1542     # Turn sources into objects.  We use a while loop like this
1543     # because we might add to @files in the loop.
1544     while (scalar @files > 0)
1545     {
1546         $_ = shift @files;
1547
1548         # Configure substitutions in _SOURCES variables are errors.
1549         if (/^\@.*\@$/)
1550         {
1551           my $parent_msg = '';
1552           $parent_msg = "\nand is referred to from `$topparent'"
1553             if $topparent ne $var->name;
1554           err_var ($var,
1555                    "`" . $var->name . "' includes configure substitution `$_'"
1556                    . $parent_msg . ";\nconfigure " .
1557                    "substitutions are not allowed in _SOURCES variables");
1558           next;
1559         }
1560
1561         # If the source file is in a subdirectory then the `.o' is put
1562         # into the current directory, unless the subdir-objects option
1563         # is in effect.
1564
1565         # Split file name into base and extension.
1566         next if ! /^(?:(.*)\/)?([^\/]*)($KNOWN_EXTENSIONS_PATTERN)$/;
1567         my $full = $_;
1568         my $directory = $1 || '';
1569         my $base = $2;
1570         my $extension = $3;
1571
1572         # We must generate a rule for the object if it requires its own flags.
1573         my $renamed = 0;
1574         my ($linker, $object);
1575
1576         # This records whether we've seen a derived source file (e.g.
1577         # yacc output).
1578         my $derived_source = 0;
1579
1580         # This holds the `aggregate context' of the file we are
1581         # currently examining.  If the file is compiled with
1582         # per-object flags, then it will be the name of the object.
1583         # Otherwise it will be `AM'.  This is used by the target hook
1584         # language function.
1585         my $aggregate = 'AM';
1586
1587         $extension = &derive_suffix ($extension, $nonansi_obj);
1588         my $lang;
1589         if ($extension_map{$extension} &&
1590             ($lang = $languages{$extension_map{$extension}}))
1591         {
1592             # Found the language, so see what it says.
1593             &saw_extension ($extension);
1594
1595             # Do we have per-executable flags for this executable?
1596             my $have_per_exec_flags = 0;
1597             my @peflags = @{$lang->flags};
1598             push @peflags, 'LIBTOOLFLAGS' if $nonansi_obj eq '.lo';
1599             foreach my $flag (@peflags)
1600               {
1601                 if (set_seen ("${derived}_$flag"))
1602                   {
1603                     $have_per_exec_flags = 1;
1604                     last;
1605                   }
1606               }
1607
1608             # Note: computed subr call.  The language rewrite function
1609             # should return one of the LANG_* constants.  It could
1610             # also return a list whose first value is such a constant
1611             # and whose second value is a new source extension which
1612             # should be applied.  This means this particular language
1613             # generates another source file which we must then process
1614             # further.
1615             my $subr = \&{'lang_' . $lang->name . '_rewrite'};
1616             my ($r, $source_extension)
1617                 = &$subr ($directory, $base, $extension,
1618                           $nonansi_obj, $have_per_exec_flags, $var);
1619             # Skip this entry if we were asked not to process it.
1620             next if $r == LANG_IGNORE;
1621
1622             # Now extract linker and other info.
1623             $linker = $lang->linker;
1624
1625             my $this_obj_ext;
1626             if (defined $source_extension)
1627             {
1628                 $this_obj_ext = $source_extension;
1629                 $derived_source = 1;
1630             }
1631             elsif ($lang->ansi)
1632             {
1633                 $this_obj_ext = $obj;
1634             }
1635             else
1636             {
1637                 $this_obj_ext = $nonansi_obj;
1638             }
1639             $object = $base . $this_obj_ext;
1640
1641             if ($have_per_exec_flags)
1642             {
1643                 # We have a per-executable flag in effect for this
1644                 # object.  In this case we rewrite the object's
1645                 # name to ensure it is unique.
1646
1647                 # We choose the name `DERIVED_OBJECT' to ensure
1648                 # (1) uniqueness, and (2) continuity between
1649                 # invocations.  However, this will result in a
1650                 # name that is too long for losing systems, in
1651                 # some situations.  So we provide _SHORTNAME to
1652                 # override.
1653
1654                 my $dname = $derived;
1655                 my $var = var ($derived . '_SHORTNAME');
1656                 if ($var)
1657                 {
1658                     # FIXME: should use the same Condition as
1659                     # the _SOURCES variable.  But this is really
1660                     # silly overkill -- nobody should have
1661                     # conditional shortnames.
1662                     $dname = $var->variable_value;
1663                 }
1664                 $object = $dname . '-' . $object;
1665
1666                 prog_error ($lang->name . " flags defined without compiler")
1667                   if ! defined $lang->compile;
1668
1669                 $renamed = 1;
1670             }
1671
1672             # If rewrite said it was ok, put the object into a
1673             # subdir.
1674             if ($r == LANG_SUBDIR && $directory ne '')
1675             {
1676                 $object = $directory . '/' . $object;
1677             }
1678
1679             # If the object file has been renamed (because per-target
1680             # flags are used) we cannot compile the file with an
1681             # inference rule: we need an explicit rule.
1682             #
1683             # If the source is in a subdirectory and the object is in
1684             # the current directory, we also need an explicit rule.
1685             #
1686             # If both source and object files are in a subdirectory
1687             # (this happens when the subdir-objects option is used),
1688             # then the inference will work.
1689             #
1690             # The latter case deserves a historical note.  When the
1691             # subdir-objects option was added on 1999-04-11 it was
1692             # thought that inferences rules would work for
1693             # subdirectory objects too.  Later, on 1999-11-22,
1694             # automake was changed to output explicit rules even for
1695             # subdir-objects.  Nobody remembers why, but this occured
1696             # soon after the merge of the user-dep-gen-branch so it
1697             # might be related.  In late 2003 people complained about
1698             # the size of the generated Makefile.ins (libgcj, with
1699             # 2200+ subdir objects was reported to have a 9MB
1700             # Makefile), so we now rely on inference rules again.
1701             # Maybe we'll run across the same issue as in the past,
1702             # but at least this time we can document it.  However since
1703             # dependency tracking has evolved it is possible that
1704             # our old problem no longer exists.
1705             # Using inference rules for subdir-objects has been tested
1706             # with GNU make, Solaris make, Ultrix make, BSD make,
1707             # HP-UX make, and OSF1 make successfully.
1708             if ($renamed
1709                 || ($directory ne '' && ! option 'subdir-objects')
1710                 # We must also use specific rules for a nodist_ source
1711                 # if its language requests it.
1712                 || ($lang->nodist_specific && ! $transform{'DIST_SOURCE'}))
1713             {
1714                 my $obj_sans_ext = substr ($object, 0,
1715                                            - length ($this_obj_ext));
1716                 my $full_ansi = $full;
1717                 if ($lang->ansi && option 'ansi2knr')
1718                   {
1719                     $full_ansi =~ s/$KNOWN_EXTENSIONS_PATTERN$/\$U$&/;
1720                     $obj_sans_ext .= '$U';
1721                   }
1722
1723                 my @specifics = ($full_ansi, $obj_sans_ext,
1724                                  # Only use $this_obj_ext in the derived
1725                                  # source case because in the other case we
1726                                  # *don't* want $(OBJEXT) to appear here.
1727                                  ($derived_source ? $this_obj_ext : '.o'));
1728
1729                 # If we renamed the object then we want to use the
1730                 # per-executable flag name.  But if this is simply a
1731                 # subdir build then we still want to use the AM_ flag
1732                 # name.
1733                 if ($renamed)
1734                   {
1735                     unshift @specifics, $derived;
1736                     $aggregate = $derived;
1737                   }
1738                 else
1739                   {
1740                     unshift @specifics, 'AM';
1741                   }
1742
1743                 # Each item on this list is a reference to a list consisting
1744                 # of four values followed by additional transform flags for
1745                 # file_contents.   The four values are the derived flag prefix
1746                 # (e.g. for `foo_CFLAGS', it is `foo'), the name of the
1747                 # source file, the base name of the output file, and
1748                 # the extension for the object file.
1749                 push (@{$lang_specific_files{$lang->name}},
1750                       [@specifics, %transform]);
1751             }
1752         }
1753         elsif ($extension eq $nonansi_obj)
1754         {
1755             # This is probably the result of a direct suffix rule.
1756             # In this case we just accept the rewrite.
1757             $object = "$base$extension";
1758             $linker = '';
1759         }
1760         else
1761         {
1762             # No error message here.  Used to have one, but it was
1763             # very unpopular.
1764             # FIXME: we could potentially do more processing here,
1765             # perhaps treating the new extension as though it were a
1766             # new source extension (as above).  This would require
1767             # more restructuring than is appropriate right now.
1768             next;
1769         }
1770
1771         err_am "object `$object' created by `$full' and `$object_map{$object}'"
1772           if (defined $object_map{$object}
1773               && $object_map{$object} ne $full);
1774
1775         my $comp_val = (($object =~ /\.lo$/)
1776                         ? COMPILE_LIBTOOL : COMPILE_ORDINARY);
1777         (my $comp_obj = $object) =~ s/\.lo$/.\$(OBJEXT)/;
1778         if (defined $object_compilation_map{$comp_obj}
1779             && $object_compilation_map{$comp_obj} != 0
1780             # Only see the error once.
1781             && ($object_compilation_map{$comp_obj}
1782                 != (COMPILE_LIBTOOL | COMPILE_ORDINARY))
1783             && $object_compilation_map{$comp_obj} != $comp_val)
1784           {
1785             err_am "object `$comp_obj' created both with libtool and without";
1786           }
1787         $object_compilation_map{$comp_obj} |= $comp_val;
1788
1789         if (defined $lang)
1790         {
1791             # Let the language do some special magic if required.
1792             $lang->target_hook ($aggregate, $object, $full, %transform);
1793         }
1794
1795         if ($derived_source)
1796           {
1797             prog_error ($lang->name . " has automatic dependency tracking")
1798               if $lang->autodep ne 'no';
1799             # Make sure this new source file is handled next.  That will
1800             # make it appear to be at the right place in the list.
1801             unshift (@files, $object);
1802             # Distribute derived sources unless the source they are
1803             # derived from is not.
1804             &push_dist_common ($object)
1805               unless ($topparent =~ /^(?:nobase_)?nodist_/);
1806             next;
1807           }
1808
1809         $linkers_used{$linker} = 1;
1810
1811         push (@result, $object);
1812
1813         if (! defined $object_map{$object})
1814         {
1815             my @dep_list = ();
1816             $object_map{$object} = $full;
1817
1818             # If resulting object is in subdir, we need to make
1819             # sure the subdir exists at build time.
1820             if ($object =~ /\//)
1821             {
1822                 # FIXME: check that $DIRECTORY is somewhere in the
1823                 # project
1824
1825                 # For Java, the way we're handling it right now, a
1826                 # `..' component doesn't make sense.
1827                 if ($lang->name eq 'java' && $object =~ /(\/|^)\.\.\//)
1828                   {
1829                     err_am "`$full' should not contain a `..' component";
1830                   }
1831
1832                 # Make sure object is removed by `make mostlyclean'.
1833                 $compile_clean_files{$object} = MOSTLY_CLEAN;
1834                 # If we have a libtool object then we also must remove
1835                 # the ordinary .o.
1836                 if ($object =~ /\.lo$/)
1837                 {
1838                     (my $xobj = $object) =~ s,lo$,\$(OBJEXT),;
1839                     $compile_clean_files{$xobj} = MOSTLY_CLEAN;
1840
1841                     # Remove any libtool object in this directory.
1842                     $libtool_clean_directories{$directory} = 1;
1843                 }
1844
1845                 push (@dep_list, require_build_directory ($directory));
1846
1847                 # If we're generating dependencies, we also want
1848                 # to make sure that the appropriate subdir of the
1849                 # .deps directory is created.
1850                 push (@dep_list,
1851                       require_build_directory ($directory . '/$(DEPDIR)'))
1852                   unless option 'no-dependencies';
1853             }
1854
1855             &pretty_print_rule ($object . ':', "\t", @dep_list)
1856                 if scalar @dep_list > 0;
1857         }
1858
1859         # Transform .o or $o file into .P file (for automatic
1860         # dependency code).
1861         if ($lang && $lang->autodep ne 'no')
1862         {
1863             my $depfile = $object;
1864             $depfile =~ s/\.([^.]*)$/.P$1/;
1865             $depfile =~ s/\$\(OBJEXT\)$/o/;
1866             $dep_files{dirname ($depfile) . '/$(DEPDIR)/'
1867                          . basename ($depfile)} = 1;
1868         }
1869     }
1870
1871     return @result;
1872 }
1873
1874
1875 # $LINKER
1876 # define_objects_from_sources ($VAR, $OBJVAR, $NODEFINE, $ONE_FILE,
1877 #                              $OBJ, $PARENT, $TOPPARENT, $WHERE, %TRANSFORM)
1878 # ---------------------------------------------------------------------------
1879 # Define an _OBJECTS variable for a _SOURCES variable (or subvariable)
1880 #
1881 # Arguments are:
1882 #   $VAR is the name of the _SOURCES variable
1883 #   $OBJVAR is the name of the _OBJECTS variable if known (otherwise
1884 #     it will be generated and returned).
1885 #   $NODEFINE is a boolean: if true, $OBJVAR will not be defined (but
1886 #     work done to determine the linker will be).
1887 #   $ONE_FILE is the canonical (transformed) name of object to build
1888 #   $OBJ is the object extension (i.e. either `.o' or `.lo').
1889 #   $TOPPARENT is the _SOURCES variable being processed.
1890 #   $WHERE context into which this definition is done
1891 #   %TRANSFORM extra arguments to pass to file_contents when producing
1892 #     rules
1893 #
1894 # Result is a pair ($LINKER, $OBJVAR):
1895 #    $LINKER is a boolean, true if a linker is needed to deal with the objects
1896 sub define_objects_from_sources ($$$$$$$%)
1897 {
1898   my ($var, $objvar, $nodefine, $one_file,
1899       $obj, $topparent, $where, %transform) = @_;
1900
1901   my $needlinker = "";
1902
1903   transform_variable_recursively
1904     ($var, $objvar, 'am__objects', $nodefine, $where,
1905      # The transform code to run on each filename.
1906      sub {
1907        my ($subvar, $val, $cond, $full_cond) = @_;
1908        my @trans = handle_single_transform ($subvar, $topparent,
1909                                             $one_file, $obj, $val,
1910                                             %transform);
1911        $needlinker = "true" if @trans;
1912        return @trans;
1913      });
1914
1915   return $needlinker;
1916 }
1917
1918
1919 # handle_source_transform ($CANON_TARGET, $TARGET, $OBJEXT, $WHERE, %TRANSFORM)
1920 # -----------------------------------------------------------------------------
1921 # Handle SOURCE->OBJECT transform for one program or library.
1922 # Arguments are:
1923 #   canonical (transformed) name of target to build
1924 #   actual target of object to build
1925 #   object extension (i.e., either `.o' or `$o')
1926 #   location of the source variable
1927 #   extra arguments to pass to file_contents when producing rules
1928 # Return the name of the linker variable that must be used.
1929 # Empty return means just use `LINK'.
1930 sub handle_source_transform ($$$$%)
1931 {
1932     # one_file is canonical name.  unxformed is given name.  obj is
1933     # object extension.
1934     my ($one_file, $unxformed, $obj, $where, %transform) = @_;
1935
1936     my $linker = '';
1937
1938     # No point in continuing if _OBJECTS is defined.
1939     return if reject_var ($one_file . '_OBJECTS',
1940                           $one_file . '_OBJECTS should not be defined');
1941
1942     my %used_pfx = ();
1943     my $needlinker;
1944     %linkers_used = ();
1945     foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1946                         'dist_EXTRA_', 'nodist_EXTRA_')
1947     {
1948         my $varname = $prefix . $one_file . "_SOURCES";
1949         my $var = var $varname;
1950         next unless $var;
1951
1952         # We are going to define _OBJECTS variables using the prefix.
1953         # Then we glom them all together.  So we can't use the null
1954         # prefix here as we need it later.
1955         my $xpfx = ($prefix eq '') ? 'am_' : $prefix;
1956
1957         # Keep track of which prefixes we saw.
1958         $used_pfx{$xpfx} = 1
1959           unless $prefix =~ /EXTRA_/;
1960
1961         push @sources, "\$($varname)";
1962         push @dist_sources, shadow_unconditionally ($varname, $where)
1963           unless (option ('no-dist') || $prefix =~ /^nodist_/);
1964
1965         $needlinker |=
1966             define_objects_from_sources ($varname,
1967                                          $xpfx . $one_file . '_OBJECTS',
1968                                          $prefix =~ /EXTRA_/,
1969                                          $one_file, $obj, $varname, $where,
1970                                          DIST_SOURCE => ($prefix !~ /^nodist_/),
1971                                          %transform);
1972     }
1973     if ($needlinker)
1974     {
1975         $linker ||= &resolve_linker (%linkers_used);
1976     }
1977
1978     my @keys = sort keys %used_pfx;
1979     if (scalar @keys == 0)
1980     {
1981         # The default source for libfoo.la is libfoo.c, but for
1982         # backward compatibility we first look at libfoo_la.c
1983         my $old_default_source = "$one_file.c";
1984         (my $default_source = $unxformed) =~ s,(\.[^./\\]*)?$,.c,;
1985         if ($old_default_source ne $default_source
1986             && (rule $old_default_source
1987                 || rule '$(srcdir)/' . $old_default_source
1988                 || rule '${srcdir}/' . $old_default_source
1989                 || -f $old_default_source))
1990           {
1991             my $loc = $where->clone;
1992             $loc->pop_context;
1993             msg ('obsolete', $loc,
1994                  "the default source for `$unxformed' has been changed "
1995                  . "to `$default_source'.\n(Using `$old_default_source' for "
1996                  . "backward compatibility.)");
1997             $default_source = $old_default_source;
1998           }
1999         # If a rule exists to build this source with a $(srcdir)
2000         # prefix, use that prefix in our variables too.  This is for
2001         # the sake of BSD Make.
2002         if (rule '$(srcdir)/' . $default_source
2003             || rule '${srcdir}/' . $default_source)
2004           {
2005             $default_source = '$(srcdir)/' . $default_source;
2006           }
2007
2008         &define_variable ($one_file . "_SOURCES", $default_source, $where);
2009         push (@sources, $default_source);
2010         push (@dist_sources, $default_source);
2011
2012         %linkers_used = ();
2013         my (@result) =
2014           handle_single_transform ($one_file . '_SOURCES',
2015                                    $one_file . '_SOURCES',
2016                                    $one_file, $obj,
2017                                    $default_source, %transform);
2018         $linker ||= &resolve_linker (%linkers_used);
2019         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @result);
2020     }
2021     else
2022     {
2023         @keys = map { '$(' . $_ . $one_file . '_OBJECTS)' } @keys;
2024         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @keys);
2025     }
2026
2027     # If we want to use `LINK' we must make sure it is defined.
2028     if ($linker eq '')
2029     {
2030         $need_link = 1;
2031     }
2032
2033     return $linker;
2034 }
2035
2036
2037 # handle_lib_objects ($XNAME, $VAR)
2038 # ---------------------------------
2039 # Special-case ALLOCA and LIBOBJS substitutions in _LDADD or _LIBADD variables.
2040 # Also, generate _DEPENDENCIES variable if appropriate.
2041 # Arguments are:
2042 #   transformed name of object being built, or empty string if no object
2043 #   name of _LDADD/_LIBADD-type variable to examine
2044 # Returns 1 if LIBOBJS seen, 0 otherwise.
2045 sub handle_lib_objects
2046 {
2047   my ($xname, $varname) = @_;
2048
2049   my $var = var ($varname);
2050   prog_error "handle_lib_objects: `$varname' undefined"
2051     unless $var;
2052   prog_error "handle_lib_objects: unexpected variable name `$varname'"
2053     unless $varname =~ /^(.*)(?:LIB|LD)ADD$/;
2054   my $prefix = $1 || 'AM_';
2055
2056   my $seen_libobjs = 0;
2057   my $flagvar = 0;
2058
2059   transform_variable_recursively
2060     ($varname, $xname . '_DEPENDENCIES', 'am__DEPENDENCIES',
2061      ! $xname, INTERNAL,
2062      # Transformation function, run on each filename.
2063      sub {
2064        my ($subvar, $val, $cond, $full_cond) = @_;
2065
2066        if ($val =~ /^-/)
2067          {
2068            # Skip -lfoo and -Ldir silently; these are explicitly allowed.
2069            if ($val !~ /^-[lL]/ &&
2070                # Skip -dlopen and -dlpreopen; these are explicitly allowed
2071                # for Libtool libraries or programs.  (Actually we are a bit
2072                # laxest here since this code also applies to non-libtool
2073                # libraries or programs, for which -dlopen and -dlopreopen
2074                # are pure non-sence.  Diagnosting this doesn't seems very
2075                # important: the developer will quickly get complaints from
2076                # the linker.)
2077                $val !~ /^-dl(?:pre)?open$/ &&
2078                # Only get this error once.
2079                ! $flagvar)
2080              {
2081                $flagvar = 1;
2082                # FIXME: should display a stack of nested variables
2083                # as context when $var != $subvar.
2084                err_var ($var, "linker flags such as `$val' belong in "
2085                         . "`${prefix}LDFLAGS");
2086              }
2087            return ();
2088          }
2089        elsif ($val !~ /^\@.*\@$/)
2090          {
2091            # Assume we have a file of some sort, and output it into the
2092            # dependency variable.  Autoconf substitutions are not output;
2093            # rarely is a new dependency substituted into e.g. foo_LDADD
2094            # -- but bad things (e.g. -lX11) are routinely substituted.
2095            # Note that LIBOBJS and ALLOCA are exceptions to this rule,
2096            # and handled specially below.
2097            return $val;
2098          }
2099        elsif ($val =~ /^\@(LT)?LIBOBJS\@$/)
2100          {
2101            handle_LIBOBJS ($subvar, $cond, $1);
2102            $seen_libobjs = 1;
2103            return $val;
2104          }
2105        elsif ($val =~ /^\@(LT)?ALLOCA\@$/)
2106          {
2107            handle_ALLOCA ($subvar, $cond, $1);
2108            return $val;
2109          }
2110        else
2111          {
2112            return ();
2113          }
2114      });
2115
2116   return $seen_libobjs;
2117 }
2118
2119 # handle_LIBOBJS_or_ALLOCA ($VAR)
2120 # -------------------------------
2121 # Definitions common to LIBOBJS and ALLOCA.
2122 # VAR should be one of LIBOBJS, LTLIBOBJS, ALLOCA, or LTALLOCA.
2123 sub handle_LIBOBJS_or_ALLOCA ($)
2124 {
2125   my ($var) = @_;
2126
2127   my $dir = $config_libobj_dir ? "$config_libobj_dir/" : '';
2128
2129   # If LIBOBJS files must be built in another directory we have
2130   # to define LIBOBJDIR and ensure the files get cleaned.
2131   # Otherwise LIBOBJDIR can be left undefined, and the cleaning
2132   # is achieved by `rm -f *.($OBJEXT)' in compile.am.
2133   if ($config_libobj_dir
2134       && $relative_dir ne $config_libobj_dir)
2135     {
2136       if (option 'subdir-objects')
2137         {
2138           define_variable ('LIBOBJDIR', "\$(top_builddir)/$dir", INTERNAL);
2139           $clean_files{"\$($var)"} = MOSTLY_CLEAN;
2140           # If LTLIBOBJS is used, we must also clear LIBOBJS (which might
2141           # be created by libtool as a side-effect of creating LTLIBOBJS).
2142           $clean_files{"\$($var)"} = MOSTLY_CLEAN if $var =~ s/^LT//;
2143
2144         }
2145       else
2146         {
2147           error ("`\$($var)' cannot be used outside `$dir' if"
2148                  . " `subdir-objects' is not set");
2149         }
2150     }
2151
2152   return $dir;
2153 }
2154
2155 sub handle_LIBOBJS ($$$)
2156 {
2157   my ($var, $cond, $lt) = @_;
2158   $lt ||= '';
2159   my $myobjext = ($1 ? 'l' : '') . 'o';
2160
2161   $var->requires_variables ("\@${lt}LIBOBJS\@ used", $lt . 'LIBOBJS')
2162     if ! keys %libsources;
2163
2164   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}LIBOBJS";
2165
2166   foreach my $iter (keys %libsources)
2167     {
2168       if ($iter =~ /\.[cly]$/)
2169         {
2170           &saw_extension ($&);
2171           &saw_extension ('.c');
2172         }
2173
2174       if ($iter =~ /\.h$/)
2175         {
2176           require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2177         }
2178       elsif ($iter ne 'alloca.c')
2179         {
2180           my $rewrite = $iter;
2181           $rewrite =~ s/\.c$/.P$myobjext/;
2182           $dep_files{$dir . '$(DEPDIR)/' . $rewrite} = 1;
2183           $rewrite = "^" . quotemeta ($iter) . "\$";
2184           # Only require the file if it is not a built source.
2185           my $bs = var ('BUILT_SOURCES');
2186           if (! $bs || ! grep (/$rewrite/, $bs->value_as_list_recursive))
2187             {
2188               require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2189             }
2190         }
2191     }
2192 }
2193
2194 sub handle_ALLOCA ($$$)
2195 {
2196   my ($var, $cond, $lt) = @_;
2197   my $myobjext = ($lt ? 'l' : '') . 'o';
2198   $lt ||= '';
2199   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}ALLOCA";
2200
2201   $var->requires_variables ("\@${lt}ALLOCA\@ used", $lt . 'ALLOCA');
2202   $dep_files{$dir . '$(DEPDIR)/alloca.P' . $myobjext} = 1;
2203   require_libsource_with_macro ($cond, $var, FOREIGN, 'alloca.c');
2204   &saw_extension ('.c');
2205 }
2206
2207 # Canonicalize the input parameter
2208 sub canonicalize
2209 {
2210     my ($string) = @_;
2211     $string =~ tr/A-Za-z0-9_\@/_/c;
2212     return $string;
2213 }
2214
2215 # Canonicalize a name, and check to make sure the non-canonical name
2216 # is never used.  Returns canonical name.  Arguments are name and a
2217 # list of suffixes to check for.
2218 sub check_canonical_spelling
2219 {
2220   my ($name, @suffixes) = @_;
2221
2222   my $xname = &canonicalize ($name);
2223   if ($xname ne $name)
2224     {
2225       foreach my $xt (@suffixes)
2226         {
2227           reject_var ("$name$xt", "use `$xname$xt', not `$name$xt'");
2228         }
2229     }
2230
2231   return $xname;
2232 }
2233
2234
2235 # handle_compile ()
2236 # -----------------
2237 # Set up the compile suite.
2238 sub handle_compile ()
2239 {
2240     return
2241       unless $get_object_extension_was_run;
2242
2243     # Boilerplate.
2244     my $default_includes = '';
2245     if (! option 'nostdinc')
2246       {
2247         $default_includes = ' -I. -I$(srcdir)';
2248
2249         my $var = var 'CONFIG_HEADER';
2250         if ($var)
2251           {
2252             foreach my $hdr (split (' ', $var->variable_value))
2253               {
2254                 $default_includes .= ' -I' . dirname ($hdr);
2255               }
2256           }
2257       }
2258
2259     my (@mostly_rms, @dist_rms);
2260     foreach my $item (sort keys %compile_clean_files)
2261     {
2262         if ($compile_clean_files{$item} == MOSTLY_CLEAN)
2263         {
2264             push (@mostly_rms, "\t-rm -f $item");
2265         }
2266         elsif ($compile_clean_files{$item} == DIST_CLEAN)
2267         {
2268             push (@dist_rms, "\t-rm -f $item");
2269         }
2270         else
2271         {
2272           prog_error 'invalid entry in %compile_clean_files';
2273         }
2274     }
2275
2276     my ($coms, $vars, $rules) =
2277       &file_contents_internal (1, "$libdir/am/compile.am",
2278                                new Automake::Location,
2279                                ('DEFAULT_INCLUDES' => $default_includes,
2280                                 'MOSTLYRMS' => join ("\n", @mostly_rms),
2281                                 'DISTRMS' => join ("\n", @dist_rms)));
2282     $output_vars .= $vars;
2283     $output_rules .= "$coms$rules";
2284
2285     # Check for automatic de-ANSI-fication.
2286     if (option 'ansi2knr')
2287       {
2288         my ($ansi2knr_filename, $ansi2knr_where) = @{option 'ansi2knr'};
2289         my $ansi2knr_dir = '';
2290
2291         require_variables ($ansi2knr_where, "option `ansi2knr' is used",
2292                            TRUE, "ANSI2KNR", "U");
2293
2294         # topdir is where ansi2knr should be.
2295         if ($ansi2knr_filename eq 'ansi2knr')
2296           {
2297             # Only require ansi2knr files if they should appear in
2298             # this directory.
2299             require_file ($ansi2knr_where, FOREIGN,
2300                           'ansi2knr.c', 'ansi2knr.1');
2301
2302             # ansi2knr needs to be built before subdirs, so unshift it.
2303             unshift (@all, '$(ANSI2KNR)');
2304           }
2305         else
2306           {
2307             $ansi2knr_dir = dirname ($ansi2knr_filename);
2308           }
2309
2310         $output_rules .= &file_contents ('ansi2knr',
2311                                          new Automake::Location,
2312                                          'ANSI2KNR-DIR' => $ansi2knr_dir);
2313
2314     }
2315 }
2316
2317 # handle_libtool ()
2318 # -----------------
2319 # Handle libtool rules.
2320 sub handle_libtool
2321 {
2322   return unless var ('LIBTOOL');
2323
2324   # Libtool requires some files, but only at top level.
2325   # (Starting with Libtool 2.0 we do not have to bother.  These
2326   # requirements are done with AC_REQUIRE_AUX_FILE.)
2327   require_conf_file_with_macro (TRUE, 'LIBTOOL', FOREIGN, @libtool_files)
2328     if $relative_dir eq '.' && ! $libtool_new_api;
2329
2330   my @libtool_rms;
2331   foreach my $item (sort keys %libtool_clean_directories)
2332     {
2333       my $dir = ($item eq '.') ? '' : "$item/";
2334       # .libs is for Unix, _libs for DOS.
2335       push (@libtool_rms, "\t-rm -rf ${dir}.libs ${dir}_libs");
2336     }
2337
2338   check_user_variables 'LIBTOOLFLAGS';
2339
2340   # Output the libtool compilation rules.
2341   $output_rules .= &file_contents ('libtool',
2342                                    new Automake::Location,
2343                                    LTRMS => join ("\n", @libtool_rms));
2344 }
2345
2346 # handle_programs ()
2347 # ------------------
2348 # Handle C programs.
2349 sub handle_programs
2350 {
2351   my @proglist = &am_install_var ('progs', 'PROGRAMS',
2352                                   'bin', 'sbin', 'libexec', 'pkglib',
2353                                   'noinst', 'check');
2354   return if ! @proglist;
2355
2356   my $seen_global_libobjs =
2357     var ('LDADD') && &handle_lib_objects ('', 'LDADD');
2358
2359   foreach my $pair (@proglist)
2360     {
2361       my ($where, $one_file) = @$pair;
2362
2363       my $seen_libobjs = 0;
2364       my $obj = get_object_extension '.$(OBJEXT)';
2365
2366       # Strip any $(EXEEXT) suffix the user might have added, or this
2367       # will confuse &handle_source_transform and &check_canonical_spelling.
2368       # We'll add $(EXEEXT) back later anyway.
2369       $one_file =~ s/\$\(EXEEXT\)$//;
2370
2371       # Canonicalize names and check for misspellings.
2372       my $xname = &check_canonical_spelling ($one_file, '_LDADD', '_LDFLAGS',
2373                                              '_SOURCES', '_OBJECTS',
2374                                              '_DEPENDENCIES');
2375
2376       $where->push_context ("while processing program `$one_file'");
2377       $where->set (INTERNAL->get);
2378
2379       my $linker = &handle_source_transform ($xname, $one_file, $obj, $where,
2380                                              NONLIBTOOL => 1, LIBTOOL => 0);
2381
2382       if (var ($xname . "_LDADD"))
2383         {
2384           $seen_libobjs = &handle_lib_objects ($xname, $xname . '_LDADD');
2385         }
2386       else
2387         {
2388           # User didn't define prog_LDADD override.  So do it.
2389           &define_variable ($xname . '_LDADD', '$(LDADD)', $where);
2390
2391           # This does a bit too much work.  But we need it to
2392           # generate _DEPENDENCIES when appropriate.
2393           if (var ('LDADD'))
2394             {
2395               $seen_libobjs = &handle_lib_objects ($xname, 'LDADD');
2396             }
2397         }
2398
2399       reject_var ($xname . '_LIBADD',
2400                   "use `${xname}_LDADD', not `${xname}_LIBADD'");
2401
2402       set_seen ($xname . '_DEPENDENCIES');
2403       set_seen ($xname . '_LDFLAGS');
2404
2405       # Determine program to use for link.
2406       my $xlink = &define_per_target_linker_variable ($linker, $xname);
2407
2408       # If the resulting program lies into a subdirectory,
2409       # make sure this directory will exist.
2410       my $dirstamp = require_build_directory_maybe ($one_file);
2411
2412       $output_rules .= &file_contents ('program',
2413                                        $where,
2414                                        PROGRAM  => $one_file,
2415                                        XPROGRAM => $xname,
2416                                        XLINK    => $xlink,
2417                                        DIRSTAMP => $dirstamp,
2418                                        EXEEXT   => '$(EXEEXT)');
2419
2420       if ($seen_libobjs || $seen_global_libobjs)
2421         {
2422           if (var ($xname . '_LDADD'))
2423             {
2424               &check_libobjs_sources ($xname, $xname . '_LDADD');
2425             }
2426           elsif (var ('LDADD'))
2427             {
2428               &check_libobjs_sources ($xname, 'LDADD');
2429             }
2430         }
2431     }
2432 }
2433
2434
2435 # handle_libraries ()
2436 # -------------------
2437 # Handle libraries.
2438 sub handle_libraries
2439 {
2440   my @liblist = &am_install_var ('libs', 'LIBRARIES',
2441                                  'lib', 'pkglib', 'noinst', 'check');
2442   return if ! @liblist;
2443
2444   my @prefix = am_primary_prefixes ('LIBRARIES', 0, 'lib', 'pkglib',
2445                                     'noinst', 'check');
2446
2447   if (@prefix)
2448     {
2449       my $var = rvar ($prefix[0] . '_LIBRARIES');
2450       $var->requires_variables ('library used', 'RANLIB');
2451     }
2452
2453   &define_variable ('AR', 'ar', INTERNAL);
2454   &define_variable ('ARFLAGS', 'cru', INTERNAL);
2455
2456   foreach my $pair (@liblist)
2457     {
2458       my ($where, $onelib) = @$pair;
2459
2460       my $seen_libobjs = 0;
2461       # Check that the library fits the standard naming convention.
2462       my $bn = basename ($onelib);
2463       if ($bn !~ /^lib.*\.a$/)
2464         {
2465           $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.a/;
2466           my $suggestion = dirname ($onelib) . "/$bn";
2467           $suggestion =~ s|^\./||g;
2468           msg ('error-gnu/warn', $where,
2469                "`$onelib' is not a standard library name\n"
2470                . "did you mean `$suggestion'?")
2471         }
2472
2473       $where->push_context ("while processing library `$onelib'");
2474       $where->set (INTERNAL->get);
2475
2476       my $obj = get_object_extension '.$(OBJEXT)';
2477
2478       # Canonicalize names and check for misspellings.
2479       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_SOURCES',
2480                                             '_OBJECTS', '_DEPENDENCIES',
2481                                             '_AR');
2482
2483       if (! var ($xlib . '_AR'))
2484         {
2485           &define_variable ($xlib . '_AR', '$(AR) $(ARFLAGS)', $where);
2486         }
2487
2488       # Generate support for conditional object inclusion in
2489       # libraries.
2490       if (var ($xlib . '_LIBADD'))
2491         {
2492           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2493             {
2494               $seen_libobjs = 1;
2495             }
2496         }
2497       else
2498         {
2499           &define_variable ($xlib . "_LIBADD", '', $where);
2500         }
2501
2502       reject_var ($xlib . '_LDADD',
2503                   "use `${xlib}_LIBADD', not `${xlib}_LDADD'");
2504
2505       # Make sure we at look at this.
2506       set_seen ($xlib . '_DEPENDENCIES');
2507
2508       &handle_source_transform ($xlib, $onelib, $obj, $where,
2509                                 NONLIBTOOL => 1, LIBTOOL => 0);
2510
2511       # If the resulting library lies into a subdirectory,
2512       # make sure this directory will exist.
2513       my $dirstamp = require_build_directory_maybe ($onelib);
2514
2515       $output_rules .= &file_contents ('library',
2516                                        $where,
2517                                        LIBRARY  => $onelib,
2518                                        XLIBRARY => $xlib,
2519                                        DIRSTAMP => $dirstamp);
2520
2521       if ($seen_libobjs)
2522         {
2523           if (var ($xlib . '_LIBADD'))
2524             {
2525               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2526             }
2527         }
2528     }
2529 }
2530
2531
2532 # handle_ltlibraries ()
2533 # ---------------------
2534 # Handle shared libraries.
2535 sub handle_ltlibraries
2536 {
2537   my @liblist = &am_install_var ('ltlib', 'LTLIBRARIES',
2538                                  'noinst', 'lib', 'pkglib', 'check');
2539   return if ! @liblist;
2540
2541   my @prefix = am_primary_prefixes ('LTLIBRARIES', 0, 'lib', 'pkglib',
2542                                     'noinst', 'check');
2543
2544   if (@prefix)
2545     {
2546       my $var = rvar ($prefix[0] . '_LTLIBRARIES');
2547       $var->requires_variables ('Libtool library used', 'LIBTOOL');
2548     }
2549
2550   my %instdirs = ();
2551   my %instconds = ();
2552   my %liblocations = ();        # Location (in Makefile.am) of each library.
2553
2554   foreach my $key (@prefix)
2555     {
2556       # Get the installation directory of each library.
2557       (my $dir = $key) =~ s/^nobase_//;
2558       my $var = rvar ($key . '_LTLIBRARIES');
2559
2560       # We reject libraries which are installed in several places
2561       # in the same condition, because we can only specify one
2562       # `-rpath' option.
2563       $var->traverse_recursively
2564         (sub
2565          {
2566            my ($var, $val, $cond, $full_cond) = @_;
2567            my $hcond = $full_cond->human;
2568            my $where = $var->rdef ($cond)->location;
2569            # A library cannot be installed in different directory
2570            # in overlapping conditions.
2571            if (exists $instconds{$val})
2572              {
2573                my ($msg, $acond) =
2574                  $instconds{$val}->ambiguous_p ($val, $full_cond);
2575
2576                if ($msg)
2577                  {
2578                    error ($where, $msg, partial => 1);
2579
2580                    my $dirtxt = "installed in `$dir'";
2581                    $dirtxt = "built for `$dir'"
2582                      if $dir eq 'EXTRA' || $dir eq 'noinst' || $dir eq 'check';
2583                    my $dircond =
2584                      $full_cond->true ? "" : " in condition $hcond";
2585
2586                    error ($where, "`$val' should be $dirtxt$dircond ...",
2587                           partial => 1);
2588
2589                    my $hacond = $acond->human;
2590                    my $adir = $instdirs{$val}{$acond};
2591                    my $adirtxt = "installed in `$adir'";
2592                    $adirtxt = "built for `$adir'"
2593                      if ($adir eq 'EXTRA' || $adir eq 'noinst'
2594                          || $adir eq 'check');
2595                    my $adircond = $acond->true ? "" : " in condition $hacond";
2596
2597                    my $onlyone = ($dir ne $adir) ?
2598                      ("\nLibtool libraries can be built for only one "
2599                       . "destination.") : "";
2600
2601                    error ($liblocations{$val}{$acond},
2602                           "... and should also be $adirtxt$adircond.$onlyone");
2603                    return;
2604                  }
2605              }
2606            else
2607              {
2608                $instconds{$val} = new Automake::DisjConditions;
2609              }
2610            $instdirs{$val}{$full_cond} = $dir;
2611            $liblocations{$val}{$full_cond} = $where;
2612            $instconds{$val} = $instconds{$val}->merge ($full_cond);
2613          },
2614          sub
2615          {
2616            return ();
2617          },
2618          skip_ac_subst => 1);
2619     }
2620
2621   foreach my $pair (@liblist)
2622     {
2623       my ($where, $onelib) = @$pair;
2624
2625       my $seen_libobjs = 0;
2626       my $obj = get_object_extension '.lo';
2627
2628       # Canonicalize names and check for misspellings.
2629       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_LDFLAGS',
2630                                             '_SOURCES', '_OBJECTS',
2631                                             '_DEPENDENCIES');
2632
2633       # Check that the library fits the standard naming convention.
2634       my $libname_rx = '^lib.*\.la';
2635       my $ldvar = var ("${xlib}_LDFLAGS") || var ('AM_LDFLAGS');
2636       my $ldvar2 = var ('LDFLAGS');
2637       if (($ldvar && grep (/-module/, $ldvar->value_as_list_recursive))
2638           || ($ldvar2 && grep (/-module/, $ldvar2->value_as_list_recursive)))
2639         {
2640           # Relax name checking for libtool modules.
2641           $libname_rx = '\.la';
2642         }
2643
2644       my $bn = basename ($onelib);
2645       if ($bn !~ /$libname_rx$/)
2646         {
2647           my $type = 'library';
2648           if ($libname_rx eq '\.la')
2649             {
2650               $bn =~ s/^(lib|)(.*?)(?:\.[^.]*)?$/$1$2.la/;
2651               $type = 'module';
2652             }
2653           else
2654             {
2655               $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.la/;
2656             }
2657           my $suggestion = dirname ($onelib) . "/$bn";
2658           $suggestion =~ s|^\./||g;
2659           msg ('error-gnu/warn', $where,
2660                "`$onelib' is not a standard libtool $type name\n"
2661                . "did you mean `$suggestion'?")
2662         }
2663
2664       $where->push_context ("while processing Libtool library `$onelib'");
2665       $where->set (INTERNAL->get);
2666
2667       # Make sure we look at these.
2668       set_seen ($xlib . '_LDFLAGS');
2669       set_seen ($xlib . '_DEPENDENCIES');
2670
2671       # Generate support for conditional object inclusion in
2672       # libraries.
2673       if (var ($xlib . '_LIBADD'))
2674         {
2675           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2676             {
2677               $seen_libobjs = 1;
2678             }
2679         }
2680       else
2681         {
2682           &define_variable ($xlib . "_LIBADD", '', $where);
2683         }
2684
2685       reject_var ("${xlib}_LDADD",
2686                   "use `${xlib}_LIBADD', not `${xlib}_LDADD'");
2687
2688
2689       my $linker = &handle_source_transform ($xlib, $onelib, $obj, $where,
2690                                              NONLIBTOOL => 0, LIBTOOL => 1);
2691
2692       # Determine program to use for link.
2693       my $xlink = &define_per_target_linker_variable ($linker, $xlib);
2694
2695       my $rpathvar = "am_${xlib}_rpath";
2696       my $rpath = "\$($rpathvar)";
2697       foreach my $rcond ($instconds{$onelib}->conds)
2698         {
2699           my $val;
2700           if ($instdirs{$onelib}{$rcond} eq 'EXTRA'
2701               || $instdirs{$onelib}{$rcond} eq 'noinst'
2702               || $instdirs{$onelib}{$rcond} eq 'check')
2703             {
2704               # It's an EXTRA_ library, so we can't specify -rpath,
2705               # because we don't know where the library will end up.
2706               # The user probably knows, but generally speaking automake
2707               # doesn't -- and in fact configure could decide
2708               # dynamically between two different locations.
2709               $val = '';
2710             }
2711           else
2712             {
2713               $val = ('-rpath $(' . $instdirs{$onelib}{$rcond} . 'dir)');
2714             }
2715           if ($rcond->true)
2716             {
2717               # If $rcond is true there is only one condition and
2718               # there is no point defining an helper variable.
2719               $rpath = $val;
2720             }
2721           else
2722             {
2723               define_pretty_variable ($rpathvar, $rcond, INTERNAL, $val);
2724             }
2725         }
2726
2727       # If the resulting library lies into a subdirectory,
2728       # make sure this directory will exist.
2729       my $dirstamp = require_build_directory_maybe ($onelib);
2730
2731       # Remember to cleanup .libs/ in this directory.
2732       my $dirname = dirname $onelib;
2733       $libtool_clean_directories{$dirname} = 1;
2734
2735       $output_rules .= &file_contents ('ltlibrary',
2736                                        $where,
2737                                        LTLIBRARY  => $onelib,
2738                                        XLTLIBRARY => $xlib,
2739                                        RPATH      => $rpath,
2740                                        XLINK      => $xlink,
2741                                        DIRSTAMP   => $dirstamp);
2742       if ($seen_libobjs)
2743         {
2744           if (var ($xlib . '_LIBADD'))
2745             {
2746               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2747             }
2748         }
2749     }
2750 }
2751
2752 # See if any _SOURCES variable were misspelled.
2753 sub check_typos ()
2754 {
2755   # It is ok if the user sets this particular variable.
2756   set_seen 'AM_LDFLAGS';
2757
2758   foreach my $primary ('SOURCES', 'LIBADD', 'LDADD', 'LDFLAGS', 'DEPENDENCIES')
2759     {
2760       foreach my $var (variables $primary)
2761         {
2762           my $varname = $var->name;
2763           # A configure variable is always legitimate.
2764           next if exists $configure_vars{$varname};
2765
2766           for my $cond ($var->conditions->conds)
2767             {
2768               $varname =~ /^(?:nobase_)?(?:dist_|nodist_)?(.*)_[[:alnum:]]+$/;
2769               msg_var ('syntax', $var, "variable `$varname' is defined but no"
2770                        . " program or\nlibrary has `$1' as canonic name"
2771                        . " (possible typo)")
2772                 unless $var->rdef ($cond)->seen;
2773             }
2774         }
2775     }
2776 }
2777
2778
2779 # Handle scripts.
2780 sub handle_scripts
2781 {
2782     # NOTE we no longer automatically clean SCRIPTS, because it is
2783     # useful to sometimes distribute scripts verbatim.  This happens
2784     # e.g. in Automake itself.
2785     &am_install_var ('-candist', 'scripts', 'SCRIPTS',
2786                      'bin', 'sbin', 'libexec', 'pkgdata',
2787                      'noinst', 'check');
2788 }
2789
2790
2791
2792
2793 ## ------------------------ ##
2794 ## Handling Texinfo files.  ##
2795 ## ------------------------ ##
2796
2797 # ($OUTFILE, $VFILE, @CLEAN_FILES)
2798 # &scan_texinfo_file ($FILENAME)
2799 # ------------------------------
2800 # $OUTFILE     - name of the info file produced by $FILENAME.
2801 # $VFILE       - name of the version.texi file used (undef if none).
2802 # @CLEAN_FILES - list of byproducts (indexes etc.)
2803 sub scan_texinfo_file ($)
2804 {
2805   my ($filename) = @_;
2806
2807   # Some of the following extensions are always created, no matter
2808   # whether indexes are used or not.  Other (like cps, fns, ... pgs)
2809   # are only created when they are used.  We used to scan $FILENAME
2810   # for their use, but that is not enough: they could be used in
2811   # included files.  We can't scan included files because we don't
2812   # know the include path.  Therefore we always erase these files, no
2813   # matter whether they are used or not.
2814   #
2815   # (tmp is only created if an @macro is used and a certain e-TeX
2816   # feature is not available.)
2817   my %clean_suffixes =
2818     map { $_ => 1 } (qw(aux log toc tmp
2819                         cp cps
2820                         fn fns
2821                         ky kys
2822                         vr vrs
2823                         tp tps
2824                         pg pgs)); # grep 'new.*index' texinfo.tex
2825
2826   my $texi = new Automake::XFile "< $filename";
2827   verb "reading $filename";
2828
2829   my ($outfile, $vfile);
2830   while ($_ = $texi->getline)
2831     {
2832       if (/^\@setfilename +(\S+)/)
2833         {
2834           # Honor only the first @setfilename.  (It's possible to have
2835           # more occurrences later if the manual shows examples of how
2836           # to use @setfilename...)
2837           next if $outfile;
2838
2839           $outfile = $1;
2840           if ($outfile =~ /\.(.+)$/ && $1 ne 'info')
2841             {
2842               error ("$filename:$.",
2843                      "output `$outfile' has unrecognized extension");
2844               return;
2845             }
2846         }
2847       # A "version.texi" file is actually any file whose name matches
2848       # "vers*.texi".
2849       elsif (/^\@include\s+(vers[^.]*\.texi)\s*$/)
2850         {
2851           $vfile = $1;
2852         }
2853
2854       # Try to find new or unused indexes.
2855
2856       # Creating a new category of index.
2857       elsif (/^\@def(code)?index (\w+)/)
2858         {
2859           $clean_suffixes{$2} = 1;
2860           $clean_suffixes{"$2s"} = 1;
2861         }
2862
2863       # Merging an index into an another.
2864       elsif (/^\@syn(code)?index (\w+) (\w+)/)
2865         {
2866           delete $clean_suffixes{"$2s"};
2867           $clean_suffixes{"$3s"} = 1;
2868         }
2869
2870     }
2871
2872   if (! $outfile)
2873     {
2874       err_am "`$filename' missing \@setfilename";
2875       return;
2876     }
2877
2878   my $infobase = basename ($filename);
2879   $infobase =~ s/\.te?xi(nfo)?$//;
2880   return ($outfile, $vfile,
2881           map { "$infobase.$_" } (sort keys %clean_suffixes));
2882 }
2883
2884
2885 # ($DIRSTAMP, @CLEAN_FILES)
2886 # output_texinfo_build_rules ($SOURCE, $DEST, $INSRC, @DEPENDENCIES)
2887 # ------------------------------------------------------------------
2888 # SOURCE - the source Texinfo file
2889 # DEST - the destination Info file
2890 # INSRC - wether DEST should be built in the source tree
2891 # DEPENDENCIES - known dependencies
2892 sub output_texinfo_build_rules ($$$@)
2893 {
2894   my ($source, $dest, $insrc, @deps) = @_;
2895
2896   # Split `a.texi' into `a' and `.texi'.
2897   my ($spfx, $ssfx) = ($source =~ /^(.*?)(\.[^.]*)?$/);
2898   my ($dpfx, $dsfx) = ($dest =~ /^(.*?)(\.[^.]*)?$/);
2899
2900   $ssfx ||= "";
2901   $dsfx ||= "";
2902
2903   # We can output two kinds of rules: the "generic" rules use Make
2904   # suffix rules and are appropriate when $source and $dest do not lie
2905   # in a sub-directory; the "specific" rules are needed in the other
2906   # case.
2907   #
2908   # The former are output only once (this is not really apparent here,
2909   # but just remember that some logic deeper in Automake will not
2910   # output the same rule twice); while the later need to be output for
2911   # each Texinfo source.
2912   my $generic;
2913   my $makeinfoflags;
2914   my $sdir = dirname $source;
2915   if ($sdir eq '.' && dirname ($dest) eq '.')
2916     {
2917       $generic = 1;
2918       $makeinfoflags = '-I $(srcdir)';
2919     }
2920   else
2921     {
2922       $generic = 0;
2923       $makeinfoflags = "-I $sdir -I \$(srcdir)/$sdir";
2924     }
2925
2926   # A directory can contain two kinds of info files: some built in the
2927   # source tree, and some built in the build tree.  The rules are
2928   # different in each case.  However we cannot output two different
2929   # set of generic rules.  Because in-source builds are more usual, we
2930   # use generic rules in this case and fall back to "specific" rules
2931   # for build-dir builds.  (It should not be a problem to invert this
2932   # if needed.)
2933   $generic = 0 unless $insrc;
2934
2935   # We cannot use a suffix rule to build info files with an empty
2936   # extension.  Otherwise we would output a single suffix inference
2937   # rule, with separate dependencies, as in
2938   #
2939   #    .texi:
2940   #             $(MAKEINFO) ...
2941   #    foo.info: foo.texi
2942   #
2943   # which confuse Solaris make.  (See the Autoconf manual for
2944   # details.)  Therefore we use a specific rule in this case.  This
2945   # applies to info files only (dvi and pdf files always have an
2946   # extension).
2947   my $generic_info = ($generic && $dsfx) ? 1 : 0;
2948
2949   # If the resulting file lie into a subdirectory,
2950   # make sure this directory will exist.
2951   my $dirstamp = require_build_directory_maybe ($dest);
2952
2953   my $dipfx = ($insrc ? '$(srcdir)/' : '') . $dpfx;
2954
2955   $output_rules .= file_contents ('texibuild',
2956                                   new Automake::Location,
2957                                   DEPS             => "@deps",
2958                                   DEST_PREFIX      => $dpfx,
2959                                   DEST_INFO_PREFIX => $dipfx,
2960                                   DEST_SUFFIX      => $dsfx,
2961                                   DIRSTAMP         => $dirstamp,
2962                                   GENERIC          => $generic,
2963                                   GENERIC_INFO     => $generic_info,
2964                                   INSRC            => $insrc,
2965                                   MAKEINFOFLAGS    => $makeinfoflags,
2966                                   SOURCE           => ($generic
2967                                                        ? '$<' : $source),
2968                                   SOURCE_INFO      => ($generic_info
2969                                                        ? '$<' : $source),
2970                                   SOURCE_REAL      => $source,
2971                                   SOURCE_SUFFIX    => $ssfx,
2972                                   );
2973   return ($dirstamp, "$dpfx.dvi", "$dpfx.pdf", "$dpfx.ps", "$dpfx.html");
2974 }
2975
2976
2977 # $TEXICLEANS
2978 # handle_texinfo_helper ($info_texinfos)
2979 # --------------------------------------
2980 # Handle all Texinfo source; helper for handle_texinfo.
2981 sub handle_texinfo_helper ($)
2982 {
2983   my ($info_texinfos) = @_;
2984   my (@infobase, @info_deps_list, @texi_deps);
2985   my %versions;
2986   my $done = 0;
2987   my @texi_cleans;
2988
2989   # Build a regex matching user-cleaned files.
2990   my $d = var 'DISTCLEANFILES';
2991   my $c = var 'CLEANFILES';
2992   my @f = ();
2993   push @f, $d->value_as_list_recursive (inner_expand => 1) if $d;
2994   push @f, $c->value_as_list_recursive (inner_expand => 1) if $c;
2995   @f = map { s|[^A-Za-z_0-9*\[\]\-]|\\$&|g; s|\*|[^/]*|g; $_; } @f;
2996   my $user_cleaned_files = '^(?:' . join ('|', @f) . ')$';
2997
2998   foreach my $texi
2999       ($info_texinfos->value_as_list_recursive (inner_expand => 1))
3000     {
3001       my $infobase = $texi;
3002       $infobase =~ s/\.(txi|texinfo|texi)$//;
3003
3004       if ($infobase eq $texi)
3005         {
3006           # FIXME: report line number.
3007           err_am "texinfo file `$texi' has unrecognized extension";
3008           next;
3009         }
3010
3011       push @infobase, $infobase;
3012
3013       # If 'version.texi' is referenced by input file, then include
3014       # automatic versioning capability.
3015       my ($out_file, $vtexi, @clean_files) =
3016         scan_texinfo_file ("$relative_dir/$texi")
3017         or next;
3018       push (@texi_cleans, @clean_files);
3019
3020       # If the Texinfo source is in a subdirectory, create the
3021       # resulting info in this subdirectory.  If it is in the current
3022       # directory, try hard to not prefix "./" because it breaks the
3023       # generic rules.
3024       my $outdir = dirname ($texi) . '/';
3025       $outdir = "" if $outdir eq './';
3026       $out_file =  $outdir . $out_file;
3027
3028       # Until Automake 1.6.3, .info files were built in the
3029       # source tree.  This was an obstacle to the support of
3030       # non-distributed .info files, and non-distributed .texi
3031       # files.
3032       #
3033       # * Non-distributed .texi files is important in some packages
3034       #   where .texi files are built at make time, probably using
3035       #   other binaries built in the package itself, maybe using
3036       #   tools or information found on the build host.  Because
3037       #   these files are not distributed they are always rebuilt
3038       #   at make time; they should therefore not lie in the source
3039       #   directory.  One plan was to support this using
3040       #   nodist_info_TEXINFOS or something similar.  (Doing this
3041       #   requires some sanity checks.  For instance Automake should
3042       #   not allow:
3043       #      dist_info_TEXINFO = foo.texi
3044       #      nodist_foo_TEXINFO = included.texi
3045       #   because a distributed file should never depend on a
3046       #   non-distributed file.)
3047       #
3048       # * If .texi files are not distributed, then .info files should
3049       #   not be distributed either.  There are also cases where one
3050       #   want to distribute .texi files, but do not want to
3051       #   distribute the .info files.  For instance the Texinfo package
3052       #   distributes the tool used to build these files; it would
3053       #   be a waste of space to distribute them.  It's not clear
3054       #   which syntax we should use to indicate that .info files should
3055       #   not be distributed.  Akim Demaille suggested that eventually
3056       #   we switch to a new syntax:
3057       #   |  Maybe we should take some inspiration from what's already
3058       #   |  done in the rest of Automake.  Maybe there is too much
3059       #   |  syntactic sugar here, and you want
3060       #   |     nodist_INFO = bar.info
3061       #   |     dist_bar_info_SOURCES = bar.texi
3062       #   |     bar_texi_DEPENDENCIES = foo.texi
3063       #   |  with a bit of magic to have bar.info represent the whole
3064       #   |  bar*info set.  That's a lot more verbose that the current
3065       #   |  situation, but it is # not new, hence the user has less
3066       #   |  to learn.
3067       #   |
3068       #   |  But there is still too much room for meaningless specs:
3069       #   |     nodist_INFO = bar.info
3070       #   |     dist_bar_info_SOURCES = bar.texi
3071       #   |     dist_PS = bar.ps something-written-by-hand.ps
3072       #   |     nodist_bar_ps_SOURCES = bar.texi
3073       #   |     bar_texi_DEPENDENCIES = foo.texi
3074       #   |  here bar.texi is dist_ in line 2, and nodist_ in 4.
3075       #
3076       # Back to the point, it should be clear that in order to support
3077       # non-distributed .info files, we need to build them in the
3078       # build tree, not in the source tree (non-distributed .texi
3079       # files are less of a problem, because we do not output build
3080       # rules for them).  In Automake 1.7 .info build rules have been
3081       # largely cleaned up so that .info files get always build in the
3082       # build tree, even when distributed.  The idea was that
3083       #   (1) if during a VPATH build the .info file was found to be
3084       #       absent or out-of-date (in the source tree or in the
3085       #       build tree), Make would rebuild it in the build tree.
3086       #       If an up-to-date source-tree of the .info file existed,
3087       #       make would not rebuild it in the build tree.
3088       #   (2) having two copies of .info files, one in the source tree
3089       #       and one (newer) in the build tree is not a problem
3090       #       because `make dist' always pick files in the build tree
3091       #       first.
3092       # However it turned out the be a bad idea for several reasons:
3093       #   * Tru64, OpenBSD, and FreeBSD (not NetBSD) Make do not behave
3094       #     like GNU Make on point (1) above.  These implementations
3095       #     of Make would always rebuild .info files in the build
3096       #     tree, even if such files were up to date in the source
3097       #     tree.  Consequently, it was impossible to perform a VPATH
3098       #     build of a package containing Texinfo files using these
3099       #     Make implementations.
3100       #     (Refer to the Autoconf Manual, section "Limitation of
3101       #     Make", paragraph "VPATH", item "target lookup", for
3102       #     an account of the differences between these
3103       #     implementations.)
3104       #   * The GNU Coding Standards require these files to be built
3105       #     in the source-tree (when they are distributed, that is).
3106       #   * Keeping a fresher copy of distributed files in the
3107       #     build tree can be annoying during development because
3108       #     - if the files is kept under CVS, you really want it
3109       #       to be updated in the source tree
3110       #     - it is confusing that `make distclean' does not erase
3111       #       all files in the build tree.
3112       #
3113       # Consequently, starting with Automake 1.8, .info files are
3114       # built in the source tree again.  Because we still plan to
3115       # support non-distributed .info files at some point, we
3116       # have a single variable ($INSRC) that controls whether
3117       # the current .info file must be built in the source tree
3118       # or in the build tree.  Actually this variable is switched
3119       # off for .info files that appear to be cleaned; this is
3120       # for backward compatibility with package such as Texinfo,
3121       # which do things like
3122       #   info_TEXINFOS = texinfo.txi info-stnd.texi info.texi
3123       #   DISTCLEANFILES = texinfo texinfo-* info*.info*
3124       #   # Do not create info files for distribution.
3125       #   dist-info:
3126       # in order not to distribute .info files.
3127       my $insrc = ($out_file =~ $user_cleaned_files) ? 0 : 1;
3128
3129       my $soutdir = '$(srcdir)/' . $outdir;
3130       $outdir = $soutdir if $insrc;
3131
3132       # If user specified file_TEXINFOS, then use that as explicit
3133       # dependency list.
3134       @texi_deps = ();
3135       push (@texi_deps, "$soutdir$vtexi") if $vtexi;
3136
3137       my $canonical = canonicalize ($infobase);
3138       if (var ($canonical . "_TEXINFOS"))
3139         {
3140           push (@texi_deps, '$(' . $canonical . '_TEXINFOS)');
3141           push_dist_common ('$(' . $canonical . '_TEXINFOS)');
3142         }
3143
3144       my ($dirstamp, @cfiles) =
3145         output_texinfo_build_rules ($texi, $out_file, $insrc, @texi_deps);
3146       push (@texi_cleans, @cfiles);
3147
3148       push (@info_deps_list, $out_file);
3149
3150       # If a vers*.texi file is needed, emit the rule.
3151       if ($vtexi)
3152         {
3153           err_am ("`$vtexi', included in `$texi', "
3154                   . "also included in `$versions{$vtexi}'")
3155             if defined $versions{$vtexi};
3156           $versions{$vtexi} = $texi;
3157
3158           # We number the stamp-vti files.  This is doable since the
3159           # actual names don't matter much.  We only number starting
3160           # with the second one, so that the common case looks nice.
3161           my $vti = ($done ? $done : 'vti');
3162           ++$done;
3163
3164           # This is ugly, but it is our historical practice.
3165           if ($config_aux_dir_set_in_configure_ac)
3166             {
3167               require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3168                                             'mdate-sh');
3169             }
3170           else
3171             {
3172               require_file_with_macro (TRUE, 'info_TEXINFOS',
3173                                        FOREIGN, 'mdate-sh');
3174             }
3175
3176           my $conf_dir;
3177           if ($config_aux_dir_set_in_configure_ac)
3178             {
3179               $conf_dir = "$am_config_aux_dir/";
3180             }
3181           else
3182             {
3183               $conf_dir = '$(srcdir)/';
3184             }
3185           $output_rules .= file_contents ('texi-vers',
3186                                           new Automake::Location,
3187                                           TEXI     => $texi,
3188                                           VTI      => $vti,
3189                                           STAMPVTI => "${soutdir}stamp-$vti",
3190                                           VTEXI    => "$soutdir$vtexi",
3191                                           MDDIR    => $conf_dir,
3192                                           DIRSTAMP => $dirstamp);
3193         }
3194     }
3195
3196   # Handle location of texinfo.tex.
3197   my $need_texi_file = 0;
3198   my $texinfodir;
3199   if (var ('TEXINFO_TEX'))
3200     {
3201       # The user defined TEXINFO_TEX so assume he knows what he is
3202       # doing.
3203       $texinfodir = ('$(srcdir)/'
3204                      . dirname (variable_value ('TEXINFO_TEX')));
3205     }
3206   elsif (option 'cygnus')
3207     {
3208       $texinfodir = '$(top_srcdir)/../texinfo';
3209       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3210     }
3211   elsif ($config_aux_dir_set_in_configure_ac)
3212     {
3213       $texinfodir = $am_config_aux_dir;
3214       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3215       $need_texi_file = 2; # so that we require_conf_file later
3216     }
3217   else
3218     {
3219       $texinfodir = '$(srcdir)';
3220       $need_texi_file = 1;
3221     }
3222   define_variable ('am__TEXINFO_TEX_DIR', $texinfodir, INTERNAL);
3223
3224   push (@dist_targets, 'dist-info');
3225
3226   if (! option 'no-installinfo')
3227     {
3228       # Make sure documentation is made and installed first.  Use
3229       # $(INFO_DEPS), not 'info', because otherwise recursive makes
3230       # get run twice during "make all".
3231       unshift (@all, '$(INFO_DEPS)');
3232     }
3233
3234   define_files_variable ("DVIS", @infobase, 'dvi', INTERNAL);
3235   define_files_variable ("PDFS", @infobase, 'pdf', INTERNAL);
3236   define_files_variable ("PSS", @infobase, 'ps', INTERNAL);
3237   define_files_variable ("HTMLS", @infobase, 'html', INTERNAL);
3238
3239   # This next isn't strictly needed now -- the places that look here
3240   # could easily be changed to look in info_TEXINFOS.  But this is
3241   # probably better, in case noinst_TEXINFOS is ever supported.
3242   define_variable ("TEXINFOS", variable_value ('info_TEXINFOS'), INTERNAL);
3243
3244   # Do some error checking.  Note that this file is not required
3245   # when in Cygnus mode; instead we defined TEXINFO_TEX explicitly
3246   # up above.
3247   if ($need_texi_file && ! option 'no-texinfo.tex')
3248     {
3249       if ($need_texi_file > 1)
3250         {
3251           require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3252                                         'texinfo.tex');
3253         }
3254       else
3255         {
3256           require_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3257                                    'texinfo.tex');
3258         }
3259     }
3260
3261   return makefile_wrap ("", "\t  ", @texi_cleans);
3262 }
3263
3264
3265 # handle_texinfo ()
3266 # -----------------
3267 # Handle all Texinfo source.
3268 sub handle_texinfo ()
3269 {
3270   reject_var 'TEXINFOS', "`TEXINFOS' is an anachronism; use `info_TEXINFOS'";
3271   # FIXME: I think this is an obsolete future feature name.
3272   reject_var 'html_TEXINFOS', "HTML generation not yet supported";
3273
3274   my $info_texinfos = var ('info_TEXINFOS');
3275   my $texiclean = "";
3276   if ($info_texinfos)
3277     {
3278       $texiclean = handle_texinfo_helper ($info_texinfos);
3279     }
3280   $output_rules .=  file_contents ('texinfos',
3281                                    new Automake::Location,
3282                                    TEXICLEAN     => $texiclean,
3283                                    'LOCAL-TEXIS' => !!$info_texinfos);
3284 }
3285
3286
3287 # Handle any man pages.
3288 sub handle_man_pages
3289 {
3290   reject_var 'MANS', "`MANS' is an anachronism; use `man_MANS'";
3291
3292   # Find all the sections in use.  We do this by first looking for
3293   # "standard" sections, and then looking for any additional
3294   # sections used in man_MANS.
3295   my (%sections, %vlist);
3296   # We handle nodist_ for uniformity.  man pages aren't distributed
3297   # by default so it isn't actually very important.
3298   foreach my $pfx ('', 'dist_', 'nodist_')
3299     {
3300       # Add more sections as needed.
3301       foreach my $section ('0'..'9', 'n', 'l')
3302         {
3303           my $varname = $pfx . 'man' . $section . '_MANS';
3304           if (var ($varname))
3305             {
3306               $sections{$section} = 1;
3307               $varname = '$(' . $varname . ')';
3308               $vlist{$varname} = 1;
3309
3310               &push_dist_common ($varname)
3311                 if $pfx eq 'dist_';
3312             }
3313         }
3314
3315       my $varname = $pfx . 'man_MANS';
3316       my $var = var ($varname);
3317       if ($var)
3318         {
3319           foreach ($var->value_as_list_recursive)
3320             {
3321               # A page like `foo.1c' goes into man1dir.
3322               if (/\.([0-9a-z])([a-z]*)$/)
3323                 {
3324                   $sections{$1} = 1;
3325                 }
3326             }
3327
3328           $varname = '$(' . $varname . ')';
3329           $vlist{$varname} = 1;
3330           &push_dist_common ($varname)
3331             if $pfx eq 'dist_';
3332         }
3333     }
3334
3335   return unless %sections;
3336
3337   # Now for each section, generate an install and uninstall rule.
3338   # Sort sections so output is deterministic.
3339   foreach my $section (sort keys %sections)
3340     {
3341       $output_rules .= &file_contents ('mans',
3342                                        new Automake::Location,
3343                                        SECTION => $section);
3344     }
3345
3346   my @mans = sort keys %vlist;
3347   $output_vars .= file_contents ('mans-vars',
3348                                  new Automake::Location,
3349                                  MANS => "@mans");
3350
3351   push (@all, '$(MANS)')
3352     unless option 'no-installman';
3353 }
3354
3355 # Handle DATA variables.
3356 sub handle_data
3357 {
3358     &am_install_var ('-noextra', '-candist', 'data', 'DATA',
3359                      'data', 'dataroot', 'dvi', 'html', 'pdf', 'ps',
3360                      'sysconf', 'sharedstate', 'localstate',
3361                      'pkgdata', 'lisp', 'noinst', 'check');
3362 }
3363
3364 # Handle TAGS.
3365 sub handle_tags
3366 {
3367     my @tag_deps = ();
3368     my @ctag_deps = ();
3369     if (var ('SUBDIRS'))
3370     {
3371         $output_rules .= ("tags-recursive:\n"
3372                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
3373                           # Never fail here if a subdir fails; it
3374                           # isn't important.
3375                           . "\t  test \"\$\$subdir\" = . || (cd \$\$subdir"
3376                           . " && \$(MAKE) \$(AM_MAKEFLAGS) tags); \\\n"
3377                           . "\tdone\n");
3378         push (@tag_deps, 'tags-recursive');
3379         &depend ('.PHONY', 'tags-recursive');
3380
3381         $output_rules .= ("ctags-recursive:\n"
3382                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
3383                           # Never fail here if a subdir fails; it
3384                           # isn't important.
3385                           . "\t  test \"\$\$subdir\" = . || (cd \$\$subdir"
3386                           . " && \$(MAKE) \$(AM_MAKEFLAGS) ctags); \\\n"
3387                           . "\tdone\n");
3388         push (@ctag_deps, 'ctags-recursive');
3389         &depend ('.PHONY', 'ctags-recursive');
3390     }
3391
3392     if (&saw_sources_p (1)
3393         || var ('ETAGS_ARGS')
3394         || @tag_deps)
3395     {
3396         my @config;
3397         foreach my $spec (@config_headers)
3398         {
3399             my ($out, @ins) = split_config_file_spec ($spec);
3400             foreach my $in (@ins)
3401               {
3402                 # If the config header source is in this directory,
3403                 # require it.
3404                 push @config, basename ($in)
3405                   if $relative_dir eq dirname ($in);
3406               }
3407         }
3408         $output_rules .= &file_contents ('tags',
3409                                          new Automake::Location,
3410                                          CONFIG    => "@config",
3411                                          TAGSDIRS  => "@tag_deps",
3412                                          CTAGSDIRS => "@ctag_deps");
3413
3414         set_seen 'TAGS_DEPENDENCIES';
3415     }
3416     elsif (reject_var ('TAGS_DEPENDENCIES',
3417                        "doesn't make sense to define `TAGS_DEPENDENCIES'"
3418                        . "without\nsources or `ETAGS_ARGS'"))
3419     {
3420     }
3421     else
3422     {
3423         # Every Makefile must define some sort of TAGS rule.
3424         # Otherwise, it would be possible for a top-level "make TAGS"
3425         # to fail because some subdirectory failed.
3426         $output_rules .= "tags: TAGS\nTAGS:\n\n";
3427         # Ditto ctags.
3428         $output_rules .= "ctags: CTAGS\nCTAGS:\n\n";
3429     }
3430 }
3431
3432 # Handle multilib support.
3433 sub handle_multilib
3434 {
3435   if ($seen_multilib && $relative_dir eq '.')
3436     {
3437       $output_rules .= &file_contents ('multilib', new Automake::Location);
3438       push (@all, 'all-multi');
3439     }
3440 }
3441
3442
3443 # user_phony_rule ($NAME)
3444 # -----------------------
3445 # Return false if rule $NAME does not exist.  Otherwise,
3446 # declare it as phony, complete its definition (in case it is
3447 # conditional), and return its Automake::Rule instance.
3448 sub user_phony_rule ($)
3449 {
3450   my ($name) = @_;
3451   my $rule = rule $name;
3452   if ($rule)
3453     {
3454       depend ('.PHONY', $name);
3455       # Define $NAME in all condition where it is not already defined,
3456       # so that it is always OK to depend on $NAME.
3457       for my $c ($rule->not_always_defined_in_cond (TRUE)->conds)
3458         {
3459           Automake::Rule::define ($name, 'internal', RULE_AUTOMAKE,
3460                                   $c, INTERNAL);
3461           $output_rules .= $c->subst_string . "$name:\n";
3462         }
3463     }
3464   return $rule;
3465 }
3466
3467
3468 # $BOOLEAN
3469 # &for_dist_common ($A, $B)
3470 # -------------------------
3471 # Subroutine for &handle_dist: sort files to dist.
3472 #
3473 # We put README first because it then becomes easier to make a
3474 # Usenet-compliant shar file (in these, README must be first).
3475 #
3476 # FIXME: do more ordering of files here.
3477 sub for_dist_common
3478 {
3479     return 0
3480         if $a eq $b;
3481     return -1
3482         if $a eq 'README';
3483     return 1
3484         if $b eq 'README';
3485     return $a cmp $b;
3486 }
3487
3488
3489 # handle_dist
3490 # -----------
3491 # Handle 'dist' target.
3492 sub handle_dist ()
3493 {
3494   # Substutions for distdit.am
3495   my %transform;
3496
3497   # Define DIST_SUBDIRS.  This must always be done, regardless of the
3498   # no-dist setting: target like `distclean' or `maintainer-clean' use it.
3499   my $subdirs = var ('SUBDIRS');
3500   if ($subdirs)
3501     {
3502       # If SUBDIRS is conditionally defined, then set DIST_SUBDIRS
3503       # to all possible directories, and use it.  If DIST_SUBDIRS is
3504       # defined, just use it.
3505
3506       # Note that we check DIST_SUBDIRS first on purpose, so that
3507       # we don't call has_conditional_contents for now reason.
3508       # (In the past one project used so many conditional subdirectories
3509       # that calling has_conditional_contents on SUBDIRS caused
3510       # automake to grow to 150Mb -- this should not happen with
3511       # the current implementation of has_conditional_contents,
3512       # but it's more efficient to avoid the call anyway.)
3513       if (var ('DIST_SUBDIRS'))
3514         {
3515         }
3516       elsif ($subdirs->has_conditional_contents)
3517         {
3518           define_pretty_variable
3519             ('DIST_SUBDIRS', TRUE, INTERNAL,
3520              uniq ($subdirs->value_as_list_recursive));
3521         }
3522       else
3523         {
3524           # We always define this because that is what `distclean'
3525           # wants.
3526           define_pretty_variable ('DIST_SUBDIRS', TRUE, INTERNAL,
3527                                   '$(SUBDIRS)');
3528         }
3529     }
3530
3531   # The remaining definitions are only required when a dist target is used.
3532   return if option 'no-dist';
3533
3534   # At least one of the archive formats must be enabled.
3535   if ($relative_dir eq '.')
3536     {
3537       my $archive_defined = option 'no-dist-gzip' ? 0 : 1;
3538       $archive_defined ||=
3539         grep { option "dist-$_" } ('shar', 'zip', 'tarZ', 'bzip2');
3540       error (option 'no-dist-gzip',
3541              "no-dist-gzip specified but no dist-* specified, "
3542              . "at least one archive format must be enabled")
3543         unless $archive_defined;
3544     }
3545
3546   # Look for common files that should be included in distribution.
3547   # If the aux dir is set, and it does not have a Makefile.am, then
3548   # we check for these files there as well.
3549   my $check_aux = 0;
3550   if ($relative_dir eq '.'
3551       && $config_aux_dir_set_in_configure_ac)
3552     {
3553       if (! &is_make_dir ($config_aux_dir))
3554         {
3555           $check_aux = 1;
3556         }
3557     }
3558   foreach my $cfile (@common_files)
3559     {
3560       if (dir_has_case_matching_file ($relative_dir, $cfile)
3561           # The file might be absent, but if it can be built it's ok.
3562           || rule $cfile)
3563         {
3564           &push_dist_common ($cfile);
3565         }
3566
3567       # Don't use `elsif' here because a file might meaningfully
3568       # appear in both directories.
3569       if ($check_aux && dir_has_case_matching_file ($config_aux_dir, $cfile))
3570         {
3571           &push_dist_common ("$config_aux_dir/$cfile")
3572         }
3573     }
3574
3575   # We might copy elements from $configure_dist_common to
3576   # %dist_common if we think we need to.  If the file appears in our
3577   # directory, we would have discovered it already, so we don't
3578   # check that.  But if the file is in a subdir without a Makefile,
3579   # we want to distribute it here if we are doing `.'.  Ugly!
3580   if ($relative_dir eq '.')
3581     {
3582       foreach my $file (split (' ' , $configure_dist_common))
3583         {
3584           push_dist_common ($file)
3585             unless is_make_dir (dirname ($file));
3586         }
3587     }
3588
3589   # Files to distributed.  Don't use ->value_as_list_recursive
3590   # as it recursively expands `$(dist_pkgdata_DATA)' etc.
3591   my @dist_common = split (' ', rvar ('DIST_COMMON')->variable_value);
3592   @dist_common = uniq (sort for_dist_common (@dist_common));
3593   variable_delete 'DIST_COMMON';
3594   define_pretty_variable ('DIST_COMMON', TRUE, INTERNAL, @dist_common);
3595
3596   # Now that we've processed DIST_COMMON, disallow further attempts
3597   # to set it.
3598   $handle_dist_run = 1;
3599
3600   # Scan EXTRA_DIST to see if we need to distribute anything from a
3601   # subdir.  If so, add it to the list.  I didn't want to do this
3602   # originally, but there were so many requests that I finally
3603   # relented.
3604   my $extra_dist = var ('EXTRA_DIST');
3605   if ($extra_dist)
3606     {
3607       # FIXME: This should be fixed to work with conditions.  That
3608       # will require only making the entries in %dist_dirs under the
3609       # appropriate condition.  This is meaningful if the nature of
3610       # the distribution should depend upon the configure options
3611       # used.
3612       foreach ($extra_dist->value_as_list_recursive (skip_ac_subst => 1))
3613         {
3614           next unless s,/+[^/]+$,,;
3615           $dist_dirs{$_} = 1
3616             unless $_ eq '.';
3617         }
3618     }
3619
3620   # We have to check DIST_COMMON for extra directories in case the
3621   # user put a source used in AC_OUTPUT into a subdir.
3622   my $topsrcdir = backname ($relative_dir);
3623   foreach (rvar ('DIST_COMMON')->value_as_list_recursive (skip_ac_subst => 1))
3624     {
3625       s/\$\(top_srcdir\)/$topsrcdir/;
3626       s/\$\(srcdir\)/./;
3627       # Strip any leading `./'.
3628       s,^(:?\./+)*,,;
3629       next unless s,/+[^/]+$,,;
3630       $dist_dirs{$_} = 1
3631         unless $_ eq '.';
3632     }
3633
3634   $transform{'DISTCHECK-HOOK'} = !! rule 'distcheck-hook';
3635   $transform{'GETTEXT'} = $seen_gettext && !$seen_gettext_external;
3636
3637   # Prepend $(distdir) to each directory given.
3638   my %rewritten = map { '$(distdir)/' . "$_" => 1 } keys %dist_dirs;
3639   $transform{'DISTDIRS'} = join (' ', sort keys %rewritten);
3640
3641   # If the target `dist-hook' exists, make sure it is run.  This
3642   # allows users to do random weird things to the distribution
3643   # before it is packaged up.
3644   push (@dist_targets, 'dist-hook')
3645     if user_phony_rule 'dist-hook';
3646   $transform{'DIST-TARGETS'} = join (' ', @dist_targets);
3647
3648   my $flm = option ('filename-length-max');
3649   my $filename_filter = $flm ? '.' x $flm->[1] : '';
3650
3651   $output_rules .= &file_contents ('distdir',
3652                                    new Automake::Location,
3653                                    %transform,
3654                                    FILENAME_FILTER => $filename_filter);
3655 }
3656
3657
3658 # check_directory ($NAME, $WHERE)
3659 # -------------------------------
3660 # Ensure $NAME is a directory, and that it uses sane name.
3661 # Use $WHERE as a location in the diagnostic, if any.
3662 sub check_directory ($$)
3663 {
3664   my ($dir, $where) = @_;
3665
3666   error $where, "required directory $relative_dir/$dir does not exist"
3667     unless -d "$relative_dir/$dir";
3668
3669   # If an `obj/' directory exists, BSD make will enter it before
3670   # reading `Makefile'.  Hence the `Makefile' in the current directory
3671   # will not be read.
3672   #
3673   #  % cat Makefile
3674   #  all:
3675   #          echo Hello
3676   #  % cat obj/Makefile
3677   #  all:
3678   #          echo World
3679   #  % make      # GNU make
3680   #  echo Hello
3681   #  Hello
3682   #  % pmake     # BSD make
3683   #  echo World
3684   #  World
3685   msg ('portability', $where,
3686        "naming a subdirectory `obj' causes troubles with BSD make")
3687     if $dir eq 'obj';
3688
3689   # `aux' is probably the most important of the following forbidden name,
3690   # since it's tempting to use it as an AC_CONFIG_AUX_DIR.
3691   msg ('portability', $where,
3692        "name `$dir' is reserved on W32 and DOS platforms")
3693     if grep (/^\Q$dir\E$/i, qw/aux lpt1 lpt2 lpt3 com1 com2 com3 com4 con prn/);
3694 }
3695
3696 # check_directories_in_var ($VARIABLE)
3697 # ------------------------------------
3698 # Recursively check all items in variables $VARIABLE as directories
3699 sub check_directories_in_var ($)
3700 {
3701   my ($var) = @_;
3702   $var->traverse_recursively
3703     (sub
3704      {
3705        my ($var, $val, $cond, $full_cond) = @_;
3706        check_directory ($val, $var->rdef ($cond)->location);
3707        return ();
3708      },
3709      undef,
3710      skip_ac_subst => 1);
3711 }
3712
3713 # &handle_subdirs ()
3714 # ------------------
3715 # Handle subdirectories.
3716 sub handle_subdirs ()
3717 {
3718   my $subdirs = var ('SUBDIRS');
3719   return
3720     unless $subdirs;
3721
3722   check_directories_in_var $subdirs;
3723
3724   my $dsubdirs = var ('DIST_SUBDIRS');
3725   check_directories_in_var $dsubdirs
3726     if $dsubdirs;
3727
3728   $output_rules .= &file_contents ('subdirs', new Automake::Location);
3729   rvar ('RECURSIVE_TARGETS')->rdef (TRUE)->{'pretty'} = VAR_SORTED; # Gross!
3730 }
3731
3732
3733 # ($REGEN, @DEPENDENCIES)
3734 # &scan_aclocal_m4
3735 # ----------------
3736 # If aclocal.m4 creation is automated, return the list of its dependencies.
3737 sub scan_aclocal_m4 ()
3738 {
3739   my $regen_aclocal = 0;
3740
3741   set_seen 'CONFIG_STATUS_DEPENDENCIES';
3742   set_seen 'CONFIGURE_DEPENDENCIES';
3743
3744   if (-f 'aclocal.m4')
3745     {
3746       &define_variable ("ACLOCAL_M4", '$(top_srcdir)/aclocal.m4', INTERNAL);
3747
3748       my $aclocal = new Automake::XFile "< aclocal.m4";
3749       my $line = $aclocal->getline;
3750       $regen_aclocal = $line =~ 'generated automatically by aclocal';
3751     }
3752
3753   my @ac_deps = ();
3754
3755   if (set_seen ('ACLOCAL_M4_SOURCES'))
3756     {
3757       push (@ac_deps, '$(ACLOCAL_M4_SOURCES)');
3758       msg_var ('obsolete', 'ACLOCAL_M4_SOURCES',
3759                "`ACLOCAL_M4_SOURCES' is obsolete.\n"
3760                . "It should be safe to simply remove it.");
3761     }
3762
3763   # Note that it might be possible that aclocal.m4 doesn't exist but
3764   # should be auto-generated.  This case probably isn't very
3765   # important.
3766
3767   return ($regen_aclocal, @ac_deps);
3768 }
3769
3770
3771 # Helper function for substitute_ac_subst_variables.
3772 sub substitute_ac_subst_variables_worker($)
3773 {
3774   my ($token) = @_;
3775   return "\@$token\@" if var $token;
3776   return "\${$token\}";
3777 }
3778
3779 # substitute_ac_subst_variables ($TEXT)
3780 # -------------------------------------
3781 # Replace any occurence of ${FOO} in $TEXT by @FOO@ if FOO is an AC_SUBST
3782 # variable.
3783 sub substitute_ac_subst_variables ($)
3784 {
3785   my ($text) = @_;
3786   $text =~ s/\${([^ \t=:+{}]+)}/&substitute_ac_subst_variables_worker ($1)/ge;
3787   return $text;
3788 }
3789
3790 # @DEPENDENCIES
3791 # &prepend_srcdir (@INPUTS)
3792 # -------------------------
3793 # Prepend $(srcdir) or $(top_srcdir) to all @INPUTS.  The idea is that
3794 # if an input file has a directory part the same as the current
3795 # directory, then the directory part is simply replaced by $(srcdir).
3796 # But if the directory part is different, then $(top_srcdir) is
3797 # prepended.
3798 sub prepend_srcdir (@)
3799 {
3800   my (@inputs) = @_;
3801   my @newinputs;
3802
3803   foreach my $single (@inputs)
3804     {
3805       if (dirname ($single) eq $relative_dir)
3806         {
3807           push (@newinputs, '$(srcdir)/' . basename ($single));
3808         }
3809       else
3810         {
3811           push (@newinputs, '$(top_srcdir)/' . $single);
3812         }
3813     }
3814   return @newinputs;
3815 }
3816
3817 # @DEPENDENCIES
3818 # rewrite_inputs_into_dependencies ($OUTPUT, @INPUTS)
3819 # ---------------------------------------------------
3820 # Compute a list of dependencies appropriate for the rebuild
3821 # rule of
3822 #   AC_CONFIG_FILES($OUTPUT:$INPUT[0]:$INPUTS[1]:...)
3823 # Also distribute $INPUTs which are not build by another AC_CONFIG_FILES.
3824 sub rewrite_inputs_into_dependencies ($@)
3825 {
3826   my ($file, @inputs) = @_;
3827   my @res = ();
3828
3829   for my $i (@inputs)
3830     {
3831       # We cannot create dependencies on shell variables.
3832       next if (substitute_ac_subst_variables $i) =~ /\$/;
3833
3834       if (exists $ac_config_files_location{$i})
3835         {
3836           my $di = dirname $i;
3837           if ($di eq $relative_dir)
3838             {
3839               $i = basename $i;
3840             }
3841           # In the top-level Makefile we do not use $(top_builddir), because
3842           # we are already there, and since the targets are built without
3843           # a $(top_builddir), it helps BSD Make to match them with
3844           # dependencies.
3845           elsif ($relative_dir ne '.')
3846             {
3847               $i = '$(top_builddir)/' . $i;
3848             }
3849         }
3850       else
3851         {
3852           msg ('error', $ac_config_files_location{$file},
3853                "required file `$i' not found")
3854             unless $i =~ /\$/ || exists $output_files{$i} || -f $i;
3855           ($i) = prepend_srcdir ($i);
3856           push_dist_common ($i);
3857         }
3858       push @res, $i;
3859     }
3860   return @res;
3861 }
3862
3863
3864
3865 # &handle_configure ($MAKEFILE_AM, $MAKEFILE_IN, $MAKEFILE, @INPUTS)
3866 # ------------------------------------------------------------------
3867 # Handle remaking and configure stuff.
3868 # We need the name of the input file, to do proper remaking rules.
3869 sub handle_configure ($$$@)
3870 {
3871   my ($makefile_am, $makefile_in, $makefile, @inputs) = @_;
3872
3873   prog_error 'empty @inputs'
3874     unless @inputs;
3875
3876   my ($rel_makefile_am, $rel_makefile_in) = prepend_srcdir ($makefile_am,
3877                                                             $makefile_in);
3878   my $rel_makefile = basename $makefile;
3879
3880   my $colon_infile = ':' . join (':', @inputs);
3881   $colon_infile = '' if $colon_infile eq ":$makefile.in";
3882   my @rewritten = rewrite_inputs_into_dependencies ($makefile, @inputs);
3883   my ($regen_aclocal_m4, @aclocal_m4_deps) = scan_aclocal_m4;
3884   define_pretty_variable ('am__aclocal_m4_deps', TRUE, INTERNAL,
3885                           @configure_deps, @aclocal_m4_deps,
3886                           '$(top_srcdir)/' . $configure_ac);
3887   my @configuredeps = ('$(am__aclocal_m4_deps)', '$(CONFIGURE_DEPENDENCIES)');
3888   push @configuredeps, '$(ACLOCAL_M4)' if -f 'aclocal.m4';
3889   define_pretty_variable ('am__configure_deps', TRUE, INTERNAL,
3890                           @configuredeps);
3891
3892   $output_rules .= file_contents
3893     ('configure',
3894      new Automake::Location,
3895      MAKEFILE              => $rel_makefile,
3896      'MAKEFILE-DEPS'       => "@rewritten",
3897      'CONFIG-MAKEFILE'     => ($relative_dir eq '.') ? '$@' : '$(subdir)/$@',
3898      'MAKEFILE-IN'         => $rel_makefile_in,
3899      'MAKEFILE-IN-DEPS'    => "@include_stack",
3900      'MAKEFILE-AM'         => $rel_makefile_am,
3901      STRICTNESS            => global_option 'cygnus'
3902                                 ? 'cygnus' : $strictness_name,
3903      'USE-DEPS'            => global_option 'no-dependencies'
3904                                 ? ' --ignore-deps' : '',
3905      'MAKEFILE-AM-SOURCES' => "$makefile$colon_infile",
3906      'REGEN-ACLOCAL-M4'    => $regen_aclocal_m4);
3907
3908   if ($relative_dir eq '.')
3909     {
3910       &push_dist_common ('acconfig.h')
3911         if -f 'acconfig.h';
3912     }
3913
3914   # If we have a configure header, require it.
3915   my $hdr_index = 0;
3916   my @distclean_config;
3917   foreach my $spec (@config_headers)
3918     {
3919       $hdr_index += 1;
3920       # $CONFIG_H_PATH: config.h from top level.
3921       my ($config_h_path, @ins) = split_config_file_spec ($spec);
3922       my $config_h_dir = dirname ($config_h_path);
3923
3924       # If the header is in the current directory we want to build
3925       # the header here.  Otherwise, if we're at the topmost
3926       # directory and the header's directory doesn't have a
3927       # Makefile, then we also want to build the header.
3928       if ($relative_dir eq $config_h_dir
3929           || ($relative_dir eq '.' && ! &is_make_dir ($config_h_dir)))
3930         {
3931           my ($cn_sans_dir, $stamp_dir);
3932           if ($relative_dir eq $config_h_dir)
3933             {
3934               $cn_sans_dir = basename ($config_h_path);
3935               $stamp_dir = '';
3936             }
3937           else
3938             {
3939               $cn_sans_dir = $config_h_path;
3940               if ($config_h_dir eq '.')
3941                 {
3942                   $stamp_dir = '';
3943                 }
3944               else
3945                 {
3946                   $stamp_dir = $config_h_dir . '/';
3947                 }
3948             }
3949
3950           # This will also distribute all inputs.
3951           @ins = rewrite_inputs_into_dependencies ($config_h_path, @ins);
3952
3953           # Cannot define rebuild rules for filenames with shell variables.
3954           next if (substitute_ac_subst_variables $config_h_path) =~ /\$/;
3955
3956           # Header defined in this directory.
3957           my @files;
3958           if (-f $config_h_path . '.top')
3959             {
3960               push (@files, "$cn_sans_dir.top");
3961             }
3962           if (-f $config_h_path . '.bot')
3963             {
3964               push (@files, "$cn_sans_dir.bot");
3965             }
3966
3967           push_dist_common (@files);
3968
3969           # For now, acconfig.h can only appear in the top srcdir.
3970           if (-f 'acconfig.h')
3971             {
3972               push (@files, '$(top_srcdir)/acconfig.h');
3973             }
3974
3975           my $stamp = "${stamp_dir}stamp-h${hdr_index}";
3976           $output_rules .=
3977             file_contents ('remake-hdr',
3978                            new Automake::Location,
3979                            FILES            => "@files",
3980                            CONFIG_H         => $cn_sans_dir,
3981                            CONFIG_HIN       => $ins[0],
3982                            CONFIG_H_DEPS    => "@ins",
3983                            CONFIG_H_PATH    => $config_h_path,
3984                            STAMP            => "$stamp");
3985
3986           push @distclean_config, $cn_sans_dir, $stamp;
3987         }
3988     }
3989
3990   $output_rules .= file_contents ('clean-hdr',
3991                                   new Automake::Location,
3992                                   FILES => "@distclean_config")
3993     if @distclean_config;
3994
3995   # Distribute and define mkinstalldirs only if it is already present
3996   # in the package, for backward compatibility (some people may still
3997   # use $(mkinstalldirs)).
3998   my $mkidpath = "$config_aux_dir/mkinstalldirs";
3999   if (-f $mkidpath)
4000     {
4001       # Use require_file so that any existing script gets updated
4002       # by --force-missing.
4003       require_conf_file ($mkidpath, FOREIGN, 'mkinstalldirs');
4004       define_variable ('mkinstalldirs',
4005                        "\$(SHELL) $am_config_aux_dir/mkinstalldirs", INTERNAL);
4006     }
4007   else
4008     {
4009       # Use $(install_sh), not $(mkdir_p) because the latter requires
4010       # at least one argument, and $(mkinstalldirs) used to work
4011       # even without arguments (e.g. $(mkinstalldirs) $(conditional_dir)).
4012       define_variable ('mkinstalldirs', '$(install_sh) -d', INTERNAL);
4013     }
4014
4015   reject_var ('CONFIG_HEADER',
4016               "`CONFIG_HEADER' is an anachronism; now determined "
4017               . "automatically\nfrom `$configure_ac'");
4018
4019   my @config_h;
4020   foreach my $spec (@config_headers)
4021     {
4022       my ($out, @ins) = split_config_file_spec ($spec);
4023       # Generate CONFIG_HEADER define.
4024       if ($relative_dir eq dirname ($out))
4025         {
4026           push @config_h, basename ($out);
4027         }
4028       else
4029         {
4030           push @config_h, "\$(top_builddir)/$out";
4031         }
4032     }
4033   define_variable ("CONFIG_HEADER", "@config_h", INTERNAL)
4034     if @config_h;
4035
4036   # Now look for other files in this directory which must be remade
4037   # by config.status, and generate rules for them.
4038   my @actual_other_files = ();
4039   foreach my $lfile (@other_input_files)
4040     {
4041       my $file;
4042       my @inputs;
4043       if ($lfile =~ /^([^:]*):(.*)$/)
4044         {
4045           # This is the ":" syntax of AC_OUTPUT.
4046           $file = $1;
4047           @inputs = split (':', $2);
4048         }
4049       else
4050         {
4051           # Normal usage.
4052           $file = $lfile;
4053           @inputs = $file . '.in';
4054         }
4055
4056       # Automake files should not be stored in here, but in %MAKE_LIST.
4057       prog_error ("$lfile in \@other_input_files\n"
4058                   . "\@other_input_files = (@other_input_files)")
4059         if -f $file . '.am';
4060
4061       my $local = basename ($file);
4062
4063       # Make sure the dist directory for each input file is created.
4064       # We only have to do this at the topmost level though.  This
4065       # is a bit ugly but it easier than spreading out the logic,
4066       # especially in cases like AC_OUTPUT(foo/out:bar/in), where
4067       # there is no Makefile in bar/.
4068       if ($relative_dir eq '.')
4069         {
4070           foreach (@inputs)
4071             {
4072               $dist_dirs{dirname ($_)} = 1;
4073             }
4074         }
4075
4076       # We skip files that aren't in this directory.  However, if
4077       # the file's directory does not have a Makefile, and we are
4078       # currently doing `.', then we create a rule to rebuild the
4079       # file in the subdir.
4080       my $fd = dirname ($file);
4081       if ($fd ne $relative_dir)
4082         {
4083           if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4084             {
4085               $local = $file;
4086             }
4087           else
4088             {
4089               next;
4090             }
4091         }
4092
4093       my @rewritten_inputs = rewrite_inputs_into_dependencies ($file, @inputs);
4094
4095       # Cannot output rules for shell variables.
4096       next if (substitute_ac_subst_variables $local) =~ /\$/;
4097
4098       $output_rules .= ($local . ': '
4099                         . '$(top_builddir)/config.status '
4100                         . "@rewritten_inputs\n"
4101                         . "\t"
4102                         . 'cd $(top_builddir) && '
4103                         . '$(SHELL) ./config.status '
4104                         . ($relative_dir eq '.' ? '' : '$(subdir)/')
4105                         . '$@'
4106                         . "\n");
4107       push (@actual_other_files, $local);
4108     }
4109
4110   # For links we should clean destinations and distribute sources.
4111   foreach my $spec (@config_links)
4112     {
4113       my ($link, $file) = split /:/, $spec;
4114       # Some people do AC_CONFIG_LINKS($computed).  We only handle
4115       # the DEST:SRC form.
4116       next unless $file;
4117       my $where = $ac_config_files_location{$link};
4118
4119       # Skip destinations that contain shell variables.
4120       if ((substitute_ac_subst_variables $link) !~ /\$/)
4121         {
4122           # We skip links that aren't in this directory.  However, if
4123           # the link's directory does not have a Makefile, and we are
4124           # currently doing `.', then we add the link to CONFIG_CLEAN_FILES
4125           # in `.'s Makefile.in.
4126           my $local = basename ($link);
4127           my $fd = dirname ($link);
4128           if ($fd ne $relative_dir)
4129             {
4130               if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4131                 {
4132                   $local = $link;
4133                 }
4134               else
4135                 {
4136                   $local = undef;
4137                 }
4138             }
4139           push @actual_other_files, $local if $local;
4140         }
4141
4142       # Do not process sources that contain shell variables.
4143       if ((substitute_ac_subst_variables $file) !~ /\$/)
4144         {
4145           my $fd = dirname ($file);
4146
4147           # Make sure the dist directory for each input file is created.
4148           # We only have to do this at the topmost level though.
4149           if ($relative_dir eq '.')
4150             {
4151               $dist_dirs{$fd} = 1;
4152             }
4153
4154           # We distribute files that are in this directory.
4155           # At the top-level (`.') we also distribute files whose
4156           # directory does not have a Makefile.
4157           if (($fd eq $relative_dir)
4158               || ($relative_dir eq '.' && ! &is_make_dir ($fd)))
4159             {
4160               # The following will distribute $file as a side-effect when
4161               # it is appropriate (i.e., when $file is not already an output).
4162               # We do not need the result, just the side-effect.
4163               rewrite_inputs_into_dependencies ($link, $file);
4164             }
4165         }
4166     }
4167
4168   # These files get removed by "make distclean".
4169   define_pretty_variable ('CONFIG_CLEAN_FILES', TRUE, INTERNAL,
4170                           @actual_other_files);
4171 }
4172
4173 # Handle C headers.
4174 sub handle_headers
4175 {
4176     my @r = &am_install_var ('-defaultdist', 'header', 'HEADERS', 'include',
4177                              'oldinclude', 'pkginclude',
4178                              'noinst', 'check');
4179     foreach (@r)
4180     {
4181       next unless $_->[1] =~ /\..*$/;
4182       &saw_extension ($&);
4183     }
4184 }
4185
4186 sub handle_gettext
4187 {
4188   return if ! $seen_gettext || $relative_dir ne '.';
4189
4190   my $subdirs = var 'SUBDIRS';
4191
4192   if (! $subdirs)
4193     {
4194       err_ac "AM_GNU_GETTEXT used but SUBDIRS not defined";
4195       return;
4196     }
4197
4198   # Perform some sanity checks to help users get the right setup.
4199   # We disable these tests when po/ doesn't exist in order not to disallow
4200   # unusual gettext setups.
4201   #
4202   # Bruno Haible:
4203   # | The idea is:
4204   # |
4205   # |  1) If a package doesn't have a directory po/ at top level, it
4206   # |     will likely have multiple po/ directories in subpackages.
4207   # |
4208   # |  2) It is useful to warn for the absence of intl/ if AM_GNU_GETTEXT
4209   # |     is used without 'external'. It is also useful to warn for the
4210   # |     presence of intl/ if AM_GNU_GETTEXT([external]) is used. Both
4211   # |     warnings apply only to the usual layout of packages, therefore
4212   # |     they should both be disabled if no po/ directory is found at
4213   # |     top level.
4214
4215   if (-d 'po')
4216     {
4217       my @subdirs = $subdirs->value_as_list_recursive;
4218
4219       msg_var ('syntax', $subdirs,
4220                "AM_GNU_GETTEXT used but `po' not in SUBDIRS")
4221         if ! grep ($_ eq 'po', @subdirs);
4222
4223       # intl/ is not required when AM_GNU_GETTEXT is called with
4224       # the `external' option.
4225       msg_var ('syntax', $subdirs,
4226                "AM_GNU_GETTEXT used but `intl' not in SUBDIRS")
4227         if (! $seen_gettext_external
4228             && ! grep ($_ eq 'intl', @subdirs));
4229
4230       # intl/ should not be used with AM_GNU_GETTEXT([external])
4231       msg_var ('syntax', $subdirs,
4232                "`intl' should not be in SUBDIRS when "
4233                . "AM_GNU_GETTEXT([external]) is used")
4234         if ($seen_gettext_external && grep ($_ eq 'intl', @subdirs));
4235     }
4236
4237   require_file ($ac_gettext_location, GNU, 'ABOUT-NLS');
4238 }
4239
4240 # Handle footer elements.
4241 sub handle_footer
4242 {
4243     reject_rule ('.SUFFIXES',
4244                  "use variable `SUFFIXES', not target `.SUFFIXES'");
4245
4246     # Note: AIX 4.1 /bin/make will fail if any suffix rule appears
4247     # before .SUFFIXES.  So we make sure that .SUFFIXES appears before
4248     # anything else, by sticking it right after the default: target.
4249     $output_header .= ".SUFFIXES:\n";
4250     my $suffixes = var 'SUFFIXES';
4251     my @suffixes = Automake::Rule::suffixes;
4252     if (@suffixes || $suffixes)
4253     {
4254         # Make sure SUFFIXES has unique elements.  Sort them to ensure
4255         # the output remains consistent.  However, $(SUFFIXES) is
4256         # always at the start of the list, unsorted.  This is done
4257         # because make will choose rules depending on the ordering of
4258         # suffixes, and this lets the user have some control.  Push
4259         # actual suffixes, and not $(SUFFIXES).  Some versions of make
4260         # do not like variable substitutions on the .SUFFIXES line.
4261         my @user_suffixes = ($suffixes
4262                              ? $suffixes->value_as_list_recursive : ());
4263
4264         my %suffixes = map { $_ => 1 } @suffixes;
4265         delete @suffixes{@user_suffixes};
4266
4267         $output_header .= (".SUFFIXES: "
4268                            . join (' ', @user_suffixes, sort keys %suffixes)
4269                            . "\n");
4270     }
4271
4272     $output_trailer .= file_contents ('footer', new Automake::Location);
4273 }
4274
4275
4276 # Generate `make install' rules.
4277 sub handle_install ()
4278 {
4279   $output_rules .= &file_contents
4280     ('install',
4281      new Automake::Location,
4282      maybe_BUILT_SOURCES => (set_seen ('BUILT_SOURCES')
4283                              ? (" \$(BUILT_SOURCES)\n"
4284                                 . "\t\$(MAKE) \$(AM_MAKEFLAGS)")
4285                              : ''),
4286      'installdirs-local' => (user_phony_rule 'installdirs-local'
4287                              ? ' installdirs-local' : ''),
4288      am__installdirs => variable_value ('am__installdirs') || '');
4289 }
4290
4291
4292 # Deal with all and all-am.
4293 sub handle_all ($)
4294 {
4295     my ($makefile) = @_;
4296
4297     # Output `all-am'.
4298
4299     # Put this at the beginning for the sake of non-GNU makes.  This
4300     # is still wrong if these makes can run parallel jobs.  But it is
4301     # right enough.
4302     unshift (@all, basename ($makefile));
4303
4304     foreach my $spec (@config_headers)
4305       {
4306         my ($out, @ins) = split_config_file_spec ($spec);
4307         push (@all, basename ($out))
4308           if dirname ($out) eq $relative_dir;
4309       }
4310
4311     # Install `all' hooks.
4312     push (@all, "all-local")
4313       if user_phony_rule "all-local";
4314
4315     &pretty_print_rule ("all-am:", "\t\t", @all);
4316     &depend ('.PHONY', 'all-am', 'all');
4317
4318
4319     # Output `all'.
4320
4321     my @local_headers = ();
4322     push @local_headers, '$(BUILT_SOURCES)'
4323       if var ('BUILT_SOURCES');
4324     foreach my $spec (@config_headers)
4325       {
4326         my ($out, @ins) = split_config_file_spec ($spec);
4327         push @local_headers, basename ($out)
4328           if dirname ($out) eq $relative_dir;
4329       }
4330
4331     if (@local_headers)
4332       {
4333         # We need to make sure config.h is built before we recurse.
4334         # We also want to make sure that built sources are built
4335         # before any ordinary `all' targets are run.  We can't do this
4336         # by changing the order of dependencies to the "all" because
4337         # that breaks when using parallel makes.  Instead we handle
4338         # things explicitly.
4339         $output_all .= ("all: @local_headers"
4340                         . "\n\t"
4341                         . '$(MAKE) $(AM_MAKEFLAGS) '
4342                         . (var ('SUBDIRS') ? 'all-recursive' : 'all-am')
4343                         . "\n\n");
4344       }
4345     else
4346       {
4347         $output_all .= "all: " . (var ('SUBDIRS')
4348                                   ? 'all-recursive' : 'all-am') . "\n\n";
4349       }
4350 }
4351
4352
4353 # &do_check_merge_target ()
4354 # -------------------------
4355 # Handle check merge target specially.
4356 sub do_check_merge_target ()
4357 {
4358   # Include user-defined local form of target.
4359   push @check_tests, 'check-local'
4360     if user_phony_rule 'check-local';
4361
4362   # In --cygnus mode, check doesn't depend on all.
4363   if (option 'cygnus')
4364     {
4365       # Just run the local check rules.
4366       pretty_print_rule ('check-am:', "\t\t", @check);
4367     }
4368   else
4369     {
4370       # The check target must depend on the local equivalent of
4371       # `all', to ensure all the primary targets are built.  Then it
4372       # must build the local check rules.
4373       $output_rules .= "check-am: all-am\n";
4374       pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4375                          @check)
4376         if @check;
4377     }
4378   pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4379                      @check_tests)
4380     if @check_tests;
4381
4382   depend '.PHONY', 'check', 'check-am';
4383   # Handle recursion.  We have to honor BUILT_SOURCES like for `all:'.
4384   $output_rules .= ("check: "
4385                     . (var ('BUILT_SOURCES')
4386                        ? "\$(BUILT_SOURCES)\n\t\$(MAKE) \$(AM_MAKEFLAGS) "
4387                        : '')
4388                     . (var ('SUBDIRS') ? 'check-recursive' : 'check-am')
4389                     . "\n");
4390 }
4391
4392 # handle_clean ($MAKEFILE)
4393 # ------------------------
4394 # Handle all 'clean' targets.
4395 sub handle_clean ($)
4396 {
4397   my ($makefile) = @_;
4398
4399   # Clean the files listed in user variables if they exist.
4400   $clean_files{'$(MOSTLYCLEANFILES)'} = MOSTLY_CLEAN
4401     if var ('MOSTLYCLEANFILES');
4402   $clean_files{'$(CLEANFILES)'} = CLEAN
4403     if var ('CLEANFILES');
4404   $clean_files{'$(DISTCLEANFILES)'} = DIST_CLEAN
4405     if var ('DISTCLEANFILES');
4406   $clean_files{'$(MAINTAINERCLEANFILES)'} = MAINTAINER_CLEAN
4407     if var ('MAINTAINERCLEANFILES');
4408
4409   # Built sources are automatically removed by maintainer-clean.
4410   $clean_files{'$(BUILT_SOURCES)'} = MAINTAINER_CLEAN
4411     if var ('BUILT_SOURCES');
4412
4413   # Compute a list of "rm"s to run for each target.
4414   my %rms = (MOSTLY_CLEAN, [],
4415              CLEAN, [],
4416              DIST_CLEAN, [],
4417              MAINTAINER_CLEAN, []);
4418
4419   foreach my $file (keys %clean_files)
4420     {
4421       my $when = $clean_files{$file};
4422       prog_error 'invalid entry in %clean_files'
4423         unless exists $rms{$when};
4424
4425       my $rm = "rm -f $file";
4426       # If file is a variable, make sure when don't call `rm -f' without args.
4427       $rm ="test -z \"$file\" || $rm"
4428         if ($file =~ /^\s*\$(\(.*\)|\{.*\})\s*$/);
4429
4430       push @{$rms{$when}}, "\t-$rm\n";
4431     }
4432
4433   $output_rules .= &file_contents
4434     ('clean',
4435      new Automake::Location,
4436      MOSTLYCLEAN_RMS      => join ('', sort @{$rms{&MOSTLY_CLEAN}}),
4437      CLEAN_RMS            => join ('', sort @{$rms{&CLEAN}}),
4438      DISTCLEAN_RMS        => join ('', sort @{$rms{&DIST_CLEAN}}),
4439      MAINTAINER_CLEAN_RMS => join ('', sort @{$rms{&MAINTAINER_CLEAN}}),
4440      MAKEFILE             => basename $makefile,
4441      );
4442 }
4443
4444
4445 # &target_cmp ($A, $B)
4446 # --------------------
4447 # Subroutine for &handle_factored_dependencies to let `.PHONY' and
4448 # other `.TARGETS' be last.
4449 sub target_cmp
4450 {
4451   return 0 if $a eq $b;
4452
4453   my $a1 = substr ($a, 0, 1);
4454   my $b1 = substr ($b, 0, 1);
4455   if ($a1 ne $b1)
4456     {
4457       return -1 if $b1 eq '.';
4458       return 1 if $a1 eq '.';
4459     }
4460   return $a cmp $b;
4461 }
4462
4463
4464 # &handle_factored_dependencies ()
4465 # --------------------------------
4466 # Handle everything related to gathered targets.
4467 sub handle_factored_dependencies
4468 {
4469   # Reject bad hooks.
4470   foreach my $utarg ('uninstall-data-local', 'uninstall-data-hook',
4471                      'uninstall-exec-local', 'uninstall-exec-hook',
4472                      'uninstall-dvi-local',
4473                      'uninstall-html-local',
4474                      'uninstall-info-local',
4475                      'uninstall-pdf-local',
4476                      'uninstall-ps-local')
4477     {
4478       my $x = $utarg;
4479       $x =~ s/-.*-/-/;
4480       reject_rule ($utarg, "use `$x', not `$utarg'");
4481     }
4482
4483   reject_rule ('install-local',
4484                "use `install-data-local' or `install-exec-local', "
4485                . "not `install-local'");
4486
4487   reject_rule ('install-hook',
4488                "use `install-data-hook' or `install-exec-hook', "
4489                . "not `install-hook'");
4490
4491   # Install the -local hooks.
4492   foreach (keys %dependencies)
4493     {
4494       # Hooks are installed on the -am targets.
4495       s/-am$// or next;
4496       depend ("$_-am", "$_-local")
4497         if user_phony_rule "$_-local";
4498     }
4499
4500   # Install the -hook hooks.
4501   # FIXME: Why not be as liberal as we are with -local hooks?
4502   foreach ('install-exec', 'install-data', 'uninstall')
4503     {
4504       if (user_phony_rule "$_-hook")
4505         {
4506           $actions{"$_-am"} .=
4507             ("\t\@\$(NORMAL_INSTALL)\n"
4508              . "\t" . '$(MAKE) $(AM_MAKEFLAGS) ' . "$_-hook\n");
4509           depend ('.MAKE', "$_-am");
4510         }
4511     }
4512
4513   # All the required targets are phony.
4514   depend ('.PHONY', keys %required_targets);
4515
4516   # Actually output gathered targets.
4517   foreach (sort target_cmp keys %dependencies)
4518     {
4519       # If there is nothing about this guy, skip it.
4520       next
4521         unless (@{$dependencies{$_}}
4522                 || $actions{$_}
4523                 || $required_targets{$_});
4524
4525       # Define gathered targets in undefined conditions.
4526       # FIXME: Right now we must handle .PHONY as an exception,
4527       # because people write things like
4528       #    .PHONY: myphonytarget
4529       # to append dependencies.  This would not work if Automake
4530       # refrained from defining its own .PHONY target as it does
4531       # with other overridden targets.
4532       # Likewise for `.MAKE'.
4533       my @undefined_conds = (TRUE,);
4534       if ($_ ne '.PHONY' && $_ ne '.MAKE')
4535         {
4536           @undefined_conds =
4537             Automake::Rule::define ($_, 'internal',
4538                                     RULE_AUTOMAKE, TRUE, INTERNAL);
4539         }
4540       my @uniq_deps = uniq (sort @{$dependencies{$_}});
4541       foreach my $cond (@undefined_conds)
4542         {
4543           my $condstr = $cond->subst_string;
4544           &pretty_print_rule ("$condstr$_:", "$condstr\t", @uniq_deps);
4545           $output_rules .= $actions{$_} if defined $actions{$_};
4546           $output_rules .= "\n";
4547         }
4548     }
4549 }
4550
4551
4552 # &handle_tests_dejagnu ()
4553 # ------------------------
4554 sub handle_tests_dejagnu
4555 {
4556     push (@check_tests, 'check-DEJAGNU');
4557     $output_rules .= file_contents ('dejagnu', new Automake::Location);
4558 }
4559
4560
4561 # Handle TESTS variable and other checks.
4562 sub handle_tests
4563 {
4564   if (option 'dejagnu')
4565     {
4566       &handle_tests_dejagnu;
4567     }
4568   else
4569     {
4570       foreach my $c ('DEJATOOL', 'RUNTEST', 'RUNTESTFLAGS')
4571         {
4572           reject_var ($c, "`$c' defined but `dejagnu' not in "
4573                       . "`AUTOMAKE_OPTIONS'");
4574         }
4575     }
4576
4577   if (var ('TESTS'))
4578     {
4579       push (@check_tests, 'check-TESTS');
4580       $output_rules .= &file_contents ('check', new Automake::Location);
4581     }
4582 }
4583
4584 # Handle Emacs Lisp.
4585 sub handle_emacs_lisp
4586 {
4587   my @elfiles = &am_install_var ('-candist', 'lisp', 'LISP',
4588                                  'lisp', 'noinst');
4589
4590   return if ! @elfiles;
4591
4592   define_pretty_variable ('am__ELFILES', TRUE, INTERNAL,
4593                           map { $_->[1] } @elfiles);
4594   define_pretty_variable ('am__ELCFILES', TRUE, INTERNAL,
4595                           '$(am__ELFILES:.el=.elc)');
4596   # This one can be overridden by users.
4597   define_pretty_variable ('ELCFILES', TRUE, INTERNAL, '$(LISP:.el=.elc)');
4598
4599   push @all, '$(ELCFILES)';
4600
4601   require_variables ($elfiles[0][0], "Emacs Lisp sources seen", TRUE,
4602                      'EMACS', 'lispdir');
4603   require_conf_file ($elfiles[0][0], FOREIGN, 'elisp-comp');
4604   &define_variable ('elisp_comp', "$am_config_aux_dir/elisp-comp", INTERNAL);
4605 }
4606
4607 # Handle Python
4608 sub handle_python
4609 {
4610   my @pyfiles = &am_install_var ('-defaultdist', 'python', 'PYTHON',
4611                                  'noinst');
4612   return if ! @pyfiles;
4613
4614   require_variables ($pyfiles[0][0], "Python sources seen", TRUE, 'PYTHON');
4615   require_conf_file ($pyfiles[0][0], FOREIGN, 'py-compile');
4616   &define_variable ('py_compile', "$am_config_aux_dir/py-compile", INTERNAL);
4617 }
4618
4619 # Handle Java.
4620 sub handle_java
4621 {
4622     my @sourcelist = &am_install_var ('-candist',
4623                                       'java', 'JAVA',
4624                                       'java', 'noinst', 'check');
4625     return if ! @sourcelist;
4626
4627     my @prefix = am_primary_prefixes ('JAVA', 1,
4628                                       'java', 'noinst', 'check');
4629
4630     my $dir;
4631     foreach my $curs (@prefix)
4632       {
4633         next
4634           if $curs eq 'EXTRA';
4635
4636         err_var "${curs}_JAVA", "multiple _JAVA primaries in use"
4637           if defined $dir;
4638         $dir = $curs;
4639       }
4640
4641
4642     push (@all, 'class' . $dir . '.stamp');
4643 }
4644
4645
4646 # Handle some of the minor options.
4647 sub handle_minor_options
4648 {
4649   if (option 'readme-alpha')
4650     {
4651       if ($relative_dir eq '.')
4652         {
4653           if ($package_version !~ /^$GNITS_VERSION_PATTERN$/)
4654             {
4655               msg ('error-gnits', $package_version_location,
4656                    "version `$package_version' doesn't follow " .
4657                    "Gnits standards");
4658             }
4659           if (defined $1 && -f 'README-alpha')
4660             {
4661               # This means we have an alpha release.  See
4662               # GNITS_VERSION_PATTERN for details.
4663               push_dist_common ('README-alpha');
4664             }
4665         }
4666     }
4667 }
4668
4669 ################################################################
4670
4671 # ($OUTPUT, @INPUTS)
4672 # &split_config_file_spec ($SPEC)
4673 # -------------------------------
4674 # Decode the Autoconf syntax for config files (files, headers, links
4675 # etc.).
4676 sub split_config_file_spec ($)
4677 {
4678   my ($spec) = @_;
4679   my ($output, @inputs) = split (/:/, $spec);
4680
4681   push @inputs, "$output.in"
4682     unless @inputs;
4683
4684   return ($output, @inputs);
4685 }
4686
4687 # $input
4688 # locate_am (@POSSIBLE_SOURCES)
4689 # -----------------------------
4690 # AC_CONFIG_FILES allow specifications such as Makefile:top.in:mid.in:bot.in
4691 # This functions returns the first *.in file for which a *.am exists.
4692 # It returns undef otherwise.
4693 sub locate_am (@)
4694 {
4695   my (@rest) = @_;
4696   my $input;
4697   foreach my $file (@rest)
4698     {
4699       if (($file =~ /^(.*)\.in$/) && -f "$1.am")
4700         {
4701           $input = $file;
4702           last;
4703         }
4704     }
4705   return $input;
4706 }
4707
4708 my %make_list;
4709
4710 # &scan_autoconf_config_files ($WHERE, $CONFIG-FILES)
4711 # ---------------------------------------------------
4712 # Study $CONFIG-FILES which is the first argument to AC_CONFIG_FILES
4713 # (or AC_OUTPUT).
4714 sub scan_autoconf_config_files ($$)
4715 {
4716   my ($where, $config_files) = @_;
4717
4718   # Look at potential Makefile.am's.
4719   foreach (split ' ', $config_files)
4720     {
4721       # Must skip empty string for Perl 4.
4722       next if $_ eq "\\" || $_ eq '';
4723
4724       # Handle $local:$input syntax.
4725       my ($local, @rest) = split (/:/);
4726       @rest = ("$local.in",) unless @rest;
4727       my $input = locate_am @rest;
4728       if ($input)
4729         {
4730           # We have a file that automake should generate.
4731           $make_list{$input} = join (':', ($local, @rest));
4732         }
4733       else
4734         {
4735           # We have a file that automake should cause to be
4736           # rebuilt, but shouldn't generate itself.
4737           push (@other_input_files, $_);
4738         }
4739       $ac_config_files_location{$local} = $where;
4740     }
4741 }
4742
4743
4744 # &scan_autoconf_traces ($FILENAME)
4745 # ---------------------------------
4746 sub scan_autoconf_traces ($)
4747 {
4748   my ($filename) = @_;
4749
4750   # Macros to trace, with their minimal number of arguments.
4751   #
4752   # IMPORTANT: If you add a macro here, you should also add this macro
4753   # =========  to Automake-preselection in autoconf/lib/autom4te.in.
4754   my %traced = (
4755                 AC_CANONICAL_BUILD => 0,
4756                 AC_CANONICAL_HOST => 0,
4757                 AC_CANONICAL_TARGET => 0,
4758                 AC_CONFIG_AUX_DIR => 1,
4759                 AC_CONFIG_FILES => 1,
4760                 AC_CONFIG_HEADERS => 1,
4761                 AC_CONFIG_LIBOBJ_DIR => 1,
4762                 AC_CONFIG_LINKS => 1,
4763                 AC_INIT => 0,
4764                 AC_LIBSOURCE => 1,
4765                 AC_REQUIRE_AUX_FILE => 1,
4766                 AC_SUBST_TRACE => 1,
4767                 AM_AUTOMAKE_VERSION => 1,
4768                 AM_CONDITIONAL => 2,
4769                 AM_ENABLE_MULTILIB => 0,
4770                 AM_GNU_GETTEXT => 0,
4771                 AM_INIT_AUTOMAKE => 0,
4772                 AM_MAINTAINER_MODE => 0,
4773                 AM_PROG_CC_C_O => 0,
4774                 LT_SUPPORTED_TAG => 1,
4775                 _LT_AC_TAGCONFIG => 0,
4776                 m4_include => 1,
4777                 m4_sinclude => 1,
4778                 sinclude => 1,
4779               );
4780
4781   my $traces = ($ENV{AUTOCONF} || 'autoconf') . " ";
4782
4783   # Use a separator unlikely to be used, not `:', the default, which
4784   # has a precise meaning for AC_CONFIG_FILES and so on.
4785   $traces .= join (' ',
4786                    map { "--trace=$_" . ':\$f:\$l::\$n::\${::}%' }
4787                    (keys %traced));
4788
4789   my $tracefh = new Automake::XFile ("$traces $filename |");
4790   verb "reading $traces";
4791
4792   while ($_ = $tracefh->getline)
4793     {
4794       chomp;
4795       my ($here, @args) = split (/::/);
4796       my $where = new Automake::Location $here;
4797       my $macro = $args[0];
4798
4799       prog_error ("unrequested trace `$macro'")
4800         unless exists $traced{$macro};
4801
4802       # Skip and diagnose malformed calls.
4803       if ($#args < $traced{$macro})
4804         {
4805           msg ('syntax', $where, "not enough arguments for $macro");
4806           next;
4807         }
4808
4809       # Alphabetical ordering please.
4810       if ($macro eq 'AC_CANONICAL_BUILD')
4811         {
4812           if ($seen_canonical <= AC_CANONICAL_BUILD)
4813             {
4814               $seen_canonical = AC_CANONICAL_BUILD;
4815               $canonical_location = $where;
4816             }
4817         }
4818       elsif ($macro eq 'AC_CANONICAL_HOST')
4819         {
4820           if ($seen_canonical <= AC_CANONICAL_HOST)
4821             {
4822               $seen_canonical = AC_CANONICAL_HOST;
4823               $canonical_location = $where;
4824             }
4825         }
4826       elsif ($macro eq 'AC_CANONICAL_TARGET')
4827         {
4828           $seen_canonical = AC_CANONICAL_TARGET;
4829           $canonical_location = $where;
4830         }
4831       elsif ($macro eq 'AC_CONFIG_AUX_DIR')
4832         {
4833           if ($seen_init_automake)
4834             {
4835               error ($where, "AC_CONFIG_AUX_DIR must be called before "
4836                      . "AM_INIT_AUTOMAKE...", partial => 1);
4837               error ($seen_init_automake, "... AM_INIT_AUTOMAKE called here");
4838             }
4839           $config_aux_dir = $args[1];
4840           $config_aux_dir_set_in_configure_ac = 1;
4841           $relative_dir = '.';
4842           check_directory ($config_aux_dir, $where);
4843         }
4844       elsif ($macro eq 'AC_CONFIG_FILES')
4845         {
4846           # Look at potential Makefile.am's.
4847           scan_autoconf_config_files ($where, $args[1]);
4848         }
4849       elsif ($macro eq 'AC_CONFIG_HEADERS')
4850         {
4851           foreach my $spec (split (' ', $args[1]))
4852             {
4853               my ($dest, @src) = split (':', $spec);
4854               $ac_config_files_location{$dest} = $where;
4855               push @config_headers, $spec;
4856             }
4857         }
4858       elsif ($macro eq 'AC_CONFIG_LIBOBJ_DIR')
4859         {
4860           $config_libobj_dir = $args[1];
4861           $relative_dir = '.';
4862           check_directory ($config_libobj_dir, $where);
4863         }
4864       elsif ($macro eq 'AC_CONFIG_LINKS')
4865         {
4866           foreach my $spec (split (' ', $args[1]))
4867             {
4868               my ($dest, $src) = split (':', $spec);
4869               $ac_config_files_location{$dest} = $where;
4870               push @config_links, $spec;
4871             }
4872         }
4873       elsif ($macro eq 'AC_INIT')
4874         {
4875           if (defined $args[2])
4876             {
4877               $package_version = $args[2];
4878               $package_version_location = $where;
4879             }
4880         }
4881       elsif ($macro eq 'AC_LIBSOURCE')
4882         {
4883           $libsources{$args[1]} = $here;
4884         }
4885       elsif ($macro eq 'AC_SUBST_TRACE')
4886         {
4887           # Just check for alphanumeric in AC_SUBST_TRACE.  If you do
4888           # AC_SUBST(5), then too bad.
4889           $configure_vars{$args[1]} = $where
4890             if $args[1] =~ /^\w+$/;
4891         }
4892       elsif ($macro eq 'AM_AUTOMAKE_VERSION')
4893         {
4894           error ($where,
4895                  "version mismatch.  This is Automake $VERSION,\n" .
4896                  "but the definition used by this AM_INIT_AUTOMAKE\n" .
4897                  "comes from Automake $args[1].  You should recreate\n" .
4898                  "aclocal.m4 with aclocal and run automake again.\n",
4899                  # $? = 63 is used to indicate version mismatch to missing.
4900                  exit_code => 63)
4901             if $VERSION ne $args[1];
4902
4903           $seen_automake_version = 1;
4904         }
4905       elsif ($macro eq 'AM_CONDITIONAL')
4906         {
4907           $configure_cond{$args[1]} = $where;
4908         }
4909       elsif ($macro eq 'AM_ENABLE_MULTILIB')
4910         {
4911           $seen_multilib = $where;
4912         }
4913       elsif ($macro eq 'AM_GNU_GETTEXT')
4914         {
4915           $seen_gettext = $where;
4916           $ac_gettext_location = $where;
4917           $seen_gettext_external = grep ($_ eq 'external', @args);
4918         }
4919       elsif ($macro eq 'AM_INIT_AUTOMAKE')
4920         {
4921           $seen_init_automake = $where;
4922           if (defined $args[2])
4923             {
4924               $package_version = $args[2];
4925               $package_version_location = $where;
4926             }
4927           elsif (defined $args[1])
4928             {
4929               exit $exit_code
4930                 if (process_global_option_list ($where,
4931                                                 split (' ', $args[1])));
4932             }
4933         }
4934       elsif ($macro eq 'AM_MAINTAINER_MODE')
4935         {
4936           $seen_maint_mode = $where;
4937         }
4938       elsif ($macro eq 'AM_PROG_CC_C_O')
4939         {
4940           $seen_cc_c_o = $where;
4941         }
4942       elsif ($macro eq 'AC_REQUIRE_AUX_FILE')
4943         {
4944           # Only remember the first time a file is required.
4945           $required_aux_file{$args[1]} = $where
4946             unless exists $required_aux_file{$args[1]};
4947         }
4948       elsif ($macro eq 'm4_include'
4949              || $macro eq 'm4_sinclude'
4950              || $macro eq 'sinclude')
4951         {
4952           # Skip missing `sinclude'd files.
4953           next if $macro ne 'm4_include' && ! -f $args[1];
4954
4955           # Some modified versions of Autoconf don't use
4956           # forzen files.  Consequently it's possible that we see all
4957           # m4_include's performed during Autoconf's startup.
4958           # Obviously we don't want to distribute Autoconf's files
4959           # so we skip absolute filenames here.
4960           push @configure_deps, '$(top_srcdir)/' . $args[1]
4961             unless $here =~ m,^(?:\w:)?[\\/],;
4962           # Keep track of the greatest timestamp.
4963           if (-e $args[1])
4964             {
4965               my $mtime = mtime $args[1];
4966               $configure_deps_greatest_timestamp = $mtime
4967                 if $mtime > $configure_deps_greatest_timestamp;
4968             }
4969         }
4970       elsif ($macro eq 'LT_SUPPORTED_TAG')
4971         {
4972           $libtool_tags{$args[1]} = 1;
4973           $libtool_new_api = 1;
4974         }
4975       elsif ($macro eq '_LT_AC_TAGCONFIG')
4976         {
4977           # _LT_AC_TAGCONFIG is an old macro present in Libtool 1.5.
4978           # We use it to detect whether tags are supported.  Our
4979           # prefered interface is LT_SUPPORTED_TAG, but it was
4980           # introduced in Libtool 1.6.
4981           if (0 == keys %libtool_tags)
4982             {
4983               # Hardcode the tags supported by Libtool 1.5.
4984               %libtool_tags = (CC => 1, CXX => 1, GCJ => 1, F77 => 1);
4985             }
4986         }
4987     }
4988
4989   $tracefh->close;
4990 }
4991
4992
4993 # &scan_autoconf_files ()
4994 # -----------------------
4995 # Check whether we use `configure.ac' or `configure.in'.
4996 # Scan it (and possibly `aclocal.m4') for interesting things.
4997 # We must scan aclocal.m4 because there might be AC_SUBSTs and such there.
4998 sub scan_autoconf_files ()
4999 {
5000   # Reinitialize libsources here.  This isn't really necessary,
5001   # since we currently assume there is only one configure.ac.  But
5002   # that won't always be the case.
5003   %libsources = ();
5004
5005   # Keep track of the youngest configure dependency.
5006   $configure_deps_greatest_timestamp = mtime $configure_ac;
5007   if (-e 'aclocal.m4')
5008     {
5009       my $mtime = mtime 'aclocal.m4';
5010       $configure_deps_greatest_timestamp = $mtime
5011         if $mtime > $configure_deps_greatest_timestamp;
5012     }
5013
5014   scan_autoconf_traces ($configure_ac);
5015
5016   @configure_input_files = sort keys %make_list;
5017   # Set input and output files if not specified by user.
5018   if (! @input_files)
5019     {
5020       @input_files = @configure_input_files;
5021       %output_files = %make_list;
5022     }
5023
5024
5025   if (! $seen_init_automake)
5026     {
5027       err_ac ("no proper invocation of AM_INIT_AUTOMAKE was found.\nYou "
5028               . "should verify that $configure_ac invokes AM_INIT_AUTOMAKE,"
5029               . "\nthat aclocal.m4 is present in the top-level directory,\n"
5030               . "and that aclocal.m4 was recently regenerated "
5031               . "(using aclocal).");
5032     }
5033   else
5034     {
5035       if (! $seen_automake_version)
5036         {
5037           if (-f 'aclocal.m4')
5038             {
5039               error ($seen_init_automake,
5040                      "your implementation of AM_INIT_AUTOMAKE comes from " .
5041                      "an\nold Automake version.  You should recreate " .
5042                      "aclocal.m4\nwith aclocal and run automake again.\n",
5043                      # $? = 63 is used to indicate version mismatch to missing.
5044                      exit_code => 63);
5045             }
5046           else
5047             {
5048               error ($seen_init_automake,
5049                      "no proper implementation of AM_INIT_AUTOMAKE was " .
5050                      "found,\nprobably because aclocal.m4 is missing...\n" .
5051                      "You should run aclocal to create this file, then\n" .
5052                      "run automake again.\n");
5053             }
5054         }
5055     }
5056
5057   locate_aux_dir ();
5058
5059   # Reorder @input_files so that the Makefile that distributes aux
5060   # files is processed last.  This is important because each directory
5061   # can require auxiliary scripts and we should wait until they have
5062   # been installed before distributing them.
5063
5064   # The Makefile.in that distribute the aux files is the one in
5065   # $config_aux_dir or the top-level Makefile.
5066   my $auxdirdist = is_make_dir ($config_aux_dir) ? $config_aux_dir : '.';
5067   my @new_input_files = ();
5068   while (@input_files)
5069     {
5070       my $in = pop @input_files;
5071       my @ins = split (/:/, $output_files{$in});
5072       if (dirname ($ins[0]) eq $auxdirdist)
5073         {
5074           push @new_input_files, $in;
5075           $automake_will_process_aux_dir = 1;
5076         }
5077       else
5078         {
5079           unshift @new_input_files, $in;
5080         }
5081     }
5082   @input_files = @new_input_files;
5083
5084   # If neither the auxdir/Makefile nor the ./Makefile are generated
5085   # by Automake, we won't distribute the aux files anyway.  Assume
5086   # the user know what (s)he does, and pretend we will distribute
5087   # them to disable the error in require_file_internal.
5088   $automake_will_process_aux_dir = 1 if ! is_make_dir ($auxdirdist);
5089
5090   # Look for some files we need.  Always check for these.  This
5091   # check must be done for every run, even those where we are only
5092   # looking at a subdir Makefile.  We must set relative_dir for
5093   # maybe_push_required_file to work.
5094   $relative_dir = '.';
5095   foreach my $file (keys %required_aux_file)
5096     {
5097       require_conf_file ($required_aux_file{$file}->get, FOREIGN, $file)
5098     }
5099   err_am "`install.sh' is an anachronism; use `install-sh' instead"
5100     if -f $config_aux_dir . '/install.sh';
5101
5102   # Preserve dist_common for later.
5103   $configure_dist_common = variable_value ('DIST_COMMON') || '';
5104
5105 }
5106
5107 ################################################################
5108
5109 # Set up for Cygnus mode.
5110 sub check_cygnus
5111 {
5112   my $cygnus = option 'cygnus';
5113   return unless $cygnus;
5114
5115   set_strictness ('foreign');
5116   set_option ('no-installinfo', $cygnus);
5117   set_option ('no-dependencies', $cygnus);
5118   set_option ('no-dist', $cygnus);
5119
5120   err_ac "`AM_MAINTAINER_MODE' required when --cygnus specified"
5121     if !$seen_maint_mode;
5122 }
5123
5124 # Do any extra checking for GNU standards.
5125 sub check_gnu_standards
5126 {
5127   if ($relative_dir eq '.')
5128     {
5129       # In top level (or only) directory.
5130       require_file ("$am_file.am", GNU,
5131                     qw/INSTALL NEWS README AUTHORS ChangeLog/);
5132
5133       # Accept one of these three licenses; default to COPYING.
5134       # Make sure we do not overwrite an existing license.
5135       my $license;
5136       foreach (qw /COPYING COPYING.LIB COPYING.LESSER/)
5137         {
5138           if (-f $_)
5139             {
5140               $license = $_;
5141               last;
5142             }
5143         }
5144       require_file ("$am_file.am", GNU, 'COPYING')
5145         unless $license;
5146     }
5147
5148   for my $opt ('no-installman', 'no-installinfo')
5149     {
5150       msg ('error-gnu', option $opt,
5151            "option `$opt' disallowed by GNU standards")
5152         if option $opt;
5153     }
5154 }
5155
5156 # Do any extra checking for GNITS standards.
5157 sub check_gnits_standards
5158 {
5159   if ($relative_dir eq '.')
5160     {
5161       # In top level (or only) directory.
5162       require_file ("$am_file.am", GNITS, 'THANKS');
5163     }
5164 }
5165
5166 ################################################################
5167 #
5168 # Functions to handle files of each language.
5169
5170 # Each `lang_X_rewrite($DIRECTORY, $BASE, $EXT)' function follows a
5171 # simple formula: Return value is LANG_SUBDIR if the resulting object
5172 # file should be in a subdir if the source file is, LANG_PROCESS if
5173 # file is to be dealt with, LANG_IGNORE otherwise.
5174
5175 # Much of the actual processing is handled in
5176 # handle_single_transform.  These functions exist so that
5177 # auxiliary information can be recorded for a later cleanup pass.
5178 # Note that the calls to these functions are computed, so don't bother
5179 # searching for their precise names in the source.
5180
5181 # This is just a convenience function that can be used to determine
5182 # when a subdir object should be used.
5183 sub lang_sub_obj
5184 {
5185     return option 'subdir-objects' ? LANG_SUBDIR : LANG_PROCESS;
5186 }
5187
5188 # Rewrite a single C source file.
5189 sub lang_c_rewrite
5190 {
5191   my ($directory, $base, $ext, $nonansi_obj, $have_per_exec_flags, $var) = @_;
5192
5193   if (option 'ansi2knr' && $base =~ /_$/)
5194     {
5195       # FIXME: include line number in error.
5196       err_am "C source file `$base.c' would be deleted by ansi2knr rules";
5197     }
5198
5199   my $r = LANG_PROCESS;
5200   if (option 'subdir-objects')
5201     {
5202       $r = LANG_SUBDIR;
5203       if ($directory && $directory ne '.')
5204         {
5205           $base = $directory . '/' . $base;
5206
5207           # libtool is always able to put the object at the proper place,
5208           # so we do not have to require AM_PROG_CC_C_O when building .lo files.
5209           err_var ($var, "compiling `$base.c' in subdir requires "
5210                    . "`AM_PROG_CC_C_O' in `$configure_ac'",
5211                    uniq_scope => US_GLOBAL,
5212                    uniq_part => 'AM_PROG_CC_C_O subdir')
5213             unless $seen_cc_c_o || $nonansi_obj eq '.lo';
5214         }
5215
5216       # In this case we already have the directory information, so
5217       # don't add it again.
5218       $de_ansi_files{$base} = '';
5219     }
5220   else
5221     {
5222       $de_ansi_files{$base} = (($directory eq '.' || $directory eq '')
5223                                ? ''
5224                                : "$directory/");
5225     }
5226
5227   if (! $seen_cc_c_o
5228       && $have_per_exec_flags
5229       && ! option 'subdir-objects'
5230       && $nonansi_obj ne '.lo')
5231     {
5232       err_var ($var, "compiling `$base.c' with per-target flags requires "
5233                . "`AM_PROG_CC_C_O' in `$configure_ac'",
5234                uniq_scope => US_GLOBAL,
5235                uniq_part => 'AM_PROG_CC_C_O per-target')
5236     }
5237
5238     return $r;
5239 }
5240
5241 # Rewrite a single C++ source file.
5242 sub lang_cxx_rewrite
5243 {
5244     return &lang_sub_obj;
5245 }
5246
5247 # Rewrite a single header file.
5248 sub lang_header_rewrite
5249 {
5250     # Header files are simply ignored.
5251     return LANG_IGNORE;
5252 }
5253
5254 # Rewrite a single yacc file.
5255 sub lang_yacc_rewrite
5256 {
5257     my ($directory, $base, $ext) = @_;
5258
5259     my $r = &lang_sub_obj;
5260     (my $newext = $ext) =~ tr/y/c/;
5261     return ($r, $newext);
5262 }
5263
5264 # Rewrite a single yacc++ file.
5265 sub lang_yaccxx_rewrite
5266 {
5267     my ($directory, $base, $ext) = @_;
5268
5269     my $r = &lang_sub_obj;
5270     (my $newext = $ext) =~ tr/y/c/;
5271     return ($r, $newext);
5272 }
5273
5274 # Rewrite a single lex file.
5275 sub lang_lex_rewrite
5276 {
5277     my ($directory, $base, $ext) = @_;
5278
5279     my $r = &lang_sub_obj;
5280     (my $newext = $ext) =~ tr/l/c/;
5281     return ($r, $newext);
5282 }
5283
5284 # Rewrite a single lex++ file.
5285 sub lang_lexxx_rewrite
5286 {
5287     my ($directory, $base, $ext) = @_;
5288
5289     my $r = &lang_sub_obj;
5290     (my $newext = $ext) =~ tr/l/c/;
5291     return ($r, $newext);
5292 }
5293
5294 # Rewrite a single assembly file.
5295 sub lang_asm_rewrite
5296 {
5297     return &lang_sub_obj;
5298 }
5299
5300 # Rewrite a single preprocessed assembly file.
5301 sub lang_cppasm_rewrite
5302 {
5303     return &lang_sub_obj;
5304 }
5305
5306 # Rewrite a single Fortran 77 file.
5307 sub lang_f77_rewrite
5308 {
5309     return LANG_PROCESS;
5310 }
5311
5312 # Rewrite a single Fortran file.
5313 sub lang_fc_rewrite
5314 {
5315     return LANG_PROCESS;
5316 }
5317
5318 # Rewrite a single preprocessed Fortran file.
5319 sub lang_ppfc_rewrite
5320 {
5321     return LANG_PROCESS;
5322 }
5323
5324 # Rewrite a single preprocessed Fortran 77 file.
5325 sub lang_ppf77_rewrite
5326 {
5327     return LANG_PROCESS;
5328 }
5329
5330 # Rewrite a single ratfor file.
5331 sub lang_ratfor_rewrite
5332 {
5333     return LANG_PROCESS;
5334 }
5335
5336 # Rewrite a single Objective C file.
5337 sub lang_objc_rewrite
5338 {
5339     return &lang_sub_obj;
5340 }
5341
5342 # Rewrite a single Java file.
5343 sub lang_java_rewrite
5344 {
5345     return LANG_SUBDIR;
5346 }
5347
5348 # The lang_X_finish functions are called after all source file
5349 # processing is done.  Each should handle defining rules for the
5350 # language, etc.  A finish function is only called if a source file of
5351 # the appropriate type has been seen.
5352
5353 sub lang_c_finish
5354 {
5355     # Push all libobjs files onto de_ansi_files.  We actually only
5356     # push files which exist in the current directory, and which are
5357     # genuine source files.
5358     foreach my $file (keys %libsources)
5359     {
5360         if ($file =~ /^(.*)\.[cly]$/ && -f "$relative_dir/$file")
5361         {
5362             $de_ansi_files{$1} = ''
5363         }
5364     }
5365
5366     if (option 'ansi2knr' && keys %de_ansi_files)
5367     {
5368         # Make all _.c files depend on their corresponding .c files.
5369         my @objects;
5370         foreach my $base (sort keys %de_ansi_files)
5371         {
5372             # Each _.c file must depend on ansi2knr; otherwise it
5373             # might be used in a parallel build before it is built.
5374             # We need to support files in the srcdir and in the build
5375             # dir (because these files might be auto-generated.  But
5376             # we can't use $< -- some makes only define $< during a
5377             # suffix rule.
5378             my $ansfile = $de_ansi_files{$base} . $base . '.c';
5379             $output_rules .= ($base . "_.c: $ansfile \$(ANSI2KNR)\n\t"
5380                               . '$(CPP) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) '
5381                               . '`if test -f $(srcdir)/' . $ansfile
5382                               . '; then echo $(srcdir)/' . $ansfile
5383                               . '; else echo ' . $ansfile . '; fi` '
5384                               . "| sed 's/^# \\([0-9]\\)/#line \\1/' "
5385                               . '| $(ANSI2KNR) > $@'
5386                               # If ansi2knr fails then we shouldn't
5387                               # create the _.c file
5388                               . " || rm -f \$\@\n");
5389             push (@objects, $base . '_.$(OBJEXT)');
5390             push (@objects, $base . '_.lo')
5391               if var ('LIBTOOL');
5392
5393             # Explicitly clean the _.c files if they are in a
5394             # subdirectory. (In the current directory they get erased
5395             # by a `rm -f *_.c' rule.)
5396             $clean_files{$base . '_.c'} = MOSTLY_CLEAN
5397               if dirname ($base) ne '.';
5398         }
5399
5400         # Make all _.o (and _.lo) files depend on ansi2knr.
5401         # Use a sneaky little hack to make it print nicely.
5402         &pretty_print_rule ('', '', @objects, ':', '$(ANSI2KNR)');
5403     }
5404 }
5405
5406 # This is a yacc helper which is called whenever we have decided to
5407 # compile a yacc file.
5408 sub lang_yacc_target_hook
5409 {
5410     my ($self, $aggregate, $output, $input, %transform) = @_;
5411
5412     my $flag = $aggregate . "_YFLAGS";
5413     my $flagvar = var $flag;
5414     my $YFLAGSvar = var 'YFLAGS';
5415     if (($flagvar && $flagvar->variable_value =~ /$DASH_D_PATTERN/o)
5416         || ($YFLAGSvar && $YFLAGSvar->variable_value =~ /$DASH_D_PATTERN/o))
5417     {
5418         (my $output_base = $output) =~ s/$KNOWN_EXTENSIONS_PATTERN$//;
5419         my $header = $output_base . '.h';
5420
5421         # Found a `-d' that applies to the compilation of this file.
5422         # Add a dependency for the generated header file, and arrange
5423         # for that file to be included in the distribution.
5424         foreach my $cond (Automake::Rule::define (${header}, 'internal',
5425                                                   RULE_AUTOMAKE, TRUE,
5426                                                   INTERNAL))
5427           {
5428             my $condstr = $cond->subst_string;
5429             $output_rules .=
5430               "$condstr${header}: $output\n"
5431               # Recover from removal of $header
5432               . "$condstr\t\@if test ! -f \$@; then \\\n"
5433               . "$condstr\t  rm -f $output; \\\n"
5434               . "$condstr\t  \$(MAKE) \$(AM_MAKEFLAGS) $output; \\\n"
5435               . "$condstr\telse :; fi\n";
5436           }
5437         # Distribute the generated file, unless its .y source was
5438         # listed in a nodist_ variable.  (&handle_source_transform
5439         # will set DIST_SOURCE.)
5440         &push_dist_common ($header)
5441           if $transform{'DIST_SOURCE'};
5442
5443         # If the files are built in the build directory, then we want
5444         # to remove them with `make clean'.  If they are in srcdir
5445         # they shouldn't be touched.  However, we can't determine this
5446         # statically, and the GNU rules say that yacc/lex output files
5447         # should be removed by maintainer-clean.  So that's what we
5448         # do.
5449         $clean_files{$header} = MAINTAINER_CLEAN;
5450     }
5451     # Erase $OUTPUT on `make maintainer-clean' (by GNU standards).
5452     # See the comment above for $HEADER.
5453     $clean_files{$output} = MAINTAINER_CLEAN;
5454 }
5455
5456 # This is a lex helper which is called whenever we have decided to
5457 # compile a lex file.
5458 sub lang_lex_target_hook
5459 {
5460     my ($self, $aggregate, $output, $input) = @_;
5461     # If the files are built in the build directory, then we want to
5462     # remove them with `make clean'.  If they are in srcdir they
5463     # shouldn't be touched.  However, we can't determine this
5464     # statically, and the GNU rules say that yacc/lex output files
5465     # should be removed by maintainer-clean.  So that's what we do.
5466     $clean_files{$output} = MAINTAINER_CLEAN;
5467 }
5468
5469 # This is a helper for both lex and yacc.
5470 sub yacc_lex_finish_helper
5471 {
5472   return if defined $language_scratch{'lex-yacc-done'};
5473   $language_scratch{'lex-yacc-done'} = 1;
5474
5475   # If there is more than one distinct yacc (resp lex) source file
5476   # in a given directory, then the `ylwrap' program is required to
5477   # allow parallel builds to work correctly.  FIXME: for now, no
5478   # line number.
5479   require_conf_file ($configure_ac, FOREIGN, 'ylwrap');
5480   &define_variable ('YLWRAP', "$am_config_aux_dir/ylwrap", INTERNAL);
5481 }
5482
5483 sub lang_yacc_finish
5484 {
5485   return if defined $language_scratch{'yacc-done'};
5486   $language_scratch{'yacc-done'} = 1;
5487
5488   reject_var 'YACCFLAGS', "`YACCFLAGS' obsolete; use `YFLAGS' instead";
5489
5490   &yacc_lex_finish_helper
5491     if count_files_for_language ('yacc') > 1;
5492 }
5493
5494
5495 sub lang_lex_finish
5496 {
5497   return if defined $language_scratch{'lex-done'};
5498   $language_scratch{'lex-done'} = 1;
5499
5500   &yacc_lex_finish_helper
5501     if count_files_for_language ('lex') > 1;
5502 }
5503
5504
5505 # Given a hash table of linker names, pick the name that has the most
5506 # precedence.  This is lame, but something has to have global
5507 # knowledge in order to eliminate the conflict.  Add more linkers as
5508 # required.
5509 sub resolve_linker
5510 {
5511     my (%linkers) = @_;
5512
5513     foreach my $l (qw(GCJLINK CXXLINK F77LINK FCLINK OBJCLINK))
5514     {
5515         return $l if defined $linkers{$l};
5516     }
5517     return 'LINK';
5518 }
5519
5520 # Called to indicate that an extension was used.
5521 sub saw_extension
5522 {
5523     my ($ext) = @_;
5524     if (! defined $extension_seen{$ext})
5525     {
5526         $extension_seen{$ext} = 1;
5527     }
5528     else
5529     {
5530         ++$extension_seen{$ext};
5531     }
5532 }
5533
5534 # Return the number of files seen for a given language.  Knows about
5535 # special cases we care about.  FIXME: this is hideous.  We need
5536 # something that involves real language objects.  For instance yacc
5537 # and yaccxx could both derive from a common yacc class which would
5538 # know about the strange ylwrap requirement.  (Or better yet we could
5539 # just not support legacy yacc!)
5540 sub count_files_for_language
5541 {
5542     my ($name) = @_;
5543
5544     my @names;
5545     if ($name eq 'yacc' || $name eq 'yaccxx')
5546     {
5547         @names = ('yacc', 'yaccxx');
5548     }
5549     elsif ($name eq 'lex' || $name eq 'lexxx')
5550     {
5551         @names = ('lex', 'lexxx');
5552     }
5553     else
5554     {
5555         @names = ($name);
5556     }
5557
5558     my $r = 0;
5559     foreach $name (@names)
5560     {
5561         my $lang = $languages{$name};
5562         foreach my $ext (@{$lang->extensions})
5563         {
5564             $r += $extension_seen{$ext}
5565                 if defined $extension_seen{$ext};
5566         }
5567     }
5568
5569     return $r
5570 }
5571
5572 # Called to ask whether source files have been seen . If HEADERS is 1,
5573 # headers can be included.
5574 sub saw_sources_p
5575 {
5576     my ($headers) = @_;
5577
5578     # count all the sources
5579     my $count = 0;
5580     foreach my $val (values %extension_seen)
5581     {
5582         $count += $val;
5583     }
5584
5585     if (!$headers)
5586     {
5587         $count -= count_files_for_language ('header');
5588     }
5589
5590     return $count > 0;
5591 }
5592
5593
5594 # register_language (%ATTRIBUTE)
5595 # ------------------------------
5596 # Register a single language.
5597 # Each %ATTRIBUTE is of the form ATTRIBUTE => VALUE.
5598 sub register_language (%)
5599 {
5600   my (%option) = @_;
5601
5602   # Set the defaults.
5603   $option{'ansi'} = 0
5604     unless defined $option{'ansi'};
5605   $option{'autodep'} = 'no'
5606     unless defined $option{'autodep'};
5607   $option{'linker'} = ''
5608     unless defined $option{'linker'};
5609   $option{'flags'} = []
5610     unless defined $option{'flags'};
5611   $option{'output_extensions'} = sub { return ( '.$(OBJEXT)', '.lo' ) }
5612     unless defined $option{'output_extensions'};
5613   $option{'nodist_specific'} = 0
5614     unless defined $option{'nodist_specific'};
5615
5616   my $lang = new Language (%option);
5617
5618   # Fill indexes.
5619   $extension_map{$_} = $lang->name foreach @{$lang->extensions};
5620   $languages{$lang->name} = $lang;
5621   my $link = $lang->linker;
5622   if ($link)
5623     {
5624       if (exists $link_languages{$link})
5625         {
5626           prog_error ("`$link' has different definitions in "
5627                       . $lang->name . " and " . $link_languages{$link}->name)
5628             if $lang->link ne $link_languages{$link}->link;
5629         }
5630       else
5631         {
5632           $link_languages{$link} = $lang;
5633         }
5634     }
5635
5636   # Update the pattern of known extensions.
5637   accept_extensions (@{$lang->extensions});
5638
5639   # Upate the $suffix_rule map.
5640   foreach my $suffix (@{$lang->extensions})
5641     {
5642       foreach my $dest (&{$lang->output_extensions} ($suffix))
5643         {
5644           register_suffix_rule (INTERNAL, $suffix, $dest);
5645         }
5646     }
5647 }
5648
5649 # derive_suffix ($EXT, $OBJ)
5650 # --------------------------
5651 # This function is used to find a path from a user-specified suffix $EXT
5652 # to $OBJ or to some other suffix we recognize internally, e.g. `cc'.
5653 sub derive_suffix ($$)
5654 {
5655   my ($source_ext, $obj) = @_;
5656
5657   while (! $extension_map{$source_ext}
5658          && $source_ext ne $obj
5659          && exists $suffix_rules->{$source_ext}
5660          && exists $suffix_rules->{$source_ext}{$obj})
5661     {
5662       $source_ext = $suffix_rules->{$source_ext}{$obj}[0];
5663     }
5664
5665   return $source_ext;
5666 }
5667
5668
5669 ################################################################
5670
5671 # Pretty-print something and append to output_rules.
5672 sub pretty_print_rule
5673 {
5674     $output_rules .= &makefile_wrap (@_);
5675 }
5676
5677
5678 ################################################################
5679
5680
5681 ## -------------------------------- ##
5682 ## Handling the conditional stack.  ##
5683 ## -------------------------------- ##
5684
5685
5686 # $STRING
5687 # make_conditional_string ($NEGATE, $COND)
5688 # ----------------------------------------
5689 sub make_conditional_string ($$)
5690 {
5691   my ($negate, $cond) = @_;
5692   $cond = "${cond}_TRUE"
5693     unless $cond =~ /^TRUE|FALSE$/;
5694   $cond = Automake::Condition::conditional_negate ($cond)
5695     if $negate;
5696   return $cond;
5697 }
5698
5699
5700 # $COND
5701 # cond_stack_if ($NEGATE, $COND, $WHERE)
5702 # --------------------------------------
5703 sub cond_stack_if ($$$)
5704 {
5705   my ($negate, $cond, $where) = @_;
5706
5707   error $where, "$cond does not appear in AM_CONDITIONAL"
5708     if ! $configure_cond{$cond} && $cond !~ /^TRUE|FALSE$/;
5709
5710   push (@cond_stack, make_conditional_string ($negate, $cond));
5711
5712   return new Automake::Condition (@cond_stack);
5713 }
5714
5715
5716 # $COND
5717 # cond_stack_else ($NEGATE, $COND, $WHERE)
5718 # ----------------------------------------
5719 sub cond_stack_else ($$$)
5720 {
5721   my ($negate, $cond, $where) = @_;
5722
5723   if (! @cond_stack)
5724     {
5725       error $where, "else without if";
5726       return FALSE;
5727     }
5728
5729   $cond_stack[$#cond_stack] =
5730     Automake::Condition::conditional_negate ($cond_stack[$#cond_stack]);
5731
5732   # If $COND is given, check against it.
5733   if (defined $cond)
5734     {
5735       $cond = make_conditional_string ($negate, $cond);
5736
5737       error ($where, "else reminder ($negate$cond) incompatible with "
5738              . "current conditional: $cond_stack[$#cond_stack]")
5739         if $cond_stack[$#cond_stack] ne $cond;
5740     }
5741
5742   return new Automake::Condition (@cond_stack);
5743 }
5744
5745
5746 # $COND
5747 # cond_stack_endif ($NEGATE, $COND, $WHERE)
5748 # -----------------------------------------
5749 sub cond_stack_endif ($$$)
5750 {
5751   my ($negate, $cond, $where) = @_;
5752   my $old_cond;
5753
5754   if (! @cond_stack)
5755     {
5756       error $where, "endif without if";
5757       return TRUE;
5758     }
5759
5760   # If $COND is given, check against it.
5761   if (defined $cond)
5762     {
5763       $cond = make_conditional_string ($negate, $cond);
5764
5765       error ($where, "endif reminder ($negate$cond) incompatible with "
5766              . "current conditional: $cond_stack[$#cond_stack]")
5767         if $cond_stack[$#cond_stack] ne $cond;
5768     }
5769
5770   pop @cond_stack;
5771
5772   return new Automake::Condition (@cond_stack);
5773 }
5774
5775
5776
5777
5778
5779 ## ------------------------ ##
5780 ## Handling the variables.  ##
5781 ## ------------------------ ##
5782
5783
5784 # &define_pretty_variable ($VAR, $COND, $WHERE, @VALUE)
5785 # -----------------------------------------------------
5786 # Like define_variable, but the value is a list, and the variable may
5787 # be defined conditionally.  The second argument is the Condition
5788 # under which the value should be defined; this should be the empty
5789 # string to define the variable unconditionally.  The third argument
5790 # is a list holding the values to use for the variable.  The value is
5791 # pretty printed in the output file.
5792 sub define_pretty_variable ($$$@)
5793 {
5794     my ($var, $cond, $where, @value) = @_;
5795
5796     if (! vardef ($var, $cond))
5797     {
5798         Automake::Variable::define ($var, VAR_AUTOMAKE, '', $cond, "@value",
5799                                     '', $where, VAR_PRETTY);
5800         rvar ($var)->rdef ($cond)->set_seen;
5801     }
5802 }
5803
5804
5805 # define_variable ($VAR, $VALUE, $WHERE)
5806 # --------------------------------------
5807 # Define a new Automake Makefile variable VAR to VALUE, but only if
5808 # not already defined.
5809 sub define_variable ($$$)
5810 {
5811     my ($var, $value, $where) = @_;
5812     define_pretty_variable ($var, TRUE, $where, $value);
5813 }
5814
5815
5816 # define_files_variable ($VAR, \@BASENAME, $EXTENSION, $WHERE)
5817 # -----------------------------------------------------------
5818 # Define the $VAR which content is the list of file names composed of
5819 # a @BASENAME and the $EXTENSION.
5820 sub define_files_variable ($\@$$)
5821 {
5822   my ($var, $basename, $extension, $where) = @_;
5823   define_variable ($var,
5824                    join (' ', map { "$_.$extension" } @$basename),
5825                    $where);
5826 }
5827
5828
5829 # Like define_variable, but define a variable to be the configure
5830 # substitution by the same name.
5831 sub define_configure_variable ($)
5832 {
5833   my ($var) = @_;
5834
5835   my $pretty = VAR_ASIS;
5836   my $owner = VAR_CONFIGURE;
5837
5838   # Do not output the ANSI2KNR configure variable -- we AC_SUBST
5839   # it in protos.m4, but later redefine it elsewhere.  This is
5840   # pretty hacky.  We also don't output AMDEPBACKSLASH: it might
5841   # be subst'd by `\', which certainly would not be appreciated by
5842   # Make.
5843   if ($var eq 'ANSI2KNR' || $var eq 'AMDEPBACKSLASH')
5844     {
5845       $pretty = VAR_SILENT;
5846       $owner = VAR_AUTOMAKE;
5847     }
5848
5849   Automake::Variable::define ($var, $owner, '', TRUE, subst $var,
5850                               '', $configure_vars{$var}, $pretty);
5851 }
5852
5853
5854 # define_compiler_variable ($LANG)
5855 # --------------------------------
5856 # Define a compiler variable.  We also handle defining the `LT'
5857 # version of the command when using libtool.
5858 sub define_compiler_variable ($)
5859 {
5860     my ($lang) = @_;
5861
5862     my ($var, $value) = ($lang->compiler, $lang->compile);
5863     my $libtool_tag = '';
5864     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
5865       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
5866     &define_variable ($var, $value, INTERNAL);
5867     &define_variable ("LT$var",
5868                       "\$(LIBTOOL) $libtool_tag\$(AM_LIBTOOLFLAGS) "
5869                       . "\$(LIBTOOLFLAGS) --mode=compile $value",
5870                       INTERNAL)
5871       if var ('LIBTOOL');
5872 }
5873
5874
5875 # define_linker_variable ($LANG)
5876 # ------------------------------
5877 # Define linker variables.
5878 sub define_linker_variable ($)
5879 {
5880     my ($lang) = @_;
5881
5882     my $libtool_tag = '';
5883     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
5884       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
5885     # CCLD = $(CC).
5886     &define_variable ($lang->lder, $lang->ld, INTERNAL);
5887     # CCLINK = $(CCLD) blah blah...
5888     &define_variable ($lang->linker,
5889                       ((var ('LIBTOOL') ?
5890                         "\$(LIBTOOL) $libtool_tag\$(AM_LIBTOOLFLAGS) "
5891                         . "\$(LIBTOOLFLAGS) --mode=link " : '')
5892                        . $lang->link),
5893                       INTERNAL);
5894 }
5895
5896 sub define_per_target_linker_variable ($$)
5897 {
5898   my ($linker, $target) = @_;
5899
5900   # If the user wrote a custom link command, we don't define ours.
5901   return "${target}_LINK"
5902     if set_seen "${target}_LINK";
5903
5904   my $xlink = $linker ? $linker : 'LINK';
5905
5906   my $lang = $link_languages{$xlink};
5907   prog_error "Unknown language for linker variable `$xlink'"
5908     unless $lang;
5909
5910   my $link_command = $lang->link;
5911   if (var 'LIBTOOL')
5912     {
5913       my $libtool_tag = '';
5914       $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
5915         if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
5916
5917       $link_command =
5918         "\$(LIBTOOL) $libtool_tag\$(AM_LIBTOOLFLAGS) \$(LIBTOOLFLAGS) "
5919         . "--mode=link " . $link_command;
5920     }
5921
5922   # Rewrite each occurrence of `AM_$flag' in the link
5923   # command into `${derived}_$flag' if it exists.
5924   my $orig_command = $link_command;
5925   my @flags = (@{$lang->flags}, 'LDFLAGS');
5926   push @flags, 'LIBTOOLFLAGS' if var 'LIBTOOL';
5927   for my $flag (@flags)
5928     {
5929       my $val = "${target}_$flag";
5930       $link_command =~ s/\(AM_$flag\)/\($val\)/
5931         if set_seen ($val);
5932     }
5933
5934   # If the computed command is the same as the generic command, use
5935   # the command linker variable.
5936   return $lang->linker
5937     if $link_command eq $orig_command;
5938
5939   &define_variable ("${target}_LINK", $link_command, INTERNAL);
5940   return "${target}_LINK";
5941 }
5942
5943 ################################################################
5944
5945 # &check_trailing_slash ($WHERE, $LINE)
5946 # --------------------------------------
5947 # Return 1 iff $LINE ends with a slash.
5948 # Might modify $LINE.
5949 sub check_trailing_slash ($\$)
5950 {
5951   my ($where, $line) = @_;
5952
5953   # Ignore `##' lines.
5954   return 0 if $$line =~ /$IGNORE_PATTERN/o;
5955
5956   # Catch and fix a common error.
5957   msg "syntax", $where, "whitespace following trailing backslash"
5958     if $$line =~ s/\\\s+\n$/\\\n/;
5959
5960   return $$line =~ /\\$/;
5961 }
5962
5963
5964 # &read_am_file ($AMFILE, $WHERE)
5965 # -------------------------------
5966 # Read Makefile.am and set up %contents.  Simultaneously copy lines
5967 # from Makefile.am into $output_trailer, or define variables as
5968 # appropriate.  NOTE we put rules in the trailer section.  We want
5969 # user rules to come after our generated stuff.
5970 sub read_am_file ($$)
5971 {
5972     my ($amfile, $where) = @_;
5973
5974     my $am_file = new Automake::XFile ("< $amfile");
5975     verb "reading $amfile";
5976
5977     # Keep track of the youngest output dependency.
5978     my $mtime = mtime $amfile;
5979     $output_deps_greatest_timestamp = $mtime
5980       if $mtime > $output_deps_greatest_timestamp;
5981
5982     my $spacing = '';
5983     my $comment = '';
5984     my $blank = 0;
5985     my $saw_bk = 0;
5986     my $var_look = VAR_ASIS;
5987
5988     use constant IN_VAR_DEF => 0;
5989     use constant IN_RULE_DEF => 1;
5990     use constant IN_COMMENT => 2;
5991     my $prev_state = IN_RULE_DEF;
5992
5993     while ($_ = $am_file->getline)
5994     {
5995         $where->set ("$amfile:$.");
5996         if (/$IGNORE_PATTERN/o)
5997         {
5998             # Merely delete comments beginning with two hashes.
5999         }
6000         elsif (/$WHITE_PATTERN/o)
6001         {
6002             error $where, "blank line following trailing backslash"
6003               if $saw_bk;
6004             # Stick a single white line before the incoming macro or rule.
6005             $spacing = "\n";
6006             $blank = 1;
6007             # Flush all comments seen so far.
6008             if ($comment ne '')
6009             {
6010                 $output_vars .= $comment;
6011                 $comment = '';
6012             }
6013         }
6014         elsif (/$COMMENT_PATTERN/o)
6015         {
6016             # Stick comments before the incoming macro or rule.  Make
6017             # sure a blank line precedes the first block of comments.
6018             $spacing = "\n" unless $blank;
6019             $blank = 1;
6020             $comment .= $spacing . $_;
6021             $spacing = '';
6022             $prev_state = IN_COMMENT;
6023         }
6024         else
6025         {
6026             last;
6027         }
6028         $saw_bk = check_trailing_slash ($where, $_);
6029     }
6030
6031     # We save the conditional stack on entry, and then check to make
6032     # sure it is the same on exit.  This lets us conditionally include
6033     # other files.
6034     my @saved_cond_stack = @cond_stack;
6035     my $cond = new Automake::Condition (@cond_stack);
6036
6037     my $last_var_name = '';
6038     my $last_var_type = '';
6039     my $last_var_value = '';
6040     my $last_where;
6041     # FIXME: shouldn't use $_ in this loop; it is too big.
6042     while ($_)
6043     {
6044         $where->set ("$amfile:$.");
6045
6046         # Make sure the line is \n-terminated.
6047         chomp;
6048         $_ .= "\n";
6049
6050         # Don't look at MAINTAINER_MODE_TRUE here.  That shouldn't be
6051         # used by users.  @MAINT@ is an anachronism now.
6052         $_ =~ s/\@MAINT\@//g
6053             unless $seen_maint_mode;
6054
6055         my $new_saw_bk = check_trailing_slash ($where, $_);
6056
6057         if (/$IGNORE_PATTERN/o)
6058         {
6059             # Merely delete comments beginning with two hashes.
6060
6061             # Keep any backslash from the previous line.
6062             $new_saw_bk = $saw_bk;
6063         }
6064         elsif (/$WHITE_PATTERN/o)
6065         {
6066             # Stick a single white line before the incoming macro or rule.
6067             $spacing = "\n";
6068             error $where, "blank line following trailing backslash"
6069               if $saw_bk;
6070         }
6071         elsif (/$COMMENT_PATTERN/o)
6072         {
6073             error $where, "comment following trailing backslash"
6074               if $saw_bk && $comment eq '';
6075
6076             # Stick comments before the incoming macro or rule.
6077             $comment .= $spacing . $_;
6078             $spacing = '';
6079             $prev_state = IN_COMMENT;
6080         }
6081         elsif ($saw_bk)
6082         {
6083             if ($prev_state == IN_RULE_DEF)
6084             {
6085               my $cond = new Automake::Condition @cond_stack;
6086               $output_trailer .= $cond->subst_string;
6087               $output_trailer .= $_;
6088             }
6089             elsif ($prev_state == IN_COMMENT)
6090             {
6091                 # If the line doesn't start with a `#', add it.
6092                 # We do this because a continued comment like
6093                 #   # A = foo \
6094                 #         bar \
6095                 #         baz
6096                 # is not portable.  BSD make doesn't honor
6097                 # escaped newlines in comments.
6098                 s/^#?/#/;
6099                 $comment .= $spacing . $_;
6100             }
6101             else # $prev_state == IN_VAR_DEF
6102             {
6103               $last_var_value .= ' '
6104                 unless $last_var_value =~ /\s$/;
6105               $last_var_value .= $_;
6106
6107               if (!/\\$/)
6108                 {
6109                   Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6110                                               $last_var_type, $cond,
6111                                               $last_var_value, $comment,
6112                                               $last_where, VAR_ASIS)
6113                     if $cond != FALSE;
6114                   $comment = $spacing = '';
6115                 }
6116             }
6117         }
6118
6119         elsif (/$IF_PATTERN/o)
6120           {
6121             $cond = cond_stack_if ($1, $2, $where);
6122           }
6123         elsif (/$ELSE_PATTERN/o)
6124           {
6125             $cond = cond_stack_else ($1, $2, $where);
6126           }
6127         elsif (/$ENDIF_PATTERN/o)
6128           {
6129             $cond = cond_stack_endif ($1, $2, $where);
6130           }
6131
6132         elsif (/$RULE_PATTERN/o)
6133         {
6134             # Found a rule.
6135             $prev_state = IN_RULE_DEF;
6136
6137             # For now we have to output all definitions of user rules
6138             # and can't diagnose duplicates (see the comment in
6139             # Automake::Rule::define). So we go on and ignore the return value.
6140             Automake::Rule::define ($1, $amfile, RULE_USER, $cond, $where);
6141
6142             check_variable_expansions ($_, $where);
6143
6144             $output_trailer .= $comment . $spacing;
6145             my $cond = new Automake::Condition @cond_stack;
6146             $output_trailer .= $cond->subst_string;
6147             $output_trailer .= $_;
6148             $comment = $spacing = '';
6149         }
6150         elsif (/$ASSIGNMENT_PATTERN/o)
6151         {
6152             # Found a macro definition.
6153             $prev_state = IN_VAR_DEF;
6154             $last_var_name = $1;
6155             $last_var_type = $2;
6156             $last_var_value = $3;
6157             $last_where = $where->clone;
6158             if ($3 ne '' && substr ($3, -1) eq "\\")
6159               {
6160                 # We preserve the `\' because otherwise the long lines
6161                 # that are generated will be truncated by broken
6162                 # `sed's.
6163                 $last_var_value = $3 . "\n";
6164               }
6165             # Normally we try to output variable definitions in the
6166             # same format they were input.  However, POSIX compliant
6167             # systems are not required to support lines longer than
6168             # 2048 bytes (most notably, some sed implementation are
6169             # limited to 4000 bytes, and sed is used by config.status
6170             # to rewrite Makefile.in into Makefile).  Moreover nobody
6171             # would really write such long lines by hand since it is
6172             # hardly maintainable.  So if a line is longer that 1000
6173             # bytes (an arbitrary limit), assume it has been
6174             # automatically generated by some tools, and flatten the
6175             # variable definition.  Otherwise, keep the variable as it
6176             # as been input.
6177             $var_look = VAR_PRETTY if length ($last_var_value) >= 1000;
6178
6179             if (!/\\$/)
6180               {
6181                 Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6182                                             $last_var_type, $cond,
6183                                             $last_var_value, $comment,
6184                                             $last_where, $var_look)
6185                   if $cond != FALSE;
6186                 $comment = $spacing = '';
6187                 $var_look = VAR_ASIS;
6188               }
6189         }
6190         elsif (/$INCLUDE_PATTERN/o)
6191         {
6192             my $path = $1;
6193
6194             if ($path =~ s/^\$\(top_srcdir\)\///)
6195               {
6196                 push (@include_stack, "\$\(top_srcdir\)/$path");
6197                 # Distribute any included file.
6198
6199                 # Always use the $(top_srcdir) prefix in DIST_COMMON,
6200                 # otherwise OSF make will implicitly copy the included
6201                 # file in the build tree during `make distdir' to satisfy
6202                 # the dependency.
6203                 # (subdircond2.test and subdircond3.test will fail.)
6204                 push_dist_common ("\$\(top_srcdir\)/$path");
6205               }
6206             else
6207               {
6208                 $path =~ s/\$\(srcdir\)\///;
6209                 push (@include_stack, "\$\(srcdir\)/$path");
6210                 # Always use the $(srcdir) prefix in DIST_COMMON,
6211                 # otherwise OSF make will implicitly copy the included
6212                 # file in the build tree during `make distdir' to satisfy
6213                 # the dependency.
6214                 # (subdircond2.test and subdircond3.test will fail.)
6215                 push_dist_common ("\$\(srcdir\)/$path");
6216                 $path = $relative_dir . "/" . $path if $relative_dir ne '.';
6217               }
6218             $where->push_context ("`$path' included from here");
6219             &read_am_file ($path, $where);
6220             $where->pop_context;
6221         }
6222         else
6223         {
6224             # This isn't an error; it is probably a continued rule.
6225             # In fact, this is what we assume.
6226             $prev_state = IN_RULE_DEF;
6227             check_variable_expansions ($_, $where);
6228             $output_trailer .= $comment . $spacing;
6229             my $cond = new Automake::Condition @cond_stack;
6230             $output_trailer .= $cond->subst_string;
6231             $output_trailer .= $_;
6232             $comment = $spacing = '';
6233             error $where, "`#' comment at start of rule is unportable"
6234               if $_ =~ /^\t\s*\#/;
6235         }
6236
6237         $saw_bk = $new_saw_bk;
6238         $_ = $am_file->getline;
6239     }
6240
6241     $output_trailer .= $comment;
6242
6243     error ($where, "trailing backslash on last line")
6244       if $saw_bk;
6245
6246     error ($where, (@cond_stack ? "unterminated conditionals: @cond_stack"
6247                     : "too many conditionals closed in include file"))
6248       if "@saved_cond_stack" ne "@cond_stack";
6249 }
6250
6251
6252 # define_standard_variables ()
6253 # ----------------------------
6254 # A helper for read_main_am_file which initializes configure variables
6255 # and variables from header-vars.am.
6256 sub define_standard_variables
6257 {
6258   my $saved_output_vars = $output_vars;
6259   my ($comments, undef, $rules) =
6260     file_contents_internal (1, "$libdir/am/header-vars.am",
6261                             new Automake::Location);
6262
6263   foreach my $var (sort keys %configure_vars)
6264     {
6265       &define_configure_variable ($var);
6266     }
6267
6268   $output_vars .= $comments . $rules;
6269 }
6270
6271 # Read main am file.
6272 sub read_main_am_file
6273 {
6274     my ($amfile) = @_;
6275
6276     # This supports the strange variable tricks we are about to play.
6277     prog_error (macros_dump () . "variable defined before read_main_am_file")
6278       if (scalar (variables) > 0);
6279
6280     # Generate copyright header for generated Makefile.in.
6281     # We do discard the output of predefined variables, handled below.
6282     $output_vars = ("# $in_file_name generated by automake "
6283                    . $VERSION . " from $am_file_name.\n");
6284     $output_vars .= '# ' . subst ('configure_input') . "\n";
6285     $output_vars .= $gen_copyright;
6286
6287     # We want to predefine as many variables as possible.  This lets
6288     # the user set them with `+=' in Makefile.am.
6289     &define_standard_variables;
6290
6291     # Read user file, which might override some of our values.
6292     &read_am_file ($amfile, new Automake::Location);
6293 }
6294
6295
6296
6297 ################################################################
6298
6299 # $FLATTENED
6300 # &flatten ($STRING)
6301 # ------------------
6302 # Flatten the $STRING and return the result.
6303 sub flatten
6304 {
6305   $_ = shift;
6306
6307   s/\\\n//somg;
6308   s/\s+/ /g;
6309   s/^ //;
6310   s/ $//;
6311
6312   return $_;
6313 }
6314
6315 # transform($TOKEN, \%PAIRS)
6316 # ==========================
6317 # If ($TOKEN, $VAL) is in %PAIRS:
6318 #   - replaces %$TOKEN% with $VAL,
6319 #   - enables/disables ?$TOKEN? and ?!$TOKEN?,
6320 #   - replaces %?$TOKEN% with TRUE or FALSE.
6321 sub transform($$)
6322 {
6323   my ($token, $transform) = @_;
6324
6325   if (substr ($token, 0, 1) eq '%')
6326     {
6327       my $cond = (substr ($token, 1, 1) eq '?') ? 1 : 0;
6328       $token = substr ($token, 1 + $cond, -1);
6329       my $val = $transform->{$token};
6330       prog_error "Unknown %token% `$token'" unless defined $val;
6331       if ($cond)
6332         {
6333           return $val ? 'TRUE' : 'FALSE';
6334         }
6335       else
6336         {
6337           return $val;
6338         }
6339     }
6340   # Now $token is '?xxx?' or '?!xxx?'.
6341   my $neg = (substr ($token, 1, 1) eq '!') ? 1 : 0;
6342   $token = substr ($token, 1 + $neg, -1);
6343   my $val = $transform->{$token};
6344   prog_error "Unknown ?token? `$token' (neg = $neg)" unless defined $val;
6345   return (!!$val == $neg) ? '##%' : '';
6346 }
6347
6348 # @PARAGRAPHS
6349 # &make_paragraphs ($MAKEFILE, [%TRANSFORM])
6350 # ------------------------------------------
6351 # Load a $MAKEFILE, apply the %TRANSFORM, and return it as a list of
6352 # paragraphs.
6353 sub make_paragraphs ($%)
6354 {
6355   my ($file, %transform) = @_;
6356
6357   # Complete %transform with global options.
6358   # Note that %transform goes last, so it overrides global options.
6359   %transform = ('CYGNUS'      => !! option 'cygnus',
6360                  'MAINTAINER-MODE'
6361                  => $seen_maint_mode ? subst ('MAINTAINER_MODE_TRUE') : '',
6362
6363                  'BZIP2'       => !! option 'dist-bzip2',
6364                  'COMPRESS'    => !! option 'dist-tarZ',
6365                  'GZIP'        =>  ! option 'no-dist-gzip',
6366                  'SHAR'        => !! option 'dist-shar',
6367                  'ZIP'         => !! option 'dist-zip',
6368
6369                  'INSTALL-INFO' =>  ! option 'no-installinfo',
6370                  'INSTALL-MAN'  =>  ! option 'no-installman',
6371                  'CK-NEWS'      => !! option 'check-news',
6372
6373                  'SUBDIRS'      => !! var ('SUBDIRS'),
6374                  'TOPDIR_P'     => $relative_dir eq '.',
6375
6376                  'BUILD'    => ($seen_canonical >= AC_CANONICAL_BUILD),
6377                  'HOST'     => ($seen_canonical >= AC_CANONICAL_HOST),
6378                  'TARGET'   => ($seen_canonical >= AC_CANONICAL_TARGET),
6379
6380                  'LIBTOOL'      => !! var ('LIBTOOL'),
6381                  'NONLIBTOOL'   => 1,
6382                  'FIRST'        => ! $transformed_files{$file},
6383                 %transform);
6384
6385   $transformed_files{$file} = 1;
6386   $_ = $am_file_cache{$file};
6387
6388   if (! defined $_)
6389     {
6390       verb "reading $file";
6391       # Swallow the whole file.
6392       my $fc_file = new Automake::XFile "< $file";
6393       my $saved_dollar_slash = $/;
6394       undef $/;
6395       $_ = $fc_file->getline;
6396       $/ = $saved_dollar_slash;
6397       $fc_file->close;
6398
6399       # Remove ##-comments.
6400       # Besides we don't need more than two consecutive new-lines.
6401       s/(?:$IGNORE_PATTERN|(?<=\n\n)\n+)//gom;
6402
6403       $am_file_cache{$file} = $_;
6404     }
6405
6406   # Substitute Automake template tokens.
6407   s/(?:%\??[\w\-]+%|\?!?[\w\-]+\?)/transform($&, \%transform)/ge;
6408   # transform() may have added some ##%-comments to strip.
6409   # (we use `##%' instead of `##' so we can distinguish ##%##%##% from
6410   # ####### and do not remove the latter.)
6411   s/^[ \t]*(?:##%)+.*\n//gm;
6412
6413   # Split at unescaped new lines.
6414   my @lines = split (/(?<!\\)\n/, $_);
6415   my @res;
6416
6417   while (defined ($_ = shift @lines))
6418     {
6419       my $paragraph = $_;
6420       # If we are a rule, eat as long as we start with a tab.
6421       if (/$RULE_PATTERN/smo)
6422         {
6423           while (defined ($_ = shift @lines) && $_ =~ /^\t/)
6424             {
6425               $paragraph .= "\n$_";
6426             }
6427           unshift (@lines, $_);
6428         }
6429
6430       # If we are a comments, eat as much comments as you can.
6431       elsif (/$COMMENT_PATTERN/smo)
6432         {
6433           while (defined ($_ = shift @lines)
6434                  && $_ =~ /$COMMENT_PATTERN/smo)
6435             {
6436               $paragraph .= "\n$_";
6437             }
6438           unshift (@lines, $_);
6439         }
6440
6441       push @res, $paragraph;
6442     }
6443
6444   return @res;
6445 }
6446
6447
6448
6449 # ($COMMENT, $VARIABLES, $RULES)
6450 # &file_contents_internal ($IS_AM, $FILE, $WHERE, [%TRANSFORM])
6451 # -------------------------------------------------------------
6452 # Return contents of a file from $libdir/am, automatically skipping
6453 # macros or rules which are already known. $IS_AM iff the caller is
6454 # reading an Automake file (as opposed to the user's Makefile.am).
6455 sub file_contents_internal ($$$%)
6456 {
6457     my ($is_am, $file, $where, %transform) = @_;
6458
6459     $where->set ($file);
6460
6461     my $result_vars = '';
6462     my $result_rules = '';
6463     my $comment = '';
6464     my $spacing = '';
6465
6466     # The following flags are used to track rules spanning across
6467     # multiple paragraphs.
6468     my $is_rule = 0;            # 1 if we are processing a rule.
6469     my $discard_rule = 0;       # 1 if the current rule should not be output.
6470
6471     # We save the conditional stack on entry, and then check to make
6472     # sure it is the same on exit.  This lets us conditionally include
6473     # other files.
6474     my @saved_cond_stack = @cond_stack;
6475     my $cond = new Automake::Condition (@cond_stack);
6476
6477     foreach (make_paragraphs ($file, %transform))
6478     {
6479         # FIXME: no line number available.
6480         $where->set ($file);
6481
6482         # Sanity checks.
6483         error $where, "blank line following trailing backslash:\n$_"
6484           if /\\$/;
6485         error $where, "comment following trailing backslash:\n$_"
6486           if /\\#/;
6487
6488         if (/^$/)
6489         {
6490             $is_rule = 0;
6491             # Stick empty line before the incoming macro or rule.
6492             $spacing = "\n";
6493         }
6494         elsif (/$COMMENT_PATTERN/mso)
6495         {
6496             $is_rule = 0;
6497             # Stick comments before the incoming macro or rule.
6498             $comment = "$_\n";
6499         }
6500
6501         # Handle inclusion of other files.
6502         elsif (/$INCLUDE_PATTERN/o)
6503         {
6504             if ($cond != FALSE)
6505               {
6506                 my $file = ($is_am ? "$libdir/am/" : '') . $1;
6507                 $where->push_context ("`$file' included from here");
6508                 # N-ary `.=' fails.
6509                 my ($com, $vars, $rules)
6510                   = file_contents_internal ($is_am, $file, $where, %transform);
6511                 $where->pop_context;
6512                 $comment .= $com;
6513                 $result_vars .= $vars;
6514                 $result_rules .= $rules;
6515               }
6516         }
6517
6518         # Handling the conditionals.
6519         elsif (/$IF_PATTERN/o)
6520           {
6521             $cond = cond_stack_if ($1, $2, $file);
6522           }
6523         elsif (/$ELSE_PATTERN/o)
6524           {
6525             $cond = cond_stack_else ($1, $2, $file);
6526           }
6527         elsif (/$ENDIF_PATTERN/o)
6528           {
6529             $cond = cond_stack_endif ($1, $2, $file);
6530           }
6531
6532         # Handling rules.
6533         elsif (/$RULE_PATTERN/mso)
6534         {
6535           $is_rule = 1;
6536           $discard_rule = 0;
6537           # Separate relationship from optional actions: the first
6538           # `new-line tab" not preceded by backslash (continuation
6539           # line).
6540           my $paragraph = $_;
6541           /^(.*?)(?:(?<!\\)\n(\t.*))?$/s;
6542           my ($relationship, $actions) = ($1, $2 || '');
6543
6544           # Separate targets from dependencies: the first colon.
6545           $relationship =~ /^([^:]+\S+) *: *(.*)$/som;
6546           my ($targets, $dependencies) = ($1, $2);
6547           # Remove the escaped new lines.
6548           # I don't know why, but I have to use a tmp $flat_deps.
6549           my $flat_deps = &flatten ($dependencies);
6550           my @deps = split (' ', $flat_deps);
6551
6552           foreach (split (' ' , $targets))
6553             {
6554               # FIXME: 1. We are not robust to people defining several targets
6555               # at once, only some of them being in %dependencies.  The
6556               # actions from the targets in %dependencies are usually generated
6557               # from the content of %actions, but if some targets in $targets
6558               # are not in %dependencies the ELSE branch will output
6559               # a rule for all $targets (i.e. the targets which are both
6560               # in %dependencies and $targets will have two rules).
6561
6562               # FIXME: 2. The logic here is not able to output a
6563               # multi-paragraph rule several time (e.g. for each condition
6564               # it is defined for) because it only knows the first paragraph.
6565
6566               # FIXME: 3. We are not robust to people defining a subset
6567               # of a previously defined "multiple-target" rule.  E.g.
6568               # `foo:' after `foo bar:'.
6569
6570               # Output only if not in FALSE.
6571               if (defined $dependencies{$_} && $cond != FALSE)
6572                 {
6573                   &depend ($_, @deps);
6574                   if ($actions{$_})
6575                     {
6576                       $actions{$_} .= "\n$actions" if $actions;
6577                     }
6578                   else
6579                     {
6580                       $actions{$_} = $actions;
6581                     }
6582                 }
6583               else
6584                 {
6585                   # Free-lance dependency.  Output the rule for all the
6586                   # targets instead of one by one.
6587                   my @undefined_conds =
6588                     Automake::Rule::define ($targets, $file,
6589                                             $is_am ? RULE_AUTOMAKE : RULE_USER,
6590                                             $cond, $where);
6591                   for my $undefined_cond (@undefined_conds)
6592                     {
6593                       my $condparagraph = $paragraph;
6594                       $condparagraph =~ s/^/$undefined_cond->subst_string/gme;
6595                       $result_rules .= "$spacing$comment$condparagraph\n";
6596                     }
6597                   if (scalar @undefined_conds == 0)
6598                     {
6599                       # Remember to discard next paragraphs
6600                       # if they belong to this rule.
6601                       # (but see also FIXME: #2 above.)
6602                       $discard_rule = 1;
6603                     }
6604                   $comment = $spacing = '';
6605                   last;
6606                 }
6607             }
6608         }
6609
6610         elsif (/$ASSIGNMENT_PATTERN/mso)
6611         {
6612             my ($var, $type, $val) = ($1, $2, $3);
6613             error $where, "variable `$var' with trailing backslash"
6614               if /\\$/;
6615
6616             $is_rule = 0;
6617
6618             Automake::Variable::define ($var,
6619                                         $is_am ? VAR_AUTOMAKE : VAR_MAKEFILE,
6620                                         $type, $cond, $val, $comment, $where,
6621                                         VAR_ASIS)
6622               if $cond != FALSE;
6623
6624             $comment = $spacing = '';
6625         }
6626         else
6627         {
6628             # This isn't an error; it is probably some tokens which
6629             # configure is supposed to replace, such as `@SET-MAKE@',
6630             # or some part of a rule cut by an if/endif.
6631             if (! $cond->false && ! ($is_rule && $discard_rule))
6632               {
6633                 s/^/$cond->subst_string/gme;
6634                 $result_rules .= "$spacing$comment$_\n";
6635               }
6636             $comment = $spacing = '';
6637         }
6638     }
6639
6640     error ($where, @cond_stack ?
6641            "unterminated conditionals: @cond_stack" :
6642            "too many conditionals closed in include file")
6643       if "@saved_cond_stack" ne "@cond_stack";
6644
6645     return ($comment, $result_vars, $result_rules);
6646 }
6647
6648
6649 # $CONTENTS
6650 # &file_contents ($BASENAME, $WHERE, [%TRANSFORM])
6651 # ------------------------------------------------
6652 # Return contents of a file from $libdir/am, automatically skipping
6653 # macros or rules which are already known.
6654 sub file_contents ($$%)
6655 {
6656     my ($basename, $where, %transform) = @_;
6657     my ($comments, $variables, $rules) =
6658       file_contents_internal (1, "$libdir/am/$basename.am", $where,
6659                               %transform);
6660     return "$comments$variables$rules";
6661 }
6662
6663
6664 # &append_exeext ($MACRO)
6665 # -----------------------
6666 # Macro is an Automake magic macro which primary is PROGRAMS, e.g.
6667 # bin_PROGRAMS.  Make sure these programs have $(EXEEXT) appended.
6668 sub append_exeext ($)
6669 {
6670   my ($macro) = @_;
6671
6672   prog_error "append_exeext ($macro)"
6673     unless $macro =~ /_PROGRAMS$/;
6674
6675   transform_variable_recursively
6676     ($macro, $macro, 'am__EXEEXT', 0, INTERNAL,
6677      sub {
6678        my ($subvar, $val, $cond, $full_cond) = @_;
6679        # Append $(EXEEXT) unless the user did it already, or it's a
6680        # @substitution@.
6681        $val .= '$(EXEEXT)' unless $val =~ /(?:\$\(EXEEXT\)$|^[@]\w+[@]$)/;
6682        return $val;
6683      });
6684 }
6685
6686
6687 # @PREFIX
6688 # &am_primary_prefixes ($PRIMARY, $CAN_DIST, @PREFIXES)
6689 # -----------------------------------------------------
6690 # Find all variable prefixes that are used for install directories.  A
6691 # prefix `zar' qualifies iff:
6692 #
6693 # * `zardir' is a variable.
6694 # * `zar_PRIMARY' is a variable.
6695 #
6696 # As a side effect, it looks for misspellings.  It is an error to have
6697 # a variable ending in a "reserved" suffix whose prefix is unknown, e.g.
6698 # "bin_PROGRAMS".  However, unusual prefixes are allowed if a variable
6699 # of the same name (with "dir" appended) exists.  For instance, if the
6700 # variable "zardir" is defined, then "zar_PROGRAMS" becomes valid.
6701 # This is to provide a little extra flexibility in those cases which
6702 # need it.
6703 sub am_primary_prefixes ($$@)
6704 {
6705   my ($primary, $can_dist, @prefixes) = @_;
6706
6707   local $_;
6708   my %valid = map { $_ => 0 } @prefixes;
6709   $valid{'EXTRA'} = 0;
6710   foreach my $var (variables $primary)
6711     {
6712       # Automake is allowed to define variables that look like primaries
6713       # but which aren't.  E.g. INSTALL_sh_DATA.
6714       # Autoconf can also define variables like INSTALL_DATA, so
6715       # ignore all configure variables (at least those which are not
6716       # redefined in Makefile.am).
6717       # FIXME: We should make sure that these variables are not
6718       # conditionally defined (or else adjust the condition below).
6719       my $def = $var->def (TRUE);
6720       next if $def && $def->owner != VAR_MAKEFILE;
6721
6722       my $varname = $var->name;
6723
6724       if ($varname =~ /^(nobase_)?(dist_|nodist_)?(.*)_[[:alnum:]]+$/)
6725         {
6726           my ($base, $dist, $X) = ($1 || '', $2 || '', $3 || '');
6727           if ($dist ne '' && ! $can_dist)
6728             {
6729               err_var ($var,
6730                        "invalid variable `$varname': `dist' is forbidden");
6731             }
6732           # Standard directories must be explicitly allowed.
6733           elsif (! defined $valid{$X} && exists $standard_prefix{$X})
6734             {
6735               err_var ($var,
6736                        "`${X}dir' is not a legitimate directory " .
6737                        "for `$primary'");
6738             }
6739           # A not explicitly valid directory is allowed if Xdir is defined.
6740           elsif (! defined $valid{$X} &&
6741                  $var->requires_variables ("`$varname' is used", "${X}dir"))
6742             {
6743               # Nothing to do.  Any error message has been output
6744               # by $var->requires_variables.
6745             }
6746           else
6747             {
6748               # Ensure all extended prefixes are actually used.
6749               $valid{"$base$dist$X"} = 1;
6750             }
6751         }
6752       else
6753         {
6754           prog_error "unexpected variable name: $varname";
6755         }
6756     }
6757
6758   # Return only those which are actually defined.
6759   return sort grep { var ($_ . '_' . $primary) } keys %valid;
6760 }
6761
6762
6763 # Handle `where_HOW' variable magic.  Does all lookups, generates
6764 # install code, and possibly generates code to define the primary
6765 # variable.  The first argument is the name of the .am file to munge,
6766 # the second argument is the primary variable (e.g. HEADERS), and all
6767 # subsequent arguments are possible installation locations.
6768 #
6769 # Returns list of [$location, $value] pairs, where
6770 # $value's are the values in all where_HOW variable, and $location
6771 # there associated location (the place here their parent variables were
6772 # defined).
6773 #
6774 # FIXME: this should be rewritten to be cleaner.  It should be broken
6775 # up into multiple functions.
6776 #
6777 # Usage is: am_install_var (OPTION..., file, HOW, where...)
6778 sub am_install_var
6779 {
6780   my (@args) = @_;
6781
6782   my $do_require = 1;
6783   my $can_dist = 0;
6784   my $default_dist = 0;
6785   while (@args)
6786     {
6787       if ($args[0] eq '-noextra')
6788         {
6789           $do_require = 0;
6790         }
6791       elsif ($args[0] eq '-candist')
6792         {
6793           $can_dist = 1;
6794         }
6795       elsif ($args[0] eq '-defaultdist')
6796         {
6797           $default_dist = 1;
6798           $can_dist = 1;
6799         }
6800       elsif ($args[0] !~ /^-/)
6801         {
6802           last;
6803         }
6804       shift (@args);
6805     }
6806
6807   my ($file, $primary, @prefix) = @args;
6808
6809   # Now that configure substitutions are allowed in where_HOW
6810   # variables, it is an error to actually define the primary.  We
6811   # allow `JAVA', as it is customarily used to mean the Java
6812   # interpreter.  This is but one of several Java hacks.  Similarly,
6813   # `PYTHON' is customarily used to mean the Python interpreter.
6814   reject_var $primary, "`$primary' is an anachronism"
6815     unless $primary eq 'JAVA' || $primary eq 'PYTHON';
6816
6817   # Get the prefixes which are valid and actually used.
6818   @prefix = am_primary_prefixes ($primary, $can_dist, @prefix);
6819
6820   # If a primary includes a configure substitution, then the EXTRA_
6821   # form is required.  Otherwise we can't properly do our job.
6822   my $require_extra;
6823
6824   my @used = ();
6825   my @result = ();
6826
6827   foreach my $X (@prefix)
6828     {
6829       my $nodir_name = $X;
6830       my $one_name = $X . '_' . $primary;
6831       my $one_var = var $one_name;
6832
6833       my $strip_subdir = 1;
6834       # If subdir prefix should be preserved, do so.
6835       if ($nodir_name =~ /^nobase_/)
6836         {
6837           $strip_subdir = 0;
6838           $nodir_name =~ s/^nobase_//;
6839         }
6840
6841       # If files should be distributed, do so.
6842       my $dist_p = 0;
6843       if ($can_dist)
6844         {
6845           $dist_p = (($default_dist && $nodir_name !~ /^nodist_/)
6846                      || (! $default_dist && $nodir_name =~ /^dist_/));
6847           $nodir_name =~ s/^(dist|nodist)_//;
6848         }
6849
6850
6851       # Use the location of the currently processed variable.
6852       # We are not processing a particular condition, so pick the first
6853       # available.
6854       my $tmpcond = $one_var->conditions->one_cond;
6855       my $where = $one_var->rdef ($tmpcond)->location->clone;
6856
6857       # Append actual contents of where_PRIMARY variable to
6858       # @result, skipping @substitutions@.
6859       foreach my $locvals ($one_var->value_as_list_recursive (location => 1))
6860         {
6861           my ($loc, $value) = @$locvals;
6862           # Skip configure substitutions.
6863           if ($value =~ /^\@.*\@$/)
6864             {
6865               if ($nodir_name eq 'EXTRA')
6866                 {
6867                   error ($where,
6868                          "`$one_name' contains configure substitution, "
6869                          . "but shouldn't");
6870                 }
6871               # Check here to make sure variables defined in
6872               # configure.ac do not imply that EXTRA_PRIMARY
6873               # must be defined.
6874               elsif (! defined $configure_vars{$one_name})
6875                 {
6876                   $require_extra = $one_name
6877                     if $do_require;
6878                 }
6879             }
6880           else
6881             {
6882               push (@result, $locvals);
6883             }
6884         }
6885       # A blatant hack: we rewrite each _PROGRAMS primary to include
6886       # EXEEXT.
6887       append_exeext ($one_name)
6888         if $primary eq 'PROGRAMS';
6889       # "EXTRA" shouldn't be used when generating clean targets,
6890       # all, or install targets.  We used to warn if EXTRA_FOO was
6891       # defined uselessly, but this was annoying.
6892       next
6893         if $nodir_name eq 'EXTRA';
6894
6895       if ($nodir_name eq 'check')
6896         {
6897           push (@check, '$(' . $one_name . ')');
6898         }
6899       else
6900         {
6901           push (@used, '$(' . $one_name . ')');
6902         }
6903
6904       # Is this to be installed?
6905       my $install_p = $nodir_name ne 'noinst' && $nodir_name ne 'check';
6906
6907       # If so, with install-exec? (or install-data?).
6908       my $exec_p = ($nodir_name =~ /$EXEC_DIR_PATTERN/o);
6909
6910       my $check_options_p = $install_p && !! option 'std-options';
6911
6912       # Use the location of the currently processed variable as context.
6913       $where->push_context ("while processing `$one_name'");
6914
6915       # The variable containing all file to distribute.
6916       my $distvar = "\$($one_name)";
6917       $distvar = shadow_unconditionally ($one_name, $where)
6918         if ($dist_p && $one_var->has_conditional_contents);
6919
6920       # Singular form of $PRIMARY.
6921       (my $one_primary = $primary) =~ s/S$//;
6922       $output_rules .= &file_contents ($file, $where,
6923                                        PRIMARY     => $primary,
6924                                        ONE_PRIMARY => $one_primary,
6925                                        DIR         => $X,
6926                                        NDIR        => $nodir_name,
6927                                        BASE        => $strip_subdir,
6928
6929                                        EXEC      => $exec_p,
6930                                        INSTALL   => $install_p,
6931                                        DIST      => $dist_p,
6932                                        DISTVAR   => $distvar,
6933                                        'CK-OPTS' => $check_options_p);
6934     }
6935
6936   # The JAVA variable is used as the name of the Java interpreter.
6937   # The PYTHON variable is used as the name of the Python interpreter.
6938   if (@used && $primary ne 'JAVA' && $primary ne 'PYTHON')
6939     {
6940       # Define it.
6941       define_pretty_variable ($primary, TRUE, INTERNAL, @used);
6942       $output_vars .= "\n";
6943     }
6944
6945   err_var ($require_extra,
6946            "`$require_extra' contains configure substitution,\n"
6947            . "but `EXTRA_$primary' not defined")
6948     if ($require_extra && ! var ('EXTRA_' . $primary));
6949
6950   # Push here because PRIMARY might be configure time determined.
6951   push (@all, '$(' . $primary . ')')
6952     if @used && $primary ne 'JAVA' && $primary ne 'PYTHON';
6953
6954   # Make the result unique.  This lets the user use conditionals in
6955   # a natural way, but still lets us program lazily -- we don't have
6956   # to worry about handling a particular object more than once.
6957   # We will keep only one location per object.
6958   my %result = ();
6959   for my $pair (@result)
6960     {
6961       my ($loc, $val) = @$pair;
6962       $result{$val} = $loc;
6963     }
6964   my @l = sort keys %result;
6965   return map { [$result{$_}->clone, $_] } @l;
6966 }
6967
6968
6969 ################################################################
6970
6971 # Each key in this hash is the name of a directory holding a
6972 # Makefile.in.  These variables are local to `is_make_dir'.
6973 my %make_dirs = ();
6974 my $make_dirs_set = 0;
6975
6976 sub is_make_dir
6977 {
6978     my ($dir) = @_;
6979     if (! $make_dirs_set)
6980     {
6981         foreach my $iter (@configure_input_files)
6982         {
6983             $make_dirs{dirname ($iter)} = 1;
6984         }
6985         # We also want to notice Makefile.in's.
6986         foreach my $iter (@other_input_files)
6987         {
6988             if ($iter =~ /Makefile\.in$/)
6989             {
6990                 $make_dirs{dirname ($iter)} = 1;
6991             }
6992         }
6993         $make_dirs_set = 1;
6994     }
6995     return defined $make_dirs{$dir};
6996 }
6997
6998 ################################################################
6999
7000 # Find the aux dir.  This should match the algorithm used by
7001 # ./configure. (See the Autoconf documentation for for
7002 # AC_CONFIG_AUX_DIR.)
7003 sub locate_aux_dir ()
7004 {
7005   if (! $config_aux_dir_set_in_configure_ac)
7006     {
7007       # The default auxiliary directory is the first
7008       # of ., .., or ../.. that contains install-sh.
7009       # Assume . if install-sh doesn't exist yet.
7010       for my $dir (qw (. .. ../..))
7011         {
7012           if (-f "$dir/install-sh")
7013             {
7014               $config_aux_dir = $dir;
7015               last;
7016             }
7017         }
7018       $config_aux_dir = '.' unless $config_aux_dir;
7019     }
7020   # Avoid unsightly '/.'s.
7021   $am_config_aux_dir =
7022     '$(top_srcdir)' . ($config_aux_dir eq '.' ? "" : "/$config_aux_dir");
7023   $am_config_aux_dir =~ s,/*$,,;
7024 }
7025
7026
7027 # &maybe_push_required_file ($DIR, $FILE, $FULLFILE)
7028 # --------------------------------------------------
7029 # See if we want to push this file onto dist_common.  This function
7030 # encodes the rules for deciding when to do so.
7031 sub maybe_push_required_file
7032 {
7033   my ($dir, $file, $fullfile) = @_;
7034
7035   if ($dir eq $relative_dir)
7036     {
7037       push_dist_common ($file);
7038       return 1;
7039     }
7040   elsif ($relative_dir eq '.' && ! &is_make_dir ($dir))
7041     {
7042       # If we are doing the topmost directory, and the file is in a
7043       # subdir which does not have a Makefile, then we distribute it
7044       # here.
7045
7046       # If a required file is above the source tree, it is important
7047       # to prefix it with `$(srcdir)' so that no VPATH search is
7048       # performed.  Otherwise problems occur with Make implementations
7049       # that rewrite and simplify rules whose dependencies are found in a
7050       # VPATH location.  Here is an example with OSF1/Tru64 Make.
7051       #
7052       #   % cat Makefile
7053       #   VPATH = sub
7054       #   distdir: ../a
7055       #           echo ../a
7056       #   % ls
7057       #   Makefile a
7058       #   % make
7059       #   echo a
7060       #   a
7061       #
7062       # Dependency `../a' was found in `sub/../a', but this make
7063       # implementation simplified it as `a'.  (Note that the sub/
7064       # directory does not even exist.)
7065       #
7066       # This kind of VPATH rewriting seems hard to cancel.  The
7067       # distdir.am hack against VPATH rewriting works only when no
7068       # simplification is done, i.e., for dependencies which are in
7069       # subdirectories, not in enclosing directories.  Hence, in
7070       # the latter case we use a full path to make sure no VPATH
7071       # search occurs.
7072       $fullfile = '$(srcdir)/' . $fullfile
7073         if $dir =~ m,^\.\.(?:$|/),;
7074
7075       push_dist_common ($fullfile);
7076       return 1;
7077     }
7078   return 0;
7079 }
7080
7081
7082 # If a file name appears as a key in this hash, then it has already
7083 # been checked for.  This allows us not to report the same error more
7084 # than once.
7085 my %required_file_not_found = ();
7086
7087 # &require_file_internal ($WHERE, $MYSTRICT, $DIRECTORY, @FILES)
7088 # --------------------------------------------------------------
7089 # Verify that the file must exist in $DIRECTORY, or install it.
7090 # $MYSTRICT is the strictness level at which this file becomes required.
7091 sub require_file_internal ($$$@)
7092 {
7093   my ($where, $mystrict, $dir, @files) = @_;
7094
7095   foreach my $file (@files)
7096     {
7097       my $fullfile = "$dir/$file";
7098       my $found_it = 0;
7099       my $dangling_sym = 0;
7100
7101       if (-l $fullfile && ! -f $fullfile)
7102         {
7103           $dangling_sym = 1;
7104         }
7105       elsif (dir_has_case_matching_file ($dir, $file))
7106         {
7107           $found_it = 1;
7108           maybe_push_required_file ($dir, $file, $fullfile);
7109         }
7110
7111       # `--force-missing' only has an effect if `--add-missing' is
7112       # specified.
7113       if ($found_it && (! $add_missing || ! $force_missing))
7114         {
7115           next;
7116         }
7117       else
7118         {
7119           # If we've already looked for it, we're done.  You might
7120           # wonder why we don't do this before searching for the
7121           # file.  If we do that, then something like
7122           # AC_OUTPUT(subdir/foo foo) will fail to put foo.in into
7123           # DIST_COMMON.
7124           if (! $found_it)
7125             {
7126               next if defined $required_file_not_found{$fullfile};
7127               $required_file_not_found{$fullfile} = 1;
7128             }
7129
7130           if ($strictness >= $mystrict)
7131             {
7132               if ($dangling_sym && $add_missing)
7133                 {
7134                   unlink ($fullfile);
7135                 }
7136
7137               my $trailer = '';
7138               my $suppress = 0;
7139
7140               # Only install missing files according to our desired
7141               # strictness level.
7142               my $message = "required file `$fullfile' not found";
7143               if ($add_missing)
7144                 {
7145                   if (-f "$libdir/$file")
7146                     {
7147                       $suppress = 1;
7148
7149                       # Install the missing file.  Symlink if we
7150                       # can, copy if we must.  Note: delete the file
7151                       # first, in case it is a dangling symlink.
7152                       $message = "installing `$fullfile'";
7153                       # Windows Perl will hang if we try to delete a
7154                       # file that doesn't exist.
7155                       unlink ($fullfile) if -f $fullfile;
7156                       if ($symlink_exists && ! $copy_missing)
7157                         {
7158                           if (! symlink ("$libdir/$file", $fullfile))
7159                             {
7160                               $suppress = 0;
7161                               $trailer = "; error while making link: $!";
7162                             }
7163                         }
7164                       elsif (system ('cp', "$libdir/$file", $fullfile))
7165                         {
7166                           $suppress = 0;
7167                           $trailer = "\n    error while copying";
7168                         }
7169                       reset_dir_cache ($dir);
7170                     }
7171
7172                   if (! maybe_push_required_file (dirname ($fullfile),
7173                                                   $file, $fullfile))
7174                     {
7175                       if (! $found_it && ! $automake_will_process_aux_dir)
7176                         {
7177                           # We have added the file but could not push it
7178                           # into DIST_COMMON, probably because this is
7179                           # an auxiliary file and we are not processing
7180                           # the top level Makefile.  Furthermore Automake
7181                           # hasn't been asked to create the Makefile.in
7182                           # that distribute the aux dir files.
7183                           error ($where, 'Please make a full run of automake'
7184                                  . " so $fullfile gets distributed.");
7185                         }
7186                     }
7187                 }
7188               else
7189                 {
7190                   $trailer = "\n  `automake --add-missing' can install `$file'"
7191                     if -f "$libdir/$file";
7192                 }
7193
7194               # If --force-missing was specified, and we have
7195               # actually found the file, then do nothing.
7196               next
7197                 if $found_it && $force_missing;
7198
7199               # If we couldn' install the file, but it is a target in
7200               # the Makefile, don't print anything.  This allows files
7201               # like README, AUTHORS, or THANKS to be generated.
7202               next
7203                 if !$suppress && rule $file;
7204
7205               msg ($suppress ? 'note' : 'error', $where, "$message$trailer");
7206             }
7207         }
7208     }
7209 }
7210
7211 # &require_file ($WHERE, $MYSTRICT, @FILES)
7212 # -----------------------------------------
7213 sub require_file ($$@)
7214 {
7215     my ($where, $mystrict, @files) = @_;
7216     require_file_internal ($where, $mystrict, $relative_dir, @files);
7217 }
7218
7219 # &require_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7220 # -----------------------------------------------------------
7221 sub require_file_with_macro ($$$@)
7222 {
7223     my ($cond, $macro, $mystrict, @files) = @_;
7224     $macro = rvar ($macro) unless ref $macro;
7225     require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7226 }
7227
7228 # &require_libsource_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7229 # ----------------------------------------------------------------
7230 # Require an AC_LIBSOURCEd file.  If AC_CONFIG_LIBOBJ_DIR was called, it
7231 # must be in that directory.  Otherwise expect it in the current directory.
7232 sub require_libsource_with_macro ($$$@)
7233 {
7234     my ($cond, $macro, $mystrict, @files) = @_;
7235     $macro = rvar ($macro) unless ref $macro;
7236     if ($config_libobj_dir)
7237       {
7238         require_file_internal ($macro->rdef ($cond)->location, $mystrict,
7239                                $config_libobj_dir, @files);
7240       }
7241     else
7242       {
7243         require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7244       }
7245 }
7246
7247 # &require_conf_file ($WHERE, $MYSTRICT, @FILES)
7248 # ----------------------------------------------
7249 # Looks in configuration path, as specified by AC_CONFIG_AUX_DIR.
7250 sub require_conf_file ($$@)
7251 {
7252     my ($where, $mystrict, @files) = @_;
7253     require_file_internal ($where, $mystrict, $config_aux_dir, @files);
7254 }
7255
7256
7257 # &require_conf_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7258 # ----------------------------------------------------------------
7259 sub require_conf_file_with_macro ($$$@)
7260 {
7261     my ($cond, $macro, $mystrict, @files) = @_;
7262     require_conf_file (rvar ($macro)->rdef ($cond)->location,
7263                        $mystrict, @files);
7264 }
7265
7266 ################################################################
7267
7268 # &require_build_directory ($DIRECTORY)
7269 # ------------------------------------
7270 # Emit rules to create $DIRECTORY if needed, and return
7271 # the file that any target requiring this directory should be made
7272 # dependent upon.
7273 # We don't want to emit the rule twice, and want to reuse it
7274 # for directories with equivalent names (e.g., `foo/bar' and `./foo//bar').
7275 sub require_build_directory ($)
7276 {
7277   my $directory = shift;
7278
7279   return $directory_map{$directory} if exists $directory_map{$directory};
7280
7281   my $cdir = File::Spec->canonpath ($directory);
7282
7283   if (exists $directory_map{$cdir})
7284     {
7285       my $stamp = $directory_map{$cdir};
7286       $directory_map{$directory} = $stamp;
7287       return $stamp;
7288     }
7289
7290   my $dirstamp = "$cdir/\$(am__dirstamp)";
7291
7292   $directory_map{$directory} = $dirstamp;
7293   $directory_map{$cdir} = $dirstamp;
7294
7295   # Set a variable for the dirstamp basename.
7296   define_pretty_variable ('am__dirstamp', TRUE, INTERNAL,
7297                           '$(am__leading_dot)dirstamp');
7298
7299   # Directory must be removed by `make distclean'.
7300   $clean_files{$dirstamp} = DIST_CLEAN;
7301
7302   $output_rules .= ("$dirstamp:\n"
7303                     . "\t\@\$(mkdir_p) $directory\n"
7304                     . "\t\@: > $dirstamp\n");
7305
7306   return $dirstamp;
7307 }
7308
7309 # &require_build_directory_maybe ($FILE)
7310 # --------------------------------------
7311 # If $FILE lies in a subdirectory, emit a rule to create this
7312 # directory and return the file that $FILE should be made
7313 # dependent upon.  Otherwise, just return the empty string.
7314 sub require_build_directory_maybe ($)
7315 {
7316     my $file = shift;
7317     my $directory = dirname ($file);
7318
7319     if ($directory ne '.')
7320     {
7321         return require_build_directory ($directory);
7322     }
7323     else
7324     {
7325         return '';
7326     }
7327 }
7328
7329 ################################################################
7330
7331 # Push a list of files onto dist_common.
7332 sub push_dist_common
7333 {
7334   prog_error "push_dist_common run after handle_dist"
7335     if $handle_dist_run;
7336   Automake::Variable::define ('DIST_COMMON', VAR_AUTOMAKE, '+', TRUE, "@_",
7337                               '', INTERNAL, VAR_PRETTY);
7338 }
7339
7340
7341 ################################################################
7342
7343 # generate_makefile ($MAKEFILE_AM, $MAKEFILE_IN)
7344 # ----------------------------------------------
7345 # Generate a Makefile.in given the name of the corresponding Makefile and
7346 # the name of the file output by config.status.
7347 sub generate_makefile ($$)
7348 {
7349   my ($makefile_am, $makefile_in) = @_;
7350
7351   # Reset all the Makefile.am related variables.
7352   initialize_per_input;
7353
7354   # AUTOMAKE_OPTIONS can contains -W flags to disable or enable
7355   # warnings for this file.  So hold any warning issued before
7356   # we have processed AUTOMAKE_OPTIONS.
7357   buffer_messages ('warning');
7358
7359   # Name of input file ("Makefile.am") and output file
7360   # ("Makefile.in").  These have no directory components.
7361   $am_file_name = basename ($makefile_am);
7362   $in_file_name = basename ($makefile_in);
7363
7364   # $OUTPUT is encoded.  If it contains a ":" then the first element
7365   # is the real output file, and all remaining elements are input
7366   # files.  We don't scan or otherwise deal with these input files,
7367   # other than to mark them as dependencies.  See
7368   # &scan_autoconf_files for details.
7369   my ($makefile, @inputs) = split (/:/, $output_files{$makefile_in});
7370
7371   $relative_dir = dirname ($makefile);
7372   $am_relative_dir = dirname ($makefile_am);
7373
7374   read_main_am_file ($makefile_am);
7375   if (handle_options)
7376     {
7377       # Process buffered warnings.
7378       flush_messages;
7379       # Fatal error.  Just return, so we can continue with next file.
7380       return;
7381     }
7382   # Process buffered warnings.
7383   flush_messages;
7384
7385   # There are a few install-related variables that you should not define.
7386   foreach my $var ('PRE_INSTALL', 'POST_INSTALL', 'NORMAL_INSTALL')
7387     {
7388       my $v = var $var;
7389       if ($v)
7390         {
7391           my $def = $v->def (TRUE);
7392           prog_error "$var not defined in condition TRUE"
7393             unless $def;
7394           reject_var $var, "`$var' should not be defined"
7395             if $def->owner != VAR_AUTOMAKE;
7396         }
7397     }
7398
7399   # Catch some obsolete variables.
7400   msg_var ('obsolete', 'INCLUDES',
7401            "`INCLUDES' is the old name for `AM_CPPFLAGS' (or `*_CPPFLAGS')")
7402     if var ('INCLUDES');
7403
7404   # Must do this after reading .am file.
7405   define_variable ('subdir', $relative_dir, INTERNAL);
7406
7407   # If DIST_SUBDIRS is defined, make sure SUBDIRS is, so that
7408   # recursive rules are enabled.
7409   define_pretty_variable ('SUBDIRS', TRUE, INTERNAL, '')
7410     if var 'DIST_SUBDIRS' && ! var 'SUBDIRS';
7411
7412   # Check first, because we might modify some state.
7413   check_cygnus;
7414   check_gnu_standards;
7415   check_gnits_standards;
7416
7417   handle_configure ($makefile_am, $makefile_in, $makefile, @inputs);
7418   handle_gettext;
7419   handle_libraries;
7420   handle_ltlibraries;
7421   handle_programs;
7422   handle_scripts;
7423
7424   # These must be run after all the sources are scanned.  They
7425   # use variables defined by &handle_libraries, &handle_ltlibraries,
7426   # or &handle_programs.
7427   handle_compile;
7428   handle_languages;
7429   handle_libtool;
7430
7431   # Variables used by distdir.am and tags.am.
7432   define_pretty_variable ('SOURCES', TRUE, INTERNAL, @sources);
7433   if (! option 'no-dist')
7434     {
7435       define_pretty_variable ('DIST_SOURCES', TRUE, INTERNAL, @dist_sources);
7436     }
7437
7438   handle_multilib;
7439   handle_texinfo;
7440   handle_emacs_lisp;
7441   handle_python;
7442   handle_java;
7443   handle_man_pages;
7444   handle_data;
7445   handle_headers;
7446   handle_subdirs;
7447   handle_tags;
7448   handle_minor_options;
7449   handle_tests;
7450
7451   # This must come after most other rules.
7452   handle_dist;
7453
7454   handle_footer;
7455   do_check_merge_target;
7456   handle_all ($makefile);
7457
7458   # FIXME: Gross!
7459   if (var ('lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
7460     {
7461       $output_rules .= "install-binPROGRAMS: install-libLTLIBRARIES\n\n";
7462     }
7463
7464   handle_install;
7465   handle_clean ($makefile);
7466   handle_factored_dependencies;
7467
7468   # Comes last, because all the above procedures may have
7469   # defined or overridden variables.
7470   $output_vars .= output_variables;
7471
7472   check_typos;
7473
7474   my ($out_file) = $output_directory . '/' . $makefile_in;
7475
7476   if ($exit_code != 0)
7477     {
7478       verb "not writing $out_file because of earlier errors";
7479       return;
7480     }
7481
7482   if (! -d ($output_directory . '/' . $am_relative_dir))
7483     {
7484       mkdir ($output_directory . '/' . $am_relative_dir, 0755);
7485     }
7486
7487   # We make sure that `all:' is the first target.
7488   my $output =
7489     "$output_vars$output_all$output_header$output_rules$output_trailer";
7490
7491   # Decide whether we must update the output file or not.
7492   # We have to update in the following situations.
7493   #  * $force_generation is set.
7494   #  * any of the output dependencies is younger than the output
7495   #  * the contents of the output is different (this can happen
7496   #    if the project has been populated with a file listed in
7497   #    @common_files since the last run).
7498   # Output's dependencies are split in two sets:
7499   #  * dependencies which are also configure dependencies
7500   #    These do not change between each Makefile.am
7501   #  * other dependencies, specific to the Makefile.am being processed
7502   #    (such as the Makefile.am itself, or any Makefile fragment
7503   #    it includes).
7504   my $timestamp = mtime $out_file;
7505   if (! $force_generation
7506       && $configure_deps_greatest_timestamp < $timestamp
7507       && $output_deps_greatest_timestamp < $timestamp
7508       && $output eq contents ($out_file))
7509     {
7510       verb "$out_file unchanged";
7511       # No need to update.
7512       return;
7513     }
7514
7515   if (-e $out_file)
7516     {
7517       unlink ($out_file)
7518         or fatal "cannot remove $out_file: $!\n";
7519     }
7520
7521   my $gm_file = new Automake::XFile "> $out_file";
7522   verb "creating $out_file";
7523   print $gm_file $output;
7524 }
7525
7526 ################################################################
7527
7528
7529
7530
7531 ################################################################
7532
7533 # Print usage information.
7534 sub usage ()
7535 {
7536     print "Usage: $0 [OPTION] ... [Makefile]...
7537
7538 Generate Makefile.in for configure from Makefile.am.
7539
7540 Operation modes:
7541       --help               print this help, then exit
7542       --version            print version number, then exit
7543   -v, --verbose            verbosely list files processed
7544       --no-force           only update Makefile.in's that are out of date
7545   -W, --warnings=CATEGORY  report the warnings falling in CATEGORY
7546
7547 Dependency tracking:
7548   -i, --ignore-deps      disable dependency tracking code
7549       --include-deps     enable dependency tracking code
7550
7551 Flavors:
7552       --cygnus           assume program is part of Cygnus-style tree
7553       --foreign          set strictness to foreign
7554       --gnits            set strictness to gnits
7555       --gnu              set strictness to gnu
7556
7557 Library files:
7558   -a, --add-missing      add missing standard files to package
7559       --libdir=DIR       directory storing library files
7560   -c, --copy             with -a, copy missing files (default is symlink)
7561   -f, --force-missing    force update of standard files
7562
7563 ";
7564     Automake::ChannelDefs::usage;
7565
7566     my ($last, @lcomm);
7567     $last = '';
7568     foreach my $iter (sort ((@common_files, @common_sometimes)))
7569     {
7570         push (@lcomm, $iter) unless $iter eq $last;
7571         $last = $iter;
7572     }
7573
7574     my @four;
7575     print "\nFiles which are automatically distributed, if found:\n";
7576     format USAGE_FORMAT =
7577   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<
7578   $four[0],           $four[1],           $four[2],           $four[3]
7579 .
7580     $~ = "USAGE_FORMAT";
7581
7582     my $cols = 4;
7583     my $rows = int(@lcomm / $cols);
7584     my $rest = @lcomm % $cols;
7585
7586     if ($rest)
7587     {
7588         $rows++;
7589     }
7590     else
7591     {
7592         $rest = $cols;
7593     }
7594
7595     for (my $y = 0; $y < $rows; $y++)
7596     {
7597         @four = ("", "", "", "");
7598         for (my $x = 0; $x < $cols; $x++)
7599         {
7600             last if $y + 1 == $rows && $x == $rest;
7601
7602             my $idx = (($x > $rest)
7603                        ?  ($rows * $rest + ($rows - 1) * ($x - $rest))
7604                        : ($rows * $x));
7605
7606             $idx += $y;
7607             $four[$x] = $lcomm[$idx];
7608         }
7609         write;
7610     }
7611
7612     print "\nReport bugs to <bug-automake\@gnu.org>.\n";
7613
7614     # --help always returns 0 per GNU standards.
7615     exit 0;
7616 }
7617
7618
7619 # &version ()
7620 # -----------
7621 # Print version information
7622 sub version ()
7623 {
7624   print <<EOF;
7625 automake (GNU $PACKAGE) $VERSION
7626 Written by Tom Tromey <tromey\@redhat.com>
7627        and Alexandre Duret-Lutz <adl\@gnu.org>.
7628
7629 Copyright 2005 Free Software Foundation, Inc.
7630 This is free software; see the source for copying conditions.  There is NO
7631 warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
7632 EOF
7633   # --version always returns 0 per GNU standards.
7634   exit 0;
7635 }
7636
7637 ################################################################
7638
7639 # Parse command line.
7640 sub parse_arguments ()
7641 {
7642   # Start off as gnu.
7643   set_strictness ('gnu');
7644
7645   my $cli_where = new Automake::Location;
7646   my %cli_options =
7647     (
7648      'libdir=s'         => \$libdir,
7649      'gnu'              => sub { set_strictness ('gnu'); },
7650      'gnits'            => sub { set_strictness ('gnits'); },
7651      'cygnus'           => sub { set_global_option ('cygnus', $cli_where); },
7652      'foreign'          => sub { set_strictness ('foreign'); },
7653      'include-deps'     => sub { unset_global_option ('no-dependencies'); },
7654      'i|ignore-deps'    => sub { set_global_option ('no-dependencies',
7655                                                     $cli_where); },
7656      'no-force'         => sub { $force_generation = 0; },
7657      'f|force-missing'  => \$force_missing,
7658      'o|output-dir=s'   => \$output_directory,
7659      'a|add-missing'    => \$add_missing,
7660      'c|copy'           => \$copy_missing,
7661      'v|verbose'        => sub { setup_channel 'verb', silent => 0; },
7662      'W|warnings=s'     => \&parse_warnings,
7663      # These long options (--Werror and --Wno-error) for backward
7664      # compatibility.  Use -Werror and -Wno-error today.
7665      'Werror'           => sub { parse_warnings 'W', 'error'; },
7666      'Wno-error'        => sub { parse_warnings 'W', 'no-error'; },
7667      );
7668   use Getopt::Long;
7669   Getopt::Long::config ("bundling", "pass_through");
7670
7671   # See if --version or --help is used.  We want to process these before
7672   # anything else because the GNU Coding Standards require us to
7673   # `exit 0' after processing these options, and we can't guarantee this
7674   # if we treat other options first.  (Handling other options first
7675   # could produce error diagnostics, and in this condition it is
7676   # confusing if Automake does `exit 0'.)
7677   my %cli_options_1st_pass =
7678     (
7679      'version' => \&version,
7680      'help'    => \&usage,
7681      # Recognize all other options (and their arguments) but do nothing.
7682      map { $_ => sub {} } (keys %cli_options)
7683      );
7684   my @ARGV_backup = @ARGV;
7685   Getopt::Long::GetOptions %cli_options_1st_pass
7686     or exit 1;
7687   @ARGV = @ARGV_backup;
7688
7689   # Now *really* process the options.  This time we know that --help
7690   # and --version are not present, but we specify them nonetheless so
7691   # that ambiguous abbreviation are diagnosed.
7692   Getopt::Long::GetOptions %cli_options, 'version' => sub {}, 'help' => sub {}
7693     or exit 1;
7694
7695   if (defined $output_directory)
7696     {
7697       msg 'obsolete', "`--output-dir' is deprecated\n";
7698     }
7699   else
7700     {
7701       # In the next release we'll remove this entirely.
7702       $output_directory = '.';
7703     }
7704
7705   return unless @ARGV;
7706
7707   if ($ARGV[0] =~ /^-./)
7708     {
7709       my %argopts;
7710       for my $k (keys %cli_options)
7711         {
7712           if ($k =~ /(.*)=s$/)
7713             {
7714               map { $argopts{(length ($_) == 1)
7715                              ? "-$_" : "--$_" } = 1; } (split (/\|/, $1));
7716             }
7717         }
7718       if ($ARGV[0] eq '--')
7719         {
7720           shift @ARGV;
7721         }
7722       elsif (exists $argopts{$ARGV[0]})
7723         {
7724           fatal ("option `$ARGV[0]' requires an argument\n"
7725                  . "Try `$0 --help' for more information.");
7726         }
7727       else
7728         {
7729           fatal ("unrecognized option `$ARGV[0]'.\n"
7730                  . "Try `$0 --help' for more information.");
7731         }
7732     }
7733
7734   my $errspec = 0;
7735   foreach my $arg (@ARGV)
7736     {
7737       fatal ("empty argument\nTry `$0 --help' for more information.")
7738         if ($arg eq '');
7739
7740       # Handle $local:$input syntax.
7741       my ($local, @rest) = split (/:/, $arg);
7742       @rest = ("$local.in",) unless @rest;
7743       my $input = locate_am @rest;
7744       if ($input)
7745         {
7746           push @input_files, $input;
7747           $output_files{$input} = join (':', ($local, @rest));
7748         }
7749       else
7750         {
7751           error "no Automake input file found for `$arg'";
7752           $errspec = 1;
7753         }
7754     }
7755   fatal "no input file found among supplied arguments"
7756     if $errspec && ! @input_files;
7757 }
7758
7759 ################################################################
7760
7761 # Parse the WARNINGS environment variable.
7762 parse_WARNINGS;
7763
7764 # Parse command line.
7765 parse_arguments;
7766
7767 $configure_ac = require_configure_ac;
7768
7769 # Do configure.ac scan only once.
7770 scan_autoconf_files;
7771
7772 if (! @input_files)
7773   {
7774     my $msg = '';
7775     $msg = "\nDid you forget AC_CONFIG_FILES([Makefile]) in $configure_ac?"
7776       if -f 'Makefile.am';
7777     fatal ("no `Makefile.am' found for any configure output$msg");
7778   }
7779
7780 # Now do all the work on each file.
7781 foreach my $file (@input_files)
7782   {
7783     ($am_file = $file) =~ s/\.in$//;
7784     if (! -f ($am_file . '.am'))
7785       {
7786         error "`$am_file.am' does not exist";
7787       }
7788     else
7789       {
7790         # Any warning setting now local to this Makefile.am.
7791         dup_channel_setup;
7792
7793         generate_makefile ($am_file . '.am', $file);
7794
7795         # Back out any warning setting.
7796         drop_channel_setup;
7797       }
7798   }
7799
7800 exit $exit_code;
7801
7802
7803 ### Setup "GNU" style for perl-mode and cperl-mode.
7804 ## Local Variables:
7805 ## perl-indent-level: 2
7806 ## perl-continued-statement-offset: 2
7807 ## perl-continued-brace-offset: 0
7808 ## perl-brace-offset: 0
7809 ## perl-brace-imaginary-offset: 0
7810 ## perl-label-offset: -2
7811 ## cperl-indent-level: 2
7812 ## cperl-brace-offset: 0
7813 ## cperl-continued-brace-offset: 0
7814 ## cperl-label-offset: -2
7815 ## cperl-extra-newline-before-brace: t
7816 ## cperl-merge-trailing-else: nil
7817 ## cperl-continued-statement-offset: 2
7818 ## End: