automake.in

   1 #!@PERL@ -w
   2 # -*- perl -*-
   3 # @configure_input@
   4
   5 eval 'case $# in 0) exec @PERL@ -S "$0";; *) exec @PERL@ -S "$0" "$@";; esac'
   6     if 0;
   7
   8 # automake - create Makefile.in from Makefile.am
   9 # Copyright (C) 1994-2012 Free Software Foundation, Inc.
  10
  11 # This program is free software; you can redistribute it and/or modify
  12 # it under the terms of the GNU General Public License as published by
  13 # the Free Software Foundation; either version 2, or (at your option)
  14 # any later version.
  15
  16 # This program is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 # GNU General Public License for more details.
  20
  21 # You should have received a copy of the GNU General Public License
  22 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 # Originally written by David Mackenzie <djm@gnu.ai.mit.edu>.
  25 # Perl reimplementation by Tom Tromey <tromey@redhat.com>, and
  26 # Alexandre Duret-Lutz <adl@gnu.org>.
  27
  28 package Language;
  29
  30 BEGIN
  31 {
  32   my $perllibdir = $ENV{'perllibdir'} || '@datadir@/@PACKAGE@-@APIVERSION@';
  33   unshift @INC, (split '@PATH_SEPARATOR@', $perllibdir);
  34
  35   # Override SHELL.  This is required on DJGPP so that system() uses
  36   # bash, not COMMAND.COM which doesn't quote arguments properly.
  37   # Other systems aren't expected to use $SHELL when Automake
  38   # runs, but it should be safe to drop the "if DJGPP" guard if
  39   # it turns up other systems need the same thing.  After all,
  40   # if SHELL is used, ./configure's SHELL is always better than
  41   # the user's SHELL (which may be something like tcsh).
  42   $ENV{'SHELL'} = '@SHELL@' if exists $ENV{'DJDIR'};
  43 }
  44
  45 use Class::Struct ();
  46 Class::Struct::struct (
  47         # Short name of the language (c, f77...).
  48         'name' => "\$",
  49         # Nice name of the language (C, Fortran 77...).
  50         'Name' => "\$",
  51
  52         # List of configure variables which must be defined.
  53         'config_vars' => '@',
  54
  55         # 'pure' is '1' or ''.  A 'pure' language is one where, if
  56         # all the files in a directory are of that language, then we
  57         # do not require the C compiler or any code to call it.
  58         'pure'   => "\$",
  59
  60         'autodep' => "\$",
  61
  62         # Name of the compiling variable (COMPILE).
  63         'compiler'  => "\$",
  64         # Content of the compiling variable.
  65         'compile'  => "\$",
  66         # Flag to require compilation without linking (-c).
  67         'compile_flag' => "\$",
  68         'extensions' => '@',
  69         # A subroutine to compute a list of possible extensions of
  70         # the product given the input extensions.
  71         # (defaults to a subroutine which returns ('.$(OBJEXT)', '.lo'))
  72         'output_extensions' => "\$",
  73         # A list of flag variables used in 'compile'.
  74         # (defaults to [])
  75         'flags' => "@",
  76
  77         # Any tag to pass to libtool while compiling.
  78         'libtool_tag' => "\$",
  79
  80         # The file to use when generating rules for this language.
  81         # The default is 'depend2'.
  82         'rule_file' => "\$",
  83
  84         # Name of the linking variable (LINK).
  85         'linker' => "\$",
  86         # Content of the linking variable.
  87         'link' => "\$",
  88
  89         # Name of the compiler variable (CC).
  90         'ccer' => "\$",
  91
  92         # Name of the linker variable (LD).
  93         'lder' => "\$",
  94         # Content of the linker variable ($(CC)).
  95         'ld' => "\$",
  96
  97         # Flag to specify the output file (-o).
  98         'output_flag' => "\$",
  99         '_finish' => "\$",
 100
 101         # This is a subroutine which is called whenever we finally
 102         # determine the context in which a source file will be
 103         # compiled.
 104         '_target_hook' => "\$",
 105
 106         # If TRUE, nodist_ sources will be compiled using specific rules
 107         # (i.e. not inference rules).  The default is FALSE.
 108         'nodist_specific' => "\$");
 109
 110
 111 sub finish ($)
 112 {
 113   my ($self) = @_;
 114   if (defined $self->_finish)
 115     {
 116       &{$self->_finish} (@_);
 117     }
 118 }
 119
 120 sub target_hook ($$$$%)
 121 {
 122     my ($self) = @_;
 123     if (defined $self->_target_hook)
 124     {
 125         &{$self->_target_hook} (@_);
 126     }
 127 }
 128
 129 package Automake;
 130
 131 use strict;
 132 use Automake::Config;
 133 BEGIN
 134 {
 135   if ($perl_threads)
 136     {
 137       require threads;
 138       import threads;
 139       require Thread::Queue;
 140       import Thread::Queue;
 141     }
 142 }
 143 use Automake::General;
 144 use Automake::XFile;
 145 use Automake::Channels;
 146 use Automake::ChannelDefs;
 147 use Automake::Configure_ac;
 148 use Automake::FileUtils;
 149 use Automake::Location;
 150 use Automake::Condition qw/TRUE FALSE/;
 151 use Automake::DisjConditions;
 152 use Automake::Options;
 153 use Automake::Variable;
 154 use Automake::VarDef;
 155 use Automake::Rule;
 156 use Automake::RuleDef;
 157 use Automake::Wrap 'makefile_wrap';
 158 use File::Basename;
 159 use File::Spec;
 160 use Carp;
 161
 162 ## ----------- ##
 163 ## Constants.  ##
 164 ## ----------- ##
 165
 166 # Some regular expressions.  One reason to put them here is that it
 167 # makes indentation work better in Emacs.
 168
 169 # Writing singled-quoted-$-terminated regexes is a pain because
 170 # perl-mode thinks of $' as the ${'} variable (instead of a $ followed
 171 # by a closing quote.  Letting perl-mode think the quote is not closed
 172 # leads to all sort of misindentations.  On the other hand, defining
 173 # regexes as double-quoted strings is far less readable.  So usually
 174 # we will write:
 175 #
 176 #  $REGEX = '^regex_value' . "\$";
 177
 178 my $IGNORE_PATTERN = '^\s*##([^#\n].*)?\n';
 179 my $WHITE_PATTERN = '^\s*' . "\$";
 180 my $COMMENT_PATTERN = '^#';
 181 my $TARGET_PATTERN='[$a-zA-Z0-9_.@%][-.a-zA-Z0-9_(){}/$+@%]*';
 182 # A rule has three parts: a list of targets, a list of dependencies,
 183 # and optionally actions.
 184 my $RULE_PATTERN =
 185   "^($TARGET_PATTERN(?:(?:\\\\\n|\\s)+$TARGET_PATTERN)*) *:([^=].*|)\$";
 186
 187 # Only recognize leading spaces, not leading tabs.  If we recognize
 188 # leading tabs here then we need to make the reader smarter, because
 189 # otherwise it will think rules like 'foo=bar; \' are errors.
 190 my $ASSIGNMENT_PATTERN = '^ *([^ \t=:+]*)\s*([:+]?)=\s*(.*)' . "\$";
 191 # This pattern recognizes a Gnits version id and sets $1 if the
 192 # release is an alpha release.  We also allow a suffix which can be
 193 # used to extend the version number with a "fork" identifier.
 194 my $GNITS_VERSION_PATTERN = '\d+\.\d+([a-z]|\.\d+)?(-[A-Za-z0-9]+)?';
 195
 196 my $IF_PATTERN = '^if\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*)\s*(?:#.*)?' . "\$";
 197 my $ELSE_PATTERN =
 198   '^else(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 199 my $ENDIF_PATTERN =
 200   '^endif(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 201 my $PATH_PATTERN = '(\w|[+/.-])+';
 202 # This will pass through anything not of the prescribed form.
 203 my $INCLUDE_PATTERN = ('^include\s+'
 204                        . '((\$\(top_srcdir\)/' . $PATH_PATTERN . ')'
 205                        . '|(\$\(srcdir\)/' . $PATH_PATTERN . ')'
 206                        . '|([^/\$]' . $PATH_PATTERN . '))\s*(#.*)?' . "\$");
 207
 208 # Directories installed during 'install-exec' phase.
 209 my $EXEC_DIR_PATTERN =
 210   '^(?:bin|sbin|libexec|sysconf|localstate|lib|pkglib|.*exec.*)' . "\$";
 211
 212 # Values for AC_CANONICAL_*
 213 use constant AC_CANONICAL_BUILD  => 1;
 214 use constant AC_CANONICAL_HOST   => 2;
 215 use constant AC_CANONICAL_TARGET => 3;
 216
 217 # Values indicating when something should be cleaned.
 218 use constant MOSTLY_CLEAN     => 0;
 219 use constant CLEAN            => 1;
 220 use constant DIST_CLEAN       => 2;
 221 use constant MAINTAINER_CLEAN => 3;
 222
 223 # Libtool files.
 224 my @libtool_files = qw(ltmain.sh config.guess config.sub);
 225 # ltconfig appears here for compatibility with old versions of libtool.
 226 my @libtool_sometimes = qw(ltconfig ltcf-c.sh ltcf-cxx.sh ltcf-gcj.sh);
 227
 228 # Commonly found files we look for and automatically include in
 229 # DISTFILES.
 230 my @common_files =
 231     (qw(ABOUT-GNU ABOUT-NLS AUTHORS BACKLOG COPYING COPYING.DOC COPYING.LIB
 232         COPYING.LESSER ChangeLog INSTALL NEWS README THANKS TODO
 233         ar-lib compile config.guess config.rpath
 234         config.sub depcomp elisp-comp install-sh libversion.in mdate-sh
 235         missing mkinstalldirs py-compile texinfo.tex ylwrap),
 236      @libtool_files, @libtool_sometimes);
 237
 238 # Commonly used files we auto-include, but only sometimes.  This list
 239 # is used for the --help output only.
 240 my @common_sometimes =
 241   qw(aclocal.m4 acconfig.h config.h.top config.h.bot configure
 242      configure.ac configure.in stamp-vti);
 243
 244 # Standard directories from the GNU Coding Standards, and additional
 245 # pkg* directories from Automake.  Stored in a hash for fast member check.
 246 my %standard_prefix =
 247     map { $_ => 1 } (qw(bin data dataroot doc dvi exec html include info
 248                         lib libexec lisp locale localstate man man1 man2
 249                         man3 man4 man5 man6 man7 man8 man9 oldinclude pdf
 250                         pkgdata pkginclude pkglib pkglibexec ps sbin
 251                         sharedstate sysconf));
 252
 253 # Copyright on generated Makefile.ins.
 254 my $gen_copyright = "\
 255 # Copyright (C) 1994-$RELEASE_YEAR Free Software Foundation, Inc.
 256
 257 # This Makefile.in is free software; the Free Software Foundation
 258 # gives unlimited permission to copy and/or distribute it,
 259 # with or without modifications, as long as this notice is preserved.
 260
 261 # This program is distributed in the hope that it will be useful,
 262 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
 263 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 264 # PARTICULAR PURPOSE.
 265 ";
 266
 267 # These constants are returned by the lang_*_rewrite functions.
 268 # LANG_SUBDIR means that the resulting object file should be in a
 269 # subdir if the source file is.  In this case the file name cannot
 270 # have '..' components.
 271 use constant LANG_IGNORE  => 0;
 272 use constant LANG_PROCESS => 1;
 273 use constant LANG_SUBDIR  => 2;
 274
 275 # These are used when keeping track of whether an object can be built
 276 # by two different paths.
 277 use constant COMPILE_LIBTOOL  => 1;
 278 use constant COMPILE_ORDINARY => 2;
 279
 280 # We can't always associate a location to a variable or a rule,
 281 # when it's defined by Automake.  We use INTERNAL in this case.
 282 use constant INTERNAL => new Automake::Location;
 283
 284 # Serialization keys for message queues.
 285 use constant QUEUE_MESSAGE   => "msg";
 286 use constant QUEUE_CONF_FILE => "conf file";
 287 use constant QUEUE_LOCATION  => "location";
 288 use constant QUEUE_STRING    => "string";
 289
 290 ## ---------------------------------- ##
 291 ## Variables related to the options.  ##
 292 ## ---------------------------------- ##
 293
 294 # TRUE if we should always generate Makefile.in.
 295 my $force_generation = 1;
 296
 297 # From the Perl manual.
 298 my $symlink_exists = (eval 'symlink ("", "");', $@ eq '');
 299
 300 # TRUE if missing standard files should be installed.
 301 my $add_missing = 0;
 302
 303 # TRUE if we should copy missing files; otherwise symlink if possible.
 304 my $copy_missing = 0;
 305
 306 # TRUE if we should always update files that we know about.
 307 my $force_missing = 0;
 308
 309
 310 ## ---------------------------------------- ##
 311 ## Variables filled during files scanning.  ##
 312 ## ---------------------------------------- ##
 313
 314 # Name of the configure.ac file.
 315 my $configure_ac;
 316
 317 # Files found by scanning configure.ac for LIBOBJS.
 318 my %libsources = ();
 319
 320 # Names used in AC_CONFIG_HEADER call.
 321 my @config_headers = ();
 322
 323 # Names used in AC_CONFIG_LINKS call.
 324 my @config_links = ();
 325
 326 # List of Makefile.am's to process, and their corresponding outputs.
 327 my @input_files = ();
 328 my %output_files = ();
 329
 330 # Complete list of Makefile.am's that exist.
 331 my @configure_input_files = ();
 332
 333 # List of files in AC_CONFIG_FILES/AC_OUTPUT without Makefile.am's,
 334 # and their outputs.
 335 my @other_input_files = ();
 336 # Where each AC_CONFIG_FILES/AC_OUTPUT/AC_CONFIG_LINK/AC_CONFIG_HEADER appears.
 337 # The keys are the files created by these macros.
 338 my %ac_config_files_location = ();
 339 # The condition under which AC_CONFIG_FOOS appears.
 340 my %ac_config_files_condition = ();
 341
 342 # Directory to search for configure-required files.  This
 343 # will be computed by &locate_aux_dir and can be set using
 344 # AC_CONFIG_AUX_DIR in configure.ac.
 345 # $CONFIG_AUX_DIR is the 'raw' directory, valid only in the source-tree.
 346 my $config_aux_dir = '';
 347 my $config_aux_dir_set_in_configure_ac = 0;
 348 # $AM_CONFIG_AUX_DIR is prefixed with $(top_srcdir), so it can be used
 349 # in Makefiles.
 350 my $am_config_aux_dir = '';
 351
 352 # Directory to search for AC_LIBSOURCE files, as set by AC_CONFIG_LIBOBJ_DIR
 353 # in configure.ac.
 354 my $config_libobj_dir = '';
 355
 356 # Whether AM_GNU_GETTEXT has been seen in configure.ac.
 357 my $seen_gettext = 0;
 358 # Whether AM_GNU_GETTEXT([external]) is used.
 359 my $seen_gettext_external = 0;
 360 # Where AM_GNU_GETTEXT appears.
 361 my $ac_gettext_location;
 362 # Whether AM_GNU_GETTEXT_INTL_SUBDIR has been seen.
 363 my $seen_gettext_intl = 0;
 364
 365 # Lists of tags supported by Libtool.
 366 my %libtool_tags = ();
 367 # 1 if Libtool uses LT_SUPPORTED_TAG.  If it does, then it also
 368 # uses AC_REQUIRE_AUX_FILE.
 369 my $libtool_new_api = 0;
 370
 371 # Most important AC_CANONICAL_* macro seen so far.
 372 my $seen_canonical = 0;
 373 # Location of that macro.
 374 my $canonical_location;
 375
 376 # Where AM_MAINTAINER_MODE appears.
 377 my $seen_maint_mode;
 378
 379 # Actual version we've seen.
 380 my $package_version = '';
 381
 382 # Where version is defined.
 383 my $package_version_location;
 384
 385 # TRUE if we've seen AM_PROG_AR
 386 my $seen_ar = 0;
 387
 388 # TRUE if we've seen AM_PROG_CC_C_O
 389 my $seen_cc_c_o = 0;
 390
 391 # Location of AC_REQUIRE_AUX_FILE calls, indexed by their argument.
 392 my %required_aux_file = ();
 393
 394 # Where AM_INIT_AUTOMAKE is called;
 395 my $seen_init_automake = 0;
 396
 397 # TRUE if we've seen AM_AUTOMAKE_VERSION.
 398 my $seen_automake_version = 0;
 399
 400 # Hash table of discovered configure substitutions.  Keys are names,
 401 # values are 'FILE:LINE' strings which are used by error message
 402 # generation.
 403 my %configure_vars = ();
 404
 405 # Ignored configure substitutions (i.e., variables not to be output in
 406 # Makefile.in)
 407 my %ignored_configure_vars = ();
 408
 409 # Files included by $configure_ac.
 410 my @configure_deps = ();
 411
 412 # Greatest timestamp of configure's dependencies.
 413 my $configure_deps_greatest_timestamp = 0;
 414
 415 # Hash table of AM_CONDITIONAL variables seen in configure.
 416 my %configure_cond = ();
 417
 418 # This maps extensions onto language names.
 419 my %extension_map = ();
 420
 421 # List of the DIST_COMMON files we discovered while reading
 422 # configure.ac.
 423 my $configure_dist_common = '';
 424
 425 # This maps languages names onto objects.
 426 my %languages = ();
 427 # Maps each linker variable onto a language object.
 428 my %link_languages = ();
 429
 430 # maps extensions to needed source flags.
 431 my %sourceflags = ();
 432
 433 # List of targets we must always output.
 434 # FIXME: Complete, and remove falsely required targets.
 435 my %required_targets =
 436   (
 437    'all'          => 1,
 438    'dvi'          => 1,
 439    'pdf'          => 1,
 440    'ps'           => 1,
 441    'info'         => 1,
 442    'install-info' => 1,
 443    'install'      => 1,
 444    'install-data' => 1,
 445    'install-exec' => 1,
 446    'uninstall'    => 1,
 447
 448    # FIXME: Not required, temporary hacks.
 449    # Well, actually they are sort of required: the -recursive
 450    # targets will run them anyway...
 451    'html-am'         => 1,
 452    'dvi-am'          => 1,
 453    'pdf-am'          => 1,
 454    'ps-am'           => 1,
 455    'info-am'         => 1,
 456    'install-data-am' => 1,
 457    'install-exec-am' => 1,
 458    'install-html-am' => 1,
 459    'install-dvi-am'  => 1,
 460    'install-pdf-am'  => 1,
 461    'install-ps-am'   => 1,
 462    'install-info-am' => 1,
 463    'installcheck-am' => 1,
 464    'uninstall-am' => 1,
 465
 466    'install-man' => 1,
 467   );
 468
 469 # Queue to push require_conf_file requirements to.
 470 my $required_conf_file_queue;
 471
 472 # The name of the Makefile currently being processed.
 473 my $am_file = 'BUG';
 474
 475 ################################################################
 476
 477 ## ------------------------------------------ ##
 478 ## Variables reset by &initialize_per_input.  ##
 479 ## ------------------------------------------ ##
 480
 481 # Basename and relative dir of the input file.
 482 my $am_file_name;
 483 my $am_relative_dir;
 484
 485 # Same but wrt Makefile.in.
 486 my $in_file_name;
 487 my $relative_dir;
 488
 489 # Relative path to the top directory.
 490 my $topsrcdir;
 491
 492 # Greatest timestamp of the output's dependencies (excluding
 493 # configure's dependencies).
 494 my $output_deps_greatest_timestamp;
 495
 496 # These variables are used when generating each Makefile.in.
 497 # They hold the Makefile.in until it is ready to be printed.
 498 my $output_vars;
 499 my $output_all;
 500 my $output_header;
 501 my $output_rules;
 502 my $output_trailer;
 503
 504 # This is the conditional stack, updated on if/else/endif, and
 505 # used to build Condition objects.
 506 my @cond_stack;
 507
 508 # This holds the set of included files.
 509 my @include_stack;
 510
 511 # List of dependencies for the obvious targets.
 512 my @all;
 513 my @check;
 514 my @check_tests;
 515
 516 # Keys in this hash table are files to delete.  The associated
 517 # value tells when this should happen (MOSTLY_CLEAN, DIST_CLEAN, etc.)
 518 my %clean_files;
 519
 520 # Keys in this hash table are object files or other files in
 521 # subdirectories which need to be removed.  This only holds files
 522 # which are created by compilations.  The value in the hash indicates
 523 # when the file should be removed.
 524 my %compile_clean_files;
 525
 526 # Keys in this hash table are directories where we expect to build a
 527 # libtool object.  We use this information to decide what directories
 528 # to delete.
 529 my %libtool_clean_directories;
 530
 531 # Value of $(SOURCES), used by tags.am.
 532 my @sources;
 533 # Sources which go in the distribution.
 534 my @dist_sources;
 535
 536 # This hash maps object file names onto their corresponding source
 537 # file names.  This is used to ensure that each object is created
 538 # by a single source file.
 539 my %object_map;
 540
 541 # This hash maps object file names onto an integer value representing
 542 # whether this object has been built via ordinary compilation or
 543 # libtool compilation (the COMPILE_* constants).
 544 my %object_compilation_map;
 545
 546
 547 # This keeps track of the directories for which we've already
 548 # created dirstamp code.  Keys are directories, values are stamp files.
 549 # Several keys can share the same stamp files if they are equivalent
 550 # (as are './/foo' and 'foo').
 551 my %directory_map;
 552
 553 # All .P files.
 554 my %dep_files;
 555
 556 # This is a list of all targets to run during "make dist".
 557 my @dist_targets;
 558
 559 # Keep track of all programs declared in this Makefile, without
 560 # $(EXEEXT).  @substitutions@ are not listed.
 561 my %known_programs;
 562 my %known_libraries;
 563
 564 # This keeps track of which extensions we've seen (that we care
 565 # about).
 566 my %extension_seen;
 567
 568 # This is random scratch space for the language finish functions.
 569 # Don't randomly overwrite it; examine other uses of keys first.
 570 my %language_scratch;
 571
 572 # We keep track of which objects need special (per-executable)
 573 # handling on a per-language basis.
 574 my %lang_specific_files;
 575
 576 # This is set when 'handle_dist' has finished.  Once this happens,
 577 # we should no longer push on dist_common.
 578 my $handle_dist_run;
 579
 580 # Used to store a set of linkers needed to generate the sources currently
 581 # under consideration.
 582 my %linkers_used;
 583
 584 # True if we need 'LINK' defined.  This is a hack.
 585 my $need_link;
 586
 587 # Does the generated Makefile have to build some compiled object
 588 # (for binary programs, or plain or libtool libraries)?
 589 my $must_handle_compiled_objects;
 590
 591 # Record each file processed by make_paragraphs.
 592 my %transformed_files;
 593
 594 ################################################################
 595
 596 ## ---------------------------------------------- ##
 597 ## Variables not reset by &initialize_per_input.  ##
 598 ## ---------------------------------------------- ##
 599
 600 # Cache each file processed by make_paragraphs.
 601 # (This is different from %transformed_files because
 602 # %transformed_files is reset for each file while %am_file_cache
 603 # it global to the run.)
 604 my %am_file_cache;
 605
 606 ################################################################
 607
 608 # var_SUFFIXES_trigger ($TYPE, $VALUE)
 609 # ------------------------------------
 610 # This is called by Automake::Variable::define() when SUFFIXES
 611 # is defined ($TYPE eq '') or appended ($TYPE eq '+').
 612 # The work here needs to be performed as a side-effect of the
 613 # macro_define() call because SUFFIXES definitions impact
 614 # on $KNOWN_EXTENSIONS_PATTERN which is used used when parsing
 615 # the input am file.
 616 sub var_SUFFIXES_trigger ($$)
 617 {
 618     my ($type, $value) = @_;
 619     accept_extensions (split (' ', $value));
 620 }
 621 Automake::Variable::hook ('SUFFIXES', \&var_SUFFIXES_trigger);
 622
 623 ################################################################
 624
 625 ## --------------------------------- ##
 626 ## Forward subroutine declarations.  ##
 627 ## --------------------------------- ##
 628 sub register_language (%);
 629 sub file_contents_internal ($$$%);
 630 sub define_files_variable ($\@$$);
 631
 632
 633 # &initialize_per_input ()
 634 # ------------------------
 635 # (Re)-Initialize per-Makefile.am variables.
 636 sub initialize_per_input ()
 637 {
 638     reset_local_duplicates ();
 639
 640     $am_file_name = undef;
 641     $am_relative_dir = undef;
 642
 643     $in_file_name = undef;
 644     $relative_dir = undef;
 645     $topsrcdir = undef;
 646
 647     $output_deps_greatest_timestamp = 0;
 648
 649     $output_vars = '';
 650     $output_all = '';
 651     $output_header = '';
 652     $output_rules = '';
 653     $output_trailer = '';
 654
 655     Automake::Options::reset;
 656     Automake::Variable::reset;
 657     Automake::Rule::reset;
 658
 659     @cond_stack = ();
 660
 661     @include_stack = ();
 662
 663     @all = ();
 664     @check = ();
 665     @check_tests = ();
 666
 667     %clean_files = ();
 668     %compile_clean_files = ();
 669
 670     # We always include '.'.  This isn't strictly correct.
 671     %libtool_clean_directories = ('.' => 1);
 672
 673     @sources = ();
 674     @dist_sources = ();
 675
 676     %object_map = ();
 677     %object_compilation_map = ();
 678
 679     %directory_map = ();
 680
 681     %dep_files = ();
 682
 683     @dist_targets = ();
 684
 685     %known_programs = ();
 686     %known_libraries= ();
 687
 688     %extension_seen = ();
 689
 690     %language_scratch = ();
 691
 692     %lang_specific_files = ();
 693
 694     $handle_dist_run = 0;
 695
 696     $need_link = 0;
 697
 698     $must_handle_compiled_objects = 0;
 699
 700     %transformed_files = ();
 701 }
 702
 703
 704 ################################################################
 705
 706 # Initialize our list of languages that are internally supported.
 707
 708 # C.
 709 register_language ('name' => 'c',
 710                    'Name' => 'C',
 711                    'config_vars' => ['CC'],
 712                    'autodep' => '',
 713                    'flags' => ['CFLAGS', 'CPPFLAGS'],
 714                    'ccer' => 'CC',
 715                    'compiler' => 'COMPILE',
 716                    'compile' => '$(CC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CFLAGS) $(CFLAGS)',
 717                    'lder' => 'CCLD',
 718                    'ld' => '$(CC)',
 719                    'linker' => 'LINK',
 720                    'link' => '$(CCLD) $(AM_CFLAGS) $(CFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 721                    'compile_flag' => '-c',
 722                    'libtool_tag' => 'CC',
 723                    'extensions' => ['.c']);
 724
 725 # C++.
 726 register_language ('name' => 'cxx',
 727                    'Name' => 'C++',
 728                    'config_vars' => ['CXX'],
 729                    'linker' => 'CXXLINK',
 730                    'link' => '$(CXXLD) $(AM_CXXFLAGS) $(CXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 731                    'autodep' => 'CXX',
 732                    'flags' => ['CXXFLAGS', 'CPPFLAGS'],
 733                    'compile' => '$(CXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CXXFLAGS) $(CXXFLAGS)',
 734                    'ccer' => 'CXX',
 735                    'compiler' => 'CXXCOMPILE',
 736                    'compile_flag' => '-c',
 737                    'output_flag' => '-o',
 738                    'libtool_tag' => 'CXX',
 739                    'lder' => 'CXXLD',
 740                    'ld' => '$(CXX)',
 741                    'pure' => 1,
 742                    'extensions' => ['.c++', '.cc', '.cpp', '.cxx', '.C']);
 743
 744 # Objective C.
 745 register_language ('name' => 'objc',
 746                    'Name' => 'Objective C',
 747                    'config_vars' => ['OBJC'],
 748                    'linker' => 'OBJCLINK',
 749                    'link' => '$(OBJCLD) $(AM_OBJCFLAGS) $(OBJCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 750                    'autodep' => 'OBJC',
 751                    'flags' => ['OBJCFLAGS', 'CPPFLAGS'],
 752                    'compile' => '$(OBJC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCFLAGS) $(OBJCFLAGS)',
 753                    'ccer' => 'OBJC',
 754                    'compiler' => 'OBJCCOMPILE',
 755                    'compile_flag' => '-c',
 756                    'output_flag' => '-o',
 757                    'lder' => 'OBJCLD',
 758                    'ld' => '$(OBJC)',
 759                    'pure' => 1,
 760                    'extensions' => ['.m']);
 761
 762 # Objective C++.
 763 register_language ('name' => 'objcxx',
 764                    'Name' => 'Objective C++',
 765                    'config_vars' => ['OBJCXX'],
 766                    'linker' => 'OBJCXXLINK',
 767                    'link' => '$(OBJCXXLD) $(AM_OBJCXXFLAGS) $(OBJCXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 768                    'autodep' => 'OBJCXX',
 769                    'flags' => ['OBJCXXFLAGS', 'CPPFLAGS'],
 770                    'compile' => '$(OBJCXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCXXFLAGS) $(OBJCXXFLAGS)',
 771                    'ccer' => 'OBJCXX',
 772                    'compiler' => 'OBJCXXCOMPILE',
 773                    'compile_flag' => '-c',
 774                    'output_flag' => '-o',
 775                    'lder' => 'OBJCXXLD',
 776                    'ld' => '$(OBJCXX)',
 777                    'pure' => 1,
 778                    'extensions' => ['.mm']);
 779
 780 # Unified Parallel C.
 781 register_language ('name' => 'upc',
 782                    'Name' => 'Unified Parallel C',
 783                    'config_vars' => ['UPC'],
 784                    'linker' => 'UPCLINK',
 785                    'link' => '$(UPCLD) $(AM_UPCFLAGS) $(UPCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 786                    'autodep' => 'UPC',
 787                    'flags' => ['UPCFLAGS', 'CPPFLAGS'],
 788                    'compile' => '$(UPC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_UPCFLAGS) $(UPCFLAGS)',
 789                    'ccer' => 'UPC',
 790                    'compiler' => 'UPCCOMPILE',
 791                    'compile_flag' => '-c',
 792                    'output_flag' => '-o',
 793                    'lder' => 'UPCLD',
 794                    'ld' => '$(UPC)',
 795                    'pure' => 1,
 796                    'extensions' => ['.upc']);
 797
 798 # Headers.
 799 register_language ('name' => 'header',
 800                    'Name' => 'Header',
 801                    'extensions' => ['.h', '.H', '.hxx', '.h++', '.hh',
 802                                     '.hpp', '.inc'],
 803                    # No output.
 804                    'output_extensions' => sub { return () },
 805                    # Nothing to do.
 806                    '_finish' => sub { });
 807
 808 # Vala
 809 register_language ('name' => 'vala',
 810                    'Name' => 'Vala',
 811                    'config_vars' => ['VALAC'],
 812                    'flags' => [],
 813                    'compile' => '$(VALAC) $(AM_VALAFLAGS) $(VALAFLAGS)',
 814                    'ccer' => 'VALAC',
 815                    'compiler' => 'VALACOMPILE',
 816                    'extensions' => ['.vala'],
 817                    'output_extensions' => sub { (my $ext = $_[0]) =~ s/vala$/c/;
 818                                                 return ($ext,) },
 819                    'rule_file' => 'vala',
 820                    '_finish' => \&lang_vala_finish,
 821                    '_target_hook' => \&lang_vala_target_hook,
 822                    'nodist_specific' => 1);
 823
 824 # Yacc (C & C++).
 825 register_language ('name' => 'yacc',
 826                    'Name' => 'Yacc',
 827                    'config_vars' => ['YACC'],
 828                    'flags' => ['YFLAGS'],
 829                    'compile' => '$(YACC) $(AM_YFLAGS) $(YFLAGS)',
 830                    'ccer' => 'YACC',
 831                    'compiler' => 'YACCCOMPILE',
 832                    'extensions' => ['.y'],
 833                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 834                                                 return ($ext,) },
 835                    'rule_file' => 'yacc',
 836                    '_finish' => \&lang_yacc_finish,
 837                    '_target_hook' => \&lang_yacc_target_hook,
 838                    'nodist_specific' => 1);
 839 register_language ('name' => 'yaccxx',
 840                    'Name' => 'Yacc (C++)',
 841                    'config_vars' => ['YACC'],
 842                    'rule_file' => 'yacc',
 843                    'flags' => ['YFLAGS'],
 844                    'ccer' => 'YACC',
 845                    'compiler' => 'YACCCOMPILE',
 846                    'compile' => '$(YACC) $(AM_YFLAGS) $(YFLAGS)',
 847                    'extensions' => ['.y++', '.yy', '.yxx', '.ypp'],
 848                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 849                                                 return ($ext,) },
 850                    '_finish' => \&lang_yacc_finish,
 851                    '_target_hook' => \&lang_yacc_target_hook,
 852                    'nodist_specific' => 1);
 853
 854 # Lex (C & C++).
 855 register_language ('name' => 'lex',
 856                    'Name' => 'Lex',
 857                    'config_vars' => ['LEX'],
 858                    'rule_file' => 'lex',
 859                    'flags' => ['LFLAGS'],
 860                    'compile' => '$(LEX) $(AM_LFLAGS) $(LFLAGS)',
 861                    'ccer' => 'LEX',
 862                    'compiler' => 'LEXCOMPILE',
 863                    'extensions' => ['.l'],
 864                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 865                                                 return ($ext,) },
 866                    '_finish' => \&lang_lex_finish,
 867                    '_target_hook' => \&lang_lex_target_hook,
 868                    'nodist_specific' => 1);
 869 register_language ('name' => 'lexxx',
 870                    'Name' => 'Lex (C++)',
 871                    'config_vars' => ['LEX'],
 872                    'rule_file' => 'lex',
 873                    'flags' => ['LFLAGS'],
 874                    'compile' => '$(LEX) $(AM_LFLAGS) $(LFLAGS)',
 875                    'ccer' => 'LEX',
 876                    'compiler' => 'LEXCOMPILE',
 877                    'extensions' => ['.l++', '.ll', '.lxx', '.lpp'],
 878                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 879                                                 return ($ext,) },
 880                    '_finish' => \&lang_lex_finish,
 881                    '_target_hook' => \&lang_lex_target_hook,
 882                    'nodist_specific' => 1);
 883
 884 # Assembler.
 885 register_language ('name' => 'asm',
 886                    'Name' => 'Assembler',
 887                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 888
 889                    'flags' => ['CCASFLAGS'],
 890                    # Users can set AM_CCASFLAGS to include DEFS, INCLUDES,
 891                    # or anything else required.  They can also set CCAS.
 892                    # Or simply use Preprocessed Assembler.
 893                    'compile' => '$(CCAS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 894                    'ccer' => 'CCAS',
 895                    'compiler' => 'CCASCOMPILE',
 896                    'compile_flag' => '-c',
 897                    'output_flag' => '-o',
 898                    'extensions' => ['.s']);
 899
 900 # Preprocessed Assembler.
 901 register_language ('name' => 'cppasm',
 902                    'Name' => 'Preprocessed Assembler',
 903                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 904
 905                    'autodep' => 'CCAS',
 906                    'flags' => ['CCASFLAGS', 'CPPFLAGS'],
 907                    'compile' => '$(CCAS) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 908                    'ccer' => 'CPPAS',
 909                    'compiler' => 'CPPASCOMPILE',
 910                    'compile_flag' => '-c',
 911                    'output_flag' => '-o',
 912                    'extensions' => ['.S', '.sx']);
 913
 914 # Fortran 77
 915 register_language ('name' => 'f77',
 916                    'Name' => 'Fortran 77',
 917                    'config_vars' => ['F77'],
 918                    'linker' => 'F77LINK',
 919                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 920                    'flags' => ['FFLAGS'],
 921                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS)',
 922                    'ccer' => 'F77',
 923                    'compiler' => 'F77COMPILE',
 924                    'compile_flag' => '-c',
 925                    'output_flag' => '-o',
 926                    'libtool_tag' => 'F77',
 927                    'lder' => 'F77LD',
 928                    'ld' => '$(F77)',
 929                    'pure' => 1,
 930                    'extensions' => ['.f', '.for']);
 931
 932 # Fortran
 933 register_language ('name' => 'fc',
 934                    'Name' => 'Fortran',
 935                    'config_vars' => ['FC'],
 936                    'linker' => 'FCLINK',
 937                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 938                    'flags' => ['FCFLAGS'],
 939                    'compile' => '$(FC) $(AM_FCFLAGS) $(FCFLAGS)',
 940                    'ccer' => 'FC',
 941                    'compiler' => 'FCCOMPILE',
 942                    'compile_flag' => '-c',
 943                    'output_flag' => '-o',
 944                    'libtool_tag' => 'FC',
 945                    'lder' => 'FCLD',
 946                    'ld' => '$(FC)',
 947                    'pure' => 1,
 948                    'extensions' => ['.f90', '.f95', '.f03', '.f08']);
 949
 950 # Preprocessed Fortran
 951 register_language ('name' => 'ppfc',
 952                    'Name' => 'Preprocessed Fortran',
 953                    'config_vars' => ['FC'],
 954                    'linker' => 'FCLINK',
 955                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 956                    'lder' => 'FCLD',
 957                    'ld' => '$(FC)',
 958                    'flags' => ['FCFLAGS', 'CPPFLAGS'],
 959                    'ccer' => 'PPFC',
 960                    'compiler' => 'PPFCCOMPILE',
 961                    'compile' => '$(FC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FCFLAGS) $(FCFLAGS)',
 962                    'compile_flag' => '-c',
 963                    'output_flag' => '-o',
 964                    'libtool_tag' => 'FC',
 965                    'pure' => 1,
 966                    'extensions' => ['.F90','.F95', '.F03', '.F08']);
 967
 968 # Preprocessed Fortran 77
 969 #
 970 # The current support for preprocessing Fortran 77 just involves
 971 # passing "$(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS)
 972 # $(CPPFLAGS)" as additional flags to the Fortran 77 compiler, since
 973 # this is how GNU Make does it; see the "GNU Make Manual, Edition 0.51
 974 # for 'make' Version 3.76 Beta" (specifically, from info file
 975 # '(make)Catalogue of Rules').
 976 #
 977 # A better approach would be to write an Autoconf test
 978 # (i.e. AC_PROG_FPP) for a Fortran 77 preprocessor, because not all
 979 # Fortran 77 compilers know how to do preprocessing.  The Autoconf
 980 # macro AC_PROG_FPP should test the Fortran 77 compiler first for
 981 # preprocessing capabilities, and then fall back on cpp (if cpp were
 982 # available).
 983 register_language ('name' => 'ppf77',
 984                    'Name' => 'Preprocessed Fortran 77',
 985                    'config_vars' => ['F77'],
 986                    'linker' => 'F77LINK',
 987                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 988                    'lder' => 'F77LD',
 989                    'ld' => '$(F77)',
 990                    'flags' => ['FFLAGS', 'CPPFLAGS'],
 991                    'ccer' => 'PPF77',
 992                    'compiler' => 'PPF77COMPILE',
 993                    'compile' => '$(F77) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FFLAGS) $(FFLAGS)',
 994                    'compile_flag' => '-c',
 995                    'output_flag' => '-o',
 996                    'libtool_tag' => 'F77',
 997                    'pure' => 1,
 998                    'extensions' => ['.F']);
 999
1000 # Ratfor.
1001 register_language ('name' => 'ratfor',
1002                    'Name' => 'Ratfor',
1003                    'config_vars' => ['F77'],
1004                    'linker' => 'F77LINK',
1005                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
1006                    'lder' => 'F77LD',
1007                    'ld' => '$(F77)',
1008                    'flags' => ['RFLAGS', 'FFLAGS'],
1009                    # FIXME also FFLAGS.
1010                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS) $(AM_RFLAGS) $(RFLAGS)',
1011                    'ccer' => 'F77',
1012                    'compiler' => 'RCOMPILE',
1013                    'compile_flag' => '-c',
1014                    'output_flag' => '-o',
1015                    'libtool_tag' => 'F77',
1016                    'pure' => 1,
1017                    'extensions' => ['.r']);
1018
1019 # Java via gcj.
1020 register_language ('name' => 'java',
1021                    'Name' => 'Java',
1022                    'config_vars' => ['GCJ'],
1023                    'linker' => 'GCJLINK',
1024                    'link' => '$(GCJLD) $(AM_GCJFLAGS) $(GCJFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
1025                    'autodep' => 'GCJ',
1026                    'flags' => ['GCJFLAGS'],
1027                    'compile' => '$(GCJ) $(AM_GCJFLAGS) $(GCJFLAGS)',
1028                    'ccer' => 'GCJ',
1029                    'compiler' => 'GCJCOMPILE',
1030                    'compile_flag' => '-c',
1031                    'output_flag' => '-o',
1032                    'libtool_tag' => 'GCJ',
1033                    'lder' => 'GCJLD',
1034                    'ld' => '$(GCJ)',
1035                    'pure' => 1,
1036                    'extensions' => ['.java', '.class', '.zip', '.jar']);
1037
1038 ################################################################
1039
1040 # Error reporting functions.
1041
1042 # err_am ($MESSAGE, [%OPTIONS])
1043 # -----------------------------
1044 # Uncategorized errors about the current Makefile.am.
1045 sub err_am ($;%)
1046 {
1047   msg_am ('error', @_);
1048 }
1049
1050 # err_ac ($MESSAGE, [%OPTIONS])
1051 # -----------------------------
1052 # Uncategorized errors about configure.ac.
1053 sub err_ac ($;%)
1054 {
1055   msg_ac ('error', @_);
1056 }
1057
1058 # msg_am ($CHANNEL, $MESSAGE, [%OPTIONS])
1059 # ---------------------------------------
1060 # Messages about about the current Makefile.am.
1061 sub msg_am ($$;%)
1062 {
1063   my ($channel, $msg, %opts) = @_;
1064   msg $channel, "${am_file}.am", $msg, %opts;
1065 }
1066
1067 # msg_ac ($CHANNEL, $MESSAGE, [%OPTIONS])
1068 # ---------------------------------------
1069 # Messages about about configure.ac.
1070 sub msg_ac ($$;%)
1071 {
1072   my ($channel, $msg, %opts) = @_;
1073   msg $channel, $configure_ac, $msg, %opts;
1074 }
1075
1076 ################################################################
1077
1078 # subst ($TEXT)
1079 # -------------
1080 # Return a configure-style substitution using the indicated text.
1081 # We do this to avoid having the substitutions directly in automake.in;
1082 # when we do that they are sometimes removed and this causes confusion
1083 # and bugs.
1084 sub subst ($)
1085 {
1086     my ($text) = @_;
1087     return '@' . $text . '@';
1088 }
1089
1090 ################################################################
1091
1092
1093 # $BACKPATH
1094 # &backname ($RELDIR)
1095 # --------------------
1096 # If I "cd $RELDIR", then to come back, I should "cd $BACKPATH".
1097 # For instance 'src/foo' => '../..'.
1098 # Works with non strictly increasing paths, i.e., 'src/../lib' => '..'.
1099 sub backname ($)
1100 {
1101     my ($file) = @_;
1102     my @res;
1103     foreach (split (/\//, $file))
1104     {
1105         next if $_ eq '.' || $_ eq '';
1106         if ($_ eq '..')
1107         {
1108             pop @res
1109               or prog_error ("trying to reverse path '$file' pointing outside tree");
1110         }
1111         else
1112         {
1113             push (@res, '..');
1114         }
1115     }
1116     return join ('/', @res) || '.';
1117 }
1118
1119 ################################################################
1120
1121 # 'silent-rules' mode handling functions.
1122
1123 # verbose_var (NAME)
1124 # ------------------
1125 # The public variable stem used to implement 'silent-rules'.
1126 sub verbose_var ($)
1127 {
1128     my ($name) = @_;
1129     return 'AM_V_' . $name;
1130 }
1131
1132 # verbose_private_var (NAME)
1133 # --------------------------
1134 # The naming policy for the private variables for 'silent-rules'.
1135 sub verbose_private_var ($)
1136 {
1137     my ($name) = @_;
1138     return 'am__v_' . $name;
1139 }
1140
1141 # define_verbose_var (NAME, VAL-IF-SILENT, [VAL-IF-VERBOSE])
1142 # ----------------------------------------------------------
1143 # For 'silent-rules' mode, setup VAR and dispatcher, to expand to
1144 # VAL-IF-SILENT if silent, to VAL-IF-VERBOSE (defaulting to empty)
1145 # if not.
1146 sub define_verbose_var ($$;$)
1147 {
1148     my ($name, $silent_val, $verbose_val) = @_;
1149     $verbose_val = '' unless defined $verbose_val;
1150     my $var = verbose_var ($name);
1151     my $pvar = verbose_private_var ($name);
1152     my $silent_var = $pvar . '_0';
1153     my $verbose_var = $pvar . '_1';
1154     if (option 'silent-rules')
1155       {
1156         # For typical 'make's, 'configure' replaces AM_V (inside @@) with $(V)
1157         # and AM_DEFAULT_V (inside @@) with $(AM_DEFAULT_VERBOSITY).
1158         # For strict POSIX 2008 'make's, it replaces them with 0 or 1 instead.
1159         # See AM_SILENT_RULES in m4/silent.m4.
1160         define_variable ($var, '$(' . $pvar . '_@'.'AM_V'.'@)', INTERNAL);
1161         define_variable ($pvar . '_', '$(' . $pvar . '_@'.'AM_DEFAULT_V'.'@)', INTERNAL);
1162         Automake::Variable::define ($silent_var, VAR_AUTOMAKE, '', TRUE,
1163                                     $silent_val, '', INTERNAL, VAR_ASIS)
1164           if (! vardef ($silent_var, TRUE));
1165         Automake::Variable::define ($verbose_var, VAR_AUTOMAKE, '', TRUE,
1166                                     $verbose_val, '', INTERNAL, VAR_ASIS)
1167           if (! vardef ($verbose_var, TRUE));
1168 }
1169 }
1170
1171 # Above should not be needed in the general automake code.
1172
1173 # verbose_flag (NAME)
1174 # -------------------
1175 # Contents of %VERBOSE%: variable to expand before rule command.
1176 sub verbose_flag ($)
1177 {
1178     my ($name) = @_;
1179     return '$(' . verbose_var ($name) . ')'
1180       if (option 'silent-rules');
1181     return '';
1182 }
1183
1184 sub verbose_nodep_flag ($)
1185 {
1186     my ($name) = @_;
1187     return '$(' . verbose_var ($name) . subst ('am__nodep') . ')'
1188       if (option 'silent-rules');
1189     return '';
1190 }
1191
1192 # silent_flag
1193 # -----------
1194 # Contents of %SILENT%: variable to expand to '@' when silent.
1195 sub silent_flag ()
1196 {
1197     return verbose_flag ('at');
1198 }
1199
1200 # define_verbose_tagvar (NAME)
1201 # ----------------------------
1202 # Engage the needed 'silent-rules' machinery for tag NAME.
1203 sub define_verbose_tagvar ($)
1204 {
1205     my ($name) = @_;
1206     if (option 'silent-rules')
1207       {
1208         define_verbose_var ($name, '@echo "  '. $name . ' ' x (8 - length ($name)) . '" $@;');
1209         define_verbose_var ('at', '@');
1210       }
1211 }
1212
1213 # define_verbose_texinfo
1214 # ----------------------
1215 # Engage the needed 'silent-rules' machinery for assorted texinfo commands.
1216 sub define_verbose_texinfo ()
1217 {
1218   my @tagvars = ('DVIPS', 'MAKEINFO', 'INFOHTML', 'TEXI2DVI', 'TEXI2PDF');
1219   foreach my $tag (@tagvars)
1220     {
1221       define_verbose_tagvar($tag);
1222     }
1223   define_verbose_var('texinfo', '-q');
1224   define_verbose_var('texidevnull', '> /dev/null');
1225 }
1226
1227 # define_verbose_libtool
1228 # ----------------------
1229 # Engage the needed 'silent-rules' machinery for 'libtool --silent'.
1230 sub define_verbose_libtool ()
1231 {
1232     define_verbose_var ('lt', '--silent');
1233     return verbose_flag ('lt');
1234 }
1235
1236
1237 ################################################################
1238
1239
1240 # Handle AUTOMAKE_OPTIONS variable.  Return 1 on error, 0 otherwise.
1241 sub handle_options
1242 {
1243   my $var = var ('AUTOMAKE_OPTIONS');
1244   if ($var)
1245     {
1246       if ($var->has_conditional_contents)
1247         {
1248           msg_var ('unsupported', $var,
1249                    "'AUTOMAKE_OPTIONS' cannot have conditional contents");
1250         }
1251       my @options = map { { option => $_->[1], where => $_->[0] } }
1252                         $var->value_as_list_recursive (cond_filter => TRUE,
1253                                                        location => 1);
1254       return 1 if process_option_list (@options);
1255     }
1256
1257   # Override portability-recursive warning.
1258   switch_warning ('no-portability-recursive')
1259     if option 'silent-rules';
1260
1261   if ($strictness == GNITS)
1262     {
1263       set_option ('readme-alpha', INTERNAL);
1264       set_option ('std-options', INTERNAL);
1265       set_option ('check-news', INTERNAL);
1266     }
1267
1268   return 0;
1269 }
1270
1271 # shadow_unconditionally ($varname, $where)
1272 # -----------------------------------------
1273 # Return a $(variable) that contains all possible values
1274 # $varname can take.
1275 # If the VAR wasn't defined conditionally, return $(VAR).
1276 # Otherwise we create an am__VAR_DIST variable which contains
1277 # all possible values, and return $(am__VAR_DIST).
1278 sub shadow_unconditionally ($$)
1279 {
1280   my ($varname, $where) = @_;
1281   my $var = var $varname;
1282   if ($var->has_conditional_contents)
1283     {
1284       $varname = "am__${varname}_DIST";
1285       my @files = uniq ($var->value_as_list_recursive);
1286       define_pretty_variable ($varname, TRUE, $where, @files);
1287     }
1288   return "\$($varname)"
1289 }
1290
1291 # check_user_variables (@LIST)
1292 # ----------------------------
1293 # Make sure each variable VAR in @LIST does not exist, suggest using AM_VAR
1294 # otherwise.
1295 sub check_user_variables (@)
1296 {
1297   my @dont_override = @_;
1298   foreach my $flag (@dont_override)
1299     {
1300       my $var = var $flag;
1301       if ($var)
1302         {
1303           for my $cond ($var->conditions->conds)
1304             {
1305               if ($var->rdef ($cond)->owner == VAR_MAKEFILE)
1306                 {
1307                   msg_cond_var ('gnu', $cond, $flag,
1308                                 "'$flag' is a user variable, "
1309                                 . "you should not override it;\n"
1310                                 . "use 'AM_$flag' instead");
1311                 }
1312             }
1313         }
1314     }
1315 }
1316
1317 # Call finish function for each language that was used.
1318 sub handle_languages
1319 {
1320     if (! option 'no-dependencies')
1321     {
1322         # Include auto-dep code.  Don't include it if DEP_FILES would
1323         # be empty.
1324         if (&saw_sources_p (0) && keys %dep_files)
1325         {
1326             # Set location of depcomp.
1327             &define_variable ('depcomp',
1328                               "\$(SHELL) $am_config_aux_dir/depcomp",
1329                               INTERNAL);
1330             &define_variable ('am__depfiles_maybe', 'depfiles', INTERNAL);
1331
1332             require_conf_file ("$am_file.am", FOREIGN, 'depcomp');
1333
1334             my @deplist = sort keys %dep_files;
1335             # Generate each 'include' individually.  Irix 6 make will
1336             # not properly include several files resulting from a
1337             # variable expansion; generating many separate includes
1338             # seems safest.
1339             $output_rules .= "\n";
1340             foreach my $iter (@deplist)
1341             {
1342                 $output_rules .= (subst ('AMDEP_TRUE')
1343                                   . subst ('am__include')
1344                                   . ' '
1345                                   . subst ('am__quote')
1346                                   . $iter
1347                                   . subst ('am__quote')
1348                                   . "\n");
1349             }
1350
1351             # Compute the set of directories to remove in distclean-depend.
1352             my @depdirs = uniq (map { dirname ($_) } @deplist);
1353             $output_rules .= &file_contents ('depend',
1354                                              new Automake::Location,
1355                                              DEPDIRS => "@depdirs");
1356         }
1357     }
1358     else
1359     {
1360         &define_variable ('depcomp', '', INTERNAL);
1361         &define_variable ('am__depfiles_maybe', '', INTERNAL);
1362     }
1363
1364     my %done;
1365
1366     # Is the C linker needed?
1367     my $needs_c = 0;
1368     foreach my $ext (sort keys %extension_seen)
1369     {
1370         next unless $extension_map{$ext};
1371
1372         my $lang = $languages{$extension_map{$ext}};
1373
1374         my $rule_file = $lang->rule_file || 'depend2';
1375
1376         # Get information on $LANG.
1377         my $pfx = $lang->autodep;
1378         my $fpfx = ($pfx eq '') ? 'CC' : $pfx;
1379
1380         my ($AMDEP, $FASTDEP) =
1381           (option 'no-dependencies' || $lang->autodep eq 'no')
1382           ? ('FALSE', 'FALSE') : ('AMDEP', "am__fastdep$fpfx");
1383
1384         my $verbose = verbose_flag ($lang->ccer || 'GEN');
1385         my $verbose_nodep = ($AMDEP eq 'FALSE')
1386           ? $verbose : verbose_nodep_flag ($lang->ccer || 'GEN');
1387         my $silent = silent_flag ();
1388
1389         my %transform = ('EXT'     => $ext,
1390                          'PFX'     => $pfx,
1391                          'FPFX'    => $fpfx,
1392                          'AMDEP'   => $AMDEP,
1393                          'FASTDEP' => $FASTDEP,
1394                          '-c'      => $lang->compile_flag || '',
1395                          # These are not used, but they need to be defined
1396                          # so &transform do not complain.
1397                          SUBDIROBJ     => 0,
1398                          'DERIVED-EXT' => 'BUG',
1399                          DIST_SOURCE   => 1,
1400                          VERBOSE   => $verbose,
1401                          'VERBOSE-NODEP' => $verbose_nodep,
1402                          SILENT    => $silent,
1403                         );
1404
1405         # Generate the appropriate rules for this extension.
1406         if (((! option 'no-dependencies') && $lang->autodep ne 'no')
1407             || defined $lang->compile)
1408         {
1409             # Some C compilers don't support -c -o.  Use it only if really
1410             # needed.
1411             my $output_flag = $lang->output_flag || '';
1412             $output_flag = '-o'
1413               if (! $output_flag
1414                   && $lang->name eq 'c'
1415                   && option 'subdir-objects');
1416
1417             # Compute a possible derived extension.
1418             # This is not used by depend2.am.
1419             my $der_ext = (&{$lang->output_extensions} ($ext))[0];
1420
1421             # When we output an inference rule like '.c.o:' we
1422             # have two cases to consider: either subdir-objects
1423             # is used, or it is not.
1424             #
1425             # In the latter case the rule is used to build objects
1426             # in the current directory, and dependencies always
1427             # go into './$(DEPDIR)/'.  We can hard-code this value.
1428             #
1429             # In the former case the rule can be used to build
1430             # objects in sub-directories too.  Dependencies should
1431             # go into the appropriate sub-directories, e.g.,
1432             # 'sub/$(DEPDIR)/'.  The value of this directory
1433             # needs to be computed on-the-fly.
1434             #
1435             # DEPBASE holds the name of this directory, plus the
1436             # basename part of the object file (extensions Po, TPo,
1437             # Plo, TPlo will be added later as appropriate).  It is
1438             # either hardcoded, or a shell variable ('$depbase') that
1439             # will be computed by the rule.
1440             my $depbase =
1441               option ('subdir-objects') ? '$$depbase' : '$(DEPDIR)/$*';
1442             $output_rules .=
1443               file_contents ($rule_file,
1444                              new Automake::Location,
1445                              %transform,
1446                              GENERIC   => 1,
1447
1448                              'DERIVED-EXT' => $der_ext,
1449
1450                              DEPBASE   => $depbase,
1451                              BASE      => '$*',
1452                              SOURCE    => '$<',
1453                              SOURCEFLAG => $sourceflags{$ext} || '',
1454                              OBJ       => '$@',
1455                              OBJOBJ    => '$@',
1456                              LTOBJ     => '$@',
1457
1458                              COMPILE   => '$(' . $lang->compiler . ')',
1459                              LTCOMPILE => '$(LT' . $lang->compiler . ')',
1460                              -o        => $output_flag,
1461                              SUBDIROBJ => !! option 'subdir-objects');
1462         }
1463
1464         # Now include code for each specially handled object with this
1465         # language.
1466         my %seen_files = ();
1467         foreach my $file (@{$lang_specific_files{$lang->name}})
1468         {
1469             my ($derived, $source, $obj, $myext, $srcext, %file_transform) = @$file;
1470
1471             # We might see a given object twice, for instance if it is
1472             # used under different conditions.
1473             next if defined $seen_files{$obj};
1474             $seen_files{$obj} = 1;
1475
1476             prog_error ("found " . $lang->name .
1477                         " in handle_languages, but compiler not defined")
1478               unless defined $lang->compile;
1479
1480             my $obj_compile = $lang->compile;
1481
1482             # Rewrite each occurrence of 'AM_$flag' in the compile
1483             # rule into '${derived}_$flag' if it exists.
1484             for my $flag (@{$lang->flags})
1485               {
1486                 my $val = "${derived}_$flag";
1487                 $obj_compile =~ s/\(AM_$flag\)/\($val\)/
1488                   if set_seen ($val);
1489               }
1490
1491             my $libtool_tag = '';
1492             if ($lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag})
1493               {
1494                 $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
1495               }
1496
1497             my $ptltflags = "${derived}_LIBTOOLFLAGS";
1498             $ptltflags = 'AM_LIBTOOLFLAGS' unless set_seen $ptltflags;
1499
1500             my $ltverbose = define_verbose_libtool ();
1501             my $obj_ltcompile =
1502               "\$(LIBTOOL) $ltverbose $libtool_tag\$($ptltflags) \$(LIBTOOLFLAGS) "
1503               . "--mode=compile $obj_compile";
1504
1505             # We _need_ '-o' for per object rules.
1506             my $output_flag = $lang->output_flag || '-o';
1507
1508             my $depbase = dirname ($obj);
1509             $depbase = ''
1510                 if $depbase eq '.';
1511             $depbase .= '/'
1512                 unless $depbase eq '';
1513             $depbase .= '$(DEPDIR)/' . basename ($obj);
1514
1515             $output_rules .=
1516               file_contents ($rule_file,
1517                              new Automake::Location,
1518                              %transform,
1519                              GENERIC   => 0,
1520
1521                              DEPBASE   => $depbase,
1522                              BASE      => $obj,
1523                              SOURCE    => $source,
1524                              SOURCEFLAG => $sourceflags{$srcext} || '',
1525                              # Use $myext and not '.o' here, in case
1526                              # we are actually building a new source
1527                              # file -- e.g. via yacc.
1528                              OBJ       => "$obj$myext",
1529                              OBJOBJ    => "$obj.obj",
1530                              LTOBJ     => "$obj.lo",
1531
1532                              VERBOSE   => $verbose,
1533                              'VERBOSE-NODEP'  => $verbose_nodep,
1534                              SILENT    => $silent,
1535                              COMPILE   => $obj_compile,
1536                              LTCOMPILE => $obj_ltcompile,
1537                              -o        => $output_flag,
1538                              %file_transform);
1539         }
1540
1541         # The rest of the loop is done once per language.
1542         next if defined $done{$lang};
1543         $done{$lang} = 1;
1544
1545         # Load the language dependent Makefile chunks.
1546         my %lang = map { uc ($_) => 0 } keys %languages;
1547         $lang{uc ($lang->name)} = 1;
1548         $output_rules .= file_contents ('lang-compile',
1549                                         new Automake::Location,
1550                                         %transform, %lang);
1551
1552         # If the source to a program consists entirely of code from a
1553         # 'pure' language, for instance C++ or Fortran 77, then we
1554         # don't need the C compiler code.  However if we run into
1555         # something unusual then we do generate the C code.  There are
1556         # probably corner cases here that do not work properly.
1557         # People linking Java code to Fortran code deserve pain.
1558         $needs_c ||= ! $lang->pure;
1559
1560         define_compiler_variable ($lang)
1561           if ($lang->compile);
1562
1563         define_linker_variable ($lang)
1564           if ($lang->link);
1565
1566         require_variables ("$am_file.am", $lang->Name . " source seen",
1567                            TRUE, @{$lang->config_vars});
1568
1569         # Call the finisher.
1570         $lang->finish;
1571
1572         # Flags listed in '->flags' are user variables (per GNU Standards),
1573         # they should not be overridden in the Makefile...
1574         my @dont_override = @{$lang->flags};
1575         # ... and so is LDFLAGS.
1576         push @dont_override, 'LDFLAGS' if $lang->link;
1577
1578         check_user_variables @dont_override;
1579     }
1580
1581     # If the project is entirely C++ or entirely Fortran 77 (i.e., 1
1582     # suffix rule was learned), don't bother with the C stuff.  But if
1583     # anything else creeps in, then use it.
1584     $needs_c = 1
1585       if $need_link || suffix_rules_count > 1;
1586
1587     if ($needs_c)
1588       {
1589         &define_compiler_variable ($languages{'c'})
1590           unless defined $done{$languages{'c'}};
1591         define_linker_variable ($languages{'c'});
1592       }
1593
1594     # Always provide the user with 'AM_V_GEN' for 'silent-rules' mode.
1595     define_verbose_tagvar ('GEN');
1596 }
1597
1598
1599 # append_exeext { PREDICATE } $MACRO
1600 # ----------------------------------
1601 # Append $(EXEEXT) to each filename in $F appearing in the Makefile
1602 # variable $MACRO if &PREDICATE($F) is true.  @substitutions@ are
1603 # ignored.
1604 #
1605 # This is typically used on all filenames of *_PROGRAMS, and filenames
1606 # of TESTS that are programs.
1607 sub append_exeext (&$)
1608 {
1609   my ($pred, $macro) = @_;
1610
1611   transform_variable_recursively
1612     ($macro, $macro, 'am__EXEEXT', 0, INTERNAL,
1613      sub {
1614        my ($subvar, $val, $cond, $full_cond) = @_;
1615        # Append $(EXEEXT) unless the user did it already, or it's a
1616        # @substitution@.
1617        $val .= '$(EXEEXT)'
1618          if $val !~ /(?:\$\(EXEEXT\)$|^[@]\w+[@]$)/ && &$pred ($val);
1619        return $val;
1620      });
1621 }
1622
1623
1624 # Check to make sure a source defined in LIBOBJS is not explicitly
1625 # mentioned.  This is a separate function (as opposed to being inlined
1626 # in handle_source_transform) because it isn't always appropriate to
1627 # do this check.
1628 sub check_libobjs_sources
1629 {
1630   my ($one_file, $unxformed) = @_;
1631
1632   foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1633                       'dist_EXTRA_', 'nodist_EXTRA_')
1634     {
1635       my @files;
1636       my $varname = $prefix . $one_file . '_SOURCES';
1637       my $var = var ($varname);
1638       if ($var)
1639         {
1640           @files = $var->value_as_list_recursive;
1641         }
1642       elsif ($prefix eq '')
1643         {
1644           @files = ($unxformed . '.c');
1645         }
1646       else
1647         {
1648           next;
1649         }
1650
1651       foreach my $file (@files)
1652         {
1653           err_var ($prefix . $one_file . '_SOURCES',
1654                    "automatically discovered file '$file' should not" .
1655                    " be explicitly mentioned")
1656             if defined $libsources{$file};
1657         }
1658     }
1659 }
1660
1661
1662 # @OBJECTS
1663 # handle_single_transform ($VAR, $TOPPARENT, $DERIVED, $OBJ, $FILE, %TRANSFORM)
1664 # -----------------------------------------------------------------------------
1665 # Does much of the actual work for handle_source_transform.
1666 # Arguments are:
1667 #   $VAR is the name of the variable that the source filenames come from
1668 #   $TOPPARENT is the name of the _SOURCES variable which is being processed
1669 #   $DERIVED is the name of resulting executable or library
1670 #   $OBJ is the object extension (e.g., '.lo')
1671 #   $FILE the source file to transform
1672 #   %TRANSFORM contains extras arguments to pass to file_contents
1673 #     when producing explicit rules
1674 # Result is a list of the names of objects
1675 # %linkers_used will be updated with any linkers needed
1676 sub handle_single_transform ($$$$$%)
1677 {
1678     my ($var, $topparent, $derived, $obj, $_file, %transform) = @_;
1679     my @files = ($_file);
1680     my @result = ();
1681
1682     # Turn sources into objects.  We use a while loop like this
1683     # because we might add to @files in the loop.
1684     while (scalar @files > 0)
1685     {
1686         $_ = shift @files;
1687
1688         # Configure substitutions in _SOURCES variables are errors.
1689         if (/^\@.*\@$/)
1690         {
1691           my $parent_msg = '';
1692           $parent_msg = "\nand is referred to from '$topparent'"
1693             if $topparent ne $var->name;
1694           err_var ($var,
1695                    "'" . $var->name . "' includes configure substitution '$_'"
1696                    . $parent_msg . ";\nconfigure " .
1697                    "substitutions are not allowed in _SOURCES variables");
1698           next;
1699         }
1700
1701         # If the source file is in a subdirectory then the '.o' is put
1702         # into the current directory, unless the subdir-objects option
1703         # is in effect.
1704
1705         # Split file name into base and extension.
1706         next if ! /^(?:(.*)\/)?([^\/]*)($KNOWN_EXTENSIONS_PATTERN)$/;
1707         my $full = $_;
1708         my $directory = $1 || '';
1709         my $base = $2;
1710         my $extension = $3;
1711
1712         # We must generate a rule for the object if it requires its own flags.
1713         my $renamed = 0;
1714         my ($linker, $object);
1715
1716         # This records whether we've seen a derived source file (e.g.
1717         # yacc output).
1718         my $derived_source = 0;
1719
1720         # This holds the 'aggregate context' of the file we are
1721         # currently examining.  If the file is compiled with
1722         # per-object flags, then it will be the name of the object.
1723         # Otherwise it will be 'AM'.  This is used by the target hook
1724         # language function.
1725         my $aggregate = 'AM';
1726
1727         $extension = &derive_suffix ($extension, $obj);
1728         my $lang;
1729         if ($extension_map{$extension} &&
1730             ($lang = $languages{$extension_map{$extension}}))
1731         {
1732             # Found the language, so see what it says.
1733             &saw_extension ($extension);
1734
1735             # Do we have per-executable flags for this executable?
1736             my $have_per_exec_flags = 0;
1737             my @peflags = @{$lang->flags};
1738             push @peflags, 'LIBTOOLFLAGS' if $obj eq '.lo';
1739             foreach my $flag (@peflags)
1740               {
1741                 if (set_seen ("${derived}_$flag"))
1742                   {
1743                     $have_per_exec_flags = 1;
1744                     last;
1745                   }
1746               }
1747
1748             # Note: computed subr call.  The language rewrite function
1749             # should return one of the LANG_* constants.  It could
1750             # also return a list whose first value is such a constant
1751             # and whose second value is a new source extension which
1752             # should be applied.  This means this particular language
1753             # generates another source file which we must then process
1754             # further.
1755             my $subr = \&{'lang_' . $lang->name . '_rewrite'};
1756             my ($r, $source_extension)
1757                 = &$subr ($directory, $base, $extension,
1758                           $obj, $have_per_exec_flags, $var);
1759             # Skip this entry if we were asked not to process it.
1760             next if $r == LANG_IGNORE;
1761
1762             # Now extract linker and other info.
1763             $linker = $lang->linker;
1764
1765             my $this_obj_ext;
1766             if (defined $source_extension)
1767             {
1768                 $this_obj_ext = $source_extension;
1769                 $derived_source = 1;
1770             }
1771             else
1772             {
1773                 $this_obj_ext = $obj;
1774             }
1775             $object = $base . $this_obj_ext;
1776
1777             if ($have_per_exec_flags)
1778             {
1779                 # We have a per-executable flag in effect for this
1780                 # object.  In this case we rewrite the object's
1781                 # name to ensure it is unique.
1782
1783                 # We choose the name 'DERIVED_OBJECT' to ensure
1784                 # (1) uniqueness, and (2) continuity between
1785                 # invocations.  However, this will result in a
1786                 # name that is too long for losing systems, in
1787                 # some situations.  So we provide _SHORTNAME to
1788                 # override.
1789
1790                 my $dname = $derived;
1791                 my $var = var ($derived . '_SHORTNAME');
1792                 if ($var)
1793                 {
1794                     # FIXME: should use the same Condition as
1795                     # the _SOURCES variable.  But this is really
1796                     # silly overkill -- nobody should have
1797                     # conditional shortnames.
1798                     $dname = $var->variable_value;
1799                 }
1800                 $object = $dname . '-' . $object;
1801
1802                 prog_error ($lang->name . " flags defined without compiler")
1803                   if ! defined $lang->compile;
1804
1805                 $renamed = 1;
1806             }
1807
1808             # If rewrite said it was ok, put the object into a
1809             # subdir.
1810             if ($r == LANG_SUBDIR && $directory ne '')
1811             {
1812                 $object = $directory . '/' . $object;
1813             }
1814
1815             # If the object file has been renamed (because per-target
1816             # flags are used) we cannot compile the file with an
1817             # inference rule: we need an explicit rule.
1818             #
1819             # If the source is in a subdirectory and the object is in
1820             # the current directory, we also need an explicit rule.
1821             #
1822             # If both source and object files are in a subdirectory
1823             # (this happens when the subdir-objects option is used),
1824             # then the inference will work.
1825             #
1826             # The latter case deserves a historical note.  When the
1827             # subdir-objects option was added on 1999-04-11 it was
1828             # thought that inferences rules would work for
1829             # subdirectory objects too.  Later, on 1999-11-22,
1830             # automake was changed to output explicit rules even for
1831             # subdir-objects.  Nobody remembers why, but this occurred
1832             # soon after the merge of the user-dep-gen-branch so it
1833             # might be related.  In late 2003 people complained about
1834             # the size of the generated Makefile.ins (libgcj, with
1835             # 2200+ subdir objects was reported to have a 9MB
1836             # Makefile), so we now rely on inference rules again.
1837             # Maybe we'll run across the same issue as in the past,
1838             # but at least this time we can document it.  However since
1839             # dependency tracking has evolved it is possible that
1840             # our old problem no longer exists.
1841             # Using inference rules for subdir-objects has been tested
1842             # with GNU make, Solaris make, Ultrix make, BSD make,
1843             # HP-UX make, and OSF1 make successfully.
1844             if ($renamed
1845                 || ($directory ne '' && ! option 'subdir-objects')
1846                 # We must also use specific rules for a nodist_ source
1847                 # if its language requests it.
1848                 || ($lang->nodist_specific && ! $transform{'DIST_SOURCE'}))
1849             {
1850                 my $obj_sans_ext = substr ($object, 0,
1851                                            - length ($this_obj_ext));
1852                 my $full_ansi;
1853                 if ($directory ne '')
1854                   {
1855                         $full_ansi = $directory . '/' . $base . $extension;
1856                   }
1857                 else
1858                   {
1859                         $full_ansi = $base . $extension;
1860                   }
1861
1862                 my @specifics = ($full_ansi, $obj_sans_ext,
1863                                  # Only use $this_obj_ext in the derived
1864                                  # source case because in the other case we
1865                                  # *don't* want $(OBJEXT) to appear here.
1866                                  ($derived_source ? $this_obj_ext : '.o'),
1867                                  $extension);
1868
1869                 # If we renamed the object then we want to use the
1870                 # per-executable flag name.  But if this is simply a
1871                 # subdir build then we still want to use the AM_ flag
1872                 # name.
1873                 if ($renamed)
1874                   {
1875                     unshift @specifics, $derived;
1876                     $aggregate = $derived;
1877                   }
1878                 else
1879                   {
1880                     unshift @specifics, 'AM';
1881                   }
1882
1883                 # Each item on this list is a reference to a list consisting
1884                 # of four values followed by additional transform flags for
1885                 # file_contents.  The four values are the derived flag prefix
1886                 # (e.g. for 'foo_CFLAGS', it is 'foo'), the name of the
1887                 # source file, the base name of the output file, and
1888                 # the extension for the object file.
1889                 push (@{$lang_specific_files{$lang->name}},
1890                       [@specifics, %transform]);
1891             }
1892         }
1893         elsif ($extension eq $obj)
1894         {
1895             # This is probably the result of a direct suffix rule.
1896             # In this case we just accept the rewrite.
1897             $object = "$base$extension";
1898             $object = "$directory/$object" if $directory ne '';
1899             $linker = '';
1900         }
1901         else
1902         {
1903             # No error message here.  Used to have one, but it was
1904             # very unpopular.
1905             # FIXME: we could potentially do more processing here,
1906             # perhaps treating the new extension as though it were a
1907             # new source extension (as above).  This would require
1908             # more restructuring than is appropriate right now.
1909             next;
1910         }
1911
1912         err_am "object '$object' created by '$full' and '$object_map{$object}'"
1913           if (defined $object_map{$object}
1914               && $object_map{$object} ne $full);
1915
1916         my $comp_val = (($object =~ /\.lo$/)
1917                         ? COMPILE_LIBTOOL : COMPILE_ORDINARY);
1918         (my $comp_obj = $object) =~ s/\.lo$/.\$(OBJEXT)/;
1919         if (defined $object_compilation_map{$comp_obj}
1920             && $object_compilation_map{$comp_obj} != 0
1921             # Only see the error once.
1922             && ($object_compilation_map{$comp_obj}
1923                 != (COMPILE_LIBTOOL | COMPILE_ORDINARY))
1924             && $object_compilation_map{$comp_obj} != $comp_val)
1925           {
1926             err_am "object '$comp_obj' created both with libtool and without";
1927           }
1928         $object_compilation_map{$comp_obj} |= $comp_val;
1929
1930         if (defined $lang)
1931         {
1932             # Let the language do some special magic if required.
1933             $lang->target_hook ($aggregate, $object, $full, %transform);
1934         }
1935
1936         if ($derived_source)
1937           {
1938             prog_error ($lang->name . " has automatic dependency tracking")
1939               if $lang->autodep ne 'no';
1940             # Make sure this new source file is handled next.  That will
1941             # make it appear to be at the right place in the list.
1942             unshift (@files, $object);
1943             # Distribute derived sources unless the source they are
1944             # derived from is not.
1945             &push_dist_common ($object)
1946               unless ($topparent =~ /^(?:nobase_)?nodist_/);
1947             next;
1948           }
1949
1950         $linkers_used{$linker} = 1;
1951
1952         push (@result, $object);
1953
1954         if (! defined $object_map{$object})
1955         {
1956             my @dep_list = ();
1957             $object_map{$object} = $full;
1958
1959             # If resulting object is in subdir, we need to make
1960             # sure the subdir exists at build time.
1961             if ($object =~ /\//)
1962             {
1963                 # FIXME: check that $DIRECTORY is somewhere in the
1964                 # project
1965
1966                 # For Java, the way we're handling it right now, a
1967                 # '..' component doesn't make sense.
1968                 if ($lang && $lang->name eq 'java' && $object =~ /(\/|^)\.\.\//)
1969                   {
1970                     err_am "'$full' should not contain a '..' component";
1971                   }
1972
1973                 # Make sure object is removed by 'make mostlyclean'.
1974                 $compile_clean_files{$object} = MOSTLY_CLEAN;
1975                 # If we have a libtool object then we also must remove
1976                 # the ordinary .o.
1977                 if ($object =~ /\.lo$/)
1978                 {
1979                     (my $xobj = $object) =~ s,lo$,\$(OBJEXT),;
1980                     $compile_clean_files{$xobj} = MOSTLY_CLEAN;
1981
1982                     # Remove any libtool object in this directory.
1983                     $libtool_clean_directories{$directory} = 1;
1984                 }
1985
1986                 push (@dep_list, require_build_directory ($directory));
1987
1988                 # If we're generating dependencies, we also want
1989                 # to make sure that the appropriate subdir of the
1990                 # .deps directory is created.
1991                 push (@dep_list,
1992                       require_build_directory ($directory . '/$(DEPDIR)'))
1993                   unless option 'no-dependencies';
1994             }
1995
1996             &pretty_print_rule ($object . ':', "\t", @dep_list)
1997                 if scalar @dep_list > 0;
1998         }
1999
2000         # Transform .o or $o file into .P file (for automatic
2001         # dependency code).
2002         # Properly flatten multiple adjacent slashes, as Solaris 10 make
2003         # might fail over them in an include statement.
2004         # Leading double slashes may be special, as per Posix, so deal
2005         # with them carefully.
2006         if ($lang && $lang->autodep ne 'no')
2007         {
2008             my $depfile = $object;
2009             $depfile =~ s/\.([^.]*)$/.P$1/;
2010             $depfile =~ s/\$\(OBJEXT\)$/o/;
2011             my $maybe_extra_leading_slash = '';
2012             $maybe_extra_leading_slash = '/' if $depfile =~ m,^//[^/],;
2013             $depfile =~ s,/+,/,g;
2014             my $basename = basename ($depfile);
2015             # This might make $dirname empty, but we account for that below.
2016             (my $dirname = dirname ($depfile)) =~ s/\/*$//;
2017             $dirname = $maybe_extra_leading_slash . $dirname;
2018             $dep_files{$dirname . '/$(DEPDIR)/' . $basename} = 1;
2019         }
2020     }
2021
2022     return @result;
2023 }
2024
2025
2026 # $LINKER
2027 # define_objects_from_sources ($VAR, $OBJVAR, $NODEFINE, $ONE_FILE,
2028 #                              $OBJ, $PARENT, $TOPPARENT, $WHERE, %TRANSFORM)
2029 # ---------------------------------------------------------------------------
2030 # Define an _OBJECTS variable for a _SOURCES variable (or subvariable)
2031 #
2032 # Arguments are:
2033 #   $VAR is the name of the _SOURCES variable
2034 #   $OBJVAR is the name of the _OBJECTS variable if known (otherwise
2035 #     it will be generated and returned).
2036 #   $NODEFINE is a boolean: if true, $OBJVAR will not be defined (but
2037 #     work done to determine the linker will be).
2038 #   $ONE_FILE is the canonical (transformed) name of object to build
2039 #   $OBJ is the object extension (i.e. either '.o' or '.lo').
2040 #   $TOPPARENT is the _SOURCES variable being processed.
2041 #   $WHERE context into which this definition is done
2042 #   %TRANSFORM extra arguments to pass to file_contents when producing
2043 #     rules
2044 #
2045 # Result is a pair ($LINKER, $OBJVAR):
2046 #    $LINKER is a boolean, true if a linker is needed to deal with the objects
2047 sub define_objects_from_sources ($$$$$$$%)
2048 {
2049   my ($var, $objvar, $nodefine, $one_file,
2050       $obj, $topparent, $where, %transform) = @_;
2051
2052   my $needlinker = "";
2053
2054   transform_variable_recursively
2055     ($var, $objvar, 'am__objects', $nodefine, $where,
2056      # The transform code to run on each filename.
2057      sub {
2058        my ($subvar, $val, $cond, $full_cond) = @_;
2059        my @trans = handle_single_transform ($subvar, $topparent,
2060                                             $one_file, $obj, $val,
2061                                             %transform);
2062        $needlinker = "true" if @trans;
2063        return @trans;
2064      });
2065
2066   return $needlinker;
2067 }
2068
2069
2070 # handle_source_transform ($CANON_TARGET, $TARGET, $OBJEXT, $WHERE, %TRANSFORM)
2071 # -----------------------------------------------------------------------------
2072 # Handle SOURCE->OBJECT transform for one program or library.
2073 # Arguments are:
2074 #   canonical (transformed) name of target to build
2075 #   actual target of object to build
2076 #   object extension (i.e., either '.o' or '$o')
2077 #   location of the source variable
2078 #   extra arguments to pass to file_contents when producing rules
2079 # Return the name of the linker variable that must be used.
2080 # Empty return means just use 'LINK'.
2081 sub handle_source_transform ($$$$%)
2082 {
2083     # one_file is canonical name.  unxformed is given name.  obj is
2084     # object extension.
2085     my ($one_file, $unxformed, $obj, $where, %transform) = @_;
2086
2087     my $linker = '';
2088
2089     # No point in continuing if _OBJECTS is defined.
2090     return if reject_var ($one_file . '_OBJECTS',
2091                           $one_file . '_OBJECTS should not be defined');
2092
2093     my %used_pfx = ();
2094     my $needlinker;
2095     %linkers_used = ();
2096     foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
2097                         'dist_EXTRA_', 'nodist_EXTRA_')
2098     {
2099         my $varname = $prefix . $one_file . "_SOURCES";
2100         my $var = var $varname;
2101         next unless $var;
2102
2103         # We are going to define _OBJECTS variables using the prefix.
2104         # Then we glom them all together.  So we can't use the null
2105         # prefix here as we need it later.
2106         my $xpfx = ($prefix eq '') ? 'am_' : $prefix;
2107
2108         # Keep track of which prefixes we saw.
2109         $used_pfx{$xpfx} = 1
2110           unless $prefix =~ /EXTRA_/;
2111
2112         push @sources, "\$($varname)";
2113         push @dist_sources, shadow_unconditionally ($varname, $where)
2114           unless (option ('no-dist') || $prefix =~ /^nodist_/);
2115
2116         $needlinker |=
2117             define_objects_from_sources ($varname,
2118                                          $xpfx . $one_file . '_OBJECTS',
2119                                          $prefix =~ /EXTRA_/,
2120                                          $one_file, $obj, $varname, $where,
2121                                          DIST_SOURCE => ($prefix !~ /^nodist_/),
2122                                          %transform);
2123     }
2124     if ($needlinker)
2125     {
2126         $linker ||= &resolve_linker (%linkers_used);
2127     }
2128
2129     my @keys = sort keys %used_pfx;
2130     if (scalar @keys == 0)
2131     {
2132         # The default source for libfoo.la is libfoo.c, but for
2133         # backward compatibility we first look at libfoo_la.c,
2134         # if no default source suffix is given.
2135         my $old_default_source = "$one_file.c";
2136         my $ext_var = var ('AM_DEFAULT_SOURCE_EXT');
2137         my $default_source_ext = $ext_var ? variable_value ($ext_var) : '.c';
2138         msg_var ('unsupported', $ext_var, $ext_var->name . " can assume at most one value")
2139           if $default_source_ext =~ /[\t ]/;
2140         (my $default_source = $unxformed) =~ s,(\.[^./\\]*)?$,$default_source_ext,;
2141         if ($old_default_source ne $default_source
2142             && !$ext_var
2143             && (rule $old_default_source
2144                 || rule '$(srcdir)/' . $old_default_source
2145                 || rule '${srcdir}/' . $old_default_source
2146                 || -f $old_default_source))
2147           {
2148             my $loc = $where->clone;
2149             $loc->pop_context;
2150             msg ('obsolete', $loc,
2151                  "the default source for '$unxformed' has been changed "
2152                  . "to '$default_source'.\n(Using '$old_default_source' for "
2153                  . "backward compatibility.)");
2154             $default_source = $old_default_source;
2155           }
2156         # If a rule exists to build this source with a $(srcdir)
2157         # prefix, use that prefix in our variables too.  This is for
2158         # the sake of BSD Make.
2159         if (rule '$(srcdir)/' . $default_source
2160             || rule '${srcdir}/' . $default_source)
2161           {
2162             $default_source = '$(srcdir)/' . $default_source;
2163           }
2164
2165         &define_variable ($one_file . "_SOURCES", $default_source, $where);
2166         push (@sources, $default_source);
2167         push (@dist_sources, $default_source);
2168
2169         %linkers_used = ();
2170         my (@result) =
2171           handle_single_transform ($one_file . '_SOURCES',
2172                                    $one_file . '_SOURCES',
2173                                    $one_file, $obj,
2174                                    $default_source, %transform);
2175         $linker ||= &resolve_linker (%linkers_used);
2176         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @result);
2177     }
2178     else
2179     {
2180         @keys = map { '$(' . $_ . $one_file . '_OBJECTS)' } @keys;
2181         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @keys);
2182     }
2183
2184     # If we want to use 'LINK' we must make sure it is defined.
2185     if ($linker eq '')
2186     {
2187         $need_link = 1;
2188     }
2189
2190     return $linker;
2191 }
2192
2193
2194 # handle_lib_objects ($XNAME, $VAR)
2195 # ---------------------------------
2196 # Special-case ALLOCA and LIBOBJS substitutions in _LDADD or _LIBADD variables.
2197 # Also, generate _DEPENDENCIES variable if appropriate.
2198 # Arguments are:
2199 #   transformed name of object being built, or empty string if no object
2200 #   name of _LDADD/_LIBADD-type variable to examine
2201 # Returns 1 if LIBOBJS seen, 0 otherwise.
2202 sub handle_lib_objects
2203 {
2204   my ($xname, $varname) = @_;
2205
2206   my $var = var ($varname);
2207   prog_error "'$varname' undefined"
2208     unless $var;
2209   prog_error "unexpected variable name '$varname'"
2210     unless $varname =~ /^(.*)(?:LIB|LD)ADD$/;
2211   my $prefix = $1 || 'AM_';
2212
2213   my $seen_libobjs = 0;
2214   my $flagvar = 0;
2215
2216   transform_variable_recursively
2217     ($varname, $xname . '_DEPENDENCIES', 'am__DEPENDENCIES',
2218      ! $xname, INTERNAL,
2219      # Transformation function, run on each filename.
2220      sub {
2221        my ($subvar, $val, $cond, $full_cond) = @_;
2222
2223        if ($val =~ /^-/)
2224          {
2225            # Skip -lfoo and -Ldir silently; these are explicitly allowed.
2226            if ($val !~ /^-[lL]/ &&
2227                # Skip -dlopen and -dlpreopen; these are explicitly allowed
2228                # for Libtool libraries or programs.  (Actually we are a bit
2229                # lax here since this code also applies to non-libtool
2230                # libraries or programs, for which -dlopen and -dlopreopen
2231                # are pure nonsense.  Diagnosing this doesn't seem very
2232                # important: the developer will quickly get complaints from
2233                # the linker.)
2234                $val !~ /^-dl(?:pre)?open$/ &&
2235                # Only get this error once.
2236                ! $flagvar)
2237              {
2238                $flagvar = 1;
2239                # FIXME: should display a stack of nested variables
2240                # as context when $var != $subvar.
2241                err_var ($var, "linker flags such as '$val' belong in "
2242                         . "'${prefix}LDFLAGS'");
2243              }
2244            return ();
2245          }
2246        elsif ($val !~ /^\@.*\@$/)
2247          {
2248            # Assume we have a file of some sort, and output it into the
2249            # dependency variable.  Autoconf substitutions are not output;
2250            # rarely is a new dependency substituted into e.g. foo_LDADD
2251            # -- but bad things (e.g. -lX11) are routinely substituted.
2252            # Note that LIBOBJS and ALLOCA are exceptions to this rule,
2253            # and handled specially below.
2254            return $val;
2255          }
2256        elsif ($val =~ /^\@(LT)?LIBOBJS\@$/)
2257          {
2258            handle_LIBOBJS ($subvar, $cond, $1);
2259            $seen_libobjs = 1;
2260            return $val;
2261          }
2262        elsif ($val =~ /^\@(LT)?ALLOCA\@$/)
2263          {
2264            handle_ALLOCA ($subvar, $cond, $1);
2265            return $val;
2266          }
2267        else
2268          {
2269            return ();
2270          }
2271      });
2272
2273   return $seen_libobjs;
2274 }
2275
2276 # handle_LIBOBJS_or_ALLOCA ($VAR)
2277 # -------------------------------
2278 # Definitions common to LIBOBJS and ALLOCA.
2279 # VAR should be one of LIBOBJS, LTLIBOBJS, ALLOCA, or LTALLOCA.
2280 sub handle_LIBOBJS_or_ALLOCA ($)
2281 {
2282   my ($var) = @_;
2283
2284   my $dir = '';
2285
2286   # If LIBOBJS files must be built in another directory we have
2287   # to define LIBOBJDIR and ensure the files get cleaned.
2288   # Otherwise LIBOBJDIR can be left undefined, and the cleaning
2289   # is achieved by 'rm -f *.$(OBJEXT)' in compile.am.
2290   if ($config_libobj_dir
2291       && $relative_dir ne $config_libobj_dir)
2292     {
2293       if (option 'subdir-objects')
2294         {
2295           # In the top-level Makefile we do not use $(top_builddir), because
2296           # we are already there, and since the targets are built without
2297           # a $(top_builddir), it helps BSD Make to match them with
2298           # dependencies.
2299           $dir = "$config_libobj_dir/" if $config_libobj_dir ne '.';
2300           $dir = "$topsrcdir/$dir" if $relative_dir ne '.';
2301           define_variable ('LIBOBJDIR', "$dir", INTERNAL);
2302           $clean_files{"\$($var)"} = MOSTLY_CLEAN;
2303           # If LTLIBOBJS is used, we must also clear LIBOBJS (which might
2304           # be created by libtool as a side-effect of creating LTLIBOBJS).
2305           $clean_files{"\$($var)"} = MOSTLY_CLEAN if $var =~ s/^LT//;
2306         }
2307       else
2308         {
2309           error ("'\$($var)' cannot be used outside '$config_libobj_dir' if"
2310                  . " 'subdir-objects' is not set");
2311         }
2312     }
2313
2314   return $dir;
2315 }
2316
2317 sub handle_LIBOBJS ($$$)
2318 {
2319   my ($var, $cond, $lt) = @_;
2320   my $myobjext = $lt ? 'lo' : 'o';
2321   $lt ||= '';
2322
2323   $var->requires_variables ("\@${lt}LIBOBJS\@ used", $lt . 'LIBOBJS')
2324     if ! keys %libsources;
2325
2326   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}LIBOBJS";
2327
2328   foreach my $iter (keys %libsources)
2329     {
2330       if ($iter =~ /\.[cly]$/)
2331         {
2332           &saw_extension ($&);
2333           &saw_extension ('.c');
2334         }
2335
2336       if ($iter =~ /\.h$/)
2337         {
2338           require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2339         }
2340       elsif ($iter ne 'alloca.c')
2341         {
2342           my $rewrite = $iter;
2343           $rewrite =~ s/\.c$/.P$myobjext/;
2344           $dep_files{$dir . '$(DEPDIR)/' . $rewrite} = 1;
2345           $rewrite = "^" . quotemeta ($iter) . "\$";
2346           # Only require the file if it is not a built source.
2347           my $bs = var ('BUILT_SOURCES');
2348           if (! $bs || ! grep (/$rewrite/, $bs->value_as_list_recursive))
2349             {
2350               require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2351             }
2352         }
2353     }
2354 }
2355
2356 sub handle_ALLOCA ($$$)
2357 {
2358   my ($var, $cond, $lt) = @_;
2359   my $myobjext = $lt ? 'lo' : 'o';
2360   $lt ||= '';
2361   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}ALLOCA";
2362
2363   $var->requires_variables ("\@${lt}ALLOCA\@ used", $lt . 'ALLOCA');
2364   $dep_files{$dir . '$(DEPDIR)/alloca.P' . $myobjext} = 1;
2365   require_libsource_with_macro ($cond, $var, FOREIGN, 'alloca.c');
2366   &saw_extension ('.c');
2367 }
2368
2369 # Canonicalize the input parameter
2370 sub canonicalize
2371 {
2372     my ($string) = @_;
2373     $string =~ tr/A-Za-z0-9_\@/_/c;
2374     return $string;
2375 }
2376
2377 # Canonicalize a name, and check to make sure the non-canonical name
2378 # is never used.  Returns canonical name.  Arguments are name and a
2379 # list of suffixes to check for.
2380 sub check_canonical_spelling
2381 {
2382   my ($name, @suffixes) = @_;
2383
2384   my $xname = &canonicalize ($name);
2385   if ($xname ne $name)
2386     {
2387       foreach my $xt (@suffixes)
2388         {
2389           reject_var ("$name$xt", "use '$xname$xt', not '$name$xt'");
2390         }
2391     }
2392
2393   return $xname;
2394 }
2395
2396
2397 # handle_compile ()
2398 # -----------------
2399 # Set up the compile suite.
2400 sub handle_compile ()
2401 {
2402    return if ! $must_handle_compiled_objects;
2403
2404     # Boilerplate.
2405     my $default_includes = '';
2406     if (! option 'nostdinc')
2407       {
2408         my @incs = ('-I.', subst ('am__isrc'));
2409
2410         my $var = var 'CONFIG_HEADER';
2411         if ($var)
2412           {
2413             foreach my $hdr (split (' ', $var->variable_value))
2414               {
2415                 push @incs, '-I' . dirname ($hdr);
2416               }
2417           }
2418         # We want '-I. -I$(srcdir)', but the latter -I is redundant
2419         # and unaesthetic in non-VPATH builds.  We use `-I.@am__isrc@`
2420         # instead.  It will be replaced by '-I.' or '-I. -I$(srcdir)'.
2421         # Items in CONFIG_HEADER are never in $(srcdir) so it is safe
2422         # to just put @am__isrc@ right after '-I.', without a space.
2423         ($default_includes = ' ' . uniq (@incs)) =~ s/ @/@/;
2424       }
2425
2426     my (@mostly_rms, @dist_rms);
2427     foreach my $item (sort keys %compile_clean_files)
2428     {
2429         if ($compile_clean_files{$item} == MOSTLY_CLEAN)
2430         {
2431             push (@mostly_rms, "\t-rm -f $item");
2432         }
2433         elsif ($compile_clean_files{$item} == DIST_CLEAN)
2434         {
2435             push (@dist_rms, "\t-rm -f $item");
2436         }
2437         else
2438         {
2439           prog_error 'invalid entry in %compile_clean_files';
2440         }
2441     }
2442
2443     my ($coms, $vars, $rules) =
2444       &file_contents_internal (1, "$libdir/am/compile.am",
2445                                new Automake::Location,
2446                                ('DEFAULT_INCLUDES' => $default_includes,
2447                                 'MOSTLYRMS' => join ("\n", @mostly_rms),
2448                                 'DISTRMS' => join ("\n", @dist_rms)));
2449     $output_vars .= $vars;
2450     $output_rules .= "$coms$rules";
2451 }
2452
2453 # handle_libtool ()
2454 # -----------------
2455 # Handle libtool rules.
2456 sub handle_libtool
2457 {
2458   return unless var ('LIBTOOL');
2459
2460   # Libtool requires some files, but only at top level.
2461   # (Starting with Libtool 2.0 we do not have to bother.  These
2462   # requirements are done with AC_REQUIRE_AUX_FILE.)
2463   require_conf_file_with_macro (TRUE, 'LIBTOOL', FOREIGN, @libtool_files)
2464     if $relative_dir eq '.' && ! $libtool_new_api;
2465
2466   my @libtool_rms;
2467   foreach my $item (sort keys %libtool_clean_directories)
2468     {
2469       my $dir = ($item eq '.') ? '' : "$item/";
2470       # .libs is for Unix, _libs for DOS.
2471       push (@libtool_rms, "\t-rm -rf ${dir}.libs ${dir}_libs");
2472     }
2473
2474   check_user_variables 'LIBTOOLFLAGS';
2475
2476   # Output the libtool compilation rules.
2477   $output_rules .= &file_contents ('libtool',
2478                                    new Automake::Location,
2479                                    LTRMS => join ("\n", @libtool_rms));
2480 }
2481
2482 # handle_programs ()
2483 # ------------------
2484 # Handle C programs.
2485 sub handle_programs
2486 {
2487   my @proglist = &am_install_var ('progs', 'PROGRAMS',
2488                                   'bin', 'sbin', 'libexec', 'pkglibexec',
2489                                   'noinst', 'check');
2490   return if ! @proglist;
2491   $must_handle_compiled_objects = 1;
2492
2493   my $seen_global_libobjs =
2494     var ('LDADD') && &handle_lib_objects ('', 'LDADD');
2495
2496   foreach my $pair (@proglist)
2497     {
2498       my ($where, $one_file) = @$pair;
2499
2500       my $seen_libobjs = 0;
2501       my $obj = '.$(OBJEXT)';
2502
2503       $known_programs{$one_file} = $where;
2504
2505       # Canonicalize names and check for misspellings.
2506       my $xname = &check_canonical_spelling ($one_file, '_LDADD', '_LDFLAGS',
2507                                              '_SOURCES', '_OBJECTS',
2508                                              '_DEPENDENCIES');
2509
2510       $where->push_context ("while processing program '$one_file'");
2511       $where->set (INTERNAL->get);
2512
2513       my $linker = &handle_source_transform ($xname, $one_file, $obj, $where,
2514                                              NONLIBTOOL => 1, LIBTOOL => 0);
2515
2516       if (var ($xname . "_LDADD"))
2517         {
2518           $seen_libobjs = &handle_lib_objects ($xname, $xname . '_LDADD');
2519         }
2520       else
2521         {
2522           # User didn't define prog_LDADD override.  So do it.
2523           &define_variable ($xname . '_LDADD', '$(LDADD)', $where);
2524
2525           # This does a bit too much work.  But we need it to
2526           # generate _DEPENDENCIES when appropriate.
2527           if (var ('LDADD'))
2528             {
2529               $seen_libobjs = &handle_lib_objects ($xname, 'LDADD');
2530             }
2531         }
2532
2533       reject_var ($xname . '_LIBADD',
2534                   "use '${xname}_LDADD', not '${xname}_LIBADD'");
2535
2536       set_seen ($xname . '_DEPENDENCIES');
2537       set_seen ('EXTRA_' . $xname . '_DEPENDENCIES');
2538       set_seen ($xname . '_LDFLAGS');
2539
2540       # Determine program to use for link.
2541       my($xlink, $vlink) = &define_per_target_linker_variable ($linker, $xname);
2542       $vlink = verbose_flag ($vlink || 'GEN');
2543
2544       # If the resulting program lies into a subdirectory,
2545       # make sure this directory will exist.
2546       my $dirstamp = require_build_directory_maybe ($one_file);
2547
2548       $libtool_clean_directories{dirname ($one_file)} = 1;
2549
2550       $output_rules .= &file_contents ('program',
2551                                        $where,
2552                                        PROGRAM  => $one_file,
2553                                        XPROGRAM => $xname,
2554                                        XLINK    => $xlink,
2555                                        VERBOSE  => $vlink,
2556                                        DIRSTAMP => $dirstamp,
2557                                        EXEEXT   => '$(EXEEXT)');
2558
2559       if ($seen_libobjs || $seen_global_libobjs)
2560         {
2561           if (var ($xname . '_LDADD'))
2562             {
2563               &check_libobjs_sources ($xname, $xname . '_LDADD');
2564             }
2565           elsif (var ('LDADD'))
2566             {
2567               &check_libobjs_sources ($xname, 'LDADD');
2568             }
2569         }
2570     }
2571 }
2572
2573
2574 # handle_libraries ()
2575 # -------------------
2576 # Handle libraries.
2577 sub handle_libraries
2578 {
2579   my @liblist = &am_install_var ('libs', 'LIBRARIES',
2580                                  'lib', 'pkglib', 'noinst', 'check');
2581   return if ! @liblist;
2582   $must_handle_compiled_objects = 1;
2583
2584   my @prefix = am_primary_prefixes ('LIBRARIES', 0, 'lib', 'pkglib',
2585                                     'noinst', 'check');
2586
2587   if (@prefix)
2588     {
2589       my $var = rvar ($prefix[0] . '_LIBRARIES');
2590       $var->requires_variables ('library used', 'RANLIB');
2591     }
2592
2593   &define_variable ('AR', 'ar', INTERNAL);
2594   &define_variable ('ARFLAGS', 'cru', INTERNAL);
2595   &define_verbose_tagvar ('AR');
2596
2597   foreach my $pair (@liblist)
2598     {
2599       my ($where, $onelib) = @$pair;
2600
2601       my $seen_libobjs = 0;
2602       # Check that the library fits the standard naming convention.
2603       my $bn = basename ($onelib);
2604       if ($bn !~ /^lib.*\.a$/)
2605         {
2606           $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.a/;
2607           my $suggestion = dirname ($onelib) . "/$bn";
2608           $suggestion =~ s|^\./||g;
2609           msg ('error-gnu/warn', $where,
2610                "'$onelib' is not a standard library name\n"
2611                . "did you mean '$suggestion'?")
2612         }
2613
2614       ($known_libraries{$onelib} = $bn) =~ s/\.a$//;
2615
2616       $where->push_context ("while processing library '$onelib'");
2617       $where->set (INTERNAL->get);
2618
2619       my $obj = '.$(OBJEXT)';
2620
2621       # Canonicalize names and check for misspellings.
2622       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_SOURCES',
2623                                             '_OBJECTS', '_DEPENDENCIES',
2624                                             '_AR');
2625
2626       if (! var ($xlib . '_AR'))
2627         {
2628           &define_variable ($xlib . '_AR', '$(AR) $(ARFLAGS)', $where);
2629         }
2630
2631       # Generate support for conditional object inclusion in
2632       # libraries.
2633       if (var ($xlib . '_LIBADD'))
2634         {
2635           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2636             {
2637               $seen_libobjs = 1;
2638             }
2639         }
2640       else
2641         {
2642           &define_variable ($xlib . "_LIBADD", '', $where);
2643         }
2644
2645       reject_var ($xlib . '_LDADD',
2646                   "use '${xlib}_LIBADD', not '${xlib}_LDADD'");
2647
2648       # Make sure we at look at this.
2649       set_seen ($xlib . '_DEPENDENCIES');
2650       set_seen ('EXTRA_' . $xlib . '_DEPENDENCIES');
2651
2652       &handle_source_transform ($xlib, $onelib, $obj, $where,
2653                                 NONLIBTOOL => 1, LIBTOOL => 0);
2654
2655       # If the resulting library lies into a subdirectory,
2656       # make sure this directory will exist.
2657       my $dirstamp = require_build_directory_maybe ($onelib);
2658       my $verbose = verbose_flag ('AR');
2659       my $silent = silent_flag ();
2660
2661       $output_rules .= &file_contents ('library',
2662                                        $where,
2663                                        VERBOSE  => $verbose,
2664                                        SILENT   => $silent,
2665                                        LIBRARY  => $onelib,
2666                                        XLIBRARY => $xlib,
2667                                        DIRSTAMP => $dirstamp);
2668
2669       if ($seen_libobjs)
2670         {
2671           if (var ($xlib . '_LIBADD'))
2672             {
2673               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2674             }
2675         }
2676
2677       if (! $seen_ar)
2678         {
2679           msg ('extra-portability', $where,
2680                "'$onelib': linking libraries using a non-POSIX\n"
2681                . "archiver requires 'AM_PROG_AR' in '$configure_ac'")
2682         }
2683     }
2684 }
2685
2686
2687 # handle_ltlibraries ()
2688 # ---------------------
2689 # Handle shared libraries.
2690 sub handle_ltlibraries
2691 {
2692   my @liblist = &am_install_var ('ltlib', 'LTLIBRARIES',
2693                                  'noinst', 'lib', 'pkglib', 'check');
2694   return if ! @liblist;
2695   $must_handle_compiled_objects = 1;
2696
2697   my @prefix = am_primary_prefixes ('LTLIBRARIES', 0, 'lib', 'pkglib',
2698                                     'noinst', 'check');
2699
2700   if (@prefix)
2701     {
2702       my $var = rvar ($prefix[0] . '_LTLIBRARIES');
2703       $var->requires_variables ('Libtool library used', 'LIBTOOL');
2704     }
2705
2706   my %instdirs = ();
2707   my %instsubdirs = ();
2708   my %instconds = ();
2709   my %liblocations = ();        # Location (in Makefile.am) of each library.
2710
2711   foreach my $key (@prefix)
2712     {
2713       # Get the installation directory of each library.
2714       my $dir = $key;
2715       my $strip_subdir = 1;
2716       if ($dir =~ /^nobase_/)
2717         {
2718           $dir =~ s/^nobase_//;
2719           $strip_subdir = 0;
2720         }
2721       my $var = rvar ($key . '_LTLIBRARIES');
2722
2723       # We reject libraries which are installed in several places
2724       # in the same condition, because we can only specify one
2725       # '-rpath' option.
2726       $var->traverse_recursively
2727         (sub
2728          {
2729            my ($var, $val, $cond, $full_cond) = @_;
2730            my $hcond = $full_cond->human;
2731            my $where = $var->rdef ($cond)->location;
2732            my $ldir = '';
2733            $ldir = '/' . dirname ($val)
2734              if (!$strip_subdir);
2735            # A library cannot be installed in different directories
2736            # in overlapping conditions.
2737            if (exists $instconds{$val})
2738              {
2739                my ($msg, $acond) =
2740                  $instconds{$val}->ambiguous_p ($val, $full_cond);
2741
2742                if ($msg)
2743                  {
2744                    error ($where, $msg, partial => 1);
2745                    my $dirtxt = "installed " . ($strip_subdir ? "in" : "below") . " '$dir'";
2746                    $dirtxt = "built for '$dir'"
2747                      if $dir eq 'EXTRA' || $dir eq 'noinst' || $dir eq 'check';
2748                    my $dircond =
2749                      $full_cond->true ? "" : " in condition $hcond";
2750
2751                    error ($where, "'$val' should be $dirtxt$dircond ...",
2752                           partial => 1);
2753
2754                    my $hacond = $acond->human;
2755                    my $adir = $instdirs{$val}{$acond};
2756                    my $adirtxt = "installed in '$adir'";
2757                    $adirtxt = "built for '$adir'"
2758                      if ($adir eq 'EXTRA' || $adir eq 'noinst'
2759                          || $adir eq 'check');
2760                    my $adircond = $acond->true ? "" : " in condition $hacond";
2761
2762                    my $onlyone = ($dir ne $adir) ?
2763                      ("\nLibtool libraries can be built for only one "
2764                       . "destination") : "";
2765
2766                    error ($liblocations{$val}{$acond},
2767                           "... and should also be $adirtxt$adircond.$onlyone");
2768                    return;
2769                  }
2770              }
2771            else
2772              {
2773                $instconds{$val} = new Automake::DisjConditions;
2774              }
2775            $instdirs{$val}{$full_cond} = $dir;
2776            $instsubdirs{$val}{$full_cond} = $ldir;
2777            $liblocations{$val}{$full_cond} = $where;
2778            $instconds{$val} = $instconds{$val}->merge ($full_cond);
2779          },
2780          sub
2781          {
2782            return ();
2783          },
2784          skip_ac_subst => 1);
2785     }
2786
2787   foreach my $pair (@liblist)
2788     {
2789       my ($where, $onelib) = @$pair;
2790
2791       my $seen_libobjs = 0;
2792       my $obj = '.lo';
2793
2794       # Canonicalize names and check for misspellings.
2795       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_LDFLAGS',
2796                                             '_SOURCES', '_OBJECTS',
2797                                             '_DEPENDENCIES');
2798
2799       # Check that the library fits the standard naming convention.
2800       my $libname_rx = '^lib.*\.la';
2801       my $ldvar = var ("${xlib}_LDFLAGS") || var ('AM_LDFLAGS');
2802       my $ldvar2 = var ('LDFLAGS');
2803       if (($ldvar && grep (/-module/, $ldvar->value_as_list_recursive))
2804           || ($ldvar2 && grep (/-module/, $ldvar2->value_as_list_recursive)))
2805         {
2806           # Relax name checking for libtool modules.
2807           $libname_rx = '\.la';
2808         }
2809
2810       my $bn = basename ($onelib);
2811       if ($bn !~ /$libname_rx$/)
2812         {
2813           my $type = 'library';
2814           if ($libname_rx eq '\.la')
2815             {
2816               $bn =~ s/^(lib|)(.*?)(?:\.[^.]*)?$/$1$2.la/;
2817               $type = 'module';
2818             }
2819           else
2820             {
2821               $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.la/;
2822             }
2823           my $suggestion = dirname ($onelib) . "/$bn";
2824           $suggestion =~ s|^\./||g;
2825           msg ('error-gnu/warn', $where,
2826                "'$onelib' is not a standard libtool $type name\n"
2827                . "did you mean '$suggestion'?")
2828         }
2829
2830       ($known_libraries{$onelib} = $bn) =~ s/\.la$//;
2831
2832       $where->push_context ("while processing Libtool library '$onelib'");
2833       $where->set (INTERNAL->get);
2834
2835       # Make sure we look at these.
2836       set_seen ($xlib . '_LDFLAGS');
2837       set_seen ($xlib . '_DEPENDENCIES');
2838       set_seen ('EXTRA_' . $xlib . '_DEPENDENCIES');
2839
2840       # Generate support for conditional object inclusion in
2841       # libraries.
2842       if (var ($xlib . '_LIBADD'))
2843         {
2844           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2845             {
2846               $seen_libobjs = 1;
2847             }
2848         }
2849       else
2850         {
2851           &define_variable ($xlib . "_LIBADD", '', $where);
2852         }
2853
2854       reject_var ("${xlib}_LDADD",
2855                   "use '${xlib}_LIBADD', not '${xlib}_LDADD'");
2856
2857
2858       my $linker = &handle_source_transform ($xlib, $onelib, $obj, $where,
2859                                              NONLIBTOOL => 0, LIBTOOL => 1);
2860
2861       # Determine program to use for link.
2862       my($xlink, $vlink) = &define_per_target_linker_variable ($linker, $xlib);
2863       $vlink = verbose_flag ($vlink || 'GEN');
2864
2865       my $rpathvar = "am_${xlib}_rpath";
2866       my $rpath = "\$($rpathvar)";
2867       foreach my $rcond ($instconds{$onelib}->conds)
2868         {
2869           my $val;
2870           if ($instdirs{$onelib}{$rcond} eq 'EXTRA'
2871               || $instdirs{$onelib}{$rcond} eq 'noinst'
2872               || $instdirs{$onelib}{$rcond} eq 'check')
2873             {
2874               # It's an EXTRA_ library, so we can't specify -rpath,
2875               # because we don't know where the library will end up.
2876               # The user probably knows, but generally speaking automake
2877               # doesn't -- and in fact configure could decide
2878               # dynamically between two different locations.
2879               $val = '';
2880             }
2881           else
2882             {
2883               $val = ('-rpath $(' . $instdirs{$onelib}{$rcond} . 'dir)');
2884               $val .= $instsubdirs{$onelib}{$rcond}
2885                 if defined $instsubdirs{$onelib}{$rcond};
2886             }
2887           if ($rcond->true)
2888             {
2889               # If $rcond is true there is only one condition and
2890               # there is no point defining an helper variable.
2891               $rpath = $val;
2892             }
2893           else
2894             {
2895               define_pretty_variable ($rpathvar, $rcond, INTERNAL, $val);
2896             }
2897         }
2898
2899       # If the resulting library lies into a subdirectory,
2900       # make sure this directory will exist.
2901       my $dirstamp = require_build_directory_maybe ($onelib);
2902
2903       # Remember to cleanup .libs/ in this directory.
2904       my $dirname = dirname $onelib;
2905       $libtool_clean_directories{$dirname} = 1;
2906
2907       $output_rules .= &file_contents ('ltlibrary',
2908                                        $where,
2909                                        LTLIBRARY  => $onelib,
2910                                        XLTLIBRARY => $xlib,
2911                                        RPATH      => $rpath,
2912                                        XLINK      => $xlink,
2913                                        VERBOSE    => $vlink,
2914                                        DIRSTAMP   => $dirstamp);
2915       if ($seen_libobjs)
2916         {
2917           if (var ($xlib . '_LIBADD'))
2918             {
2919               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2920             }
2921         }
2922
2923       if (! $seen_ar)
2924         {
2925           msg ('extra-portability', $where,
2926                "'$onelib': linking libtool libraries using a non-POSIX\n"
2927                . "archiver requires 'AM_PROG_AR' in '$configure_ac'")
2928         }
2929     }
2930 }
2931
2932 # See if any _SOURCES variable were misspelled.
2933 sub check_typos ()
2934 {
2935   # It is ok if the user sets this particular variable.
2936   set_seen 'AM_LDFLAGS';
2937
2938   foreach my $primary ('SOURCES', 'LIBADD', 'LDADD', 'LDFLAGS', 'DEPENDENCIES')
2939     {
2940       foreach my $var (variables $primary)
2941         {
2942           my $varname = $var->name;
2943           # A configure variable is always legitimate.
2944           next if exists $configure_vars{$varname};
2945
2946           for my $cond ($var->conditions->conds)
2947             {
2948               $varname =~ /^(?:EXTRA_)?(?:nobase_)?(?:dist_|nodist_)?(.*)_[[:alnum:]]+$/;
2949               msg_var ('syntax', $var, "variable '$varname' is defined but no"
2950                        . " program or\nlibrary has '$1' as canonical name"
2951                        . " (possible typo)")
2952                 unless $var->rdef ($cond)->seen;
2953             }
2954         }
2955     }
2956 }
2957
2958
2959 # Handle scripts.
2960 sub handle_scripts
2961 {
2962     # NOTE we no longer automatically clean SCRIPTS, because it is
2963     # useful to sometimes distribute scripts verbatim.  This happens
2964     # e.g. in Automake itself.
2965     &am_install_var ('-candist', 'scripts', 'SCRIPTS',
2966                      'bin', 'sbin', 'libexec', 'pkglibexec', 'pkgdata',
2967                      'noinst', 'check');
2968 }
2969
2970
2971
2972
2973 ## ------------------------ ##
2974 ## Handling Texinfo files.  ##
2975 ## ------------------------ ##
2976
2977 # ($OUTFILE, $VFILE, @CLEAN_FILES)
2978 # &scan_texinfo_file ($FILENAME)
2979 # ------------------------------
2980 # $OUTFILE     - name of the info file produced by $FILENAME.
2981 # $VFILE       - name of the version.texi file used (undef if none).
2982 # @CLEAN_FILES - list of byproducts (indexes etc.)
2983 sub scan_texinfo_file ($)
2984 {
2985   my ($filename) = @_;
2986
2987   # Some of the following extensions are always created, no matter
2988   # whether indexes are used or not.  Other (like cps, fns, ... pgs)
2989   # are only created when they are used.  We used to scan $FILENAME
2990   # for their use, but that is not enough: they could be used in
2991   # included files.  We can't scan included files because we don't
2992   # know the include path.  Therefore we always erase these files, no
2993   # matter whether they are used or not.
2994   #
2995   # (tmp is only created if an @macro is used and a certain e-TeX
2996   # feature is not available.)
2997   my %clean_suffixes =
2998     map { $_ => 1 } (qw(aux log toc tmp
2999                         cp cps
3000                         fn fns
3001                         ky kys
3002                         vr vrs
3003                         tp tps
3004                         pg pgs)); # grep 'new.*index' texinfo.tex
3005
3006   my $texi = new Automake::XFile "< $filename";
3007   verb "reading $filename";
3008
3009   my ($outfile, $vfile);
3010   while ($_ = $texi->getline)
3011     {
3012       if (/^\@setfilename +(\S+)/)
3013         {
3014           # Honor only the first @setfilename.  (It's possible to have
3015           # more occurrences later if the manual shows examples of how
3016           # to use @setfilename...)
3017           next if $outfile;
3018
3019           $outfile = $1;
3020           if ($outfile =~ /\.([^.]+)$/ && $1 ne 'info')
3021             {
3022               error ("$filename:$.",
3023                      "output '$outfile' has unrecognized extension");
3024               return;
3025             }
3026         }
3027       # A "version.texi" file is actually any file whose name matches
3028       # "vers*.texi".
3029       elsif (/^\@include\s+(vers[^.]*\.texi)\s*$/)
3030         {
3031           $vfile = $1;
3032         }
3033
3034       # Try to find new or unused indexes.
3035
3036       # Creating a new category of index.
3037       elsif (/^\@def(code)?index (\w+)/)
3038         {
3039           $clean_suffixes{$2} = 1;
3040           $clean_suffixes{"$2s"} = 1;
3041         }
3042
3043       # Merging an index into an another.
3044       elsif (/^\@syn(code)?index (\w+) (\w+)/)
3045         {
3046           delete $clean_suffixes{"$2s"};
3047           $clean_suffixes{"$3s"} = 1;
3048         }
3049
3050     }
3051
3052   if (! $outfile)
3053     {
3054       err_am "'$filename' missing \@setfilename";
3055       return;
3056     }
3057
3058   my $infobase = basename ($filename);
3059   $infobase =~ s/\.te?xi(nfo)?$//;
3060   return ($outfile, $vfile,
3061           map { "$infobase.$_" } (sort keys %clean_suffixes));
3062 }
3063
3064
3065 # ($DIRSTAMP, @CLEAN_FILES)
3066 # output_texinfo_build_rules ($SOURCE, $DEST, $INSRC, @DEPENDENCIES)
3067 # ------------------------------------------------------------------
3068 # SOURCE - the source Texinfo file
3069 # DEST - the destination Info file
3070 # INSRC - whether DEST should be built in the source tree
3071 # DEPENDENCIES - known dependencies
3072 sub output_texinfo_build_rules ($$$@)
3073 {
3074   my ($source, $dest, $insrc, @deps) = @_;
3075
3076   # Split 'a.texi' into 'a' and '.texi'.
3077   my ($spfx, $ssfx) = ($source =~ /^(.*?)(\.[^.]*)?$/);
3078   my ($dpfx, $dsfx) = ($dest =~ /^(.*?)(\.[^.]*)?$/);
3079
3080   $ssfx ||= "";
3081   $dsfx ||= "";
3082
3083   # We can output two kinds of rules: the "generic" rules use Make
3084   # suffix rules and are appropriate when $source and $dest do not lie
3085   # in a sub-directory; the "specific" rules are needed in the other
3086   # case.
3087   #
3088   # The former are output only once (this is not really apparent here,
3089   # but just remember that some logic deeper in Automake will not
3090   # output the same rule twice); while the later need to be output for
3091   # each Texinfo source.
3092   my $generic;
3093   my $makeinfoflags;
3094   my $sdir = dirname $source;
3095   if ($sdir eq '.' && dirname ($dest) eq '.')
3096     {
3097       $generic = 1;
3098       $makeinfoflags = '-I $(srcdir)';
3099     }
3100   else
3101     {
3102       $generic = 0;
3103       $makeinfoflags = "-I $sdir -I \$(srcdir)/$sdir";
3104     }
3105
3106   # A directory can contain two kinds of info files: some built in the
3107   # source tree, and some built in the build tree.  The rules are
3108   # different in each case.  However we cannot output two different
3109   # set of generic rules.  Because in-source builds are more usual, we
3110   # use generic rules in this case and fall back to "specific" rules
3111   # for build-dir builds.  (It should not be a problem to invert this
3112   # if needed.)
3113   $generic = 0 unless $insrc;
3114
3115   # We cannot use a suffix rule to build info files with an empty
3116   # extension.  Otherwise we would output a single suffix inference
3117   # rule, with separate dependencies, as in
3118   #
3119   #    .texi:
3120   #             $(MAKEINFO) ...
3121   #    foo.info: foo.texi
3122   #
3123   # which confuse Solaris make.  (See the Autoconf manual for
3124   # details.)  Therefore we use a specific rule in this case.  This
3125   # applies to info files only (dvi and pdf files always have an
3126   # extension).
3127   my $generic_info = ($generic && $dsfx) ? 1 : 0;
3128
3129   # If the resulting file lie into a subdirectory,
3130   # make sure this directory will exist.
3131   my $dirstamp = require_build_directory_maybe ($dest);
3132
3133   my $dipfx = ($insrc ? '$(srcdir)/' : '') . $dpfx;
3134
3135   $output_rules .= file_contents ('texibuild',
3136                                   new Automake::Location,
3137                                   AM_V_MAKEINFO    => verbose_flag('MAKEINFO'),
3138                                   AM_V_TEXI2DVI    => verbose_flag('TEXI2DVI'),
3139                                   AM_V_TEXI2PDF    => verbose_flag('TEXI2PDF'),
3140                                   DEPS             => "@deps",
3141                                   DEST_PREFIX      => $dpfx,
3142                                   DEST_INFO_PREFIX => $dipfx,
3143                                   DEST_SUFFIX      => $dsfx,
3144                                   DIRSTAMP         => $dirstamp,
3145                                   GENERIC          => $generic,
3146                                   GENERIC_INFO     => $generic_info,
3147                                   INSRC            => $insrc,
3148                                   MAKEINFOFLAGS    => $makeinfoflags,
3149                                   SILENT           => silent_flag(),
3150                                   SOURCE           => ($generic
3151                                                        ? '$<' : $source),
3152                                   SOURCE_INFO      => ($generic_info
3153                                                        ? '$<' : $source),
3154                                   SOURCE_REAL      => $source,
3155                                   SOURCE_SUFFIX    => $ssfx,
3156                                   TEXIQUIET        => verbose_flag('texinfo'),
3157                                   TEXIDEVNULL      => verbose_flag('texidevnull'),
3158                                   );
3159   return ($dirstamp, "$dpfx.dvi", "$dpfx.pdf", "$dpfx.ps", "$dpfx.html");
3160 }
3161
3162
3163 # ($MOSTLYCLEAN, $TEXICLEAN, $MAINTCLEAN)
3164 # handle_texinfo_helper ($info_texinfos)
3165 # --------------------------------------
3166 # Handle all Texinfo source; helper for handle_texinfo.
3167 sub handle_texinfo_helper ($)
3168 {
3169   my ($info_texinfos) = @_;
3170   my (@infobase, @info_deps_list, @texi_deps);
3171   my %versions;
3172   my $done = 0;
3173   my (@mostly_cleans, @texi_cleans, @maint_cleans) = ('', '', '');
3174
3175   # Build a regex matching user-cleaned files.
3176   my $d = var 'DISTCLEANFILES';
3177   my $c = var 'CLEANFILES';
3178   my @f = ();
3179   push @f, $d->value_as_list_recursive (inner_expand => 1) if $d;
3180   push @f, $c->value_as_list_recursive (inner_expand => 1) if $c;
3181   @f = map { s|[^A-Za-z_0-9*\[\]\-]|\\$&|g; s|\*|[^/]*|g; $_; } @f;
3182   my $user_cleaned_files = '^(?:' . join ('|', @f) . ')$';
3183
3184   foreach my $texi
3185       ($info_texinfos->value_as_list_recursive (inner_expand => 1))
3186     {
3187       my $infobase = $texi;
3188       $infobase =~ s/\.(txi|texinfo|texi)$//;
3189
3190       if ($infobase eq $texi)
3191         {
3192           # FIXME: report line number.
3193           err_am "texinfo file '$texi' has unrecognized extension";
3194           next;
3195         }
3196
3197       push @infobase, $infobase;
3198
3199       # If 'version.texi' is referenced by input file, then include
3200       # automatic versioning capability.
3201       my ($out_file, $vtexi, @clean_files) =
3202         scan_texinfo_file ("$relative_dir/$texi")
3203         or next;
3204       push (@mostly_cleans, @clean_files);
3205
3206       # If the Texinfo source is in a subdirectory, create the
3207       # resulting info in this subdirectory.  If it is in the current
3208       # directory, try hard to not prefix "./" because it breaks the
3209       # generic rules.
3210       my $outdir = dirname ($texi) . '/';
3211       $outdir = "" if $outdir eq './';
3212       $out_file =  $outdir . $out_file;
3213
3214       # Until Automake 1.6.3, .info files were built in the
3215       # source tree.  This was an obstacle to the support of
3216       # non-distributed .info files, and non-distributed .texi
3217       # files.
3218       #
3219       # * Non-distributed .texi files is important in some packages
3220       #   where .texi files are built at make time, probably using
3221       #   other binaries built in the package itself, maybe using
3222       #   tools or information found on the build host.  Because
3223       #   these files are not distributed they are always rebuilt
3224       #   at make time; they should therefore not lie in the source
3225       #   directory.  One plan was to support this using
3226       #   nodist_info_TEXINFOS or something similar.  (Doing this
3227       #   requires some sanity checks.  For instance Automake should
3228       #   not allow:
3229       #      dist_info_TEXINFOS = foo.texi
3230       #      nodist_foo_TEXINFOS = included.texi
3231       #   because a distributed file should never depend on a
3232       #   non-distributed file.)
3233       #
3234       # * If .texi files are not distributed, then .info files should
3235       #   not be distributed either.  There are also cases where one
3236       #   wants to distribute .texi files, but does not want to
3237       #   distribute the .info files.  For instance the Texinfo package
3238       #   distributes the tool used to build these files; it would
3239       #   be a waste of space to distribute them.  It's not clear
3240       #   which syntax we should use to indicate that .info files should
3241       #   not be distributed.  Akim Demaille suggested that eventually
3242       #   we switch to a new syntax:
3243       #   |  Maybe we should take some inspiration from what's already
3244       #   |  done in the rest of Automake.  Maybe there is too much
3245       #   |  syntactic sugar here, and you want
3246       #   |     nodist_INFO = bar.info
3247       #   |     dist_bar_info_SOURCES = bar.texi
3248       #   |     bar_texi_DEPENDENCIES = foo.texi
3249       #   |  with a bit of magic to have bar.info represent the whole
3250       #   |  bar*info set.  That's a lot more verbose that the current
3251       #   |  situation, but it is # not new, hence the user has less
3252       #   |  to learn.
3253       #   |
3254       #   |  But there is still too much room for meaningless specs:
3255       #   |     nodist_INFO = bar.info
3256       #   |     dist_bar_info_SOURCES = bar.texi
3257       #   |     dist_PS = bar.ps something-written-by-hand.ps
3258       #   |     nodist_bar_ps_SOURCES = bar.texi
3259       #   |     bar_texi_DEPENDENCIES = foo.texi
3260       #   |  here bar.texi is dist_ in line 2, and nodist_ in 4.
3261       #
3262       # Back to the point, it should be clear that in order to support
3263       # non-distributed .info files, we need to build them in the
3264       # build tree, not in the source tree (non-distributed .texi
3265       # files are less of a problem, because we do not output build
3266       # rules for them).  In Automake 1.7 .info build rules have been
3267       # largely cleaned up so that .info files get always build in the
3268       # build tree, even when distributed.  The idea was that
3269       #   (1) if during a VPATH build the .info file was found to be
3270       #       absent or out-of-date (in the source tree or in the
3271       #       build tree), Make would rebuild it in the build tree.
3272       #       If an up-to-date source-tree of the .info file existed,
3273       #       make would not rebuild it in the build tree.
3274       #   (2) having two copies of .info files, one in the source tree
3275       #       and one (newer) in the build tree is not a problem
3276       #       because 'make dist' always pick files in the build tree
3277       #       first.
3278       # However it turned out the be a bad idea for several reasons:
3279       #   * Tru64, OpenBSD, and FreeBSD (not NetBSD) Make do not behave
3280       #     like GNU Make on point (1) above.  These implementations
3281       #     of Make would always rebuild .info files in the build
3282       #     tree, even if such files were up to date in the source
3283       #     tree.  Consequently, it was impossible to perform a VPATH
3284       #     build of a package containing Texinfo files using these
3285       #     Make implementations.
3286       #     (Refer to the Autoconf Manual, section "Limitation of
3287       #     Make", paragraph "VPATH", item "target lookup", for
3288       #     an account of the differences between these
3289       #     implementations.)
3290       #   * The GNU Coding Standards require these files to be built
3291       #     in the source-tree (when they are distributed, that is).
3292       #   * Keeping a fresher copy of distributed files in the
3293       #     build tree can be annoying during development because
3294       #     - if the files is kept under CVS, you really want it
3295       #       to be updated in the source tree
3296       #     - it is confusing that 'make distclean' does not erase
3297       #       all files in the build tree.
3298       #
3299       # Consequently, starting with Automake 1.8, .info files are
3300       # built in the source tree again.  Because we still plan to
3301       # support non-distributed .info files at some point, we
3302       # have a single variable ($INSRC) that controls whether
3303       # the current .info file must be built in the source tree
3304       # or in the build tree.  Actually this variable is switched
3305       # off for .info files that appear to be cleaned; this is
3306       # for backward compatibility with package such as Texinfo,
3307       # which do things like
3308       #   info_TEXINFOS = texinfo.txi info-stnd.texi info.texi
3309       #   DISTCLEANFILES = texinfo texinfo-* info*.info*
3310       #   # Do not create info files for distribution.
3311       #   dist-info:
3312       # in order not to distribute .info files.
3313       my $insrc = ($out_file =~ $user_cleaned_files) ? 0 : 1;
3314
3315       my $soutdir = '$(srcdir)/' . $outdir;
3316       $outdir = $soutdir if $insrc;
3317
3318       # If user specified file_TEXINFOS, then use that as explicit
3319       # dependency list.
3320       @texi_deps = ();
3321       push (@texi_deps, "$soutdir$vtexi") if $vtexi;
3322
3323       my $canonical = canonicalize ($infobase);
3324       if (var ($canonical . "_TEXINFOS"))
3325         {
3326           push (@texi_deps, '$(' . $canonical . '_TEXINFOS)');
3327           push_dist_common ('$(' . $canonical . '_TEXINFOS)');
3328         }
3329
3330       my ($dirstamp, @cfiles) =
3331         output_texinfo_build_rules ($texi, $out_file, $insrc, @texi_deps);
3332       push (@texi_cleans, @cfiles);
3333
3334       push (@info_deps_list, $out_file);
3335
3336       # If a vers*.texi file is needed, emit the rule.
3337       if ($vtexi)
3338         {
3339           err_am ("'$vtexi', included in '$texi', "
3340                   . "also included in '$versions{$vtexi}'")
3341             if defined $versions{$vtexi};
3342           $versions{$vtexi} = $texi;
3343
3344           # We number the stamp-vti files.  This is doable since the
3345           # actual names don't matter much.  We only number starting
3346           # with the second one, so that the common case looks nice.
3347           my $vti = ($done ? $done : 'vti');
3348           ++$done;
3349
3350           # This is ugly, but it is our historical practice.
3351           if ($config_aux_dir_set_in_configure_ac)
3352             {
3353               require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3354                                             'mdate-sh');
3355             }
3356           else
3357             {
3358               require_file_with_macro (TRUE, 'info_TEXINFOS',
3359                                        FOREIGN, 'mdate-sh');
3360             }
3361
3362           my $conf_dir;
3363           if ($config_aux_dir_set_in_configure_ac)
3364             {
3365               $conf_dir = "$am_config_aux_dir/";
3366             }
3367           else
3368             {
3369               $conf_dir = '$(srcdir)/';
3370             }
3371           $output_rules .= file_contents ('texi-vers',
3372                                           new Automake::Location,
3373                                           TEXI     => $texi,
3374                                           VTI      => $vti,
3375                                           STAMPVTI => "${soutdir}stamp-$vti",
3376                                           VTEXI    => "$soutdir$vtexi",
3377                                           MDDIR    => $conf_dir,
3378                                           DIRSTAMP => $dirstamp);
3379         }
3380     }
3381
3382   # Handle location of texinfo.tex.
3383   my $need_texi_file = 0;
3384   my $texinfodir;
3385   if (var ('TEXINFO_TEX'))
3386     {
3387       # The user defined TEXINFO_TEX so assume he knows what he is
3388       # doing.
3389       $texinfodir = ('$(srcdir)/'
3390                      . dirname (variable_value ('TEXINFO_TEX')));
3391     }
3392   elsif (option 'cygnus')
3393     {
3394       $texinfodir = '$(top_srcdir)/../texinfo';
3395       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3396     }
3397   elsif ($config_aux_dir_set_in_configure_ac)
3398     {
3399       $texinfodir = $am_config_aux_dir;
3400       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3401       $need_texi_file = 2; # so that we require_conf_file later
3402     }
3403   else
3404     {
3405       $texinfodir = '$(srcdir)';
3406       $need_texi_file = 1;
3407     }
3408   define_variable ('am__TEXINFO_TEX_DIR', $texinfodir, INTERNAL);
3409
3410   push (@dist_targets, 'dist-info');
3411
3412   if (! option 'no-installinfo')
3413     {
3414       # Make sure documentation is made and installed first.  Use
3415       # $(INFO_DEPS), not 'info', because otherwise recursive makes
3416       # get run twice during "make all".
3417       unshift (@all, '$(INFO_DEPS)');
3418     }
3419
3420   define_files_variable ("DVIS", @infobase, 'dvi', INTERNAL);
3421   define_files_variable ("PDFS", @infobase, 'pdf', INTERNAL);
3422   define_files_variable ("PSS", @infobase, 'ps', INTERNAL);
3423   define_files_variable ("HTMLS", @infobase, 'html', INTERNAL);
3424
3425   # This next isn't strictly needed now -- the places that look here
3426   # could easily be changed to look in info_TEXINFOS.  But this is
3427   # probably better, in case noinst_TEXINFOS is ever supported.
3428   define_variable ("TEXINFOS", variable_value ('info_TEXINFOS'), INTERNAL);
3429
3430   # Do some error checking.  Note that this file is not required
3431   # when in Cygnus mode; instead we defined TEXINFO_TEX explicitly
3432   # up above.
3433   if ($need_texi_file && ! option 'no-texinfo.tex')
3434     {
3435       if ($need_texi_file > 1)
3436         {
3437           require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3438                                         'texinfo.tex');
3439         }
3440       else
3441         {
3442           require_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3443                                    'texinfo.tex');
3444         }
3445     }
3446
3447   return (makefile_wrap ("", "\t  ", @mostly_cleans),
3448           makefile_wrap ("", "\t  ", @texi_cleans),
3449           makefile_wrap ("", "\t  ", @maint_cleans));
3450 }
3451
3452
3453 # handle_texinfo ()
3454 # -----------------
3455 # Handle all Texinfo source.
3456 sub handle_texinfo ()
3457 {
3458   reject_var 'TEXINFOS', "'TEXINFOS' is an anachronism; use 'info_TEXINFOS'";
3459   # FIXME: I think this is an obsolete future feature name.
3460   reject_var 'html_TEXINFOS', "HTML generation not yet supported";
3461
3462   my $info_texinfos = var ('info_TEXINFOS');
3463   my ($mostlyclean, $clean, $maintclean) = ('', '', '');
3464   if ($info_texinfos)
3465     {
3466       define_verbose_texinfo;
3467       ($mostlyclean, $clean, $maintclean) = handle_texinfo_helper ($info_texinfos);
3468       chomp $mostlyclean;
3469       chomp $clean;
3470       chomp $maintclean;
3471     }
3472
3473   $output_rules .=  file_contents ('texinfos',
3474                                    new Automake::Location,
3475                                    AM_V_DVIPS    => verbose_flag('DVIPS'),
3476                                    MOSTLYCLEAN   => $mostlyclean,
3477                                    TEXICLEAN     => $clean,
3478                                    MAINTCLEAN    => $maintclean,
3479                                    'LOCAL-TEXIS' => !!$info_texinfos,
3480                                    TEXIQUIET     => verbose_flag('texinfo'));
3481 }
3482
3483
3484 # Handle any man pages.
3485 sub handle_man_pages
3486 {
3487   reject_var 'MANS', "'MANS' is an anachronism; use 'man_MANS'";
3488
3489   # Find all the sections in use.  We do this by first looking for
3490   # "standard" sections, and then looking for any additional
3491   # sections used in man_MANS.
3492   my (%sections, %notrans_sections, %trans_sections,
3493       %notrans_vars, %trans_vars, %notrans_sect_vars, %trans_sect_vars);
3494   # We handle nodist_ for uniformity.  man pages aren't distributed
3495   # by default so it isn't actually very important.
3496   foreach my $npfx ('', 'notrans_')
3497     {
3498       foreach my $pfx ('', 'dist_', 'nodist_')
3499         {
3500           # Add more sections as needed.
3501           foreach my $section ('0'..'9', 'n', 'l')
3502             {
3503               my $varname = $npfx . $pfx . 'man' . $section . '_MANS';
3504               if (var ($varname))
3505                 {
3506                   $sections{$section} = 1;
3507                   $varname = '$(' . $varname . ')';
3508                   if ($npfx eq 'notrans_')
3509                     {
3510                       $notrans_sections{$section} = 1;
3511                       $notrans_sect_vars{$varname} = 1;
3512                     }
3513                   else
3514                     {
3515                       $trans_sections{$section} = 1;
3516                       $trans_sect_vars{$varname} = 1;
3517                     }
3518
3519                   &push_dist_common ($varname)
3520                     if $pfx eq 'dist_';
3521                 }
3522             }
3523
3524           my $varname = $npfx . $pfx . 'man_MANS';
3525           my $var = var ($varname);
3526           if ($var)
3527             {
3528               foreach ($var->value_as_list_recursive)
3529                 {
3530                   # A page like 'foo.1c' goes into man1dir.
3531                   if (/\.([0-9a-z])([a-z]*)$/)
3532                     {
3533                       $sections{$1} = 1;
3534                       if ($npfx eq 'notrans_')
3535                         {
3536                           $notrans_sections{$1} = 1;
3537                         }
3538                       else
3539                         {
3540                           $trans_sections{$1} = 1;
3541                         }
3542                     }
3543                 }
3544
3545               $varname = '$(' . $varname . ')';
3546               if ($npfx eq 'notrans_')
3547                 {
3548                   $notrans_vars{$varname} = 1;
3549                 }
3550               else
3551                 {
3552                   $trans_vars{$varname} = 1;
3553                 }
3554               &push_dist_common ($varname)
3555                 if $pfx eq 'dist_';
3556             }
3557         }
3558     }
3559
3560   return unless %sections;
3561
3562   my @unsorted_deps;
3563
3564   # Build section independent variables.
3565   my $have_notrans = %notrans_vars;
3566   my @notrans_list = sort keys %notrans_vars;
3567   my $have_trans = %trans_vars;
3568   my @trans_list = sort keys %trans_vars;
3569
3570   # Now for each section, generate an install and uninstall rule.
3571   # Sort sections so output is deterministic.
3572   foreach my $section (sort keys %sections)
3573     {
3574       # Build section dependent variables.
3575       my $notrans_mans = $have_notrans || exists $notrans_sections{$section};
3576       my $trans_mans = $have_trans || exists $trans_sections{$section};
3577       my (%notrans_this_sect, %trans_this_sect);
3578       my $expr = 'man' . $section . '_MANS';
3579       foreach my $varname (keys %notrans_sect_vars)
3580         {
3581           if ($varname =~ /$expr/)
3582             {
3583               $notrans_this_sect{$varname} = 1;
3584             }
3585         }
3586       foreach my $varname (keys %trans_sect_vars)
3587         {
3588           if ($varname =~ /$expr/)
3589             {
3590               $trans_this_sect{$varname} = 1;
3591             }
3592         }
3593       my @notrans_sect_list = sort keys %notrans_this_sect;
3594       my @trans_sect_list = sort keys %trans_this_sect;
3595       @unsorted_deps = (keys %notrans_vars, keys %trans_vars,
3596                         keys %notrans_this_sect, keys %trans_this_sect);
3597       my @deps = sort @unsorted_deps;
3598       $output_rules .= &file_contents ('mans',
3599                                        new Automake::Location,
3600                                        SECTION           => $section,
3601                                        DEPS              => "@deps",
3602                                        NOTRANS_MANS      => $notrans_mans,
3603                                        NOTRANS_SECT_LIST => "@notrans_sect_list",
3604                                        HAVE_NOTRANS      => $have_notrans,
3605                                        NOTRANS_LIST      => "@notrans_list",
3606                                        TRANS_MANS        => $trans_mans,
3607                                        TRANS_SECT_LIST   => "@trans_sect_list",
3608                                        HAVE_TRANS        => $have_trans,
3609                                        TRANS_LIST        => "@trans_list");
3610     }
3611
3612   @unsorted_deps  = (keys %notrans_vars, keys %trans_vars,
3613                      keys %notrans_sect_vars, keys %trans_sect_vars);
3614   my @mans = sort @unsorted_deps;
3615   $output_vars .= file_contents ('mans-vars',
3616                                  new Automake::Location,
3617                                  MANS => "@mans");
3618
3619   push (@all, '$(MANS)')
3620     unless option 'no-installman';
3621 }
3622
3623 # Handle DATA variables.
3624 sub handle_data
3625 {
3626     &am_install_var ('-noextra', '-candist', 'data', 'DATA',
3627                      'data', 'dataroot', 'doc', 'dvi', 'html', 'pdf',
3628                      'ps', 'sysconf', 'sharedstate', 'localstate',
3629                      'pkgdata', 'lisp', 'noinst', 'check');
3630 }
3631
3632 # Handle TAGS.
3633 sub handle_tags
3634 {
3635     my @tag_deps = ();
3636     my @ctag_deps = ();
3637     my @cscope_deps = ();
3638     if (var ('SUBDIRS'))
3639     {
3640         $output_rules .= ("tags-recursive:\n"
3641                           . "\tlist='\$(SUBDIRS)'; for subdir in \$\$list; do \\\n"
3642                           # Never fail here if a subdir fails; it
3643                           # isn't important.
3644                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3645                           . " && \$(MAKE) \$(AM_MAKEFLAGS) tags); \\\n"
3646                           . "\tdone\n");
3647         push (@tag_deps, 'tags-recursive');
3648         &depend ('.PHONY', 'tags-recursive');
3649         &depend ('.MAKE', 'tags-recursive');
3650
3651         $output_rules .= ("ctags-recursive:\n"
3652                           . "\tlist='\$(SUBDIRS)'; for subdir in \$\$list; do \\\n"
3653                           # Never fail here if a subdir fails; it
3654                           # isn't important.
3655                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3656                           . " && \$(MAKE) \$(AM_MAKEFLAGS) ctags); \\\n"
3657                           . "\tdone\n");
3658         push (@ctag_deps, 'ctags-recursive');
3659         &depend ('.PHONY', 'ctags-recursive');
3660         &depend ('.MAKE', 'ctags-recursive');
3661
3662         $output_rules .= ("cscopelist-recursive:\n"
3663                           . "\tlist='\$(SUBDIRS)'; for subdir in \$\$list; do \\\n"
3664                           # Never fail here if a subdir fails; it
3665                           # isn't important.
3666                           . "\t  test \"\$\$subdir\" = . || (\$(am__cd) \$\$subdir"
3667                           . " && \$(MAKE) \$(AM_MAKEFLAGS) cscopelist); \\\n"
3668                           . "\tdone\n");
3669         push (@cscope_deps, 'cscopelist-recursive');
3670         &depend ('.PHONY', 'cscopelist-recursive');
3671         &depend ('.MAKE', 'cscopelist-recursive');
3672     }
3673
3674     if (&saw_sources_p (1)
3675         || var ('ETAGS_ARGS')
3676         || @tag_deps)
3677     {
3678         my @config;
3679         foreach my $spec (@config_headers)
3680         {
3681             my ($out, @ins) = split_config_file_spec ($spec);
3682             foreach my $in (@ins)
3683               {
3684                 # If the config header source is in this directory,
3685                 # require it.
3686                 push @config, basename ($in)
3687                   if $relative_dir eq dirname ($in);
3688               }
3689         }
3690         $output_rules .= &file_contents ('tags',
3691                                          new Automake::Location,
3692                                          CONFIG    => "@config",
3693                                          TAGSDIRS  => "@tag_deps",
3694                                          CTAGSDIRS => "@ctag_deps",
3695                                          CSCOPEDIRS => "@cscope_deps");
3696
3697         set_seen 'TAGS_DEPENDENCIES';
3698     }
3699     elsif (reject_var ('TAGS_DEPENDENCIES',
3700                        "it doesn't make sense to define 'TAGS_DEPENDENCIES'"
3701                        . " without\nsources or 'ETAGS_ARGS'"))
3702     {
3703     }
3704     else
3705     {
3706         # Every Makefile must define some sort of TAGS rule.
3707         # Otherwise, it would be possible for a top-level "make TAGS"
3708         # to fail because some subdirectory failed.
3709         $output_rules .= "tags: TAGS\nTAGS:\n\n";
3710         # Ditto ctags and cscope.
3711         $output_rules .= "ctags: CTAGS\nCTAGS:\n\n";
3712         $output_rules .= "cscope cscopelist:\n\n";
3713     }
3714 }
3715
3716
3717 # user_phony_rule ($NAME)
3718 # -----------------------
3719 # Return false if rule $NAME does not exist.  Otherwise,
3720 # declare it as phony, complete its definition (in case it is
3721 # conditional), and return its Automake::Rule instance.
3722 sub user_phony_rule ($)
3723 {
3724   my ($name) = @_;
3725   my $rule = rule $name;
3726   if ($rule)
3727     {
3728       depend ('.PHONY', $name);
3729       # Define $NAME in all condition where it is not already defined,
3730       # so that it is always OK to depend on $NAME.
3731       for my $c ($rule->not_always_defined_in_cond (TRUE)->conds)
3732         {
3733           Automake::Rule::define ($name, 'internal', RULE_AUTOMAKE,
3734                                   $c, INTERNAL);
3735           $output_rules .= $c->subst_string . "$name:\n";
3736         }
3737     }
3738   return $rule;
3739 }
3740
3741
3742 # $BOOLEAN
3743 # &for_dist_common ($A, $B)
3744 # -------------------------
3745 # Subroutine for &handle_dist: sort files to dist.
3746 #
3747 # We put README first because it then becomes easier to make a
3748 # Usenet-compliant shar file (in these, README must be first).
3749 #
3750 # FIXME: do more ordering of files here.
3751 sub for_dist_common
3752 {
3753     return 0
3754         if $a eq $b;
3755     return -1
3756         if $a eq 'README';
3757     return 1
3758         if $b eq 'README';
3759     return $a cmp $b;
3760 }
3761
3762 # handle_dist
3763 # -----------
3764 # Handle 'dist' target.
3765 sub handle_dist ()
3766 {
3767   # Substitutions for distdir.am
3768   my %transform;
3769
3770   # Define DIST_SUBDIRS.  This must always be done, regardless of the
3771   # no-dist setting: target like 'distclean' or 'maintainer-clean' use it.
3772   my $subdirs = var ('SUBDIRS');
3773   if ($subdirs)
3774     {
3775       # If SUBDIRS is conditionally defined, then set DIST_SUBDIRS
3776       # to all possible directories, and use it.  If DIST_SUBDIRS is
3777       # defined, just use it.
3778
3779       # Note that we check DIST_SUBDIRS first on purpose, so that
3780       # we don't call has_conditional_contents for now reason.
3781       # (In the past one project used so many conditional subdirectories
3782       # that calling has_conditional_contents on SUBDIRS caused
3783       # automake to grow to 150Mb -- this should not happen with
3784       # the current implementation of has_conditional_contents,
3785       # but it's more efficient to avoid the call anyway.)
3786       if (var ('DIST_SUBDIRS'))
3787         {
3788         }
3789       elsif ($subdirs->has_conditional_contents)
3790         {
3791           define_pretty_variable
3792             ('DIST_SUBDIRS', TRUE, INTERNAL,
3793              uniq ($subdirs->value_as_list_recursive));
3794         }
3795       else
3796         {
3797           # We always define this because that is what 'distclean'
3798           # wants.
3799           define_pretty_variable ('DIST_SUBDIRS', TRUE, INTERNAL,
3800                                   '$(SUBDIRS)');
3801         }
3802     }
3803
3804   # The remaining definitions are only required when a dist target is used.
3805   return if option 'no-dist';
3806
3807   # At least one of the archive formats must be enabled.
3808   if ($relative_dir eq '.')
3809     {
3810       my $archive_defined = option 'no-dist-gzip' ? 0 : 1;
3811       $archive_defined ||=
3812         grep { option "dist-$_" } qw(shar zip tarZ bzip2 lzip lzma xz);
3813       error (option 'no-dist-gzip',
3814              "no-dist-gzip specified but no dist-* specified,\n"
3815              . "at least one archive format must be enabled")
3816         unless $archive_defined;
3817     }
3818
3819   # Look for common files that should be included in distribution.
3820   # If the aux dir is set, and it does not have a Makefile.am, then
3821   # we check for these files there as well.
3822   my $check_aux = 0;
3823   if ($relative_dir eq '.'
3824       && $config_aux_dir_set_in_configure_ac)
3825     {
3826       if (! &is_make_dir ($config_aux_dir))
3827         {
3828           $check_aux = 1;
3829         }
3830     }
3831   foreach my $cfile (@common_files)
3832     {
3833       if (dir_has_case_matching_file ($relative_dir, $cfile)
3834           # The file might be absent, but if it can be built it's ok.
3835           || rule $cfile)
3836         {
3837           &push_dist_common ($cfile);
3838         }
3839
3840       # Don't use 'elsif' here because a file might meaningfully
3841       # appear in both directories.
3842       if ($check_aux && dir_has_case_matching_file ($config_aux_dir, $cfile))
3843         {
3844           &push_dist_common ("$config_aux_dir/$cfile")
3845         }
3846     }
3847
3848   # We might copy elements from $configure_dist_common to
3849   # %dist_common if we think we need to.  If the file appears in our
3850   # directory, we would have discovered it already, so we don't
3851   # check that.  But if the file is in a subdir without a Makefile,
3852   # we want to distribute it here if we are doing '.'.  Ugly!
3853   # Also, in some corner cases, it's possible that the following code
3854   # will cause the same file to appear in the $(DIST_COMMON) variables
3855   # of two distinct Makefiles; but this is not a problem, since the
3856   # 'distdir' target in 'lib/am/distdir.am' can deal with the same
3857   # file being distributed multiple times.
3858   # See also automake bug#9651.
3859   if ($relative_dir eq '.')
3860     {
3861       foreach my $file (split (' ' , $configure_dist_common))
3862         {
3863           my $dir = dirname ($file);
3864           push_dist_common ($file)
3865             if ($dir eq '.' || ! is_make_dir ($dir));
3866         }
3867     }
3868
3869   # Files to distributed.  Don't use ->value_as_list_recursive
3870   # as it recursively expands '$(dist_pkgdata_DATA)' etc.
3871   my @dist_common = split (' ', rvar ('DIST_COMMON')->variable_value);
3872   @dist_common = uniq (sort for_dist_common (@dist_common));
3873   variable_delete 'DIST_COMMON';
3874   define_pretty_variable ('DIST_COMMON', TRUE, INTERNAL, @dist_common);
3875
3876   # Now that we've processed DIST_COMMON, disallow further attempts
3877   # to set it.
3878   $handle_dist_run = 1;
3879
3880   # Scan EXTRA_DIST to see if we need to distribute anything from a
3881   # subdir.  If so, add it to the list.  I didn't want to do this
3882   # originally, but there were so many requests that I finally
3883   # relented.
3884   my $extra_dist = var ('EXTRA_DIST');
3885
3886   $transform{'DISTCHECK-HOOK'} = !! rule 'distcheck-hook';
3887   $transform{'GETTEXT'} = $seen_gettext && !$seen_gettext_external;
3888
3889   # If the target 'dist-hook' exists, make sure it is run.  This
3890   # allows users to do random weird things to the distribution
3891   # before it is packaged up.
3892   push (@dist_targets, 'dist-hook')
3893     if user_phony_rule 'dist-hook';
3894   $transform{'DIST-TARGETS'} = join (' ', @dist_targets);
3895
3896   my $flm = option ('filename-length-max');
3897   my $filename_filter = $flm ? '.' x $flm->[1] : '';
3898
3899   $output_rules .= &file_contents ('distdir',
3900                                    new Automake::Location,
3901                                    %transform,
3902                                    FILENAME_FILTER => $filename_filter);
3903 }
3904
3905
3906 # check_directory ($NAME, $WHERE [, $RELATIVE_DIR = "."])
3907 # -------------------------------------------------------
3908 # Ensure $NAME is a directory (in $RELATIVE_DIR), and that it uses a sane
3909 # name.  Use $WHERE as a location in the diagnostic, if any.
3910 sub check_directory ($$;$)
3911 {
3912   my ($dir, $where, $reldir) = @_;
3913   $reldir = '.' unless defined $reldir;
3914
3915   error $where, "required directory $reldir/$dir does not exist"
3916     unless -d "$reldir/$dir";
3917
3918   # If an 'obj/' directory exists, BSD make will enter it before
3919   # reading 'Makefile'.  Hence the 'Makefile' in the current directory
3920   # will not be read.
3921   #
3922   #  % cat Makefile
3923   #  all:
3924   #          echo Hello
3925   #  % cat obj/Makefile
3926   #  all:
3927   #          echo World
3928   #  % make      # GNU make
3929   #  echo Hello
3930   #  Hello
3931   #  % pmake     # BSD make
3932   #  echo World
3933   #  World
3934   msg ('portability', $where,
3935        "naming a subdirectory 'obj' causes troubles with BSD make")
3936     if $dir eq 'obj';
3937
3938   # 'aux' is probably the most important of the following forbidden name,
3939   # since it's tempting to use it as an AC_CONFIG_AUX_DIR.
3940   msg ('portability', $where,
3941        "name '$dir' is reserved on W32 and DOS platforms")
3942     if grep (/^\Q$dir\E$/i, qw/aux lpt1 lpt2 lpt3 com1 com2 com3 com4 con prn/);
3943 }
3944
3945 # check_directories_in_var ($VARIABLE)
3946 # ------------------------------------
3947 # Recursively check all items in variables $VARIABLE as directories
3948 sub check_directories_in_var ($)
3949 {
3950   my ($var) = @_;
3951   $var->traverse_recursively
3952     (sub
3953      {
3954        my ($var, $val, $cond, $full_cond) = @_;
3955        check_directory ($val, $var->rdef ($cond)->location, $relative_dir);
3956        return ();
3957      },
3958      undef,
3959      skip_ac_subst => 1);
3960 }
3961
3962 # &handle_subdirs ()
3963 # ------------------
3964 # Handle subdirectories.
3965 sub handle_subdirs ()
3966 {
3967   my $subdirs = var ('SUBDIRS');
3968   return
3969     unless $subdirs;
3970
3971   check_directories_in_var $subdirs;
3972
3973   my $dsubdirs = var ('DIST_SUBDIRS');
3974   check_directories_in_var $dsubdirs
3975     if $dsubdirs;
3976
3977   $output_rules .= &file_contents ('subdirs', new Automake::Location);
3978   rvar ('RECURSIVE_TARGETS')->rdef (TRUE)->{'pretty'} = VAR_SORTED; # Gross!
3979 }
3980
3981
3982 # ($REGEN, @DEPENDENCIES)
3983 # &scan_aclocal_m4
3984 # ----------------
3985 # If aclocal.m4 creation is automated, return the list of its dependencies.
3986 sub scan_aclocal_m4 ()
3987 {
3988   my $regen_aclocal = 0;
3989
3990   set_seen 'CONFIG_STATUS_DEPENDENCIES';
3991   set_seen 'CONFIGURE_DEPENDENCIES';
3992
3993   if (-f 'aclocal.m4')
3994     {
3995       &define_variable ("ACLOCAL_M4", '$(top_srcdir)/aclocal.m4', INTERNAL);
3996
3997       my $aclocal = new Automake::XFile "< aclocal.m4";
3998       my $line = $aclocal->getline;
3999       $regen_aclocal = $line =~ 'generated automatically by aclocal';
4000     }
4001
4002   my @ac_deps = ();
4003
4004   if (set_seen ('ACLOCAL_M4_SOURCES'))
4005     {
4006       push (@ac_deps, '$(ACLOCAL_M4_SOURCES)');
4007       msg_var ('obsolete', 'ACLOCAL_M4_SOURCES',
4008                "'ACLOCAL_M4_SOURCES' is obsolete.\n"
4009                . "It should be safe to simply remove it");
4010     }
4011
4012   # Note that it might be possible that aclocal.m4 doesn't exist but
4013   # should be auto-generated.  This case probably isn't very
4014   # important.
4015
4016   return ($regen_aclocal, @ac_deps);
4017 }
4018
4019
4020 # Helper function for substitute_ac_subst_variables.
4021 sub substitute_ac_subst_variables_worker($)
4022 {
4023   my ($token) = @_;
4024   return "\@$token\@" if var $token;
4025   return "\${$token\}";
4026 }
4027
4028 # substitute_ac_subst_variables ($TEXT)
4029 # -------------------------------------
4030 # Replace any occurrence of ${FOO} in $TEXT by @FOO@ if FOO is an AC_SUBST
4031 # variable.
4032 sub substitute_ac_subst_variables ($)
4033 {
4034   my ($text) = @_;
4035   $text =~ s/\${([^ \t=:+{}]+)}/&substitute_ac_subst_variables_worker ($1)/ge;
4036   return $text;
4037 }
4038
4039 # @DEPENDENCIES
4040 # &prepend_srcdir (@INPUTS)
4041 # -------------------------
4042 # Prepend $(srcdir) or $(top_srcdir) to all @INPUTS.  The idea is that
4043 # if an input file has a directory part the same as the current
4044 # directory, then the directory part is simply replaced by $(srcdir).
4045 # But if the directory part is different, then $(top_srcdir) is
4046 # prepended.
4047 sub prepend_srcdir (@)
4048 {
4049   my (@inputs) = @_;
4050   my @newinputs;
4051
4052   foreach my $single (@inputs)
4053     {
4054       if (dirname ($single) eq $relative_dir)
4055         {
4056           push (@newinputs, '$(srcdir)/' . basename ($single));
4057         }
4058       else
4059         {
4060           push (@newinputs, '$(top_srcdir)/' . $single);
4061         }
4062     }
4063   return @newinputs;
4064 }
4065
4066 # @DEPENDENCIES
4067 # rewrite_inputs_into_dependencies ($OUTPUT, @INPUTS)
4068 # ---------------------------------------------------
4069 # Compute a list of dependencies appropriate for the rebuild
4070 # rule of
4071 #   AC_CONFIG_FILES($OUTPUT:$INPUT[0]:$INPUTS[1]:...)
4072 # Also distribute $INPUTs which are not built by another AC_CONFIG_FOOs.
4073 sub rewrite_inputs_into_dependencies ($@)
4074 {
4075   my ($file, @inputs) = @_;
4076   my @res = ();
4077
4078   for my $i (@inputs)
4079     {
4080       # We cannot create dependencies on shell variables.
4081       next if (substitute_ac_subst_variables $i) =~ /\$/;
4082
4083       if (exists $ac_config_files_location{$i} && $i ne $file)
4084         {
4085           my $di = dirname $i;
4086           if ($di eq $relative_dir)
4087             {
4088               $i = basename $i;
4089             }
4090           # In the top-level Makefile we do not use $(top_builddir), because
4091           # we are already there, and since the targets are built without
4092           # a $(top_builddir), it helps BSD Make to match them with
4093           # dependencies.
4094           elsif ($relative_dir ne '.')
4095             {
4096               $i = '$(top_builddir)/' . $i;
4097             }
4098         }
4099       else
4100         {
4101           msg ('error', $ac_config_files_location{$file},
4102                "required file '$i' not found")
4103             unless $i =~ /\$/ || exists $output_files{$i} || -f $i;
4104           ($i) = prepend_srcdir ($i);
4105           push_dist_common ($i);
4106         }
4107       push @res, $i;
4108     }
4109   return @res;
4110 }
4111
4112
4113
4114 # &handle_configure ($MAKEFILE_AM, $MAKEFILE_IN, $MAKEFILE, @INPUTS)
4115 # ------------------------------------------------------------------
4116 # Handle remaking and configure stuff.
4117 # We need the name of the input file, to do proper remaking rules.
4118 sub handle_configure ($$$@)
4119 {
4120   my ($makefile_am, $makefile_in, $makefile, @inputs) = @_;
4121
4122   prog_error 'empty @inputs'
4123     unless @inputs;
4124
4125   my ($rel_makefile_am, $rel_makefile_in) = prepend_srcdir ($makefile_am,
4126                                                             $makefile_in);
4127   my $rel_makefile = basename $makefile;
4128
4129   my $colon_infile = ':' . join (':', @inputs);
4130   $colon_infile = '' if $colon_infile eq ":$makefile.in";
4131   my @rewritten = rewrite_inputs_into_dependencies ($makefile, @inputs);
4132   my ($regen_aclocal_m4, @aclocal_m4_deps) = scan_aclocal_m4;
4133   define_pretty_variable ('am__aclocal_m4_deps', TRUE, INTERNAL,
4134                           @configure_deps, @aclocal_m4_deps,
4135                           '$(top_srcdir)/' . $configure_ac);
4136   my @configuredeps = ('$(am__aclocal_m4_deps)', '$(CONFIGURE_DEPENDENCIES)');
4137   push @configuredeps, '$(ACLOCAL_M4)' if -f 'aclocal.m4';
4138   define_pretty_variable ('am__configure_deps', TRUE, INTERNAL,
4139                           @configuredeps);
4140
4141   my $automake_options = '--' . (global_option 'cygnus' ? 'cygnus' : $strictness_name)
4142                          . (global_option 'no-dependencies' ? ' --ignore-deps' : '');
4143
4144   $output_rules .= file_contents
4145     ('configure',
4146      new Automake::Location,
4147      MAKEFILE              => $rel_makefile,
4148      'MAKEFILE-DEPS'       => "@rewritten",
4149      'CONFIG-MAKEFILE'     => ($relative_dir eq '.') ? '$@' : '$(subdir)/$@',
4150      'MAKEFILE-IN'         => $rel_makefile_in,
4151      'HAVE-MAKEFILE-IN-DEPS' => (@include_stack > 0),
4152      'MAKEFILE-IN-DEPS'    => "@include_stack",
4153      'MAKEFILE-AM'         => $rel_makefile_am,
4154      'AUTOMAKE-OPTIONS'    => $automake_options,
4155      'MAKEFILE-AM-SOURCES' => "$makefile$colon_infile",
4156      'REGEN-ACLOCAL-M4'    => $regen_aclocal_m4,
4157      VERBOSE               => verbose_flag ('GEN'));
4158
4159   if ($relative_dir eq '.')
4160     {
4161       &push_dist_common ('acconfig.h')
4162         if -f 'acconfig.h';
4163     }
4164
4165   # If we have a configure header, require it.
4166   my $hdr_index = 0;
4167   my @distclean_config;
4168   foreach my $spec (@config_headers)
4169     {
4170       $hdr_index += 1;
4171       # $CONFIG_H_PATH: config.h from top level.
4172       my ($config_h_path, @ins) = split_config_file_spec ($spec);
4173       my $config_h_dir = dirname ($config_h_path);
4174
4175       # If the header is in the current directory we want to build
4176       # the header here.  Otherwise, if we're at the topmost
4177       # directory and the header's directory doesn't have a
4178       # Makefile, then we also want to build the header.
4179       if ($relative_dir eq $config_h_dir
4180           || ($relative_dir eq '.' && ! &is_make_dir ($config_h_dir)))
4181         {
4182           my ($cn_sans_dir, $stamp_dir);
4183           if ($relative_dir eq $config_h_dir)
4184             {
4185               $cn_sans_dir = basename ($config_h_path);
4186               $stamp_dir = '';
4187             }
4188           else
4189             {
4190               $cn_sans_dir = $config_h_path;
4191               if ($config_h_dir eq '.')
4192                 {
4193                   $stamp_dir = '';
4194                 }
4195               else
4196                 {
4197                   $stamp_dir = $config_h_dir . '/';
4198                 }
4199             }
4200
4201           # This will also distribute all inputs.
4202           @ins = rewrite_inputs_into_dependencies ($config_h_path, @ins);
4203
4204           # Cannot define rebuild rules for filenames with shell variables.
4205           next if (substitute_ac_subst_variables $config_h_path) =~ /\$/;
4206
4207           # Header defined in this directory.
4208           my @files;
4209           if (-f $config_h_path . '.top')
4210             {
4211               push (@files, "$cn_sans_dir.top");
4212             }
4213           if (-f $config_h_path . '.bot')
4214             {
4215               push (@files, "$cn_sans_dir.bot");
4216             }
4217
4218           push_dist_common (@files);
4219
4220           # For now, acconfig.h can only appear in the top srcdir.
4221           if (-f 'acconfig.h')
4222             {
4223               push (@files, '$(top_srcdir)/acconfig.h');
4224             }
4225
4226           my $stamp = "${stamp_dir}stamp-h${hdr_index}";
4227           $output_rules .=
4228             file_contents ('remake-hdr',
4229                            new Automake::Location,
4230                            FILES            => "@files",
4231                            CONFIG_H         => $cn_sans_dir,
4232                            CONFIG_HIN       => $ins[0],
4233                            CONFIG_H_DEPS    => "@ins",
4234                            CONFIG_H_PATH    => $config_h_path,
4235                            STAMP            => "$stamp");
4236
4237           push @distclean_config, $cn_sans_dir, $stamp;
4238         }
4239     }
4240
4241   $output_rules .= file_contents ('clean-hdr',
4242                                   new Automake::Location,
4243                                   FILES => "@distclean_config")
4244     if @distclean_config;
4245
4246   # Distribute and define mkinstalldirs only if it is already present
4247   # in the package, for backward compatibility (some people may still
4248   # use $(mkinstalldirs)).
4249   my $mkidpath = "$config_aux_dir/mkinstalldirs";
4250   if (-f $mkidpath)
4251     {
4252       # Use require_file so that any existing script gets updated
4253       # by --force-missing.
4254       require_conf_file ($mkidpath, FOREIGN, 'mkinstalldirs');
4255       define_variable ('mkinstalldirs',
4256                        "\$(SHELL) $am_config_aux_dir/mkinstalldirs", INTERNAL);
4257     }
4258   else
4259     {
4260       # Use $(install_sh), not $(MKDIR_P) because the latter requires
4261       # at least one argument, and $(mkinstalldirs) used to work
4262       # even without arguments (e.g. $(mkinstalldirs) $(conditional_dir)).
4263       define_variable ('mkinstalldirs', '$(install_sh) -d', INTERNAL);
4264     }
4265
4266   reject_var ('CONFIG_HEADER',
4267               "'CONFIG_HEADER' is an anachronism; now determined "
4268               . "automatically\nfrom '$configure_ac'");
4269
4270   my @config_h;
4271   foreach my $spec (@config_headers)
4272     {
4273       my ($out, @ins) = split_config_file_spec ($spec);
4274       # Generate CONFIG_HEADER define.
4275       if ($relative_dir eq dirname ($out))
4276         {
4277           push @config_h, basename ($out);
4278         }
4279       else
4280         {
4281           push @config_h, "\$(top_builddir)/$out";
4282         }
4283     }
4284   define_variable ("CONFIG_HEADER", "@config_h", INTERNAL)
4285     if @config_h;
4286
4287   # Now look for other files in this directory which must be remade
4288   # by config.status, and generate rules for them.
4289   my @actual_other_files = ();
4290   # These get cleaned only in a VPATH build.
4291   my @actual_other_vpath_files = ();
4292   foreach my $lfile (@other_input_files)
4293     {
4294       my $file;
4295       my @inputs;
4296       if ($lfile =~ /^([^:]*):(.*)$/)
4297         {
4298           # This is the ":" syntax of AC_OUTPUT.
4299           $file = $1;
4300           @inputs = split (':', $2);
4301         }
4302       else
4303         {
4304           # Normal usage.
4305           $file = $lfile;
4306           @inputs = $file . '.in';
4307         }
4308
4309       # Automake files should not be stored in here, but in %MAKE_LIST.
4310       prog_error ("$lfile in \@other_input_files\n"
4311                   . "\@other_input_files = (@other_input_files)")
4312         if -f $file . '.am';
4313
4314       my $local = basename ($file);
4315
4316       # We skip files that aren't in this directory.  However, if
4317       # the file's directory does not have a Makefile, and we are
4318       # currently doing '.', then we create a rule to rebuild the
4319       # file in the subdir.
4320       my $fd = dirname ($file);
4321       if ($fd ne $relative_dir)
4322         {
4323           if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4324             {
4325               $local = $file;
4326             }
4327           else
4328             {
4329               next;
4330             }
4331         }
4332
4333       my @rewritten_inputs = rewrite_inputs_into_dependencies ($file, @inputs);
4334
4335       # Cannot output rules for shell variables.
4336       next if (substitute_ac_subst_variables $local) =~ /\$/;
4337
4338       my $condstr = '';
4339       my $cond = $ac_config_files_condition{$lfile};
4340       if (defined $cond)
4341         {
4342           $condstr = $cond->subst_string;
4343           Automake::Rule::define ($local, $configure_ac, RULE_AUTOMAKE, $cond,
4344                                   $ac_config_files_location{$file});
4345         }
4346       $output_rules .= ($condstr . $local . ': '
4347                         . '$(top_builddir)/config.status '
4348                         . "@rewritten_inputs\n"
4349                         . $condstr . "\t"
4350                         . 'cd $(top_builddir) && '
4351                         . '$(SHELL) ./config.status '
4352                         . ($relative_dir eq '.' ? '' : '$(subdir)/')
4353                         . '$@'
4354                         . "\n");
4355       push (@actual_other_files, $local);
4356     }
4357
4358   # For links we should clean destinations and distribute sources.
4359   foreach my $spec (@config_links)
4360     {
4361       my ($link, $file) = split /:/, $spec;
4362       # Some people do AC_CONFIG_LINKS($computed).  We only handle
4363       # the DEST:SRC form.
4364       next unless $file;
4365       my $where = $ac_config_files_location{$link};
4366
4367       # Skip destinations that contain shell variables.
4368       if ((substitute_ac_subst_variables $link) !~ /\$/)
4369         {
4370           # We skip links that aren't in this directory.  However, if
4371           # the link's directory does not have a Makefile, and we are
4372           # currently doing '.', then we add the link to CONFIG_CLEAN_FILES
4373           # in '.'s Makefile.in.
4374           my $local = basename ($link);
4375           my $fd = dirname ($link);
4376           if ($fd ne $relative_dir)
4377             {
4378               if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4379                 {
4380                   $local = $link;
4381                 }
4382               else
4383                 {
4384                   $local = undef;
4385                 }
4386             }
4387           if ($file ne $link)
4388             {
4389               push @actual_other_files, $local if $local;
4390             }
4391           else
4392             {
4393               push @actual_other_vpath_files, $local if $local;
4394             }
4395         }
4396
4397       # Do not process sources that contain shell variables.
4398       if ((substitute_ac_subst_variables $file) !~ /\$/)
4399         {
4400           my $fd = dirname ($file);
4401
4402           # We distribute files that are in this directory.
4403           # At the top-level ('.') we also distribute files whose
4404           # directory does not have a Makefile.
4405           if (($fd eq $relative_dir)
4406               || ($relative_dir eq '.' && ! &is_make_dir ($fd)))
4407             {
4408               # The following will distribute $file as a side-effect when
4409               # it is appropriate (i.e., when $file is not already an output).
4410               # We do not need the result, just the side-effect.
4411               rewrite_inputs_into_dependencies ($link, $file);
4412             }
4413         }
4414     }
4415
4416   # These files get removed by "make distclean".
4417   define_pretty_variable ('CONFIG_CLEAN_FILES', TRUE, INTERNAL,
4418                           @actual_other_files);
4419   define_pretty_variable ('CONFIG_CLEAN_VPATH_FILES', TRUE, INTERNAL,
4420                           @actual_other_vpath_files);
4421 }
4422
4423 # Handle C headers.
4424 sub handle_headers
4425 {
4426     my @r = &am_install_var ('-defaultdist', 'header', 'HEADERS', 'include',
4427                              'oldinclude', 'pkginclude',
4428                              'noinst', 'check');
4429     foreach (@r)
4430     {
4431       next unless $_->[1] =~ /\..*$/;
4432       &saw_extension ($&);
4433     }
4434 }
4435
4436 sub handle_gettext
4437 {
4438   return if ! $seen_gettext || $relative_dir ne '.';
4439
4440   my $subdirs = var 'SUBDIRS';
4441
4442   if (! $subdirs)
4443     {
4444       err_ac "AM_GNU_GETTEXT used but SUBDIRS not defined";
4445       return;
4446     }
4447
4448   # Perform some sanity checks to help users get the right setup.
4449   # We disable these tests when po/ doesn't exist in order not to disallow
4450   # unusual gettext setups.
4451   #
4452   # Bruno Haible:
4453   # | The idea is:
4454   # |
4455   # |  1) If a package doesn't have a directory po/ at top level, it
4456   # |     will likely have multiple po/ directories in subpackages.
4457   # |
4458   # |  2) It is useful to warn for the absence of intl/ if AM_GNU_GETTEXT
4459   # |     is used without 'external'. It is also useful to warn for the
4460   # |     presence of intl/ if AM_GNU_GETTEXT([external]) is used. Both
4461   # |     warnings apply only to the usual layout of packages, therefore
4462   # |     they should both be disabled if no po/ directory is found at
4463   # |     top level.
4464
4465   if (-d 'po')
4466     {
4467       my @subdirs = $subdirs->value_as_list_recursive;
4468
4469       msg_var ('syntax', $subdirs,
4470                "AM_GNU_GETTEXT used but 'po' not in SUBDIRS")
4471         if ! grep ($_ eq 'po', @subdirs);
4472
4473       # intl/ is not required when AM_GNU_GETTEXT is called with the
4474       # 'external' option and AM_GNU_GETTEXT_INTL_SUBDIR is not called.
4475       msg_var ('syntax', $subdirs,
4476                "AM_GNU_GETTEXT used but 'intl' not in SUBDIRS")
4477         if (! ($seen_gettext_external && ! $seen_gettext_intl)
4478             && ! grep ($_ eq 'intl', @subdirs));
4479
4480       # intl/ should not be used with AM_GNU_GETTEXT([external]), except
4481       # if AM_GNU_GETTEXT_INTL_SUBDIR is called.
4482       msg_var ('syntax', $subdirs,
4483                "'intl' should not be in SUBDIRS when "
4484                . "AM_GNU_GETTEXT([external]) is used")
4485         if ($seen_gettext_external && ! $seen_gettext_intl
4486             && grep ($_ eq 'intl', @subdirs));
4487     }
4488
4489   require_file ($ac_gettext_location, GNU, 'ABOUT-NLS');
4490 }
4491
4492 # Handle footer elements.
4493 sub handle_footer
4494 {
4495     reject_rule ('.SUFFIXES',
4496                  "use variable 'SUFFIXES', not target '.SUFFIXES'");
4497
4498     # Note: AIX 4.1 /bin/make will fail if any suffix rule appears
4499     # before .SUFFIXES.  So we make sure that .SUFFIXES appears before
4500     # anything else, by sticking it right after the default: target.
4501     $output_header .= ".SUFFIXES:\n";
4502     my $suffixes = var 'SUFFIXES';
4503     my @suffixes = Automake::Rule::suffixes;
4504     if (@suffixes || $suffixes)
4505     {
4506         # Make sure SUFFIXES has unique elements.  Sort them to ensure
4507         # the output remains consistent.  However, $(SUFFIXES) is
4508         # always at the start of the list, unsorted.  This is done
4509         # because make will choose rules depending on the ordering of
4510         # suffixes, and this lets the user have some control.  Push
4511         # actual suffixes, and not $(SUFFIXES).  Some versions of make
4512         # do not like variable substitutions on the .SUFFIXES line.
4513         my @user_suffixes = ($suffixes
4514                              ? $suffixes->value_as_list_recursive : ());
4515
4516         my %suffixes = map { $_ => 1 } @suffixes;
4517         delete @suffixes{@user_suffixes};
4518
4519         $output_header .= (".SUFFIXES: "
4520                            . join (' ', @user_suffixes, sort keys %suffixes)
4521                            . "\n");
4522     }
4523
4524     $output_trailer .= file_contents ('footer', new Automake::Location);
4525 }
4526
4527
4528 # Generate 'make install' rules.
4529 sub handle_install ()
4530 {
4531   $output_rules .= &file_contents
4532     ('install',
4533      new Automake::Location,
4534      maybe_BUILT_SOURCES => (set_seen ('BUILT_SOURCES')
4535                              ? (" \$(BUILT_SOURCES)\n"
4536                                 . "\t\$(MAKE) \$(AM_MAKEFLAGS)")
4537                              : ''),
4538      'installdirs-local' => (user_phony_rule 'installdirs-local'
4539                              ? ' installdirs-local' : ''),
4540      am__installdirs => variable_value ('am__installdirs') || '');
4541 }
4542
4543
4544 # Deal with all and all-am.
4545 sub handle_all ($)
4546 {
4547     my ($makefile) = @_;
4548
4549     # Output 'all-am'.
4550
4551     # Put this at the beginning for the sake of non-GNU makes.  This
4552     # is still wrong if these makes can run parallel jobs.  But it is
4553     # right enough.
4554     unshift (@all, basename ($makefile));
4555
4556     foreach my $spec (@config_headers)
4557       {
4558         my ($out, @ins) = split_config_file_spec ($spec);
4559         push (@all, basename ($out))
4560           if dirname ($out) eq $relative_dir;
4561       }
4562
4563     # Install 'all' hooks.
4564     push (@all, "all-local")
4565       if user_phony_rule "all-local";
4566
4567     &pretty_print_rule ("all-am:", "\t\t", @all);
4568     &depend ('.PHONY', 'all-am', 'all');
4569
4570
4571     # Output 'all'.
4572
4573     my @local_headers = ();
4574     push @local_headers, '$(BUILT_SOURCES)'
4575       if var ('BUILT_SOURCES');
4576     foreach my $spec (@config_headers)
4577       {
4578         my ($out, @ins) = split_config_file_spec ($spec);
4579         push @local_headers, basename ($out)
4580           if dirname ($out) eq $relative_dir;
4581       }
4582
4583     if (@local_headers)
4584       {
4585         # We need to make sure config.h is built before we recurse.
4586         # We also want to make sure that built sources are built
4587         # before any ordinary 'all' targets are run.  We can't do this
4588         # by changing the order of dependencies to the "all" because
4589         # that breaks when using parallel makes.  Instead we handle
4590         # things explicitly.
4591         $output_all .= ("all: @local_headers"
4592                         . "\n\t"
4593                         . '$(MAKE) $(AM_MAKEFLAGS) '
4594                         . (var ('SUBDIRS') ? 'all-recursive' : 'all-am')
4595                         . "\n\n");
4596         depend ('.MAKE', 'all');
4597       }
4598     else
4599       {
4600         $output_all .= "all: " . (var ('SUBDIRS')
4601                                   ? 'all-recursive' : 'all-am') . "\n\n";
4602       }
4603 }
4604
4605
4606 # &do_check_merge_target ()
4607 # -------------------------
4608 # Handle check merge target specially.
4609 sub do_check_merge_target ()
4610 {
4611   # Include user-defined local form of target.
4612   push @check_tests, 'check-local'
4613     if user_phony_rule 'check-local';
4614
4615   # In --cygnus mode, check doesn't depend on all.
4616   if (option 'cygnus')
4617     {
4618       # Just run the local check rules.
4619       pretty_print_rule ('check-am:', "\t\t", @check);
4620     }
4621   else
4622     {
4623       # The check target must depend on the local equivalent of
4624       # 'all', to ensure all the primary targets are built.  Then it
4625       # must build the local check rules.
4626       $output_rules .= "check-am: all-am\n";
4627       if (@check)
4628         {
4629           pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4630                              @check);
4631           depend ('.MAKE', 'check-am');
4632         }
4633     }
4634   if (@check_tests)
4635     {
4636       pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4637                          @check_tests);
4638       depend ('.MAKE', 'check-am');
4639     }
4640
4641   depend '.PHONY', 'check', 'check-am';
4642   # Handle recursion.  We have to honor BUILT_SOURCES like for 'all:'.
4643   $output_rules .= ("check: "
4644                     . (var ('BUILT_SOURCES')
4645                        ? "\$(BUILT_SOURCES)\n\t\$(MAKE) \$(AM_MAKEFLAGS) "
4646                        : '')
4647                     . (var ('SUBDIRS') ? 'check-recursive' : 'check-am')
4648                     . "\n");
4649   depend ('.MAKE', 'check')
4650     if var ('BUILT_SOURCES');
4651 }
4652
4653 # handle_clean ($MAKEFILE)
4654 # ------------------------
4655 # Handle all 'clean' targets.
4656 sub handle_clean ($)
4657 {
4658   my ($makefile) = @_;
4659
4660   # Clean the files listed in user variables if they exist.
4661   $clean_files{'$(MOSTLYCLEANFILES)'} = MOSTLY_CLEAN
4662     if var ('MOSTLYCLEANFILES');
4663   $clean_files{'$(CLEANFILES)'} = CLEAN
4664     if var ('CLEANFILES');
4665   $clean_files{'$(DISTCLEANFILES)'} = DIST_CLEAN
4666     if var ('DISTCLEANFILES');
4667   $clean_files{'$(MAINTAINERCLEANFILES)'} = MAINTAINER_CLEAN
4668     if var ('MAINTAINERCLEANFILES');
4669
4670   # Built sources are automatically removed by maintainer-clean.
4671   $clean_files{'$(BUILT_SOURCES)'} = MAINTAINER_CLEAN
4672     if var ('BUILT_SOURCES');
4673
4674   # Compute a list of "rm"s to run for each target.
4675   my %rms = (MOSTLY_CLEAN, [],
4676              CLEAN, [],
4677              DIST_CLEAN, [],
4678              MAINTAINER_CLEAN, []);
4679
4680   foreach my $file (keys %clean_files)
4681     {
4682       my $when = $clean_files{$file};
4683       prog_error 'invalid entry in %clean_files'
4684         unless exists $rms{$when};
4685
4686       my $rm = "rm -f $file";
4687       # If file is a variable, make sure when don't call 'rm -f' without args.
4688       $rm ="test -z \"$file\" || $rm"
4689         if ($file =~ /^\s*\$(\(.*\)|\{.*\})\s*$/);
4690
4691       push @{$rms{$when}}, "\t-$rm\n";
4692     }
4693
4694   $output_rules .= &file_contents
4695     ('clean',
4696      new Automake::Location,
4697      MOSTLYCLEAN_RMS      => join ('', sort @{$rms{&MOSTLY_CLEAN}}),
4698      CLEAN_RMS            => join ('', sort @{$rms{&CLEAN}}),
4699      DISTCLEAN_RMS        => join ('', sort @{$rms{&DIST_CLEAN}}),
4700      MAINTAINER_CLEAN_RMS => join ('', sort @{$rms{&MAINTAINER_CLEAN}}),
4701      MAKEFILE             => basename $makefile,
4702      );
4703 }
4704
4705
4706 # &target_cmp ($A, $B)
4707 # --------------------
4708 # Subroutine for &handle_factored_dependencies to let '.PHONY' and
4709 # other '.TARGETS' be last.
4710 sub target_cmp
4711 {
4712   return 0 if $a eq $b;
4713
4714   my $a1 = substr ($a, 0, 1);
4715   my $b1 = substr ($b, 0, 1);
4716   if ($a1 ne $b1)
4717     {
4718       return -1 if $b1 eq '.';
4719       return 1 if $a1 eq '.';
4720     }
4721   return $a cmp $b;
4722 }
4723
4724
4725 # &handle_factored_dependencies ()
4726 # --------------------------------
4727 # Handle everything related to gathered targets.
4728 sub handle_factored_dependencies
4729 {
4730   # Reject bad hooks.
4731   foreach my $utarg ('uninstall-data-local', 'uninstall-data-hook',
4732                      'uninstall-exec-local', 'uninstall-exec-hook',
4733                      'uninstall-dvi-local',
4734                      'uninstall-html-local',
4735                      'uninstall-info-local',
4736                      'uninstall-pdf-local',
4737                      'uninstall-ps-local')
4738     {
4739       my $x = $utarg;
4740       $x =~ s/-.*-/-/;
4741       reject_rule ($utarg, "use '$x', not '$utarg'");
4742     }
4743
4744   reject_rule ('install-local',
4745                "use 'install-data-local' or 'install-exec-local', "
4746                . "not 'install-local'");
4747
4748   reject_rule ('install-hook',
4749                "use 'install-data-hook' or 'install-exec-hook', "
4750                . "not 'install-hook'");
4751
4752   # Install the -local hooks.
4753   foreach (keys %dependencies)
4754     {
4755       # Hooks are installed on the -am targets.
4756       s/-am$// or next;
4757       depend ("$_-am", "$_-local")
4758         if user_phony_rule "$_-local";
4759     }
4760
4761   # Install the -hook hooks.
4762   # FIXME: Why not be as liberal as we are with -local hooks?
4763   foreach ('install-exec', 'install-data', 'uninstall')
4764     {
4765       if (user_phony_rule "$_-hook")
4766         {
4767           depend ('.MAKE', "$_-am");
4768           register_action("$_-am",
4769                           ("\t\@\$(NORMAL_INSTALL)\n"
4770                            . "\t\$(MAKE) \$(AM_MAKEFLAGS) $_-hook"));
4771         }
4772     }
4773
4774   # All the required targets are phony.
4775   depend ('.PHONY', keys %required_targets);
4776
4777   # Actually output gathered targets.
4778   foreach (sort target_cmp keys %dependencies)
4779     {
4780       # If there is nothing about this guy, skip it.
4781       next
4782         unless (@{$dependencies{$_}}
4783                 || $actions{$_}
4784                 || $required_targets{$_});
4785
4786       # Define gathered targets in undefined conditions.
4787       # FIXME: Right now we must handle .PHONY as an exception,
4788       # because people write things like
4789       #    .PHONY: myphonytarget
4790       # to append dependencies.  This would not work if Automake
4791       # refrained from defining its own .PHONY target as it does
4792       # with other overridden targets.
4793       # Likewise for '.MAKE'.
4794       my @undefined_conds = (TRUE,);
4795       if ($_ ne '.PHONY' && $_ ne '.MAKE')
4796         {
4797           @undefined_conds =
4798             Automake::Rule::define ($_, 'internal',
4799                                     RULE_AUTOMAKE, TRUE, INTERNAL);
4800         }
4801       my @uniq_deps = uniq (sort @{$dependencies{$_}});
4802       foreach my $cond (@undefined_conds)
4803         {
4804           my $condstr = $cond->subst_string;
4805           &pretty_print_rule ("$condstr$_:", "$condstr\t", @uniq_deps);
4806           $output_rules .= $actions{$_} if defined $actions{$_};
4807           $output_rules .= "\n";
4808         }
4809     }
4810 }
4811
4812
4813 # &handle_tests_dejagnu ()
4814 # ------------------------
4815 sub handle_tests_dejagnu
4816 {
4817     push (@check_tests, 'check-DEJAGNU');
4818     $output_rules .= file_contents ('dejagnu', new Automake::Location);
4819 }
4820
4821 sub handle_per_suffix_test
4822 {
4823   my ($test_suffix, %transform) = @_;
4824   my ($pfx, $generic, $parallel_tests_option, $am_exeext);
4825   prog_error ("called with 'parallel-tests' option not set")
4826     unless $parallel_tests_option = option 'parallel-tests';
4827   if ($test_suffix eq '')
4828     {
4829       $pfx = '';
4830       $generic = 0;
4831       $am_exeext = 'FALSE';
4832     }
4833   else
4834     {
4835       prog_error ("test suffix '$test_suffix' lacks leading dot")
4836         unless $test_suffix =~ m/^\.(.*)/;
4837       $pfx = uc ($1) . '_';
4838       $generic = 1;
4839       $am_exeext = exists $configure_vars{'EXEEXT'} ? 'am__EXEEXT'
4840                                                     : 'FALSE';
4841     }
4842   # The "test driver" program, deputed to handle tests protocol used by
4843   # test scripts.  By default, it's assumed that no protocol is used,
4844   # so we fall back to the old "parallel-tests" behaviour, implemented
4845   # by the 'test-driver' auxiliary script.
4846   if (! var "${pfx}LOG_DRIVER")
4847     {
4848       require_conf_file ($parallel_tests_option->{position}, FOREIGN,
4849                         'test-driver');
4850       define_variable ("${pfx}LOG_DRIVER",
4851                        "\$(SHELL) $am_config_aux_dir/test-driver",
4852                        INTERNAL);
4853     }
4854   my $driver = '$(' . $pfx . 'LOG_DRIVER)';
4855   my $driver_flags = '$(AM_' . $pfx . 'LOG_DRIVER_FLAGS)'
4856                        . ' $(' . $pfx . 'LOG_DRIVER_FLAGS)';
4857   my $compile = "${pfx}LOG_COMPILE";
4858   define_variable ($compile,
4859                    '$(' . $pfx . 'LOG_COMPILER)'
4860                       . ' $(AM_' .  $pfx . 'LOG_FLAGS)'
4861                       . ' $(' . $pfx . 'LOG_FLAGS)',
4862                      INTERNAL);
4863   $output_rules .= file_contents ('check2', new Automake::Location,
4864                                    GENERIC => $generic,
4865                                    DRIVER => $driver,
4866                                    DRIVER_FLAGS => $driver_flags,
4867                                    COMPILE => '$(' . $compile . ')',
4868                                    EXT => $test_suffix,
4869                                    am__EXEEXT => $am_exeext,
4870                                    %transform);
4871 }
4872
4873 # is_valid_test_extension ($EXT)
4874 # ------------------------------
4875 # Return true if $EXT can appear in $(TEST_EXTENSIONS), return false
4876 # otherwise.
4877 sub is_valid_test_extension ($)
4878 {
4879   my $ext = shift;
4880   return 1
4881     if ($ext =~ /^\.[a-zA-Z_][a-zA-Z0-9_]*$/);
4882   return 1
4883     if (exists $configure_vars{'EXEEXT'} && $ext eq subst ('EXEEXT'));
4884   return 0;
4885 }
4886
4887 # Handle TESTS variable and other checks.
4888 sub handle_tests
4889 {
4890   if (option 'dejagnu')
4891     {
4892       &handle_tests_dejagnu;
4893     }
4894   else
4895     {
4896       foreach my $c ('DEJATOOL', 'RUNTEST', 'RUNTESTFLAGS')
4897         {
4898           reject_var ($c, "'$c' defined but 'dejagnu' not in "
4899                       . "'AUTOMAKE_OPTIONS'");
4900         }
4901     }
4902
4903   if (var ('TESTS'))
4904     {
4905       push (@check_tests, 'check-TESTS');
4906       my $check_deps = "@check";
4907       $output_rules .= &file_contents ('check', new Automake::Location,
4908                                        COLOR => !! option 'color-tests',
4909                                        PARALLEL_TESTS => !! option 'parallel-tests',
4910                                        CHECK_DEPS => $check_deps);
4911
4912       # Tests that are known programs should have $(EXEEXT) appended.
4913       # For matching purposes, we need to adjust XFAIL_TESTS as well.
4914       append_exeext { exists $known_programs{$_[0]} } 'TESTS';
4915       append_exeext { exists $known_programs{$_[0]} } 'XFAIL_TESTS'
4916         if (var ('XFAIL_TESTS'));
4917
4918       if (my $parallel_tests = option 'parallel-tests')
4919         {
4920           define_variable ('TEST_SUITE_LOG', 'test-suite.log', INTERNAL);
4921           my $suff = '.test';
4922           my $at_exeext = '';
4923           my $handle_exeext = exists $configure_vars{'EXEEXT'};
4924           if ($handle_exeext)
4925             {
4926               $at_exeext = subst ('EXEEXT');
4927               $suff = $at_exeext  . ' ' . $suff;
4928             }
4929           if (! var 'TEST_EXTENSIONS')
4930             {
4931               define_variable ('TEST_EXTENSIONS', $suff, INTERNAL);
4932             }
4933           my $var = var 'TEST_EXTENSIONS';
4934           # Currently, we are not able to deal with conditional contents
4935           # in TEST_EXTENSIONS.
4936           if ($var->has_conditional_contents)
4937            {
4938              msg_var 'unsupported', $var,
4939                      "'TEST_EXTENSIONS' cannot have conditional contents";
4940            }
4941           my @test_suffixes = $var->value_as_list_recursive;
4942           if ((my @invalid_test_suffixes =
4943                   grep { !is_valid_test_extension $_ } @test_suffixes) > 0)
4944             {
4945               error $var->rdef (TRUE)->location,
4946                     "invalid test extensions: @invalid_test_suffixes";
4947             }
4948           @test_suffixes = grep { is_valid_test_extension $_ } @test_suffixes;
4949           if ($handle_exeext)
4950             {
4951               unshift (@test_suffixes, $at_exeext)
4952                 unless $test_suffixes[0] eq $at_exeext;
4953             }
4954           unshift (@test_suffixes, '');
4955
4956           transform_variable_recursively
4957             ('TESTS', 'TEST_LOGS', 'am__testlogs', 1, INTERNAL,
4958               sub {
4959                 my ($subvar, $val, $cond, $full_cond) = @_;
4960                 my $obj = $val;
4961                 return $obj
4962                   if $val =~ /^\@.*\@$/;
4963                 $obj =~ s/\$\(EXEEXT\)$//o;
4964
4965                 if ($val =~ /(\$\((top_)?srcdir\))\//o)
4966                   {
4967                     msg ('error', $subvar->rdef ($cond)->location,
4968                          "parallel-tests: using '$1' in TESTS is currently broken: '$val'");
4969                   }
4970
4971                 foreach my $test_suffix (@test_suffixes)
4972                   {
4973                     next
4974                       if $test_suffix eq $at_exeext || $test_suffix eq '';
4975                     return substr ($obj, 0, length ($obj) - length ($test_suffix)) . '.log'
4976                       if substr ($obj, - length ($test_suffix)) eq $test_suffix;
4977                   }
4978                 my $base = $obj;
4979                 $obj .= '.log';
4980                 handle_per_suffix_test ('',
4981                                         OBJ => $obj,
4982                                         BASE => $base,
4983                                         SOURCE => $val);
4984                 return $obj;
4985               });
4986
4987           my $nhelper=1;
4988           my $prev = 'TESTS';
4989           my $post = '';
4990           my $last_suffix = $test_suffixes[$#test_suffixes];
4991           my $cur = '';
4992           foreach my $test_suffix (@test_suffixes)
4993             {
4994               if ($test_suffix eq $last_suffix)
4995                 {
4996                   $cur = 'TEST_LOGS';
4997                 }
4998               else
4999                 {
5000                   $cur = 'am__test_logs' . $nhelper;
5001                 }
5002               define_variable ($cur,
5003                 '$(' . $prev . ':' . $test_suffix . $post . '=.log)', INTERNAL);
5004               $post = '.log';
5005               $prev = $cur;
5006               $nhelper++;
5007               if ($test_suffix ne $at_exeext && $test_suffix ne '')
5008                 {
5009                   handle_per_suffix_test ($test_suffix,
5010                                           OBJ => '',
5011                                           BASE => '$*',
5012                                           SOURCE => '$<');
5013                 }
5014             }
5015           $clean_files{'$(TEST_LOGS)'} = MOSTLY_CLEAN;
5016           $clean_files{'$(TEST_LOGS:.log=.trs)'} = MOSTLY_CLEAN;
5017           $clean_files{'$(TEST_SUITE_LOG)'} = MOSTLY_CLEAN;
5018         }
5019     }
5020 }
5021
5022 # Handle Emacs Lisp.
5023 sub handle_emacs_lisp
5024 {
5025   my @elfiles = &am_install_var ('-candist', 'lisp', 'LISP',
5026                                  'lisp', 'noinst');
5027
5028   return if ! @elfiles;
5029
5030   define_pretty_variable ('am__ELFILES', TRUE, INTERNAL,
5031                           map { $_->[1] } @elfiles);
5032   define_pretty_variable ('am__ELCFILES', TRUE, INTERNAL,
5033                           '$(am__ELFILES:.el=.elc)');
5034   # This one can be overridden by users.
5035   define_pretty_variable ('ELCFILES', TRUE, INTERNAL, '$(LISP:.el=.elc)');
5036
5037   push @all, '$(ELCFILES)';
5038
5039   require_variables ($elfiles[0][0], "Emacs Lisp sources seen", TRUE,
5040                      'EMACS', 'lispdir');
5041   require_conf_file ($elfiles[0][0], FOREIGN, 'elisp-comp');
5042   &define_variable ('elisp_comp', "$am_config_aux_dir/elisp-comp", INTERNAL);
5043 }
5044
5045 # Handle Python
5046 sub handle_python
5047 {
5048   my @pyfiles = &am_install_var ('-defaultdist', 'python', 'PYTHON',
5049                                  'noinst');
5050   return if ! @pyfiles;
5051
5052   require_variables ($pyfiles[0][0], "Python sources seen", TRUE, 'PYTHON');
5053   require_conf_file ($pyfiles[0][0], FOREIGN, 'py-compile');
5054   &define_variable ('py_compile', "$am_config_aux_dir/py-compile", INTERNAL);
5055 }
5056
5057 # Handle Java.
5058 sub handle_java
5059 {
5060     my @sourcelist = &am_install_var ('-candist',
5061                                       'java', 'JAVA',
5062                                       'noinst', 'check');
5063     return if ! @sourcelist;
5064
5065     my @prefixes = am_primary_prefixes ('JAVA', 1,
5066                                         'noinst', 'check');
5067
5068     my $dir;
5069     my @java_sources = ();
5070     foreach my $prefix (@prefixes)
5071       {
5072         (my $curs = $prefix) =~ s/^(?:nobase_)?(?:dist_|nodist_)?//;
5073
5074         next
5075           if $curs eq 'EXTRA';
5076
5077         push @java_sources, '$(' . $prefix . '_JAVA' . ')';
5078
5079         if (defined $dir)
5080           {
5081             err_var "${curs}_JAVA", "multiple _JAVA primaries in use"
5082              unless $curs eq $dir;
5083           }
5084
5085         $dir = $curs;
5086       }
5087
5088     define_pretty_variable ('am__java_sources', TRUE, INTERNAL,
5089                             "@java_sources");
5090
5091     if ($dir eq 'check')
5092       {
5093         push (@check, "class$dir.stamp");
5094       }
5095     else
5096       {
5097         push (@all, "class$dir.stamp");
5098       }
5099 }
5100
5101
5102 # Handle some of the minor options.
5103 sub handle_minor_options
5104 {
5105   if (option 'readme-alpha')
5106     {
5107       if ($relative_dir eq '.')
5108         {
5109           if ($package_version !~ /^$GNITS_VERSION_PATTERN$/)
5110             {
5111               msg ('error-gnits', $package_version_location,
5112                    "version '$package_version' doesn't follow " .
5113                    "Gnits standards");
5114             }
5115           if (defined $1 && -f 'README-alpha')
5116             {
5117               # This means we have an alpha release.  See
5118               # GNITS_VERSION_PATTERN for details.
5119               push_dist_common ('README-alpha');
5120             }
5121         }
5122     }
5123 }
5124
5125 ################################################################
5126
5127 # ($OUTPUT, @INPUTS)
5128 # &split_config_file_spec ($SPEC)
5129 # -------------------------------
5130 # Decode the Autoconf syntax for config files (files, headers, links
5131 # etc.).
5132 sub split_config_file_spec ($)
5133 {
5134   my ($spec) = @_;
5135   my ($output, @inputs) = split (/:/, $spec);
5136
5137   push @inputs, "$output.in"
5138     unless @inputs;
5139
5140   return ($output, @inputs);
5141 }
5142
5143 # $input
5144 # locate_am (@POSSIBLE_SOURCES)
5145 # -----------------------------
5146 # AC_CONFIG_FILES allow specifications such as Makefile:top.in:mid.in:bot.in
5147 # This functions returns the first *.in file for which a *.am exists.
5148 # It returns undef otherwise.
5149 sub locate_am (@)
5150 {
5151   my (@rest) = @_;
5152   my $input;
5153   foreach my $file (@rest)
5154     {
5155       if (($file =~ /^(.*)\.in$/) && -f "$1.am")
5156         {
5157           $input = $file;
5158           last;
5159         }
5160     }
5161   return $input;
5162 }
5163
5164 my %make_list;
5165
5166 # &scan_autoconf_config_files ($WHERE, $CONFIG-FILES)
5167 # ---------------------------------------------------
5168 # Study $CONFIG-FILES which is the first argument to AC_CONFIG_FILES
5169 # (or AC_OUTPUT).
5170 sub scan_autoconf_config_files ($$)
5171 {
5172   my ($where, $config_files) = @_;
5173
5174   # Look at potential Makefile.am's.
5175   foreach (split ' ', $config_files)
5176     {
5177       # Must skip empty string for Perl 4.
5178       next if $_ eq "\\" || $_ eq '';
5179
5180       # Handle $local:$input syntax.
5181       my ($local, @rest) = split (/:/);
5182       @rest = ("$local.in",) unless @rest;
5183       # Keep in sync with 'conffile-leading-dot.test'.
5184       msg ('unsupported', $where,
5185            "omit leading './' from config file names such as '$local';"
5186            . "\nremake rules might be subtly broken otherwise")
5187         if ($local =~ /^\.\//);
5188       my $input = locate_am @rest;
5189       if ($input)
5190         {
5191           # We have a file that automake should generate.
5192           $make_list{$input} = join (':', ($local, @rest));
5193         }
5194       else
5195         {
5196           # We have a file that automake should cause to be
5197           # rebuilt, but shouldn't generate itself.
5198           push (@other_input_files, $_);
5199         }
5200       $ac_config_files_location{$local} = $where;
5201       $ac_config_files_condition{$local} =
5202         new Automake::Condition (@cond_stack)
5203           if (@cond_stack);
5204     }
5205 }
5206
5207
5208 # &scan_autoconf_traces ($FILENAME)
5209 # ---------------------------------
5210 sub scan_autoconf_traces ($)
5211 {
5212   my ($filename) = @_;
5213
5214   # Macros to trace, with their minimal number of arguments.
5215   #
5216   # IMPORTANT: If you add a macro here, you should also add this macro
5217   # =========  to Automake-preselection in autoconf/lib/autom4te.in.
5218   my %traced = (
5219                 AC_CANONICAL_BUILD => 0,
5220                 AC_CANONICAL_HOST => 0,
5221                 AC_CANONICAL_TARGET => 0,
5222                 AC_CONFIG_AUX_DIR => 1,
5223                 AC_CONFIG_FILES => 1,
5224                 AC_CONFIG_HEADERS => 1,
5225                 AC_CONFIG_LIBOBJ_DIR => 1,
5226                 AC_CONFIG_LINKS => 1,
5227                 AC_FC_SRCEXT => 1,
5228                 AC_INIT => 0,
5229                 AC_LIBSOURCE => 1,
5230                 AC_REQUIRE_AUX_FILE => 1,
5231                 AC_SUBST_TRACE => 1,
5232                 AM_AUTOMAKE_VERSION => 1,
5233                 AM_PROG_MKDIR_P => 0, # FIXME: to be removed in 1.13
5234                 AM_CONDITIONAL => 2,
5235                 AM_GNU_GETTEXT => 0,
5236                 AM_GNU_GETTEXT_INTL_SUBDIR => 0,
5237                 AM_INIT_AUTOMAKE => 0,
5238                 AM_MAINTAINER_MODE => 0,
5239                 AM_PROG_AR => 0,
5240                 AM_PROG_CC_C_O => 0,
5241                 AM_SILENT_RULES => 0,
5242                 _AM_SUBST_NOTMAKE => 1,
5243                 _AM_COND_IF => 1,
5244                 _AM_COND_ELSE => 1,
5245                 _AM_COND_ENDIF => 1,
5246                 LT_SUPPORTED_TAG => 1,
5247                 _LT_AC_TAGCONFIG => 0,
5248                 m4_include => 1,
5249                 m4_sinclude => 1,
5250                 sinclude => 1,
5251               );
5252
5253   my $traces = ($ENV{AUTOCONF} || '@am_AUTOCONF@') . " ";
5254
5255   # Use a separator unlikely to be used, not ':', the default, which
5256   # has a precise meaning for AC_CONFIG_FILES and so on.
5257   $traces .= join (' ',
5258                    map { "--trace=$_" . ':\$f:\$l::\$d::\$n::\${::}%' }
5259                    (keys %traced));
5260
5261   my $tracefh = new Automake::XFile ("$traces $filename |");
5262   verb "reading $traces";
5263
5264   @cond_stack = ();
5265   my $where;
5266
5267   while ($_ = $tracefh->getline)
5268     {
5269       chomp;
5270       my ($here, $depth, @args) = split (/::/);
5271       $where = new Automake::Location $here;
5272       my $macro = $args[0];
5273
5274       prog_error ("unrequested trace '$macro'")
5275         unless exists $traced{$macro};
5276
5277       # Skip and diagnose malformed calls.
5278       if ($#args < $traced{$macro})
5279         {
5280           msg ('syntax', $where, "not enough arguments for $macro");
5281           next;
5282         }
5283
5284       # Alphabetical ordering please.
5285       if ($macro eq 'AC_CANONICAL_BUILD')
5286         {
5287           if ($seen_canonical <= AC_CANONICAL_BUILD)
5288             {
5289               $seen_canonical = AC_CANONICAL_BUILD;
5290               $canonical_location = $where;
5291             }
5292         }
5293       elsif ($macro eq 'AC_CANONICAL_HOST')
5294         {
5295           if ($seen_canonical <= AC_CANONICAL_HOST)
5296             {
5297               $seen_canonical = AC_CANONICAL_HOST;
5298               $canonical_location = $where;
5299             }
5300         }
5301       elsif ($macro eq 'AC_CANONICAL_TARGET')
5302         {
5303           $seen_canonical = AC_CANONICAL_TARGET;
5304           $canonical_location = $where;
5305         }
5306       elsif ($macro eq 'AC_CONFIG_AUX_DIR')
5307         {
5308           if ($seen_init_automake)
5309             {
5310               error ($where, "AC_CONFIG_AUX_DIR must be called before "
5311                      . "AM_INIT_AUTOMAKE ...", partial => 1);
5312               error ($seen_init_automake, "... AM_INIT_AUTOMAKE called here");
5313             }
5314           $config_aux_dir = $args[1];
5315           $config_aux_dir_set_in_configure_ac = 1;
5316           check_directory ($config_aux_dir, $where);
5317         }
5318       elsif ($macro eq 'AC_CONFIG_FILES')
5319         {
5320           # Look at potential Makefile.am's.
5321           scan_autoconf_config_files ($where, $args[1]);
5322         }
5323       elsif ($macro eq 'AC_CONFIG_HEADERS')
5324         {
5325           foreach my $spec (split (' ', $args[1]))
5326             {
5327               my ($dest, @src) = split (':', $spec);
5328               $ac_config_files_location{$dest} = $where;
5329               push @config_headers, $spec;
5330             }
5331         }
5332       elsif ($macro eq 'AC_CONFIG_LIBOBJ_DIR')
5333         {
5334           $config_libobj_dir = $args[1];
5335           check_directory ($config_libobj_dir, $where);
5336         }
5337       elsif ($macro eq 'AC_CONFIG_LINKS')
5338         {
5339           foreach my $spec (split (' ', $args[1]))
5340             {
5341               my ($dest, $src) = split (':', $spec);
5342               $ac_config_files_location{$dest} = $where;
5343               push @config_links, $spec;
5344             }
5345         }
5346       elsif ($macro eq 'AC_FC_SRCEXT')
5347         {
5348           my $suffix = $args[1];
5349           # These flags are used as %SOURCEFLAG% in depend2.am,
5350           # where the trailing space is important.
5351           $sourceflags{'.' . $suffix} = '$(FCFLAGS_' . $suffix . ') '
5352             if ($suffix eq 'f90' || $suffix eq 'f95' || $suffix eq 'f03' || $suffix eq 'f08');
5353         }
5354       elsif ($macro eq 'AC_INIT')
5355         {
5356           if (defined $args[2])
5357             {
5358               $package_version = $args[2];
5359               $package_version_location = $where;
5360             }
5361         }
5362       elsif ($macro eq 'AC_LIBSOURCE')
5363         {
5364           $libsources{$args[1]} = $here;
5365         }
5366       elsif ($macro eq 'AC_REQUIRE_AUX_FILE')
5367         {
5368           # Only remember the first time a file is required.
5369           $required_aux_file{$args[1]} = $where
5370             unless exists $required_aux_file{$args[1]};
5371         }
5372       elsif ($macro eq 'AC_SUBST_TRACE')
5373         {
5374           # Just check for alphanumeric in AC_SUBST_TRACE.  If you do
5375           # AC_SUBST(5), then too bad.
5376           $configure_vars{$args[1]} = $where
5377             if $args[1] =~ /^\w+$/;
5378         }
5379       elsif ($macro eq 'AM_AUTOMAKE_VERSION')
5380         {
5381           error ($where,
5382                  "version mismatch.  This is Automake $VERSION,\n" .
5383                  "but the definition used by this AM_INIT_AUTOMAKE\n" .
5384                  "comes from Automake $args[1].  You should recreate\n" .
5385                  "aclocal.m4 with aclocal and run automake again.\n",
5386                  # $? = 63 is used to indicate version mismatch to missing.
5387                  exit_code => 63)
5388             if $VERSION ne $args[1];
5389
5390           $seen_automake_version = 1;
5391         }
5392       elsif ($macro eq 'AM_PROG_MKDIR_P') # FIXME: to be removed in 1.13
5393         {
5394           msg 'obsolete', $where, <<'EOF';
5395 The 'AM_PROG_MKDIR_P' macro is deprecated, and will soon be removed.
5396 You should use the Autoconf-provided 'AC_PROG_MKDIR_P' macro instead,
5397 and use '$(MKDIR_P)' instead of '$(mkdir_p)'in your Makefile.am files.
5398 EOF
5399         }
5400       elsif ($macro eq 'AM_CONDITIONAL')
5401         {
5402           $configure_cond{$args[1]} = $where;
5403         }
5404       elsif ($macro eq 'AM_GNU_GETTEXT')
5405         {
5406           $seen_gettext = $where;
5407           $ac_gettext_location = $where;
5408           $seen_gettext_external = grep ($_ eq 'external', @args);
5409         }
5410       elsif ($macro eq 'AM_GNU_GETTEXT_INTL_SUBDIR')
5411         {
5412           $seen_gettext_intl = $where;
5413         }
5414       elsif ($macro eq 'AM_INIT_AUTOMAKE')
5415         {
5416           $seen_init_automake = $where;
5417           if (defined $args[2])
5418             {
5419               msg 'obsolete', $where, <<'EOF';
5420 AM_INIT_AUTOMAKE: two- and three-arguments forms are deprecated.  For more info, see:
5421 http://www.gnu.org/software/automake/manual/automake.html#Modernize-AM_INIT_AUTOMAKE-invocation
5422 EOF
5423               $package_version = $args[2];
5424               $package_version_location = $where;
5425             }
5426           elsif (defined $args[1])
5427             {
5428               my @opts = split (' ', $args[1]);
5429               @opts = map { { option => $_, where => $where } } @opts;
5430               exit $exit_code if process_global_option_list (@opts);
5431             }
5432         }
5433       elsif ($macro eq 'AM_MAINTAINER_MODE')
5434         {
5435           $seen_maint_mode = $where;
5436         }
5437       elsif ($macro eq 'AM_PROG_AR')
5438         {
5439           $seen_ar = $where;
5440         }
5441       elsif ($macro eq 'AM_PROG_CC_C_O')
5442         {
5443           $seen_cc_c_o = $where;
5444         }
5445       elsif ($macro eq 'AM_SILENT_RULES')
5446         {
5447           set_global_option ('silent-rules', $where);
5448         }
5449       elsif ($macro eq '_AM_COND_IF')
5450         {
5451           cond_stack_if ('', $args[1], $where);
5452           error ($where, "missing m4 quoting, macro depth $depth")
5453             if ($depth != 1);
5454         }
5455       elsif ($macro eq '_AM_COND_ELSE')
5456         {
5457           cond_stack_else ('!', $args[1], $where);
5458           error ($where, "missing m4 quoting, macro depth $depth")
5459             if ($depth != 1);
5460         }
5461       elsif ($macro eq '_AM_COND_ENDIF')
5462         {
5463           cond_stack_endif (undef, undef, $where);
5464           error ($where, "missing m4 quoting, macro depth $depth")
5465             if ($depth != 1);
5466         }
5467       elsif ($macro eq '_AM_SUBST_NOTMAKE')
5468         {
5469           $ignored_configure_vars{$args[1]} = $where;
5470         }
5471       elsif ($macro eq 'm4_include'
5472              || $macro eq 'm4_sinclude'
5473              || $macro eq 'sinclude')
5474         {
5475           # Skip missing 'sinclude'd files.
5476           next if $macro ne 'm4_include' && ! -f $args[1];
5477
5478           # Some modified versions of Autoconf don't use
5479           # frozen files.  Consequently it's possible that we see all
5480           # m4_include's performed during Autoconf's startup.
5481           # Obviously we don't want to distribute Autoconf's files
5482           # so we skip absolute filenames here.
5483           push @configure_deps, '$(top_srcdir)/' . $args[1]
5484             unless $here =~ m,^(?:\w:)?[\\/],;
5485           # Keep track of the greatest timestamp.
5486           if (-e $args[1])
5487             {
5488               my $mtime = mtime $args[1];
5489               $configure_deps_greatest_timestamp = $mtime
5490                 if $mtime > $configure_deps_greatest_timestamp;
5491             }
5492         }
5493       elsif ($macro eq 'LT_SUPPORTED_TAG')
5494         {
5495           $libtool_tags{$args[1]} = 1;
5496           $libtool_new_api = 1;
5497         }
5498       elsif ($macro eq '_LT_AC_TAGCONFIG')
5499         {
5500           # _LT_AC_TAGCONFIG is an old macro present in Libtool 1.5.
5501           # We use it to detect whether tags are supported.  Our
5502           # preferred interface is LT_SUPPORTED_TAG, but it was
5503           # introduced in Libtool 1.6.
5504           if (0 == keys %libtool_tags)
5505             {
5506               # Hardcode the tags supported by Libtool 1.5.
5507               %libtool_tags = (CC => 1, CXX => 1, GCJ => 1, F77 => 1);
5508             }
5509         }
5510     }
5511
5512   error ($where, "condition stack not properly closed")
5513     if (@cond_stack);
5514
5515   $tracefh->close;
5516 }
5517
5518
5519 # &scan_autoconf_files ()
5520 # -----------------------
5521 # Check whether we use 'configure.ac' or 'configure.in'.
5522 # Scan it (and possibly 'aclocal.m4') for interesting things.
5523 # We must scan aclocal.m4 because there might be AC_SUBSTs and such there.
5524 sub scan_autoconf_files ()
5525 {
5526   # Reinitialize libsources here.  This isn't really necessary,
5527   # since we currently assume there is only one configure.ac.  But
5528   # that won't always be the case.
5529   %libsources = ();
5530
5531   # Keep track of the youngest configure dependency.
5532   $configure_deps_greatest_timestamp = mtime $configure_ac;
5533   if (-e 'aclocal.m4')
5534     {
5535       my $mtime = mtime 'aclocal.m4';
5536       $configure_deps_greatest_timestamp = $mtime
5537         if $mtime > $configure_deps_greatest_timestamp;
5538     }
5539
5540   scan_autoconf_traces ($configure_ac);
5541
5542   @configure_input_files = sort keys %make_list;
5543   # Set input and output files if not specified by user.
5544   if (! @input_files)
5545     {
5546       @input_files = @configure_input_files;
5547       %output_files = %make_list;
5548     }
5549
5550
5551   if (! $seen_init_automake)
5552     {
5553       err_ac ("no proper invocation of AM_INIT_AUTOMAKE was found.\nYou "
5554               . "should verify that $configure_ac invokes AM_INIT_AUTOMAKE,"
5555               . "\nthat aclocal.m4 is present in the top-level directory,\n"
5556               . "and that aclocal.m4 was recently regenerated "
5557               . "(using aclocal)");
5558     }
5559   else
5560     {
5561       if (! $seen_automake_version)
5562         {
5563           if (-f 'aclocal.m4')
5564             {
5565               error ($seen_init_automake,
5566                      "your implementation of AM_INIT_AUTOMAKE comes from " .
5567                      "an\nold Automake version.  You should recreate " .
5568                      "aclocal.m4\nwith aclocal and run automake again",
5569                      # $? = 63 is used to indicate version mismatch to missing.
5570                      exit_code => 63);
5571             }
5572           else
5573             {
5574               error ($seen_init_automake,
5575                      "no proper implementation of AM_INIT_AUTOMAKE was " .
5576                      "found,\nprobably because aclocal.m4 is missing.\n" .
5577                      "You should run aclocal to create this file, then\n" .
5578                      "run automake again");
5579             }
5580         }
5581     }
5582
5583   locate_aux_dir ();
5584
5585   # Look for some files we need.  Always check for these.  This
5586   # check must be done for every run, even those where we are only
5587   # looking at a subdir Makefile.  We must set relative_dir for
5588   # push_required_file to work.
5589   # Sort the files for stable verbose output.
5590   $relative_dir = '.';
5591   foreach my $file (sort keys %required_aux_file)
5592     {
5593       require_conf_file ($required_aux_file{$file}->get, FOREIGN, $file)
5594     }
5595   err_am "'install.sh' is an anachronism; use 'install-sh' instead"
5596     if -f $config_aux_dir . '/install.sh';
5597
5598   # Preserve dist_common for later.
5599   $configure_dist_common = variable_value ('DIST_COMMON') || '';
5600
5601 }
5602
5603 ################################################################
5604
5605 # Set up for Cygnus mode.
5606 sub check_cygnus
5607 {
5608   my $cygnus = option 'cygnus';
5609   return unless $cygnus;
5610
5611   # This feature is deprecated, will be removed in the next
5612   # Automake major release.
5613   msg 'obsolete', $cygnus->get,
5614       "support for Cygnus-style trees is deprecated";
5615
5616   set_strictness ('foreign');
5617   set_option ('no-installinfo', $cygnus);
5618   set_option ('no-dependencies', $cygnus);
5619   set_option ('no-dist', $cygnus);
5620
5621   err_ac "'AM_MAINTAINER_MODE' required when --cygnus specified"
5622     if !$seen_maint_mode;
5623 }
5624
5625 # Do any extra checking for GNU standards.
5626 sub check_gnu_standards
5627 {
5628   if ($relative_dir eq '.')
5629     {
5630       # In top level (or only) directory.
5631       require_file ("$am_file.am", GNU,
5632                     qw/INSTALL NEWS README AUTHORS ChangeLog/);
5633
5634       # Accept one of these three licenses; default to COPYING.
5635       # Make sure we do not overwrite an existing license.
5636       my $license;
5637       foreach (qw /COPYING COPYING.LIB COPYING.LESSER/)
5638         {
5639           if (-f $_)
5640             {
5641               $license = $_;
5642               last;
5643             }
5644         }
5645       require_file ("$am_file.am", GNU, 'COPYING')
5646         unless $license;
5647     }
5648
5649   for my $opt ('no-installman', 'no-installinfo')
5650     {
5651       msg ('error-gnu', option $opt,
5652            "option '$opt' disallowed by GNU standards")
5653         if option $opt;
5654     }
5655 }
5656
5657 # Do any extra checking for GNITS standards.
5658 sub check_gnits_standards
5659 {
5660   if ($relative_dir eq '.')
5661     {
5662       # In top level (or only) directory.
5663       require_file ("$am_file.am", GNITS, 'THANKS');
5664     }
5665 }
5666
5667 ################################################################
5668 #
5669 # Functions to handle files of each language.
5670
5671 # Each 'lang_X_rewrite($DIRECTORY, $BASE, $EXT)' function follows a
5672 # simple formula: Return value is LANG_SUBDIR if the resulting object
5673 # file should be in a subdir if the source file is, LANG_PROCESS if
5674 # file is to be dealt with, LANG_IGNORE otherwise.
5675
5676 # Much of the actual processing is handled in
5677 # handle_single_transform.  These functions exist so that
5678 # auxiliary information can be recorded for a later cleanup pass.
5679 # Note that the calls to these functions are computed, so don't bother
5680 # searching for their precise names in the source.
5681
5682 # This is just a convenience function that can be used to determine
5683 # when a subdir object should be used.
5684 sub lang_sub_obj
5685 {
5686     return option 'subdir-objects' ? LANG_SUBDIR : LANG_PROCESS;
5687 }
5688
5689 # Rewrite a single C source file.
5690 sub lang_c_rewrite
5691 {
5692   my ($directory, $base, $ext, $obj, $have_per_exec_flags, $var) = @_;
5693
5694   my $r = LANG_PROCESS;
5695   if (option 'subdir-objects')
5696     {
5697       $r = LANG_SUBDIR;
5698       if ($directory && $directory ne '.')
5699         {
5700           $base = $directory . '/' . $base;
5701
5702           # libtool is always able to put the object at the proper place,
5703           # so we do not have to require AM_PROG_CC_C_O when building .lo files.
5704           msg_var ('portability', $var,
5705                    "compiling '$base.c' in subdir requires "
5706                    . "'AM_PROG_CC_C_O' in '$configure_ac'",
5707                    uniq_scope => US_GLOBAL,
5708                    uniq_part => 'AM_PROG_CC_C_O subdir')
5709             unless $seen_cc_c_o || $obj eq '.lo';
5710         }
5711     }
5712
5713   if (! $seen_cc_c_o
5714       && $have_per_exec_flags
5715       && ! option 'subdir-objects'
5716       && $obj ne '.lo')
5717     {
5718       msg_var ('portability',
5719                $var, "compiling '$base.c' with per-target flags requires "
5720                . "'AM_PROG_CC_C_O' in '$configure_ac'",
5721                uniq_scope => US_GLOBAL,
5722                uniq_part => 'AM_PROG_CC_C_O per-target')
5723     }
5724
5725     return $r;
5726 }
5727
5728 # Rewrite a single C++ source file.
5729 sub lang_cxx_rewrite
5730 {
5731     return &lang_sub_obj;
5732 }
5733
5734 # Rewrite a single header file.
5735 sub lang_header_rewrite
5736 {
5737     # Header files are simply ignored.
5738     return LANG_IGNORE;
5739 }
5740
5741 # Rewrite a single Vala source file.
5742 sub lang_vala_rewrite
5743 {
5744     my ($directory, $base, $ext) = @_;
5745
5746     (my $newext = $ext) =~ s/vala$/c/;
5747     return (LANG_SUBDIR, $newext);
5748 }
5749
5750 # Rewrite a single yacc file.
5751 sub lang_yacc_rewrite
5752 {
5753     my ($directory, $base, $ext) = @_;
5754
5755     my $r = &lang_sub_obj;
5756     (my $newext = $ext) =~ tr/y/c/;
5757     return ($r, $newext);
5758 }
5759
5760 # Rewrite a single yacc++ file.
5761 sub lang_yaccxx_rewrite
5762 {
5763     my ($directory, $base, $ext) = @_;
5764
5765     my $r = &lang_sub_obj;
5766     (my $newext = $ext) =~ tr/y/c/;
5767     return ($r, $newext);
5768 }
5769
5770 # Rewrite a single lex file.
5771 sub lang_lex_rewrite
5772 {
5773     my ($directory, $base, $ext) = @_;
5774
5775     my $r = &lang_sub_obj;
5776     (my $newext = $ext) =~ tr/l/c/;
5777     return ($r, $newext);
5778 }
5779
5780 # Rewrite a single lex++ file.
5781 sub lang_lexxx_rewrite
5782 {
5783     my ($directory, $base, $ext) = @_;
5784
5785     my $r = &lang_sub_obj;
5786     (my $newext = $ext) =~ tr/l/c/;
5787     return ($r, $newext);
5788 }
5789
5790 # Rewrite a single assembly file.
5791 sub lang_asm_rewrite
5792 {
5793     return &lang_sub_obj;
5794 }
5795
5796 # Rewrite a single preprocessed assembly file.
5797 sub lang_cppasm_rewrite
5798 {
5799     return &lang_sub_obj;
5800 }
5801
5802 # Rewrite a single Fortran 77 file.
5803 sub lang_f77_rewrite
5804 {
5805     return &lang_sub_obj;
5806 }
5807
5808 # Rewrite a single Fortran file.
5809 sub lang_fc_rewrite
5810 {
5811     return &lang_sub_obj;
5812 }
5813
5814 # Rewrite a single preprocessed Fortran file.
5815 sub lang_ppfc_rewrite
5816 {
5817     return &lang_sub_obj;
5818 }
5819
5820 # Rewrite a single preprocessed Fortran 77 file.
5821 sub lang_ppf77_rewrite
5822 {
5823     return &lang_sub_obj;
5824 }
5825
5826 # Rewrite a single ratfor file.
5827 sub lang_ratfor_rewrite
5828 {
5829     return &lang_sub_obj;
5830 }
5831
5832 # Rewrite a single Objective C file.
5833 sub lang_objc_rewrite
5834 {
5835     return &lang_sub_obj;
5836 }
5837
5838 # Rewrite a single Objective C++ file.
5839 sub lang_objcxx_rewrite
5840 {
5841     return &lang_sub_obj;
5842 }
5843
5844 # Rewrite a single Unified Parallel C file.
5845 sub lang_upc_rewrite
5846 {
5847     return &lang_sub_obj;
5848 }
5849
5850 # Rewrite a single Java file.
5851 sub lang_java_rewrite
5852 {
5853     return LANG_SUBDIR;
5854 }
5855
5856 # The lang_X_finish functions are called after all source file
5857 # processing is done.  Each should handle defining rules for the
5858 # language, etc.  A finish function is only called if a source file of
5859 # the appropriate type has been seen.
5860
5861 sub lang_vala_finish_target ($$)
5862 {
5863   my ($self, $name) = @_;
5864
5865   my $derived = canonicalize ($name);
5866   my $var = var "${derived}_SOURCES";
5867   return unless $var;
5868
5869   my @vala_sources = grep { /\.(vala|vapi)$/ } ($var->value_as_list_recursive);
5870
5871   # For automake bug#11229.
5872   return unless @vala_sources;
5873
5874   foreach my $vala_file (@vala_sources)
5875     {
5876       my $c_file = $vala_file;
5877       if ($c_file =~ s/(.*)\.vala$/$1.c/)
5878         {
5879           $c_file = "\$(srcdir)/$c_file";
5880           $output_rules .= "$c_file: \$(srcdir)/${derived}_vala.stamp\n"
5881             . "\t\@if test -f \$@; then :; else rm -f \$(srcdir)/${derived}_vala.stamp; fi\n"
5882             . "\t\@if test -f \$@; then :; else \\\n"
5883             . "\t  \$(MAKE) \$(AM_MAKEFLAGS) \$(srcdir)/${derived}_vala.stamp; \\\n"
5884             . "\tfi\n";
5885           $clean_files{$c_file} = MAINTAINER_CLEAN;
5886         }
5887     }
5888
5889   # Add rebuild rules for generated header and vapi files
5890   my $flags = var ($derived . '_VALAFLAGS');
5891   if ($flags)
5892     {
5893       my $lastflag = '';
5894       foreach my $flag ($flags->value_as_list_recursive)
5895         {
5896           if (grep (/$lastflag/, ('-H', '-h', '--header', '--internal-header',
5897                                   '--vapi', '--internal-vapi', '--gir')))
5898             {
5899               my $headerfile = "\$(srcdir)/$flag";
5900               $output_rules .= "$headerfile: \$(srcdir)/${derived}_vala.stamp\n"
5901                 . "\t\@if test -f \$@; then :; else rm -f \$(srcdir)/${derived}_vala.stamp; fi\n"
5902                 . "\t\@if test -f \$@; then :; else \\\n"
5903                 . "\t  \$(MAKE) \$(AM_MAKEFLAGS) \$(srcdir)/${derived}_vala.stamp; \\\n"
5904                 . "\tfi\n";
5905
5906               # valac is not used when building from dist tarballs
5907               # distribute the generated files
5908               push_dist_common ($headerfile);
5909               $clean_files{$headerfile} = MAINTAINER_CLEAN;
5910             }
5911           $lastflag = $flag;
5912         }
5913     }
5914
5915   my $compile = $self->compile;
5916
5917   # Rewrite each occurrence of 'AM_VALAFLAGS' in the compile
5918   # rule into '${derived}_VALAFLAGS' if it exists.
5919   my $val = "${derived}_VALAFLAGS";
5920   $compile =~ s/\(AM_VALAFLAGS\)/\($val\)/
5921     if set_seen ($val);
5922
5923   # VALAFLAGS is a user variable (per GNU Standards),
5924   # it should not be overridden in the Makefile...
5925   check_user_variables 'VALAFLAGS';
5926
5927   my $dirname = dirname ($name);
5928
5929   # Only generate C code, do not run C compiler
5930   $compile .= " -C";
5931
5932   my $verbose = verbose_flag ('VALAC');
5933   my $silent = silent_flag ();
5934   my $stampfile = "\$(srcdir)/${derived}_vala.stamp";
5935
5936   $output_rules .=
5937     "\$(srcdir)/${derived}_vala.stamp: @vala_sources\n".
5938 # Since the C files generated from the vala sources depend on the
5939 # ${derived}_vala.stamp file, we must ensure its timestamp is older than
5940 # those of the C files generated by the valac invocation below (this is
5941 # especially important on systems with sub-second timestamp resolution).
5942 # Thus we need to create the stamp file *before* invoking valac, and to
5943 # move it to its final location only after valac has been invoked.
5944     "\t${silent}rm -f \$\@ && echo stamp > \$\@-t\n".
5945     "\t${verbose}\$(am__cd) \$(srcdir) && $compile @vala_sources\n".
5946     "\t${silent}mv -f \$\@-t \$\@\n";
5947
5948   push_dist_common ($stampfile);
5949
5950   $clean_files{$stampfile} = MAINTAINER_CLEAN;
5951 }
5952
5953 # Add output rules to invoke valac and create stamp file as a witness
5954 # to handle multiple outputs. This function is called after all source
5955 # file processing is done.
5956 sub lang_vala_finish
5957 {
5958   my ($self) = @_;
5959
5960   foreach my $prog (keys %known_programs)
5961     {
5962       lang_vala_finish_target ($self, $prog);
5963     }
5964
5965   while (my ($name) = each %known_libraries)
5966     {
5967       lang_vala_finish_target ($self, $name);
5968     }
5969 }
5970
5971 # The built .c files should be cleaned only on maintainer-clean
5972 # as the .c files are distributed. This function is called for each
5973 # .vala source file.
5974 sub lang_vala_target_hook
5975 {
5976   my ($self, $aggregate, $output, $input, %transform) = @_;
5977
5978   $clean_files{$output} = MAINTAINER_CLEAN;
5979 }
5980
5981 # This is a yacc helper which is called whenever we have decided to
5982 # compile a yacc file.
5983 sub lang_yacc_target_hook
5984 {
5985     my ($self, $aggregate, $output, $input, %transform) = @_;
5986
5987     # If some relevant *YFLAGS variable contains the '-d' flag, we'll
5988     # have to to generate special code.
5989     my $yflags_contains_minus_d = 0;
5990
5991     foreach my $pfx ("", "${aggregate}_")
5992       {
5993         my $yflagsvar = var ("${pfx}YFLAGS");
5994         next unless $yflagsvar;
5995         # We cannot work reliably with conditionally-defined YFLAGS.
5996         if ($yflagsvar->has_conditional_contents)
5997           {
5998             msg_var ('unsupported', $yflagsvar,
5999                      "'${pfx}YFLAGS' cannot have conditional contents");
6000           }
6001         else
6002           {
6003             $yflags_contains_minus_d = 1
6004               if grep (/^-d$/, $yflagsvar->value_as_list_recursive);
6005           }
6006       }
6007
6008     if ($yflags_contains_minus_d)
6009       {
6010         # Found a '-d' that applies to the compilation of this file.
6011         # Add a dependency for the generated header file, and arrange
6012         # for that file to be included in the distribution.
6013
6014         # The extension of the output file (e.g., '.c' or '.cxx').
6015         # We'll need it to compute the name of the generated header file.
6016         (my $output_ext = basename ($output)) =~ s/.*(\.[^.]+)$/$1/;
6017
6018         # We know that a yacc input should be turned into either a C or
6019         # C++ output file.  We depend on this fact (here and in yacc.am),
6020         # so check that it really holds.
6021         my $lang = $languages{$extension_map{$output_ext}};
6022         prog_error "invalid output name '$output' for yacc file '$input'"
6023           if (!$lang || ($lang->name ne 'c' && $lang->name ne 'cxx'));
6024
6025         (my $header_ext = $output_ext) =~ s/c/h/g;
6026         # Quote $output_ext in the regexp, so that dots in it are taken
6027         # as literal dots, not as metacharacters.
6028         (my $header = $output) =~ s/\Q$output_ext\E$/$header_ext/;
6029
6030         foreach my $cond (Automake::Rule::define (${header}, 'internal',
6031                                                   RULE_AUTOMAKE, TRUE,
6032                                                   INTERNAL))
6033           {
6034             my $condstr = $cond->subst_string;
6035             $output_rules .=
6036               "$condstr${header}: $output\n"
6037               # Recover from removal of $header
6038               . "$condstr\t\@if test ! -f \$@; then rm -f $output; else :; fi\n"
6039               . "$condstr\t\@if test ! -f \$@; then \$(MAKE) \$(AM_MAKEFLAGS) $output; else :; fi\n";
6040           }
6041         # Distribute the generated file, unless its .y source was
6042         # listed in a nodist_ variable.  (&handle_source_transform
6043         # will set DIST_SOURCE.)
6044         &push_dist_common ($header)
6045           if $transform{'DIST_SOURCE'};
6046
6047         # The GNU rules say that yacc/lex output files should be removed
6048         # by maintainer-clean.  However, if the files are not distributed,
6049         # then we want to remove them with "make clean"; otherwise,
6050         # "make distcheck" will fail.
6051         $clean_files{$header} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
6052       }
6053     # See the comment above for $HEADER.
6054     $clean_files{$output} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
6055 }
6056
6057 # This is a lex helper which is called whenever we have decided to
6058 # compile a lex file.
6059 sub lang_lex_target_hook
6060 {
6061     my ($self, $aggregate, $output, $input, %transform) = @_;
6062     # The GNU rules say that yacc/lex output files should be removed
6063     # by maintainer-clean.  However, if the files are not distributed,
6064     # then we want to remove them with "make clean"; otherwise,
6065     # "make distcheck" will fail.
6066     $clean_files{$output} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
6067 }
6068
6069 # This is a helper for both lex and yacc.
6070 sub yacc_lex_finish_helper
6071 {
6072   return if defined $language_scratch{'lex-yacc-done'};
6073   $language_scratch{'lex-yacc-done'} = 1;
6074
6075   # FIXME: for now, no line number.
6076   require_conf_file ($configure_ac, FOREIGN, 'ylwrap');
6077   &define_variable ('YLWRAP', "$am_config_aux_dir/ylwrap", INTERNAL);
6078 }
6079
6080 sub lang_yacc_finish
6081 {
6082   return if defined $language_scratch{'yacc-done'};
6083   $language_scratch{'yacc-done'} = 1;
6084
6085   reject_var 'YACCFLAGS', "'YACCFLAGS' obsolete; use 'YFLAGS' instead";
6086
6087   yacc_lex_finish_helper;
6088 }
6089
6090
6091 sub lang_lex_finish
6092 {
6093   return if defined $language_scratch{'lex-done'};
6094   $language_scratch{'lex-done'} = 1;
6095
6096   yacc_lex_finish_helper;
6097 }
6098
6099
6100 # Given a hash table of linker names, pick the name that has the most
6101 # precedence.  This is lame, but something has to have global
6102 # knowledge in order to eliminate the conflict.  Add more linkers as
6103 # required.
6104 sub resolve_linker
6105 {
6106     my (%linkers) = @_;
6107
6108     foreach my $l (qw(GCJLINK OBJCXXLINK CXXLINK F77LINK FCLINK OBJCLINK UPCLINK))
6109     {
6110         return $l if defined $linkers{$l};
6111     }
6112     return 'LINK';
6113 }
6114
6115 # Called to indicate that an extension was used.
6116 sub saw_extension
6117 {
6118     my ($ext) = @_;
6119     if (! defined $extension_seen{$ext})
6120     {
6121         $extension_seen{$ext} = 1;
6122     }
6123     else
6124     {
6125         ++$extension_seen{$ext};
6126     }
6127 }
6128
6129 # Return the number of files seen for a given language.  Knows about
6130 # special cases we care about.  FIXME: this is hideous.  We need
6131 # something that involves real language objects.  For instance yacc
6132 # and yaccxx could both derive from a common yacc class which would
6133 # know about the strange ylwrap requirement.  (Or better yet we could
6134 # just not support legacy yacc!)
6135 sub count_files_for_language
6136 {
6137     my ($name) = @_;
6138
6139     my @names;
6140     if ($name eq 'yacc' || $name eq 'yaccxx')
6141     {
6142         @names = ('yacc', 'yaccxx');
6143     }
6144     elsif ($name eq 'lex' || $name eq 'lexxx')
6145     {
6146         @names = ('lex', 'lexxx');
6147     }
6148     else
6149     {
6150         @names = ($name);
6151     }
6152
6153     my $r = 0;
6154     foreach $name (@names)
6155     {
6156         my $lang = $languages{$name};
6157         foreach my $ext (@{$lang->extensions})
6158         {
6159             $r += $extension_seen{$ext}
6160                 if defined $extension_seen{$ext};
6161         }
6162     }
6163
6164     return $r
6165 }
6166
6167 # Called to ask whether source files have been seen . If HEADERS is 1,
6168 # headers can be included.
6169 sub saw_sources_p
6170 {
6171     my ($headers) = @_;
6172
6173     # count all the sources
6174     my $count = 0;
6175     foreach my $val (values %extension_seen)
6176     {
6177         $count += $val;
6178     }
6179
6180     if (!$headers)
6181     {
6182         $count -= count_files_for_language ('header');
6183     }
6184
6185     return $count > 0;
6186 }
6187
6188
6189 # register_language (%ATTRIBUTE)
6190 # ------------------------------
6191 # Register a single language.
6192 # Each %ATTRIBUTE is of the form ATTRIBUTE => VALUE.
6193 sub register_language (%)
6194 {
6195   my (%option) = @_;
6196
6197   # Set the defaults.
6198   $option{'autodep'} = 'no'
6199     unless defined $option{'autodep'};
6200   $option{'linker'} = ''
6201     unless defined $option{'linker'};
6202   $option{'flags'} = []
6203     unless defined $option{'flags'};
6204   $option{'output_extensions'} = sub { return ( '.$(OBJEXT)', '.lo' ) }
6205     unless defined $option{'output_extensions'};
6206   $option{'nodist_specific'} = 0
6207     unless defined $option{'nodist_specific'};
6208
6209   my $lang = new Language (%option);
6210
6211   # Fill indexes.
6212   $extension_map{$_} = $lang->name foreach @{$lang->extensions};
6213   $languages{$lang->name} = $lang;
6214   my $link = $lang->linker;
6215   if ($link)
6216     {
6217       if (exists $link_languages{$link})
6218         {
6219           prog_error ("'$link' has different definitions in "
6220                       . $lang->name . " and " . $link_languages{$link}->name)
6221             if $lang->link ne $link_languages{$link}->link;
6222         }
6223       else
6224         {
6225           $link_languages{$link} = $lang;
6226         }
6227     }
6228
6229   # Update the pattern of known extensions.
6230   accept_extensions (@{$lang->extensions});
6231
6232   # Upate the $suffix_rule map.
6233   foreach my $suffix (@{$lang->extensions})
6234     {
6235       foreach my $dest (&{$lang->output_extensions} ($suffix))
6236         {
6237           register_suffix_rule (INTERNAL, $suffix, $dest);
6238         }
6239     }
6240 }
6241
6242 # derive_suffix ($EXT, $OBJ)
6243 # --------------------------
6244 # This function is used to find a path from a user-specified suffix $EXT
6245 # to $OBJ or to some other suffix we recognize internally, e.g. 'cc'.
6246 sub derive_suffix ($$)
6247 {
6248   my ($source_ext, $obj) = @_;
6249
6250   while (! $extension_map{$source_ext}
6251          && $source_ext ne $obj
6252          && exists $suffix_rules->{$source_ext}
6253          && exists $suffix_rules->{$source_ext}{$obj})
6254     {
6255       $source_ext = $suffix_rules->{$source_ext}{$obj}[0];
6256     }
6257
6258   return $source_ext;
6259 }
6260
6261
6262 ################################################################
6263
6264 # Pretty-print something and append to output_rules.
6265 sub pretty_print_rule
6266 {
6267     $output_rules .= &makefile_wrap (@_);
6268 }
6269
6270
6271 ################################################################
6272
6273
6274 ## -------------------------------- ##
6275 ## Handling the conditional stack.  ##
6276 ## -------------------------------- ##
6277
6278
6279 # $STRING
6280 # make_conditional_string ($NEGATE, $COND)
6281 # ----------------------------------------
6282 sub make_conditional_string ($$)
6283 {
6284   my ($negate, $cond) = @_;
6285   $cond = "${cond}_TRUE"
6286     unless $cond =~ /^TRUE|FALSE$/;
6287   $cond = Automake::Condition::conditional_negate ($cond)
6288     if $negate;
6289   return $cond;
6290 }
6291
6292
6293 my %_am_macro_for_cond =
6294   (
6295   AMDEP => "one of the compiler tests\n"
6296            . "    AC_PROG_CC, AC_PROG_CXX, AC_PROG_OBJC, AC_PROG_OBJCXX,\n"
6297            . "    AM_PROG_AS, AM_PROG_GCJ, AM_PROG_UPC",
6298   am__fastdepCC => 'AC_PROG_CC',
6299   am__fastdepCCAS => 'AM_PROG_AS',
6300   am__fastdepCXX => 'AC_PROG_CXX',
6301   am__fastdepGCJ => 'AM_PROG_GCJ',
6302   am__fastdepOBJC => 'AC_PROG_OBJC',
6303   am__fastdepOBJCXX => 'AC_PROG_OBJCXX',
6304   am__fastdepUPC => 'AM_PROG_UPC'
6305   );
6306
6307 # $COND
6308 # cond_stack_if ($NEGATE, $COND, $WHERE)
6309 # --------------------------------------
6310 sub cond_stack_if ($$$)
6311 {
6312   my ($negate, $cond, $where) = @_;
6313
6314   if (! $configure_cond{$cond} && $cond !~ /^TRUE|FALSE$/)
6315     {
6316       my $text = "$cond does not appear in AM_CONDITIONAL";
6317       my $scope = US_LOCAL;
6318       if (exists $_am_macro_for_cond{$cond})
6319         {
6320           my $mac = $_am_macro_for_cond{$cond};
6321           $text .= "\n  The usual way to define '$cond' is to add ";
6322           $text .= ($mac =~ / /) ? $mac : "'$mac'";
6323           $text .= "\n  to '$configure_ac' and run 'aclocal' and 'autoconf' again";
6324           # These warnings appear in Automake files (depend2.am),
6325           # so there is no need to display them more than once:
6326           $scope = US_GLOBAL;
6327         }
6328       error $where, $text, uniq_scope => $scope;
6329     }
6330
6331   push (@cond_stack, make_conditional_string ($negate, $cond));
6332
6333   return new Automake::Condition (@cond_stack);
6334 }
6335
6336
6337 # $COND
6338 # cond_stack_else ($NEGATE, $COND, $WHERE)
6339 # ----------------------------------------
6340 sub cond_stack_else ($$$)
6341 {
6342   my ($negate, $cond, $where) = @_;
6343
6344   if (! @cond_stack)
6345     {
6346       error $where, "else without if";
6347       return FALSE;
6348     }
6349
6350   $cond_stack[$#cond_stack] =
6351     Automake::Condition::conditional_negate ($cond_stack[$#cond_stack]);
6352
6353   # If $COND is given, check against it.
6354   if (defined $cond)
6355     {
6356       $cond = make_conditional_string ($negate, $cond);
6357
6358       error ($where, "else reminder ($negate$cond) incompatible with "
6359              . "current conditional: $cond_stack[$#cond_stack]")
6360         if $cond_stack[$#cond_stack] ne $cond;
6361     }
6362
6363   return new Automake::Condition (@cond_stack);
6364 }
6365
6366
6367 # $COND
6368 # cond_stack_endif ($NEGATE, $COND, $WHERE)
6369 # -----------------------------------------
6370 sub cond_stack_endif ($$$)
6371 {
6372   my ($negate, $cond, $where) = @_;
6373   my $old_cond;
6374
6375   if (! @cond_stack)
6376     {
6377       error $where, "endif without if";
6378       return TRUE;
6379     }
6380
6381   # If $COND is given, check against it.
6382   if (defined $cond)
6383     {
6384       $cond = make_conditional_string ($negate, $cond);
6385
6386       error ($where, "endif reminder ($negate$cond) incompatible with "
6387              . "current conditional: $cond_stack[$#cond_stack]")
6388         if $cond_stack[$#cond_stack] ne $cond;
6389     }
6390
6391   pop @cond_stack;
6392
6393   return new Automake::Condition (@cond_stack);
6394 }
6395
6396
6397
6398
6399
6400 ## ------------------------ ##
6401 ## Handling the variables.  ##
6402 ## ------------------------ ##
6403
6404
6405 # &define_pretty_variable ($VAR, $COND, $WHERE, @VALUE)
6406 # -----------------------------------------------------
6407 # Like define_variable, but the value is a list, and the variable may
6408 # be defined conditionally.  The second argument is the condition
6409 # under which the value should be defined; this should be the empty
6410 # string to define the variable unconditionally.  The third argument
6411 # is a list holding the values to use for the variable.  The value is
6412 # pretty printed in the output file.
6413 sub define_pretty_variable ($$$@)
6414 {
6415     my ($var, $cond, $where, @value) = @_;
6416
6417     if (! vardef ($var, $cond))
6418     {
6419         Automake::Variable::define ($var, VAR_AUTOMAKE, '', $cond, "@value",
6420                                     '', $where, VAR_PRETTY);
6421         rvar ($var)->rdef ($cond)->set_seen;
6422     }
6423 }
6424
6425
6426 # define_variable ($VAR, $VALUE, $WHERE)
6427 # --------------------------------------
6428 # Define a new Automake Makefile variable VAR to VALUE, but only if
6429 # not already defined.
6430 sub define_variable ($$$)
6431 {
6432     my ($var, $value, $where) = @_;
6433     define_pretty_variable ($var, TRUE, $where, $value);
6434 }
6435
6436
6437 # define_files_variable ($VAR, \@BASENAME, $EXTENSION, $WHERE)
6438 # ------------------------------------------------------------
6439 # Define the $VAR which content is the list of file names composed of
6440 # a @BASENAME and the $EXTENSION.
6441 sub define_files_variable ($\@$$)
6442 {
6443   my ($var, $basename, $extension, $where) = @_;
6444   define_variable ($var,
6445                    join (' ', map { "$_.$extension" } @$basename),
6446                    $where);
6447 }
6448
6449
6450 # Like define_variable, but define a variable to be the configure
6451 # substitution by the same name.
6452 sub define_configure_variable ($)
6453 {
6454   my ($var) = @_;
6455   # Some variables we do not want to output.  For instance it
6456   # would be a bad idea to output `U = @U@` when `@U@` can be
6457   # substituted as `\`.
6458   my $pretty = exists $ignored_configure_vars{$var} ? VAR_SILENT : VAR_ASIS;
6459   Automake::Variable::define ($var, VAR_CONFIGURE, '', TRUE, subst $var,
6460                               '', $configure_vars{$var}, $pretty);
6461 }
6462
6463
6464 # define_compiler_variable ($LANG)
6465 # --------------------------------
6466 # Define a compiler variable.  We also handle defining the 'LT'
6467 # version of the command when using libtool.
6468 sub define_compiler_variable ($)
6469 {
6470     my ($lang) = @_;
6471
6472     my ($var, $value) = ($lang->compiler, $lang->compile);
6473     my $libtool_tag = '';
6474     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6475       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6476     &define_variable ($var, $value, INTERNAL);
6477     if (var ('LIBTOOL'))
6478       {
6479         my $verbose = define_verbose_libtool ();
6480         &define_variable ("LT$var",
6481                           "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) "
6482                           . "\$(LIBTOOLFLAGS) --mode=compile $value",
6483                           INTERNAL);
6484       }
6485     define_verbose_tagvar ($lang->ccer || 'GEN');
6486 }
6487
6488
6489 # define_linker_variable ($LANG)
6490 # ------------------------------
6491 # Define linker variables.
6492 sub define_linker_variable ($)
6493 {
6494     my ($lang) = @_;
6495
6496     my $libtool_tag = '';
6497     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6498       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6499     # CCLD = $(CC).
6500     &define_variable ($lang->lder, $lang->ld, INTERNAL);
6501     # CCLINK = $(CCLD) blah blah...
6502     my $link = '';
6503     if (var ('LIBTOOL'))
6504       {
6505         my $verbose = define_verbose_libtool ();
6506         $link = "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) "
6507                 . "\$(LIBTOOLFLAGS) --mode=link ";
6508       }
6509     &define_variable ($lang->linker, $link . $lang->link, INTERNAL);
6510     &define_variable ($lang->compiler,  $lang);
6511     &define_verbose_tagvar ($lang->lder || 'GEN');
6512 }
6513
6514 sub define_per_target_linker_variable ($$)
6515 {
6516   my ($linker, $target) = @_;
6517
6518   # If the user wrote a custom link command, we don't define ours.
6519   return "${target}_LINK"
6520     if set_seen "${target}_LINK";
6521
6522   my $xlink = $linker ? $linker : 'LINK';
6523
6524   my $lang = $link_languages{$xlink};
6525   prog_error "Unknown language for linker variable '$xlink'"
6526     unless $lang;
6527
6528   my $link_command = $lang->link;
6529   if (var 'LIBTOOL')
6530     {
6531       my $libtool_tag = '';
6532       $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6533         if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6534
6535       my $verbose = define_verbose_libtool ();
6536       $link_command =
6537         "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) \$(LIBTOOLFLAGS) "
6538         . "--mode=link " . $link_command;
6539     }
6540
6541   # Rewrite each occurrence of 'AM_$flag' in the link
6542   # command into '${derived}_$flag' if it exists.
6543   my $orig_command = $link_command;
6544   my @flags = (@{$lang->flags}, 'LDFLAGS');
6545   push @flags, 'LIBTOOLFLAGS' if var 'LIBTOOL';
6546   for my $flag (@flags)
6547     {
6548       my $val = "${target}_$flag";
6549       $link_command =~ s/\(AM_$flag\)/\($val\)/
6550         if set_seen ($val);
6551     }
6552
6553   # If the computed command is the same as the generic command, use
6554   # the command linker variable.
6555   return ($lang->linker, $lang->lder)
6556     if $link_command eq $orig_command;
6557
6558   &define_variable ("${target}_LINK", $link_command, INTERNAL);
6559   return ("${target}_LINK", $lang->lder);
6560 }
6561
6562 ################################################################
6563
6564 # &check_trailing_slash ($WHERE, $LINE)
6565 # -------------------------------------
6566 # Return 1 iff $LINE ends with a slash.
6567 # Might modify $LINE.
6568 sub check_trailing_slash ($\$)
6569 {
6570   my ($where, $line) = @_;
6571
6572   # Ignore '##' lines.
6573   return 0 if $$line =~ /$IGNORE_PATTERN/o;
6574
6575   # Catch and fix a common error.
6576   msg "syntax", $where, "whitespace following trailing backslash"
6577     if $$line =~ s/\\\s+\n$/\\\n/;
6578
6579   return $$line =~ /\\$/;
6580 }
6581
6582
6583 # &read_am_file ($AMFILE, $WHERE)
6584 # -------------------------------
6585 # Read Makefile.am and set up %contents.  Simultaneously copy lines
6586 # from Makefile.am into $output_trailer, or define variables as
6587 # appropriate.  NOTE we put rules in the trailer section.  We want
6588 # user rules to come after our generated stuff.
6589 sub read_am_file ($$)
6590 {
6591     my ($amfile, $where) = @_;
6592
6593     my $am_file = new Automake::XFile ("< $amfile");
6594     verb "reading $amfile";
6595
6596     # Keep track of the youngest output dependency.
6597     my $mtime = mtime $amfile;
6598     $output_deps_greatest_timestamp = $mtime
6599       if $mtime > $output_deps_greatest_timestamp;
6600
6601     my $spacing = '';
6602     my $comment = '';
6603     my $blank = 0;
6604     my $saw_bk = 0;
6605     my $var_look = VAR_ASIS;
6606
6607     use constant IN_VAR_DEF => 0;
6608     use constant IN_RULE_DEF => 1;
6609     use constant IN_COMMENT => 2;
6610     my $prev_state = IN_RULE_DEF;
6611
6612     while ($_ = $am_file->getline)
6613     {
6614         $where->set ("$amfile:$.");
6615         if (/$IGNORE_PATTERN/o)
6616         {
6617             # Merely delete comments beginning with two hashes.
6618         }
6619         elsif (/$WHITE_PATTERN/o)
6620         {
6621             error $where, "blank line following trailing backslash"
6622               if $saw_bk;
6623             # Stick a single white line before the incoming macro or rule.
6624             $spacing = "\n";
6625             $blank = 1;
6626             # Flush all comments seen so far.
6627             if ($comment ne '')
6628             {
6629                 $output_vars .= $comment;
6630                 $comment = '';
6631             }
6632         }
6633         elsif (/$COMMENT_PATTERN/o)
6634         {
6635             # Stick comments before the incoming macro or rule.  Make
6636             # sure a blank line precedes the first block of comments.
6637             $spacing = "\n" unless $blank;
6638             $blank = 1;
6639             $comment .= $spacing . $_;
6640             $spacing = '';
6641             $prev_state = IN_COMMENT;
6642         }
6643         else
6644         {
6645             last;
6646         }
6647         $saw_bk = check_trailing_slash ($where, $_);
6648     }
6649
6650     # We save the conditional stack on entry, and then check to make
6651     # sure it is the same on exit.  This lets us conditionally include
6652     # other files.
6653     my @saved_cond_stack = @cond_stack;
6654     my $cond = new Automake::Condition (@cond_stack);
6655
6656     my $last_var_name = '';
6657     my $last_var_type = '';
6658     my $last_var_value = '';
6659     my $last_where;
6660     # FIXME: shouldn't use $_ in this loop; it is too big.
6661     while ($_)
6662     {
6663         $where->set ("$amfile:$.");
6664
6665         # Make sure the line is \n-terminated.
6666         chomp;
6667         $_ .= "\n";
6668
6669         # Don't look at MAINTAINER_MODE_TRUE here.  That shouldn't be
6670         # used by users.  @MAINT@ is an anachronism now.
6671         $_ =~ s/\@MAINT\@//g
6672             unless $seen_maint_mode;
6673
6674         my $new_saw_bk = check_trailing_slash ($where, $_);
6675
6676         if (/$IGNORE_PATTERN/o)
6677         {
6678             # Merely delete comments beginning with two hashes.
6679
6680             # Keep any backslash from the previous line.
6681             $new_saw_bk = $saw_bk;
6682         }
6683         elsif (/$WHITE_PATTERN/o)
6684         {
6685             # Stick a single white line before the incoming macro or rule.
6686             $spacing = "\n";
6687             error $where, "blank line following trailing backslash"
6688               if $saw_bk;
6689         }
6690         elsif (/$COMMENT_PATTERN/o)
6691         {
6692             error $where, "comment following trailing backslash"
6693               if $saw_bk && $prev_state != IN_COMMENT;
6694
6695             # Stick comments before the incoming macro or rule.
6696             $comment .= $spacing . $_;
6697             $spacing = '';
6698             $prev_state = IN_COMMENT;
6699         }
6700         elsif ($saw_bk)
6701         {
6702             if ($prev_state == IN_RULE_DEF)
6703             {
6704               my $cond = new Automake::Condition @cond_stack;
6705               $output_trailer .= $cond->subst_string;
6706               $output_trailer .= $_;
6707             }
6708             elsif ($prev_state == IN_COMMENT)
6709             {
6710                 # If the line doesn't start with a '#', add it.
6711                 # We do this because a continued comment like
6712                 #   # A = foo \
6713                 #         bar \
6714                 #         baz
6715                 # is not portable.  BSD make doesn't honor
6716                 # escaped newlines in comments.
6717                 s/^#?/#/;
6718                 $comment .= $spacing . $_;
6719             }
6720             else # $prev_state == IN_VAR_DEF
6721             {
6722               $last_var_value .= ' '
6723                 unless $last_var_value =~ /\s$/;
6724               $last_var_value .= $_;
6725
6726               if (!/\\$/)
6727                 {
6728                   Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6729                                               $last_var_type, $cond,
6730                                               $last_var_value, $comment,
6731                                               $last_where, VAR_ASIS)
6732                     if $cond != FALSE;
6733                   $comment = $spacing = '';
6734                 }
6735             }
6736         }
6737
6738         elsif (/$IF_PATTERN/o)
6739           {
6740             $cond = cond_stack_if ($1, $2, $where);
6741           }
6742         elsif (/$ELSE_PATTERN/o)
6743           {
6744             $cond = cond_stack_else ($1, $2, $where);
6745           }
6746         elsif (/$ENDIF_PATTERN/o)
6747           {
6748             $cond = cond_stack_endif ($1, $2, $where);
6749           }
6750
6751         elsif (/$RULE_PATTERN/o)
6752         {
6753             # Found a rule.
6754             $prev_state = IN_RULE_DEF;
6755
6756             # For now we have to output all definitions of user rules
6757             # and can't diagnose duplicates (see the comment in
6758             # Automake::Rule::define). So we go on and ignore the return value.
6759             Automake::Rule::define ($1, $amfile, RULE_USER, $cond, $where);
6760
6761             check_variable_expansions ($_, $where);
6762
6763             $output_trailer .= $comment . $spacing;
6764             my $cond = new Automake::Condition @cond_stack;
6765             $output_trailer .= $cond->subst_string;
6766             $output_trailer .= $_;
6767             $comment = $spacing = '';
6768         }
6769         elsif (/$ASSIGNMENT_PATTERN/o)
6770         {
6771             # Found a macro definition.
6772             $prev_state = IN_VAR_DEF;
6773             $last_var_name = $1;
6774             $last_var_type = $2;
6775             $last_var_value = $3;
6776             $last_where = $where->clone;
6777             if ($3 ne '' && substr ($3, -1) eq "\\")
6778               {
6779                 # We preserve the '\' because otherwise the long lines
6780                 # that are generated will be truncated by broken
6781                 # 'sed's.
6782                 $last_var_value = $3 . "\n";
6783               }
6784             # Normally we try to output variable definitions in the
6785             # same format they were input.  However, POSIX compliant
6786             # systems are not required to support lines longer than
6787             # 2048 bytes (most notably, some sed implementation are
6788             # limited to 4000 bytes, and sed is used by config.status
6789             # to rewrite Makefile.in into Makefile).  Moreover nobody
6790             # would really write such long lines by hand since it is
6791             # hardly maintainable.  So if a line is longer that 1000
6792             # bytes (an arbitrary limit), assume it has been
6793             # automatically generated by some tools, and flatten the
6794             # variable definition.  Otherwise, keep the variable as it
6795             # as been input.
6796             $var_look = VAR_PRETTY if length ($last_var_value) >= 1000;
6797
6798             if (!/\\$/)
6799               {
6800                 Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6801                                             $last_var_type, $cond,
6802                                             $last_var_value, $comment,
6803                                             $last_where, $var_look)
6804                   if $cond != FALSE;
6805                 $comment = $spacing = '';
6806                 $var_look = VAR_ASIS;
6807               }
6808         }
6809         elsif (/$INCLUDE_PATTERN/o)
6810         {
6811             my $path = $1;
6812
6813             if ($path =~ s/^\$\(top_srcdir\)\///)
6814               {
6815                 push (@include_stack, "\$\(top_srcdir\)/$path");
6816                 # Distribute any included file.
6817
6818                 # Always use the $(top_srcdir) prefix in DIST_COMMON,
6819                 # otherwise OSF make will implicitly copy the included
6820                 # file in the build tree during "make distdir" to satisfy
6821                 # the dependency.
6822                 # (subdircond2.test and subdircond3.test will fail.)
6823                 push_dist_common ("\$\(top_srcdir\)/$path");
6824               }
6825             else
6826               {
6827                 $path =~ s/\$\(srcdir\)\///;
6828                 push (@include_stack, "\$\(srcdir\)/$path");
6829                 # Always use the $(srcdir) prefix in DIST_COMMON,
6830                 # otherwise OSF make will implicitly copy the included
6831                 # file in the build tree during "make distdir" to satisfy
6832                 # the dependency.
6833                 # (subdircond2.test and subdircond3.test will fail.)
6834                 push_dist_common ("\$\(srcdir\)/$path");
6835                 $path = $relative_dir . "/" . $path if $relative_dir ne '.';
6836               }
6837             $where->push_context ("'$path' included from here");
6838             &read_am_file ($path, $where);
6839             $where->pop_context;
6840         }
6841         else
6842         {
6843             # This isn't an error; it is probably a continued rule.
6844             # In fact, this is what we assume.
6845             $prev_state = IN_RULE_DEF;
6846             check_variable_expansions ($_, $where);
6847             $output_trailer .= $comment . $spacing;
6848             my $cond = new Automake::Condition @cond_stack;
6849             $output_trailer .= $cond->subst_string;
6850             $output_trailer .= $_;
6851             $comment = $spacing = '';
6852             error $where, "'#' comment at start of rule is unportable"
6853               if $_ =~ /^\t\s*\#/;
6854         }
6855
6856         $saw_bk = $new_saw_bk;
6857         $_ = $am_file->getline;
6858     }
6859
6860     $output_trailer .= $comment;
6861
6862     error ($where, "trailing backslash on last line")
6863       if $saw_bk;
6864
6865     error ($where, (@cond_stack ? "unterminated conditionals: @cond_stack"
6866                     : "too many conditionals closed in include file"))
6867       if "@saved_cond_stack" ne "@cond_stack";
6868 }
6869
6870
6871 # define_standard_variables ()
6872 # ----------------------------
6873 # A helper for read_main_am_file which initializes configure variables
6874 # and variables from header-vars.am.
6875 sub define_standard_variables
6876 {
6877   my $saved_output_vars = $output_vars;
6878   my ($comments, undef, $rules) =
6879     file_contents_internal (1, "$libdir/am/header-vars.am",
6880                             new Automake::Location);
6881
6882   foreach my $var (sort keys %configure_vars)
6883     {
6884       &define_configure_variable ($var);
6885     }
6886
6887   $output_vars .= $comments . $rules;
6888 }
6889
6890 # Read main am file.
6891 sub read_main_am_file
6892 {
6893     my ($amfile) = @_;
6894
6895     # This supports the strange variable tricks we are about to play.
6896     prog_error ("variable defined before read_main_am_file\n" . variables_dump ())
6897       if (scalar (variables) > 0);
6898
6899     # Generate copyright header for generated Makefile.in.
6900     # We do discard the output of predefined variables, handled below.
6901     $output_vars = ("# $in_file_name generated by automake "
6902                    . $VERSION . " from $am_file_name.\n");
6903     $output_vars .= '# ' . subst ('configure_input') . "\n";
6904     $output_vars .= $gen_copyright;
6905
6906     # We want to predefine as many variables as possible.  This lets
6907     # the user set them with '+=' in Makefile.am.
6908     &define_standard_variables;
6909
6910     # Read user file, which might override some of our values.
6911     &read_am_file ($amfile, new Automake::Location);
6912 }
6913
6914
6915
6916 ################################################################
6917
6918 # $FLATTENED
6919 # &flatten ($STRING)
6920 # ------------------
6921 # Flatten the $STRING and return the result.
6922 sub flatten
6923 {
6924   $_ = shift;
6925
6926   s/\\\n//somg;
6927   s/\s+/ /g;
6928   s/^ //;
6929   s/ $//;
6930
6931   return $_;
6932 }
6933
6934
6935 # transform_token ($TOKEN, \%PAIRS, $KEY)
6936 # =======================================
6937 # Return the value associated to $KEY in %PAIRS, as used on $TOKEN
6938 # (which should be ?KEY? or any of the special %% requests)..
6939 sub transform_token ($$$)
6940 {
6941   my ($token, $transform, $key) = @_;
6942   my $res = $transform->{$key};
6943   prog_error "Unknown key '$key' in '$token'" unless defined $res;
6944   return $res;
6945 }
6946
6947
6948 # transform ($TOKEN, \%PAIRS)
6949 # ===========================
6950 # If ($TOKEN, $VAL) is in %PAIRS:
6951 #   - replaces %KEY% with $VAL,
6952 #   - enables/disables ?KEY? and ?!KEY?,
6953 #   - replaces %?KEY% with TRUE or FALSE.
6954 #   - replaces %KEY?IFTRUE%, %KEY:IFFALSE%, and %KEY?IFTRUE:IFFALSE% with
6955 #     IFTRUE / IFFALSE, as appropriate.
6956 sub transform ($$)
6957 {
6958   my ($token, $transform) = @_;
6959
6960   # %KEY%.
6961   # Must be before the following pattern to exclude the case
6962   # when there is neither IFTRUE nor IFFALSE.
6963   if ($token =~ /^%([\w\-]+)%$/)
6964     {
6965       return transform_token ($token, $transform, $1);
6966     }
6967   # %KEY?IFTRUE%, %KEY:IFFALSE%, and %KEY?IFTRUE:IFFALSE%.
6968   elsif ($token =~ /^%([\w\-]+)(?:\?([^?:%]+))?(?::([^?:%]+))?%$/)
6969     {
6970       return transform_token ($token, $transform, $1) ? ($2 || '') : ($3 || '');
6971     }
6972   # %?KEY%.
6973   elsif ($token =~ /^%\?([\w\-]+)%$/)
6974     {
6975       return transform_token ($token, $transform, $1) ? 'TRUE' : 'FALSE';
6976     }
6977   # ?KEY? and ?!KEY?.
6978   elsif ($token =~ /^ \? (!?) ([\w\-]+) \? $/x)
6979     {
6980       my $neg = ($1 eq '!') ? 1 : 0;
6981       my $val = transform_token ($token, $transform, $2);
6982       return (!!$val == $neg) ? '##%' : '';
6983     }
6984   else
6985     {
6986       prog_error "Unknown request format: $token";
6987     }
6988 }
6989
6990 # $TEXT
6991 # preprocess_file ($MAKEFILE, [%TRANSFORM])
6992 # -----------------------------------------
6993 # Load a $MAKEFILE, apply the %TRANSFORM, and return the result.
6994 # No extra parsing of post-processing is done (i.e., recognition of
6995 # rules declaration or of make variables definitions).
6996 sub preprocess_file ($%)
6997 {
6998   my ($file, %transform) = @_;
6999
7000   # Complete %transform with global options.
7001   # Note that %transform goes last, so it overrides global options.
7002   %transform = ('CYGNUS'      => !! option 'cygnus',
7003                  'MAINTAINER-MODE'
7004                  => $seen_maint_mode ? subst ('MAINTAINER_MODE_TRUE') : '',
7005
7006                  'XZ'          => !! option 'dist-xz',
7007                  'LZMA'        => !! option 'dist-lzma',
7008                  'LZIP'        => !! option 'dist-lzip',
7009                  'BZIP2'       => !! option 'dist-bzip2',
7010                  'COMPRESS'    => !! option 'dist-tarZ',
7011                  'GZIP'        =>  ! option 'no-dist-gzip',
7012                  'SHAR'        => !! option 'dist-shar',
7013                  'ZIP'         => !! option 'dist-zip',
7014
7015                  'INSTALL-INFO' =>  ! option 'no-installinfo',
7016                  'INSTALL-MAN'  =>  ! option 'no-installman',
7017                  'HAVE-MANS'    => !! var ('MANS'),
7018                  'CK-NEWS'      => !! option 'check-news',
7019
7020                  'SUBDIRS'      => !! var ('SUBDIRS'),
7021                  'TOPDIR_P'     => $relative_dir eq '.',
7022
7023                  'BUILD'    => ($seen_canonical >= AC_CANONICAL_BUILD),
7024                  'HOST'     => ($seen_canonical >= AC_CANONICAL_HOST),
7025                  'TARGET'   => ($seen_canonical >= AC_CANONICAL_TARGET),
7026
7027                  'LIBTOOL'      => !! var ('LIBTOOL'),
7028                  'NONLIBTOOL'   => 1,
7029                 %transform);
7030
7031   if (! defined ($_ = $am_file_cache{$file}))
7032     {
7033       verb "reading $file";
7034       # Swallow the whole file.
7035       my $fc_file = new Automake::XFile "< $file";
7036       my $saved_dollar_slash = $/;
7037       undef $/;
7038       $_ = $fc_file->getline;
7039       $/ = $saved_dollar_slash;
7040       $fc_file->close;
7041       # Remove ##-comments.
7042       # Besides we don't need more than two consecutive new-lines.
7043       s/(?:$IGNORE_PATTERN|(?<=\n\n)\n+)//gom;
7044       # Remember the contents of the just-read file.
7045       $am_file_cache{$file} = $_;
7046     }
7047
7048   # Substitute Automake template tokens.
7049   s/(?: % \?? [\w\-]+ %
7050       | % [\w\-]+ (?:\?[^?:%]+)? (?::[^?:%]+)? %
7051       | \? !? [\w\-]+ \?
7052     )/transform($&, \%transform)/gex;
7053   # transform() may have added some ##%-comments to strip.
7054   # (we use '##%' instead of '##' so we can distinguish ##%##%##% from
7055   # ####### and do not remove the latter.)
7056   s/^[ \t]*(?:##%)+.*\n//gm;
7057
7058   return $_;
7059 }
7060
7061
7062 # @PARAGRAPHS
7063 # &make_paragraphs ($MAKEFILE, [%TRANSFORM])
7064 # ------------------------------------------
7065 # Load a $MAKEFILE, apply the %TRANSFORM, and return it as a list of
7066 # paragraphs.
7067 sub make_paragraphs ($%)
7068 {
7069   my ($file, %transform) = @_;
7070   $transform{FIRST} = !$transformed_files{$file};
7071   $transformed_files{$file} = 1;
7072
7073   my @lines = split /(?<!\\)\n/, preprocess_file ($file, %transform);
7074   my @res;
7075
7076   while (defined ($_ = shift @lines))
7077     {
7078       my $paragraph = $_;
7079       # If we are a rule, eat as long as we start with a tab.
7080       if (/$RULE_PATTERN/smo)
7081         {
7082           while (defined ($_ = shift @lines) && $_ =~ /^\t/)
7083             {
7084               $paragraph .= "\n$_";
7085             }
7086           unshift (@lines, $_);
7087         }
7088
7089       # If we are a comments, eat as much comments as you can.
7090       elsif (/$COMMENT_PATTERN/smo)
7091         {
7092           while (defined ($_ = shift @lines)
7093                  && $_ =~ /$COMMENT_PATTERN/smo)
7094             {
7095               $paragraph .= "\n$_";
7096             }
7097           unshift (@lines, $_);
7098         }
7099
7100       push @res, $paragraph;
7101     }
7102
7103   return @res;
7104 }
7105
7106
7107
7108 # ($COMMENT, $VARIABLES, $RULES)
7109 # &file_contents_internal ($IS_AM, $FILE, $WHERE, [%TRANSFORM])
7110 # -------------------------------------------------------------
7111 # Return contents of a file from $libdir/am, automatically skipping
7112 # macros or rules which are already known. $IS_AM iff the caller is
7113 # reading an Automake file (as opposed to the user's Makefile.am).
7114 sub file_contents_internal ($$$%)
7115 {
7116     my ($is_am, $file, $where, %transform) = @_;
7117
7118     $where->set ($file);
7119
7120     my $result_vars = '';
7121     my $result_rules = '';
7122     my $comment = '';
7123     my $spacing = '';
7124
7125     # The following flags are used to track rules spanning across
7126     # multiple paragraphs.
7127     my $is_rule = 0;            # 1 if we are processing a rule.
7128     my $discard_rule = 0;       # 1 if the current rule should not be output.
7129
7130     # We save the conditional stack on entry, and then check to make
7131     # sure it is the same on exit.  This lets us conditionally include
7132     # other files.
7133     my @saved_cond_stack = @cond_stack;
7134     my $cond = new Automake::Condition (@cond_stack);
7135
7136     foreach (make_paragraphs ($file, %transform))
7137     {
7138         # FIXME: no line number available.
7139         $where->set ($file);
7140
7141         # Sanity checks.
7142         error $where, "blank line following trailing backslash:\n$_"
7143           if /\\$/;
7144         error $where, "comment following trailing backslash:\n$_"
7145           if /\\#/;
7146
7147         if (/^$/)
7148         {
7149             $is_rule = 0;
7150             # Stick empty line before the incoming macro or rule.
7151             $spacing = "\n";
7152         }
7153         elsif (/$COMMENT_PATTERN/mso)
7154         {
7155             $is_rule = 0;
7156             # Stick comments before the incoming macro or rule.
7157             $comment = "$_\n";
7158         }
7159
7160         # Handle inclusion of other files.
7161         elsif (/$INCLUDE_PATTERN/o)
7162         {
7163             if ($cond != FALSE)
7164               {
7165                 my $file = ($is_am ? "$libdir/am/" : '') . $1;
7166                 $where->push_context ("'$file' included from here");
7167                 # N-ary '.=' fails.
7168                 my ($com, $vars, $rules)
7169                   = file_contents_internal ($is_am, $file, $where, %transform);
7170                 $where->pop_context;
7171                 $comment .= $com;
7172                 $result_vars .= $vars;
7173                 $result_rules .= $rules;
7174               }
7175         }
7176
7177         # Handling the conditionals.
7178         elsif (/$IF_PATTERN/o)
7179           {
7180             $cond = cond_stack_if ($1, $2, $file);
7181           }
7182         elsif (/$ELSE_PATTERN/o)
7183           {
7184             $cond = cond_stack_else ($1, $2, $file);
7185           }
7186         elsif (/$ENDIF_PATTERN/o)
7187           {
7188             $cond = cond_stack_endif ($1, $2, $file);
7189           }
7190
7191         # Handling rules.
7192         elsif (/$RULE_PATTERN/mso)
7193         {
7194           $is_rule = 1;
7195           $discard_rule = 0;
7196           # Separate relationship from optional actions: the first
7197           # `new-line tab" not preceded by backslash (continuation
7198           # line).
7199           my $paragraph = $_;
7200           /^(.*?)(?:(?<!\\)\n(\t.*))?$/s;
7201           my ($relationship, $actions) = ($1, $2 || '');
7202
7203           # Separate targets from dependencies: the first colon.
7204           $relationship =~ /^([^:]+\S+) *: *(.*)$/som;
7205           my ($targets, $dependencies) = ($1, $2);
7206           # Remove the escaped new lines.
7207           # I don't know why, but I have to use a tmp $flat_deps.
7208           my $flat_deps = &flatten ($dependencies);
7209           my @deps = split (' ', $flat_deps);
7210
7211           foreach (split (' ', $targets))
7212             {
7213               # FIXME: 1. We are not robust to people defining several targets
7214               # at once, only some of them being in %dependencies.  The
7215               # actions from the targets in %dependencies are usually generated
7216               # from the content of %actions, but if some targets in $targets
7217               # are not in %dependencies the ELSE branch will output
7218               # a rule for all $targets (i.e. the targets which are both
7219               # in %dependencies and $targets will have two rules).
7220
7221               # FIXME: 2. The logic here is not able to output a
7222               # multi-paragraph rule several time (e.g. for each condition
7223               # it is defined for) because it only knows the first paragraph.
7224
7225               # FIXME: 3. We are not robust to people defining a subset
7226               # of a previously defined "multiple-target" rule.  E.g.
7227               # 'foo:' after 'foo bar:'.
7228
7229               # Output only if not in FALSE.
7230               if (defined $dependencies{$_} && $cond != FALSE)
7231                 {
7232                   &depend ($_, @deps);
7233                   register_action ($_, $actions);
7234                 }
7235               else
7236                 {
7237                   # Free-lance dependency.  Output the rule for all the
7238                   # targets instead of one by one.
7239                   my @undefined_conds =
7240                     Automake::Rule::define ($targets, $file,
7241                                             $is_am ? RULE_AUTOMAKE : RULE_USER,
7242                                             $cond, $where);
7243                   for my $undefined_cond (@undefined_conds)
7244                     {
7245                       my $condparagraph = $paragraph;
7246                       $condparagraph =~ s/^/$undefined_cond->subst_string/gme;
7247                       $result_rules .= "$spacing$comment$condparagraph\n";
7248                     }
7249                   if (scalar @undefined_conds == 0)
7250                     {
7251                       # Remember to discard next paragraphs
7252                       # if they belong to this rule.
7253                       # (but see also FIXME: #2 above.)
7254                       $discard_rule = 1;
7255                     }
7256                   $comment = $spacing = '';
7257                   last;
7258                 }
7259             }
7260         }
7261
7262         elsif (/$ASSIGNMENT_PATTERN/mso)
7263         {
7264             my ($var, $type, $val) = ($1, $2, $3);
7265             error $where, "variable '$var' with trailing backslash"
7266               if /\\$/;
7267
7268             $is_rule = 0;
7269
7270             Automake::Variable::define ($var,
7271                                         $is_am ? VAR_AUTOMAKE : VAR_MAKEFILE,
7272                                         $type, $cond, $val, $comment, $where,
7273                                         VAR_ASIS)
7274               if $cond != FALSE;
7275
7276             $comment = $spacing = '';
7277         }
7278         else
7279         {
7280             # This isn't an error; it is probably some tokens which
7281             # configure is supposed to replace, such as '@SET-MAKE@',
7282             # or some part of a rule cut by an if/endif.
7283             if (! $cond->false && ! ($is_rule && $discard_rule))
7284               {
7285                 s/^/$cond->subst_string/gme;
7286                 $result_rules .= "$spacing$comment$_\n";
7287               }
7288             $comment = $spacing = '';
7289         }
7290     }
7291
7292     error ($where, @cond_stack ?
7293            "unterminated conditionals: @cond_stack" :
7294            "too many conditionals closed in include file")
7295       if "@saved_cond_stack" ne "@cond_stack";
7296
7297     return ($comment, $result_vars, $result_rules);
7298 }
7299
7300
7301 # $CONTENTS
7302 # &file_contents ($BASENAME, $WHERE, [%TRANSFORM])
7303 # ------------------------------------------------
7304 # Return contents of a file from $libdir/am, automatically skipping
7305 # macros or rules which are already known.
7306 sub file_contents ($$%)
7307 {
7308     my ($basename, $where, %transform) = @_;
7309     my ($comments, $variables, $rules) =
7310       file_contents_internal (1, "$libdir/am/$basename.am", $where,
7311                               %transform);
7312     return "$comments$variables$rules";
7313 }
7314
7315
7316 # @PREFIX
7317 # &am_primary_prefixes ($PRIMARY, $CAN_DIST, @PREFIXES)
7318 # -----------------------------------------------------
7319 # Find all variable prefixes that are used for install directories.  A
7320 # prefix 'zar' qualifies iff:
7321 #
7322 # * 'zardir' is a variable.
7323 # * 'zar_PRIMARY' is a variable.
7324 #
7325 # As a side effect, it looks for misspellings.  It is an error to have
7326 # a variable ending in a "reserved" suffix whose prefix is unknown, e.g.
7327 # "bni_PROGRAMS".  However, unusual prefixes are allowed if a variable
7328 # of the same name (with "dir" appended) exists.  For instance, if the
7329 # variable "zardir" is defined, then "zar_PROGRAMS" becomes valid.
7330 # This is to provide a little extra flexibility in those cases which
7331 # need it.
7332 sub am_primary_prefixes ($$@)
7333 {
7334   my ($primary, $can_dist, @prefixes) = @_;
7335
7336   local $_;
7337   my %valid = map { $_ => 0 } @prefixes;
7338   $valid{'EXTRA'} = 0;
7339   foreach my $var (variables $primary)
7340     {
7341       # Automake is allowed to define variables that look like primaries
7342       # but which aren't.  E.g. INSTALL_sh_DATA.
7343       # Autoconf can also define variables like INSTALL_DATA, so
7344       # ignore all configure variables (at least those which are not
7345       # redefined in Makefile.am).
7346       # FIXME: We should make sure that these variables are not
7347       # conditionally defined (or else adjust the condition below).
7348       my $def = $var->def (TRUE);
7349       next if $def && $def->owner != VAR_MAKEFILE;
7350
7351       my $varname = $var->name;
7352
7353       if ($varname =~ /^(nobase_)?(dist_|nodist_)?(.*)_[[:alnum:]]+$/)
7354         {
7355           my ($base, $dist, $X) = ($1 || '', $2 || '', $3 || '');
7356           if ($dist ne '' && ! $can_dist)
7357             {
7358               err_var ($var,
7359                        "invalid variable '$varname': 'dist' is forbidden");
7360             }
7361           # Standard directories must be explicitly allowed.
7362           elsif (! defined $valid{$X} && exists $standard_prefix{$X})
7363             {
7364               err_var ($var,
7365                        "'${X}dir' is not a legitimate directory " .
7366                        "for '$primary'");
7367             }
7368           # A not explicitly valid directory is allowed if Xdir is defined.
7369           elsif (! defined $valid{$X} &&
7370                  $var->requires_variables ("'$varname' is used", "${X}dir"))
7371             {
7372               # Nothing to do.  Any error message has been output
7373               # by $var->requires_variables.
7374             }
7375           else
7376             {
7377               # Ensure all extended prefixes are actually used.
7378               $valid{"$base$dist$X"} = 1;
7379             }
7380         }
7381       else
7382         {
7383           prog_error "unexpected variable name: $varname";
7384         }
7385     }
7386
7387   # Return only those which are actually defined.
7388   return sort grep { var ($_ . '_' . $primary) } keys %valid;
7389 }
7390
7391
7392 # Handle 'where_HOW' variable magic.  Does all lookups, generates
7393 # install code, and possibly generates code to define the primary
7394 # variable.  The first argument is the name of the .am file to munge,
7395 # the second argument is the primary variable (e.g. HEADERS), and all
7396 # subsequent arguments are possible installation locations.
7397 #
7398 # Returns list of [$location, $value] pairs, where
7399 # $value's are the values in all where_HOW variable, and $location
7400 # there associated location (the place here their parent variables were
7401 # defined).
7402 #
7403 # FIXME: this should be rewritten to be cleaner.  It should be broken
7404 # up into multiple functions.
7405 #
7406 # Usage is: am_install_var (OPTION..., file, HOW, where...)
7407 sub am_install_var
7408 {
7409   my (@args) = @_;
7410
7411   my $do_require = 1;
7412   my $can_dist = 0;
7413   my $default_dist = 0;
7414   while (@args)
7415     {
7416       if ($args[0] eq '-noextra')
7417         {
7418           $do_require = 0;
7419         }
7420       elsif ($args[0] eq '-candist')
7421         {
7422           $can_dist = 1;
7423         }
7424       elsif ($args[0] eq '-defaultdist')
7425         {
7426           $default_dist = 1;
7427           $can_dist = 1;
7428         }
7429       elsif ($args[0] !~ /^-/)
7430         {
7431           last;
7432         }
7433       shift (@args);
7434     }
7435
7436   my ($file, $primary, @prefix) = @args;
7437
7438   # Now that configure substitutions are allowed in where_HOW
7439   # variables, it is an error to actually define the primary.  We
7440   # allow 'JAVA', as it is customarily used to mean the Java
7441   # interpreter.  This is but one of several Java hacks.  Similarly,
7442   # 'PYTHON' is customarily used to mean the Python interpreter.
7443   reject_var $primary, "'$primary' is an anachronism"
7444     unless $primary eq 'JAVA' || $primary eq 'PYTHON';
7445
7446   # Get the prefixes which are valid and actually used.
7447   @prefix = am_primary_prefixes ($primary, $can_dist, @prefix);
7448
7449   # If a primary includes a configure substitution, then the EXTRA_
7450   # form is required.  Otherwise we can't properly do our job.
7451   my $require_extra;
7452
7453   my @used = ();
7454   my @result = ();
7455
7456   foreach my $X (@prefix)
7457     {
7458       my $nodir_name = $X;
7459       my $one_name = $X . '_' . $primary;
7460       my $one_var = var $one_name;
7461
7462       my $strip_subdir = 1;
7463       # If subdir prefix should be preserved, do so.
7464       if ($nodir_name =~ /^nobase_/)
7465         {
7466           $strip_subdir = 0;
7467           $nodir_name =~ s/^nobase_//;
7468         }
7469
7470       # If files should be distributed, do so.
7471       my $dist_p = 0;
7472       if ($can_dist)
7473         {
7474           $dist_p = (($default_dist && $nodir_name !~ /^nodist_/)
7475                      || (! $default_dist && $nodir_name =~ /^dist_/));
7476           $nodir_name =~ s/^(dist|nodist)_//;
7477         }
7478
7479
7480       # Use the location of the currently processed variable.
7481       # We are not processing a particular condition, so pick the first
7482       # available.
7483       my $tmpcond = $one_var->conditions->one_cond;
7484       my $where = $one_var->rdef ($tmpcond)->location->clone;
7485
7486       # Append actual contents of where_PRIMARY variable to
7487       # @result, skipping @substitutions@.
7488       foreach my $locvals ($one_var->value_as_list_recursive (location => 1))
7489         {
7490           my ($loc, $value) = @$locvals;
7491           # Skip configure substitutions.
7492           if ($value =~ /^\@.*\@$/)
7493             {
7494               if ($nodir_name eq 'EXTRA')
7495                 {
7496                   error ($where,
7497                          "'$one_name' contains configure substitution, "
7498                          . "but shouldn't");
7499                 }
7500               # Check here to make sure variables defined in
7501               # configure.ac do not imply that EXTRA_PRIMARY
7502               # must be defined.
7503               elsif (! defined $configure_vars{$one_name})
7504                 {
7505                   $require_extra = $one_name
7506                     if $do_require;
7507                 }
7508             }
7509           else
7510             {
7511               # Strip any $(EXEEXT) suffix the user might have added, or this
7512               # will confuse &handle_source_transform and &check_canonical_spelling.
7513               # We'll add $(EXEEXT) back later anyway.
7514               # Do it here rather than in handle_programs so the uniquifying at the
7515               # end of this function works.
7516               ${$locvals}[1] =~ s/\$\(EXEEXT\)$//
7517                 if $primary eq 'PROGRAMS';
7518
7519               push (@result, $locvals);
7520             }
7521         }
7522       # A blatant hack: we rewrite each _PROGRAMS primary to include
7523       # EXEEXT.
7524       append_exeext { 1 } $one_name
7525         if $primary eq 'PROGRAMS';
7526       # "EXTRA" shouldn't be used when generating clean targets,
7527       # all, or install targets.  We used to warn if EXTRA_FOO was
7528       # defined uselessly, but this was annoying.
7529       next
7530         if $nodir_name eq 'EXTRA';
7531
7532       if ($nodir_name eq 'check')
7533         {
7534           push (@check, '$(' . $one_name . ')');
7535         }
7536       else
7537         {
7538           push (@used, '$(' . $one_name . ')');
7539         }
7540
7541       # Is this to be installed?
7542       my $install_p = $nodir_name ne 'noinst' && $nodir_name ne 'check';
7543
7544       # If so, with install-exec? (or install-data?).
7545       my $exec_p = ($nodir_name =~ /$EXEC_DIR_PATTERN/o);
7546
7547       my $check_options_p = $install_p && !! option 'std-options';
7548
7549       # Use the location of the currently processed variable as context.
7550       $where->push_context ("while processing '$one_name'");
7551
7552       # The variable containing all files to distribute.
7553       my $distvar = "\$($one_name)";
7554       $distvar = shadow_unconditionally ($one_name, $where)
7555         if ($dist_p && $one_var->has_conditional_contents);
7556
7557       # Singular form of $PRIMARY.
7558       (my $one_primary = $primary) =~ s/S$//;
7559       $output_rules .= &file_contents ($file, $where,
7560                                        PRIMARY     => $primary,
7561                                        ONE_PRIMARY => $one_primary,
7562                                        DIR         => $X,
7563                                        NDIR        => $nodir_name,
7564                                        BASE        => $strip_subdir,
7565
7566                                        EXEC      => $exec_p,
7567                                        INSTALL   => $install_p,
7568                                        DIST      => $dist_p,
7569                                        DISTVAR   => $distvar,
7570                                        'CK-OPTS' => $check_options_p);
7571     }
7572
7573   # The JAVA variable is used as the name of the Java interpreter.
7574   # The PYTHON variable is used as the name of the Python interpreter.
7575   if (@used && $primary ne 'JAVA' && $primary ne 'PYTHON')
7576     {
7577       # Define it.
7578       define_pretty_variable ($primary, TRUE, INTERNAL, @used);
7579       $output_vars .= "\n";
7580     }
7581
7582   err_var ($require_extra,
7583            "'$require_extra' contains configure substitution,\n"
7584            . "but 'EXTRA_$primary' not defined")
7585     if ($require_extra && ! var ('EXTRA_' . $primary));
7586
7587   # Push here because PRIMARY might be configure time determined.
7588   push (@all, '$(' . $primary . ')')
7589     if @used && $primary ne 'JAVA' && $primary ne 'PYTHON';
7590
7591   # Make the result unique.  This lets the user use conditionals in
7592   # a natural way, but still lets us program lazily -- we don't have
7593   # to worry about handling a particular object more than once.
7594   # We will keep only one location per object.
7595   my %result = ();
7596   for my $pair (@result)
7597     {
7598       my ($loc, $val) = @$pair;
7599       $result{$val} = $loc;
7600     }
7601   my @l = sort keys %result;
7602   return map { [$result{$_}->clone, $_] } @l;
7603 }
7604
7605
7606 ################################################################
7607
7608 # Each key in this hash is the name of a directory holding a
7609 # Makefile.in.  These variables are local to 'is_make_dir'.
7610 my %make_dirs = ();
7611 my $make_dirs_set = 0;
7612
7613 sub is_make_dir
7614 {
7615     my ($dir) = @_;
7616     if (! $make_dirs_set)
7617     {
7618         foreach my $iter (@configure_input_files)
7619         {
7620             $make_dirs{dirname ($iter)} = 1;
7621         }
7622         # We also want to notice Makefile.in's.
7623         foreach my $iter (@other_input_files)
7624         {
7625             if ($iter =~ /Makefile\.in$/)
7626             {
7627                 $make_dirs{dirname ($iter)} = 1;
7628             }
7629         }
7630         $make_dirs_set = 1;
7631     }
7632     return defined $make_dirs{$dir};
7633 }
7634
7635 ################################################################
7636
7637 # Find the aux dir.  This should match the algorithm used by
7638 # ./configure. (See the Autoconf documentation for for
7639 # AC_CONFIG_AUX_DIR.)
7640 sub locate_aux_dir ()
7641 {
7642   if (! $config_aux_dir_set_in_configure_ac)
7643     {
7644       # The default auxiliary directory is the first
7645       # of ., .., or ../.. that contains install-sh.
7646       # Assume . if install-sh doesn't exist yet.
7647       for my $dir (qw (. .. ../..))
7648         {
7649           if (-f "$dir/install-sh")
7650             {
7651               $config_aux_dir = $dir;
7652               last;
7653             }
7654         }
7655       $config_aux_dir = '.' unless $config_aux_dir;
7656     }
7657   # Avoid unsightly '/.'s.
7658   $am_config_aux_dir =
7659     '$(top_srcdir)' . ($config_aux_dir eq '.' ? "" : "/$config_aux_dir");
7660   $am_config_aux_dir =~ s,/*$,,;
7661 }
7662
7663
7664 # &push_required_file ($DIR, $FILE, $FULLFILE)
7665 # --------------------------------------------------
7666 # Push the given file onto DIST_COMMON.
7667 sub push_required_file
7668 {
7669   my ($dir, $file, $fullfile) = @_;
7670
7671   # If the file to be distributed is in the same directory of the
7672   # currently processed Makefile.am, then we want to distribute it
7673   # from this same Makefile.am.
7674   if ($dir eq $relative_dir)
7675     {
7676       push_dist_common ($file);
7677     }
7678   # This is needed to allow a construct in a non-top-level Makefile.am
7679   # to require a file in the build-aux directory (see at least the test
7680   # script 'test-driver-is-distributed.test').  This is related to the
7681   # automake bug#9546.  Note that the use of $config_aux_dir instead
7682   # of $am_config_aux_dir here is deliberate and necessary.
7683   elsif ($dir eq $config_aux_dir)
7684     {
7685       push_dist_common ("$am_config_aux_dir/$file");
7686     }
7687   # FIXME: another spacial case, for AC_LIBOBJ/AC_LIBSOURCE support.
7688   # We probably need some refactoring of this function and its callers,
7689   # to have a more explicit and systematic handling of all the special
7690   # cases; but, since there are only two of them, this is low-priority
7691   # ATM.
7692   elsif ($config_libobj_dir && $dir eq $config_libobj_dir)
7693     {
7694       # Avoid unsightly '/.'s.
7695       my $am_config_libobj_dir =
7696         '$(top_srcdir)' .
7697         ($config_libobj_dir eq '.' ? "" : "/$config_libobj_dir");
7698       $am_config_libobj_dir =~ s|/*$||;
7699       push_dist_common ("$am_config_libobj_dir/$file");
7700     }
7701   elsif ($relative_dir eq '.' && ! &is_make_dir ($dir))
7702     {
7703       # If we are doing the topmost directory, and the file is in a
7704       # subdir which does not have a Makefile, then we distribute it
7705       # here.
7706
7707       # If a required file is above the source tree, it is important
7708       # to prefix it with '$(srcdir)' so that no VPATH search is
7709       # performed.  Otherwise problems occur with Make implementations
7710       # that rewrite and simplify rules whose dependencies are found in a
7711       # VPATH location.  Here is an example with OSF1/Tru64 Make.
7712       #
7713       #   % cat Makefile
7714       #   VPATH = sub
7715       #   distdir: ../a
7716       #           echo ../a
7717       #   % ls
7718       #   Makefile a
7719       #   % make
7720       #   echo a
7721       #   a
7722       #
7723       # Dependency '../a' was found in 'sub/../a', but this make
7724       # implementation simplified it as 'a'.  (Note that the sub/
7725       # directory does not even exist.)
7726       #
7727       # This kind of VPATH rewriting seems hard to cancel.  The
7728       # distdir.am hack against VPATH rewriting works only when no
7729       # simplification is done, i.e., for dependencies which are in
7730       # subdirectories, not in enclosing directories.  Hence, in
7731       # the latter case we use a full path to make sure no VPATH
7732       # search occurs.
7733       $fullfile = '$(srcdir)/' . $fullfile
7734         if $dir =~ m,^\.\.(?:$|/),;
7735
7736       push_dist_common ($fullfile);
7737     }
7738   else
7739     {
7740       prog_error "a Makefile in relative directory $relative_dir " .
7741                  "can't add files in directory $dir to DIST_COMMON";
7742     }
7743 }
7744
7745
7746 # If a file name appears as a key in this hash, then it has already
7747 # been checked for.  This allows us not to report the same error more
7748 # than once.
7749 my %required_file_not_found = ();
7750
7751 # &required_file_check_or_copy ($WHERE, $DIRECTORY, $FILE)
7752 # --------------------------------------------------------
7753 # Verify that the file must exist in $DIRECTORY, or install it.
7754 sub required_file_check_or_copy ($$$)
7755 {
7756   my ($where, $dir, $file) = @_;
7757
7758   my $fullfile = "$dir/$file";
7759   my $found_it = 0;
7760   my $dangling_sym = 0;
7761
7762   if (-l $fullfile && ! -f $fullfile)
7763     {
7764       $dangling_sym = 1;
7765     }
7766   elsif (dir_has_case_matching_file ($dir, $file))
7767     {
7768       $found_it = 1;
7769     }
7770
7771   # '--force-missing' only has an effect if '--add-missing' is
7772   # specified.
7773   return
7774     if $found_it && (! $add_missing || ! $force_missing);
7775
7776   # If we've already looked for it, we're done.  You might
7777   # wonder why we don't do this before searching for the
7778   # file.  If we do that, then something like
7779   # AC_OUTPUT(subdir/foo foo) will fail to put foo.in into
7780   # DIST_COMMON.
7781   if (! $found_it)
7782     {
7783       return if defined $required_file_not_found{$fullfile};
7784       $required_file_not_found{$fullfile} = 1;
7785     }
7786   if ($dangling_sym && $add_missing)
7787     {
7788       unlink ($fullfile);
7789     }
7790
7791   my $trailer = '';
7792   my $trailer2 = '';
7793   my $suppress = 0;
7794
7795   # Only install missing files according to our desired
7796   # strictness level.
7797   my $message = "required file '$fullfile' not found";
7798   if ($add_missing)
7799     {
7800       if (-f "$libdir/$file")
7801         {
7802           $suppress = 1;
7803
7804           # Install the missing file.  Symlink if we
7805           # can, copy if we must.  Note: delete the file
7806           # first, in case it is a dangling symlink.
7807           $message = "installing '$fullfile'";
7808
7809           # The license file should not be volatile.
7810           if ($file eq "COPYING")
7811             {
7812               $message .= " using GNU General Public License v3 file";
7813               $trailer2 = "\n    Consider adding the COPYING file"
7814                         . " to the version control system"
7815                         . "\n    for your code, to avoid questions"
7816                         . " about which license your project uses";
7817             }
7818
7819           # Windows Perl will hang if we try to delete a
7820           # file that doesn't exist.
7821           unlink ($fullfile) if -f $fullfile;
7822           if ($symlink_exists && ! $copy_missing)
7823             {
7824               if (! symlink ("$libdir/$file", $fullfile)
7825                   || ! -e $fullfile)
7826                 {
7827                   $suppress = 0;
7828                   $trailer = "; error while making link: $!";
7829                 }
7830             }
7831           elsif (system ('cp', "$libdir/$file", $fullfile))
7832             {
7833               $suppress = 0;
7834               $trailer = "\n    error while copying";
7835             }
7836           set_dir_cache_file ($dir, $file);
7837         }
7838     }
7839   else
7840     {
7841       $trailer = "\n  'automake --add-missing' can install '$file'"
7842         if -f "$libdir/$file";
7843     }
7844
7845   # If --force-missing was specified, and we have
7846   # actually found the file, then do nothing.
7847   return
7848     if $found_it && $force_missing;
7849
7850   # If we couldn't install the file, but it is a target in
7851   # the Makefile, don't print anything.  This allows files
7852   # like README, AUTHORS, or THANKS to be generated.
7853   return
7854     if !$suppress && rule $file;
7855
7856   msg ($suppress ? 'note' : 'error', $where, "$message$trailer$trailer2");
7857 }
7858
7859
7860 # &require_file_internal ($WHERE, $MYSTRICT, $DIRECTORY, $QUEUE, @FILES)
7861 # ----------------------------------------------------------------------
7862 # Verify that the file must exist in $DIRECTORY, or install it.
7863 # $MYSTRICT is the strictness level at which this file becomes required.
7864 # Worker threads may queue up the action to be serialized by the master,
7865 # if $QUEUE is true
7866 sub require_file_internal ($$$@)
7867 {
7868   my ($where, $mystrict, $dir, $queue, @files) = @_;
7869
7870   return
7871     unless $strictness >= $mystrict;
7872
7873   foreach my $file (@files)
7874     {
7875       push_required_file ($dir, $file, "$dir/$file");
7876       if ($queue)
7877         {
7878           queue_required_file_check_or_copy ($required_conf_file_queue,
7879                                              QUEUE_CONF_FILE, $relative_dir,
7880                                              $where, $mystrict, @files);
7881         }
7882       else
7883         {
7884           required_file_check_or_copy ($where, $dir, $file);
7885         }
7886     }
7887 }
7888
7889 # &require_file ($WHERE, $MYSTRICT, @FILES)
7890 # -----------------------------------------
7891 sub require_file ($$@)
7892 {
7893     my ($where, $mystrict, @files) = @_;
7894     require_file_internal ($where, $mystrict, $relative_dir, 0, @files);
7895 }
7896
7897 # &require_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7898 # -----------------------------------------------------------
7899 sub require_file_with_macro ($$$@)
7900 {
7901     my ($cond, $macro, $mystrict, @files) = @_;
7902     $macro = rvar ($macro) unless ref $macro;
7903     require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7904 }
7905
7906 # &require_libsource_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7907 # ----------------------------------------------------------------
7908 # Require an AC_LIBSOURCEd file.  If AC_CONFIG_LIBOBJ_DIR was called, it
7909 # must be in that directory.  Otherwise expect it in the current directory.
7910 sub require_libsource_with_macro ($$$@)
7911 {
7912     my ($cond, $macro, $mystrict, @files) = @_;
7913     $macro = rvar ($macro) unless ref $macro;
7914     if ($config_libobj_dir)
7915       {
7916         require_file_internal ($macro->rdef ($cond)->location, $mystrict,
7917                                $config_libobj_dir, 0, @files);
7918       }
7919     else
7920       {
7921         require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7922       }
7923 }
7924
7925 # &queue_required_file_check_or_copy ($QUEUE, $KEY, $DIR, $WHERE,
7926 #                                     $MYSTRICT, @FILES)
7927 # ---------------------------------------------------------------
7928 sub queue_required_file_check_or_copy ($$$$@)
7929 {
7930     my ($queue, $key, $dir, $where, $mystrict, @files) = @_;
7931     my @serial_loc;
7932     if (ref $where)
7933       {
7934         @serial_loc = (QUEUE_LOCATION, $where->serialize ());
7935       }
7936     else
7937       {
7938         @serial_loc = (QUEUE_STRING, $where);
7939       }
7940     $queue->enqueue ($key, $dir, @serial_loc, $mystrict, 0 + @files, @files);
7941 }
7942
7943 # &require_queued_file_check_or_copy ($QUEUE)
7944 # -------------------------------------------
7945 sub require_queued_file_check_or_copy ($)
7946 {
7947     my ($queue) = @_;
7948     my $where;
7949     my $dir = $queue->dequeue ();
7950     my $loc_key = $queue->dequeue ();
7951     if ($loc_key eq QUEUE_LOCATION)
7952       {
7953         $where = Automake::Location::deserialize ($queue);
7954       }
7955     elsif ($loc_key eq QUEUE_STRING)
7956       {
7957         $where = $queue->dequeue ();
7958       }
7959     else
7960       {
7961         prog_error "unexpected key $loc_key";
7962       }
7963     my $mystrict = $queue->dequeue ();
7964     my $nfiles = $queue->dequeue ();
7965     my @files;
7966     push @files, $queue->dequeue ()
7967       foreach (1 .. $nfiles);
7968     return
7969       unless $strictness >= $mystrict;
7970     foreach my $file (@files)
7971       {
7972         required_file_check_or_copy ($where, $config_aux_dir, $file);
7973       }
7974 }
7975
7976 # &require_conf_file ($WHERE, $MYSTRICT, @FILES)
7977 # ----------------------------------------------
7978 # Looks in configuration path, as specified by AC_CONFIG_AUX_DIR.
7979 sub require_conf_file ($$@)
7980 {
7981     my ($where, $mystrict, @files) = @_;
7982     my $queue = defined $required_conf_file_queue ? 1 : 0;
7983     require_file_internal ($where, $mystrict, $config_aux_dir,
7984                            $queue, @files);
7985 }
7986
7987
7988 # &require_conf_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7989 # ----------------------------------------------------------------
7990 sub require_conf_file_with_macro ($$$@)
7991 {
7992     my ($cond, $macro, $mystrict, @files) = @_;
7993     require_conf_file (rvar ($macro)->rdef ($cond)->location,
7994                        $mystrict, @files);
7995 }
7996
7997 ################################################################
7998
7999 # &require_build_directory ($DIRECTORY)
8000 # -------------------------------------
8001 # Emit rules to create $DIRECTORY if needed, and return
8002 # the file that any target requiring this directory should be made
8003 # dependent upon.
8004 # We don't want to emit the rule twice, and want to reuse it
8005 # for directories with equivalent names (e.g., 'foo/bar' and './foo//bar').
8006 sub require_build_directory ($)
8007 {
8008   my $directory = shift;
8009
8010   return $directory_map{$directory} if exists $directory_map{$directory};
8011
8012   my $cdir = File::Spec->canonpath ($directory);
8013
8014   if (exists $directory_map{$cdir})
8015     {
8016       my $stamp = $directory_map{$cdir};
8017       $directory_map{$directory} = $stamp;
8018       return $stamp;
8019     }
8020
8021   my $dirstamp = "$cdir/\$(am__dirstamp)";
8022
8023   $directory_map{$directory} = $dirstamp;
8024   $directory_map{$cdir} = $dirstamp;
8025
8026   # Set a variable for the dirstamp basename.
8027   define_pretty_variable ('am__dirstamp', TRUE, INTERNAL,
8028                           '$(am__leading_dot)dirstamp');
8029
8030   # Directory must be removed by 'make distclean'.
8031   $clean_files{$dirstamp} = DIST_CLEAN;
8032
8033   $output_rules .= ("$dirstamp:\n"
8034                     . "\t\@\$(MKDIR_P) $directory\n"
8035                     . "\t\@: > $dirstamp\n");
8036
8037   return $dirstamp;
8038 }
8039
8040 # &require_build_directory_maybe ($FILE)
8041 # --------------------------------------
8042 # If $FILE lies in a subdirectory, emit a rule to create this
8043 # directory and return the file that $FILE should be made
8044 # dependent upon.  Otherwise, just return the empty string.
8045 sub require_build_directory_maybe ($)
8046 {
8047     my $file = shift;
8048     my $directory = dirname ($file);
8049
8050     if ($directory ne '.')
8051     {
8052         return require_build_directory ($directory);
8053     }
8054     else
8055     {
8056         return '';
8057     }
8058 }
8059
8060 ################################################################
8061
8062 # Push a list of files onto dist_common.
8063 sub push_dist_common
8064 {
8065   prog_error "push_dist_common run after handle_dist"
8066     if $handle_dist_run;
8067   Automake::Variable::define ('DIST_COMMON', VAR_AUTOMAKE, '+', TRUE, "@_",
8068                               '', INTERNAL, VAR_PRETTY);
8069 }
8070
8071
8072 ################################################################
8073
8074 # generate_makefile ($MAKEFILE_AM, $MAKEFILE_IN)
8075 # ----------------------------------------------
8076 # Generate a Makefile.in given the name of the corresponding Makefile and
8077 # the name of the file output by config.status.
8078 sub generate_makefile ($$)
8079 {
8080   my ($makefile_am, $makefile_in) = @_;
8081
8082   # Reset all the Makefile.am related variables.
8083   initialize_per_input;
8084
8085   # AUTOMAKE_OPTIONS can contains -W flags to disable or enable
8086   # warnings for this file.  So hold any warning issued before
8087   # we have processed AUTOMAKE_OPTIONS.
8088   buffer_messages ('warning');
8089
8090   # Name of input file ("Makefile.am") and output file
8091   # ("Makefile.in").  These have no directory components.
8092   $am_file_name = basename ($makefile_am);
8093   $in_file_name = basename ($makefile_in);
8094
8095   # $OUTPUT is encoded.  If it contains a ":" then the first element
8096   # is the real output file, and all remaining elements are input
8097   # files.  We don't scan or otherwise deal with these input files,
8098   # other than to mark them as dependencies.  See
8099   # &scan_autoconf_files for details.
8100   my ($makefile, @inputs) = split (/:/, $output_files{$makefile_in});
8101
8102   $relative_dir = dirname ($makefile);
8103   $am_relative_dir = dirname ($makefile_am);
8104   $topsrcdir = backname ($relative_dir);
8105
8106   read_main_am_file ($makefile_am);
8107   if (handle_options)
8108     {
8109       # Process buffered warnings.
8110       flush_messages;
8111       # Fatal error.  Just return, so we can continue with next file.
8112       return;
8113     }
8114   # Process buffered warnings.
8115   flush_messages;
8116
8117   # There are a few install-related variables that you should not define.
8118   foreach my $var ('PRE_INSTALL', 'POST_INSTALL', 'NORMAL_INSTALL')
8119     {
8120       my $v = var $var;
8121       if ($v)
8122         {
8123           my $def = $v->def (TRUE);
8124           prog_error "$var not defined in condition TRUE"
8125             unless $def;
8126           reject_var $var, "'$var' should not be defined"
8127             if $def->owner != VAR_AUTOMAKE;
8128         }
8129     }
8130
8131   # Catch some obsolete variables.
8132   msg_var ('obsolete', 'INCLUDES',
8133            "'INCLUDES' is the old name for 'AM_CPPFLAGS' (or '*_CPPFLAGS')")
8134     if var ('INCLUDES');
8135
8136   # Must do this after reading .am file.
8137   define_variable ('subdir', $relative_dir, INTERNAL);
8138
8139   # If DIST_SUBDIRS is defined, make sure SUBDIRS is, so that
8140   # recursive rules are enabled.
8141   define_pretty_variable ('SUBDIRS', TRUE, INTERNAL, '')
8142     if var 'DIST_SUBDIRS' && ! var 'SUBDIRS';
8143
8144   # Check first, because we might modify some state.
8145   check_cygnus;
8146   check_gnu_standards;
8147   check_gnits_standards;
8148
8149   handle_configure ($makefile_am, $makefile_in, $makefile, @inputs);
8150   handle_gettext;
8151   handle_libraries;
8152   handle_ltlibraries;
8153   handle_programs;
8154   handle_scripts;
8155
8156   # These must be run after all the sources are scanned.  They
8157   # use variables defined by &handle_libraries, &handle_ltlibraries,
8158   # or &handle_programs.
8159   handle_compile;
8160   handle_languages;
8161   handle_libtool;
8162
8163   # Variables used by distdir.am and tags.am.
8164   define_pretty_variable ('SOURCES', TRUE, INTERNAL, @sources);
8165   if (! option 'no-dist')
8166     {
8167       define_pretty_variable ('DIST_SOURCES', TRUE, INTERNAL, @dist_sources);
8168     }
8169
8170   handle_texinfo;
8171   handle_emacs_lisp;
8172   handle_python;
8173   handle_java;
8174   handle_man_pages;
8175   handle_data;
8176   handle_headers;
8177   handle_subdirs;
8178   handle_tags;
8179   handle_minor_options;
8180   # Must come after handle_programs so that %known_programs is up-to-date.
8181   handle_tests;
8182
8183   # This must come after most other rules.
8184   handle_dist;
8185
8186   handle_footer;
8187   do_check_merge_target;
8188   handle_all ($makefile);
8189
8190   # FIXME: Gross!
8191   if (var ('lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
8192     {
8193       $output_rules .= "install-binPROGRAMS: install-libLTLIBRARIES\n\n";
8194     }
8195   if (var ('nobase_lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
8196     {
8197       $output_rules .= "install-binPROGRAMS: install-nobase_libLTLIBRARIES\n\n";
8198     }
8199
8200   handle_install;
8201   handle_clean ($makefile);
8202   handle_factored_dependencies;
8203
8204   # Comes last, because all the above procedures may have
8205   # defined or overridden variables.
8206   $output_vars .= output_variables;
8207
8208   check_typos;
8209
8210   if ($exit_code != 0)
8211     {
8212       verb "not writing $makefile_in because of earlier errors";
8213       return;
8214     }
8215
8216   mkdir ($am_relative_dir, 0755) if ! -d $am_relative_dir;
8217
8218   # We make sure that 'all:' is the first target.
8219   my $output =
8220     "$output_vars$output_all$output_header$output_rules$output_trailer";
8221
8222   # Decide whether we must update the output file or not.
8223   # We have to update in the following situations.
8224   #  * $force_generation is set.
8225   #  * any of the output dependencies is younger than the output
8226   #  * the contents of the output is different (this can happen
8227   #    if the project has been populated with a file listed in
8228   #    @common_files since the last run).
8229   # Output's dependencies are split in two sets:
8230   #  * dependencies which are also configure dependencies
8231   #    These do not change between each Makefile.am
8232   #  * other dependencies, specific to the Makefile.am being processed
8233   #    (such as the Makefile.am itself, or any Makefile fragment
8234   #    it includes).
8235   my $timestamp = mtime $makefile_in;
8236   if (! $force_generation
8237       && $configure_deps_greatest_timestamp < $timestamp
8238       && $output_deps_greatest_timestamp < $timestamp
8239       && $output eq contents ($makefile_in))
8240     {
8241       verb "$makefile_in unchanged";
8242       # No need to update.
8243       return;
8244     }
8245
8246   if (-e $makefile_in)
8247     {
8248       unlink ($makefile_in)
8249         or fatal "cannot remove $makefile_in: $!";
8250     }
8251
8252   my $gm_file = new Automake::XFile "> $makefile_in";
8253   verb "creating $makefile_in";
8254   print $gm_file $output;
8255 }
8256
8257 ################################################################
8258
8259
8260
8261
8262 ################################################################
8263
8264 # Helper function for usage().
8265 sub print_autodist_files (@)
8266 {
8267   my @lcomm = sort (&uniq (@_));
8268
8269   my @four;
8270   format USAGE_FORMAT =
8271   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<
8272   $four[0],           $four[1],           $four[2],           $four[3]
8273 .
8274   local $~ = "USAGE_FORMAT";
8275
8276   my $cols = 4;
8277   my $rows = int(@lcomm / $cols);
8278   my $rest = @lcomm % $cols;
8279
8280   if ($rest)
8281     {
8282       $rows++;
8283     }
8284   else
8285     {
8286       $rest = $cols;
8287     }
8288
8289   for (my $y = 0; $y < $rows; $y++)
8290     {
8291       @four = ("", "", "", "");
8292       for (my $x = 0; $x < $cols; $x++)
8293         {
8294           last if $y + 1 == $rows && $x == $rest;
8295
8296           my $idx = (($x > $rest)
8297                ?  ($rows * $rest + ($rows - 1) * ($x - $rest))
8298                : ($rows * $x));
8299
8300           $idx += $y;
8301           $four[$x] = $lcomm[$idx];
8302         }
8303       write;
8304     }
8305 }
8306
8307
8308 # Print usage information.
8309 sub usage ()
8310 {
8311     print "Usage: $0 [OPTION]... [Makefile]...
8312
8313 Generate Makefile.in for configure from Makefile.am.
8314
8315 Operation modes:
8316       --help               print this help, then exit
8317       --version            print version number, then exit
8318   -v, --verbose            verbosely list files processed
8319       --no-force           only update Makefile.in's that are out of date
8320   -W, --warnings=CATEGORY  report the warnings falling in CATEGORY
8321
8322 Dependency tracking:
8323   -i, --ignore-deps      disable dependency tracking code
8324       --include-deps     enable dependency tracking code
8325
8326 Flavors:
8327       --cygnus           assume program is part of Cygnus-style tree
8328       --foreign          set strictness to foreign
8329       --gnits            set strictness to gnits
8330       --gnu              set strictness to gnu
8331
8332 Library files:
8333   -a, --add-missing      add missing standard files to package
8334       --libdir=DIR       set directory storing library files
8335       --print-libdir     print directory storing library files
8336   -c, --copy             with -a, copy missing files (default is symlink)
8337   -f, --force-missing    force update of standard files
8338
8339 ";
8340     Automake::ChannelDefs::usage;
8341
8342     print "\nFiles automatically distributed if found " .
8343           "(always):\n";
8344     print_autodist_files @common_files;
8345     print "\nFiles automatically distributed if found " .
8346           "(under certain conditions):\n";
8347     print_autodist_files @common_sometimes;
8348
8349     print '
8350 Report bugs to <@PACKAGE_BUGREPORT@>.
8351 GNU Automake home page: <@PACKAGE_URL@>.
8352 General help using GNU software: <http://www.gnu.org/gethelp/>.
8353 ';
8354
8355     # --help always returns 0 per GNU standards.
8356     exit 0;
8357 }
8358
8359
8360 # &version ()
8361 # -----------
8362 # Print version information
8363 sub version ()
8364 {
8365   print <<EOF;
8366 automake (GNU $PACKAGE) $VERSION
8367 Copyright (C) $RELEASE_YEAR Free Software Foundation, Inc.
8368 License GPLv2+: GNU GPL version 2 or later <http://gnu.org/licenses/gpl-2.0.html>
8369 This is free software: you are free to change and redistribute it.
8370 There is NO WARRANTY, to the extent permitted by law.
8371
8372 Written by Tom Tromey <tromey\@redhat.com>
8373        and Alexandre Duret-Lutz <adl\@gnu.org>.
8374 EOF
8375   # --version always returns 0 per GNU standards.
8376   exit 0;
8377 }
8378
8379 ################################################################
8380
8381 # Parse command line.
8382 sub parse_arguments ()
8383 {
8384   my $strict = 'gnu';
8385   my $cygnus = 0;
8386   my $ignore_deps = 0;
8387   my @warnings = ();
8388
8389   my %cli_options =
8390     (
8391      'version' => \&version,
8392      'help'    => \&usage,
8393      'libdir=s' => \$libdir,
8394      'print-libdir'     => sub { print "$libdir\n"; exit 0; },
8395      'gnu'              => sub { $strict = 'gnu'; },
8396      'gnits'            => sub { $strict = 'gnits'; },
8397      'foreign'          => sub { $strict = 'foreign'; },
8398      'cygnus'           => \$cygnus,
8399      'include-deps'     => sub { $ignore_deps = 0; },
8400      'i|ignore-deps'    => sub { $ignore_deps = 1; },
8401      'no-force' => sub { $force_generation = 0; },
8402      'f|force-missing'  => \$force_missing,
8403      'a|add-missing'    => \$add_missing,
8404      'c|copy'           => \$copy_missing,
8405      'v|verbose'        => sub { setup_channel 'verb', silent => 0; },
8406      'W|warnings=s'     => \@warnings,
8407      );
8408
8409   use Automake::Getopt ();
8410   Automake::Getopt::parse_options %cli_options;
8411
8412   set_strictness ($strict);
8413   my $cli_where = new Automake::Location;
8414   set_global_option ('cygnus', $cli_where) if $cygnus;
8415   set_global_option ('no-dependencies', $cli_where) if $ignore_deps;
8416   for my $warning (@warnings)
8417     {
8418       &parse_warnings ('-W', $warning);
8419     }
8420
8421   return unless @ARGV;
8422
8423   my $errspec = 0;
8424   foreach my $arg (@ARGV)
8425     {
8426       fatal ("empty argument\nTry '$0 --help' for more information")
8427         if ($arg eq '');
8428
8429       # Handle $local:$input syntax.
8430       my ($local, @rest) = split (/:/, $arg);
8431       @rest = ("$local.in",) unless @rest;
8432       my $input = locate_am @rest;
8433       if ($input)
8434         {
8435           push @input_files, $input;
8436           $output_files{$input} = join (':', ($local, @rest));
8437         }
8438       else
8439         {
8440           error "no Automake input file found for '$arg'";
8441           $errspec = 1;
8442         }
8443     }
8444   fatal "no input file found among supplied arguments"
8445     if $errspec && ! @input_files;
8446 }
8447
8448
8449 # handle_makefile ($MAKEFILE_IN)
8450 # ------------------------------
8451 # Deal with $MAKEFILE_IN.
8452 sub handle_makefile ($)
8453 {
8454   my ($file) =  @_;
8455   ($am_file = $file) =~ s/\.in$//;
8456   if (! -f ($am_file . '.am'))
8457     {
8458       error "'$am_file.am' does not exist";
8459     }
8460   else
8461     {
8462       # Any warning setting now local to this Makefile.am.
8463       dup_channel_setup;
8464
8465       generate_makefile ($am_file . '.am', $file);
8466
8467       # Back out any warning setting.
8468       drop_channel_setup;
8469     }
8470 }
8471
8472 # handle_makefiles_serial ()
8473 # --------------------------
8474 # Deal with all makefiles, without threads.
8475 sub handle_makefiles_serial ()
8476 {
8477   foreach my $file (@input_files)
8478     {
8479       handle_makefile ($file);
8480     }
8481 }
8482
8483 # get_number_of_threads ()
8484 # ------------------------
8485 # Logic for deciding how many worker threads to use.
8486 sub get_number_of_threads
8487 {
8488   my $nthreads = $ENV{'AUTOMAKE_JOBS'} || 0;
8489
8490   $nthreads = 0
8491     unless $nthreads =~ /^[0-9]+$/;
8492
8493   # It doesn't make sense to use more threads than makefiles,
8494   my $max_threads = @input_files;
8495
8496   if ($nthreads > $max_threads)
8497     {
8498       $nthreads = $max_threads;
8499     }
8500   return $nthreads;
8501 }
8502
8503 # handle_makefiles_threaded ($NTHREADS)
8504 # -------------------------------------
8505 # Deal with all makefiles, using threads.  The general strategy is to
8506 # spawn NTHREADS worker threads, dispatch makefiles to them, and let the
8507 # worker threads push back everything that needs serialization:
8508 # * warning and (normal) error messages, for stable stderr output
8509 #   order and content (avoiding duplicates, for example),
8510 # * races when installing aux files (and respective messages),
8511 # * races when collecting aux files for distribution.
8512 #
8513 # The latter requires that the makefile that deals with the aux dir
8514 # files be handled last, done by the master thread.
8515 sub handle_makefiles_threaded ($)
8516 {
8517   my ($nthreads) = @_;
8518
8519   # The file queue distributes all makefiles, the message queues
8520   # collect all serializations needed for respective files.
8521   my $file_queue = Thread::Queue->new;
8522   my %msg_queues;
8523   foreach my $file (@input_files)
8524     {
8525       $msg_queues{$file} = Thread::Queue->new;
8526     }
8527
8528   verb "spawning $nthreads worker threads";
8529   my @threads = (1 .. $nthreads);
8530   foreach my $t (@threads)
8531     {
8532       $t = threads->new (sub
8533         {
8534           while (my $file = $file_queue->dequeue)
8535             {
8536               verb "handling $file";
8537               my $queue = $msg_queues{$file};
8538               setup_channel_queue ($queue, QUEUE_MESSAGE);
8539               $required_conf_file_queue = $queue;
8540               handle_makefile ($file);
8541               $queue->enqueue (undef);
8542               setup_channel_queue (undef, undef);
8543               $required_conf_file_queue = undef;
8544             }
8545           return $exit_code;
8546         });
8547     }
8548
8549   # Queue all makefiles.
8550   verb "queuing " . @input_files . " input files";
8551   $file_queue->enqueue (@input_files, (undef) x @threads);
8552
8553   # Collect and process serializations.
8554   foreach my $file (@input_files)
8555     {
8556       verb "dequeuing messages for " . $file;
8557       reset_local_duplicates ();
8558       my $queue = $msg_queues{$file};
8559       while (my $key = $queue->dequeue)
8560         {
8561           if ($key eq QUEUE_MESSAGE)
8562             {
8563               pop_channel_queue ($queue);
8564             }
8565           elsif ($key eq QUEUE_CONF_FILE)
8566             {
8567               require_queued_file_check_or_copy ($queue);
8568             }
8569           else
8570             {
8571               prog_error "unexpected key $key";
8572             }
8573         }
8574     }
8575
8576   foreach my $t (@threads)
8577     {
8578       my @exit_thread = $t->join;
8579       $exit_code = $exit_thread[0]
8580         if ($exit_thread[0] > $exit_code);
8581     }
8582 }
8583
8584 ################################################################
8585
8586 # Parse the WARNINGS environment variable.
8587 parse_WARNINGS;
8588
8589 # Parse command line.
8590 parse_arguments;
8591
8592 $configure_ac = require_configure_ac;
8593
8594 # Do configure.ac scan only once.
8595 scan_autoconf_files;
8596
8597 if (! @input_files)
8598   {
8599     my $msg = '';
8600     $msg = "\nDid you forget AC_CONFIG_FILES([Makefile]) in $configure_ac?"
8601       if -f 'Makefile.am';
8602     fatal ("no 'Makefile.am' found for any configure output$msg");
8603   }
8604
8605 my $nthreads = get_number_of_threads ();
8606
8607 if ($perl_threads && $nthreads >= 1)
8608   {
8609     handle_makefiles_threaded ($nthreads);
8610   }
8611 else
8612   {
8613     handle_makefiles_serial ();
8614   }
8615
8616 exit $exit_code;
8617
8618
8619 ### Setup "GNU" style for perl-mode and cperl-mode.
8620 ## Local Variables:
8621 ## perl-indent-level: 2
8622 ## perl-continued-statement-offset: 2
8623 ## perl-continued-brace-offset: 0
8624 ## perl-brace-offset: 0
8625 ## perl-brace-imaginary-offset: 0
8626 ## perl-label-offset: -2
8627 ## cperl-indent-level: 2
8628 ## cperl-brace-offset: 0
8629 ## cperl-continued-brace-offset: 0
8630 ## cperl-label-offset: -2
8631 ## cperl-extra-newline-before-brace: t
8632 ## cperl-merge-trailing-else: nil
8633 ## cperl-continued-statement-offset: 2
8634 ## End: