automake.in

   1 #!@PERL@ -w
   2 # -*- perl -*-
   3 # @configure_input@
   4
   5 eval 'case $# in 0) exec @PERL@ -S "$0";; *) exec @PERL@ -S "$0" "$@";; esac'
   6     if 0;
   7
   8 # automake - create Makefile.in from Makefile.am
   9 # Copyright (C) 1994-2012 Free Software Foundation, Inc.
  10
  11 # This program is free software; you can redistribute it and/or modify
  12 # it under the terms of the GNU General Public License as published by
  13 # the Free Software Foundation; either version 2, or (at your option)
  14 # any later version.
  15
  16 # This program is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 # GNU General Public License for more details.
  20
  21 # You should have received a copy of the GNU General Public License
  22 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 # Originally written by David Mackenzie <djm@gnu.ai.mit.edu>.
  25 # Perl reimplementation by Tom Tromey <tromey@redhat.com>, and
  26 # Alexandre Duret-Lutz <adl@gnu.org>.
  27
  28 package Language;
  29
  30 BEGIN
  31 {
  32   my $perllibdir = $ENV{'perllibdir'} || '@datadir@/@PACKAGE@-@APIVERSION@';
  33   unshift @INC, (split '@PATH_SEPARATOR@', $perllibdir);
  34
  35   # Override SHELL.  This is required on DJGPP so that system() uses
  36   # bash, not COMMAND.COM which doesn't quote arguments properly.
  37   # Other systems aren't expected to use $SHELL when Automake
  38   # runs, but it should be safe to drop the "if DJGPP" guard if
  39   # it turns up other systems need the same thing.  After all,
  40   # if SHELL is used, ./configure's SHELL is always better than
  41   # the user's SHELL (which may be something like tcsh).
  42   $ENV{'SHELL'} = '@SHELL@' if exists $ENV{'DJDIR'};
  43 }
  44
  45 use Class::Struct ();
  46 Class::Struct::struct (
  47         # Short name of the language (c, f77...).
  48         'name' => "\$",
  49         # Nice name of the language (C, Fortran 77...).
  50         'Name' => "\$",
  51
  52         # List of configure variables which must be defined.
  53         'config_vars' => '@',
  54
  55         # 'pure' is '1' or ''.  A 'pure' language is one where, if
  56         # all the files in a directory are of that language, then we
  57         # do not require the C compiler or any code to call it.
  58         'pure'   => "\$",
  59
  60         'autodep' => "\$",
  61
  62         # Name of the compiling variable (COMPILE).
  63         'compiler'  => "\$",
  64         # Content of the compiling variable.
  65         'compile'  => "\$",
  66         # Flag to require compilation without linking (-c).
  67         'compile_flag' => "\$",
  68         'extensions' => '@',
  69         # A subroutine to compute a list of possible extensions of
  70         # the product given the input extensions.
  71         # (defaults to a subroutine which returns ('.$(OBJEXT)', '.lo'))
  72         'output_extensions' => "\$",
  73         # A list of flag variables used in 'compile'.
  74         # (defaults to [])
  75         'flags' => "@",
  76
  77         # Any tag to pass to libtool while compiling.
  78         'libtool_tag' => "\$",
  79
  80         # The file to use when generating rules for this language.
  81         # The default is 'depend2'.
  82         'rule_file' => "\$",
  83
  84         # Name of the linking variable (LINK).
  85         'linker' => "\$",
  86         # Content of the linking variable.
  87         'link' => "\$",
  88
  89         # Name of the compiler variable (CC).
  90         'ccer' => "\$",
  91
  92         # Name of the linker variable (LD).
  93         'lder' => "\$",
  94         # Content of the linker variable ($(CC)).
  95         'ld' => "\$",
  96
  97         # Flag to specify the output file (-o).
  98         'output_flag' => "\$",
  99         '_finish' => "\$",
 100
 101         # This is a subroutine which is called whenever we finally
 102         # determine the context in which a source file will be
 103         # compiled.
 104         '_target_hook' => "\$",
 105
 106         # If TRUE, nodist_ sources will be compiled using specific rules
 107         # (i.e. not inference rules).  The default is FALSE.
 108         'nodist_specific' => "\$");
 109
 110
 111 sub finish ($)
 112 {
 113   my ($self) = @_;
 114   if (defined $self->_finish)
 115     {
 116       &{$self->_finish} (@_);
 117     }
 118 }
 119
 120 sub target_hook ($$$$%)
 121 {
 122     my ($self) = @_;
 123     if (defined $self->_target_hook)
 124     {
 125         &{$self->_target_hook} (@_);
 126     }
 127 }
 128
 129 package Automake;
 130
 131 use strict;
 132 use Automake::Config;
 133 BEGIN
 134 {
 135   if ($perl_threads)
 136     {
 137       require threads;
 138       import threads;
 139       require Thread::Queue;
 140       import Thread::Queue;
 141     }
 142 }
 143 use Automake::General;
 144 use Automake::XFile;
 145 use Automake::Channels;
 146 use Automake::ChannelDefs;
 147 use Automake::Configure_ac;
 148 use Automake::FileUtils;
 149 use Automake::Location;
 150 use Automake::Condition qw/TRUE FALSE/;
 151 use Automake::DisjConditions;
 152 use Automake::Options;
 153 use Automake::Variable;
 154 use Automake::VarDef;
 155 use Automake::Rule;
 156 use Automake::RuleDef;
 157 use Automake::Wrap 'makefile_wrap';
 158 use File::Basename;
 159 use File::Spec;
 160 use Carp;
 161
 162 ## ----------- ##
 163 ## Constants.  ##
 164 ## ----------- ##
 165
 166 # Some regular expressions.  One reason to put them here is that it
 167 # makes indentation work better in Emacs.
 168
 169 # Writing singled-quoted-$-terminated regexes is a pain because
 170 # perl-mode thinks of $' as the ${'} variable (instead of a $ followed
 171 # by a closing quote.  Letting perl-mode think the quote is not closed
 172 # leads to all sort of misindentations.  On the other hand, defining
 173 # regexes as double-quoted strings is far less readable.  So usually
 174 # we will write:
 175 #
 176 #  $REGEX = '^regex_value' . "\$";
 177
 178 my $IGNORE_PATTERN = '^\s*##([^#\n].*)?\n';
 179 my $WHITE_PATTERN = '^\s*' . "\$";
 180 my $COMMENT_PATTERN = '^#';
 181 my $TARGET_PATTERN='[$a-zA-Z0-9_.@%][-.a-zA-Z0-9_(){}/$+@%]*';
 182 # A rule has three parts: a list of targets, a list of dependencies,
 183 # and optionally actions.
 184 my $RULE_PATTERN =
 185   "^($TARGET_PATTERN(?:(?:\\\\\n|\\s)+$TARGET_PATTERN)*) *:([^=].*|)\$";
 186
 187 # Only recognize leading spaces, not leading tabs.  If we recognize
 188 # leading tabs here then we need to make the reader smarter, because
 189 # otherwise it will think rules like 'foo=bar; \' are errors.
 190 my $ASSIGNMENT_PATTERN = '^ *([^ \t=:+]*)\s*([:+]?)=\s*(.*)' . "\$";
 191 # This pattern recognizes a Gnits version id and sets $1 if the
 192 # release is an alpha release.  We also allow a suffix which can be
 193 # used to extend the version number with a "fork" identifier.
 194 my $GNITS_VERSION_PATTERN = '\d+\.\d+([a-z]|\.\d+)?(-[A-Za-z0-9]+)?';
 195
 196 my $IF_PATTERN = '^if\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*)\s*(?:#.*)?' . "\$";
 197 my $ELSE_PATTERN =
 198   '^else(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 199 my $ENDIF_PATTERN =
 200   '^endif(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 201 my $PATH_PATTERN = '(\w|[+/.-])+';
 202 # This will pass through anything not of the prescribed form.
 203 my $INCLUDE_PATTERN = ('^include\s+'
 204                        . '((\$\(top_srcdir\)/' . $PATH_PATTERN . ')'
 205                        . '|(\$\(srcdir\)/' . $PATH_PATTERN . ')'
 206                        . '|([^/\$]' . $PATH_PATTERN . '))\s*(#.*)?' . "\$");
 207
 208 # Directories installed during 'install-exec' phase.
 209 my $EXEC_DIR_PATTERN =
 210   '^(?:bin|sbin|libexec|sysconf|localstate|lib|pkglib|.*exec.*)' . "\$";
 211
 212 # Values for AC_CANONICAL_*
 213 use constant AC_CANONICAL_BUILD  => 1;
 214 use constant AC_CANONICAL_HOST   => 2;
 215 use constant AC_CANONICAL_TARGET => 3;
 216
 217 # Values indicating when something should be cleaned.
 218 use constant MOSTLY_CLEAN     => 0;
 219 use constant CLEAN            => 1;
 220 use constant DIST_CLEAN       => 2;
 221 use constant MAINTAINER_CLEAN => 3;
 222
 223 # Libtool files.
 224 my @libtool_files = qw(ltmain.sh config.guess config.sub);
 225 # ltconfig appears here for compatibility with old versions of libtool.
 226 my @libtool_sometimes = qw(ltconfig ltcf-c.sh ltcf-cxx.sh ltcf-gcj.sh);
 227
 228 # Commonly found files we look for and automatically include in
 229 # DISTFILES.
 230 my @common_files =
 231     (qw(ABOUT-GNU ABOUT-NLS AUTHORS BACKLOG COPYING COPYING.DOC COPYING.LIB
 232         COPYING.LESSER ChangeLog INSTALL NEWS README THANKS TODO
 233         ar-lib compile config.guess config.rpath
 234         config.sub depcomp elisp-comp install-sh libversion.in mdate-sh
 235         missing mkinstalldirs py-compile texinfo.tex ylwrap),
 236      @libtool_files, @libtool_sometimes);
 237
 238 # Commonly used files we auto-include, but only sometimes.  This list
 239 # is used for the --help output only.
 240 my @common_sometimes =
 241   qw(aclocal.m4 acconfig.h config.h.top config.h.bot configure
 242      configure.ac configure.in stamp-vti);
 243
 244 # Standard directories from the GNU Coding Standards, and additional
 245 # pkg* directories from Automake.  Stored in a hash for fast member check.
 246 my %standard_prefix =
 247     map { $_ => 1 } (qw(bin data dataroot doc dvi exec html include info
 248                         lib libexec lisp locale localstate man man1 man2
 249                         man3 man4 man5 man6 man7 man8 man9 oldinclude pdf
 250                         pkgdata pkginclude pkglib pkglibexec ps sbin
 251                         sharedstate sysconf));
 252
 253 # Copyright on generated Makefile.ins.
 254 my $gen_copyright = "\
 255 # Copyright (C) 1994-$RELEASE_YEAR Free Software Foundation, Inc.
 256
 257 # This Makefile.in is free software; the Free Software Foundation
 258 # gives unlimited permission to copy and/or distribute it,
 259 # with or without modifications, as long as this notice is preserved.
 260
 261 # This program is distributed in the hope that it will be useful,
 262 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
 263 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 264 # PARTICULAR PURPOSE.
 265 ";
 266
 267 # These constants are returned by the lang_*_rewrite functions.
 268 # LANG_SUBDIR means that the resulting object file should be in a
 269 # subdir if the source file is.  In this case the file name cannot
 270 # have '..' components.
 271 use constant LANG_IGNORE  => 0;
 272 use constant LANG_PROCESS => 1;
 273 use constant LANG_SUBDIR  => 2;
 274
 275 # These are used when keeping track of whether an object can be built
 276 # by two different paths.
 277 use constant COMPILE_LIBTOOL  => 1;
 278 use constant COMPILE_ORDINARY => 2;
 279
 280 # We can't always associate a location to a variable or a rule,
 281 # when it's defined by Automake.  We use INTERNAL in this case.
 282 use constant INTERNAL => new Automake::Location;
 283
 284 # Serialization keys for message queues.
 285 use constant QUEUE_MESSAGE   => "msg";
 286 use constant QUEUE_CONF_FILE => "conf file";
 287 use constant QUEUE_LOCATION  => "location";
 288 use constant QUEUE_STRING    => "string";
 289
 290 ## ---------------------------------- ##
 291 ## Variables related to the options.  ##
 292 ## ---------------------------------- ##
 293
 294 # TRUE if we should always generate Makefile.in.
 295 my $force_generation = 1;
 296
 297 # From the Perl manual.
 298 my $symlink_exists = (eval 'symlink ("", "");', $@ eq '');
 299
 300 # TRUE if missing standard files should be installed.
 301 my $add_missing = 0;
 302
 303 # TRUE if we should copy missing files; otherwise symlink if possible.
 304 my $copy_missing = 0;
 305
 306 # TRUE if we should always update files that we know about.
 307 my $force_missing = 0;
 308
 309
 310 ## ---------------------------------------- ##
 311 ## Variables filled during files scanning.  ##
 312 ## ---------------------------------------- ##
 313
 314 # Name of the configure.ac file.
 315 my $configure_ac;
 316
 317 # Files found by scanning configure.ac for LIBOBJS.
 318 my %libsources = ();
 319
 320 # Names used in AC_CONFIG_HEADER call.
 321 my @config_headers = ();
 322
 323 # Names used in AC_CONFIG_LINKS call.
 324 my @config_links = ();
 325
 326 # List of Makefile.am's to process, and their corresponding outputs.
 327 my @input_files = ();
 328 my %output_files = ();
 329
 330 # Complete list of Makefile.am's that exist.
 331 my @configure_input_files = ();
 332
 333 # List of files in AC_CONFIG_FILES/AC_OUTPUT without Makefile.am's,
 334 # and their outputs.
 335 my @other_input_files = ();
 336 # Where each AC_CONFIG_FILES/AC_OUTPUT/AC_CONFIG_LINK/AC_CONFIG_HEADER appears.
 337 # The keys are the files created by these macros.
 338 my %ac_config_files_location = ();
 339 # The condition under which AC_CONFIG_FOOS appears.
 340 my %ac_config_files_condition = ();
 341
 342 # Directory to search for configure-required files.  This
 343 # will be computed by &locate_aux_dir and can be set using
 344 # AC_CONFIG_AUX_DIR in configure.ac.
 345 # $CONFIG_AUX_DIR is the 'raw' directory, valid only in the source-tree.
 346 my $config_aux_dir = '';
 347 my $config_aux_dir_set_in_configure_ac = 0;
 348 # $AM_CONFIG_AUX_DIR is prefixed with $(top_srcdir), so it can be used
 349 # in Makefiles.
 350 my $am_config_aux_dir = '';
 351
 352 # Directory to search for AC_LIBSOURCE files, as set by AC_CONFIG_LIBOBJ_DIR
 353 # in configure.ac.
 354 my $config_libobj_dir = '';
 355
 356 # Whether AM_GNU_GETTEXT has been seen in configure.ac.
 357 my $seen_gettext = 0;
 358 # Whether AM_GNU_GETTEXT([external]) is used.
 359 my $seen_gettext_external = 0;
 360 # Where AM_GNU_GETTEXT appears.
 361 my $ac_gettext_location;
 362 # Whether AM_GNU_GETTEXT_INTL_SUBDIR has been seen.
 363 my $seen_gettext_intl = 0;
 364
 365 # Lists of tags supported by Libtool.
 366 my %libtool_tags = ();
 367 # 1 if Libtool uses LT_SUPPORTED_TAG.  If it does, then it also
 368 # uses AC_REQUIRE_AUX_FILE.
 369 my $libtool_new_api = 0;
 370
 371 # Most important AC_CANONICAL_* macro seen so far.
 372 my $seen_canonical = 0;
 373
 374 # Where AM_MAINTAINER_MODE appears.
 375 my $seen_maint_mode;
 376
 377 # Actual version we've seen.
 378 my $package_version = '';
 379
 380 # Where version is defined.
 381 my $package_version_location;
 382
 383 # TRUE if we've seen AM_PROG_AR
 384 my $seen_ar = 0;
 385
 386 # TRUE if we've seen AM_PROG_CC_C_O
 387 my $seen_cc_c_o = 0;
 388
 389 # Location of AC_REQUIRE_AUX_FILE calls, indexed by their argument.
 390 my %required_aux_file = ();
 391
 392 # Where AM_INIT_AUTOMAKE is called;
 393 my $seen_init_automake = 0;
 394
 395 # TRUE if we've seen AM_AUTOMAKE_VERSION.
 396 my $seen_automake_version = 0;
 397
 398 # Hash table of discovered configure substitutions.  Keys are names,
 399 # values are 'FILE:LINE' strings which are used by error message
 400 # generation.
 401 my %configure_vars = ();
 402
 403 # Ignored configure substitutions (i.e., variables not to be output in
 404 # Makefile.in)
 405 my %ignored_configure_vars = ();
 406
 407 # Files included by $configure_ac.
 408 my @configure_deps = ();
 409
 410 # Greatest timestamp of configure's dependencies.
 411 my $configure_deps_greatest_timestamp = 0;
 412
 413 # Hash table of AM_CONDITIONAL variables seen in configure.
 414 my %configure_cond = ();
 415
 416 # This maps extensions onto language names.
 417 my %extension_map = ();
 418
 419 # List of the DIST_COMMON files we discovered while reading
 420 # configure.ac.
 421 my $configure_dist_common = '';
 422
 423 # This maps languages names onto objects.
 424 my %languages = ();
 425 # Maps each linker variable onto a language object.
 426 my %link_languages = ();
 427
 428 # maps extensions to needed source flags.
 429 my %sourceflags = ();
 430
 431 # List of targets we must always output.
 432 # FIXME: Complete, and remove falsely required targets.
 433 my %required_targets =
 434   (
 435    'all'          => 1,
 436    'dvi'          => 1,
 437    'pdf'          => 1,
 438    'ps'           => 1,
 439    'info'         => 1,
 440    'install-info' => 1,
 441    'install'      => 1,
 442    'install-data' => 1,
 443    'install-exec' => 1,
 444    'uninstall'    => 1,
 445
 446    # FIXME: Not required, temporary hacks.
 447    # Well, actually they are sort of required: the -recursive
 448    # targets will run them anyway...
 449    'html-am'         => 1,
 450    'dvi-am'          => 1,
 451    'pdf-am'          => 1,
 452    'ps-am'           => 1,
 453    'info-am'         => 1,
 454    'install-data-am' => 1,
 455    'install-exec-am' => 1,
 456    'install-html-am' => 1,
 457    'install-dvi-am'  => 1,
 458    'install-pdf-am'  => 1,
 459    'install-ps-am'   => 1,
 460    'install-info-am' => 1,
 461    'installcheck-am' => 1,
 462    'uninstall-am' => 1,
 463
 464    'install-man' => 1,
 465   );
 466
 467 # Queue to push require_conf_file requirements to.
 468 my $required_conf_file_queue;
 469
 470 # The name of the Makefile currently being processed.
 471 my $am_file = 'BUG';
 472
 473 ################################################################
 474
 475 ## ------------------------------------------ ##
 476 ## Variables reset by &initialize_per_input.  ##
 477 ## ------------------------------------------ ##
 478
 479 # Basename and relative dir of the input file.
 480 my $am_file_name;
 481 my $am_relative_dir;
 482
 483 # Same but wrt Makefile.in.
 484 my $in_file_name;
 485 my $relative_dir;
 486
 487 # Greatest timestamp of the output's dependencies (excluding
 488 # configure's dependencies).
 489 my $output_deps_greatest_timestamp;
 490
 491 # These variables are used when generating each Makefile.in.
 492 # They hold the Makefile.in until it is ready to be printed.
 493 my $output_vars;
 494 my $output_all;
 495 my $output_header;
 496 my $output_rules;
 497 my $output_trailer;
 498
 499 # This is the conditional stack, updated on if/else/endif, and
 500 # used to build Condition objects.
 501 my @cond_stack;
 502
 503 # This holds the set of included files.
 504 my @include_stack;
 505
 506 # List of dependencies for the obvious targets.
 507 my @all;
 508 my @check;
 509 my @check_tests;
 510
 511 # Keys in this hash table are files to delete.  The associated
 512 # value tells when this should happen (MOSTLY_CLEAN, DIST_CLEAN, etc.)
 513 my %clean_files;
 514
 515 # Keys in this hash table are object files or other files in
 516 # subdirectories which need to be removed.  This only holds files
 517 # which are created by compilations.  The value in the hash indicates
 518 # when the file should be removed.
 519 my %compile_clean_files;
 520
 521 # Keys in this hash table are directories where we expect to build a
 522 # libtool object.  We use this information to decide what directories
 523 # to delete.
 524 my %libtool_clean_directories;
 525
 526 # Value of $(SOURCES), used by tags.am.
 527 my @sources;
 528 # Sources which go in the distribution.
 529 my @dist_sources;
 530
 531 # This hash maps object file names onto their corresponding source
 532 # file names.  This is used to ensure that each object is created
 533 # by a single source file.
 534 my %object_map;
 535
 536 # This hash maps object file names onto an integer value representing
 537 # whether this object has been built via ordinary compilation or
 538 # libtool compilation (the COMPILE_* constants).
 539 my %object_compilation_map;
 540
 541
 542 # This keeps track of the directories for which we've already
 543 # created dirstamp code.  Keys are directories, values are stamp files.
 544 # Several keys can share the same stamp files if they are equivalent
 545 # (as are './/foo' and 'foo').
 546 my %directory_map;
 547
 548 # All .P files.
 549 my %dep_files;
 550
 551 # This is a list of all targets to run during "make dist".
 552 my @dist_targets;
 553
 554 # Keep track of all programs declared in this Makefile, without
 555 # $(EXEEXT).  @substitutions@ are not listed.
 556 my %known_programs;
 557 my %known_libraries;
 558
 559 # This keeps track of which extensions we've seen (that we care
 560 # about).
 561 my %extension_seen;
 562
 563 # This is random scratch space for the language finish functions.
 564 # Don't randomly overwrite it; examine other uses of keys first.
 565 my %language_scratch;
 566
 567 # We keep track of which objects need special (per-executable)
 568 # handling on a per-language basis.
 569 my %lang_specific_files;
 570
 571 # This is set when 'handle_dist' has finished.  Once this happens,
 572 # we should no longer push on dist_common.
 573 my $handle_dist_run;
 574
 575 # Used to store a set of linkers needed to generate the sources currently
 576 # under consideration.
 577 my %linkers_used;
 578
 579 # True if we need 'LINK' defined.  This is a hack.
 580 my $need_link;
 581
 582 # Does the generated Makefile have to build some compiled object
 583 # (for binary programs, or plain or libtool libraries)?
 584 my $must_handle_compiled_objects;
 585
 586 # Record each file processed by make_paragraphs.
 587 my %transformed_files;
 588
 589 ################################################################
 590
 591 ## ---------------------------------------------- ##
 592 ## Variables not reset by &initialize_per_input.  ##
 593 ## ---------------------------------------------- ##
 594
 595 # Cache each file processed by make_paragraphs.
 596 # (This is different from %transformed_files because
 597 # %transformed_files is reset for each file while %am_file_cache
 598 # it global to the run.)
 599 my %am_file_cache;
 600
 601 ################################################################
 602
 603 # var_SUFFIXES_trigger ($TYPE, $VALUE)
 604 # ------------------------------------
 605 # This is called by Automake::Variable::define() when SUFFIXES
 606 # is defined ($TYPE eq '') or appended ($TYPE eq '+').
 607 # The work here needs to be performed as a side-effect of the
 608 # macro_define() call because SUFFIXES definitions impact
 609 # on $KNOWN_EXTENSIONS_PATTERN which is used used when parsing
 610 # the input am file.
 611 sub var_SUFFIXES_trigger ($$)
 612 {
 613     my ($type, $value) = @_;
 614     accept_extensions (split (' ', $value));
 615 }
 616 Automake::Variable::hook ('SUFFIXES', \&var_SUFFIXES_trigger);
 617
 618 ################################################################
 619
 620 ## --------------------------------- ##
 621 ## Forward subroutine declarations.  ##
 622 ## --------------------------------- ##
 623 sub register_language (%);
 624 sub file_contents_internal ($$$%);
 625 sub define_files_variable ($\@$$);
 626
 627
 628 # &initialize_per_input ()
 629 # ------------------------
 630 # (Re)-Initialize per-Makefile.am variables.
 631 sub initialize_per_input ()
 632 {
 633     reset_local_duplicates ();
 634
 635     $am_file_name = undef;
 636     $am_relative_dir = undef;
 637
 638     $in_file_name = undef;
 639     $relative_dir = undef;
 640
 641     $output_deps_greatest_timestamp = 0;
 642
 643     $output_vars = '';
 644     $output_all = '';
 645     $output_header = '';
 646     $output_rules = '';
 647     $output_trailer = '';
 648
 649     Automake::Options::reset;
 650     Automake::Variable::reset;
 651     Automake::Rule::reset;
 652
 653     @cond_stack = ();
 654
 655     @include_stack = ();
 656
 657     @all = ();
 658     @check = ();
 659     @check_tests = ();
 660
 661     %clean_files = ();
 662     %compile_clean_files = ();
 663
 664     # We always include '.'.  This isn't strictly correct.
 665     %libtool_clean_directories = ('.' => 1);
 666
 667     @sources = ();
 668     @dist_sources = ();
 669
 670     %object_map = ();
 671     %object_compilation_map = ();
 672
 673     %directory_map = ();
 674
 675     %dep_files = ();
 676
 677     @dist_targets = ();
 678
 679     %known_programs = ();
 680     %known_libraries= ();
 681
 682     %extension_seen = ();
 683
 684     %language_scratch = ();
 685
 686     %lang_specific_files = ();
 687
 688     $handle_dist_run = 0;
 689
 690     $need_link = 0;
 691
 692     $must_handle_compiled_objects = 0;
 693
 694     %transformed_files = ();
 695 }
 696
 697
 698 ################################################################
 699
 700 # Initialize our list of languages that are internally supported.
 701
 702 # C.
 703 register_language ('name' => 'c',
 704                    'Name' => 'C',
 705                    'config_vars' => ['CC'],
 706                    'autodep' => '',
 707                    'flags' => ['CFLAGS', 'CPPFLAGS'],
 708                    'ccer' => 'CC',
 709                    'compiler' => 'COMPILE',
 710                    'compile' => '$(CC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CFLAGS) $(CFLAGS)',
 711                    'lder' => 'CCLD',
 712                    'ld' => '$(CC)',
 713                    'linker' => 'LINK',
 714                    'link' => '$(CCLD) $(AM_CFLAGS) $(CFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 715                    'compile_flag' => '-c',
 716                    'libtool_tag' => 'CC',
 717                    'extensions' => ['.c']);
 718
 719 # C++.
 720 register_language ('name' => 'cxx',
 721                    'Name' => 'C++',
 722                    'config_vars' => ['CXX'],
 723                    'linker' => 'CXXLINK',
 724                    'link' => '$(CXXLD) $(AM_CXXFLAGS) $(CXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 725                    'autodep' => 'CXX',
 726                    'flags' => ['CXXFLAGS', 'CPPFLAGS'],
 727                    'compile' => '$(CXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CXXFLAGS) $(CXXFLAGS)',
 728                    'ccer' => 'CXX',
 729                    'compiler' => 'CXXCOMPILE',
 730                    'compile_flag' => '-c',
 731                    'output_flag' => '-o',
 732                    'libtool_tag' => 'CXX',
 733                    'lder' => 'CXXLD',
 734                    'ld' => '$(CXX)',
 735                    'pure' => 1,
 736                    'extensions' => ['.c++', '.cc', '.cpp', '.cxx', '.C']);
 737
 738 # Objective C.
 739 register_language ('name' => 'objc',
 740                    'Name' => 'Objective C',
 741                    'config_vars' => ['OBJC'],
 742                    'linker' => 'OBJCLINK',
 743                    'link' => '$(OBJCLD) $(AM_OBJCFLAGS) $(OBJCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 744                    'autodep' => 'OBJC',
 745                    'flags' => ['OBJCFLAGS', 'CPPFLAGS'],
 746                    'compile' => '$(OBJC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCFLAGS) $(OBJCFLAGS)',
 747                    'ccer' => 'OBJC',
 748                    'compiler' => 'OBJCCOMPILE',
 749                    'compile_flag' => '-c',
 750                    'output_flag' => '-o',
 751                    'lder' => 'OBJCLD',
 752                    'ld' => '$(OBJC)',
 753                    'pure' => 1,
 754                    'extensions' => ['.m']);
 755
 756 # Objective C++.
 757 register_language ('name' => 'objcxx',
 758                    'Name' => 'Objective C++',
 759                    'config_vars' => ['OBJCXX'],
 760                    'linker' => 'OBJCXXLINK',
 761                    'link' => '$(OBJCXXLD) $(AM_OBJCXXFLAGS) $(OBJCXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 762                    'autodep' => 'OBJCXX',
 763                    'flags' => ['OBJCXXFLAGS', 'CPPFLAGS'],
 764                    'compile' => '$(OBJCXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCXXFLAGS) $(OBJCXXFLAGS)',
 765                    'ccer' => 'OBJCXX',
 766                    'compiler' => 'OBJCXXCOMPILE',
 767                    'compile_flag' => '-c',
 768                    'output_flag' => '-o',
 769                    'lder' => 'OBJCXXLD',
 770                    'ld' => '$(OBJCXX)',
 771                    'pure' => 1,
 772                    'extensions' => ['.mm']);
 773
 774 # Unified Parallel C.
 775 register_language ('name' => 'upc',
 776                    'Name' => 'Unified Parallel C',
 777                    'config_vars' => ['UPC'],
 778                    'linker' => 'UPCLINK',
 779                    'link' => '$(UPCLD) $(AM_UPCFLAGS) $(UPCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 780                    'autodep' => 'UPC',
 781                    'flags' => ['UPCFLAGS', 'CPPFLAGS'],
 782                    'compile' => '$(UPC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_UPCFLAGS) $(UPCFLAGS)',
 783                    'ccer' => 'UPC',
 784                    'compiler' => 'UPCCOMPILE',
 785                    'compile_flag' => '-c',
 786                    'output_flag' => '-o',
 787                    'lder' => 'UPCLD',
 788                    'ld' => '$(UPC)',
 789                    'pure' => 1,
 790                    'extensions' => ['.upc']);
 791
 792 # Headers.
 793 register_language ('name' => 'header',
 794                    'Name' => 'Header',
 795                    'extensions' => ['.h', '.H', '.hxx', '.h++', '.hh',
 796                                     '.hpp', '.inc'],
 797                    # No output.
 798                    'output_extensions' => sub { return () },
 799                    # Nothing to do.
 800                    '_finish' => sub { });
 801
 802 # Vala
 803 register_language ('name' => 'vala',
 804                    'Name' => 'Vala',
 805                    'config_vars' => ['VALAC'],
 806                    'flags' => [],
 807                    'compile' => '$(VALAC) $(AM_VALAFLAGS) $(VALAFLAGS)',
 808                    'ccer' => 'VALAC',
 809                    'compiler' => 'VALACOMPILE',
 810                    'extensions' => ['.vala'],
 811                    'output_extensions' => sub { (my $ext = $_[0]) =~ s/vala$/c/;
 812                                                 return ($ext,) },
 813                    'rule_file' => 'vala',
 814                    '_finish' => \&lang_vala_finish,
 815                    '_target_hook' => \&lang_vala_target_hook,
 816                    'nodist_specific' => 1);
 817
 818 # Yacc (C & C++).
 819 register_language ('name' => 'yacc',
 820                    'Name' => 'Yacc',
 821                    'config_vars' => ['YACC'],
 822                    'flags' => ['YFLAGS'],
 823                    'compile' => '$(YACC) $(AM_YFLAGS) $(YFLAGS)',
 824                    'ccer' => 'YACC',
 825                    'compiler' => 'YACCCOMPILE',
 826                    'extensions' => ['.y'],
 827                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 828                                                 return ($ext,) },
 829                    'rule_file' => 'yacc',
 830                    '_finish' => \&lang_yacc_finish,
 831                    '_target_hook' => \&lang_yacc_target_hook,
 832                    'nodist_specific' => 1);
 833 register_language ('name' => 'yaccxx',
 834                    'Name' => 'Yacc (C++)',
 835                    'config_vars' => ['YACC'],
 836                    'rule_file' => 'yacc',
 837                    'flags' => ['YFLAGS'],
 838                    'ccer' => 'YACC',
 839                    'compiler' => 'YACCCOMPILE',
 840                    'compile' => '$(YACC) $(AM_YFLAGS) $(YFLAGS)',
 841                    'extensions' => ['.y++', '.yy', '.yxx', '.ypp'],
 842                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 843                                                 return ($ext,) },
 844                    '_finish' => \&lang_yacc_finish,
 845                    '_target_hook' => \&lang_yacc_target_hook,
 846                    'nodist_specific' => 1);
 847
 848 # Lex (C & C++).
 849 register_language ('name' => 'lex',
 850                    'Name' => 'Lex',
 851                    'config_vars' => ['LEX'],
 852                    'rule_file' => 'lex',
 853                    'flags' => ['LFLAGS'],
 854                    'compile' => '$(LEX) $(AM_LFLAGS) $(LFLAGS)',
 855                    'ccer' => 'LEX',
 856                    'compiler' => 'LEXCOMPILE',
 857                    'extensions' => ['.l'],
 858                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 859                                                 return ($ext,) },
 860                    '_finish' => \&lang_lex_finish,
 861                    '_target_hook' => \&lang_lex_target_hook,
 862                    'nodist_specific' => 1);
 863 register_language ('name' => 'lexxx',
 864                    'Name' => 'Lex (C++)',
 865                    'config_vars' => ['LEX'],
 866                    'rule_file' => 'lex',
 867                    'flags' => ['LFLAGS'],
 868                    'compile' => '$(LEX) $(AM_LFLAGS) $(LFLAGS)',
 869                    'ccer' => 'LEX',
 870                    'compiler' => 'LEXCOMPILE',
 871                    'extensions' => ['.l++', '.ll', '.lxx', '.lpp'],
 872                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 873                                                 return ($ext,) },
 874                    '_finish' => \&lang_lex_finish,
 875                    '_target_hook' => \&lang_lex_target_hook,
 876                    'nodist_specific' => 1);
 877
 878 # Assembler.
 879 register_language ('name' => 'asm',
 880                    'Name' => 'Assembler',
 881                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 882
 883                    'flags' => ['CCASFLAGS'],
 884                    # Users can set AM_CCASFLAGS to include DEFS, INCLUDES,
 885                    # or anything else required.  They can also set CCAS.
 886                    # Or simply use Preprocessed Assembler.
 887                    'compile' => '$(CCAS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 888                    'ccer' => 'CCAS',
 889                    'compiler' => 'CCASCOMPILE',
 890                    'compile_flag' => '-c',
 891                    'output_flag' => '-o',
 892                    'extensions' => ['.s']);
 893
 894 # Preprocessed Assembler.
 895 register_language ('name' => 'cppasm',
 896                    'Name' => 'Preprocessed Assembler',
 897                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 898
 899                    'autodep' => 'CCAS',
 900                    'flags' => ['CCASFLAGS', 'CPPFLAGS'],
 901                    'compile' => '$(CCAS) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 902                    'ccer' => 'CPPAS',
 903                    'compiler' => 'CPPASCOMPILE',
 904                    'compile_flag' => '-c',
 905                    'output_flag' => '-o',
 906                    'extensions' => ['.S', '.sx']);
 907
 908 # Fortran 77
 909 register_language ('name' => 'f77',
 910                    'Name' => 'Fortran 77',
 911                    'config_vars' => ['F77'],
 912                    'linker' => 'F77LINK',
 913                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 914                    'flags' => ['FFLAGS'],
 915                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS)',
 916                    'ccer' => 'F77',
 917                    'compiler' => 'F77COMPILE',
 918                    'compile_flag' => '-c',
 919                    'output_flag' => '-o',
 920                    'libtool_tag' => 'F77',
 921                    'lder' => 'F77LD',
 922                    'ld' => '$(F77)',
 923                    'pure' => 1,
 924                    'extensions' => ['.f', '.for']);
 925
 926 # Fortran
 927 register_language ('name' => 'fc',
 928                    'Name' => 'Fortran',
 929                    'config_vars' => ['FC'],
 930                    'linker' => 'FCLINK',
 931                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 932                    'flags' => ['FCFLAGS'],
 933                    'compile' => '$(FC) $(AM_FCFLAGS) $(FCFLAGS)',
 934                    'ccer' => 'FC',
 935                    'compiler' => 'FCCOMPILE',
 936                    'compile_flag' => '-c',
 937                    'output_flag' => '-o',
 938                    'libtool_tag' => 'FC',
 939                    'lder' => 'FCLD',
 940                    'ld' => '$(FC)',
 941                    'pure' => 1,
 942                    'extensions' => ['.f90', '.f95', '.f03', '.f08']);
 943
 944 # Preprocessed Fortran
 945 register_language ('name' => 'ppfc',
 946                    'Name' => 'Preprocessed Fortran',
 947                    'config_vars' => ['FC'],
 948                    'linker' => 'FCLINK',
 949                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 950                    'lder' => 'FCLD',
 951                    'ld' => '$(FC)',
 952                    'flags' => ['FCFLAGS', 'CPPFLAGS'],
 953                    'ccer' => 'PPFC',
 954                    'compiler' => 'PPFCCOMPILE',
 955                    'compile' => '$(FC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FCFLAGS) $(FCFLAGS)',
 956                    'compile_flag' => '-c',
 957                    'output_flag' => '-o',
 958                    'libtool_tag' => 'FC',
 959                    'pure' => 1,
 960                    'extensions' => ['.F90','.F95', '.F03', '.F08']);
 961
 962 # Preprocessed Fortran 77
 963 #
 964 # The current support for preprocessing Fortran 77 just involves
 965 # passing "$(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS)
 966 # $(CPPFLAGS)" as additional flags to the Fortran 77 compiler, since
 967 # this is how GNU Make does it; see the "GNU Make Manual, Edition 0.51
 968 # for 'make' Version 3.76 Beta" (specifically, from info file
 969 # '(make)Catalogue of Rules').
 970 #
 971 # A better approach would be to write an Autoconf test
 972 # (i.e. AC_PROG_FPP) for a Fortran 77 preprocessor, because not all
 973 # Fortran 77 compilers know how to do preprocessing.  The Autoconf
 974 # macro AC_PROG_FPP should test the Fortran 77 compiler first for
 975 # preprocessing capabilities, and then fall back on cpp (if cpp were
 976 # available).
 977 register_language ('name' => 'ppf77',
 978                    'Name' => 'Preprocessed Fortran 77',
 979                    'config_vars' => ['F77'],
 980                    'linker' => 'F77LINK',
 981                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 982                    'lder' => 'F77LD',
 983                    'ld' => '$(F77)',
 984                    'flags' => ['FFLAGS', 'CPPFLAGS'],
 985                    'ccer' => 'PPF77',
 986                    'compiler' => 'PPF77COMPILE',
 987                    'compile' => '$(F77) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FFLAGS) $(FFLAGS)',
 988                    'compile_flag' => '-c',
 989                    'output_flag' => '-o',
 990                    'libtool_tag' => 'F77',
 991                    'pure' => 1,
 992                    'extensions' => ['.F']);
 993
 994 # Ratfor.
 995 register_language ('name' => 'ratfor',
 996                    'Name' => 'Ratfor',
 997                    'config_vars' => ['F77'],
 998                    'linker' => 'F77LINK',
 999                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
1000                    'lder' => 'F77LD',
1001                    'ld' => '$(F77)',
1002                    'flags' => ['RFLAGS', 'FFLAGS'],
1003                    # FIXME also FFLAGS.
1004                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS) $(AM_RFLAGS) $(RFLAGS)',
1005                    'ccer' => 'F77',
1006                    'compiler' => 'RCOMPILE',
1007                    'compile_flag' => '-c',
1008                    'output_flag' => '-o',
1009                    'libtool_tag' => 'F77',
1010                    'pure' => 1,
1011                    'extensions' => ['.r']);
1012
1013 # Java via gcj.
1014 register_language ('name' => 'java',
1015                    'Name' => 'Java',
1016                    'config_vars' => ['GCJ'],
1017                    'linker' => 'GCJLINK',
1018                    'link' => '$(GCJLD) $(AM_GCJFLAGS) $(GCJFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
1019                    'autodep' => 'GCJ',
1020                    'flags' => ['GCJFLAGS'],
1021                    'compile' => '$(GCJ) $(AM_GCJFLAGS) $(GCJFLAGS)',
1022                    'ccer' => 'GCJ',
1023                    'compiler' => 'GCJCOMPILE',
1024                    'compile_flag' => '-c',
1025                    'output_flag' => '-o',
1026                    'libtool_tag' => 'GCJ',
1027                    'lder' => 'GCJLD',
1028                    'ld' => '$(GCJ)',
1029                    'pure' => 1,
1030                    'extensions' => ['.java', '.class', '.zip', '.jar']);
1031
1032 ################################################################
1033
1034 # Error reporting functions.
1035
1036 # err_am ($MESSAGE, [%OPTIONS])
1037 # -----------------------------
1038 # Uncategorized errors about the current Makefile.am.
1039 sub err_am ($;%)
1040 {
1041   msg_am ('error', @_);
1042 }
1043
1044 # err_ac ($MESSAGE, [%OPTIONS])
1045 # -----------------------------
1046 # Uncategorized errors about configure.ac.
1047 sub err_ac ($;%)
1048 {
1049   msg_ac ('error', @_);
1050 }
1051
1052 # msg_am ($CHANNEL, $MESSAGE, [%OPTIONS])
1053 # ---------------------------------------
1054 # Messages about about the current Makefile.am.
1055 sub msg_am ($$;%)
1056 {
1057   my ($channel, $msg, %opts) = @_;
1058   msg $channel, "${am_file}.am", $msg, %opts;
1059 }
1060
1061 # msg_ac ($CHANNEL, $MESSAGE, [%OPTIONS])
1062 # ---------------------------------------
1063 # Messages about about configure.ac.
1064 sub msg_ac ($$;%)
1065 {
1066   my ($channel, $msg, %opts) = @_;
1067   msg $channel, $configure_ac, $msg, %opts;
1068 }
1069
1070 ################################################################
1071
1072 # subst ($TEXT)
1073 # -------------
1074 # Return a configure-style substitution using the indicated text.
1075 # We do this to avoid having the substitutions directly in automake.in;
1076 # when we do that they are sometimes removed and this causes confusion
1077 # and bugs.
1078 sub subst ($)
1079 {
1080     my ($text) = @_;
1081     return '@' . $text . '@';
1082 }
1083
1084 ################################################################
1085
1086
1087 # $BACKPATH
1088 # &backname ($RELDIR)
1089 # --------------------
1090 # If I "cd $RELDIR", then to come back, I should "cd $BACKPATH".
1091 # For instance 'src/foo' => '../..'.
1092 # Works with non strictly increasing paths, i.e., 'src/../lib' => '..'.
1093 sub backname ($)
1094 {
1095     my ($file) = @_;
1096     my @res;
1097     foreach (split (/\//, $file))
1098     {
1099         next if $_ eq '.' || $_ eq '';
1100         if ($_ eq '..')
1101         {
1102             pop @res
1103               or prog_error ("trying to reverse path '$file' pointing outside tree");
1104         }
1105         else
1106         {
1107             push (@res, '..');
1108         }
1109     }
1110     return join ('/', @res) || '.';
1111 }
1112
1113 ################################################################
1114
1115 # 'silent-rules' mode handling functions.
1116
1117 # verbose_var (NAME)
1118 # ------------------
1119 # The public variable stem used to implement 'silent-rules'.
1120 sub verbose_var ($)
1121 {
1122     my ($name) = @_;
1123     return 'AM_V_' . $name;
1124 }
1125
1126 # verbose_private_var (NAME)
1127 # --------------------------
1128 # The naming policy for the private variables for 'silent-rules'.
1129 sub verbose_private_var ($)
1130 {
1131     my ($name) = @_;
1132     return 'am__v_' . $name;
1133 }
1134
1135 # define_verbose_var (NAME, VAL-IF-SILENT, [VAL-IF-VERBOSE])
1136 # ----------------------------------------------------------
1137 # For 'silent-rules' mode, setup VAR and dispatcher, to expand to
1138 # VAL-IF-SILENT if silent, to VAL-IF-VERBOSE (defaulting to empty)
1139 # if not.
1140 sub define_verbose_var ($$;$)
1141 {
1142     my ($name, $silent_val, $verbose_val) = @_;
1143     $verbose_val = '' unless defined $verbose_val;
1144     my $var = verbose_var ($name);
1145     my $pvar = verbose_private_var ($name);
1146     my $silent_var = $pvar . '_0';
1147     my $verbose_var = $pvar . '_1';
1148     if (option 'silent-rules')
1149       {
1150         # For typical 'make's, 'configure' replaces AM_V (inside @@) with $(V)
1151         # and AM_DEFAULT_V (inside @@) with $(AM_DEFAULT_VERBOSITY).
1152         # For strict POSIX 2008 'make's, it replaces them with 0 or 1 instead.
1153         # See AM_SILENT_RULES in m4/silent.m4.
1154         define_variable ($var, '$(' . $pvar . '_@'.'AM_V'.'@)', INTERNAL);
1155         define_variable ($pvar . '_', '$(' . $pvar . '_@'.'AM_DEFAULT_V'.'@)', INTERNAL);
1156         Automake::Variable::define ($silent_var, VAR_AUTOMAKE, '', TRUE,
1157                                     $silent_val, '', INTERNAL, VAR_ASIS)
1158           if (! vardef ($silent_var, TRUE));
1159         Automake::Variable::define ($verbose_var, VAR_AUTOMAKE, '', TRUE,
1160                                     $verbose_val, '', INTERNAL, VAR_ASIS)
1161           if (! vardef ($verbose_var, TRUE));
1162 }
1163 }
1164
1165 # Above should not be needed in the general automake code.
1166
1167 # verbose_flag (NAME)
1168 # -------------------
1169 # Contents of %VERBOSE%: variable to expand before rule command.
1170 sub verbose_flag ($)
1171 {
1172     my ($name) = @_;
1173     return '$(' . verbose_var ($name) . ')'
1174       if (option 'silent-rules');
1175     return '';
1176 }
1177
1178 sub verbose_nodep_flag ($)
1179 {
1180     my ($name) = @_;
1181     return '$(' . verbose_var ($name) . subst ('am__nodep') . ')'
1182       if (option 'silent-rules');
1183     return '';
1184 }
1185
1186 # silent_flag
1187 # -----------
1188 # Contents of %SILENT%: variable to expand to '@' when silent.
1189 sub silent_flag ()
1190 {
1191     return verbose_flag ('at');
1192 }
1193
1194 # define_verbose_tagvar (NAME)
1195 # ----------------------------
1196 # Engage the needed 'silent-rules' machinery for tag NAME.
1197 sub define_verbose_tagvar ($)
1198 {
1199     my ($name) = @_;
1200     if (option 'silent-rules')
1201       {
1202         define_verbose_var ($name, '@echo "  '. $name . ' ' x (8 - length ($name)) . '" $@;');
1203       }
1204 }
1205
1206 # define_verbose_texinfo
1207 # ----------------------
1208 # Engage the needed 'silent-rules' machinery for assorted texinfo commands.
1209 sub define_verbose_texinfo ()
1210 {
1211   my @tagvars = ('DVIPS', 'MAKEINFO', 'INFOHTML', 'TEXI2DVI', 'TEXI2PDF');
1212   foreach my $tag (@tagvars)
1213     {
1214       define_verbose_tagvar($tag);
1215     }
1216   define_verbose_var('texinfo', '-q');
1217   define_verbose_var('texidevnull', '> /dev/null');
1218 }
1219
1220 # define_verbose_libtool
1221 # ----------------------
1222 # Engage the needed 'silent-rules' machinery for 'libtool --silent'.
1223 sub define_verbose_libtool ()
1224 {
1225     define_verbose_var ('lt', '--silent');
1226     return verbose_flag ('lt');
1227 }
1228
1229 sub handle_silent ()
1230 {
1231     return unless option 'silent-rules';
1232     # Define "$(AM_V_P)", expanding to a shell conditional that can be
1233     # used in make recipes to determine whether we are being run in
1234     # silent mode or not.  The choice of the name derives from the LISP
1235     # convention of appending the letter 'P' to denote a predicate (see
1236     # also "the '-P' convention" in the Jargon File); we do so for lack
1237     # of a better convention.
1238     define_verbose_var ('P', 'false', ':');
1239     # *Always* provide the user with 'AM_V_GEN' for 'silent-rules' mode.
1240     define_verbose_tagvar ('GEN');
1241     define_verbose_var ('at', '@');
1242 }
1243
1244
1245 ################################################################
1246
1247
1248 # Handle AUTOMAKE_OPTIONS variable.  Return 1 on error, 0 otherwise.
1249 sub handle_options
1250 {
1251   my $var = var ('AUTOMAKE_OPTIONS');
1252   if ($var)
1253     {
1254       if ($var->has_conditional_contents)
1255         {
1256           msg_var ('unsupported', $var,
1257                    "'AUTOMAKE_OPTIONS' cannot have conditional contents");
1258         }
1259       my @options = map { { option => $_->[1], where => $_->[0] } }
1260                         $var->value_as_list_recursive (cond_filter => TRUE,
1261                                                        location => 1);
1262       return 1 if process_option_list (@options);
1263     }
1264
1265   # Override portability-recursive warning.
1266   switch_warning ('no-portability-recursive')
1267     if option 'silent-rules';
1268
1269   if ($strictness == GNITS)
1270     {
1271       set_option ('readme-alpha', INTERNAL);
1272       set_option ('std-options', INTERNAL);
1273       set_option ('check-news', INTERNAL);
1274     }
1275
1276   return 0;
1277 }
1278
1279 # shadow_unconditionally ($varname, $where)
1280 # -----------------------------------------
1281 # Return a $(variable) that contains all possible values
1282 # $varname can take.
1283 # If the VAR wasn't defined conditionally, return $(VAR).
1284 # Otherwise we create an am__VAR_DIST variable which contains
1285 # all possible values, and return $(am__VAR_DIST).
1286 sub shadow_unconditionally ($$)
1287 {
1288   my ($varname, $where) = @_;
1289   my $var = var $varname;
1290   if ($var->has_conditional_contents)
1291     {
1292       $varname = "am__${varname}_DIST";
1293       my @files = uniq ($var->value_as_list_recursive);
1294       define_pretty_variable ($varname, TRUE, $where, @files);
1295     }
1296   return "\$($varname)"
1297 }
1298
1299 # check_user_variables (@LIST)
1300 # ----------------------------
1301 # Make sure each variable VAR in @LIST does not exist, suggest using AM_VAR
1302 # otherwise.
1303 sub check_user_variables (@)
1304 {
1305   my @dont_override = @_;
1306   foreach my $flag (@dont_override)
1307     {
1308       my $var = var $flag;
1309       if ($var)
1310         {
1311           for my $cond ($var->conditions->conds)
1312             {
1313               if ($var->rdef ($cond)->owner == VAR_MAKEFILE)
1314                 {
1315                   msg_cond_var ('gnu', $cond, $flag,
1316                                 "'$flag' is a user variable, "
1317                                 . "you should not override it;\n"
1318                                 . "use 'AM_$flag' instead");
1319                 }
1320             }
1321         }
1322     }
1323 }
1324
1325 # Call finish function for each language that was used.
1326 sub handle_languages
1327 {
1328     if (! option 'no-dependencies')
1329     {
1330         # Include auto-dep code.  Don't include it if DEP_FILES would
1331         # be empty.
1332         if (&saw_sources_p (0) && keys %dep_files)
1333         {
1334             # Set location of depcomp.
1335             &define_variable ('depcomp',
1336                               "\$(SHELL) $am_config_aux_dir/depcomp",
1337                               INTERNAL);
1338             &define_variable ('am__depfiles_maybe', 'depfiles', INTERNAL);
1339
1340             require_conf_file ("$am_file.am", FOREIGN, 'depcomp');
1341
1342             my @deplist = sort keys %dep_files;
1343             # Generate each 'include' individually.  Irix 6 make will
1344             # not properly include several files resulting from a
1345             # variable expansion; generating many separate includes
1346             # seems safest.
1347             $output_rules .= "\n";
1348             foreach my $iter (@deplist)
1349             {
1350                 $output_rules .= (subst ('AMDEP_TRUE')
1351                                   . subst ('am__include')
1352                                   . ' '
1353                                   . subst ('am__quote')
1354                                   . $iter
1355                                   . subst ('am__quote')
1356                                   . "\n");
1357             }
1358
1359             # Compute the set of directories to remove in distclean-depend.
1360             my @depdirs = uniq (map { dirname ($_) } @deplist);
1361             $output_rules .= &file_contents ('depend',
1362                                              new Automake::Location,
1363                                              DEPDIRS => "@depdirs");
1364         }
1365     }
1366     else
1367     {
1368         &define_variable ('depcomp', '', INTERNAL);
1369         &define_variable ('am__depfiles_maybe', '', INTERNAL);
1370     }
1371
1372     my %done;
1373
1374     # Is the C linker needed?
1375     my $needs_c = 0;
1376     foreach my $ext (sort keys %extension_seen)
1377     {
1378         next unless $extension_map{$ext};
1379
1380         my $lang = $languages{$extension_map{$ext}};
1381
1382         my $rule_file = $lang->rule_file || 'depend2';
1383
1384         # Get information on $LANG.
1385         my $pfx = $lang->autodep;
1386         my $fpfx = ($pfx eq '') ? 'CC' : $pfx;
1387
1388         my ($AMDEP, $FASTDEP) =
1389           (option 'no-dependencies' || $lang->autodep eq 'no')
1390           ? ('FALSE', 'FALSE') : ('AMDEP', "am__fastdep$fpfx");
1391
1392         my $verbose = verbose_flag ($lang->ccer || 'GEN');
1393         my $verbose_nodep = ($AMDEP eq 'FALSE')
1394           ? $verbose : verbose_nodep_flag ($lang->ccer || 'GEN');
1395         my $silent = silent_flag ();
1396
1397         my %transform = ('EXT'     => $ext,
1398                          'PFX'     => $pfx,
1399                          'FPFX'    => $fpfx,
1400                          'AMDEP'   => $AMDEP,
1401                          'FASTDEP' => $FASTDEP,
1402                          '-c'      => $lang->compile_flag || '',
1403                          # These are not used, but they need to be defined
1404                          # so &transform do not complain.
1405                          SUBDIROBJ     => 0,
1406                          'DERIVED-EXT' => 'BUG',
1407                          DIST_SOURCE   => 1,
1408                          VERBOSE   => $verbose,
1409                          'VERBOSE-NODEP' => $verbose_nodep,
1410                          SILENT    => $silent,
1411                         );
1412
1413         # Generate the appropriate rules for this extension.
1414         if (((! option 'no-dependencies') && $lang->autodep ne 'no')
1415             || defined $lang->compile)
1416         {
1417             # Some C compilers don't support -c -o.  Use it only if really
1418             # needed.
1419             my $output_flag = $lang->output_flag || '';
1420             $output_flag = '-o'
1421               if (! $output_flag
1422                   && $lang->name eq 'c'
1423                   && option 'subdir-objects');
1424
1425             # Compute a possible derived extension.
1426             # This is not used by depend2.am.
1427             my $der_ext = (&{$lang->output_extensions} ($ext))[0];
1428
1429             # When we output an inference rule like '.c.o:' we
1430             # have two cases to consider: either subdir-objects
1431             # is used, or it is not.
1432             #
1433             # In the latter case the rule is used to build objects
1434             # in the current directory, and dependencies always
1435             # go into './$(DEPDIR)/'.  We can hard-code this value.
1436             #
1437             # In the former case the rule can be used to build
1438             # objects in sub-directories too.  Dependencies should
1439             # go into the appropriate sub-directories, e.g.,
1440             # 'sub/$(DEPDIR)/'.  The value of this directory
1441             # needs to be computed on-the-fly.
1442             #
1443             # DEPBASE holds the name of this directory, plus the
1444             # basename part of the object file (extensions Po, TPo,
1445             # Plo, TPlo will be added later as appropriate).  It is
1446             # either hardcoded, or a shell variable ('$depbase') that
1447             # will be computed by the rule.
1448             my $depbase =
1449               option ('subdir-objects') ? '$$depbase' : '$(DEPDIR)/$*';
1450             $output_rules .=
1451               file_contents ($rule_file,
1452                              new Automake::Location,
1453                              %transform,
1454                              GENERIC   => 1,
1455
1456                              'DERIVED-EXT' => $der_ext,
1457
1458                              DEPBASE   => $depbase,
1459                              BASE      => '$*',
1460                              SOURCE    => '$<',
1461                              SOURCEFLAG => $sourceflags{$ext} || '',
1462                              OBJ       => '$@',
1463                              OBJOBJ    => '$@',
1464                              LTOBJ     => '$@',
1465
1466                              COMPILE   => '$(' . $lang->compiler . ')',
1467                              LTCOMPILE => '$(LT' . $lang->compiler . ')',
1468                              -o        => $output_flag,
1469                              SUBDIROBJ => !! option 'subdir-objects');
1470         }
1471
1472         # Now include code for each specially handled object with this
1473         # language.
1474         my %seen_files = ();
1475         foreach my $file (@{$lang_specific_files{$lang->name}})
1476         {
1477             my ($derived, $source, $obj, $myext, $srcext, %file_transform) = @$file;
1478
1479             # We might see a given object twice, for instance if it is
1480             # used under different conditions.
1481             next if defined $seen_files{$obj};
1482             $seen_files{$obj} = 1;
1483
1484             prog_error ("found " . $lang->name .
1485                         " in handle_languages, but compiler not defined")
1486               unless defined $lang->compile;
1487
1488             my $obj_compile = $lang->compile;
1489
1490             # Rewrite each occurrence of 'AM_$flag' in the compile
1491             # rule into '${derived}_$flag' if it exists.
1492             for my $flag (@{$lang->flags})
1493               {
1494                 my $val = "${derived}_$flag";
1495                 $obj_compile =~ s/\(AM_$flag\)/\($val\)/
1496                   if set_seen ($val);
1497               }
1498
1499             my $libtool_tag = '';
1500             if ($lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag})
1501               {
1502                 $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
1503               }
1504
1505             my $ptltflags = "${derived}_LIBTOOLFLAGS";
1506             $ptltflags = 'AM_LIBTOOLFLAGS' unless set_seen $ptltflags;
1507
1508             my $ltverbose = define_verbose_libtool ();
1509             my $obj_ltcompile =
1510               "\$(LIBTOOL) $ltverbose $libtool_tag\$($ptltflags) \$(LIBTOOLFLAGS) "
1511               . "--mode=compile $obj_compile";
1512
1513             # We _need_ '-o' for per object rules.
1514             my $output_flag = $lang->output_flag || '-o';
1515
1516             my $depbase = dirname ($obj);
1517             $depbase = ''
1518                 if $depbase eq '.';
1519             $depbase .= '/'
1520                 unless $depbase eq '';
1521             $depbase .= '$(DEPDIR)/' . basename ($obj);
1522
1523             $output_rules .=
1524               file_contents ($rule_file,
1525                              new Automake::Location,
1526                              %transform,
1527                              GENERIC   => 0,
1528
1529                              DEPBASE   => $depbase,
1530                              BASE      => $obj,
1531                              SOURCE    => $source,
1532                              SOURCEFLAG => $sourceflags{$srcext} || '',
1533                              # Use $myext and not '.o' here, in case
1534                              # we are actually building a new source
1535                              # file -- e.g. via yacc.
1536                              OBJ       => "$obj$myext",
1537                              OBJOBJ    => "$obj.obj",
1538                              LTOBJ     => "$obj.lo",
1539
1540                              VERBOSE   => $verbose,
1541                              'VERBOSE-NODEP'  => $verbose_nodep,
1542                              SILENT    => $silent,
1543                              COMPILE   => $obj_compile,
1544                              LTCOMPILE => $obj_ltcompile,
1545                              -o        => $output_flag,
1546                              %file_transform);
1547         }
1548
1549         # The rest of the loop is done once per language.
1550         next if defined $done{$lang};
1551         $done{$lang} = 1;
1552
1553         # Load the language dependent Makefile chunks.
1554         my %lang = map { uc ($_) => 0 } keys %languages;
1555         $lang{uc ($lang->name)} = 1;
1556         $output_rules .= file_contents ('lang-compile',
1557                                         new Automake::Location,
1558                                         %transform, %lang);
1559
1560         # If the source to a program consists entirely of code from a
1561         # 'pure' language, for instance C++ or Fortran 77, then we
1562         # don't need the C compiler code.  However if we run into
1563         # something unusual then we do generate the C code.  There are
1564         # probably corner cases here that do not work properly.
1565         # People linking Java code to Fortran code deserve pain.
1566         $needs_c ||= ! $lang->pure;
1567
1568         define_compiler_variable ($lang)
1569           if ($lang->compile);
1570
1571         define_linker_variable ($lang)
1572           if ($lang->link);
1573
1574         require_variables ("$am_file.am", $lang->Name . " source seen",
1575                            TRUE, @{$lang->config_vars});
1576
1577         # Call the finisher.
1578         $lang->finish;
1579
1580         # Flags listed in '->flags' are user variables (per GNU Standards),
1581         # they should not be overridden in the Makefile...
1582         my @dont_override = @{$lang->flags};
1583         # ... and so is LDFLAGS.
1584         push @dont_override, 'LDFLAGS' if $lang->link;
1585
1586         check_user_variables @dont_override;
1587     }
1588
1589     # If the project is entirely C++ or entirely Fortran 77 (i.e., 1
1590     # suffix rule was learned), don't bother with the C stuff.  But if
1591     # anything else creeps in, then use it.
1592     $needs_c = 1
1593       if $need_link || suffix_rules_count > 1;
1594
1595     if ($needs_c)
1596       {
1597         &define_compiler_variable ($languages{'c'})
1598           unless defined $done{$languages{'c'}};
1599         define_linker_variable ($languages{'c'});
1600       }
1601 }
1602
1603
1604 # append_exeext { PREDICATE } $MACRO
1605 # ----------------------------------
1606 # Append $(EXEEXT) to each filename in $F appearing in the Makefile
1607 # variable $MACRO if &PREDICATE($F) is true.  @substitutions@ are
1608 # ignored.
1609 #
1610 # This is typically used on all filenames of *_PROGRAMS, and filenames
1611 # of TESTS that are programs.
1612 sub append_exeext (&$)
1613 {
1614   my ($pred, $macro) = @_;
1615
1616   transform_variable_recursively
1617     ($macro, $macro, 'am__EXEEXT', 0, INTERNAL,
1618      sub {
1619        my ($subvar, $val, $cond, $full_cond) = @_;
1620        # Append $(EXEEXT) unless the user did it already, or it's a
1621        # @substitution@.
1622        $val .= '$(EXEEXT)'
1623          if $val !~ /(?:\$\(EXEEXT\)$|^[@]\w+[@]$)/ && &$pred ($val);
1624        return $val;
1625      });
1626 }
1627
1628
1629 # Check to make sure a source defined in LIBOBJS is not explicitly
1630 # mentioned.  This is a separate function (as opposed to being inlined
1631 # in handle_source_transform) because it isn't always appropriate to
1632 # do this check.
1633 sub check_libobjs_sources
1634 {
1635   my ($one_file, $unxformed) = @_;
1636
1637   foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1638                       'dist_EXTRA_', 'nodist_EXTRA_')
1639     {
1640       my @files;
1641       my $varname = $prefix . $one_file . '_SOURCES';
1642       my $var = var ($varname);
1643       if ($var)
1644         {
1645           @files = $var->value_as_list_recursive;
1646         }
1647       elsif ($prefix eq '')
1648         {
1649           @files = ($unxformed . '.c');
1650         }
1651       else
1652         {
1653           next;
1654         }
1655
1656       foreach my $file (@files)
1657         {
1658           err_var ($prefix . $one_file . '_SOURCES',
1659                    "automatically discovered file '$file' should not" .
1660                    " be explicitly mentioned")
1661             if defined $libsources{$file};
1662         }
1663     }
1664 }
1665
1666
1667 # @OBJECTS
1668 # handle_single_transform ($VAR, $TOPPARENT, $DERIVED, $OBJ, $FILE, %TRANSFORM)
1669 # -----------------------------------------------------------------------------
1670 # Does much of the actual work for handle_source_transform.
1671 # Arguments are:
1672 #   $VAR is the name of the variable that the source filenames come from
1673 #   $TOPPARENT is the name of the _SOURCES variable which is being processed
1674 #   $DERIVED is the name of resulting executable or library
1675 #   $OBJ is the object extension (e.g., '.lo')
1676 #   $FILE the source file to transform
1677 #   %TRANSFORM contains extras arguments to pass to file_contents
1678 #     when producing explicit rules
1679 # Result is a list of the names of objects
1680 # %linkers_used will be updated with any linkers needed
1681 sub handle_single_transform ($$$$$%)
1682 {
1683     my ($var, $topparent, $derived, $obj, $_file, %transform) = @_;
1684     my @files = ($_file);
1685     my @result = ();
1686
1687     # Turn sources into objects.  We use a while loop like this
1688     # because we might add to @files in the loop.
1689     while (scalar @files > 0)
1690     {
1691         $_ = shift @files;
1692
1693         # Configure substitutions in _SOURCES variables are errors.
1694         if (/^\@.*\@$/)
1695         {
1696           my $parent_msg = '';
1697           $parent_msg = "\nand is referred to from '$topparent'"
1698             if $topparent ne $var->name;
1699           err_var ($var,
1700                    "'" . $var->name . "' includes configure substitution '$_'"
1701                    . $parent_msg . ";\nconfigure " .
1702                    "substitutions are not allowed in _SOURCES variables");
1703           next;
1704         }
1705
1706         # If the source file is in a subdirectory then the '.o' is put
1707         # into the current directory, unless the subdir-objects option
1708         # is in effect.
1709
1710         # Split file name into base and extension.
1711         next if ! /^(?:(.*)\/)?([^\/]*)($KNOWN_EXTENSIONS_PATTERN)$/;
1712         my $full = $_;
1713         my $directory = $1 || '';
1714         my $base = $2;
1715         my $extension = $3;
1716
1717         # We must generate a rule for the object if it requires its own flags.
1718         my $renamed = 0;
1719         my ($linker, $object);
1720
1721         # This records whether we've seen a derived source file (e.g.
1722         # yacc output).
1723         my $derived_source = 0;
1724
1725         # This holds the 'aggregate context' of the file we are
1726         # currently examining.  If the file is compiled with
1727         # per-object flags, then it will be the name of the object.
1728         # Otherwise it will be 'AM'.  This is used by the target hook
1729         # language function.
1730         my $aggregate = 'AM';
1731
1732         $extension = &derive_suffix ($extension, $obj);
1733         my $lang;
1734         if ($extension_map{$extension} &&
1735             ($lang = $languages{$extension_map{$extension}}))
1736         {
1737             # Found the language, so see what it says.
1738             &saw_extension ($extension);
1739
1740             # Do we have per-executable flags for this executable?
1741             my $have_per_exec_flags = 0;
1742             my @peflags = @{$lang->flags};
1743             push @peflags, 'LIBTOOLFLAGS' if $obj eq '.lo';
1744             foreach my $flag (@peflags)
1745               {
1746                 if (set_seen ("${derived}_$flag"))
1747                   {
1748                     $have_per_exec_flags = 1;
1749                     last;
1750                   }
1751               }
1752
1753             # Note: computed subr call.  The language rewrite function
1754             # should return one of the LANG_* constants.  It could
1755             # also return a list whose first value is such a constant
1756             # and whose second value is a new source extension which
1757             # should be applied.  This means this particular language
1758             # generates another source file which we must then process
1759             # further.
1760             my $subr = \&{'lang_' . $lang->name . '_rewrite'};
1761             my ($r, $source_extension)
1762                 = &$subr ($directory, $base, $extension,
1763                           $obj, $have_per_exec_flags, $var);
1764             # Skip this entry if we were asked not to process it.
1765             next if $r == LANG_IGNORE;
1766
1767             # Now extract linker and other info.
1768             $linker = $lang->linker;
1769
1770             my $this_obj_ext;
1771             if (defined $source_extension)
1772             {
1773                 $this_obj_ext = $source_extension;
1774                 $derived_source = 1;
1775             }
1776             else
1777             {
1778                 $this_obj_ext = $obj;
1779             }
1780             $object = $base . $this_obj_ext;
1781
1782             if ($have_per_exec_flags)
1783             {
1784                 # We have a per-executable flag in effect for this
1785                 # object.  In this case we rewrite the object's
1786                 # name to ensure it is unique.
1787
1788                 # We choose the name 'DERIVED_OBJECT' to ensure
1789                 # (1) uniqueness, and (2) continuity between
1790                 # invocations.  However, this will result in a
1791                 # name that is too long for losing systems, in
1792                 # some situations.  So we provide _SHORTNAME to
1793                 # override.
1794
1795                 my $dname = $derived;
1796                 my $var = var ($derived . '_SHORTNAME');
1797                 if ($var)
1798                 {
1799                     # FIXME: should use the same Condition as
1800                     # the _SOURCES variable.  But this is really
1801                     # silly overkill -- nobody should have
1802                     # conditional shortnames.
1803                     $dname = $var->variable_value;
1804                 }
1805                 $object = $dname . '-' . $object;
1806
1807                 prog_error ($lang->name . " flags defined without compiler")
1808                   if ! defined $lang->compile;
1809
1810                 $renamed = 1;
1811             }
1812
1813             # If rewrite said it was ok, put the object into a
1814             # subdir.
1815             if ($r == LANG_SUBDIR && $directory ne '')
1816             {
1817                 $object = $directory . '/' . $object;
1818             }
1819
1820             # If the object file has been renamed (because per-target
1821             # flags are used) we cannot compile the file with an
1822             # inference rule: we need an explicit rule.
1823             #
1824             # If the source is in a subdirectory and the object is in
1825             # the current directory, we also need an explicit rule.
1826             #
1827             # If both source and object files are in a subdirectory
1828             # (this happens when the subdir-objects option is used),
1829             # then the inference will work.
1830             #
1831             # The latter case deserves a historical note.  When the
1832             # subdir-objects option was added on 1999-04-11 it was
1833             # thought that inferences rules would work for
1834             # subdirectory objects too.  Later, on 1999-11-22,
1835             # automake was changed to output explicit rules even for
1836             # subdir-objects.  Nobody remembers why, but this occurred
1837             # soon after the merge of the user-dep-gen-branch so it
1838             # might be related.  In late 2003 people complained about
1839             # the size of the generated Makefile.ins (libgcj, with
1840             # 2200+ subdir objects was reported to have a 9MB
1841             # Makefile), so we now rely on inference rules again.
1842             # Maybe we'll run across the same issue as in the past,
1843             # but at least this time we can document it.  However since
1844             # dependency tracking has evolved it is possible that
1845             # our old problem no longer exists.
1846             # Using inference rules for subdir-objects has been tested
1847             # with GNU make, Solaris make, Ultrix make, BSD make,
1848             # HP-UX make, and OSF1 make successfully.
1849             if ($renamed
1850                 || ($directory ne '' && ! option 'subdir-objects')
1851                 # We must also use specific rules for a nodist_ source
1852                 # if its language requests it.
1853                 || ($lang->nodist_specific && ! $transform{'DIST_SOURCE'}))
1854             {
1855                 my $obj_sans_ext = substr ($object, 0,
1856                                            - length ($this_obj_ext));
1857                 my $full_ansi;
1858                 if ($directory ne '')
1859                   {
1860                         $full_ansi = $directory . '/' . $base . $extension;
1861                   }
1862                 else
1863                   {
1864                         $full_ansi = $base . $extension;
1865                   }
1866
1867                 my @specifics = ($full_ansi, $obj_sans_ext,
1868                                  # Only use $this_obj_ext in the derived
1869                                  # source case because in the other case we
1870                                  # *don't* want $(OBJEXT) to appear here.
1871                                  ($derived_source ? $this_obj_ext : '.o'),
1872                                  $extension);
1873
1874                 # If we renamed the object then we want to use the
1875                 # per-executable flag name.  But if this is simply a
1876                 # subdir build then we still want to use the AM_ flag
1877                 # name.
1878                 if ($renamed)
1879                   {
1880                     unshift @specifics, $derived;
1881                     $aggregate = $derived;
1882                   }
1883                 else
1884                   {
1885                     unshift @specifics, 'AM';
1886                   }
1887
1888                 # Each item on this list is a reference to a list consisting
1889                 # of four values followed by additional transform flags for
1890                 # file_contents.  The four values are the derived flag prefix
1891                 # (e.g. for 'foo_CFLAGS', it is 'foo'), the name of the
1892                 # source file, the base name of the output file, and
1893                 # the extension for the object file.
1894                 push (@{$lang_specific_files{$lang->name}},
1895                       [@specifics, %transform]);
1896             }
1897         }
1898         elsif ($extension eq $obj)
1899         {
1900             # This is probably the result of a direct suffix rule.
1901             # In this case we just accept the rewrite.
1902             $object = "$base$extension";
1903             $object = "$directory/$object" if $directory ne '';
1904             $linker = '';
1905         }
1906         else
1907         {
1908             # No error message here.  Used to have one, but it was
1909             # very unpopular.
1910             # FIXME: we could potentially do more processing here,
1911             # perhaps treating the new extension as though it were a
1912             # new source extension (as above).  This would require
1913             # more restructuring than is appropriate right now.
1914             next;
1915         }
1916
1917         err_am "object '$object' created by '$full' and '$object_map{$object}'"
1918           if (defined $object_map{$object}
1919               && $object_map{$object} ne $full);
1920
1921         my $comp_val = (($object =~ /\.lo$/)
1922                         ? COMPILE_LIBTOOL : COMPILE_ORDINARY);
1923         (my $comp_obj = $object) =~ s/\.lo$/.\$(OBJEXT)/;
1924         if (defined $object_compilation_map{$comp_obj}
1925             && $object_compilation_map{$comp_obj} != 0
1926             # Only see the error once.
1927             && ($object_compilation_map{$comp_obj}
1928                 != (COMPILE_LIBTOOL | COMPILE_ORDINARY))
1929             && $object_compilation_map{$comp_obj} != $comp_val)
1930           {
1931             err_am "object '$comp_obj' created both with libtool and without";
1932           }
1933         $object_compilation_map{$comp_obj} |= $comp_val;
1934
1935         if (defined $lang)
1936         {
1937             # Let the language do some special magic if required.
1938             $lang->target_hook ($aggregate, $object, $full, %transform);
1939         }
1940
1941         if ($derived_source)
1942           {
1943             prog_error ($lang->name . " has automatic dependency tracking")
1944               if $lang->autodep ne 'no';
1945             # Make sure this new source file is handled next.  That will
1946             # make it appear to be at the right place in the list.
1947             unshift (@files, $object);
1948             # Distribute derived sources unless the source they are
1949             # derived from is not.
1950             &push_dist_common ($object)
1951               unless ($topparent =~ /^(?:nobase_)?nodist_/);
1952             next;
1953           }
1954
1955         $linkers_used{$linker} = 1;
1956
1957         push (@result, $object);
1958
1959         if (! defined $object_map{$object})
1960         {
1961             my @dep_list = ();
1962             $object_map{$object} = $full;
1963
1964             # If resulting object is in subdir, we need to make
1965             # sure the subdir exists at build time.
1966             if ($object =~ /\//)
1967             {
1968                 # FIXME: check that $DIRECTORY is somewhere in the
1969                 # project
1970
1971                 # For Java, the way we're handling it right now, a
1972                 # '..' component doesn't make sense.
1973                 if ($lang && $lang->name eq 'java' && $object =~ /(\/|^)\.\.\//)
1974                   {
1975                     err_am "'$full' should not contain a '..' component";
1976                   }
1977
1978                 # Make sure *all* objects files in the subdirectory are
1979                 # removed by "make mostlyclean".  Not only this is more
1980                 # efficient than listing the object files to be removed
1981                 # individually (which would cause an 'rm' invocation for
1982                 # each of them -- very inefficient, see bug#10697), it
1983                 # would also leave stale object files in the subdirectory
1984                 # whenever a source file there is removed or renamed.
1985                 $compile_clean_files{"$directory/*.\$(OBJEXT)"} = MOSTLY_CLEAN;
1986                 if ($object =~ /\.lo$/)
1987                   {
1988                     # If we have a libtool object, then we also must remove
1989                     # any '.lo' objects in its same subdirectory.
1990                     $compile_clean_files{"$directory/*.lo"} = MOSTLY_CLEAN;
1991                     # Remember to cleanup .libs/ in this directory.
1992                     $libtool_clean_directories{$directory} = 1;
1993                   }
1994
1995                 push (@dep_list, require_build_directory ($directory));
1996
1997                 # If we're generating dependencies, we also want
1998                 # to make sure that the appropriate subdir of the
1999                 # .deps directory is created.
2000                 push (@dep_list,
2001                       require_build_directory ($directory . '/$(DEPDIR)'))
2002                   unless option 'no-dependencies';
2003             }
2004
2005             &pretty_print_rule ($object . ':', "\t", @dep_list)
2006                 if scalar @dep_list > 0;
2007         }
2008
2009         # Transform .o or $o file into .P file (for automatic
2010         # dependency code).
2011         # Properly flatten multiple adjacent slashes, as Solaris 10 make
2012         # might fail over them in an include statement.
2013         # Leading double slashes may be special, as per Posix, so deal
2014         # with them carefully.
2015         if ($lang && $lang->autodep ne 'no')
2016         {
2017             my $depfile = $object;
2018             $depfile =~ s/\.([^.]*)$/.P$1/;
2019             $depfile =~ s/\$\(OBJEXT\)$/o/;
2020             my $maybe_extra_leading_slash = '';
2021             $maybe_extra_leading_slash = '/' if $depfile =~ m,^//[^/],;
2022             $depfile =~ s,/+,/,g;
2023             my $basename = basename ($depfile);
2024             # This might make $dirname empty, but we account for that below.
2025             (my $dirname = dirname ($depfile)) =~ s/\/*$//;
2026             $dirname = $maybe_extra_leading_slash . $dirname;
2027             $dep_files{$dirname . '/$(DEPDIR)/' . $basename} = 1;
2028         }
2029     }
2030
2031     return @result;
2032 }
2033
2034
2035 # $LINKER
2036 # define_objects_from_sources ($VAR, $OBJVAR, $NODEFINE, $ONE_FILE,
2037 #                              $OBJ, $PARENT, $TOPPARENT, $WHERE, %TRANSFORM)
2038 # ---------------------------------------------------------------------------
2039 # Define an _OBJECTS variable for a _SOURCES variable (or subvariable)
2040 #
2041 # Arguments are:
2042 #   $VAR is the name of the _SOURCES variable
2043 #   $OBJVAR is the name of the _OBJECTS variable if known (otherwise
2044 #     it will be generated and returned).
2045 #   $NODEFINE is a boolean: if true, $OBJVAR will not be defined (but
2046 #     work done to determine the linker will be).
2047 #   $ONE_FILE is the canonical (transformed) name of object to build
2048 #   $OBJ is the object extension (i.e. either '.o' or '.lo').
2049 #   $TOPPARENT is the _SOURCES variable being processed.
2050 #   $WHERE context into which this definition is done
2051 #   %TRANSFORM extra arguments to pass to file_contents when producing
2052 #     rules
2053 #
2054 # Result is a pair ($LINKER, $OBJVAR):
2055 #    $LINKER is a boolean, true if a linker is needed to deal with the objects
2056 sub define_objects_from_sources ($$$$$$$%)
2057 {
2058   my ($var, $objvar, $nodefine, $one_file,
2059       $obj, $topparent, $where, %transform) = @_;
2060
2061   my $needlinker = "";
2062
2063   transform_variable_recursively
2064     ($var, $objvar, 'am__objects', $nodefine, $where,
2065      # The transform code to run on each filename.
2066      sub {
2067        my ($subvar, $val, $cond, $full_cond) = @_;
2068        my @trans = handle_single_transform ($subvar, $topparent,
2069                                             $one_file, $obj, $val,
2070                                             %transform);
2071        $needlinker = "true" if @trans;
2072        return @trans;
2073      });
2074
2075   return $needlinker;
2076 }
2077
2078
2079 # handle_source_transform ($CANON_TARGET, $TARGET, $OBJEXT, $WHERE, %TRANSFORM)
2080 # -----------------------------------------------------------------------------
2081 # Handle SOURCE->OBJECT transform for one program or library.
2082 # Arguments are:
2083 #   canonical (transformed) name of target to build
2084 #   actual target of object to build
2085 #   object extension (i.e., either '.o' or '$o')
2086 #   location of the source variable
2087 #   extra arguments to pass to file_contents when producing rules
2088 # Return the name of the linker variable that must be used.
2089 # Empty return means just use 'LINK'.
2090 sub handle_source_transform ($$$$%)
2091 {
2092     # one_file is canonical name.  unxformed is given name.  obj is
2093     # object extension.
2094     my ($one_file, $unxformed, $obj, $where, %transform) = @_;
2095
2096     my $linker = '';
2097
2098     # No point in continuing if _OBJECTS is defined.
2099     return if reject_var ($one_file . '_OBJECTS',
2100                           $one_file . '_OBJECTS should not be defined');
2101
2102     my %used_pfx = ();
2103     my $needlinker;
2104     %linkers_used = ();
2105     foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
2106                         'dist_EXTRA_', 'nodist_EXTRA_')
2107     {
2108         my $varname = $prefix . $one_file . "_SOURCES";
2109         my $var = var $varname;
2110         next unless $var;
2111
2112         # We are going to define _OBJECTS variables using the prefix.
2113         # Then we glom them all together.  So we can't use the null
2114         # prefix here as we need it later.
2115         my $xpfx = ($prefix eq '') ? 'am_' : $prefix;
2116
2117         # Keep track of which prefixes we saw.
2118         $used_pfx{$xpfx} = 1
2119           unless $prefix =~ /EXTRA_/;
2120
2121         push @sources, "\$($varname)";
2122         push @dist_sources, shadow_unconditionally ($varname, $where)
2123           unless (option ('no-dist') || $prefix =~ /^nodist_/);
2124
2125         $needlinker |=
2126             define_objects_from_sources ($varname,
2127                                          $xpfx . $one_file . '_OBJECTS',
2128                                          $prefix =~ /EXTRA_/,
2129                                          $one_file, $obj, $varname, $where,
2130                                          DIST_SOURCE => ($prefix !~ /^nodist_/),
2131                                          %transform);
2132     }
2133     if ($needlinker)
2134     {
2135         $linker ||= &resolve_linker (%linkers_used);
2136     }
2137
2138     my @keys = sort keys %used_pfx;
2139     if (scalar @keys == 0)
2140     {
2141         # The default source for libfoo.la is libfoo.c, but for
2142         # backward compatibility we first look at libfoo_la.c,
2143         # if no default source suffix is given.
2144         my $old_default_source = "$one_file.c";
2145         my $ext_var = var ('AM_DEFAULT_SOURCE_EXT');
2146         my $default_source_ext = $ext_var ? variable_value ($ext_var) : '.c';
2147         msg_var ('unsupported', $ext_var, $ext_var->name . " can assume at most one value")
2148           if $default_source_ext =~ /[\t ]/;
2149         (my $default_source = $unxformed) =~ s,(\.[^./\\]*)?$,$default_source_ext,;
2150         if ($old_default_source ne $default_source
2151             && !$ext_var
2152             && (rule $old_default_source
2153                 || rule '$(srcdir)/' . $old_default_source
2154                 || rule '${srcdir}/' . $old_default_source
2155                 || -f $old_default_source))
2156           {
2157             my $loc = $where->clone;
2158             $loc->pop_context;
2159             msg ('obsolete', $loc,
2160                  "the default source for '$unxformed' has been changed "
2161                  . "to '$default_source'.\n(Using '$old_default_source' for "
2162                  . "backward compatibility.)");
2163             $default_source = $old_default_source;
2164           }
2165         # If a rule exists to build this source with a $(srcdir)
2166         # prefix, use that prefix in our variables too.  This is for
2167         # the sake of BSD Make.
2168         if (rule '$(srcdir)/' . $default_source
2169             || rule '${srcdir}/' . $default_source)
2170           {
2171             $default_source = '$(srcdir)/' . $default_source;
2172           }
2173
2174         &define_variable ($one_file . "_SOURCES", $default_source, $where);
2175         push (@sources, $default_source);
2176         push (@dist_sources, $default_source);
2177
2178         %linkers_used = ();
2179         my (@result) =
2180           handle_single_transform ($one_file . '_SOURCES',
2181                                    $one_file . '_SOURCES',
2182                                    $one_file, $obj,
2183                                    $default_source, %transform);
2184         $linker ||= &resolve_linker (%linkers_used);
2185         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @result);
2186     }
2187     else
2188     {
2189         @keys = map { '$(' . $_ . $one_file . '_OBJECTS)' } @keys;
2190         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @keys);
2191     }
2192
2193     # If we want to use 'LINK' we must make sure it is defined.
2194     if ($linker eq '')
2195     {
2196         $need_link = 1;
2197     }
2198
2199     return $linker;
2200 }
2201
2202
2203 # handle_lib_objects ($XNAME, $VAR)
2204 # ---------------------------------
2205 # Special-case ALLOCA and LIBOBJS substitutions in _LDADD or _LIBADD variables.
2206 # Also, generate _DEPENDENCIES variable if appropriate.
2207 # Arguments are:
2208 #   transformed name of object being built, or empty string if no object
2209 #   name of _LDADD/_LIBADD-type variable to examine
2210 # Returns 1 if LIBOBJS seen, 0 otherwise.
2211 sub handle_lib_objects
2212 {
2213   my ($xname, $varname) = @_;
2214
2215   my $var = var ($varname);
2216   prog_error "'$varname' undefined"
2217     unless $var;
2218   prog_error "unexpected variable name '$varname'"
2219     unless $varname =~ /^(.*)(?:LIB|LD)ADD$/;
2220   my $prefix = $1 || 'AM_';
2221
2222   my $seen_libobjs = 0;
2223   my $flagvar = 0;
2224
2225   transform_variable_recursively
2226     ($varname, $xname . '_DEPENDENCIES', 'am__DEPENDENCIES',
2227      ! $xname, INTERNAL,
2228      # Transformation function, run on each filename.
2229      sub {
2230        my ($subvar, $val, $cond, $full_cond) = @_;
2231
2232        if ($val =~ /^-/)
2233          {
2234            # Skip -lfoo and -Ldir silently; these are explicitly allowed.
2235            if ($val !~ /^-[lL]/ &&
2236                # Skip -dlopen and -dlpreopen; these are explicitly allowed
2237                # for Libtool libraries or programs.  (Actually we are a bit
2238                # lax here since this code also applies to non-libtool
2239                # libraries or programs, for which -dlopen and -dlopreopen
2240                # are pure nonsense.  Diagnosing this doesn't seem very
2241                # important: the developer will quickly get complaints from
2242                # the linker.)
2243                $val !~ /^-dl(?:pre)?open$/ &&
2244                # Only get this error once.
2245                ! $flagvar)
2246              {
2247                $flagvar = 1;
2248                # FIXME: should display a stack of nested variables
2249                # as context when $var != $subvar.
2250                err_var ($var, "linker flags such as '$val' belong in "
2251                         . "'${prefix}LDFLAGS'");
2252              }
2253            return ();
2254          }
2255        elsif ($val !~ /^\@.*\@$/)
2256          {
2257            # Assume we have a file of some sort, and output it into the
2258            # dependency variable.  Autoconf substitutions are not output;
2259            # rarely is a new dependency substituted into e.g. foo_LDADD
2260            # -- but bad things (e.g. -lX11) are routinely substituted.
2261            # Note that LIBOBJS and ALLOCA are exceptions to this rule,
2262            # and handled specially below.
2263            return $val;
2264          }
2265        elsif ($val =~ /^\@(LT)?LIBOBJS\@$/)
2266          {
2267            handle_LIBOBJS ($subvar, $cond, $1);
2268            $seen_libobjs = 1;
2269            return $val;
2270          }
2271        elsif ($val =~ /^\@(LT)?ALLOCA\@$/)
2272          {
2273            handle_ALLOCA ($subvar, $cond, $1);
2274            return $val;
2275          }
2276        else
2277          {
2278            return ();
2279          }
2280      });
2281
2282   return $seen_libobjs;
2283 }
2284
2285 # handle_LIBOBJS_or_ALLOCA ($VAR)
2286 # -------------------------------
2287 # Definitions common to LIBOBJS and ALLOCA.
2288 # VAR should be one of LIBOBJS, LTLIBOBJS, ALLOCA, or LTALLOCA.
2289 sub handle_LIBOBJS_or_ALLOCA ($)
2290 {
2291   my ($var) = @_;
2292
2293   my $dir = '';
2294
2295   # If LIBOBJS files must be built in another directory we have
2296   # to define LIBOBJDIR and ensure the files get cleaned.
2297   # Otherwise LIBOBJDIR can be left undefined, and the cleaning
2298   # is achieved by 'rm -f *.$(OBJEXT)' in compile.am.
2299   if ($config_libobj_dir
2300       && $relative_dir ne $config_libobj_dir)
2301     {
2302       if (option 'subdir-objects')
2303         {
2304           # In the top-level Makefile we do not use $(top_builddir), because
2305           # we are already there, and since the targets are built without
2306           # a $(top_builddir), it helps BSD Make to match them with
2307           # dependencies.
2308           $dir = "$config_libobj_dir/"
2309             if $config_libobj_dir ne '.';
2310           $dir = backname ($relative_dir) . "/$dir"
2311             if $relative_dir ne '.';
2312           define_variable ('LIBOBJDIR', "$dir", INTERNAL);
2313           $clean_files{"\$($var)"} = MOSTLY_CLEAN;
2314           # If LTLIBOBJS is used, we must also clear LIBOBJS (which might
2315           # be created by libtool as a side-effect of creating LTLIBOBJS).
2316           $clean_files{"\$($var)"} = MOSTLY_CLEAN if $var =~ s/^LT//;
2317         }
2318       else
2319         {
2320           error ("'\$($var)' cannot be used outside '$config_libobj_dir' if"
2321                  . " 'subdir-objects' is not set");
2322         }
2323     }
2324
2325   return $dir;
2326 }
2327
2328 sub handle_LIBOBJS ($$$)
2329 {
2330   my ($var, $cond, $lt) = @_;
2331   my $myobjext = $lt ? 'lo' : 'o';
2332   $lt ||= '';
2333
2334   $var->requires_variables ("\@${lt}LIBOBJS\@ used", $lt . 'LIBOBJS')
2335     if ! keys %libsources;
2336
2337   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}LIBOBJS";
2338
2339   foreach my $iter (keys %libsources)
2340     {
2341       if ($iter =~ /\.[cly]$/)
2342         {
2343           &saw_extension ($&);
2344           &saw_extension ('.c');
2345         }
2346
2347       if ($iter =~ /\.h$/)
2348         {
2349           require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2350         }
2351       elsif ($iter ne 'alloca.c')
2352         {
2353           my $rewrite = $iter;
2354           $rewrite =~ s/\.c$/.P$myobjext/;
2355           $dep_files{$dir . '$(DEPDIR)/' . $rewrite} = 1;
2356           $rewrite = "^" . quotemeta ($iter) . "\$";
2357           # Only require the file if it is not a built source.
2358           my $bs = var ('BUILT_SOURCES');
2359           if (! $bs || ! grep (/$rewrite/, $bs->value_as_list_recursive))
2360             {
2361               require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2362             }
2363         }
2364     }
2365 }
2366
2367 sub handle_ALLOCA ($$$)
2368 {
2369   my ($var, $cond, $lt) = @_;
2370   my $myobjext = $lt ? 'lo' : 'o';
2371   $lt ||= '';
2372   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}ALLOCA";
2373
2374   $var->requires_variables ("\@${lt}ALLOCA\@ used", $lt . 'ALLOCA');
2375   $dep_files{$dir . '$(DEPDIR)/alloca.P' . $myobjext} = 1;
2376   require_libsource_with_macro ($cond, $var, FOREIGN, 'alloca.c');
2377   &saw_extension ('.c');
2378 }
2379
2380 # Canonicalize the input parameter
2381 sub canonicalize
2382 {
2383     my ($string) = @_;
2384     $string =~ tr/A-Za-z0-9_\@/_/c;
2385     return $string;
2386 }
2387
2388 # Canonicalize a name, and check to make sure the non-canonical name
2389 # is never used.  Returns canonical name.  Arguments are name and a
2390 # list of suffixes to check for.
2391 sub check_canonical_spelling
2392 {
2393   my ($name, @suffixes) = @_;
2394
2395   my $xname = &canonicalize ($name);
2396   if ($xname ne $name)
2397     {
2398       foreach my $xt (@suffixes)
2399         {
2400           reject_var ("$name$xt", "use '$xname$xt', not '$name$xt'");
2401         }
2402     }
2403
2404   return $xname;
2405 }
2406
2407
2408 # handle_compile ()
2409 # -----------------
2410 # Set up the compile suite.
2411 sub handle_compile ()
2412 {
2413    return if ! $must_handle_compiled_objects;
2414
2415     # Boilerplate.
2416     my $default_includes = '';
2417     if (! option 'nostdinc')
2418       {
2419         my @incs = ('-I.', subst ('am__isrc'));
2420
2421         my $var = var 'CONFIG_HEADER';
2422         if ($var)
2423           {
2424             foreach my $hdr (split (' ', $var->variable_value))
2425               {
2426                 push @incs, '-I' . dirname ($hdr);
2427               }
2428           }
2429         # We want '-I. -I$(srcdir)', but the latter -I is redundant
2430         # and unaesthetic in non-VPATH builds.  We use `-I.@am__isrc@`
2431         # instead.  It will be replaced by '-I.' or '-I. -I$(srcdir)'.
2432         # Items in CONFIG_HEADER are never in $(srcdir) so it is safe
2433         # to just put @am__isrc@ right after '-I.', without a space.
2434         ($default_includes = ' ' . uniq (@incs)) =~ s/ @/@/;
2435       }
2436
2437     my (@mostly_rms, @dist_rms);
2438     foreach my $item (sort keys %compile_clean_files)
2439     {
2440         if ($compile_clean_files{$item} == MOSTLY_CLEAN)
2441         {
2442             push (@mostly_rms, "\t-rm -f $item");
2443         }
2444         elsif ($compile_clean_files{$item} == DIST_CLEAN)
2445         {
2446             push (@dist_rms, "\t-rm -f $item");
2447         }
2448         else
2449         {
2450           prog_error 'invalid entry in %compile_clean_files';
2451         }
2452     }
2453
2454     my ($coms, $vars, $rules) =
2455       &file_contents_internal (1, "$libdir/am/compile.am",
2456                                new Automake::Location,
2457                                ('DEFAULT_INCLUDES' => $default_includes,
2458                                 'MOSTLYRMS' => join ("\n", @mostly_rms),
2459                                 'DISTRMS' => join ("\n", @dist_rms)));
2460     $output_vars .= $vars;
2461     $output_rules .= "$coms$rules";
2462 }
2463
2464 # handle_libtool ()
2465 # -----------------
2466 # Handle libtool rules.
2467 sub handle_libtool
2468 {
2469   return unless var ('LIBTOOL');
2470
2471   # Libtool requires some files, but only at top level.
2472   # (Starting with Libtool 2.0 we do not have to bother.  These
2473   # requirements are done with AC_REQUIRE_AUX_FILE.)
2474   require_conf_file_with_macro (TRUE, 'LIBTOOL', FOREIGN, @libtool_files)
2475     if $relative_dir eq '.' && ! $libtool_new_api;
2476
2477   my @libtool_rms;
2478   foreach my $item (sort keys %libtool_clean_directories)
2479     {
2480       my $dir = ($item eq '.') ? '' : "$item/";
2481       # .libs is for Unix, _libs for DOS.
2482       push (@libtool_rms, "\t-rm -rf ${dir}.libs ${dir}_libs");
2483     }
2484
2485   check_user_variables 'LIBTOOLFLAGS';
2486
2487   # Output the libtool compilation rules.
2488   $output_rules .= &file_contents ('libtool',
2489                                    new Automake::Location,
2490                                    LTRMS => join ("\n", @libtool_rms));
2491 }
2492
2493 # handle_programs ()
2494 # ------------------
2495 # Handle C programs.
2496 sub handle_programs
2497 {
2498   my @proglist = &am_install_var ('progs', 'PROGRAMS',
2499                                   'bin', 'sbin', 'libexec', 'pkglibexec',
2500                                   'noinst', 'check');
2501   return if ! @proglist;
2502   $must_handle_compiled_objects = 1;
2503
2504   my $seen_global_libobjs =
2505     var ('LDADD') && &handle_lib_objects ('', 'LDADD');
2506
2507   foreach my $pair (@proglist)
2508     {
2509       my ($where, $one_file) = @$pair;
2510
2511       my $seen_libobjs = 0;
2512       my $obj = '.$(OBJEXT)';
2513
2514       $known_programs{$one_file} = $where;
2515
2516       # Canonicalize names and check for misspellings.
2517       my $xname = &check_canonical_spelling ($one_file, '_LDADD', '_LDFLAGS',
2518                                              '_SOURCES', '_OBJECTS',
2519                                              '_DEPENDENCIES');
2520
2521       $where->push_context ("while processing program '$one_file'");
2522       $where->set (INTERNAL->get);
2523
2524       my $linker = &handle_source_transform ($xname, $one_file, $obj, $where,
2525                                              NONLIBTOOL => 1, LIBTOOL => 0);
2526
2527       if (var ($xname . "_LDADD"))
2528         {
2529           $seen_libobjs = &handle_lib_objects ($xname, $xname . '_LDADD');
2530         }
2531       else
2532         {
2533           # User didn't define prog_LDADD override.  So do it.
2534           &define_variable ($xname . '_LDADD', '$(LDADD)', $where);
2535
2536           # This does a bit too much work.  But we need it to
2537           # generate _DEPENDENCIES when appropriate.
2538           if (var ('LDADD'))
2539             {
2540               $seen_libobjs = &handle_lib_objects ($xname, 'LDADD');
2541             }
2542         }
2543
2544       reject_var ($xname . '_LIBADD',
2545                   "use '${xname}_LDADD', not '${xname}_LIBADD'");
2546
2547       set_seen ($xname . '_DEPENDENCIES');
2548       set_seen ('EXTRA_' . $xname . '_DEPENDENCIES');
2549       set_seen ($xname . '_LDFLAGS');
2550
2551       # Determine program to use for link.
2552       my($xlink, $vlink) = &define_per_target_linker_variable ($linker, $xname);
2553       $vlink = verbose_flag ($vlink || 'GEN');
2554
2555       # If the resulting program lies into a subdirectory,
2556       # make sure this directory will exist.
2557       my $dirstamp = require_build_directory_maybe ($one_file);
2558
2559       $libtool_clean_directories{dirname ($one_file)} = 1;
2560
2561       $output_rules .= &file_contents ('program',
2562                                        $where,
2563                                        PROGRAM  => $one_file,
2564                                        XPROGRAM => $xname,
2565                                        XLINK    => $xlink,
2566                                        VERBOSE  => $vlink,
2567                                        DIRSTAMP => $dirstamp,
2568                                        EXEEXT   => '$(EXEEXT)');
2569
2570       if ($seen_libobjs || $seen_global_libobjs)
2571         {
2572           if (var ($xname . '_LDADD'))
2573             {
2574               &check_libobjs_sources ($xname, $xname . '_LDADD');
2575             }
2576           elsif (var ('LDADD'))
2577             {
2578               &check_libobjs_sources ($xname, 'LDADD');
2579             }
2580         }
2581     }
2582 }
2583
2584
2585 # handle_libraries ()
2586 # -------------------
2587 # Handle libraries.
2588 sub handle_libraries
2589 {
2590   my @liblist = &am_install_var ('libs', 'LIBRARIES',
2591                                  'lib', 'pkglib', 'noinst', 'check');
2592   return if ! @liblist;
2593   $must_handle_compiled_objects = 1;
2594
2595   my @prefix = am_primary_prefixes ('LIBRARIES', 0, 'lib', 'pkglib',
2596                                     'noinst', 'check');
2597
2598   if (@prefix)
2599     {
2600       my $var = rvar ($prefix[0] . '_LIBRARIES');
2601       $var->requires_variables ('library used', 'RANLIB');
2602     }
2603
2604   &define_variable ('AR', 'ar', INTERNAL);
2605   &define_variable ('ARFLAGS', 'cru', INTERNAL);
2606   &define_verbose_tagvar ('AR');
2607
2608   foreach my $pair (@liblist)
2609     {
2610       my ($where, $onelib) = @$pair;
2611
2612       my $seen_libobjs = 0;
2613       # Check that the library fits the standard naming convention.
2614       my $bn = basename ($onelib);
2615       if ($bn !~ /^lib.*\.a$/)
2616         {
2617           $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.a/;
2618           my $suggestion = dirname ($onelib) . "/$bn";
2619           $suggestion =~ s|^\./||g;
2620           msg ('error-gnu/warn', $where,
2621                "'$onelib' is not a standard library name\n"
2622                . "did you mean '$suggestion'?")
2623         }
2624
2625       ($known_libraries{$onelib} = $bn) =~ s/\.a$//;
2626
2627       $where->push_context ("while processing library '$onelib'");
2628       $where->set (INTERNAL->get);
2629
2630       my $obj = '.$(OBJEXT)';
2631
2632       # Canonicalize names and check for misspellings.
2633       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_SOURCES',
2634                                             '_OBJECTS', '_DEPENDENCIES',
2635                                             '_AR');
2636
2637       if (! var ($xlib . '_AR'))
2638         {
2639           &define_variable ($xlib . '_AR', '$(AR) $(ARFLAGS)', $where);
2640         }
2641
2642       # Generate support for conditional object inclusion in
2643       # libraries.
2644       if (var ($xlib . '_LIBADD'))
2645         {
2646           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2647             {
2648               $seen_libobjs = 1;
2649             }
2650         }
2651       else
2652         {
2653           &define_variable ($xlib . "_LIBADD", '', $where);
2654         }
2655
2656       reject_var ($xlib . '_LDADD',
2657                   "use '${xlib}_LIBADD', not '${xlib}_LDADD'");
2658
2659       # Make sure we at look at this.
2660       set_seen ($xlib . '_DEPENDENCIES');
2661       set_seen ('EXTRA_' . $xlib . '_DEPENDENCIES');
2662
2663       &handle_source_transform ($xlib, $onelib, $obj, $where,
2664                                 NONLIBTOOL => 1, LIBTOOL => 0);
2665
2666       # If the resulting library lies into a subdirectory,
2667       # make sure this directory will exist.
2668       my $dirstamp = require_build_directory_maybe ($onelib);
2669       my $verbose = verbose_flag ('AR');
2670       my $silent = silent_flag ();
2671
2672       $output_rules .= &file_contents ('library',
2673                                        $where,
2674                                        VERBOSE  => $verbose,
2675                                        SILENT   => $silent,
2676                                        LIBRARY  => $onelib,
2677                                        XLIBRARY => $xlib,
2678                                        DIRSTAMP => $dirstamp);
2679
2680       if ($seen_libobjs)
2681         {
2682           if (var ($xlib . '_LIBADD'))
2683             {
2684               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2685             }
2686         }
2687
2688       if (! $seen_ar)
2689         {
2690           msg ('extra-portability', $where,
2691                "'$onelib': linking libraries using a non-POSIX\n"
2692                . "archiver requires 'AM_PROG_AR' in '$configure_ac'")
2693         }
2694     }
2695 }
2696
2697
2698 # handle_ltlibraries ()
2699 # ---------------------
2700 # Handle shared libraries.
2701 sub handle_ltlibraries
2702 {
2703   my @liblist = &am_install_var ('ltlib', 'LTLIBRARIES',
2704                                  'noinst', 'lib', 'pkglib', 'check');
2705   return if ! @liblist;
2706   $must_handle_compiled_objects = 1;
2707
2708   my @prefix = am_primary_prefixes ('LTLIBRARIES', 0, 'lib', 'pkglib',
2709                                     'noinst', 'check');
2710
2711   if (@prefix)
2712     {
2713       my $var = rvar ($prefix[0] . '_LTLIBRARIES');
2714       $var->requires_variables ('Libtool library used', 'LIBTOOL');
2715     }
2716
2717   my %instdirs = ();
2718   my %instsubdirs = ();
2719   my %instconds = ();
2720   my %liblocations = ();        # Location (in Makefile.am) of each library.
2721
2722   foreach my $key (@prefix)
2723     {
2724       # Get the installation directory of each library.
2725       my $dir = $key;
2726       my $strip_subdir = 1;
2727       if ($dir =~ /^nobase_/)
2728         {
2729           $dir =~ s/^nobase_//;
2730           $strip_subdir = 0;
2731         }
2732       my $var = rvar ($key . '_LTLIBRARIES');
2733
2734       # We reject libraries which are installed in several places
2735       # in the same condition, because we can only specify one
2736       # '-rpath' option.
2737       $var->traverse_recursively
2738         (sub
2739          {
2740            my ($var, $val, $cond, $full_cond) = @_;
2741            my $hcond = $full_cond->human;
2742            my $where = $var->rdef ($cond)->location;
2743            my $ldir = '';
2744            $ldir = '/' . dirname ($val)
2745              if (!$strip_subdir);
2746            # A library cannot be installed in different directories
2747            # in overlapping conditions.
2748            if (exists $instconds{$val})
2749              {
2750                my ($msg, $acond) =
2751                  $instconds{$val}->ambiguous_p ($val, $full_cond);
2752
2753                if ($msg)
2754                  {
2755                    error ($where, $msg, partial => 1);
2756                    my $dirtxt = "installed " . ($strip_subdir ? "in" : "below") . " '$dir'";
2757                    $dirtxt = "built for '$dir'"
2758                      if $dir eq 'EXTRA' || $dir eq 'noinst' || $dir eq 'check';
2759                    my $dircond =
2760                      $full_cond->true ? "" : " in condition $hcond";
2761
2762                    error ($where, "'$val' should be $dirtxt$dircond ...",
2763                           partial => 1);
2764
2765                    my $hacond = $acond->human;
2766                    my $adir = $instdirs{$val}{$acond};
2767                    my $adirtxt = "installed in '$adir'";
2768                    $adirtxt = "built for '$adir'"
2769                      if ($adir eq 'EXTRA' || $adir eq 'noinst'
2770                          || $adir eq 'check');
2771                    my $adircond = $acond->true ? "" : " in condition $hacond";
2772
2773                    my $onlyone = ($dir ne $adir) ?
2774                      ("\nLibtool libraries can be built for only one "
2775                       . "destination") : "";
2776
2777                    error ($liblocations{$val}{$acond},
2778                           "... and should also be $adirtxt$adircond.$onlyone");
2779                    return;
2780                  }
2781              }
2782            else
2783              {
2784                $instconds{$val} = new Automake::DisjConditions;
2785              }
2786            $instdirs{$val}{$full_cond} = $dir;
2787            $instsubdirs{$val}{$full_cond} = $ldir;
2788            $liblocations{$val}{$full_cond} = $where;
2789            $instconds{$val} = $instconds{$val}->merge ($full_cond);
2790          },
2791          sub
2792          {
2793            return ();
2794          },
2795          skip_ac_subst => 1);
2796     }
2797
2798   foreach my $pair (@liblist)
2799     {
2800       my ($where, $onelib) = @$pair;
2801
2802       my $seen_libobjs = 0;
2803       my $obj = '.lo';
2804
2805       # Canonicalize names and check for misspellings.
2806       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_LDFLAGS',
2807                                             '_SOURCES', '_OBJECTS',
2808                                             '_DEPENDENCIES');
2809
2810       # Check that the library fits the standard naming convention.
2811       my $libname_rx = '^lib.*\.la';
2812       my $ldvar = var ("${xlib}_LDFLAGS") || var ('AM_LDFLAGS');
2813       my $ldvar2 = var ('LDFLAGS');
2814       if (($ldvar && grep (/-module/, $ldvar->value_as_list_recursive))
2815           || ($ldvar2 && grep (/-module/, $ldvar2->value_as_list_recursive)))
2816         {
2817           # Relax name checking for libtool modules.
2818           $libname_rx = '\.la';
2819         }
2820
2821       my $bn = basename ($onelib);
2822       if ($bn !~ /$libname_rx$/)
2823         {
2824           my $type = 'library';
2825           if ($libname_rx eq '\.la')
2826             {
2827               $bn =~ s/^(lib|)(.*?)(?:\.[^.]*)?$/$1$2.la/;
2828               $type = 'module';
2829             }
2830           else
2831             {
2832               $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.la/;
2833             }
2834           my $suggestion = dirname ($onelib) . "/$bn";
2835           $suggestion =~ s|^\./||g;
2836           msg ('error-gnu/warn', $where,
2837                "'$onelib' is not a standard libtool $type name\n"
2838                . "did you mean '$suggestion'?")
2839         }
2840
2841       ($known_libraries{$onelib} = $bn) =~ s/\.la$//;
2842
2843       $where->push_context ("while processing Libtool library '$onelib'");
2844       $where->set (INTERNAL->get);
2845
2846       # Make sure we look at these.
2847       set_seen ($xlib . '_LDFLAGS');
2848       set_seen ($xlib . '_DEPENDENCIES');
2849       set_seen ('EXTRA_' . $xlib . '_DEPENDENCIES');
2850
2851       # Generate support for conditional object inclusion in
2852       # libraries.
2853       if (var ($xlib . '_LIBADD'))
2854         {
2855           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2856             {
2857               $seen_libobjs = 1;
2858             }
2859         }
2860       else
2861         {
2862           &define_variable ($xlib . "_LIBADD", '', $where);
2863         }
2864
2865       reject_var ("${xlib}_LDADD",
2866                   "use '${xlib}_LIBADD', not '${xlib}_LDADD'");
2867
2868
2869       my $linker = &handle_source_transform ($xlib, $onelib, $obj, $where,
2870                                              NONLIBTOOL => 0, LIBTOOL => 1);
2871
2872       # Determine program to use for link.
2873       my($xlink, $vlink) = &define_per_target_linker_variable ($linker, $xlib);
2874       $vlink = verbose_flag ($vlink || 'GEN');
2875
2876       my $rpathvar = "am_${xlib}_rpath";
2877       my $rpath = "\$($rpathvar)";
2878       foreach my $rcond ($instconds{$onelib}->conds)
2879         {
2880           my $val;
2881           if ($instdirs{$onelib}{$rcond} eq 'EXTRA'
2882               || $instdirs{$onelib}{$rcond} eq 'noinst'
2883               || $instdirs{$onelib}{$rcond} eq 'check')
2884             {
2885               # It's an EXTRA_ library, so we can't specify -rpath,
2886               # because we don't know where the library will end up.
2887               # The user probably knows, but generally speaking automake
2888               # doesn't -- and in fact configure could decide
2889               # dynamically between two different locations.
2890               $val = '';
2891             }
2892           else
2893             {
2894               $val = ('-rpath $(' . $instdirs{$onelib}{$rcond} . 'dir)');
2895               $val .= $instsubdirs{$onelib}{$rcond}
2896                 if defined $instsubdirs{$onelib}{$rcond};
2897             }
2898           if ($rcond->true)
2899             {
2900               # If $rcond is true there is only one condition and
2901               # there is no point defining an helper variable.
2902               $rpath = $val;
2903             }
2904           else
2905             {
2906               define_pretty_variable ($rpathvar, $rcond, INTERNAL, $val);
2907             }
2908         }
2909
2910       # If the resulting library lies into a subdirectory,
2911       # make sure this directory will exist.
2912       my $dirstamp = require_build_directory_maybe ($onelib);
2913
2914       # Remember to cleanup .libs/ in this directory.
2915       my $dirname = dirname $onelib;
2916       $libtool_clean_directories{$dirname} = 1;
2917
2918       $output_rules .= &file_contents ('ltlibrary',
2919                                        $where,
2920                                        LTLIBRARY  => $onelib,
2921                                        XLTLIBRARY => $xlib,
2922                                        RPATH      => $rpath,
2923                                        XLINK      => $xlink,
2924                                        VERBOSE    => $vlink,
2925                                        DIRSTAMP   => $dirstamp);
2926       if ($seen_libobjs)
2927         {
2928           if (var ($xlib . '_LIBADD'))
2929             {
2930               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2931             }
2932         }
2933
2934       if (! $seen_ar)
2935         {
2936           msg ('extra-portability', $where,
2937                "'$onelib': linking libtool libraries using a non-POSIX\n"
2938                . "archiver requires 'AM_PROG_AR' in '$configure_ac'")
2939         }
2940     }
2941 }
2942
2943 # See if any _SOURCES variable were misspelled.
2944 sub check_typos ()
2945 {
2946   # It is ok if the user sets this particular variable.
2947   set_seen 'AM_LDFLAGS';
2948
2949   foreach my $primary ('SOURCES', 'LIBADD', 'LDADD', 'LDFLAGS', 'DEPENDENCIES')
2950     {
2951       foreach my $var (variables $primary)
2952         {
2953           my $varname = $var->name;
2954           # A configure variable is always legitimate.
2955           next if exists $configure_vars{$varname};
2956
2957           for my $cond ($var->conditions->conds)
2958             {
2959               $varname =~ /^(?:EXTRA_)?(?:nobase_)?(?:dist_|nodist_)?(.*)_[[:alnum:]]+$/;
2960               msg_var ('syntax', $var, "variable '$varname' is defined but no"
2961                        . " program or\nlibrary has '$1' as canonical name"
2962                        . " (possible typo)")
2963                 unless $var->rdef ($cond)->seen;
2964             }
2965         }
2966     }
2967 }
2968
2969
2970 # Handle scripts.
2971 sub handle_scripts
2972 {
2973     # NOTE we no longer automatically clean SCRIPTS, because it is
2974     # useful to sometimes distribute scripts verbatim.  This happens
2975     # e.g. in Automake itself.
2976     &am_install_var ('-candist', 'scripts', 'SCRIPTS',
2977                      'bin', 'sbin', 'libexec', 'pkglibexec', 'pkgdata',
2978                      'noinst', 'check');
2979 }
2980
2981
2982
2983
2984 ## ------------------------ ##
2985 ## Handling Texinfo files.  ##
2986 ## ------------------------ ##
2987
2988 # ($OUTFILE, $VFILE, @CLEAN_FILES)
2989 # &scan_texinfo_file ($FILENAME)
2990 # ------------------------------
2991 # $OUTFILE     - name of the info file produced by $FILENAME.
2992 # $VFILE       - name of the version.texi file used (undef if none).
2993 # @CLEAN_FILES - list of byproducts (indexes etc.)
2994 sub scan_texinfo_file ($)
2995 {
2996   my ($filename) = @_;
2997
2998   # Some of the following extensions are always created, no matter
2999   # whether indexes are used or not.  Other (like cps, fns, ... pgs)
3000   # are only created when they are used.  We used to scan $FILENAME
3001   # for their use, but that is not enough: they could be used in
3002   # included files.  We can't scan included files because we don't
3003   # know the include path.  Therefore we always erase these files, no
3004   # matter whether they are used or not.
3005   #
3006   # (tmp is only created if an @macro is used and a certain e-TeX
3007   # feature is not available.)
3008   my %clean_suffixes =
3009     map { $_ => 1 } (qw(aux log toc tmp
3010                         cp cps
3011                         fn fns
3012                         ky kys
3013                         vr vrs
3014                         tp tps
3015                         pg pgs)); # grep 'new.*index' texinfo.tex
3016
3017   my $texi = new Automake::XFile "< $filename";
3018   verb "reading $filename";
3019
3020   my ($outfile, $vfile);
3021   while ($_ = $texi->getline)
3022     {
3023       if (/^\@setfilename +(\S+)/)
3024         {
3025           # Honor only the first @setfilename.  (It's possible to have
3026           # more occurrences later if the manual shows examples of how
3027           # to use @setfilename...)
3028           next if $outfile;
3029
3030           $outfile = $1;
3031           if ($outfile =~ /\.([^.]+)$/ && $1 ne 'info')
3032             {
3033               error ("$filename:$.",
3034                      "output '$outfile' has unrecognized extension");
3035               return;
3036             }
3037         }
3038       # A "version.texi" file is actually any file whose name matches
3039       # "vers*.texi".
3040       elsif (/^\@include\s+(vers[^.]*\.texi)\s*$/)
3041         {
3042           $vfile = $1;
3043         }
3044
3045       # Try to find new or unused indexes.
3046
3047       # Creating a new category of index.
3048       elsif (/^\@def(code)?index (\w+)/)
3049         {
3050           $clean_suffixes{$2} = 1;
3051           $clean_suffixes{"$2s"} = 1;
3052         }
3053
3054       # Merging an index into an another.
3055       elsif (/^\@syn(code)?index (\w+) (\w+)/)
3056         {
3057           delete $clean_suffixes{"$2s"};
3058           $clean_suffixes{"$3s"} = 1;
3059         }
3060
3061     }
3062
3063   if (! $outfile)
3064     {
3065       err_am "'$filename' missing \@setfilename";
3066       return;
3067     }
3068
3069   my $infobase = basename ($filename);
3070   $infobase =~ s/\.te?xi(nfo)?$//;
3071   return ($outfile, $vfile,
3072           map { "$infobase.$_" } (sort keys %clean_suffixes));
3073 }
3074
3075
3076 # ($DIRSTAMP, @CLEAN_FILES)
3077 # output_texinfo_build_rules ($SOURCE, $DEST, $INSRC, @DEPENDENCIES)
3078 # ------------------------------------------------------------------
3079 # SOURCE - the source Texinfo file
3080 # DEST - the destination Info file
3081 # INSRC - whether DEST should be built in the source tree
3082 # DEPENDENCIES - known dependencies
3083 sub output_texinfo_build_rules ($$$@)
3084 {
3085   my ($source, $dest, $insrc, @deps) = @_;
3086
3087   # Split 'a.texi' into 'a' and '.texi'.
3088   my ($spfx, $ssfx) = ($source =~ /^(.*?)(\.[^.]*)?$/);
3089   my ($dpfx, $dsfx) = ($dest =~ /^(.*?)(\.[^.]*)?$/);
3090
3091   $ssfx ||= "";
3092   $dsfx ||= "";
3093
3094   # We can output two kinds of rules: the "generic" rules use Make
3095   # suffix rules and are appropriate when $source and $dest do not lie
3096   # in a sub-directory; the "specific" rules are needed in the other
3097   # case.
3098   #
3099   # The former are output only once (this is not really apparent here,
3100   # but just remember that some logic deeper in Automake will not
3101   # output the same rule twice); while the later need to be output for
3102   # each Texinfo source.
3103   my $generic;
3104   my $makeinfoflags;
3105   my $sdir = dirname $source;
3106   if ($sdir eq '.' && dirname ($dest) eq '.')
3107     {
3108       $generic = 1;
3109       $makeinfoflags = '-I $(srcdir)';
3110     }
3111   else
3112     {
3113       $generic = 0;
3114       $makeinfoflags = "-I $sdir -I \$(srcdir)/$sdir";
3115     }
3116
3117   # A directory can contain two kinds of info files: some built in the
3118   # source tree, and some built in the build tree.  The rules are
3119   # different in each case.  However we cannot output two different
3120   # set of generic rules.  Because in-source builds are more usual, we
3121   # use generic rules in this case and fall back to "specific" rules
3122   # for build-dir builds.  (It should not be a problem to invert this
3123   # if needed.)
3124   $generic = 0 unless $insrc;
3125
3126   # We cannot use a suffix rule to build info files with an empty
3127   # extension.  Otherwise we would output a single suffix inference
3128   # rule, with separate dependencies, as in
3129   #
3130   #    .texi:
3131   #             $(MAKEINFO) ...
3132   #    foo.info: foo.texi
3133   #
3134   # which confuse Solaris make.  (See the Autoconf manual for
3135   # details.)  Therefore we use a specific rule in this case.  This
3136   # applies to info files only (dvi and pdf files always have an
3137   # extension).
3138   my $generic_info = ($generic && $dsfx) ? 1 : 0;
3139
3140   # If the resulting file lie into a subdirectory,
3141   # make sure this directory will exist.
3142   my $dirstamp = require_build_directory_maybe ($dest);
3143
3144   my $dipfx = ($insrc ? '$(srcdir)/' : '') . $dpfx;
3145
3146   $output_rules .= file_contents ('texibuild',
3147                                   new Automake::Location,
3148                                   AM_V_MAKEINFO    => verbose_flag('MAKEINFO'),
3149                                   AM_V_TEXI2DVI    => verbose_flag('TEXI2DVI'),
3150                                   AM_V_TEXI2PDF    => verbose_flag('TEXI2PDF'),
3151                                   DEPS             => "@deps",
3152                                   DEST_PREFIX      => $dpfx,
3153                                   DEST_INFO_PREFIX => $dipfx,
3154                                   DEST_SUFFIX      => $dsfx,
3155                                   DIRSTAMP         => $dirstamp,
3156                                   GENERIC          => $generic,
3157                                   GENERIC_INFO     => $generic_info,
3158                                   INSRC            => $insrc,
3159                                   MAKEINFOFLAGS    => $makeinfoflags,
3160                                   SILENT           => silent_flag(),
3161                                   SOURCE           => ($generic
3162                                                        ? '$<' : $source),
3163                                   SOURCE_INFO      => ($generic_info
3164                                                        ? '$<' : $source),
3165                                   SOURCE_REAL      => $source,
3166                                   SOURCE_SUFFIX    => $ssfx,
3167                                   TEXIQUIET        => verbose_flag('texinfo'),
3168                                   TEXIDEVNULL      => verbose_flag('texidevnull'),
3169                                   );
3170   return ($dirstamp, "$dpfx.dvi", "$dpfx.pdf", "$dpfx.ps", "$dpfx.html");
3171 }
3172
3173
3174 # ($MOSTLYCLEAN, $TEXICLEAN, $MAINTCLEAN)
3175 # handle_texinfo_helper ($info_texinfos)
3176 # --------------------------------------
3177 # Handle all Texinfo source; helper for handle_texinfo.
3178 sub handle_texinfo_helper ($)
3179 {
3180   my ($info_texinfos) = @_;
3181   my (@infobase, @info_deps_list, @texi_deps);
3182   my %versions;
3183   my $done = 0;
3184   my (@mostly_cleans, @texi_cleans, @maint_cleans) = ('', '', '');
3185
3186   # Build a regex matching user-cleaned files.
3187   my $d = var 'DISTCLEANFILES';
3188   my $c = var 'CLEANFILES';
3189   my @f = ();
3190   push @f, $d->value_as_list_recursive (inner_expand => 1) if $d;
3191   push @f, $c->value_as_list_recursive (inner_expand => 1) if $c;
3192   @f = map { s|[^A-Za-z_0-9*\[\]\-]|\\$&|g; s|\*|[^/]*|g; $_; } @f;
3193   my $user_cleaned_files = '^(?:' . join ('|', @f) . ')$';
3194
3195   foreach my $texi
3196       ($info_texinfos->value_as_list_recursive (inner_expand => 1))
3197     {
3198       my $infobase = $texi;
3199       $infobase =~ s/\.(txi|texinfo|texi)$//;
3200
3201       if ($infobase eq $texi)
3202         {
3203           # FIXME: report line number.
3204           err_am "texinfo file '$texi' has unrecognized extension";
3205           next;
3206         }
3207
3208       push @infobase, $infobase;
3209
3210       # If 'version.texi' is referenced by input file, then include
3211       # automatic versioning capability.
3212       my ($out_file, $vtexi, @clean_files) =
3213         scan_texinfo_file ("$relative_dir/$texi")
3214         or next;
3215       push (@mostly_cleans, @clean_files);
3216
3217       # If the Texinfo source is in a subdirectory, create the
3218       # resulting info in this subdirectory.  If it is in the current
3219       # directory, try hard to not prefix "./" because it breaks the
3220       # generic rules.
3221       my $outdir = dirname ($texi) . '/';
3222       $outdir = "" if $outdir eq './';
3223       $out_file =  $outdir . $out_file;
3224
3225       # Until Automake 1.6.3, .info files were built in the
3226       # source tree.  This was an obstacle to the support of
3227       # non-distributed .info files, and non-distributed .texi
3228       # files.
3229       #
3230       # * Non-distributed .texi files is important in some packages
3231       #   where .texi files are built at make time, probably using
3232       #   other binaries built in the package itself, maybe using
3233       #   tools or information found on the build host.  Because
3234       #   these files are not distributed they are always rebuilt
3235       #   at make time; they should therefore not lie in the source
3236       #   directory.  One plan was to support this using
3237       #   nodist_info_TEXINFOS or something similar.  (Doing this
3238       #   requires some sanity checks.  For instance Automake should
3239       #   not allow:
3240       #      dist_info_TEXINFOS = foo.texi
3241       #      nodist_foo_TEXINFOS = included.texi
3242       #   because a distributed file should never depend on a
3243       #   non-distributed file.)
3244       #
3245       # * If .texi files are not distributed, then .info files should
3246       #   not be distributed either.  There are also cases where one
3247       #   wants to distribute .texi files, but does not want to
3248       #   distribute the .info files.  For instance the Texinfo package
3249       #   distributes the tool used to build these files; it would
3250       #   be a waste of space to distribute them.  It's not clear
3251       #   which syntax we should use to indicate that .info files should
3252       #   not be distributed.  Akim Demaille suggested that eventually
3253       #   we switch to a new syntax:
3254       #   |  Maybe we should take some inspiration from what's already
3255       #   |  done in the rest of Automake.  Maybe there is too much
3256       #   |  syntactic sugar here, and you want
3257       #   |     nodist_INFO = bar.info
3258       #   |     dist_bar_info_SOURCES = bar.texi
3259       #   |     bar_texi_DEPENDENCIES = foo.texi
3260       #   |  with a bit of magic to have bar.info represent the whole
3261       #   |  bar*info set.  That's a lot more verbose that the current
3262       #   |  situation, but it is # not new, hence the user has less
3263       #   |  to learn.
3264       #   |
3265       #   |  But there is still too much room for meaningless specs:
3266       #   |     nodist_INFO = bar.info
3267       #   |     dist_bar_info_SOURCES = bar.texi
3268       #   |     dist_PS = bar.ps something-written-by-hand.ps
3269       #   |     nodist_bar_ps_SOURCES = bar.texi
3270       #   |     bar_texi_DEPENDENCIES = foo.texi
3271       #   |  here bar.texi is dist_ in line 2, and nodist_ in 4.
3272       #
3273       # Back to the point, it should be clear that in order to support
3274       # non-distributed .info files, we need to build them in the
3275       # build tree, not in the source tree (non-distributed .texi
3276       # files are less of a problem, because we do not output build
3277       # rules for them).  In Automake 1.7 .info build rules have been
3278       # largely cleaned up so that .info files get always build in the
3279       # build tree, even when distributed.  The idea was that
3280       #   (1) if during a VPATH build the .info file was found to be
3281       #       absent or out-of-date (in the source tree or in the
3282       #       build tree), Make would rebuild it in the build tree.
3283       #       If an up-to-date source-tree of the .info file existed,
3284       #       make would not rebuild it in the build tree.
3285       #   (2) having two copies of .info files, one in the source tree
3286       #       and one (newer) in the build tree is not a problem
3287       #       because 'make dist' always pick files in the build tree
3288       #       first.
3289       # However it turned out the be a bad idea for several reasons:
3290       #   * Tru64, OpenBSD, and FreeBSD (not NetBSD) Make do not behave
3291       #     like GNU Make on point (1) above.  These implementations
3292       #     of Make would always rebuild .info files in the build
3293       #     tree, even if such files were up to date in the source
3294       #     tree.  Consequently, it was impossible to perform a VPATH
3295       #     build of a package containing Texinfo files using these
3296       #     Make implementations.
3297       #     (Refer to the Autoconf Manual, section "Limitation of
3298       #     Make", paragraph "VPATH", item "target lookup", for
3299       #     an account of the differences between these
3300       #     implementations.)
3301       #   * The GNU Coding Standards require these files to be built
3302       #     in the source-tree (when they are distributed, that is).
3303       #   * Keeping a fresher copy of distributed files in the
3304       #     build tree can be annoying during development because
3305       #     - if the files is kept under CVS, you really want it
3306       #       to be updated in the source tree
3307       #     - it is confusing that 'make distclean' does not erase
3308       #       all files in the build tree.
3309       #
3310       # Consequently, starting with Automake 1.8, .info files are
3311       # built in the source tree again.  Because we still plan to
3312       # support non-distributed .info files at some point, we
3313       # have a single variable ($INSRC) that controls whether
3314       # the current .info file must be built in the source tree
3315       # or in the build tree.  Actually this variable is switched
3316       # off for .info files that appear to be cleaned; this is
3317       # for backward compatibility with package such as Texinfo,
3318       # which do things like
3319       #   info_TEXINFOS = texinfo.txi info-stnd.texi info.texi
3320       #   DISTCLEANFILES = texinfo texinfo-* info*.info*
3321       #   # Do not create info files for distribution.
3322       #   dist-info:
3323       # in order not to distribute .info files.
3324       my $insrc = ($out_file =~ $user_cleaned_files) ? 0 : 1;
3325
3326       my $soutdir = '$(srcdir)/' . $outdir;
3327       $outdir = $soutdir if $insrc;
3328
3329       # If user specified file_TEXINFOS, then use that as explicit
3330       # dependency list.
3331       @texi_deps = ();
3332       push (@texi_deps, "$soutdir$vtexi") if $vtexi;
3333
3334       my $canonical = canonicalize ($infobase);
3335       if (var ($canonical . "_TEXINFOS"))
3336         {
3337           push (@texi_deps, '$(' . $canonical . '_TEXINFOS)');
3338           push_dist_common ('$(' . $canonical . '_TEXINFOS)');
3339         }
3340
3341       my ($dirstamp, @cfiles) =
3342         output_texinfo_build_rules ($texi, $out_file, $insrc, @texi_deps);
3343       push (@texi_cleans, @cfiles);
3344
3345       push (@info_deps_list, $out_file);
3346
3347       # If a vers*.texi file is needed, emit the rule.
3348       if ($vtexi)
3349         {
3350           err_am ("'$vtexi', included in '$texi', "
3351                   . "also included in '$versions{$vtexi}'")
3352             if defined $versions{$vtexi};
3353           $versions{$vtexi} = $texi;
3354
3355           # We number the stamp-vti files.  This is doable since the
3356           # actual names don't matter much.  We only number starting
3357           # with the second one, so that the common case looks nice.
3358           my $vti = ($done ? $done : 'vti');
3359           ++$done;
3360
3361           # This is ugly, but it is our historical practice.
3362           if ($config_aux_dir_set_in_configure_ac)
3363             {
3364               require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3365                                             'mdate-sh');
3366             }
3367           else
3368             {
3369               require_file_with_macro (TRUE, 'info_TEXINFOS',
3370                                        FOREIGN, 'mdate-sh');
3371             }
3372
3373           my $conf_dir;
3374           if ($config_aux_dir_set_in_configure_ac)
3375             {
3376               $conf_dir = "$am_config_aux_dir/";
3377             }
3378           else
3379             {
3380               $conf_dir = '$(srcdir)/';
3381             }
3382           $output_rules .= file_contents ('texi-vers',
3383                                           new Automake::Location,
3384                                           TEXI     => $texi,
3385                                           VTI      => $vti,
3386                                           STAMPVTI => "${soutdir}stamp-$vti",
3387                                           VTEXI    => "$soutdir$vtexi",
3388                                           MDDIR    => $conf_dir,
3389                                           DIRSTAMP => $dirstamp);
3390         }
3391     }
3392
3393   # Handle location of texinfo.tex.
3394   my $need_texi_file = 0;
3395   my $texinfodir;
3396   if (var ('TEXINFO_TEX'))
3397     {
3398       # The user defined TEXINFO_TEX so assume he knows what he is
3399       # doing.
3400       $texinfodir = ('$(srcdir)/'
3401                      . dirname (variable_value ('TEXINFO_TEX')));
3402     }
3403   elsif (option 'cygnus')
3404     {
3405       $texinfodir = '$(top_srcdir)/../texinfo';
3406       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3407     }
3408   elsif ($config_aux_dir_set_in_configure_ac)
3409     {
3410       $texinfodir = $am_config_aux_dir;
3411       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3412       $need_texi_file = 2; # so that we require_conf_file later
3413     }
3414   else
3415     {
3416       $texinfodir = '$(srcdir)';
3417       $need_texi_file = 1;
3418     }
3419   define_variable ('am__TEXINFO_TEX_DIR', $texinfodir, INTERNAL);
3420
3421   push (@dist_targets, 'dist-info');
3422
3423   if (! option 'no-installinfo')
3424     {
3425       # Make sure documentation is made and installed first.  Use
3426       # $(INFO_DEPS), not 'info', because otherwise recursive makes
3427       # get run twice during "make all".
3428       unshift (@all, '$(INFO_DEPS)');
3429     }
3430
3431   define_files_variable ("DVIS", @infobase, 'dvi', INTERNAL);
3432   define_files_variable ("PDFS", @infobase, 'pdf', INTERNAL);
3433   define_files_variable ("PSS", @infobase, 'ps', INTERNAL);
3434   define_files_variable ("HTMLS", @infobase, 'html', INTERNAL);
3435
3436   # This next isn't strictly needed now -- the places that look here
3437   # could easily be changed to look in info_TEXINFOS.  But this is
3438   # probably better, in case noinst_TEXINFOS is ever supported.
3439   define_variable ("TEXINFOS", variable_value ('info_TEXINFOS'), INTERNAL);
3440
3441   # Do some error checking.  Note that this file is not required
3442   # when in Cygnus mode; instead we defined TEXINFO_TEX explicitly
3443   # up above.
3444   if ($need_texi_file && ! option 'no-texinfo.tex')
3445     {
3446       if ($need_texi_file > 1)
3447         {
3448           require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3449                                         'texinfo.tex');
3450         }
3451       else
3452         {
3453           require_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3454                                    'texinfo.tex');
3455         }
3456     }
3457
3458   return (makefile_wrap ("", "\t  ", @mostly_cleans),
3459           makefile_wrap ("", "\t  ", @texi_cleans),
3460           makefile_wrap ("", "\t  ", @maint_cleans));
3461 }
3462
3463
3464 # handle_texinfo ()
3465 # -----------------
3466 # Handle all Texinfo source.
3467 sub handle_texinfo ()
3468 {
3469   reject_var 'TEXINFOS', "'TEXINFOS' is an anachronism; use 'info_TEXINFOS'";
3470   # FIXME: I think this is an obsolete future feature name.
3471   reject_var 'html_TEXINFOS', "HTML generation not yet supported";
3472
3473   my $info_texinfos = var ('info_TEXINFOS');
3474   my ($mostlyclean, $clean, $maintclean) = ('', '', '');
3475   if ($info_texinfos)
3476     {
3477       define_verbose_texinfo;
3478       ($mostlyclean, $clean, $maintclean) = handle_texinfo_helper ($info_texinfos);
3479       chomp $mostlyclean;
3480       chomp $clean;
3481       chomp $maintclean;
3482     }
3483
3484   $output_rules .=  file_contents ('texinfos',
3485                                    new Automake::Location,
3486                                    AM_V_DVIPS    => verbose_flag('DVIPS'),
3487                                    MOSTLYCLEAN   => $mostlyclean,
3488                                    TEXICLEAN     => $clean,
3489                                    MAINTCLEAN    => $maintclean,
3490                                    'LOCAL-TEXIS' => !!$info_texinfos,
3491                                    TEXIQUIET     => verbose_flag('texinfo'));
3492 }
3493
3494
3495 # Handle any man pages.
3496 sub handle_man_pages
3497 {
3498   reject_var 'MANS', "'MANS' is an anachronism; use 'man_MANS'";
3499
3500   # Find all the sections in use.  We do this by first looking for
3501   # "standard" sections, and then looking for any additional
3502   # sections used in man_MANS.
3503   my (%sections, %notrans_sections, %trans_sections,
3504       %notrans_vars, %trans_vars, %notrans_sect_vars, %trans_sect_vars);
3505   # We handle nodist_ for uniformity.  man pages aren't distributed
3506   # by default so it isn't actually very important.
3507   foreach my $npfx ('', 'notrans_')
3508     {
3509       foreach my $pfx ('', 'dist_', 'nodist_')
3510         {
3511           # Add more sections as needed.
3512           foreach my $section ('0'..'9', 'n', 'l')
3513             {
3514               my $varname = $npfx . $pfx . 'man' . $section . '_MANS';
3515               if (var ($varname))
3516                 {
3517                   $sections{$section} = 1;
3518                   $varname = '$(' . $varname . ')';
3519                   if ($npfx eq 'notrans_')
3520                     {
3521                       $notrans_sections{$section} = 1;
3522                       $notrans_sect_vars{$varname} = 1;
3523                     }
3524                   else
3525                     {
3526                       $trans_sections{$section} = 1;
3527                       $trans_sect_vars{$varname} = 1;
3528                     }
3529
3530                   &push_dist_common ($varname)
3531                     if $pfx eq 'dist_';
3532                 }
3533             }
3534
3535           my $varname = $npfx . $pfx . 'man_MANS';
3536           my $var = var ($varname);
3537           if ($var)
3538             {
3539               foreach ($var->value_as_list_recursive)
3540                 {
3541                   # A page like 'foo.1c' goes into man1dir.
3542                   if (/\.([0-9a-z])([a-z]*)$/)
3543                     {
3544                       $sections{$1} = 1;
3545                       if ($npfx eq 'notrans_')
3546                         {
3547                           $notrans_sections{$1} = 1;
3548                         }
3549                       else
3550                         {
3551                           $trans_sections{$1} = 1;
3552                         }
3553                     }
3554                 }
3555
3556               $varname = '$(' . $varname . ')';
3557               if ($npfx eq 'notrans_')
3558                 {
3559                   $notrans_vars{$varname} = 1;
3560                 }
3561               else
3562                 {
3563                   $trans_vars{$varname} = 1;
3564                 }
3565               &push_dist_common ($varname)
3566                 if $pfx eq 'dist_';
3567             }
3568         }
3569     }
3570
3571   return unless %sections;
3572
3573   my @unsorted_deps;
3574
3575   # Build section independent variables.
3576   my $have_notrans = %notrans_vars;
3577   my @notrans_list = sort keys %notrans_vars;
3578   my $have_trans = %trans_vars;
3579   my @trans_list = sort keys %trans_vars;
3580
3581   # Now for each section, generate an install and uninstall rule.
3582   # Sort sections so output is deterministic.
3583   foreach my $section (sort keys %sections)
3584     {
3585       # Build section dependent variables.
3586       my $notrans_mans = $have_notrans || exists $notrans_sections{$section};
3587       my $trans_mans = $have_trans || exists $trans_sections{$section};
3588       my (%notrans_this_sect, %trans_this_sect);
3589       my $expr = 'man' . $section . '_MANS';
3590       foreach my $varname (keys %notrans_sect_vars)
3591         {
3592           if ($varname =~ /$expr/)
3593             {
3594               $notrans_this_sect{$varname} = 1;
3595             }
3596         }
3597       foreach my $varname (keys %trans_sect_vars)
3598         {
3599           if ($varname =~ /$expr/)
3600             {
3601               $trans_this_sect{$varname} = 1;
3602             }
3603         }
3604       my @notrans_sect_list = sort keys %notrans_this_sect;
3605       my @trans_sect_list = sort keys %trans_this_sect;
3606       @unsorted_deps = (keys %notrans_vars, keys %trans_vars,
3607                         keys %notrans_this_sect, keys %trans_this_sect);
3608       my @deps = sort @unsorted_deps;
3609       $output_rules .= &file_contents ('mans',
3610                                        new Automake::Location,
3611                                        SECTION           => $section,
3612                                        DEPS              => "@deps",
3613                                        NOTRANS_MANS      => $notrans_mans,
3614                                        NOTRANS_SECT_LIST => "@notrans_sect_list",
3615                                        HAVE_NOTRANS      => $have_notrans,
3616                                        NOTRANS_LIST      => "@notrans_list",
3617                                        TRANS_MANS        => $trans_mans,
3618                                        TRANS_SECT_LIST   => "@trans_sect_list",
3619                                        HAVE_TRANS        => $have_trans,
3620                                        TRANS_LIST        => "@trans_list");
3621     }
3622
3623   @unsorted_deps  = (keys %notrans_vars, keys %trans_vars,
3624                      keys %notrans_sect_vars, keys %trans_sect_vars);
3625   my @mans = sort @unsorted_deps;
3626   $output_vars .= file_contents ('mans-vars',
3627                                  new Automake::Location,
3628                                  MANS => "@mans");
3629
3630   push (@all, '$(MANS)')
3631     unless option 'no-installman';
3632 }
3633
3634 # Handle DATA variables.
3635 sub handle_data
3636 {
3637     &am_install_var ('-noextra', '-candist', 'data', 'DATA',
3638                      'data', 'dataroot', 'doc', 'dvi', 'html', 'pdf',
3639                      'ps', 'sysconf', 'sharedstate', 'localstate',
3640                      'pkgdata', 'lisp', 'noinst', 'check');
3641 }
3642
3643 # Handle TAGS.
3644 sub handle_tags
3645 {
3646     my @tag_deps = ();
3647     my @ctag_deps = ();
3648     my @cscope_deps = ();
3649     if (var ('SUBDIRS'))
3650     {
3651         $output_rules .= ("tags-recursive:\n"
3652                           . "\tlist='\$(SUBDIRS)'; for subdir in \$\$list; do \\\n"
3653                           # Never fail here if a subdir fails; it
3654                           # isn't important.
3655                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3656                           . " && \$(MAKE) \$(AM_MAKEFLAGS) tags); \\\n"
3657                           . "\tdone\n");
3658         push (@tag_deps, 'tags-recursive');
3659         &depend ('.PHONY', 'tags-recursive');
3660         &depend ('.MAKE', 'tags-recursive');
3661
3662         $output_rules .= ("ctags-recursive:\n"
3663                           . "\tlist='\$(SUBDIRS)'; for subdir in \$\$list; do \\\n"
3664                           # Never fail here if a subdir fails; it
3665                           # isn't important.
3666                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3667                           . " && \$(MAKE) \$(AM_MAKEFLAGS) ctags); \\\n"
3668                           . "\tdone\n");
3669         push (@ctag_deps, 'ctags-recursive');
3670         &depend ('.PHONY', 'ctags-recursive');
3671         &depend ('.MAKE', 'ctags-recursive');
3672
3673         $output_rules .= ("cscopelist-recursive:\n"
3674                           . "\tlist='\$(SUBDIRS)'; for subdir in \$\$list; do \\\n"
3675                           # Never fail here if a subdir fails; it
3676                           # isn't important.
3677                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3678                           . " && \$(MAKE) \$(AM_MAKEFLAGS) cscopelist); \\\n"
3679                           . "\tdone\n");
3680         push (@cscope_deps, 'cscopelist-recursive');
3681         &depend ('.PHONY', 'cscopelist-recursive');
3682         &depend ('.MAKE', 'cscopelist-recursive');
3683     }
3684
3685     if (&saw_sources_p (1)
3686         || var ('ETAGS_ARGS')
3687         || @tag_deps)
3688     {
3689         my @config;
3690         foreach my $spec (@config_headers)
3691         {
3692             my ($out, @ins) = split_config_file_spec ($spec);
3693             foreach my $in (@ins)
3694               {
3695                 # If the config header source is in this directory,
3696                 # require it.
3697                 push @config, basename ($in)
3698                   if $relative_dir eq dirname ($in);
3699               }
3700         }
3701         $output_rules .= &file_contents ('tags',
3702                                          new Automake::Location,
3703                                          CONFIG    => "@config",
3704                                          TAGSDIRS  => "@tag_deps",
3705                                          CTAGSDIRS => "@ctag_deps",
3706                                          CSCOPEDIRS => "@cscope_deps");
3707
3708         set_seen 'TAGS_DEPENDENCIES';
3709     }
3710     elsif (reject_var ('TAGS_DEPENDENCIES',
3711                        "it doesn't make sense to define 'TAGS_DEPENDENCIES'"
3712                        . " without\nsources or 'ETAGS_ARGS'"))
3713     {
3714     }
3715     else
3716     {
3717         # Every Makefile must define some sort of TAGS rule.
3718         # Otherwise, it would be possible for a top-level "make TAGS"
3719         # to fail because some subdirectory failed.
3720         $output_rules .= "tags: TAGS\nTAGS:\n\n";
3721         # Ditto ctags and cscope.
3722         $output_rules .= "ctags: CTAGS\nCTAGS:\n\n";
3723         $output_rules .= "cscope cscopelist:\n\n";
3724     }
3725 }
3726
3727
3728 # user_phony_rule ($NAME)
3729 # -----------------------
3730 # Return false if rule $NAME does not exist.  Otherwise,
3731 # declare it as phony, complete its definition (in case it is
3732 # conditional), and return its Automake::Rule instance.
3733 sub user_phony_rule ($)
3734 {
3735   my ($name) = @_;
3736   my $rule = rule $name;
3737   if ($rule)
3738     {
3739       depend ('.PHONY', $name);
3740       # Define $NAME in all condition where it is not already defined,
3741       # so that it is always OK to depend on $NAME.
3742       for my $c ($rule->not_always_defined_in_cond (TRUE)->conds)
3743         {
3744           Automake::Rule::define ($name, 'internal', RULE_AUTOMAKE,
3745                                   $c, INTERNAL);
3746           $output_rules .= $c->subst_string . "$name:\n";
3747         }
3748     }
3749   return $rule;
3750 }
3751
3752
3753 # $BOOLEAN
3754 # &for_dist_common ($A, $B)
3755 # -------------------------
3756 # Subroutine for &handle_dist: sort files to dist.
3757 #
3758 # We put README first because it then becomes easier to make a
3759 # Usenet-compliant shar file (in these, README must be first).
3760 #
3761 # FIXME: do more ordering of files here.
3762 sub for_dist_common
3763 {
3764     return 0
3765         if $a eq $b;
3766     return -1
3767         if $a eq 'README';
3768     return 1
3769         if $b eq 'README';
3770     return $a cmp $b;
3771 }
3772
3773 # handle_dist
3774 # -----------
3775 # Handle 'dist' target.
3776 sub handle_dist ()
3777 {
3778   # Substitutions for distdir.am
3779   my %transform;
3780
3781   # Define DIST_SUBDIRS.  This must always be done, regardless of the
3782   # no-dist setting: target like 'distclean' or 'maintainer-clean' use it.
3783   my $subdirs = var ('SUBDIRS');
3784   if ($subdirs)
3785     {
3786       # If SUBDIRS is conditionally defined, then set DIST_SUBDIRS
3787       # to all possible directories, and use it.  If DIST_SUBDIRS is
3788       # defined, just use it.
3789
3790       # Note that we check DIST_SUBDIRS first on purpose, so that
3791       # we don't call has_conditional_contents for now reason.
3792       # (In the past one project used so many conditional subdirectories
3793       # that calling has_conditional_contents on SUBDIRS caused
3794       # automake to grow to 150Mb -- this should not happen with
3795       # the current implementation of has_conditional_contents,
3796       # but it's more efficient to avoid the call anyway.)
3797       if (var ('DIST_SUBDIRS'))
3798         {
3799         }
3800       elsif ($subdirs->has_conditional_contents)
3801         {
3802           define_pretty_variable
3803             ('DIST_SUBDIRS', TRUE, INTERNAL,
3804              uniq ($subdirs->value_as_list_recursive));
3805         }
3806       else
3807         {
3808           # We always define this because that is what 'distclean'
3809           # wants.
3810           define_pretty_variable ('DIST_SUBDIRS', TRUE, INTERNAL,
3811                                   '$(SUBDIRS)');
3812         }
3813     }
3814
3815   # The remaining definitions are only required when a dist target is used.
3816   return if option 'no-dist';
3817
3818   # At least one of the archive formats must be enabled.
3819   if ($relative_dir eq '.')
3820     {
3821       my $archive_defined = option 'no-dist-gzip' ? 0 : 1;
3822       $archive_defined ||=
3823         grep { option "dist-$_" } qw(shar zip tarZ bzip2 lzip lzma xz);
3824       error (option 'no-dist-gzip',
3825              "no-dist-gzip specified but no dist-* specified,\n"
3826              . "at least one archive format must be enabled")
3827         unless $archive_defined;
3828     }
3829
3830   # Look for common files that should be included in distribution.
3831   # If the aux dir is set, and it does not have a Makefile.am, then
3832   # we check for these files there as well.
3833   my $check_aux = 0;
3834   if ($relative_dir eq '.'
3835       && $config_aux_dir_set_in_configure_ac)
3836     {
3837       if (! &is_make_dir ($config_aux_dir))
3838         {
3839           $check_aux = 1;
3840         }
3841     }
3842   foreach my $cfile (@common_files)
3843     {
3844       if (dir_has_case_matching_file ($relative_dir, $cfile)
3845           # The file might be absent, but if it can be built it's ok.
3846           || rule $cfile)
3847         {
3848           &push_dist_common ($cfile);
3849         }
3850
3851       # Don't use 'elsif' here because a file might meaningfully
3852       # appear in both directories.
3853       if ($check_aux && dir_has_case_matching_file ($config_aux_dir, $cfile))
3854         {
3855           &push_dist_common ("$config_aux_dir/$cfile")
3856         }
3857     }
3858
3859   # We might copy elements from $configure_dist_common to
3860   # %dist_common if we think we need to.  If the file appears in our
3861   # directory, we would have discovered it already, so we don't
3862   # check that.  But if the file is in a subdir without a Makefile,
3863   # we want to distribute it here if we are doing '.'.  Ugly!
3864   # Also, in some corner cases, it's possible that the following code
3865   # will cause the same file to appear in the $(DIST_COMMON) variables
3866   # of two distinct Makefiles; but this is not a problem, since the
3867   # 'distdir' target in 'lib/am/distdir.am' can deal with the same
3868   # file being distributed multiple times.
3869   # See also automake bug#9651.
3870   if ($relative_dir eq '.')
3871     {
3872       foreach my $file (split (' ' , $configure_dist_common))
3873         {
3874           my $dir = dirname ($file);
3875           push_dist_common ($file)
3876             if ($dir eq '.' || ! is_make_dir ($dir));
3877         }
3878     }
3879
3880   # Files to distributed.  Don't use ->value_as_list_recursive
3881   # as it recursively expands '$(dist_pkgdata_DATA)' etc.
3882   my @dist_common = split (' ', rvar ('DIST_COMMON')->variable_value);
3883   @dist_common = uniq (sort for_dist_common (@dist_common));
3884   variable_delete 'DIST_COMMON';
3885   define_pretty_variable ('DIST_COMMON', TRUE, INTERNAL, @dist_common);
3886
3887   # Now that we've processed DIST_COMMON, disallow further attempts
3888   # to set it.
3889   $handle_dist_run = 1;
3890
3891   # Scan EXTRA_DIST to see if we need to distribute anything from a
3892   # subdir.  If so, add it to the list.  I didn't want to do this
3893   # originally, but there were so many requests that I finally
3894   # relented.
3895   my $extra_dist = var ('EXTRA_DIST');
3896
3897   $transform{'DISTCHECK-HOOK'} = !! rule 'distcheck-hook';
3898   $transform{'GETTEXT'} = $seen_gettext && !$seen_gettext_external;
3899
3900   # If the target 'dist-hook' exists, make sure it is run.  This
3901   # allows users to do random weird things to the distribution
3902   # before it is packaged up.
3903   push (@dist_targets, 'dist-hook')
3904     if user_phony_rule 'dist-hook';
3905   $transform{'DIST-TARGETS'} = join (' ', @dist_targets);
3906
3907   my $flm = option ('filename-length-max');
3908   my $filename_filter = $flm ? '.' x $flm->[1] : '';
3909
3910   $output_rules .= &file_contents ('distdir',
3911                                    new Automake::Location,
3912                                    %transform,
3913                                    FILENAME_FILTER => $filename_filter);
3914 }
3915
3916
3917 # check_directory ($NAME, $WHERE [, $RELATIVE_DIR = "."])
3918 # -------------------------------------------------------
3919 # Ensure $NAME is a directory (in $RELATIVE_DIR), and that it uses a sane
3920 # name.  Use $WHERE as a location in the diagnostic, if any.
3921 sub check_directory ($$;$)
3922 {
3923   my ($dir, $where, $reldir) = @_;
3924   $reldir = '.' unless defined $reldir;
3925
3926   error $where, "required directory $reldir/$dir does not exist"
3927     unless -d "$reldir/$dir";
3928
3929   # If an 'obj/' directory exists, BSD make will enter it before
3930   # reading 'Makefile'.  Hence the 'Makefile' in the current directory
3931   # will not be read.
3932   #
3933   #  % cat Makefile
3934   #  all:
3935   #          echo Hello
3936   #  % cat obj/Makefile
3937   #  all:
3938   #          echo World
3939   #  % make      # GNU make
3940   #  echo Hello
3941   #  Hello
3942   #  % pmake     # BSD make
3943   #  echo World
3944   #  World
3945   msg ('portability', $where,
3946        "naming a subdirectory 'obj' causes troubles with BSD make")
3947     if $dir eq 'obj';
3948
3949   # 'aux' is probably the most important of the following forbidden name,
3950   # since it's tempting to use it as an AC_CONFIG_AUX_DIR.
3951   msg ('portability', $where,
3952        "name '$dir' is reserved on W32 and DOS platforms")
3953     if grep (/^\Q$dir\E$/i, qw/aux lpt1 lpt2 lpt3 com1 com2 com3 com4 con prn/);
3954 }
3955
3956 # check_directories_in_var ($VARIABLE)
3957 # ------------------------------------
3958 # Recursively check all items in variables $VARIABLE as directories
3959 sub check_directories_in_var ($)
3960 {
3961   my ($var) = @_;
3962   $var->traverse_recursively
3963     (sub
3964      {
3965        my ($var, $val, $cond, $full_cond) = @_;
3966        check_directory ($val, $var->rdef ($cond)->location, $relative_dir);
3967        return ();
3968      },
3969      undef,
3970      skip_ac_subst => 1);
3971 }
3972
3973 # &handle_subdirs ()
3974 # ------------------
3975 # Handle subdirectories.
3976 sub handle_subdirs ()
3977 {
3978   my $subdirs = var ('SUBDIRS');
3979   return
3980     unless $subdirs;
3981
3982   check_directories_in_var $subdirs;
3983
3984   my $dsubdirs = var ('DIST_SUBDIRS');
3985   check_directories_in_var $dsubdirs
3986     if $dsubdirs;
3987
3988   $output_rules .= &file_contents ('subdirs', new Automake::Location);
3989   rvar ('RECURSIVE_TARGETS')->rdef (TRUE)->{'pretty'} = VAR_SORTED; # Gross!
3990 }
3991
3992
3993 # ($REGEN, @DEPENDENCIES)
3994 # &scan_aclocal_m4
3995 # ----------------
3996 # If aclocal.m4 creation is automated, return the list of its dependencies.
3997 sub scan_aclocal_m4 ()
3998 {
3999   my $regen_aclocal = 0;
4000
4001   set_seen 'CONFIG_STATUS_DEPENDENCIES';
4002   set_seen 'CONFIGURE_DEPENDENCIES';
4003
4004   if (-f 'aclocal.m4')
4005     {
4006       &define_variable ("ACLOCAL_M4", '$(top_srcdir)/aclocal.m4', INTERNAL);
4007
4008       my $aclocal = new Automake::XFile "< aclocal.m4";
4009       my $line = $aclocal->getline;
4010       $regen_aclocal = $line =~ 'generated automatically by aclocal';
4011     }
4012
4013   my @ac_deps = ();
4014
4015   if (set_seen ('ACLOCAL_M4_SOURCES'))
4016     {
4017       push (@ac_deps, '$(ACLOCAL_M4_SOURCES)');
4018       msg_var ('obsolete', 'ACLOCAL_M4_SOURCES',
4019                "'ACLOCAL_M4_SOURCES' is obsolete.\n"
4020                . "It should be safe to simply remove it");
4021     }
4022
4023   # Note that it might be possible that aclocal.m4 doesn't exist but
4024   # should be auto-generated.  This case probably isn't very
4025   # important.
4026
4027   return ($regen_aclocal, @ac_deps);
4028 }
4029
4030
4031 # Helper function for substitute_ac_subst_variables.
4032 sub substitute_ac_subst_variables_worker($)
4033 {
4034   my ($token) = @_;
4035   return "\@$token\@" if var $token;
4036   return "\${$token\}";
4037 }
4038
4039 # substitute_ac_subst_variables ($TEXT)
4040 # -------------------------------------
4041 # Replace any occurrence of ${FOO} in $TEXT by @FOO@ if FOO is an AC_SUBST
4042 # variable.
4043 sub substitute_ac_subst_variables ($)
4044 {
4045   my ($text) = @_;
4046   $text =~ s/\${([^ \t=:+{}]+)}/&substitute_ac_subst_variables_worker ($1)/ge;
4047   return $text;
4048 }
4049
4050 # @DEPENDENCIES
4051 # &prepend_srcdir (@INPUTS)
4052 # -------------------------
4053 # Prepend $(srcdir) or $(top_srcdir) to all @INPUTS.  The idea is that
4054 # if an input file has a directory part the same as the current
4055 # directory, then the directory part is simply replaced by $(srcdir).
4056 # But if the directory part is different, then $(top_srcdir) is
4057 # prepended.
4058 sub prepend_srcdir (@)
4059 {
4060   my (@inputs) = @_;
4061   my @newinputs;
4062
4063   foreach my $single (@inputs)
4064     {
4065       if (dirname ($single) eq $relative_dir)
4066         {
4067           push (@newinputs, '$(srcdir)/' . basename ($single));
4068         }
4069       else
4070         {
4071           push (@newinputs, '$(top_srcdir)/' . $single);
4072         }
4073     }
4074   return @newinputs;
4075 }
4076
4077 # @DEPENDENCIES
4078 # rewrite_inputs_into_dependencies ($OUTPUT, @INPUTS)
4079 # ---------------------------------------------------
4080 # Compute a list of dependencies appropriate for the rebuild
4081 # rule of
4082 #   AC_CONFIG_FILES($OUTPUT:$INPUT[0]:$INPUTS[1]:...)
4083 # Also distribute $INPUTs which are not built by another AC_CONFIG_FOOs.
4084 sub rewrite_inputs_into_dependencies ($@)
4085 {
4086   my ($file, @inputs) = @_;
4087   my @res = ();
4088
4089   for my $i (@inputs)
4090     {
4091       # We cannot create dependencies on shell variables.
4092       next if (substitute_ac_subst_variables $i) =~ /\$/;
4093
4094       if (exists $ac_config_files_location{$i} && $i ne $file)
4095         {
4096           my $di = dirname $i;
4097           if ($di eq $relative_dir)
4098             {
4099               $i = basename $i;
4100             }
4101           # In the top-level Makefile we do not use $(top_builddir), because
4102           # we are already there, and since the targets are built without
4103           # a $(top_builddir), it helps BSD Make to match them with
4104           # dependencies.
4105           elsif ($relative_dir ne '.')
4106             {
4107               $i = '$(top_builddir)/' . $i;
4108             }
4109         }
4110       else
4111         {
4112           msg ('error', $ac_config_files_location{$file},
4113                "required file '$i' not found")
4114             unless $i =~ /\$/ || exists $output_files{$i} || -f $i;
4115           ($i) = prepend_srcdir ($i);
4116           push_dist_common ($i);
4117         }
4118       push @res, $i;
4119     }
4120   return @res;
4121 }
4122
4123
4124
4125 # &handle_configure ($MAKEFILE_AM, $MAKEFILE_IN, $MAKEFILE, @INPUTS)
4126 # ------------------------------------------------------------------
4127 # Handle remaking and configure stuff.
4128 # We need the name of the input file, to do proper remaking rules.
4129 sub handle_configure ($$$@)
4130 {
4131   my ($makefile_am, $makefile_in, $makefile, @inputs) = @_;
4132
4133   prog_error 'empty @inputs'
4134     unless @inputs;
4135
4136   my ($rel_makefile_am, $rel_makefile_in) = prepend_srcdir ($makefile_am,
4137                                                             $makefile_in);
4138   my $rel_makefile = basename $makefile;
4139
4140   my $colon_infile = ':' . join (':', @inputs);
4141   $colon_infile = '' if $colon_infile eq ":$makefile.in";
4142   my @rewritten = rewrite_inputs_into_dependencies ($makefile, @inputs);
4143   my ($regen_aclocal_m4, @aclocal_m4_deps) = scan_aclocal_m4;
4144   define_pretty_variable ('am__aclocal_m4_deps', TRUE, INTERNAL,
4145                           @configure_deps, @aclocal_m4_deps,
4146                           '$(top_srcdir)/' . $configure_ac);
4147   my @configuredeps = ('$(am__aclocal_m4_deps)', '$(CONFIGURE_DEPENDENCIES)');
4148   push @configuredeps, '$(ACLOCAL_M4)' if -f 'aclocal.m4';
4149   define_pretty_variable ('am__configure_deps', TRUE, INTERNAL,
4150                           @configuredeps);
4151
4152   my $automake_options = '--' . (global_option 'cygnus' ? 'cygnus' : $strictness_name)
4153                          . (global_option 'no-dependencies' ? ' --ignore-deps' : '');
4154
4155   $output_rules .= file_contents
4156     ('configure',
4157      new Automake::Location,
4158      MAKEFILE              => $rel_makefile,
4159      'MAKEFILE-DEPS'       => "@rewritten",
4160      'CONFIG-MAKEFILE'     => ($relative_dir eq '.') ? '$@' : '$(subdir)/$@',
4161      'MAKEFILE-IN'         => $rel_makefile_in,
4162      'HAVE-MAKEFILE-IN-DEPS' => (@include_stack > 0),
4163      'MAKEFILE-IN-DEPS'    => "@include_stack",
4164      'MAKEFILE-AM'         => $rel_makefile_am,
4165      'AUTOMAKE-OPTIONS'    => $automake_options,
4166      'MAKEFILE-AM-SOURCES' => "$makefile$colon_infile",
4167      'REGEN-ACLOCAL-M4'    => $regen_aclocal_m4,
4168      VERBOSE               => verbose_flag ('GEN'));
4169
4170   if ($relative_dir eq '.')
4171     {
4172       &push_dist_common ('acconfig.h')
4173         if -f 'acconfig.h';
4174     }
4175
4176   # If we have a configure header, require it.
4177   my $hdr_index = 0;
4178   my @distclean_config;
4179   foreach my $spec (@config_headers)
4180     {
4181       $hdr_index += 1;
4182       # $CONFIG_H_PATH: config.h from top level.
4183       my ($config_h_path, @ins) = split_config_file_spec ($spec);
4184       my $config_h_dir = dirname ($config_h_path);
4185
4186       # If the header is in the current directory we want to build
4187       # the header here.  Otherwise, if we're at the topmost
4188       # directory and the header's directory doesn't have a
4189       # Makefile, then we also want to build the header.
4190       if ($relative_dir eq $config_h_dir
4191           || ($relative_dir eq '.' && ! &is_make_dir ($config_h_dir)))
4192         {
4193           my ($cn_sans_dir, $stamp_dir);
4194           if ($relative_dir eq $config_h_dir)
4195             {
4196               $cn_sans_dir = basename ($config_h_path);
4197               $stamp_dir = '';
4198             }
4199           else
4200             {
4201               $cn_sans_dir = $config_h_path;
4202               if ($config_h_dir eq '.')
4203                 {
4204                   $stamp_dir = '';
4205                 }
4206               else
4207                 {
4208                   $stamp_dir = $config_h_dir . '/';
4209                 }
4210             }
4211
4212           # This will also distribute all inputs.
4213           @ins = rewrite_inputs_into_dependencies ($config_h_path, @ins);
4214
4215           # Cannot define rebuild rules for filenames with shell variables.
4216           next if (substitute_ac_subst_variables $config_h_path) =~ /\$/;
4217
4218           # Header defined in this directory.
4219           my @files;
4220           if (-f $config_h_path . '.top')
4221             {
4222               push (@files, "$cn_sans_dir.top");
4223             }
4224           if (-f $config_h_path . '.bot')
4225             {
4226               push (@files, "$cn_sans_dir.bot");
4227             }
4228
4229           push_dist_common (@files);
4230
4231           # For now, acconfig.h can only appear in the top srcdir.
4232           if (-f 'acconfig.h')
4233             {
4234               push (@files, '$(top_srcdir)/acconfig.h');
4235             }
4236
4237           my $stamp = "${stamp_dir}stamp-h${hdr_index}";
4238           $output_rules .=
4239             file_contents ('remake-hdr',
4240                            new Automake::Location,
4241                            FILES            => "@files",
4242                            CONFIG_H         => $cn_sans_dir,
4243                            CONFIG_HIN       => $ins[0],
4244                            CONFIG_H_DEPS    => "@ins",
4245                            CONFIG_H_PATH    => $config_h_path,
4246                            STAMP            => "$stamp");
4247
4248           push @distclean_config, $cn_sans_dir, $stamp;
4249         }
4250     }
4251
4252   $output_rules .= file_contents ('clean-hdr',
4253                                   new Automake::Location,
4254                                   FILES => "@distclean_config")
4255     if @distclean_config;
4256
4257   # Distribute and define mkinstalldirs only if it is already present
4258   # in the package, for backward compatibility (some people may still
4259   # use $(mkinstalldirs)).
4260   my $mkidpath = "$config_aux_dir/mkinstalldirs";
4261   if (-f $mkidpath)
4262     {
4263       # Use require_file so that any existing script gets updated
4264       # by --force-missing.
4265       require_conf_file ($mkidpath, FOREIGN, 'mkinstalldirs');
4266       define_variable ('mkinstalldirs',
4267                        "\$(SHELL) $am_config_aux_dir/mkinstalldirs", INTERNAL);
4268     }
4269   else
4270     {
4271       # Use $(install_sh), not $(MKDIR_P) because the latter requires
4272       # at least one argument, and $(mkinstalldirs) used to work
4273       # even without arguments (e.g. $(mkinstalldirs) $(conditional_dir)).
4274       define_variable ('mkinstalldirs', '$(install_sh) -d', INTERNAL);
4275     }
4276
4277   reject_var ('CONFIG_HEADER',
4278               "'CONFIG_HEADER' is an anachronism; now determined "
4279               . "automatically\nfrom '$configure_ac'");
4280
4281   my @config_h;
4282   foreach my $spec (@config_headers)
4283     {
4284       my ($out, @ins) = split_config_file_spec ($spec);
4285       # Generate CONFIG_HEADER define.
4286       if ($relative_dir eq dirname ($out))
4287         {
4288           push @config_h, basename ($out);
4289         }
4290       else
4291         {
4292           push @config_h, "\$(top_builddir)/$out";
4293         }
4294     }
4295   define_variable ("CONFIG_HEADER", "@config_h", INTERNAL)
4296     if @config_h;
4297
4298   # Now look for other files in this directory which must be remade
4299   # by config.status, and generate rules for them.
4300   my @actual_other_files = ();
4301   # These get cleaned only in a VPATH build.
4302   my @actual_other_vpath_files = ();
4303   foreach my $lfile (@other_input_files)
4304     {
4305       my $file;
4306       my @inputs;
4307       if ($lfile =~ /^([^:]*):(.*)$/)
4308         {
4309           # This is the ":" syntax of AC_OUTPUT.
4310           $file = $1;
4311           @inputs = split (':', $2);
4312         }
4313       else
4314         {
4315           # Normal usage.
4316           $file = $lfile;
4317           @inputs = $file . '.in';
4318         }
4319
4320       # Automake files should not be stored in here, but in %MAKE_LIST.
4321       prog_error ("$lfile in \@other_input_files\n"
4322                   . "\@other_input_files = (@other_input_files)")
4323         if -f $file . '.am';
4324
4325       my $local = basename ($file);
4326
4327       # We skip files that aren't in this directory.  However, if
4328       # the file's directory does not have a Makefile, and we are
4329       # currently doing '.', then we create a rule to rebuild the
4330       # file in the subdir.
4331       my $fd = dirname ($file);
4332       if ($fd ne $relative_dir)
4333         {
4334           if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4335             {
4336               $local = $file;
4337             }
4338           else
4339             {
4340               next;
4341             }
4342         }
4343
4344       my @rewritten_inputs = rewrite_inputs_into_dependencies ($file, @inputs);
4345
4346       # Cannot output rules for shell variables.
4347       next if (substitute_ac_subst_variables $local) =~ /\$/;
4348
4349       my $condstr = '';
4350       my $cond = $ac_config_files_condition{$lfile};
4351       if (defined $cond)
4352         {
4353           $condstr = $cond->subst_string;
4354           Automake::Rule::define ($local, $configure_ac, RULE_AUTOMAKE, $cond,
4355                                   $ac_config_files_location{$file});
4356         }
4357       $output_rules .= ($condstr . $local . ': '
4358                         . '$(top_builddir)/config.status '
4359                         . "@rewritten_inputs\n"
4360                         . $condstr . "\t"
4361                         . 'cd $(top_builddir) && '
4362                         . '$(SHELL) ./config.status '
4363                         . ($relative_dir eq '.' ? '' : '$(subdir)/')
4364                         . '$@'
4365                         . "\n");
4366       push (@actual_other_files, $local);
4367     }
4368
4369   # For links we should clean destinations and distribute sources.
4370   foreach my $spec (@config_links)
4371     {
4372       my ($link, $file) = split /:/, $spec;
4373       # Some people do AC_CONFIG_LINKS($computed).  We only handle
4374       # the DEST:SRC form.
4375       next unless $file;
4376       my $where = $ac_config_files_location{$link};
4377
4378       # Skip destinations that contain shell variables.
4379       if ((substitute_ac_subst_variables $link) !~ /\$/)
4380         {
4381           # We skip links that aren't in this directory.  However, if
4382           # the link's directory does not have a Makefile, and we are
4383           # currently doing '.', then we add the link to CONFIG_CLEAN_FILES
4384           # in '.'s Makefile.in.
4385           my $local = basename ($link);
4386           my $fd = dirname ($link);
4387           if ($fd ne $relative_dir)
4388             {
4389               if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4390                 {
4391                   $local = $link;
4392                 }
4393               else
4394                 {
4395                   $local = undef;
4396                 }
4397             }
4398           if ($file ne $link)
4399             {
4400               push @actual_other_files, $local if $local;
4401             }
4402           else
4403             {
4404               push @actual_other_vpath_files, $local if $local;
4405             }
4406         }
4407
4408       # Do not process sources that contain shell variables.
4409       if ((substitute_ac_subst_variables $file) !~ /\$/)
4410         {
4411           my $fd = dirname ($file);
4412
4413           # We distribute files that are in this directory.
4414           # At the top-level ('.') we also distribute files whose
4415           # directory does not have a Makefile.
4416           if (($fd eq $relative_dir)
4417               || ($relative_dir eq '.' && ! &is_make_dir ($fd)))
4418             {
4419               # The following will distribute $file as a side-effect when
4420               # it is appropriate (i.e., when $file is not already an output).
4421               # We do not need the result, just the side-effect.
4422               rewrite_inputs_into_dependencies ($link, $file);
4423             }
4424         }
4425     }
4426
4427   # These files get removed by "make distclean".
4428   define_pretty_variable ('CONFIG_CLEAN_FILES', TRUE, INTERNAL,
4429                           @actual_other_files);
4430   define_pretty_variable ('CONFIG_CLEAN_VPATH_FILES', TRUE, INTERNAL,
4431                           @actual_other_vpath_files);
4432 }
4433
4434 # Handle C headers.
4435 sub handle_headers
4436 {
4437     my @r = &am_install_var ('-defaultdist', 'header', 'HEADERS', 'include',
4438                              'oldinclude', 'pkginclude',
4439                              'noinst', 'check');
4440     foreach (@r)
4441     {
4442       next unless $_->[1] =~ /\..*$/;
4443       &saw_extension ($&);
4444     }
4445 }
4446
4447 sub handle_gettext
4448 {
4449   return if ! $seen_gettext || $relative_dir ne '.';
4450
4451   my $subdirs = var 'SUBDIRS';
4452
4453   if (! $subdirs)
4454     {
4455       err_ac "AM_GNU_GETTEXT used but SUBDIRS not defined";
4456       return;
4457     }
4458
4459   # Perform some sanity checks to help users get the right setup.
4460   # We disable these tests when po/ doesn't exist in order not to disallow
4461   # unusual gettext setups.
4462   #
4463   # Bruno Haible:
4464   # | The idea is:
4465   # |
4466   # |  1) If a package doesn't have a directory po/ at top level, it
4467   # |     will likely have multiple po/ directories in subpackages.
4468   # |
4469   # |  2) It is useful to warn for the absence of intl/ if AM_GNU_GETTEXT
4470   # |     is used without 'external'. It is also useful to warn for the
4471   # |     presence of intl/ if AM_GNU_GETTEXT([external]) is used. Both
4472   # |     warnings apply only to the usual layout of packages, therefore
4473   # |     they should both be disabled if no po/ directory is found at
4474   # |     top level.
4475
4476   if (-d 'po')
4477     {
4478       my @subdirs = $subdirs->value_as_list_recursive;
4479
4480       msg_var ('syntax', $subdirs,
4481                "AM_GNU_GETTEXT used but 'po' not in SUBDIRS")
4482         if ! grep ($_ eq 'po', @subdirs);
4483
4484       # intl/ is not required when AM_GNU_GETTEXT is called with the
4485       # 'external' option and AM_GNU_GETTEXT_INTL_SUBDIR is not called.
4486       msg_var ('syntax', $subdirs,
4487                "AM_GNU_GETTEXT used but 'intl' not in SUBDIRS")
4488         if (! ($seen_gettext_external && ! $seen_gettext_intl)
4489             && ! grep ($_ eq 'intl', @subdirs));
4490
4491       # intl/ should not be used with AM_GNU_GETTEXT([external]), except
4492       # if AM_GNU_GETTEXT_INTL_SUBDIR is called.
4493       msg_var ('syntax', $subdirs,
4494                "'intl' should not be in SUBDIRS when "
4495                . "AM_GNU_GETTEXT([external]) is used")
4496         if ($seen_gettext_external && ! $seen_gettext_intl
4497             && grep ($_ eq 'intl', @subdirs));
4498     }
4499
4500   require_file ($ac_gettext_location, GNU, 'ABOUT-NLS');
4501 }
4502
4503 # Handle footer elements.
4504 sub handle_footer
4505 {
4506     reject_rule ('.SUFFIXES',
4507                  "use variable 'SUFFIXES', not target '.SUFFIXES'");
4508
4509     # Note: AIX 4.1 /bin/make will fail if any suffix rule appears
4510     # before .SUFFIXES.  So we make sure that .SUFFIXES appears before
4511     # anything else, by sticking it right after the default: target.
4512     $output_header .= ".SUFFIXES:\n";
4513     my $suffixes = var 'SUFFIXES';
4514     my @suffixes = Automake::Rule::suffixes;
4515     if (@suffixes || $suffixes)
4516     {
4517         # Make sure SUFFIXES has unique elements.  Sort them to ensure
4518         # the output remains consistent.  However, $(SUFFIXES) is
4519         # always at the start of the list, unsorted.  This is done
4520         # because make will choose rules depending on the ordering of
4521         # suffixes, and this lets the user have some control.  Push
4522         # actual suffixes, and not $(SUFFIXES).  Some versions of make
4523         # do not like variable substitutions on the .SUFFIXES line.
4524         my @user_suffixes = ($suffixes
4525                              ? $suffixes->value_as_list_recursive : ());
4526
4527         my %suffixes = map { $_ => 1 } @suffixes;
4528         delete @suffixes{@user_suffixes};
4529
4530         $output_header .= (".SUFFIXES: "
4531                            . join (' ', @user_suffixes, sort keys %suffixes)
4532                            . "\n");
4533     }
4534
4535     $output_trailer .= file_contents ('footer', new Automake::Location);
4536 }
4537
4538
4539 # Generate 'make install' rules.
4540 sub handle_install ()
4541 {
4542   $output_rules .= &file_contents
4543     ('install',
4544      new Automake::Location,
4545      maybe_BUILT_SOURCES => (set_seen ('BUILT_SOURCES')
4546                              ? (" \$(BUILT_SOURCES)\n"
4547                                 . "\t\$(MAKE) \$(AM_MAKEFLAGS)")
4548                              : ''),
4549      'installdirs-local' => (user_phony_rule 'installdirs-local'
4550                              ? ' installdirs-local' : ''),
4551      am__installdirs => variable_value ('am__installdirs') || '');
4552 }
4553
4554
4555 # Deal with all and all-am.
4556 sub handle_all ($)
4557 {
4558     my ($makefile) = @_;
4559
4560     # Output 'all-am'.
4561
4562     # Put this at the beginning for the sake of non-GNU makes.  This
4563     # is still wrong if these makes can run parallel jobs.  But it is
4564     # right enough.
4565     unshift (@all, basename ($makefile));
4566
4567     foreach my $spec (@config_headers)
4568       {
4569         my ($out, @ins) = split_config_file_spec ($spec);
4570         push (@all, basename ($out))
4571           if dirname ($out) eq $relative_dir;
4572       }
4573
4574     # Install 'all' hooks.
4575     push (@all, "all-local")
4576       if user_phony_rule "all-local";
4577
4578     &pretty_print_rule ("all-am:", "\t\t", @all);
4579     &depend ('.PHONY', 'all-am', 'all');
4580
4581
4582     # Output 'all'.
4583
4584     my @local_headers = ();
4585     push @local_headers, '$(BUILT_SOURCES)'
4586       if var ('BUILT_SOURCES');
4587     foreach my $spec (@config_headers)
4588       {
4589         my ($out, @ins) = split_config_file_spec ($spec);
4590         push @local_headers, basename ($out)
4591           if dirname ($out) eq $relative_dir;
4592       }
4593
4594     if (@local_headers)
4595       {
4596         # We need to make sure config.h is built before we recurse.
4597         # We also want to make sure that built sources are built
4598         # before any ordinary 'all' targets are run.  We can't do this
4599         # by changing the order of dependencies to the "all" because
4600         # that breaks when using parallel makes.  Instead we handle
4601         # things explicitly.
4602         $output_all .= ("all: @local_headers"
4603                         . "\n\t"
4604                         . '$(MAKE) $(AM_MAKEFLAGS) '
4605                         . (var ('SUBDIRS') ? 'all-recursive' : 'all-am')
4606                         . "\n\n");
4607         depend ('.MAKE', 'all');
4608       }
4609     else
4610       {
4611         $output_all .= "all: " . (var ('SUBDIRS')
4612                                   ? 'all-recursive' : 'all-am') . "\n\n";
4613       }
4614 }
4615
4616
4617 # &do_check_merge_target ()
4618 # -------------------------
4619 # Handle check merge target specially.
4620 sub do_check_merge_target ()
4621 {
4622   # Include user-defined local form of target.
4623   push @check_tests, 'check-local'
4624     if user_phony_rule 'check-local';
4625
4626   # In --cygnus mode, check doesn't depend on all.
4627   if (option 'cygnus')
4628     {
4629       # Just run the local check rules.
4630       pretty_print_rule ('check-am:', "\t\t", @check);
4631     }
4632   else
4633     {
4634       # The check target must depend on the local equivalent of
4635       # 'all', to ensure all the primary targets are built.  Then it
4636       # must build the local check rules.
4637       $output_rules .= "check-am: all-am\n";
4638       if (@check)
4639         {
4640           pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4641                              @check);
4642           depend ('.MAKE', 'check-am');
4643         }
4644     }
4645   if (@check_tests)
4646     {
4647       pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4648                          @check_tests);
4649       depend ('.MAKE', 'check-am');
4650     }
4651
4652   depend '.PHONY', 'check', 'check-am';
4653   # Handle recursion.  We have to honor BUILT_SOURCES like for 'all:'.
4654   $output_rules .= ("check: "
4655                     . (var ('BUILT_SOURCES')
4656                        ? "\$(BUILT_SOURCES)\n\t\$(MAKE) \$(AM_MAKEFLAGS) "
4657                        : '')
4658                     . (var ('SUBDIRS') ? 'check-recursive' : 'check-am')
4659                     . "\n");
4660   depend ('.MAKE', 'check')
4661     if var ('BUILT_SOURCES');
4662 }
4663
4664 # handle_clean ($MAKEFILE)
4665 # ------------------------
4666 # Handle all 'clean' targets.
4667 sub handle_clean ($)
4668 {
4669   my ($makefile) = @_;
4670
4671   # Clean the files listed in user variables if they exist.
4672   $clean_files{'$(MOSTLYCLEANFILES)'} = MOSTLY_CLEAN
4673     if var ('MOSTLYCLEANFILES');
4674   $clean_files{'$(CLEANFILES)'} = CLEAN
4675     if var ('CLEANFILES');
4676   $clean_files{'$(DISTCLEANFILES)'} = DIST_CLEAN
4677     if var ('DISTCLEANFILES');
4678   $clean_files{'$(MAINTAINERCLEANFILES)'} = MAINTAINER_CLEAN
4679     if var ('MAINTAINERCLEANFILES');
4680
4681   # Built sources are automatically removed by maintainer-clean.
4682   $clean_files{'$(BUILT_SOURCES)'} = MAINTAINER_CLEAN
4683     if var ('BUILT_SOURCES');
4684
4685   # Compute a list of "rm"s to run for each target.
4686   my %rms = (MOSTLY_CLEAN, [],
4687              CLEAN, [],
4688              DIST_CLEAN, [],
4689              MAINTAINER_CLEAN, []);
4690
4691   foreach my $file (keys %clean_files)
4692     {
4693       my $when = $clean_files{$file};
4694       prog_error 'invalid entry in %clean_files'
4695         unless exists $rms{$when};
4696
4697       my $rm = "rm -f $file";
4698       # If file is a variable, make sure when don't call 'rm -f' without args.
4699       $rm ="test -z \"$file\" || $rm"
4700         if ($file =~ /^\s*\$(\(.*\)|\{.*\})\s*$/);
4701
4702       push @{$rms{$when}}, "\t-$rm\n";
4703     }
4704
4705   $output_rules .= &file_contents
4706     ('clean',
4707      new Automake::Location,
4708      MOSTLYCLEAN_RMS      => join ('', sort @{$rms{&MOSTLY_CLEAN}}),
4709      CLEAN_RMS            => join ('', sort @{$rms{&CLEAN}}),
4710      DISTCLEAN_RMS        => join ('', sort @{$rms{&DIST_CLEAN}}),
4711      MAINTAINER_CLEAN_RMS => join ('', sort @{$rms{&MAINTAINER_CLEAN}}),
4712      MAKEFILE             => basename $makefile,
4713      );
4714 }
4715
4716
4717 # &target_cmp ($A, $B)
4718 # --------------------
4719 # Subroutine for &handle_factored_dependencies to let '.PHONY' and
4720 # other '.TARGETS' be last.
4721 sub target_cmp
4722 {
4723   return 0 if $a eq $b;
4724
4725   my $a1 = substr ($a, 0, 1);
4726   my $b1 = substr ($b, 0, 1);
4727   if ($a1 ne $b1)
4728     {
4729       return -1 if $b1 eq '.';
4730       return 1 if $a1 eq '.';
4731     }
4732   return $a cmp $b;
4733 }
4734
4735
4736 # &handle_factored_dependencies ()
4737 # --------------------------------
4738 # Handle everything related to gathered targets.
4739 sub handle_factored_dependencies
4740 {
4741   # Reject bad hooks.
4742   foreach my $utarg ('uninstall-data-local', 'uninstall-data-hook',
4743                      'uninstall-exec-local', 'uninstall-exec-hook',
4744                      'uninstall-dvi-local',
4745                      'uninstall-html-local',
4746                      'uninstall-info-local',
4747                      'uninstall-pdf-local',
4748                      'uninstall-ps-local')
4749     {
4750       my $x = $utarg;
4751       $x =~ s/-.*-/-/;
4752       reject_rule ($utarg, "use '$x', not '$utarg'");
4753     }
4754
4755   reject_rule ('install-local',
4756                "use 'install-data-local' or 'install-exec-local', "
4757                . "not 'install-local'");
4758
4759   reject_rule ('install-hook',
4760                "use 'install-data-hook' or 'install-exec-hook', "
4761                . "not 'install-hook'");
4762
4763   # Install the -local hooks.
4764   foreach (keys %dependencies)
4765     {
4766       # Hooks are installed on the -am targets.
4767       s/-am$// or next;
4768       depend ("$_-am", "$_-local")
4769         if user_phony_rule "$_-local";
4770     }
4771
4772   # Install the -hook hooks.
4773   # FIXME: Why not be as liberal as we are with -local hooks?
4774   foreach ('install-exec', 'install-data', 'uninstall')
4775     {
4776       if (user_phony_rule "$_-hook")
4777         {
4778           depend ('.MAKE', "$_-am");
4779           register_action("$_-am",
4780                           ("\t\@\$(NORMAL_INSTALL)\n"
4781                            . "\t\$(MAKE) \$(AM_MAKEFLAGS) $_-hook"));
4782         }
4783     }
4784
4785   # All the required targets are phony.
4786   depend ('.PHONY', keys %required_targets);
4787
4788   # Actually output gathered targets.
4789   foreach (sort target_cmp keys %dependencies)
4790     {
4791       # If there is nothing about this guy, skip it.
4792       next
4793         unless (@{$dependencies{$_}}
4794                 || $actions{$_}
4795                 || $required_targets{$_});
4796
4797       # Define gathered targets in undefined conditions.
4798       # FIXME: Right now we must handle .PHONY as an exception,
4799       # because people write things like
4800       #    .PHONY: myphonytarget
4801       # to append dependencies.  This would not work if Automake
4802       # refrained from defining its own .PHONY target as it does
4803       # with other overridden targets.
4804       # Likewise for '.MAKE'.
4805       my @undefined_conds = (TRUE,);
4806       if ($_ ne '.PHONY' && $_ ne '.MAKE')
4807         {
4808           @undefined_conds =
4809             Automake::Rule::define ($_, 'internal',
4810                                     RULE_AUTOMAKE, TRUE, INTERNAL);
4811         }
4812       my @uniq_deps = uniq (sort @{$dependencies{$_}});
4813       foreach my $cond (@undefined_conds)
4814         {
4815           my $condstr = $cond->subst_string;
4816           &pretty_print_rule ("$condstr$_:", "$condstr\t", @uniq_deps);
4817           $output_rules .= $actions{$_} if defined $actions{$_};
4818           $output_rules .= "\n";
4819         }
4820     }
4821 }
4822
4823
4824 # &handle_tests_dejagnu ()
4825 # ------------------------
4826 sub handle_tests_dejagnu
4827 {
4828     push (@check_tests, 'check-DEJAGNU');
4829     $output_rules .= file_contents ('dejagnu', new Automake::Location);
4830 }
4831
4832 sub handle_per_suffix_test
4833 {
4834   my ($test_suffix, %transform) = @_;
4835   my ($pfx, $generic, $parallel_tests_option, $am_exeext);
4836   prog_error ("called with 'parallel-tests' option not set")
4837     unless $parallel_tests_option = option 'parallel-tests';
4838   if ($test_suffix eq '')
4839     {
4840       $pfx = '';
4841       $generic = 0;
4842       $am_exeext = 'FALSE';
4843     }
4844   else
4845     {
4846       prog_error ("test suffix '$test_suffix' lacks leading dot")
4847         unless $test_suffix =~ m/^\.(.*)/;
4848       $pfx = uc ($1) . '_';
4849       $generic = 1;
4850       $am_exeext = exists $configure_vars{'EXEEXT'} ? 'am__EXEEXT'
4851                                                     : 'FALSE';
4852     }
4853   # The "test driver" program, deputed to handle tests protocol used by
4854   # test scripts.  By default, it's assumed that no protocol is used,
4855   # so we fall back to the old "parallel-tests" behaviour, implemented
4856   # by the 'test-driver' auxiliary script.
4857   if (! var "${pfx}LOG_DRIVER")
4858     {
4859       require_conf_file ($parallel_tests_option->{position}, FOREIGN,
4860                         'test-driver');
4861       define_variable ("${pfx}LOG_DRIVER",
4862                        "\$(SHELL) $am_config_aux_dir/test-driver",
4863                        INTERNAL);
4864     }
4865   my $driver = '$(' . $pfx . 'LOG_DRIVER)';
4866   my $driver_flags = '$(AM_' . $pfx . 'LOG_DRIVER_FLAGS)'
4867                        . ' $(' . $pfx . 'LOG_DRIVER_FLAGS)';
4868   my $compile = "${pfx}LOG_COMPILE";
4869   define_variable ($compile,
4870                    '$(' . $pfx . 'LOG_COMPILER)'
4871                       . ' $(AM_' .  $pfx . 'LOG_FLAGS)'
4872                       . ' $(' . $pfx . 'LOG_FLAGS)',
4873                      INTERNAL);
4874   $output_rules .= file_contents ('check2', new Automake::Location,
4875                                    GENERIC => $generic,
4876                                    DRIVER => $driver,
4877                                    DRIVER_FLAGS => $driver_flags,
4878                                    COMPILE => '$(' . $compile . ')',
4879                                    EXT => $test_suffix,
4880                                    am__EXEEXT => $am_exeext,
4881                                    %transform);
4882 }
4883
4884 # is_valid_test_extension ($EXT)
4885 # ------------------------------
4886 # Return true if $EXT can appear in $(TEST_EXTENSIONS), return false
4887 # otherwise.
4888 sub is_valid_test_extension ($)
4889 {
4890   my $ext = shift;
4891   return 1
4892     if ($ext =~ /^\.[a-zA-Z_][a-zA-Z0-9_]*$/);
4893   return 1
4894     if (exists $configure_vars{'EXEEXT'} && $ext eq subst ('EXEEXT'));
4895   return 0;
4896 }
4897
4898 # Handle TESTS variable and other checks.
4899 sub handle_tests
4900 {
4901   if (option 'dejagnu')
4902     {
4903       &handle_tests_dejagnu;
4904     }
4905   else
4906     {
4907       foreach my $c ('DEJATOOL', 'RUNTEST', 'RUNTESTFLAGS')
4908         {
4909           reject_var ($c, "'$c' defined but 'dejagnu' not in "
4910                       . "'AUTOMAKE_OPTIONS'");
4911         }
4912     }
4913
4914   if (var ('TESTS'))
4915     {
4916       push (@check_tests, 'check-TESTS');
4917       my $check_deps = "@check";
4918       $output_rules .= &file_contents ('check', new Automake::Location,
4919                                        COLOR => !! option 'color-tests',
4920                                        PARALLEL_TESTS => !! option 'parallel-tests',
4921                                        CHECK_DEPS => $check_deps);
4922
4923       # Tests that are known programs should have $(EXEEXT) appended.
4924       # For matching purposes, we need to adjust XFAIL_TESTS as well.
4925       append_exeext { exists $known_programs{$_[0]} } 'TESTS';
4926       append_exeext { exists $known_programs{$_[0]} } 'XFAIL_TESTS'
4927         if (var ('XFAIL_TESTS'));
4928
4929       if (my $parallel_tests = option 'parallel-tests')
4930         {
4931           define_variable ('TEST_SUITE_LOG', 'test-suite.log', INTERNAL);
4932           my $suff = '.test';
4933           my $at_exeext = '';
4934           my $handle_exeext = exists $configure_vars{'EXEEXT'};
4935           if ($handle_exeext)
4936             {
4937               $at_exeext = subst ('EXEEXT');
4938               $suff = $at_exeext  . ' ' . $suff;
4939             }
4940           if (! var 'TEST_EXTENSIONS')
4941             {
4942               define_variable ('TEST_EXTENSIONS', $suff, INTERNAL);
4943             }
4944           my $var = var 'TEST_EXTENSIONS';
4945           # Currently, we are not able to deal with conditional contents
4946           # in TEST_EXTENSIONS.
4947           if ($var->has_conditional_contents)
4948            {
4949              msg_var 'unsupported', $var,
4950                      "'TEST_EXTENSIONS' cannot have conditional contents";
4951            }
4952           my @test_suffixes = $var->value_as_list_recursive;
4953           if ((my @invalid_test_suffixes =
4954                   grep { !is_valid_test_extension $_ } @test_suffixes) > 0)
4955             {
4956               error $var->rdef (TRUE)->location,
4957                     "invalid test extensions: @invalid_test_suffixes";
4958             }
4959           @test_suffixes = grep { is_valid_test_extension $_ } @test_suffixes;
4960           if ($handle_exeext)
4961             {
4962               unshift (@test_suffixes, $at_exeext)
4963                 unless $test_suffixes[0] eq $at_exeext;
4964             }
4965           unshift (@test_suffixes, '');
4966
4967           transform_variable_recursively
4968             ('TESTS', 'TEST_LOGS', 'am__testlogs', 1, INTERNAL,
4969               sub {
4970                 my ($subvar, $val, $cond, $full_cond) = @_;
4971                 my $obj = $val;
4972                 return $obj
4973                   if $val =~ /^\@.*\@$/;
4974                 $obj =~ s/\$\(EXEEXT\)$//o;
4975
4976                 if ($val =~ /(\$\((top_)?srcdir\))\//o)
4977                   {
4978                     msg ('error', $subvar->rdef ($cond)->location,
4979                          "parallel-tests: using '$1' in TESTS is currently broken: '$val'");
4980                   }
4981
4982                 foreach my $test_suffix (@test_suffixes)
4983                   {
4984                     next
4985                       if $test_suffix eq $at_exeext || $test_suffix eq '';
4986                     return substr ($obj, 0, length ($obj) - length ($test_suffix)) . '.log'
4987                       if substr ($obj, - length ($test_suffix)) eq $test_suffix;
4988                   }
4989                 my $base = $obj;
4990                 $obj .= '.log';
4991                 handle_per_suffix_test ('',
4992                                         OBJ => $obj,
4993                                         BASE => $base,
4994                                         SOURCE => $val);
4995                 return $obj;
4996               });
4997
4998           my $nhelper=1;
4999           my $prev = 'TESTS';
5000           my $post = '';
5001           my $last_suffix = $test_suffixes[$#test_suffixes];
5002           my $cur = '';
5003           foreach my $test_suffix (@test_suffixes)
5004             {
5005               if ($test_suffix eq $last_suffix)
5006                 {
5007                   $cur = 'TEST_LOGS';
5008                 }
5009               else
5010                 {
5011                   $cur = 'am__test_logs' . $nhelper;
5012                 }
5013               define_variable ($cur,
5014                 '$(' . $prev . ':' . $test_suffix . $post . '=.log)', INTERNAL);
5015               $post = '.log';
5016               $prev = $cur;
5017               $nhelper++;
5018               if ($test_suffix ne $at_exeext && $test_suffix ne '')
5019                 {
5020                   handle_per_suffix_test ($test_suffix,
5021                                           OBJ => '',
5022                                           BASE => '$*',
5023                                           SOURCE => '$<');
5024                 }
5025             }
5026           $clean_files{'$(TEST_LOGS)'} = MOSTLY_CLEAN;
5027           $clean_files{'$(TEST_LOGS:.log=.trs)'} = MOSTLY_CLEAN;
5028           $clean_files{'$(TEST_SUITE_LOG)'} = MOSTLY_CLEAN;
5029         }
5030     }
5031 }
5032
5033 # Handle Emacs Lisp.
5034 sub handle_emacs_lisp
5035 {
5036   my @elfiles = &am_install_var ('-candist', 'lisp', 'LISP',
5037                                  'lisp', 'noinst');
5038
5039   return if ! @elfiles;
5040
5041   define_pretty_variable ('am__ELFILES', TRUE, INTERNAL,
5042                           map { $_->[1] } @elfiles);
5043   define_pretty_variable ('am__ELCFILES', TRUE, INTERNAL,
5044                           '$(am__ELFILES:.el=.elc)');
5045   # This one can be overridden by users.
5046   define_pretty_variable ('ELCFILES', TRUE, INTERNAL, '$(LISP:.el=.elc)');
5047
5048   push @all, '$(ELCFILES)';
5049
5050   require_variables ($elfiles[0][0], "Emacs Lisp sources seen", TRUE,
5051                      'EMACS', 'lispdir');
5052   require_conf_file ($elfiles[0][0], FOREIGN, 'elisp-comp');
5053   &define_variable ('elisp_comp', "$am_config_aux_dir/elisp-comp", INTERNAL);
5054 }
5055
5056 # Handle Python
5057 sub handle_python
5058 {
5059   my @pyfiles = &am_install_var ('-defaultdist', 'python', 'PYTHON',
5060                                  'noinst');
5061   return if ! @pyfiles;
5062
5063   require_variables ($pyfiles[0][0], "Python sources seen", TRUE, 'PYTHON');
5064   require_conf_file ($pyfiles[0][0], FOREIGN, 'py-compile');
5065   &define_variable ('py_compile', "$am_config_aux_dir/py-compile", INTERNAL);
5066 }
5067
5068 # Handle Java.
5069 sub handle_java
5070 {
5071     my @sourcelist = &am_install_var ('-candist',
5072                                       'java', 'JAVA',
5073                                       'noinst', 'check');
5074     return if ! @sourcelist;
5075
5076     my @prefixes = am_primary_prefixes ('JAVA', 1,
5077                                         'noinst', 'check');
5078
5079     my $dir;
5080     my @java_sources = ();
5081     foreach my $prefix (@prefixes)
5082       {
5083         (my $curs = $prefix) =~ s/^(?:nobase_)?(?:dist_|nodist_)?//;
5084
5085         next
5086           if $curs eq 'EXTRA';
5087
5088         push @java_sources, '$(' . $prefix . '_JAVA' . ')';
5089
5090         if (defined $dir)
5091           {
5092             err_var "${curs}_JAVA", "multiple _JAVA primaries in use"
5093              unless $curs eq $dir;
5094           }
5095
5096         $dir = $curs;
5097       }
5098
5099     define_pretty_variable ('am__java_sources', TRUE, INTERNAL,
5100                             "@java_sources");
5101
5102     if ($dir eq 'check')
5103       {
5104         push (@check, "class$dir.stamp");
5105       }
5106     else
5107       {
5108         push (@all, "class$dir.stamp");
5109       }
5110 }
5111
5112
5113 # Handle some of the minor options.
5114 sub handle_minor_options
5115 {
5116   if (option 'readme-alpha')
5117     {
5118       if ($relative_dir eq '.')
5119         {
5120           if ($package_version !~ /^$GNITS_VERSION_PATTERN$/)
5121             {
5122               msg ('error-gnits', $package_version_location,
5123                    "version '$package_version' doesn't follow " .
5124                    "Gnits standards");
5125             }
5126           if (defined $1 && -f 'README-alpha')
5127             {
5128               # This means we have an alpha release.  See
5129               # GNITS_VERSION_PATTERN for details.
5130               push_dist_common ('README-alpha');
5131             }
5132         }
5133     }
5134 }
5135
5136 ################################################################
5137
5138 # ($OUTPUT, @INPUTS)
5139 # &split_config_file_spec ($SPEC)
5140 # -------------------------------
5141 # Decode the Autoconf syntax for config files (files, headers, links
5142 # etc.).
5143 sub split_config_file_spec ($)
5144 {
5145   my ($spec) = @_;
5146   my ($output, @inputs) = split (/:/, $spec);
5147
5148   push @inputs, "$output.in"
5149     unless @inputs;
5150
5151   return ($output, @inputs);
5152 }
5153
5154 # $input
5155 # locate_am (@POSSIBLE_SOURCES)
5156 # -----------------------------
5157 # AC_CONFIG_FILES allow specifications such as Makefile:top.in:mid.in:bot.in
5158 # This functions returns the first *.in file for which a *.am exists.
5159 # It returns undef otherwise.
5160 sub locate_am (@)
5161 {
5162   my (@rest) = @_;
5163   my $input;
5164   foreach my $file (@rest)
5165     {
5166       if (($file =~ /^(.*)\.in$/) && -f "$1.am")
5167         {
5168           $input = $file;
5169           last;
5170         }
5171     }
5172   return $input;
5173 }
5174
5175 my %make_list;
5176
5177 # &scan_autoconf_config_files ($WHERE, $CONFIG-FILES)
5178 # ---------------------------------------------------
5179 # Study $CONFIG-FILES which is the first argument to AC_CONFIG_FILES
5180 # (or AC_OUTPUT).
5181 sub scan_autoconf_config_files ($$)
5182 {
5183   my ($where, $config_files) = @_;
5184
5185   # Look at potential Makefile.am's.
5186   foreach (split ' ', $config_files)
5187     {
5188       # Must skip empty string for Perl 4.
5189       next if $_ eq "\\" || $_ eq '';
5190
5191       # Handle $local:$input syntax.
5192       my ($local, @rest) = split (/:/);
5193       @rest = ("$local.in",) unless @rest;
5194       # Keep in sync with 'conffile-leading-dot.test'.
5195       msg ('unsupported', $where,
5196            "omit leading './' from config file names such as '$local';"
5197            . "\nremake rules might be subtly broken otherwise")
5198         if ($local =~ /^\.\//);
5199       my $input = locate_am @rest;
5200       if ($input)
5201         {
5202           # We have a file that automake should generate.
5203           $make_list{$input} = join (':', ($local, @rest));
5204         }
5205       else
5206         {
5207           # We have a file that automake should cause to be
5208           # rebuilt, but shouldn't generate itself.
5209           push (@other_input_files, $_);
5210         }
5211       $ac_config_files_location{$local} = $where;
5212       $ac_config_files_condition{$local} =
5213         new Automake::Condition (@cond_stack)
5214           if (@cond_stack);
5215     }
5216 }
5217
5218
5219 # &scan_autoconf_traces ($FILENAME)
5220 # ---------------------------------
5221 sub scan_autoconf_traces ($)
5222 {
5223   my ($filename) = @_;
5224
5225   # Macros to trace, with their minimal number of arguments.
5226   #
5227   # IMPORTANT: If you add a macro here, you should also add this macro
5228   # =========  to Automake-preselection in autoconf/lib/autom4te.in.
5229   my %traced = (
5230                 AC_CANONICAL_BUILD => 0,
5231                 AC_CANONICAL_HOST => 0,
5232                 AC_CANONICAL_TARGET => 0,
5233                 AC_CONFIG_AUX_DIR => 1,
5234                 AC_CONFIG_FILES => 1,
5235                 AC_CONFIG_HEADERS => 1,
5236                 AC_CONFIG_LIBOBJ_DIR => 1,
5237                 AC_CONFIG_LINKS => 1,
5238                 AC_FC_SRCEXT => 1,
5239                 AC_INIT => 0,
5240                 AC_LIBSOURCE => 1,
5241                 AC_REQUIRE_AUX_FILE => 1,
5242                 AC_SUBST_TRACE => 1,
5243                 AM_AUTOMAKE_VERSION => 1,
5244                 AM_PROG_MKDIR_P => 0, # FIXME: to be removed in 1.13
5245                 AM_CONDITIONAL => 2,
5246                 AM_GNU_GETTEXT => 0,
5247                 AM_GNU_GETTEXT_INTL_SUBDIR => 0,
5248                 AM_INIT_AUTOMAKE => 0,
5249                 AM_MAINTAINER_MODE => 0,
5250                 AM_PROG_AR => 0,
5251                 AM_PROG_CC_C_O => 0,
5252                 AM_SILENT_RULES => 0,
5253                 _AM_SUBST_NOTMAKE => 1,
5254                 _AM_COND_IF => 1,
5255                 _AM_COND_ELSE => 1,
5256                 _AM_COND_ENDIF => 1,
5257                 LT_SUPPORTED_TAG => 1,
5258                 _LT_AC_TAGCONFIG => 0,
5259                 m4_include => 1,
5260                 m4_sinclude => 1,
5261                 sinclude => 1,
5262               );
5263
5264   my $traces = ($ENV{AUTOCONF} || '@am_AUTOCONF@') . " ";
5265
5266   # Use a separator unlikely to be used, not ':', the default, which
5267   # has a precise meaning for AC_CONFIG_FILES and so on.
5268   $traces .= join (' ',
5269                    map { "--trace=$_" . ':\$f:\$l::\$d::\$n::\${::}%' }
5270                    (keys %traced));
5271
5272   my $tracefh = new Automake::XFile ("$traces $filename |");
5273   verb "reading $traces";
5274
5275   @cond_stack = ();
5276   my $where;
5277
5278   while ($_ = $tracefh->getline)
5279     {
5280       chomp;
5281       my ($here, $depth, @args) = split (/::/);
5282       $where = new Automake::Location $here;
5283       my $macro = $args[0];
5284
5285       prog_error ("unrequested trace '$macro'")
5286         unless exists $traced{$macro};
5287
5288       # Skip and diagnose malformed calls.
5289       if ($#args < $traced{$macro})
5290         {
5291           msg ('syntax', $where, "not enough arguments for $macro");
5292           next;
5293         }
5294
5295       # Alphabetical ordering please.
5296       if ($macro eq 'AC_CANONICAL_BUILD')
5297         {
5298           if ($seen_canonical <= AC_CANONICAL_BUILD)
5299             {
5300               $seen_canonical = AC_CANONICAL_BUILD;
5301             }
5302         }
5303       elsif ($macro eq 'AC_CANONICAL_HOST')
5304         {
5305           if ($seen_canonical <= AC_CANONICAL_HOST)
5306             {
5307               $seen_canonical = AC_CANONICAL_HOST;
5308             }
5309         }
5310       elsif ($macro eq 'AC_CANONICAL_TARGET')
5311         {
5312           $seen_canonical = AC_CANONICAL_TARGET;
5313         }
5314       elsif ($macro eq 'AC_CONFIG_AUX_DIR')
5315         {
5316           if ($seen_init_automake)
5317             {
5318               error ($where, "AC_CONFIG_AUX_DIR must be called before "
5319                      . "AM_INIT_AUTOMAKE ...", partial => 1);
5320               error ($seen_init_automake, "... AM_INIT_AUTOMAKE called here");
5321             }
5322           $config_aux_dir = $args[1];
5323           $config_aux_dir_set_in_configure_ac = 1;
5324           check_directory ($config_aux_dir, $where);
5325         }
5326       elsif ($macro eq 'AC_CONFIG_FILES')
5327         {
5328           # Look at potential Makefile.am's.
5329           scan_autoconf_config_files ($where, $args[1]);
5330         }
5331       elsif ($macro eq 'AC_CONFIG_HEADERS')
5332         {
5333           foreach my $spec (split (' ', $args[1]))
5334             {
5335               my ($dest, @src) = split (':', $spec);
5336               $ac_config_files_location{$dest} = $where;
5337               push @config_headers, $spec;
5338             }
5339         }
5340       elsif ($macro eq 'AC_CONFIG_LIBOBJ_DIR')
5341         {
5342           $config_libobj_dir = $args[1];
5343           check_directory ($config_libobj_dir, $where);
5344         }
5345       elsif ($macro eq 'AC_CONFIG_LINKS')
5346         {
5347           foreach my $spec (split (' ', $args[1]))
5348             {
5349               my ($dest, $src) = split (':', $spec);
5350               $ac_config_files_location{$dest} = $where;
5351               push @config_links, $spec;
5352             }
5353         }
5354       elsif ($macro eq 'AC_FC_SRCEXT')
5355         {
5356           my $suffix = $args[1];
5357           # These flags are used as %SOURCEFLAG% in depend2.am,
5358           # where the trailing space is important.
5359           $sourceflags{'.' . $suffix} = '$(FCFLAGS_' . $suffix . ') '
5360             if ($suffix eq 'f90' || $suffix eq 'f95' || $suffix eq 'f03' || $suffix eq 'f08');
5361         }
5362       elsif ($macro eq 'AC_INIT')
5363         {
5364           if (defined $args[2])
5365             {
5366               $package_version = $args[2];
5367               $package_version_location = $where;
5368             }
5369         }
5370       elsif ($macro eq 'AC_LIBSOURCE')
5371         {
5372           $libsources{$args[1]} = $here;
5373         }
5374       elsif ($macro eq 'AC_REQUIRE_AUX_FILE')
5375         {
5376           # Only remember the first time a file is required.
5377           $required_aux_file{$args[1]} = $where
5378             unless exists $required_aux_file{$args[1]};
5379         }
5380       elsif ($macro eq 'AC_SUBST_TRACE')
5381         {
5382           # Just check for alphanumeric in AC_SUBST_TRACE.  If you do
5383           # AC_SUBST(5), then too bad.
5384           $configure_vars{$args[1]} = $where
5385             if $args[1] =~ /^\w+$/;
5386         }
5387       elsif ($macro eq 'AM_AUTOMAKE_VERSION')
5388         {
5389           error ($where,
5390                  "version mismatch.  This is Automake $VERSION,\n" .
5391                  "but the definition used by this AM_INIT_AUTOMAKE\n" .
5392                  "comes from Automake $args[1].  You should recreate\n" .
5393                  "aclocal.m4 with aclocal and run automake again.\n",
5394                  # $? = 63 is used to indicate version mismatch to missing.
5395                  exit_code => 63)
5396             if $VERSION ne $args[1];
5397
5398           $seen_automake_version = 1;
5399         }
5400       elsif ($macro eq 'AM_PROG_MKDIR_P') # FIXME: to be removed in 1.13
5401         {
5402           msg 'obsolete', $where, <<'EOF';
5403 The 'AM_PROG_MKDIR_P' macro is deprecated, and will soon be removed.
5404 You should use the Autoconf-provided 'AC_PROG_MKDIR_P' macro instead,
5405 and use '$(MKDIR_P)' instead of '$(mkdir_p)'in your Makefile.am files.
5406 EOF
5407         }
5408       elsif ($macro eq 'AM_CONDITIONAL')
5409         {
5410           $configure_cond{$args[1]} = $where;
5411         }
5412       elsif ($macro eq 'AM_GNU_GETTEXT')
5413         {
5414           $seen_gettext = $where;
5415           $ac_gettext_location = $where;
5416           $seen_gettext_external = grep ($_ eq 'external', @args);
5417         }
5418       elsif ($macro eq 'AM_GNU_GETTEXT_INTL_SUBDIR')
5419         {
5420           $seen_gettext_intl = $where;
5421         }
5422       elsif ($macro eq 'AM_INIT_AUTOMAKE')
5423         {
5424           $seen_init_automake = $where;
5425           if (defined $args[2])
5426             {
5427               msg 'obsolete', $where, <<'EOF';
5428 AM_INIT_AUTOMAKE: two- and three-arguments forms are deprecated.  For more info, see:
5429 http://www.gnu.org/software/automake/manual/automake.html#Modernize-AM_INIT_AUTOMAKE-invocation
5430 EOF
5431               $package_version = $args[2];
5432               $package_version_location = $where;
5433             }
5434           elsif (defined $args[1])
5435             {
5436               my @opts = split (' ', $args[1]);
5437               @opts = map { { option => $_, where => $where } } @opts;
5438               exit $exit_code if process_global_option_list (@opts);
5439             }
5440         }
5441       elsif ($macro eq 'AM_MAINTAINER_MODE')
5442         {
5443           $seen_maint_mode = $where;
5444         }
5445       elsif ($macro eq 'AM_PROG_AR')
5446         {
5447           $seen_ar = $where;
5448         }
5449       elsif ($macro eq 'AM_PROG_CC_C_O')
5450         {
5451           $seen_cc_c_o = $where;
5452         }
5453       elsif ($macro eq 'AM_SILENT_RULES')
5454         {
5455           set_global_option ('silent-rules', $where);
5456         }
5457       elsif ($macro eq '_AM_COND_IF')
5458         {
5459           cond_stack_if ('', $args[1], $where);
5460           error ($where, "missing m4 quoting, macro depth $depth")
5461             if ($depth != 1);
5462         }
5463       elsif ($macro eq '_AM_COND_ELSE')
5464         {
5465           cond_stack_else ('!', $args[1], $where);
5466           error ($where, "missing m4 quoting, macro depth $depth")
5467             if ($depth != 1);
5468         }
5469       elsif ($macro eq '_AM_COND_ENDIF')
5470         {
5471           cond_stack_endif (undef, undef, $where);
5472           error ($where, "missing m4 quoting, macro depth $depth")
5473             if ($depth != 1);
5474         }
5475       elsif ($macro eq '_AM_SUBST_NOTMAKE')
5476         {
5477           $ignored_configure_vars{$args[1]} = $where;
5478         }
5479       elsif ($macro eq 'm4_include'
5480              || $macro eq 'm4_sinclude'
5481              || $macro eq 'sinclude')
5482         {
5483           # Skip missing 'sinclude'd files.
5484           next if $macro ne 'm4_include' && ! -f $args[1];
5485
5486           # Some modified versions of Autoconf don't use
5487           # frozen files.  Consequently it's possible that we see all
5488           # m4_include's performed during Autoconf's startup.
5489           # Obviously we don't want to distribute Autoconf's files
5490           # so we skip absolute filenames here.
5491           push @configure_deps, '$(top_srcdir)/' . $args[1]
5492             unless $here =~ m,^(?:\w:)?[\\/],;
5493           # Keep track of the greatest timestamp.
5494           if (-e $args[1])
5495             {
5496               my $mtime = mtime $args[1];
5497               $configure_deps_greatest_timestamp = $mtime
5498                 if $mtime > $configure_deps_greatest_timestamp;
5499             }
5500         }
5501       elsif ($macro eq 'LT_SUPPORTED_TAG')
5502         {
5503           $libtool_tags{$args[1]} = 1;
5504           $libtool_new_api = 1;
5505         }
5506       elsif ($macro eq '_LT_AC_TAGCONFIG')
5507         {
5508           # _LT_AC_TAGCONFIG is an old macro present in Libtool 1.5.
5509           # We use it to detect whether tags are supported.  Our
5510           # preferred interface is LT_SUPPORTED_TAG, but it was
5511           # introduced in Libtool 1.6.
5512           if (0 == keys %libtool_tags)
5513             {
5514               # Hardcode the tags supported by Libtool 1.5.
5515               %libtool_tags = (CC => 1, CXX => 1, GCJ => 1, F77 => 1);
5516             }
5517         }
5518     }
5519
5520   error ($where, "condition stack not properly closed")
5521     if (@cond_stack);
5522
5523   $tracefh->close;
5524 }
5525
5526
5527 # &scan_autoconf_files ()
5528 # -----------------------
5529 # Check whether we use 'configure.ac' or 'configure.in'.
5530 # Scan it (and possibly 'aclocal.m4') for interesting things.
5531 # We must scan aclocal.m4 because there might be AC_SUBSTs and such there.
5532 sub scan_autoconf_files ()
5533 {
5534   # Reinitialize libsources here.  This isn't really necessary,
5535   # since we currently assume there is only one configure.ac.  But
5536   # that won't always be the case.
5537   %libsources = ();
5538
5539   # Keep track of the youngest configure dependency.
5540   $configure_deps_greatest_timestamp = mtime $configure_ac;
5541   if (-e 'aclocal.m4')
5542     {
5543       my $mtime = mtime 'aclocal.m4';
5544       $configure_deps_greatest_timestamp = $mtime
5545         if $mtime > $configure_deps_greatest_timestamp;
5546     }
5547
5548   scan_autoconf_traces ($configure_ac);
5549
5550   @configure_input_files = sort keys %make_list;
5551   # Set input and output files if not specified by user.
5552   if (! @input_files)
5553     {
5554       @input_files = @configure_input_files;
5555       %output_files = %make_list;
5556     }
5557
5558
5559   if (! $seen_init_automake)
5560     {
5561       err_ac ("no proper invocation of AM_INIT_AUTOMAKE was found.\nYou "
5562               . "should verify that $configure_ac invokes AM_INIT_AUTOMAKE,"
5563               . "\nthat aclocal.m4 is present in the top-level directory,\n"
5564               . "and that aclocal.m4 was recently regenerated "
5565               . "(using aclocal)");
5566     }
5567   else
5568     {
5569       if (! $seen_automake_version)
5570         {
5571           if (-f 'aclocal.m4')
5572             {
5573               error ($seen_init_automake,
5574                      "your implementation of AM_INIT_AUTOMAKE comes from " .
5575                      "an\nold Automake version.  You should recreate " .
5576                      "aclocal.m4\nwith aclocal and run automake again",
5577                      # $? = 63 is used to indicate version mismatch to missing.
5578                      exit_code => 63);
5579             }
5580           else
5581             {
5582               error ($seen_init_automake,
5583                      "no proper implementation of AM_INIT_AUTOMAKE was " .
5584                      "found,\nprobably because aclocal.m4 is missing.\n" .
5585                      "You should run aclocal to create this file, then\n" .
5586                      "run automake again");
5587             }
5588         }
5589     }
5590
5591   locate_aux_dir ();
5592
5593   # Look for some files we need.  Always check for these.  This
5594   # check must be done for every run, even those where we are only
5595   # looking at a subdir Makefile.  We must set relative_dir for
5596   # push_required_file to work.
5597   # Sort the files for stable verbose output.
5598   $relative_dir = '.';
5599   foreach my $file (sort keys %required_aux_file)
5600     {
5601       require_conf_file ($required_aux_file{$file}->get, FOREIGN, $file)
5602     }
5603   err_am "'install.sh' is an anachronism; use 'install-sh' instead"
5604     if -f $config_aux_dir . '/install.sh';
5605
5606   # Preserve dist_common for later.
5607   $configure_dist_common = variable_value ('DIST_COMMON') || '';
5608
5609 }
5610
5611 ################################################################
5612
5613 # Set up for Cygnus mode.
5614 sub check_cygnus
5615 {
5616   my $cygnus = option 'cygnus';
5617   return unless $cygnus;
5618
5619   # This feature is deprecated, will be removed in the next
5620   # Automake major release.
5621   msg 'obsolete', $cygnus->get,
5622       "support for Cygnus-style trees is deprecated";
5623
5624   set_strictness ('foreign');
5625   set_option ('no-installinfo', $cygnus);
5626   set_option ('no-dependencies', $cygnus);
5627   set_option ('no-dist', $cygnus);
5628
5629   err_ac "'AM_MAINTAINER_MODE' required when --cygnus specified"
5630     if !$seen_maint_mode;
5631 }
5632
5633 # Do any extra checking for GNU standards.
5634 sub check_gnu_standards
5635 {
5636   if ($relative_dir eq '.')
5637     {
5638       # In top level (or only) directory.
5639       require_file ("$am_file.am", GNU,
5640                     qw/INSTALL NEWS README AUTHORS ChangeLog/);
5641
5642       # Accept one of these three licenses; default to COPYING.
5643       # Make sure we do not overwrite an existing license.
5644       my $license;
5645       foreach (qw /COPYING COPYING.LIB COPYING.LESSER/)
5646         {
5647           if (-f $_)
5648             {
5649               $license = $_;
5650               last;
5651             }
5652         }
5653       require_file ("$am_file.am", GNU, 'COPYING')
5654         unless $license;
5655     }
5656
5657   for my $opt ('no-installman', 'no-installinfo')
5658     {
5659       msg ('error-gnu', option $opt,
5660            "option '$opt' disallowed by GNU standards")
5661         if option $opt;
5662     }
5663 }
5664
5665 # Do any extra checking for GNITS standards.
5666 sub check_gnits_standards
5667 {
5668   if ($relative_dir eq '.')
5669     {
5670       # In top level (or only) directory.
5671       require_file ("$am_file.am", GNITS, 'THANKS');
5672     }
5673 }
5674
5675 ################################################################
5676 #
5677 # Functions to handle files of each language.
5678
5679 # Each 'lang_X_rewrite($DIRECTORY, $BASE, $EXT)' function follows a
5680 # simple formula: Return value is LANG_SUBDIR if the resulting object
5681 # file should be in a subdir if the source file is, LANG_PROCESS if
5682 # file is to be dealt with, LANG_IGNORE otherwise.
5683
5684 # Much of the actual processing is handled in
5685 # handle_single_transform.  These functions exist so that
5686 # auxiliary information can be recorded for a later cleanup pass.
5687 # Note that the calls to these functions are computed, so don't bother
5688 # searching for their precise names in the source.
5689
5690 # This is just a convenience function that can be used to determine
5691 # when a subdir object should be used.
5692 sub lang_sub_obj
5693 {
5694     return option 'subdir-objects' ? LANG_SUBDIR : LANG_PROCESS;
5695 }
5696
5697 # Rewrite a single C source file.
5698 sub lang_c_rewrite
5699 {
5700   my ($directory, $base, $ext, $obj, $have_per_exec_flags, $var) = @_;
5701
5702   my $r = LANG_PROCESS;
5703   if (option 'subdir-objects')
5704     {
5705       $r = LANG_SUBDIR;
5706       if ($directory && $directory ne '.')
5707         {
5708           $base = $directory . '/' . $base;
5709
5710           # libtool is always able to put the object at the proper place,
5711           # so we do not have to require AM_PROG_CC_C_O when building .lo files.
5712           msg_var ('portability', $var,
5713                    "compiling '$base.c' in subdir requires "
5714                    . "'AM_PROG_CC_C_O' in '$configure_ac'",
5715                    uniq_scope => US_GLOBAL,
5716                    uniq_part => 'AM_PROG_CC_C_O subdir')
5717             unless $seen_cc_c_o || $obj eq '.lo';
5718         }
5719     }
5720
5721   if (! $seen_cc_c_o
5722       && $have_per_exec_flags
5723       && ! option 'subdir-objects'
5724       && $obj ne '.lo')
5725     {
5726       msg_var ('portability',
5727                $var, "compiling '$base.c' with per-target flags requires "
5728                . "'AM_PROG_CC_C_O' in '$configure_ac'",
5729                uniq_scope => US_GLOBAL,
5730                uniq_part => 'AM_PROG_CC_C_O per-target')
5731     }
5732
5733     return $r;
5734 }
5735
5736 # Rewrite a single C++ source file.
5737 sub lang_cxx_rewrite
5738 {
5739     return &lang_sub_obj;
5740 }
5741
5742 # Rewrite a single header file.
5743 sub lang_header_rewrite
5744 {
5745     # Header files are simply ignored.
5746     return LANG_IGNORE;
5747 }
5748
5749 # Rewrite a single Vala source file.
5750 sub lang_vala_rewrite
5751 {
5752     my ($directory, $base, $ext) = @_;
5753
5754     (my $newext = $ext) =~ s/vala$/c/;
5755     return (LANG_SUBDIR, $newext);
5756 }
5757
5758 # Rewrite a single yacc file.
5759 sub lang_yacc_rewrite
5760 {
5761     my ($directory, $base, $ext) = @_;
5762
5763     my $r = &lang_sub_obj;
5764     (my $newext = $ext) =~ tr/y/c/;
5765     return ($r, $newext);
5766 }
5767
5768 # Rewrite a single yacc++ file.
5769 sub lang_yaccxx_rewrite
5770 {
5771     my ($directory, $base, $ext) = @_;
5772
5773     my $r = &lang_sub_obj;
5774     (my $newext = $ext) =~ tr/y/c/;
5775     return ($r, $newext);
5776 }
5777
5778 # Rewrite a single lex file.
5779 sub lang_lex_rewrite
5780 {
5781     my ($directory, $base, $ext) = @_;
5782
5783     my $r = &lang_sub_obj;
5784     (my $newext = $ext) =~ tr/l/c/;
5785     return ($r, $newext);
5786 }
5787
5788 # Rewrite a single lex++ file.
5789 sub lang_lexxx_rewrite
5790 {
5791     my ($directory, $base, $ext) = @_;
5792
5793     my $r = &lang_sub_obj;
5794     (my $newext = $ext) =~ tr/l/c/;
5795     return ($r, $newext);
5796 }
5797
5798 # Rewrite a single assembly file.
5799 sub lang_asm_rewrite
5800 {
5801     return &lang_sub_obj;
5802 }
5803
5804 # Rewrite a single preprocessed assembly file.
5805 sub lang_cppasm_rewrite
5806 {
5807     return &lang_sub_obj;
5808 }
5809
5810 # Rewrite a single Fortran 77 file.
5811 sub lang_f77_rewrite
5812 {
5813     return &lang_sub_obj;
5814 }
5815
5816 # Rewrite a single Fortran file.
5817 sub lang_fc_rewrite
5818 {
5819     return &lang_sub_obj;
5820 }
5821
5822 # Rewrite a single preprocessed Fortran file.
5823 sub lang_ppfc_rewrite
5824 {
5825     return &lang_sub_obj;
5826 }
5827
5828 # Rewrite a single preprocessed Fortran 77 file.
5829 sub lang_ppf77_rewrite
5830 {
5831     return &lang_sub_obj;
5832 }
5833
5834 # Rewrite a single ratfor file.
5835 sub lang_ratfor_rewrite
5836 {
5837     return &lang_sub_obj;
5838 }
5839
5840 # Rewrite a single Objective C file.
5841 sub lang_objc_rewrite
5842 {
5843     return &lang_sub_obj;
5844 }
5845
5846 # Rewrite a single Objective C++ file.
5847 sub lang_objcxx_rewrite
5848 {
5849     return &lang_sub_obj;
5850 }
5851
5852 # Rewrite a single Unified Parallel C file.
5853 sub lang_upc_rewrite
5854 {
5855     return &lang_sub_obj;
5856 }
5857
5858 # Rewrite a single Java file.
5859 sub lang_java_rewrite
5860 {
5861     return LANG_SUBDIR;
5862 }
5863
5864 # The lang_X_finish functions are called after all source file
5865 # processing is done.  Each should handle defining rules for the
5866 # language, etc.  A finish function is only called if a source file of
5867 # the appropriate type has been seen.
5868
5869 sub lang_vala_finish_target ($$)
5870 {
5871   my ($self, $name) = @_;
5872
5873   my $derived = canonicalize ($name);
5874   my $var = var "${derived}_SOURCES";
5875   return unless $var;
5876
5877   my @vala_sources = grep { /\.(vala|vapi)$/ } ($var->value_as_list_recursive);
5878
5879   # For automake bug#11229.
5880   return unless @vala_sources;
5881
5882   foreach my $vala_file (@vala_sources)
5883     {
5884       my $c_file = $vala_file;
5885       if ($c_file =~ s/(.*)\.vala$/$1.c/)
5886         {
5887           $c_file = "\$(srcdir)/$c_file";
5888           $output_rules .= "$c_file: \$(srcdir)/${derived}_vala.stamp\n"
5889             . "\t\@if test -f \$@; then :; else rm -f \$(srcdir)/${derived}_vala.stamp; fi\n"
5890             . "\t\@if test -f \$@; then :; else \\\n"
5891             . "\t  \$(MAKE) \$(AM_MAKEFLAGS) \$(srcdir)/${derived}_vala.stamp; \\\n"
5892             . "\tfi\n";
5893           $clean_files{$c_file} = MAINTAINER_CLEAN;
5894         }
5895     }
5896
5897   # Add rebuild rules for generated header and vapi files
5898   my $flags = var ($derived . '_VALAFLAGS');
5899   if ($flags)
5900     {
5901       my $lastflag = '';
5902       foreach my $flag ($flags->value_as_list_recursive)
5903         {
5904           if (grep (/$lastflag/, ('-H', '-h', '--header', '--internal-header',
5905                                   '--vapi', '--internal-vapi', '--gir')))
5906             {
5907               my $headerfile = "\$(srcdir)/$flag";
5908               $output_rules .= "$headerfile: \$(srcdir)/${derived}_vala.stamp\n"
5909                 . "\t\@if test -f \$@; then :; else rm -f \$(srcdir)/${derived}_vala.stamp; fi\n"
5910                 . "\t\@if test -f \$@; then :; else \\\n"
5911                 . "\t  \$(MAKE) \$(AM_MAKEFLAGS) \$(srcdir)/${derived}_vala.stamp; \\\n"
5912                 . "\tfi\n";
5913
5914               # valac is not used when building from dist tarballs
5915               # distribute the generated files
5916               push_dist_common ($headerfile);
5917               $clean_files{$headerfile} = MAINTAINER_CLEAN;
5918             }
5919           $lastflag = $flag;
5920         }
5921     }
5922
5923   my $compile = $self->compile;
5924
5925   # Rewrite each occurrence of 'AM_VALAFLAGS' in the compile
5926   # rule into '${derived}_VALAFLAGS' if it exists.
5927   my $val = "${derived}_VALAFLAGS";
5928   $compile =~ s/\(AM_VALAFLAGS\)/\($val\)/
5929     if set_seen ($val);
5930
5931   # VALAFLAGS is a user variable (per GNU Standards),
5932   # it should not be overridden in the Makefile...
5933   check_user_variables 'VALAFLAGS';
5934
5935   my $dirname = dirname ($name);
5936
5937   # Only generate C code, do not run C compiler
5938   $compile .= " -C";
5939
5940   my $verbose = verbose_flag ('VALAC');
5941   my $silent = silent_flag ();
5942   my $stampfile = "\$(srcdir)/${derived}_vala.stamp";
5943
5944   $output_rules .=
5945     "\$(srcdir)/${derived}_vala.stamp: @vala_sources\n".
5946 # Since the C files generated from the vala sources depend on the
5947 # ${derived}_vala.stamp file, we must ensure its timestamp is older than
5948 # those of the C files generated by the valac invocation below (this is
5949 # especially important on systems with sub-second timestamp resolution).
5950 # Thus we need to create the stamp file *before* invoking valac, and to
5951 # move it to its final location only after valac has been invoked.
5952     "\t${silent}rm -f \$\@ && echo stamp > \$\@-t\n".
5953     "\t${verbose}\$(am__cd) \$(srcdir) && $compile @vala_sources\n".
5954     "\t${silent}mv -f \$\@-t \$\@\n";
5955
5956   push_dist_common ($stampfile);
5957
5958   $clean_files{$stampfile} = MAINTAINER_CLEAN;
5959 }
5960
5961 # Add output rules to invoke valac and create stamp file as a witness
5962 # to handle multiple outputs. This function is called after all source
5963 # file processing is done.
5964 sub lang_vala_finish
5965 {
5966   my ($self) = @_;
5967
5968   foreach my $prog (keys %known_programs)
5969     {
5970       lang_vala_finish_target ($self, $prog);
5971     }
5972
5973   while (my ($name) = each %known_libraries)
5974     {
5975       lang_vala_finish_target ($self, $name);
5976     }
5977 }
5978
5979 # The built .c files should be cleaned only on maintainer-clean
5980 # as the .c files are distributed. This function is called for each
5981 # .vala source file.
5982 sub lang_vala_target_hook
5983 {
5984   my ($self, $aggregate, $output, $input, %transform) = @_;
5985
5986   $clean_files{$output} = MAINTAINER_CLEAN;
5987 }
5988
5989 # This is a yacc helper which is called whenever we have decided to
5990 # compile a yacc file.
5991 sub lang_yacc_target_hook
5992 {
5993     my ($self, $aggregate, $output, $input, %transform) = @_;
5994
5995     # If some relevant *YFLAGS variable contains the '-d' flag, we'll
5996     # have to to generate special code.
5997     my $yflags_contains_minus_d = 0;
5998
5999     foreach my $pfx ("", "${aggregate}_")
6000       {
6001         my $yflagsvar = var ("${pfx}YFLAGS");
6002         next unless $yflagsvar;
6003         # We cannot work reliably with conditionally-defined YFLAGS.
6004         if ($yflagsvar->has_conditional_contents)
6005           {
6006             msg_var ('unsupported', $yflagsvar,
6007                      "'${pfx}YFLAGS' cannot have conditional contents");
6008           }
6009         else
6010           {
6011             $yflags_contains_minus_d = 1
6012               if grep (/^-d$/, $yflagsvar->value_as_list_recursive);
6013           }
6014       }
6015
6016     if ($yflags_contains_minus_d)
6017       {
6018         # Found a '-d' that applies to the compilation of this file.
6019         # Add a dependency for the generated header file, and arrange
6020         # for that file to be included in the distribution.
6021
6022         # The extension of the output file (e.g., '.c' or '.cxx').
6023         # We'll need it to compute the name of the generated header file.
6024         (my $output_ext = basename ($output)) =~ s/.*(\.[^.]+)$/$1/;
6025
6026         # We know that a yacc input should be turned into either a C or
6027         # C++ output file.  We depend on this fact (here and in yacc.am),
6028         # so check that it really holds.
6029         my $lang = $languages{$extension_map{$output_ext}};
6030         prog_error "invalid output name '$output' for yacc file '$input'"
6031           if (!$lang || ($lang->name ne 'c' && $lang->name ne 'cxx'));
6032
6033         (my $header_ext = $output_ext) =~ s/c/h/g;
6034         # Quote $output_ext in the regexp, so that dots in it are taken
6035         # as literal dots, not as metacharacters.
6036         (my $header = $output) =~ s/\Q$output_ext\E$/$header_ext/;
6037
6038         foreach my $cond (Automake::Rule::define (${header}, 'internal',
6039                                                   RULE_AUTOMAKE, TRUE,
6040                                                   INTERNAL))
6041           {
6042             my $condstr = $cond->subst_string;
6043             $output_rules .=
6044               "$condstr${header}: $output\n"
6045               # Recover from removal of $header
6046               . "$condstr\t\@if test ! -f \$@; then rm -f $output; else :; fi\n"
6047               . "$condstr\t\@if test ! -f \$@; then \$(MAKE) \$(AM_MAKEFLAGS) $output; else :; fi\n";
6048           }
6049         # Distribute the generated file, unless its .y source was
6050         # listed in a nodist_ variable.  (&handle_source_transform
6051         # will set DIST_SOURCE.)
6052         &push_dist_common ($header)
6053           if $transform{'DIST_SOURCE'};
6054
6055         # The GNU rules say that yacc/lex output files should be removed
6056         # by maintainer-clean.  However, if the files are not distributed,
6057         # then we want to remove them with "make clean"; otherwise,
6058         # "make distcheck" will fail.
6059         $clean_files{$header} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
6060       }
6061     # See the comment above for $HEADER.
6062     $clean_files{$output} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
6063 }
6064
6065 # This is a lex helper which is called whenever we have decided to
6066 # compile a lex file.
6067 sub lang_lex_target_hook
6068 {
6069     my ($self, $aggregate, $output, $input, %transform) = @_;
6070     # The GNU rules say that yacc/lex output files should be removed
6071     # by maintainer-clean.  However, if the files are not distributed,
6072     # then we want to remove them with "make clean"; otherwise,
6073     # "make distcheck" will fail.
6074     $clean_files{$output} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
6075 }
6076
6077 # This is a helper for both lex and yacc.
6078 sub yacc_lex_finish_helper
6079 {
6080   return if defined $language_scratch{'lex-yacc-done'};
6081   $language_scratch{'lex-yacc-done'} = 1;
6082
6083   # FIXME: for now, no line number.
6084   require_conf_file ($configure_ac, FOREIGN, 'ylwrap');
6085   &define_variable ('YLWRAP', "$am_config_aux_dir/ylwrap", INTERNAL);
6086 }
6087
6088 sub lang_yacc_finish
6089 {
6090   return if defined $language_scratch{'yacc-done'};
6091   $language_scratch{'yacc-done'} = 1;
6092
6093   reject_var 'YACCFLAGS', "'YACCFLAGS' obsolete; use 'YFLAGS' instead";
6094
6095   yacc_lex_finish_helper;
6096 }
6097
6098
6099 sub lang_lex_finish
6100 {
6101   return if defined $language_scratch{'lex-done'};
6102   $language_scratch{'lex-done'} = 1;
6103
6104   yacc_lex_finish_helper;
6105 }
6106
6107
6108 # Given a hash table of linker names, pick the name that has the most
6109 # precedence.  This is lame, but something has to have global
6110 # knowledge in order to eliminate the conflict.  Add more linkers as
6111 # required.
6112 sub resolve_linker
6113 {
6114     my (%linkers) = @_;
6115
6116     foreach my $l (qw(GCJLINK OBJCXXLINK CXXLINK F77LINK FCLINK OBJCLINK UPCLINK))
6117     {
6118         return $l if defined $linkers{$l};
6119     }
6120     return 'LINK';
6121 }
6122
6123 # Called to indicate that an extension was used.
6124 sub saw_extension
6125 {
6126     my ($ext) = @_;
6127     if (! defined $extension_seen{$ext})
6128     {
6129         $extension_seen{$ext} = 1;
6130     }
6131     else
6132     {
6133         ++$extension_seen{$ext};
6134     }
6135 }
6136
6137 # Return the number of files seen for a given language.  Knows about
6138 # special cases we care about.  FIXME: this is hideous.  We need
6139 # something that involves real language objects.  For instance yacc
6140 # and yaccxx could both derive from a common yacc class which would
6141 # know about the strange ylwrap requirement.  (Or better yet we could
6142 # just not support legacy yacc!)
6143 sub count_files_for_language
6144 {
6145     my ($name) = @_;
6146
6147     my @names;
6148     if ($name eq 'yacc' || $name eq 'yaccxx')
6149     {
6150         @names = ('yacc', 'yaccxx');
6151     }
6152     elsif ($name eq 'lex' || $name eq 'lexxx')
6153     {
6154         @names = ('lex', 'lexxx');
6155     }
6156     else
6157     {
6158         @names = ($name);
6159     }
6160
6161     my $r = 0;
6162     foreach $name (@names)
6163     {
6164         my $lang = $languages{$name};
6165         foreach my $ext (@{$lang->extensions})
6166         {
6167             $r += $extension_seen{$ext}
6168                 if defined $extension_seen{$ext};
6169         }
6170     }
6171
6172     return $r
6173 }
6174
6175 # Called to ask whether source files have been seen . If HEADERS is 1,
6176 # headers can be included.
6177 sub saw_sources_p
6178 {
6179     my ($headers) = @_;
6180
6181     # count all the sources
6182     my $count = 0;
6183     foreach my $val (values %extension_seen)
6184     {
6185         $count += $val;
6186     }
6187
6188     if (!$headers)
6189     {
6190         $count -= count_files_for_language ('header');
6191     }
6192
6193     return $count > 0;
6194 }
6195
6196
6197 # register_language (%ATTRIBUTE)
6198 # ------------------------------
6199 # Register a single language.
6200 # Each %ATTRIBUTE is of the form ATTRIBUTE => VALUE.
6201 sub register_language (%)
6202 {
6203   my (%option) = @_;
6204
6205   # Set the defaults.
6206   $option{'autodep'} = 'no'
6207     unless defined $option{'autodep'};
6208   $option{'linker'} = ''
6209     unless defined $option{'linker'};
6210   $option{'flags'} = []
6211     unless defined $option{'flags'};
6212   $option{'output_extensions'} = sub { return ( '.$(OBJEXT)', '.lo' ) }
6213     unless defined $option{'output_extensions'};
6214   $option{'nodist_specific'} = 0
6215     unless defined $option{'nodist_specific'};
6216
6217   my $lang = new Language (%option);
6218
6219   # Fill indexes.
6220   $extension_map{$_} = $lang->name foreach @{$lang->extensions};
6221   $languages{$lang->name} = $lang;
6222   my $link = $lang->linker;
6223   if ($link)
6224     {
6225       if (exists $link_languages{$link})
6226         {
6227           prog_error ("'$link' has different definitions in "
6228                       . $lang->name . " and " . $link_languages{$link}->name)
6229             if $lang->link ne $link_languages{$link}->link;
6230         }
6231       else
6232         {
6233           $link_languages{$link} = $lang;
6234         }
6235     }
6236
6237   # Update the pattern of known extensions.
6238   accept_extensions (@{$lang->extensions});
6239
6240   # Upate the $suffix_rule map.
6241   foreach my $suffix (@{$lang->extensions})
6242     {
6243       foreach my $dest (&{$lang->output_extensions} ($suffix))
6244         {
6245           register_suffix_rule (INTERNAL, $suffix, $dest);
6246         }
6247     }
6248 }
6249
6250 # derive_suffix ($EXT, $OBJ)
6251 # --------------------------
6252 # This function is used to find a path from a user-specified suffix $EXT
6253 # to $OBJ or to some other suffix we recognize internally, e.g. 'cc'.
6254 sub derive_suffix ($$)
6255 {
6256   my ($source_ext, $obj) = @_;
6257
6258   while (! $extension_map{$source_ext}
6259          && $source_ext ne $obj
6260          && exists $suffix_rules->{$source_ext}
6261          && exists $suffix_rules->{$source_ext}{$obj})
6262     {
6263       $source_ext = $suffix_rules->{$source_ext}{$obj}[0];
6264     }
6265
6266   return $source_ext;
6267 }
6268
6269
6270 ################################################################
6271
6272 # Pretty-print something and append to output_rules.
6273 sub pretty_print_rule
6274 {
6275     $output_rules .= &makefile_wrap (@_);
6276 }
6277
6278
6279 ################################################################
6280
6281
6282 ## -------------------------------- ##
6283 ## Handling the conditional stack.  ##
6284 ## -------------------------------- ##
6285
6286
6287 # $STRING
6288 # make_conditional_string ($NEGATE, $COND)
6289 # ----------------------------------------
6290 sub make_conditional_string ($$)
6291 {
6292   my ($negate, $cond) = @_;
6293   $cond = "${cond}_TRUE"
6294     unless $cond =~ /^TRUE|FALSE$/;
6295   $cond = Automake::Condition::conditional_negate ($cond)
6296     if $negate;
6297   return $cond;
6298 }
6299
6300
6301 my %_am_macro_for_cond =
6302   (
6303   AMDEP => "one of the compiler tests\n"
6304            . "    AC_PROG_CC, AC_PROG_CXX, AC_PROG_OBJC, AC_PROG_OBJCXX,\n"
6305            . "    AM_PROG_AS, AM_PROG_GCJ, AM_PROG_UPC",
6306   am__fastdepCC => 'AC_PROG_CC',
6307   am__fastdepCCAS => 'AM_PROG_AS',
6308   am__fastdepCXX => 'AC_PROG_CXX',
6309   am__fastdepGCJ => 'AM_PROG_GCJ',
6310   am__fastdepOBJC => 'AC_PROG_OBJC',
6311   am__fastdepOBJCXX => 'AC_PROG_OBJCXX',
6312   am__fastdepUPC => 'AM_PROG_UPC'
6313   );
6314
6315 # $COND
6316 # cond_stack_if ($NEGATE, $COND, $WHERE)
6317 # --------------------------------------
6318 sub cond_stack_if ($$$)
6319 {
6320   my ($negate, $cond, $where) = @_;
6321
6322   if (! $configure_cond{$cond} && $cond !~ /^TRUE|FALSE$/)
6323     {
6324       my $text = "$cond does not appear in AM_CONDITIONAL";
6325       my $scope = US_LOCAL;
6326       if (exists $_am_macro_for_cond{$cond})
6327         {
6328           my $mac = $_am_macro_for_cond{$cond};
6329           $text .= "\n  The usual way to define '$cond' is to add ";
6330           $text .= ($mac =~ / /) ? $mac : "'$mac'";
6331           $text .= "\n  to '$configure_ac' and run 'aclocal' and 'autoconf' again";
6332           # These warnings appear in Automake files (depend2.am),
6333           # so there is no need to display them more than once:
6334           $scope = US_GLOBAL;
6335         }
6336       error $where, $text, uniq_scope => $scope;
6337     }
6338
6339   push (@cond_stack, make_conditional_string ($negate, $cond));
6340
6341   return new Automake::Condition (@cond_stack);
6342 }
6343
6344
6345 # $COND
6346 # cond_stack_else ($NEGATE, $COND, $WHERE)
6347 # ----------------------------------------
6348 sub cond_stack_else ($$$)
6349 {
6350   my ($negate, $cond, $where) = @_;
6351
6352   if (! @cond_stack)
6353     {
6354       error $where, "else without if";
6355       return FALSE;
6356     }
6357
6358   $cond_stack[$#cond_stack] =
6359     Automake::Condition::conditional_negate ($cond_stack[$#cond_stack]);
6360
6361   # If $COND is given, check against it.
6362   if (defined $cond)
6363     {
6364       $cond = make_conditional_string ($negate, $cond);
6365
6366       error ($where, "else reminder ($negate$cond) incompatible with "
6367              . "current conditional: $cond_stack[$#cond_stack]")
6368         if $cond_stack[$#cond_stack] ne $cond;
6369     }
6370
6371   return new Automake::Condition (@cond_stack);
6372 }
6373
6374
6375 # $COND
6376 # cond_stack_endif ($NEGATE, $COND, $WHERE)
6377 # -----------------------------------------
6378 sub cond_stack_endif ($$$)
6379 {
6380   my ($negate, $cond, $where) = @_;
6381   my $old_cond;
6382
6383   if (! @cond_stack)
6384     {
6385       error $where, "endif without if";
6386       return TRUE;
6387     }
6388
6389   # If $COND is given, check against it.
6390   if (defined $cond)
6391     {
6392       $cond = make_conditional_string ($negate, $cond);
6393
6394       error ($where, "endif reminder ($negate$cond) incompatible with "
6395              . "current conditional: $cond_stack[$#cond_stack]")
6396         if $cond_stack[$#cond_stack] ne $cond;
6397     }
6398
6399   pop @cond_stack;
6400
6401   return new Automake::Condition (@cond_stack);
6402 }
6403
6404
6405
6406
6407
6408 ## ------------------------ ##
6409 ## Handling the variables.  ##
6410 ## ------------------------ ##
6411
6412
6413 # &define_pretty_variable ($VAR, $COND, $WHERE, @VALUE)
6414 # -----------------------------------------------------
6415 # Like define_variable, but the value is a list, and the variable may
6416 # be defined conditionally.  The second argument is the condition
6417 # under which the value should be defined; this should be the empty
6418 # string to define the variable unconditionally.  The third argument
6419 # is a list holding the values to use for the variable.  The value is
6420 # pretty printed in the output file.
6421 sub define_pretty_variable ($$$@)
6422 {
6423     my ($var, $cond, $where, @value) = @_;
6424
6425     if (! vardef ($var, $cond))
6426     {
6427         Automake::Variable::define ($var, VAR_AUTOMAKE, '', $cond, "@value",
6428                                     '', $where, VAR_PRETTY);
6429         rvar ($var)->rdef ($cond)->set_seen;
6430     }
6431 }
6432
6433
6434 # define_variable ($VAR, $VALUE, $WHERE)
6435 # --------------------------------------
6436 # Define a new Automake Makefile variable VAR to VALUE, but only if
6437 # not already defined.
6438 sub define_variable ($$$)
6439 {
6440     my ($var, $value, $where) = @_;
6441     define_pretty_variable ($var, TRUE, $where, $value);
6442 }
6443
6444
6445 # define_files_variable ($VAR, \@BASENAME, $EXTENSION, $WHERE)
6446 # ------------------------------------------------------------
6447 # Define the $VAR which content is the list of file names composed of
6448 # a @BASENAME and the $EXTENSION.
6449 sub define_files_variable ($\@$$)
6450 {
6451   my ($var, $basename, $extension, $where) = @_;
6452   define_variable ($var,
6453                    join (' ', map { "$_.$extension" } @$basename),
6454                    $where);
6455 }
6456
6457
6458 # Like define_variable, but define a variable to be the configure
6459 # substitution by the same name.
6460 sub define_configure_variable ($)
6461 {
6462   my ($var) = @_;
6463   # Some variables we do not want to output.  For instance it
6464   # would be a bad idea to output `U = @U@` when `@U@` can be
6465   # substituted as `\`.
6466   my $pretty = exists $ignored_configure_vars{$var} ? VAR_SILENT : VAR_ASIS;
6467   Automake::Variable::define ($var, VAR_CONFIGURE, '', TRUE, subst $var,
6468                               '', $configure_vars{$var}, $pretty);
6469 }
6470
6471
6472 # define_compiler_variable ($LANG)
6473 # --------------------------------
6474 # Define a compiler variable.  We also handle defining the 'LT'
6475 # version of the command when using libtool.
6476 sub define_compiler_variable ($)
6477 {
6478     my ($lang) = @_;
6479
6480     my ($var, $value) = ($lang->compiler, $lang->compile);
6481     my $libtool_tag = '';
6482     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6483       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6484     &define_variable ($var, $value, INTERNAL);
6485     if (var ('LIBTOOL'))
6486       {
6487         my $verbose = define_verbose_libtool ();
6488         &define_variable ("LT$var",
6489                           "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) "
6490                           . "\$(LIBTOOLFLAGS) --mode=compile $value",
6491                           INTERNAL);
6492       }
6493     define_verbose_tagvar ($lang->ccer || 'GEN');
6494 }
6495
6496
6497 # define_linker_variable ($LANG)
6498 # ------------------------------
6499 # Define linker variables.
6500 sub define_linker_variable ($)
6501 {
6502     my ($lang) = @_;
6503
6504     my $libtool_tag = '';
6505     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6506       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6507     # CCLD = $(CC).
6508     &define_variable ($lang->lder, $lang->ld, INTERNAL);
6509     # CCLINK = $(CCLD) blah blah...
6510     my $link = '';
6511     if (var ('LIBTOOL'))
6512       {
6513         my $verbose = define_verbose_libtool ();
6514         $link = "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) "
6515                 . "\$(LIBTOOLFLAGS) --mode=link ";
6516       }
6517     &define_variable ($lang->linker, $link . $lang->link, INTERNAL);
6518     &define_variable ($lang->compiler,  $lang);
6519     &define_verbose_tagvar ($lang->lder || 'GEN');
6520 }
6521
6522 sub define_per_target_linker_variable ($$)
6523 {
6524   my ($linker, $target) = @_;
6525
6526   # If the user wrote a custom link command, we don't define ours.
6527   return "${target}_LINK"
6528     if set_seen "${target}_LINK";
6529
6530   my $xlink = $linker ? $linker : 'LINK';
6531
6532   my $lang = $link_languages{$xlink};
6533   prog_error "Unknown language for linker variable '$xlink'"
6534     unless $lang;
6535
6536   my $link_command = $lang->link;
6537   if (var 'LIBTOOL')
6538     {
6539       my $libtool_tag = '';
6540       $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6541         if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6542
6543       my $verbose = define_verbose_libtool ();
6544       $link_command =
6545         "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) \$(LIBTOOLFLAGS) "
6546         . "--mode=link " . $link_command;
6547     }
6548
6549   # Rewrite each occurrence of 'AM_$flag' in the link
6550   # command into '${derived}_$flag' if it exists.
6551   my $orig_command = $link_command;
6552   my @flags = (@{$lang->flags}, 'LDFLAGS');
6553   push @flags, 'LIBTOOLFLAGS' if var 'LIBTOOL';
6554   for my $flag (@flags)
6555     {
6556       my $val = "${target}_$flag";
6557       $link_command =~ s/\(AM_$flag\)/\($val\)/
6558         if set_seen ($val);
6559     }
6560
6561   # If the computed command is the same as the generic command, use
6562   # the command linker variable.
6563   return ($lang->linker, $lang->lder)
6564     if $link_command eq $orig_command;
6565
6566   &define_variable ("${target}_LINK", $link_command, INTERNAL);
6567   return ("${target}_LINK", $lang->lder);
6568 }
6569
6570 ################################################################
6571
6572 # &check_trailing_slash ($WHERE, $LINE)
6573 # -------------------------------------
6574 # Return 1 iff $LINE ends with a slash.
6575 # Might modify $LINE.
6576 sub check_trailing_slash ($\$)
6577 {
6578   my ($where, $line) = @_;
6579
6580   # Ignore '##' lines.
6581   return 0 if $$line =~ /$IGNORE_PATTERN/o;
6582
6583   # Catch and fix a common error.
6584   msg "syntax", $where, "whitespace following trailing backslash"
6585     if $$line =~ s/\\\s+\n$/\\\n/;
6586
6587   return $$line =~ /\\$/;
6588 }
6589
6590
6591 # &read_am_file ($AMFILE, $WHERE)
6592 # -------------------------------
6593 # Read Makefile.am and set up %contents.  Simultaneously copy lines
6594 # from Makefile.am into $output_trailer, or define variables as
6595 # appropriate.  NOTE we put rules in the trailer section.  We want
6596 # user rules to come after our generated stuff.
6597 sub read_am_file ($$)
6598 {
6599     my ($amfile, $where) = @_;
6600
6601     my $am_file = new Automake::XFile ("< $amfile");
6602     verb "reading $amfile";
6603
6604     # Keep track of the youngest output dependency.
6605     my $mtime = mtime $amfile;
6606     $output_deps_greatest_timestamp = $mtime
6607       if $mtime > $output_deps_greatest_timestamp;
6608
6609     my $spacing = '';
6610     my $comment = '';
6611     my $blank = 0;
6612     my $saw_bk = 0;
6613     my $var_look = VAR_ASIS;
6614
6615     use constant IN_VAR_DEF => 0;
6616     use constant IN_RULE_DEF => 1;
6617     use constant IN_COMMENT => 2;
6618     my $prev_state = IN_RULE_DEF;
6619
6620     while ($_ = $am_file->getline)
6621     {
6622         $where->set ("$amfile:$.");
6623         if (/$IGNORE_PATTERN/o)
6624         {
6625             # Merely delete comments beginning with two hashes.
6626         }
6627         elsif (/$WHITE_PATTERN/o)
6628         {
6629             error $where, "blank line following trailing backslash"
6630               if $saw_bk;
6631             # Stick a single white line before the incoming macro or rule.
6632             $spacing = "\n";
6633             $blank = 1;
6634             # Flush all comments seen so far.
6635             if ($comment ne '')
6636             {
6637                 $output_vars .= $comment;
6638                 $comment = '';
6639             }
6640         }
6641         elsif (/$COMMENT_PATTERN/o)
6642         {
6643             # Stick comments before the incoming macro or rule.  Make
6644             # sure a blank line precedes the first block of comments.
6645             $spacing = "\n" unless $blank;
6646             $blank = 1;
6647             $comment .= $spacing . $_;
6648             $spacing = '';
6649             $prev_state = IN_COMMENT;
6650         }
6651         else
6652         {
6653             last;
6654         }
6655         $saw_bk = check_trailing_slash ($where, $_);
6656     }
6657
6658     # We save the conditional stack on entry, and then check to make
6659     # sure it is the same on exit.  This lets us conditionally include
6660     # other files.
6661     my @saved_cond_stack = @cond_stack;
6662     my $cond = new Automake::Condition (@cond_stack);
6663
6664     my $last_var_name = '';
6665     my $last_var_type = '';
6666     my $last_var_value = '';
6667     my $last_where;
6668     # FIXME: shouldn't use $_ in this loop; it is too big.
6669     while ($_)
6670     {
6671         $where->set ("$amfile:$.");
6672
6673         # Make sure the line is \n-terminated.
6674         chomp;
6675         $_ .= "\n";
6676
6677         # Don't look at MAINTAINER_MODE_TRUE here.  That shouldn't be
6678         # used by users.  @MAINT@ is an anachronism now.
6679         $_ =~ s/\@MAINT\@//g
6680             unless $seen_maint_mode;
6681
6682         my $new_saw_bk = check_trailing_slash ($where, $_);
6683
6684         if (/$IGNORE_PATTERN/o)
6685         {
6686             # Merely delete comments beginning with two hashes.
6687
6688             # Keep any backslash from the previous line.
6689             $new_saw_bk = $saw_bk;
6690         }
6691         elsif (/$WHITE_PATTERN/o)
6692         {
6693             # Stick a single white line before the incoming macro or rule.
6694             $spacing = "\n";
6695             error $where, "blank line following trailing backslash"
6696               if $saw_bk;
6697         }
6698         elsif (/$COMMENT_PATTERN/o)
6699         {
6700             error $where, "comment following trailing backslash"
6701               if $saw_bk && $prev_state != IN_COMMENT;
6702
6703             # Stick comments before the incoming macro or rule.
6704             $comment .= $spacing . $_;
6705             $spacing = '';
6706             $prev_state = IN_COMMENT;
6707         }
6708         elsif ($saw_bk)
6709         {
6710             if ($prev_state == IN_RULE_DEF)
6711             {
6712               my $cond = new Automake::Condition @cond_stack;
6713               $output_trailer .= $cond->subst_string;
6714               $output_trailer .= $_;
6715             }
6716             elsif ($prev_state == IN_COMMENT)
6717             {
6718                 # If the line doesn't start with a '#', add it.
6719                 # We do this because a continued comment like
6720                 #   # A = foo \
6721                 #         bar \
6722                 #         baz
6723                 # is not portable.  BSD make doesn't honor
6724                 # escaped newlines in comments.
6725                 s/^#?/#/;
6726                 $comment .= $spacing . $_;
6727             }
6728             else # $prev_state == IN_VAR_DEF
6729             {
6730               $last_var_value .= ' '
6731                 unless $last_var_value =~ /\s$/;
6732               $last_var_value .= $_;
6733
6734               if (!/\\$/)
6735                 {
6736                   Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6737                                               $last_var_type, $cond,
6738                                               $last_var_value, $comment,
6739                                               $last_where, VAR_ASIS)
6740                     if $cond != FALSE;
6741                   $comment = $spacing = '';
6742                 }
6743             }
6744         }
6745
6746         elsif (/$IF_PATTERN/o)
6747           {
6748             $cond = cond_stack_if ($1, $2, $where);
6749           }
6750         elsif (/$ELSE_PATTERN/o)
6751           {
6752             $cond = cond_stack_else ($1, $2, $where);
6753           }
6754         elsif (/$ENDIF_PATTERN/o)
6755           {
6756             $cond = cond_stack_endif ($1, $2, $where);
6757           }
6758
6759         elsif (/$RULE_PATTERN/o)
6760         {
6761             # Found a rule.
6762             $prev_state = IN_RULE_DEF;
6763
6764             # For now we have to output all definitions of user rules
6765             # and can't diagnose duplicates (see the comment in
6766             # Automake::Rule::define). So we go on and ignore the return value.
6767             Automake::Rule::define ($1, $amfile, RULE_USER, $cond, $where);
6768
6769             check_variable_expansions ($_, $where);
6770
6771             $output_trailer .= $comment . $spacing;
6772             my $cond = new Automake::Condition @cond_stack;
6773             $output_trailer .= $cond->subst_string;
6774             $output_trailer .= $_;
6775             $comment = $spacing = '';
6776         }
6777         elsif (/$ASSIGNMENT_PATTERN/o)
6778         {
6779             # Found a macro definition.
6780             $prev_state = IN_VAR_DEF;
6781             $last_var_name = $1;
6782             $last_var_type = $2;
6783             $last_var_value = $3;
6784             $last_where = $where->clone;
6785             if ($3 ne '' && substr ($3, -1) eq "\\")
6786               {
6787                 # We preserve the '\' because otherwise the long lines
6788                 # that are generated will be truncated by broken
6789                 # 'sed's.
6790                 $last_var_value = $3 . "\n";
6791               }
6792             # Normally we try to output variable definitions in the
6793             # same format they were input.  However, POSIX compliant
6794             # systems are not required to support lines longer than
6795             # 2048 bytes (most notably, some sed implementation are
6796             # limited to 4000 bytes, and sed is used by config.status
6797             # to rewrite Makefile.in into Makefile).  Moreover nobody
6798             # would really write such long lines by hand since it is
6799             # hardly maintainable.  So if a line is longer that 1000
6800             # bytes (an arbitrary limit), assume it has been
6801             # automatically generated by some tools, and flatten the
6802             # variable definition.  Otherwise, keep the variable as it
6803             # as been input.
6804             $var_look = VAR_PRETTY if length ($last_var_value) >= 1000;
6805
6806             if (!/\\$/)
6807               {
6808                 Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6809                                             $last_var_type, $cond,
6810                                             $last_var_value, $comment,
6811                                             $last_where, $var_look)
6812                   if $cond != FALSE;
6813                 $comment = $spacing = '';
6814                 $var_look = VAR_ASIS;
6815               }
6816         }
6817         elsif (/$INCLUDE_PATTERN/o)
6818         {
6819             my $path = $1;
6820
6821             if ($path =~ s/^\$\(top_srcdir\)\///)
6822               {
6823                 push (@include_stack, "\$\(top_srcdir\)/$path");
6824                 # Distribute any included file.
6825
6826                 # Always use the $(top_srcdir) prefix in DIST_COMMON,
6827                 # otherwise OSF make will implicitly copy the included
6828                 # file in the build tree during "make distdir" to satisfy
6829                 # the dependency.
6830                 # (subdircond2.test and subdircond3.test will fail.)
6831                 push_dist_common ("\$\(top_srcdir\)/$path");
6832               }
6833             else
6834               {
6835                 $path =~ s/\$\(srcdir\)\///;
6836                 push (@include_stack, "\$\(srcdir\)/$path");
6837                 # Always use the $(srcdir) prefix in DIST_COMMON,
6838                 # otherwise OSF make will implicitly copy the included
6839                 # file in the build tree during "make distdir" to satisfy
6840                 # the dependency.
6841                 # (subdircond2.test and subdircond3.test will fail.)
6842                 push_dist_common ("\$\(srcdir\)/$path");
6843                 $path = $relative_dir . "/" . $path if $relative_dir ne '.';
6844               }
6845             $where->push_context ("'$path' included from here");
6846             &read_am_file ($path, $where);
6847             $where->pop_context;
6848         }
6849         else
6850         {
6851             # This isn't an error; it is probably a continued rule.
6852             # In fact, this is what we assume.
6853             $prev_state = IN_RULE_DEF;
6854             check_variable_expansions ($_, $where);
6855             $output_trailer .= $comment . $spacing;
6856             my $cond = new Automake::Condition @cond_stack;
6857             $output_trailer .= $cond->subst_string;
6858             $output_trailer .= $_;
6859             $comment = $spacing = '';
6860             error $where, "'#' comment at start of rule is unportable"
6861               if $_ =~ /^\t\s*\#/;
6862         }
6863
6864         $saw_bk = $new_saw_bk;
6865         $_ = $am_file->getline;
6866     }
6867
6868     $output_trailer .= $comment;
6869
6870     error ($where, "trailing backslash on last line")
6871       if $saw_bk;
6872
6873     error ($where, (@cond_stack ? "unterminated conditionals: @cond_stack"
6874                     : "too many conditionals closed in include file"))
6875       if "@saved_cond_stack" ne "@cond_stack";
6876 }
6877
6878
6879 # define_standard_variables ()
6880 # ----------------------------
6881 # A helper for read_main_am_file which initializes configure variables
6882 # and variables from header-vars.am.
6883 sub define_standard_variables
6884 {
6885   my $saved_output_vars = $output_vars;
6886   my ($comments, undef, $rules) =
6887     file_contents_internal (1, "$libdir/am/header-vars.am",
6888                             new Automake::Location);
6889
6890   foreach my $var (sort keys %configure_vars)
6891     {
6892       &define_configure_variable ($var);
6893     }
6894
6895   $output_vars .= $comments . $rules;
6896 }
6897
6898 # Read main am file.
6899 sub read_main_am_file
6900 {
6901     my ($amfile) = @_;
6902
6903     # This supports the strange variable tricks we are about to play.
6904     prog_error ("variable defined before read_main_am_file\n" . variables_dump ())
6905       if (scalar (variables) > 0);
6906
6907     # Generate copyright header for generated Makefile.in.
6908     # We do discard the output of predefined variables, handled below.
6909     $output_vars = ("# $in_file_name generated by automake "
6910                    . $VERSION . " from $am_file_name.\n");
6911     $output_vars .= '# ' . subst ('configure_input') . "\n";
6912     $output_vars .= $gen_copyright;
6913
6914     # We want to predefine as many variables as possible.  This lets
6915     # the user set them with '+=' in Makefile.am.
6916     &define_standard_variables;
6917
6918     # Read user file, which might override some of our values.
6919     &read_am_file ($amfile, new Automake::Location);
6920 }
6921
6922
6923
6924 ################################################################
6925
6926 # $FLATTENED
6927 # &flatten ($STRING)
6928 # ------------------
6929 # Flatten the $STRING and return the result.
6930 sub flatten
6931 {
6932   $_ = shift;
6933
6934   s/\\\n//somg;
6935   s/\s+/ /g;
6936   s/^ //;
6937   s/ $//;
6938
6939   return $_;
6940 }
6941
6942
6943 # transform_token ($TOKEN, \%PAIRS, $KEY)
6944 # =======================================
6945 # Return the value associated to $KEY in %PAIRS, as used on $TOKEN
6946 # (which should be ?KEY? or any of the special %% requests)..
6947 sub transform_token ($$$)
6948 {
6949   my ($token, $transform, $key) = @_;
6950   my $res = $transform->{$key};
6951   prog_error "Unknown key '$key' in '$token'" unless defined $res;
6952   return $res;
6953 }
6954
6955
6956 # transform ($TOKEN, \%PAIRS)
6957 # ===========================
6958 # If ($TOKEN, $VAL) is in %PAIRS:
6959 #   - replaces %KEY% with $VAL,
6960 #   - enables/disables ?KEY? and ?!KEY?,
6961 #   - replaces %?KEY% with TRUE or FALSE.
6962 #   - replaces %KEY?IFTRUE%, %KEY:IFFALSE%, and %KEY?IFTRUE:IFFALSE% with
6963 #     IFTRUE / IFFALSE, as appropriate.
6964 sub transform ($$)
6965 {
6966   my ($token, $transform) = @_;
6967
6968   # %KEY%.
6969   # Must be before the following pattern to exclude the case
6970   # when there is neither IFTRUE nor IFFALSE.
6971   if ($token =~ /^%([\w\-]+)%$/)
6972     {
6973       return transform_token ($token, $transform, $1);
6974     }
6975   # %KEY?IFTRUE%, %KEY:IFFALSE%, and %KEY?IFTRUE:IFFALSE%.
6976   elsif ($token =~ /^%([\w\-]+)(?:\?([^?:%]+))?(?::([^?:%]+))?%$/)
6977     {
6978       return transform_token ($token, $transform, $1) ? ($2 || '') : ($3 || '');
6979     }
6980   # %?KEY%.
6981   elsif ($token =~ /^%\?([\w\-]+)%$/)
6982     {
6983       return transform_token ($token, $transform, $1) ? 'TRUE' : 'FALSE';
6984     }
6985   # ?KEY? and ?!KEY?.
6986   elsif ($token =~ /^ \? (!?) ([\w\-]+) \? $/x)
6987     {
6988       my $neg = ($1 eq '!') ? 1 : 0;
6989       my $val = transform_token ($token, $transform, $2);
6990       return (!!$val == $neg) ? '##%' : '';
6991     }
6992   else
6993     {
6994       prog_error "Unknown request format: $token";
6995     }
6996 }
6997
6998 # $TEXT
6999 # preprocess_file ($MAKEFILE, [%TRANSFORM])
7000 # -----------------------------------------
7001 # Load a $MAKEFILE, apply the %TRANSFORM, and return the result.
7002 # No extra parsing or post-processing is done (i.e., recognition of
7003 # rules declaration or of make variables definitions).
7004 sub preprocess_file ($%)
7005 {
7006   my ($file, %transform) = @_;
7007
7008   # Complete %transform with global options.
7009   # Note that %transform goes last, so it overrides global options.
7010   %transform = ('CYGNUS'      => !! option 'cygnus',
7011                  'MAINTAINER-MODE'
7012                  => $seen_maint_mode ? subst ('MAINTAINER_MODE_TRUE') : '',
7013
7014                  'XZ'          => !! option 'dist-xz',
7015                  'LZMA'        => !! option 'dist-lzma',
7016                  'LZIP'        => !! option 'dist-lzip',
7017                  'BZIP2'       => !! option 'dist-bzip2',
7018                  'COMPRESS'    => !! option 'dist-tarZ',
7019                  'GZIP'        =>  ! option 'no-dist-gzip',
7020                  'SHAR'        => !! option 'dist-shar',
7021                  'ZIP'         => !! option 'dist-zip',
7022
7023                  'INSTALL-INFO' =>  ! option 'no-installinfo',
7024                  'INSTALL-MAN'  =>  ! option 'no-installman',
7025                  'HAVE-MANS'    => !! var ('MANS'),
7026                  'CK-NEWS'      => !! option 'check-news',
7027
7028                  'SUBDIRS'      => !! var ('SUBDIRS'),
7029                  'TOPDIR_P'     => $relative_dir eq '.',
7030
7031                  'BUILD'    => ($seen_canonical >= AC_CANONICAL_BUILD),
7032                  'HOST'     => ($seen_canonical >= AC_CANONICAL_HOST),
7033                  'TARGET'   => ($seen_canonical >= AC_CANONICAL_TARGET),
7034
7035                  'LIBTOOL'      => !! var ('LIBTOOL'),
7036                  'NONLIBTOOL'   => 1,
7037                 %transform);
7038
7039   if (! defined ($_ = $am_file_cache{$file}))
7040     {
7041       verb "reading $file";
7042       # Swallow the whole file.
7043       my $fc_file = new Automake::XFile "< $file";
7044       my $saved_dollar_slash = $/;
7045       undef $/;
7046       $_ = $fc_file->getline;
7047       $/ = $saved_dollar_slash;
7048       $fc_file->close;
7049       # Remove ##-comments.
7050       # Besides we don't need more than two consecutive new-lines.
7051       s/(?:$IGNORE_PATTERN|(?<=\n\n)\n+)//gom;
7052       # Remember the contents of the just-read file.
7053       $am_file_cache{$file} = $_;
7054     }
7055
7056   # Substitute Automake template tokens.
7057   s/(?: % \?? [\w\-]+ %
7058       | % [\w\-]+ (?:\?[^?:%]+)? (?::[^?:%]+)? %
7059       | \? !? [\w\-]+ \?
7060     )/transform($&, \%transform)/gex;
7061   # transform() may have added some ##%-comments to strip.
7062   # (we use '##%' instead of '##' so we can distinguish ##%##%##% from
7063   # ####### and do not remove the latter.)
7064   s/^[ \t]*(?:##%)+.*\n//gm;
7065
7066   return $_;
7067 }
7068
7069
7070 # @PARAGRAPHS
7071 # &make_paragraphs ($MAKEFILE, [%TRANSFORM])
7072 # ------------------------------------------
7073 # Load a $MAKEFILE, apply the %TRANSFORM, and return it as a list of
7074 # paragraphs.
7075 sub make_paragraphs ($%)
7076 {
7077   my ($file, %transform) = @_;
7078   $transform{FIRST} = !$transformed_files{$file};
7079   $transformed_files{$file} = 1;
7080
7081   my @lines = split /(?<!\\)\n/, preprocess_file ($file, %transform);
7082   my @res;
7083
7084   while (defined ($_ = shift @lines))
7085     {
7086       my $paragraph = $_;
7087       # If we are a rule, eat as long as we start with a tab.
7088       if (/$RULE_PATTERN/smo)
7089         {
7090           while (defined ($_ = shift @lines) && $_ =~ /^\t/)
7091             {
7092               $paragraph .= "\n$_";
7093             }
7094           unshift (@lines, $_);
7095         }
7096
7097       # If we are a comments, eat as much comments as you can.
7098       elsif (/$COMMENT_PATTERN/smo)
7099         {
7100           while (defined ($_ = shift @lines)
7101                  && $_ =~ /$COMMENT_PATTERN/smo)
7102             {
7103               $paragraph .= "\n$_";
7104             }
7105           unshift (@lines, $_);
7106         }
7107
7108       push @res, $paragraph;
7109     }
7110
7111   return @res;
7112 }
7113
7114
7115
7116 # ($COMMENT, $VARIABLES, $RULES)
7117 # &file_contents_internal ($IS_AM, $FILE, $WHERE, [%TRANSFORM])
7118 # -------------------------------------------------------------
7119 # Return contents of a file from $libdir/am, automatically skipping
7120 # macros or rules which are already known. $IS_AM iff the caller is
7121 # reading an Automake file (as opposed to the user's Makefile.am).
7122 sub file_contents_internal ($$$%)
7123 {
7124     my ($is_am, $file, $where, %transform) = @_;
7125
7126     $where->set ($file);
7127
7128     my $result_vars = '';
7129     my $result_rules = '';
7130     my $comment = '';
7131     my $spacing = '';
7132
7133     # The following flags are used to track rules spanning across
7134     # multiple paragraphs.
7135     my $is_rule = 0;            # 1 if we are processing a rule.
7136     my $discard_rule = 0;       # 1 if the current rule should not be output.
7137
7138     # We save the conditional stack on entry, and then check to make
7139     # sure it is the same on exit.  This lets us conditionally include
7140     # other files.
7141     my @saved_cond_stack = @cond_stack;
7142     my $cond = new Automake::Condition (@cond_stack);
7143
7144     foreach (make_paragraphs ($file, %transform))
7145     {
7146         # FIXME: no line number available.
7147         $where->set ($file);
7148
7149         # Sanity checks.
7150         error $where, "blank line following trailing backslash:\n$_"
7151           if /\\$/;
7152         error $where, "comment following trailing backslash:\n$_"
7153           if /\\#/;
7154
7155         if (/^$/)
7156         {
7157             $is_rule = 0;
7158             # Stick empty line before the incoming macro or rule.
7159             $spacing = "\n";
7160         }
7161         elsif (/$COMMENT_PATTERN/mso)
7162         {
7163             $is_rule = 0;
7164             # Stick comments before the incoming macro or rule.
7165             $comment = "$_\n";
7166         }
7167
7168         # Handle inclusion of other files.
7169         elsif (/$INCLUDE_PATTERN/o)
7170         {
7171             if ($cond != FALSE)
7172               {
7173                 my $file = ($is_am ? "$libdir/am/" : '') . $1;
7174                 $where->push_context ("'$file' included from here");
7175                 # N-ary '.=' fails.
7176                 my ($com, $vars, $rules)
7177                   = file_contents_internal ($is_am, $file, $where, %transform);
7178                 $where->pop_context;
7179                 $comment .= $com;
7180                 $result_vars .= $vars;
7181                 $result_rules .= $rules;
7182               }
7183         }
7184
7185         # Handling the conditionals.
7186         elsif (/$IF_PATTERN/o)
7187           {
7188             $cond = cond_stack_if ($1, $2, $file);
7189           }
7190         elsif (/$ELSE_PATTERN/o)
7191           {
7192             $cond = cond_stack_else ($1, $2, $file);
7193           }
7194         elsif (/$ENDIF_PATTERN/o)
7195           {
7196             $cond = cond_stack_endif ($1, $2, $file);
7197           }
7198
7199         # Handling rules.
7200         elsif (/$RULE_PATTERN/mso)
7201         {
7202           $is_rule = 1;
7203           $discard_rule = 0;
7204           # Separate relationship from optional actions: the first
7205           # `new-line tab" not preceded by backslash (continuation
7206           # line).
7207           my $paragraph = $_;
7208           /^(.*?)(?:(?<!\\)\n(\t.*))?$/s;
7209           my ($relationship, $actions) = ($1, $2 || '');
7210
7211           # Separate targets from dependencies: the first colon.
7212           $relationship =~ /^([^:]+\S+) *: *(.*)$/som;
7213           my ($targets, $dependencies) = ($1, $2);
7214           # Remove the escaped new lines.
7215           # I don't know why, but I have to use a tmp $flat_deps.
7216           my $flat_deps = &flatten ($dependencies);
7217           my @deps = split (' ', $flat_deps);
7218
7219           foreach (split (' ', $targets))
7220             {
7221               # FIXME: 1. We are not robust to people defining several targets
7222               # at once, only some of them being in %dependencies.  The
7223               # actions from the targets in %dependencies are usually generated
7224               # from the content of %actions, but if some targets in $targets
7225               # are not in %dependencies the ELSE branch will output
7226               # a rule for all $targets (i.e. the targets which are both
7227               # in %dependencies and $targets will have two rules).
7228
7229               # FIXME: 2. The logic here is not able to output a
7230               # multi-paragraph rule several time (e.g. for each condition
7231               # it is defined for) because it only knows the first paragraph.
7232
7233               # FIXME: 3. We are not robust to people defining a subset
7234               # of a previously defined "multiple-target" rule.  E.g.
7235               # 'foo:' after 'foo bar:'.
7236
7237               # Output only if not in FALSE.
7238               if (defined $dependencies{$_} && $cond != FALSE)
7239                 {
7240                   &depend ($_, @deps);
7241                   register_action ($_, $actions);
7242                 }
7243               else
7244                 {
7245                   # Free-lance dependency.  Output the rule for all the
7246                   # targets instead of one by one.
7247                   my @undefined_conds =
7248                     Automake::Rule::define ($targets, $file,
7249                                             $is_am ? RULE_AUTOMAKE : RULE_USER,
7250                                             $cond, $where);
7251                   for my $undefined_cond (@undefined_conds)
7252                     {
7253                       my $condparagraph = $paragraph;
7254                       $condparagraph =~ s/^/$undefined_cond->subst_string/gme;
7255                       $result_rules .= "$spacing$comment$condparagraph\n";
7256                     }
7257                   if (scalar @undefined_conds == 0)
7258                     {
7259                       # Remember to discard next paragraphs
7260                       # if they belong to this rule.
7261                       # (but see also FIXME: #2 above.)
7262                       $discard_rule = 1;
7263                     }
7264                   $comment = $spacing = '';
7265                   last;
7266                 }
7267             }
7268         }
7269
7270         elsif (/$ASSIGNMENT_PATTERN/mso)
7271         {
7272             my ($var, $type, $val) = ($1, $2, $3);
7273             error $where, "variable '$var' with trailing backslash"
7274               if /\\$/;
7275
7276             $is_rule = 0;
7277
7278             Automake::Variable::define ($var,
7279                                         $is_am ? VAR_AUTOMAKE : VAR_MAKEFILE,
7280                                         $type, $cond, $val, $comment, $where,
7281                                         VAR_ASIS)
7282               if $cond != FALSE;
7283
7284             $comment = $spacing = '';
7285         }
7286         else
7287         {
7288             # This isn't an error; it is probably some tokens which
7289             # configure is supposed to replace, such as '@SET-MAKE@',
7290             # or some part of a rule cut by an if/endif.
7291             if (! $cond->false && ! ($is_rule && $discard_rule))
7292               {
7293                 s/^/$cond->subst_string/gme;
7294                 $result_rules .= "$spacing$comment$_\n";
7295               }
7296             $comment = $spacing = '';
7297         }
7298     }
7299
7300     error ($where, @cond_stack ?
7301            "unterminated conditionals: @cond_stack" :
7302            "too many conditionals closed in include file")
7303       if "@saved_cond_stack" ne "@cond_stack";
7304
7305     return ($comment, $result_vars, $result_rules);
7306 }
7307
7308
7309 # $CONTENTS
7310 # &file_contents ($BASENAME, $WHERE, [%TRANSFORM])
7311 # ------------------------------------------------
7312 # Return contents of a file from $libdir/am, automatically skipping
7313 # macros or rules which are already known.
7314 sub file_contents ($$%)
7315 {
7316     my ($basename, $where, %transform) = @_;
7317     my ($comments, $variables, $rules) =
7318       file_contents_internal (1, "$libdir/am/$basename.am", $where,
7319                               %transform);
7320     return "$comments$variables$rules";
7321 }
7322
7323
7324 # @PREFIX
7325 # &am_primary_prefixes ($PRIMARY, $CAN_DIST, @PREFIXES)
7326 # -----------------------------------------------------
7327 # Find all variable prefixes that are used for install directories.  A
7328 # prefix 'zar' qualifies iff:
7329 #
7330 # * 'zardir' is a variable.
7331 # * 'zar_PRIMARY' is a variable.
7332 #
7333 # As a side effect, it looks for misspellings.  It is an error to have
7334 # a variable ending in a "reserved" suffix whose prefix is unknown, e.g.
7335 # "bni_PROGRAMS".  However, unusual prefixes are allowed if a variable
7336 # of the same name (with "dir" appended) exists.  For instance, if the
7337 # variable "zardir" is defined, then "zar_PROGRAMS" becomes valid.
7338 # This is to provide a little extra flexibility in those cases which
7339 # need it.
7340 sub am_primary_prefixes ($$@)
7341 {
7342   my ($primary, $can_dist, @prefixes) = @_;
7343
7344   local $_;
7345   my %valid = map { $_ => 0 } @prefixes;
7346   $valid{'EXTRA'} = 0;
7347   foreach my $var (variables $primary)
7348     {
7349       # Automake is allowed to define variables that look like primaries
7350       # but which aren't.  E.g. INSTALL_sh_DATA.
7351       # Autoconf can also define variables like INSTALL_DATA, so
7352       # ignore all configure variables (at least those which are not
7353       # redefined in Makefile.am).
7354       # FIXME: We should make sure that these variables are not
7355       # conditionally defined (or else adjust the condition below).
7356       my $def = $var->def (TRUE);
7357       next if $def && $def->owner != VAR_MAKEFILE;
7358
7359       my $varname = $var->name;
7360
7361       if ($varname =~ /^(nobase_)?(dist_|nodist_)?(.*)_[[:alnum:]]+$/)
7362         {
7363           my ($base, $dist, $X) = ($1 || '', $2 || '', $3 || '');
7364           if ($dist ne '' && ! $can_dist)
7365             {
7366               err_var ($var,
7367                        "invalid variable '$varname': 'dist' is forbidden");
7368             }
7369           # Standard directories must be explicitly allowed.
7370           elsif (! defined $valid{$X} && exists $standard_prefix{$X})
7371             {
7372               err_var ($var,
7373                        "'${X}dir' is not a legitimate directory " .
7374                        "for '$primary'");
7375             }
7376           # A not explicitly valid directory is allowed if Xdir is defined.
7377           elsif (! defined $valid{$X} &&
7378                  $var->requires_variables ("'$varname' is used", "${X}dir"))
7379             {
7380               # Nothing to do.  Any error message has been output
7381               # by $var->requires_variables.
7382             }
7383           else
7384             {
7385               # Ensure all extended prefixes are actually used.
7386               $valid{"$base$dist$X"} = 1;
7387             }
7388         }
7389       else
7390         {
7391           prog_error "unexpected variable name: $varname";
7392         }
7393     }
7394
7395   # Return only those which are actually defined.
7396   return sort grep { var ($_ . '_' . $primary) } keys %valid;
7397 }
7398
7399
7400 # Handle 'where_HOW' variable magic.  Does all lookups, generates
7401 # install code, and possibly generates code to define the primary
7402 # variable.  The first argument is the name of the .am file to munge,
7403 # the second argument is the primary variable (e.g. HEADERS), and all
7404 # subsequent arguments are possible installation locations.
7405 #
7406 # Returns list of [$location, $value] pairs, where
7407 # $value's are the values in all where_HOW variable, and $location
7408 # there associated location (the place here their parent variables were
7409 # defined).
7410 #
7411 # FIXME: this should be rewritten to be cleaner.  It should be broken
7412 # up into multiple functions.
7413 #
7414 # Usage is: am_install_var (OPTION..., file, HOW, where...)
7415 sub am_install_var
7416 {
7417   my (@args) = @_;
7418
7419   my $do_require = 1;
7420   my $can_dist = 0;
7421   my $default_dist = 0;
7422   while (@args)
7423     {
7424       if ($args[0] eq '-noextra')
7425         {
7426           $do_require = 0;
7427         }
7428       elsif ($args[0] eq '-candist')
7429         {
7430           $can_dist = 1;
7431         }
7432       elsif ($args[0] eq '-defaultdist')
7433         {
7434           $default_dist = 1;
7435           $can_dist = 1;
7436         }
7437       elsif ($args[0] !~ /^-/)
7438         {
7439           last;
7440         }
7441       shift (@args);
7442     }
7443
7444   my ($file, $primary, @prefix) = @args;
7445
7446   # Now that configure substitutions are allowed in where_HOW
7447   # variables, it is an error to actually define the primary.  We
7448   # allow 'JAVA', as it is customarily used to mean the Java
7449   # interpreter.  This is but one of several Java hacks.  Similarly,
7450   # 'PYTHON' is customarily used to mean the Python interpreter.
7451   reject_var $primary, "'$primary' is an anachronism"
7452     unless $primary eq 'JAVA' || $primary eq 'PYTHON';
7453
7454   # Get the prefixes which are valid and actually used.
7455   @prefix = am_primary_prefixes ($primary, $can_dist, @prefix);
7456
7457   # If a primary includes a configure substitution, then the EXTRA_
7458   # form is required.  Otherwise we can't properly do our job.
7459   my $require_extra;
7460
7461   my @used = ();
7462   my @result = ();
7463
7464   foreach my $X (@prefix)
7465     {
7466       my $nodir_name = $X;
7467       my $one_name = $X . '_' . $primary;
7468       my $one_var = var $one_name;
7469
7470       my $strip_subdir = 1;
7471       # If subdir prefix should be preserved, do so.
7472       if ($nodir_name =~ /^nobase_/)
7473         {
7474           $strip_subdir = 0;
7475           $nodir_name =~ s/^nobase_//;
7476         }
7477
7478       # If files should be distributed, do so.
7479       my $dist_p = 0;
7480       if ($can_dist)
7481         {
7482           $dist_p = (($default_dist && $nodir_name !~ /^nodist_/)
7483                      || (! $default_dist && $nodir_name =~ /^dist_/));
7484           $nodir_name =~ s/^(dist|nodist)_//;
7485         }
7486
7487
7488       # Use the location of the currently processed variable.
7489       # We are not processing a particular condition, so pick the first
7490       # available.
7491       my $tmpcond = $one_var->conditions->one_cond;
7492       my $where = $one_var->rdef ($tmpcond)->location->clone;
7493
7494       # Append actual contents of where_PRIMARY variable to
7495       # @result, skipping @substitutions@.
7496       foreach my $locvals ($one_var->value_as_list_recursive (location => 1))
7497         {
7498           my ($loc, $value) = @$locvals;
7499           # Skip configure substitutions.
7500           if ($value =~ /^\@.*\@$/)
7501             {
7502               if ($nodir_name eq 'EXTRA')
7503                 {
7504                   error ($where,
7505                          "'$one_name' contains configure substitution, "
7506                          . "but shouldn't");
7507                 }
7508               # Check here to make sure variables defined in
7509               # configure.ac do not imply that EXTRA_PRIMARY
7510               # must be defined.
7511               elsif (! defined $configure_vars{$one_name})
7512                 {
7513                   $require_extra = $one_name
7514                     if $do_require;
7515                 }
7516             }
7517           else
7518             {
7519               # Strip any $(EXEEXT) suffix the user might have added, or this
7520               # will confuse &handle_source_transform and &check_canonical_spelling.
7521               # We'll add $(EXEEXT) back later anyway.
7522               # Do it here rather than in handle_programs so the uniquifying at the
7523               # end of this function works.
7524               ${$locvals}[1] =~ s/\$\(EXEEXT\)$//
7525                 if $primary eq 'PROGRAMS';
7526
7527               push (@result, $locvals);
7528             }
7529         }
7530       # A blatant hack: we rewrite each _PROGRAMS primary to include
7531       # EXEEXT.
7532       append_exeext { 1 } $one_name
7533         if $primary eq 'PROGRAMS';
7534       # "EXTRA" shouldn't be used when generating clean targets,
7535       # all, or install targets.  We used to warn if EXTRA_FOO was
7536       # defined uselessly, but this was annoying.
7537       next
7538         if $nodir_name eq 'EXTRA';
7539
7540       if ($nodir_name eq 'check')
7541         {
7542           push (@check, '$(' . $one_name . ')');
7543         }
7544       else
7545         {
7546           push (@used, '$(' . $one_name . ')');
7547         }
7548
7549       # Is this to be installed?
7550       my $install_p = $nodir_name ne 'noinst' && $nodir_name ne 'check';
7551
7552       # If so, with install-exec? (or install-data?).
7553       my $exec_p = ($nodir_name =~ /$EXEC_DIR_PATTERN/o);
7554
7555       my $check_options_p = $install_p && !! option 'std-options';
7556
7557       # Use the location of the currently processed variable as context.
7558       $where->push_context ("while processing '$one_name'");
7559
7560       # The variable containing all files to distribute.
7561       my $distvar = "\$($one_name)";
7562       $distvar = shadow_unconditionally ($one_name, $where)
7563         if ($dist_p && $one_var->has_conditional_contents);
7564
7565       # Singular form of $PRIMARY.
7566       (my $one_primary = $primary) =~ s/S$//;
7567       $output_rules .= &file_contents ($file, $where,
7568                                        PRIMARY     => $primary,
7569                                        ONE_PRIMARY => $one_primary,
7570                                        DIR         => $X,
7571                                        NDIR        => $nodir_name,
7572                                        BASE        => $strip_subdir,
7573
7574                                        EXEC      => $exec_p,
7575                                        INSTALL   => $install_p,
7576                                        DIST      => $dist_p,
7577                                        DISTVAR   => $distvar,
7578                                        'CK-OPTS' => $check_options_p);
7579     }
7580
7581   # The JAVA variable is used as the name of the Java interpreter.
7582   # The PYTHON variable is used as the name of the Python interpreter.
7583   if (@used && $primary ne 'JAVA' && $primary ne 'PYTHON')
7584     {
7585       # Define it.
7586       define_pretty_variable ($primary, TRUE, INTERNAL, @used);
7587       $output_vars .= "\n";
7588     }
7589
7590   err_var ($require_extra,
7591            "'$require_extra' contains configure substitution,\n"
7592            . "but 'EXTRA_$primary' not defined")
7593     if ($require_extra && ! var ('EXTRA_' . $primary));
7594
7595   # Push here because PRIMARY might be configure time determined.
7596   push (@all, '$(' . $primary . ')')
7597     if @used && $primary ne 'JAVA' && $primary ne 'PYTHON';
7598
7599   # Make the result unique.  This lets the user use conditionals in
7600   # a natural way, but still lets us program lazily -- we don't have
7601   # to worry about handling a particular object more than once.
7602   # We will keep only one location per object.
7603   my %result = ();
7604   for my $pair (@result)
7605     {
7606       my ($loc, $val) = @$pair;
7607       $result{$val} = $loc;
7608     }
7609   my @l = sort keys %result;
7610   return map { [$result{$_}->clone, $_] } @l;
7611 }
7612
7613
7614 ################################################################
7615
7616 # Each key in this hash is the name of a directory holding a
7617 # Makefile.in.  These variables are local to 'is_make_dir'.
7618 my %make_dirs = ();
7619 my $make_dirs_set = 0;
7620
7621 sub is_make_dir
7622 {
7623     my ($dir) = @_;
7624     if (! $make_dirs_set)
7625     {
7626         foreach my $iter (@configure_input_files)
7627         {
7628             $make_dirs{dirname ($iter)} = 1;
7629         }
7630         # We also want to notice Makefile.in's.
7631         foreach my $iter (@other_input_files)
7632         {
7633             if ($iter =~ /Makefile\.in$/)
7634             {
7635                 $make_dirs{dirname ($iter)} = 1;
7636             }
7637         }
7638         $make_dirs_set = 1;
7639     }
7640     return defined $make_dirs{$dir};
7641 }
7642
7643 ################################################################
7644
7645 # Find the aux dir.  This should match the algorithm used by
7646 # ./configure. (See the Autoconf documentation for for
7647 # AC_CONFIG_AUX_DIR.)
7648 sub locate_aux_dir ()
7649 {
7650   if (! $config_aux_dir_set_in_configure_ac)
7651     {
7652       # The default auxiliary directory is the first
7653       # of ., .., or ../.. that contains install-sh.
7654       # Assume . if install-sh doesn't exist yet.
7655       for my $dir (qw (. .. ../..))
7656         {
7657           if (-f "$dir/install-sh")
7658             {
7659               $config_aux_dir = $dir;
7660               last;
7661             }
7662         }
7663       $config_aux_dir = '.' unless $config_aux_dir;
7664     }
7665   # Avoid unsightly '/.'s.
7666   $am_config_aux_dir =
7667     '$(top_srcdir)' . ($config_aux_dir eq '.' ? "" : "/$config_aux_dir");
7668   $am_config_aux_dir =~ s,/*$,,;
7669 }
7670
7671
7672 # &push_required_file ($DIR, $FILE, $FULLFILE)
7673 # --------------------------------------------------
7674 # Push the given file onto DIST_COMMON.
7675 sub push_required_file
7676 {
7677   my ($dir, $file, $fullfile) = @_;
7678
7679   # If the file to be distributed is in the same directory of the
7680   # currently processed Makefile.am, then we want to distribute it
7681   # from this same Makefile.am.
7682   if ($dir eq $relative_dir)
7683     {
7684       push_dist_common ($file);
7685     }
7686   # This is needed to allow a construct in a non-top-level Makefile.am
7687   # to require a file in the build-aux directory (see at least the test
7688   # script 'test-driver-is-distributed.test').  This is related to the
7689   # automake bug#9546.  Note that the use of $config_aux_dir instead
7690   # of $am_config_aux_dir here is deliberate and necessary.
7691   elsif ($dir eq $config_aux_dir)
7692     {
7693       push_dist_common ("$am_config_aux_dir/$file");
7694     }
7695   # FIXME: another spacial case, for AC_LIBOBJ/AC_LIBSOURCE support.
7696   # We probably need some refactoring of this function and its callers,
7697   # to have a more explicit and systematic handling of all the special
7698   # cases; but, since there are only two of them, this is low-priority
7699   # ATM.
7700   elsif ($config_libobj_dir && $dir eq $config_libobj_dir)
7701     {
7702       # Avoid unsightly '/.'s.
7703       my $am_config_libobj_dir =
7704         '$(top_srcdir)' .
7705         ($config_libobj_dir eq '.' ? "" : "/$config_libobj_dir");
7706       $am_config_libobj_dir =~ s|/*$||;
7707       push_dist_common ("$am_config_libobj_dir/$file");
7708     }
7709   elsif ($relative_dir eq '.' && ! &is_make_dir ($dir))
7710     {
7711       # If we are doing the topmost directory, and the file is in a
7712       # subdir which does not have a Makefile, then we distribute it
7713       # here.
7714
7715       # If a required file is above the source tree, it is important
7716       # to prefix it with '$(srcdir)' so that no VPATH search is
7717       # performed.  Otherwise problems occur with Make implementations
7718       # that rewrite and simplify rules whose dependencies are found in a
7719       # VPATH location.  Here is an example with OSF1/Tru64 Make.
7720       #
7721       #   % cat Makefile
7722       #   VPATH = sub
7723       #   distdir: ../a
7724       #           echo ../a
7725       #   % ls
7726       #   Makefile a
7727       #   % make
7728       #   echo a
7729       #   a
7730       #
7731       # Dependency '../a' was found in 'sub/../a', but this make
7732       # implementation simplified it as 'a'.  (Note that the sub/
7733       # directory does not even exist.)
7734       #
7735       # This kind of VPATH rewriting seems hard to cancel.  The
7736       # distdir.am hack against VPATH rewriting works only when no
7737       # simplification is done, i.e., for dependencies which are in
7738       # subdirectories, not in enclosing directories.  Hence, in
7739       # the latter case we use a full path to make sure no VPATH
7740       # search occurs.
7741       $fullfile = '$(srcdir)/' . $fullfile
7742         if $dir =~ m,^\.\.(?:$|/),;
7743
7744       push_dist_common ($fullfile);
7745     }
7746   else
7747     {
7748       prog_error "a Makefile in relative directory $relative_dir " .
7749                  "can't add files in directory $dir to DIST_COMMON";
7750     }
7751 }
7752
7753
7754 # If a file name appears as a key in this hash, then it has already
7755 # been checked for.  This allows us not to report the same error more
7756 # than once.
7757 my %required_file_not_found = ();
7758
7759 # &required_file_check_or_copy ($WHERE, $DIRECTORY, $FILE)
7760 # --------------------------------------------------------
7761 # Verify that the file must exist in $DIRECTORY, or install it.
7762 sub required_file_check_or_copy ($$$)
7763 {
7764   my ($where, $dir, $file) = @_;
7765
7766   my $fullfile = "$dir/$file";
7767   my $found_it = 0;
7768   my $dangling_sym = 0;
7769
7770   if (-l $fullfile && ! -f $fullfile)
7771     {
7772       $dangling_sym = 1;
7773     }
7774   elsif (dir_has_case_matching_file ($dir, $file))
7775     {
7776       $found_it = 1;
7777     }
7778
7779   # '--force-missing' only has an effect if '--add-missing' is
7780   # specified.
7781   return
7782     if $found_it && (! $add_missing || ! $force_missing);
7783
7784   # If we've already looked for it, we're done.  You might
7785   # wonder why we don't do this before searching for the
7786   # file.  If we do that, then something like
7787   # AC_OUTPUT(subdir/foo foo) will fail to put foo.in into
7788   # DIST_COMMON.
7789   if (! $found_it)
7790     {
7791       return if defined $required_file_not_found{$fullfile};
7792       $required_file_not_found{$fullfile} = 1;
7793     }
7794   if ($dangling_sym && $add_missing)
7795     {
7796       unlink ($fullfile);
7797     }
7798
7799   my $trailer = '';
7800   my $trailer2 = '';
7801   my $suppress = 0;
7802
7803   # Only install missing files according to our desired
7804   # strictness level.
7805   my $message = "required file '$fullfile' not found";
7806   if ($add_missing)
7807     {
7808       if (-f "$libdir/$file")
7809         {
7810           $suppress = 1;
7811
7812           # Install the missing file.  Symlink if we
7813           # can, copy if we must.  Note: delete the file
7814           # first, in case it is a dangling symlink.
7815           $message = "installing '$fullfile'";
7816
7817           # The license file should not be volatile.
7818           if ($file eq "COPYING")
7819             {
7820               $message .= " using GNU General Public License v3 file";
7821               $trailer2 = "\n    Consider adding the COPYING file"
7822                         . " to the version control system"
7823                         . "\n    for your code, to avoid questions"
7824                         . " about which license your project uses";
7825             }
7826
7827           # Windows Perl will hang if we try to delete a
7828           # file that doesn't exist.
7829           unlink ($fullfile) if -f $fullfile;
7830           if ($symlink_exists && ! $copy_missing)
7831             {
7832               if (! symlink ("$libdir/$file", $fullfile)
7833                   || ! -e $fullfile)
7834                 {
7835                   $suppress = 0;
7836                   $trailer = "; error while making link: $!";
7837                 }
7838             }
7839           elsif (system ('cp', "$libdir/$file", $fullfile))
7840             {
7841               $suppress = 0;
7842               $trailer = "\n    error while copying";
7843             }
7844           set_dir_cache_file ($dir, $file);
7845         }
7846     }
7847   else
7848     {
7849       $trailer = "\n  'automake --add-missing' can install '$file'"
7850         if -f "$libdir/$file";
7851     }
7852
7853   # If --force-missing was specified, and we have
7854   # actually found the file, then do nothing.
7855   return
7856     if $found_it && $force_missing;
7857
7858   # If we couldn't install the file, but it is a target in
7859   # the Makefile, don't print anything.  This allows files
7860   # like README, AUTHORS, or THANKS to be generated.
7861   return
7862     if !$suppress && rule $file;
7863
7864   msg ($suppress ? 'note' : 'error', $where, "$message$trailer$trailer2");
7865 }
7866
7867
7868 # &require_file_internal ($WHERE, $MYSTRICT, $DIRECTORY, $QUEUE, @FILES)
7869 # ----------------------------------------------------------------------
7870 # Verify that the file must exist in $DIRECTORY, or install it.
7871 # $MYSTRICT is the strictness level at which this file becomes required.
7872 # Worker threads may queue up the action to be serialized by the master,
7873 # if $QUEUE is true
7874 sub require_file_internal ($$$@)
7875 {
7876   my ($where, $mystrict, $dir, $queue, @files) = @_;
7877
7878   return
7879     unless $strictness >= $mystrict;
7880
7881   foreach my $file (@files)
7882     {
7883       push_required_file ($dir, $file, "$dir/$file");
7884       if ($queue)
7885         {
7886           queue_required_file_check_or_copy ($required_conf_file_queue,
7887                                              QUEUE_CONF_FILE, $relative_dir,
7888                                              $where, $mystrict, @files);
7889         }
7890       else
7891         {
7892           required_file_check_or_copy ($where, $dir, $file);
7893         }
7894     }
7895 }
7896
7897 # &require_file ($WHERE, $MYSTRICT, @FILES)
7898 # -----------------------------------------
7899 sub require_file ($$@)
7900 {
7901     my ($where, $mystrict, @files) = @_;
7902     require_file_internal ($where, $mystrict, $relative_dir, 0, @files);
7903 }
7904
7905 # &require_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7906 # -----------------------------------------------------------
7907 sub require_file_with_macro ($$$@)
7908 {
7909     my ($cond, $macro, $mystrict, @files) = @_;
7910     $macro = rvar ($macro) unless ref $macro;
7911     require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7912 }
7913
7914 # &require_libsource_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7915 # ----------------------------------------------------------------
7916 # Require an AC_LIBSOURCEd file.  If AC_CONFIG_LIBOBJ_DIR was called, it
7917 # must be in that directory.  Otherwise expect it in the current directory.
7918 sub require_libsource_with_macro ($$$@)
7919 {
7920     my ($cond, $macro, $mystrict, @files) = @_;
7921     $macro = rvar ($macro) unless ref $macro;
7922     if ($config_libobj_dir)
7923       {
7924         require_file_internal ($macro->rdef ($cond)->location, $mystrict,
7925                                $config_libobj_dir, 0, @files);
7926       }
7927     else
7928       {
7929         require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7930       }
7931 }
7932
7933 # &queue_required_file_check_or_copy ($QUEUE, $KEY, $DIR, $WHERE,
7934 #                                     $MYSTRICT, @FILES)
7935 # ---------------------------------------------------------------
7936 sub queue_required_file_check_or_copy ($$$$@)
7937 {
7938     my ($queue, $key, $dir, $where, $mystrict, @files) = @_;
7939     my @serial_loc;
7940     if (ref $where)
7941       {
7942         @serial_loc = (QUEUE_LOCATION, $where->serialize ());
7943       }
7944     else
7945       {
7946         @serial_loc = (QUEUE_STRING, $where);
7947       }
7948     $queue->enqueue ($key, $dir, @serial_loc, $mystrict, 0 + @files, @files);
7949 }
7950
7951 # &require_queued_file_check_or_copy ($QUEUE)
7952 # -------------------------------------------
7953 sub require_queued_file_check_or_copy ($)
7954 {
7955     my ($queue) = @_;
7956     my $where;
7957     my $dir = $queue->dequeue ();
7958     my $loc_key = $queue->dequeue ();
7959     if ($loc_key eq QUEUE_LOCATION)
7960       {
7961         $where = Automake::Location::deserialize ($queue);
7962       }
7963     elsif ($loc_key eq QUEUE_STRING)
7964       {
7965         $where = $queue->dequeue ();
7966       }
7967     else
7968       {
7969         prog_error "unexpected key $loc_key";
7970       }
7971     my $mystrict = $queue->dequeue ();
7972     my $nfiles = $queue->dequeue ();
7973     my @files;
7974     push @files, $queue->dequeue ()
7975       foreach (1 .. $nfiles);
7976     return
7977       unless $strictness >= $mystrict;
7978     foreach my $file (@files)
7979       {
7980         required_file_check_or_copy ($where, $config_aux_dir, $file);
7981       }
7982 }
7983
7984 # &require_conf_file ($WHERE, $MYSTRICT, @FILES)
7985 # ----------------------------------------------
7986 # Looks in configuration path, as specified by AC_CONFIG_AUX_DIR.
7987 sub require_conf_file ($$@)
7988 {
7989     my ($where, $mystrict, @files) = @_;
7990     my $queue = defined $required_conf_file_queue ? 1 : 0;
7991     require_file_internal ($where, $mystrict, $config_aux_dir,
7992                            $queue, @files);
7993 }
7994
7995
7996 # &require_conf_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7997 # ----------------------------------------------------------------
7998 sub require_conf_file_with_macro ($$$@)
7999 {
8000     my ($cond, $macro, $mystrict, @files) = @_;
8001     require_conf_file (rvar ($macro)->rdef ($cond)->location,
8002                        $mystrict, @files);
8003 }
8004
8005 ################################################################
8006
8007 # &require_build_directory ($DIRECTORY)
8008 # -------------------------------------
8009 # Emit rules to create $DIRECTORY if needed, and return
8010 # the file that any target requiring this directory should be made
8011 # dependent upon.
8012 # We don't want to emit the rule twice, and want to reuse it
8013 # for directories with equivalent names (e.g., 'foo/bar' and './foo//bar').
8014 sub require_build_directory ($)
8015 {
8016   my $directory = shift;
8017
8018   return $directory_map{$directory} if exists $directory_map{$directory};
8019
8020   my $cdir = File::Spec->canonpath ($directory);
8021
8022   if (exists $directory_map{$cdir})
8023     {
8024       my $stamp = $directory_map{$cdir};
8025       $directory_map{$directory} = $stamp;
8026       return $stamp;
8027     }
8028
8029   my $dirstamp = "$cdir/\$(am__dirstamp)";
8030
8031   $directory_map{$directory} = $dirstamp;
8032   $directory_map{$cdir} = $dirstamp;
8033
8034   # Set a variable for the dirstamp basename.
8035   define_pretty_variable ('am__dirstamp', TRUE, INTERNAL,
8036                           '$(am__leading_dot)dirstamp');
8037
8038   # Directory must be removed by 'make distclean'.
8039   $clean_files{$dirstamp} = DIST_CLEAN;
8040
8041   $output_rules .= ("$dirstamp:\n"
8042                     . "\t\@\$(MKDIR_P) $directory\n"
8043                     . "\t\@: > $dirstamp\n");
8044
8045   return $dirstamp;
8046 }
8047
8048 # &require_build_directory_maybe ($FILE)
8049 # --------------------------------------
8050 # If $FILE lies in a subdirectory, emit a rule to create this
8051 # directory and return the file that $FILE should be made
8052 # dependent upon.  Otherwise, just return the empty string.
8053 sub require_build_directory_maybe ($)
8054 {
8055     my $file = shift;
8056     my $directory = dirname ($file);
8057
8058     if ($directory ne '.')
8059     {
8060         return require_build_directory ($directory);
8061     }
8062     else
8063     {
8064         return '';
8065     }
8066 }
8067
8068 ################################################################
8069
8070 # Push a list of files onto dist_common.
8071 sub push_dist_common
8072 {
8073   prog_error "push_dist_common run after handle_dist"
8074     if $handle_dist_run;
8075   Automake::Variable::define ('DIST_COMMON', VAR_AUTOMAKE, '+', TRUE, "@_",
8076                               '', INTERNAL, VAR_PRETTY);
8077 }
8078
8079
8080 ################################################################
8081
8082 # generate_makefile ($MAKEFILE_AM, $MAKEFILE_IN)
8083 # ----------------------------------------------
8084 # Generate a Makefile.in given the name of the corresponding Makefile and
8085 # the name of the file output by config.status.
8086 sub generate_makefile ($$)
8087 {
8088   my ($makefile_am, $makefile_in) = @_;
8089
8090   # Reset all the Makefile.am related variables.
8091   initialize_per_input;
8092
8093   # AUTOMAKE_OPTIONS can contains -W flags to disable or enable
8094   # warnings for this file.  So hold any warning issued before
8095   # we have processed AUTOMAKE_OPTIONS.
8096   buffer_messages ('warning');
8097
8098   # Name of input file ("Makefile.am") and output file
8099   # ("Makefile.in").  These have no directory components.
8100   $am_file_name = basename ($makefile_am);
8101   $in_file_name = basename ($makefile_in);
8102
8103   # $OUTPUT is encoded.  If it contains a ":" then the first element
8104   # is the real output file, and all remaining elements are input
8105   # files.  We don't scan or otherwise deal with these input files,
8106   # other than to mark them as dependencies.  See
8107   # &scan_autoconf_files for details.
8108   my ($makefile, @inputs) = split (/:/, $output_files{$makefile_in});
8109
8110   $relative_dir = dirname ($makefile);
8111   $am_relative_dir = dirname ($makefile_am);
8112
8113   read_main_am_file ($makefile_am);
8114   if (handle_options)
8115     {
8116       # Process buffered warnings.
8117       flush_messages;
8118       # Fatal error.  Just return, so we can continue with next file.
8119       return;
8120     }
8121   # Process buffered warnings.
8122   flush_messages;
8123
8124   # There are a few install-related variables that you should not define.
8125   foreach my $var ('PRE_INSTALL', 'POST_INSTALL', 'NORMAL_INSTALL')
8126     {
8127       my $v = var $var;
8128       if ($v)
8129         {
8130           my $def = $v->def (TRUE);
8131           prog_error "$var not defined in condition TRUE"
8132             unless $def;
8133           reject_var $var, "'$var' should not be defined"
8134             if $def->owner != VAR_AUTOMAKE;
8135         }
8136     }
8137
8138   # Catch some obsolete variables.
8139   msg_var ('obsolete', 'INCLUDES',
8140            "'INCLUDES' is the old name for 'AM_CPPFLAGS' (or '*_CPPFLAGS')")
8141     if var ('INCLUDES');
8142
8143   # Must do this after reading .am file.
8144   define_variable ('subdir', $relative_dir, INTERNAL);
8145
8146   # If DIST_SUBDIRS is defined, make sure SUBDIRS is, so that
8147   # recursive rules are enabled.
8148   define_pretty_variable ('SUBDIRS', TRUE, INTERNAL, '')
8149     if var 'DIST_SUBDIRS' && ! var 'SUBDIRS';
8150
8151   # Check first, because we might modify some state.
8152   check_cygnus;
8153   check_gnu_standards;
8154   check_gnits_standards;
8155
8156   handle_configure ($makefile_am, $makefile_in, $makefile, @inputs);
8157   handle_gettext;
8158   handle_libraries;
8159   handle_ltlibraries;
8160   handle_programs;
8161   handle_scripts;
8162
8163   handle_silent;
8164
8165   # These must be run after all the sources are scanned.  They
8166   # use variables defined by &handle_libraries, &handle_ltlibraries,
8167   # or &handle_programs.
8168   handle_compile;
8169   handle_languages;
8170   handle_libtool;
8171
8172   # Variables used by distdir.am and tags.am.
8173   define_pretty_variable ('SOURCES', TRUE, INTERNAL, @sources);
8174   if (! option 'no-dist')
8175     {
8176       define_pretty_variable ('DIST_SOURCES', TRUE, INTERNAL, @dist_sources);
8177     }
8178
8179   handle_texinfo;
8180   handle_emacs_lisp;
8181   handle_python;
8182   handle_java;
8183   handle_man_pages;
8184   handle_data;
8185   handle_headers;
8186   handle_subdirs;
8187   handle_tags;
8188   handle_minor_options;
8189   # Must come after handle_programs so that %known_programs is up-to-date.
8190   handle_tests;
8191
8192   # This must come after most other rules.
8193   handle_dist;
8194
8195   handle_footer;
8196   do_check_merge_target;
8197   handle_all ($makefile);
8198
8199   # FIXME: Gross!
8200   if (var ('lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
8201     {
8202       $output_rules .= "install-binPROGRAMS: install-libLTLIBRARIES\n\n";
8203     }
8204   if (var ('nobase_lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
8205     {
8206       $output_rules .= "install-binPROGRAMS: install-nobase_libLTLIBRARIES\n\n";
8207     }
8208
8209   handle_install;
8210   handle_clean ($makefile);
8211   handle_factored_dependencies;
8212
8213   # Comes last, because all the above procedures may have
8214   # defined or overridden variables.
8215   $output_vars .= output_variables;
8216
8217   check_typos;
8218
8219   if ($exit_code != 0)
8220     {
8221       verb "not writing $makefile_in because of earlier errors";
8222       return;
8223     }
8224
8225   mkdir ($am_relative_dir, 0755) if ! -d $am_relative_dir;
8226
8227   # We make sure that 'all:' is the first target.
8228   my $output =
8229     "$output_vars$output_all$output_header$output_rules$output_trailer";
8230
8231   # Decide whether we must update the output file or not.
8232   # We have to update in the following situations.
8233   #  * $force_generation is set.
8234   #  * any of the output dependencies is younger than the output
8235   #  * the contents of the output is different (this can happen
8236   #    if the project has been populated with a file listed in
8237   #    @common_files since the last run).
8238   # Output's dependencies are split in two sets:
8239   #  * dependencies which are also configure dependencies
8240   #    These do not change between each Makefile.am
8241   #  * other dependencies, specific to the Makefile.am being processed
8242   #    (such as the Makefile.am itself, or any Makefile fragment
8243   #    it includes).
8244   my $timestamp = mtime $makefile_in;
8245   if (! $force_generation
8246       && $configure_deps_greatest_timestamp < $timestamp
8247       && $output_deps_greatest_timestamp < $timestamp
8248       && $output eq contents ($makefile_in))
8249     {
8250       verb "$makefile_in unchanged";
8251       # No need to update.
8252       return;
8253     }
8254
8255   if (-e $makefile_in)
8256     {
8257       unlink ($makefile_in)
8258         or fatal "cannot remove $makefile_in: $!";
8259     }
8260
8261   my $gm_file = new Automake::XFile "> $makefile_in";
8262   verb "creating $makefile_in";
8263   print $gm_file $output;
8264 }
8265
8266 ################################################################
8267
8268
8269
8270
8271 ################################################################
8272
8273 # Helper function for usage().
8274 sub print_autodist_files (@)
8275 {
8276   my @lcomm = sort (&uniq (@_));
8277
8278   my @four;
8279   format USAGE_FORMAT =
8280   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<
8281   $four[0],           $four[1],           $four[2],           $four[3]
8282 .
8283   local $~ = "USAGE_FORMAT";
8284
8285   my $cols = 4;
8286   my $rows = int(@lcomm / $cols);
8287   my $rest = @lcomm % $cols;
8288
8289   if ($rest)
8290     {
8291       $rows++;
8292     }
8293   else
8294     {
8295       $rest = $cols;
8296     }
8297
8298   for (my $y = 0; $y < $rows; $y++)
8299     {
8300       @four = ("", "", "", "");
8301       for (my $x = 0; $x < $cols; $x++)
8302         {
8303           last if $y + 1 == $rows && $x == $rest;
8304
8305           my $idx = (($x > $rest)
8306                ?  ($rows * $rest + ($rows - 1) * ($x - $rest))
8307                : ($rows * $x));
8308
8309           $idx += $y;
8310           $four[$x] = $lcomm[$idx];
8311         }
8312       write;
8313     }
8314 }
8315
8316
8317 # Print usage information.
8318 sub usage ()
8319 {
8320     print "Usage: $0 [OPTION]... [Makefile]...
8321
8322 Generate Makefile.in for configure from Makefile.am.
8323
8324 Operation modes:
8325       --help               print this help, then exit
8326       --version            print version number, then exit
8327   -v, --verbose            verbosely list files processed
8328       --no-force           only update Makefile.in's that are out of date
8329   -W, --warnings=CATEGORY  report the warnings falling in CATEGORY
8330
8331 Dependency tracking:
8332   -i, --ignore-deps      disable dependency tracking code
8333       --include-deps     enable dependency tracking code
8334
8335 Flavors:
8336       --cygnus           assume program is part of Cygnus-style tree
8337       --foreign          set strictness to foreign
8338       --gnits            set strictness to gnits
8339       --gnu              set strictness to gnu
8340
8341 Library files:
8342   -a, --add-missing      add missing standard files to package
8343       --libdir=DIR       set directory storing library files
8344       --print-libdir     print directory storing library files
8345   -c, --copy             with -a, copy missing files (default is symlink)
8346   -f, --force-missing    force update of standard files
8347
8348 ";
8349     Automake::ChannelDefs::usage;
8350
8351     print "\nFiles automatically distributed if found " .
8352           "(always):\n";
8353     print_autodist_files @common_files;
8354     print "\nFiles automatically distributed if found " .
8355           "(under certain conditions):\n";
8356     print_autodist_files @common_sometimes;
8357
8358     print '
8359 Report bugs to <@PACKAGE_BUGREPORT@>.
8360 GNU Automake home page: <@PACKAGE_URL@>.
8361 General help using GNU software: <http://www.gnu.org/gethelp/>.
8362 ';
8363
8364     # --help always returns 0 per GNU standards.
8365     exit 0;
8366 }
8367
8368
8369 # &version ()
8370 # -----------
8371 # Print version information
8372 sub version ()
8373 {
8374   print <<EOF;
8375 automake (GNU $PACKAGE) $VERSION
8376 Copyright (C) $RELEASE_YEAR Free Software Foundation, Inc.
8377 License GPLv2+: GNU GPL version 2 or later <http://gnu.org/licenses/gpl-2.0.html>
8378 This is free software: you are free to change and redistribute it.
8379 There is NO WARRANTY, to the extent permitted by law.
8380
8381 Written by Tom Tromey <tromey\@redhat.com>
8382        and Alexandre Duret-Lutz <adl\@gnu.org>.
8383 EOF
8384   # --version always returns 0 per GNU standards.
8385   exit 0;
8386 }
8387
8388 ################################################################
8389
8390 # Parse command line.
8391 sub parse_arguments ()
8392 {
8393   my $strict = 'gnu';
8394   my $cygnus = 0;
8395   my $ignore_deps = 0;
8396   my @warnings = ();
8397
8398   my %cli_options =
8399     (
8400      'version' => \&version,
8401      'help'    => \&usage,
8402      'libdir=s' => \$libdir,
8403      'print-libdir'     => sub { print "$libdir\n"; exit 0; },
8404      'gnu'              => sub { $strict = 'gnu'; },
8405      'gnits'            => sub { $strict = 'gnits'; },
8406      'foreign'          => sub { $strict = 'foreign'; },
8407      'cygnus'           => \$cygnus,
8408      'include-deps'     => sub { $ignore_deps = 0; },
8409      'i|ignore-deps'    => sub { $ignore_deps = 1; },
8410      'no-force' => sub { $force_generation = 0; },
8411      'f|force-missing'  => \$force_missing,
8412      'a|add-missing'    => \$add_missing,
8413      'c|copy'           => \$copy_missing,
8414      'v|verbose'        => sub { setup_channel 'verb', silent => 0; },
8415      'W|warnings=s'     => \@warnings,
8416      );
8417
8418   use Automake::Getopt ();
8419   Automake::Getopt::parse_options %cli_options;
8420
8421   set_strictness ($strict);
8422   my $cli_where = new Automake::Location;
8423   set_global_option ('cygnus', $cli_where) if $cygnus;
8424   set_global_option ('no-dependencies', $cli_where) if $ignore_deps;
8425   for my $warning (@warnings)
8426     {
8427       &parse_warnings ('-W', $warning);
8428     }
8429
8430   return unless @ARGV;
8431
8432   my $errspec = 0;
8433   foreach my $arg (@ARGV)
8434     {
8435       fatal ("empty argument\nTry '$0 --help' for more information")
8436         if ($arg eq '');
8437
8438       # Handle $local:$input syntax.
8439       my ($local, @rest) = split (/:/, $arg);
8440       @rest = ("$local.in",) unless @rest;
8441       my $input = locate_am @rest;
8442       if ($input)
8443         {
8444           push @input_files, $input;
8445           $output_files{$input} = join (':', ($local, @rest));
8446         }
8447       else
8448         {
8449           error "no Automake input file found for '$arg'";
8450           $errspec = 1;
8451         }
8452     }
8453   fatal "no input file found among supplied arguments"
8454     if $errspec && ! @input_files;
8455 }
8456
8457
8458 # handle_makefile ($MAKEFILE_IN)
8459 # ------------------------------
8460 # Deal with $MAKEFILE_IN.
8461 sub handle_makefile ($)
8462 {
8463   my ($file) =  @_;
8464   ($am_file = $file) =~ s/\.in$//;
8465   if (! -f ($am_file . '.am'))
8466     {
8467       error "'$am_file.am' does not exist";
8468     }
8469   else
8470     {
8471       # Any warning setting now local to this Makefile.am.
8472       dup_channel_setup;
8473
8474       generate_makefile ($am_file . '.am', $file);
8475
8476       # Back out any warning setting.
8477       drop_channel_setup;
8478     }
8479 }
8480
8481 # handle_makefiles_serial ()
8482 # --------------------------
8483 # Deal with all makefiles, without threads.
8484 sub handle_makefiles_serial ()
8485 {
8486   foreach my $file (@input_files)
8487     {
8488       handle_makefile ($file);
8489     }
8490 }
8491
8492 # get_number_of_threads ()
8493 # ------------------------
8494 # Logic for deciding how many worker threads to use.
8495 sub get_number_of_threads
8496 {
8497   my $nthreads = $ENV{'AUTOMAKE_JOBS'} || 0;
8498
8499   $nthreads = 0
8500     unless $nthreads =~ /^[0-9]+$/;
8501
8502   # It doesn't make sense to use more threads than makefiles,
8503   my $max_threads = @input_files;
8504
8505   if ($nthreads > $max_threads)
8506     {
8507       $nthreads = $max_threads;
8508     }
8509   return $nthreads;
8510 }
8511
8512 # handle_makefiles_threaded ($NTHREADS)
8513 # -------------------------------------
8514 # Deal with all makefiles, using threads.  The general strategy is to
8515 # spawn NTHREADS worker threads, dispatch makefiles to them, and let the
8516 # worker threads push back everything that needs serialization:
8517 # * warning and (normal) error messages, for stable stderr output
8518 #   order and content (avoiding duplicates, for example),
8519 # * races when installing aux files (and respective messages),
8520 # * races when collecting aux files for distribution.
8521 #
8522 # The latter requires that the makefile that deals with the aux dir
8523 # files be handled last, done by the master thread.
8524 sub handle_makefiles_threaded ($)
8525 {
8526   my ($nthreads) = @_;
8527
8528   # The file queue distributes all makefiles, the message queues
8529   # collect all serializations needed for respective files.
8530   my $file_queue = Thread::Queue->new;
8531   my %msg_queues;
8532   foreach my $file (@input_files)
8533     {
8534       $msg_queues{$file} = Thread::Queue->new;
8535     }
8536
8537   verb "spawning $nthreads worker threads";
8538   my @threads = (1 .. $nthreads);
8539   foreach my $t (@threads)
8540     {
8541       $t = threads->new (sub
8542         {
8543           while (my $file = $file_queue->dequeue)
8544             {
8545               verb "handling $file";
8546               my $queue = $msg_queues{$file};
8547               setup_channel_queue ($queue, QUEUE_MESSAGE);
8548               $required_conf_file_queue = $queue;
8549               handle_makefile ($file);
8550               $queue->enqueue (undef);
8551               setup_channel_queue (undef, undef);
8552               $required_conf_file_queue = undef;
8553             }
8554           return $exit_code;
8555         });
8556     }
8557
8558   # Queue all makefiles.
8559   verb "queuing " . @input_files . " input files";
8560   $file_queue->enqueue (@input_files, (undef) x @threads);
8561
8562   # Collect and process serializations.
8563   foreach my $file (@input_files)
8564     {
8565       verb "dequeuing messages for " . $file;
8566       reset_local_duplicates ();
8567       my $queue = $msg_queues{$file};
8568       while (my $key = $queue->dequeue)
8569         {
8570           if ($key eq QUEUE_MESSAGE)
8571             {
8572               pop_channel_queue ($queue);
8573             }
8574           elsif ($key eq QUEUE_CONF_FILE)
8575             {
8576               require_queued_file_check_or_copy ($queue);
8577             }
8578           else
8579             {
8580               prog_error "unexpected key $key";
8581             }
8582         }
8583     }
8584
8585   foreach my $t (@threads)
8586     {
8587       my @exit_thread = $t->join;
8588       $exit_code = $exit_thread[0]
8589         if ($exit_thread[0] > $exit_code);
8590     }
8591 }
8592
8593 ################################################################
8594
8595 # Parse the WARNINGS environment variable.
8596 parse_WARNINGS;
8597
8598 # Parse command line.
8599 parse_arguments;
8600
8601 $configure_ac = require_configure_ac;
8602
8603 # Do configure.ac scan only once.
8604 scan_autoconf_files;
8605
8606 if (! @input_files)
8607   {
8608     my $msg = '';
8609     $msg = "\nDid you forget AC_CONFIG_FILES([Makefile]) in $configure_ac?"
8610       if -f 'Makefile.am';
8611     fatal ("no 'Makefile.am' found for any configure output$msg");
8612   }
8613
8614 my $nthreads = get_number_of_threads ();
8615
8616 if ($perl_threads && $nthreads >= 1)
8617   {
8618     handle_makefiles_threaded ($nthreads);
8619   }
8620 else
8621   {
8622     handle_makefiles_serial ();
8623   }
8624
8625 exit $exit_code;
8626
8627
8628 ### Setup "GNU" style for perl-mode and cperl-mode.
8629 ## Local Variables:
8630 ## perl-indent-level: 2
8631 ## perl-continued-statement-offset: 2
8632 ## perl-continued-brace-offset: 0
8633 ## perl-brace-offset: 0
8634 ## perl-brace-imaginary-offset: 0
8635 ## perl-label-offset: -2
8636 ## cperl-indent-level: 2
8637 ## cperl-brace-offset: 0
8638 ## cperl-continued-brace-offset: 0
8639 ## cperl-label-offset: -2
8640 ## cperl-extra-newline-before-brace: t
8641 ## cperl-merge-trailing-else: nil
8642 ## cperl-continued-statement-offset: 2
8643 ## End: