automake.in

   1 #!@PERL@ -w
   2 # -*- perl -*-
   3 # @configure_input@
   4
   5 eval 'case $# in 0) exec @PERL@ -S "$0";; *) exec @PERL@ -S "$0" "$@";; esac'
   6     if 0;
   7
   8 # automake - create Makefile.in from Makefile.am
   9 # Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
  10 # 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012 Free
  11 # Software Foundation, Inc.
  12
  13 # This program is free software; you can redistribute it and/or modify
  14 # it under the terms of the GNU General Public License as published by
  15 # the Free Software Foundation; either version 2, or (at your option)
  16 # any later version.
  17
  18 # This program is distributed in the hope that it will be useful,
  19 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 # GNU General Public License for more details.
  22
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 # Originally written by David Mackenzie <djm@gnu.ai.mit.edu>.
  27 # Perl reimplementation by Tom Tromey <tromey@redhat.com>, and
  28 # Alexandre Duret-Lutz <adl@gnu.org>.
  29
  30 package Language;
  31
  32 BEGIN
  33 {
  34   my $perllibdir = $ENV{'perllibdir'} || '@datadir@/@PACKAGE@-@APIVERSION@';
  35   unshift @INC, (split '@PATH_SEPARATOR@', $perllibdir);
  36
  37   # Override SHELL.  This is required on DJGPP so that system() uses
  38   # bash, not COMMAND.COM which doesn't quote arguments properly.
  39   # Other systems aren't expected to use $SHELL when Automake
  40   # runs, but it should be safe to drop the `if DJGPP' guard if
  41   # it turns up other systems need the same thing.  After all,
  42   # if SHELL is used, ./configure's SHELL is always better than
  43   # the user's SHELL (which may be something like tcsh).
  44   $ENV{'SHELL'} = '@SHELL@' if exists $ENV{'DJDIR'};
  45 }
  46
  47 use Automake::Struct;
  48 struct (# Short name of the language (c, f77...).
  49         'name' => "\$",
  50         # Nice name of the language (C, Fortran 77...).
  51         'Name' => "\$",
  52
  53         # List of configure variables which must be defined.
  54         'config_vars' => '@',
  55
  56         # `pure' is `1' or `'.  A `pure' language is one where, if
  57         # all the files in a directory are of that language, then we
  58         # do not require the C compiler or any code to call it.
  59         'pure'   => "\$",
  60
  61         'autodep' => "\$",
  62
  63         # Name of the compiling variable (COMPILE).
  64         'compiler'  => "\$",
  65         # Content of the compiling variable.
  66         'compile'  => "\$",
  67         # Flag to require compilation without linking (-c).
  68         'compile_flag' => "\$",
  69         'extensions' => '@',
  70         # A subroutine to compute a list of possible extensions of
  71         # the product given the input extensions.
  72         # (defaults to a subroutine which returns ('.$(OBJEXT)', '.lo'))
  73         'output_extensions' => "\$",
  74         # A list of flag variables used in 'compile'.
  75         # (defaults to [])
  76         'flags' => "@",
  77
  78         # Any tag to pass to libtool while compiling.
  79         'libtool_tag' => "\$",
  80
  81         # The file to use when generating rules for this language.
  82         # The default is 'depend2'.
  83         'rule_file' => "\$",
  84
  85         # Name of the linking variable (LINK).
  86         'linker' => "\$",
  87         # Content of the linking variable.
  88         'link' => "\$",
  89
  90         # Name of the compiler variable (CC).
  91         'ccer' => "\$",
  92
  93         # Name of the linker variable (LD).
  94         'lder' => "\$",
  95         # Content of the linker variable ($(CC)).
  96         'ld' => "\$",
  97
  98         # Flag to specify the output file (-o).
  99         'output_flag' => "\$",
 100         '_finish' => "\$",
 101
 102         # This is a subroutine which is called whenever we finally
 103         # determine the context in which a source file will be
 104         # compiled.
 105         '_target_hook' => "\$",
 106
 107         # If TRUE, nodist_ sources will be compiled using specific rules
 108         # (i.e. not inference rules).  The default is FALSE.
 109         'nodist_specific' => "\$");
 110
 111
 112 sub finish ($)
 113 {
 114   my ($self) = @_;
 115   if (defined $self->_finish)
 116     {
 117       &{$self->_finish} (@_);
 118     }
 119 }
 120
 121 sub target_hook ($$$$%)
 122 {
 123     my ($self) = @_;
 124     if (defined $self->_target_hook)
 125     {
 126         &{$self->_target_hook} (@_);
 127     }
 128 }
 129
 130 package Automake;
 131
 132 use strict;
 133 use Automake::Config;
 134 BEGIN
 135 {
 136   if ($perl_threads)
 137     {
 138       require threads;
 139       import threads;
 140       require Thread::Queue;
 141       import Thread::Queue;
 142     }
 143 }
 144 use Automake::General;
 145 use Automake::XFile;
 146 use Automake::Channels;
 147 use Automake::ChannelDefs;
 148 use Automake::Configure_ac;
 149 use Automake::FileUtils;
 150 use Automake::Location;
 151 use Automake::Condition qw/TRUE FALSE/;
 152 use Automake::DisjConditions;
 153 use Automake::Options;
 154 use Automake::Version;
 155 use Automake::Variable;
 156 use Automake::VarDef;
 157 use Automake::Rule;
 158 use Automake::RuleDef;
 159 use Automake::Wrap 'makefile_wrap';
 160 use File::Basename;
 161 use File::Spec;
 162 use Carp;
 163
 164 ## ----------- ##
 165 ## Constants.  ##
 166 ## ----------- ##
 167
 168 # Some regular expressions.  One reason to put them here is that it
 169 # makes indentation work better in Emacs.
 170
 171 # Writing singled-quoted-$-terminated regexes is a pain because
 172 # perl-mode thinks of $' as the ${'} variable (instead of a $ followed
 173 # by a closing quote.  Letting perl-mode think the quote is not closed
 174 # leads to all sort of misindentations.  On the other hand, defining
 175 # regexes as double-quoted strings is far less readable.  So usually
 176 # we will write:
 177 #
 178 #  $REGEX = '^regex_value' . "\$";
 179
 180 my $IGNORE_PATTERN = '^\s*##([^#\n].*)?\n';
 181 my $WHITE_PATTERN = '^\s*' . "\$";
 182 my $COMMENT_PATTERN = '^#';
 183 my $TARGET_PATTERN='[$a-zA-Z0-9_.@%][-.a-zA-Z0-9_(){}/$+@%]*';
 184 # A rule has three parts: a list of targets, a list of dependencies,
 185 # and optionally actions.
 186 my $RULE_PATTERN =
 187   "^($TARGET_PATTERN(?:(?:\\\\\n|\\s)+$TARGET_PATTERN)*) *:([^=].*|)\$";
 188
 189 # Only recognize leading spaces, not leading tabs.  If we recognize
 190 # leading tabs here then we need to make the reader smarter, because
 191 # otherwise it will think rules like `foo=bar; \' are errors.
 192 my $ASSIGNMENT_PATTERN = '^ *([^ \t=:+]*)\s*([:+]?)=\s*(.*)' . "\$";
 193 # This pattern recognizes a Gnits version id and sets $1 if the
 194 # release is an alpha release.  We also allow a suffix which can be
 195 # used to extend the version number with a "fork" identifier.
 196 my $GNITS_VERSION_PATTERN = '\d+\.\d+([a-z]|\.\d+)?(-[A-Za-z0-9]+)?';
 197
 198 my $IF_PATTERN = '^if\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*)\s*(?:#.*)?' . "\$";
 199 my $ELSE_PATTERN =
 200   '^else(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 201 my $ENDIF_PATTERN =
 202   '^endif(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 203 my $PATH_PATTERN = '(\w|[+/.-])+';
 204 # This will pass through anything not of the prescribed form.
 205 my $INCLUDE_PATTERN = ('^include\s+'
 206                        . '((\$\(top_srcdir\)/' . $PATH_PATTERN . ')'
 207                        . '|(\$\(srcdir\)/' . $PATH_PATTERN . ')'
 208                        . '|([^/\$]' . $PATH_PATTERN . '))\s*(#.*)?' . "\$");
 209
 210 # Directories installed during 'install-exec' phase.
 211 my $EXEC_DIR_PATTERN =
 212   '^(?:bin|sbin|libexec|sysconf|localstate|lib|pkglib|.*exec.*)' . "\$";
 213
 214 # Values for AC_CANONICAL_*
 215 use constant AC_CANONICAL_BUILD  => 1;
 216 use constant AC_CANONICAL_HOST   => 2;
 217 use constant AC_CANONICAL_TARGET => 3;
 218
 219 # Values indicating when something should be cleaned.
 220 use constant MOSTLY_CLEAN     => 0;
 221 use constant CLEAN            => 1;
 222 use constant DIST_CLEAN       => 2;
 223 use constant MAINTAINER_CLEAN => 3;
 224
 225 # Libtool files.
 226 my @libtool_files = qw(ltmain.sh config.guess config.sub);
 227 # ltconfig appears here for compatibility with old versions of libtool.
 228 my @libtool_sometimes = qw(ltconfig ltcf-c.sh ltcf-cxx.sh ltcf-gcj.sh);
 229
 230 # Commonly found files we look for and automatically include in
 231 # DISTFILES.
 232 my @common_files =
 233     (qw(ABOUT-GNU ABOUT-NLS AUTHORS BACKLOG COPYING COPYING.DOC COPYING.LIB
 234         COPYING.LESSER ChangeLog INSTALL NEWS README THANKS TODO
 235         ar-lib compile config.guess config.rpath
 236         config.sub depcomp elisp-comp install-sh libversion.in mdate-sh
 237         missing mkinstalldirs py-compile texinfo.tex ylwrap),
 238      @libtool_files, @libtool_sometimes);
 239
 240 # Commonly used files we auto-include, but only sometimes.  This list
 241 # is used for the --help output only.
 242 my @common_sometimes =
 243   qw(aclocal.m4 acconfig.h config.h.top config.h.bot configure
 244      configure.ac configure.in stamp-vti);
 245
 246 # Standard directories from the GNU Coding Standards, and additional
 247 # pkg* directories from Automake.  Stored in a hash for fast member check.
 248 my %standard_prefix =
 249     map { $_ => 1 } (qw(bin data dataroot doc dvi exec html include info
 250                         lib libexec lisp locale localstate man man1 man2
 251                         man3 man4 man5 man6 man7 man8 man9 oldinclude pdf
 252                         pkgdata pkginclude pkglib pkglibexec ps sbin
 253                         sharedstate sysconf));
 254
 255 # Copyright on generated Makefile.ins.
 256 my $gen_copyright = "\
 257 # Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
 258 # 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011 Free Software
 259 # Foundation, Inc.
 260 # This Makefile.in is free software; the Free Software Foundation
 261 # gives unlimited permission to copy and/or distribute it,
 262 # with or without modifications, as long as this notice is preserved.
 263
 264 # This program is distributed in the hope that it will be useful,
 265 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
 266 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 267 # PARTICULAR PURPOSE.
 268 ";
 269
 270 # These constants are returned by the lang_*_rewrite functions.
 271 # LANG_SUBDIR means that the resulting object file should be in a
 272 # subdir if the source file is.  In this case the file name cannot
 273 # have `..' components.
 274 use constant LANG_IGNORE  => 0;
 275 use constant LANG_PROCESS => 1;
 276 use constant LANG_SUBDIR  => 2;
 277
 278 # These are used when keeping track of whether an object can be built
 279 # by two different paths.
 280 use constant COMPILE_LIBTOOL  => 1;
 281 use constant COMPILE_ORDINARY => 2;
 282
 283 # We can't always associate a location to a variable or a rule,
 284 # when it's defined by Automake.  We use INTERNAL in this case.
 285 use constant INTERNAL => new Automake::Location;
 286
 287 # Serialization keys for message queues.
 288 use constant QUEUE_MESSAGE   => "msg";
 289 use constant QUEUE_CONF_FILE => "conf file";
 290 use constant QUEUE_LOCATION  => "location";
 291 use constant QUEUE_STRING    => "string";
 292 \f
 293
 294 ## ---------------------------------- ##
 295 ## Variables related to the options.  ##
 296 ## ---------------------------------- ##
 297
 298 # TRUE if we should always generate Makefile.in.
 299 my $force_generation = 1;
 300
 301 # From the Perl manual.
 302 my $symlink_exists = (eval 'symlink ("", "");', $@ eq '');
 303
 304 # TRUE if missing standard files should be installed.
 305 my $add_missing = 0;
 306
 307 # TRUE if we should copy missing files; otherwise symlink if possible.
 308 my $copy_missing = 0;
 309
 310 # TRUE if we should always update files that we know about.
 311 my $force_missing = 0;
 312
 313
 314 ## ---------------------------------------- ##
 315 ## Variables filled during files scanning.  ##
 316 ## ---------------------------------------- ##
 317
 318 # Name of the configure.ac file.
 319 my $configure_ac;
 320
 321 # Files found by scanning configure.ac for LIBOBJS.
 322 my %libsources = ();
 323
 324 # Names used in AC_CONFIG_HEADER call.
 325 my @config_headers = ();
 326
 327 # Names used in AC_CONFIG_LINKS call.
 328 my @config_links = ();
 329
 330 # List of Makefile.am's to process, and their corresponding outputs.
 331 my @input_files = ();
 332 my %output_files = ();
 333
 334 # Complete list of Makefile.am's that exist.
 335 my @configure_input_files = ();
 336
 337 # List of files in AC_CONFIG_FILES/AC_OUTPUT without Makefile.am's,
 338 # and their outputs.
 339 my @other_input_files = ();
 340 # Where each AC_CONFIG_FILES/AC_OUTPUT/AC_CONFIG_LINK/AC_CONFIG_HEADER appears.
 341 # The keys are the files created by these macros.
 342 my %ac_config_files_location = ();
 343 # The condition under which AC_CONFIG_FOOS appears.
 344 my %ac_config_files_condition = ();
 345
 346 # Directory to search for configure-required files.  This
 347 # will be computed by &locate_aux_dir and can be set using
 348 # AC_CONFIG_AUX_DIR in configure.ac.
 349 # $CONFIG_AUX_DIR is the `raw' directory, valid only in the source-tree.
 350 my $config_aux_dir = '';
 351 my $config_aux_dir_set_in_configure_ac = 0;
 352 # $AM_CONFIG_AUX_DIR is prefixed with $(top_srcdir), so it can be used
 353 # in Makefiles.
 354 my $am_config_aux_dir = '';
 355
 356 # Directory to search for AC_LIBSOURCE files, as set by AC_CONFIG_LIBOBJ_DIR
 357 # in configure.ac.
 358 my $config_libobj_dir = '';
 359
 360 # Whether AM_GNU_GETTEXT has been seen in configure.ac.
 361 my $seen_gettext = 0;
 362 # Whether AM_GNU_GETTEXT([external]) is used.
 363 my $seen_gettext_external = 0;
 364 # Where AM_GNU_GETTEXT appears.
 365 my $ac_gettext_location;
 366 # Whether AM_GNU_GETTEXT_INTL_SUBDIR has been seen.
 367 my $seen_gettext_intl = 0;
 368
 369 # Lists of tags supported by Libtool.
 370 my %libtool_tags = ();
 371 # 1 if Libtool uses LT_SUPPORTED_TAG.  If it does, then it also
 372 # uses AC_REQUIRE_AUX_FILE.
 373 my $libtool_new_api = 0;
 374
 375 # Most important AC_CANONICAL_* macro seen so far.
 376 my $seen_canonical = 0;
 377 # Location of that macro.
 378 my $canonical_location;
 379
 380 # Where AM_MAINTAINER_MODE appears.
 381 my $seen_maint_mode;
 382
 383 # Actual version we've seen.
 384 my $package_version = '';
 385
 386 # Where version is defined.
 387 my $package_version_location;
 388
 389 # TRUE if we've seen AM_ENABLE_MULTILIB.
 390 my $seen_multilib = 0;
 391
 392 # TRUE if we've seen AM_PROG_AR
 393 my $seen_ar = 0;
 394
 395 # TRUE if we've seen AM_PROG_CC_C_O
 396 my $seen_cc_c_o = 0;
 397
 398 # Location of AC_REQUIRE_AUX_FILE calls, indexed by their argument.
 399 my %required_aux_file = ();
 400
 401 # Where AM_INIT_AUTOMAKE is called;
 402 my $seen_init_automake = 0;
 403
 404 # TRUE if we've seen AM_AUTOMAKE_VERSION.
 405 my $seen_automake_version = 0;
 406
 407 # Hash table of discovered configure substitutions.  Keys are names,
 408 # values are `FILE:LINE' strings which are used by error message
 409 # generation.
 410 my %configure_vars = ();
 411
 412 # Ignored configure substitutions (i.e., variables not to be output in
 413 # Makefile.in)
 414 my %ignored_configure_vars = ();
 415
 416 # Files included by $configure_ac.
 417 my @configure_deps = ();
 418
 419 # Greatest timestamp of configure's dependencies.
 420 my $configure_deps_greatest_timestamp = 0;
 421
 422 # Hash table of AM_CONDITIONAL variables seen in configure.
 423 my %configure_cond = ();
 424
 425 # This maps extensions onto language names.
 426 my %extension_map = ();
 427
 428 # List of the DIST_COMMON files we discovered while reading
 429 # configure.in
 430 my $configure_dist_common = '';
 431
 432 # This maps languages names onto objects.
 433 my %languages = ();
 434 # Maps each linker variable onto a language object.
 435 my %link_languages = ();
 436
 437 # maps extensions to needed source flags.
 438 my %sourceflags = ();
 439
 440 # List of targets we must always output.
 441 # FIXME: Complete, and remove falsely required targets.
 442 my %required_targets =
 443   (
 444    'all'          => 1,
 445    'dvi'          => 1,
 446    'pdf'          => 1,
 447    'ps'           => 1,
 448    'info'         => 1,
 449    'install-info' => 1,
 450    'install'      => 1,
 451    'install-data' => 1,
 452    'install-exec' => 1,
 453    'uninstall'    => 1,
 454
 455    # FIXME: Not required, temporary hacks.
 456    # Well, actually they are sort of required: the -recursive
 457    # targets will run them anyway...
 458    'html-am'         => 1,
 459    'dvi-am'          => 1,
 460    'pdf-am'          => 1,
 461    'ps-am'           => 1,
 462    'info-am'         => 1,
 463    'install-data-am' => 1,
 464    'install-exec-am' => 1,
 465    'install-html-am' => 1,
 466    'install-dvi-am'  => 1,
 467    'install-pdf-am'  => 1,
 468    'install-ps-am'   => 1,
 469    'install-info-am' => 1,
 470    'installcheck-am' => 1,
 471    'uninstall-am' => 1,
 472
 473    'install-man' => 1,
 474   );
 475
 476 # Queue to push require_conf_file requirements to.
 477 my $required_conf_file_queue;
 478
 479 # The name of the Makefile currently being processed.
 480 my $am_file = 'BUG';
 481 \f
 482
 483 ################################################################
 484
 485 ## ------------------------------------------ ##
 486 ## Variables reset by &initialize_per_input.  ##
 487 ## ------------------------------------------ ##
 488
 489 # Basename and relative dir of the input file.
 490 my $am_file_name;
 491 my $am_relative_dir;
 492
 493 # Same but wrt Makefile.in.
 494 my $in_file_name;
 495 my $relative_dir;
 496
 497 # Relative path to the top directory.
 498 my $topsrcdir;
 499
 500 # Greatest timestamp of the output's dependencies (excluding
 501 # configure's dependencies).
 502 my $output_deps_greatest_timestamp;
 503
 504 # These variables are used when generating each Makefile.in.
 505 # They hold the Makefile.in until it is ready to be printed.
 506 my $output_vars;
 507 my $output_all;
 508 my $output_header;
 509 my $output_rules;
 510 my $output_trailer;
 511
 512 # This is the conditional stack, updated on if/else/endif, and
 513 # used to build Condition objects.
 514 my @cond_stack;
 515
 516 # This holds the set of included files.
 517 my @include_stack;
 518
 519 # List of dependencies for the obvious targets.
 520 my @all;
 521 my @check;
 522 my @check_tests;
 523
 524 # Keys in this hash table are files to delete.  The associated
 525 # value tells when this should happen (MOSTLY_CLEAN, DIST_CLEAN, etc.)
 526 my %clean_files;
 527
 528 # Keys in this hash table are object files or other files in
 529 # subdirectories which need to be removed.  This only holds files
 530 # which are created by compilations.  The value in the hash indicates
 531 # when the file should be removed.
 532 my %compile_clean_files;
 533
 534 # Keys in this hash table are directories where we expect to build a
 535 # libtool object.  We use this information to decide what directories
 536 # to delete.
 537 my %libtool_clean_directories;
 538
 539 # Value of `$(SOURCES)', used by tags.am.
 540 my @sources;
 541 # Sources which go in the distribution.
 542 my @dist_sources;
 543
 544 # This hash maps object file names onto their corresponding source
 545 # file names.  This is used to ensure that each object is created
 546 # by a single source file.
 547 my %object_map;
 548
 549 # This hash maps object file names onto an integer value representing
 550 # whether this object has been built via ordinary compilation or
 551 # libtool compilation (the COMPILE_* constants).
 552 my %object_compilation_map;
 553
 554
 555 # This keeps track of the directories for which we've already
 556 # created dirstamp code.  Keys are directories, values are stamp files.
 557 # Several keys can share the same stamp files if they are equivalent
 558 # (as are `.//foo' and `foo').
 559 my %directory_map;
 560
 561 # All .P files.
 562 my %dep_files;
 563
 564 # This is a list of all targets to run during "make dist".
 565 my @dist_targets;
 566
 567 # Keep track of all programs declared in this Makefile, without
 568 # $(EXEEXT).  @substitutions@ are not listed.
 569 my %known_programs;
 570 my %known_libraries;
 571
 572 # This keeps track of which extensions we've seen (that we care
 573 # about).
 574 my %extension_seen;
 575
 576 # This is random scratch space for the language finish functions.
 577 # Don't randomly overwrite it; examine other uses of keys first.
 578 my %language_scratch;
 579
 580 # We keep track of which objects need special (per-executable)
 581 # handling on a per-language basis.
 582 my %lang_specific_files;
 583
 584 # This is set when `handle_dist' has finished.  Once this happens,
 585 # we should no longer push on dist_common.
 586 my $handle_dist_run;
 587
 588 # Used to store a set of linkers needed to generate the sources currently
 589 # under consideration.
 590 my %linkers_used;
 591
 592 # True if we need `LINK' defined.  This is a hack.
 593 my $need_link;
 594
 595 # Does the generated Makefile have to build some compiled object
 596 # (for binary programs, or plain or libtool libraries)?
 597 my $must_handle_compiled_objects;
 598
 599 # Record each file processed by make_paragraphs.
 600 my %transformed_files;
 601 \f
 602
 603 ################################################################
 604
 605 ## ---------------------------------------------- ##
 606 ## Variables not reset by &initialize_per_input.  ##
 607 ## ---------------------------------------------- ##
 608
 609 # Cache each file processed by make_paragraphs.
 610 # (This is different from %transformed_files because
 611 # %transformed_files is reset for each file while %am_file_cache
 612 # it global to the run.)
 613 my %am_file_cache;
 614
 615 ################################################################
 616
 617 # var_SUFFIXES_trigger ($TYPE, $VALUE)
 618 # ------------------------------------
 619 # This is called by Automake::Variable::define() when SUFFIXES
 620 # is defined ($TYPE eq '') or appended ($TYPE eq '+').
 621 # The work here needs to be performed as a side-effect of the
 622 # macro_define() call because SUFFIXES definitions impact
 623 # on $KNOWN_EXTENSIONS_PATTERN which is used used when parsing
 624 # the input am file.
 625 sub var_SUFFIXES_trigger ($$)
 626 {
 627     my ($type, $value) = @_;
 628     accept_extensions (split (' ', $value));
 629 }
 630 Automake::Variable::hook ('SUFFIXES', \&var_SUFFIXES_trigger);
 631
 632 ################################################################
 633
 634 ## --------------------------------- ##
 635 ## Forward subroutine declarations.  ##
 636 ## --------------------------------- ##
 637 sub register_language (%);
 638 sub file_contents_internal ($$$%);
 639 sub define_files_variable ($\@$$);
 640
 641
 642 # &initialize_per_input ()
 643 # ------------------------
 644 # (Re)-Initialize per-Makefile.am variables.
 645 sub initialize_per_input ()
 646 {
 647     reset_local_duplicates ();
 648
 649     $am_file_name = undef;
 650     $am_relative_dir = undef;
 651
 652     $in_file_name = undef;
 653     $relative_dir = undef;
 654     $topsrcdir = undef;
 655
 656     $output_deps_greatest_timestamp = 0;
 657
 658     $output_vars = '';
 659     $output_all = '';
 660     $output_header = '';
 661     $output_rules = '';
 662     $output_trailer = '';
 663
 664     Automake::Options::reset;
 665     Automake::Variable::reset;
 666     Automake::Rule::reset;
 667
 668     @cond_stack = ();
 669
 670     @include_stack = ();
 671
 672     @all = ();
 673     @check = ();
 674     @check_tests = ();
 675
 676     %clean_files = ();
 677     %compile_clean_files = ();
 678
 679     # We always include `.'.  This isn't strictly correct.
 680     %libtool_clean_directories = ('.' => 1);
 681
 682     @sources = ();
 683     @dist_sources = ();
 684
 685     %object_map = ();
 686     %object_compilation_map = ();
 687
 688     %directory_map = ();
 689
 690     %dep_files = ();
 691
 692     @dist_targets = ();
 693
 694     %known_programs = ();
 695     %known_libraries= ();
 696
 697     %extension_seen = ();
 698
 699     %language_scratch = ();
 700
 701     %lang_specific_files = ();
 702
 703     $handle_dist_run = 0;
 704
 705     $need_link = 0;
 706
 707     $must_handle_compiled_objects = 0;
 708
 709     %transformed_files = ();
 710 }
 711
 712
 713 ################################################################
 714
 715 # Initialize our list of languages that are internally supported.
 716
 717 # C.
 718 register_language ('name' => 'c',
 719                    'Name' => 'C',
 720                    'config_vars' => ['CC'],
 721                    'autodep' => '',
 722                    'flags' => ['CFLAGS', 'CPPFLAGS'],
 723                    'ccer' => 'CC',
 724                    'compiler' => 'COMPILE',
 725                    'compile' => '$(CC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CFLAGS) $(CFLAGS)',
 726                    'lder' => 'CCLD',
 727                    'ld' => '$(CC)',
 728                    'linker' => 'LINK',
 729                    'link' => '$(CCLD) $(AM_CFLAGS) $(CFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 730                    'compile_flag' => '-c',
 731                    'libtool_tag' => 'CC',
 732                    'extensions' => ['.c']);
 733
 734 # C++.
 735 register_language ('name' => 'cxx',
 736                    'Name' => 'C++',
 737                    'config_vars' => ['CXX'],
 738                    'linker' => 'CXXLINK',
 739                    'link' => '$(CXXLD) $(AM_CXXFLAGS) $(CXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 740                    'autodep' => 'CXX',
 741                    'flags' => ['CXXFLAGS', 'CPPFLAGS'],
 742                    'compile' => '$(CXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CXXFLAGS) $(CXXFLAGS)',
 743                    'ccer' => 'CXX',
 744                    'compiler' => 'CXXCOMPILE',
 745                    'compile_flag' => '-c',
 746                    'output_flag' => '-o',
 747                    'libtool_tag' => 'CXX',
 748                    'lder' => 'CXXLD',
 749                    'ld' => '$(CXX)',
 750                    'pure' => 1,
 751                    'extensions' => ['.c++', '.cc', '.cpp', '.cxx', '.C']);
 752
 753 # Objective C.
 754 register_language ('name' => 'objc',
 755                    'Name' => 'Objective C',
 756                    'config_vars' => ['OBJC'],
 757                    'linker' => 'OBJCLINK',
 758                    'link' => '$(OBJCLD) $(AM_OBJCFLAGS) $(OBJCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 759                    'autodep' => 'OBJC',
 760                    'flags' => ['OBJCFLAGS', 'CPPFLAGS'],
 761                    'compile' => '$(OBJC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCFLAGS) $(OBJCFLAGS)',
 762                    'ccer' => 'OBJC',
 763                    'compiler' => 'OBJCCOMPILE',
 764                    'compile_flag' => '-c',
 765                    'output_flag' => '-o',
 766                    'lder' => 'OBJCLD',
 767                    'ld' => '$(OBJC)',
 768                    'pure' => 1,
 769                    'extensions' => ['.m']);
 770
 771 # Unified Parallel C.
 772 register_language ('name' => 'upc',
 773                    'Name' => 'Unified Parallel C',
 774                    'config_vars' => ['UPC'],
 775                    'linker' => 'UPCLINK',
 776                    'link' => '$(UPCLD) $(AM_UPCFLAGS) $(UPCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 777                    'autodep' => 'UPC',
 778                    'flags' => ['UPCFLAGS', 'CPPFLAGS'],
 779                    'compile' => '$(UPC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_UPCFLAGS) $(UPCFLAGS)',
 780                    'ccer' => 'UPC',
 781                    'compiler' => 'UPCCOMPILE',
 782                    'compile_flag' => '-c',
 783                    'output_flag' => '-o',
 784                    'lder' => 'UPCLD',
 785                    'ld' => '$(UPC)',
 786                    'pure' => 1,
 787                    'extensions' => ['.upc']);
 788
 789 # Headers.
 790 register_language ('name' => 'header',
 791                    'Name' => 'Header',
 792                    'extensions' => ['.h', '.H', '.hxx', '.h++', '.hh',
 793                                     '.hpp', '.inc'],
 794                    # No output.
 795                    'output_extensions' => sub { return () },
 796                    # Nothing to do.
 797                    '_finish' => sub { });
 798
 799 # Vala
 800 register_language ('name' => 'vala',
 801                    'Name' => 'Vala',
 802                    'config_vars' => ['VALAC'],
 803                    'flags' => [],
 804                    'compile' => '$(VALAC) $(AM_VALAFLAGS) $(VALAFLAGS)',
 805                    'ccer' => 'VALAC',
 806                    'compiler' => 'VALACOMPILE',
 807                    'extensions' => ['.vala'],
 808                    'output_extensions' => sub { (my $ext = $_[0]) =~ s/vala$/c/;
 809                                                 return ($ext,) },
 810                    'rule_file' => 'vala',
 811                    '_finish' => \&lang_vala_finish,
 812                    '_target_hook' => \&lang_vala_target_hook,
 813                    'nodist_specific' => 1);
 814
 815 # Yacc (C & C++).
 816 register_language ('name' => 'yacc',
 817                    'Name' => 'Yacc',
 818                    'config_vars' => ['YACC'],
 819                    'flags' => ['YFLAGS'],
 820                    'compile' => '$(YACC) $(AM_YFLAGS) $(YFLAGS)',
 821                    'ccer' => 'YACC',
 822                    'compiler' => 'YACCCOMPILE',
 823                    'extensions' => ['.y'],
 824                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 825                                                 return ($ext,) },
 826                    'rule_file' => 'yacc',
 827                    '_finish' => \&lang_yacc_finish,
 828                    '_target_hook' => \&lang_yacc_target_hook,
 829                    'nodist_specific' => 1);
 830 register_language ('name' => 'yaccxx',
 831                    'Name' => 'Yacc (C++)',
 832                    'config_vars' => ['YACC'],
 833                    'rule_file' => 'yacc',
 834                    'flags' => ['YFLAGS'],
 835                    'ccer' => 'YACC',
 836                    'compiler' => 'YACCCOMPILE',
 837                    'compile' => '$(YACC) $(AM_YFLAGS) $(YFLAGS)',
 838                    'extensions' => ['.y++', '.yy', '.yxx', '.ypp'],
 839                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 840                                                 return ($ext,) },
 841                    '_finish' => \&lang_yacc_finish,
 842                    '_target_hook' => \&lang_yacc_target_hook,
 843                    'nodist_specific' => 1);
 844
 845 # Lex (C & C++).
 846 register_language ('name' => 'lex',
 847                    'Name' => 'Lex',
 848                    'config_vars' => ['LEX'],
 849                    'rule_file' => 'lex',
 850                    'flags' => ['LFLAGS'],
 851                    'compile' => '$(LEX) $(AM_LFLAGS) $(LFLAGS)',
 852                    'ccer' => 'LEX',
 853                    'compiler' => 'LEXCOMPILE',
 854                    'extensions' => ['.l'],
 855                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 856                                                 return ($ext,) },
 857                    '_finish' => \&lang_lex_finish,
 858                    '_target_hook' => \&lang_lex_target_hook,
 859                    'nodist_specific' => 1);
 860 register_language ('name' => 'lexxx',
 861                    'Name' => 'Lex (C++)',
 862                    'config_vars' => ['LEX'],
 863                    'rule_file' => 'lex',
 864                    'flags' => ['LFLAGS'],
 865                    'compile' => '$(LEX) $(AM_LFLAGS) $(LFLAGS)',
 866                    'ccer' => 'LEX',
 867                    'compiler' => 'LEXCOMPILE',
 868                    'extensions' => ['.l++', '.ll', '.lxx', '.lpp'],
 869                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 870                                                 return ($ext,) },
 871                    '_finish' => \&lang_lex_finish,
 872                    '_target_hook' => \&lang_lex_target_hook,
 873                    'nodist_specific' => 1);
 874
 875 # Assembler.
 876 register_language ('name' => 'asm',
 877                    'Name' => 'Assembler',
 878                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 879
 880                    'flags' => ['CCASFLAGS'],
 881                    # Users can set AM_CCASFLAGS to include DEFS, INCLUDES,
 882                    # or anything else required.  They can also set CCAS.
 883                    # Or simply use Preprocessed Assembler.
 884                    'compile' => '$(CCAS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 885                    'ccer' => 'CCAS',
 886                    'compiler' => 'CCASCOMPILE',
 887                    'compile_flag' => '-c',
 888                    'output_flag' => '-o',
 889                    'extensions' => ['.s']);
 890
 891 # Preprocessed Assembler.
 892 register_language ('name' => 'cppasm',
 893                    'Name' => 'Preprocessed Assembler',
 894                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 895
 896                    'autodep' => 'CCAS',
 897                    'flags' => ['CCASFLAGS', 'CPPFLAGS'],
 898                    'compile' => '$(CCAS) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 899                    'ccer' => 'CPPAS',
 900                    'compiler' => 'CPPASCOMPILE',
 901                    'compile_flag' => '-c',
 902                    'output_flag' => '-o',
 903                    'extensions' => ['.S', '.sx']);
 904
 905 # Fortran 77
 906 register_language ('name' => 'f77',
 907                    'Name' => 'Fortran 77',
 908                    'config_vars' => ['F77'],
 909                    'linker' => 'F77LINK',
 910                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 911                    'flags' => ['FFLAGS'],
 912                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS)',
 913                    'ccer' => 'F77',
 914                    'compiler' => 'F77COMPILE',
 915                    'compile_flag' => '-c',
 916                    'output_flag' => '-o',
 917                    'libtool_tag' => 'F77',
 918                    'lder' => 'F77LD',
 919                    'ld' => '$(F77)',
 920                    'pure' => 1,
 921                    'extensions' => ['.f', '.for']);
 922
 923 # Fortran
 924 register_language ('name' => 'fc',
 925                    'Name' => 'Fortran',
 926                    'config_vars' => ['FC'],
 927                    'linker' => 'FCLINK',
 928                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 929                    'flags' => ['FCFLAGS'],
 930                    'compile' => '$(FC) $(AM_FCFLAGS) $(FCFLAGS)',
 931                    'ccer' => 'FC',
 932                    'compiler' => 'FCCOMPILE',
 933                    'compile_flag' => '-c',
 934                    'output_flag' => '-o',
 935                    'libtool_tag' => 'FC',
 936                    'lder' => 'FCLD',
 937                    'ld' => '$(FC)',
 938                    'pure' => 1,
 939                    'extensions' => ['.f90', '.f95', '.f03', '.f08']);
 940
 941 # Preprocessed Fortran
 942 register_language ('name' => 'ppfc',
 943                    'Name' => 'Preprocessed Fortran',
 944                    'config_vars' => ['FC'],
 945                    'linker' => 'FCLINK',
 946                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 947                    'lder' => 'FCLD',
 948                    'ld' => '$(FC)',
 949                    'flags' => ['FCFLAGS', 'CPPFLAGS'],
 950                    'ccer' => 'PPFC',
 951                    'compiler' => 'PPFCCOMPILE',
 952                    'compile' => '$(FC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FCFLAGS) $(FCFLAGS)',
 953                    'compile_flag' => '-c',
 954                    'output_flag' => '-o',
 955                    'libtool_tag' => 'FC',
 956                    'pure' => 1,
 957                    'extensions' => ['.F90','.F95', '.F03', '.F08']);
 958
 959 # Preprocessed Fortran 77
 960 #
 961 # The current support for preprocessing Fortran 77 just involves
 962 # passing `$(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS)
 963 # $(CPPFLAGS)' as additional flags to the Fortran 77 compiler, since
 964 # this is how GNU Make does it; see the `GNU Make Manual, Edition 0.51
 965 # for `make' Version 3.76 Beta' (specifically, from info file
 966 # `(make)Catalogue of Rules').
 967 #
 968 # A better approach would be to write an Autoconf test
 969 # (i.e. AC_PROG_FPP) for a Fortran 77 preprocessor, because not all
 970 # Fortran 77 compilers know how to do preprocessing.  The Autoconf
 971 # macro AC_PROG_FPP should test the Fortran 77 compiler first for
 972 # preprocessing capabilities, and then fall back on cpp (if cpp were
 973 # available).
 974 register_language ('name' => 'ppf77',
 975                    'Name' => 'Preprocessed Fortran 77',
 976                    'config_vars' => ['F77'],
 977                    'linker' => 'F77LINK',
 978                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 979                    'lder' => 'F77LD',
 980                    'ld' => '$(F77)',
 981                    'flags' => ['FFLAGS', 'CPPFLAGS'],
 982                    'ccer' => 'PPF77',
 983                    'compiler' => 'PPF77COMPILE',
 984                    'compile' => '$(F77) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FFLAGS) $(FFLAGS)',
 985                    'compile_flag' => '-c',
 986                    'output_flag' => '-o',
 987                    'libtool_tag' => 'F77',
 988                    'pure' => 1,
 989                    'extensions' => ['.F']);
 990
 991 # Ratfor.
 992 register_language ('name' => 'ratfor',
 993                    'Name' => 'Ratfor',
 994                    'config_vars' => ['F77'],
 995                    'linker' => 'F77LINK',
 996                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 997                    'lder' => 'F77LD',
 998                    'ld' => '$(F77)',
 999                    'flags' => ['RFLAGS', 'FFLAGS'],
1000                    # FIXME also FFLAGS.
1001                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS) $(AM_RFLAGS) $(RFLAGS)',
1002                    'ccer' => 'F77',
1003                    'compiler' => 'RCOMPILE',
1004                    'compile_flag' => '-c',
1005                    'output_flag' => '-o',
1006                    'libtool_tag' => 'F77',
1007                    'pure' => 1,
1008                    'extensions' => ['.r']);
1009
1010 # Java via gcj.
1011 register_language ('name' => 'java',
1012                    'Name' => 'Java',
1013                    'config_vars' => ['GCJ'],
1014                    'linker' => 'GCJLINK',
1015                    'link' => '$(GCJLD) $(AM_GCJFLAGS) $(GCJFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
1016                    'autodep' => 'GCJ',
1017                    'flags' => ['GCJFLAGS'],
1018                    'compile' => '$(GCJ) $(AM_GCJFLAGS) $(GCJFLAGS)',
1019                    'ccer' => 'GCJ',
1020                    'compiler' => 'GCJCOMPILE',
1021                    'compile_flag' => '-c',
1022                    'output_flag' => '-o',
1023                    'libtool_tag' => 'GCJ',
1024                    'lder' => 'GCJLD',
1025                    'ld' => '$(GCJ)',
1026                    'pure' => 1,
1027                    'extensions' => ['.java', '.class', '.zip', '.jar']);
1028
1029 ################################################################
1030
1031 # Error reporting functions.
1032
1033 # err_am ($MESSAGE, [%OPTIONS])
1034 # -----------------------------
1035 # Uncategorized errors about the current Makefile.am.
1036 sub err_am ($;%)
1037 {
1038   msg_am ('error', @_);
1039 }
1040
1041 # err_ac ($MESSAGE, [%OPTIONS])
1042 # -----------------------------
1043 # Uncategorized errors about configure.ac.
1044 sub err_ac ($;%)
1045 {
1046   msg_ac ('error', @_);
1047 }
1048
1049 # msg_am ($CHANNEL, $MESSAGE, [%OPTIONS])
1050 # ---------------------------------------
1051 # Messages about about the current Makefile.am.
1052 sub msg_am ($$;%)
1053 {
1054   my ($channel, $msg, %opts) = @_;
1055   msg $channel, "${am_file}.am", $msg, %opts;
1056 }
1057
1058 # msg_ac ($CHANNEL, $MESSAGE, [%OPTIONS])
1059 # ---------------------------------------
1060 # Messages about about configure.ac.
1061 sub msg_ac ($$;%)
1062 {
1063   my ($channel, $msg, %opts) = @_;
1064   msg $channel, $configure_ac, $msg, %opts;
1065 }
1066
1067 ################################################################
1068
1069 # subst ($TEXT)
1070 # -------------
1071 # Return a configure-style substitution using the indicated text.
1072 # We do this to avoid having the substitutions directly in automake.in;
1073 # when we do that they are sometimes removed and this causes confusion
1074 # and bugs.
1075 sub subst ($)
1076 {
1077     my ($text) = @_;
1078     return '@' . $text . '@';
1079 }
1080
1081 ################################################################
1082
1083
1084 # $BACKPATH
1085 # &backname ($REL-DIR)
1086 # --------------------
1087 # If I `cd $REL-DIR', then to come back, I should `cd $BACKPATH'.
1088 # For instance `src/foo' => `../..'.
1089 # Works with non strictly increasing paths, i.e., `src/../lib' => `..'.
1090 sub backname ($)
1091 {
1092     my ($file) = @_;
1093     my @res;
1094     foreach (split (/\//, $file))
1095     {
1096         next if $_ eq '.' || $_ eq '';
1097         if ($_ eq '..')
1098         {
1099             pop @res
1100               or prog_error ("trying to reverse path `$file' pointing outside tree");
1101         }
1102         else
1103         {
1104             push (@res, '..');
1105         }
1106     }
1107     return join ('/', @res) || '.';
1108 }
1109
1110 ################################################################
1111
1112 # `silent-rules' mode handling functions.
1113
1114 # verbose_var (NAME)
1115 # ------------------
1116 # The public variable stem used to implement `silent-rules'.
1117 sub verbose_var ($)
1118 {
1119     my ($name) = @_;
1120     return 'AM_V_' . $name;
1121 }
1122
1123 # verbose_private_var (NAME)
1124 # --------------------------
1125 # The naming policy for the private variables for `silent-rules'.
1126 sub verbose_private_var ($)
1127 {
1128     my ($name) = @_;
1129     return 'am__v_' . $name;
1130 }
1131
1132 # define_verbose_var (NAME, VAL)
1133 # ------------------------------
1134 # For `silent-rules' mode, setup VAR and dispatcher, to expand to VAL if silent.
1135 sub define_verbose_var ($$)
1136 {
1137     my ($name, $val) = @_;
1138     my $var = verbose_var ($name);
1139     my $pvar = verbose_private_var ($name);
1140     my $silent_var = $pvar . '_0';
1141     if (option 'silent-rules')
1142       {
1143         # For typical `make's, `configure' replaces AM_V (inside @@) with $(V)
1144         # and AM_DEFAULT_V (inside @@) with $(AM_DEFAULT_VERBOSITY).
1145         # For strict POSIX 2008 `make's, it replaces them with 0 or 1 instead.
1146         # See AM_SILENT_RULES in m4/silent.m4.
1147         define_variable ($var, '$(' . $pvar . '_@'.'AM_V'.'@)', INTERNAL);
1148         define_variable ($pvar . '_', '$(' . $pvar . '_@'.'AM_DEFAULT_V'.'@)', INTERNAL);
1149         Automake::Variable::define ($silent_var, VAR_AUTOMAKE, '', TRUE, $val,
1150                                     '', INTERNAL, VAR_ASIS)
1151           if (! vardef ($silent_var, TRUE));
1152       }
1153 }
1154
1155 # Above should not be needed in the general automake code.
1156
1157 # verbose_flag (NAME)
1158 # -------------------
1159 # Contents of %VERBOSE%: variable to expand before rule command.
1160 sub verbose_flag ($)
1161 {
1162     my ($name) = @_;
1163     return '$(' . verbose_var ($name) . ')'
1164       if (option 'silent-rules');
1165     return '';
1166 }
1167
1168 sub verbose_nodep_flag ($)
1169 {
1170     my ($name) = @_;
1171     return '$(' . verbose_var ($name) . subst ('am__nodep') . ')'
1172       if (option 'silent-rules');
1173     return '';
1174 }
1175
1176 # silent_flag
1177 # -----------
1178 # Contents of %SILENT%: variable to expand to `@' when silent.
1179 sub silent_flag ()
1180 {
1181     return verbose_flag ('at');
1182 }
1183
1184 # define_verbose_tagvar (NAME)
1185 # ----------------------------
1186 # Engage the needed `silent-rules' machinery for tag NAME.
1187 sub define_verbose_tagvar ($)
1188 {
1189     my ($name) = @_;
1190     if (option 'silent-rules')
1191       {
1192         define_verbose_var ($name, '@echo "  '. $name . ' ' x (8 - length ($name)) . '" $@;');
1193         define_verbose_var ('at', '@');
1194       }
1195 }
1196
1197 # define_verbose_texinfo
1198 # ----------------------
1199 # Engage the needed `silent-rules' machinery for assorted texinfo commands.
1200 sub define_verbose_texinfo ()
1201 {
1202   my @tagvars = ('DVIPS', 'MAKEINFO', 'INFOHTML', 'TEXI2DVI', 'TEXI2PDF');
1203   foreach my $tag (@tagvars)
1204     {
1205       define_verbose_tagvar($tag);
1206     }
1207   define_verbose_var('texinfo', '-q');
1208   define_verbose_var('texidevnull', '> /dev/null');
1209 }
1210
1211 # define_verbose_libtool
1212 # ----------------------
1213 # Engage the needed `silent-rules' machinery for `libtool --silent'.
1214 sub define_verbose_libtool ()
1215 {
1216     define_verbose_var ('lt', '--silent');
1217     return verbose_flag ('lt');
1218 }
1219
1220
1221 ################################################################
1222
1223
1224 # Handle AUTOMAKE_OPTIONS variable.  Return 1 on error, 0 otherwise.
1225 sub handle_options
1226 {
1227   my $var = var ('AUTOMAKE_OPTIONS');
1228   if ($var)
1229     {
1230       if ($var->has_conditional_contents)
1231         {
1232           msg_var ('unsupported', $var,
1233                    "`AUTOMAKE_OPTIONS' cannot have conditional contents");
1234         }
1235       my @options = map { { option => $_->[1], where => $_->[0] } }
1236                         $var->value_as_list_recursive (cond_filter => TRUE,
1237                                                        location => 1);
1238       return 1 if process_option_list (@options);
1239     }
1240
1241   # Override portability-recursive warning.
1242   switch_warning ('no-portability-recursive')
1243     if option 'silent-rules';
1244
1245   if ($strictness == GNITS)
1246     {
1247       set_option ('readme-alpha', INTERNAL);
1248       set_option ('std-options', INTERNAL);
1249       set_option ('check-news', INTERNAL);
1250     }
1251
1252   return 0;
1253 }
1254
1255 # shadow_unconditionally ($varname, $where)
1256 # -----------------------------------------
1257 # Return a $(variable) that contains all possible values
1258 # $varname can take.
1259 # If the VAR wasn't defined conditionally, return $(VAR).
1260 # Otherwise we create an am__VAR_DIST variable which contains
1261 # all possible values, and return $(am__VAR_DIST).
1262 sub shadow_unconditionally ($$)
1263 {
1264   my ($varname, $where) = @_;
1265   my $var = var $varname;
1266   if ($var->has_conditional_contents)
1267     {
1268       $varname = "am__${varname}_DIST";
1269       my @files = uniq ($var->value_as_list_recursive);
1270       define_pretty_variable ($varname, TRUE, $where, @files);
1271     }
1272   return "\$($varname)"
1273 }
1274
1275 # check_user_variables (@LIST)
1276 # ----------------------------
1277 # Make sure each variable VAR in @LIST does not exist, suggest using AM_VAR
1278 # otherwise.
1279 sub check_user_variables (@)
1280 {
1281   my @dont_override = @_;
1282   foreach my $flag (@dont_override)
1283     {
1284       my $var = var $flag;
1285       if ($var)
1286         {
1287           for my $cond ($var->conditions->conds)
1288             {
1289               if ($var->rdef ($cond)->owner == VAR_MAKEFILE)
1290                 {
1291                   msg_cond_var ('gnu', $cond, $flag,
1292                                 "`$flag' is a user variable, "
1293                                 . "you should not override it;\n"
1294                                 . "use `AM_$flag' instead");
1295                 }
1296             }
1297         }
1298     }
1299 }
1300
1301 # Call finish function for each language that was used.
1302 sub handle_languages
1303 {
1304     if (! option 'no-dependencies')
1305     {
1306         # Include auto-dep code.  Don't include it if DEP_FILES would
1307         # be empty.
1308         if (&saw_sources_p (0) && keys %dep_files)
1309         {
1310             # Set location of depcomp.
1311             &define_variable ('depcomp',
1312                               "\$(SHELL) $am_config_aux_dir/depcomp",
1313                               INTERNAL);
1314             &define_variable ('am__depfiles_maybe', 'depfiles', INTERNAL);
1315
1316             require_conf_file ("$am_file.am", FOREIGN, 'depcomp');
1317
1318             my @deplist = sort keys %dep_files;
1319             # Generate each `include' individually.  Irix 6 make will
1320             # not properly include several files resulting from a
1321             # variable expansion; generating many separate includes
1322             # seems safest.
1323             $output_rules .= "\n";
1324             foreach my $iter (@deplist)
1325             {
1326                 $output_rules .= (subst ('AMDEP_TRUE')
1327                                   . subst ('am__include')
1328                                   . ' '
1329                                   . subst ('am__quote')
1330                                   . $iter
1331                                   . subst ('am__quote')
1332                                   . "\n");
1333             }
1334
1335             # Compute the set of directories to remove in distclean-depend.
1336             my @depdirs = uniq (map { dirname ($_) } @deplist);
1337             $output_rules .= &file_contents ('depend',
1338                                              new Automake::Location,
1339                                              DEPDIRS => "@depdirs");
1340         }
1341     }
1342     else
1343     {
1344         &define_variable ('depcomp', '', INTERNAL);
1345         &define_variable ('am__depfiles_maybe', '', INTERNAL);
1346     }
1347
1348     my %done;
1349
1350     # Is the C linker needed?
1351     my $needs_c = 0;
1352     foreach my $ext (sort keys %extension_seen)
1353     {
1354         next unless $extension_map{$ext};
1355
1356         my $lang = $languages{$extension_map{$ext}};
1357
1358         my $rule_file = $lang->rule_file || 'depend2';
1359
1360         # Get information on $LANG.
1361         my $pfx = $lang->autodep;
1362         my $fpfx = ($pfx eq '') ? 'CC' : $pfx;
1363
1364         my ($AMDEP, $FASTDEP) =
1365           (option 'no-dependencies' || $lang->autodep eq 'no')
1366           ? ('FALSE', 'FALSE') : ('AMDEP', "am__fastdep$fpfx");
1367
1368         my $verbose = verbose_flag ($lang->ccer || 'GEN');
1369         my $verbose_nodep = ($AMDEP eq 'FALSE')
1370           ? $verbose : verbose_nodep_flag ($lang->ccer || 'GEN');
1371         my $silent = silent_flag ();
1372
1373         my %transform = ('EXT'     => $ext,
1374                          'PFX'     => $pfx,
1375                          'FPFX'    => $fpfx,
1376                          'AMDEP'   => $AMDEP,
1377                          'FASTDEP' => $FASTDEP,
1378                          '-c'      => $lang->compile_flag || '',
1379                          # These are not used, but they need to be defined
1380                          # so &transform do not complain.
1381                          SUBDIROBJ     => 0,
1382                          'DERIVED-EXT' => 'BUG',
1383                          DIST_SOURCE   => 1,
1384                          VERBOSE   => $verbose,
1385                          'VERBOSE-NODEP' => $verbose_nodep,
1386                          SILENT    => $silent,
1387                         );
1388
1389         # Generate the appropriate rules for this extension.
1390         if (((! option 'no-dependencies') && $lang->autodep ne 'no')
1391             || defined $lang->compile)
1392         {
1393             # Some C compilers don't support -c -o.  Use it only if really
1394             # needed.
1395             my $output_flag = $lang->output_flag || '';
1396             $output_flag = '-o'
1397               if (! $output_flag
1398                   && $lang->name eq 'c'
1399                   && option 'subdir-objects');
1400
1401             # Compute a possible derived extension.
1402             # This is not used by depend2.am.
1403             my $der_ext = (&{$lang->output_extensions} ($ext))[0];
1404
1405             # When we output an inference rule like `.c.o:' we
1406             # have two cases to consider: either subdir-objects
1407             # is used, or it is not.
1408             #
1409             # In the latter case the rule is used to build objects
1410             # in the current directory, and dependencies always
1411             # go into `./$(DEPDIR)/'.  We can hard-code this value.
1412             #
1413             # In the former case the rule can be used to build
1414             # objects in sub-directories too.  Dependencies should
1415             # go into the appropriate sub-directories, e.g.,
1416             # `sub/$(DEPDIR)/'.  The value of this directory
1417             # needs to be computed on-the-fly.
1418             #
1419             # DEPBASE holds the name of this directory, plus the
1420             # basename part of the object file (extensions Po, TPo,
1421             # Plo, TPlo will be added later as appropriate).  It is
1422             # either hardcoded, or a shell variable (`$depbase') that
1423             # will be computed by the rule.
1424             my $depbase =
1425               option ('subdir-objects') ? '$$depbase' : '$(DEPDIR)/$*';
1426             $output_rules .=
1427               file_contents ($rule_file,
1428                              new Automake::Location,
1429                              %transform,
1430                              GENERIC   => 1,
1431
1432                              'DERIVED-EXT' => $der_ext,
1433
1434                              DEPBASE   => $depbase,
1435                              BASE      => '$*',
1436                              SOURCE    => '$<',
1437                              SOURCEFLAG => $sourceflags{$ext} || '',
1438                              OBJ       => '$@',
1439                              OBJOBJ    => '$@',
1440                              LTOBJ     => '$@',
1441
1442                              COMPILE   => '$(' . $lang->compiler . ')',
1443                              LTCOMPILE => '$(LT' . $lang->compiler . ')',
1444                              -o        => $output_flag,
1445                              SUBDIROBJ => !! option 'subdir-objects');
1446         }
1447
1448         # Now include code for each specially handled object with this
1449         # language.
1450         my %seen_files = ();
1451         foreach my $file (@{$lang_specific_files{$lang->name}})
1452         {
1453             my ($derived, $source, $obj, $myext, $srcext, %file_transform) = @$file;
1454
1455             # We might see a given object twice, for instance if it is
1456             # used under different conditions.
1457             next if defined $seen_files{$obj};
1458             $seen_files{$obj} = 1;
1459
1460             prog_error ("found " . $lang->name .
1461                         " in handle_languages, but compiler not defined")
1462               unless defined $lang->compile;
1463
1464             my $obj_compile = $lang->compile;
1465
1466             # Rewrite each occurrence of `AM_$flag' in the compile
1467             # rule into `${derived}_$flag' if it exists.
1468             for my $flag (@{$lang->flags})
1469               {
1470                 my $val = "${derived}_$flag";
1471                 $obj_compile =~ s/\(AM_$flag\)/\($val\)/
1472                   if set_seen ($val);
1473               }
1474
1475             my $libtool_tag = '';
1476             if ($lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag})
1477               {
1478                 $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
1479               }
1480
1481             my $ptltflags = "${derived}_LIBTOOLFLAGS";
1482             $ptltflags = 'AM_LIBTOOLFLAGS' unless set_seen $ptltflags;
1483
1484             my $ltverbose = define_verbose_libtool ();
1485             my $obj_ltcompile =
1486               "\$(LIBTOOL) $ltverbose $libtool_tag\$($ptltflags) \$(LIBTOOLFLAGS) "
1487               . "--mode=compile $obj_compile";
1488
1489             # We _need_ `-o' for per object rules.
1490             my $output_flag = $lang->output_flag || '-o';
1491
1492             my $depbase = dirname ($obj);
1493             $depbase = ''
1494                 if $depbase eq '.';
1495             $depbase .= '/'
1496                 unless $depbase eq '';
1497             $depbase .= '$(DEPDIR)/' . basename ($obj);
1498
1499             $output_rules .=
1500               file_contents ($rule_file,
1501                              new Automake::Location,
1502                              %transform,
1503                              GENERIC   => 0,
1504
1505                              DEPBASE   => $depbase,
1506                              BASE      => $obj,
1507                              SOURCE    => $source,
1508                              SOURCEFLAG => $sourceflags{$srcext} || '',
1509                              # Use $myext and not `.o' here, in case
1510                              # we are actually building a new source
1511                              # file -- e.g. via yacc.
1512                              OBJ       => "$obj$myext",
1513                              OBJOBJ    => "$obj.obj",
1514                              LTOBJ     => "$obj.lo",
1515
1516                              VERBOSE   => $verbose,
1517                              'VERBOSE-NODEP'  => $verbose_nodep,
1518                              SILENT    => $silent,
1519                              COMPILE   => $obj_compile,
1520                              LTCOMPILE => $obj_ltcompile,
1521                              -o        => $output_flag,
1522                              %file_transform);
1523         }
1524
1525         # The rest of the loop is done once per language.
1526         next if defined $done{$lang};
1527         $done{$lang} = 1;
1528
1529         # Load the language dependent Makefile chunks.
1530         my %lang = map { uc ($_) => 0 } keys %languages;
1531         $lang{uc ($lang->name)} = 1;
1532         $output_rules .= file_contents ('lang-compile',
1533                                         new Automake::Location,
1534                                         %transform, %lang);
1535
1536         # If the source to a program consists entirely of code from a
1537         # `pure' language, for instance C++ or Fortran 77, then we
1538         # don't need the C compiler code.  However if we run into
1539         # something unusual then we do generate the C code.  There are
1540         # probably corner cases here that do not work properly.
1541         # People linking Java code to Fortran code deserve pain.
1542         $needs_c ||= ! $lang->pure;
1543
1544         define_compiler_variable ($lang)
1545           if ($lang->compile);
1546
1547         define_linker_variable ($lang)
1548           if ($lang->link);
1549
1550         require_variables ("$am_file.am", $lang->Name . " source seen",
1551                            TRUE, @{$lang->config_vars});
1552
1553         # Call the finisher.
1554         $lang->finish;
1555
1556         # Flags listed in `->flags' are user variables (per GNU Standards),
1557         # they should not be overridden in the Makefile...
1558         my @dont_override = @{$lang->flags};
1559         # ... and so is LDFLAGS.
1560         push @dont_override, 'LDFLAGS' if $lang->link;
1561
1562         check_user_variables @dont_override;
1563     }
1564
1565     # If the project is entirely C++ or entirely Fortran 77 (i.e., 1
1566     # suffix rule was learned), don't bother with the C stuff.  But if
1567     # anything else creeps in, then use it.
1568     $needs_c = 1
1569       if $need_link || suffix_rules_count > 1;
1570
1571     if ($needs_c)
1572       {
1573         &define_compiler_variable ($languages{'c'})
1574           unless defined $done{$languages{'c'}};
1575         define_linker_variable ($languages{'c'});
1576       }
1577
1578     # Always provide the user with `AM_V_GEN' for `silent-rules' mode.
1579     define_verbose_tagvar ('GEN');
1580 }
1581
1582
1583 # append_exeext { PREDICATE } $MACRO
1584 # ----------------------------------
1585 # Append $(EXEEXT) to each filename in $F appearing in the Makefile
1586 # variable $MACRO if &PREDICATE($F) is true.  @substitutions@ are
1587 # ignored.
1588 #
1589 # This is typically used on all filenames of *_PROGRAMS, and filenames
1590 # of TESTS that are programs.
1591 sub append_exeext (&$)
1592 {
1593   my ($pred, $macro) = @_;
1594
1595   transform_variable_recursively
1596     ($macro, $macro, 'am__EXEEXT', 0, INTERNAL,
1597      sub {
1598        my ($subvar, $val, $cond, $full_cond) = @_;
1599        # Append $(EXEEXT) unless the user did it already, or it's a
1600        # @substitution@.
1601        $val .= '$(EXEEXT)'
1602          if $val !~ /(?:\$\(EXEEXT\)$|^[@]\w+[@]$)/ && &$pred ($val);
1603        return $val;
1604      });
1605 }
1606
1607
1608 # Check to make sure a source defined in LIBOBJS is not explicitly
1609 # mentioned.  This is a separate function (as opposed to being inlined
1610 # in handle_source_transform) because it isn't always appropriate to
1611 # do this check.
1612 sub check_libobjs_sources
1613 {
1614   my ($one_file, $unxformed) = @_;
1615
1616   foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1617                       'dist_EXTRA_', 'nodist_EXTRA_')
1618     {
1619       my @files;
1620       my $varname = $prefix . $one_file . '_SOURCES';
1621       my $var = var ($varname);
1622       if ($var)
1623         {
1624           @files = $var->value_as_list_recursive;
1625         }
1626       elsif ($prefix eq '')
1627         {
1628           @files = ($unxformed . '.c');
1629         }
1630       else
1631         {
1632           next;
1633         }
1634
1635       foreach my $file (@files)
1636         {
1637           err_var ($prefix . $one_file . '_SOURCES',
1638                    "automatically discovered file `$file' should not" .
1639                    " be explicitly mentioned")
1640             if defined $libsources{$file};
1641         }
1642     }
1643 }
1644
1645
1646 # @OBJECTS
1647 # handle_single_transform ($VAR, $TOPPARENT, $DERIVED, $OBJ, $FILE, %TRANSFORM)
1648 # -----------------------------------------------------------------------------
1649 # Does much of the actual work for handle_source_transform.
1650 # Arguments are:
1651 #   $VAR is the name of the variable that the source filenames come from
1652 #   $TOPPARENT is the name of the _SOURCES variable which is being processed
1653 #   $DERIVED is the name of resulting executable or library
1654 #   $OBJ is the object extension (e.g., `.lo')
1655 #   $FILE the source file to transform
1656 #   %TRANSFORM contains extras arguments to pass to file_contents
1657 #     when producing explicit rules
1658 # Result is a list of the names of objects
1659 # %linkers_used will be updated with any linkers needed
1660 sub handle_single_transform ($$$$$%)
1661 {
1662     my ($var, $topparent, $derived, $obj, $_file, %transform) = @_;
1663     my @files = ($_file);
1664     my @result = ();
1665
1666     # Turn sources into objects.  We use a while loop like this
1667     # because we might add to @files in the loop.
1668     while (scalar @files > 0)
1669     {
1670         $_ = shift @files;
1671
1672         # Configure substitutions in _SOURCES variables are errors.
1673         if (/^\@.*\@$/)
1674         {
1675           my $parent_msg = '';
1676           $parent_msg = "\nand is referred to from `$topparent'"
1677             if $topparent ne $var->name;
1678           err_var ($var,
1679                    "`" . $var->name . "' includes configure substitution `$_'"
1680                    . $parent_msg . ";\nconfigure " .
1681                    "substitutions are not allowed in _SOURCES variables");
1682           next;
1683         }
1684
1685         # If the source file is in a subdirectory then the `.o' is put
1686         # into the current directory, unless the subdir-objects option
1687         # is in effect.
1688
1689         # Split file name into base and extension.
1690         next if ! /^(?:(.*)\/)?([^\/]*)($KNOWN_EXTENSIONS_PATTERN)$/;
1691         my $full = $_;
1692         my $directory = $1 || '';
1693         my $base = $2;
1694         my $extension = $3;
1695
1696         # We must generate a rule for the object if it requires its own flags.
1697         my $renamed = 0;
1698         my ($linker, $object);
1699
1700         # This records whether we've seen a derived source file (e.g.
1701         # yacc output).
1702         my $derived_source = 0;
1703
1704         # This holds the `aggregate context' of the file we are
1705         # currently examining.  If the file is compiled with
1706         # per-object flags, then it will be the name of the object.
1707         # Otherwise it will be `AM'.  This is used by the target hook
1708         # language function.
1709         my $aggregate = 'AM';
1710
1711         $extension = &derive_suffix ($extension, $obj);
1712         my $lang;
1713         if ($extension_map{$extension} &&
1714             ($lang = $languages{$extension_map{$extension}}))
1715         {
1716             # Found the language, so see what it says.
1717             &saw_extension ($extension);
1718
1719             # Do we have per-executable flags for this executable?
1720             my $have_per_exec_flags = 0;
1721             my @peflags = @{$lang->flags};
1722             push @peflags, 'LIBTOOLFLAGS' if $obj eq '.lo';
1723             foreach my $flag (@peflags)
1724               {
1725                 if (set_seen ("${derived}_$flag"))
1726                   {
1727                     $have_per_exec_flags = 1;
1728                     last;
1729                   }
1730               }
1731
1732             # Note: computed subr call.  The language rewrite function
1733             # should return one of the LANG_* constants.  It could
1734             # also return a list whose first value is such a constant
1735             # and whose second value is a new source extension which
1736             # should be applied.  This means this particular language
1737             # generates another source file which we must then process
1738             # further.
1739             my $subr = \&{'lang_' . $lang->name . '_rewrite'};
1740             my ($r, $source_extension)
1741                 = &$subr ($directory, $base, $extension,
1742                           $obj, $have_per_exec_flags, $var);
1743             # Skip this entry if we were asked not to process it.
1744             next if $r == LANG_IGNORE;
1745
1746             # Now extract linker and other info.
1747             $linker = $lang->linker;
1748
1749             my $this_obj_ext;
1750             if (defined $source_extension)
1751             {
1752                 $this_obj_ext = $source_extension;
1753                 $derived_source = 1;
1754             }
1755             else
1756             {
1757                 $this_obj_ext = $obj;
1758             }
1759             $object = $base . $this_obj_ext;
1760
1761             if ($have_per_exec_flags)
1762             {
1763                 # We have a per-executable flag in effect for this
1764                 # object.  In this case we rewrite the object's
1765                 # name to ensure it is unique.
1766
1767                 # We choose the name `DERIVED_OBJECT' to ensure
1768                 # (1) uniqueness, and (2) continuity between
1769                 # invocations.  However, this will result in a
1770                 # name that is too long for losing systems, in
1771                 # some situations.  So we provide _SHORTNAME to
1772                 # override.
1773
1774                 my $dname = $derived;
1775                 my $var = var ($derived . '_SHORTNAME');
1776                 if ($var)
1777                 {
1778                     # FIXME: should use the same Condition as
1779                     # the _SOURCES variable.  But this is really
1780                     # silly overkill -- nobody should have
1781                     # conditional shortnames.
1782                     $dname = $var->variable_value;
1783                 }
1784                 $object = $dname . '-' . $object;
1785
1786                 prog_error ($lang->name . " flags defined without compiler")
1787                   if ! defined $lang->compile;
1788
1789                 $renamed = 1;
1790             }
1791
1792             # If rewrite said it was ok, put the object into a
1793             # subdir.
1794             if ($r == LANG_SUBDIR && $directory ne '')
1795             {
1796                 $object = $directory . '/' . $object;
1797             }
1798
1799             # If the object file has been renamed (because per-target
1800             # flags are used) we cannot compile the file with an
1801             # inference rule: we need an explicit rule.
1802             #
1803             # If the source is in a subdirectory and the object is in
1804             # the current directory, we also need an explicit rule.
1805             #
1806             # If both source and object files are in a subdirectory
1807             # (this happens when the subdir-objects option is used),
1808             # then the inference will work.
1809             #
1810             # The latter case deserves a historical note.  When the
1811             # subdir-objects option was added on 1999-04-11 it was
1812             # thought that inferences rules would work for
1813             # subdirectory objects too.  Later, on 1999-11-22,
1814             # automake was changed to output explicit rules even for
1815             # subdir-objects.  Nobody remembers why, but this occurred
1816             # soon after the merge of the user-dep-gen-branch so it
1817             # might be related.  In late 2003 people complained about
1818             # the size of the generated Makefile.ins (libgcj, with
1819             # 2200+ subdir objects was reported to have a 9MB
1820             # Makefile), so we now rely on inference rules again.
1821             # Maybe we'll run across the same issue as in the past,
1822             # but at least this time we can document it.  However since
1823             # dependency tracking has evolved it is possible that
1824             # our old problem no longer exists.
1825             # Using inference rules for subdir-objects has been tested
1826             # with GNU make, Solaris make, Ultrix make, BSD make,
1827             # HP-UX make, and OSF1 make successfully.
1828             if ($renamed
1829                 || ($directory ne '' && ! option 'subdir-objects')
1830                 # We must also use specific rules for a nodist_ source
1831                 # if its language requests it.
1832                 || ($lang->nodist_specific && ! $transform{'DIST_SOURCE'}))
1833             {
1834                 my $obj_sans_ext = substr ($object, 0,
1835                                            - length ($this_obj_ext));
1836                 my $full_ansi;
1837                 if ($directory ne '')
1838                   {
1839                         $full_ansi = $directory . '/' . $base . $extension;
1840                   }
1841                 else
1842                   {
1843                         $full_ansi = $base . $extension;
1844                   }
1845
1846                 my @specifics = ($full_ansi, $obj_sans_ext,
1847                                  # Only use $this_obj_ext in the derived
1848                                  # source case because in the other case we
1849                                  # *don't* want $(OBJEXT) to appear here.
1850                                  ($derived_source ? $this_obj_ext : '.o'),
1851                                  $extension);
1852
1853                 # If we renamed the object then we want to use the
1854                 # per-executable flag name.  But if this is simply a
1855                 # subdir build then we still want to use the AM_ flag
1856                 # name.
1857                 if ($renamed)
1858                   {
1859                     unshift @specifics, $derived;
1860                     $aggregate = $derived;
1861                   }
1862                 else
1863                   {
1864                     unshift @specifics, 'AM';
1865                   }
1866
1867                 # Each item on this list is a reference to a list consisting
1868                 # of four values followed by additional transform flags for
1869                 # file_contents.  The four values are the derived flag prefix
1870                 # (e.g. for `foo_CFLAGS', it is `foo'), the name of the
1871                 # source file, the base name of the output file, and
1872                 # the extension for the object file.
1873                 push (@{$lang_specific_files{$lang->name}},
1874                       [@specifics, %transform]);
1875             }
1876         }
1877         elsif ($extension eq $obj)
1878         {
1879             # This is probably the result of a direct suffix rule.
1880             # In this case we just accept the rewrite.
1881             $object = "$base$extension";
1882             $object = "$directory/$object" if $directory ne '';
1883             $linker = '';
1884         }
1885         else
1886         {
1887             # No error message here.  Used to have one, but it was
1888             # very unpopular.
1889             # FIXME: we could potentially do more processing here,
1890             # perhaps treating the new extension as though it were a
1891             # new source extension (as above).  This would require
1892             # more restructuring than is appropriate right now.
1893             next;
1894         }
1895
1896         err_am "object `$object' created by `$full' and `$object_map{$object}'"
1897           if (defined $object_map{$object}
1898               && $object_map{$object} ne $full);
1899
1900         my $comp_val = (($object =~ /\.lo$/)
1901                         ? COMPILE_LIBTOOL : COMPILE_ORDINARY);
1902         (my $comp_obj = $object) =~ s/\.lo$/.\$(OBJEXT)/;
1903         if (defined $object_compilation_map{$comp_obj}
1904             && $object_compilation_map{$comp_obj} != 0
1905             # Only see the error once.
1906             && ($object_compilation_map{$comp_obj}
1907                 != (COMPILE_LIBTOOL | COMPILE_ORDINARY))
1908             && $object_compilation_map{$comp_obj} != $comp_val)
1909           {
1910             err_am "object `$comp_obj' created both with libtool and without";
1911           }
1912         $object_compilation_map{$comp_obj} |= $comp_val;
1913
1914         if (defined $lang)
1915         {
1916             # Let the language do some special magic if required.
1917             $lang->target_hook ($aggregate, $object, $full, %transform);
1918         }
1919
1920         if ($derived_source)
1921           {
1922             prog_error ($lang->name . " has automatic dependency tracking")
1923               if $lang->autodep ne 'no';
1924             # Make sure this new source file is handled next.  That will
1925             # make it appear to be at the right place in the list.
1926             unshift (@files, $object);
1927             # Distribute derived sources unless the source they are
1928             # derived from is not.
1929             &push_dist_common ($object)
1930               unless ($topparent =~ /^(?:nobase_)?nodist_/);
1931             next;
1932           }
1933
1934         $linkers_used{$linker} = 1;
1935
1936         push (@result, $object);
1937
1938         if (! defined $object_map{$object})
1939         {
1940             my @dep_list = ();
1941             $object_map{$object} = $full;
1942
1943             # If resulting object is in subdir, we need to make
1944             # sure the subdir exists at build time.
1945             if ($object =~ /\//)
1946             {
1947                 # FIXME: check that $DIRECTORY is somewhere in the
1948                 # project
1949
1950                 # For Java, the way we're handling it right now, a
1951                 # `..' component doesn't make sense.
1952                 if ($lang && $lang->name eq 'java' && $object =~ /(\/|^)\.\.\//)
1953                   {
1954                     err_am "`$full' should not contain a `..' component";
1955                   }
1956
1957                 # Make sure object is removed by `make mostlyclean'.
1958                 $compile_clean_files{$object} = MOSTLY_CLEAN;
1959                 # If we have a libtool object then we also must remove
1960                 # the ordinary .o.
1961                 if ($object =~ /\.lo$/)
1962                 {
1963                     (my $xobj = $object) =~ s,lo$,\$(OBJEXT),;
1964                     $compile_clean_files{$xobj} = MOSTLY_CLEAN;
1965
1966                     # Remove any libtool object in this directory.
1967                     $libtool_clean_directories{$directory} = 1;
1968                 }
1969
1970                 push (@dep_list, require_build_directory ($directory));
1971
1972                 # If we're generating dependencies, we also want
1973                 # to make sure that the appropriate subdir of the
1974                 # .deps directory is created.
1975                 push (@dep_list,
1976                       require_build_directory ($directory . '/$(DEPDIR)'))
1977                   unless option 'no-dependencies';
1978             }
1979
1980             &pretty_print_rule ($object . ':', "\t", @dep_list)
1981                 if scalar @dep_list > 0;
1982         }
1983
1984         # Transform .o or $o file into .P file (for automatic
1985         # dependency code).
1986         # Properly flatten multiple adjacent slashes, as Solaris 10 make
1987         # might fail over them in an include statement.
1988         # Leading double slashes may be special, as per Posix, so deal
1989         # with them carefully.
1990         if ($lang && $lang->autodep ne 'no')
1991         {
1992             my $depfile = $object;
1993             $depfile =~ s/\.([^.]*)$/.P$1/;
1994             $depfile =~ s/\$\(OBJEXT\)$/o/;
1995             my $maybe_extra_leading_slash = '';
1996             $maybe_extra_leading_slash = '/' if $depfile =~ m,^//[^/],;
1997             $depfile =~ s,/+,/,g;
1998             my $basename = basename ($depfile);
1999             # This might make $dirname empty, but we account for that below.
2000             (my $dirname = dirname ($depfile)) =~ s/\/*$//;
2001             $dirname = $maybe_extra_leading_slash . $dirname;
2002             $dep_files{$dirname . '/$(DEPDIR)/' . $basename} = 1;
2003         }
2004     }
2005
2006     return @result;
2007 }
2008
2009
2010 # $LINKER
2011 # define_objects_from_sources ($VAR, $OBJVAR, $NODEFINE, $ONE_FILE,
2012 #                              $OBJ, $PARENT, $TOPPARENT, $WHERE, %TRANSFORM)
2013 # ---------------------------------------------------------------------------
2014 # Define an _OBJECTS variable for a _SOURCES variable (or subvariable)
2015 #
2016 # Arguments are:
2017 #   $VAR is the name of the _SOURCES variable
2018 #   $OBJVAR is the name of the _OBJECTS variable if known (otherwise
2019 #     it will be generated and returned).
2020 #   $NODEFINE is a boolean: if true, $OBJVAR will not be defined (but
2021 #     work done to determine the linker will be).
2022 #   $ONE_FILE is the canonical (transformed) name of object to build
2023 #   $OBJ is the object extension (i.e. either `.o' or `.lo').
2024 #   $TOPPARENT is the _SOURCES variable being processed.
2025 #   $WHERE context into which this definition is done
2026 #   %TRANSFORM extra arguments to pass to file_contents when producing
2027 #     rules
2028 #
2029 # Result is a pair ($LINKER, $OBJVAR):
2030 #    $LINKER is a boolean, true if a linker is needed to deal with the objects
2031 sub define_objects_from_sources ($$$$$$$%)
2032 {
2033   my ($var, $objvar, $nodefine, $one_file,
2034       $obj, $topparent, $where, %transform) = @_;
2035
2036   my $needlinker = "";
2037
2038   transform_variable_recursively
2039     ($var, $objvar, 'am__objects', $nodefine, $where,
2040      # The transform code to run on each filename.
2041      sub {
2042        my ($subvar, $val, $cond, $full_cond) = @_;
2043        my @trans = handle_single_transform ($subvar, $topparent,
2044                                             $one_file, $obj, $val,
2045                                             %transform);
2046        $needlinker = "true" if @trans;
2047        return @trans;
2048      });
2049
2050   return $needlinker;
2051 }
2052
2053
2054 # handle_source_transform ($CANON_TARGET, $TARGET, $OBJEXT, $WHERE, %TRANSFORM)
2055 # -----------------------------------------------------------------------------
2056 # Handle SOURCE->OBJECT transform for one program or library.
2057 # Arguments are:
2058 #   canonical (transformed) name of target to build
2059 #   actual target of object to build
2060 #   object extension (i.e., either `.o' or `$o')
2061 #   location of the source variable
2062 #   extra arguments to pass to file_contents when producing rules
2063 # Return the name of the linker variable that must be used.
2064 # Empty return means just use `LINK'.
2065 sub handle_source_transform ($$$$%)
2066 {
2067     # one_file is canonical name.  unxformed is given name.  obj is
2068     # object extension.
2069     my ($one_file, $unxformed, $obj, $where, %transform) = @_;
2070
2071     my $linker = '';
2072
2073     # No point in continuing if _OBJECTS is defined.
2074     return if reject_var ($one_file . '_OBJECTS',
2075                           $one_file . '_OBJECTS should not be defined');
2076
2077     my %used_pfx = ();
2078     my $needlinker;
2079     %linkers_used = ();
2080     foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
2081                         'dist_EXTRA_', 'nodist_EXTRA_')
2082     {
2083         my $varname = $prefix . $one_file . "_SOURCES";
2084         my $var = var $varname;
2085         next unless $var;
2086
2087         # We are going to define _OBJECTS variables using the prefix.
2088         # Then we glom them all together.  So we can't use the null
2089         # prefix here as we need it later.
2090         my $xpfx = ($prefix eq '') ? 'am_' : $prefix;
2091
2092         # Keep track of which prefixes we saw.
2093         $used_pfx{$xpfx} = 1
2094           unless $prefix =~ /EXTRA_/;
2095
2096         push @sources, "\$($varname)";
2097         push @dist_sources, shadow_unconditionally ($varname, $where)
2098           unless (option ('no-dist') || $prefix =~ /^nodist_/);
2099
2100         $needlinker |=
2101             define_objects_from_sources ($varname,
2102                                          $xpfx . $one_file . '_OBJECTS',
2103                                          $prefix =~ /EXTRA_/,
2104                                          $one_file, $obj, $varname, $where,
2105                                          DIST_SOURCE => ($prefix !~ /^nodist_/),
2106                                          %transform);
2107     }
2108     if ($needlinker)
2109     {
2110         $linker ||= &resolve_linker (%linkers_used);
2111     }
2112
2113     my @keys = sort keys %used_pfx;
2114     if (scalar @keys == 0)
2115     {
2116         # The default source for libfoo.la is libfoo.c, but for
2117         # backward compatibility we first look at libfoo_la.c,
2118         # if no default source suffix is given.
2119         my $old_default_source = "$one_file.c";
2120         my $ext_var = var ('AM_DEFAULT_SOURCE_EXT');
2121         my $default_source_ext = $ext_var ? variable_value ($ext_var) : '.c';
2122         msg_var ('unsupported', $ext_var, $ext_var->name . " can assume at most one value")
2123           if $default_source_ext =~ /[\t ]/;
2124         (my $default_source = $unxformed) =~ s,(\.[^./\\]*)?$,$default_source_ext,;
2125         if ($old_default_source ne $default_source
2126             && !$ext_var
2127             && (rule $old_default_source
2128                 || rule '$(srcdir)/' . $old_default_source
2129                 || rule '${srcdir}/' . $old_default_source
2130                 || -f $old_default_source))
2131           {
2132             my $loc = $where->clone;
2133             $loc->pop_context;
2134             msg ('obsolete', $loc,
2135                  "the default source for `$unxformed' has been changed "
2136                  . "to `$default_source'.\n(Using `$old_default_source' for "
2137                  . "backward compatibility.)");
2138             $default_source = $old_default_source;
2139           }
2140         # If a rule exists to build this source with a $(srcdir)
2141         # prefix, use that prefix in our variables too.  This is for
2142         # the sake of BSD Make.
2143         if (rule '$(srcdir)/' . $default_source
2144             || rule '${srcdir}/' . $default_source)
2145           {
2146             $default_source = '$(srcdir)/' . $default_source;
2147           }
2148
2149         &define_variable ($one_file . "_SOURCES", $default_source, $where);
2150         push (@sources, $default_source);
2151         push (@dist_sources, $default_source);
2152
2153         %linkers_used = ();
2154         my (@result) =
2155           handle_single_transform ($one_file . '_SOURCES',
2156                                    $one_file . '_SOURCES',
2157                                    $one_file, $obj,
2158                                    $default_source, %transform);
2159         $linker ||= &resolve_linker (%linkers_used);
2160         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @result);
2161     }
2162     else
2163     {
2164         @keys = map { '$(' . $_ . $one_file . '_OBJECTS)' } @keys;
2165         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @keys);
2166     }
2167
2168     # If we want to use `LINK' we must make sure it is defined.
2169     if ($linker eq '')
2170     {
2171         $need_link = 1;
2172     }
2173
2174     return $linker;
2175 }
2176
2177
2178 # handle_lib_objects ($XNAME, $VAR)
2179 # ---------------------------------
2180 # Special-case ALLOCA and LIBOBJS substitutions in _LDADD or _LIBADD variables.
2181 # Also, generate _DEPENDENCIES variable if appropriate.
2182 # Arguments are:
2183 #   transformed name of object being built, or empty string if no object
2184 #   name of _LDADD/_LIBADD-type variable to examine
2185 # Returns 1 if LIBOBJS seen, 0 otherwise.
2186 sub handle_lib_objects
2187 {
2188   my ($xname, $varname) = @_;
2189
2190   my $var = var ($varname);
2191   prog_error "`$varname' undefined"
2192     unless $var;
2193   prog_error "unexpected variable name `$varname'"
2194     unless $varname =~ /^(.*)(?:LIB|LD)ADD$/;
2195   my $prefix = $1 || 'AM_';
2196
2197   my $seen_libobjs = 0;
2198   my $flagvar = 0;
2199
2200   transform_variable_recursively
2201     ($varname, $xname . '_DEPENDENCIES', 'am__DEPENDENCIES',
2202      ! $xname, INTERNAL,
2203      # Transformation function, run on each filename.
2204      sub {
2205        my ($subvar, $val, $cond, $full_cond) = @_;
2206
2207        if ($val =~ /^-/)
2208          {
2209            # Skip -lfoo and -Ldir silently; these are explicitly allowed.
2210            if ($val !~ /^-[lL]/ &&
2211                # Skip -dlopen and -dlpreopen; these are explicitly allowed
2212                # for Libtool libraries or programs.  (Actually we are a bit
2213                # lax here since this code also applies to non-libtool
2214                # libraries or programs, for which -dlopen and -dlopreopen
2215                # are pure nonsense.  Diagnosing this doesn't seem very
2216                # important: the developer will quickly get complaints from
2217                # the linker.)
2218                $val !~ /^-dl(?:pre)?open$/ &&
2219                # Only get this error once.
2220                ! $flagvar)
2221              {
2222                $flagvar = 1;
2223                # FIXME: should display a stack of nested variables
2224                # as context when $var != $subvar.
2225                err_var ($var, "linker flags such as `$val' belong in "
2226                         . "`${prefix}LDFLAGS'");
2227              }
2228            return ();
2229          }
2230        elsif ($val !~ /^\@.*\@$/)
2231          {
2232            # Assume we have a file of some sort, and output it into the
2233            # dependency variable.  Autoconf substitutions are not output;
2234            # rarely is a new dependency substituted into e.g. foo_LDADD
2235            # -- but bad things (e.g. -lX11) are routinely substituted.
2236            # Note that LIBOBJS and ALLOCA are exceptions to this rule,
2237            # and handled specially below.
2238            return $val;
2239          }
2240        elsif ($val =~ /^\@(LT)?LIBOBJS\@$/)
2241          {
2242            handle_LIBOBJS ($subvar, $cond, $1);
2243            $seen_libobjs = 1;
2244            return $val;
2245          }
2246        elsif ($val =~ /^\@(LT)?ALLOCA\@$/)
2247          {
2248            handle_ALLOCA ($subvar, $cond, $1);
2249            return $val;
2250          }
2251        else
2252          {
2253            return ();
2254          }
2255      });
2256
2257   return $seen_libobjs;
2258 }
2259
2260 # handle_LIBOBJS_or_ALLOCA ($VAR)
2261 # -------------------------------
2262 # Definitions common to LIBOBJS and ALLOCA.
2263 # VAR should be one of LIBOBJS, LTLIBOBJS, ALLOCA, or LTALLOCA.
2264 sub handle_LIBOBJS_or_ALLOCA ($)
2265 {
2266   my ($var) = @_;
2267
2268   my $dir = '';
2269
2270   # If LIBOBJS files must be built in another directory we have
2271   # to define LIBOBJDIR and ensure the files get cleaned.
2272   # Otherwise LIBOBJDIR can be left undefined, and the cleaning
2273   # is achieved by `rm -f *.$(OBJEXT)' in compile.am.
2274   if ($config_libobj_dir
2275       && $relative_dir ne $config_libobj_dir)
2276     {
2277       if (option 'subdir-objects')
2278         {
2279           # In the top-level Makefile we do not use $(top_builddir), because
2280           # we are already there, and since the targets are built without
2281           # a $(top_builddir), it helps BSD Make to match them with
2282           # dependencies.
2283           $dir = "$config_libobj_dir/" if $config_libobj_dir ne '.';
2284           $dir = "$topsrcdir/$dir" if $relative_dir ne '.';
2285           define_variable ('LIBOBJDIR', "$dir", INTERNAL);
2286           $clean_files{"\$($var)"} = MOSTLY_CLEAN;
2287           # If LTLIBOBJS is used, we must also clear LIBOBJS (which might
2288           # be created by libtool as a side-effect of creating LTLIBOBJS).
2289           $clean_files{"\$($var)"} = MOSTLY_CLEAN if $var =~ s/^LT//;
2290         }
2291       else
2292         {
2293           error ("`\$($var)' cannot be used outside `$config_libobj_dir' if"
2294                  . " `subdir-objects' is not set");
2295         }
2296     }
2297
2298   return $dir;
2299 }
2300
2301 sub handle_LIBOBJS ($$$)
2302 {
2303   my ($var, $cond, $lt) = @_;
2304   my $myobjext = $lt ? 'lo' : 'o';
2305   $lt ||= '';
2306
2307   $var->requires_variables ("\@${lt}LIBOBJS\@ used", $lt . 'LIBOBJS')
2308     if ! keys %libsources;
2309
2310   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}LIBOBJS";
2311
2312   foreach my $iter (keys %libsources)
2313     {
2314       if ($iter =~ /\.[cly]$/)
2315         {
2316           &saw_extension ($&);
2317           &saw_extension ('.c');
2318         }
2319
2320       if ($iter =~ /\.h$/)
2321         {
2322           require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2323         }
2324       elsif ($iter ne 'alloca.c')
2325         {
2326           my $rewrite = $iter;
2327           $rewrite =~ s/\.c$/.P$myobjext/;
2328           $dep_files{$dir . '$(DEPDIR)/' . $rewrite} = 1;
2329           $rewrite = "^" . quotemeta ($iter) . "\$";
2330           # Only require the file if it is not a built source.
2331           my $bs = var ('BUILT_SOURCES');
2332           if (! $bs || ! grep (/$rewrite/, $bs->value_as_list_recursive))
2333             {
2334               require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2335             }
2336         }
2337     }
2338 }
2339
2340 sub handle_ALLOCA ($$$)
2341 {
2342   my ($var, $cond, $lt) = @_;
2343   my $myobjext = $lt ? 'lo' : 'o';
2344   $lt ||= '';
2345   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}ALLOCA";
2346
2347   $var->requires_variables ("\@${lt}ALLOCA\@ used", $lt . 'ALLOCA');
2348   $dep_files{$dir . '$(DEPDIR)/alloca.P' . $myobjext} = 1;
2349   require_libsource_with_macro ($cond, $var, FOREIGN, 'alloca.c');
2350   &saw_extension ('.c');
2351 }
2352
2353 # Canonicalize the input parameter
2354 sub canonicalize
2355 {
2356     my ($string) = @_;
2357     $string =~ tr/A-Za-z0-9_\@/_/c;
2358     return $string;
2359 }
2360
2361 # Canonicalize a name, and check to make sure the non-canonical name
2362 # is never used.  Returns canonical name.  Arguments are name and a
2363 # list of suffixes to check for.
2364 sub check_canonical_spelling
2365 {
2366   my ($name, @suffixes) = @_;
2367
2368   my $xname = &canonicalize ($name);
2369   if ($xname ne $name)
2370     {
2371       foreach my $xt (@suffixes)
2372         {
2373           reject_var ("$name$xt", "use `$xname$xt', not `$name$xt'");
2374         }
2375     }
2376
2377   return $xname;
2378 }
2379
2380
2381 # handle_compile ()
2382 # -----------------
2383 # Set up the compile suite.
2384 sub handle_compile ()
2385 {
2386    return if ! $must_handle_compiled_objects;
2387
2388     # Boilerplate.
2389     my $default_includes = '';
2390     if (! option 'nostdinc')
2391       {
2392         my @incs = ('-I.', subst ('am__isrc'));
2393
2394         my $var = var 'CONFIG_HEADER';
2395         if ($var)
2396           {
2397             foreach my $hdr (split (' ', $var->variable_value))
2398               {
2399                 push @incs, '-I' . dirname ($hdr);
2400               }
2401           }
2402         # We want `-I. -I$(srcdir)', but the latter -I is redundant
2403         # and unaesthetic in non-VPATH builds.  We use `-I.@am__isrc@`
2404         # instead.  It will be replaced by '-I.' or '-I. -I$(srcdir)'.
2405         # Items in CONFIG_HEADER are never in $(srcdir) so it is safe
2406         # to just put @am__isrc@ right after `-I.', without a space.
2407         ($default_includes = ' ' . uniq (@incs)) =~ s/ @/@/;
2408       }
2409
2410     my (@mostly_rms, @dist_rms);
2411     foreach my $item (sort keys %compile_clean_files)
2412     {
2413         if ($compile_clean_files{$item} == MOSTLY_CLEAN)
2414         {
2415             push (@mostly_rms, "\t-rm -f $item");
2416         }
2417         elsif ($compile_clean_files{$item} == DIST_CLEAN)
2418         {
2419             push (@dist_rms, "\t-rm -f $item");
2420         }
2421         else
2422         {
2423           prog_error 'invalid entry in %compile_clean_files';
2424         }
2425     }
2426
2427     my ($coms, $vars, $rules) =
2428       &file_contents_internal (1, "$libdir/am/compile.am",
2429                                new Automake::Location,
2430                                ('DEFAULT_INCLUDES' => $default_includes,
2431                                 'MOSTLYRMS' => join ("\n", @mostly_rms),
2432                                 'DISTRMS' => join ("\n", @dist_rms)));
2433     $output_vars .= $vars;
2434     $output_rules .= "$coms$rules";
2435 }
2436
2437 # handle_libtool ()
2438 # -----------------
2439 # Handle libtool rules.
2440 sub handle_libtool
2441 {
2442   return unless var ('LIBTOOL');
2443
2444   # Libtool requires some files, but only at top level.
2445   # (Starting with Libtool 2.0 we do not have to bother.  These
2446   # requirements are done with AC_REQUIRE_AUX_FILE.)
2447   require_conf_file_with_macro (TRUE, 'LIBTOOL', FOREIGN, @libtool_files)
2448     if $relative_dir eq '.' && ! $libtool_new_api;
2449
2450   my @libtool_rms;
2451   foreach my $item (sort keys %libtool_clean_directories)
2452     {
2453       my $dir = ($item eq '.') ? '' : "$item/";
2454       # .libs is for Unix, _libs for DOS.
2455       push (@libtool_rms, "\t-rm -rf ${dir}.libs ${dir}_libs");
2456     }
2457
2458   check_user_variables 'LIBTOOLFLAGS';
2459
2460   # Output the libtool compilation rules.
2461   $output_rules .= &file_contents ('libtool',
2462                                    new Automake::Location,
2463                                    LTRMS => join ("\n", @libtool_rms));
2464 }
2465
2466 # handle_programs ()
2467 # ------------------
2468 # Handle C programs.
2469 sub handle_programs
2470 {
2471   my @proglist = &am_install_var ('progs', 'PROGRAMS',
2472                                   'bin', 'sbin', 'libexec', 'pkglibexec',
2473                                   'noinst', 'check');
2474   return if ! @proglist;
2475   $must_handle_compiled_objects = 1;
2476
2477   my $seen_global_libobjs =
2478     var ('LDADD') && &handle_lib_objects ('', 'LDADD');
2479
2480   foreach my $pair (@proglist)
2481     {
2482       my ($where, $one_file) = @$pair;
2483
2484       my $seen_libobjs = 0;
2485       my $obj = '.$(OBJEXT)';
2486
2487       $known_programs{$one_file} = $where;
2488
2489       # Canonicalize names and check for misspellings.
2490       my $xname = &check_canonical_spelling ($one_file, '_LDADD', '_LDFLAGS',
2491                                              '_SOURCES', '_OBJECTS',
2492                                              '_DEPENDENCIES');
2493
2494       $where->push_context ("while processing program `$one_file'");
2495       $where->set (INTERNAL->get);
2496
2497       my $linker = &handle_source_transform ($xname, $one_file, $obj, $where,
2498                                              NONLIBTOOL => 1, LIBTOOL => 0);
2499
2500       if (var ($xname . "_LDADD"))
2501         {
2502           $seen_libobjs = &handle_lib_objects ($xname, $xname . '_LDADD');
2503         }
2504       else
2505         {
2506           # User didn't define prog_LDADD override.  So do it.
2507           &define_variable ($xname . '_LDADD', '$(LDADD)', $where);
2508
2509           # This does a bit too much work.  But we need it to
2510           # generate _DEPENDENCIES when appropriate.
2511           if (var ('LDADD'))
2512             {
2513               $seen_libobjs = &handle_lib_objects ($xname, 'LDADD');
2514             }
2515         }
2516
2517       reject_var ($xname . '_LIBADD',
2518                   "use `${xname}_LDADD', not `${xname}_LIBADD'");
2519
2520       set_seen ($xname . '_DEPENDENCIES');
2521       set_seen ('EXTRA_' . $xname . '_DEPENDENCIES');
2522       set_seen ($xname . '_LDFLAGS');
2523
2524       # Determine program to use for link.
2525       my($xlink, $vlink) = &define_per_target_linker_variable ($linker, $xname);
2526       $vlink = verbose_flag ($vlink || 'GEN');
2527
2528       # If the resulting program lies into a subdirectory,
2529       # make sure this directory will exist.
2530       my $dirstamp = require_build_directory_maybe ($one_file);
2531
2532       $libtool_clean_directories{dirname ($one_file)} = 1;
2533
2534       $output_rules .= &file_contents ('program',
2535                                        $where,
2536                                        PROGRAM  => $one_file,
2537                                        XPROGRAM => $xname,
2538                                        XLINK    => $xlink,
2539                                        VERBOSE  => $vlink,
2540                                        DIRSTAMP => $dirstamp,
2541                                        EXEEXT   => '$(EXEEXT)');
2542
2543       if ($seen_libobjs || $seen_global_libobjs)
2544         {
2545           if (var ($xname . '_LDADD'))
2546             {
2547               &check_libobjs_sources ($xname, $xname . '_LDADD');
2548             }
2549           elsif (var ('LDADD'))
2550             {
2551               &check_libobjs_sources ($xname, 'LDADD');
2552             }
2553         }
2554     }
2555 }
2556
2557
2558 # handle_libraries ()
2559 # -------------------
2560 # Handle libraries.
2561 sub handle_libraries
2562 {
2563   my @liblist = &am_install_var ('libs', 'LIBRARIES',
2564                                  'lib', 'pkglib', 'noinst', 'check');
2565   return if ! @liblist;
2566   $must_handle_compiled_objects = 1;
2567
2568   my @prefix = am_primary_prefixes ('LIBRARIES', 0, 'lib', 'pkglib',
2569                                     'noinst', 'check');
2570
2571   if (@prefix)
2572     {
2573       my $var = rvar ($prefix[0] . '_LIBRARIES');
2574       $var->requires_variables ('library used', 'RANLIB');
2575     }
2576
2577   &define_variable ('AR', 'ar', INTERNAL);
2578   &define_variable ('ARFLAGS', 'cru', INTERNAL);
2579   &define_verbose_tagvar ('AR');
2580
2581   foreach my $pair (@liblist)
2582     {
2583       my ($where, $onelib) = @$pair;
2584
2585       my $seen_libobjs = 0;
2586       # Check that the library fits the standard naming convention.
2587       my $bn = basename ($onelib);
2588       if ($bn !~ /^lib.*\.a$/)
2589         {
2590           $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.a/;
2591           my $suggestion = dirname ($onelib) . "/$bn";
2592           $suggestion =~ s|^\./||g;
2593           msg ('error-gnu/warn', $where,
2594                "`$onelib' is not a standard library name\n"
2595                . "did you mean `$suggestion'?")
2596         }
2597
2598       ($known_libraries{$onelib} = $bn) =~ s/\.a$//;
2599
2600       $where->push_context ("while processing library `$onelib'");
2601       $where->set (INTERNAL->get);
2602
2603       my $obj = '.$(OBJEXT)';
2604
2605       # Canonicalize names and check for misspellings.
2606       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_SOURCES',
2607                                             '_OBJECTS', '_DEPENDENCIES',
2608                                             '_AR');
2609
2610       if (! var ($xlib . '_AR'))
2611         {
2612           &define_variable ($xlib . '_AR', '$(AR) $(ARFLAGS)', $where);
2613         }
2614
2615       # Generate support for conditional object inclusion in
2616       # libraries.
2617       if (var ($xlib . '_LIBADD'))
2618         {
2619           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2620             {
2621               $seen_libobjs = 1;
2622             }
2623         }
2624       else
2625         {
2626           &define_variable ($xlib . "_LIBADD", '', $where);
2627         }
2628
2629       reject_var ($xlib . '_LDADD',
2630                   "use `${xlib}_LIBADD', not `${xlib}_LDADD'");
2631
2632       # Make sure we at look at this.
2633       set_seen ($xlib . '_DEPENDENCIES');
2634       set_seen ('EXTRA_' . $xlib . '_DEPENDENCIES');
2635
2636       &handle_source_transform ($xlib, $onelib, $obj, $where,
2637                                 NONLIBTOOL => 1, LIBTOOL => 0);
2638
2639       # If the resulting library lies into a subdirectory,
2640       # make sure this directory will exist.
2641       my $dirstamp = require_build_directory_maybe ($onelib);
2642       my $verbose = verbose_flag ('AR');
2643       my $silent = silent_flag ();
2644
2645       $output_rules .= &file_contents ('library',
2646                                        $where,
2647                                        VERBOSE  => $verbose,
2648                                        SILENT   => $silent,
2649                                        LIBRARY  => $onelib,
2650                                        XLIBRARY => $xlib,
2651                                        DIRSTAMP => $dirstamp);
2652
2653       if ($seen_libobjs)
2654         {
2655           if (var ($xlib . '_LIBADD'))
2656             {
2657               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2658             }
2659         }
2660
2661       if (! $seen_ar)
2662         {
2663           msg ('extra-portability', $where,
2664                "`$onelib': linking libraries using a non-POSIX\n"
2665                . "archiver requires `AM_PROG_AR' in `$configure_ac'")
2666         }
2667     }
2668 }
2669
2670
2671 # handle_ltlibraries ()
2672 # ---------------------
2673 # Handle shared libraries.
2674 sub handle_ltlibraries
2675 {
2676   my @liblist = &am_install_var ('ltlib', 'LTLIBRARIES',
2677                                  'noinst', 'lib', 'pkglib', 'check');
2678   return if ! @liblist;
2679   $must_handle_compiled_objects = 1;
2680
2681   my @prefix = am_primary_prefixes ('LTLIBRARIES', 0, 'lib', 'pkglib',
2682                                     'noinst', 'check');
2683
2684   if (@prefix)
2685     {
2686       my $var = rvar ($prefix[0] . '_LTLIBRARIES');
2687       $var->requires_variables ('Libtool library used', 'LIBTOOL');
2688     }
2689
2690   my %instdirs = ();
2691   my %instsubdirs = ();
2692   my %instconds = ();
2693   my %liblocations = ();        # Location (in Makefile.am) of each library.
2694
2695   foreach my $key (@prefix)
2696     {
2697       # Get the installation directory of each library.
2698       my $dir = $key;
2699       my $strip_subdir = 1;
2700       if ($dir =~ /^nobase_/)
2701         {
2702           $dir =~ s/^nobase_//;
2703           $strip_subdir = 0;
2704         }
2705       my $var = rvar ($key . '_LTLIBRARIES');
2706
2707       # We reject libraries which are installed in several places
2708       # in the same condition, because we can only specify one
2709       # `-rpath' option.
2710       $var->traverse_recursively
2711         (sub
2712          {
2713            my ($var, $val, $cond, $full_cond) = @_;
2714            my $hcond = $full_cond->human;
2715            my $where = $var->rdef ($cond)->location;
2716            my $ldir = '';
2717            $ldir = '/' . dirname ($val)
2718              if (!$strip_subdir);
2719            # A library cannot be installed in different directories
2720            # in overlapping conditions.
2721            if (exists $instconds{$val})
2722              {
2723                my ($msg, $acond) =
2724                  $instconds{$val}->ambiguous_p ($val, $full_cond);
2725
2726                if ($msg)
2727                  {
2728                    error ($where, $msg, partial => 1);
2729                    my $dirtxt = "installed " . ($strip_subdir ? "in" : "below") . " `$dir'";
2730                    $dirtxt = "built for `$dir'"
2731                      if $dir eq 'EXTRA' || $dir eq 'noinst' || $dir eq 'check';
2732                    my $dircond =
2733                      $full_cond->true ? "" : " in condition $hcond";
2734
2735                    error ($where, "`$val' should be $dirtxt$dircond ...",
2736                           partial => 1);
2737
2738                    my $hacond = $acond->human;
2739                    my $adir = $instdirs{$val}{$acond};
2740                    my $adirtxt = "installed in `$adir'";
2741                    $adirtxt = "built for `$adir'"
2742                      if ($adir eq 'EXTRA' || $adir eq 'noinst'
2743                          || $adir eq 'check');
2744                    my $adircond = $acond->true ? "" : " in condition $hacond";
2745
2746                    my $onlyone = ($dir ne $adir) ?
2747                      ("\nLibtool libraries can be built for only one "
2748                       . "destination") : "";
2749
2750                    error ($liblocations{$val}{$acond},
2751                           "... and should also be $adirtxt$adircond.$onlyone");
2752                    return;
2753                  }
2754              }
2755            else
2756              {
2757                $instconds{$val} = new Automake::DisjConditions;
2758              }
2759            $instdirs{$val}{$full_cond} = $dir;
2760            $instsubdirs{$val}{$full_cond} = $ldir;
2761            $liblocations{$val}{$full_cond} = $where;
2762            $instconds{$val} = $instconds{$val}->merge ($full_cond);
2763          },
2764          sub
2765          {
2766            return ();
2767          },
2768          skip_ac_subst => 1);
2769     }
2770
2771   foreach my $pair (@liblist)
2772     {
2773       my ($where, $onelib) = @$pair;
2774
2775       my $seen_libobjs = 0;
2776       my $obj = '.lo';
2777
2778       # Canonicalize names and check for misspellings.
2779       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_LDFLAGS',
2780                                             '_SOURCES', '_OBJECTS',
2781                                             '_DEPENDENCIES');
2782
2783       # Check that the library fits the standard naming convention.
2784       my $libname_rx = '^lib.*\.la';
2785       my $ldvar = var ("${xlib}_LDFLAGS") || var ('AM_LDFLAGS');
2786       my $ldvar2 = var ('LDFLAGS');
2787       if (($ldvar && grep (/-module/, $ldvar->value_as_list_recursive))
2788           || ($ldvar2 && grep (/-module/, $ldvar2->value_as_list_recursive)))
2789         {
2790           # Relax name checking for libtool modules.
2791           $libname_rx = '\.la';
2792         }
2793
2794       my $bn = basename ($onelib);
2795       if ($bn !~ /$libname_rx$/)
2796         {
2797           my $type = 'library';
2798           if ($libname_rx eq '\.la')
2799             {
2800               $bn =~ s/^(lib|)(.*?)(?:\.[^.]*)?$/$1$2.la/;
2801               $type = 'module';
2802             }
2803           else
2804             {
2805               $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.la/;
2806             }
2807           my $suggestion = dirname ($onelib) . "/$bn";
2808           $suggestion =~ s|^\./||g;
2809           msg ('error-gnu/warn', $where,
2810                "`$onelib' is not a standard libtool $type name\n"
2811                . "did you mean `$suggestion'?")
2812         }
2813
2814       ($known_libraries{$onelib} = $bn) =~ s/\.la$//;
2815
2816       $where->push_context ("while processing Libtool library `$onelib'");
2817       $where->set (INTERNAL->get);
2818
2819       # Make sure we look at these.
2820       set_seen ($xlib . '_LDFLAGS');
2821       set_seen ($xlib . '_DEPENDENCIES');
2822       set_seen ('EXTRA_' . $xlib . '_DEPENDENCIES');
2823
2824       # Generate support for conditional object inclusion in
2825       # libraries.
2826       if (var ($xlib . '_LIBADD'))
2827         {
2828           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2829             {
2830               $seen_libobjs = 1;
2831             }
2832         }
2833       else
2834         {
2835           &define_variable ($xlib . "_LIBADD", '', $where);
2836         }
2837
2838       reject_var ("${xlib}_LDADD",
2839                   "use `${xlib}_LIBADD', not `${xlib}_LDADD'");
2840
2841
2842       my $linker = &handle_source_transform ($xlib, $onelib, $obj, $where,
2843                                              NONLIBTOOL => 0, LIBTOOL => 1);
2844
2845       # Determine program to use for link.
2846       my($xlink, $vlink) = &define_per_target_linker_variable ($linker, $xlib);
2847       $vlink = verbose_flag ($vlink || 'GEN');
2848
2849       my $rpathvar = "am_${xlib}_rpath";
2850       my $rpath = "\$($rpathvar)";
2851       foreach my $rcond ($instconds{$onelib}->conds)
2852         {
2853           my $val;
2854           if ($instdirs{$onelib}{$rcond} eq 'EXTRA'
2855               || $instdirs{$onelib}{$rcond} eq 'noinst'
2856               || $instdirs{$onelib}{$rcond} eq 'check')
2857             {
2858               # It's an EXTRA_ library, so we can't specify -rpath,
2859               # because we don't know where the library will end up.
2860               # The user probably knows, but generally speaking automake
2861               # doesn't -- and in fact configure could decide
2862               # dynamically between two different locations.
2863               $val = '';
2864             }
2865           else
2866             {
2867               $val = ('-rpath $(' . $instdirs{$onelib}{$rcond} . 'dir)');
2868               $val .= $instsubdirs{$onelib}{$rcond}
2869                 if defined $instsubdirs{$onelib}{$rcond};
2870             }
2871           if ($rcond->true)
2872             {
2873               # If $rcond is true there is only one condition and
2874               # there is no point defining an helper variable.
2875               $rpath = $val;
2876             }
2877           else
2878             {
2879               define_pretty_variable ($rpathvar, $rcond, INTERNAL, $val);
2880             }
2881         }
2882
2883       # If the resulting library lies into a subdirectory,
2884       # make sure this directory will exist.
2885       my $dirstamp = require_build_directory_maybe ($onelib);
2886
2887       # Remember to cleanup .libs/ in this directory.
2888       my $dirname = dirname $onelib;
2889       $libtool_clean_directories{$dirname} = 1;
2890
2891       $output_rules .= &file_contents ('ltlibrary',
2892                                        $where,
2893                                        LTLIBRARY  => $onelib,
2894                                        XLTLIBRARY => $xlib,
2895                                        RPATH      => $rpath,
2896                                        XLINK      => $xlink,
2897                                        VERBOSE    => $vlink,
2898                                        DIRSTAMP   => $dirstamp);
2899       if ($seen_libobjs)
2900         {
2901           if (var ($xlib . '_LIBADD'))
2902             {
2903               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2904             }
2905         }
2906
2907       if (! $seen_ar)
2908         {
2909           msg ('extra-portability', $where,
2910                "`$onelib': linking libtool libraries using a non-POSIX\n"
2911                . "archiver requires `AM_PROG_AR' in `$configure_ac'")
2912         }
2913     }
2914 }
2915
2916 # See if any _SOURCES variable were misspelled.
2917 sub check_typos ()
2918 {
2919   # It is ok if the user sets this particular variable.
2920   set_seen 'AM_LDFLAGS';
2921
2922   foreach my $primary ('SOURCES', 'LIBADD', 'LDADD', 'LDFLAGS', 'DEPENDENCIES')
2923     {
2924       foreach my $var (variables $primary)
2925         {
2926           my $varname = $var->name;
2927           # A configure variable is always legitimate.
2928           next if exists $configure_vars{$varname};
2929
2930           for my $cond ($var->conditions->conds)
2931             {
2932               $varname =~ /^(?:EXTRA_)?(?:nobase_)?(?:dist_|nodist_)?(.*)_[[:alnum:]]+$/;
2933               msg_var ('syntax', $var, "variable `$varname' is defined but no"
2934                        . " program or\nlibrary has `$1' as canonical name"
2935                        . " (possible typo)")
2936                 unless $var->rdef ($cond)->seen;
2937             }
2938         }
2939     }
2940 }
2941
2942
2943 # Handle scripts.
2944 sub handle_scripts
2945 {
2946     # NOTE we no longer automatically clean SCRIPTS, because it is
2947     # useful to sometimes distribute scripts verbatim.  This happens
2948     # e.g. in Automake itself.
2949     &am_install_var ('-candist', 'scripts', 'SCRIPTS',
2950                      'bin', 'sbin', 'libexec', 'pkglibexec', 'pkgdata',
2951                      'noinst', 'check');
2952 }
2953
2954
2955
2956
2957 ## ------------------------ ##
2958 ## Handling Texinfo files.  ##
2959 ## ------------------------ ##
2960
2961 # ($OUTFILE, $VFILE, @CLEAN_FILES)
2962 # &scan_texinfo_file ($FILENAME)
2963 # ------------------------------
2964 # $OUTFILE     - name of the info file produced by $FILENAME.
2965 # $VFILE       - name of the version.texi file used (undef if none).
2966 # @CLEAN_FILES - list of byproducts (indexes etc.)
2967 sub scan_texinfo_file ($)
2968 {
2969   my ($filename) = @_;
2970
2971   # Some of the following extensions are always created, no matter
2972   # whether indexes are used or not.  Other (like cps, fns, ... pgs)
2973   # are only created when they are used.  We used to scan $FILENAME
2974   # for their use, but that is not enough: they could be used in
2975   # included files.  We can't scan included files because we don't
2976   # know the include path.  Therefore we always erase these files, no
2977   # matter whether they are used or not.
2978   #
2979   # (tmp is only created if an @macro is used and a certain e-TeX
2980   # feature is not available.)
2981   my %clean_suffixes =
2982     map { $_ => 1 } (qw(aux log toc tmp
2983                         cp cps
2984                         fn fns
2985                         ky kys
2986                         vr vrs
2987                         tp tps
2988                         pg pgs)); # grep 'new.*index' texinfo.tex
2989
2990   my $texi = new Automake::XFile "< $filename";
2991   verb "reading $filename";
2992
2993   my ($outfile, $vfile);
2994   while ($_ = $texi->getline)
2995     {
2996       if (/^\@setfilename +(\S+)/)
2997         {
2998           # Honor only the first @setfilename.  (It's possible to have
2999           # more occurrences later if the manual shows examples of how
3000           # to use @setfilename...)
3001           next if $outfile;
3002
3003           $outfile = $1;
3004           if ($outfile =~ /\.([^.]+)$/ && $1 ne 'info')
3005             {
3006               error ("$filename:$.",
3007                      "output `$outfile' has unrecognized extension");
3008               return;
3009             }
3010         }
3011       # A "version.texi" file is actually any file whose name matches
3012       # "vers*.texi".
3013       elsif (/^\@include\s+(vers[^.]*\.texi)\s*$/)
3014         {
3015           $vfile = $1;
3016         }
3017
3018       # Try to find new or unused indexes.
3019
3020       # Creating a new category of index.
3021       elsif (/^\@def(code)?index (\w+)/)
3022         {
3023           $clean_suffixes{$2} = 1;
3024           $clean_suffixes{"$2s"} = 1;
3025         }
3026
3027       # Merging an index into an another.
3028       elsif (/^\@syn(code)?index (\w+) (\w+)/)
3029         {
3030           delete $clean_suffixes{"$2s"};
3031           $clean_suffixes{"$3s"} = 1;
3032         }
3033
3034     }
3035
3036   if (! $outfile)
3037     {
3038       err_am "`$filename' missing \@setfilename";
3039       return;
3040     }
3041
3042   my $infobase = basename ($filename);
3043   $infobase =~ s/\.te?xi(nfo)?$//;
3044   return ($outfile, $vfile,
3045           map { "$infobase.$_" } (sort keys %clean_suffixes));
3046 }
3047
3048
3049 # ($DIRSTAMP, @CLEAN_FILES)
3050 # output_texinfo_build_rules ($SOURCE, $DEST, $INSRC, @DEPENDENCIES)
3051 # ------------------------------------------------------------------
3052 # SOURCE - the source Texinfo file
3053 # DEST - the destination Info file
3054 # INSRC - whether DEST should be built in the source tree
3055 # DEPENDENCIES - known dependencies
3056 sub output_texinfo_build_rules ($$$@)
3057 {
3058   my ($source, $dest, $insrc, @deps) = @_;
3059
3060   # Split `a.texi' into `a' and `.texi'.
3061   my ($spfx, $ssfx) = ($source =~ /^(.*?)(\.[^.]*)?$/);
3062   my ($dpfx, $dsfx) = ($dest =~ /^(.*?)(\.[^.]*)?$/);
3063
3064   $ssfx ||= "";
3065   $dsfx ||= "";
3066
3067   # We can output two kinds of rules: the "generic" rules use Make
3068   # suffix rules and are appropriate when $source and $dest do not lie
3069   # in a sub-directory; the "specific" rules are needed in the other
3070   # case.
3071   #
3072   # The former are output only once (this is not really apparent here,
3073   # but just remember that some logic deeper in Automake will not
3074   # output the same rule twice); while the later need to be output for
3075   # each Texinfo source.
3076   my $generic;
3077   my $makeinfoflags;
3078   my $sdir = dirname $source;
3079   if ($sdir eq '.' && dirname ($dest) eq '.')
3080     {
3081       $generic = 1;
3082       $makeinfoflags = '-I $(srcdir)';
3083     }
3084   else
3085     {
3086       $generic = 0;
3087       $makeinfoflags = "-I $sdir -I \$(srcdir)/$sdir";
3088     }
3089
3090   # A directory can contain two kinds of info files: some built in the
3091   # source tree, and some built in the build tree.  The rules are
3092   # different in each case.  However we cannot output two different
3093   # set of generic rules.  Because in-source builds are more usual, we
3094   # use generic rules in this case and fall back to "specific" rules
3095   # for build-dir builds.  (It should not be a problem to invert this
3096   # if needed.)
3097   $generic = 0 unless $insrc;
3098
3099   # We cannot use a suffix rule to build info files with an empty
3100   # extension.  Otherwise we would output a single suffix inference
3101   # rule, with separate dependencies, as in
3102   #
3103   #    .texi:
3104   #             $(MAKEINFO) ...
3105   #    foo.info: foo.texi
3106   #
3107   # which confuse Solaris make.  (See the Autoconf manual for
3108   # details.)  Therefore we use a specific rule in this case.  This
3109   # applies to info files only (dvi and pdf files always have an
3110   # extension).
3111   my $generic_info = ($generic && $dsfx) ? 1 : 0;
3112
3113   # If the resulting file lie into a subdirectory,
3114   # make sure this directory will exist.
3115   my $dirstamp = require_build_directory_maybe ($dest);
3116
3117   my $dipfx = ($insrc ? '$(srcdir)/' : '') . $dpfx;
3118
3119   $output_rules .= file_contents ('texibuild',
3120                                   new Automake::Location,
3121                                   AM_V_MAKEINFO    => verbose_flag('MAKEINFO'),
3122                                   AM_V_TEXI2DVI    => verbose_flag('TEXI2DVI'),
3123                                   AM_V_TEXI2PDF    => verbose_flag('TEXI2PDF'),
3124                                   DEPS             => "@deps",
3125                                   DEST_PREFIX      => $dpfx,
3126                                   DEST_INFO_PREFIX => $dipfx,
3127                                   DEST_SUFFIX      => $dsfx,
3128                                   DIRSTAMP         => $dirstamp,
3129                                   GENERIC          => $generic,
3130                                   GENERIC_INFO     => $generic_info,
3131                                   INSRC            => $insrc,
3132                                   MAKEINFOFLAGS    => $makeinfoflags,
3133                                   SILENT           => silent_flag(),
3134                                   SOURCE           => ($generic
3135                                                        ? '$<' : $source),
3136                                   SOURCE_INFO      => ($generic_info
3137                                                        ? '$<' : $source),
3138                                   SOURCE_REAL      => $source,
3139                                   SOURCE_SUFFIX    => $ssfx,
3140                                   TEXIQUIET        => verbose_flag('texinfo'),
3141                                   TEXIDEVNULL      => verbose_flag('texidevnull'),
3142                                   );
3143   return ($dirstamp, "$dpfx.dvi", "$dpfx.pdf", "$dpfx.ps", "$dpfx.html");
3144 }
3145
3146
3147 # ($MOSTLYCLEAN, $TEXICLEAN, $MAINTCLEAN)
3148 # handle_texinfo_helper ($info_texinfos)
3149 # --------------------------------------
3150 # Handle all Texinfo source; helper for handle_texinfo.
3151 sub handle_texinfo_helper ($)
3152 {
3153   my ($info_texinfos) = @_;
3154   my (@infobase, @info_deps_list, @texi_deps);
3155   my %versions;
3156   my $done = 0;
3157   my (@mostly_cleans, @texi_cleans, @maint_cleans) = ('', '', '');
3158
3159   # Build a regex matching user-cleaned files.
3160   my $d = var 'DISTCLEANFILES';
3161   my $c = var 'CLEANFILES';
3162   my @f = ();
3163   push @f, $d->value_as_list_recursive (inner_expand => 1) if $d;
3164   push @f, $c->value_as_list_recursive (inner_expand => 1) if $c;
3165   @f = map { s|[^A-Za-z_0-9*\[\]\-]|\\$&|g; s|\*|[^/]*|g; $_; } @f;
3166   my $user_cleaned_files = '^(?:' . join ('|', @f) . ')$';
3167
3168   foreach my $texi
3169       ($info_texinfos->value_as_list_recursive (inner_expand => 1))
3170     {
3171       my $infobase = $texi;
3172       $infobase =~ s/\.(txi|texinfo|texi)$//;
3173
3174       if ($infobase eq $texi)
3175         {
3176           # FIXME: report line number.
3177           err_am "texinfo file `$texi' has unrecognized extension";
3178           next;
3179         }
3180
3181       push @infobase, $infobase;
3182
3183       # If 'version.texi' is referenced by input file, then include
3184       # automatic versioning capability.
3185       my ($out_file, $vtexi, @clean_files) =
3186         scan_texinfo_file ("$relative_dir/$texi")
3187         or next;
3188       push (@mostly_cleans, @clean_files);
3189
3190       # If the Texinfo source is in a subdirectory, create the
3191       # resulting info in this subdirectory.  If it is in the current
3192       # directory, try hard to not prefix "./" because it breaks the
3193       # generic rules.
3194       my $outdir = dirname ($texi) . '/';
3195       $outdir = "" if $outdir eq './';
3196       $out_file =  $outdir . $out_file;
3197
3198       # Until Automake 1.6.3, .info files were built in the
3199       # source tree.  This was an obstacle to the support of
3200       # non-distributed .info files, and non-distributed .texi
3201       # files.
3202       #
3203       # * Non-distributed .texi files is important in some packages
3204       #   where .texi files are built at make time, probably using
3205       #   other binaries built in the package itself, maybe using
3206       #   tools or information found on the build host.  Because
3207       #   these files are not distributed they are always rebuilt
3208       #   at make time; they should therefore not lie in the source
3209       #   directory.  One plan was to support this using
3210       #   nodist_info_TEXINFOS or something similar.  (Doing this
3211       #   requires some sanity checks.  For instance Automake should
3212       #   not allow:
3213       #      dist_info_TEXINFOS = foo.texi
3214       #      nodist_foo_TEXINFOS = included.texi
3215       #   because a distributed file should never depend on a
3216       #   non-distributed file.)
3217       #
3218       # * If .texi files are not distributed, then .info files should
3219       #   not be distributed either.  There are also cases where one
3220       #   wants to distribute .texi files, but does not want to
3221       #   distribute the .info files.  For instance the Texinfo package
3222       #   distributes the tool used to build these files; it would
3223       #   be a waste of space to distribute them.  It's not clear
3224       #   which syntax we should use to indicate that .info files should
3225       #   not be distributed.  Akim Demaille suggested that eventually
3226       #   we switch to a new syntax:
3227       #   |  Maybe we should take some inspiration from what's already
3228       #   |  done in the rest of Automake.  Maybe there is too much
3229       #   |  syntactic sugar here, and you want
3230       #   |     nodist_INFO = bar.info
3231       #   |     dist_bar_info_SOURCES = bar.texi
3232       #   |     bar_texi_DEPENDENCIES = foo.texi
3233       #   |  with a bit of magic to have bar.info represent the whole
3234       #   |  bar*info set.  That's a lot more verbose that the current
3235       #   |  situation, but it is # not new, hence the user has less
3236       #   |  to learn.
3237       #   |
3238       #   |  But there is still too much room for meaningless specs:
3239       #   |     nodist_INFO = bar.info
3240       #   |     dist_bar_info_SOURCES = bar.texi
3241       #   |     dist_PS = bar.ps something-written-by-hand.ps
3242       #   |     nodist_bar_ps_SOURCES = bar.texi
3243       #   |     bar_texi_DEPENDENCIES = foo.texi
3244       #   |  here bar.texi is dist_ in line 2, and nodist_ in 4.
3245       #
3246       # Back to the point, it should be clear that in order to support
3247       # non-distributed .info files, we need to build them in the
3248       # build tree, not in the source tree (non-distributed .texi
3249       # files are less of a problem, because we do not output build
3250       # rules for them).  In Automake 1.7 .info build rules have been
3251       # largely cleaned up so that .info files get always build in the
3252       # build tree, even when distributed.  The idea was that
3253       #   (1) if during a VPATH build the .info file was found to be
3254       #       absent or out-of-date (in the source tree or in the
3255       #       build tree), Make would rebuild it in the build tree.
3256       #       If an up-to-date source-tree of the .info file existed,
3257       #       make would not rebuild it in the build tree.
3258       #   (2) having two copies of .info files, one in the source tree
3259       #       and one (newer) in the build tree is not a problem
3260       #       because `make dist' always pick files in the build tree
3261       #       first.
3262       # However it turned out the be a bad idea for several reasons:
3263       #   * Tru64, OpenBSD, and FreeBSD (not NetBSD) Make do not behave
3264       #     like GNU Make on point (1) above.  These implementations
3265       #     of Make would always rebuild .info files in the build
3266       #     tree, even if such files were up to date in the source
3267       #     tree.  Consequently, it was impossible to perform a VPATH
3268       #     build of a package containing Texinfo files using these
3269       #     Make implementations.
3270       #     (Refer to the Autoconf Manual, section "Limitation of
3271       #     Make", paragraph "VPATH", item "target lookup", for
3272       #     an account of the differences between these
3273       #     implementations.)
3274       #   * The GNU Coding Standards require these files to be built
3275       #     in the source-tree (when they are distributed, that is).
3276       #   * Keeping a fresher copy of distributed files in the
3277       #     build tree can be annoying during development because
3278       #     - if the files is kept under CVS, you really want it
3279       #       to be updated in the source tree
3280       #     - it is confusing that `make distclean' does not erase
3281       #       all files in the build tree.
3282       #
3283       # Consequently, starting with Automake 1.8, .info files are
3284       # built in the source tree again.  Because we still plan to
3285       # support non-distributed .info files at some point, we
3286       # have a single variable ($INSRC) that controls whether
3287       # the current .info file must be built in the source tree
3288       # or in the build tree.  Actually this variable is switched
3289       # off for .info files that appear to be cleaned; this is
3290       # for backward compatibility with package such as Texinfo,
3291       # which do things like
3292       #   info_TEXINFOS = texinfo.txi info-stnd.texi info.texi
3293       #   DISTCLEANFILES = texinfo texinfo-* info*.info*
3294       #   # Do not create info files for distribution.
3295       #   dist-info:
3296       # in order not to distribute .info files.
3297       my $insrc = ($out_file =~ $user_cleaned_files) ? 0 : 1;
3298
3299       my $soutdir = '$(srcdir)/' . $outdir;
3300       $outdir = $soutdir if $insrc;
3301
3302       # If user specified file_TEXINFOS, then use that as explicit
3303       # dependency list.
3304       @texi_deps = ();
3305       push (@texi_deps, "$soutdir$vtexi") if $vtexi;
3306
3307       my $canonical = canonicalize ($infobase);
3308       if (var ($canonical . "_TEXINFOS"))
3309         {
3310           push (@texi_deps, '$(' . $canonical . '_TEXINFOS)');
3311           push_dist_common ('$(' . $canonical . '_TEXINFOS)');
3312         }
3313
3314       my ($dirstamp, @cfiles) =
3315         output_texinfo_build_rules ($texi, $out_file, $insrc, @texi_deps);
3316       push (@texi_cleans, @cfiles);
3317
3318       push (@info_deps_list, $out_file);
3319
3320       # If a vers*.texi file is needed, emit the rule.
3321       if ($vtexi)
3322         {
3323           err_am ("`$vtexi', included in `$texi', "
3324                   . "also included in `$versions{$vtexi}'")
3325             if defined $versions{$vtexi};
3326           $versions{$vtexi} = $texi;
3327
3328           # We number the stamp-vti files.  This is doable since the
3329           # actual names don't matter much.  We only number starting
3330           # with the second one, so that the common case looks nice.
3331           my $vti = ($done ? $done : 'vti');
3332           ++$done;
3333
3334           # This is ugly, but it is our historical practice.
3335           if ($config_aux_dir_set_in_configure_ac)
3336             {
3337               require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3338                                             'mdate-sh');
3339             }
3340           else
3341             {
3342               require_file_with_macro (TRUE, 'info_TEXINFOS',
3343                                        FOREIGN, 'mdate-sh');
3344             }
3345
3346           my $conf_dir;
3347           if ($config_aux_dir_set_in_configure_ac)
3348             {
3349               $conf_dir = "$am_config_aux_dir/";
3350             }
3351           else
3352             {
3353               $conf_dir = '$(srcdir)/';
3354             }
3355           $output_rules .= file_contents ('texi-vers',
3356                                           new Automake::Location,
3357                                           TEXI     => $texi,
3358                                           VTI      => $vti,
3359                                           STAMPVTI => "${soutdir}stamp-$vti",
3360                                           VTEXI    => "$soutdir$vtexi",
3361                                           MDDIR    => $conf_dir,
3362                                           DIRSTAMP => $dirstamp);
3363         }
3364     }
3365
3366   # Handle location of texinfo.tex.
3367   my $need_texi_file = 0;
3368   my $texinfodir;
3369   if (var ('TEXINFO_TEX'))
3370     {
3371       # The user defined TEXINFO_TEX so assume he knows what he is
3372       # doing.
3373       $texinfodir = ('$(srcdir)/'
3374                      . dirname (variable_value ('TEXINFO_TEX')));
3375     }
3376   elsif (option 'cygnus')
3377     {
3378       $texinfodir = '$(top_srcdir)/../texinfo';
3379       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3380     }
3381   elsif ($config_aux_dir_set_in_configure_ac)
3382     {
3383       $texinfodir = $am_config_aux_dir;
3384       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3385       $need_texi_file = 2; # so that we require_conf_file later
3386     }
3387   else
3388     {
3389       $texinfodir = '$(srcdir)';
3390       $need_texi_file = 1;
3391     }
3392   define_variable ('am__TEXINFO_TEX_DIR', $texinfodir, INTERNAL);
3393
3394   push (@dist_targets, 'dist-info');
3395
3396   if (! option 'no-installinfo')
3397     {
3398       # Make sure documentation is made and installed first.  Use
3399       # $(INFO_DEPS), not 'info', because otherwise recursive makes
3400       # get run twice during "make all".
3401       unshift (@all, '$(INFO_DEPS)');
3402     }
3403
3404   define_files_variable ("DVIS", @infobase, 'dvi', INTERNAL);
3405   define_files_variable ("PDFS", @infobase, 'pdf', INTERNAL);
3406   define_files_variable ("PSS", @infobase, 'ps', INTERNAL);
3407   define_files_variable ("HTMLS", @infobase, 'html', INTERNAL);
3408
3409   # This next isn't strictly needed now -- the places that look here
3410   # could easily be changed to look in info_TEXINFOS.  But this is
3411   # probably better, in case noinst_TEXINFOS is ever supported.
3412   define_variable ("TEXINFOS", variable_value ('info_TEXINFOS'), INTERNAL);
3413
3414   # Do some error checking.  Note that this file is not required
3415   # when in Cygnus mode; instead we defined TEXINFO_TEX explicitly
3416   # up above.
3417   if ($need_texi_file && ! option 'no-texinfo.tex')
3418     {
3419       if ($need_texi_file > 1)
3420         {
3421           require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3422                                         'texinfo.tex');
3423         }
3424       else
3425         {
3426           require_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3427                                    'texinfo.tex');
3428         }
3429     }
3430
3431   return (makefile_wrap ("", "\t  ", @mostly_cleans),
3432           makefile_wrap ("", "\t  ", @texi_cleans),
3433           makefile_wrap ("", "\t  ", @maint_cleans));
3434 }
3435
3436
3437 # handle_texinfo ()
3438 # -----------------
3439 # Handle all Texinfo source.
3440 sub handle_texinfo ()
3441 {
3442   reject_var 'TEXINFOS', "`TEXINFOS' is an anachronism; use `info_TEXINFOS'";
3443   # FIXME: I think this is an obsolete future feature name.
3444   reject_var 'html_TEXINFOS', "HTML generation not yet supported";
3445
3446   my $info_texinfos = var ('info_TEXINFOS');
3447   my ($mostlyclean, $clean, $maintclean) = ('', '', '');
3448   if ($info_texinfos)
3449     {
3450       define_verbose_texinfo;
3451       ($mostlyclean, $clean, $maintclean) = handle_texinfo_helper ($info_texinfos);
3452       chomp $mostlyclean;
3453       chomp $clean;
3454       chomp $maintclean;
3455     }
3456
3457   $output_rules .=  file_contents ('texinfos',
3458                                    new Automake::Location,
3459                                    AM_V_DVIPS    => verbose_flag('DVIPS'),
3460                                    MOSTLYCLEAN   => $mostlyclean,
3461                                    TEXICLEAN     => $clean,
3462                                    MAINTCLEAN    => $maintclean,
3463                                    'LOCAL-TEXIS' => !!$info_texinfos,
3464                                    TEXIQUIET     => verbose_flag('texinfo'));
3465 }
3466
3467
3468 # Handle any man pages.
3469 sub handle_man_pages
3470 {
3471   reject_var 'MANS', "`MANS' is an anachronism; use `man_MANS'";
3472
3473   # Find all the sections in use.  We do this by first looking for
3474   # "standard" sections, and then looking for any additional
3475   # sections used in man_MANS.
3476   my (%sections, %notrans_sections, %trans_sections,
3477       %notrans_vars, %trans_vars, %notrans_sect_vars, %trans_sect_vars);
3478   # We handle nodist_ for uniformity.  man pages aren't distributed
3479   # by default so it isn't actually very important.
3480   foreach my $npfx ('', 'notrans_')
3481     {
3482       foreach my $pfx ('', 'dist_', 'nodist_')
3483         {
3484           # Add more sections as needed.
3485           foreach my $section ('0'..'9', 'n', 'l')
3486             {
3487               my $varname = $npfx . $pfx . 'man' . $section . '_MANS';
3488               if (var ($varname))
3489                 {
3490                   $sections{$section} = 1;
3491                   $varname = '$(' . $varname . ')';
3492                   if ($npfx eq 'notrans_')
3493                     {
3494                       $notrans_sections{$section} = 1;
3495                       $notrans_sect_vars{$varname} = 1;
3496                     }
3497                   else
3498                     {
3499                       $trans_sections{$section} = 1;
3500                       $trans_sect_vars{$varname} = 1;
3501                     }
3502
3503                   &push_dist_common ($varname)
3504                     if $pfx eq 'dist_';
3505                 }
3506             }
3507
3508           my $varname = $npfx . $pfx . 'man_MANS';
3509           my $var = var ($varname);
3510           if ($var)
3511             {
3512               foreach ($var->value_as_list_recursive)
3513                 {
3514                   # A page like `foo.1c' goes into man1dir.
3515                   if (/\.([0-9a-z])([a-z]*)$/)
3516                     {
3517                       $sections{$1} = 1;
3518                       if ($npfx eq 'notrans_')
3519                         {
3520                           $notrans_sections{$1} = 1;
3521                         }
3522                       else
3523                         {
3524                           $trans_sections{$1} = 1;
3525                         }
3526                     }
3527                 }
3528
3529               $varname = '$(' . $varname . ')';
3530               if ($npfx eq 'notrans_')
3531                 {
3532                   $notrans_vars{$varname} = 1;
3533                 }
3534               else
3535                 {
3536                   $trans_vars{$varname} = 1;
3537                 }
3538               &push_dist_common ($varname)
3539                 if $pfx eq 'dist_';
3540             }
3541         }
3542     }
3543
3544   return unless %sections;
3545
3546   my @unsorted_deps;
3547
3548   # Build section independent variables.
3549   my $have_notrans = %notrans_vars;
3550   my @notrans_list = sort keys %notrans_vars;
3551   my $have_trans = %trans_vars;
3552   my @trans_list = sort keys %trans_vars;
3553
3554   # Now for each section, generate an install and uninstall rule.
3555   # Sort sections so output is deterministic.
3556   foreach my $section (sort keys %sections)
3557     {
3558       # Build section dependent variables.
3559       my $notrans_mans = $have_notrans || exists $notrans_sections{$section};
3560       my $trans_mans = $have_trans || exists $trans_sections{$section};
3561       my (%notrans_this_sect, %trans_this_sect);
3562       my $expr = 'man' . $section . '_MANS';
3563       foreach my $varname (keys %notrans_sect_vars)
3564         {
3565           if ($varname =~ /$expr/)
3566             {
3567               $notrans_this_sect{$varname} = 1;
3568             }
3569         }
3570       foreach my $varname (keys %trans_sect_vars)
3571         {
3572           if ($varname =~ /$expr/)
3573             {
3574               $trans_this_sect{$varname} = 1;
3575             }
3576         }
3577       my @notrans_sect_list = sort keys %notrans_this_sect;
3578       my @trans_sect_list = sort keys %trans_this_sect;
3579       @unsorted_deps = (keys %notrans_vars, keys %trans_vars,
3580                         keys %notrans_this_sect, keys %trans_this_sect);
3581       my @deps = sort @unsorted_deps;
3582       $output_rules .= &file_contents ('mans',
3583                                        new Automake::Location,
3584                                        SECTION           => $section,
3585                                        DEPS              => "@deps",
3586                                        NOTRANS_MANS      => $notrans_mans,
3587                                        NOTRANS_SECT_LIST => "@notrans_sect_list",
3588                                        HAVE_NOTRANS      => $have_notrans,
3589                                        NOTRANS_LIST      => "@notrans_list",
3590                                        TRANS_MANS        => $trans_mans,
3591                                        TRANS_SECT_LIST   => "@trans_sect_list",
3592                                        HAVE_TRANS        => $have_trans,
3593                                        TRANS_LIST        => "@trans_list");
3594     }
3595
3596   @unsorted_deps  = (keys %notrans_vars, keys %trans_vars,
3597                      keys %notrans_sect_vars, keys %trans_sect_vars);
3598   my @mans = sort @unsorted_deps;
3599   $output_vars .= file_contents ('mans-vars',
3600                                  new Automake::Location,
3601                                  MANS => "@mans");
3602
3603   push (@all, '$(MANS)')
3604     unless option 'no-installman';
3605 }
3606
3607 # Handle DATA variables.
3608 sub handle_data
3609 {
3610     &am_install_var ('-noextra', '-candist', 'data', 'DATA',
3611                      'data', 'dataroot', 'doc', 'dvi', 'html', 'pdf',
3612                      'ps', 'sysconf', 'sharedstate', 'localstate',
3613                      'pkgdata', 'lisp', 'noinst', 'check');
3614 }
3615
3616 # Handle TAGS.
3617 sub handle_tags
3618 {
3619     my @tag_deps = ();
3620     my @ctag_deps = ();
3621     my @cscope_deps = ();
3622     if (var ('SUBDIRS'))
3623     {
3624         $output_rules .= ("tags-recursive:\n"
3625                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
3626                           # Never fail here if a subdir fails; it
3627                           # isn't important.
3628                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3629                           . " && \$(MAKE) \$(AM_MAKEFLAGS) tags); \\\n"
3630                           . "\tdone\n");
3631         push (@tag_deps, 'tags-recursive');
3632         &depend ('.PHONY', 'tags-recursive');
3633         &depend ('.MAKE', 'tags-recursive');
3634
3635         $output_rules .= ("ctags-recursive:\n"
3636                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
3637                           # Never fail here if a subdir fails; it
3638                           # isn't important.
3639                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3640                           . " && \$(MAKE) \$(AM_MAKEFLAGS) ctags); \\\n"
3641                           . "\tdone\n");
3642         push (@ctag_deps, 'ctags-recursive');
3643         &depend ('.PHONY', 'ctags-recursive');
3644         &depend ('.MAKE', 'ctags-recursive');
3645
3646         $output_rules .= ("cscopelist-recursive:\n"
3647                           . "\tlist=\'\$(SUBDIRS)\'; for subdir in \$\$list; do \\\n"
3648                           # Never fail here if a subdir fails; it
3649                           # isn't important.
3650                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3651                           . " && \$(MAKE) \$(AM_MAKEFLAGS) cscopelist); \\\n"
3652                           . "\tdone\n");
3653         push (@cscope_deps, 'cscopelist-recursive');
3654         &depend ('.PHONY', 'cscopelist-recursive');
3655         &depend ('.MAKE', 'cscopelist-recursive');
3656     }
3657
3658     if (&saw_sources_p (1)
3659         || var ('ETAGS_ARGS')
3660         || @tag_deps)
3661     {
3662         my @config;
3663         foreach my $spec (@config_headers)
3664         {
3665             my ($out, @ins) = split_config_file_spec ($spec);
3666             foreach my $in (@ins)
3667               {
3668                 # If the config header source is in this directory,
3669                 # require it.
3670                 push @config, basename ($in)
3671                   if $relative_dir eq dirname ($in);
3672               }
3673         }
3674         $output_rules .= &file_contents ('tags',
3675                                          new Automake::Location,
3676                                          CONFIG    => "@config",
3677                                          TAGSDIRS  => "@tag_deps",
3678                                          CTAGSDIRS => "@ctag_deps",
3679                                          CSCOPEDIRS => "@cscope_deps");
3680
3681         set_seen 'TAGS_DEPENDENCIES';
3682     }
3683     elsif (reject_var ('TAGS_DEPENDENCIES',
3684                        "it doesn't make sense to define `TAGS_DEPENDENCIES'"
3685                        . " without\nsources or `ETAGS_ARGS'"))
3686     {
3687     }
3688     else
3689     {
3690         # Every Makefile must define some sort of TAGS rule.
3691         # Otherwise, it would be possible for a top-level "make TAGS"
3692         # to fail because some subdirectory failed.
3693         $output_rules .= "tags: TAGS\nTAGS:\n\n";
3694         # Ditto ctags and cscope.
3695         $output_rules .= "ctags: CTAGS\nCTAGS:\n\n";
3696         $output_rules .= "cscope cscopelist:\n\n";
3697     }
3698 }
3699
3700 # Handle multilib support.
3701 sub handle_multilib
3702 {
3703   if ($seen_multilib && $relative_dir eq '.')
3704     {
3705       $output_rules .= &file_contents ('multilib', new Automake::Location);
3706       push (@all, 'all-multi');
3707     }
3708 }
3709
3710
3711 # user_phony_rule ($NAME)
3712 # -----------------------
3713 # Return false if rule $NAME does not exist.  Otherwise,
3714 # declare it as phony, complete its definition (in case it is
3715 # conditional), and return its Automake::Rule instance.
3716 sub user_phony_rule ($)
3717 {
3718   my ($name) = @_;
3719   my $rule = rule $name;
3720   if ($rule)
3721     {
3722       depend ('.PHONY', $name);
3723       # Define $NAME in all condition where it is not already defined,
3724       # so that it is always OK to depend on $NAME.
3725       for my $c ($rule->not_always_defined_in_cond (TRUE)->conds)
3726         {
3727           Automake::Rule::define ($name, 'internal', RULE_AUTOMAKE,
3728                                   $c, INTERNAL);
3729           $output_rules .= $c->subst_string . "$name:\n";
3730         }
3731     }
3732   return $rule;
3733 }
3734
3735
3736 # $BOOLEAN
3737 # &for_dist_common ($A, $B)
3738 # -------------------------
3739 # Subroutine for &handle_dist: sort files to dist.
3740 #
3741 # We put README first because it then becomes easier to make a
3742 # Usenet-compliant shar file (in these, README must be first).
3743 #
3744 # FIXME: do more ordering of files here.
3745 sub for_dist_common
3746 {
3747     return 0
3748         if $a eq $b;
3749     return -1
3750         if $a eq 'README';
3751     return 1
3752         if $b eq 'README';
3753     return $a cmp $b;
3754 }
3755
3756 # handle_dist
3757 # -----------
3758 # Handle 'dist' target.
3759 sub handle_dist ()
3760 {
3761   # Substitutions for distdir.am
3762   my %transform;
3763
3764   # Define DIST_SUBDIRS.  This must always be done, regardless of the
3765   # no-dist setting: target like `distclean' or `maintainer-clean' use it.
3766   my $subdirs = var ('SUBDIRS');
3767   if ($subdirs)
3768     {
3769       # If SUBDIRS is conditionally defined, then set DIST_SUBDIRS
3770       # to all possible directories, and use it.  If DIST_SUBDIRS is
3771       # defined, just use it.
3772
3773       # Note that we check DIST_SUBDIRS first on purpose, so that
3774       # we don't call has_conditional_contents for now reason.
3775       # (In the past one project used so many conditional subdirectories
3776       # that calling has_conditional_contents on SUBDIRS caused
3777       # automake to grow to 150Mb -- this should not happen with
3778       # the current implementation of has_conditional_contents,
3779       # but it's more efficient to avoid the call anyway.)
3780       if (var ('DIST_SUBDIRS'))
3781         {
3782         }
3783       elsif ($subdirs->has_conditional_contents)
3784         {
3785           define_pretty_variable
3786             ('DIST_SUBDIRS', TRUE, INTERNAL,
3787              uniq ($subdirs->value_as_list_recursive));
3788         }
3789       else
3790         {
3791           # We always define this because that is what `distclean'
3792           # wants.
3793           define_pretty_variable ('DIST_SUBDIRS', TRUE, INTERNAL,
3794                                   '$(SUBDIRS)');
3795         }
3796     }
3797
3798   # The remaining definitions are only required when a dist target is used.
3799   return if option 'no-dist';
3800
3801   # At least one of the archive formats must be enabled.
3802   if ($relative_dir eq '.')
3803     {
3804       my $archive_defined = option 'no-dist-gzip' ? 0 : 1;
3805       $archive_defined ||=
3806         grep { option "dist-$_" } qw(shar zip tarZ bzip2 lzip lzma xz);
3807       error (option 'no-dist-gzip',
3808              "no-dist-gzip specified but no dist-* specified,\n"
3809              . "at least one archive format must be enabled")
3810         unless $archive_defined;
3811     }
3812
3813   # Look for common files that should be included in distribution.
3814   # If the aux dir is set, and it does not have a Makefile.am, then
3815   # we check for these files there as well.
3816   my $check_aux = 0;
3817   if ($relative_dir eq '.'
3818       && $config_aux_dir_set_in_configure_ac)
3819     {
3820       if (! &is_make_dir ($config_aux_dir))
3821         {
3822           $check_aux = 1;
3823         }
3824     }
3825   foreach my $cfile (@common_files)
3826     {
3827       if (dir_has_case_matching_file ($relative_dir, $cfile)
3828           # The file might be absent, but if it can be built it's ok.
3829           || rule $cfile)
3830         {
3831           &push_dist_common ($cfile);
3832         }
3833
3834       # Don't use `elsif' here because a file might meaningfully
3835       # appear in both directories.
3836       if ($check_aux && dir_has_case_matching_file ($config_aux_dir, $cfile))
3837         {
3838           &push_dist_common ("$config_aux_dir/$cfile")
3839         }
3840     }
3841
3842   # We might copy elements from $configure_dist_common to
3843   # %dist_common if we think we need to.  If the file appears in our
3844   # directory, we would have discovered it already, so we don't
3845   # check that.  But if the file is in a subdir without a Makefile,
3846   # we want to distribute it here if we are doing `.'.  Ugly!
3847   # Also, in some corner cases, it's possible that the following code
3848   # will cause the same file to appear in the $(DIST_COMMON) variables
3849   # of two distinct Makefiles; but this is not a problem, since the
3850   # `distdir' target in `lib/am/distdir.am' can deal with the same
3851   # file being distributed multiple times.
3852   # See also automake bug#9651.
3853   if ($relative_dir eq '.')
3854     {
3855       foreach my $file (split (' ' , $configure_dist_common))
3856         {
3857           my $dir = dirname ($file);
3858           push_dist_common ($file)
3859             if ($dir eq '.' || ! is_make_dir ($dir));
3860         }
3861     }
3862
3863   # Files to distributed.  Don't use ->value_as_list_recursive
3864   # as it recursively expands `$(dist_pkgdata_DATA)' etc.
3865   my @dist_common = split (' ', rvar ('DIST_COMMON')->variable_value);
3866   @dist_common = uniq (sort for_dist_common (@dist_common));
3867   variable_delete 'DIST_COMMON';
3868   define_pretty_variable ('DIST_COMMON', TRUE, INTERNAL, @dist_common);
3869
3870   # Now that we've processed DIST_COMMON, disallow further attempts
3871   # to set it.
3872   $handle_dist_run = 1;
3873
3874   # Scan EXTRA_DIST to see if we need to distribute anything from a
3875   # subdir.  If so, add it to the list.  I didn't want to do this
3876   # originally, but there were so many requests that I finally
3877   # relented.
3878   my $extra_dist = var ('EXTRA_DIST');
3879
3880   $transform{'DISTCHECK-HOOK'} = !! rule 'distcheck-hook';
3881   $transform{'GETTEXT'} = $seen_gettext && !$seen_gettext_external;
3882
3883   # If the target `dist-hook' exists, make sure it is run.  This
3884   # allows users to do random weird things to the distribution
3885   # before it is packaged up.
3886   push (@dist_targets, 'dist-hook')
3887     if user_phony_rule 'dist-hook';
3888   $transform{'DIST-TARGETS'} = join (' ', @dist_targets);
3889
3890   my $flm = option ('filename-length-max');
3891   my $filename_filter = $flm ? '.' x $flm->[1] : '';
3892
3893   $output_rules .= &file_contents ('distdir',
3894                                    new Automake::Location,
3895                                    %transform,
3896                                    FILENAME_FILTER => $filename_filter);
3897 }
3898
3899
3900 # check_directory ($NAME, $WHERE [, $RELATIVE_DIR = "."])
3901 # -------------------------------------------------------
3902 # Ensure $NAME is a directory (in $RELATIVE_DIR), and that it uses a sane
3903 # name.  Use $WHERE as a location in the diagnostic, if any.
3904 sub check_directory ($$;$)
3905 {
3906   my ($dir, $where, $reldir) = @_;
3907   $reldir = '.' unless defined $reldir;
3908
3909   error $where, "required directory $reldir/$dir does not exist"
3910     unless -d "$reldir/$dir";
3911
3912   # If an `obj/' directory exists, BSD make will enter it before
3913   # reading `Makefile'.  Hence the `Makefile' in the current directory
3914   # will not be read.
3915   #
3916   #  % cat Makefile
3917   #  all:
3918   #          echo Hello
3919   #  % cat obj/Makefile
3920   #  all:
3921   #          echo World
3922   #  % make      # GNU make
3923   #  echo Hello
3924   #  Hello
3925   #  % pmake     # BSD make
3926   #  echo World
3927   #  World
3928   msg ('portability', $where,
3929        "naming a subdirectory `obj' causes troubles with BSD make")
3930     if $dir eq 'obj';
3931
3932   # `aux' is probably the most important of the following forbidden name,
3933   # since it's tempting to use it as an AC_CONFIG_AUX_DIR.
3934   msg ('portability', $where,
3935        "name `$dir' is reserved on W32 and DOS platforms")
3936     if grep (/^\Q$dir\E$/i, qw/aux lpt1 lpt2 lpt3 com1 com2 com3 com4 con prn/);
3937 }
3938
3939 # check_directories_in_var ($VARIABLE)
3940 # ------------------------------------
3941 # Recursively check all items in variables $VARIABLE as directories
3942 sub check_directories_in_var ($)
3943 {
3944   my ($var) = @_;
3945   $var->traverse_recursively
3946     (sub
3947      {
3948        my ($var, $val, $cond, $full_cond) = @_;
3949        check_directory ($val, $var->rdef ($cond)->location, $relative_dir);
3950        return ();
3951      },
3952      undef,
3953      skip_ac_subst => 1);
3954 }
3955
3956 # &handle_subdirs ()
3957 # ------------------
3958 # Handle subdirectories.
3959 sub handle_subdirs ()
3960 {
3961   my $subdirs = var ('SUBDIRS');
3962   return
3963     unless $subdirs;
3964
3965   check_directories_in_var $subdirs;
3966
3967   my $dsubdirs = var ('DIST_SUBDIRS');
3968   check_directories_in_var $dsubdirs
3969     if $dsubdirs;
3970
3971   $output_rules .= &file_contents ('subdirs', new Automake::Location);
3972   rvar ('RECURSIVE_TARGETS')->rdef (TRUE)->{'pretty'} = VAR_SORTED; # Gross!
3973 }
3974
3975
3976 # ($REGEN, @DEPENDENCIES)
3977 # &scan_aclocal_m4
3978 # ----------------
3979 # If aclocal.m4 creation is automated, return the list of its dependencies.
3980 sub scan_aclocal_m4 ()
3981 {
3982   my $regen_aclocal = 0;
3983
3984   set_seen 'CONFIG_STATUS_DEPENDENCIES';
3985   set_seen 'CONFIGURE_DEPENDENCIES';
3986
3987   if (-f 'aclocal.m4')
3988     {
3989       &define_variable ("ACLOCAL_M4", '$(top_srcdir)/aclocal.m4', INTERNAL);
3990
3991       my $aclocal = new Automake::XFile "< aclocal.m4";
3992       my $line = $aclocal->getline;
3993       $regen_aclocal = $line =~ 'generated automatically by aclocal';
3994     }
3995
3996   my @ac_deps = ();
3997
3998   if (set_seen ('ACLOCAL_M4_SOURCES'))
3999     {
4000       push (@ac_deps, '$(ACLOCAL_M4_SOURCES)');
4001       msg_var ('obsolete', 'ACLOCAL_M4_SOURCES',
4002                "`ACLOCAL_M4_SOURCES' is obsolete.\n"
4003                . "It should be safe to simply remove it");
4004     }
4005
4006   # Note that it might be possible that aclocal.m4 doesn't exist but
4007   # should be auto-generated.  This case probably isn't very
4008   # important.
4009
4010   return ($regen_aclocal, @ac_deps);
4011 }
4012
4013
4014 # Helper function for substitute_ac_subst_variables.
4015 sub substitute_ac_subst_variables_worker($)
4016 {
4017   my ($token) = @_;
4018   return "\@$token\@" if var $token;
4019   return "\${$token\}";
4020 }
4021
4022 # substitute_ac_subst_variables ($TEXT)
4023 # -------------------------------------
4024 # Replace any occurrence of ${FOO} in $TEXT by @FOO@ if FOO is an AC_SUBST
4025 # variable.
4026 sub substitute_ac_subst_variables ($)
4027 {
4028   my ($text) = @_;
4029   $text =~ s/\${([^ \t=:+{}]+)}/&substitute_ac_subst_variables_worker ($1)/ge;
4030   return $text;
4031 }
4032
4033 # @DEPENDENCIES
4034 # &prepend_srcdir (@INPUTS)
4035 # -------------------------
4036 # Prepend $(srcdir) or $(top_srcdir) to all @INPUTS.  The idea is that
4037 # if an input file has a directory part the same as the current
4038 # directory, then the directory part is simply replaced by $(srcdir).
4039 # But if the directory part is different, then $(top_srcdir) is
4040 # prepended.
4041 sub prepend_srcdir (@)
4042 {
4043   my (@inputs) = @_;
4044   my @newinputs;
4045
4046   foreach my $single (@inputs)
4047     {
4048       if (dirname ($single) eq $relative_dir)
4049         {
4050           push (@newinputs, '$(srcdir)/' . basename ($single));
4051         }
4052       else
4053         {
4054           push (@newinputs, '$(top_srcdir)/' . $single);
4055         }
4056     }
4057   return @newinputs;
4058 }
4059
4060 # @DEPENDENCIES
4061 # rewrite_inputs_into_dependencies ($OUTPUT, @INPUTS)
4062 # ---------------------------------------------------
4063 # Compute a list of dependencies appropriate for the rebuild
4064 # rule of
4065 #   AC_CONFIG_FILES($OUTPUT:$INPUT[0]:$INPUTS[1]:...)
4066 # Also distribute $INPUTs which are not built by another AC_CONFIG_FOOs.
4067 sub rewrite_inputs_into_dependencies ($@)
4068 {
4069   my ($file, @inputs) = @_;
4070   my @res = ();
4071
4072   for my $i (@inputs)
4073     {
4074       # We cannot create dependencies on shell variables.
4075       next if (substitute_ac_subst_variables $i) =~ /\$/;
4076
4077       if (exists $ac_config_files_location{$i} && $i ne $file)
4078         {
4079           my $di = dirname $i;
4080           if ($di eq $relative_dir)
4081             {
4082               $i = basename $i;
4083             }
4084           # In the top-level Makefile we do not use $(top_builddir), because
4085           # we are already there, and since the targets are built without
4086           # a $(top_builddir), it helps BSD Make to match them with
4087           # dependencies.
4088           elsif ($relative_dir ne '.')
4089             {
4090               $i = '$(top_builddir)/' . $i;
4091             }
4092         }
4093       else
4094         {
4095           msg ('error', $ac_config_files_location{$file},
4096                "required file `$i' not found")
4097             unless $i =~ /\$/ || exists $output_files{$i} || -f $i;
4098           ($i) = prepend_srcdir ($i);
4099           push_dist_common ($i);
4100         }
4101       push @res, $i;
4102     }
4103   return @res;
4104 }
4105
4106
4107
4108 # &handle_configure ($MAKEFILE_AM, $MAKEFILE_IN, $MAKEFILE, @INPUTS)
4109 # ------------------------------------------------------------------
4110 # Handle remaking and configure stuff.
4111 # We need the name of the input file, to do proper remaking rules.
4112 sub handle_configure ($$$@)
4113 {
4114   my ($makefile_am, $makefile_in, $makefile, @inputs) = @_;
4115
4116   prog_error 'empty @inputs'
4117     unless @inputs;
4118
4119   my ($rel_makefile_am, $rel_makefile_in) = prepend_srcdir ($makefile_am,
4120                                                             $makefile_in);
4121   my $rel_makefile = basename $makefile;
4122
4123   my $colon_infile = ':' . join (':', @inputs);
4124   $colon_infile = '' if $colon_infile eq ":$makefile.in";
4125   my @rewritten = rewrite_inputs_into_dependencies ($makefile, @inputs);
4126   my ($regen_aclocal_m4, @aclocal_m4_deps) = scan_aclocal_m4;
4127   define_pretty_variable ('am__aclocal_m4_deps', TRUE, INTERNAL,
4128                           @configure_deps, @aclocal_m4_deps,
4129                           '$(top_srcdir)/' . $configure_ac);
4130   my @configuredeps = ('$(am__aclocal_m4_deps)', '$(CONFIGURE_DEPENDENCIES)');
4131   push @configuredeps, '$(ACLOCAL_M4)' if -f 'aclocal.m4';
4132   define_pretty_variable ('am__configure_deps', TRUE, INTERNAL,
4133                           @configuredeps);
4134
4135   my $automake_options = '--' . (global_option 'cygnus' ? 'cygnus' : $strictness_name)
4136                          . (global_option 'no-dependencies' ? ' --ignore-deps' : '');
4137
4138   $output_rules .= file_contents
4139     ('configure',
4140      new Automake::Location,
4141      MAKEFILE              => $rel_makefile,
4142      'MAKEFILE-DEPS'       => "@rewritten",
4143      'CONFIG-MAKEFILE'     => ($relative_dir eq '.') ? '$@' : '$(subdir)/$@',
4144      'MAKEFILE-IN'         => $rel_makefile_in,
4145      'HAVE-MAKEFILE-IN-DEPS' => (@include_stack > 0),
4146      'MAKEFILE-IN-DEPS'    => "@include_stack",
4147      'MAKEFILE-AM'         => $rel_makefile_am,
4148      'AUTOMAKE-OPTIONS'    => $automake_options,
4149      'MAKEFILE-AM-SOURCES' => "$makefile$colon_infile",
4150      'REGEN-ACLOCAL-M4'    => $regen_aclocal_m4,
4151      VERBOSE               => verbose_flag ('GEN'));
4152
4153   if ($relative_dir eq '.')
4154     {
4155       &push_dist_common ('acconfig.h')
4156         if -f 'acconfig.h';
4157     }
4158
4159   # If we have a configure header, require it.
4160   my $hdr_index = 0;
4161   my @distclean_config;
4162   foreach my $spec (@config_headers)
4163     {
4164       $hdr_index += 1;
4165       # $CONFIG_H_PATH: config.h from top level.
4166       my ($config_h_path, @ins) = split_config_file_spec ($spec);
4167       my $config_h_dir = dirname ($config_h_path);
4168
4169       # If the header is in the current directory we want to build
4170       # the header here.  Otherwise, if we're at the topmost
4171       # directory and the header's directory doesn't have a
4172       # Makefile, then we also want to build the header.
4173       if ($relative_dir eq $config_h_dir
4174           || ($relative_dir eq '.' && ! &is_make_dir ($config_h_dir)))
4175         {
4176           my ($cn_sans_dir, $stamp_dir);
4177           if ($relative_dir eq $config_h_dir)
4178             {
4179               $cn_sans_dir = basename ($config_h_path);
4180               $stamp_dir = '';
4181             }
4182           else
4183             {
4184               $cn_sans_dir = $config_h_path;
4185               if ($config_h_dir eq '.')
4186                 {
4187                   $stamp_dir = '';
4188                 }
4189               else
4190                 {
4191                   $stamp_dir = $config_h_dir . '/';
4192                 }
4193             }
4194
4195           # This will also distribute all inputs.
4196           @ins = rewrite_inputs_into_dependencies ($config_h_path, @ins);
4197
4198           # Cannot define rebuild rules for filenames with shell variables.
4199           next if (substitute_ac_subst_variables $config_h_path) =~ /\$/;
4200
4201           # Header defined in this directory.
4202           my @files;
4203           if (-f $config_h_path . '.top')
4204             {
4205               push (@files, "$cn_sans_dir.top");
4206             }
4207           if (-f $config_h_path . '.bot')
4208             {
4209               push (@files, "$cn_sans_dir.bot");
4210             }
4211
4212           push_dist_common (@files);
4213
4214           # For now, acconfig.h can only appear in the top srcdir.
4215           if (-f 'acconfig.h')
4216             {
4217               push (@files, '$(top_srcdir)/acconfig.h');
4218             }
4219
4220           my $stamp = "${stamp_dir}stamp-h${hdr_index}";
4221           $output_rules .=
4222             file_contents ('remake-hdr',
4223                            new Automake::Location,
4224                            FILES            => "@files",
4225                            CONFIG_H         => $cn_sans_dir,
4226                            CONFIG_HIN       => $ins[0],
4227                            CONFIG_H_DEPS    => "@ins",
4228                            CONFIG_H_PATH    => $config_h_path,
4229                            STAMP            => "$stamp");
4230
4231           push @distclean_config, $cn_sans_dir, $stamp;
4232         }
4233     }
4234
4235   $output_rules .= file_contents ('clean-hdr',
4236                                   new Automake::Location,
4237                                   FILES => "@distclean_config")
4238     if @distclean_config;
4239
4240   # Distribute and define mkinstalldirs only if it is already present
4241   # in the package, for backward compatibility (some people may still
4242   # use $(mkinstalldirs)).
4243   my $mkidpath = "$config_aux_dir/mkinstalldirs";
4244   if (-f $mkidpath)
4245     {
4246       # Use require_file so that any existing script gets updated
4247       # by --force-missing.
4248       require_conf_file ($mkidpath, FOREIGN, 'mkinstalldirs');
4249       define_variable ('mkinstalldirs',
4250                        "\$(SHELL) $am_config_aux_dir/mkinstalldirs", INTERNAL);
4251     }
4252   else
4253     {
4254       # Use $(install_sh), not $(MKDIR_P) because the latter requires
4255       # at least one argument, and $(mkinstalldirs) used to work
4256       # even without arguments (e.g. $(mkinstalldirs) $(conditional_dir)).
4257       define_variable ('mkinstalldirs', '$(install_sh) -d', INTERNAL);
4258     }
4259
4260   reject_var ('CONFIG_HEADER',
4261               "`CONFIG_HEADER' is an anachronism; now determined "
4262               . "automatically\nfrom `$configure_ac'");
4263
4264   my @config_h;
4265   foreach my $spec (@config_headers)
4266     {
4267       my ($out, @ins) = split_config_file_spec ($spec);
4268       # Generate CONFIG_HEADER define.
4269       if ($relative_dir eq dirname ($out))
4270         {
4271           push @config_h, basename ($out);
4272         }
4273       else
4274         {
4275           push @config_h, "\$(top_builddir)/$out";
4276         }
4277     }
4278   define_variable ("CONFIG_HEADER", "@config_h", INTERNAL)
4279     if @config_h;
4280
4281   # Now look for other files in this directory which must be remade
4282   # by config.status, and generate rules for them.
4283   my @actual_other_files = ();
4284   # These get cleaned only in a VPATH build.
4285   my @actual_other_vpath_files = ();
4286   foreach my $lfile (@other_input_files)
4287     {
4288       my $file;
4289       my @inputs;
4290       if ($lfile =~ /^([^:]*):(.*)$/)
4291         {
4292           # This is the ":" syntax of AC_OUTPUT.
4293           $file = $1;
4294           @inputs = split (':', $2);
4295         }
4296       else
4297         {
4298           # Normal usage.
4299           $file = $lfile;
4300           @inputs = $file . '.in';
4301         }
4302
4303       # Automake files should not be stored in here, but in %MAKE_LIST.
4304       prog_error ("$lfile in \@other_input_files\n"
4305                   . "\@other_input_files = (@other_input_files)")
4306         if -f $file . '.am';
4307
4308       my $local = basename ($file);
4309
4310       # We skip files that aren't in this directory.  However, if
4311       # the file's directory does not have a Makefile, and we are
4312       # currently doing `.', then we create a rule to rebuild the
4313       # file in the subdir.
4314       my $fd = dirname ($file);
4315       if ($fd ne $relative_dir)
4316         {
4317           if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4318             {
4319               $local = $file;
4320             }
4321           else
4322             {
4323               next;
4324             }
4325         }
4326
4327       my @rewritten_inputs = rewrite_inputs_into_dependencies ($file, @inputs);
4328
4329       # Cannot output rules for shell variables.
4330       next if (substitute_ac_subst_variables $local) =~ /\$/;
4331
4332       my $condstr = '';
4333       my $cond = $ac_config_files_condition{$lfile};
4334       if (defined $cond)
4335         {
4336           $condstr = $cond->subst_string;
4337           Automake::Rule::define ($local, $configure_ac, RULE_AUTOMAKE, $cond,
4338                                   $ac_config_files_location{$file});
4339         }
4340       $output_rules .= ($condstr . $local . ': '
4341                         . '$(top_builddir)/config.status '
4342                         . "@rewritten_inputs\n"
4343                         . $condstr . "\t"
4344                         . 'cd $(top_builddir) && '
4345                         . '$(SHELL) ./config.status '
4346                         . ($relative_dir eq '.' ? '' : '$(subdir)/')
4347                         . '$@'
4348                         . "\n");
4349       push (@actual_other_files, $local);
4350     }
4351
4352   # For links we should clean destinations and distribute sources.
4353   foreach my $spec (@config_links)
4354     {
4355       my ($link, $file) = split /:/, $spec;
4356       # Some people do AC_CONFIG_LINKS($computed).  We only handle
4357       # the DEST:SRC form.
4358       next unless $file;
4359       my $where = $ac_config_files_location{$link};
4360
4361       # Skip destinations that contain shell variables.
4362       if ((substitute_ac_subst_variables $link) !~ /\$/)
4363         {
4364           # We skip links that aren't in this directory.  However, if
4365           # the link's directory does not have a Makefile, and we are
4366           # currently doing `.', then we add the link to CONFIG_CLEAN_FILES
4367           # in `.'s Makefile.in.
4368           my $local = basename ($link);
4369           my $fd = dirname ($link);
4370           if ($fd ne $relative_dir)
4371             {
4372               if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4373                 {
4374                   $local = $link;
4375                 }
4376               else
4377                 {
4378                   $local = undef;
4379                 }
4380             }
4381           if ($file ne $link)
4382             {
4383               push @actual_other_files, $local if $local;
4384             }
4385           else
4386             {
4387               push @actual_other_vpath_files, $local if $local;
4388             }
4389         }
4390
4391       # Do not process sources that contain shell variables.
4392       if ((substitute_ac_subst_variables $file) !~ /\$/)
4393         {
4394           my $fd = dirname ($file);
4395
4396           # We distribute files that are in this directory.
4397           # At the top-level (`.') we also distribute files whose
4398           # directory does not have a Makefile.
4399           if (($fd eq $relative_dir)
4400               || ($relative_dir eq '.' && ! &is_make_dir ($fd)))
4401             {
4402               # The following will distribute $file as a side-effect when
4403               # it is appropriate (i.e., when $file is not already an output).
4404               # We do not need the result, just the side-effect.
4405               rewrite_inputs_into_dependencies ($link, $file);
4406             }
4407         }
4408     }
4409
4410   # These files get removed by "make distclean".
4411   define_pretty_variable ('CONFIG_CLEAN_FILES', TRUE, INTERNAL,
4412                           @actual_other_files);
4413   define_pretty_variable ('CONFIG_CLEAN_VPATH_FILES', TRUE, INTERNAL,
4414                           @actual_other_vpath_files);
4415 }
4416
4417 # Handle C headers.
4418 sub handle_headers
4419 {
4420     my @r = &am_install_var ('-defaultdist', 'header', 'HEADERS', 'include',
4421                              'oldinclude', 'pkginclude',
4422                              'noinst', 'check');
4423     foreach (@r)
4424     {
4425       next unless $_->[1] =~ /\..*$/;
4426       &saw_extension ($&);
4427     }
4428 }
4429
4430 sub handle_gettext
4431 {
4432   return if ! $seen_gettext || $relative_dir ne '.';
4433
4434   my $subdirs = var 'SUBDIRS';
4435
4436   if (! $subdirs)
4437     {
4438       err_ac "AM_GNU_GETTEXT used but SUBDIRS not defined";
4439       return;
4440     }
4441
4442   # Perform some sanity checks to help users get the right setup.
4443   # We disable these tests when po/ doesn't exist in order not to disallow
4444   # unusual gettext setups.
4445   #
4446   # Bruno Haible:
4447   # | The idea is:
4448   # |
4449   # |  1) If a package doesn't have a directory po/ at top level, it
4450   # |     will likely have multiple po/ directories in subpackages.
4451   # |
4452   # |  2) It is useful to warn for the absence of intl/ if AM_GNU_GETTEXT
4453   # |     is used without 'external'. It is also useful to warn for the
4454   # |     presence of intl/ if AM_GNU_GETTEXT([external]) is used. Both
4455   # |     warnings apply only to the usual layout of packages, therefore
4456   # |     they should both be disabled if no po/ directory is found at
4457   # |     top level.
4458
4459   if (-d 'po')
4460     {
4461       my @subdirs = $subdirs->value_as_list_recursive;
4462
4463       msg_var ('syntax', $subdirs,
4464                "AM_GNU_GETTEXT used but `po' not in SUBDIRS")
4465         if ! grep ($_ eq 'po', @subdirs);
4466
4467       # intl/ is not required when AM_GNU_GETTEXT is called with the
4468       # `external' option and AM_GNU_GETTEXT_INTL_SUBDIR is not called.
4469       msg_var ('syntax', $subdirs,
4470                "AM_GNU_GETTEXT used but `intl' not in SUBDIRS")
4471         if (! ($seen_gettext_external && ! $seen_gettext_intl)
4472             && ! grep ($_ eq 'intl', @subdirs));
4473
4474       # intl/ should not be used with AM_GNU_GETTEXT([external]), except
4475       # if AM_GNU_GETTEXT_INTL_SUBDIR is called.
4476       msg_var ('syntax', $subdirs,
4477                "`intl' should not be in SUBDIRS when "
4478                . "AM_GNU_GETTEXT([external]) is used")
4479         if ($seen_gettext_external && ! $seen_gettext_intl
4480             && grep ($_ eq 'intl', @subdirs));
4481     }
4482
4483   require_file ($ac_gettext_location, GNU, 'ABOUT-NLS');
4484 }
4485
4486 # Handle footer elements.
4487 sub handle_footer
4488 {
4489     reject_rule ('.SUFFIXES',
4490                  "use variable `SUFFIXES', not target `.SUFFIXES'");
4491
4492     # Note: AIX 4.1 /bin/make will fail if any suffix rule appears
4493     # before .SUFFIXES.  So we make sure that .SUFFIXES appears before
4494     # anything else, by sticking it right after the default: target.
4495     $output_header .= ".SUFFIXES:\n";
4496     my $suffixes = var 'SUFFIXES';
4497     my @suffixes = Automake::Rule::suffixes;
4498     if (@suffixes || $suffixes)
4499     {
4500         # Make sure SUFFIXES has unique elements.  Sort them to ensure
4501         # the output remains consistent.  However, $(SUFFIXES) is
4502         # always at the start of the list, unsorted.  This is done
4503         # because make will choose rules depending on the ordering of
4504         # suffixes, and this lets the user have some control.  Push
4505         # actual suffixes, and not $(SUFFIXES).  Some versions of make
4506         # do not like variable substitutions on the .SUFFIXES line.
4507         my @user_suffixes = ($suffixes
4508                              ? $suffixes->value_as_list_recursive : ());
4509
4510         my %suffixes = map { $_ => 1 } @suffixes;
4511         delete @suffixes{@user_suffixes};
4512
4513         $output_header .= (".SUFFIXES: "
4514                            . join (' ', @user_suffixes, sort keys %suffixes)
4515                            . "\n");
4516     }
4517
4518     $output_trailer .= file_contents ('footer', new Automake::Location);
4519 }
4520
4521
4522 # Generate `make install' rules.
4523 sub handle_install ()
4524 {
4525   $output_rules .= &file_contents
4526     ('install',
4527      new Automake::Location,
4528      maybe_BUILT_SOURCES => (set_seen ('BUILT_SOURCES')
4529                              ? (" \$(BUILT_SOURCES)\n"
4530                                 . "\t\$(MAKE) \$(AM_MAKEFLAGS)")
4531                              : ''),
4532      'installdirs-local' => (user_phony_rule 'installdirs-local'
4533                              ? ' installdirs-local' : ''),
4534      am__installdirs => variable_value ('am__installdirs') || '');
4535 }
4536
4537
4538 # Deal with all and all-am.
4539 sub handle_all ($)
4540 {
4541     my ($makefile) = @_;
4542
4543     # Output `all-am'.
4544
4545     # Put this at the beginning for the sake of non-GNU makes.  This
4546     # is still wrong if these makes can run parallel jobs.  But it is
4547     # right enough.
4548     unshift (@all, basename ($makefile));
4549
4550     foreach my $spec (@config_headers)
4551       {
4552         my ($out, @ins) = split_config_file_spec ($spec);
4553         push (@all, basename ($out))
4554           if dirname ($out) eq $relative_dir;
4555       }
4556
4557     # Install `all' hooks.
4558     push (@all, "all-local")
4559       if user_phony_rule "all-local";
4560
4561     &pretty_print_rule ("all-am:", "\t\t", @all);
4562     &depend ('.PHONY', 'all-am', 'all');
4563
4564
4565     # Output `all'.
4566
4567     my @local_headers = ();
4568     push @local_headers, '$(BUILT_SOURCES)'
4569       if var ('BUILT_SOURCES');
4570     foreach my $spec (@config_headers)
4571       {
4572         my ($out, @ins) = split_config_file_spec ($spec);
4573         push @local_headers, basename ($out)
4574           if dirname ($out) eq $relative_dir;
4575       }
4576
4577     if (@local_headers)
4578       {
4579         # We need to make sure config.h is built before we recurse.
4580         # We also want to make sure that built sources are built
4581         # before any ordinary `all' targets are run.  We can't do this
4582         # by changing the order of dependencies to the "all" because
4583         # that breaks when using parallel makes.  Instead we handle
4584         # things explicitly.
4585         $output_all .= ("all: @local_headers"
4586                         . "\n\t"
4587                         . '$(MAKE) $(AM_MAKEFLAGS) '
4588                         . (var ('SUBDIRS') ? 'all-recursive' : 'all-am')
4589                         . "\n\n");
4590         depend ('.MAKE', 'all');
4591       }
4592     else
4593       {
4594         $output_all .= "all: " . (var ('SUBDIRS')
4595                                   ? 'all-recursive' : 'all-am') . "\n\n";
4596       }
4597 }
4598
4599
4600 # &do_check_merge_target ()
4601 # -------------------------
4602 # Handle check merge target specially.
4603 sub do_check_merge_target ()
4604 {
4605   # Include user-defined local form of target.
4606   push @check_tests, 'check-local'
4607     if user_phony_rule 'check-local';
4608
4609   # In --cygnus mode, check doesn't depend on all.
4610   if (option 'cygnus')
4611     {
4612       # Just run the local check rules.
4613       pretty_print_rule ('check-am:', "\t\t", @check);
4614     }
4615   else
4616     {
4617       # The check target must depend on the local equivalent of
4618       # `all', to ensure all the primary targets are built.  Then it
4619       # must build the local check rules.
4620       $output_rules .= "check-am: all-am\n";
4621       if (@check)
4622         {
4623           pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4624                              @check);
4625           depend ('.MAKE', 'check-am');
4626         }
4627     }
4628   if (@check_tests)
4629     {
4630       pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4631                          @check_tests);
4632       depend ('.MAKE', 'check-am');
4633     }
4634
4635   depend '.PHONY', 'check', 'check-am';
4636   # Handle recursion.  We have to honor BUILT_SOURCES like for `all:'.
4637   $output_rules .= ("check: "
4638                     . (var ('BUILT_SOURCES')
4639                        ? "\$(BUILT_SOURCES)\n\t\$(MAKE) \$(AM_MAKEFLAGS) "
4640                        : '')
4641                     . (var ('SUBDIRS') ? 'check-recursive' : 'check-am')
4642                     . "\n");
4643   depend ('.MAKE', 'check')
4644     if var ('BUILT_SOURCES');
4645 }
4646
4647 # handle_clean ($MAKEFILE)
4648 # ------------------------
4649 # Handle all 'clean' targets.
4650 sub handle_clean ($)
4651 {
4652   my ($makefile) = @_;
4653
4654   # Clean the files listed in user variables if they exist.
4655   $clean_files{'$(MOSTLYCLEANFILES)'} = MOSTLY_CLEAN
4656     if var ('MOSTLYCLEANFILES');
4657   $clean_files{'$(CLEANFILES)'} = CLEAN
4658     if var ('CLEANFILES');
4659   $clean_files{'$(DISTCLEANFILES)'} = DIST_CLEAN
4660     if var ('DISTCLEANFILES');
4661   $clean_files{'$(MAINTAINERCLEANFILES)'} = MAINTAINER_CLEAN
4662     if var ('MAINTAINERCLEANFILES');
4663
4664   # Built sources are automatically removed by maintainer-clean.
4665   $clean_files{'$(BUILT_SOURCES)'} = MAINTAINER_CLEAN
4666     if var ('BUILT_SOURCES');
4667
4668   # Compute a list of "rm"s to run for each target.
4669   my %rms = (MOSTLY_CLEAN, [],
4670              CLEAN, [],
4671              DIST_CLEAN, [],
4672              MAINTAINER_CLEAN, []);
4673
4674   foreach my $file (keys %clean_files)
4675     {
4676       my $when = $clean_files{$file};
4677       prog_error 'invalid entry in %clean_files'
4678         unless exists $rms{$when};
4679
4680       my $rm = "rm -f $file";
4681       # If file is a variable, make sure when don't call `rm -f' without args.
4682       $rm ="test -z \"$file\" || $rm"
4683         if ($file =~ /^\s*\$(\(.*\)|\{.*\})\s*$/);
4684
4685       push @{$rms{$when}}, "\t-$rm\n";
4686     }
4687
4688   $output_rules .= &file_contents
4689     ('clean',
4690      new Automake::Location,
4691      MOSTLYCLEAN_RMS      => join ('', sort @{$rms{&MOSTLY_CLEAN}}),
4692      CLEAN_RMS            => join ('', sort @{$rms{&CLEAN}}),
4693      DISTCLEAN_RMS        => join ('', sort @{$rms{&DIST_CLEAN}}),
4694      MAINTAINER_CLEAN_RMS => join ('', sort @{$rms{&MAINTAINER_CLEAN}}),
4695      MAKEFILE             => basename $makefile,
4696      );
4697 }
4698
4699
4700 # &target_cmp ($A, $B)
4701 # --------------------
4702 # Subroutine for &handle_factored_dependencies to let `.PHONY' and
4703 # other `.TARGETS' be last.
4704 sub target_cmp
4705 {
4706   return 0 if $a eq $b;
4707
4708   my $a1 = substr ($a, 0, 1);
4709   my $b1 = substr ($b, 0, 1);
4710   if ($a1 ne $b1)
4711     {
4712       return -1 if $b1 eq '.';
4713       return 1 if $a1 eq '.';
4714     }
4715   return $a cmp $b;
4716 }
4717
4718
4719 # &handle_factored_dependencies ()
4720 # --------------------------------
4721 # Handle everything related to gathered targets.
4722 sub handle_factored_dependencies
4723 {
4724   # Reject bad hooks.
4725   foreach my $utarg ('uninstall-data-local', 'uninstall-data-hook',
4726                      'uninstall-exec-local', 'uninstall-exec-hook',
4727                      'uninstall-dvi-local',
4728                      'uninstall-html-local',
4729                      'uninstall-info-local',
4730                      'uninstall-pdf-local',
4731                      'uninstall-ps-local')
4732     {
4733       my $x = $utarg;
4734       $x =~ s/-.*-/-/;
4735       reject_rule ($utarg, "use `$x', not `$utarg'");
4736     }
4737
4738   reject_rule ('install-local',
4739                "use `install-data-local' or `install-exec-local', "
4740                . "not `install-local'");
4741
4742   reject_rule ('install-hook',
4743                "use `install-data-hook' or `install-exec-hook', "
4744                . "not `install-hook'");
4745
4746   # Install the -local hooks.
4747   foreach (keys %dependencies)
4748     {
4749       # Hooks are installed on the -am targets.
4750       s/-am$// or next;
4751       depend ("$_-am", "$_-local")
4752         if user_phony_rule "$_-local";
4753     }
4754
4755   # Install the -hook hooks.
4756   # FIXME: Why not be as liberal as we are with -local hooks?
4757   foreach ('install-exec', 'install-data', 'uninstall')
4758     {
4759       if (user_phony_rule "$_-hook")
4760         {
4761           depend ('.MAKE', "$_-am");
4762           register_action("$_-am",
4763                           ("\t\@\$(NORMAL_INSTALL)\n"
4764                            . "\t\$(MAKE) \$(AM_MAKEFLAGS) $_-hook"));
4765         }
4766     }
4767
4768   # All the required targets are phony.
4769   depend ('.PHONY', keys %required_targets);
4770
4771   # Actually output gathered targets.
4772   foreach (sort target_cmp keys %dependencies)
4773     {
4774       # If there is nothing about this guy, skip it.
4775       next
4776         unless (@{$dependencies{$_}}
4777                 || $actions{$_}
4778                 || $required_targets{$_});
4779
4780       # Define gathered targets in undefined conditions.
4781       # FIXME: Right now we must handle .PHONY as an exception,
4782       # because people write things like
4783       #    .PHONY: myphonytarget
4784       # to append dependencies.  This would not work if Automake
4785       # refrained from defining its own .PHONY target as it does
4786       # with other overridden targets.
4787       # Likewise for `.MAKE'.
4788       my @undefined_conds = (TRUE,);
4789       if ($_ ne '.PHONY' && $_ ne '.MAKE')
4790         {
4791           @undefined_conds =
4792             Automake::Rule::define ($_, 'internal',
4793                                     RULE_AUTOMAKE, TRUE, INTERNAL);
4794         }
4795       my @uniq_deps = uniq (sort @{$dependencies{$_}});
4796       foreach my $cond (@undefined_conds)
4797         {
4798           my $condstr = $cond->subst_string;
4799           &pretty_print_rule ("$condstr$_:", "$condstr\t", @uniq_deps);
4800           $output_rules .= $actions{$_} if defined $actions{$_};
4801           $output_rules .= "\n";
4802         }
4803     }
4804 }
4805
4806
4807 # &handle_tests_dejagnu ()
4808 # ------------------------
4809 sub handle_tests_dejagnu
4810 {
4811     push (@check_tests, 'check-DEJAGNU');
4812     $output_rules .= file_contents ('dejagnu', new Automake::Location);
4813 }
4814
4815 sub handle_per_suffix_test
4816 {
4817   my ($test_suffix, %transform) = @_;
4818   my ($pfx, $generic, $parallel_tests_option, $am_exeext);
4819   prog_error ("called with 'parallel-tests' option not set")
4820     unless $parallel_tests_option = option 'parallel-tests';
4821   if ($test_suffix eq '')
4822     {
4823       $pfx = '';
4824       $generic = 0;
4825       $am_exeext = 'FALSE';
4826     }
4827   else
4828     {
4829       prog_error ("test suffix `$test_suffix' lacks leading dot")
4830         unless $test_suffix =~ m/^\.(.*)/;
4831       $pfx = uc ($1) . '_';
4832       $generic = 1;
4833       $am_exeext = exists $configure_vars{'EXEEXT'} ? 'am__EXEEXT'
4834                                                     : 'FALSE';
4835     }
4836   # The "test driver" program, deputed to handle tests protocol used by
4837   # test scripts.  By default, it's assumed that no protocol is used,
4838   # so we fall back to the old "parallel-tests" behaviour, implemented
4839   # by the `test-driver' auxiliary script.
4840   if (! var "${pfx}LOG_DRIVER")
4841     {
4842       require_conf_file ($parallel_tests_option->{position}, FOREIGN,
4843                         'test-driver');
4844       define_variable ("${pfx}LOG_DRIVER",
4845                        "\$(SHELL) $am_config_aux_dir/test-driver",
4846                        INTERNAL);
4847     }
4848   my $driver = '$(' . $pfx . 'LOG_DRIVER)';
4849   my $driver_flags = '$(AM_' . $pfx . 'LOG_DRIVER_FLAGS)'
4850                        . ' $(' . $pfx . 'LOG_DRIVER_FLAGS)';
4851   my $compile = "${pfx}LOG_COMPILE";
4852   define_variable ($compile,
4853                    '$(' . $pfx . 'LOG_COMPILER)'
4854                       . ' $(AM_' .  $pfx . 'LOG_FLAGS)'
4855                       . ' $(' . $pfx . 'LOG_FLAGS)',
4856                      INTERNAL);
4857   $output_rules .= file_contents ('check2', new Automake::Location,
4858                                    GENERIC => $generic,
4859                                    DRIVER => $driver,
4860                                    DRIVER_FLAGS => $driver_flags,
4861                                    COMPILE => '$(' . $compile . ')',
4862                                    EXT => $test_suffix,
4863                                    am__EXEEXT => $am_exeext,
4864                                    %transform);
4865 }
4866
4867 # is_valid_test_extension ($EXT)
4868 # ------------------------------
4869 # Return true if $EXT can appear in $(TEST_EXTENSIONS), return false
4870 # otherwise.
4871 sub is_valid_test_extension ($)
4872 {
4873   my $ext = shift;
4874   return 1
4875     if ($ext =~ /^\.[a-zA-Z_][a-zA-Z0-9_]*$/);
4876   return 1
4877     if (exists $configure_vars{'EXEEXT'} && $ext eq subst ('EXEEXT'));
4878   return 0;
4879 }
4880
4881 # Handle TESTS variable and other checks.
4882 sub handle_tests
4883 {
4884   if (option 'dejagnu')
4885     {
4886       &handle_tests_dejagnu;
4887     }
4888   else
4889     {
4890       foreach my $c ('DEJATOOL', 'RUNTEST', 'RUNTESTFLAGS')
4891         {
4892           reject_var ($c, "`$c' defined but `dejagnu' not in "
4893                       . "`AUTOMAKE_OPTIONS'");
4894         }
4895     }
4896
4897   if (var ('TESTS'))
4898     {
4899       push (@check_tests, 'check-TESTS');
4900       $output_rules .= &file_contents ('check', new Automake::Location,
4901                                        COLOR => !! option 'color-tests',
4902                                        PARALLEL_TESTS => !! option 'parallel-tests');
4903
4904       # Tests that are known programs should have $(EXEEXT) appended.
4905       # For matching purposes, we need to adjust XFAIL_TESTS as well.
4906       append_exeext { exists $known_programs{$_[0]} } 'TESTS';
4907       append_exeext { exists $known_programs{$_[0]} } 'XFAIL_TESTS'
4908         if (var ('XFAIL_TESTS'));
4909
4910       if (my $parallel_tests = option 'parallel-tests')
4911         {
4912           define_variable ('TEST_SUITE_LOG', 'test-suite.log', INTERNAL);
4913           define_variable ('TEST_SUITE_HTML', '$(TEST_SUITE_LOG:.log=.html)', INTERNAL);
4914           my $suff = '.test';
4915           my $at_exeext = '';
4916           my $handle_exeext = exists $configure_vars{'EXEEXT'};
4917           if ($handle_exeext)
4918             {
4919               $at_exeext = subst ('EXEEXT');
4920               $suff = $at_exeext  . ' ' . $suff;
4921             }
4922           if (! var 'TEST_EXTENSIONS')
4923             {
4924               define_variable ('TEST_EXTENSIONS', $suff, INTERNAL);
4925             }
4926           my $var = var 'TEST_EXTENSIONS';
4927           # Currently, we are not able to deal with conditional contents
4928           # in TEST_EXTENSIONS.
4929           if ($var->has_conditional_contents)
4930            {
4931              msg_var 'unsupported', $var,
4932                      "`TEST_EXTENSIONS' cannot have conditional contents";
4933            }
4934           my @test_suffixes = $var->value_as_list_recursive;
4935           if ((my @invalid_test_suffixes =
4936                   grep { !is_valid_test_extension $_ } @test_suffixes) > 0)
4937             {
4938               error $var->rdef (TRUE)->location,
4939                     "invalid test extensions: @invalid_test_suffixes";
4940             }
4941           @test_suffixes = grep { is_valid_test_extension $_ } @test_suffixes;
4942           if ($handle_exeext)
4943             {
4944               unshift (@test_suffixes, $at_exeext)
4945                 unless $test_suffixes[0] eq $at_exeext;
4946             }
4947           unshift (@test_suffixes, '');
4948
4949           transform_variable_recursively
4950             ('TESTS', 'TEST_LOGS', 'am__testlogs', 1, INTERNAL,
4951               sub {
4952                 my ($subvar, $val, $cond, $full_cond) = @_;
4953                 my $obj = $val;
4954                 return $obj
4955                   if $val =~ /^\@.*\@$/;
4956                 $obj =~ s/\$\(EXEEXT\)$//o;
4957
4958                 if ($val =~ /(\$\((top_)?srcdir\))\//o)
4959                   {
4960                     msg ('error', $subvar->rdef ($cond)->location,
4961                          "parallel-tests: using `$1' in TESTS is currently broken: `$val'");
4962                   }
4963
4964                 foreach my $test_suffix (@test_suffixes)
4965                   {
4966                     next
4967                       if $test_suffix eq $at_exeext || $test_suffix eq '';
4968                     return substr ($obj, 0, length ($obj) - length ($test_suffix)) . '.log'
4969                       if substr ($obj, - length ($test_suffix)) eq $test_suffix;
4970                   }
4971                 my $base = $obj;
4972                 $obj .= '.log';
4973                 handle_per_suffix_test ('',
4974                                         OBJ => $obj,
4975                                         BASE => $base,
4976                                         SOURCE => $val);
4977                 return $obj;
4978               });
4979
4980           my $nhelper=1;
4981           my $prev = 'TESTS';
4982           my $post = '';
4983           my $last_suffix = $test_suffixes[$#test_suffixes];
4984           my $cur = '';
4985           foreach my $test_suffix (@test_suffixes)
4986             {
4987               if ($test_suffix eq $last_suffix)
4988                 {
4989                   $cur = 'TEST_LOGS';
4990                 }
4991               else
4992                 {
4993                   $cur = 'am__test_logs' . $nhelper;
4994                 }
4995               define_variable ($cur,
4996                 '$(' . $prev . ':' . $test_suffix . $post . '=.log)', INTERNAL);
4997               $post = '.log';
4998               $prev = $cur;
4999               $nhelper++;
5000               if ($test_suffix ne $at_exeext && $test_suffix ne '')
5001                 {
5002                   handle_per_suffix_test ($test_suffix,
5003                                           OBJ => '',
5004                                           BASE => '$*',
5005                                           SOURCE => '$<');
5006                 }
5007             }
5008           $clean_files{'$(TEST_LOGS)'} = MOSTLY_CLEAN;
5009           $clean_files{'$(TEST_LOGS:.log=.trs)'} = MOSTLY_CLEAN;
5010           $clean_files{'$(TEST_SUITE_LOG)'} = MOSTLY_CLEAN;
5011           $clean_files{'$(TEST_SUITE_HTML)'} = MOSTLY_CLEAN;
5012         }
5013     }
5014 }
5015
5016 # Handle Emacs Lisp.
5017 sub handle_emacs_lisp
5018 {
5019   my @elfiles = &am_install_var ('-candist', 'lisp', 'LISP',
5020                                  'lisp', 'noinst');
5021
5022   return if ! @elfiles;
5023
5024   define_pretty_variable ('am__ELFILES', TRUE, INTERNAL,
5025                           map { $_->[1] } @elfiles);
5026   define_pretty_variable ('am__ELCFILES', TRUE, INTERNAL,
5027                           '$(am__ELFILES:.el=.elc)');
5028   # This one can be overridden by users.
5029   define_pretty_variable ('ELCFILES', TRUE, INTERNAL, '$(LISP:.el=.elc)');
5030
5031   push @all, '$(ELCFILES)';
5032
5033   require_variables ($elfiles[0][0], "Emacs Lisp sources seen", TRUE,
5034                      'EMACS', 'lispdir');
5035   require_conf_file ($elfiles[0][0], FOREIGN, 'elisp-comp');
5036   &define_variable ('elisp_comp', "$am_config_aux_dir/elisp-comp", INTERNAL);
5037 }
5038
5039 # Handle Python
5040 sub handle_python
5041 {
5042   my @pyfiles = &am_install_var ('-defaultdist', 'python', 'PYTHON',
5043                                  'noinst');
5044   return if ! @pyfiles;
5045
5046   require_variables ($pyfiles[0][0], "Python sources seen", TRUE, 'PYTHON');
5047   require_conf_file ($pyfiles[0][0], FOREIGN, 'py-compile');
5048   &define_variable ('py_compile', "$am_config_aux_dir/py-compile", INTERNAL);
5049 }
5050
5051 # Handle Java.
5052 sub handle_java
5053 {
5054     my @sourcelist = &am_install_var ('-candist',
5055                                       'java', 'JAVA',
5056                                       'noinst', 'check');
5057     return if ! @sourcelist;
5058
5059     my @prefixes = am_primary_prefixes ('JAVA', 1,
5060                                         'noinst', 'check');
5061
5062     my $dir;
5063     my @java_sources = ();
5064     foreach my $prefix (@prefixes)
5065       {
5066         (my $curs = $prefix) =~ s/^(?:nobase_)?(?:dist_|nodist_)?//;
5067
5068         next
5069           if $curs eq 'EXTRA';
5070
5071         push @java_sources, '$(' . $prefix . '_JAVA' . ')';
5072
5073         if (defined $dir)
5074           {
5075             err_var "${curs}_JAVA", "multiple _JAVA primaries in use"
5076              unless $curs eq $dir;
5077           }
5078
5079         $dir = $curs;
5080       }
5081
5082     define_pretty_variable ('am__java_sources', TRUE, INTERNAL,
5083                             "@java_sources");
5084
5085     if ($dir eq 'check')
5086       {
5087         push (@check, "class$dir.stamp");
5088       }
5089     else
5090       {
5091         push (@all, "class$dir.stamp");
5092       }
5093 }
5094
5095
5096 # Handle some of the minor options.
5097 sub handle_minor_options
5098 {
5099   if (option 'readme-alpha')
5100     {
5101       if ($relative_dir eq '.')
5102         {
5103           if ($package_version !~ /^$GNITS_VERSION_PATTERN$/)
5104             {
5105               msg ('error-gnits', $package_version_location,
5106                    "version `$package_version' doesn't follow " .
5107                    "Gnits standards");
5108             }
5109           if (defined $1 && -f 'README-alpha')
5110             {
5111               # This means we have an alpha release.  See
5112               # GNITS_VERSION_PATTERN for details.
5113               push_dist_common ('README-alpha');
5114             }
5115         }
5116     }
5117 }
5118
5119 ################################################################
5120
5121 # ($OUTPUT, @INPUTS)
5122 # &split_config_file_spec ($SPEC)
5123 # -------------------------------
5124 # Decode the Autoconf syntax for config files (files, headers, links
5125 # etc.).
5126 sub split_config_file_spec ($)
5127 {
5128   my ($spec) = @_;
5129   my ($output, @inputs) = split (/:/, $spec);
5130
5131   push @inputs, "$output.in"
5132     unless @inputs;
5133
5134   return ($output, @inputs);
5135 }
5136
5137 # $input
5138 # locate_am (@POSSIBLE_SOURCES)
5139 # -----------------------------
5140 # AC_CONFIG_FILES allow specifications such as Makefile:top.in:mid.in:bot.in
5141 # This functions returns the first *.in file for which a *.am exists.
5142 # It returns undef otherwise.
5143 sub locate_am (@)
5144 {
5145   my (@rest) = @_;
5146   my $input;
5147   foreach my $file (@rest)
5148     {
5149       if (($file =~ /^(.*)\.in$/) && -f "$1.am")
5150         {
5151           $input = $file;
5152           last;
5153         }
5154     }
5155   return $input;
5156 }
5157
5158 my %make_list;
5159
5160 # &scan_autoconf_config_files ($WHERE, $CONFIG-FILES)
5161 # ---------------------------------------------------
5162 # Study $CONFIG-FILES which is the first argument to AC_CONFIG_FILES
5163 # (or AC_OUTPUT).
5164 sub scan_autoconf_config_files ($$)
5165 {
5166   my ($where, $config_files) = @_;
5167
5168   # Look at potential Makefile.am's.
5169   foreach (split ' ', $config_files)
5170     {
5171       # Must skip empty string for Perl 4.
5172       next if $_ eq "\\" || $_ eq '';
5173
5174       # Handle $local:$input syntax.
5175       my ($local, @rest) = split (/:/);
5176       @rest = ("$local.in",) unless @rest;
5177       msg ('portability', $where,
5178           "omit leading `./' from config file names such as `$local',"
5179           . "\nas not all make implementations treat `file' and `./file' equally")
5180         if ($local =~ /^\.\//);
5181       my $input = locate_am @rest;
5182       if ($input)
5183         {
5184           # We have a file that automake should generate.
5185           $make_list{$input} = join (':', ($local, @rest));
5186         }
5187       else
5188         {
5189           # We have a file that automake should cause to be
5190           # rebuilt, but shouldn't generate itself.
5191           push (@other_input_files, $_);
5192         }
5193       $ac_config_files_location{$local} = $where;
5194       $ac_config_files_condition{$local} =
5195         new Automake::Condition (@cond_stack)
5196           if (@cond_stack);
5197     }
5198 }
5199
5200
5201 # &scan_autoconf_traces ($FILENAME)
5202 # ---------------------------------
5203 sub scan_autoconf_traces ($)
5204 {
5205   my ($filename) = @_;
5206
5207   # Macros to trace, with their minimal number of arguments.
5208   #
5209   # IMPORTANT: If you add a macro here, you should also add this macro
5210   # =========  to Automake-preselection in autoconf/lib/autom4te.in.
5211   my %traced = (
5212                 AC_CANONICAL_BUILD => 0,
5213                 AC_CANONICAL_HOST => 0,
5214                 AC_CANONICAL_TARGET => 0,
5215                 AC_CONFIG_AUX_DIR => 1,
5216                 AC_CONFIG_FILES => 1,
5217                 AC_CONFIG_HEADERS => 1,
5218                 AC_CONFIG_LIBOBJ_DIR => 1,
5219                 AC_CONFIG_LINKS => 1,
5220                 AC_FC_SRCEXT => 1,
5221                 AC_INIT => 0,
5222                 AC_LIBSOURCE => 1,
5223                 AC_REQUIRE_AUX_FILE => 1,
5224                 AC_SUBST_TRACE => 1,
5225                 AM_AUTOMAKE_VERSION => 1,
5226                 AM_CONDITIONAL => 2,
5227                 AM_ENABLE_MULTILIB => 0,
5228                 AM_GNU_GETTEXT => 0,
5229                 AM_GNU_GETTEXT_INTL_SUBDIR => 0,
5230                 AM_INIT_AUTOMAKE => 0,
5231                 AM_MAINTAINER_MODE => 0,
5232                 AM_PROG_AR => 0,
5233                 AM_PROG_CC_C_O => 0,
5234                 AM_SILENT_RULES => 0,
5235                 _AM_SUBST_NOTMAKE => 1,
5236                 _AM_COND_IF => 1,
5237                 _AM_COND_ELSE => 1,
5238                 _AM_COND_ENDIF => 1,
5239                 LT_SUPPORTED_TAG => 1,
5240                 _LT_AC_TAGCONFIG => 0,
5241                 m4_include => 1,
5242                 m4_sinclude => 1,
5243                 sinclude => 1,
5244               );
5245
5246   my $traces = ($ENV{AUTOCONF} || '@am_AUTOCONF@') . " ";
5247
5248   # Use a separator unlikely to be used, not `:', the default, which
5249   # has a precise meaning for AC_CONFIG_FILES and so on.
5250   $traces .= join (' ',
5251                    map { "--trace=$_" . ':\$f:\$l::\$d::\$n::\${::}%' }
5252                    (keys %traced));
5253
5254   my $tracefh = new Automake::XFile ("$traces $filename |");
5255   verb "reading $traces";
5256
5257   @cond_stack = ();
5258   my $where;
5259
5260   while ($_ = $tracefh->getline)
5261     {
5262       chomp;
5263       my ($here, $depth, @args) = split (/::/);
5264       $where = new Automake::Location $here;
5265       my $macro = $args[0];
5266
5267       prog_error ("unrequested trace `$macro'")
5268         unless exists $traced{$macro};
5269
5270       # Skip and diagnose malformed calls.
5271       if ($#args < $traced{$macro})
5272         {
5273           msg ('syntax', $where, "not enough arguments for $macro");
5274           next;
5275         }
5276
5277       # Alphabetical ordering please.
5278       if ($macro eq 'AC_CANONICAL_BUILD')
5279         {
5280           if ($seen_canonical <= AC_CANONICAL_BUILD)
5281             {
5282               $seen_canonical = AC_CANONICAL_BUILD;
5283               $canonical_location = $where;
5284             }
5285         }
5286       elsif ($macro eq 'AC_CANONICAL_HOST')
5287         {
5288           if ($seen_canonical <= AC_CANONICAL_HOST)
5289             {
5290               $seen_canonical = AC_CANONICAL_HOST;
5291               $canonical_location = $where;
5292             }
5293         }
5294       elsif ($macro eq 'AC_CANONICAL_TARGET')
5295         {
5296           $seen_canonical = AC_CANONICAL_TARGET;
5297           $canonical_location = $where;
5298         }
5299       elsif ($macro eq 'AC_CONFIG_AUX_DIR')
5300         {
5301           if ($seen_init_automake)
5302             {
5303               error ($where, "AC_CONFIG_AUX_DIR must be called before "
5304                      . "AM_INIT_AUTOMAKE ...", partial => 1);
5305               error ($seen_init_automake, "... AM_INIT_AUTOMAKE called here");
5306             }
5307           $config_aux_dir = $args[1];
5308           $config_aux_dir_set_in_configure_ac = 1;
5309           check_directory ($config_aux_dir, $where);
5310         }
5311       elsif ($macro eq 'AC_CONFIG_FILES')
5312         {
5313           # Look at potential Makefile.am's.
5314           scan_autoconf_config_files ($where, $args[1]);
5315         }
5316       elsif ($macro eq 'AC_CONFIG_HEADERS')
5317         {
5318           foreach my $spec (split (' ', $args[1]))
5319             {
5320               my ($dest, @src) = split (':', $spec);
5321               $ac_config_files_location{$dest} = $where;
5322               push @config_headers, $spec;
5323             }
5324         }
5325       elsif ($macro eq 'AC_CONFIG_LIBOBJ_DIR')
5326         {
5327           $config_libobj_dir = $args[1];
5328           check_directory ($config_libobj_dir, $where);
5329         }
5330       elsif ($macro eq 'AC_CONFIG_LINKS')
5331         {
5332           foreach my $spec (split (' ', $args[1]))
5333             {
5334               my ($dest, $src) = split (':', $spec);
5335               $ac_config_files_location{$dest} = $where;
5336               push @config_links, $spec;
5337             }
5338         }
5339       elsif ($macro eq 'AC_FC_SRCEXT')
5340         {
5341           my $suffix = $args[1];
5342           # These flags are used as %SOURCEFLAG% in depend2.am,
5343           # where the trailing space is important.
5344           $sourceflags{'.' . $suffix} = '$(FCFLAGS_' . $suffix . ') '
5345             if ($suffix eq 'f90' || $suffix eq 'f95' || $suffix eq 'f03' || $suffix eq 'f08');
5346         }
5347       elsif ($macro eq 'AC_INIT')
5348         {
5349           if (defined $args[2])
5350             {
5351               $package_version = $args[2];
5352               $package_version_location = $where;
5353             }
5354         }
5355       elsif ($macro eq 'AC_LIBSOURCE')
5356         {
5357           $libsources{$args[1]} = $here;
5358         }
5359       elsif ($macro eq 'AC_REQUIRE_AUX_FILE')
5360         {
5361           # Only remember the first time a file is required.
5362           $required_aux_file{$args[1]} = $where
5363             unless exists $required_aux_file{$args[1]};
5364         }
5365       elsif ($macro eq 'AC_SUBST_TRACE')
5366         {
5367           # Just check for alphanumeric in AC_SUBST_TRACE.  If you do
5368           # AC_SUBST(5), then too bad.
5369           $configure_vars{$args[1]} = $where
5370             if $args[1] =~ /^\w+$/;
5371         }
5372       elsif ($macro eq 'AM_AUTOMAKE_VERSION')
5373         {
5374           error ($where,
5375                  "version mismatch.  This is Automake $VERSION,\n" .
5376                  "but the definition used by this AM_INIT_AUTOMAKE\n" .
5377                  "comes from Automake $args[1].  You should recreate\n" .
5378                  "aclocal.m4 with aclocal and run automake again.\n",
5379                  # $? = 63 is used to indicate version mismatch to missing.
5380                  exit_code => 63)
5381             if $VERSION ne $args[1];
5382
5383           $seen_automake_version = 1;
5384         }
5385       elsif ($macro eq 'AM_CONDITIONAL')
5386         {
5387           $configure_cond{$args[1]} = $where;
5388         }
5389       elsif ($macro eq 'AM_ENABLE_MULTILIB')
5390         {
5391           $seen_multilib = $where;
5392         }
5393       elsif ($macro eq 'AM_GNU_GETTEXT')
5394         {
5395           $seen_gettext = $where;
5396           $ac_gettext_location = $where;
5397           $seen_gettext_external = grep ($_ eq 'external', @args);
5398         }
5399       elsif ($macro eq 'AM_GNU_GETTEXT_INTL_SUBDIR')
5400         {
5401           $seen_gettext_intl = $where;
5402         }
5403       elsif ($macro eq 'AM_INIT_AUTOMAKE')
5404         {
5405           $seen_init_automake = $where;
5406           if (defined $args[2])
5407             {
5408               $package_version = $args[2];
5409               $package_version_location = $where;
5410             }
5411           elsif (defined $args[1])
5412             {
5413               my @opts = split (' ', $args[1]);
5414               @opts = map { { option => $_, where => $where } } @opts;
5415               exit $exit_code if process_global_option_list (@opts);
5416             }
5417         }
5418       elsif ($macro eq 'AM_MAINTAINER_MODE')
5419         {
5420           $seen_maint_mode = $where;
5421         }
5422       elsif ($macro eq 'AM_PROG_AR')
5423         {
5424           $seen_ar = $where;
5425         }
5426       elsif ($macro eq 'AM_PROG_CC_C_O')
5427         {
5428           $seen_cc_c_o = $where;
5429         }
5430       elsif ($macro eq 'AM_SILENT_RULES')
5431         {
5432           set_global_option ('silent-rules', $where);
5433         }
5434       elsif ($macro eq '_AM_COND_IF')
5435         {
5436           cond_stack_if ('', $args[1], $where);
5437           error ($where, "missing m4 quoting, macro depth $depth")
5438             if ($depth != 1);
5439         }
5440       elsif ($macro eq '_AM_COND_ELSE')
5441         {
5442           cond_stack_else ('!', $args[1], $where);
5443           error ($where, "missing m4 quoting, macro depth $depth")
5444             if ($depth != 1);
5445         }
5446       elsif ($macro eq '_AM_COND_ENDIF')
5447         {
5448           cond_stack_endif (undef, undef, $where);
5449           error ($where, "missing m4 quoting, macro depth $depth")
5450             if ($depth != 1);
5451         }
5452       elsif ($macro eq '_AM_SUBST_NOTMAKE')
5453         {
5454           $ignored_configure_vars{$args[1]} = $where;
5455         }
5456       elsif ($macro eq 'm4_include'
5457              || $macro eq 'm4_sinclude'
5458              || $macro eq 'sinclude')
5459         {
5460           # Skip missing `sinclude'd files.
5461           next if $macro ne 'm4_include' && ! -f $args[1];
5462
5463           # Some modified versions of Autoconf don't use
5464           # frozen files.  Consequently it's possible that we see all
5465           # m4_include's performed during Autoconf's startup.
5466           # Obviously we don't want to distribute Autoconf's files
5467           # so we skip absolute filenames here.
5468           push @configure_deps, '$(top_srcdir)/' . $args[1]
5469             unless $here =~ m,^(?:\w:)?[\\/],;
5470           # Keep track of the greatest timestamp.
5471           if (-e $args[1])
5472             {
5473               my $mtime = mtime $args[1];
5474               $configure_deps_greatest_timestamp = $mtime
5475                 if $mtime > $configure_deps_greatest_timestamp;
5476             }
5477         }
5478       elsif ($macro eq 'LT_SUPPORTED_TAG')
5479         {
5480           $libtool_tags{$args[1]} = 1;
5481           $libtool_new_api = 1;
5482         }
5483       elsif ($macro eq '_LT_AC_TAGCONFIG')
5484         {
5485           # _LT_AC_TAGCONFIG is an old macro present in Libtool 1.5.
5486           # We use it to detect whether tags are supported.  Our
5487           # preferred interface is LT_SUPPORTED_TAG, but it was
5488           # introduced in Libtool 1.6.
5489           if (0 == keys %libtool_tags)
5490             {
5491               # Hardcode the tags supported by Libtool 1.5.
5492               %libtool_tags = (CC => 1, CXX => 1, GCJ => 1, F77 => 1);
5493             }
5494         }
5495     }
5496
5497   error ($where, "condition stack not properly closed")
5498     if (@cond_stack);
5499
5500   $tracefh->close;
5501 }
5502
5503
5504 # &scan_autoconf_files ()
5505 # -----------------------
5506 # Check whether we use `configure.ac' or `configure.in'.
5507 # Scan it (and possibly `aclocal.m4') for interesting things.
5508 # We must scan aclocal.m4 because there might be AC_SUBSTs and such there.
5509 sub scan_autoconf_files ()
5510 {
5511   # Reinitialize libsources here.  This isn't really necessary,
5512   # since we currently assume there is only one configure.ac.  But
5513   # that won't always be the case.
5514   %libsources = ();
5515
5516   # Keep track of the youngest configure dependency.
5517   $configure_deps_greatest_timestamp = mtime $configure_ac;
5518   if (-e 'aclocal.m4')
5519     {
5520       my $mtime = mtime 'aclocal.m4';
5521       $configure_deps_greatest_timestamp = $mtime
5522         if $mtime > $configure_deps_greatest_timestamp;
5523     }
5524
5525   scan_autoconf_traces ($configure_ac);
5526
5527   @configure_input_files = sort keys %make_list;
5528   # Set input and output files if not specified by user.
5529   if (! @input_files)
5530     {
5531       @input_files = @configure_input_files;
5532       %output_files = %make_list;
5533     }
5534
5535
5536   if (! $seen_init_automake)
5537     {
5538       err_ac ("no proper invocation of AM_INIT_AUTOMAKE was found.\nYou "
5539               . "should verify that $configure_ac invokes AM_INIT_AUTOMAKE,"
5540               . "\nthat aclocal.m4 is present in the top-level directory,\n"
5541               . "and that aclocal.m4 was recently regenerated "
5542               . "(using aclocal)");
5543     }
5544   else
5545     {
5546       if (! $seen_automake_version)
5547         {
5548           if (-f 'aclocal.m4')
5549             {
5550               error ($seen_init_automake,
5551                      "your implementation of AM_INIT_AUTOMAKE comes from " .
5552                      "an\nold Automake version.  You should recreate " .
5553                      "aclocal.m4\nwith aclocal and run automake again",
5554                      # $? = 63 is used to indicate version mismatch to missing.
5555                      exit_code => 63);
5556             }
5557           else
5558             {
5559               error ($seen_init_automake,
5560                      "no proper implementation of AM_INIT_AUTOMAKE was " .
5561                      "found,\nprobably because aclocal.m4 is missing.\n" .
5562                      "You should run aclocal to create this file, then\n" .
5563                      "run automake again");
5564             }
5565         }
5566     }
5567
5568   locate_aux_dir ();
5569
5570   # Look for some files we need.  Always check for these.  This
5571   # check must be done for every run, even those where we are only
5572   # looking at a subdir Makefile.  We must set relative_dir for
5573   # push_required_file to work.
5574   # Sort the files for stable verbose output.
5575   $relative_dir = '.';
5576   foreach my $file (sort keys %required_aux_file)
5577     {
5578       require_conf_file ($required_aux_file{$file}->get, FOREIGN, $file)
5579     }
5580   err_am "`install.sh' is an anachronism; use `install-sh' instead"
5581     if -f $config_aux_dir . '/install.sh';
5582
5583   # Preserve dist_common for later.
5584   $configure_dist_common = variable_value ('DIST_COMMON') || '';
5585
5586 }
5587
5588 ################################################################
5589
5590 # Set up for Cygnus mode.
5591 sub check_cygnus
5592 {
5593   my $cygnus = option 'cygnus';
5594   return unless $cygnus;
5595
5596   set_strictness ('foreign');
5597   set_option ('no-installinfo', $cygnus);
5598   set_option ('no-dependencies', $cygnus);
5599   set_option ('no-dist', $cygnus);
5600
5601   err_ac "`AM_MAINTAINER_MODE' required when --cygnus specified"
5602     if !$seen_maint_mode;
5603 }
5604
5605 # Do any extra checking for GNU standards.
5606 sub check_gnu_standards
5607 {
5608   if ($relative_dir eq '.')
5609     {
5610       # In top level (or only) directory.
5611       require_file ("$am_file.am", GNU,
5612                     qw/INSTALL NEWS README AUTHORS ChangeLog/);
5613
5614       # Accept one of these three licenses; default to COPYING.
5615       # Make sure we do not overwrite an existing license.
5616       my $license;
5617       foreach (qw /COPYING COPYING.LIB COPYING.LESSER/)
5618         {
5619           if (-f $_)
5620             {
5621               $license = $_;
5622               last;
5623             }
5624         }
5625       require_file ("$am_file.am", GNU, 'COPYING')
5626         unless $license;
5627     }
5628
5629   for my $opt ('no-installman', 'no-installinfo')
5630     {
5631       msg ('error-gnu', option $opt,
5632            "option `$opt' disallowed by GNU standards")
5633         if option $opt;
5634     }
5635 }
5636
5637 # Do any extra checking for GNITS standards.
5638 sub check_gnits_standards
5639 {
5640   if ($relative_dir eq '.')
5641     {
5642       # In top level (or only) directory.
5643       require_file ("$am_file.am", GNITS, 'THANKS');
5644     }
5645 }
5646
5647 ################################################################
5648 #
5649 # Functions to handle files of each language.
5650
5651 # Each `lang_X_rewrite($DIRECTORY, $BASE, $EXT)' function follows a
5652 # simple formula: Return value is LANG_SUBDIR if the resulting object
5653 # file should be in a subdir if the source file is, LANG_PROCESS if
5654 # file is to be dealt with, LANG_IGNORE otherwise.
5655
5656 # Much of the actual processing is handled in
5657 # handle_single_transform.  These functions exist so that
5658 # auxiliary information can be recorded for a later cleanup pass.
5659 # Note that the calls to these functions are computed, so don't bother
5660 # searching for their precise names in the source.
5661
5662 # This is just a convenience function that can be used to determine
5663 # when a subdir object should be used.
5664 sub lang_sub_obj
5665 {
5666     return option 'subdir-objects' ? LANG_SUBDIR : LANG_PROCESS;
5667 }
5668
5669 # Rewrite a single C source file.
5670 sub lang_c_rewrite
5671 {
5672   my ($directory, $base, $ext, $obj, $have_per_exec_flags, $var) = @_;
5673
5674   my $r = LANG_PROCESS;
5675   if (option 'subdir-objects')
5676     {
5677       $r = LANG_SUBDIR;
5678       if ($directory && $directory ne '.')
5679         {
5680           $base = $directory . '/' . $base;
5681
5682           # libtool is always able to put the object at the proper place,
5683           # so we do not have to require AM_PROG_CC_C_O when building .lo files.
5684           msg_var ('portability', $var,
5685                    "compiling `$base.c' in subdir requires "
5686                    . "`AM_PROG_CC_C_O' in `$configure_ac'",
5687                    uniq_scope => US_GLOBAL,
5688                    uniq_part => 'AM_PROG_CC_C_O subdir')
5689             unless $seen_cc_c_o || $obj eq '.lo';
5690         }
5691     }
5692
5693   if (! $seen_cc_c_o
5694       && $have_per_exec_flags
5695       && ! option 'subdir-objects'
5696       && $obj ne '.lo')
5697     {
5698       msg_var ('portability',
5699                $var, "compiling `$base.c' with per-target flags requires "
5700                . "`AM_PROG_CC_C_O' in `$configure_ac'",
5701                uniq_scope => US_GLOBAL,
5702                uniq_part => 'AM_PROG_CC_C_O per-target')
5703     }
5704
5705     return $r;
5706 }
5707
5708 # Rewrite a single C++ source file.
5709 sub lang_cxx_rewrite
5710 {
5711     return &lang_sub_obj;
5712 }
5713
5714 # Rewrite a single header file.
5715 sub lang_header_rewrite
5716 {
5717     # Header files are simply ignored.
5718     return LANG_IGNORE;
5719 }
5720
5721 # Rewrite a single Vala source file.
5722 sub lang_vala_rewrite
5723 {
5724     my ($directory, $base, $ext) = @_;
5725
5726     (my $newext = $ext) =~ s/vala$/c/;
5727     return (LANG_SUBDIR, $newext);
5728 }
5729
5730 # Rewrite a single yacc file.
5731 sub lang_yacc_rewrite
5732 {
5733     my ($directory, $base, $ext) = @_;
5734
5735     my $r = &lang_sub_obj;
5736     (my $newext = $ext) =~ tr/y/c/;
5737     return ($r, $newext);
5738 }
5739
5740 # Rewrite a single yacc++ file.
5741 sub lang_yaccxx_rewrite
5742 {
5743     my ($directory, $base, $ext) = @_;
5744
5745     my $r = &lang_sub_obj;
5746     (my $newext = $ext) =~ tr/y/c/;
5747     return ($r, $newext);
5748 }
5749
5750 # Rewrite a single lex file.
5751 sub lang_lex_rewrite
5752 {
5753     my ($directory, $base, $ext) = @_;
5754
5755     my $r = &lang_sub_obj;
5756     (my $newext = $ext) =~ tr/l/c/;
5757     return ($r, $newext);
5758 }
5759
5760 # Rewrite a single lex++ file.
5761 sub lang_lexxx_rewrite
5762 {
5763     my ($directory, $base, $ext) = @_;
5764
5765     my $r = &lang_sub_obj;
5766     (my $newext = $ext) =~ tr/l/c/;
5767     return ($r, $newext);
5768 }
5769
5770 # Rewrite a single assembly file.
5771 sub lang_asm_rewrite
5772 {
5773     return &lang_sub_obj;
5774 }
5775
5776 # Rewrite a single preprocessed assembly file.
5777 sub lang_cppasm_rewrite
5778 {
5779     return &lang_sub_obj;
5780 }
5781
5782 # Rewrite a single Fortran 77 file.
5783 sub lang_f77_rewrite
5784 {
5785     return &lang_sub_obj;
5786 }
5787
5788 # Rewrite a single Fortran file.
5789 sub lang_fc_rewrite
5790 {
5791     return &lang_sub_obj;
5792 }
5793
5794 # Rewrite a single preprocessed Fortran file.
5795 sub lang_ppfc_rewrite
5796 {
5797     return &lang_sub_obj;
5798 }
5799
5800 # Rewrite a single preprocessed Fortran 77 file.
5801 sub lang_ppf77_rewrite
5802 {
5803     return &lang_sub_obj;
5804 }
5805
5806 # Rewrite a single ratfor file.
5807 sub lang_ratfor_rewrite
5808 {
5809     return &lang_sub_obj;
5810 }
5811
5812 # Rewrite a single Objective C file.
5813 sub lang_objc_rewrite
5814 {
5815     return &lang_sub_obj;
5816 }
5817
5818 # Rewrite a single Unified Parallel C file.
5819 sub lang_upc_rewrite
5820 {
5821     return &lang_sub_obj;
5822 }
5823
5824 # Rewrite a single Java file.
5825 sub lang_java_rewrite
5826 {
5827     return LANG_SUBDIR;
5828 }
5829
5830 # The lang_X_finish functions are called after all source file
5831 # processing is done.  Each should handle defining rules for the
5832 # language, etc.  A finish function is only called if a source file of
5833 # the appropriate type has been seen.
5834
5835 sub lang_vala_finish_target ($$)
5836 {
5837   my ($self, $name) = @_;
5838
5839   my $derived = canonicalize ($name);
5840   my $varname = $derived . '_SOURCES';
5841   my $var = var ($varname);
5842
5843   if ($var)
5844     {
5845       foreach my $file ($var->value_as_list_recursive)
5846         {
5847           $output_rules .= "\$(srcdir)/$file: \$(srcdir)/${derived}_vala.stamp\n"
5848             . "\t\@if test -f \$@; then :; else rm -f \$(srcdir)/${derived}_vala.stamp; fi\n"
5849             . "\t\@if test -f \$@; then :; else \\\n"
5850             . "\t  \$(MAKE) \$(AM_MAKEFLAGS) \$(srcdir)/${derived}_vala.stamp; \\\n"
5851             . "\tfi\n"
5852             if $file =~ s/(.*)\.vala$/$1.c/;
5853         }
5854     }
5855
5856   # Add rebuild rules for generated header and vapi files
5857   my $flags = var ($derived . '_VALAFLAGS');
5858   if ($flags)
5859     {
5860       my $lastflag = '';
5861       foreach my $flag ($flags->value_as_list_recursive)
5862         {
5863           if (grep (/$lastflag/, ('-H', '-h', '--header', '--internal-header',
5864                                   '--vapi', '--internal-vapi', '--gir')))
5865             {
5866               my $headerfile = $flag;
5867               $output_rules .= "\$(srcdir)/$headerfile: \$(srcdir)/${derived}_vala.stamp\n"
5868                 . "\t\@if test -f \$@; then :; else rm -f \$(srcdir)/${derived}_vala.stamp; fi\n"
5869                 . "\t\@if test -f \$@; then :; else \\\n"
5870                 . "\t  \$(MAKE) \$(AM_MAKEFLAGS) \$(srcdir)/${derived}_vala.stamp; \\\n"
5871                 . "\tfi\n";
5872
5873               # valac is not used when building from dist tarballs
5874               # distribute the generated files
5875               push_dist_common ($headerfile);
5876               $clean_files{$headerfile} = MAINTAINER_CLEAN;
5877             }
5878           $lastflag = $flag;
5879         }
5880     }
5881
5882   my $compile = $self->compile;
5883
5884   # Rewrite each occurrence of `AM_VALAFLAGS' in the compile
5885   # rule into `${derived}_VALAFLAGS' if it exists.
5886   my $val = "${derived}_VALAFLAGS";
5887   $compile =~ s/\(AM_VALAFLAGS\)/\($val\)/
5888     if set_seen ($val);
5889
5890   # VALAFLAGS is a user variable (per GNU Standards),
5891   # it should not be overridden in the Makefile...
5892   check_user_variables ['VALAFLAGS'];
5893
5894   my $dirname = dirname ($name);
5895
5896   # Only generate C code, do not run C compiler
5897   $compile .= " -C";
5898
5899   my $verbose = verbose_flag ('VALAC');
5900   my $silent = silent_flag ();
5901
5902   $output_rules .=
5903     "\$(srcdir)/${derived}_vala.stamp: \$(${derived}_SOURCES)\n".
5904     "\t${verbose}\$(am__cd) \$(srcdir) && ${compile} \$(${derived}_SOURCES)\n".
5905     "\t${silent}touch \$@\n";
5906
5907   push_dist_common ("${derived}_vala.stamp");
5908
5909   $clean_files{"${derived}_vala.stamp"} = MAINTAINER_CLEAN;
5910 }
5911
5912 # Add output rules to invoke valac and create stamp file as a witness
5913 # to handle multiple outputs. This function is called after all source
5914 # file processing is done.
5915 sub lang_vala_finish
5916 {
5917   my ($self) = @_;
5918
5919   foreach my $prog (keys %known_programs)
5920     {
5921       lang_vala_finish_target ($self, $prog);
5922     }
5923
5924   while (my ($name) = each %known_libraries)
5925     {
5926       lang_vala_finish_target ($self, $name);
5927     }
5928 }
5929
5930 # The built .c files should be cleaned only on maintainer-clean
5931 # as the .c files are distributed. This function is called for each
5932 # .vala source file.
5933 sub lang_vala_target_hook
5934 {
5935   my ($self, $aggregate, $output, $input, %transform) = @_;
5936
5937   $clean_files{$output} = MAINTAINER_CLEAN;
5938 }
5939
5940 # This is a yacc helper which is called whenever we have decided to
5941 # compile a yacc file.
5942 sub lang_yacc_target_hook
5943 {
5944     my ($self, $aggregate, $output, $input, %transform) = @_;
5945
5946     # If some relevant *YFLAGS variable contains the `-d' flag, we'll
5947     # have to to generate special code.
5948     my $yflags_contains_minus_d = 0;
5949
5950     foreach my $pfx ("", "${aggregate}_")
5951       {
5952         my $yflagsvar = var ("${pfx}YFLAGS");
5953         next unless $yflagsvar;
5954         # We cannot work reliably with conditionally-defined YFLAGS.
5955         if ($yflagsvar->has_conditional_contents)
5956           {
5957             msg_var ('unsupported', $yflagsvar,
5958                      "`${pfx}YFLAGS' cannot have conditional contents");
5959           }
5960         else
5961           {
5962             $yflags_contains_minus_d = 1
5963               if grep (/^-d$/, $yflagsvar->value_as_list_recursive);
5964           }
5965       }
5966
5967     if ($yflags_contains_minus_d)
5968       {
5969         (my $output_base = $output) =~ s/$KNOWN_EXTENSIONS_PATTERN$//;
5970         my $header = $output_base . '.h';
5971
5972         # Found a `-d' that applies to the compilation of this file.
5973         # Add a dependency for the generated header file, and arrange
5974         # for that file to be included in the distribution.
5975         foreach my $cond (Automake::Rule::define (${header}, 'internal',
5976                                                   RULE_AUTOMAKE, TRUE,
5977                                                   INTERNAL))
5978           {
5979             my $condstr = $cond->subst_string;
5980             $output_rules .=
5981               "$condstr${header}: $output\n"
5982               # Recover from removal of $header
5983               . "$condstr\t\@if test ! -f \$@; then rm -f $output; else :; fi\n"
5984               . "$condstr\t\@if test ! -f \$@; then \$(MAKE) \$(AM_MAKEFLAGS) $output; else :; fi\n";
5985           }
5986         # Distribute the generated file, unless its .y source was
5987         # listed in a nodist_ variable.  (&handle_source_transform
5988         # will set DIST_SOURCE.)
5989         &push_dist_common ($header)
5990           if $transform{'DIST_SOURCE'};
5991
5992         # The GNU rules say that yacc/lex output files should be removed
5993         # by maintainer-clean.  However, if the files are not distributed,
5994         # then we want to remove them with "make clean"; otherwise,
5995         # "make distcheck" will fail.
5996         $clean_files{$header} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
5997       }
5998     # See the comment above for $HEADER.
5999     $clean_files{$output} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
6000 }
6001
6002 # This is a lex helper which is called whenever we have decided to
6003 # compile a lex file.
6004 sub lang_lex_target_hook
6005 {
6006     my ($self, $aggregate, $output, $input) = @_;
6007     # If the files are built in the build directory, then we want to
6008     # remove them with `make clean'.  If they are in srcdir they
6009     # shouldn't be touched.  However, we can't determine this
6010     # statically, and the GNU rules say that yacc/lex output files
6011     # should be removed by maintainer-clean.  So that's what we do.
6012     $clean_files{$output} = MAINTAINER_CLEAN;
6013 }
6014
6015 # This is a helper for both lex and yacc.
6016 sub yacc_lex_finish_helper
6017 {
6018   return if defined $language_scratch{'lex-yacc-done'};
6019   $language_scratch{'lex-yacc-done'} = 1;
6020
6021   # FIXME: for now, no line number.
6022   require_conf_file ($configure_ac, FOREIGN, 'ylwrap');
6023   &define_variable ('YLWRAP', "$am_config_aux_dir/ylwrap", INTERNAL);
6024 }
6025
6026 sub lang_yacc_finish
6027 {
6028   return if defined $language_scratch{'yacc-done'};
6029   $language_scratch{'yacc-done'} = 1;
6030
6031   reject_var 'YACCFLAGS', "`YACCFLAGS' obsolete; use `YFLAGS' instead";
6032
6033   yacc_lex_finish_helper;
6034 }
6035
6036
6037 sub lang_lex_finish
6038 {
6039   return if defined $language_scratch{'lex-done'};
6040   $language_scratch{'lex-done'} = 1;
6041
6042   yacc_lex_finish_helper;
6043 }
6044
6045
6046 # Given a hash table of linker names, pick the name that has the most
6047 # precedence.  This is lame, but something has to have global
6048 # knowledge in order to eliminate the conflict.  Add more linkers as
6049 # required.
6050 sub resolve_linker
6051 {
6052     my (%linkers) = @_;
6053
6054     foreach my $l (qw(GCJLINK CXXLINK F77LINK FCLINK OBJCLINK UPCLINK))
6055     {
6056         return $l if defined $linkers{$l};
6057     }
6058     return 'LINK';
6059 }
6060
6061 # Called to indicate that an extension was used.
6062 sub saw_extension
6063 {
6064     my ($ext) = @_;
6065     if (! defined $extension_seen{$ext})
6066     {
6067         $extension_seen{$ext} = 1;
6068     }
6069     else
6070     {
6071         ++$extension_seen{$ext};
6072     }
6073 }
6074
6075 # Return the number of files seen for a given language.  Knows about
6076 # special cases we care about.  FIXME: this is hideous.  We need
6077 # something that involves real language objects.  For instance yacc
6078 # and yaccxx could both derive from a common yacc class which would
6079 # know about the strange ylwrap requirement.  (Or better yet we could
6080 # just not support legacy yacc!)
6081 sub count_files_for_language
6082 {
6083     my ($name) = @_;
6084
6085     my @names;
6086     if ($name eq 'yacc' || $name eq 'yaccxx')
6087     {
6088         @names = ('yacc', 'yaccxx');
6089     }
6090     elsif ($name eq 'lex' || $name eq 'lexxx')
6091     {
6092         @names = ('lex', 'lexxx');
6093     }
6094     else
6095     {
6096         @names = ($name);
6097     }
6098
6099     my $r = 0;
6100     foreach $name (@names)
6101     {
6102         my $lang = $languages{$name};
6103         foreach my $ext (@{$lang->extensions})
6104         {
6105             $r += $extension_seen{$ext}
6106                 if defined $extension_seen{$ext};
6107         }
6108     }
6109
6110     return $r
6111 }
6112
6113 # Called to ask whether source files have been seen . If HEADERS is 1,
6114 # headers can be included.
6115 sub saw_sources_p
6116 {
6117     my ($headers) = @_;
6118
6119     # count all the sources
6120     my $count = 0;
6121     foreach my $val (values %extension_seen)
6122     {
6123         $count += $val;
6124     }
6125
6126     if (!$headers)
6127     {
6128         $count -= count_files_for_language ('header');
6129     }
6130
6131     return $count > 0;
6132 }
6133
6134
6135 # register_language (%ATTRIBUTE)
6136 # ------------------------------
6137 # Register a single language.
6138 # Each %ATTRIBUTE is of the form ATTRIBUTE => VALUE.
6139 sub register_language (%)
6140 {
6141   my (%option) = @_;
6142
6143   # Set the defaults.
6144   $option{'autodep'} = 'no'
6145     unless defined $option{'autodep'};
6146   $option{'linker'} = ''
6147     unless defined $option{'linker'};
6148   $option{'flags'} = []
6149     unless defined $option{'flags'};
6150   $option{'output_extensions'} = sub { return ( '.$(OBJEXT)', '.lo' ) }
6151     unless defined $option{'output_extensions'};
6152   $option{'nodist_specific'} = 0
6153     unless defined $option{'nodist_specific'};
6154
6155   my $lang = new Language (%option);
6156
6157   # Fill indexes.
6158   $extension_map{$_} = $lang->name foreach @{$lang->extensions};
6159   $languages{$lang->name} = $lang;
6160   my $link = $lang->linker;
6161   if ($link)
6162     {
6163       if (exists $link_languages{$link})
6164         {
6165           prog_error ("`$link' has different definitions in "
6166                       . $lang->name . " and " . $link_languages{$link}->name)
6167             if $lang->link ne $link_languages{$link}->link;
6168         }
6169       else
6170         {
6171           $link_languages{$link} = $lang;
6172         }
6173     }
6174
6175   # Update the pattern of known extensions.
6176   accept_extensions (@{$lang->extensions});
6177
6178   # Upate the $suffix_rule map.
6179   foreach my $suffix (@{$lang->extensions})
6180     {
6181       foreach my $dest (&{$lang->output_extensions} ($suffix))
6182         {
6183           register_suffix_rule (INTERNAL, $suffix, $dest);
6184         }
6185     }
6186 }
6187
6188 # derive_suffix ($EXT, $OBJ)
6189 # --------------------------
6190 # This function is used to find a path from a user-specified suffix $EXT
6191 # to $OBJ or to some other suffix we recognize internally, e.g. `cc'.
6192 sub derive_suffix ($$)
6193 {
6194   my ($source_ext, $obj) = @_;
6195
6196   while (! $extension_map{$source_ext}
6197          && $source_ext ne $obj
6198          && exists $suffix_rules->{$source_ext}
6199          && exists $suffix_rules->{$source_ext}{$obj})
6200     {
6201       $source_ext = $suffix_rules->{$source_ext}{$obj}[0];
6202     }
6203
6204   return $source_ext;
6205 }
6206
6207
6208 ################################################################
6209
6210 # Pretty-print something and append to output_rules.
6211 sub pretty_print_rule
6212 {
6213     $output_rules .= &makefile_wrap (@_);
6214 }
6215
6216
6217 ################################################################
6218
6219
6220 ## -------------------------------- ##
6221 ## Handling the conditional stack.  ##
6222 ## -------------------------------- ##
6223
6224
6225 # $STRING
6226 # make_conditional_string ($NEGATE, $COND)
6227 # ----------------------------------------
6228 sub make_conditional_string ($$)
6229 {
6230   my ($negate, $cond) = @_;
6231   $cond = "${cond}_TRUE"
6232     unless $cond =~ /^TRUE|FALSE$/;
6233   $cond = Automake::Condition::conditional_negate ($cond)
6234     if $negate;
6235   return $cond;
6236 }
6237
6238
6239 my %_am_macro_for_cond =
6240   (
6241   AMDEP => "one of the compiler tests\n"
6242            . "    AC_PROG_CC, AC_PROG_CXX, AC_PROG_CXX, AC_PROG_OBJC,\n"
6243            . "    AM_PROG_AS, AM_PROG_GCJ, AM_PROG_UPC",
6244   am__fastdepCC => 'AC_PROG_CC',
6245   am__fastdepCCAS => 'AM_PROG_AS',
6246   am__fastdepCXX => 'AC_PROG_CXX',
6247   am__fastdepGCJ => 'AM_PROG_GCJ',
6248   am__fastdepOBJC => 'AC_PROG_OBJC',
6249   am__fastdepUPC => 'AM_PROG_UPC'
6250   );
6251
6252 # $COND
6253 # cond_stack_if ($NEGATE, $COND, $WHERE)
6254 # --------------------------------------
6255 sub cond_stack_if ($$$)
6256 {
6257   my ($negate, $cond, $where) = @_;
6258
6259   if (! $configure_cond{$cond} && $cond !~ /^TRUE|FALSE$/)
6260     {
6261       my $text = "$cond does not appear in AM_CONDITIONAL";
6262       my $scope = US_LOCAL;
6263       if (exists $_am_macro_for_cond{$cond})
6264         {
6265           my $mac = $_am_macro_for_cond{$cond};
6266           $text .= "\n  The usual way to define `$cond' is to add ";
6267           $text .= ($mac =~ / /) ? $mac : "`$mac'";
6268           $text .= "\n  to `$configure_ac' and run `aclocal' and `autoconf' again";
6269           # These warnings appear in Automake files (depend2.am),
6270           # so there is no need to display them more than once:
6271           $scope = US_GLOBAL;
6272         }
6273       error $where, $text, uniq_scope => $scope;
6274     }
6275
6276   push (@cond_stack, make_conditional_string ($negate, $cond));
6277
6278   return new Automake::Condition (@cond_stack);
6279 }
6280
6281
6282 # $COND
6283 # cond_stack_else ($NEGATE, $COND, $WHERE)
6284 # ----------------------------------------
6285 sub cond_stack_else ($$$)
6286 {
6287   my ($negate, $cond, $where) = @_;
6288
6289   if (! @cond_stack)
6290     {
6291       error $where, "else without if";
6292       return FALSE;
6293     }
6294
6295   $cond_stack[$#cond_stack] =
6296     Automake::Condition::conditional_negate ($cond_stack[$#cond_stack]);
6297
6298   # If $COND is given, check against it.
6299   if (defined $cond)
6300     {
6301       $cond = make_conditional_string ($negate, $cond);
6302
6303       error ($where, "else reminder ($negate$cond) incompatible with "
6304              . "current conditional: $cond_stack[$#cond_stack]")
6305         if $cond_stack[$#cond_stack] ne $cond;
6306     }
6307
6308   return new Automake::Condition (@cond_stack);
6309 }
6310
6311
6312 # $COND
6313 # cond_stack_endif ($NEGATE, $COND, $WHERE)
6314 # -----------------------------------------
6315 sub cond_stack_endif ($$$)
6316 {
6317   my ($negate, $cond, $where) = @_;
6318   my $old_cond;
6319
6320   if (! @cond_stack)
6321     {
6322       error $where, "endif without if";
6323       return TRUE;
6324     }
6325
6326   # If $COND is given, check against it.
6327   if (defined $cond)
6328     {
6329       $cond = make_conditional_string ($negate, $cond);
6330
6331       error ($where, "endif reminder ($negate$cond) incompatible with "
6332              . "current conditional: $cond_stack[$#cond_stack]")
6333         if $cond_stack[$#cond_stack] ne $cond;
6334     }
6335
6336   pop @cond_stack;
6337
6338   return new Automake::Condition (@cond_stack);
6339 }
6340
6341
6342
6343
6344
6345 ## ------------------------ ##
6346 ## Handling the variables.  ##
6347 ## ------------------------ ##
6348
6349
6350 # &define_pretty_variable ($VAR, $COND, $WHERE, @VALUE)
6351 # -----------------------------------------------------
6352 # Like define_variable, but the value is a list, and the variable may
6353 # be defined conditionally.  The second argument is the condition
6354 # under which the value should be defined; this should be the empty
6355 # string to define the variable unconditionally.  The third argument
6356 # is a list holding the values to use for the variable.  The value is
6357 # pretty printed in the output file.
6358 sub define_pretty_variable ($$$@)
6359 {
6360     my ($var, $cond, $where, @value) = @_;
6361
6362     if (! vardef ($var, $cond))
6363     {
6364         Automake::Variable::define ($var, VAR_AUTOMAKE, '', $cond, "@value",
6365                                     '', $where, VAR_PRETTY);
6366         rvar ($var)->rdef ($cond)->set_seen;
6367     }
6368 }
6369
6370
6371 # define_variable ($VAR, $VALUE, $WHERE)
6372 # --------------------------------------
6373 # Define a new Automake Makefile variable VAR to VALUE, but only if
6374 # not already defined.
6375 sub define_variable ($$$)
6376 {
6377     my ($var, $value, $where) = @_;
6378     define_pretty_variable ($var, TRUE, $where, $value);
6379 }
6380
6381
6382 # define_files_variable ($VAR, \@BASENAME, $EXTENSION, $WHERE)
6383 # ------------------------------------------------------------
6384 # Define the $VAR which content is the list of file names composed of
6385 # a @BASENAME and the $EXTENSION.
6386 sub define_files_variable ($\@$$)
6387 {
6388   my ($var, $basename, $extension, $where) = @_;
6389   define_variable ($var,
6390                    join (' ', map { "$_.$extension" } @$basename),
6391                    $where);
6392 }
6393
6394
6395 # Like define_variable, but define a variable to be the configure
6396 # substitution by the same name.
6397 sub define_configure_variable ($)
6398 {
6399   my ($var) = @_;
6400   # Some variables we do not want to output.  For instance it
6401   # would be a bad idea to output `U = @U@` when `@U@` can be
6402   # substituted as `\`.
6403   my $pretty = exists $ignored_configure_vars{$var} ? VAR_SILENT : VAR_ASIS;
6404   Automake::Variable::define ($var, VAR_CONFIGURE, '', TRUE, subst $var,
6405                               '', $configure_vars{$var}, $pretty);
6406 }
6407
6408
6409 # define_compiler_variable ($LANG)
6410 # --------------------------------
6411 # Define a compiler variable.  We also handle defining the `LT'
6412 # version of the command when using libtool.
6413 sub define_compiler_variable ($)
6414 {
6415     my ($lang) = @_;
6416
6417     my ($var, $value) = ($lang->compiler, $lang->compile);
6418     my $libtool_tag = '';
6419     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6420       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6421     &define_variable ($var, $value, INTERNAL);
6422     if (var ('LIBTOOL'))
6423       {
6424         my $verbose = define_verbose_libtool ();
6425         &define_variable ("LT$var",
6426                           "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) "
6427                           . "\$(LIBTOOLFLAGS) --mode=compile $value",
6428                           INTERNAL);
6429       }
6430     define_verbose_tagvar ($lang->ccer || 'GEN');
6431 }
6432
6433
6434 # define_linker_variable ($LANG)
6435 # ------------------------------
6436 # Define linker variables.
6437 sub define_linker_variable ($)
6438 {
6439     my ($lang) = @_;
6440
6441     my $libtool_tag = '';
6442     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6443       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6444     # CCLD = $(CC).
6445     &define_variable ($lang->lder, $lang->ld, INTERNAL);
6446     # CCLINK = $(CCLD) blah blah...
6447     my $link = '';
6448     if (var ('LIBTOOL'))
6449       {
6450         my $verbose = define_verbose_libtool ();
6451         $link = "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) "
6452                 . "\$(LIBTOOLFLAGS) --mode=link ";
6453       }
6454     &define_variable ($lang->linker, $link . $lang->link, INTERNAL);
6455     &define_variable ($lang->compiler,  $lang);
6456     &define_verbose_tagvar ($lang->lder || 'GEN');
6457 }
6458
6459 sub define_per_target_linker_variable ($$)
6460 {
6461   my ($linker, $target) = @_;
6462
6463   # If the user wrote a custom link command, we don't define ours.
6464   return "${target}_LINK"
6465     if set_seen "${target}_LINK";
6466
6467   my $xlink = $linker ? $linker : 'LINK';
6468
6469   my $lang = $link_languages{$xlink};
6470   prog_error "Unknown language for linker variable `$xlink'"
6471     unless $lang;
6472
6473   my $link_command = $lang->link;
6474   if (var 'LIBTOOL')
6475     {
6476       my $libtool_tag = '';
6477       $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6478         if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6479
6480       my $verbose = define_verbose_libtool ();
6481       $link_command =
6482         "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) \$(LIBTOOLFLAGS) "
6483         . "--mode=link " . $link_command;
6484     }
6485
6486   # Rewrite each occurrence of `AM_$flag' in the link
6487   # command into `${derived}_$flag' if it exists.
6488   my $orig_command = $link_command;
6489   my @flags = (@{$lang->flags}, 'LDFLAGS');
6490   push @flags, 'LIBTOOLFLAGS' if var 'LIBTOOL';
6491   for my $flag (@flags)
6492     {
6493       my $val = "${target}_$flag";
6494       $link_command =~ s/\(AM_$flag\)/\($val\)/
6495         if set_seen ($val);
6496     }
6497
6498   # If the computed command is the same as the generic command, use
6499   # the command linker variable.
6500   return ($lang->linker, $lang->lder)
6501     if $link_command eq $orig_command;
6502
6503   &define_variable ("${target}_LINK", $link_command, INTERNAL);
6504   return ("${target}_LINK", $lang->lder);
6505 }
6506
6507 ################################################################
6508
6509 # &check_trailing_slash ($WHERE, $LINE)
6510 # -------------------------------------
6511 # Return 1 iff $LINE ends with a slash.
6512 # Might modify $LINE.
6513 sub check_trailing_slash ($\$)
6514 {
6515   my ($where, $line) = @_;
6516
6517   # Ignore `##' lines.
6518   return 0 if $$line =~ /$IGNORE_PATTERN/o;
6519
6520   # Catch and fix a common error.
6521   msg "syntax", $where, "whitespace following trailing backslash"
6522     if $$line =~ s/\\\s+\n$/\\\n/;
6523
6524   return $$line =~ /\\$/;
6525 }
6526
6527
6528 # &read_am_file ($AMFILE, $WHERE)
6529 # -------------------------------
6530 # Read Makefile.am and set up %contents.  Simultaneously copy lines
6531 # from Makefile.am into $output_trailer, or define variables as
6532 # appropriate.  NOTE we put rules in the trailer section.  We want
6533 # user rules to come after our generated stuff.
6534 sub read_am_file ($$)
6535 {
6536     my ($amfile, $where) = @_;
6537
6538     my $am_file = new Automake::XFile ("< $amfile");
6539     verb "reading $amfile";
6540
6541     # Keep track of the youngest output dependency.
6542     my $mtime = mtime $amfile;
6543     $output_deps_greatest_timestamp = $mtime
6544       if $mtime > $output_deps_greatest_timestamp;
6545
6546     my $spacing = '';
6547     my $comment = '';
6548     my $blank = 0;
6549     my $saw_bk = 0;
6550     my $var_look = VAR_ASIS;
6551
6552     use constant IN_VAR_DEF => 0;
6553     use constant IN_RULE_DEF => 1;
6554     use constant IN_COMMENT => 2;
6555     my $prev_state = IN_RULE_DEF;
6556
6557     while ($_ = $am_file->getline)
6558     {
6559         $where->set ("$amfile:$.");
6560         if (/$IGNORE_PATTERN/o)
6561         {
6562             # Merely delete comments beginning with two hashes.
6563         }
6564         elsif (/$WHITE_PATTERN/o)
6565         {
6566             error $where, "blank line following trailing backslash"
6567               if $saw_bk;
6568             # Stick a single white line before the incoming macro or rule.
6569             $spacing = "\n";
6570             $blank = 1;
6571             # Flush all comments seen so far.
6572             if ($comment ne '')
6573             {
6574                 $output_vars .= $comment;
6575                 $comment = '';
6576             }
6577         }
6578         elsif (/$COMMENT_PATTERN/o)
6579         {
6580             # Stick comments before the incoming macro or rule.  Make
6581             # sure a blank line precedes the first block of comments.
6582             $spacing = "\n" unless $blank;
6583             $blank = 1;
6584             $comment .= $spacing . $_;
6585             $spacing = '';
6586             $prev_state = IN_COMMENT;
6587         }
6588         else
6589         {
6590             last;
6591         }
6592         $saw_bk = check_trailing_slash ($where, $_);
6593     }
6594
6595     # We save the conditional stack on entry, and then check to make
6596     # sure it is the same on exit.  This lets us conditionally include
6597     # other files.
6598     my @saved_cond_stack = @cond_stack;
6599     my $cond = new Automake::Condition (@cond_stack);
6600
6601     my $last_var_name = '';
6602     my $last_var_type = '';
6603     my $last_var_value = '';
6604     my $last_where;
6605     # FIXME: shouldn't use $_ in this loop; it is too big.
6606     while ($_)
6607     {
6608         $where->set ("$amfile:$.");
6609
6610         # Make sure the line is \n-terminated.
6611         chomp;
6612         $_ .= "\n";
6613
6614         # Don't look at MAINTAINER_MODE_TRUE here.  That shouldn't be
6615         # used by users.  @MAINT@ is an anachronism now.
6616         $_ =~ s/\@MAINT\@//g
6617             unless $seen_maint_mode;
6618
6619         my $new_saw_bk = check_trailing_slash ($where, $_);
6620
6621         if (/$IGNORE_PATTERN/o)
6622         {
6623             # Merely delete comments beginning with two hashes.
6624
6625             # Keep any backslash from the previous line.
6626             $new_saw_bk = $saw_bk;
6627         }
6628         elsif (/$WHITE_PATTERN/o)
6629         {
6630             # Stick a single white line before the incoming macro or rule.
6631             $spacing = "\n";
6632             error $where, "blank line following trailing backslash"
6633               if $saw_bk;
6634         }
6635         elsif (/$COMMENT_PATTERN/o)
6636         {
6637             error $where, "comment following trailing backslash"
6638               if $saw_bk && $prev_state != IN_COMMENT;
6639
6640             # Stick comments before the incoming macro or rule.
6641             $comment .= $spacing . $_;
6642             $spacing = '';
6643             $prev_state = IN_COMMENT;
6644         }
6645         elsif ($saw_bk)
6646         {
6647             if ($prev_state == IN_RULE_DEF)
6648             {
6649               my $cond = new Automake::Condition @cond_stack;
6650               $output_trailer .= $cond->subst_string;
6651               $output_trailer .= $_;
6652             }
6653             elsif ($prev_state == IN_COMMENT)
6654             {
6655                 # If the line doesn't start with a `#', add it.
6656                 # We do this because a continued comment like
6657                 #   # A = foo \
6658                 #         bar \
6659                 #         baz
6660                 # is not portable.  BSD make doesn't honor
6661                 # escaped newlines in comments.
6662                 s/^#?/#/;
6663                 $comment .= $spacing . $_;
6664             }
6665             else # $prev_state == IN_VAR_DEF
6666             {
6667               $last_var_value .= ' '
6668                 unless $last_var_value =~ /\s$/;
6669               $last_var_value .= $_;
6670
6671               if (!/\\$/)
6672                 {
6673                   Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6674                                               $last_var_type, $cond,
6675                                               $last_var_value, $comment,
6676                                               $last_where, VAR_ASIS)
6677                     if $cond != FALSE;
6678                   $comment = $spacing = '';
6679                 }
6680             }
6681         }
6682
6683         elsif (/$IF_PATTERN/o)
6684           {
6685             $cond = cond_stack_if ($1, $2, $where);
6686           }
6687         elsif (/$ELSE_PATTERN/o)
6688           {
6689             $cond = cond_stack_else ($1, $2, $where);
6690           }
6691         elsif (/$ENDIF_PATTERN/o)
6692           {
6693             $cond = cond_stack_endif ($1, $2, $where);
6694           }
6695
6696         elsif (/$RULE_PATTERN/o)
6697         {
6698             # Found a rule.
6699             $prev_state = IN_RULE_DEF;
6700
6701             # For now we have to output all definitions of user rules
6702             # and can't diagnose duplicates (see the comment in
6703             # Automake::Rule::define). So we go on and ignore the return value.
6704             Automake::Rule::define ($1, $amfile, RULE_USER, $cond, $where);
6705
6706             check_variable_expansions ($_, $where);
6707
6708             $output_trailer .= $comment . $spacing;
6709             my $cond = new Automake::Condition @cond_stack;
6710             $output_trailer .= $cond->subst_string;
6711             $output_trailer .= $_;
6712             $comment = $spacing = '';
6713         }
6714         elsif (/$ASSIGNMENT_PATTERN/o)
6715         {
6716             # Found a macro definition.
6717             $prev_state = IN_VAR_DEF;
6718             $last_var_name = $1;
6719             $last_var_type = $2;
6720             $last_var_value = $3;
6721             $last_where = $where->clone;
6722             if ($3 ne '' && substr ($3, -1) eq "\\")
6723               {
6724                 # We preserve the `\' because otherwise the long lines
6725                 # that are generated will be truncated by broken
6726                 # `sed's.
6727                 $last_var_value = $3 . "\n";
6728               }
6729             # Normally we try to output variable definitions in the
6730             # same format they were input.  However, POSIX compliant
6731             # systems are not required to support lines longer than
6732             # 2048 bytes (most notably, some sed implementation are
6733             # limited to 4000 bytes, and sed is used by config.status
6734             # to rewrite Makefile.in into Makefile).  Moreover nobody
6735             # would really write such long lines by hand since it is
6736             # hardly maintainable.  So if a line is longer that 1000
6737             # bytes (an arbitrary limit), assume it has been
6738             # automatically generated by some tools, and flatten the
6739             # variable definition.  Otherwise, keep the variable as it
6740             # as been input.
6741             $var_look = VAR_PRETTY if length ($last_var_value) >= 1000;
6742
6743             if (!/\\$/)
6744               {
6745                 Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6746                                             $last_var_type, $cond,
6747                                             $last_var_value, $comment,
6748                                             $last_where, $var_look)
6749                   if $cond != FALSE;
6750                 $comment = $spacing = '';
6751                 $var_look = VAR_ASIS;
6752               }
6753         }
6754         elsif (/$INCLUDE_PATTERN/o)
6755         {
6756             my $path = $1;
6757
6758             if ($path =~ s/^\$\(top_srcdir\)\///)
6759               {
6760                 push (@include_stack, "\$\(top_srcdir\)/$path");
6761                 # Distribute any included file.
6762
6763                 # Always use the $(top_srcdir) prefix in DIST_COMMON,
6764                 # otherwise OSF make will implicitly copy the included
6765                 # file in the build tree during `make distdir' to satisfy
6766                 # the dependency.
6767                 # (subdircond2.test and subdircond3.test will fail.)
6768                 push_dist_common ("\$\(top_srcdir\)/$path");
6769               }
6770             else
6771               {
6772                 $path =~ s/\$\(srcdir\)\///;
6773                 push (@include_stack, "\$\(srcdir\)/$path");
6774                 # Always use the $(srcdir) prefix in DIST_COMMON,
6775                 # otherwise OSF make will implicitly copy the included
6776                 # file in the build tree during `make distdir' to satisfy
6777                 # the dependency.
6778                 # (subdircond2.test and subdircond3.test will fail.)
6779                 push_dist_common ("\$\(srcdir\)/$path");
6780                 $path = $relative_dir . "/" . $path if $relative_dir ne '.';
6781               }
6782             $where->push_context ("`$path' included from here");
6783             &read_am_file ($path, $where);
6784             $where->pop_context;
6785         }
6786         else
6787         {
6788             # This isn't an error; it is probably a continued rule.
6789             # In fact, this is what we assume.
6790             $prev_state = IN_RULE_DEF;
6791             check_variable_expansions ($_, $where);
6792             $output_trailer .= $comment . $spacing;
6793             my $cond = new Automake::Condition @cond_stack;
6794             $output_trailer .= $cond->subst_string;
6795             $output_trailer .= $_;
6796             $comment = $spacing = '';
6797             error $where, "`#' comment at start of rule is unportable"
6798               if $_ =~ /^\t\s*\#/;
6799         }
6800
6801         $saw_bk = $new_saw_bk;
6802         $_ = $am_file->getline;
6803     }
6804
6805     $output_trailer .= $comment;
6806
6807     error ($where, "trailing backslash on last line")
6808       if $saw_bk;
6809
6810     error ($where, (@cond_stack ? "unterminated conditionals: @cond_stack"
6811                     : "too many conditionals closed in include file"))
6812       if "@saved_cond_stack" ne "@cond_stack";
6813 }
6814
6815
6816 # define_standard_variables ()
6817 # ----------------------------
6818 # A helper for read_main_am_file which initializes configure variables
6819 # and variables from header-vars.am.
6820 sub define_standard_variables
6821 {
6822   my $saved_output_vars = $output_vars;
6823   my ($comments, undef, $rules) =
6824     file_contents_internal (1, "$libdir/am/header-vars.am",
6825                             new Automake::Location);
6826
6827   foreach my $var (sort keys %configure_vars)
6828     {
6829       &define_configure_variable ($var);
6830     }
6831
6832   $output_vars .= $comments . $rules;
6833 }
6834
6835 # Read main am file.
6836 sub read_main_am_file
6837 {
6838     my ($amfile) = @_;
6839
6840     # This supports the strange variable tricks we are about to play.
6841     prog_error ("variable defined before read_main_am_file\n" . variables_dump ())
6842       if (scalar (variables) > 0);
6843
6844     # Generate copyright header for generated Makefile.in.
6845     # We do discard the output of predefined variables, handled below.
6846     $output_vars = ("# $in_file_name generated by automake "
6847                    . $VERSION . " from $am_file_name.\n");
6848     $output_vars .= '# ' . subst ('configure_input') . "\n";
6849     $output_vars .= $gen_copyright;
6850
6851     # We want to predefine as many variables as possible.  This lets
6852     # the user set them with `+=' in Makefile.am.
6853     &define_standard_variables;
6854
6855     # Read user file, which might override some of our values.
6856     &read_am_file ($amfile, new Automake::Location);
6857 }
6858
6859
6860
6861 ################################################################
6862
6863 # $FLATTENED
6864 # &flatten ($STRING)
6865 # ------------------
6866 # Flatten the $STRING and return the result.
6867 sub flatten
6868 {
6869   $_ = shift;
6870
6871   s/\\\n//somg;
6872   s/\s+/ /g;
6873   s/^ //;
6874   s/ $//;
6875
6876   return $_;
6877 }
6878
6879
6880 # transform_token ($TOKEN, \%PAIRS, $KEY)
6881 # =======================================
6882 # Return the value associated to $KEY in %PAIRS, as used on $TOKEN
6883 # (which should be ?KEY? or any of the special %% requests)..
6884 sub transform_token ($$$)
6885 {
6886   my ($token, $transform, $key) = @_;
6887   my $res = $transform->{$key};
6888   prog_error "Unknown key `$key' in `$token'" unless defined $res;
6889   return $res;
6890 }
6891
6892
6893 # transform ($TOKEN, \%PAIRS)
6894 # ===========================
6895 # If ($TOKEN, $VAL) is in %PAIRS:
6896 #   - replaces %KEY% with $VAL,
6897 #   - enables/disables ?KEY? and ?!KEY?,
6898 #   - replaces %?KEY% with TRUE or FALSE.
6899 #   - replaces %KEY?IFTRUE%, %KEY:IFFALSE%, and %KEY?IFTRUE:IFFALSE% with
6900 #     IFTRUE / IFFALSE, as appropriate.
6901 sub transform ($$)
6902 {
6903   my ($token, $transform) = @_;
6904
6905   # %KEY%.
6906   # Must be before the following pattern to exclude the case
6907   # when there is neither IFTRUE nor IFFALSE.
6908   if ($token =~ /^%([\w\-]+)%$/)
6909     {
6910       return transform_token ($token, $transform, $1);
6911     }
6912   # %KEY?IFTRUE%, %KEY:IFFALSE%, and %KEY?IFTRUE:IFFALSE%.
6913   elsif ($token =~ /^%([\w\-]+)(?:\?([^?:%]+))?(?::([^?:%]+))?%$/)
6914     {
6915       return transform_token ($token, $transform, $1) ? ($2 || '') : ($3 || '');
6916     }
6917   # %?KEY%.
6918   elsif ($token =~ /^%\?([\w\-]+)%$/)
6919     {
6920       return transform_token ($token, $transform, $1) ? 'TRUE' : 'FALSE';
6921     }
6922   # ?KEY? and ?!KEY?.
6923   elsif ($token =~ /^ \? (!?) ([\w\-]+) \? $/x)
6924     {
6925       my $neg = ($1 eq '!') ? 1 : 0;
6926       my $val = transform_token ($token, $transform, $2);
6927       return (!!$val == $neg) ? '##%' : '';
6928     }
6929   else
6930     {
6931       prog_error "Unknown request format: $token";
6932     }
6933 }
6934
6935
6936 # @PARAGRAPHS
6937 # &make_paragraphs ($MAKEFILE, [%TRANSFORM])
6938 # ------------------------------------------
6939 # Load a $MAKEFILE, apply the %TRANSFORM, and return it as a list of
6940 # paragraphs.
6941 sub make_paragraphs ($%)
6942 {
6943   my ($file, %transform) = @_;
6944
6945   # Complete %transform with global options.
6946   # Note that %transform goes last, so it overrides global options.
6947   %transform = ('CYGNUS'      => !! option 'cygnus',
6948                  'MAINTAINER-MODE'
6949                  => $seen_maint_mode ? subst ('MAINTAINER_MODE_TRUE') : '',
6950
6951                  'XZ'          => !! option 'dist-xz',
6952                  'LZMA'        => !! option 'dist-lzma',
6953                  'LZIP'        => !! option 'dist-lzip',
6954                  'BZIP2'       => !! option 'dist-bzip2',
6955                  'COMPRESS'    => !! option 'dist-tarZ',
6956                  'GZIP'        =>  ! option 'no-dist-gzip',
6957                  'SHAR'        => !! option 'dist-shar',
6958                  'ZIP'         => !! option 'dist-zip',
6959
6960                  'INSTALL-INFO' =>  ! option 'no-installinfo',
6961                  'INSTALL-MAN'  =>  ! option 'no-installman',
6962                  'HAVE-MANS'    => !! var ('MANS'),
6963                  'CK-NEWS'      => !! option 'check-news',
6964
6965                  'SUBDIRS'      => !! var ('SUBDIRS'),
6966                  'TOPDIR_P'     => $relative_dir eq '.',
6967
6968                  'BUILD'    => ($seen_canonical >= AC_CANONICAL_BUILD),
6969                  'HOST'     => ($seen_canonical >= AC_CANONICAL_HOST),
6970                  'TARGET'   => ($seen_canonical >= AC_CANONICAL_TARGET),
6971
6972                  'LIBTOOL'      => !! var ('LIBTOOL'),
6973                  'NONLIBTOOL'   => 1,
6974                  'FIRST'        => ! $transformed_files{$file},
6975                 %transform);
6976
6977   $transformed_files{$file} = 1;
6978   $_ = $am_file_cache{$file};
6979
6980   if (! defined $_)
6981     {
6982       verb "reading $file";
6983       # Swallow the whole file.
6984       my $fc_file = new Automake::XFile "< $file";
6985       my $saved_dollar_slash = $/;
6986       undef $/;
6987       $_ = $fc_file->getline;
6988       $/ = $saved_dollar_slash;
6989       $fc_file->close;
6990
6991       # Remove ##-comments.
6992       # Besides we don't need more than two consecutive new-lines.
6993       s/(?:$IGNORE_PATTERN|(?<=\n\n)\n+)//gom;
6994
6995       $am_file_cache{$file} = $_;
6996     }
6997
6998   # Substitute Automake template tokens.
6999   s/(?: % \?? [\w\-]+ %
7000       | % [\w\-]+ (?:\?[^?:%]+)? (?::[^?:%]+)? %
7001       | \? !? [\w\-]+ \?
7002     )/transform($&, \%transform)/gex;
7003   # transform() may have added some ##%-comments to strip.
7004   # (we use `##%' instead of `##' so we can distinguish ##%##%##% from
7005   # ####### and do not remove the latter.)
7006   s/^[ \t]*(?:##%)+.*\n//gm;
7007
7008   # Split at unescaped new lines.
7009   my @lines = split (/(?<!\\)\n/, $_);
7010   my @res;
7011
7012   while (defined ($_ = shift @lines))
7013     {
7014       my $paragraph = $_;
7015       # If we are a rule, eat as long as we start with a tab.
7016       if (/$RULE_PATTERN/smo)
7017         {
7018           while (defined ($_ = shift @lines) && $_ =~ /^\t/)
7019             {
7020               $paragraph .= "\n$_";
7021             }
7022           unshift (@lines, $_);
7023         }
7024
7025       # If we are a comments, eat as much comments as you can.
7026       elsif (/$COMMENT_PATTERN/smo)
7027         {
7028           while (defined ($_ = shift @lines)
7029                  && $_ =~ /$COMMENT_PATTERN/smo)
7030             {
7031               $paragraph .= "\n$_";
7032             }
7033           unshift (@lines, $_);
7034         }
7035
7036       push @res, $paragraph;
7037     }
7038
7039   return @res;
7040 }
7041
7042
7043
7044 # ($COMMENT, $VARIABLES, $RULES)
7045 # &file_contents_internal ($IS_AM, $FILE, $WHERE, [%TRANSFORM])
7046 # -------------------------------------------------------------
7047 # Return contents of a file from $libdir/am, automatically skipping
7048 # macros or rules which are already known. $IS_AM iff the caller is
7049 # reading an Automake file (as opposed to the user's Makefile.am).
7050 sub file_contents_internal ($$$%)
7051 {
7052     my ($is_am, $file, $where, %transform) = @_;
7053
7054     $where->set ($file);
7055
7056     my $result_vars = '';
7057     my $result_rules = '';
7058     my $comment = '';
7059     my $spacing = '';
7060
7061     # The following flags are used to track rules spanning across
7062     # multiple paragraphs.
7063     my $is_rule = 0;            # 1 if we are processing a rule.
7064     my $discard_rule = 0;       # 1 if the current rule should not be output.
7065
7066     # We save the conditional stack on entry, and then check to make
7067     # sure it is the same on exit.  This lets us conditionally include
7068     # other files.
7069     my @saved_cond_stack = @cond_stack;
7070     my $cond = new Automake::Condition (@cond_stack);
7071
7072     foreach (make_paragraphs ($file, %transform))
7073     {
7074         # FIXME: no line number available.
7075         $where->set ($file);
7076
7077         # Sanity checks.
7078         error $where, "blank line following trailing backslash:\n$_"
7079           if /\\$/;
7080         error $where, "comment following trailing backslash:\n$_"
7081           if /\\#/;
7082
7083         if (/^$/)
7084         {
7085             $is_rule = 0;
7086             # Stick empty line before the incoming macro or rule.
7087             $spacing = "\n";
7088         }
7089         elsif (/$COMMENT_PATTERN/mso)
7090         {
7091             $is_rule = 0;
7092             # Stick comments before the incoming macro or rule.
7093             $comment = "$_\n";
7094         }
7095
7096         # Handle inclusion of other files.
7097         elsif (/$INCLUDE_PATTERN/o)
7098         {
7099             if ($cond != FALSE)
7100               {
7101                 my $file = ($is_am ? "$libdir/am/" : '') . $1;
7102                 $where->push_context ("`$file' included from here");
7103                 # N-ary `.=' fails.
7104                 my ($com, $vars, $rules)
7105                   = file_contents_internal ($is_am, $file, $where, %transform);
7106                 $where->pop_context;
7107                 $comment .= $com;
7108                 $result_vars .= $vars;
7109                 $result_rules .= $rules;
7110               }
7111         }
7112
7113         # Handling the conditionals.
7114         elsif (/$IF_PATTERN/o)
7115           {
7116             $cond = cond_stack_if ($1, $2, $file);
7117           }
7118         elsif (/$ELSE_PATTERN/o)
7119           {
7120             $cond = cond_stack_else ($1, $2, $file);
7121           }
7122         elsif (/$ENDIF_PATTERN/o)
7123           {
7124             $cond = cond_stack_endif ($1, $2, $file);
7125           }
7126
7127         # Handling rules.
7128         elsif (/$RULE_PATTERN/mso)
7129         {
7130           $is_rule = 1;
7131           $discard_rule = 0;
7132           # Separate relationship from optional actions: the first
7133           # `new-line tab" not preceded by backslash (continuation
7134           # line).
7135           my $paragraph = $_;
7136           /^(.*?)(?:(?<!\\)\n(\t.*))?$/s;
7137           my ($relationship, $actions) = ($1, $2 || '');
7138
7139           # Separate targets from dependencies: the first colon.
7140           $relationship =~ /^([^:]+\S+) *: *(.*)$/som;
7141           my ($targets, $dependencies) = ($1, $2);
7142           # Remove the escaped new lines.
7143           # I don't know why, but I have to use a tmp $flat_deps.
7144           my $flat_deps = &flatten ($dependencies);
7145           my @deps = split (' ', $flat_deps);
7146
7147           foreach (split (' ', $targets))
7148             {
7149               # FIXME: 1. We are not robust to people defining several targets
7150               # at once, only some of them being in %dependencies.  The
7151               # actions from the targets in %dependencies are usually generated
7152               # from the content of %actions, but if some targets in $targets
7153               # are not in %dependencies the ELSE branch will output
7154               # a rule for all $targets (i.e. the targets which are both
7155               # in %dependencies and $targets will have two rules).
7156
7157               # FIXME: 2. The logic here is not able to output a
7158               # multi-paragraph rule several time (e.g. for each condition
7159               # it is defined for) because it only knows the first paragraph.
7160
7161               # FIXME: 3. We are not robust to people defining a subset
7162               # of a previously defined "multiple-target" rule.  E.g.
7163               # `foo:' after `foo bar:'.
7164
7165               # Output only if not in FALSE.
7166               if (defined $dependencies{$_} && $cond != FALSE)
7167                 {
7168                   &depend ($_, @deps);
7169                   register_action ($_, $actions);
7170                 }
7171               else
7172                 {
7173                   # Free-lance dependency.  Output the rule for all the
7174                   # targets instead of one by one.
7175                   my @undefined_conds =
7176                     Automake::Rule::define ($targets, $file,
7177                                             $is_am ? RULE_AUTOMAKE : RULE_USER,
7178                                             $cond, $where);
7179                   for my $undefined_cond (@undefined_conds)
7180                     {
7181                       my $condparagraph = $paragraph;
7182                       $condparagraph =~ s/^/$undefined_cond->subst_string/gme;
7183                       $result_rules .= "$spacing$comment$condparagraph\n";
7184                     }
7185                   if (scalar @undefined_conds == 0)
7186                     {
7187                       # Remember to discard next paragraphs
7188                       # if they belong to this rule.
7189                       # (but see also FIXME: #2 above.)
7190                       $discard_rule = 1;
7191                     }
7192                   $comment = $spacing = '';
7193                   last;
7194                 }
7195             }
7196         }
7197
7198         elsif (/$ASSIGNMENT_PATTERN/mso)
7199         {
7200             my ($var, $type, $val) = ($1, $2, $3);
7201             error $where, "variable `$var' with trailing backslash"
7202               if /\\$/;
7203
7204             $is_rule = 0;
7205
7206             Automake::Variable::define ($var,
7207                                         $is_am ? VAR_AUTOMAKE : VAR_MAKEFILE,
7208                                         $type, $cond, $val, $comment, $where,
7209                                         VAR_ASIS)
7210               if $cond != FALSE;
7211
7212             $comment = $spacing = '';
7213         }
7214         else
7215         {
7216             # This isn't an error; it is probably some tokens which
7217             # configure is supposed to replace, such as `@SET-MAKE@',
7218             # or some part of a rule cut by an if/endif.
7219             if (! $cond->false && ! ($is_rule && $discard_rule))
7220               {
7221                 s/^/$cond->subst_string/gme;
7222                 $result_rules .= "$spacing$comment$_\n";
7223               }
7224             $comment = $spacing = '';
7225         }
7226     }
7227
7228     error ($where, @cond_stack ?
7229            "unterminated conditionals: @cond_stack" :
7230            "too many conditionals closed in include file")
7231       if "@saved_cond_stack" ne "@cond_stack";
7232
7233     return ($comment, $result_vars, $result_rules);
7234 }
7235
7236
7237 # $CONTENTS
7238 # &file_contents ($BASENAME, $WHERE, [%TRANSFORM])
7239 # ------------------------------------------------
7240 # Return contents of a file from $libdir/am, automatically skipping
7241 # macros or rules which are already known.
7242 sub file_contents ($$%)
7243 {
7244     my ($basename, $where, %transform) = @_;
7245     my ($comments, $variables, $rules) =
7246       file_contents_internal (1, "$libdir/am/$basename.am", $where,
7247                               %transform);
7248     return "$comments$variables$rules";
7249 }
7250
7251
7252 # @PREFIX
7253 # &am_primary_prefixes ($PRIMARY, $CAN_DIST, @PREFIXES)
7254 # -----------------------------------------------------
7255 # Find all variable prefixes that are used for install directories.  A
7256 # prefix `zar' qualifies iff:
7257 #
7258 # * `zardir' is a variable.
7259 # * `zar_PRIMARY' is a variable.
7260 #
7261 # As a side effect, it looks for misspellings.  It is an error to have
7262 # a variable ending in a "reserved" suffix whose prefix is unknown, e.g.
7263 # "bni_PROGRAMS".  However, unusual prefixes are allowed if a variable
7264 # of the same name (with "dir" appended) exists.  For instance, if the
7265 # variable "zardir" is defined, then "zar_PROGRAMS" becomes valid.
7266 # This is to provide a little extra flexibility in those cases which
7267 # need it.
7268 sub am_primary_prefixes ($$@)
7269 {
7270   my ($primary, $can_dist, @prefixes) = @_;
7271
7272   local $_;
7273   my %valid = map { $_ => 0 } @prefixes;
7274   $valid{'EXTRA'} = 0;
7275   foreach my $var (variables $primary)
7276     {
7277       # Automake is allowed to define variables that look like primaries
7278       # but which aren't.  E.g. INSTALL_sh_DATA.
7279       # Autoconf can also define variables like INSTALL_DATA, so
7280       # ignore all configure variables (at least those which are not
7281       # redefined in Makefile.am).
7282       # FIXME: We should make sure that these variables are not
7283       # conditionally defined (or else adjust the condition below).
7284       my $def = $var->def (TRUE);
7285       next if $def && $def->owner != VAR_MAKEFILE;
7286
7287       my $varname = $var->name;
7288
7289       if ($varname =~ /^(nobase_)?(dist_|nodist_)?(.*)_[[:alnum:]]+$/)
7290         {
7291           my ($base, $dist, $X) = ($1 || '', $2 || '', $3 || '');
7292           if ($dist ne '' && ! $can_dist)
7293             {
7294               err_var ($var,
7295                        "invalid variable `$varname': `dist' is forbidden");
7296             }
7297           # Standard directories must be explicitly allowed.
7298           elsif (! defined $valid{$X} && exists $standard_prefix{$X})
7299             {
7300               err_var ($var,
7301                        "`${X}dir' is not a legitimate directory " .
7302                        "for `$primary'");
7303             }
7304           # A not explicitly valid directory is allowed if Xdir is defined.
7305           elsif (! defined $valid{$X} &&
7306                  $var->requires_variables ("`$varname' is used", "${X}dir"))
7307             {
7308               # Nothing to do.  Any error message has been output
7309               # by $var->requires_variables.
7310             }
7311           else
7312             {
7313               # Ensure all extended prefixes are actually used.
7314               $valid{"$base$dist$X"} = 1;
7315             }
7316         }
7317       else
7318         {
7319           prog_error "unexpected variable name: $varname";
7320         }
7321     }
7322
7323   # Return only those which are actually defined.
7324   return sort grep { var ($_ . '_' . $primary) } keys %valid;
7325 }
7326
7327
7328 # Handle `where_HOW' variable magic.  Does all lookups, generates
7329 # install code, and possibly generates code to define the primary
7330 # variable.  The first argument is the name of the .am file to munge,
7331 # the second argument is the primary variable (e.g. HEADERS), and all
7332 # subsequent arguments are possible installation locations.
7333 #
7334 # Returns list of [$location, $value] pairs, where
7335 # $value's are the values in all where_HOW variable, and $location
7336 # there associated location (the place here their parent variables were
7337 # defined).
7338 #
7339 # FIXME: this should be rewritten to be cleaner.  It should be broken
7340 # up into multiple functions.
7341 #
7342 # Usage is: am_install_var (OPTION..., file, HOW, where...)
7343 sub am_install_var
7344 {
7345   my (@args) = @_;
7346
7347   my $do_require = 1;
7348   my $can_dist = 0;
7349   my $default_dist = 0;
7350   while (@args)
7351     {
7352       if ($args[0] eq '-noextra')
7353         {
7354           $do_require = 0;
7355         }
7356       elsif ($args[0] eq '-candist')
7357         {
7358           $can_dist = 1;
7359         }
7360       elsif ($args[0] eq '-defaultdist')
7361         {
7362           $default_dist = 1;
7363           $can_dist = 1;
7364         }
7365       elsif ($args[0] !~ /^-/)
7366         {
7367           last;
7368         }
7369       shift (@args);
7370     }
7371
7372   my ($file, $primary, @prefix) = @args;
7373
7374   # Now that configure substitutions are allowed in where_HOW
7375   # variables, it is an error to actually define the primary.  We
7376   # allow `JAVA', as it is customarily used to mean the Java
7377   # interpreter.  This is but one of several Java hacks.  Similarly,
7378   # `PYTHON' is customarily used to mean the Python interpreter.
7379   reject_var $primary, "`$primary' is an anachronism"
7380     unless $primary eq 'JAVA' || $primary eq 'PYTHON';
7381
7382   # Get the prefixes which are valid and actually used.
7383   @prefix = am_primary_prefixes ($primary, $can_dist, @prefix);
7384
7385   # If a primary includes a configure substitution, then the EXTRA_
7386   # form is required.  Otherwise we can't properly do our job.
7387   my $require_extra;
7388
7389   my @used = ();
7390   my @result = ();
7391
7392   foreach my $X (@prefix)
7393     {
7394       my $nodir_name = $X;
7395       my $one_name = $X . '_' . $primary;
7396       my $one_var = var $one_name;
7397
7398       my $strip_subdir = 1;
7399       # If subdir prefix should be preserved, do so.
7400       if ($nodir_name =~ /^nobase_/)
7401         {
7402           $strip_subdir = 0;
7403           $nodir_name =~ s/^nobase_//;
7404         }
7405
7406       # If files should be distributed, do so.
7407       my $dist_p = 0;
7408       if ($can_dist)
7409         {
7410           $dist_p = (($default_dist && $nodir_name !~ /^nodist_/)
7411                      || (! $default_dist && $nodir_name =~ /^dist_/));
7412           $nodir_name =~ s/^(dist|nodist)_//;
7413         }
7414
7415
7416       # Use the location of the currently processed variable.
7417       # We are not processing a particular condition, so pick the first
7418       # available.
7419       my $tmpcond = $one_var->conditions->one_cond;
7420       my $where = $one_var->rdef ($tmpcond)->location->clone;
7421
7422       # Append actual contents of where_PRIMARY variable to
7423       # @result, skipping @substitutions@.
7424       foreach my $locvals ($one_var->value_as_list_recursive (location => 1))
7425         {
7426           my ($loc, $value) = @$locvals;
7427           # Skip configure substitutions.
7428           if ($value =~ /^\@.*\@$/)
7429             {
7430               if ($nodir_name eq 'EXTRA')
7431                 {
7432                   error ($where,
7433                          "`$one_name' contains configure substitution, "
7434                          . "but shouldn't");
7435                 }
7436               # Check here to make sure variables defined in
7437               # configure.ac do not imply that EXTRA_PRIMARY
7438               # must be defined.
7439               elsif (! defined $configure_vars{$one_name})
7440                 {
7441                   $require_extra = $one_name
7442                     if $do_require;
7443                 }
7444             }
7445           else
7446             {
7447               # Strip any $(EXEEXT) suffix the user might have added, or this
7448               # will confuse &handle_source_transform and &check_canonical_spelling.
7449               # We'll add $(EXEEXT) back later anyway.
7450               # Do it here rather than in handle_programs so the uniquifying at the
7451               # end of this function works.
7452               ${$locvals}[1] =~ s/\$\(EXEEXT\)$//
7453                 if $primary eq 'PROGRAMS';
7454
7455               push (@result, $locvals);
7456             }
7457         }
7458       # A blatant hack: we rewrite each _PROGRAMS primary to include
7459       # EXEEXT.
7460       append_exeext { 1 } $one_name
7461         if $primary eq 'PROGRAMS';
7462       # "EXTRA" shouldn't be used when generating clean targets,
7463       # all, or install targets.  We used to warn if EXTRA_FOO was
7464       # defined uselessly, but this was annoying.
7465       next
7466         if $nodir_name eq 'EXTRA';
7467
7468       if ($nodir_name eq 'check')
7469         {
7470           push (@check, '$(' . $one_name . ')');
7471         }
7472       else
7473         {
7474           push (@used, '$(' . $one_name . ')');
7475         }
7476
7477       # Is this to be installed?
7478       my $install_p = $nodir_name ne 'noinst' && $nodir_name ne 'check';
7479
7480       # If so, with install-exec? (or install-data?).
7481       my $exec_p = ($nodir_name =~ /$EXEC_DIR_PATTERN/o);
7482
7483       my $check_options_p = $install_p && !! option 'std-options';
7484
7485       # Use the location of the currently processed variable as context.
7486       $where->push_context ("while processing `$one_name'");
7487
7488       # The variable containing all files to distribute.
7489       my $distvar = "\$($one_name)";
7490       $distvar = shadow_unconditionally ($one_name, $where)
7491         if ($dist_p && $one_var->has_conditional_contents);
7492
7493       # Singular form of $PRIMARY.
7494       (my $one_primary = $primary) =~ s/S$//;
7495       $output_rules .= &file_contents ($file, $where,
7496                                        PRIMARY     => $primary,
7497                                        ONE_PRIMARY => $one_primary,
7498                                        DIR         => $X,
7499                                        NDIR        => $nodir_name,
7500                                        BASE        => $strip_subdir,
7501
7502                                        EXEC      => $exec_p,
7503                                        INSTALL   => $install_p,
7504                                        DIST      => $dist_p,
7505                                        DISTVAR   => $distvar,
7506                                        'CK-OPTS' => $check_options_p);
7507     }
7508
7509   # The JAVA variable is used as the name of the Java interpreter.
7510   # The PYTHON variable is used as the name of the Python interpreter.
7511   if (@used && $primary ne 'JAVA' && $primary ne 'PYTHON')
7512     {
7513       # Define it.
7514       define_pretty_variable ($primary, TRUE, INTERNAL, @used);
7515       $output_vars .= "\n";
7516     }
7517
7518   err_var ($require_extra,
7519            "`$require_extra' contains configure substitution,\n"
7520            . "but `EXTRA_$primary' not defined")
7521     if ($require_extra && ! var ('EXTRA_' . $primary));
7522
7523   # Push here because PRIMARY might be configure time determined.
7524   push (@all, '$(' . $primary . ')')
7525     if @used && $primary ne 'JAVA' && $primary ne 'PYTHON';
7526
7527   # Make the result unique.  This lets the user use conditionals in
7528   # a natural way, but still lets us program lazily -- we don't have
7529   # to worry about handling a particular object more than once.
7530   # We will keep only one location per object.
7531   my %result = ();
7532   for my $pair (@result)
7533     {
7534       my ($loc, $val) = @$pair;
7535       $result{$val} = $loc;
7536     }
7537   my @l = sort keys %result;
7538   return map { [$result{$_}->clone, $_] } @l;
7539 }
7540
7541
7542 ################################################################
7543
7544 # Each key in this hash is the name of a directory holding a
7545 # Makefile.in.  These variables are local to `is_make_dir'.
7546 my %make_dirs = ();
7547 my $make_dirs_set = 0;
7548
7549 sub is_make_dir
7550 {
7551     my ($dir) = @_;
7552     if (! $make_dirs_set)
7553     {
7554         foreach my $iter (@configure_input_files)
7555         {
7556             $make_dirs{dirname ($iter)} = 1;
7557         }
7558         # We also want to notice Makefile.in's.
7559         foreach my $iter (@other_input_files)
7560         {
7561             if ($iter =~ /Makefile\.in$/)
7562             {
7563                 $make_dirs{dirname ($iter)} = 1;
7564             }
7565         }
7566         $make_dirs_set = 1;
7567     }
7568     return defined $make_dirs{$dir};
7569 }
7570
7571 ################################################################
7572
7573 # Find the aux dir.  This should match the algorithm used by
7574 # ./configure. (See the Autoconf documentation for for
7575 # AC_CONFIG_AUX_DIR.)
7576 sub locate_aux_dir ()
7577 {
7578   if (! $config_aux_dir_set_in_configure_ac)
7579     {
7580       # The default auxiliary directory is the first
7581       # of ., .., or ../.. that contains install-sh.
7582       # Assume . if install-sh doesn't exist yet.
7583       for my $dir (qw (. .. ../..))
7584         {
7585           if (-f "$dir/install-sh")
7586             {
7587               $config_aux_dir = $dir;
7588               last;
7589             }
7590         }
7591       $config_aux_dir = '.' unless $config_aux_dir;
7592     }
7593   # Avoid unsightly '/.'s.
7594   $am_config_aux_dir =
7595     '$(top_srcdir)' . ($config_aux_dir eq '.' ? "" : "/$config_aux_dir");
7596   $am_config_aux_dir =~ s,/*$,,;
7597 }
7598
7599
7600 # &push_required_file ($DIR, $FILE, $FULLFILE)
7601 # --------------------------------------------------
7602 # Push the given file onto DIST_COMMON.
7603 sub push_required_file
7604 {
7605   my ($dir, $file, $fullfile) = @_;
7606
7607   # If the file to be distributed is in the same directory of the
7608   # currently processed Makefile.am, then we want to distribute it
7609   # from this same Makefile.am.
7610   if ($dir eq $relative_dir)
7611     {
7612       push_dist_common ($file);
7613     }
7614   # This is needed to allow a construct in a non-top-level Makefile.am
7615   # to require a file in the build-aux directory (see at least the test
7616   # script `test-driver-is-distributed.test').  This is related to the
7617   # automake bug#9546.  Note that the use of $config_aux_dir instead
7618   # of $am_config_aux_dir here is deliberate and necessary.
7619   elsif ($dir eq $config_aux_dir)
7620     {
7621       push_dist_common ("$am_config_aux_dir/$file");
7622     }
7623   # FIXME: another spacial case, for AC_LIBOBJ/AC_LIBSOURCE support.
7624   # We probably need some refactoring of this function and its callers,
7625   # to have a more explicit and systematic handling of all the special
7626   # cases; but, since there are only two of them, this is low-priority
7627   # ATM.
7628   elsif ($config_libobj_dir && $dir eq $config_libobj_dir)
7629     {
7630       # Avoid unsightly '/.'s.
7631       my $am_config_libobj_dir =
7632         '$(top_srcdir)' .
7633         ($config_libobj_dir eq '.' ? "" : "/$config_libobj_dir");
7634       $am_config_libobj_dir =~ s|/*$||;
7635       push_dist_common ("$am_config_libobj_dir/$file");
7636     }
7637   elsif ($relative_dir eq '.' && ! &is_make_dir ($dir))
7638     {
7639       # If we are doing the topmost directory, and the file is in a
7640       # subdir which does not have a Makefile, then we distribute it
7641       # here.
7642
7643       # If a required file is above the source tree, it is important
7644       # to prefix it with `$(srcdir)' so that no VPATH search is
7645       # performed.  Otherwise problems occur with Make implementations
7646       # that rewrite and simplify rules whose dependencies are found in a
7647       # VPATH location.  Here is an example with OSF1/Tru64 Make.
7648       #
7649       #   % cat Makefile
7650       #   VPATH = sub
7651       #   distdir: ../a
7652       #           echo ../a
7653       #   % ls
7654       #   Makefile a
7655       #   % make
7656       #   echo a
7657       #   a
7658       #
7659       # Dependency `../a' was found in `sub/../a', but this make
7660       # implementation simplified it as `a'.  (Note that the sub/
7661       # directory does not even exist.)
7662       #
7663       # This kind of VPATH rewriting seems hard to cancel.  The
7664       # distdir.am hack against VPATH rewriting works only when no
7665       # simplification is done, i.e., for dependencies which are in
7666       # subdirectories, not in enclosing directories.  Hence, in
7667       # the latter case we use a full path to make sure no VPATH
7668       # search occurs.
7669       $fullfile = '$(srcdir)/' . $fullfile
7670         if $dir =~ m,^\.\.(?:$|/),;
7671
7672       push_dist_common ($fullfile);
7673     }
7674   else
7675     {
7676       prog_error "a Makefile in relative directory $relative_dir " .
7677                  "can't add files in directory $dir to DIST_COMMON";
7678     }
7679 }
7680
7681
7682 # If a file name appears as a key in this hash, then it has already
7683 # been checked for.  This allows us not to report the same error more
7684 # than once.
7685 my %required_file_not_found = ();
7686
7687 # &required_file_check_or_copy ($WHERE, $DIRECTORY, $FILE)
7688 # --------------------------------------------------------
7689 # Verify that the file must exist in $DIRECTORY, or install it.
7690 sub required_file_check_or_copy ($$$)
7691 {
7692   my ($where, $dir, $file) = @_;
7693
7694   my $fullfile = "$dir/$file";
7695   my $found_it = 0;
7696   my $dangling_sym = 0;
7697
7698   if (-l $fullfile && ! -f $fullfile)
7699     {
7700       $dangling_sym = 1;
7701     }
7702   elsif (dir_has_case_matching_file ($dir, $file))
7703     {
7704       $found_it = 1;
7705     }
7706
7707   # `--force-missing' only has an effect if `--add-missing' is
7708   # specified.
7709   return
7710     if $found_it && (! $add_missing || ! $force_missing);
7711
7712   # If we've already looked for it, we're done.  You might
7713   # wonder why we don't do this before searching for the
7714   # file.  If we do that, then something like
7715   # AC_OUTPUT(subdir/foo foo) will fail to put foo.in into
7716   # DIST_COMMON.
7717   if (! $found_it)
7718     {
7719       return if defined $required_file_not_found{$fullfile};
7720       $required_file_not_found{$fullfile} = 1;
7721     }
7722   if ($dangling_sym && $add_missing)
7723     {
7724       unlink ($fullfile);
7725     }
7726
7727   my $trailer = '';
7728   my $trailer2 = '';
7729   my $suppress = 0;
7730
7731   # Only install missing files according to our desired
7732   # strictness level.
7733   my $message = "required file `$fullfile' not found";
7734   if ($add_missing)
7735     {
7736       if (-f "$libdir/$file")
7737         {
7738           $suppress = 1;
7739
7740           # Install the missing file.  Symlink if we
7741           # can, copy if we must.  Note: delete the file
7742           # first, in case it is a dangling symlink.
7743           $message = "installing `$fullfile'";
7744
7745           # The license file should not be volatile.
7746           if ($file eq "COPYING")
7747             {
7748               $message .= " using GNU General Public License v3 file";
7749               $trailer2 = "\n    Consider adding the COPYING file"
7750                         . " to the version control system"
7751                         . "\n    for your code, to avoid questions"
7752                         . " about which license your project uses";
7753             }
7754
7755           # Windows Perl will hang if we try to delete a
7756           # file that doesn't exist.
7757           unlink ($fullfile) if -f $fullfile;
7758           if ($symlink_exists && ! $copy_missing)
7759             {
7760               if (! symlink ("$libdir/$file", $fullfile)
7761                   || ! -e $fullfile)
7762                 {
7763                   $suppress = 0;
7764                   $trailer = "; error while making link: $!";
7765                 }
7766             }
7767           elsif (system ('cp', "$libdir/$file", $fullfile))
7768             {
7769               $suppress = 0;
7770               $trailer = "\n    error while copying";
7771             }
7772           set_dir_cache_file ($dir, $file);
7773         }
7774     }
7775   else
7776     {
7777       $trailer = "\n  `automake --add-missing' can install `$file'"
7778         if -f "$libdir/$file";
7779     }
7780
7781   # If --force-missing was specified, and we have
7782   # actually found the file, then do nothing.
7783   return
7784     if $found_it && $force_missing;
7785
7786   # If we couldn't install the file, but it is a target in
7787   # the Makefile, don't print anything.  This allows files
7788   # like README, AUTHORS, or THANKS to be generated.
7789   return
7790     if !$suppress && rule $file;
7791
7792   msg ($suppress ? 'note' : 'error', $where, "$message$trailer$trailer2");
7793 }
7794
7795
7796 # &require_file_internal ($WHERE, $MYSTRICT, $DIRECTORY, $QUEUE, @FILES)
7797 # ----------------------------------------------------------------------
7798 # Verify that the file must exist in $DIRECTORY, or install it.
7799 # $MYSTRICT is the strictness level at which this file becomes required.
7800 # Worker threads may queue up the action to be serialized by the master,
7801 # if $QUEUE is true
7802 sub require_file_internal ($$$@)
7803 {
7804   my ($where, $mystrict, $dir, $queue, @files) = @_;
7805
7806   return
7807     unless $strictness >= $mystrict;
7808
7809   foreach my $file (@files)
7810     {
7811       push_required_file ($dir, $file, "$dir/$file");
7812       if ($queue)
7813         {
7814           queue_required_file_check_or_copy ($required_conf_file_queue,
7815                                              QUEUE_CONF_FILE, $relative_dir,
7816                                              $where, $mystrict, @files);
7817         }
7818       else
7819         {
7820           required_file_check_or_copy ($where, $dir, $file);
7821         }
7822     }
7823 }
7824
7825 # &require_file ($WHERE, $MYSTRICT, @FILES)
7826 # -----------------------------------------
7827 sub require_file ($$@)
7828 {
7829     my ($where, $mystrict, @files) = @_;
7830     require_file_internal ($where, $mystrict, $relative_dir, 0, @files);
7831 }
7832
7833 # &require_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7834 # -----------------------------------------------------------
7835 sub require_file_with_macro ($$$@)
7836 {
7837     my ($cond, $macro, $mystrict, @files) = @_;
7838     $macro = rvar ($macro) unless ref $macro;
7839     require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7840 }
7841
7842 # &require_libsource_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7843 # ----------------------------------------------------------------
7844 # Require an AC_LIBSOURCEd file.  If AC_CONFIG_LIBOBJ_DIR was called, it
7845 # must be in that directory.  Otherwise expect it in the current directory.
7846 sub require_libsource_with_macro ($$$@)
7847 {
7848     my ($cond, $macro, $mystrict, @files) = @_;
7849     $macro = rvar ($macro) unless ref $macro;
7850     if ($config_libobj_dir)
7851       {
7852         require_file_internal ($macro->rdef ($cond)->location, $mystrict,
7853                                $config_libobj_dir, 0, @files);
7854       }
7855     else
7856       {
7857         require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7858       }
7859 }
7860
7861 # &queue_required_file_check_or_copy ($QUEUE, $KEY, $DIR, $WHERE,
7862 #                                     $MYSTRICT, @FILES)
7863 # ---------------------------------------------------------------
7864 sub queue_required_file_check_or_copy ($$$$@)
7865 {
7866     my ($queue, $key, $dir, $where, $mystrict, @files) = @_;
7867     my @serial_loc;
7868     if (ref $where)
7869       {
7870         @serial_loc = (QUEUE_LOCATION, $where->serialize ());
7871       }
7872     else
7873       {
7874         @serial_loc = (QUEUE_STRING, $where);
7875       }
7876     $queue->enqueue ($key, $dir, @serial_loc, $mystrict, 0 + @files, @files);
7877 }
7878
7879 # &require_queued_file_check_or_copy ($QUEUE)
7880 # -------------------------------------------
7881 sub require_queued_file_check_or_copy ($)
7882 {
7883     my ($queue) = @_;
7884     my $where;
7885     my $dir = $queue->dequeue ();
7886     my $loc_key = $queue->dequeue ();
7887     if ($loc_key eq QUEUE_LOCATION)
7888       {
7889         $where = Automake::Location::deserialize ($queue);
7890       }
7891     elsif ($loc_key eq QUEUE_STRING)
7892       {
7893         $where = $queue->dequeue ();
7894       }
7895     else
7896       {
7897         prog_error "unexpected key $loc_key";
7898       }
7899     my $mystrict = $queue->dequeue ();
7900     my $nfiles = $queue->dequeue ();
7901     my @files;
7902     push @files, $queue->dequeue ()
7903       foreach (1 .. $nfiles);
7904     return
7905       unless $strictness >= $mystrict;
7906     foreach my $file (@files)
7907       {
7908         required_file_check_or_copy ($where, $config_aux_dir, $file);
7909       }
7910 }
7911
7912 # &require_conf_file ($WHERE, $MYSTRICT, @FILES)
7913 # ----------------------------------------------
7914 # Looks in configuration path, as specified by AC_CONFIG_AUX_DIR.
7915 sub require_conf_file ($$@)
7916 {
7917     my ($where, $mystrict, @files) = @_;
7918     my $queue = defined $required_conf_file_queue ? 1 : 0;
7919     require_file_internal ($where, $mystrict, $config_aux_dir,
7920                            $queue, @files);
7921 }
7922
7923
7924 # &require_conf_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7925 # ----------------------------------------------------------------
7926 sub require_conf_file_with_macro ($$$@)
7927 {
7928     my ($cond, $macro, $mystrict, @files) = @_;
7929     require_conf_file (rvar ($macro)->rdef ($cond)->location,
7930                        $mystrict, @files);
7931 }
7932
7933 ################################################################
7934
7935 # &require_build_directory ($DIRECTORY)
7936 # -------------------------------------
7937 # Emit rules to create $DIRECTORY if needed, and return
7938 # the file that any target requiring this directory should be made
7939 # dependent upon.
7940 # We don't want to emit the rule twice, and want to reuse it
7941 # for directories with equivalent names (e.g., `foo/bar' and `./foo//bar').
7942 sub require_build_directory ($)
7943 {
7944   my $directory = shift;
7945
7946   return $directory_map{$directory} if exists $directory_map{$directory};
7947
7948   my $cdir = File::Spec->canonpath ($directory);
7949
7950   if (exists $directory_map{$cdir})
7951     {
7952       my $stamp = $directory_map{$cdir};
7953       $directory_map{$directory} = $stamp;
7954       return $stamp;
7955     }
7956
7957   my $dirstamp = "$cdir/\$(am__dirstamp)";
7958
7959   $directory_map{$directory} = $dirstamp;
7960   $directory_map{$cdir} = $dirstamp;
7961
7962   # Set a variable for the dirstamp basename.
7963   define_pretty_variable ('am__dirstamp', TRUE, INTERNAL,
7964                           '$(am__leading_dot)dirstamp');
7965
7966   # Directory must be removed by `make distclean'.
7967   $clean_files{$dirstamp} = DIST_CLEAN;
7968
7969   $output_rules .= ("$dirstamp:\n"
7970                     . "\t\@\$(MKDIR_P) $directory\n"
7971                     . "\t\@: > $dirstamp\n");
7972
7973   return $dirstamp;
7974 }
7975
7976 # &require_build_directory_maybe ($FILE)
7977 # --------------------------------------
7978 # If $FILE lies in a subdirectory, emit a rule to create this
7979 # directory and return the file that $FILE should be made
7980 # dependent upon.  Otherwise, just return the empty string.
7981 sub require_build_directory_maybe ($)
7982 {
7983     my $file = shift;
7984     my $directory = dirname ($file);
7985
7986     if ($directory ne '.')
7987     {
7988         return require_build_directory ($directory);
7989     }
7990     else
7991     {
7992         return '';
7993     }
7994 }
7995
7996 ################################################################
7997
7998 # Push a list of files onto dist_common.
7999 sub push_dist_common
8000 {
8001   prog_error "push_dist_common run after handle_dist"
8002     if $handle_dist_run;
8003   Automake::Variable::define ('DIST_COMMON', VAR_AUTOMAKE, '+', TRUE, "@_",
8004                               '', INTERNAL, VAR_PRETTY);
8005 }
8006
8007
8008 ################################################################
8009
8010 # generate_makefile ($MAKEFILE_AM, $MAKEFILE_IN)
8011 # ----------------------------------------------
8012 # Generate a Makefile.in given the name of the corresponding Makefile and
8013 # the name of the file output by config.status.
8014 sub generate_makefile ($$)
8015 {
8016   my ($makefile_am, $makefile_in) = @_;
8017
8018   # Reset all the Makefile.am related variables.
8019   initialize_per_input;
8020
8021   # AUTOMAKE_OPTIONS can contains -W flags to disable or enable
8022   # warnings for this file.  So hold any warning issued before
8023   # we have processed AUTOMAKE_OPTIONS.
8024   buffer_messages ('warning');
8025
8026   # Name of input file ("Makefile.am") and output file
8027   # ("Makefile.in").  These have no directory components.
8028   $am_file_name = basename ($makefile_am);
8029   $in_file_name = basename ($makefile_in);
8030
8031   # $OUTPUT is encoded.  If it contains a ":" then the first element
8032   # is the real output file, and all remaining elements are input
8033   # files.  We don't scan or otherwise deal with these input files,
8034   # other than to mark them as dependencies.  See
8035   # &scan_autoconf_files for details.
8036   my ($makefile, @inputs) = split (/:/, $output_files{$makefile_in});
8037
8038   $relative_dir = dirname ($makefile);
8039   $am_relative_dir = dirname ($makefile_am);
8040   $topsrcdir = backname ($relative_dir);
8041
8042   read_main_am_file ($makefile_am);
8043   if (handle_options)
8044     {
8045       # Process buffered warnings.
8046       flush_messages;
8047       # Fatal error.  Just return, so we can continue with next file.
8048       return;
8049     }
8050   # Process buffered warnings.
8051   flush_messages;
8052
8053   # There are a few install-related variables that you should not define.
8054   foreach my $var ('PRE_INSTALL', 'POST_INSTALL', 'NORMAL_INSTALL')
8055     {
8056       my $v = var $var;
8057       if ($v)
8058         {
8059           my $def = $v->def (TRUE);
8060           prog_error "$var not defined in condition TRUE"
8061             unless $def;
8062           reject_var $var, "`$var' should not be defined"
8063             if $def->owner != VAR_AUTOMAKE;
8064         }
8065     }
8066
8067   # Catch some obsolete variables.
8068   msg_var ('obsolete', 'INCLUDES',
8069            "`INCLUDES' is the old name for `AM_CPPFLAGS' (or `*_CPPFLAGS')")
8070     if var ('INCLUDES');
8071
8072   # Must do this after reading .am file.
8073   define_variable ('subdir', $relative_dir, INTERNAL);
8074
8075   # If DIST_SUBDIRS is defined, make sure SUBDIRS is, so that
8076   # recursive rules are enabled.
8077   define_pretty_variable ('SUBDIRS', TRUE, INTERNAL, '')
8078     if var 'DIST_SUBDIRS' && ! var 'SUBDIRS';
8079
8080   # Check first, because we might modify some state.
8081   check_cygnus;
8082   check_gnu_standards;
8083   check_gnits_standards;
8084
8085   handle_configure ($makefile_am, $makefile_in, $makefile, @inputs);
8086   handle_gettext;
8087   handle_libraries;
8088   handle_ltlibraries;
8089   handle_programs;
8090   handle_scripts;
8091
8092   # These must be run after all the sources are scanned.  They
8093   # use variables defined by &handle_libraries, &handle_ltlibraries,
8094   # or &handle_programs.
8095   handle_compile;
8096   handle_languages;
8097   handle_libtool;
8098
8099   # Variables used by distdir.am and tags.am.
8100   define_pretty_variable ('SOURCES', TRUE, INTERNAL, @sources);
8101   if (! option 'no-dist')
8102     {
8103       define_pretty_variable ('DIST_SOURCES', TRUE, INTERNAL, @dist_sources);
8104     }
8105
8106   handle_multilib;
8107   handle_texinfo;
8108   handle_emacs_lisp;
8109   handle_python;
8110   handle_java;
8111   handle_man_pages;
8112   handle_data;
8113   handle_headers;
8114   handle_subdirs;
8115   handle_tags;
8116   handle_minor_options;
8117   # Must come after handle_programs so that %known_programs is up-to-date.
8118   handle_tests;
8119
8120   # This must come after most other rules.
8121   handle_dist;
8122
8123   handle_footer;
8124   do_check_merge_target;
8125   handle_all ($makefile);
8126
8127   # FIXME: Gross!
8128   if (var ('lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
8129     {
8130       $output_rules .= "install-binPROGRAMS: install-libLTLIBRARIES\n\n";
8131     }
8132   if (var ('nobase_lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
8133     {
8134       $output_rules .= "install-binPROGRAMS: install-nobase_libLTLIBRARIES\n\n";
8135     }
8136
8137   handle_install;
8138   handle_clean ($makefile);
8139   handle_factored_dependencies;
8140
8141   # Comes last, because all the above procedures may have
8142   # defined or overridden variables.
8143   $output_vars .= output_variables;
8144
8145   check_typos;
8146
8147   if ($exit_code != 0)
8148     {
8149       verb "not writing $makefile_in because of earlier errors";
8150       return;
8151     }
8152
8153   mkdir ($am_relative_dir, 0755) if ! -d $am_relative_dir;
8154
8155   # We make sure that `all:' is the first target.
8156   my $output =
8157     "$output_vars$output_all$output_header$output_rules$output_trailer";
8158
8159   # Decide whether we must update the output file or not.
8160   # We have to update in the following situations.
8161   #  * $force_generation is set.
8162   #  * any of the output dependencies is younger than the output
8163   #  * the contents of the output is different (this can happen
8164   #    if the project has been populated with a file listed in
8165   #    @common_files since the last run).
8166   # Output's dependencies are split in two sets:
8167   #  * dependencies which are also configure dependencies
8168   #    These do not change between each Makefile.am
8169   #  * other dependencies, specific to the Makefile.am being processed
8170   #    (such as the Makefile.am itself, or any Makefile fragment
8171   #    it includes).
8172   my $timestamp = mtime $makefile_in;
8173   if (! $force_generation
8174       && $configure_deps_greatest_timestamp < $timestamp
8175       && $output_deps_greatest_timestamp < $timestamp
8176       && $output eq contents ($makefile_in))
8177     {
8178       verb "$makefile_in unchanged";
8179       # No need to update.
8180       return;
8181     }
8182
8183   if (-e $makefile_in)
8184     {
8185       unlink ($makefile_in)
8186         or fatal "cannot remove $makefile_in: $!";
8187     }
8188
8189   my $gm_file = new Automake::XFile "> $makefile_in";
8190   verb "creating $makefile_in";
8191   print $gm_file $output;
8192 }
8193
8194 ################################################################
8195
8196
8197
8198
8199 ################################################################
8200
8201 # Helper function for usage().
8202 sub print_autodist_files (@)
8203 {
8204   my @lcomm = sort (&uniq (@_));
8205
8206   my @four;
8207   format USAGE_FORMAT =
8208   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<
8209   $four[0],           $four[1],           $four[2],           $four[3]
8210 .
8211   local $~ = "USAGE_FORMAT";
8212
8213   my $cols = 4;
8214   my $rows = int(@lcomm / $cols);
8215   my $rest = @lcomm % $cols;
8216
8217   if ($rest)
8218     {
8219       $rows++;
8220     }
8221   else
8222     {
8223       $rest = $cols;
8224     }
8225
8226   for (my $y = 0; $y < $rows; $y++)
8227     {
8228       @four = ("", "", "", "");
8229       for (my $x = 0; $x < $cols; $x++)
8230         {
8231           last if $y + 1 == $rows && $x == $rest;
8232
8233           my $idx = (($x > $rest)
8234                ?  ($rows * $rest + ($rows - 1) * ($x - $rest))
8235                : ($rows * $x));
8236
8237           $idx += $y;
8238           $four[$x] = $lcomm[$idx];
8239         }
8240       write;
8241     }
8242 }
8243
8244
8245 # Print usage information.
8246 sub usage ()
8247 {
8248     print "Usage: $0 [OPTION]... [Makefile]...
8249
8250 Generate Makefile.in for configure from Makefile.am.
8251
8252 Operation modes:
8253       --help               print this help, then exit
8254       --version            print version number, then exit
8255   -v, --verbose            verbosely list files processed
8256       --no-force           only update Makefile.in's that are out of date
8257   -W, --warnings=CATEGORY  report the warnings falling in CATEGORY
8258
8259 Dependency tracking:
8260   -i, --ignore-deps      disable dependency tracking code
8261       --include-deps     enable dependency tracking code
8262
8263 Flavors:
8264       --cygnus           assume program is part of Cygnus-style tree
8265       --foreign          set strictness to foreign
8266       --gnits            set strictness to gnits
8267       --gnu              set strictness to gnu
8268
8269 Library files:
8270   -a, --add-missing      add missing standard files to package
8271       --libdir=DIR       directory storing library files
8272   -c, --copy             with -a, copy missing files (default is symlink)
8273   -f, --force-missing    force update of standard files
8274
8275 ";
8276     Automake::ChannelDefs::usage;
8277
8278     print "\nFiles automatically distributed if found " .
8279           "(always):\n";
8280     print_autodist_files @common_files;
8281     print "\nFiles automatically distributed if found " .
8282           "(under certain conditions):\n";
8283     print_autodist_files @common_sometimes;
8284
8285     print '
8286 Report bugs to <@PACKAGE_BUGREPORT@>.
8287 GNU Automake home page: <@PACKAGE_URL@>.
8288 General help using GNU software: <http://www.gnu.org/gethelp/>.
8289 ';
8290
8291     # --help always returns 0 per GNU standards.
8292     exit 0;
8293 }
8294
8295
8296 # &version ()
8297 # -----------
8298 # Print version information
8299 sub version ()
8300 {
8301   print <<EOF;
8302 automake (GNU $PACKAGE) $VERSION
8303 Copyright (C) 2011 Free Software Foundation, Inc.
8304 License GPLv2+: GNU GPL version 2 or later <http://gnu.org/licenses/gpl-2.0.html>
8305 This is free software: you are free to change and redistribute it.
8306 There is NO WARRANTY, to the extent permitted by law.
8307
8308 Written by Tom Tromey <tromey\@redhat.com>
8309        and Alexandre Duret-Lutz <adl\@gnu.org>.
8310 EOF
8311   # --version always returns 0 per GNU standards.
8312   exit 0;
8313 }
8314
8315 ################################################################
8316
8317 # Parse command line.
8318 sub parse_arguments ()
8319 {
8320   my $strict = 'gnu';
8321   my $cygnus = 0;
8322   my $ignore_deps = 0;
8323   my @warnings = ();
8324
8325   my %cli_options =
8326     (
8327      'libdir=s' => \$libdir,
8328      'gnu'              => sub { $strict = 'gnu'; },
8329      'gnits'            => sub { $strict = 'gnits'; },
8330      'foreign'          => sub { $strict = 'foreign'; },
8331      'cygnus'           => \$cygnus,
8332      'include-deps'     => sub { $ignore_deps = 0; },
8333      'i|ignore-deps'    => sub { $ignore_deps = 1; },
8334      'no-force' => sub { $force_generation = 0; },
8335      'f|force-missing'  => \$force_missing,
8336      'a|add-missing'    => \$add_missing,
8337      'c|copy'           => \$copy_missing,
8338      'v|verbose'        => sub { setup_channel 'verb', silent => 0; },
8339      'W|warnings=s'     => \@warnings,
8340      );
8341   use Getopt::Long;
8342   Getopt::Long::config ("bundling", "pass_through");
8343
8344   # See if --version or --help is used.  We want to process these before
8345   # anything else because the GNU Coding Standards require us to
8346   # `exit 0' after processing these options, and we can't guarantee this
8347   # if we treat other options first.  (Handling other options first
8348   # could produce error diagnostics, and in this condition it is
8349   # confusing if Automake does `exit 0'.)
8350   my %cli_options_1st_pass =
8351     (
8352      'version' => \&version,
8353      'help'    => \&usage,
8354      # Recognize all other options (and their arguments) but do nothing.
8355      map { $_ => sub {} } (keys %cli_options)
8356      );
8357   my @ARGV_backup = @ARGV;
8358   Getopt::Long::GetOptions %cli_options_1st_pass
8359     or exit 1;
8360   @ARGV = @ARGV_backup;
8361
8362   # Now *really* process the options.  This time we know that --help
8363   # and --version are not present, but we specify them nonetheless so
8364   # that ambiguous abbreviation are diagnosed.
8365   Getopt::Long::GetOptions %cli_options, 'version' => sub {}, 'help' => sub {}
8366     or exit 1;
8367
8368   set_strictness ($strict);
8369   my $cli_where = new Automake::Location;
8370   set_global_option ('cygnus', $cli_where) if $cygnus;
8371   set_global_option ('no-dependencies', $cli_where) if $ignore_deps;
8372   for my $warning (@warnings)
8373     {
8374       &parse_warnings ('-W', $warning);
8375     }
8376
8377   return unless @ARGV;
8378
8379   if ($ARGV[0] =~ /^-./)
8380     {
8381       my %argopts;
8382       for my $k (keys %cli_options)
8383         {
8384           if ($k =~ /(.*)=s$/)
8385             {
8386               map { $argopts{(length ($_) == 1)
8387                              ? "-$_" : "--$_" } = 1; } (split (/\|/, $1));
8388             }
8389         }
8390       if ($ARGV[0] eq '--')
8391         {
8392           shift @ARGV;
8393         }
8394       elsif (exists $argopts{$ARGV[0]})
8395         {
8396           fatal ("option `$ARGV[0]' requires an argument.\n"
8397                  . "Try `$0 --help' for more information");
8398         }
8399       else
8400         {
8401           fatal ("unrecognized option `$ARGV[0]'.\n"
8402                  . "Try `$0 --help' for more information");
8403         }
8404     }
8405
8406   my $errspec = 0;
8407   foreach my $arg (@ARGV)
8408     {
8409       fatal ("empty argument\nTry `$0 --help' for more information")
8410         if ($arg eq '');
8411
8412       # Handle $local:$input syntax.
8413       my ($local, @rest) = split (/:/, $arg);
8414       @rest = ("$local.in",) unless @rest;
8415       my $input = locate_am @rest;
8416       if ($input)
8417         {
8418           push @input_files, $input;
8419           $output_files{$input} = join (':', ($local, @rest));
8420         }
8421       else
8422         {
8423           error "no Automake input file found for `$arg'";
8424           $errspec = 1;
8425         }
8426     }
8427   fatal "no input file found among supplied arguments"
8428     if $errspec && ! @input_files;
8429 }
8430
8431
8432 # handle_makefile ($MAKEFILE_IN)
8433 # ------------------------------
8434 # Deal with $MAKEFILE_IN.
8435 sub handle_makefile ($)
8436 {
8437   my ($file) =  @_;
8438   ($am_file = $file) =~ s/\.in$//;
8439   if (! -f ($am_file . '.am'))
8440     {
8441       error "`$am_file.am' does not exist";
8442     }
8443   else
8444     {
8445       # Any warning setting now local to this Makefile.am.
8446       dup_channel_setup;
8447
8448       generate_makefile ($am_file . '.am', $file);
8449
8450       # Back out any warning setting.
8451       drop_channel_setup;
8452     }
8453 }
8454
8455 # handle_makefiles_serial ()
8456 # --------------------------
8457 # Deal with all makefiles, without threads.
8458 sub handle_makefiles_serial ()
8459 {
8460   foreach my $file (@input_files)
8461     {
8462       handle_makefile ($file);
8463     }
8464 }
8465
8466 # get_number_of_threads ()
8467 # ------------------------
8468 # Logic for deciding how many worker threads to use.
8469 sub get_number_of_threads
8470 {
8471   my $nthreads = $ENV{'AUTOMAKE_JOBS'} || 0;
8472
8473   $nthreads = 0
8474     unless $nthreads =~ /^[0-9]+$/;
8475
8476   # It doesn't make sense to use more threads than makefiles,
8477   my $max_threads = @input_files;
8478
8479   if ($nthreads > $max_threads)
8480     {
8481       $nthreads = $max_threads;
8482     }
8483   return $nthreads;
8484 }
8485
8486 # handle_makefiles_threaded ($NTHREADS)
8487 # -------------------------------------
8488 # Deal with all makefiles, using threads.  The general strategy is to
8489 # spawn NTHREADS worker threads, dispatch makefiles to them, and let the
8490 # worker threads push back everything that needs serialization:
8491 # * warning and (normal) error messages, for stable stderr output
8492 #   order and content (avoiding duplicates, for example),
8493 # * races when installing aux files (and respective messages),
8494 # * races when collecting aux files for distribution.
8495 #
8496 # The latter requires that the makefile that deals with the aux dir
8497 # files be handled last, done by the master thread.
8498 sub handle_makefiles_threaded ($)
8499 {
8500   my ($nthreads) = @_;
8501
8502   # The file queue distributes all makefiles, the message queues
8503   # collect all serializations needed for respective files.
8504   my $file_queue = Thread::Queue->new;
8505   my %msg_queues;
8506   foreach my $file (@input_files)
8507     {
8508       $msg_queues{$file} = Thread::Queue->new;
8509     }
8510
8511   verb "spawning $nthreads worker threads";
8512   my @threads = (1 .. $nthreads);
8513   foreach my $t (@threads)
8514     {
8515       $t = threads->new (sub
8516         {
8517           while (my $file = $file_queue->dequeue)
8518             {
8519               verb "handling $file";
8520               my $queue = $msg_queues{$file};
8521               setup_channel_queue ($queue, QUEUE_MESSAGE);
8522               $required_conf_file_queue = $queue;
8523               handle_makefile ($file);
8524               $queue->enqueue (undef);
8525               setup_channel_queue (undef, undef);
8526               $required_conf_file_queue = undef;
8527             }
8528           return $exit_code;
8529         });
8530     }
8531
8532   # Queue all makefiles.
8533   verb "queuing " . @input_files . " input files";
8534   $file_queue->enqueue (@input_files, (undef) x @threads);
8535
8536   # Collect and process serializations.
8537   foreach my $file (@input_files)
8538     {
8539       verb "dequeuing messages for " . $file;
8540       reset_local_duplicates ();
8541       my $queue = $msg_queues{$file};
8542       while (my $key = $queue->dequeue)
8543         {
8544           if ($key eq QUEUE_MESSAGE)
8545             {
8546               pop_channel_queue ($queue);
8547             }
8548           elsif ($key eq QUEUE_CONF_FILE)
8549             {
8550               require_queued_file_check_or_copy ($queue);
8551             }
8552           else
8553             {
8554               prog_error "unexpected key $key";
8555             }
8556         }
8557     }
8558
8559   foreach my $t (@threads)
8560     {
8561       my @exit_thread = $t->join;
8562       $exit_code = $exit_thread[0]
8563         if ($exit_thread[0] > $exit_code);
8564     }
8565 }
8566
8567 ################################################################
8568
8569 # Parse the WARNINGS environment variable.
8570 parse_WARNINGS;
8571
8572 # Parse command line.
8573 parse_arguments;
8574
8575 $configure_ac = require_configure_ac;
8576
8577 # Do configure.ac scan only once.
8578 scan_autoconf_files;
8579
8580 if (! @input_files)
8581   {
8582     my $msg = '';
8583     $msg = "\nDid you forget AC_CONFIG_FILES([Makefile]) in $configure_ac?"
8584       if -f 'Makefile.am';
8585     fatal ("no `Makefile.am' found for any configure output$msg");
8586   }
8587
8588 my $nthreads = get_number_of_threads ();
8589
8590 if ($perl_threads && $nthreads >= 1)
8591   {
8592     handle_makefiles_threaded ($nthreads);
8593   }
8594 else
8595   {
8596     handle_makefiles_serial ();
8597   }
8598
8599 exit $exit_code;
8600
8601
8602 ### Setup "GNU" style for perl-mode and cperl-mode.
8603 ## Local Variables:
8604 ## perl-indent-level: 2
8605 ## perl-continued-statement-offset: 2
8606 ## perl-continued-brace-offset: 0
8607 ## perl-brace-offset: 0
8608 ## perl-brace-imaginary-offset: 0
8609 ## perl-label-offset: -2
8610 ## cperl-indent-level: 2
8611 ## cperl-brace-offset: 0
8612 ## cperl-continued-brace-offset: 0
8613 ## cperl-label-offset: -2
8614 ## cperl-extra-newline-before-brace: t
8615 ## cperl-merge-trailing-else: nil
8616 ## cperl-continued-statement-offset: 2
8617 ## End: